configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5 builtin(include, glib/libcharset/codeset.m4)dnl
   6 builtin(include, glib/libcharset/glibc21.m4)dnl
   7
   8 # require autoconf 2.13
   9 AC_PREREQ(2.13)
  10
  11 # Process this file with autoconf to produce a configure script.
  12 AC_INIT(glib/glib.h)
  13
  14 # Save this value here, since automake will set cflags later
  15 cflags_set=${CFLAGS+set}
  16
  17 # we rewrite this file
  18 rm -f glibconfig-sysdefs.h
  19
  20 GLIB_AC_DIVERT_BEFORE_HELP([
  21 #
  22 # The following version number definitions apply to GLib, GModule, GObject
  23 # and GThread as a whole, so if changes occoured in any of them, they are all
  24 # treated with the same interface and binary age.
  25 #
  26 # Making releases:
  27 #   GLIB_MICRO_VERSION += 1;
  28 #   GLIB_INTERFACE_AGE += 1;
  29 #   GLIB_BINARY_AGE += 1;
  30 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  31 # if backwards compatibility has been broken,
  32 # set GLIB_BINARY_AGE _and_ GLIB_INTERFACE_AGE to 0.
  33 #
  34 GLIB_MAJOR_VERSION=1
  35 GLIB_MINOR_VERSION=3
  36 GLIB_MICRO_VERSION=10
  37 GLIB_INTERFACE_AGE=0
  38 GLIB_BINARY_AGE=0
  39 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  40 ])dnl
  41
  42 AC_SUBST(GLIB_MAJOR_VERSION)
  43 AC_SUBST(GLIB_MINOR_VERSION)
  44 AC_SUBST(GLIB_MICRO_VERSION)
  45 AC_SUBST(GLIB_VERSION)
  46 AC_SUBST(GLIB_INTERFACE_AGE)
  47 AC_SUBST(GLIB_BINARY_AGE)
  48
  49 # libtool versioning
  50 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  51 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  52 LT_REVISION=$GLIB_INTERFACE_AGE
  53 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  54 LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  55 AC_SUBST(LT_RELEASE)
  56 AC_SUBST(LT_CURRENT)
  57 AC_SUBST(LT_REVISION)
  58 AC_SUBST(LT_AGE)
  59 AC_SUBST(LT_CURRENT_MINUS_AGE)
  60
  61 VERSION=$GLIB_VERSION
  62 PACKAGE=glib
  63
  64 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  65
  66 # Specify a configuration file
  67 AM_CONFIG_HEADER(config.h)
  68
  69 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION,
  70                    [Define to the GLIB major version])
  71 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION,
  72                    [Define to the GLIB minor version])
  73 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION,
  74                    [Define to the GLIB micro version])
  75 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE,
  76                    [Define to the GLIB interface age])
  77 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE,
  78                    [Define to the GLIB binary age])
  79
  80 dnl Initialize maintainer mode
  81 AM_MAINTAINER_MODE
  82
  83 AC_CANONICAL_HOST
  84
  85 AC_MSG_CHECKING(for the BeOS)
  86 case $host in
  87   *-*-beos*)
  88     glib_native_beos="yes"
  89     ;;
  90   *)
  91     glib_native_beos="no"
  92     ;;
  93 esac
  94 AC_MSG_RESULT([$glib_native_beos])
  95
  96 dnl
  97
  98 AC_MSG_CHECKING([for Win32])
  99 case "$host" in
 100   *-*-mingw*)
 101     glib_native_win32=yes
 102     G_LIB_WIN32_RESOURCE=glib-win32res.lo
 103     G_MODULE_WIN32_RESOURCE=gmodule-win32res.lo
 104     G_OBJECT_WIN32_RESOURCE=gobject-win32res.lo
 105     G_THREAD_WIN32_RESOURCE=gthread-win32res.lo
 106     GLIB_DEF=glib.def
 107     GMODULE_DEF=gmodule.def
 108     GOBJECT_DEF=gobject.def
 109     GTHREAD_DEF=gthread.def
 110     TESTGMODULE_EXP=testgmodule.exp
 111     ;;
 112   *)
 113     glib_native_win32=no
 114     G_LIB_WIN32_RESOURCE=
 115     G_MODULE_WIN32_RESOURCE=
 116     G_OBJECT_WIN32_RESOURCE=
 117     G_THREAD_WIN32_RESOURCE=
 118     GLIB_DEF=
 119     GMODULE_DEF=
 120     GOBJECT_DEF=
 121     GTHREAD_DEF=
 122     TESTGMODULE_EXP=
 123     ;;
 124 esac
 125 AC_MSG_RESULT([$glib_native_win32])
 126 AM_CONDITIONAL(OS_WIN32, test "$glib_native_win32" = "yes")
 127 AC_SUBST(G_LIB_WIN32_RESOURCE)
 128 AC_SUBST(G_MODULE_WIN32_RESOURCE)
 129 AC_SUBST(G_OBJECT_WIN32_RESOURCE)
 130 AC_SUBST(G_THREAD_WIN32_RESOURCE)
 131 AC_SUBST(GLIB_DEF)
 132 AC_SUBST(GMODULE_DEF)
 133 AC_SUBST(GOBJECT_DEF)
 134 AC_SUBST(GTHREAD_DEF)
 135 AC_SUBST(TESTGMODULE_EXP)
 136
 137 if test "$glib_native_win32" = "yes"; then
 138   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 139 fi
 140 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 141
 142 GLIB_AC_DIVERT_BEFORE_HELP([
 143 # figure debugging default, prior to $ac_help setup
 144 case $GLIB_MINOR_VERSION in
 145 *[[13579]]) debug_default=yes ;;
 146 *)          debug_default=minimum ;;
 147 esac[]dnl
 148 ])
 149
 150 dnl declare --enable-* args and collect ac_help strings
 151 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
 152 AC_ARG_ENABLE(gc_friendly, [  --enable-gc-friendly    turn on garbage collector friendliness [default=no]],,enable_gc_friendly=no)
 153 AC_ARG_ENABLE(mem_pools, [  --disable-mem-pools     disable all glib memory pools],,disable_mem_pools=no)
 154 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
 155                     , enable_ansi=no)
 156 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
 157                           ([=no] will override --with-threads)],,enable_threads=yes)
 158 AC_ARG_ENABLE(rebuilds, [  --disable-rebuilds      disable all source autogeneration rules],,enable_rebuilds=yes)
 159
 160 if test "x$enable_threads" != "xyes"; then
 161   enable_threads=no
 162 fi
 163
 164 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 165         [Whether glib was compiled with debugging enabled])
 166
 167 AC_MSG_CHECKING(whether to enable garbage collector friendliness)
 168 if test "x$enable_gc_friendly" = "xyes"; then
 169   AC_DEFINE(ENABLE_GC_FRIENDLY, 1, [Whether to enable GC friendliness])
 170   AC_SUBST(ENABLE_GC_FRIENDLY)
 171   AC_MSG_RESULT(yes)
 172 else
 173   AC_MSG_RESULT(no)
 174 fi
 175
 176 AC_MSG_CHECKING(whether to disable memory pools)
 177 if test "x$disable_mem_pools" = "xno"; then
 178   AC_MSG_RESULT(no)
 179 else
 180   AC_DEFINE(DISABLE_MEM_POOLS, 1, [Whether to disable memory pools])
 181   AC_SUBST(DISABLE_MEM_POOLS)
 182   AC_MSG_RESULT(yes)
 183 fi
 184
 185 dnl Checks for programs.
 186 AC_PROG_CC
 187
 188 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 189 AC_CHECK_PROGS(CXX, $CCC c++ g++ gcc CC cxx cc++ cl, gcc)
 190 AC_LANG_SAVE
 191 AC_LANG_CPLUSPLUS
 192 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 193 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 194 AC_LANG_RESTORE
 195
 196 AM_PROG_CC_STDC
 197 AC_PROG_INSTALL
 198
 199 #
 200 # Find pkg-config
 201 #
 202 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 203 if test x$PKG_CONFIG = xno ; then
 204   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
 205 fi
 206
 207 if pkg-config --atleast-pkgconfig-version 0.5 ; then
 208   :
 209 else
 210   AC_MSG_ERROR([*** pkg-config too old; version 0.5 or better required.])
 211 fi
 212
 213 if test "x$enable_debug" = "xyes"; then
 214   if test x$cflags_set != xset ; then
 215       case " $CFLAGS " in
 216       *[[\ \    ]]-g[[\ \       ]]*) ;;
 217       *) CFLAGS="$CFLAGS -g" ;;
 218       esac
 219   fi
 220
 221   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 222 else
 223   if test "x$enable_debug" = "xno"; then
 224     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 225   fi
 226 fi
 227
 228 # Ensure -fnative-struct is used when compiling for Win32
 229 if test "x$glib_native_win32" = "xyes"; then
 230   if test "x$GCC" = "xyes"; then
 231     case " $CFLAGS " in
 232     *[[\ \      ]]-fnative-struct[[\ \  ]]*) ;;
 233     *) CFLAGS="$CFLAGS -fnative-struct" ;;
 234     esac
 235   fi
 236 fi
 237
 238 AC_CYGWIN
 239 AC_EXEEXT
 240
 241 # define a MAINT-like variable REBUILD which is set if Perl
 242 # and awk are found, so autogenerated sources can be rebuilt
 243 AC_PROG_AWK
 244 AC_CHECK_PROGS(PERL, perl5 perl)
 245 # We would like indent, but don't require it.
 246 AC_CHECK_PROG(INDENT, indent, indent)
 247 REBUILD=\#
 248 if test "x$enable_rebuilds" = "xyes" && \
 249      test -n "$PERL" && \
 250      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 251      test -n "$AWK" ; then
 252   REBUILD=
 253 fi
 254 AC_SUBST(REBUILD)
 255
 256 # Need full path to Perl for glib-mkenums
 257 #
 258 if test "x$PERL" != x ; then
 259   AC_PATH_PROG(PERL_PATH, $PERL)
 260 else
 261   PERL_PATH="/usr/bin/env perl"
 262 fi
 263 AC_SUBST(PERL_PATH)
 264
 265 dnl
 266 dnl gettext support
 267 dnl
 268
 269 ALL_LINGUAS="az ca de es eu fr nn no ru sk sl sv ta tr uk zh_TW"
 270 AM_GLIB_GNU_GETTEXT
 271
 272 if test "$gt_cv_func_dgettext_libc" = "yes" || test "$gt_cv_func_dgettext_libintl" = "yes"; then
 273   :
 274 else
 275   AC_MSG_ERROR([
 276 *** You must have either have gettext support in your C library, or use the
 277 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 278 ])
 279 fi
 280
 281 LIBS="$LIBS $INTLLIBS"
 282
 283 GETTEXT_PACKAGE=glib20
 284 AC_SUBST(GETTEXT_PACKAGE)
 285 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE")
 286
 287 # AM_GLIB_GNU_GETTEXT above substs $DATADIRNAME
 288 # this is the directory where the *.{mo,gmo} files are installed
 289 GLIB_LOCALE_DIR="${prefix}/${DATADIRNAME}/locale"
 290 AC_DEFINE_UNQUOTED(GLIB_LOCALE_DIR,"$GLIB_LOCALE_DIR")
 291
 292 dnl Initialize libtool
 293 AC_LIBTOOL_WIN32_DLL
 294 AM_PROG_LIBTOOL
 295
 296 if test "x$GCC" = "xyes"; then
 297   case " $CFLAGS " in
 298   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 299   *) CFLAGS="$CFLAGS -Wall" ;;
 300   esac
 301
 302   if test "x$enable_ansi" = "xyes"; then
 303     case " $CFLAGS " in
 304     *[[\ \      ]]-ansi[[\ \    ]]*) ;;
 305     *) CFLAGS="$CFLAGS -ansi" ;;
 306     esac
 307
 308     case " $CFLAGS " in
 309     *[[\ \      ]]-pedantic[[\ \        ]]*) ;;
 310     *) CFLAGS="$CFLAGS -pedantic" ;;
 311     esac
 312   fi
 313 fi
 314
 315 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 316 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 317 glib_save_LIBS=$LIBS
 318 LIBS="$LIBS -lm"
 319 AC_TRY_RUN([#include <math.h>
 320              int main (void) { return (log(1) != log(1.)); }],
 321      AC_MSG_RESULT(none needed),
 322      glib_save_CFLAGS=$CFLAGS
 323      CFLAGS="$CFLAGS -std1"
 324      AC_TRY_RUN([#include <math.h>
 325                  int main (void) { return (log(1) != log(1.)); }],
 326          AC_MSG_RESULT(-std1),
 327          AC_MSG_RESULT()
 328          CFLAGS=$glib_save_CFLAGS
 329          AC_MSG_WARN(
 330                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 331      )
 332 )
 333 LIBS=$glib_save_LIBS
 334
 335 dnl NeXTStep cc seems to need this
 336 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 337 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 338   AC_MSG_RESULT(none needed),
 339   glib_save_CFLAGS=$CFLAGS
 340   CFLAGS="$CFLAGS -posix"
 341   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 342     AC_MSG_RESULT(-posix),
 343     AC_MSG_RESULT()
 344     CFLAGS=$glib_save_CFLAGS
 345     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 346
 347 # Checks for header files.
 348 AC_HEADER_STDC
 349
 350 # Checks for library functions.
 351 AC_FUNC_VPRINTF
 352
 353 AC_FUNC_ALLOCA
 354
 355 AC_CHECK_FUNCS(atexit on_exit)
 356
 357 AC_CHECK_SIZEOF(char)
 358 AC_CHECK_SIZEOF(short)
 359 AC_CHECK_SIZEOF(long)
 360 AC_CHECK_SIZEOF(int)
 361 AC_CHECK_SIZEOF(void *)
 362 AC_CHECK_SIZEOF(long long)
 363 AC_CHECK_SIZEOF(__int64)
 364
 365 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 366   :
 367 else
 368   AC_MSG_ERROR([
 369 *** GLib requires a 64 bit type. You might want to consider
 370 *** using the GNU C compiler.
 371 ])
 372 fi
 373
 374 if test x$ac_cv_sizeof_long_long = x8; then
 375         # long long is a 64 bit integer.
 376         AC_MSG_CHECKING(for format to printf and scanf a gint64)
 377         AC_CACHE_VAL(glib_cv_long_long_format,[
 378                 for format in ll q I64; do
 379                   AC_TRY_RUN([#include <stdio.h>
 380                         int main()
 381                         {
 382                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 383                           char buffer[1000];
 384                           sprintf (buffer, "%${format}u", a);
 385                           sscanf (buffer, "%${format}u", &b);
 386                           exit (b!=a);
 387                         }
 388                         ],
 389                         glib_cv_long_long_format=${format}
 390                         break)
 391                 done])
 392         if test -n "$glib_cv_long_long_format"; then
 393           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 394         else
 395           AC_MSG_RESULT(none)
 396         fi
 397 elif test x$ac_cv_sizeof___int64 = x8; then
 398         # __int64 is a 64 bit integer.
 399         AC_MSG_CHECKING(for format to printf and scanf a gint64)
 400         # We know this is MSVC, and what the formats are
 401         glib_cv_long_long_format=I64
 402         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 403 fi
 404
 405 dnl long doubles were not used, and a portability problem
 406 dnl AC_C_LONG_DOUBLE
 407 AC_C_CONST
 408
 409 dnl ok, here we try to check whether the systems prototypes for
 410 dnl malloc and friends actually match the prototypes provided
 411 dnl by gmem.h (keep in sync). i currently only know how to check
 412 dnl this reliably with gcc (-Werror), improvements for other
 413 dnl compilers are apprechiated.
 414 SANE_MALLOC_PROTOS=no
 415 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 416 glib_save_CFLAGS=$CFLAGS
 417 if test "x$GCC" = "xyes"; then
 418   CFLAGS="$CFLAGS -Werror"
 419   AC_TRY_COMPILE([#include <stdlib.h>], [
 420     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 421     void* (*my_malloc_p)  (size_t)         = malloc;
 422     void  (*my_free_p)    (void*)          = free;
 423     void* (*my_realloc_p) (void*, size_t)  = realloc;
 424     my_calloc_p = 0;
 425     my_malloc_p = 0;
 426     my_free_p = 0;
 427     my_realloc_p = 0;
 428   ],
 429     AC_DEFINE(SANE_MALLOC_PROTOS)
 430     SANE_MALLOC_PROTOS=yes)
 431 fi
 432 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 433 CFLAGS=$glib_save_CFLAGS
 434
 435
 436 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 437 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 438 dnl actually supported.
 439 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 440         AC_TRY_RUN([
 441         __inline int foo () { return 0; }
 442         int main () { return foo (); }
 443         ],
 444         glib_cv_has__inline=yes
 445         ,
 446         glib_cv_has__inline=no
 447         ,)
 448 ])
 449 case x$glib_cv_has__inline in
 450 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 451 esac
 452 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 453         AC_TRY_RUN([
 454         __inline__ int foo () { return 0; }
 455         int main () { return foo (); }
 456         ],
 457         glib_cv_has__inline__=yes
 458         ,
 459         glib_cv_has__inline__=no
 460         ,)
 461 ])
 462 case x$glib_cv_has__inline__ in
 463 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 464 esac
 465 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 466         AC_TRY_RUN([
 467         #undef inline
 468         inline int foo () { return 0; }
 469         int main () { return foo (); }
 470         ],
 471         glib_cv_hasinline=yes
 472         ,
 473         glib_cv_hasinline=no
 474         ,)
 475 ])
 476 case x$glib_cv_hasinline in
 477 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 478 esac
 479
 480 # check for flavours of varargs macros
 481 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 482 AC_TRY_COMPILE([],[
 483 int a(int p1, int p2, int p3);
 484 #define call_a(...) a(1,__VA_ARGS__)
 485 call_a(2,3);
 486 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 487 AC_MSG_RESULT($g_have_iso_c_varargs)
 488
 489 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 490 if test "$CXX" = ""; then
 491 dnl No C++ compiler
 492   g_have_iso_cxx_varargs=no
 493 else
 494   AC_LANG_CPLUSPLUS
 495   AC_TRY_COMPILE([],[
 496 int a(int p1, int p2, int p3);
 497 #define call_a(...) a(1,__VA_ARGS__)
 498 call_a(2,3);
 499 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 500   AC_LANG_C
 501 fi
 502 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 503
 504 AC_MSG_CHECKING(for GNUC varargs macros)
 505 AC_TRY_COMPILE([],[
 506 int a(int p1, int p2, int p3);
 507 #define call_a(params...) a(1,params)
 508 call_a(2,3);
 509 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 510 AC_MSG_RESULT($g_have_gnuc_varargs)
 511
 512 # check for bytesex stuff
 513 AC_C_BIGENDIAN
 514
 515 # check for header files
 516 AC_CHECK_HEADERS([float.h limits.h pwd.h sys/param.h sys/poll.h sys/select.h])
 517 AC_CHECK_HEADERS([sys/time.h sys/times.h unistd.h values.h stdint.h sched.h])
 518
 519 # Checks for libcharset
 520 jm_LANGINFO_CODESET
 521 jm_GLIBC21
 522 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 523 AC_CHECK_FUNCS(setlocale)
 524
 525 AC_MSG_CHECKING(whether make is GNU Make)
 526 STRIP_BEGIN=
 527 STRIP_END=
 528 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 529         STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
 530         STRIP_END=')'
 531         AC_MSG_RESULT(yes)
 532 else
 533         AC_MSG_RESULT(no)
 534 fi
 535 STRIP_DUMMY=
 536 AC_SUBST(STRIP_DUMMY)
 537 AC_SUBST(STRIP_BEGIN)
 538 AC_SUBST(STRIP_END)
 539
 540 # check additional type sizes
 541 size_includes=["
 542 #include <stdarg.h>
 543 #include <stdio.h>
 544 #include <ctype.h>
 545 #include <string.h>
 546 "]
 547 if test "x$ac_cv_header_stdint_h" = "xyes"; then
 548   size_includes=["$size_includes
 549 #include <stdint.h>
 550 "]
 551 fi
 552 if test "x$ac_cv_header_unistd_h" = "xyes"; then
 553   size_includes=["$size_includes
 554 #include <unistd.h>
 555 "]
 556 fi
 557 GLIB_SIZEOF([$size_includes], size_t, size_t)
 558 GLIB_SIZEOF([$size_includes], ptrdiff_t, ptrdiff_t)
 559 GLIB_SIZEOF([$size_includes], intmax_t, intmax_t)
 560
 561 # Check for some functions
 562 AC_CHECK_FUNCS(lstat strerror strsignal memmove mkstemp vsnprintf stpcpy strcasecmp strncasecmp poll getcwd nanosleep vasprintf)
 563
 564 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 565 # The check is borrowed from the PERL Configure script.
 566 if test "$ac_cv_func_memmove" != "yes"; then
 567   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 568     glib_cv_working_bcopy,[AC_TRY_RUN([
 569       int main() {
 570         char buf[128], abc[128], *b;
 571         int len, off, align;
 572         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 573         for (align = 7; align >= 0; align--) {
 574           for (len = 36; len; len--) {
 575             b = buf+align; bcopy(abc, b, len);
 576             for (off = 1; off <= len; off++) {
 577               bcopy(b, b+off, len); bcopy(b+off, b, len);
 578                 if (bcmp(b, abc, len)) return(1);
 579             }
 580           }
 581         }
 582         return(0);
 583       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 584   if test "$glib_cv_working_bcopy" = "yes"; then
 585     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 586   fi
 587 fi
 588
 589 # Check for sys_errlist
 590 AC_MSG_CHECKING(for sys_errlist)
 591 AC_TRY_LINK(, [
 592 extern char *sys_errlist[];
 593 extern int sys_nerr;
 594 sys_errlist[sys_nerr-1][0] = 0;
 595 ], glib_ok=yes, glib_ok=no)
 596 AC_MSG_RESULT($glib_ok)
 597 if test "$glib_ok" = "no"; then
 598     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 599 fi
 600
 601 # Check for sys_siglist
 602 AC_MSG_CHECKING(for sys_siglist)
 603 AC_TRY_LINK(, [
 604 extern char *sys_siglist[];
 605 exit (sys_siglist[0]);
 606 ], glib_ok=yes, glib_ok=no)
 607 AC_MSG_RESULT($glib_ok)
 608 if test "$glib_ok" = "no"; then
 609     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 610 fi
 611
 612 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 613 AC_MSG_CHECKING(for sys_siglist declaration)
 614 AC_TRY_COMPILE([#include <signal.h>], [
 615 strlen (sys_siglist[0]);
 616 ], glib_ok=yes, glib_ok=no)
 617 AC_MSG_RESULT($glib_ok)
 618 if test "$glib_ok" = "no"; then
 619     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 620 fi
 621
 622 # Check if <sys/select.h> needs to be included for fd_set
 623 AC_MSG_CHECKING([for fd_set])
 624 AC_TRY_COMPILE([#include <sys/types.h>],
 625         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 626 if test "$gtk_ok" = "yes"; then
 627     AC_MSG_RESULT([yes, found in sys/types.h])
 628 else
 629     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
 630     if test "$gtk_ok" = "yes"; then
 631         # *** FIXME: give it a different name
 632         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
 633         AC_MSG_RESULT([yes, found in sys/select.h])
 634     else
 635         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
 636         AC_MSG_RESULT(no)
 637     fi
 638 fi
 639
 640 dnl *** check for sane realloc() ***
 641 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
 642         AC_TRY_RUN([
 643         #include <stdlib.h>
 644         int main() {
 645           return realloc (0, sizeof (int)) == 0;
 646         }],
 647         [glib_cv_sane_realloc=yes],
 648         [glib_cv_sane_realloc=no],
 649         [])
 650 ])
 651 if test x$glib_cv_sane_realloc = xyes; then
 652   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
 653 fi
 654
 655 dnl Check for nl_langinfo and CODESET
 656
 657 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
 658 AC_TRY_COMPILE([#include <langinfo.h>],
 659         [char *codeset = nl_langinfo (CODESET);],
 660    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
 661    have_codeset=yes,
 662    have_codeset=no)
 663 AC_MSG_RESULT($have_codeset)
 664
 665
 666 dnl ****************************************
 667 dnl *** strlcpy/strlcat                  ***
 668 dnl ****************************************
 669 # Check for strlcpy
 670 AC_MSG_CHECKING(for strlcpy/strlcat)
 671 AC_TRY_LINK([#include <stdlib.h>
 672 #include <string.h>], [
 673 char *p = malloc(10);
 674 (void) strlcpy(p, "hi", 10);
 675 (void) strlcat(p, "bye", 10);
 676 ], glib_ok=yes, glib_ok=no)
 677 AC_MSG_RESULT($glib_ok)
 678 if test "$glib_ok" = "yes"; then
 679     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
 680 fi
 681
 682
 683 dnl **********************
 684 dnl *** va_copy checks ***
 685 dnl **********************
 686 dnl we currently check for all three va_copy possibilities, so we get
 687 dnl all results in config.log for bug reports.
 688 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
 689         AC_TRY_RUN([
 690         #include <stdarg.h>
 691         void f (int i, ...) {
 692         va_list args1, args2;
 693         va_start (args1, i);
 694         va_copy (args2, args1);
 695         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 696           exit (1);
 697         va_end (args1); va_end (args2);
 698         }
 699         int main() {
 700           f (0, 42);
 701           return 0;
 702         }],
 703         [glib_cv_va_copy=yes],
 704         [glib_cv_va_copy=no],
 705         [])
 706 ])
 707 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
 708         AC_TRY_RUN([
 709         #include <stdarg.h>
 710         void f (int i, ...) {
 711         va_list args1, args2;
 712         va_start (args1, i);
 713         __va_copy (args2, args1);
 714         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 715           exit (1);
 716         va_end (args1); va_end (args2);
 717         }
 718         int main() {
 719           f (0, 42);
 720           return 0;
 721         }],
 722         [glib_cv___va_copy=yes],
 723         [glib_cv___va_copy=no],
 724         [])
 725 ])
 726
 727 if test "x$glib_cv_va_copy" = "xyes"; then
 728   g_va_copy_func=va_copy
 729 else if test "x$glib_cv___va_copy" = "xyes"; then
 730   g_va_copy_func=__va_copy
 731 fi
 732 fi
 733
 734 if test -n "$g_va_copy_func"; then
 735   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
 736 fi
 737
 738 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
 739         AC_TRY_RUN([
 740         #include <stdarg.h>
 741         void f (int i, ...) {
 742         va_list args1, args2;
 743         va_start (args1, i);
 744         args2 = args1;
 745         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 746           exit (1);
 747         va_end (args1); va_end (args2);
 748         }
 749         int main() {
 750           f (0, 42);
 751           return 0;
 752         }],
 753         [glib_cv_va_val_copy=yes],
 754         [glib_cv_va_val_copy=no],
 755         [])
 756 ])
 757
 758 if test "x$glib_cv_va_val_copy" = "xno"; then
 759   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 760 fi
 761
 762 dnl ***********************
 763 dnl *** g_module checks ***
 764 dnl ***********************
 765 G_MODULE_LIBS=
 766 G_MODULE_LIBS_EXTRA=
 767 G_MODULE_PLUGIN_LIBS=
 768 G_MODULE_LDFLAGS=
 769 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
 770 G_MODULE_NEED_USCORE=0
 771 G_MODULE_BROKEN_RTLD_GLOBAL=0
 772 G_MODULE_HAVE_DLERROR=0
 773 dnl *** force native WIN32 shared lib loader
 774 if test -z "$G_MODULE_IMPL"; then
 775   case "$host" in
 776   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
 777   esac
 778 fi
 779 dnl *** dlopen() and dlsym() in system libraries
 780 if test -z "$G_MODULE_IMPL"; then
 781         AC_CHECK_FUNC(dlopen,
 782                       [AC_CHECK_FUNC(dlsym,
 783                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 784                       [])
 785 fi
 786 dnl *** load_image (BeOS)
 787 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
 788   AC_CHECK_LIB(root, load_image,
 789       [G_MODULE_LIBS="-lbe -lroot -lglib"
 790       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
 791       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
 792       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
 793       [])
 794 fi
 795 dnl *** dlopen() and dlsym() in libdl
 796 if test -z "$G_MODULE_IMPL"; then
 797         AC_CHECK_LIB(dl, dlopen,
 798                      [AC_CHECK_LIB(dl, dlsym,
 799                                    [G_MODULE_LIBS=-ldl
 800                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 801                      [])
 802 fi
 803 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
 804 if test -z "$G_MODULE_IMPL"; then
 805         AC_CHECK_FUNC(NSLinkModule,
 806                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
 807                        G_MODULE_NEED_USCORE=1],
 808                       [])
 809 fi
 810 dnl *** shl_load() in libdld (HP-UX)
 811 if test -z "$G_MODULE_IMPL"; then
 812         AC_MSG_CHECKING(how to export all symbols)
 813         SAVED_LDFLAGS=$LDFLAGS
 814         LDFLAGS="$LDFLAGS -Wl,-E"
 815         AC_TRY_LINK(,[ return 0; ],
 816                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 817                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 818                 AC_TRY_LINK(,[ return 0; ],
 819                         [G_MODULE_LDFLAGS="-bexpall"],
 820                         [G_MODULE_LDFLAGS="none"])
 821         ])
 822         LDFLAGS=$SAVED_LDFLAGS
 823         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 824         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 825                 G_MODULE_LDFLAGS=
 826         fi
 827         AC_CHECK_LIB(dld, shl_load,
 828                 [G_MODULE_LIBS=-ldld
 829                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
 830                 [])
 831 fi
 832 dnl *** additional checks for G_MODULE_IMPL_DL
 833 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 834         case "$host_os" in
 835           linux*)
 836             G_MODULE_LDFLAGS='-rdynamic'
 837             ;;
 838         esac
 839         LIBS_orig="$LIBS"
 840         LDFLAGS_orig="$LDFLAGS"
 841         LIBS="$LIBS $G_MODULE_LIBS"
 842         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 843 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
 844         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
 845                 glib_cv_rtldglobal_broken,[
 846                 AC_TRY_RUN([
 847                 #include <dlfcn.h>
 848                 #ifndef RTLD_GLOBAL
 849                 #define RTLD_GLOBAL 0
 850                 #endif
 851                 #ifndef RTLD_LAZY
 852                 #define RTLD_LAZY 0
 853                 #endif
 854                 int pthread_create;
 855                 int main () {
 856                 void *handle, *global, *local;
 857                 global = &pthread_create;
 858                 handle = dlopen ("libpthread.so", RTLD_GLOBAL | RTLD_LAZY);
 859                 if (!handle) return 0;
 860                 local = dlsym (handle, "pthread_create");
 861                 return global == local;
 862                 }],
 863                         [glib_cv_rtldglobal_broken=no],
 864                         [glib_cv_rtldglobal_broken=yes],
 865                         [])
 866                 rm -f plugin.c plugin.o plugin.lo
 867         ])
 868         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
 869                 G_MODULE_BROKEN_RTLD_GLOBAL=1
 870         else
 871                 G_MODULE_BROKEN_RTLD_GLOBAL=0
 872         fi
 873 dnl *** check whether we need preceeding underscores
 874         AC_CACHE_CHECK([for preceeding underscore in symbols],
 875                 glib_cv_uscore,[
 876                 AC_TRY_RUN([
 877                 #include <dlfcn.h>
 878                 int glib_underscore_test (void) { return 42; }
 879                 int main() {
 880                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 881                   handle = dlopen ((void*)0, 0);
 882                   if (handle) {
 883                     f1 = dlsym (handle, "glib_underscore_test");
 884                     f2 = dlsym (handle, "_glib_underscore_test");
 885                   } return (!f2 || f1);
 886                 }],
 887                         [glib_cv_uscore=yes],
 888                         [glib_cv_uscore=no],
 889                         [])
 890                 rm -f plugin.c plugin.$ac_objext plugin.lo
 891         ])
 892         if test "x$glib_cv_uscore" = "xyes"; then
 893                 G_MODULE_NEED_USCORE=1
 894         else
 895                 G_MODULE_NEED_USCORE=0
 896         fi
 897
 898         LDFLAGS="$LDFLAGS_orig"
 899 dnl *** check for having dlerror()
 900         AC_CHECK_FUNC(dlerror,
 901                 [G_MODULE_HAVE_DLERROR=1],
 902                 [G_MODULE_HAVE_DLERROR=0])
 903         LIBS="$LIBS_orig"
 904 fi
 905 dnl *** done, have we got an implementation?
 906 if test -z "$G_MODULE_IMPL"; then
 907         G_MODULE_IMPL=0
 908         G_MODULE_SUPPORTED=false
 909 else
 910         G_MODULE_SUPPORTED=true
 911 fi
 912
 913 AC_MSG_CHECKING(for the suffix of shared libraries)
 914 case "$host_os" in
 915   hpux9* | hpux10* | hpux11*)  # taken from ltconfig
 916     glib_gmodule_suffix='sl'
 917     ;;
 918   cygwin* | mingw*)
 919     glib_gmodule_suffix='dll'
 920     ;;
 921   *)
 922     glib_gmodule_suffix='so'
 923     ;;
 924 esac
 925 AC_MSG_RESULT(.$glib_gmodule_suffix)
 926
 927 AC_SUBST(G_MODULE_SUPPORTED)
 928 AC_SUBST(G_MODULE_IMPL)
 929 AC_SUBST(G_MODULE_LIBS)
 930 AC_SUBST(G_MODULE_LIBS_EXTRA)
 931 AC_SUBST(G_MODULE_PLUGIN_LIBS)
 932 AC_SUBST(G_MODULE_LDFLAGS)
 933 AC_SUBST(G_MODULE_HAVE_DLERROR)
 934 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
 935 AC_SUBST(G_MODULE_NEED_USCORE)
 936 AC_SUBST(GLIB_DEBUG_FLAGS)
 937
 938 dnl **********************
 939 dnl *** g_spawn checks ***
 940 dnl **********************
 941
 942 AC_MSG_CHECKING(for gspawn implementation)
 943 case "$host" in
 944   *-*-mingw*)
 945     GSPAWN=gspawn-win32.lo
 946     ;;
 947   *)
 948     GSPAWN=gspawn.lo
 949     ;;
 950 esac
 951 AC_MSG_RESULT($GSPAWN)
 952 AC_SUBST(GSPAWN)
 953
 954 dnl *************************
 955 dnl *** GIOChannel checks ***
 956 dnl *************************
 957
 958 AC_MSG_CHECKING(for GIOChannel implementation)
 959 case "$host" in
 960   *-*-mingw*)
 961     GIO=giowin32.lo
 962     ;;
 963   *)
 964     GIO=giounix.lo
 965     ;;
 966 esac
 967 AC_MSG_RESULT($GIO)
 968 AC_SUBST(GIO)
 969
 970 dnl ****************************************
 971 dnl *** platform dependent source checks ***
 972 dnl ****************************************
 973
 974 AC_MSG_CHECKING(for platform-dependent source)
 975 case "$host" in
 976   *-*-cygwin*|*-*-mingw*)
 977     PLATFORMDEP=gwin32.lo
 978     ;;
 979   *)
 980     PLATFORMDEP=
 981     ;;
 982 esac
 983 AC_MSG_RESULT($PLATFORMDEP)
 984 AC_SUBST(PLATFORMDEP)
 985
 986 AC_MSG_CHECKING([whether to compile timeloop])
 987 case "$host" in
 988   *-*-cygwin*|*-*-mingw*)
 989     enable_timeloop=no
 990     ;;
 991   *)
 992     enable_timeloop=yes
 993     ;;
 994 esac
 995 AC_MSG_RESULT($enable_timeloop)
 996 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
 997
 998 AC_MSG_CHECKING([if building for some Win32 platform])
 999 case "$host" in
