configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5
   6 # require autoconf 2.13
   7 AC_PREREQ(2.13)
   8
   9 # Process this file with autoconf to produce a configure script.
  10 AC_INIT(glist.c)
  11
  12 # Save this value here, since automake will set cflags later
  13 cflags_set=${CFLAGS+set}
  14
  15 # we rewrite this file
  16 rm -f glibconfig-sysdefs.h
  17
  18 GLIB_DIVERT_BEFORE_HELP([
  19 #
  20 # The following version number definitions apply to GLib, GModule, GObject and GThread
  21 # as a whole, so if changes occoured in any of them, they are all
  22 # treated with the same interface and binary age.
  23 #
  24 # Making releases:
  25 #   GLIB_MICRO_VERSION += 1;
  26 #   GLIB_INTERFACE_AGE += 1;
  27 #   GLIB_BINARY_AGE += 1;
  28 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  29 # if backwards compatibility has been broken,
  30 # set GLIB_BINARY_AGE _and_ GLIB_INTERFACE_AGE to 0.
  31 #
  32 GLIB_MAJOR_VERSION=1
  33 GLIB_MINOR_VERSION=3
  34 GLIB_MICRO_VERSION=2
  35 GLIB_INTERFACE_AGE=0
  36 GLIB_BINARY_AGE=0
  37 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  38 ])dnl
  39
  40 AC_SUBST(GLIB_MAJOR_VERSION)
  41 AC_SUBST(GLIB_MINOR_VERSION)
  42 AC_SUBST(GLIB_MICRO_VERSION)
  43 AC_SUBST(GLIB_VERSION)
  44 AC_SUBST(GLIB_INTERFACE_AGE)
  45 AC_SUBST(GLIB_BINARY_AGE)
  46
  47 # libtool versioning
  48 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  49 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  50 LT_REVISION=$GLIB_INTERFACE_AGE
  51 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  52 AC_SUBST(LT_RELEASE)
  53 AC_SUBST(LT_CURRENT)
  54 AC_SUBST(LT_REVISION)
  55 AC_SUBST(LT_AGE)
  56
  57 VERSION=$GLIB_VERSION
  58 PACKAGE=glib
  59
  60 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  61
  62 # Specify a configuration file
  63 AM_CONFIG_HEADER(config.h)
  64
  65 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION,
  66                    [Define to the GLIB major version])
  67 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION,
  68                    [Define to the GLIB minor version])
  69 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION,
  70                    [Define to the GLIB micro version])
  71 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE,
  72                    [Define to the GLIB interface age])
  73 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE,
  74                    [Define to the GLIB binary age])
  75
  76 dnl Initialize maintainer mode
  77 AM_MAINTAINER_MODE
  78
  79 AC_CANONICAL_HOST
  80
  81 AC_MSG_CHECKING(for the BeOS)
  82 case $host in
  83   *-*-beos*)
  84     glib_native_beos="yes"
  85     ;;
  86   *)
  87     glib_native_beos="no"
  88     ;;
  89 esac
  90 AC_MSG_RESULT([$glib_native_beos])
  91
  92 dnl
  93
  94 GLIB_DIVERT_BEFORE_HELP([
  95 # figure debugging default, prior to $ac_help setup
  96 if test `expr $GLIB_MINOR_VERSION \% 2` = 1 ; then
  97   debug_default=yes
  98 else
  99   debug_default=minimum
 100 fi[]dnl
 101 ])
 102
 103 dnl declare --enable-* args and collect ac_help strings
 104 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
 105 AC_ARG_ENABLE(msg-prefix, [  --enable-msg-prefix     turn on program name and PID prefixing of messages and warnings],,enable_msg_prefix=no)
 106 AC_ARG_ENABLE(mem_check, [  --enable-mem-check      turn on malloc/free sanity checking [default=no]],,enable_mem_check=no)
 107 AC_ARG_ENABLE(mem_profile, [  --enable-mem-profile    turn on malloc profiling atexit [default=no]],,enable_mem_profile=no)
 108 AC_ARG_ENABLE(gc_friendly, [  --enable-gc-friendly    turn on garbage collector friendliness [default=no]],,enable_gc_friendly=no)
 109 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
 110                     , enable_ansi=no)
 111 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
 112                           ([=no] will override --with-threads)],,enable_threads=yes)
 113
 114 if test "x$enable_threads" != "xyes"; then
 115   enable_threads=no
 116 fi
 117
 118 AC_MSG_CHECKING(whether to enable memory checking)
 119 if test "x$enable_mem_check" = "xyes"; then
 120   AC_DEFINE(ENABLE_MEM_CHECK, 1, [Whether to enable memory checking])
 121   AC_SUBST(ENABLE_MEM_CHECK)
 122   AC_MSG_RESULT(yes)
 123 else
 124   AC_MSG_RESULT(no)
 125 fi
 126
 127 AC_MSG_CHECKING(whether to enable memory profiling)
 128 if test "x$enable_mem_profile" = "xyes"; then
 129   AC_DEFINE(ENABLE_MEM_PROFILE, 1, [Whether to enable memory profiling])
 130   AC_SUBST(ENABLE_MEM_PROFILE)
 131   AC_MSG_RESULT(yes)
 132 else
 133   AC_MSG_RESULT(no)
 134 fi
 135
 136 AC_MSG_CHECKING(whether to enable garbage collector friendliness)
 137 if test "x$enable_gc_friendly" = "xyes"; then
 138   AC_DEFINE(ENABLE_GC_FRIENDLY, 1, [Whether to enable GC friendliness])
 139   AC_SUBST(ENABLE_GC_FRIENDLY)
 140   AC_MSG_RESULT(yes)
 141 else
 142   AC_MSG_RESULT(no)
 143 fi
 144
 145 if test "x$enable_debug" = "xyes"; then
 146   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 147   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 148 else
 149   if test "x$enable_debug" = "xno"; then
 150     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 151   fi
 152 fi
 153
 154 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 155         [Whether glib was compiled with debugging enabled])
 156
 157 if test "x$enable_msg_prefix" = "xyes"; then
 158   AC_DEFINE_UNQUOTED(G_ENABLE_MSG_PREFIX, 1,
 159                      [Enable prefixing of error messages with program names])
 160 fi
 161
 162 # Checks for programs.
 163 AC_PROG_CC
 164 AM_PROG_CC_STDC
 165 AC_PROG_INSTALL
 166
 167 dnl Initialize libtool
 168 AM_PROG_LIBTOOL
 169
 170 if test "x$GCC" = "xyes"; then
 171   case " $CFLAGS " in
 172   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 173   *) CFLAGS="$CFLAGS -Wall" ;;
 174   esac
 175
 176   if test "x$enable_ansi" = "xyes"; then
 177     case " $CFLAGS " in
 178     *[[\ \      ]]-ansi[[\ \    ]]*) ;;
 179     *) CFLAGS="$CFLAGS -ansi" ;;
 180     esac
 181
 182     case " $CFLAGS " in
 183     *[[\ \      ]]-pedantic[[\ \        ]]*) ;;
 184     *) CFLAGS="$CFLAGS -pedantic" ;;
 185     esac
 186   fi
 187 fi
 188
 189 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 190 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 191 glib_save_LIBS=$LIBS
 192 LIBS="$LIBS -lm"
 193 AC_TRY_RUN([#include <math.h>
 194              int main (void) { return (log(1) != log(1.)); }],
 195      AC_MSG_RESULT(none needed),
 196      glib_save_CFLAGS=$CFLAGS
 197      CFLAGS="$CFLAGS -std1"
 198      AC_TRY_RUN([#include <math.h>
 199                  int main (void) { return (log(1) != log(1.)); }],
 200          AC_MSG_RESULT(-std1),
 201          AC_MSG_RESULT()
 202          CFLAGS=$glib_save_CFLAGS
 203          AC_MSG_WARN(
 204                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 205      )
 206 )
 207 LIBS=$glib_save_LIBS
 208
 209 dnl NeXTStep cc seems to need this
 210 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 211 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 212   AC_MSG_RESULT(none needed),
 213   glib_save_CFLAGS=$CFLAGS
 214   CFLAGS="$CFLAGS -posix"
 215   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 216     AC_MSG_RESULT(-posix),
 217     AC_MSG_RESULT()
 218     CFLAGS=$glib_save_CFLAGS
 219     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 220
 221 # Checks for header files.
 222 AC_HEADER_STDC
 223
 224 # Checks for library functions.
 225 AC_FUNC_VPRINTF
 226
 227 AC_FUNC_ALLOCA
 228
 229 AC_CHECK_FUNCS(atexit on_exit)
 230
 231 AC_CHECK_SIZEOF(char)
 232 AC_CHECK_SIZEOF(short)
 233 AC_CHECK_SIZEOF(long)
 234 AC_CHECK_SIZEOF(int)
 235 AC_CHECK_SIZEOF(void *)
 236 AC_CHECK_SIZEOF(long long)
 237
 238 if test x$ac_cv_sizeof_long_long = x8; then
 239         # long long is a 64 bit integer.
 240         AC_MSG_CHECKING(for format to printf and scanf a gint64)
 241         AC_CACHE_VAL(glib_cv_long_long_format,[
 242                 for format in ll q; do
 243                   AC_TRY_RUN([#include <stdio.h>
 244                         int main()
 245                         {
 246                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 247                           char buffer[1000];
 248                           sprintf (buffer, "%${format}u", a);
 249                           sscanf (buffer, "%${format}u", &b);
 250                           exit (b!=a);
 251                         }
 252                         ],
 253                         glib_cv_long_long_format=${format}
 254                         break)
 255                 done])
 256         if test -n "$glib_cv_long_long_format"; then
 257           AC_MSG_RESULT(%${glib_cv_long_long_format}i)
 258         else
 259           AC_MSG_RESULT(none)
 260         fi
 261 fi
 262
 263 dnl long doubles were not used, and a portability problem
 264 dnl AC_C_LONG_DOUBLE
 265 AC_C_CONST
 266
 267 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 268 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 269 dnl actually supported.
 270 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 271         AC_TRY_RUN([
 272         __inline int foo () { return 0; }
 273         int main () { return foo (); }
 274         ],
 275         glib_cv_has__inline=yes
 276         ,
 277         glib_cv_has__inline=no
 278         ,)
 279 ])
 280 case x$glib_cv_has__inline in
 281 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 282 esac
 283 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 284         AC_TRY_RUN([
 285         __inline__ int foo () { return 0; }
 286         int main () { return foo (); }
 287         ],
 288         glib_cv_has__inline__=yes
 289         ,
 290         glib_cv_has__inline__=no
 291         ,)
 292 ])
 293 case x$glib_cv_has__inline__ in
 294 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 295 esac
 296 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 297         AC_TRY_RUN([
 298         inline int foo () { return 0; }
 299         int main () { return foo (); }
 300         ],
 301         glib_cv_hasinline=yes
 302         ,
 303         glib_cv_hasinline=no
 304         ,)
 305 ])
 306 case x$glib_cv_hasinline in
 307 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 308 esac
 309
 310 # check for bytesex stuff
 311 AC_C_BIGENDIAN
 312
 313 # check for header files
 314 AC_CHECK_HEADERS([float.h limits.h pwd.h sys/param.h sys/poll.h sys/select.h])
 315 AC_CHECK_HEADERS([sys/time.h sys/times.h unistd.h values.h stdint.h sched.h])
 316
 317 AC_MSG_CHECKING(whether make is GNU Make)
 318 STRIP_BEGIN=
 319 STRIP_END=
 320 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 321         STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
 322         STRIP_END=')'
 323         AC_MSG_RESULT(yes)
 324 else
 325         AC_MSG_RESULT(no)
 326 fi
 327 STRIP_DUMMY=
 328 AC_SUBST(STRIP_DUMMY)
 329 AC_SUBST(STRIP_BEGIN)
 330 AC_SUBST(STRIP_END)
 331
 332 # check additional type sizes
 333 size_includes=["
 334 #include <stdarg.h>
 335 #include <stdio.h>
 336 #include <ctype.h>
 337 #include <string.h>
 338 "]
 339 if test "x$ac_cv_header_stdint_h" = "xyes"; then
 340   size_includes=["$size_includes
 341 #include <stdint.h>
 342 "]
 343 fi
 344 if test "x$ac_cv_header_unistd_h" = "xyes"; then
 345   size_includes=["$size_includes
 346 #include <unistd.h>
 347 "]
 348 fi
 349 GLIB_SIZEOF([$size_includes], size_t, size_t)
 350 GLIB_SIZEOF([$size_includes], ptrdiff_t, ptrdiff_t)
 351 GLIB_SIZEOF([$size_includes], intmax_t, intmax_t)
 352
 353 # Check for some functions
 354 AC_CHECK_FUNCS(lstat strerror strsignal memmove mkstemp vsnprintf strcasecmp strncasecmp poll getcwd)
 355
 356 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 357 # The check is borrowed from the PERL Configure script.
 358 if test "$ac_cv_func_memmove" != "yes"; then
 359   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 360     glib_cv_working_bcopy,[AC_TRY_RUN([
 361       int main() {
 362         char buf[128], abc[128], *b;
 363         int len, off, align;
 364         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 365         for (align = 7; align >= 0; align--) {
 366           for (len = 36; len; len--) {
 367             b = buf+align; bcopy(abc, b, len);
 368             for (off = 1; off <= len; off++) {
 369               bcopy(b, b+off, len); bcopy(b+off, b, len);
 370                 if (bcmp(b, abc, len)) return(1);
 371             }
 372           }
 373         }
 374         return(0);
 375       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 376   if test "$glib_cv_working_bcopy" = "yes"; then
 377     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 378   fi
 379 fi
 380
 381 # Check for sys_errlist
 382 AC_MSG_CHECKING(for sys_errlist)
 383 AC_TRY_LINK(, [
 384 extern char *sys_errlist[];
 385 extern int sys_nerr;
 386 sys_errlist[sys_nerr-1][0] = 0;
 387 ], glib_ok=yes, glib_ok=no)
 388 AC_MSG_RESULT($glib_ok)
 389 if test $glib_ok = no; then
 390     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 391 fi
 392
 393 # Check for sys_siglist
 394 AC_MSG_CHECKING(for sys_siglist)
 395 AC_TRY_LINK(, [
 396 extern char *sys_siglist[];
 397 exit (sys_siglist[0]);
 398 ], glib_ok=yes, glib_ok=no)
 399 AC_MSG_RESULT($glib_ok)
 400 if test $glib_ok = no; then
 401     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 402 fi
 403
 404 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 405 AC_MSG_CHECKING(for sys_siglist declaration)
 406 AC_TRY_COMPILE([#include <signal.h>], [
 407 strlen (sys_siglist[0]);
 408 ], glib_ok=yes, glib_ok=no)
 409 AC_MSG_RESULT($glib_ok)
 410 if test $glib_ok = no; then
 411     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 412 fi
 413
 414 # Check if <sys/select.h> needs to be included for fd_set
 415 AC_MSG_CHECKING([for fd_set])
 416 AC_TRY_COMPILE([#include <sys/types.h>],
 417         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 418 if test $gtk_ok = yes; then
 419     AC_MSG_RESULT([yes, found in sys/types.h])
 420 else
 421     AC_HEADER_EGREP(fd_set, sys/select.h, gtk_ok=yes)
 422     if test $gtk_ok = yes; then
 423         # *** FIXME: give it a different name
 424         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
 425         AC_MSG_RESULT([yes, found in sys/select.h])
 426     else
 427         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
 428         AC_MSG_RESULT(no)
 429     fi
 430 fi
 431
 432 dnl *** check for sane realloc() ***
 433 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
 434         AC_TRY_RUN([
 435         #include <stdlib.h>
 436         int main() {
 437           return realloc (0, sizeof (int)) == 0;
 438         }],
 439         [glib_cv_sane_realloc=yes],
 440         [glib_cv_sane_realloc=no],
 441         [])
 442 ])
 443 if test x$glib_cv_sane_realloc = xyes; then
 444   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
 445 fi
 446
 447 dnl Check for nl_langinfo and CODESET
 448
 449 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
 450 AC_TRY_COMPILE([#include <langinfo.h>],
 451         [char *codeset = nl_langinfo (CODESET);],
 452    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
 453    have_codeset=yes,
 454    have_codeset=no)
 455 AC_MSG_RESULT($have_codeset)
 456
 457
 458 dnl ****************************************
 459 dnl *** strlcpy/strlcat                  ***
 460 dnl ****************************************
 461 # Check for strlcpy
 462 AC_MSG_CHECKING(for strlcpy/strlcat)
 463 AC_TRY_LINK([#include <stdlib.h>
 464 #include <string.h>], [
 465 char *p = malloc(10);
 466 (void) strlcpy(p, "hi", 10);
 467 (void) strlcat(p, "bye", 10);
 468 ], glib_ok=yes, glib_ok=no)
 469 AC_MSG_RESULT($glib_ok)
 470 if test $glib_ok = yes; then
 471     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
 472 fi
 473
 474
 475 dnl **********************
 476 dnl *** va_copy checks ***
 477 dnl **********************
 478 dnl we currently check for all three va_copy possibilities, so we get
 479 dnl all results in config.log for bug reports.
 480 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
 481         AC_TRY_RUN([
 482         #include <stdarg.h>
 483         void f (int i, ...) {
 484         va_list args1, args2;
 485         va_start (args1, i);
 486         va_copy (args2, args1);
 487         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 488           exit (1);
 489         va_end (args1); va_end (args2);
 490         }
 491         int main() {
 492           f (0, 42);
 493           return 0;
 494         }],
 495         [glib_cv_va_copy=yes],
 496         [glib_cv_va_copy=no],
 497         [])
 498 ])
 499 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
 500         AC_TRY_RUN([
 501         #include <stdarg.h>
 502         void f (int i, ...) {
 503         va_list args1, args2;
 504         va_start (args1, i);
 505         __va_copy (args2, args1);
 506         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 507           exit (1);
 508         va_end (args1); va_end (args2);
 509         }
 510         int main() {
 511           f (0, 42);
 512           return 0;
 513         }],
 514         [glib_cv___va_copy=yes],
 515         [glib_cv___va_copy=no],
 516         [])
 517 ])
 518
 519 if test "x$glib_cv_va_copy" = "xyes"; then
 520   g_va_copy_func=va_copy
 521 else if test "x$glib_cv___va_copy" = "xyes"; then
 522   g_va_copy_func=__va_copy
 523 fi
 524 fi
 525
 526 if test -n "$g_va_copy_func"; then
 527   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
 528 fi
 529
 530 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
 531         AC_TRY_RUN([
 532         #include <stdarg.h>
 533         void f (int i, ...) {
 534         va_list args1, args2;
 535         va_start (args1, i);
 536         args2 = args1;
 537         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 538           exit (1);
 539         va_end (args1); va_end (args2);
 540         }
 541         int main() {
 542           f (0, 42);
 543           return 0;
 544         }],
 545         [glib_cv_va_val_copy=yes],
 546         [glib_cv_va_val_copy=no],
 547         [])
 548 ])
 549
 550 if test "x$glib_cv_va_val_copy" = "xno"; then
 551   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 552 fi
 553
 554 dnl ***********************
 555 dnl *** g_module checks ***
 556 dnl ***********************
 557 G_MODULE_LIBS=
 558 G_MODULE_LIBS_EXTRA=
 559 G_MODULE_PLUGIN_LIBS=
 560 G_MODULE_LDFLAGS=
 561 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
 562 G_MODULE_NEED_USCORE=0
 563 G_MODULE_HAVE_DLERROR=0
 564 dnl *** dlopen() and dlsym() in system libraries
 565 if test -z "$G_MODULE_IMPL"; then
 566         AC_CHECK_FUNC(dlopen,
 567                       [AC_CHECK_FUNC(dlsym,
 568                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 569                       [])
 570 fi
 571 dnl *** load_image (BeOS)
 572 if test -z "$G_MODULE_IMPL" -a "x$glib_native_beos" = "xyes"; then
 573   AC_CHECK_LIB(root, load_image,
 574       [G_MODULE_LIBS="-lbe -lroot -lglib"
 575       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
 576       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
 577       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
 578       [])
 579 fi
 580 # *** dlopen() and dlsym() in libdl
 581 if test -z "$G_MODULE_IMPL"; then
 582         AC_CHECK_LIB(dl, dlopen,
 583                      [AC_CHECK_LIB(dl, dlsym,
 584                                    [G_MODULE_LIBS=-ldl
 585                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 586                      [])
 587 fi
 588 dnl *** shl_load() in libdld (HP-UX)
 589 if test -z "$G_MODULE_IMPL"; then
 590         AC_MSG_CHECKING(how to export all symbols)
 591         SAVED_LDFLAGS=$LDFLAGS
 592         LDFLAGS="$LDFLAGS -Wl,-E"
 593         AC_TRY_LINK(,[ return 0; ],
 594                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 595                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 596                 AC_TRY_LINK(,[ return 0; ],
 597                         [G_MODULE_LDFLAGS="-bexpall"],
 598                         [G_MODULE_LDFLAGS="none"])
 599         ])
 600         LDFLAGS=$SAVED_LDFLAGS
 601         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 602         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 603                 G_MODULE_LDFLAGS=
 604         fi
 605         AC_CHECK_LIB(dld, shl_load,
 606                 [G_MODULE_LIBS=-ldld
 607                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
 608                 [])
 609 fi
 610 dnl *** additional checks for G_MODULE_IMPL_DL
 611 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 612         case "$host_os" in
 613           linux*)
 614             G_MODULE_LDFLAGS='-rdynamic'
 615             ;;
 616         esac
 617         LIBS_orig="$LIBS"
 618         LDFLAGS_orig="$LDFLAGS"
 619         LIBS="$LIBS $G_MODULE_LIBS"
 620         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 621 dnl *** check whether we need preceeding underscores
 622         AC_CACHE_CHECK([for preceeding underscore in symbols],
 623                 glib_cv_uscore,[
 624                 AC_TRY_RUN([
 625                 #include <dlfcn.h>
 626                 int glib_underscore_test (void) { return 42; }
 627                 int main() {
 628                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 629                   handle = dlopen ((void*)0, 0);
 630                   if (handle) {
 631                     f1 = dlsym (handle, "glib_underscore_test");
 632                     f2 = dlsym (handle, "_glib_underscore_test");
 633                   } return (!f2 || f1);
 634                 }],
 635                         [glib_cv_uscore=yes],
 636                         [glib_cv_uscore=no],
 637                         [])
 638                 rm -f plugin.c plugin.o plugin.lo
 639         ])
 640         if test "x$glib_cv_uscore" = "xyes"; then
 641                 G_MODULE_NEED_USCORE=1
 642         else
 643                 G_MODULE_NEED_USCORE=0
 644         fi
 645
 646         LDFLAGS="$LDFLAGS_orig"
 647 dnl *** check for having dlerror()
 648         AC_CHECK_FUNC(dlerror,
 649                 [G_MODULE_HAVE_DLERROR=1],
 650                 [G_MODULE_HAVE_DLERROR=0])
 651         LIBS="$LIBS_orig"
 652 fi
 653 dnl *** done, have e got an implementation?
 654 if test -z "$G_MODULE_IMPL"; then
 655         G_MODULE_IMPL=0
 656 fi
 657 AC_SUBST(G_MODULE_IMPL)
 658 AC_SUBST(G_MODULE_LIBS)
 659 AC_SUBST(G_MODULE_LIBS_EXTRA)
 660 AC_SUBST(G_MODULE_PLUGIN_LIBS)
 661 AC_SUBST(G_MODULE_LDFLAGS)
 662 AC_SUBST(G_MODULE_HAVE_DLERROR)
 663 AC_SUBST(G_MODULE_NEED_USCORE)
 664 AC_SUBST(GLIB_DEBUG_FLAGS)
 665
 666
 667 dnl ***********************
 668 dnl *** g_thread checks ***
 669 dnl ***********************
 670
 671 AC_ARG_WITH(threads, [  --with-threads=[none/posix/dce/solaris] specify a thread implementation to use],
 672         if test "x$with_threads" = x; then
 673                 want_threads=yes
 674         else
 675                 want_threads=$with_threads
 676         fi,
 677         want_threads=yes)
 678 if test "x$enable_threads" = "xno"; then
 679         want_threads=no
 680 fi
 681 if test "x$want_threads" = "xnone"; then
 682         want_threads=no
 683 fi
 684
 685 dnl error and warning message
 686 dnl *************************
 687
 688 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
 689                 computer. GLib will not have a default thread implementation."
 690
 691 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
 692                 platform (normaly it's "_REENTRANT"). I'll not use any flag on
 693                 compilation now, but then your programs might not work.
 694                 Please provide information on how it is done on your system."
 695
 696 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
 697                 "
 698
 699 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
 700                 provide information on your thread implementation.
 701                 You can also run 'configure --disable-threads'
 702                 to compile without thread support."
 703
 704 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
 705                 functions will not be MT-safe during their first call because
 706                 there is no working 'getpwuid_r' on your system."
 707
 708 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
 709                 because there is no 'localtime_r' on your system."
 710
 711 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
 712                 crude surrogate will be used. If you happen to know a
 713                 yield function for your system, please inform the GLib
 714                 developers."
 715
 716 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
 717                 threads on your system. Thus threads can only have the default
 718                 priority. If you happen to know these main/max
 719                 priorities, please inform the GLib developers."
 720
 721
 722 dnl determination of thread implementation
 723 dnl ***************************************
 724
 725 have_threads=none
 726 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
 727         case $host in
 728                 *-*-solaris*)
 729                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
 730                 ;;
 731         esac
 732 fi
 733 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
 734                                 || test "x$want_threads" = xdce; then
 735         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
 736         # -U_OSF_SOURCE is for Digital UNIX 4.0d
 737         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
 738         glib_save_CPPFLAGS="$CPPFLAGS"
 739         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
 740         if test "x$have_threads" = xnone; then
 741                 AC_TRY_COMPILE([#include <pthread.h>],
 742                         [pthread_attr_t attr; pthread_attr_init(&attr);],
 743                         have_threads=posix)
 744         fi
 745         if test "x$have_threads" = xnone; then
 746                 AC_TRY_COMPILE([#include <pthread.h>],
 747                         [pthread_attr_t attr; pthread_attr_create(&attr);],
 748                         have_threads=posix)
 749         fi
 750         CPPFLAGS="$glib_save_CPPFLAGS"
 751 fi
 752
 753 AC_MSG_CHECKING(for thread implementation)
 754
 755 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
 756         AC_MSG_RESULT(none available)
 757         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
 758 else
 759         AC_MSG_RESULT($have_threads)
 760 fi
 761
 762
 763 dnl determination of G_THREAD_CFLAGS
 764 dnl ********************************
 765
 766 G_THREAD_LIBS=
 767 G_THREAD_LIBS_EXTRA=
 768 G_THREAD_CFLAGS=
 769
 770 if test x"$have_threads" != xnone; then
 771
 772     G_THREAD_CFLAGS="-D_REENTRANT" # good default guess
 773
 774     case $host in
 775         *-aix*)
 776                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 777                 if test x"$GCC" = xyes; then
 778                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
 779                 fi
 780                 ;;
 781         *-freebsd2.2*)
 782                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 783
 784                 # FreeBSD 2.2.x shiped with gcc 2.7.2.x, which doesn't support
 785                 # -mthreads flag.
 786                 ;;
 787         *-sysv5uw7*)  # UnixWare 7
 788                 if test "$GCC" != "yes"; then
 789                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -Kthread"
 790                 else
 791                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -pthread"
 792                 fi
 793                 ;;
 794         *-dg-dgux*)  # DG/UX
 795                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
 796     esac
 797
 798     # if we are not finding the ctime_r function, then we probably are
 799     # not using the proper multithread flag
 800
 801     glib_save_CPPFLAGS="$CPPFLAGS"
 802     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
 803
 804     AC_TRY_COMPILE([#include <time.h>],
 805         [time_t t; char b[30]; ctime_r (&t, b);], ,
 806             [AC_TRY_COMPILE([#include <time.h>],
 807                 [time_t t; char b[30]; ctime_r (&t, b, 30);], ,
 808                         AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
 809
 810     CPPFLAGS="$glib_save_CPPFLAGS"
 811
 812     AC_MSG_CHECKING(thread related cflags)
 813     AC_MSG_RESULT($G_THREAD_CFLAGS)
 814     CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 815 fi
 816
 817 dnl determination of G_THREAD_LIBS
 818 dnl ******************************
 819
 820 mutex_has_default=no
 821 case $have_threads in
 822         posix|dce)
 823            glib_save_CPPFLAGS="$CPPFLAGS"
 824            CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
 825            G_THREAD_LIBS=error
 826            glib_save_LIBS="$LIBS"
 827            case $host in
 828              *-sysv5uw7*) # UnixWare 7
 829                 if test "$GCC" != "yes"; then
 830                         G_THREAD_LIBS="-Kthread"
 831                 else
 832                         G_THREAD_LIBS="-pthread"
 833                 fi
 834                 ;;
 835              *)
 836                 for thread_lib in "" pthread pthreads c_r thread dce; do
 837                         if test x"$thread_lib" = x; then
 838                                 add_thread_lib=""
 839                                 IN=""
 840                         else
 841                                 add_thread_lib="-l$thread_lib"
 842                                 IN=" in -l$thread_lib"
 843                         fi
 844                         if test x"$have_threads" = xposix; then
 845                                 defattr=0
 846                         else
 847                                 defattr=pthread_attr_default
 848                         fi
 849
 850                         LIBS="$glib_save_LIBS $add_thread_lib"
 851
 852                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
 853                         AC_TRY_RUN([#include <pthread.h>
 854                                 int check_me = 0;
 855                                 void* func(void* data) {check_me = 42;}
 856                                 main()
 857                                 { pthread_t t;
 858                                   void *ret;
 859                                   pthread_create (&t, $defattr, func, 0);
 860                                   pthread_join (t, &ret);
 861                                   exit (check_me != 42);
 862                                 }],
 863                                 [AC_MSG_RESULT(yes)
 864                                 G_THREAD_LIBS="$add_thread_lib"
 865                                 break],
 866                                 [AC_MSG_RESULT(no)])
 867                 done
 868                 if test "x$G_THREAD_LIBS" = xerror; then
 869                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 870                 fi
 871                 for thread_lib in "" rt rte; do
 872                         if test x"$thread_lib" = x; then
 873                                 add_thread_lib=""
 874                                 IN=""
 875                         else
 876                                 add_thread_lib="-l$thread_lib"
 877                                 IN=" in -l$thread_lib"
 878                         fi
 879                         LIBS="$glib_save_LIBS $add_thread_lib"
 880
 881                         AC_MSG_CHECKING(for sched_get_priority_min$IN)
 882                         AC_TRY_RUN([#include <sched.h>
 883                                 #include <errno.h>
 884                                 int main() {
 885                                 errno = 0;
 886                                 return sched_get_priority_min(SCHED_OTHER)==-1
 887                                         && errno != 0;
 888                                 }],
 889                                 [AC_MSG_RESULT(yes)
 890                                 G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
 891                                 posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
 892                                 posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
 893                                 break],
 894                                 [AC_MSG_RESULT(no)])
 895                 done
 896                 LIBS="$glib_save_LIBS"
 897                 ;;
 898            esac
 899            mutex_has_default=yes
 900            mutex_default_type='pthread_mutex_t'
 901            mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
 902            mutex_header_file='pthread.h'
 903            if test "x$have_threads" = "xposix"; then
 904              g_threads_impl="POSIX"
 905            else
 906              g_threads_impl="DCE"
 907              have_threads="posix"
 908            fi
 909            AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
 910            CPPFLAGS="$glib_save_CPPFLAGS"
 911            ;;
 912         solaris)
 913            G_THREAD_LIBS=error
 914            AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
 915            mutex_has_default=yes
 916            mutex_default_type='mutex_t'
 917            mutex_default_init="DEFAULTMUTEX"
 918            mutex_header_file='thread.h'
 919            g_threads_impl="SOLARIS"
 920            ;;
 921         none)
 922            g_threads_impl="NONE"
 923            ;;
 924         *)
 925            g_threads_impl="NONE"
 926            G_THREAD_LIBS=error
 927            ;;
 928 esac
 929
 930 if test "x$G_THREAD_LIBS" = xerror; then
 931         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 932 fi
 933
 934 case $host in
 935   *-*-beos*)
 936     G_THREAD_LIBS="-lbe -lroot -lglib "
 937     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
 938     ;;
 939   *)
 940     ;;
 941 esac
 942
 943 AC_MSG_CHECKING(thread related libraries)
 944 AC_MSG_RESULT($G_THREAD_LIBS)
 945
 946 dnl check for mt safe function variants and some posix functions
 947 dnl ************************************************************
 948
 949 if test x"$have_threads" != xnone; then
 950         glib_save_LIBS="$LIBS"
 951         # we are not doing the following for now, as this might require glib
 952         # to always be linked with the thread libs on some platforms.
 953         # LIBS="$LIBS $G_THREAD_LIBS"
 954         AC_CHECK_FUNCS(localtime_r)
 955         if test "$ac_cv_header_pwd_h" = "yes"; then
 956                 AC_CACHE_CHECK([for posix getpwuid_r],
 957                         ac_cv_func_posix_getpwuid_r,
 958                         [AC_TRY_RUN([#include <errno.h>
 959                                 #include <pwd.h>
 960                                 int main () { char buffer[10000];
 961                                 struct passwd pwd, *pwptr = &pwd;
 962                                 int error;
 963                                 errno = 0;
 964                                 error = getpwuid_r (0, &pwd, buffer,
 965                                         sizeof (buffer), &pwptr);
 966                                 return (error < 0 && errno == ENOSYS)
 967                                         || error == ENOSYS; }],
 968                                 [ac_cv_func_posix_getpwuid_r=yes],
 969                                 [ac_cv_func_posix_getpwuid_r=no])])
 970                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
 971                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
 972                                 [Have POSIX function getpwuid_r])
 973                 else
 974                         AC_CACHE_CHECK([for nonposix getpwuid_r],
 975                                 ac_cv_func_nonposix_getpwuid_r,
 976                                 [AC_TRY_COMPILE([#include <pwd.h>],
 977                                         [char buffer[10000];
 978                                         struct passwd pwd;
 979                                         getpwuid_r (0, &pwd, buffer,
 980                                                         sizeof (buffer));],
 981                                         [ac_cv_func_nonposix_getpwuid_r=yes],
 982                                         [ac_cv_func_nonposix_getpwuid_r=no])])
 983                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
 984                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
 985                                         [Have non-POSIX function getpwuid_r])
 986                         fi
 987                 fi
 988         fi
 989         LIBS="$LIBS $G_THREAD_LIBS"
 990         if test x"$have_threads" = xposix; then
 991                 glib_save_CPPFLAGS="$CPPFLAGS"
 992                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
 993                 GLIB_SIZEOF([#include <pthread.h>],
 994                         pthread_t,
 995                         system_thread)
 996                 # This is not AC_CHECK_FUNC to also work with function
 997                 # name mangling in header files.
 998                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
 999                 AC_TRY_LINK([#include <pthread.h>],
1000                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1001                         [AC_MSG_RESULT(yes)
1002                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1003                                   [Have function pthread_attr_setstacksize])],
1004                         [AC_MSG_RESULT(no)])
1005                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1006                 if test x"$posix_priority_min" = xnone; then
1007                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1008                                 PX_PRIO_MIN],,[
1009                                 posix_priority_min=PX_PRIO_MIN
1010                                 posix_priority_max=PX_PRIO_MAX])
1011                 fi
1012                 if test x"$posix_priority_min" = xnone; then
1013                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1014                                 PRI_OTHER_MIN],,[
1015                                 posix_priority_min=PRI_OTHER_MIN
1016                                 posix_priority_max=PRI_OTHER_MAX])
1017                 fi
1018                 if test x"$posix_priority_min" = x; then
1019                         AC_MSG_RESULT(none found)
1020                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1021                         posix_priority_min=-1
1022                         posix_priority_max=-1
1023                 else
1024                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1025                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1026                         AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])
1027                 fi
1028                 posix_yield_func=none
1029                 AC_MSG_CHECKING(for posix yield function)
1030                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1031                                                         thr_yield; do
1032                         AC_TRY_LINK([#include <pthread.h>],
1033                                 [$yield_func()],
1034                                 [posix_yield_func="$yield_func"
1035                                 break])
1036                 done
1037                 if test x"$posix_yield_func" = xnone; then
1038                         AC_MSG_RESULT(none found)
1039                         AC_MSG_WARN($POSIX_NO_YIELD)
1040                         posix_yield_func="g_usleep(1000)"
1041                 else
1042                         AC_MSG_RESULT($posix_yield_func)
1043                         posix_yield_func="$posix_yield_func()"
1044                 fi
1045                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1046                 CPPFLAGS="$glib_save_CPPFLAGS"
1047
1048                 AC_MSG_CHECKING(whether to use the PID niceness surrogate for thread priorities)
1049                 AC_TRY_RUN([#include <pthread.h>
1050                         #include <sys/types.h>
1051                         #include <unistd.h>
1052                         pid_t other_pid = 0;
1053
1054                         void* func(void* data) {other_pid = getpid();}
1055                         main()
1056                         { pthread_t t;
1057                           void *ret;
1058                           pthread_create (&t, $defattr, func, NULL);
1059                           pthread_join (t, &ret);
1060                           exit (getpid()==other_pid ||
1061                                 $posix_priority_min != $posix_priority_max);
1062                         }],
1063                         [AC_MSG_RESULT(yes),
1064                          AC_DEFINE(G_THREAD_USE_PID_SURROGATE, 1,
1065                                 [whether to use the PID niceness surrogate for thread priorities])
1066
1067                          glib_cv_sizeof_system_thread=`expr $glib_cv_sizeof_system_thread + $ac_cv_sizeof_long`],
1068                         [AC_MSG_RESULT(no)])
1069
1070         else # solaris threads
1071                 GLIB_SIZEOF([#include <thread.h>],
1072                         thread_t,
1073                         system_thread)
1074         fi
1075
1076         LIBS="$glib_save_LIBS"
1077
1078         # now spit out all the warnings.
1079         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1080            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1081                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1082         fi
1083         if test "$ac_cv_func_localtime_r" != "yes"; then
1084                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1085         fi
1086 else
1087         # If no thread implementation exists, we will provide enough
1088         # space for a pointer
1089         GLIB_SIZEOF(, void*, system_thread)
1090 fi
1091
1092 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1093                    [Source file containing theread implementation])
1094 AC_SUBST(G_THREAD_CFLAGS)
1095 AC_SUBST(G_THREAD_LIBS)
1096 AC_SUBST(G_THREAD_LIBS_EXTRA)
1097
1098 dnl **********************************************
1099 dnl *** GDefaultMutex setup and initialization ***
1100 dnl **********************************************
1101 dnl
1102 dnl if mutex_has_default = yes, we also got
1103 dnl mutex_default_type, mutex_default_init and mutex_header_file
1104 GLIB_IF_VAR_EQ(mutex_has_default, yes,
1105         glib_save_CPPFLAGS="$CPPFLAGS"
1106         glib_save_LIBS="$LIBS"
1107         LIBS="$LIBS $G_THREAD_LIBS"
1108         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1109         GLIB_SIZEOF([#include <$mutex_header_file>],
1110                     $mutex_default_type,
1111                     gmutex,
1112                     )
1113         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1114                            $mutex_default_type,
1115                            gmutex,
1116                            $glib_cv_sizeof_gmutex,
1117                            $mutex_default_init)
1118         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1119                 mutex_has_default=no
1120         fi
1121         CPPFLAGS="$glib_save_CPPFLAGS"
1122         LIBS="$glib_save_LIBS"
1123         ,
1124 )
1125
1126
1127 dnl ****************************************
1128 dnl *** GLib POLL* compatibility defines ***
1129 dnl ****************************************
1130 GLIB_SYSDEFS(
1131 [#include <sys/types.h>
1132 #include <sys/poll.h>],
1133         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
1134         glibconfig-sysdefs.h,
1135         =)
1136
1137 dnl ***********************
1138 dnl *** Tests for iconv ***
1139 dnl ***********************
1140
1141 AC_ARG_WITH(libiconv, [ --with-libiconv     Use the libiconv library ],,with_libiconv=maybe)
1142
1143 found_iconv=no
1144
1145 if test "x$with_libiconv" != "xyes" ; then
1146    #
1147    # Check in the C library
1148    #
1149    AC_CHECK_FUNC(iconv_open, with_libiconv=no; found_iconv=yes)
1150 fi
1151
1152 if test "x$with_libiconv" != "xno" ; then
1153    #
1154    # Check for libiconv
1155    #
1156    AC_CHECK_LIB(iconv, libiconv_open, with_libiconv=yes; found_iconv=yes)
1157 fi
1158
1159 if test "x$found_iconv" = "xno" ; then
1160    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
1161 fi
1162
1163 if test "x$with_libiconv" = "xyes" ; then
1164   ICONV_LIBS="-liconv"
1165   AC_DEFINE(USE_LIBICONV)
1166 fi
1167 AC_SUBST(ICONV_LIBS)
1168
1169 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
1170 dnl since we need it for g_iconv()
1171
1172 AC_MSG_CHECKING([for EILSEQ])
1173 AC_TRY_COMPILE([
1174 #include <errno.h>
1175 ],
1176 [
1177 int error = EILSEQ;
1178 ], have_eilseq=yes, have_eilseq=no);
1179 AC_MSG_RESULT($have_eilseq)
1180
1181 dnl **************************
1182 dnl *** Checks for gtk-doc ***
1183 dnl **************************
1184
1185 AC_ARG_WITH(html-dir, [  --with-html-dir=PATH path to installed docs ])
1186
1187 if test "x$with_html_dir" = "x" ; then
1188   HTML_DIR='${datadir}/gtk-doc/html'
1189 else
1190   HTML_DIR=$with_html_dir
1191 fi
1192
1193 AC_SUBST(HTML_DIR)
1194
1195
1196 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
1197 AM_CONDITIONAL(HAVE_GTK_DOC, $GTKDOC)
1198 AC_SUBST(HAVE_GTK_DOC)
1199
1200 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1201 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1202
1203 dnl Let people disable the gtk-doc stuff.
1204 AC_ARG_ENABLE(gtk-doc, [  --enable-gtk-doc  Use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)
1205
1206 if test x$enable_gtk_doc = xauto ; then
1207   if test x$GTKDOC = xtrue ; then
1208     enable_gtk_doc=yes
1209   else
1210     enable_gtk_doc=no
1211   fi
1212 fi
1213
1214 dnl NOTE: We need to use a separate automake conditional for this
1215 dnl       to make this work with the tarballs.
1216 AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
1217
1218 dnl ******************************
1219 dnl *** output the whole stuff ***
1220 dnl ******************************
1221
1222 AC_OUTPUT_COMMANDS([
1223
1224 ## Generate `glibconfig.h' in two cases
1225 ## 1. `config.status' is run either explicitly, or via configure.
1226 ##     Esp. not when it is run in `Makefile' to generate makefiles and
1227 ##     config.h
1228 ## 2. CONFIG_OTHER is set explicitly
1229 ##
1230 ## Case 1 is difficult.  We know that `automake' sets one of
1231 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
1232 ## only when AM_CONFIG_HEADER is set, however.
1233
1234 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
1235   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
1236   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
1237 fi
1238 case "$CONFIG_OTHER" in
1239 *glibconfig.h*)
1240         echo creating glibconfig.h
1241         outfile=glibconfig.h-tmp
1242         cat > $outfile <<\_______EOF
1243 /* glibconfig.h
1244  *
1245  * This is a generated file.  Please modify 'configure.in'
1246  */
1247
1248 #ifndef __G_LIBCONFIG_H__
1249 #define __G_LIBCONFIG_H__
1250
1251 #include <gmacros.h>
1252
1253 _______EOF
1254
1255         if test x$glib_limits_h = xyes; then
1256           echo '#include <limits.h>' >> $outfile
1257         fi
1258         if test x$glib_float_h = xyes; then
1259           echo '#include <float.h>' >> $outfile
1260         fi
1261         if test x$glib_values_h = xyes; then
1262           echo '#include <values.h>' >> $outfile
1263         fi
1264         if test "$glib_header_alloca_h" = "yes"; then
1265           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
1266         fi
1267         if test x$glib_sys_poll_h = xyes; then
1268           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
1269         fi
1270
1271         cat >> $outfile <<_______EOF
1272
1273 G_BEGIN_DECLS
1274
1275 #define G_MINFLOAT      $glib_mf
1276 #define G_MAXFLOAT      $glib_Mf
1277 #define G_MINDOUBLE     $glib_md
1278 #define G_MAXDOUBLE     $glib_Md
1279 #define G_MINSHORT      $glib_ms
1280 #define G_MAXSHORT      $glib_Ms
1281 #define G_MAXUSHORT     $glib_Mus
1282 #define G_MININT        $glib_mi
1283 #define G_MAXINT        $glib_Mi
1284 #define G_MAXUINT       $glib_Mui
1285 #define G_MINLONG       $glib_ml
1286 #define G_MAXLONG       $glib_Ml
1287 #define G_MAXULONG      $glib_Mul
1288
1289 _______EOF
1290
1291
1292         ### this should always be true in a modern C/C++ compiler
1293         cat >>$outfile <<_______EOF
1294 typedef signed char gint8;
1295 typedef unsigned char guint8;
1296 _______EOF
1297
1298
1299         if test -n "$gint16"; then
1300           cat >>$outfile <<_______EOF
1301 typedef signed $gint16 gint16;
1302 typedef unsigned $gint16 guint16;
1303 #define G_GINT16_FORMAT $gint16_format
1304 #define G_GUINT16_FORMAT $guint16_format
1305 _______EOF
1306         fi
1307
1308
1309         if test -n "$gint32"; then
1310           cat >>$outfile <<_______EOF
1311 typedef signed $gint32 gint32;
1312 typedef unsigned $gint32 guint32;
1313 #define G_GINT32_FORMAT $gint32_format
1314 #define G_GUINT32_FORMAT $guint32_format
1315 _______EOF
1316         fi
1317
1318
1319         if test -n "$gint64"; then
1320           cat >>$outfile <<_______EOF
1321 #define G_HAVE_GINT64 1
1322
1323 ${glib_extension}typedef signed $gint64 gint64;
1324 ${glib_extension}typedef unsigned $gint64 guint64;
1325
1326 #define G_GINT64_CONSTANT(val)  $gint64_constant
1327 _______EOF
1328                 if test -n "$gint64_format"; then
1329           cat >>$outfile <<_______EOF
1330 #define G_GINT64_FORMAT $gint64_format
1331 #define G_GUINT64_FORMAT $guint64_format
1332 _______EOF
1333                 fi
1334         fi
1335
1336         case x$glib_size_t in
1337         x2) echo "typedef gint16  gssize;" >> $outfile
1338             echo "typedef guint16 gsize;"  >> $outfile
1339             ;;
1340         x4) echo "typedef gint32  gssize;" >> $outfile
1341             echo "typedef guint32 gsize;"  >> $outfile
1342             ;;
1343         x8) echo "typedef gint64  gssize;" >> $outfile
1344             echo "typedef guint64 gsize;"  >> $outfile
1345             ;;
1346         *)  echo "#error size of size_t is unknown" >> $outfile
1347             ;;
1348         esac
1349
1350         if test -z "$glib_unknown_void_p"; then
1351           cat >>$outfile <<_______EOF
1352
1353 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
1354 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
1355
1356 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
1357 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
1358 _______EOF
1359         else
1360           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
1361         fi
1362
1363
1364
1365         cat >>$outfile <<_______EOF
1366 $glib_atexit
1367 $glib_memmove
1368 $glib_defines
1369 $glib_os
1370
1371 $glib_vacopy
1372
1373 #ifdef  __cplusplus
1374 #define G_HAVE_INLINE   1
1375 #else   /* !__cplusplus */
1376 $glib_inline
1377 #endif  /* !__cplusplus */
1378 _______EOF
1379
1380         echo >>$outfile
1381         if test x$g_have_eilseq = xno; then
1382                 cat >>$outfile <<_______EOF
1383 #ifndef EILSEQ
1384 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
1385  * The correspondence between this and the corresponding definition
1386  * in libiconv is essential.
1387  */
1388 #  define EILSEQ ENOENT
1389 #endif
1390 _______EOF
1391
1392         fi
1393
1394         echo >>$outfile
1395         if test x$g_mutex_has_default = xyes; then
1396                 cat >>$outfile <<_______EOF
1397 $g_enable_threads_def G_THREADS_ENABLED
1398 #define G_THREADS_IMPL_$g_threads_impl_def
1399 typedef struct _GStaticMutex GStaticMutex;
1400 struct _GStaticMutex
1401 {
1402   struct _GMutex *runtime_mutex;
1403   struct {
1404     union {
1405       char   pad[$g_mutex_sizeof];
1406       double dummy_double;
1407       void  *dummy_pointer;
1408       long   dummy_long;
1409     } mutex;
1410     void *debug_info;
1411   } static_mutex;
1412 };
1413 #define G_STATIC_MUTEX_INIT     { NULL, { { { $g_mutex_contents} }, NULL } }
1414 #define g_static_mutex_get_mutex(mutex) \
1415   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->static_mutex)) : \
1416    g_static_mutex_get_mutex_impl (&((mutex)->runtime_mutex)))
1417 _______EOF
1418         else
1419                 cat >>$outfile <<_______EOF
1420 $g_enable_threads_def G_THREADS_ENABLED
1421 #define G_THREADS_IMPL_$g_threads_impl_def
1422 typedef struct _GMutex* GStaticMutex;
1423 #define G_STATIC_MUTEX_INIT NULL
1424 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (mutex))
1425 _______EOF
1426         fi
1427
1428         cat >>$outfile <<_______EOF
1429 /* This represents a system thread as used by the implementation. An
1430  * alien implementaion, as loaded by g_thread_init can only count on
1431  * "sizeof (gpointer)" bytes to store their info. We however need more
1432  * for some of our native implementations. */
1433 typedef union _GSystemThread GSystemThread;
1434 union _GSystemThread
1435 {
1436   char   data[$g_system_thread_sizeof];
1437   double dummy_double;
1438   void  *dummy_pointer;
1439   long   dummy_long;
1440 };
1441 _______EOF
1442
1443         echo >>$outfile
1444         g_bit_sizes="16 32"
1445         if test -n "$gint64"; then
1446           g_bit_sizes="$g_bit_sizes 64"
1447         fi
1448         for bits in $g_bit_sizes; do
1449           cat >>$outfile <<_______EOF
1450 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
1451 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
1452 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
1453 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
1454 _______EOF
1455         done
1456
1457         cat >>$outfile <<_______EOF
1458 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
1459 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
1460 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
1461 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
1462 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
1463 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
1464 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
1465 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
1466 #define G_BYTE_ORDER $g_byte_order
1467
1468 _______EOF
1469
1470         if test -r glibconfig-sysdefs.h; then
1471           cat glibconfig-sysdefs.h >>$outfile
1472         fi
1473
1474         cat >>$outfile <<_______EOF
1475
1476 G_END_DECLS
1477
1478 #endif /* GLIBCONFIG_H */
1479 _______EOF
1480
1481
1482         if cmp -s $outfile glibconfig.h; then
1483           echo glibconfig.h is unchanged
1484           rm -f $outfile
1485         else
1486           mv $outfile glibconfig.h
1487         fi ;;
1488 esac
1489 ],[
1490
1491 # Note that if two cases are the same, case goes with the first one.
1492 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
1493 # on variable expansion in case labels.  Look at the generated config.status
1494 # for a hint.
1495
1496 glib_header_alloca_h="$ac_cv_header_alloca_h"
1497
1498 case xyes in
1499 x$ac_cv_header_float_h)
1500   glib_float_h=yes
1501   glib_mf=FLT_MIN glib_Mf=FLT_MAX
1502   glib_md=DBL_MIN glib_Md=DBL_MAX
1503   ;;
1504 x$ac_cv_header_values_h)
1505   glib_values_h=yes
1506   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
1507   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
1508   ;;
1509 esac
1510
1511 case xyes in
1512 x$ac_cv_header_limits_h)
1513   glib_limits_h=yes
1514   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
1515   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
1516   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
1517   ;;
1518 x$ac_cv_header_values_h)
1519   glib_values_h=yes
1520   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
1521   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
1522   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
1523   ;;
1524 esac
1525
1526 if test x$ac_cv_header_sys_poll_h = xyes ; then
1527   glib_sys_poll_h=yes
1528 fi
1529
1530 case 2 in
1531 $ac_cv_sizeof_short)
1532   gint16=short
1533   gint16_format='"hi"'
1534   guint16_format='"hu"'
1535   ;;
1536 $ac_cv_sizeof_int)
1537   gint16=int
1538   gint16_format='"i"'
1539   guint16_format='"u"'
1540   ;;
1541 esac
1542 case 4 in
1543 $ac_cv_sizeof_short)
1544   gint32=short
1545   gint32_format='"hi"'
1546   guint32_format='"hu"'
1547   ;;
1548 $ac_cv_sizeof_int)
1549   gint32=int
1550   gint32_format='"i"'
1551   guint32_format='"u"'
1552   ;;
1553 $ac_cv_sizeof_long)
1554   gint32=long
1555   gint32_format='"li"'
1556   guint32_format='"lu"'
1557   ;;
1558 esac
1559 case 8 in
1560 $ac_cv_sizeof_int)
1561   gint64=int
1562   gint64_format='"i"'
1563   guint64_format='"u"'
1564   glib_extension=
1565   gint64_constant='(val)'
1566   ;;
1567 $ac_cv_sizeof_long)
1568   gint64=long
1569   gint64_format='"li"'
1570   guint64_format='"lu"'
1571   glib_extension=
1572   gint64_constant='(val##L)'
1573   ;;
1574 $ac_cv_sizeof_long_long)
1575   gint64='long long'
1576   if test -n "$glib_cv_long_long_format"; then
1577     gint64_format='"'$glib_cv_long_long_format'i"'
1578     guint64_format='"'$glib_cv_long_long_format'u"'
1579   fi
1580   glib_extension='G_GNUC_EXTENSION '
1581   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1582   ;;
1583 esac
1584 glib_size_t=$glib_cv_sizeof_size_t
1585
1586 gintbits=`expr $ac_cv_sizeof_int \* 8`
1587 glongbits=`expr $ac_cv_sizeof_long \* 8`
1588
1589
1590 case $ac_cv_sizeof_void_p in
1591 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
1592 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
1593 *)                      glib_unknown_void_p=yes ;;
1594 esac
1595
1596
1597 case xyes in
1598 x$ac_cv_func_atexit)
1599   glib_atexit="
1600 #ifdef NeXT /* @#%@! NeXTStep */
1601 # define g_ATEXIT(proc) (!atexit (proc))
1602 #else
1603 # define g_ATEXIT(proc) (atexit (proc))
1604 #endif"
1605   ;;
1606 x$ac_cv_func_on_exit)
1607   glib_atexit="
1608 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
1609   ;;
1610 esac
1611
1612 case xyes in
1613 x$ac_cv_func_memmove)
1614   glib_memmove='
1615 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
1616   ;;
1617 x$glib_cv_working_bcopy)
1618   glib_memmove="
1619 /* memmove isn't available, but bcopy can copy overlapping memory regions */
1620 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
1621   ;;
1622 *)
1623   glib_memmove="
1624 /* memmove isn't found and bcopy can't copy overlapping memory regions,
1625  * so we have to roll our own copy routine. */
1626 void g_memmove (void* dest, const void * src, unsigned long len);"
1627   ;;
1628 esac
1629
1630 glib_defines="
1631 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
1632 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
1633 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
1634 "
1635
1636 case xyes in
1637 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
1638 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
1639 *)                      glib_vacopy=''
1640 esac
1641
1642 if test x$glib_cv_va_val_copy = xno; then
1643   glib_vacopy="\$glib_vacopy
1644 #define G_VA_COPY_AS_ARRAY 1"
1645 fi
1646
1647 if test x$glib_cv_hasinline = xyes; then
1648     glib_inline='#define G_HAVE_INLINE 1'
1649 fi
1650 if test x$glib_cv_has__inline = xyes; then
1651     glib_inline="\$glib_inline
1652 #define G_HAVE___INLINE 1"
1653 fi
1654 if test x$glib_cv_has__inline__ = xyes; then
1655     glib_inline="\$glib_inline
1656 #define G_HAVE___INLINE__ 1"
1657 fi
1658
1659 case xyes in
1660 x$ac_cv_c_bigendian)
1661   g_byte_order=G_BIG_ENDIAN
1662   g_bs_native=BE
1663   g_bs_alien=LE
1664   ;;
1665 *)
1666   g_byte_order=G_LITTLE_ENDIAN
1667   g_bs_native=LE
1668   g_bs_alien=BE
1669   ;;
1670 esac
1671
1672 g_have_eilseq=$have_eilseq
1673
1674 case x$have_threads in
1675 xnone)  g_enable_threads_def="#undef";;
1676 *)      g_enable_threads_def="#define";;
1677 esac
1678
1679 g_threads_impl_def=$g_threads_impl
1680
1681 g_mutex_has_default="$mutex_has_default"
1682 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
1683 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
1684 g_mutex_contents="$glib_cv_byte_contents_gmutex"
1685
1686 case $host in
1687   *-*-beos*)
1688     glib_os="#define G_OS_BEOS"
1689     ;;
1690   *-*-cygwin*)
1691     glib_os="#define G_OS_UNIX
1692 #define G_WITH_CYGWIN"
1693 v    ;;
1694   *)
1695     glib_os="#define G_OS_UNIX"
1696     ;;
1697 esac
1698 ])
1699
1700 AC_OUTPUT([
1701 glib-2.0.pc
1702 gmodule-2.0.pc
1703 gthread-2.0.pc
1704 gobject-2.0.pc
1705 glib.spec
1706 Makefile
1707 glib-config-2.0
1708 build/Makefile
1709 build/win32/Makefile
1710 gmodule/gmoduleconf.h
1711 gmodule/Makefile
1712 gobject/Makefile
1713 gthread/Makefile
1714 docs/Makefile
1715 docs/glib-config.1
1716 docs/reference/Makefile
1717 docs/reference/glib/Makefile
1718 docs/reference/gobject/Makefile
1719 tests/Makefile
1720 ],[case "$CONFIG_FILES" in
1721 *glib-config-2.0*)chmod +x glib-config-2.0;;
1722 esac
1723 echo ""
1724 echo " *** IMPORTANT *** "
1725 echo ""
1726 echo "This is a development version of GLib.  You should be using a stable"
1727 echo "version, which is available at ftp://ftp.gtk.org/pub/gtk/v1.2/.  The"
1728 echo "version you just configured is meant for developers of GLib only:"
1729 echo ""
1730 echo "  * You should not base stable software on this version of GLib."
1731 echo "  * GNOME developers should use a stable version of GLib."
1732 echo ""
1733 echo "If you install this version of GLib, we strongly recommend that you"
1734 echo "install it in a different prefix than GLib 1.2.  Use --prefix as an"
1735 echo "argument to configure to do this.  Otherwise, you will not be able to"
1736 echo "do development with GLib 1.2 any longer."
1737 echo ""
1738 echo " *** You should be using GLib 1.2 instead. ***"
1739 ])