configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5
   6 # require autoconf 2.13
   7 AC_PREREQ(2.13)
   8
   9 # Process this file with autoconf to produce a configure script.
  10 AC_INIT(glist.c)
  11
  12 # Save this value here, since automake will set cflags later
  13 cflags_set=${CFLAGS+set}
  14
  15 # we rewrite this file
  16 rm -f glibconfig-sysdefs.h
  17
  18 dnl we to AC_DIVERT_PUSH/AC_DIVERT_POP these variable definitions so they
  19 dnl are available for $ac_help expansion (don't we all *love* autoconf?)
  20 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  21 #
  22 # The following version number definitions apply to GLib and GModule
  23 # as a whole, so if changes occoured in either of them, they are both
  24 # treated with the same interface and binary age.
  25 #
  26 # Making releases:
  27 #   GLIB_MICRO_VERSION += 1;
  28 #   GLIB_INTERFACE_AGE += 1;
  29 #   GLIB_BINARY_AGE += 1;
  30 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  31 # if backwards compatibility has been broken,
  32 # set GLIB_BINARY_AGE and GLIB_INTERFACE_AGE to 0.
  33 #
  34 GLIB_MAJOR_VERSION=1
  35 GLIB_MINOR_VERSION=3
  36 GLIB_MICRO_VERSION=0
  37 GLIB_INTERFACE_AGE=0
  38 GLIB_BINARY_AGE=0
  39 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  40 dnl
  41 AC_DIVERT_POP()dnl
  42
  43 AC_SUBST(GLIB_VERSION)
  44
  45 # libtool versioning
  46 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  47 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  48 LT_REVISION=$GLIB_INTERFACE_AGE
  49 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  50 AC_SUBST(LT_RELEASE)
  51 AC_SUBST(LT_CURRENT)
  52 AC_SUBST(LT_REVISION)
  53 AC_SUBST(LT_AGE)
  54
  55 VERSION=$GLIB_VERSION
  56 PACKAGE=glib
  57
  58 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  59
  60 # Specify a configuration file
  61 AM_CONFIG_HEADER(config.h)
  62
  63 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION)
  64 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION)
  65 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION)
  66 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE)
  67 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE)
  68
  69 dnl Initialize libtool
  70 AM_PROG_LIBTOOL
  71
  72 dnl Initialize maintainer mode
  73 AM_MAINTAINER_MODE
  74
  75 AC_CANONICAL_HOST
  76
  77 dnl figure debugging default, prior to $ac_help setup
  78 dnl
  79 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  80 if test `expr $GLIB_MINOR_VERSION \% 2` = 1 ; then
  81         debug_default=yes
  82 else
  83         debug_default=minimum
  84 fi
  85 AC_DIVERT_POP()dnl
  86
  87 dnl declare --enable-* args and collect ac_help strings
  88 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
  89 AC_ARG_ENABLE(mem_check, [  --enable-mem-check      turn on malloc/free sanity checking [default=no]],,enable_mem_check=no)
  90 AC_ARG_ENABLE(mem_profile, [  --enable-mem-profile    turn on malloc profiling atexit [default=no]],,enable_mem_profile=no)
  91 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
  92                     , enable_ansi=no)
  93 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
  94                           ([=no] will override --with-threads)],,enable_threads=yes)
  95
  96 if test "x$enable_threads" != "xyes"; then
  97   enable_threads=no
  98 fi
  99
 100 AC_MSG_CHECKING(whether to enable memory checking)
 101 if test "x$enable_mem_check" = "xyes"; then
 102   AC_DEFINE(ENABLE_MEM_CHECK, 1)
 103   AC_SUBST(ENABLE_MEM_CHECK)
 104   AC_MSG_RESULT(yes)
 105 else
 106   AC_MSG_RESULT(no)
 107 fi
 108
 109 AC_MSG_CHECKING(whether to enable memory profiling)
 110 if test "x$enable_mem_profile" = "xyes"; then
 111   AC_DEFINE(ENABLE_MEM_PROFILE, 1)
 112   AC_SUBST(ENABLE_MEM_PROFILE)
 113   AC_MSG_RESULT(yes)
 114 else
 115   AC_MSG_RESULT(no)
 116 fi
 117
 118 if test "x$enable_debug" = "xyes"; then
 119   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 120   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 121 else
 122   if test "x$enable_debug" = "xno"; then
 123     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 124   fi
 125 fi
 126
 127 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 128
 129 # Checks for programs.
 130 AC_PROG_CC
 131 AM_PROG_CC_STDC
 132 AC_PROG_INSTALL
 133
 134 changequote(,)dnl
 135 if test "x$GCC" = "xyes"; then
 136   case " $CFLAGS " in
 137   *[\ \ ]-Wall[\ \      ]*) ;;
 138   *) CFLAGS="$CFLAGS -Wall" ;;
 139   esac
 140
 141   if test "x$enable_ansi" = "xyes"; then
 142     case " $CFLAGS " in
 143     *[\ \       ]-ansi[\ \      ]*) ;;
 144     *) CFLAGS="$CFLAGS -ansi" ;;
 145     esac
 146
 147     case " $CFLAGS " in
 148     *[\ \       ]-pedantic[\ \  ]*) ;;
 149     *) CFLAGS="$CFLAGS -pedantic" ;;
 150     esac
 151   fi
 152 fi
 153 changequote([,])dnl
 154
 155 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 156 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 157 glib_save_LIBS=$LIBS
 158 LIBS="$LIBS -lm"
 159 AC_TRY_RUN([#include <math.h>
 160              int main (void) { return (log(1) != log(1.)); }],
 161      AC_MSG_RESULT(none needed),
 162      glib_save_CFLAGS=$CFLAGS
 163      CFLAGS="$CFLAGS -std1"
 164      AC_TRY_RUN([#include <math.h>
 165                  int main (void) { return (log(1) != log(1.)); }],
 166          AC_MSG_RESULT(-std1),
 167          AC_MSG_RESULT()
 168          CFLAGS=$glib_save_CFLAGS
 169          AC_MSG_WARN(
 170                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 171      )
 172 )
 173 LIBS=$glib_save_LIBS
 174
 175 dnl NeXTStep cc seems to need this
 176 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 177 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 178   AC_MSG_RESULT(none needed),
 179   glib_save_CFLAGS=$CFLAGS
 180   CFLAGS="$CFLAGS -posix"
 181   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 182     AC_MSG_RESULT(-posix),
 183     AC_MSG_RESULT()
 184     CFLAGS=$glib_save_CFLAGS
 185     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 186
 187 # Checks for header files.
 188 AC_HEADER_STDC
 189
 190 # Checks for library functions.
 191 AC_FUNC_VPRINTF
 192
 193 AC_CHECK_FUNCS(atexit on_exit)
 194
 195 AC_CHECK_SIZEOF(char)
 196 AC_CHECK_SIZEOF(short)
 197 AC_CHECK_SIZEOF(long)
 198 AC_CHECK_SIZEOF(int)
 199 AC_CHECK_SIZEOF(void *)
 200 AC_CHECK_SIZEOF(long long)
 201
 202 dnl long doubles were not used, and a portability problem
 203 dnl AC_C_LONG_DOUBLE
 204 AC_C_CONST
 205
 206 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 207 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 208 dnl actually supported.
 209 AC_MSG_CHECKING(for __inline)
 210 AC_CACHE_VAL(glib_cv_has__inline,[
 211         AC_TRY_RUN([
 212         __inline int foo () { return 0; }
 213         int main () { return foo (); }
 214         ],
 215         glib_cv_has__inline=yes
 216         ,
 217         glib_cv_has__inline=no
 218         ,)
 219 ])
 220 AC_MSG_RESULT($glib_cv_has__inline)
 221 case x$glib_cv_has__inline in
 222 xyes) AC_DEFINE(G_HAVE___INLINE)
 223 esac
 224 AC_MSG_CHECKING(for __inline__)
 225 AC_CACHE_VAL(glib_cv_has__inline__,[
 226         AC_TRY_RUN([
 227         __inline__ int foo () { return 0; }
 228         int main () { return foo (); }
 229         ],
 230         glib_cv_has__inline__=yes
 231         ,
 232         glib_cv_has__inline__=no
 233         ,)
 234 ])
 235 AC_MSG_RESULT($glib_cv_has__inline__)
 236 case x$glib_cv_has__inline__ in
 237 xyes) AC_DEFINE(G_HAVE___INLINE__)
 238 esac
 239 AC_MSG_CHECKING(for inline)
 240 AC_CACHE_VAL(glib_cv_hasinline,[
 241         AC_TRY_RUN([
 242         inline int foo () { return 0; }
 243         int main () { return foo (); }
 244         ],
 245         glib_cv_hasinline=yes
 246         ,
 247         glib_cv_hasinline=no
 248         ,)
 249 ])
 250 AC_MSG_RESULT($glib_cv_hasinline)
 251 case x$glib_cv_hasinline in
 252 xyes) AC_DEFINE(G_HAVE_INLINE)
 253 esac
 254
 255 dnl for bytesex stuff
 256 AC_C_BIGENDIAN
 257
 258 dnl header file checks
 259 AC_CHECK_HEADERS(float.h, AC_DEFINE(HAVE_FLOAT_H))
 260 AC_CHECK_HEADERS(limits.h, AC_DEFINE(HAVE_LIMITS_H))
 261 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 262 AC_CHECK_HEADERS(sys/param.h, AC_DEFINE(HAVE_SYS_PARAM_H))
 263 AC_CHECK_HEADERS(sys/poll.h, AC_DEFINE(HAVE_SYS_POLL_H))
 264 AC_CHECK_HEADERS(sys/select.h, AC_DEFINE(HAVE_SYS_SELECT_H))
 265 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 266 AC_CHECK_HEADERS(sys/times.h, AC_DEFINE(HAVE_SYS_TIMES_H))
 267 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 268 AC_CHECK_HEADERS(values.h, AC_DEFINE(HAVE_VALUES_H))
 269
 270 # Check for some functions
 271 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf strcasecmp strncasecmp poll)
 272
 273 # Check for sys_errlist
 274 AC_MSG_CHECKING(for sys_errlist)
 275 AC_TRY_LINK(, [
 276 extern char *sys_errlist[];
 277 extern int sys_nerr;
 278 sys_errlist[sys_nerr-1][0] = 0;
 279 ], glib_ok=yes, glib_ok=no)
 280 AC_MSG_RESULT($glib_ok)
 281 if test $glib_ok = no; then
 282     AC_DEFINE(NO_SYS_ERRLIST)
 283 fi
 284
 285 # Check for sys_siglist
 286 AC_MSG_CHECKING(for sys_siglist)
 287 AC_TRY_LINK(, [
 288 extern char *sys_siglist[];
 289 strlen (sys_siglist[0]);
 290 ], glib_ok=yes, glib_ok=no)
 291 AC_MSG_RESULT($glib_ok)
 292 if test $glib_ok = no; then
 293     AC_DEFINE(NO_SYS_SIGLIST)
 294 fi
 295
 296 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 297 AC_MSG_CHECKING(for sys_siglist declaration)
 298 AC_TRY_COMPILE([#include <signal.h>], [
 299 strlen (sys_siglist[0]);
 300 ], glib_ok=yes, glib_ok=no)
 301 AC_MSG_RESULT($glib_ok)
 302 if test $glib_ok = no; then
 303     AC_DEFINE(NO_SYS_SIGLIST_DECL)
 304 fi
 305
 306 # Check if <sys/select.h> needs to be included for fd_set
 307 AC_MSG_CHECKING([for fd_set])
 308 AC_TRY_COMPILE([#include <sys/types.h>],
 309         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 310 if test $gtk_ok = yes; then
 311     AC_MSG_RESULT([yes, found in sys/types.h])
 312 else
 313     AC_HEADER_EGREP(fd_set, sys/select.h, gtk_ok=yes)
 314     if test $gtk_ok = yes; then
 315         AC_DEFINE(HAVE_SYS_SELECT_H)
 316         AC_MSG_RESULT([yes, found in sys/select.h])
 317     else
 318         AC_DEFINE(NO_FD_SET)
 319         AC_MSG_RESULT(no)
 320     fi
 321 fi
 322
 323
 324 dnl **********************
 325 dnl *** va_copy checks ***
 326 dnl **********************
 327 dnl we currently check for all three va_copy possibilities, so we get
 328 dnl all results in config.log for bug reports.
 329 AC_MSG_CHECKING(for an implementation of va_copy())
 330 AC_CACHE_VAL(glib_cv_va_copy,[
 331         AC_TRY_RUN([
 332         #include <stdarg.h>
 333         void f (int i, ...) {
 334         va_list args1, args2;
 335         va_start (args1, i);
 336         va_copy (args2, args1);
 337         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 338           exit (1);
 339         va_end (args1); va_end (args2);
 340         }
 341         int main() {
 342           f (0, 42);
 343           return 0;
 344         }],
 345         glib_cv_va_copy=yes
 346         ,
 347         glib_cv_va_copy=no
 348         ,)
 349 ])
 350 AC_MSG_RESULT($glib_cv_va_copy)
 351 AC_MSG_CHECKING(for an implementation of __va_copy())
 352 AC_CACHE_VAL(glib_cv___va_copy,[
 353         AC_TRY_RUN([
 354         #include <stdarg.h>
 355         void f (int i, ...) {
 356         va_list args1, args2;
 357         va_start (args1, i);
 358         __va_copy (args2, args1);
 359         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 360           exit (1);
 361         va_end (args1); va_end (args2);
 362         }
 363         int main() {
 364           f (0, 42);
 365           return 0;
 366         }],
 367         glib_cv___va_copy=yes
 368         ,
 369         glib_cv___va_copy=no
 370         ,)
 371 ])
 372 AC_MSG_RESULT($glib_cv___va_copy)
 373 AC_MSG_CHECKING(whether va_lists can be copied by value)
 374 AC_CACHE_VAL(glib_cv_va_val_copy,[
 375         AC_TRY_RUN([
 376         #include <stdarg.h>
 377         void f (int i, ...) {
 378         va_list args1, args2;
 379         va_start (args1, i);
 380         args2 = args1;
 381         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 382           exit (1);
 383         va_end (args1); va_end (args2);
 384         }
 385         int main() {
 386           f (0, 42);
 387           return 0;
 388         }],
 389         glib_cv_va_val_copy=yes
 390         ,
 391         glib_cv_va_val_copy=no
 392         ,)
 393 ])
 394 if test "x$glib_cv_va_copy" = "xyes"; then
 395   AC_DEFINE(G_VA_COPY, va_copy)
 396 else if test "x$glib_cv___va_copy" = "xyes"; then
 397   AC_DEFINE(G_VA_COPY, __va_copy)
 398 fi
 399 fi
 400 if test "x$glib_cv_va_val_copy" = "xno"; then
 401   AC_DEFINE(G_VA_COPY_AS_ARRAY)
 402 fi
 403 AC_MSG_RESULT($glib_cv_va_val_copy)
 404
 405
 406 dnl ***********************
 407 dnl *** g_module checks ***
 408 dnl ***********************
 409 G_MODULE_LIBS=
 410 G_MODULE_LDFLAGS=
 411 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
 412 G_MODULE_NEED_USCORE=0
 413 G_MODULE_HAVE_DLERROR=0
 414 dnl *** dlopen() and dlsym() in system libraries
 415 if test -z "$G_MODULE_IMPL"; then
 416         AC_CHECK_FUNC(dlopen,
 417                 AC_CHECK_FUNC(dlsym,
 418                         G_MODULE_IMPL=G_MODULE_IMPL_DL
 419                 ,)
 420         ,)
 421 fi
 422 dnl *** dlopen() and dlsym() in libdl
 423 if test -z "$G_MODULE_IMPL"; then
 424         AC_CHECK_LIB(dl, dlopen,
 425                 AC_CHECK_LIB(dl, dlsym,
 426                         G_MODULE_LIBS=-ldl
 427                         G_MODULE_IMPL=G_MODULE_IMPL_DL
 428                 ,)
 429         ,)
 430 fi
 431 dnl *** shl_load() in libdld (HP-UX)
 432 if test -z "$G_MODULE_IMPL"; then
 433         AC_MSG_CHECKING(how to export all symbols)
 434         SAVED_LDFLAGS=$LDFLAGS
 435         LDFLAGS="$LDFLAGS -Wl,-E"
 436         AC_TRY_LINK(,[ return 0; ],
 437                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 438                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 439                 AC_TRY_LINK(,[ return 0; ],
 440                         G_MODULE_LDFLAGS="-bexpall",
 441                         G_MODULE_LDFLAGS="none"
 442                 )
 443         ])
 444         LDFLAGS=$SAVED_LDFLAGS
 445         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 446         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 447                 G_MODULE_LDFLAGS=
 448         fi
 449         AC_CHECK_LIB(dld, shl_load,
 450                 G_MODULE_LIBS=-ldld
 451                 G_MODULE_IMPL=G_MODULE_IMPL_DLD
 452         ,)
 453 fi
 454 dnl *** additional checks for G_MODULE_IMPL_DL
 455 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 456         case "$host_os" in
 457           linux*)
 458             G_MODULE_LDFLAGS='-rdynamic'
 459             ;;
 460         esac
 461         LIBS_orig="$LIBS"
 462         LDFLAGS_orig="$LDFLAGS"
 463         LIBS="$LIBS $G_MODULE_LIBS"
 464         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 465 dnl *** check whether we need preceeding underscores
 466         AC_MSG_CHECKING(for preceeding underscore in symbols)
 467         AC_CACHE_VAL(glib_cv_uscore,[
 468                 AC_TRY_RUN([
 469                 #include <dlfcn.h>
 470                 int glib_underscore_test (void) { return 42; }
 471                 int main() {
 472                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 473                   handle = dlopen ((void*)0, 0);
 474                   if (handle) {
 475                     f1 = dlsym (handle, "glib_underscore_test");
 476                     f2 = dlsym (handle, "_glib_underscore_test");
 477                   } return (!f2 || f1);
 478                 }],
 479                         glib_cv_uscore=yes,
 480                         glib_cv_uscore=no,
 481                 )
 482                 rm -f plugin.c plugin.o plugin.lo
 483         ])
 484         AC_MSG_RESULT($glib_cv_uscore)
 485         if test "x$glib_cv_uscore" = "xyes"; then
 486                 G_MODULE_NEED_USCORE=1
 487         else
 488                 G_MODULE_NEED_USCORE=0
 489         fi
 490
 491         LDFLAGS="$LDFLAGS_orig"
 492 dnl *** check for having dlerror()
 493         AC_CHECK_FUNC(dlerror,
 494                 G_MODULE_HAVE_DLERROR=1,
 495                 G_MODULE_HAVE_DLERROR=0)
 496         LIBS="$LIBS_orig"
 497 fi
 498 dnl *** done, have e got an implementation?
 499 if test -z "$G_MODULE_IMPL"; then
 500         G_MODULE_IMPL=0
 501 fi
 502 AC_SUBST(G_MODULE_IMPL)
 503 AC_SUBST(G_MODULE_LIBS)
 504 AC_SUBST(G_MODULE_LDFLAGS)
 505 AC_SUBST(G_MODULE_HAVE_DLERROR)
 506 AC_SUBST(G_MODULE_NEED_USCORE)
 507 AC_SUBST(GLIB_DEBUG_FLAGS)
 508
 509
 510 dnl ***********************
 511 dnl *** g_thread checks ***
 512 dnl ***********************
 513
 514 AC_ARG_WITH(threads, [  --with-threads=[none/posix/dce/solaris/nspr] specify a thread implementation to use],
 515         if test "x$with_threads" = x; then
 516                 want_threads=yes
 517         else
 518                 want_threads=$with_threads
 519         fi,
 520         want_threads=yes)
 521 if test "x$enable_threads" = "xno"; then
 522         want_threads=no
 523 fi
 524 if test "x$want_threads" = "xnone"; then
 525         want_threads=no
 526 fi
 527
 528 dnl error and warning message
 529 dnl *************************
 530
 531 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
 532                 computer. GLib will not have a default thread implementation."
 533
 534 FLAG_DOES_NOT_WORK="I can't find the MACRO, that enables thread safety on your
 535                 platform (normaly it's "_REENTRANT"). I'll not use any flag on
 536                 compilation now, but then your programs might not work.
 537                 Please provide information on how it is done on your system."
 538
 539 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
 540                 "
 541
 542 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
 543                 provide information on your thread implementation.
 544                 You can also run 'configure --disable-threads'
 545                 to compile without thread support."
 546
 547 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
 548                 functions will not be MT-safe during their first call because
 549                 there is no working 'getpwuid_r' on your system."
 550
 551 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
 552                 because there is no 'localtime_r' on your system."
 553
 554 dnl determination of thread implementation
 555 dnl ***************************************
 556
 557 have_threads=none
 558 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
 559         case $host in
 560                 *-*-solaris*)
 561                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
 562                 ;;
 563         esac
 564 fi
 565 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
 566                                 || test "x$want_threads" = xdce; then
 567         if test "x$have_threads" = xnone; then
 568                 AC_EGREP_HEADER([[^a-zA-Z_]pthread_attr_init[^a-zA-Z_]],
 569                         pthread.h,
 570                         have_threads=posix)
 571         fi
 572         if test "x$have_threads" = xnone; then
 573                 AC_EGREP_HEADER([[^a-zA-Z_]pthread_attr_create[^a-zA-Z_]],
 574                         pthread.h,
 575                         have_threads=dce)
 576         fi
 577 fi
 578 if test "x$want_threads" = xyes || test "x$want_threads" = xnspr; then
 579         if test "x$have_threads" = xnone; then
 580                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar, have_threads=nspr)
 581         fi
 582 fi
 583
 584 AC_MSG_CHECKING(for thread implementation)
 585
 586 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
 587         AC_MSG_RESULT(none available)
 588         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
 589 else
 590         AC_MSG_RESULT($have_threads)
 591 fi
 592
 593
 594 dnl determination of G_THREAD_LIBS
 595 dnl ******************************
 596
 597 G_THREAD_LIBS=
 598 G_THREAD_CFLAGS=
 599
 600 mutex_has_default=no
 601 case $have_threads in
 602         posix|dce)
 603                 G_THREAD_LIBS=error
 604                 glib_save_LIBS="$LIBS"
 605                 for thread_lib in "" pthread pthreads c_r thread; do
 606                         # This is not AC_CHECK_LIB to also work with function
 607                         # name mangling in header files.
 608                         LIBS="$glib_save_LIBS -l$thread_lib"
 609                         IN=
 610                         test x"$thread_lib" = x || IN=" in -l$thread_lib"
 611                         AC_MSG_CHECKING(for pthread_create$IN)
 612                         AC_TRY_LINK([#include <pthread.h>],
 613                                 [pthread_create(NULL,NULL,NULL,NULL)],
 614                                 [AC_MSG_RESULT(yes)
 615                                 G_THREAD_LIBS="-l$thread_lib"
 616                                 break],
 617                                 [AC_MSG_RESULT(no)])
 618                 done
 619                 LIBS="$glib_save_LIBS"
 620                 dnl ********** DG/UX ************
 621                 AC_CHECK_LIB(thread, __d10_pthread_create,
 622                         G_THREAD_CFLAGS="-D_POSIX4A_DRAFT10_SOURCE")
 623                 mutex_has_default=yes
 624                 mutex_default_type='pthread_mutex_t'
 625                 mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
 626                 mutex_header_file='pthread.h'
 627                 if test "x$have_threads" = "xposix"; then
 628                         g_threads_impl="POSIX"
 629                 else
 630                         g_threads_impl="DCE"
 631                         have_threads="posix"
 632                 fi
 633                 ;;
 634         solaris)
 635                 G_THREAD_LIBS=error
 636                 AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
 637                 mutex_has_default=yes
 638                 mutex_default_type='mutex_t'
 639                 mutex_default_init="DEFAULTMUTEX"
 640                 mutex_header_file='thread.h'
 641                 g_threads_impl="SOLARIS"
 642                 ;;
 643         nspr)
 644                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar,
 645                              G_THREAD_LIBS="-lnspr21")
 646                 g_threads_impl="NSPR"
 647                 ;;
 648         none)
 649                 g_threads_impl="NONE"
 650                 ;;
 651         *)
 652                 g_threads_impl="NONE"
 653                 G_THREAD_LIBS=error
 654                 ;;
 655 esac
 656
 657 if test "x$G_THREAD_LIBS" = xerror; then
 658         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 659 fi
 660
 661 AC_MSG_CHECKING(thread related libraries)
 662 AC_MSG_RESULT($G_THREAD_LIBS)
 663
 664 dnl determination of G_THREAD_CFLAGS
 665 dnl ********************************
 666
 667 if test x"$enable_threads" = xyes; then
 668
 669     G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_REENTRANT" # good default guess
 670
 671     case $host in
 672         *-aix*)
 673                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 674                 if test x"$GCC" = xyes; then
 675                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
 676                 fi
 677                 ;;
 678         *-freebsd2.2*)
 679                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 680
 681                 # FreeBSD 2.2.x shiped with gcc 2.7.2.x, which doesn't support
 682                 # -mthreads flag.
 683                 ;;
 684     esac
 685
 686     # if we are not finding the ctime_r function, then we probably are
 687     # not using the proper multithread flag
 688     old_CPPFLAGS=$CPPFLAGS
 689     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
 690     AC_EGREP_HEADER([[^a-zA-Z_]ctime_r[^a-zA-Z_]], time.h, ,
 691     G_THREAD_CFLAGS=
 692     AC_MSG_WARN($FLAG_DOES_NOT_WORK))
 693     CPPFLAGS=$old_CPPFLAGS
 694
 695     AC_MSG_CHECKING(thread related cflags)
 696
 697     AC_MSG_RESULT($G_THREAD_CFLAGS)
 698 else
 699     G_THREAD_CFLAGS=
 700 fi
 701
 702 dnl check for mt safe function variants and some posix functions
 703 dnl ************************************************************
 704
 705 if test x"$enable_threads" = xyes; then
 706         glib_save_LIBS="$LIBS"
 707         glib_save_CFLAGS="$CFLAGS"
 708         # we are not doing the following for now, as this might require glib
 709         # to always be linked with the thread libs on some platforms.
 710         # LIBS="$LIBS $G_THREAD_LIBS"
 711         CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 712         AC_CHECK_FUNCS(localtime_r rand_r)
 713         if test "$ac_cv_header_pwd_h" = "yes"; then
 714                 AC_MSG_CHECKING([for getpwuid_r])
 715                 AC_CACHE_VAL(ac_cv_func_getpwuid_r,
 716                         [AC_TRY_RUN([#include <errno.h>
 717                                 int main () { char buffer[10000], *pointer;
 718                                 char getpwuid_r (long, void*, void*,
 719                                         int, void*);
 720                                 errno = 0;
 721                                 getpwuid_r (0, &buffer, &buffer,
 722                                         sizeof (buffer), &pointer);
 723                                 return errno == ENOSYS;}],
 724                                 [ac_cv_func_getpwuid_r=yes],
 725                                 [ac_cv_func_getpwuid_r=no])])
 726                 if test "$ac_cv_func_getpwuid_r" = yes; then
 727                         AC_MSG_RESULT(yes)
 728                         AC_DEFINE(HAVE_GETPWUID_R)
 729                 else
 730                         AC_MSG_RESULT(no)
 731                 fi
 732                 if test "$ac_cv_func_getpwuid_r" = "yes"; then
 733                         AC_MSG_CHECKING(whether getpwuid_r is posix like)
 734                         # getpwuid_r(0, NULL, NULL, 0) is the signature on
 735                         # solaris, if that is not found, the prog below won't
 736                         # compile, then the posix signature is assumed as
 737                         # the default.
 738                         AC_TRY_COMPILE([#include <pwd.h>],
 739                                 [getpwuid_r(0, NULL, NULL, 0);],
 740                                 [AC_MSG_RESULT(no)],
 741                                 [AC_MSG_RESULT(yes)
 742                                 AC_DEFINE(HAVE_GETPWUID_R_POSIX)])
 743                 fi
 744         fi
 745         LIBS="$glib_save_LIBS"
 746         CFLAGS="$glib_save_CFLAGS"
 747
 748         # now spit out all the warnings.
 749         if test "$ac_cv_func_getpwuid_r" != "yes"; then
 750                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
 751         fi
 752         if test "$ac_cv_func_localtime_r" != "yes"; then
 753                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
 754         fi
 755 fi
 756
 757 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c")
 758 AC_SUBST(G_THREAD_CFLAGS)
 759 AC_SUBST(G_THREAD_LIBS)
 760
 761 CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 762
 763 dnl **********************************************
 764 dnl *** GDefaultMutex setup and initialization ***
 765 dnl **********************************************
 766 dnl
 767 dnl if mutex_has_default = yes, we also got
 768 dnl mutex_default_type, mutex_default_init and mutex_header_file
 769 GLIB_IF_VAR_EQ(mutex_has_default, yes,
 770         GLIB_SIZEOF([#include <$mutex_header_file>],
 771                     $mutex_default_type,
 772                     gmutex,
 773                     )
 774         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
 775                            $mutex_default_type,
 776                            gmutex,
 777                            $glib_cv_sizeof_gmutex,
 778                            $mutex_default_init)
 779         ,
 780 )
 781
 782
 783 dnl ****************************************
 784 dnl *** GLib POLL* compatibility defines ***
 785 dnl ****************************************
 786 GLIB_SYSDEFS(
 787 [#include <sys/types.h>
 788 #include <sys/poll.h>],
 789         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
 790         glibconfig-sysdefs.h,
 791         =)
 792
 793
 794 dnl ******************************
 795 dnl *** output the whole stuff ***
 796 dnl ******************************
 797
 798 AC_OUTPUT_COMMANDS([
 799
 800 ## Generate `glibconfig.h' in two cases
 801 ## 1. `config.status' is run either explicitly, or via configure.
 802 ##     Esp. not when it is run in `Makefile' to generate makefiles and
 803 ##     config.h
 804 ## 2. CONFIG_OTHER is set explicitly
 805 ##
 806 ## Case 1 is difficult.  We know that `automake' sets one of
 807 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
 808 ## only when AM_CONFIG_HEADER is set, however.
 809
 810 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
 811   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
 812   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
 813 fi
 814 case "$CONFIG_OTHER" in
 815 *glibconfig.h*)
 816         echo creating glibconfig.h
 817         outfile=glibconfig.h-tmp
 818         cat > $outfile <<\_______EOF
 819 /* glibconfig.h
 820  *
 821  * This is a generated file.  Please modify `configure.in'
 822  */
 823
 824 #ifndef GLIBCONFIG_H
 825 #define GLIBCONFIG_H
 826
 827 #ifdef __cplusplus
 828 extern "C" {
 829 #endif /* __cplusplus */
 830
 831 _______EOF
 832
 833         if test x$glib_limits_h = xyes; then
 834           echo '#include <limits.h>' >> $outfile
 835         fi
 836         if test x$glib_float_h = xyes; then
 837           echo '#include <float.h>' >> $outfile
 838         fi
 839         if test x$glib_values_h = xyes; then
 840           echo '#include <values.h>' >> $outfile
 841         fi
 842         if test x$g_mutex_header_file != x; then
 843           echo '#include <'"$g_mutex_header_file"'>' >> $outfile
 844         fi
 845         if test x$glib_sys_poll_h = xyes; then
 846           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
 847         fi
 848
 849         cat >> $outfile <<_______EOF
 850
 851 #define G_MINFLOAT      $glib_mf
 852 #define G_MAXFLOAT      $glib_Mf
 853 #define G_MINDOUBLE     $glib_md
 854 #define G_MAXDOUBLE     $glib_Md
 855 #define G_MINSHORT      $glib_ms
 856 #define G_MAXSHORT      $glib_Ms
 857 #define G_MAXUSHORT     $glib_Mus
 858 #define G_MININT        $glib_mi
 859 #define G_MAXINT        $glib_Mi
 860 #define G_MAXUINT       $glib_Mui
 861 #define G_MINLONG       $glib_ml
 862 #define G_MAXLONG       $glib_Ml
 863 #define G_MAXULONG      $glib_Mul
 864
 865 _______EOF
 866
 867
 868         ### this should always be true in a modern C/C++ compiler
 869         cat >>$outfile <<_______EOF
 870 typedef signed char gint8;
 871 typedef unsigned char guint8;
 872 _______EOF
 873
 874
 875         if test -n "$gint16"; then
 876           cat >>$outfile <<_______EOF
 877 typedef signed $gint16 gint16;
 878 typedef unsigned $gint16 guint16;
 879 #define G_GINT16_FORMAT $gint16_format
 880 #define G_GUINT16_FORMAT $guint16_format
 881 _______EOF
 882         fi
 883
 884
 885         if test -n "$gint32"; then
 886           cat >>$outfile <<_______EOF
 887 typedef signed $gint32 gint32;
 888 typedef unsigned $gint32 guint32;
 889 #define G_GINT32_FORMAT $gint32_format
 890 #define G_GUINT32_FORMAT $guint32_format
 891 _______EOF
 892         fi
 893
 894
 895         if test -n "$gint64"; then
 896           cat >>$outfile <<_______EOF
 897 ${glib_warning_guard}#define G_HAVE_GINT64 1
 898
 899 ${glib_extension}typedef signed $gint64 gint64;
 900 ${glib_extension}typedef unsigned $gint64 guint64;
 901
 902 #define G_GINT64_FORMAT $gint64_format
 903 #define G_GUINT64_FORMAT $guint64_format
 904 #define G_GINT64_CONSTANT(val)  $gint64_constant
 905 _______EOF
 906         fi
 907
 908
 909         if test -z "$glib_unknown_void_p"; then
 910           cat >>$outfile <<_______EOF
 911
 912 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
 913 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
 914
 915 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
 916 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
 917 _______EOF
 918         else
 919           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
 920         fi
 921
 922
 923
 924         cat >>$outfile <<_______EOF
 925 $glib_atexit
 926 $glib_memmove
 927 $glib_defines
 928
 929 $glib_vacopy
 930
 931 #ifdef  __cplusplus
 932 #define G_HAVE_INLINE   1
 933 #else   /* !__cplusplus */
 934 $glib_inline
 935 #endif  /* !__cplusplus */
 936 _______EOF
 937
 938         echo >>$outfile
 939         if test x$g_mutex_has_default = xyes; then
 940                 cat >>$outfile <<_______EOF
 941 $g_enable_threads_def G_THREADS_ENABLED
 942 #define G_THREADS_IMPL_$g_threads_impl_def
 943 typedef struct _GStaticMutex GStaticMutex;
 944 struct _GStaticMutex
 945 {
 946   struct _GMutex *runtime_mutex;
 947   union {
 948     char   pad[$g_mutex_sizeof];
 949     double dummy_double;
 950     void  *dummy_pointer;
 951     long   dummy_long;
 952   } aligned_pad_u;
 953 };
 954 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
 955 #define g_static_mutex_get_mutex(mutex) \
 956   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->aligned_pad_u)) : \
 957    g_static_mutex_get_mutex_impl (&((mutex)->runtime_mutex)))
 958 _______EOF
 959         else
 960                 cat >>$outfile <<_______EOF
 961 $g_enable_threads_def G_THREADS_ENABLED
 962 #define G_THREADS_IMPL_$g_threads_impl_def
 963 typedef struct _GMutex* GStaticMutex;
 964 #define G_STATIC_MUTEX_INIT NULL
 965 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (mutex))
 966 _______EOF
 967         fi
 968
 969         echo >>$outfile
 970         g_bit_sizes="16 32"
 971         if test -n "$gint64"; then
 972           g_bit_sizes="$g_bit_sizes 64"
 973         fi
 974         for bits in $g_bit_sizes; do
 975           cat >>$outfile <<_______EOF
 976 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
 977 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
 978 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
 979 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
 980 _______EOF
 981         done
 982
 983         cat >>$outfile <<_______EOF
 984 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
 985 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
 986 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
 987 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
 988 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
 989 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
 990 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
 991 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
 992 #define G_BYTE_ORDER $g_byte_order
 993
 994 _______EOF
 995
 996         if test -r glibconfig-sysdefs.h; then
 997           cat glibconfig-sysdefs.h >>$outfile
 998         fi
 999