1000   *-*-mingw*|*-*-cygwin*)
1001     platform_win32=yes
1002     ;;
1003   *)
1004     platform_win32=no
1005     ;;
1006 esac
1007 AC_MSG_RESULT($platform_win32)
1008 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1009
1010 dnl ***********************
1011 dnl *** g_thread checks ***
1012 dnl ***********************
1013
1014 AC_ARG_WITH(threads, [  --with-threads=[none/posix/dce/solaris/win32] specify a thread implementation to use],
1015         if test "x$with_threads" = x; then
1016                 want_threads=yes
1017         else
1018                 want_threads=$with_threads
1019         fi,
1020         want_threads=yes)
1021 if test "x$enable_threads" = "xno"; then
1022         want_threads=no
1023 fi
1024 if test "x$want_threads" = "xnone"; then
1025         want_threads=no
1026 fi
1027
1028 dnl error and warning message
1029 dnl *************************
1030
1031 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1032                 computer. GLib will not have a default thread implementation."
1033
1034 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1035                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1036                 compilation now, but then your programs might not work.
1037                 Please provide information on how it is done on your system."
1038
1039 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1040                 "
1041
1042 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1043                 provide information on your thread implementation.
1044                 You can also run 'configure --disable-threads'
1045                 to compile without thread support."
1046
1047 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1048                 functions will not be MT-safe during their first call because
1049                 there is no working 'getpwuid_r' on your system."
1050
1051 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1052                 because there is no 'localtime_r' on your system."
1053
1054 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1055                 crude surrogate will be used. If you happen to know a
1056                 yield function for your system, please inform the GLib
1057                 developers."
1058
1059 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1060                 threads on your system. Thus threads can only have the default
1061                 priority. If you happen to know these main/max
1062                 priorities, please inform the GLib developers."
1063
1064
1065 dnl determination of thread implementation
1066 dnl ***************************************
1067
1068 have_threads=none
1069 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
1070         case $host in
1071                 *-*-solaris*)
1072                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
1073                 ;;
1074         esac
1075 fi
1076 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1077                                 || test "x$want_threads" = xdce; then
1078         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1079         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1080         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1081         glib_save_CPPFLAGS="$CPPFLAGS"
1082         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1083         if test "x$have_threads" = xnone; then
1084                 AC_TRY_COMPILE([#include <pthread.h>],
1085                         [pthread_attr_t attr; pthread_attr_init(&attr);],
1086                         have_threads=posix)
1087         fi
1088         if test "x$have_threads" = xnone; then
1089                 AC_TRY_COMPILE([#include <pthread.h>],
1090                         [pthread_attr_t attr; pthread_attr_create(&attr);],
1091                         have_threads=posix)
1092         fi
1093         CPPFLAGS="$glib_save_CPPFLAGS"
1094 fi
1095 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1096         case $host in
1097                 *-*-mingw*)
1098                 have_threads=win32
1099                 ;;
1100         esac
1101 fi
1102
1103 AC_MSG_CHECKING(for thread implementation)
1104
1105 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
1106         AC_MSG_RESULT(none available)
1107         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1108 else
1109         AC_MSG_RESULT($have_threads)
1110 fi
1111
1112
1113 dnl determination of G_THREAD_CFLAGS
1114 dnl ********************************
1115
1116 G_THREAD_LIBS=
1117 G_THREAD_LIBS_EXTRA=
1118 G_THREAD_CFLAGS=
1119
1120 if test x"$have_threads" != xnone; then
1121
1122     G_THREAD_CFLAGS="-D_REENTRANT" # good default guess
1123
1124     case $host in
1125         *-aix*)
1126                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
1127                 if test x"$GCC" = xyes; then
1128                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
1129                 fi
1130                 ;;
1131         *-freebsd2.2*)
1132                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
1133
1134                 # FreeBSD 2.2.x shiped with gcc 2.7.2.x, which doesn't support
1135                 # -mthreads flag.
1136                 ;;
1137         *-sysv5uw7*)  # UnixWare 7
1138                 if test "$GCC" != "yes"; then
1139                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -Kthread"
1140                 else
1141                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -pthread"
1142                 fi
1143                 ;;
1144         *-dg-dgux*)  # DG/UX
1145                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
1146     esac
1147
1148     # if we are not finding the localtime_r function, then we probably are
1149     # not using the proper multithread flag
1150
1151     glib_save_CPPFLAGS="$CPPFLAGS"
1152     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1153
1154     # First we test, whether localtime_r is declared in time.h
1155     # directly. Then we test whether a macro localtime_r exists, in
1156     # which case localtime_r in the test program is replaced and thus
1157     # if we still find localtime_r in the output, it is not defined as
1158     # a macro.
1159
1160     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1161       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1162                                                            localtime_r(a,b)],
1163                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1164
1165     CPPFLAGS="$glib_save_CPPFLAGS"
1166
1167     AC_MSG_CHECKING(thread related cflags)
1168     AC_MSG_RESULT($G_THREAD_CFLAGS)
1169     CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
1170 fi
1171
1172 dnl determination of G_THREAD_LIBS
1173 dnl ******************************
1174
1175 mutex_has_default=no
1176 case $have_threads in
1177         posix|dce)
1178            glib_save_CPPFLAGS="$CPPFLAGS"
1179            CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1180            G_THREAD_LIBS=error
1181            glib_save_LIBS="$LIBS"
1182            case $host in
1183              *-sysv5uw7*) # UnixWare 7
1184                 if test "$GCC" != "yes"; then
1185                         G_THREAD_LIBS="-Kthread"
1186                 else
1187                         G_THREAD_LIBS="-pthread"
1188                 fi
1189                 ;;
1190              *)
1191                 for thread_lib in "" pthread pthread32 pthreads c_r thread dce; do
1192                         if test x"$thread_lib" = x; then
1193                                 add_thread_lib=""
1194                                 IN=""
1195                         else
1196                                 add_thread_lib="-l$thread_lib"
1197                                 IN=" in -l$thread_lib"
1198                         fi
1199                         if test x"$have_threads" = xposix; then
1200                                 defattr=0
1201                         else
1202                                 defattr=pthread_attr_default
1203                         fi
1204
1205                         LIBS="$glib_save_LIBS $add_thread_lib"
1206
1207                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
1208                         AC_TRY_RUN([#include <pthread.h>
1209                                 int check_me = 0;
1210                                 void* func(void* data) {check_me = 42;}
1211                                 main()
1212                                 { pthread_t t;
1213                                   void *ret;
1214                                   pthread_create (&t, $defattr, func, 0);
1215                                   pthread_join (t, &ret);
1216                                   exit (check_me != 42);
1217                                 }],
1218                                 [AC_MSG_RESULT(yes)
1219                                 G_THREAD_LIBS="$add_thread_lib"
1220                                 break],
1221                                 [AC_MSG_RESULT(no)])
1222                 done
1223                 if test "x$G_THREAD_LIBS" = xerror; then
1224                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1225                 fi
1226                 for thread_lib in "" rt rte; do
1227                         if test x"$thread_lib" = x; then
1228                                 add_thread_lib=""
1229                                 IN=""
1230                         else
1231                                 add_thread_lib="-l$thread_lib"
1232                                 IN=" in -l$thread_lib"
1233                         fi
1234                         LIBS="$glib_save_LIBS $add_thread_lib"
1235
1236                         AC_MSG_CHECKING(for sched_get_priority_min$IN)
1237                         AC_TRY_RUN([#include <sched.h>
1238                                 #include <errno.h>
1239                                 int main() {
1240                                 errno = 0;
1241                                 return sched_get_priority_min(SCHED_OTHER)==-1
1242                                         && errno != 0;
1243                                 }],
1244                                 [AC_MSG_RESULT(yes)
1245                                 G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
1246                                 posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
1247                                 posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
1248                                 break],
1249                                 [AC_MSG_RESULT(no)])
1250                 done
1251                 LIBS="$glib_save_LIBS"
1252                 ;;
1253            esac
1254            mutex_has_default=yes
1255            mutex_default_type='pthread_mutex_t'
1256            mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
1257            mutex_header_file='pthread.h'
1258            if test "x$have_threads" = "xposix"; then
1259              g_threads_impl="POSIX"
1260            else
1261              g_threads_impl="DCE"
1262              have_threads="posix"
1263            fi
1264            AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
1265            CPPFLAGS="$glib_save_CPPFLAGS"
1266            ;;
1267         solaris)
1268            G_THREAD_LIBS=error
1269            AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
1270            mutex_has_default=yes
1271            mutex_default_type='mutex_t'
1272            mutex_default_init="DEFAULTMUTEX"
1273            mutex_header_file='thread.h'
1274            g_threads_impl="SOLARIS"
1275            ;;
1276         win32)
1277            g_threads_impl="WIN32"
1278            G_THREAD_LIBS=""
1279            ;;
1280         none)
1281            g_threads_impl="NONE"
1282            ;;
1283         *)
1284            g_threads_impl="NONE"
1285            G_THREAD_LIBS=error
1286            ;;
1287 esac
1288
1289 if test "x$G_THREAD_LIBS" = xerror; then
1290         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1291 fi
1292
1293 case $host in
1294   *-*-beos*)
1295     G_THREAD_LIBS="-lbe -lroot -lglib "
1296     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1297     ;;
1298   *)
1299     ;;
1300 esac
1301
1302 AC_MSG_CHECKING(thread related libraries)
1303 AC_MSG_RESULT($G_THREAD_LIBS)
1304
1305 dnl check for mt safe function variants and some posix functions
1306 dnl ************************************************************
1307
1308 if test x"$have_threads" != xnone; then
1309         glib_save_LIBS="$LIBS"
1310         # we are not doing the following for now, as this might require glib
1311         # to always be linked with the thread libs on some platforms.
1312         # LIBS="$LIBS $G_THREAD_LIBS"
1313         AC_CHECK_FUNCS(localtime_r)
1314         if test "$ac_cv_header_pwd_h" = "yes"; then
1315                 AC_CACHE_CHECK([for posix getpwuid_r],
1316                         ac_cv_func_posix_getpwuid_r,
1317                         [AC_TRY_RUN([#include <errno.h>
1318                                 #include <pwd.h>
1319                                 int main () { char buffer[10000];
1320                                 struct passwd pwd, *pwptr = &pwd;
1321                                 int error;
1322                                 errno = 0;
1323                                 error = getpwuid_r (0, &pwd, buffer,
1324                                         sizeof (buffer), &pwptr);
1325                                 return (error < 0 && errno == ENOSYS)
1326                                         || error == ENOSYS; }],
1327                                 [ac_cv_func_posix_getpwuid_r=yes],
1328                                 [ac_cv_func_posix_getpwuid_r=no])])
1329                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
1330                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
1331                                 [Have POSIX function getpwuid_r])
1332                 else
1333                         AC_CACHE_CHECK([for nonposix getpwuid_r],
1334                                 ac_cv_func_nonposix_getpwuid_r,
1335                                 [AC_TRY_LINK([#include <pwd.h>],
1336                                         [char buffer[10000];
1337                                         struct passwd pwd;
1338                                         getpwuid_r (0, &pwd, buffer,
1339                                                         sizeof (buffer));],
1340                                         [ac_cv_func_nonposix_getpwuid_r=yes],
1341                                         [ac_cv_func_nonposix_getpwuid_r=no])])
1342                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
1343                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
1344                                         [Have non-POSIX function getpwuid_r])
1345                         fi
1346                 fi
1347         fi
1348         LIBS="$LIBS $G_THREAD_LIBS"
1349         if test x"$have_threads" = xposix; then
1350                 glib_save_CPPFLAGS="$CPPFLAGS"
1351                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1352                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
1353                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
1354                 # This is not AC_CHECK_FUNC to also work with function
1355                 # name mangling in header files.
1356                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1357                 AC_TRY_LINK([#include <pthread.h>],
1358                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1359                         [AC_MSG_RESULT(yes)
1360                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1361                                   [Have function pthread_attr_setstacksize])],
1362                         [AC_MSG_RESULT(no)])
1363                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1364                 if test x"$posix_priority_min" = xnone; then
1365                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1366                                 PX_PRIO_MIN],,[
1367                                 posix_priority_min=PX_PRIO_MIN
1368                                 posix_priority_max=PX_PRIO_MAX])
1369                 fi
1370                 if test x"$posix_priority_min" = xnone; then
1371                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1372                                 PRI_OTHER_MIN],,[
1373                                 posix_priority_min=PRI_OTHER_MIN
1374                                 posix_priority_max=PRI_OTHER_MAX])
1375                 fi
1376                 if test x"$posix_priority_min" = x; then
1377                         AC_MSG_RESULT(none found)
1378                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1379                         posix_priority_min=-1
1380                         posix_priority_max=-1
1381                 else
1382                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1383                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1384                         AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])
1385                 fi
1386                 posix_yield_func=none
1387                 AC_MSG_CHECKING(for posix yield function)
1388                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1389                                                         thr_yield; do
1390                         AC_TRY_LINK([#include <pthread.h>],
1391                                 [$yield_func()],
1392                                 [posix_yield_func="$yield_func"
1393                                 break])
1394                 done
1395                 if test x"$posix_yield_func" = xnone; then
1396                         AC_MSG_RESULT(none found)
1397                         AC_MSG_WARN($POSIX_NO_YIELD)
1398                         posix_yield_func="g_usleep(1000)"
1399                 else
1400                         AC_MSG_RESULT($posix_yield_func)
1401                         posix_yield_func="$posix_yield_func()"
1402                 fi
1403                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1404                 CPPFLAGS="$glib_save_CPPFLAGS"
1405
1406                 AC_MSG_CHECKING(whether to use the PID niceness surrogate for thread priorities)
1407                 AC_TRY_RUN([#include <pthread.h>
1408                         #include <sys/types.h>
1409                         #include <unistd.h>
1410                         pid_t other_pid = 0;
1411
1412                         void* func(void* data) {other_pid = getpid();}
1413                         main()
1414                         { pthread_t t;
1415                           void *ret;
1416                           pthread_create (&t, $defattr, func, NULL);
1417                           pthread_join (t, &ret);
1418                           exit (getpid()==other_pid ||
1419                                 $posix_priority_min != $posix_priority_max);
1420                         }],
1421                         [AC_MSG_RESULT(yes)
1422                           AC_DEFINE(G_THREAD_USE_PID_SURROGATE, 1, [whether to use the PID niceness surrogate for thread priorities])
1423                         ],
1424                         [AC_MSG_RESULT(no)])
1425         elif test x"$have_threads" = xwin32; then
1426                 # It's a pointer to a private struct
1427                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
1428         else # solaris threads
1429                 GLIB_SIZEOF([#include <thread.h>], thread_t, system_thread)
1430         fi
1431
1432         LIBS="$glib_save_LIBS"
1433
1434         # now spit out all the warnings.
1435         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1436            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1437                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1438         fi
1439         if test "$ac_cv_func_localtime_r" != "yes"; then
1440                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1441         fi
1442 else
1443         # If no thread implementation exists, we will provide enough
1444         # space for a pointer
1445         GLIB_SIZEOF(, void*, system_thread)
1446 fi
1447
1448 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1449                    [Source file containing theread implementation])
1450 AC_SUBST(G_THREAD_CFLAGS)
1451 AC_SUBST(G_THREAD_LIBS)
1452 AC_SUBST(G_THREAD_LIBS_EXTRA)
1453
1454 dnl **********************************************
1455 dnl *** GDefaultMutex setup and initialization ***
1456 dnl **********************************************
1457 dnl
1458 dnl if mutex_has_default = yes, we also got
1459 dnl mutex_default_type, mutex_default_init and mutex_header_file
1460 GLIB_IF_VAR_EQ(mutex_has_default, yes,
1461         glib_save_CPPFLAGS="$CPPFLAGS"
1462         glib_save_LIBS="$LIBS"
1463         LIBS="$LIBS $G_THREAD_LIBS"
1464         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1465         GLIB_SIZEOF([#include <$mutex_header_file>],
1466                     $mutex_default_type,
1467                     gmutex,
1468                     )
1469         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1470                            $mutex_default_type,
1471                            gmutex,
1472                            $glib_cv_sizeof_gmutex,
1473                            $mutex_default_init)
1474         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1475                 mutex_has_default=no
1476         fi
1477         CPPFLAGS="$glib_save_CPPFLAGS"
1478         LIBS="$glib_save_LIBS"
1479         ,
1480 )
1481
1482
1483 dnl ****************************************
1484 dnl *** GLib POLL* compatibility defines ***
1485 dnl ****************************************
1486 GLIB_SYSDEFS(
1487 [#include <sys/types.h>
1488 #include <sys/poll.h>],
1489         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
1490         glibconfig-sysdefs.h,
1491         =)
1492
1493 dnl **********************
1494 dnl *** Win32 API libs ***
1495 dnl **********************
1496
1497 case $host in
1498   *-*-cygwin*)
1499         G_LIBS_EXTRA="-luser32 -lwsock32 -lkernel32"
1500     ;;
1501   *-*-mingw*)
1502         G_LIBS_EXTRA="-lwsock32"
1503     ;;
1504   *)
1505         G_LIBS_EXTRA=""
1506     ;;
1507 esac
1508 AC_SUBST(G_LIBS_EXTRA)
1509
1510 dnl ***********************
1511 dnl *** Tests for iconv ***
1512 dnl ***********************
1513
1514 AC_ARG_WITH(libiconv, [ --with-libiconv     Use the libiconv library ],,with_libiconv=maybe)
1515
1516 found_iconv=no
1517
1518 if test "x$with_libiconv" != "xyes" ; then
1519    #
1520    # Check in the C library
1521    #
1522    AC_CHECK_FUNC(iconv_open, with_libiconv=no; found_iconv=yes)
1523 fi
1524
1525 if test "x$with_libiconv" != "xno" ; then
1526    #
1527    # Check for libiconv
1528    #
1529    AC_CHECK_LIB(iconv, libiconv_open, with_libiconv=yes; found_iconv=yes)
1530 fi
1531
1532 if test "x$found_iconv" = "xno" ; then
1533    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
1534 fi
1535
1536 if test "x$with_libiconv" = "xyes" ; then
1537   ICONV_LIBS="-liconv"
1538   AC_DEFINE(USE_LIBICONV)
1539 fi
1540 AC_SUBST(ICONV_LIBS)
1541
1542 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
1543 dnl since we need it for g_iconv()
1544
1545 AC_MSG_CHECKING([for EILSEQ])
1546 AC_TRY_COMPILE([
1547 #include <errno.h>
1548 ],
1549 [
1550 int error = EILSEQ;
1551 ], have_eilseq=yes, have_eilseq=no);
1552 AC_MSG_RESULT($have_eilseq)
1553
1554 dnl **************************
1555 dnl *** Checks for gtk-doc ***
1556 dnl **************************
1557
1558 AC_ARG_WITH(html-dir, [  --with-html-dir=PATH    path to installed docs])
1559
1560 if test "x$with_html_dir" = "x" ; then
1561   HTML_DIR='${datadir}/gtk-doc/html'
1562 else
1563   HTML_DIR=$with_html_dir
1564 fi
1565
1566 AC_SUBST(HTML_DIR)
1567
1568 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
1569
1570 gtk_doc_min_version=0.6
1571 if $GTKDOC ; then
1572     gtk_doc_version=`gtkdoc-mkdb --version`
1573     AC_MSG_CHECKING([gtk-doc version ($gtk_doc_version) >= $gtk_doc_min_version])
1574     if perl <<EOF ; then
1575       exit (("$gtk_doc_version" =~ /^[[0-9]]+\.[[0-9]]+$/) &&
1576             ("$gtk_doc_version" >= "$gtk_doc_min_version") ? 0 : 1);
1577 EOF
1578       AC_MSG_RESULT(yes)
1579    else
1580       AC_MSG_RESULT(no)
1581       GTKDOC=false
1582    fi
1583 fi
1584
1585 AM_CONDITIONAL(HAVE_GTK_DOC, $GTKDOC)
1586 AC_SUBST(HAVE_GTK_DOC)
1587
1588 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1589 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1590
1591 dnl Let people disable the gtk-doc stuff.
1592 AC_ARG_ENABLE(gtk-doc, [  --enable-gtk-doc        use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)
1593
1594 if test x$enable_gtk_doc = xauto ; then
1595   if test x$GTKDOC = xtrue ; then
1596     enable_gtk_doc=yes
1597   else
1598     enable_gtk_doc=no
1599   fi
1600 fi
1601
1602 dnl NOTE: We need to use a separate automake conditional for this
1603 dnl       to make this work with the tarballs.
1604 AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
1605
1606 dnl ******************************
1607 dnl *** output the whole stuff ***
1608 dnl ******************************
1609
1610 AC_OUTPUT_COMMANDS([
1611
1612 ## Generate `glibconfig.h' in two cases
1613 ## 1. `config.status' is run either explicitly, or via configure.
1614 ##     Esp. not when it is run in `Makefile' to generate makefiles and
1615 ##     config.h
1616 ## 2. CONFIG_OTHER is set explicitly
1617 ##
1618 ## Case 1 is difficult.  We know that `automake' sets one of
1619 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
1620 ## only when AM_CONFIG_HEADER is set, however.
1621
1622 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
1623   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
1624   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
1625 fi
1626 case "$CONFIG_OTHER" in
1627 *glibconfig.h*)
1628         echo creating glibconfig.h
1629         outfile=glibconfig.h-tmp
1630         cat > $outfile <<\_______EOF
1631 /* glibconfig.h
1632  *
1633  * This is a generated file.  Please modify 'configure.in'
1634  */
1635
1636 #ifndef __G_LIBCONFIG_H__
1637 #define __G_LIBCONFIG_H__
1638
1639 #include <glib/gmacros.h>
1640
1641 _______EOF
1642
1643         if test x$glib_limits_h = xyes; then
1644           echo '#include <limits.h>' >> $outfile
1645         fi
1646         if test x$glib_float_h = xyes; then
1647           echo '#include <float.h>' >> $outfile
1648         fi
1649         if test x$glib_values_h = xyes; then
1650           echo '#include <values.h>' >> $outfile
1651         fi
1652         if test "$glib_header_alloca_h" = "yes"; then
1653           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
1654         fi
1655         if test x$glib_sys_poll_h = xyes; then
1656           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
1657         fi
1658
1659         cat >> $outfile <<_______EOF
1660
1661 G_BEGIN_DECLS
1662
1663 #define G_MINFLOAT      $glib_mf
1664 #define G_MAXFLOAT      $glib_Mf
1665 #define G_MINDOUBLE     $glib_md
1666 #define G_MAXDOUBLE     $glib_Md
1667 #define G_MINSHORT      $glib_ms
1668 #define G_MAXSHORT      $glib_Ms
1669 #define G_MAXUSHORT     $glib_Mus
1670 #define G_MININT        $glib_mi
1671 #define G_MAXINT        $glib_Mi
1672 #define G_MAXUINT       $glib_Mui
1673 #define G_MINLONG       $glib_ml
1674 #define G_MAXLONG       $glib_Ml
1675 #define G_MAXULONG      $glib_Mul
1676
1677 #define G_MININT64      ((gint64)  0x8000000000000000)
1678 #define G_MAXINT64      ((gint64)  0x7fffffffffffffff)
1679 #define G_MAXUINT64     ((guint64) 0xffffffffffffffff)
1680
1681 _______EOF
1682
1683
1684         ### this should always be true in a modern C/C++ compiler
1685         cat >>$outfile <<_______EOF
1686 typedef signed char gint8;
1687 typedef unsigned char guint8;
1688 _______EOF
1689
1690
1691         if test -n "$gint16"; then
1692           cat >>$outfile <<_______EOF
1693 typedef signed $gint16 gint16;
1694 typedef unsigned $gint16 guint16;
1695 #define G_GINT16_FORMAT $gint16_format
1696 #define G_GUINT16_FORMAT $guint16_format
1697 _______EOF
1698         fi
1699
1700
1701         if test -n "$gint32"; then
1702           cat >>$outfile <<_______EOF
1703 typedef signed $gint32 gint32;
1704 typedef unsigned $gint32 guint32;
1705 #define G_GINT32_FORMAT $gint32_format
1706 #define G_GUINT32_FORMAT $guint32_format
1707 _______EOF
1708         fi
1709
1710         cat >>$outfile <<_______EOF
1711 #define G_HAVE_GINT64 1          /* deprecated, always true */
1712
1713 ${glib_extension}typedef signed $gint64 gint64;
1714 ${glib_extension}typedef unsigned $gint64 guint64;
1715
1716 #define G_GINT64_CONSTANT(val)  $gint64_constant
1717
1718 #define G_GINT64_FORMAT $gint64_format
1719 #define G_GUINT64_FORMAT $guint64_format
1720 _______EOF
1721
1722         cat >>$outfile <<_______EOF
1723
1724 #define GLIB_SIZEOF_VOID_P $glib_void_p
1725 #define GLIB_SIZEOF_LONG   $glib_long
1726
1727 _______EOF
1728
1729         case x$glib_size_t in
1730         x2) echo "typedef gint16  gssize;" >> $outfile
1731             echo "typedef guint16 gsize;"  >> $outfile
1732             ;;
1733         x4) echo "typedef gint32  gssize;" >> $outfile
1734             echo "typedef guint32 gsize;"  >> $outfile
1735             ;;
1736         x8) echo "typedef gint64  gssize;" >> $outfile
1737             echo "typedef guint64 gsize;"  >> $outfile
1738             ;;
1739         *)  echo "#error size of size_t is unknown" >> $outfile
1740             ;;
1741         esac
1742
1743         if test -z "$glib_unknown_void_p"; then
1744           cat >>$outfile <<_______EOF
1745
1746 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
1747 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
1748
1749 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
1750 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
1751 _______EOF
1752         else
1753           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
1754         fi
1755
1756
1757
1758         cat >>$outfile <<_______EOF
1759 $glib_atexit
1760 $glib_memmove
1761 $glib_defines
1762 $glib_os
1763
1764 $glib_vacopy
1765
1766 #ifdef  __cplusplus
1767 #define G_HAVE_INLINE   1
1768 #else   /* !__cplusplus */
1769 $glib_inline
1770 #endif  /* !__cplusplus */
1771
1772 _______EOF
1773
1774         if test x$g_have_iso_c_varargs = xyes ; then
1775                 cat >>$outfile <<_______EOF
1776 #ifndef __cplusplus
1777 # define G_HAVE_ISO_VARARGS 1
1778 #endif
1779 _______EOF
1780         fi
1781         if test x$g_have_iso_cxx_varargs = xyes ; then
1782                 cat >>$outfile <<_______EOF
1783 #ifdef __cplusplus
1784 # define G_HAVE_ISO_VARARGS 1
1785 #endif
1786 _______EOF
1787         fi
1788         if test x$g_have_gnuc_varargs = xyes ; then
1789                 cat >>$outfile <<_______EOF
1790
1791 #define G_HAVE_GNUC_VARARGS 1
1792 _______EOF
1793         fi
1794
1795         echo >>$outfile
1796         if test x$g_have_eilseq = xno; then
1797                 cat >>$outfile <<_______EOF
1798 #ifndef EILSEQ
1799 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
1800  * The correspondence between this and the corresponding definition
1801  * in libiconv is essential.
1802  */
1803 #  define EILSEQ ENOENT
1804 #endif
1805 _______EOF
1806
1807         fi
1808
1809         echo >>$outfile
1810         if test x$g_mutex_has_default = xyes; then
1811                 cat >>$outfile <<_______EOF
1812 $g_enable_threads_def G_THREADS_ENABLED
1813 #define G_THREADS_IMPL_$g_threads_impl_def
1814 typedef struct _GStaticMutex GStaticMutex;
1815 struct _GStaticMutex
1816 {
1817   struct _GMutex *runtime_mutex;
1818   union {
1819     char   pad[$g_mutex_sizeof];
1820     double dummy_double;
1821     void  *dummy_pointer;
1822     long   dummy_long;
1823   } static_mutex;
1824 };
1825 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
1826 #define g_static_mutex_get_mutex(mutex) \
1827   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->static_mutex)) : \
1828    g_static_mutex_get_mutex_impl (&((mutex)->runtime_mutex)))
1829 _______EOF
1830         else
1831                 cat >>$outfile <<_______EOF
1832 $g_enable_threads_def G_THREADS_ENABLED
1833 #define G_THREADS_IMPL_$g_threads_impl_def
1834 typedef struct _GMutex* GStaticMutex;
1835 #define G_STATIC_MUTEX_INIT NULL
1836 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (mutex))
1837 _______EOF
1838         fi
1839
1840         cat >>$outfile <<_______EOF
1841 /* This represents a system thread as used by the implementation. An
1842  * alien implementaion, as loaded by g_thread_init can only count on
1843  * "sizeof (gpointer)" bytes to store their info. We however need more
1844  * for some of our native implementations. */
1845 typedef union _GSystemThread GSystemThread;
1846 union _GSystemThread
1847 {
1848   char   data[$g_system_thread_sizeof];
1849   double dummy_double;
1850   void  *dummy_pointer;
1851   long   dummy_long;
1852 };
1853 _______EOF
1854
1855         echo >>$outfile
1856         g_bit_sizes="16 32 64"
1857         for bits in $g_bit_sizes; do
1858           cat >>$outfile <<_______EOF
1859 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
1860 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
1861 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
1862 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
1863 _______EOF
1864         done
1865
1866         cat >>$outfile <<_______EOF
1867 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
1868 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
1869 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
1870 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
1871 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
1872 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
1873 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
1874 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
1875 #define G_BYTE_ORDER $g_byte_order
1876
1877 _______EOF
1878
1879         if test -r glibconfig-sysdefs.h; then
1880           cat glibconfig-sysdefs.h >>$outfile
1881         fi
1882
1883         cat >>$outfile <<_______EOF
1884
1885 #define G_MODULE_SUFFIX "$g_module_suffix"
1886
1887 G_END_DECLS
1888
1889 #endif /* GLIBCONFIG_H */
1890 _______EOF
1891
1892
1893         if cmp -s $outfile glibconfig.h; then
1894           echo glibconfig.h is unchanged
1895           rm -f $outfile
1896         else
1897           mv $outfile glibconfig.h
1898         fi ;;
1899 esac
1900 ],[
1901
1902 # Note that if two cases are the same, case goes with the first one.
1903 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
1904 # on variable expansion in case labels.  Look at the generated config.status
1905 # for a hint.
1906
1907 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
1908   glib_header_alloca_h="$ac_cv_working_alloca_h"
1909 else
1910   glib_header_alloca_h="$ac_cv_header_alloca_h"
1911 fi
1912
1913 case xyes in
1914 x$ac_cv_header_float_h)
1915   glib_float_h=yes
1916   glib_mf=FLT_MIN glib_Mf=FLT_MAX
1917   glib_md=DBL_MIN glib_Md=DBL_MAX
1918   ;;
1919 x$ac_cv_header_values_h)
1920   glib_values_h=yes
1921   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
1922   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
1923   ;;
1924 esac
1925
1926 case xyes in
1927 x$ac_cv_header_limits_h)
1928   glib_limits_h=yes
1929   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
1930   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
1931   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
1932   ;;
1933 x$ac_cv_header_values_h)
1934   glib_values_h=yes
1935   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
1936   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
1937   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
1938   ;;
1939 esac
1940
1941 if test x$ac_cv_header_sys_poll_h = xyes ; then
1942   glib_sys_poll_h=yes
1943 fi
1944
1945 case 2 in
1946 $ac_cv_sizeof_short)
1947   gint16=short
1948   gint16_format='"hi"'
1949   guint16_format='"hu"'
1950   ;;
1951 $ac_cv_sizeof_int)
1952   gint16=int
1953   gint16_format='"i"'
1954   guint16_format='"u"'
1955   ;;
1956 esac
1957 case 4 in
1958 $ac_cv_sizeof_short)
1959   gint32=short
1960   gint32_format='"hi"'
1961   guint32_format='"hu"'
1962   ;;
1963 $ac_cv_sizeof_int)
1964   gint32=int
1965   gint32_format='"i"'
1966   guint32_format='"u"'
1967   ;;
1968 $ac_cv_sizeof_long)
1969   gint32=long
1970   gint32_format='"li"'
1971   guint32_format='"lu"'
1972   ;;
1973 esac
1974 case 8 in
1975 $ac_cv_sizeof_int)
1976   gint64=int
1977   gint64_format='"i"'
1978   guint64_format='"u"'
1979   glib_extension=
1980   gint64_constant='(val)'
1981   ;;
1982 $ac_cv_sizeof_long)
1983   gint64=long
1984   gint64_format='"li"'
1985   guint64_format='"lu"'
1986   glib_extension=
1987   gint64_constant='(val##L)'
1988   ;;
1989 $ac_cv_sizeof_long_long)
1990   gint64='long long'
1991   if test -n "$glib_cv_long_long_format"; then
1992     gint64_format='"'$glib_cv_long_long_format'i"'
1993     guint64_format='"'$glib_cv_long_long_format'u"'
1994   fi
1995   glib_extension='G_GNUC_EXTENSION '
1996   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1997   ;;
1998 $ac_cv_sizeof___int64)
1999   gint64='__int64'
2000   if test -n "$glib_cv_long_long_format"; then
2001     gint64_format='"'$glib_cv_long_long_format'i"'
2002     guint64_format='"'$glib_cv_long_long_format'u"'
2003   fi
2004   glib_extension=
2005   gint64_constant='(val##i64)'
2006   ;;
2007 esac
2008 glib_size_t=$glib_cv_sizeof_size_t
2009 glib_void_p=$ac_cv_sizeof_long
2010 glib_long=$ac_cv_sizeof_void_p
2011
2012 gintbits=`expr $ac_cv_sizeof_int \* 8`
2013 glongbits=`expr $ac_cv_sizeof_long \* 8`
2014
2015
2016 case $ac_cv_sizeof_void_p in
2017 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
2018 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
2019 *)                      glib_unknown_void_p=yes ;;
2020 esac
2021
2022
2023 case xyes in
2024 x$ac_cv_func_atexit)
2025   glib_atexit="
2026 #ifdef NeXT /* @#%@! NeXTStep */
2027 # define g_ATEXIT(proc) (!atexit (proc))
2028 #else
2029 # define g_ATEXIT(proc) (atexit (proc))
2030 #endif"
2031   ;;
2032 x$ac_cv_func_on_exit)
2033   glib_atexit="
2034 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
2035   ;;
2036 esac
2037
2038 case xyes in
2039 x$ac_cv_func_memmove)
2040   glib_memmove='
2041 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
2042   ;;
2043 x$glib_cv_working_bcopy)
2044   glib_memmove="
2045 /* memmove isn't available, but bcopy can copy overlapping memory regions */
2046 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
2047   ;;
2048 *)
2049   glib_memmove="
2050 /* memmove isn't found and bcopy can't copy overlapping memory regions,
2051  * so we have to roll our own copy routine. */
2052 void g_memmove (void* dest, const void * src, unsigned long len);"
2053   ;;
2054 esac
2055
2056 glib_defines="
2057 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
2058 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
2059 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
2060 "
2061
2062 case xyes in
2063 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
2064 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
2065 *)                      glib_vacopy=''
2066 esac
2067
2068 if test x$glib_cv_va_val_copy = xno; then
2069   glib_vacopy="\$glib_vacopy
2070 #define G_VA_COPY_AS_ARRAY 1"
2071 fi
2072
2073 if test x$glib_cv_hasinline = xyes; then
2074     glib_inline='#define G_HAVE_INLINE 1'
2075 fi
2076 if test x$glib_cv_has__inline = xyes; then
2077     glib_inline="\$glib_inline
2078 #define G_HAVE___INLINE 1"
2079 fi
2080 if test x$glib_cv_has__inline__ = xyes; then
2081     glib_inline="\$glib_inline
2082 #define G_HAVE___INLINE__ 1"
2083 fi
2084
2085 g_have_gnuc_varargs=$g_have_gnuc_varargs
2086 g_have_iso_c_varargs=$g_have_iso_c_varargs
2087 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
2088
2089 case xyes in
2090 x$ac_cv_c_bigendian)
2091   g_byte_order=G_BIG_ENDIAN
2092   g_bs_native=BE
2093   g_bs_alien=LE
2094   ;;
2095 *)
2096   g_byte_order=G_LITTLE_ENDIAN
2097   g_bs_native=LE
2098   g_bs_alien=BE
2099   ;;
2100 esac
2101
2102 g_have_eilseq=$have_eilseq
2103
2104 case x$have_threads in
2105 xnone)  g_enable_threads_def="#undef";;
2106 *)      g_enable_threads_def="#define";;
2107 esac
2108
2109 g_threads_impl_def=$g_threads_impl
2110
2111 g_mutex_has_default="$mutex_has_default"
2112 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
2113 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
2114 g_mutex_contents="$glib_cv_byte_contents_gmutex"
2115
2116 g_module_suffix="$glib_gmodule_suffix"
2117
2118 case $host in
2119   *-*-beos*)
2120     glib_os="#define G_OS_BEOS"
2121     ;;
2122   *-*-cygwin*)
2123     glib_os="#define G_OS_UNIX
2124 #define G_PLATFORM_WIN32
2125 #define G_WITH_CYGWIN"
2126     ;;
2127   *-*-mingw*)
2128     glib_os="#define G_OS_WIN32
2129 #define G_PLATFORM_WIN32"
2130     ;;
2131   *)
2132     glib_os="#define G_OS_UNIX"
2133     ;;
2134 esac
2135 ])
2136
2137 AC_OUTPUT([
2138 glib-2.0.pc
2139 glib-2.0-uninstalled.pc
2140 gmodule-2.0.pc
2141 gmodule-2.0-uninstalled.pc
2142 gthread-2.0.pc
2143 gthread-2.0-uninstalled.pc
2144 gobject-2.0.pc
2145 gobject-2.0-uninstalled.pc
2146 glib.spec
2147 glib-zip
2148 glib-gettextize
2149 Makefile
2150 build/Makefile
2151 build/win32/Makefile
2152 build/win32/dirent/Makefile
2153 glib/Makefile
2154 glib/libcharset/Makefile
2155 gmodule/gmoduleconf.h
2156 gmodule/Makefile
2157 gobject/Makefile
2158 gobject/glib-mkenums
2159 gthread/Makefile
2160 po/Makefile.in
2161 docs/Makefile
2162 docs/reference/Makefile
2163 docs/reference/glib/Makefile
2164 docs/reference/gobject/Makefile
2165 tests/Makefile
2166 m4macros/Makefile
2167 ],[echo ""
2168 echo " *** IMPORTANT *** "
2169 echo ""
2170 echo "This is a development version of GLib.  You should be using a stable"
2171 echo "version, which is available at ftp://ftp.gtk.org/pub/gtk/v1.2/.  The"
2172 echo "version you just configured is meant for developers of GLib only:"
2173 echo ""
2174 echo "  * You should not base stable software on this version of GLib."
2175 echo "  * GNOME developers should use a stable version of GLib."
2176 echo ""
2177 echo " *** You should be using GLib 1.2 instead. ***"
2178 ])