configure.in

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 dnl ------------------------------------------------
   4 dnl Initialization and Versioning
   5 dnl ------------------------------------------------
   6
   7 AC_INIT(lib/mdct.c)
   8
   9 AC_CANONICAL_HOST
  10 AC_CANONICAL_TARGET
  11
  12 AM_CONFIG_HEADER([config.h])
  13
  14 AM_INIT_AUTOMAKE(libvorbis,1.1.3svn)
  15 AM_MAINTAINER_MODE
  16
  17 dnl Library versioning
  18
  19 V_LIB_CURRENT=3
  20 V_LIB_REVISION=1
  21 V_LIB_AGE=3
  22 VF_LIB_CURRENT=4
  23 VF_LIB_REVISION=1
  24 VF_LIB_AGE=1
  25 VE_LIB_CURRENT=2
  26 VE_LIB_REVISION=2
  27 VE_LIB_AGE=0
  28 AC_SUBST(V_LIB_CURRENT)
  29 AC_SUBST(V_LIB_REVISION)
  30 AC_SUBST(V_LIB_AGE)
  31 AC_SUBST(VF_LIB_CURRENT)
  32 AC_SUBST(VF_LIB_REVISION)
  33 AC_SUBST(VF_LIB_AGE)
  34 AC_SUBST(VE_LIB_CURRENT)
  35 AC_SUBST(VE_LIB_REVISION)
  36 AC_SUBST(VE_LIB_AGE)
  37
  38 dnl --------------------------------------------------
  39 dnl Check for programs
  40 dnl --------------------------------------------------
  41
  42 dnl save $CFLAGS since AC_PROG_CC likes to insert "-g -O2"
  43 dnl if $CFLAGS is blank
  44 cflags_save="$CFLAGS"
  45 AC_PROG_CC
  46 AC_PROG_CPP
  47 CFLAGS="$cflags_save"
  48
  49 AM_PROG_LIBTOOL
  50
  51 dnl docbook xml transform and processing tools
  52 AC_ARG_ENABLE(docs,
  53   [  --enable-docs           build the documentation],
  54   [case "${enableval}" in
  55     yes) build_docs=true;;
  56     no)  build_docs=false;;
  57     *)   AC_MSG_ERROR(unknown value ${enableval} for --enable-docs);;
  58   esac],[build_docs=false])
  59
  60 dnl ideally we'd look for other tools and support them
  61 if test x$build_docs = xtrue; then
  62   AC_CHECK_PROGS([XSLTPROC], xsltproc, [/bin/false])
  63   AC_CHECK_PROGS([PDFXMLTEX], pdfxmltex, [/bin/false])
  64   if test "x$XSLTPROC" = "x/bin/false" || test "x$PDFXMLTEX" = "x/bin/false"; then
  65     build_docs=false
  66     AC_MSG_WARN([Documentation will not be built!])
  67   fi
  68 fi
  69
  70 AM_CONDITIONAL(BUILD_DOCS, [test x$build_docs = xtrue])
  71
  72 dnl --------------------------------------------------
  73 dnl Set build flags based on environment
  74 dnl --------------------------------------------------
  75
  76 dnl Set some target options
  77
  78 cflags_save="$CFLAGS"
  79 if test -z "$GCC"; then
  80         case $host in
  81         *-*-irix*)
  82                 dnl If we're on IRIX, we wanna use cc even if gcc
  83                 dnl is there (unless the user has overriden us)...
  84                 if test -z "$CC"; then
  85                         CC=cc
  86                 fi
  87                 DEBUG="-g -signed"
  88                 CFLAGS="-O2 -w -signed"
  89                 PROFILE="-p -g3 -O2 -signed" ;;
  90         sparc-sun-solaris*)
  91                 DEBUG="-v -g"
  92                 CFLAGS="-xO4 -fast -w -fsimple -native -xcg92"
  93                 PROFILE="-v -xpg -g -xO4 -fast -native -fsimple -xcg92 -Dsuncc" ;;
  94         *)
  95                 DEBUG="-g"
  96                 CFLAGS="-O"
  97                 PROFILE="-g -p" ;;
  98         esac
  99 else
 100
 101         AC_MSG_CHECKING([GCC version])
 102         GCC_VERSION=`$CC -dumpversion`
 103         AC_MSG_RESULT([$GCC_VERSION])
 104         case $host in
 105         *86-*-linux*)
 106                 DEBUG="-g -Wall -W -D_REENTRANT -D__NO_MATH_INLINES -fsigned-char"
 107                 CFLAGS="-O20 -ffast-math -mno-ieee-fp -D_REENTRANT -fsigned-char"
 108 #               PROFILE="-Wall -W -pg -g -O20 -ffast-math -D_REENTRANT -fsigned-char -fno-inline -static"
 109                 PROFILE="-Wall -W -pg -g -O20 -ffast-math -mno-ieee-fp -D_REENTRANT -fsigned-char -fno-inline"
 110
 111                 # glibc < 2.1.3 has a serious FP bug in the math inline header
 112                 # that will cripple Vorbis.  Look to see if the magic FP stack
 113                 # clobber is missing in the mathinline header, thus indicating
 114                 # the buggy version
 115
 116                 AC_EGREP_CPP(log10.*fldlg2.*fxch,[
 117                                 #define __LIBC_INTERNAL_MATH_INLINES 1
 118                                 #define __OPTIMIZE__
 119                                 #include <math.h>
 120                                 ],bad=maybe,bad=no)
 121                 if test ${bad} = "maybe" ;then
 122                       AC_EGREP_CPP(log10.*fldlg2.*fxch.*st\([[0123456789]]*\),
 123                                         [
 124                                         #define __LIBC_INTERNAL_MATH_INLINES 1
 125                                         #define __OPTIMIZE__
 126                                         #include <math.h>
 127                                         ],bad=no,bad=yes)
 128                 fi
 129                 if test ${bad} = "yes" ;then
 130  AC_MSG_WARN([                                                        ])
 131  AC_MSG_WARN([********************************************************])
 132  AC_MSG_WARN([* The glibc headers on this machine have a serious bug *])
 133  AC_MSG_WARN([* in /usr/include/bits/mathinline.h  This bug affects  *])
 134  AC_MSG_WARN([* all floating point code, not just Ogg, built on this *])
 135  AC_MSG_WARN([* machine.  Upgrading to glibc 2.1.3 is strongly urged *])
 136  AC_MSG_WARN([* to correct the problem.  Note that upgrading glibc   *])
 137  AC_MSG_WARN([* will not fix any previously built programs; this is  *])
 138  AC_MSG_WARN([* a compile-time time bug.                             *])
 139  AC_MSG_WARN([* To work around the problem for this build of Ogg,    *])
 140  AC_MSG_WARN([* autoconf is disabling all math inlining.  This will  *])
 141  AC_MSG_WARN([* hurt Ogg performace but is necessary for an Ogg that *])
 142  AC_MSG_WARN([* will actually work.  Once glibc is upgraded, rerun   *])
 143  AC_MSG_WARN([* configure and make to build with inlining.           *])
 144  AC_MSG_WARN([********************************************************])
 145  AC_MSG_WARN([                                                        ])
 146
 147                 CFLAGS=${OPT}" -D__NO_MATH_INLINES"
 148                 PROFILE=${PROFILE}" -D__NO_MATH_INLINES"
 149                 fi;;
 150         powerpc-*-linux*)
 151                 DEBUG="-g -Wall -W -D_REENTRANT -D__NO_MATH_INLINES"
 152                 CFLAGS="-O3 -ffast-math -mfused-madd -mcpu=750 -D_REENTRANT"
 153                 PROFILE="-pg -g -O3 -ffast-math -mfused-madd -mcpu=750 -D_REENTRANT";;
 154         *-*-linux*)
 155                 DEBUG="-g -Wall -W -D_REENTRANT -D__NO_MATH_INLINES -fsigned-char"
 156                 CFLAGS="-O20 -ffast-math -D_REENTRANT -fsigned-char"
 157                 PROFILE="-pg -g -O20 -ffast-math -D_REENTRANT -fsigned-char";;
 158         sparc-sun-*)
 159                 DEBUG="-g -Wall -W -D__NO_MATH_INLINES -fsigned-char -mv8"
 160                 CFLAGS="-O20 -ffast-math -D__NO_MATH_INLINES -fsigned-char -mv8"
 161                 PROFILE="-pg -g -O20 -D__NO_MATH_INLINES -fsigned-char -mv8" ;;
 162         *-*-darwin*)
 163                 DEBUG="-DDARWIN -fno-common -force_cpusubtype_ALL -Wall -g -O0 -fsigned-char"
 164                 CFLAGS="-DDARWIN -fno-common -force_cpusubtype_ALL -Wall -g -O4 -ffast-math -fsigned-char"
 165                 PROFILE="-DDARWIN -fno-common -force_cpusubtype_ALL -Wall -g -pg -O4 -ffast-math -fsigned-char";;
 166         *)
 167                 DEBUG="-g -Wall -W -D__NO_MATH_INLINES -fsigned-char"
 168                 CFLAGS="-O20 -D__NO_MATH_INLINES -fsigned-char"
 169                 PROFILE="-O20 -g -pg -D__NO_MATH_INLINES -fsigned-char" ;;
 170         esac
 171 fi
 172 CFLAGS="$CFLAGS $cflags_save"
 173
 174 dnl --------------------------------------------------
 175 dnl Check for headers
 176 dnl --------------------------------------------------
 177
 178 AC_CHECK_HEADER(memory.h,CFLAGS="$CFLAGS -DUSE_MEMORY_H",:)
 179
 180 dnl --------------------------------------------------
 181 dnl Check for typedefs, structures, etc
 182 dnl --------------------------------------------------
 183
 184 dnl none
 185
 186 dnl --------------------------------------------------
 187 dnl Check for libraries
 188 dnl --------------------------------------------------
 189
 190 AC_CHECK_LIB(m, cos, VORBIS_LIBS="-lm", VORBIS_LIBS="")
 191 AC_CHECK_LIB(pthread, pthread_create, pthread_lib="-lpthread", :)
 192
 193 HAVE_OGG=no
 194 dnl first check through pkg-config
 195 dnl check for pkg-config itself so we don't try the m4 macro without pkg-config
 196 AC_CHECK_PROG(HAVE_PKG_CONFIG, pkg-config, yes)
 197 if test "x$HAVE_PKG_CONFIG" = "xyes"
 198 then
 199   PKG_CHECK_MODULES(OGG, ogg >= 1.0, HAVE_OGG=yes, HAVE_OGG=no)
 200 fi
 201 if test "x$HAVE_OGG" = "xno"
 202 then
 203   dnl fall back to the old school test
 204   XIPH_PATH_OGG(, AC_MSG_ERROR(must have Ogg installed!))
 205   libs_save=$LIBS
 206   LIBS="$OGG_LIBS $VORBIS_LIBS"
 207   AC_CHECK_FUNC(oggpack_writealign, , AC_MSG_ERROR(Ogg >= 1.0 required !))
 208   LIBS=$libs_save
 209 fi
 210
 211 dnl --------------------------------------------------
 212 dnl Check for library functions
 213 dnl --------------------------------------------------
 214
 215 AC_FUNC_ALLOCA
 216 AC_FUNC_MEMCMP
 217
 218 dnl --------------------------------------------------
 219 dnl Do substitutions
 220 dnl --------------------------------------------------
 221
 222 AC_SUBST(VORBIS_LIBS)
 223 AC_SUBST(DEBUG)
 224 AC_SUBST(PROFILE)
 225 AC_SUBST(pthread_lib)
 226
 227 AC_OUTPUT([
 228 Makefile
 229 lib/Makefile
 230 lib/modes/Makefile
 231 lib/books/Makefile
 232 lib/books/coupled/Makefile
 233 lib/books/uncoupled/Makefile
 234 lib/books/floor/Makefile
 235 doc/Makefile doc/vorbisfile/Makefile doc/vorbisenc/Makefile
 236 include/Makefile include/vorbis/Makefile
 237 examples/Makefile
 238 vq/Makefile
 239 libvorbis.spec
 240 vorbis.pc
 241 vorbisenc.pc
 242 vorbisfile.pc
 243 vorbis-uninstalled.pc
 244 vorbisenc-uninstalled.pc
 245 vorbisfile-uninstalled.pc
 246 ])