1000         cat >>$outfile <<_______EOF
1001 #ifdef __cplusplus
1002 }
1003 #endif /* __cplusplus */
1004
1005 #endif /* GLIBCONFIG_H */
1006 _______EOF
1007
1008
1009         if cmp -s $outfile glibconfig.h; then
1010           echo glibconfig.h is unchanged
1011           rm -f $outfile
1012         else
1013           mv $outfile glibconfig.h
1014         fi ;;
1015 esac
1016 ],[
1017
1018 # Note that if two cases are the same, case goes with the first one.
1019 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
1020 # on variable expansion in case labels.  Look at the generated config.status
1021 # for a hint.
1022
1023 case xyes in
1024 x$ac_cv_header_float_h)
1025   glib_float_h=yes
1026   glib_mf=FLT_MIN glib_Mf=FLT_MAX
1027   glib_md=DBL_MIN glib_Md=DBL_MAX
1028   ;;
1029 x$ac_cv_header_values_h)
1030   glib_values_h=yes
1031   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
1032   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
1033   ;;
1034 esac
1035
1036 case xyes in
1037 x$ac_cv_header_limits_h)
1038   glib_limits_h=yes
1039   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
1040   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
1041   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
1042   ;;
1043 x$ac_cv_header_values_h)
1044   glib_values_h=yes
1045   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus=unknown  # Please insert the right
1046   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui=unknown  # values from
1047   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul=unknown  # /usr/include/values.h
1048   ;;
1049 esac
1050
1051 if test x$ac_cv_header_sys_poll_h = xyes ; then
1052   glib_sys_poll_h=yes
1053 fi
1054
1055 case 2 in
1056 $ac_cv_sizeof_short)
1057   gint16=short
1058   gint16_format='"hi"'
1059   guint16_format='"hu"'
1060   ;;
1061 $ac_cv_sizeof_int)
1062   gint16=int
1063   gint16_format='"i"'
1064   guint16_format='"u"'
1065   ;;
1066 esac
1067 case 4 in
1068 $ac_cv_sizeof_short)
1069   gint32=short
1070   gint32_format='"hi"'
1071   guint32_format='"hu"'
1072   ;;
1073 $ac_cv_sizeof_int)
1074   gint32=int
1075   gint32_format='"i"'
1076   guint32_format='"u"'
1077   ;;
1078 $ac_cv_sizeof_long)
1079   gint32=long
1080   gint32_format='"li"'
1081   guint32_format='"lu"'
1082   ;;
1083 esac
1084 case 8 in
1085 $ac_cv_sizeof_int)
1086   gint64=int
1087   gint64_format='"i"'
1088   guint64_format='"u"'
1089   glib_extension=
1090   glib_warning_guard=
1091   gint64_constant='(val)'
1092   ;;
1093 $ac_cv_sizeof_long)
1094   gint64=long
1095   gint64_format='"li"'
1096   guint64_format='"lu"'
1097   glib_extension=
1098   glib_warning_guard=
1099   gint64_constant='(val##L)'
1100   ;;
1101 $ac_cv_sizeof_long_long)
1102   gint64='long long'
1103   gint64_format='"lli"'
1104   guint64_format='"llu"'
1105   glib_extension='G_GNUC_EXTENSION '
1106   glib_warning_guard="
1107 #if defined (__GNUC__) && __GNUC__ >= 2 && __GNUC_MINOR__ >= 8
1108 #  define G_GNUC_EXTENSION __extension__
1109 #else
1110 #  define G_GNUC_EXTENSION
1111 #endif
1112
1113 "
1114   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1115   ;;
1116 esac
1117
1118 gintbits=`expr $ac_cv_sizeof_int \* 8`
1119 glongbits=`expr $ac_cv_sizeof_long \* 8`
1120
1121
1122 case $ac_cv_sizeof_void_p in
1123 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
1124 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
1125 *)                      glib_unknown_void_p=yes ;;
1126 esac
1127
1128
1129 case xyes in
1130 x$ac_cv_func_atexit)
1131   glib_atexit="
1132 #ifdef NeXT /* @#%@! NeXTStep */
1133 # define g_ATEXIT(proc) (!atexit (proc))
1134 #else
1135 # define g_ATEXIT(proc) (atexit (proc))
1136 #endif"
1137   ;;
1138 x$ac_cv_func_on_exit)
1139   glib_atexit="
1140 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
1141   ;;
1142 esac
1143
1144 case xyes in
1145 x$ac_cv_func_memmove)
1146   glib_memmove='
1147 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
1148   ;;
1149 *)
1150   glib_memmove="
1151 /* We make the assumption that if memmove isn't available, then
1152  * bcopy will do the job. This isn't safe everywhere. (bcopy can't
1153  * necessarily handle overlapping copies) */
1154 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
1155   ;;
1156 esac
1157
1158 glib_defines="
1159 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
1160 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
1161 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
1162 "
1163
1164 case xyes in
1165 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
1166 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
1167 *)                      glib_vacopy=''
1168 esac
1169
1170 if test x$glib_cv_va_val_copy = xno; then
1171   glib_vacopy="\$glib_vacopy
1172 #define G_VA_COPY_AS_ARRAY 1"
1173 fi
1174
1175 if test x$glib_cv_hasinline = xyes; then
1176     glib_inline='#define G_HAVE_INLINE 1'
1177 fi
1178 if test x$glib_cv_has__inline = xyes; then
1179     glib_inline="\$glib_inline
1180 #define G_HAVE___INLINE 1"
1181 fi
1182 if test x$glib_cv_has__inline__ = xyes; then
1183     glib_inline="\$glib_inline
1184 #define G_HAVE___INLINE__ 1"
1185 fi
1186
1187 case xyes in
1188 x$ac_cv_c_bigendian)
1189   g_byte_order=G_BIG_ENDIAN
1190   g_bs_native=BE
1191   g_bs_alien=LE
1192   ;;
1193 *)
1194   g_byte_order=G_LITTLE_ENDIAN
1195   g_bs_native=LE
1196   g_bs_alien=BE
1197   ;;
1198 esac
1199
1200 case x$enable_threads in
1201 xyes)   g_enable_threads_def="#define";;
1202 *)      g_enable_threads_def="#undef ";;
1203 esac
1204
1205 g_threads_impl_def=$g_threads_impl
1206
1207 g_mutex_has_default="$mutex_has_default"
1208 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
1209 g_mutex_contents="$glib_cv_byte_contents_gmutex"
1210 ])
1211
1212 AC_OUTPUT([
1213 glib.spec
1214 Makefile
1215 glib-config
1216 gmodule/gmoduleconf.h
1217 gmodule/Makefile
1218 gthread/Makefile
1219 docs/Makefile
1220 tests/Makefile
1221 ],[case "$CONFIG_FILES" in
1222 *glib-config*)chmod +x glib-config;;
1223 esac])