configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5
   6 # require autoconf 2.13
   7 AC_PREREQ(2.13)
   8
   9 # Process this file with autoconf to produce a configure script.
  10 AC_INIT(glist.c)
  11
  12 # Save this value here, since automake will set cflags later
  13 cflags_set=${CFLAGS+set}
  14
  15 # we rewrite this file
  16 rm -f glibconfig-sysdefs.h
  17
  18 # The following version number definitions apply to GLib and GModule
  19 # as a whole, so if changes occoured in either of them, they are both
  20 # treated with the same interface and binary age.
  21 #
  22 # Making releases:
  23 #   GLIB_MICRO_VERSION += 1;
  24 #   GLIB_INTERFACE_AGE += 1;
  25 #   GLIB_BINARY_AGE += 1;
  26 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  27 # if backwards compatibility has been broken,
  28 # set GLIB_BINARY_AGE and GLIB_INTERFACE_AGE to 0.
  29 #
  30 GLIB_MAJOR_VERSION=1
  31 GLIB_MINOR_VERSION=1
  32 GLIB_MICRO_VERSION=13
  33 GLIB_INTERFACE_AGE=0
  34 GLIB_BINARY_AGE=0
  35 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  36 AC_SUBST(GLIB_VERSION)
  37
  38 # libtool versioning
  39 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  40 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  41 LT_REVISION=$GLIB_INTERFACE_AGE
  42 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  43 AC_SUBST(LT_RELEASE)
  44 AC_SUBST(LT_CURRENT)
  45 AC_SUBST(LT_REVISION)
  46 AC_SUBST(LT_AGE)
  47
  48 VERSION=$GLIB_VERSION
  49 PACKAGE=glib
  50
  51 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  52
  53 # Specify a configuration file
  54 AM_CONFIG_HEADER(config.h)
  55
  56 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION)
  57 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION)
  58 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION)
  59 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE)
  60 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE)
  61
  62 dnl Initialize libtool
  63 AM_PROG_LIBTOOL
  64
  65 dnl Initialize maintainer mode
  66 AM_MAINTAINER_MODE
  67
  68 AC_CANONICAL_HOST
  69
  70 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=minimum]],,enable_debug=minimum)
  71 AC_ARG_ENABLE(mem_check, [  --enable-mem-check      turn on malloc/free sanity checking [default=no]],,enable_mem_check=no)
  72 AC_ARG_ENABLE(mem_profile, [  --enable-mem-profile    turn on malloc profiling atexit [default=no]],,enable_mem_profile=no)
  73 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
  74                     , enable_ansi=no)
  75 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
  76                           ([=no] will override --with-threads)],,enable_threads=yes)
  77
  78 if test "x$enable_threads" != "xyes"; then
  79   enable_threads=no
  80 fi
  81
  82 AC_MSG_CHECKING(whether to enable memory checking)
  83 if test "x$enable_mem_check" = "xyes"; then
  84   AC_DEFINE(ENABLE_MEM_CHECK, 1)
  85   AC_SUBST(ENABLE_MEM_CHECK)
  86   AC_MSG_RESULT(yes)
  87 else
  88   AC_MSG_RESULT(no)
  89 fi
  90
  91 AC_MSG_CHECKING(whether to enable memory profiling)
  92 if test "x$enable_mem_profile" = "xyes"; then
  93   AC_DEFINE(ENABLE_MEM_PROFILE, 1)
  94   AC_SUBST(ENABLE_MEM_PROFILE)
  95   AC_MSG_RESULT(yes)
  96 else
  97   AC_MSG_RESULT(no)
  98 fi
  99
 100 if test "x$enable_debug" = "xyes"; then
 101   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 102   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 103 else
 104   if test "x$enable_debug" = "xno"; then
 105     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 106   fi
 107 fi
 108
 109 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 110
 111 # Checks for programs.
 112 AC_PROG_CC
 113 AM_PROG_CC_STDC
 114 AC_PROG_INSTALL
 115
 116 changequote(,)dnl
 117 if test "x$GCC" = "xyes"; then
 118   case " $CFLAGS " in
 119   *[\ \ ]-Wall[\ \      ]*) ;;
 120   *) CFLAGS="$CFLAGS -Wall" ;;
 121   esac
 122
 123   if test "x$enable_ansi" = "xyes"; then
 124     case " $CFLAGS " in
 125     *[\ \       ]-ansi[\ \      ]*) ;;
 126     *) CFLAGS="$CFLAGS -ansi" ;;
 127     esac
 128
 129     case " $CFLAGS " in
 130     *[\ \       ]-pedantic[\ \  ]*) ;;
 131     *) CFLAGS="$CFLAGS -pedantic" ;;
 132     esac
 133   fi
 134 fi
 135 changequote([,])dnl
 136
 137 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 138 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 139 glib_save_LIBS=$LIBS
 140 LIBS="$LIBS -lm"
 141 AC_TRY_RUN([#include <math.h>
 142              int main (void) { return (log(1) != log(1.)); }],
 143      AC_MSG_RESULT(none needed),
 144      glib_save_CFLAGS=$CFLAGS
 145      CFLAGS="$CFLAGS -std1"
 146      AC_TRY_RUN([#include <math.h>
 147                  int main (void) { return (log(1) != log(1.)); }],
 148          AC_MSG_RESULT(-std1),
 149          AC_MSG_RESULT()
 150          CFLAGS=$glib_save_CFLAGS
 151          AC_MSG_WARN(
 152                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 153      )
 154 )
 155 LIBS=$glib_save_LIBS
 156
 157 dnl NeXTStep cc seems to need this
 158 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 159 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 160   AC_MSG_RESULT(none needed),
 161   glib_save_CFLAGS=$CFLAGS
 162   CFLAGS="$CFLAGS -posix"
 163   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 164     AC_MSG_RESULT(-posix),
 165     AC_MSG_RESULT()
 166     CFLAGS=$glib_save_CFLAGS
 167     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 168
 169 # Checks for header files.
 170 AC_HEADER_STDC
 171
 172 # Checks for library functions.
 173 AC_FUNC_VPRINTF
 174
 175 AC_CHECK_FUNCS(atexit on_exit)
 176
 177 AC_CHECK_SIZEOF(char)
 178 AC_CHECK_SIZEOF(short)
 179 AC_CHECK_SIZEOF(long)
 180 AC_CHECK_SIZEOF(int)
 181 AC_CHECK_SIZEOF(void *)
 182 AC_CHECK_SIZEOF(long long)
 183
 184 dnl long doubles were not used, and a portability problem
 185 dnl AC_C_LONG_DOUBLE
 186 AC_C_CONST
 187
 188 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 189 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 190 dnl actually supported.
 191 AC_MSG_CHECKING(for __inline)
 192 AC_CACHE_VAL(glib_cv_has__inline,[
 193         AC_TRY_RUN([
 194         __inline int foo () { return 0; }
 195         int main () { return foo (); }
 196         ],
 197         glib_cv_has__inline=yes
 198         ,
 199         glib_cv_has__inline=no
 200         ,)
 201 ])
 202 AC_MSG_RESULT($glib_cv_has__inline)
 203 case x$glib_cv_has__inline in
 204 xyes) AC_DEFINE(G_HAVE___INLINE)
 205 esac
 206 AC_MSG_CHECKING(for __inline__)
 207 AC_CACHE_VAL(glib_cv_has__inline__,[
 208         AC_TRY_RUN([
 209         __inline__ int foo () { return 0; }
 210         int main () { return foo (); }
 211         ],
 212         glib_cv_has__inline__=yes
 213         ,
 214         glib_cv_has__inline__=no
 215         ,)
 216 ])
 217 AC_MSG_RESULT($glib_cv_has__inline__)
 218 case x$glib_cv_has__inline__ in
 219 xyes) AC_DEFINE(G_HAVE___INLINE__)
 220 esac
 221 AC_MSG_CHECKING(for inline)
 222 AC_CACHE_VAL(glib_cv_hasinline,[
 223         AC_TRY_RUN([
 224         inline int foo () { return 0; }
 225         int main () { return foo (); }
 226         ],
 227         glib_cv_hasinline=yes
 228         ,
 229         glib_cv_hasinline=no
 230         ,)
 231 ])
 232 AC_MSG_RESULT($glib_cv_hasinline)
 233 case x$glib_cv_hasinline in
 234 xyes) AC_DEFINE(G_HAVE_INLINE)
 235 esac
 236
 237 dnl for bytesex stuff
 238 AC_C_BIGENDIAN
 239
 240 dnl header file checks
 241 AC_CHECK_HEADERS(float.h, AC_DEFINE(HAVE_FLOAT_H))
 242 AC_CHECK_HEADERS(limits.h, AC_DEFINE(HAVE_LIMITS_H))
 243 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 244 AC_CHECK_HEADERS(sys/param.h, AC_DEFINE(HAVE_SYS_PARAM_H))
 245 AC_CHECK_HEADERS(sys/poll.h, AC_DEFINE(HAVE_SYS_POLL_H))
 246 AC_CHECK_HEADERS(sys/select.h, AC_DEFINE(HAVE_SYS_SELECT_H))
 247 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 248 AC_CHECK_HEADERS(sys/times.h, AC_DEFINE(HAVE_SYS_TIMES_H))
 249 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 250 AC_CHECK_HEADERS(values.h, AC_DEFINE(HAVE_VALUES_H))
 251
 252 # Check for some functions
 253 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf strcasecmp strncasecmp poll)
 254
 255 # Check for sys_errlist
 256 AC_MSG_CHECKING(for sys_errlist)
 257 AC_TRY_LINK(, [
 258 extern char *sys_errlist[];
 259 extern int sys_nerr;
 260 sys_errlist[sys_nerr-1][0] = 0;
 261 ], glib_ok=yes, glib_ok=no)
 262 AC_MSG_RESULT($glib_ok)
 263 if test $glib_ok = no; then
 264     AC_DEFINE(NO_SYS_ERRLIST)
 265 fi
 266
 267 # Check for sys_siglist
 268 AC_MSG_CHECKING(for sys_siglist)
 269 AC_TRY_LINK(, [
 270 extern char *sys_siglist[];
 271 strlen (sys_siglist[0]);
 272 ], glib_ok=yes, glib_ok=no)
 273 AC_MSG_RESULT($glib_ok)
 274 if test $glib_ok = no; then
 275     AC_DEFINE(NO_SYS_SIGLIST)
 276 fi
 277
 278 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 279 AC_MSG_CHECKING(for sys_siglist declaration)
 280 AC_TRY_COMPILE([#include <signal.h>], [
 281 strlen (sys_siglist[0]);
 282 ], glib_ok=yes, glib_ok=no)
 283 AC_MSG_RESULT($glib_ok)
 284 if test $glib_ok = no; then
 285     AC_DEFINE(NO_SYS_SIGLIST_DECL)
 286 fi
 287
 288 # Check if <sys/select.h> needs to be included for fd_set
 289 AC_MSG_CHECKING([for fd_set])
 290 AC_TRY_COMPILE([#include <sys/types.h>],
 291         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 292 if test $gtk_ok = yes; then
 293     AC_MSG_RESULT([yes, found in sys/types.h])
 294 else
 295     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 296     if test $gtk_ok = yes; then
 297         AC_DEFINE(HAVE_SYS_SELECT_H)
 298         AC_MSG_RESULT([yes, found in sys/select.h])
 299     else
 300         AC_DEFINE(NO_FD_SET)
 301         AC_MSG_RESULT(no)
 302     fi
 303 fi
 304
 305 # These are used only in GDK (gdki18n.h)
 306 # This stuff is here only so that we can define these
 307 # things in glibconfig.h. If gtk+ started using an installed
 308 # gdkconfig.h file, then the definitions would belong there.
 309
 310 # Check for wchar.h
 311
 312 AC_MSG_CHECKING(for wchar.h)
 313 AC_TRY_CPP([#include <wchar.h>], glib_wchar_h=yes, glib_wchar_h=no)
 314 if test $glib_wchar_h = yes; then
 315    AC_DEFINE(HAVE_WCHAR_H)
 316 fi
 317 AC_MSG_RESULT($glib_wchar_h)
 318
 319 # Check for wctype.h (for iswalnum)
 320
 321 AC_MSG_CHECKING(for wctype.h)
 322 AC_TRY_CPP([#include <wctype.h>], glib_wctype_h=yes, glib_wctype_h=no)
 323 if test $glib_wctype_h = yes; then
 324    AC_DEFINE(HAVE_WCTYPE_H)
 325 fi
 326 AC_MSG_RESULT($glib_wctype_h)
 327
 328 oLIBS="$LIBS"
 329 # in Solaris 2.5, `iswalnum' is in -lw
 330 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum)])
 331
 332 # The following is necessary for Linux libc-5.4.38
 333 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 334 AC_TRY_LINK([#include <stdlib.h>],[
 335 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 336 #  ifdef HAVE_WCTYPE_H
 337 #    include <wctype.h>
 338 #  else
 339 #    ifdef HAVE_WCHAR_H
 340 #      include <wchar.h>
 341 #    endif
 342 #  endif
 343 #else
 344 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 345 #endif
 346 iswalnum((wchar_t) 0);
 347 ], glib_working_wctype=yes, glib_working_wctype=no)
 348 LIBS="$oLIBS"
 349
 350 if test $glib_working_wctype = no; then
 351    AC_DEFINE(HAVE_BROKEN_WCTYPE)
 352 fi
 353 AC_MSG_RESULT($glib_working_wctype)
 354
 355
 356 dnl **********************
 357 dnl *** va_copy checks ***
 358 dnl **********************
 359 dnl we currently check for all three va_copy possibilities, so we get
 360 dnl all results in config.log for bug reports.
 361 AC_MSG_CHECKING(for an implementation of va_copy())
 362 AC_CACHE_VAL(glib_cv_va_copy,[
 363         AC_TRY_RUN([
 364         #include <stdarg.h>
 365         void f (int i, ...) {
 366         va_list args1, args2;
 367         va_start (args1, i);
 368         va_copy (args2, args1);
 369         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 370           exit (1);
 371         va_end (args1); va_end (args2);
 372         }
 373         int main() {
 374           f (0, 42);
 375           return 0;
 376         }],
 377         glib_cv_va_copy=yes
 378         ,
 379         glib_cv_va_copy=no
 380         ,)
 381 ])
 382 AC_MSG_RESULT($glib_cv_va_copy)
 383 AC_MSG_CHECKING(for an implementation of __va_copy())
 384 AC_CACHE_VAL(glib_cv___va_copy,[
 385         AC_TRY_RUN([
 386         #include <stdarg.h>
 387         void f (int i, ...) {
 388         va_list args1, args2;
 389         va_start (args1, i);
 390         __va_copy (args2, args1);
 391         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 392           exit (1);
 393         va_end (args1); va_end (args2);
 394         }
 395         int main() {
 396           f (0, 42);
 397           return 0;
 398         }],
 399         glib_cv___va_copy=yes
 400         ,
 401         glib_cv___va_copy=no
 402         ,)
 403 ])
 404 AC_MSG_RESULT($glib_cv___va_copy)
 405 AC_MSG_CHECKING(whether va_lists can be copied by value)
 406 AC_CACHE_VAL(glib_cv_va_val_copy,[
 407         AC_TRY_RUN([
 408         #include <stdarg.h>
 409         void f (int i, ...) {
 410         va_list args1, args2;
 411         va_start (args1, i);
 412         args2 = args1;
 413         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 414           exit (1);
 415         va_end (args1); va_end (args2);
 416         }
 417         int main() {
 418           f (0, 42);
 419           return 0;
 420         }],
 421         glib_cv_va_val_copy=yes
 422         ,
 423         glib_cv_va_val_copy=no
 424         ,)
 425 ])
 426 if test "x$glib_cv_va_copy" = "xyes"; then
 427   AC_DEFINE(G_VA_COPY, va_copy)
 428 else if test "x$glib_cv___va_copy" = "xyes"; then
 429   AC_DEFINE(G_VA_COPY, __va_copy)
 430 fi
 431 fi
 432 if test "x$glib_cv_va_val_copy" = "xno"; then
 433   AC_DEFINE(G_VA_COPY_AS_ARRAY)
 434 fi
 435 AC_MSG_RESULT($glib_cv_va_val_copy)
 436
 437
 438 dnl ***********************
 439 dnl *** g_module checks ***
 440 dnl ***********************
 441 G_MODULE_LIBS=
 442 G_MODULE_LDFLAGS=
 443 G_MODULE_IMPL=
 444 G_MODULE_NEED_USCORE=0
 445 G_MODULE_HAVE_DLERROR=0
 446 dnl *** dlopen() in system libraries
 447 if test -z "$G_MODULE_IMPL"; then
 448         AC_CHECK_FUNC(dlopen,
 449                 G_MODULE_IMPL=G_MODULE_IMPL_DL
 450         ,)
 451 fi
 452 dnl *** dlopen() in libdl
 453 if test -z "$G_MODULE_IMPL"; then
 454         AC_CHECK_LIB(dl, dlopen,
 455                 G_MODULE_LIBS=-ldl
 456                 G_MODULE_IMPL=G_MODULE_IMPL_DL
 457         ,)
 458 fi
 459 dnl *** shl_load() in libdld (HP-UX)
 460 if test -z "$G_MODULE_IMPL"; then
 461         AC_MSG_CHECKING(how to export all symbols)
 462         SAVED_LDFLAGS=$LDFLAGS
 463         LDFLAGS="$LDFLAGS -Wl,-E"
 464         AC_TRY_LINK(,[ return 0; ],
 465                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 466                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 467                 AC_TRY_LINK(,[ return 0; ],
 468                         G_MODULE_LDFLAGS="-bexpall",
 469                         G_MODULE_LDFLAGS="none"
 470                 )
 471         ])
 472         LDFLAGS=$SAVED_LDFLAGS
 473         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 474         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 475                 G_MODULE_LDFLAGS=
 476         fi
 477         AC_CHECK_LIB(dld, shl_load,
 478                 G_MODULE_LIBS=-ldld
 479                 G_MODULE_IMPL=G_MODULE_IMPL_DLD
 480         ,)
 481 fi
 482 dnl *** additional checks for G_MODULE_IMPL_DL
 483 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 484         case "$host_os" in
 485           linux*)
 486             G_MODULE_LDFLAGS='-rdynamic'
 487             ;;
 488         esac
 489         LIBS_orig="$LIBS"
 490         LDFLAGS_orig="$LDFLAGS"
 491         LIBS="$LIBS $G_MODULE_LIBS"
 492         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 493 dnl *** check whether we need preceeding underscores
 494         AC_MSG_CHECKING(for preceeding underscore in symbols)
 495         AC_CACHE_VAL(glib_cv_uscore,[
 496                 AC_TRY_RUN([
 497                 #include <dlfcn.h>
 498                 int glib_underscore_test (void) { return 42; }
 499                 int main() {
 500                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 501                   handle = dlopen ((void*)0, 0);
 502                   if (handle) {
 503                     f1 = dlsym (handle, "glib_underscore_test");
 504                     f2 = dlsym (handle, "_glib_underscore_test");
 505                   } return (!f2 || f1);
 506                 }],
 507                         glib_cv_uscore=yes,
 508                         glib_cv_uscore=no,
 509                 )
 510                 rm -f plugin.c plugin.o plugin.lo
 511         ])
 512         AC_MSG_RESULT($glib_cv_uscore)
 513         if test "x$glib_cv_uscore" = "xyes"; then
 514                 G_MODULE_NEED_USCORE=1
 515         else
 516                 G_MODULE_NEED_USCORE=0
 517         fi
 518
 519         LDFLAGS="$LDFLAGS_orig"
 520 dnl *** check for having dlerror()
 521         AC_CHECK_FUNC(dlerror,
 522                 G_MODULE_HAVE_DLERROR=1,
 523                 G_MODULE_HAVE_DLERROR=0)
 524         LIBS="$LIBS_orig"
 525 fi
 526 dnl *** done, have e got an implementation?
 527 if test -z "$G_MODULE_IMPL"; then
 528         G_MODULE_IMPL=0
 529 fi
 530 AC_SUBST(G_MODULE_IMPL)
 531 AC_SUBST(G_MODULE_LIBS)
 532 AC_SUBST(G_MODULE_LDFLAGS)
 533 AC_SUBST(G_MODULE_HAVE_DLERROR)
 534 AC_SUBST(G_MODULE_NEED_USCORE)
 535 AC_SUBST(GLIB_DEBUG_FLAGS)
 536
 537
 538 dnl ***********************
 539 dnl *** g_thread checks ***
 540 dnl ***********************
 541
 542 AC_ARG_WITH(threads, [  --with-threads=[none/posix/solaris/nspr] specify a thread implementation to use],
 543         if test "x$with_threads" = x; then
 544                 want_threads=yes
 545         else
 546                 want_threads=$with_threads
 547         fi,
 548         want_threads=yes)
 549 if test "x$enable_threads" = "xno"; then
 550         want_threads=no
 551 fi
 552 if test "x$want_threads" = "xnone"; then
 553         want_threads=no
 554 fi
 555
 556 dnl error and warning message
 557 dnl *************************
 558
 559 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
 560                 computer. glib will not be thread safe on your computer."
 561
 562 FLAG_DOES_NOT_WORK="I can't find the MACRO, that enables thread safety on your
 563                 platform (normaly it's "_REENTRANT"). I'll not use any flag on
 564                 compilation now, but then your programs might not work.
 565                 Please provide information on how it is done on your system."
 566
 567 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
 568                 "
 569
 570 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
 571                 provide informationon your thread implementation."
 572
 573 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
 574                 functions will not be MT-safe during their first call because
 575                 there is no 'getpwuid_r' on your system."
 576
 577 dnl determination of thread implementation
 578 dnl ***************************************
 579
 580 have_threads=none
 581 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
 582         case $host in
 583                 *-*-solaris*)
 584                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
 585                 ;;
 586         esac
 587 fi
 588 if test "x$want_threads" = xyes || test "x$want_threads" = xposix; then
 589         if test "x$have_threads" = xnone; then
 590                 AC_CHECK_LIB(pthread, pthread_attr_init, have_threads=posix)
 591         fi
 592         if test "x$have_threads" = xnone; then
 593                 AC_CHECK_LIB(pthreads, pthread_attr_init, have_threads=posix)
 594         fi
 595         if test "x$have_threads" = xnone; then
 596                 AC_CHECK_LIB(c_r, pthread_attr_init, have_threads=posix)
 597         fi
 598         if test "x$have_threads" = xnone; then
 599                 AC_CHECK_FUNC(pthread_attr_init, have_threads=posix)
 600         fi
 601         dnl ********** DG/UX ************
 602         if test "x$have_threads" = xnone; then
 603                 AC_CHECK_LIB(thread, __d10_pthread_attr_init,
 604                         have_threads=posix)
 605         fi
 606 fi
 607 if test "x$want_threads" = xyes || test "x$want_threads" = xnspr; then
 608         if test "x$have_threads" = xnone; then
 609                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar, have_threads=nspr)
 610         fi
 611 fi
 612
 613 AC_MSG_CHECKING(for thread implementation)
 614
 615 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
 616         AC_MSG_RESULT(none available)
 617         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
 618 else
 619         AC_MSG_RESULT($have_threads)
 620 fi
 621
 622
 623 dnl determination of G_THREAD_LIBS
 624 dnl ******************************
 625
 626 G_THREAD_LIBS=
 627 G_THREAD_CFLAGS=
 628
 629 mutex_has_default=no
 630 case $have_threads in
 631         posix)
 632                 G_THREAD_LIBS=error
 633                 AC_CHECK_LIB(pthread, pthread_attr_init,
 634                              G_THREAD_LIBS="-lpthread")
 635                 if test "x$G_THREAD_LIBS" = xerror; then
 636                         AC_CHECK_LIB(pthreads, pthread_attr_init,
 637                                 G_THREAD_LIBS="-lpthreads")
 638                 fi
 639                 if test "x$G_THREAD_LIBS" = xerror; then
 640                         AC_CHECK_LIB(c_r, pthread_attr_init,
 641                                 G_THREAD_LIBS="-lc_r")
 642                 fi
 643                 if test "x$G_THREAD_LIBS" = xerror; then
 644                         AC_CHECK_FUNC(pthread_attr_init, G_THREAD_LIBS="")
 645                 fi
 646                 dnl ********** DG/UX ************
 647                 if test "x$G_THREAD_LIBS" = xerror; then
 648                         AC_CHECK_LIB(thread, __d10_pthread_attr_init,
 649                                 G_THREAD_LIBS="-lthread"
 650                                 G_THREAD_CFLAGS="-D_POSIX4A_DRAFT10_SOURCE")
 651                 fi
 652                 mutex_has_default=yes
 653                 mutex_default_type='pthread_mutex_t'
 654                 mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
 655                 mutex_header_file='pthread.h'
 656                 g_threads_impl="POSIX"
 657                 ;;
 658         solaris)
 659                 G_THREAD_LIBS=error
 660                 AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
 661                 mutex_has_default=yes
 662                 mutex_default_type='mutex_t'
 663                 mutex_default_init="DEFAULTMUTEX"
 664                 mutex_header_file='thread.h'
 665                 g_threads_impl="SOLARIS"
 666                 ;;
 667         nspr)
 668                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar,
 669                              G_THREAD_LIBS="-lnspr21")
 670                 g_threads_impl="NSPR"
 671                 ;;
 672         none)
 673                 g_threads_impl="NONE"
 674                 ;;
 675         *)
 676                 g_threads_impl="NONE"
 677                 G_THREAD_LIBS=error
 678                 ;;
 679 esac
 680
 681 if test "x$G_THREAD_LIBS" = xerror; then
 682         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 683 fi
 684
 685 AC_MSG_CHECKING(necessary linker options)
 686 AC_MSG_RESULT($G_THREAD_LIBS)
 687
 688 dnl check for mt safe function variants
 689 dnl ***********************************
 690
 691 if test x"$have_threads" != xnone; then
 692         glib_save_LIBS="$LIBS"
 693         # we are not doing the following for now, as this might require glib
 694         # to always be linked with the thread libs on some platforms.
 695         # LIBS="$LIBS $G_THREAD_LIBS"
 696         AC_CHECK_FUNCS(localtime_r rand_r)
 697         if test "$ac_cv_header_pwd_h" = "yes"; then
 698                 AC_CHECK_FUNCS(getpwuid_r)
 699                 if test "$ac_cv_func_getpwuid_r" = "yes"; then
 700                         AC_MSG_CHECKING(whether getpwuid_r is posix like)
 701                         # getpwuid_r(0, NULL, NULL, 0) is the signature on
 702                         # solaris, if that is not found, the prog below won't
 703                         # compile, then the posix signature is assumed as
 704                         # the default.
 705                         AC_TRY_COMPILE([#include <pwd.h>],
 706                                 [getpwuid_r(0, NULL, NULL, 0);],
 707                                 [AC_MSG_RESULT(no)],
 708                                 [AC_MSG_RESULT(yes)
 709                                 AC_DEFINE(HAVE_GETPWUID_R_POSIX)])
 710                 fi
 711         fi
 712         LIBS="$glib_save_LIBS"
 713 fi
 714
 715 if test "x$enable_threads" = "xyes"; then
 716         if test "$ac_cv_func_getpwuid_r" != "yes"; then
 717                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
 718         fi
 719 fi
 720
 721 dnl determination of G_THREAD_CFLAGS
 722 dnl ********************************
 723
 724 if test x"$have_threads" != xnone; then
 725 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_REENTRANT" # good default guess
 726
 727     case $host in
 728         *-aix*)
 729                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 730                 if test x"$GCC" = xyes; then
 731                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
 732                 fi
 733                 ;;
 734         *-freebsd2.2*)
 735                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 736
 737                 # FreeBSD 2.2.x shiped with gcc 2.7.2.x, which doesn't support
 738                 # -mthreads flag.
 739                 ;;
 740     esac
 741
 742     # if we are not finding the ctime_r function, then we probably are
 743     # not using the proper multithread flag
 744     old_CPPFLAGS=$CPPFLAGS
 745     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
 746     AC_EGREP_HEADER([[^a-zA-Z_]ctime_r[^a-zA-Z_]], time.h, ,
 747     G_THREAD_CFLAGS=
 748     AC_MSG_WARN($FLAG_DOES_NOT_WORK))
 749     CPPFLAGS=$old_CPPFLAGS
 750
 751     AC_MSG_CHECKING(necessary compiler options)
 752
 753     AC_MSG_RESULT($G_THREAD_CFLAGS)
 754 else
 755     G_THREAD_CFLAGS=
 756 fi
 757
 758 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c")
 759 AC_SUBST(G_THREAD_CFLAGS)
 760 AC_SUBST(G_THREAD_LIBS)
 761
 762 CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 763
 764 dnl **********************************************
 765 dnl *** GDefaultMutex setup and initialization ***
 766 dnl **********************************************
 767 dnl
 768 dnl if mutex_has_default = yes, we also got
 769 dnl mutex_default_type, mutex_default_init and mutex_header_file
 770 GLIB_IF_VAR_EQ(mutex_has_default, yes,
 771         GLIB_SIZEOF([#include <$mutex_header_file>],
 772                     $mutex_default_type,
 773                     gmutex,
 774                     )
 775         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
 776                            $mutex_default_type,
 777                            gmutex,
 778                            $glib_cv_sizeof_gmutex,
 779                            $mutex_default_init)
 780         ,
 781 )
 782
 783
 784 dnl ****************************************
 785 dnl *** GLib POLL* compatibility defines ***
 786 dnl ****************************************
 787 GLIB_SYSDEFS(
 788 [#include <sys/types.h>
 789 #include <sys/poll.h>],
 790         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
 791         glibconfig-sysdefs.h,
 792         =)
 793
 794
 795 dnl ******************************
 796 dnl *** output the whole stuff ***
 797 dnl ******************************
 798
 799 AC_OUTPUT_COMMANDS([
 800
 801 ## Generate `glibconfig.h' in two cases
 802 ## 1. `config.status' is run either explicitly, or via configure.
 803 ##     Esp. not when it is run in `Makefile' to generate makefiles and
 804 ##     config.h
 805 ## 2. CONFIG_OTHER is set explicitly
 806 ##
 807 ## Case 1 is difficult.  We know that `automake' sets one of
 808 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
 809 ## only when AM_CONFIG_HEADER is set, however.
 810
 811 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
 812   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
 813   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
 814 fi
 815 case "$CONFIG_OTHER" in
 816 *glibconfig.h*)
 817         echo creating glibconfig.h
 818         outfile=glibconfig.h-tmp
 819         cat > $outfile <<\_______EOF
 820 /* glibconfig.h
 821  *
 822  * This is a generated file.  Please modify `configure.in'
 823  */
 824
 825 #ifndef GLIBCONFIG_H
 826 #define GLIBCONFIG_H
 827
 828 #ifdef __cplusplus
 829 extern "C" {
 830 #endif /* __cplusplus */
 831
 832 _______EOF
 833
 834         if test x$glib_limits_h = xyes; then
 835           echo '#include <limits.h>' >> $outfile
 836         fi
 837         if test x$glib_float_h = xyes; then
 838           echo '#include <float.h>' >> $outfile
 839         fi
 840         if test x$glib_values_h = xyes; then
 841           echo '#include <values.h>' >> $outfile
 842         fi
 843         if test x$g_mutex_header_file != x; then
 844           echo '#include <'"$g_mutex_header_file"'>' >> $outfile
 845         fi
 846         if test x$glib_sys_poll_h = xyes; then
 847           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
 848         fi
 849
 850         cat >> $outfile <<_______EOF
 851
 852 #define G_MINFLOAT      $glib_mf
 853 #define G_MAXFLOAT      $glib_Mf
 854 #define G_MINDOUBLE     $glib_md
 855 #define G_MAXDOUBLE     $glib_Md
 856 #define G_MINSHORT      $glib_ms
 857 #define G_MAXSHORT      $glib_Ms
 858 #define G_MININT        $glib_mi
 859 #define G_MAXINT        $glib_Mi
 860 #define G_MINLONG       $glib_ml
 861 #define G_MAXLONG       $glib_Ml
 862
 863 _______EOF
 864
 865
 866         ### this should always be true in a modern C/C++ compiler
 867         cat >>$outfile <<_______EOF
 868 typedef signed char gint8;
 869 typedef unsigned char guint8;
 870 _______EOF
 871
 872
 873         if test -n "$gint16"; then
 874           cat >>$outfile <<_______EOF
 875 typedef signed $gint16 gint16;
 876 typedef unsigned $gint16 guint16;
 877 _______EOF
 878         fi
 879
 880
 881         if test -n "$gint32"; then
 882           cat >>$outfile <<_______EOF
 883 typedef signed $gint32 gint32;
 884 typedef unsigned $gint32 guint32;
 885 _______EOF
 886         fi
 887
 888
 889         if test -n "$gint64"; then
 890           cat >>$outfile <<_______EOF
 891 ${glib_warning_guard}#define G_HAVE_GINT64 1
 892
 893 ${glib_extension}typedef signed $gint64 gint64;
 894 ${glib_extension}typedef unsigned $gint64 guint64;
 895
 896 #define G_GINT64_CONSTANT(val)  $gint64_constant
 897 _______EOF
 898         fi
 899
 900
 901         if test -z "$glib_unknown_void_p"; then
 902           cat >>$outfile <<_______EOF
 903
 904 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
 905 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
 906
 907 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
 908 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
 909 _______EOF
 910         else
 911           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
 912         fi
 913
 914
 915
 916         cat >>$outfile <<_______EOF
 917 $glib_atexit
 918 $glib_memmove
 919 $glib_defines
 920
 921 $glib_vacopy
 922
 923 #ifdef  __cplusplus
 924 #define G_HAVE_INLINE   1
 925 #else   /* !__cplusplus */
 926 $glib_inline
 927 #endif  /* !__cplusplus */
 928 _______EOF
 929
 930         echo >>$outfile
 931         if test x$g_mutex_has_default = xyes; then
 932                 cat >>$outfile <<_______EOF
 933 $g_enable_threads_def G_THREADS_ENABLED
 934 #define G_THREADS_IMPL_$g_threads_impl_def
 935 typedef struct _GStaticMutex GStaticMutex;
 936 struct _GStaticMutex
 937 {
 938   struct _GMutex *runtime_mutex;
 939   union {
 940     char   pad[$g_mutex_sizeof];
 941     double dummy_double;
 942     void  *dummy_pointer;
 943     long   dummy_long;
 944   } aligned_pad_u;
 945 };
 946 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
 947 #define g_static_mutex_get_mutex(mutex) \
 948   (g_thread_use_default_impl ? ((GMutex*) &(mutex).aligned_pad_u) : \
 949    g_static_mutex_get_mutex_impl (&(mutex).runtime_mutex))
 950 _______EOF
 951         else
 952                 cat >>$outfile <<_______EOF
 953 $g_enable_threads_def G_THREADS_ENABLED
 954 #define $g_threads_impl_def
 955 typedef struct _GMutex* GStaticMutex;
 956 #define G_STATIC_MUTEX_INIT NULL
 957 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (&(mutex)))
 958 _______EOF
 959         fi
 960
 961         echo >>$outfile
 962         g_bit_sizes="16 32"
 963         if test -n "$gint64"; then
 964           g_bit_sizes="$g_bit_sizes 64"
 965         fi
 966         for bits in $g_bit_sizes; do
 967           cat >>$outfile <<_______EOF
 968 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
 969 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
 970 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
 971 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
 972 _______EOF
 973         done
 974
 975         cat >>$outfile <<_______EOF
 976 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
 977 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
 978 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
 979 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
 980 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
 981 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
 982 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
 983 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
 984 #define G_BYTE_ORDER $g_byte_order
 985
 986 _______EOF
 987
 988         if test -r glibconfig-sysdefs.h; then
 989           cat glibconfig-sysdefs.h >>$outfile
 990         fi
 991
 992
 993         cat >>$outfile <<_______EOF
 994
 995 $glib_wc
 996
 997
 998 #ifdef __cplusplus
 999 }
1000 #endif /* __cplusplus */
1001
1002 #endif /* GLIBCONFIG_H */
1003 _______EOF
1004
1005
1006         if cmp -s $outfile glibconfig.h; then
1007           echo glibconfig.h is unchanged
1008           rm -f $outfile
1009         else
1010           mv $outfile glibconfig.h
1011         fi ;;
1012 esac
1013 ],[
1014
1015 # Note that if two cases are the same, case goes with the first one.
1016 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
1017 # on variable expansion in case labels.  Look at the generated config.status
1018 # for a hint.
1019
1020 case xyes in
1021 x$ac_cv_header_float_h)
1022   glib_float_h=yes
1023   glib_mf=FLT_MIN glib_Mf=FLT_MAX
1024   glib_md=DBL_MIN glib_Md=DBL_MAX
1025   ;;
1026 x$ac_cv_header_values_h)
1027   glib_values_h=yes
1028   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
1029   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
1030   ;;
1031 esac
1032
1033 case xyes in
1034 x$ac_cv_header_limits_h)
1035   glib_limits_h=yes
1036   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX
1037   glib_mi=INT_MIN  glib_Mi=INT_MAX
1038   glib_ml=LONG_MIN glib_Ml=LONG_MAX
1039   ;;
1040 x$ac_cv_header_values_h)
1041   glib_values_h=yes
1042   glib_ms=MINSHORT glib_Ms=MAXSHORT
1043   glib_mi=MININT   glib_Mi=MAXINT
1044   glib_ml=MINLONG  glib_Ml=MAXLONG
1045   ;;
1046 esac
1047
1048 if test x$ac_cv_header_sys_poll_h = xyes ; then
1049   glib_sys_poll_h=yes
1050 fi
1051
1052 case 2 in
1053 $ac_cv_sizeof_short)            gint16=short;;
1054 $ac_cv_sizeof_int)              gint16=int;;
1055 esac
1056 case 4 in
1057 $ac_cv_sizeof_short)            gint32=short;;
1058 $ac_cv_sizeof_int)              gint32=int;;
1059 $ac_cv_sizeof_long)             gint32=long;;
1060 esac
1061 case 8 in
1062 $ac_cv_sizeof_int)
1063   gint64=int
1064   glib_extension=
1065   glib_warning_guard=
1066   gint64_constant='(val)'
1067   ;;
1068 $ac_cv_sizeof_long)
1069   gint64=long
1070   glib_extension=
1071   glib_warning_guard=
1072   gint64_constant='(val##L)'
1073   ;;
1074 $ac_cv_sizeof_long_long)
1075   gint64='long long'
1076   glib_extension='G_GNUC_EXTENSION '
1077   glib_warning_guard="
1078 #if defined (__GNUC__) && __GNUC__ >= 2 && __GNUC_MINOR__ >= 8
1079 #  define G_GNUC_EXTENSION __extension__
1080 #else
1081 #  define G_GNUC_EXTENSION
1082 #endif
1083
1084 "
1085   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1086   ;;
1087 esac
1088
1089 gintbits=`expr $ac_cv_sizeof_int \* 8`
1090 glongbits=`expr $ac_cv_sizeof_long \* 8`
1091
1092
1093 case $ac_cv_sizeof_void_p in
1094 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
1095 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
1096 *)                      glib_unknown_void_p=yes ;;
1097 esac
1098
1099
1100 case xyes in
1101 x$ac_cv_func_atexit)
1102   glib_atexit="
1103 #ifdef NeXT /* @#%@! NeXTStep */
1104 # define g_ATEXIT(proc) (!atexit (proc))
1105 #else
1106 # define g_ATEXIT(proc) (atexit (proc))
1107 #endif"
1108   ;;
1109 x$ac_cv_func_on_exit)
1110   glib_atexit="
1111 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
1112   ;;
1113 esac
1114
1115 case xyes in
1116 x$ac_cv_func_memmove)
1117   glib_memmove='
1118 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
1119   ;;
1120 *)
1121   glib_memmove="
1122 /* We make the assumption that if memmove isn't available, then
1123  * bcopy will do the job. This isn't safe everywhere. (bcopy can't
1124  * necessarily handle overlapping copies) */
1125 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
1126   ;;
1127 esac
1128
1129 glib_defines="
1130 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
1131 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
1132 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
1133 "
1134
1135 case xyes in
1136 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
1137 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
1138 *)                      glib_vacopy=''
1139 esac
1140
1141 if test x$glib_cv_va_val_copy = xno; then
1142   glib_vacopy="\$glib_vacopy
1143 #define G_VA_COPY_AS_ARRAY 1"
1144 fi
1145
1146 if test x$glib_cv_hasinline = xyes; then
1147     glib_inline='#define G_HAVE_INLINE 1'
1148 fi
1149 if test x$glib_cv_has__inline = xyes; then
1150     glib_inline="\$glib_inline
1151 #define G_HAVE___INLINE 1"
1152 fi
1153 if test x$glib_cv_has__inline__ = xyes; then
1154     glib_inline="\$glib_inline
1155 #define G_HAVE___INLINE__ 1"
1156 fi
1157
1158 case xyes in
1159 x$ac_cv_c_bigendian)
1160   g_byte_order=G_BIG_ENDIAN
1161   g_bs_native=BE
1162   g_bs_alien=LE
1163   ;;
1164 *)
1165   g_byte_order=G_LITTLE_ENDIAN
1166   g_bs_native=LE
1167   g_bs_alien=BE
1168   ;;
1169 esac
1170
1171 if test x$glib_wchar_h = xyes; then
1172   glib_wc='
1173 #define G_HAVE_WCHAR_H 1'
1174 fi
1175 if test x$glib_wctype_h = xyes; then
1176   glib_wc="\$glib_wc
1177 #define G_HAVE_WCTYPE_H 1"
1178 fi
1179 if test x$glib_working_wctype = xno; then
1180   glib_wc="\$glib_wc
1181 #define G_HAVE_BROKEN_WCTYPE 1"
1182 fi
1183
1184 case x$enable_threads in
1185 xyes)   g_enable_threads_def="#define";;
1186 *)      g_enable_threads_def="#undef ";;
1187 esac
1188
1189 g_threads_impl_def=$g_threads_impl
1190
1191 g_mutex_has_default="$mutex_has_default"
1192 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
1193 g_mutex_contents="$glib_cv_byte_contents_gmutex"
1194 ])
1195
1196 AC_OUTPUT([
1197 Makefile
1198 glib-config
1199 gmodule/gmoduleconf.h
1200 gmodule/Makefile
1201 gthread/Makefile
1202 docs/Makefile
1203 tests/Makefile
1204 ],[case "$CONFIG_FILES" in
1205 *glib-config*)chmod +x glib-config;;
1206 esac])