configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 dnl ***********************************
   6 dnl *** include special GLib macros ***
   7 dnl ***********************************
   8
   9 m4_define(glib_configure_in)
  10 m4_include(acglib.m4)dnl
  11 m4_include(glib/libcharset/codeset.m4)dnl
  12 m4_include(glib/libcharset/glibc21.m4)dnl
  13 m4_include(m4macros/glib-gettext.m4)dnl
  14
  15 #
  16 # The following version number definitions apply to GLib, GModule, GObject
  17 # and GThread as a whole, so if changes occoured in any of them, they are all
  18 # treated with the same interface and binary age.
  19 #
  20 # Making releases:
  21 #   glib_micro_version += 1;
  22 #   glib_interface_age += 1;
  23 #   glib_binary_age += 1;
  24 # if any functions have been added, set glib_interface_age to 0.
  25 # if backwards compatibility has been broken,
  26 # set glib_binary_age _and_ glib_interface_age to 0.
  27 #
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [12])
  30 m4_define([glib_micro_version], [3])
  31 m4_define([glib_interface_age], [3])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_SRCDIR([glib/glib.h])
  56
  57 # Save this value here, since automake will set cflags later
  58 cflags_set=${CFLAGS+set}
  59
  60 AM_INIT_AUTOMAKE([no-define])
  61
  62 # Specify a configuration file
  63 AM_CONFIG_HEADER([config.h])
  64
  65
  66 GLIB_MAJOR_VERSION=glib_major_version
  67 GLIB_MINOR_VERSION=glib_minor_version
  68 GLIB_MICRO_VERSION=glib_micro_version
  69 GLIB_INTERFACE_AGE=glib_interface_age
  70 GLIB_BINARY_AGE=glib_binary_age
  71 GLIB_VERSION=glib_version
  72
  73 AC_SUBST(GLIB_MAJOR_VERSION)
  74 AC_SUBST(GLIB_MINOR_VERSION)
  75 AC_SUBST(GLIB_MICRO_VERSION)
  76 AC_SUBST(GLIB_VERSION)
  77 AC_SUBST(GLIB_INTERFACE_AGE)
  78 AC_SUBST(GLIB_BINARY_AGE)
  79
  80 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  81           [Define to the GLIB major version])
  82 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  83           [Define to the GLIB minor version])
  84 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  85           [Define to the GLIB micro version])
  86 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  87           [Define to the GLIB interface age])
  88 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  89           [Define to the GLIB binary age])
  90
  91 # libtool versioning
  92 LT_RELEASE=glib_lt_release
  93 LT_CURRENT=glib_lt_current
  94 LT_REVISION=glib_lt_revision
  95 LT_AGE=glib_lt_age
  96 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
  97 AC_SUBST(LT_RELEASE)
  98 AC_SUBST(LT_CURRENT)
  99 AC_SUBST(LT_REVISION)
 100 AC_SUBST(LT_AGE)
 101 AC_SUBST(LT_CURRENT_MINUS_AGE)
 102
 103 dnl Initialize maintainer mode
 104 AM_MAINTAINER_MODE
 105
 106 AC_CANONICAL_HOST
 107
 108 AC_MSG_CHECKING([for the BeOS])
 109 case $host in
 110   *-*-beos*)
 111     glib_native_beos="yes"
 112     ;;
 113   *)
 114     glib_native_beos="no"
 115     ;;
 116 esac
 117 AC_MSG_RESULT([$glib_native_beos])
 118
 119 dnl
 120
 121 AC_MSG_CHECKING([for Win32])
 122 case "$host" in
 123   *-*-mingw*)
 124     glib_native_win32=yes
 125     GLIB_DEF=glib.def
 126     GMODULE_DEF=gmodule.def
 127     GOBJECT_DEF=gobject.def
 128     GTHREAD_DEF=gthread.def
 129     TESTGMODULE_EXP=testgmodule.exp
 130     glib_pid_type='void *'
 131     ;;
 132   *)
 133     glib_native_win32=no
 134     GLIB_DEF=
 135     GMODULE_DEF=
 136     GOBJECT_DEF=
 137     GTHREAD_DEF=
 138     TESTGMODULE_EXP=
 139     glib_pid_type=int
 140     ;;
 141 esac
 142 case $host in
 143   *-*-linux*)
 144     glib_os_linux=yes
 145     ;;
 146 esac
 147
 148
 149 AC_MSG_RESULT([$glib_native_win32])
 150 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 151 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 152 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 153 AC_SUBST(GLIB_DEF)
 154 AC_SUBST(GMODULE_DEF)
 155 AC_SUBST(GOBJECT_DEF)
 156 AC_SUBST(GTHREAD_DEF)
 157 AC_SUBST(TESTGMODULE_EXP)
 158
 159 if test "$glib_native_win32" = "yes"; then
 160   AC_CHECK_TOOL(WINDRES, windres, no)
 161   if test "$WINDRES" = no; then
 162     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 163   fi
 164   AC_CHECK_TOOL(NM, nm, no)
 165   if test "$NM" = no; then
 166     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 167   fi
 168   AC_CHECK_TOOL(RANLIB, ranlib, :)
 169   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 170 fi
 171 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 172
 173 if test "$glib_native_win32" != yes; then
 174     # libtool option to control which symbols are exported
 175     # right now, symbols starting with _ are not exported
 176     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 177 else
 178     # We currently use .def files on Windows
 179     LIBTOOL_EXPORT_OPTIONS=
 180 fi
 181 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 182
 183 dnl declare --enable-* args and collect ac_help strings
 184 AC_ARG_ENABLE(debug,
 185               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 186                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 187               enable_debug=glib_debug_default)
 188
 189 AC_ARG_ENABLE(gc_friendly,
 190               [AC_HELP_STRING([--enable-gc-friendly],
 191                               [turn on garbage collector friendliness [default=no]])],,
 192               [enable_gc_friendly=no])
 193 AC_ARG_ENABLE(mem_pools,
 194               [AC_HELP_STRING([--disable-mem-pools],
 195                               [disable all glib memory pools])],,
 196               [disable_mem_pools=no])
 197 AC_ARG_ENABLE(threads,
 198               [AC_HELP_STRING([--enable-threads],
 199                               [turn on basic thread support [default=yes]
 200 ([=no] will override --with-threads)])],,
 201               [enable_threads=yes])
 202 AC_ARG_ENABLE(rebuilds,
 203               [AC_HELP_STRING([--disable-rebuilds],
 204                               [disable all source autogeneration rules])],,
 205               [enable_rebuilds=yes])
 206 AC_ARG_ENABLE(visibility,
 207               [AC_HELP_STRING([--disable-visibility],
 208                               [don't use ELF visibility attributes])],,
 209               [enable_visibility=yes])
 210
 211 if test "x$enable_threads" != "xyes"; then
 212   enable_threads=no
 213 fi
 214
 215 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, ["${enable_debug}"],
 216         [Whether glib was compiled with debugging enabled])
 217
 218 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 219 if test "x$enable_gc_friendly" = "xyes"; then
 220   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 221   AC_MSG_RESULT([yes])
 222 else
 223   AC_MSG_RESULT([no])
 224 fi
 225
 226 AC_MSG_CHECKING([whether to disable memory pools])
 227 if test "x$disable_mem_pools" = "xno"; then
 228   AC_MSG_RESULT([no])
 229 else
 230   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 231   AC_SUBST(DISABLE_MEM_POOLS)
 232   AC_MSG_RESULT([yes])
 233 fi
 234
 235 if test "$glib_native_win32" = "yes"; then
 236   if test x$enable_static = xyes -o x$enable_static = x; then
 237     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 238     enable_static=no
 239   fi
 240   if test x$enable_shared = xno; then
 241     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 242   fi
 243   enable_shared=yes
 244 fi
 245
 246 dnl Checks for programs.
 247 AC_PROG_CC
 248
 249 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 250 AC_CHECK_PROGS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 251 AC_LANG_SAVE
 252 AC_LANG_CPLUSPLUS
 253 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 254 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 255 AC_LANG_RESTORE
 256
 257 AM_PROG_CC_STDC
 258 AC_PROG_INSTALL
 259
 260 AC_SYS_LARGEFILE
 261
 262 #
 263 # Find pkg-config
 264 #
 265 AC_PATH_PROG(PKG_CONFIG, [pkg-config], [no])
 266 if test x$PKG_CONFIG = xno ; then
 267   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
 268 fi
 269
 270 if $PKG_CONFIG --atleast-pkgconfig-version 0.14 ; then
 271   :
 272 else
 273   AC_MSG_ERROR([*** pkg-config too old; version 0.14 or better required.])
 274 fi
 275
 276 if test "x$enable_debug" = "xyes"; then
 277   if test x$cflags_set != xset ; then
 278       case " $CFLAGS " in
 279       *[[\ \    ]]-g[[\ \       ]]*) ;;
 280       *) CFLAGS="$CFLAGS -g" ;;
 281       esac
 282   fi
 283
 284   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 285 else
 286   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 287
 288   if test "x$enable_debug" = "xno"; then
 289     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 290   fi
 291 fi
 292
 293 if test "x$enable_visibility" = "xno"; then
 294   GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DDISABLE_VISIBILITY"
 295 fi
 296
 297 # Ensure MSVC-compatible struct packing convention is used when
 298 # compiling for Win32 with gcc.
 299 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 300 # gcc2 uses "-fnative-struct".
 301 if test x"$glib_native_win32" = xyes; then
 302   if test x"$GCC" = xyes; then
 303     msnative_struct=''
 304     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 305     if test -z "$ac_cv_prog_CC"; then
 306       our_gcc="$CC"
 307     else
 308       our_gcc="$ac_cv_prog_CC"
 309     fi
 310     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 311       2.)
 312         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 313           msnative_struct='-fnative-struct'
 314         fi
 315         ;;
 316       *)
 317         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 318           msnative_struct='-mms-bitfields'
 319         fi
 320         ;;
 321     esac
 322     if test x"$msnative_struct" = x ; then
 323       AC_MSG_RESULT([no way])
 324       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 325     else
 326       CFLAGS="$CFLAGS $msnative_struct"
 327       AC_MSG_RESULT([${msnative_struct}])
 328     fi
 329   fi
 330 fi
 331
 332 AC_EXEEXT
 333
 334 # define a MAINT-like variable REBUILD which is set if Perl
 335 # and awk are found, so autogenerated sources can be rebuilt
 336 AC_PROG_AWK
 337 AC_CHECK_PROGS(PERL, [perl5 perl])
 338 # We would like indent, but don't require it.
 339 AC_CHECK_PROG(INDENT, indent, indent)
 340 REBUILD=\#
 341 if test "x$enable_rebuilds" = "xyes" && \
 342      test -n "$PERL" && \
 343      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 344      test -n "$AWK" ; then
 345   REBUILD=
 346 fi
 347 AC_SUBST(REBUILD)
 348
 349 # Need full path to Perl for glib-mkenums
 350 #
 351 if test "x$PERL" != x ; then
 352   AC_PATH_PROG(PERL_PATH, [$PERL])
 353 else
 354   PERL_PATH="/usr/bin/env perl"
 355 fi
 356 AC_SUBST(PERL_PATH)
 357
 358 dnl ***********************
 359 dnl *** Tests for iconv ***
 360 dnl ***********************
 361 dnl
 362 dnl We do this before the gettext checks, to avoid distortion
 363
 364 AC_ARG_WITH(libiconv,
 365             [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 366                             [use the libiconv library])],,
 367             [with_libiconv=maybe])
 368
 369 found_iconv=no
 370 case $with_libiconv in
 371   maybe)
 372     # Check in the C library first
 373     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 374     # Check if we have GNU libiconv
 375     if test $found_iconv = "no"; then
 376       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 377     fi
 378     # Check if we have a iconv in -liconv, possibly from vendor
 379     if test $found_iconv = "no"; then
 380       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 381     fi
 382     ;;
 383   no)
 384     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 385     ;;
 386   gnu|yes)
 387     AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 388     ;;
 389   native)
 390     AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 391     ;;
 392 esac
 393
 394 if test "x$found_iconv" = "xno" ; then
 395    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 396 fi
 397
 398 jm_GLIBC21
 399 AC_ARG_ENABLE(iconv-cache,
 400               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 401                               [cache iconv descriptors [default=auto]])],,
 402               [enable_iconv_cache=auto])
 403
 404 AC_MSG_CHECKING([Whether to cache iconv descriptors])
 405 case $enable_iconv_cache in
 406   auto)
 407     if test $ac_cv_gnu_library_2_1 = yes; then
 408       enable_iconv_cache=no
 409     else
 410       enable_iconv_cache=yes
 411     fi
 412   ;;
 413   yes|no)
 414   ;;
 415   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 416   ;;
 417 esac
 418
 419 if test $enable_iconv_cache = yes; then
 420    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 421 fi
 422
 423 AC_MSG_RESULT($enable_iconv_cache)
 424
 425
 426 dnl
 427 dnl gettext support
 428 dnl
 429
 430 ALL_LINGUAS="am ar az be bg bn bn_IN bs ca cs cy da de el en_CA en_GB eo es et eu fa fi fr ga gl gu he hi hr hu id is it ja ka ko ku lt lv mk ml mn ms nb ne nl nn or pa pl pt pt_BR ro ru rw sk sl sq sr sr@Latn sr@ije sv ta te th tl tr tt uk vi wa xh yi zh_CN zh_HK zh_TW"
 431 GLIB_GNU_GETTEXT
 432
 433 if test "$gt_cv_have_gettext" != "yes" ; then
 434   AC_MSG_ERROR([
 435 *** You must have either have gettext support in your C library, or use the
 436 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 437 ])
 438 fi
 439
 440 LIBS="$INTLLIBS $LIBS"
 441
 442 GETTEXT_PACKAGE=glib20
 443 AC_SUBST(GETTEXT_PACKAGE)
 444 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 445   [Define the gettext package to be used])
 446
 447 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 448
 449 dnl
 450 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 451 dnl
 452
 453 if test x$with_libiconv != xno ; then
 454   case " $INTLLIBS " in
 455   *[[\ \        ]]-liconv[[\ \  ]]*) ;;
 456   *) ICONV_LIBS="-liconv" ;;
 457   esac
 458 fi
 459 AC_SUBST(ICONV_LIBS)
 460
 461 case $with_libiconv in
 462   gnu)
 463     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 464     ;;
 465   native)
 466     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 467     ;;
 468 esac
 469
 470 dnl Initialize libtool
 471 AM_DISABLE_STATIC
 472 AC_LIBTOOL_WIN32_DLL
 473 AM_PROG_LIBTOOL
 474
 475 if test "x$GCC" = "xyes"; then
 476   case " $CFLAGS " in
 477   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 478   *) CFLAGS="$CFLAGS -Wall" ;;
 479   esac
 480 fi
 481
 482 dnl
 483 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 484 dnl
 485 if test $cross_compiling != yes ; then
 486     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 487     glib_save_LIBS=$LIBS
 488     LIBS="$LIBS -lm"
 489     AC_TRY_RUN([#include <math.h>
 490                  int main (void) { return (log(1) != log(1.)); }],
 491          AC_MSG_RESULT(none needed),
 492          glib_save_CFLAGS=$CFLAGS
 493          CFLAGS="$CFLAGS -std1"
 494          AC_TRY_RUN([#include <math.h>
 495                      int main (void) { return (log(1) != log(1.)); }],
 496              AC_MSG_RESULT(-std1),
 497              AC_MSG_RESULT()
 498              CFLAGS=$glib_save_CFLAGS
 499              AC_MSG_WARN(
 500                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 501          )
 502     )
 503     LIBS=$glib_save_LIBS
 504 fi
 505
 506 dnl NeXTStep cc seems to need this
 507 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 508 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 509   AC_MSG_RESULT(none needed),
 510   glib_save_CFLAGS=$CFLAGS
 511   CFLAGS="$CFLAGS -posix"
 512   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 513     AC_MSG_RESULT(-posix),
 514     AC_MSG_RESULT()
 515     CFLAGS=$glib_save_CFLAGS
 516     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 517
 518 # Checks for header files.
 519 AC_HEADER_STDC
 520
 521 # Checks for library functions.
 522 AC_FUNC_VPRINTF
 523 AC_FUNC_MMAP
 524 AC_FUNC_ALLOCA
 525 AC_CHECK_FUNCS(posix_memalign)
 526 AC_CHECK_FUNCS(memalign)
 527 AC_CHECK_FUNCS(valloc)
 528
 529 AC_CHECK_FUNCS(atexit on_exit)
 530
 531 AC_CHECK_FUNCS(timegm)
 532
 533 AC_CHECK_SIZEOF(char)
 534 AC_CHECK_SIZEOF(short)
 535 AC_CHECK_SIZEOF(long)
 536 AC_CHECK_SIZEOF(int)
 537 AC_CHECK_SIZEOF(void *)
 538 AC_CHECK_SIZEOF(long long)
 539 AC_CHECK_SIZEOF(__int64)
 540
 541 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 542   :
 543 else
 544   AC_MSG_ERROR([
 545 *** GLib requires a 64 bit type. You might want to consider
 546 *** using the GNU C compiler.
 547 ])
 548 fi
 549
 550 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 551         # long long is a 64 bit integer.
 552         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 553         AC_CACHE_VAL(glib_cv_long_long_format,[
 554                 for format in ll q I64; do
 555                   AC_TRY_RUN([#include <stdio.h>
 556                         int main()
 557                         {
 558                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 559                           char buffer[1000];
 560                           sprintf (buffer, "%${format}u", a);
 561                           sscanf (buffer, "%${format}u", &b);
 562                           exit (b!=a);
 563                         }
 564                         ],
 565                         [glib_cv_long_long_format=${format}
 566                         break],
 567                         [],[:])
 568                 done])
 569         if test -n "$glib_cv_long_long_format"; then
 570           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 571           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 572           if test x"$glib_cv_long_long_format" = xI64; then
 573             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 574           fi
 575         else
 576           AC_MSG_RESULT(none)
 577         fi
 578 elif test x$ac_cv_sizeof___int64 = x8; then
 579         # __int64 is a 64 bit integer.
 580         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 581         # We know this is MSVCRT.DLL, and what the formats are
 582         glib_cv_long_long_format=I64
 583         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 584         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 585         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 586 fi
 587
 588 dnl long doubles were not used, and a portability problem
 589 dnl AC_C_LONG_DOUBLE
 590 AC_C_CONST
 591
 592 dnl ok, here we try to check whether the systems prototypes for
 593 dnl malloc and friends actually match the prototypes provided
 594 dnl by gmem.h (keep in sync). i currently only know how to check
 595 dnl this reliably with gcc (-Werror), improvements for other
 596 dnl compilers are apprechiated.
 597 SANE_MALLOC_PROTOS=no
 598 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 599 glib_save_CFLAGS=$CFLAGS
 600 if test "x$GCC" = "xyes"; then
 601   CFLAGS="$CFLAGS -Werror"
 602   AC_TRY_COMPILE([#include <stdlib.h>], [
 603     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 604     void* (*my_malloc_p)  (size_t)         = malloc;
 605     void  (*my_free_p)    (void*)          = free;
 606     void* (*my_realloc_p) (void*, size_t)  = realloc;
 607     my_calloc_p = 0;
 608     my_malloc_p = 0;
 609     my_free_p = 0;
 610     my_realloc_p = 0;
 611   ],
 612     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 613       [Define if you have correct malloc prototypes])
 614     SANE_MALLOC_PROTOS=yes)
 615 fi
 616 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 617 CFLAGS=$glib_save_CFLAGS
 618
 619 dnl
 620 dnl check in which direction the stack grows
 621 dnl
 622 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 623         AC_TRY_RUN([
 624         volatile int *a = 0, *b = 0;
 625         void foo (void);
 626         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 627         void foo (void) { volatile int x = 5; b = &x; }
 628         ],
 629         glib_cv_stack_grows=no
 630         ,
 631         glib_cv_stack_grows=yes
 632         ,)
 633 ])
 634
 635 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 636 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 637 dnl actually supported.
 638 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 639         AC_COMPILE_IFELSE([
 640         __inline int foo () { return 0; }
 641         int main () { return foo (); }
 642         ],
 643         glib_cv_has__inline=yes
 644         ,
 645         glib_cv_has__inline=no
 646         ,)
 647 ])
 648 case x$glib_cv_has__inline in
 649 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 650 esac
 651 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 652         AC_COMPILE_IFELSE([
 653         __inline__ int foo () { return 0; }
 654         int main () { return foo (); }
 655         ],
 656         glib_cv_has__inline__=yes
 657         ,
 658         glib_cv_has__inline__=no
 659         ,)
 660 ])
 661 case x$glib_cv_has__inline__ in
 662 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 663 esac
 664 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 665         AC_COMPILE_IFELSE([
 666         #undef inline
 667         inline int foo () { return 0; }
 668         int main () { return foo (); }
 669         ],
 670         glib_cv_hasinline=yes
 671         ,
 672         glib_cv_hasinline=no
 673         ,)
 674 ])
 675 case x$glib_cv_hasinline in
 676 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 677 esac
 678
 679 # if we can use inline functions in headers
 680 AC_MSG_CHECKING(if inline functions in headers work)
 681 AC_LINK_IFELSE([
 682 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 683 #  undef inline
 684 #  define inline __inline__
 685 #elif !defined (G_HAVE_INLINE)
 686 #  undef inline
 687 #  if defined (G_HAVE___INLINE__)
 688 #    define inline __inline__
 689 #  elif defined (G_HAVE___INLINE)
 690 #    define inline __inline
 691 #  endif
 692 #endif
 693
 694 int glib_test_func2 (int);
 695
 696 static inline int
 697 glib_test_func1 (void) {
 698   return glib_test_func2 (1);
 699 }
 700
 701 int
 702 main (void) {
 703   int i = 1;
 704 }],[g_can_inline=yes],[g_can_inline=no])
 705 AC_MSG_RESULT($g_can_inline)
 706
 707 dnl *** check for working do while(0) macros ***
 708 AC_CACHE_CHECK([for working do while(0) macros], g_support_dowhile_macros, [
 709         AC_TRY_COMPILE([],[
 710         #define STMT_START do
 711         #define STMT_END while(0)
 712         #define STMT_TEST STMT_START { i = 0; } STMT_END
 713         int main(void) { int i = 1; STMT_TEST; return i; }],
 714         [g_support_dowhile_macros=yes],
 715         [g_support_dowhile_macros=no],
 716         [g_support_dowhile_macros=yes])
 717 ])
 718 if test x$g_support_dowhile_macros = xyes; then
 719   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 720 fi
 721
 722 # check for flavours of varargs macros
 723 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 724 AC_TRY_COMPILE([],[
 725 int a(int p1, int p2, int p3);
 726 #define call_a(...) a(1,__VA_ARGS__)
 727 call_a(2,3);
 728 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 729 AC_MSG_RESULT($g_have_iso_c_varargs)
 730
 731 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 732 if test "$CXX" = ""; then
 733 dnl No C++ compiler
 734   g_have_iso_cxx_varargs=no
 735 else
 736   AC_LANG_CPLUSPLUS
 737   AC_TRY_COMPILE([],[
 738 int a(int p1, int p2, int p3);
 739 #define call_a(...) a(1,__VA_ARGS__)
 740 call_a(2,3);
 741 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 742   AC_LANG_C
 743 fi
 744 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 745
 746 AC_MSG_CHECKING(for GNUC varargs macros)
 747 AC_TRY_COMPILE([],[
 748 int a(int p1, int p2, int p3);
 749 #define call_a(params...) a(1,params)
 750 call_a(2,3);
 751 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 752 AC_MSG_RESULT($g_have_gnuc_varargs)
 753
 754 # check for GNUC visibility support
 755 AC_MSG_CHECKING(for GNUC visibility attribute)
 756 GLIB_CHECK_COMPILE_WARNINGS([
 757 void
 758 __attribute__ ((visibility ("hidden")))
 759      f_hidden (void)
 760 {
 761 }
 762 void
 763 __attribute__ ((visibility ("internal")))
 764      f_internal (void)
 765 {
 766 }
 767 void
 768 __attribute__ ((visibility ("protected")))
 769      f_protected (void)
 770 {
 771 }
 772 void
 773 __attribute__ ((visibility ("default")))
 774      f_default (void)
 775 {
 776 }
 777 int main (int argc, char **argv)
 778 {
 779         f_hidden();
 780         f_internal();
 781         f_protected();
 782         f_default();
 783         return 0;
 784 }
 785 ],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 786 AC_MSG_RESULT($g_have_gnuc_visibility)
 787 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 788
 789 # check for bytesex stuff
 790 AC_C_BIGENDIAN
 791
 792 # check for header files
 793 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h sys/param.h sys/poll.h])
 794 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 795 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h sched.h malloc.h])
 796
 797 # Checks for libcharset
 798 jm_LANGINFO_CODESET
 799 jm_GLIBC21
 800 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 801 AC_CHECK_FUNCS(setlocale)
 802
 803 # check additional type sizes
 804 AC_CHECK_SIZEOF(size_t)
 805
 806 dnl Try to figure out whether gsize, gssize should be long or int
 807 AC_MSG_CHECKING([for the appropriate definition for size_t])
 808
 809 case $ac_cv_sizeof_size_t in
 810   $ac_cv_sizeof_short)
 811       glib_size_type=short
 812       ;;
 813   $ac_cv_sizeof_int)
 814       glib_size_type=int
 815       ;;
 816   $ac_cv_sizeof_long)
 817       glib_size_type=long
 818       ;;
 819   *)  AC_MSG_ERROR([No type matching size_t in size])
 820       ;;
 821 esac
 822
 823 dnl If int/long are the same size, we see which one produces
 824 dnl warnings when used in the location as size_t. (This matters
 825 dnl on AIX with xlc)
 826 dnl
 827 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 828    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 829   GLIB_CHECK_COMPILE_WARNINGS([
 830 #if defined(_AIX) && !defined(__GNUC__)
 831 #pragma options langlvl=stdc89
 832 #endif
 833 #include <stddef.h>
 834 int main ()
 835 {
 836   size_t s = 1;
 837   unsigned int *size_int = &s;
 838   return (int)*size_int;
 839 }
 840     ],glib_size_type=int,
 841       [GLIB_CHECK_COMPILE_WARNINGS([
 842 #if defined(_AIX) && !defined(__GNUC__)
 843 #pragma options langlvl=stdc89
 844 #endif
 845 #include <stddef.h>
 846 int main ()
 847 {
 848    size_t s = 1;
 849    unsigned long *size_long = &s;
 850    return (int)*size_long;
 851 }
 852         ],glib_size_type=long)])
 853 fi
 854
 855 AC_MSG_RESULT(unsigned $glib_size_type)
 856
 857 # Check for some functions
 858 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd nanosleep vasprintf setenv unsetenv getc_unlocked readlink symlink)
 859 AC_CHECK_FUNCS(clock_gettime, [], [
 860   AC_CHECK_LIB(rt, clock_gettime, [
 861     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 862     LIBS="$LIBS -lrt"
 863   ])
 864 ])
 865
 866 AC_CHECK_HEADERS(crt_externs.h)
 867 AC_CHECK_FUNCS(_NSGetEnviron)
 868
 869 AC_FUNC_VSNPRINTF_C99
 870 AC_FUNC_PRINTF_UNIX98
 871
 872 #
 873 # Check whether to use an included printf
 874 #
 875
 876 AC_ARG_ENABLE(included-printf,
 877               [AC_HELP_STRING([--enable-included-printf],
 878                               [use included printf [default=auto]])],
 879               enable_included_printf="$enableval")
 880
 881 need_included_printf=no
 882 if test "x$enable_included_printf" = "xyes" ; then
 883   need_included_printf=yes
 884 fi
 885 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
 886   need_included_printf=yes
 887 fi
 888 if test "$ac_cv_func_printf_unix98" != "yes" ; then
 889   need_included_printf=yes
 890 fi
 891 if test "x$ac_cv_sizeof_long_long" = "x8" &&
 892    test -z "$glib_cv_long_long_format" ; then
 893   need_included_printf=yes
 894 fi
 895
 896 if test "x$enable_included_printf" = "xno" &&
 897    test "x$need_included_printf" = "xyes" ; then
 898   AC_MSG_ERROR([
 899 *** Your C library's printf doesn't appear to have the features that
 900 *** GLib needs, but you specified --enable-included-printf=no.])
 901 fi
 902
 903 enable_included_printf=$need_included_printf
 904
 905 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
 906 if test "$enable_included_printf" != "yes" ; then
 907   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
 908 else
 909   if test -z "$glib_cv_long_long_format" ; then
 910     glib_cv_long_long_format="ll"
 911   fi
 912   AC_DEFINE(HAVE_VASPRINTF,1)
 913 fi
 914
 915 # Checks needed for gnulib vasnprintf
 916 bh_C_SIGNED
 917 jm_AC_TYPE_LONG_LONG
 918 gt_TYPE_LONGDOUBLE
 919 gt_TYPE_WCHAR_T
 920 gt_TYPE_WINT_T
 921 AC_TYPE_SIZE_T
 922 AC_CHECK_TYPES(ptrdiff_t)
 923 jm_AC_TYPE_INTMAX_T
 924 AC_CHECK_FUNCS(snprintf)
 925 AC_FUNC_SNPRINTF_C99
 926
 927 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 928 # The check is borrowed from the PERL Configure script.
 929 if test "$ac_cv_func_memmove" != "yes"; then
 930   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 931     glib_cv_working_bcopy,[AC_TRY_RUN([
 932       int main() {
 933         char buf[128], abc[128], *b;
 934         int len, off, align;
 935         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 936         for (align = 7; align >= 0; align--) {
 937           for (len = 36; len; len--) {
 938             b = buf+align; bcopy(abc, b, len);
 939             for (off = 1; off <= len; off++) {
 940               bcopy(b, b+off, len); bcopy(b+off, b, len);
 941                 if (bcmp(b, abc, len)) return(1);
 942             }
 943           }
 944         }
 945         return(0);
 946       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 947
 948   GLIB_ASSERT_SET(glib_cv_working_bcopy)
 949   if test "$glib_cv_working_bcopy" = "yes"; then
 950     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 951   fi
 952 fi
 953
 954 # Check for sys_errlist
 955 AC_MSG_CHECKING(for sys_errlist)
 956 AC_TRY_LINK(, [
 957 extern char *sys_errlist[];
 958 extern int sys_nerr;
 959 sys_errlist[sys_nerr-1][0] = 0;
 960 ], glib_ok=yes, glib_ok=no)
 961 AC_MSG_RESULT($glib_ok)
 962 if test "$glib_ok" = "no"; then
 963     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 964 fi
 965
 966 # Check for sys_siglist
 967 AC_MSG_CHECKING(for sys_siglist)
 968 AC_TRY_LINK(, [
 969 extern char *sys_siglist[];
 970 exit (sys_siglist[0]);
 971 ], glib_ok=yes, glib_ok=no)
 972 AC_MSG_RESULT($glib_ok)
 973 if test "$glib_ok" = "no"; then
 974     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 975 fi
 976
 977 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 978 AC_MSG_CHECKING(for sys_siglist declaration)
 979 AC_TRY_COMPILE([#include <signal.h>], [
 980 strlen (sys_siglist[0]);
 981 ], glib_ok=yes, glib_ok=no)
 982 AC_MSG_RESULT($glib_ok)
 983 if test "$glib_ok" = "no"; then
 984     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 985 fi
 986
 987 # Check if <sys/select.h> needs to be included for fd_set
 988 AC_MSG_CHECKING([for fd_set])
 989 AC_TRY_COMPILE([#include <sys/types.h>],
 990         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 991 if test "$gtk_ok" = "yes"; then
 992     AC_MSG_RESULT([yes, found in sys/types.h])
 993 else
 994     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
 995     if test "$gtk_ok" = "yes"; then
 996         # *** FIXME: give it a different name
 997         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
 998         AC_MSG_RESULT([yes, found in sys/select.h])
 999     else
1000         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1001         AC_MSG_RESULT(no)
1002     fi
1003 fi
1004
1005 dnl *** check for sane realloc() ***
1006 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1007         AC_TRY_RUN([#include <stdlib.h>
1008         int main() {
1009           return realloc (0, sizeof (int)) == 0;
1010         }],
1011         [glib_cv_sane_realloc=yes],
1012         [glib_cv_sane_realloc=no],
1013         [glib_cv_sane_realloc=yes])
1014 ])
1015 if test x$glib_cv_sane_realloc = xyes; then
1016   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1017 fi
1018
1019 dnl Check for nl_langinfo and CODESET
1020
1021 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
1022 AC_TRY_COMPILE([#include <langinfo.h>],
1023         [char *codeset = nl_langinfo (CODESET);],
1024    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1025    have_codeset=yes,
1026    have_codeset=no)
1027 AC_MSG_RESULT($have_codeset)
1028
1029
1030 dnl ****************************************
1031 dnl *** posix_memalign                   ***
1032 dnl ****************************************
1033 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1034 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1035     glib_cv_compliant_posix_memalign=0
1036     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1037         AC_TRY_RUN([
1038                 #define _XOPEN_SOURCE 600
1039                 #include <stdlib.h> /* posix_memalign() should be defined here */
1040                 /* some systems break if #include <malloc.h> used */
1041                 static void test_memalign (size_t boundary, size_t size) {
1042                     void *mem = 0;
1043                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1044                         exit (1);
1045                     else
1046                       free (mem);
1047                 }
1048                 int main() {
1049                     test_memalign (  128,   128 - 2 * sizeof (void*));
1050                     test_memalign (  256,   256 - 2 * sizeof (void*));
1051                     test_memalign (  512,   512 - 2 * sizeof (void*));
1052                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1053                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1054                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1055                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1056                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1057                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1058                     exit (0); /* success */
1059                 }
1060                 ],
1061             [glib_cv_compliant_posix_memalign=1], [], [:])
1062       :
1063     fi
1064     ])
1065 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1066     AC_MSG_RESULT(yes)
1067     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1068 else
1069     AC_MSG_RESULT(no)
1070 fi
1071
1072
1073 dnl ****************************************
1074 dnl *** strlcpy/strlcat                  ***
1075 dnl ****************************************
1076 # Check for strlcpy
1077 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1078 AC_TRY_RUN([#include <stdlib.h>
1079 #include <string.h>
1080 int main() {
1081   char p[10];
1082   (void) strlcpy (p, "hi", 10);
1083   if (strlcat (p, "bye", 0) != 3)
1084     return 1;
1085   return 0;
1086 }], glib_cv_have_strlcpy=yes,
1087     glib_cv_have_strlcpy=no,
1088     glib_cv_have_strlcpy=no)])
1089 if test "$glib_cv_have_strlcpy" = "yes"; then
1090     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1091 fi
1092
1093
1094 dnl **********************
1095 dnl *** va_copy checks ***
1096 dnl **********************
1097 dnl we currently check for all three va_copy possibilities, so we get
1098 dnl all results in config.log for bug reports.
1099 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1100         AC_LINK_IFELSE([#include <stdarg.h>
1101         void f (int i, ...) {
1102         va_list args1, args2;
1103         va_start (args1, i);
1104         va_copy (args2, args1);
1105         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1106           exit (1);
1107         va_end (args1); va_end (args2);
1108         }
1109         int main() {
1110           f (0, 42);
1111           return 0;
1112         }],
1113         [glib_cv_va_copy=yes],
1114         [glib_cv_va_copy=no])
1115 ])
1116 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1117         AC_LINK_IFELSE([#include <stdarg.h>
1118         void f (int i, ...) {
1119         va_list args1, args2;
1120         va_start (args1, i);
1121         __va_copy (args2, args1);
1122         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1123           exit (1);
1124         va_end (args1); va_end (args2);
1125         }
1126         int main() {
1127           f (0, 42);
1128           return 0;
1129         }],
1130         [glib_cv___va_copy=yes],
1131         [glib_cv___va_copy=no])
1132 ])
1133
1134 if test "x$glib_cv_va_copy" = "xyes"; then
1135   g_va_copy_func=va_copy
1136 else if test "x$glib_cv___va_copy" = "xyes"; then
1137   g_va_copy_func=__va_copy
1138 fi
1139 fi
1140
1141 if test -n "$g_va_copy_func"; then
1142   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1143 fi
1144
1145 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1146         AC_TRY_RUN([#include <stdarg.h>
1147         void f (int i, ...) {
1148         va_list args1, args2;
1149         va_start (args1, i);
1150         args2 = args1;
1151         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1152           exit (1);
1153         va_end (args1); va_end (args2);
1154         }
1155         int main() {
1156           f (0, 42);
1157           return 0;
1158         }],
1159         [glib_cv_va_val_copy=yes],
1160         [glib_cv_va_val_copy=no],
1161         [glib_cv_va_val_copy=yes])
1162 ])
1163
1164 if test "x$glib_cv_va_val_copy" = "xno"; then
1165   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1166 fi
1167
1168 dnl ***********************
1169 dnl *** g_module checks ***
1170 dnl ***********************
1171 G_MODULE_LIBS=
1172 G_MODULE_LIBS_EXTRA=
1173 G_MODULE_PLUGIN_LIBS=
1174 if test x"$glib_native_win32" = xyes; then
1175   dnl No use for this on Win32
1176   G_MODULE_LDFLAGS=
1177 else
1178   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1179 fi
1180 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1181 G_MODULE_NEED_USCORE=0
1182 G_MODULE_BROKEN_RTLD_GLOBAL=0
1183 G_MODULE_HAVE_DLERROR=0
1184 dnl *** force native WIN32 shared lib loader
1185 if test -z "$G_MODULE_IMPL"; then
1186   case "$host" in
1187   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1188   esac
1189 fi
1190 dnl *** force native AIX library loader
1191 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1192 if test -z "$G_MODULE_IMPL"; then
1193   case "$host" in
1194   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1195   esac
1196 fi
1197 dnl *** dlopen() and dlsym() in system libraries
1198 if test -z "$G_MODULE_IMPL"; then
1199         AC_CHECK_FUNC(dlopen,
1200                       [AC_CHECK_FUNC(dlsym,
1201                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1202                       [])
1203 fi
1204 dnl *** load_image (BeOS)
1205 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1206   AC_CHECK_LIB(root, load_image,
1207       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1208       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1209       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1210       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1211       [])
1212 fi
1213 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1214 if test -z "$G_MODULE_IMPL"; then
1215         AC_CHECK_FUNC(NSLinkModule,
1216                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1217                        G_MODULE_NEED_USCORE=1],
1218                       [])
1219 fi
1220 dnl *** dlopen() and dlsym() in libdl
1221 if test -z "$G_MODULE_IMPL"; then
1222         AC_CHECK_LIB(dl, dlopen,
1223                      [AC_CHECK_LIB(dl, dlsym,
1224                                    [G_MODULE_LIBS=-ldl
1225                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1226                      [])
1227 fi
1228 dnl *** shl_load() in libdld (HP-UX)
1229 if test -z "$G_MODULE_IMPL"; then
1230         AC_CHECK_LIB(dld, shl_load,
1231                 [G_MODULE_LIBS=-ldld
1232                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1233                 [])
1234 fi
1235 dnl *** additional checks for G_MODULE_IMPL_DL
1236 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1237         LIBS_orig="$LIBS"
1238         LDFLAGS_orig="$LDFLAGS"
1239         LIBS="$G_MODULE_LIBS $LIBS"
1240         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1241 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1242         echo "void glib_plugin_test(void) { }" > plugin.c
1243         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1244                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1245         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1246                 glib_cv_rtldglobal_broken,[
1247                 AC_TRY_RUN([
1248 #include <dlfcn.h>
1249 #ifndef RTLD_GLOBAL
1250 #  define RTLD_GLOBAL 0
1251 #endif
1252 #ifndef RTLD_LAZY
1253 #  define RTLD_LAZY 0
1254 #endif
1255 int glib_plugin_test;
1256 int main () {
1257     void *handle, *global, *local;
1258     global = &glib_plugin_test;
1259     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1260     if (!handle) return 0;
1261     local = dlsym (handle, "glib_plugin_test");
1262     return global == local;
1263 }                       ],
1264                         [glib_cv_rtldglobal_broken=no],
1265                         [glib_cv_rtldglobal_broken=yes],
1266                         [glib_cv_rtldglobal_broken=no])
1267                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1268                 rmdir .libs 2>/dev/null
1269         ])
1270         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1271                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1272         else
1273                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1274         fi
1275 dnl *** check whether we need preceeding underscores
1276         AC_CACHE_CHECK([for preceeding underscore in symbols],
1277                 glib_cv_uscore,[
1278                 AC_TRY_RUN([#include <dlfcn.h>
1279                 int glib_underscore_test (void) { return 42; }
1280                 int main() {
1281                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1282                   handle = dlopen ((void*)0, 0);
1283                   if (handle) {
1284                     f1 = dlsym (handle, "glib_underscore_test");
1285                     f2 = dlsym (handle, "_glib_underscore_test");
1286                   } return (!f2 || f1);
1287                 }],
1288                         [glib_cv_uscore=yes],
1289                         [glib_cv_uscore=no],
1290                         [])
1291                 rm -f plugin.c plugin.$ac_objext plugin.lo
1292         ])
1293         GLIB_ASSERT_SET(glib_cv_uscore)
1294         if test "x$glib_cv_uscore" = "xyes"; then
1295                 G_MODULE_NEED_USCORE=1
1296         else
1297                 G_MODULE_NEED_USCORE=0
1298         fi
1299
1300         LDFLAGS="$LDFLAGS_orig"
1301 dnl *** check for having dlerror()
1302         AC_CHECK_FUNC(dlerror,
1303                 [G_MODULE_HAVE_DLERROR=1],
1304                 [G_MODULE_HAVE_DLERROR=0])
1305         LIBS="$LIBS_orig"
1306 fi
1307 dnl *** done, have we got an implementation?
1308 if test -z "$G_MODULE_IMPL"; then
1309         G_MODULE_IMPL=0
1310         G_MODULE_SUPPORTED=false
1311 else
1312         G_MODULE_SUPPORTED=true
1313 fi
1314
1315 AC_MSG_CHECKING(for the suffix of shared libraries)
1316 case "$host_os" in
1317   hpux9* | hpux10* | hpux11*)  # taken from ltconfig
1318     case "$host_cpu" in
1319       hppa*)
1320         glib_gmodule_suffix='sl'
1321         ;;
1322       ia64*)
1323         glib_gmodule_suffix='so'
1324         ;;
1325     esac
1326     ;;
1327   cygwin* | mingw*)
1328     glib_gmodule_suffix='dll'
1329     ;;
1330   aix*)
1331     glib_gmodule_suffix='a'
1332     ;;
1333   *)
1334     glib_gmodule_suffix='so'
1335     ;;
1336 esac
1337 AC_MSG_RESULT(.$glib_gmodule_suffix)
1338
1339 AC_SUBST(G_MODULE_SUPPORTED)
1340 AC_SUBST(G_MODULE_IMPL)
1341 AC_SUBST(G_MODULE_LIBS)
1342 AC_SUBST(G_MODULE_LIBS_EXTRA)
1343 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1344 AC_SUBST(G_MODULE_LDFLAGS)
1345 AC_SUBST(G_MODULE_HAVE_DLERROR)
1346 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1347 AC_SUBST(G_MODULE_NEED_USCORE)
1348 AC_SUBST(GLIB_DEBUG_FLAGS)
1349
1350 dnl **********************
1351 dnl *** g_spawn checks ***
1352 dnl **********************
1353
1354 AC_MSG_CHECKING(for gspawn implementation)
1355 case "$host" in
1356   *-*-mingw*)
1357     GSPAWN=gspawn-win32.lo
1358     ;;
1359   *)
1360     GSPAWN=gspawn.lo
1361     ;;
1362 esac
1363 AC_MSG_RESULT($GSPAWN)
1364 AC_SUBST(GSPAWN)
1365
1366 dnl *************************
1367 dnl *** GIOChannel checks ***
1368 dnl *************************
1369
1370 AC_MSG_CHECKING(for GIOChannel implementation)
1371 case "$host" in
1372   *-*-mingw*)
1373     GIO=giowin32.lo
1374     ;;
1375   *)
1376     GIO=giounix.lo
1377     ;;
1378 esac
1379 AC_MSG_RESULT($GIO)
1380 AC_SUBST(GIO)
1381
1382 dnl ****************************************
1383 dnl *** platform dependent source checks ***
1384 dnl ****************************************
1385
1386 AC_MSG_CHECKING(for platform-dependent source)
1387 case "$host" in
1388   *-*-cygwin*|*-*-mingw*)
1389     PLATFORMDEP=gwin32.lo
1390     ;;
1391   *)
1392     PLATFORMDEP=
1393     ;;
1394 esac
1395 AC_MSG_RESULT($PLATFORMDEP)
1396 AC_SUBST(PLATFORMDEP)
1397
1398 AC_MSG_CHECKING([whether to compile timeloop])
1399 case "$host" in
1400   *-*-cygwin*|*-*-mingw*|*-*-minix)
1401     enable_timeloop=no
1402     ;;
1403   *)
1404     enable_timeloop=yes
1405     ;;
1406 esac
1407 AC_MSG_RESULT($enable_timeloop)
1408 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1409
1410 AC_MSG_CHECKING([if building for some Win32 platform])
1411 case "$host" in
1412   *-*-mingw*|*-*-cygwin*)
1413     platform_win32=yes
1414     ;;
1415   *)
1416     platform_win32=no
1417     ;;
1418 esac
1419 AC_MSG_RESULT($platform_win32)
1420 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1421
1422 dnl ***********************
1423 dnl *** g_thread checks ***
1424 dnl ***********************
1425
1426 AC_ARG_WITH(threads,
1427            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/win32@:>@],
1428                            [specify a thread implementation to use])],
1429            [if test "x$with_threads" = x; then
1430                 want_threads=yes
1431             else
1432                 want_threads=$with_threads
1433             fi],
1434            [want_threads=yes])
1435 if test "x$enable_threads" = "xno"; then
1436         want_threads=no
1437 fi
1438
1439 dnl error and warning message
1440 dnl *************************
1441
1442 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1443                 computer. GLib will not have a default thread implementation."
1444
1445 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1446                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1447                 compilation now, but then your programs might not work.
1448                 Please provide information on how it is done on your system."
1449
1450 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1451                 "
1452
1453 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1454                 provide information on your thread implementation.
1455                 You can also run 'configure --disable-threads'
1456                 to compile without thread support."
1457
1458 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1459                 functions will not be MT-safe during their first call because
1460                 there is no working 'getpwuid_r' on your system."
1461
1462 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1463                 because there is no 'localtime_r' on your system."
1464
1465 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1466                 crude surrogate will be used. If you happen to know a
1467                 yield function for your system, please inform the GLib
1468                 developers."
1469
1470 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1471                 threads on your system. Thus threads can only have the default
1472                 priority. If you happen to know these main/max
1473                 priorities, please inform the GLib developers."
1474
1475 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1476                 linking threaded applications. As GLib cannot do that
1477                 automatically, you will get an linkg error everytime you are
1478                 not using the right compiler. In that case you have to relink
1479                 with the right compiler. Ususally just '_r' is appended
1480                 to the compiler name."
1481
1482 dnl determination of thread implementation
1483 dnl ***************************************
1484
1485 # have_threads=no   means no thread support
1486 # have_threads=none means no default thread implementation
1487
1488 have_threads=no
1489 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1490                                 || test "x$want_threads" = xdce; then
1491         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1492         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1493         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1494         glib_save_CPPFLAGS="$CPPFLAGS"
1495         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1496         if test "x$have_threads" = xno; then
1497                 AC_TRY_COMPILE([#include <pthread.h>],
1498                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1499                         have_threads=posix)
1500         fi
1501         if test "x$have_threads" = xno; then
1502                 AC_TRY_COMPILE([#include <pthread.h>],
1503                         [pthread_mutex_t m;
1504                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1505                         have_threads=dce)
1506         fi
1507         # Tru64Unix requires -pthread to find pthread.h. See #103020
1508         CPPFLAGS="$CPPFLAGS -pthread"
1509         if test "x$have_threads" = xno; then
1510         AC_TRY_COMPILE([#include <pthread.h>],
1511                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1512                        have_threads=posix)
1513         fi
1514         CPPFLAGS="$glib_save_CPPFLAGS"
1515 fi
1516 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1517         case $host in
1518                 *-*-mingw*)
1519                 have_threads=win32
1520                 ;;
1521         esac
1522 fi
1523 if test "x$want_threads" = xnone; then
1524         have_threads=none
1525 fi
1526
1527 AC_MSG_CHECKING(for thread implementation)
1528
1529 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1530         AC_MSG_RESULT(none available)
1531         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1532 else
1533         AC_MSG_RESULT($have_threads)
1534 fi
1535
1536
1537 dnl determination of G_THREAD_CFLAGS
1538 dnl ********************************
1539
1540 G_THREAD_LIBS=
1541 G_THREAD_LIBS_EXTRA=
1542 G_THREAD_CFLAGS=
1543
1544 dnl
1545 dnl Test program for basic POSIX threads functionality
1546 dnl
1547 m4_define([glib_thread_test],[
1548 #include <stdlib.h>
1549 #include <pthread.h>
1550 int check_me = 0;
1551 void* func(void* data) {check_me = 42; return &check_me;}
1552 int main()
1553  { pthread_t t;
1554    void *ret;
1555    pthread_create (&t, $1, func, 0);
1556    pthread_join (t, &ret);
1557    exit (check_me != 42 || ret != &check_me);
1558 }])
1559
1560 dnl
1561 dnl Test program for sched_get_priority_min()
1562 dnl
1563 m4_define([glib_sched_priority_test],[
1564 #include <sched.h>
1565 #include <errno.h>
1566 int main() {
1567     errno = 0;
1568     return sched_get_priority_min(SCHED_OTHER)==-1
1569            && errno != 0;
1570 }])
1571
1572 if test x"$have_threads" != xno; then
1573
1574   if test x"$have_threads" = xposix; then
1575     # First we test for posix, whether -pthread or -pthreads do the trick as
1576     # both CPPFLAG and LIBS.
1577     # One of them does for most gcc versions and some other platforms/compilers
1578     # too and could be considered as the canonical way to go.
1579     case $host in
1580       *-*-cygwin*|*-*-darwin*)
1581          # skip cygwin and darwin -pthread or -pthreads test
1582          ;;
1583       *)
1584         for flag in pthread pthreads mt; do
1585           glib_save_CFLAGS="$CFLAGS"
1586           CFLAGS="$CFLAGS -$flag"
1587           AC_TRY_RUN(glib_thread_test(0),
1588                      glib_flag_works=yes,
1589                      glib_flag_works=no,
1590                      [AC_LINK_IFELSE(glib_thread_test(0),
1591                                      glib_flag_works=yes,
1592                                      glib_flag_works=no)])
1593           CFLAGS="$glib_save_CFLAGS"
1594           if test $glib_flag_works = yes ; then
1595              G_THREAD_CFLAGS=-$flag
1596              G_THREAD_LIBS=-$flag
1597           fi
1598         done
1599          ;;
1600     esac
1601   fi
1602
1603   if test x"$G_THREAD_CFLAGS" = x; then
1604
1605     # The canonical -pthread[s] does not work. Try something different.
1606
1607     case $host in
1608         *-aix*)
1609                 if test x"$GCC" = xyes; then
1610                         # GCC 3.0 and above needs -pthread.
1611                         # Should be coverd by the case above.
1612                         # GCC 2.x and below needs -mthreads
1613                         G_THREAD_CFLAGS="-mthreads"
1614                         G_THREAD_LIBS=$G_THREAD_CFLAGS
1615                 else
1616                         # We are probably using the aix compiler. Normaly a
1617                         # program would have to be compiled with the _r variant
1618                         # of the corresponding compiler, but we as GLib cannot
1619                         # do that: but the good news is that for compiling the
1620                         # only difference is the added -D_THREAD_SAFE compile
1621                         # option. This is according to the "C for AIX User's
1622                         # Guide".
1623                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
1624                 fi
1625                 ;;
1626         *-dg-dgux*)  # DG/UX
1627                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
1628                 ;;
1629         *-osf*)
1630                 # So we are using dce threads. posix threads are already
1631                 # catched above.
1632                 G_THREAD_CFLAGS="-threads"
1633                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1634                 ;;
1635         *-sysv5uw7*) # UnixWare 7
1636                 # We are not using gcc with -pthread. Catched above.
1637                 G_THREAD_CFLAGS="-Kthread"
1638                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1639                 ;;
1640         *-mingw*)
1641                 # No flag needed when using MSVCRT.DLL
1642                 G_THREAD_CFLAGS=""
1643                 ;;
1644         *)
1645                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1646                 ;;
1647     esac
1648
1649   fi
1650
1651     # if we are not finding the localtime_r function, then we probably are
1652     # not using the proper multithread flag
1653
1654     glib_save_CPPFLAGS="$CPPFLAGS"
1655     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1656
1657     # First we test, whether localtime_r is declared in time.h
1658     # directly. Then we test whether a macro localtime_r exists, in
1659     # which case localtime_r in the test program is replaced and thus
1660     # if we still find localtime_r in the output, it is not defined as
1661     # a macro.
1662
1663     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1664       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1665                                                            localtime_r(a,b)],
1666                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1667
1668     CPPFLAGS="$glib_save_CPPFLAGS"
1669
1670     AC_MSG_CHECKING(thread related cflags)
1671     AC_MSG_RESULT($G_THREAD_CFLAGS)
1672     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1673 fi
1674
1675 dnl determination of G_THREAD_LIBS
1676 dnl ******************************
1677
1678 mutex_has_default=no
1679 case $have_threads in
1680         posix|dce)
1681           glib_save_CPPFLAGS="$CPPFLAGS"
1682           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1683           if test x"$G_THREAD_LIBS" = x; then
1684             case $host in
1685               *-aix*)
1686                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
1687                 # probably using the aix compiler.
1688                 AC_MSG_WARN($AIX_COMPILE_INFO)
1689                 ;;
1690               *)
1691                 G_THREAD_LIBS=error
1692                 glib_save_LIBS="$LIBS"
1693                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
1694                         if test x"$thread_lib" = x; then
1695                                 add_thread_lib=""
1696                                 IN=""
1697                         else
1698                                 add_thread_lib="-l$thread_lib"
1699                                 IN=" in -l$thread_lib"
1700                         fi
1701                         if test x"$have_threads" = xposix; then
1702                                 defattr=0
1703                         else
1704                                 defattr=pthread_attr_default
1705                         fi
1706
1707                         LIBS="$add_thread_lib $glib_save_LIBS"
1708
1709                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
1710                         AC_TRY_RUN(glib_thread_test($defattr),
1711                                    glib_result=yes,
1712                                    glib_result=no,
1713                                    [AC_LINK_IFELSE(glib_thread_test($defattr),
1714                                                    glib_result=yes,
1715                                                    glib_result=no)])
1716                         AC_MSG_RESULT($glib_result)
1717
1718                         if test "$glib_result" = "yes" ; then
1719                           G_THREAD_LIBS="$add_thread_lib"
1720                           break
1721                         fi
1722                 done
1723                 if test "x$G_THREAD_LIBS" = xerror; then
1724                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1725                 fi
1726                 LIBS="$glib_save_LIBS"
1727                 ;;
1728             esac
1729           fi
1730
1731           glib_save_LIBS="$LIBS"
1732           for thread_lib in "" rt rte; do
1733             if test x"$thread_lib" = x; then
1734               add_thread_lib=""
1735               IN=""
1736             else
1737               add_thread_lib="-l$thread_lib"
1738               IN=" in -l$thread_lib"
1739             fi
1740             LIBS="$add_thread_lib $glib_save_LIBS"
1741
1742             AC_MSG_CHECKING(for sched_get_priority_min$IN)
1743             AC_TRY_RUN(glib_sched_priority_test,
1744                        glib_result=yes,
1745                        glib_result=no,
1746                        [AC_LINK_IFELSE(glib_sched_priority_test,
1747                                        glib_result=yes,
1748                                        glib_result=no)])
1749             AC_MSG_RESULT($glib_result)
1750
1751             if test "$glib_result" = "yes" ; then
1752                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
1753                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
1754                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
1755                break
1756             fi
1757           done
1758           LIBS="$glib_save_LIBS"
1759           mutex_has_default=yes
1760           mutex_default_type='pthread_mutex_t'
1761           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
1762           mutex_header_file='pthread.h'
1763           if test "x$have_threads" = "xposix"; then
1764             g_threads_impl="POSIX"
1765           else
1766             g_threads_impl="DCE"
1767             have_threads="posix"
1768           fi
1769           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
1770           CPPFLAGS="$glib_save_CPPFLAGS"
1771           ;;
1772         win32)
1773            g_threads_impl="WIN32"
1774            ;;
1775         none|no)
1776            g_threads_impl="NONE"
1777            ;;
1778         *)
1779            g_threads_impl="NONE"
1780            G_THREAD_LIBS=error
1781            ;;
1782 esac
1783
1784 if test "x$G_THREAD_LIBS" = xerror; then
1785         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1786 fi
1787
1788 case $host in
1789   *-*-beos*)
1790     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
1791     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1792     ;;
1793   *)
1794     ;;
1795 esac
1796
1797 AC_MSG_CHECKING(thread related libraries)
1798 AC_MSG_RESULT($G_THREAD_LIBS)
1799
1800 dnl check for mt safe function variants and some posix functions
1801 dnl ************************************************************
1802
1803 if test x"$have_threads" != xno; then
1804         glib_save_LIBS="$LIBS"
1805         # we are not doing the following for now, as this might require glib
1806         # to always be linked with the thread libs on some platforms.
1807         # LIBS="$LIBS $G_THREAD_LIBS"
1808         AC_CHECK_FUNCS(localtime_r)
1809         if test "$ac_cv_header_pwd_h" = "yes"; then
1810                 AC_CACHE_CHECK([for posix getpwuid_r],
1811                         ac_cv_func_posix_getpwuid_r,
1812                         [AC_TRY_RUN([
1813 #include <errno.h>
1814 #include <pwd.h>
1815 int main () {
1816     char buffer[10000];
1817     struct passwd pwd, *pwptr = &pwd;
1818     int error;
1819     errno = 0;
1820     error = getpwuid_r (0, &pwd, buffer,
1821                         sizeof (buffer), &pwptr);
1822    return (error < 0 && errno == ENOSYS)
1823            || error == ENOSYS;
1824 }                               ],
1825                                 [ac_cv_func_posix_getpwuid_r=yes],
1826                                 [ac_cv_func_posix_getpwuid_r=no])])
1827                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
1828                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
1829                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
1830                                 [Have POSIX function getpwuid_r])
1831                 else
1832                         AC_CACHE_CHECK([for nonposix getpwuid_r],
1833                                 ac_cv_func_nonposix_getpwuid_r,
1834                                 [AC_TRY_LINK([#include <pwd.h>],
1835                                         [char buffer[10000];
1836                                         struct passwd pwd;
1837                                         getpwuid_r (0, &pwd, buffer,
1838                                                         sizeof (buffer));],
1839                                         [ac_cv_func_nonposix_getpwuid_r=yes],
1840                                         [ac_cv_func_nonposix_getpwuid_r=no])])
1841                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
1842                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
1843                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
1844                                         [Have non-POSIX function getpwuid_r])
1845                         fi
1846                 fi
1847         fi
1848         LIBS="$G_THREAD_LIBS $LIBS"
1849         if test x"$have_threads" = xposix; then
1850                 glib_save_CPPFLAGS="$CPPFLAGS"
1851                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1852                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
1853                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
1854                 # This is not AC_CHECK_FUNC to also work with function
1855                 # name mangling in header files.
1856                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1857                 AC_TRY_LINK([#include <pthread.h>],
1858                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1859                         [AC_MSG_RESULT(yes)
1860                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1861                                   [Have function pthread_attr_setstacksize])],
1862                         [AC_MSG_RESULT(no)])
1863                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1864                 if test x"$posix_priority_min" = x; then
1865                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1866                                 PX_PRIO_MIN],,[
1867                                 posix_priority_min=PX_PRIO_MIN
1868                                 posix_priority_max=PX_PRIO_MAX])
1869                 fi
1870                 if test x"$posix_priority_min" = x; then
1871                         # AIX
1872                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
1873                                 PTHREAD_PRIO_MIN],,[
1874                                 posix_priority_min=PTHREAD_PRIO_MIN
1875                                 posix_priority_max=PTHREAD_PRIO_MAX])
1876                 fi
1877                 if test x"$posix_priority_min" = x; then
1878                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1879                                 PRI_OTHER_MIN],,[
1880                                 posix_priority_min=PRI_OTHER_MIN
1881                                 posix_priority_max=PRI_OTHER_MAX])
1882                 fi
1883                 if test x"$posix_priority_min" = x; then
1884                         AC_MSG_RESULT(none found)
1885                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1886                         posix_priority_min=-1
1887                         posix_priority_max=-1
1888                 else
1889                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1890                         AC_MSG_CHECKING(for pthread_setschedparam)
1891                         AC_TRY_LINK([#include <pthread.h>],
1892                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
1893                           [AC_MSG_RESULT(yes)
1894                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1895                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
1896                           [AC_MSG_RESULT(no)
1897                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
1898                 fi
1899                 posix_yield_func=none
1900                 AC_MSG_CHECKING(for posix yield function)
1901                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1902                                                         thr_yield; do
1903                         AC_TRY_LINK([#include <pthread.h>],
1904                                 [$yield_func()],
1905                                 [posix_yield_func="$yield_func"
1906                                 break])
1907                 done
1908                 if test x"$posix_yield_func" = xnone; then
1909                         AC_MSG_RESULT(none found)
1910                         AC_MSG_WARN($POSIX_NO_YIELD)
1911                         posix_yield_func="g_usleep(1000)"
1912                 else
1913                         AC_MSG_RESULT($posix_yield_func)
1914                         posix_yield_func="$posix_yield_func()"
1915                 fi
1916                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1917                 CPPFLAGS="$glib_save_CPPFLAGS"
1918
1919         elif test x"$have_threads" = xwin32; then
1920                 # It's a pointer to a private struct
1921                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
1922         fi
1923
1924         LIBS="$glib_save_LIBS"
1925
1926         # now spit out all the warnings.
1927         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1928            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1929                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1930         fi
1931         if test "$ac_cv_func_localtime_r" != "yes"; then
1932                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1933         fi
1934 fi
1935
1936 if test x"$glib_cv_sizeof_system_thread" = x; then
1937    # use a pointer as a fallback.
1938    GLIB_SIZEOF(,void *, system_thread)
1939 fi
1940
1941 #
1942 # Hack to deal with:
1943 #
1944 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
1945 #     building shared libraries with linux.
1946 #
1947 case $host in
1948   *-*-linux*)
1949     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
1950     ;;
1951   *)
1952     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
1953     ;;
1954 esac
1955
1956 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1957                    [Source file containing theread implementation])
1958 AC_SUBST(G_THREAD_CFLAGS)
1959 AC_SUBST(G_THREAD_LIBS)
1960 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
1961 AC_SUBST(G_THREAD_LIBS_EXTRA)
1962
1963 dnl **********************************************
1964 dnl *** GDefaultMutex setup and initialization ***
1965 dnl **********************************************
1966 dnl
1967 dnl if mutex_has_default = yes, we also got
1968 dnl mutex_default_type, mutex_default_init and mutex_header_file
1969 if test $mutex_has_default = yes ; then
1970         glib_save_CPPFLAGS="$CPPFLAGS"
1971         glib_save_LIBS="$LIBS"
1972         LIBS="$G_THREAD_LIBS $LIBS"
1973         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1974         GLIB_SIZEOF([#include <$mutex_header_file>],
1975                     $mutex_default_type,
1976                     gmutex)
1977         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1978                            $mutex_default_type,
1979                            gmutex,
1980                            $glib_cv_sizeof_gmutex,
1981                            $mutex_default_init)
1982         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1983                 mutex_has_default=no
1984         fi
1985         CPPFLAGS="$glib_save_CPPFLAGS"
1986         LIBS="$glib_save_LIBS"
1987 fi
1988
1989 dnl ********************************
1990 dnl *** g_atomic_* tests for gcc ***
1991 dnl ********************************
1992
1993 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
1994
1995 if test x"$GCC" = xyes; then
1996   case $host_cpu in
1997     i386)
1998       AC_MSG_RESULT([none])
1999       glib_memory_barrier_needed=no
2000       ;;
2001     i?86)
2002       AC_MSG_RESULT([i486])
2003       AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
2004                          [i486 atomic implementation])
2005       glib_memory_barrier_needed=no
2006       ;;
2007     sparc*)
2008       SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
2009                 when you are using a sparc with v9 instruction set (most
2010                 sparcs nowadays). This will make the code for atomic
2011                 operations much faster. The resulting code will not run
2012                 on very old sparcs though."
2013
2014       AC_LINK_IFELSE([[
2015         main ()
2016         {
2017           int tmp1, tmp2, tmp3;
2018           __asm__ __volatile__("casx [%2], %0, %1"
2019                                : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
2020         }]],
2021         AC_MSG_RESULT([sparcv9])
2022         AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
2023                            [sparcv9 atomic implementation]),
2024         AC_MSG_RESULT([no])
2025         AC_MSG_WARN([[$SPARCV9_WARNING]]))
2026       glib_memory_barrier_needed=yes
2027       ;;
2028     alpha*)
2029       AC_MSG_RESULT([alpha])
2030       AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
2031                          [alpha atomic implementation])
2032       glib_memory_barrier_needed=yes
2033       ;;
2034     x86_64)
2035       AC_MSG_RESULT([x86_64])
2036       AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
2037                          [x86_64 atomic implementation])
2038       glib_memory_barrier_needed=no
2039      ;;
2040     powerpc*)
2041       AC_MSG_RESULT([powerpc])
2042       AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
2043                          [powerpc atomic implementation])
2044       glib_memory_barrier_needed=yes
2045       ;;
2046     ia64)
2047       AC_MSG_RESULT([ia64])
2048       AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
2049                          [ia64 atomic implementation])
2050       glib_memory_barrier_needed=yes
2051       ;;
2052     s390|s390x)
2053       AC_MSG_RESULT([s390])
2054       AC_DEFINE_UNQUOTED(G_ATOMIC_S390, 1,
2055                          [s390 atomic implementation])
2056       glib_memory_barrier_needed=no
2057       ;;
2058     *)
2059       AC_MSG_RESULT([none])
2060       glib_memory_barrier_needed=yes
2061       ;;
2062   esac
2063 fi
2064
2065 dnl ****************************************
2066 dnl *** GLib POLL* compatibility defines ***
2067 dnl ****************************************
2068
2069 glib_poll_includes=["
2070 #include <sys/types.h>
2071 #include <sys/poll.h>
2072 "]
2073
2074 if test $ac_cv_header_sys_types_h = yes &&
2075    test $ac_cv_header_sys_poll_h = yes ; then
2076   glib_failed=false
2077   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2078   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2079   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2080   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2081   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2082   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2083   if $glib_failed ; then
2084     AC_MSG_ERROR([Could not determine values for POLL* constants])
2085   fi
2086 else
2087   glib_cv_value_POLLIN=1
2088   glib_cv_value_POLLOUT=4
2089   glib_cv_value_POLLPRI=2
2090   glib_cv_value_POLLERR=8
2091   glib_cv_value_POLLHUP=16
2092   glib_cv_value_POLLNVAL=32
2093 fi
2094
2095 dnl **********************
2096 dnl *** Win32 API libs ***
2097 dnl **********************
2098
2099 case $host in
2100   *-*-cygwin*)
2101         G_LIBS_EXTRA="-luser32 -lkernel32"
2102     ;;
2103   *-*-mingw*)
2104         G_LIBS_EXTRA="-lws2_32 -lole32"
2105     ;;
2106   *)
2107         G_LIBS_EXTRA=""
2108     ;;
2109 esac
2110 AC_SUBST(G_LIBS_EXTRA)
2111
2112 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2113 dnl since we need it for g_iconv()
2114
2115 AC_MSG_CHECKING([for EILSEQ])
2116 AC_TRY_COMPILE([
2117 #include <errno.h>
2118 ],
2119 [
2120 int error = EILSEQ;
2121 ], have_eilseq=yes, have_eilseq=no);
2122 AC_MSG_RESULT($have_eilseq)
2123
2124 dnl ******************************************************************
2125 dnl *** Look for glib-genmarshal in PATH if we are cross-compiling ***
2126 dnl ******************************************************************
2127
2128 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2129
2130 if test $cross_compiling = yes; then
2131   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2132   if test x$GLIB_GENMARSHAL = xno; then
2133     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2134   fi
2135 fi
2136
2137 dnl **************************
2138 dnl *** Checks for gtk-doc ***
2139 dnl **************************
2140
2141 GTK_DOC_CHECK([1.4])
2142
2143 AC_ARG_ENABLE(man,
2144               [AC_HELP_STRING([--enable-man],
2145                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2146               enable_man=no)
2147
2148 if test "${enable_man}" != no; then
2149 dnl
2150 dnl Check for xsltproc
2151 dnl
2152 AC_PATH_PROG([XSLTPROC], [xsltproc])
2153   if test -z "$XSLTPROC"; then
2154     enable_man=no
2155   fi
2156
2157   dnl check for DocBook DTD and stylesheets in the local catalog.
2158   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2159      [DocBook XML DTD V4.1.2],,enable_man=no)
2160   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2161      [DocBook XSL Stylesheets],,enable_man=no)
2162 fi
2163
2164 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2165
2166 dnl ******************************
2167 dnl *** output the whole stuff ***
2168 dnl ******************************
2169
2170 dnl this section will only be run if config.status is invoked with no
2171 dnl arguments, or with "glibconfig.h" as an argument.
2172 AC_CONFIG_COMMANDS([glibconfig.h],
2173 [
2174         outfile=glibconfig.h-tmp
2175         cat > $outfile <<\_______EOF
2176 /* glibconfig.h
2177  *
2178  * This is a generated file.  Please modify 'configure.in'
2179  */
2180
2181 #ifndef __G_LIBCONFIG_H__
2182 #define __G_LIBCONFIG_H__
2183
2184 #include <glib/gmacros.h>
2185
2186 _______EOF
2187
2188         if test x$glib_limits_h = xyes; then
2189           echo '#include <limits.h>' >> $outfile
2190         fi
2191         if test x$glib_float_h = xyes; then
2192           echo '#include <float.h>' >> $outfile
2193         fi
2194         if test x$glib_values_h = xyes; then
2195           echo '#include <values.h>' >> $outfile
2196         fi
2197         if test "$glib_header_alloca_h" = "yes"; then
2198           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2199         fi
2200         if test x$glib_sys_poll_h = xyes; then
2201           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2202         fi
2203
2204         cat >> $outfile <<_______EOF
2205
2206 G_BEGIN_DECLS
2207
2208 #define G_MINFLOAT      $glib_mf
2209 #define G_MAXFLOAT      $glib_Mf
2210 #define G_MINDOUBLE     $glib_md
2211 #define G_MAXDOUBLE     $glib_Md
2212 #define G_MINSHORT      $glib_ms
2213 #define G_MAXSHORT      $glib_Ms
2214 #define G_MAXUSHORT     $glib_Mus
2215 #define G_MININT        $glib_mi
2216 #define G_MAXINT        $glib_Mi
2217 #define G_MAXUINT       $glib_Mui
2218 #define G_MINLONG       $glib_ml
2219 #define G_MAXLONG       $glib_Ml
2220 #define G_MAXULONG      $glib_Mul
2221
2222 _______EOF
2223
2224
2225         ### this should always be true in a modern C/C++ compiler
2226         cat >>$outfile <<_______EOF
2227 typedef signed char gint8;
2228 typedef unsigned char guint8;
2229 _______EOF
2230
2231
2232         if test -n "$gint16"; then
2233           cat >>$outfile <<_______EOF
2234 typedef signed $gint16 gint16;
2235 typedef unsigned $gint16 guint16;
2236 #define G_GINT16_MODIFIER $gint16_modifier
2237 #define G_GINT16_FORMAT $gint16_format
2238 #define G_GUINT16_FORMAT $guint16_format
2239 _______EOF
2240         fi
2241
2242
2243         if test -n "$gint32"; then
2244           cat >>$outfile <<_______EOF
2245 typedef signed $gint32 gint32;
2246 typedef unsigned $gint32 guint32;
2247 #define G_GINT32_MODIFIER $gint32_modifier
2248 #define G_GINT32_FORMAT $gint32_format
2249 #define G_GUINT32_FORMAT $guint32_format
2250 _______EOF
2251         fi
2252
2253         cat >>$outfile <<_______EOF
2254 #define G_HAVE_GINT64 1          /* deprecated, always true */
2255
2256 ${glib_extension}typedef signed $gint64 gint64;
2257 ${glib_extension}typedef unsigned $gint64 guint64;
2258
2259 #define G_GINT64_CONSTANT(val)  $gint64_constant
2260 #define G_GUINT64_CONSTANT(val) $guint64_constant
2261 _______EOF
2262
2263         if test x$gint64_format != x ; then
2264           cat >>$outfile <<_______EOF
2265 #define G_GINT64_MODIFIER $gint64_modifier
2266 #define G_GINT64_FORMAT $gint64_format
2267 #define G_GUINT64_FORMAT $guint64_format
2268 _______EOF
2269         else
2270           cat >>$outfile <<_______EOF
2271 #undef G_GINT64_MODIFIER
2272 #undef G_GINT64_FORMAT
2273 #undef G_GUINT64_FORMAT
2274 _______EOF
2275         fi
2276
2277         cat >>$outfile <<_______EOF
2278
2279 #define GLIB_SIZEOF_VOID_P $glib_void_p
2280 #define GLIB_SIZEOF_LONG   $glib_long
2281 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2282
2283 _______EOF
2284
2285         cat >>$outfile <<_______EOF
2286 typedef signed $glib_size_type_define gssize;
2287 typedef unsigned $glib_size_type_define gsize;
2288 #define G_GSIZE_MODIFIER $gsize_modifier
2289 #define G_GSSIZE_FORMAT $gssize_format
2290 #define G_GSIZE_FORMAT $gsize_format
2291
2292 #define G_MAXSIZE       G_MAXU$glib_msize_type
2293 _______EOF
2294
2295         if test -z "$glib_unknown_void_p"; then
2296           cat >>$outfile <<_______EOF
2297
2298 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2299 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2300
2301 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2302 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2303 _______EOF
2304         else
2305           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2306         fi
2307
2308
2309
2310         cat >>$outfile <<_______EOF
2311 $glib_atexit
2312 $glib_memmove
2313 $glib_defines
2314 $glib_os
2315
2316 $glib_vacopy
2317
2318 #ifdef  __cplusplus
2319 #define G_HAVE_INLINE   1
2320 #else   /* !__cplusplus */
2321 $glib_inline
2322 #endif  /* !__cplusplus */
2323
2324 #ifdef  __cplusplus
2325 #define G_CAN_INLINE    1
2326 _______EOF
2327
2328         if test x$g_can_inline = xyes ; then
2329                 cat >>$outfile <<_______EOF
2330 #else   /* !__cplusplus */
2331 #define G_CAN_INLINE    1
2332 _______EOF
2333         fi
2334
2335         cat >>$outfile <<_______EOF
2336 #endif
2337
2338 _______EOF
2339
2340         if test x$g_have_iso_c_varargs = xyes ; then
2341                 cat >>$outfile <<_______EOF
2342 #ifndef __cplusplus
2343 # define G_HAVE_ISO_VARARGS 1
2344 #endif
2345 _______EOF
2346         fi
2347         if test x$g_have_iso_cxx_varargs = xyes ; then
2348                 cat >>$outfile <<_______EOF
2349 #ifdef __cplusplus
2350 # define G_HAVE_ISO_VARARGS 1
2351 #endif
2352 _______EOF
2353         fi
2354         if test x$g_have_gnuc_varargs = xyes ; then
2355                 cat >>$outfile <<_______EOF
2356
2357 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2358  * is passed ISO vararg support is turned off, and there is no work
2359  * around to turn it on, so we unconditionally turn it off.
2360  */
2361 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2362 #  undef G_HAVE_ISO_VARARGS
2363 #endif
2364
2365 #define G_HAVE_GNUC_VARARGS 1
2366 _______EOF
2367         fi
2368
2369         case x$g_stack_grows in
2370         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2371         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2372         esac
2373
2374
2375         echo >>$outfile
2376         if test x$g_have_eilseq = xno; then
2377                 cat >>$outfile <<_______EOF
2378 #ifndef EILSEQ
2379 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2380  * The correspondence between this and the corresponding definition
2381  * in libiconv is essential.
2382  */
2383 #  define EILSEQ ENOENT
2384 #endif
2385 _______EOF
2386
2387         fi
2388
2389         if test x$g_have_gnuc_visibility = xyes ; then
2390                 cat >>$outfile <<_______EOF
2391 #define G_HAVE_GNUC_VISIBILITY 1
2392 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2393 _______EOF
2394         else
2395                 cat >>$outfile <<_______EOF
2396 #define G_GNUC_INTERNAL
2397 _______EOF
2398         fi
2399
2400
2401         echo >>$outfile
2402         if test x$g_mutex_has_default = xyes; then
2403                 cat >>$outfile <<_______EOF
2404 $g_enable_threads_def G_THREADS_ENABLED
2405 #define G_THREADS_IMPL_$g_threads_impl_def
2406 typedef struct _GStaticMutex GStaticMutex;
2407 struct _GStaticMutex
2408 {
2409   struct _GMutex *runtime_mutex;
2410   union {
2411     char   pad[[$g_mutex_sizeof]];
2412     double dummy_double;
2413     void  *dummy_pointer;
2414     long   dummy_long;
2415   } static_mutex;
2416 };
2417 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
2418 #define g_static_mutex_get_mutex(mutex) \\
2419   (g_thread_use_default_impl ? ((GMutex*) ((mutex)->static_mutex.pad)) : \\
2420    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
2421 _______EOF
2422         else
2423                 cat >>$outfile <<_______EOF
2424 $g_enable_threads_def G_THREADS_ENABLED
2425 #define G_THREADS_IMPL_$g_threads_impl_def
2426 typedef struct _GMutex* GStaticMutex;
2427 #define G_STATIC_MUTEX_INIT NULL
2428 #define g_static_mutex_get_mutex(mutex) \\
2429   (g_static_mutex_get_mutex_impl_shortcut (mutex))
2430 _______EOF
2431         fi
2432
2433         cat >>$outfile <<_______EOF
2434 /* This represents a system thread as used by the implementation. An
2435  * alien implementaion, as loaded by g_thread_init can only count on
2436  * "sizeof (gpointer)" bytes to store their info. We however need more
2437  * for some of our native implementations. */
2438 typedef union _GSystemThread GSystemThread;
2439 union _GSystemThread
2440 {
2441   char   data[[$g_system_thread_sizeof]];
2442   double dummy_double;
2443   void  *dummy_pointer;
2444   long   dummy_long;
2445 };
2446 _______EOF
2447         if test x"$g_memory_barrier_needed" != xno; then
2448           echo >>$outfile
2449           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2450         fi
2451
2452         echo >>$outfile
2453         g_bit_sizes="16 32 64"
2454         for bits in $g_bit_sizes; do
2455           cat >>$outfile <<_______EOF
2456 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
2457 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
2458 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2459 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
2460 _______EOF
2461         done
2462
2463         cat >>$outfile <<_______EOF
2464 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
2465 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
2466 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
2467 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
2468 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
2469 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
2470 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
2471 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
2472 #define G_BYTE_ORDER $g_byte_order
2473
2474 #define GLIB_SYSDEF_POLLIN =$g_pollin
2475 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2476 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2477 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2478 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2479 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2480
2481 #define G_MODULE_SUFFIX "$g_module_suffix"
2482
2483 typedef $g_pid_type GPid;
2484
2485 G_END_DECLS
2486
2487 #endif /* GLIBCONFIG_H */
2488 _______EOF
2489
2490
2491         if cmp -s $outfile glibconfig.h; then
2492           AC_MSG_NOTICE([glibconfig.h is unchanged])
2493           rm -f $outfile
2494         else
2495           mv $outfile glibconfig.h
2496         fi
2497 ],[
2498
2499 # Note that if two cases are the same, case goes with the first one.
2500 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
2501 # on variable expansion in case labels.  Look at the generated config.status
2502 # for a hint.
2503
2504 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2505   glib_header_alloca_h="$ac_cv_working_alloca_h"
2506 else
2507   glib_header_alloca_h="$ac_cv_header_alloca_h"
2508 fi
2509
2510 case xyes in
2511 x$ac_cv_header_float_h)
2512   glib_float_h=yes
2513   glib_mf=FLT_MIN glib_Mf=FLT_MAX
2514   glib_md=DBL_MIN glib_Md=DBL_MAX
2515   ;;
2516 x$ac_cv_header_values_h)
2517   glib_values_h=yes
2518   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
2519   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
2520   ;;
2521 esac
2522
2523 case xyes in
2524 x$ac_cv_header_limits_h)
2525   glib_limits_h=yes
2526   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
2527   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
2528   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
2529   ;;
2530 x$ac_cv_header_values_h)
2531   glib_values_h=yes
2532   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
2533   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
2534   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
2535   ;;
2536 esac
2537
2538 if test x$ac_cv_header_sys_poll_h = xyes ; then
2539   glib_sys_poll_h=yes
2540 fi
2541
2542 case 2 in
2543 $ac_cv_sizeof_short)
2544   gint16=short
2545   gint16_modifier='"h"'
2546   gint16_format='"hi"'
2547   guint16_format='"hu"'
2548   ;;
2549 $ac_cv_sizeof_int)
2550   gint16=int
2551   gint16_modifier='""'
2552   gint16_format='"i"'
2553   guint16_format='"u"'
2554   ;;
2555 esac
2556 case 4 in
2557 $ac_cv_sizeof_short)
2558   gint32=short
2559   gint32_modifier='"h"'
2560   gint32_format='"hi"'
2561   guint32_format='"hu"'
2562   ;;
2563 $ac_cv_sizeof_int)
2564   gint32=int
2565   gint32_modifier='""'
2566   gint32_format='"i"'
2567   guint32_format='"u"'
2568   ;;
2569 $ac_cv_sizeof_long)
2570   gint32=long
2571   gint32_modifier='"l"'
2572   gint32_format='"li"'
2573   guint32_format='"lu"'
2574   ;;
2575 esac
2576 case 8 in
2577 $ac_cv_sizeof_int)
2578   gint64=int
2579   gint64_modifier='""'
2580   gint64_format='"i"'
2581   guint64_format='"u"'
2582   glib_extension=
2583   gint64_constant='(val)'
2584   guint64_constant='(val)'
2585   ;;
2586 $ac_cv_sizeof_long)
2587   gint64=long
2588   gint64_modifier='"l"'
2589   gint64_format='"li"'
2590   guint64_format='"lu"'
2591   glib_extension=
2592   gint64_constant='(val##L)'
2593   guint64_constant='(val##UL)'
2594   ;;
2595 $ac_cv_sizeof_long_long)
2596   gint64='long long'
2597   if test -n "$glib_cv_long_long_format"; then
2598     gint64_modifier='"'$glib_cv_long_long_format'"'
2599     gint64_format='"'$glib_cv_long_long_format'i"'
2600     guint64_format='"'$glib_cv_long_long_format'u"'
2601   fi
2602   glib_extension='G_GNUC_EXTENSION '
2603   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
2604   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
2605   ;;
2606 $ac_cv_sizeof___int64)
2607   gint64='__int64'
2608   if test -n "$glib_cv_long_long_format"; then
2609     gint64_modifier='"'$glib_cv_long_long_format'"'
2610     gint64_format='"'$glib_cv_long_long_format'i"'
2611     guint64_format='"'$glib_cv_long_long_format'u"'
2612   fi
2613   glib_extension=
2614   gint64_constant='(val##i64)'
2615   guint64_constant='(val##ui64)'
2616   ;;
2617 esac
2618 glib_size_t=$ac_cv_sizeof_size_t
2619 glib_size_type_define=$glib_size_type
2620 glib_void_p=$ac_cv_sizeof_long
2621 glib_long=$ac_cv_sizeof_void_p
2622
2623 case $glib_size_type in
2624 short)
2625   gsize_modifier='"h"'
2626   gsize_format='"hu"'
2627   gssize_format='"hi"'
2628   glib_msize_type='SHRT'
2629   ;;
2630 int)
2631   gsize_modifier='""'
2632   gsize_format='"u"'
2633   gssize_format='"i"'
2634   glib_msize_type='INT'
2635   ;;
2636 long)
2637   gsize_modifier='"l"'
2638   gsize_format='"lu"'
2639   gssize_format='"li"'
2640   glib_msize_type='LONG'
2641   ;;
2642 esac
2643
2644 gintbits=`expr $ac_cv_sizeof_int \* 8`
2645 glongbits=`expr $ac_cv_sizeof_long \* 8`
2646
2647
2648 case $ac_cv_sizeof_void_p in
2649 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
2650 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
2651 *)                      glib_unknown_void_p=yes ;;
2652 esac
2653
2654
2655 case xyes in
2656 x$ac_cv_func_atexit)
2657   glib_atexit="
2658 #ifdef NeXT /* @#%@! NeXTStep */
2659 # define g_ATEXIT(proc) (!atexit (proc))
2660 #else
2661 # define g_ATEXIT(proc) (atexit (proc))
2662 #endif"
2663   ;;
2664 x$ac_cv_func_on_exit)
2665   glib_atexit="
2666 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
2667   ;;
2668 esac
2669
2670 case xyes in
2671 x$ac_cv_func_memmove)
2672   glib_memmove='
2673 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
2674   ;;
2675 x$glib_cv_working_bcopy)
2676   glib_memmove="
2677 /* memmove isn't available, but bcopy can copy overlapping memory regions */
2678 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
2679   ;;
2680 *)
2681   glib_memmove="
2682 /* memmove isn't found and bcopy can't copy overlapping memory regions,
2683  * so we have to roll our own copy routine. */
2684 void g_memmove (void* dest, const void * src, unsigned long len);"
2685   ;;
2686 esac
2687
2688 glib_defines="
2689 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
2690 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
2691 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
2692 "
2693
2694 case xyes in
2695 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
2696 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
2697 *)                      glib_vacopy=''
2698 esac
2699
2700 if test x$glib_cv_va_val_copy = xno; then
2701   glib_vacopy="\$glib_vacopy
2702 #define G_VA_COPY_AS_ARRAY 1"
2703 fi
2704
2705 if test x$glib_cv_hasinline = xyes; then
2706     glib_inline='#define G_HAVE_INLINE 1'
2707 fi
2708 if test x$glib_cv_has__inline = xyes; then
2709     glib_inline="\$glib_inline
2710 #define G_HAVE___INLINE 1"
2711 fi
2712 if test x$glib_cv_has__inline__ = xyes; then
2713     glib_inline="\$glib_inline
2714 #define G_HAVE___INLINE__ 1"
2715 fi
2716
2717 g_have_gnuc_varargs=$g_have_gnuc_varargs
2718 g_have_iso_c_varargs=$g_have_iso_c_varargs
2719 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
2720
2721 g_can_inline=$g_can_inline
2722 g_have_gnuc_visibility=$g_have_gnuc_visibility
2723
2724 case xyes in
2725 x$ac_cv_c_bigendian)
2726   g_byte_order=G_BIG_ENDIAN
2727   g_bs_native=BE
2728   g_bs_alien=LE
2729   ;;
2730 *)
2731   g_byte_order=G_LITTLE_ENDIAN
2732   g_bs_native=LE
2733   g_bs_alien=BE
2734   ;;
2735 esac
2736
2737 g_pollin=$glib_cv_value_POLLIN
2738 g_pollout=$glib_cv_value_POLLOUT
2739 g_pollpri=$glib_cv_value_POLLPRI
2740 g_pollhup=$glib_cv_value_POLLHUP
2741 g_pollerr=$glib_cv_value_POLLERR
2742 g_pollnval=$glib_cv_value_POLLNVAL
2743
2744 g_stack_grows=$glib_cv_stack_grows
2745
2746 g_have_eilseq=$have_eilseq
2747
2748 case x$have_threads in
2749 xno)    g_enable_threads_def="#undef";;
2750 *)      g_enable_threads_def="#define";;
2751 esac
2752
2753 g_threads_impl_def=$g_threads_impl
2754
2755 g_mutex_has_default="$mutex_has_default"
2756 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
2757 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
2758 g_mutex_contents="$glib_cv_byte_contents_gmutex"
2759
2760 g_memory_barrier_needed="$glib_memory_barrier_needed"
2761
2762 g_module_suffix="$glib_gmodule_suffix"
2763
2764 g_pid_type="$glib_pid_type"
2765 case $host in
2766   *-*-beos*)
2767     glib_os="#define G_OS_BEOS"
2768     ;;
2769   *-*-cygwin*)
2770     glib_os="#define G_OS_UNIX
2771 #define G_PLATFORM_WIN32
2772 #define G_WITH_CYGWIN"
2773     ;;
2774   *-*-mingw*)
2775     glib_os="#define G_OS_WIN32
2776 #define G_PLATFORM_WIN32"
2777     ;;
2778   *)
2779     glib_os="#define G_OS_UNIX"
2780     ;;
2781 esac
2782 ])
2783
2784 AC_CONFIG_FILES([
2785 glib-2.0.pc
2786 glib-2.0-uninstalled.pc
2787 gmodule-2.0.pc
2788 gmodule-export-2.0.pc
2789 gmodule-no-export-2.0.pc
2790 gmodule-2.0-uninstalled.pc
2791 gmodule-no-export-2.0-uninstalled.pc
2792 gthread-2.0.pc
2793 gthread-2.0-uninstalled.pc
2794 gobject-2.0.pc
2795 gobject-2.0-uninstalled.pc
2796 glib-zip
2797 glib-gettextize
2798 Makefile
2799 build/Makefile
2800 build/win32/Makefile
2801 build/win32/dirent/Makefile
2802 build/win32/vs8/Makefile
2803 glib/Makefile
2804 glib/libcharset/Makefile
2805 glib/gnulib/Makefile
2806 gmodule/Makefile
2807 gmodule/gmoduleconf.h
2808 gobject/Makefile
2809 gobject/glib-mkenums
2810 gthread/Makefile
2811 po/Makefile.in
2812 docs/Makefile
2813 docs/reference/Makefile
2814 docs/reference/glib/Makefile
2815 docs/reference/glib/version.xml
2816 docs/reference/gobject/Makefile
2817 docs/reference/gobject/version.xml
2818 tests/Makefile
2819 tests/gobject/Makefile
2820 tests/refcount/Makefile
2821 m4macros/Makefile
2822 ])
2823
2824 AC_CONFIG_COMMANDS([chmod-scripts],
2825 [chmod 0755 glib-zip
2826 chmod 0755 glib-gettextize
2827 chmod 0755 gobject/glib-mkenums])
2828
2829 # we want to invoke this macro solely so that the config.status script
2830 # and automake generated makefiles know about these generated files.
2831 # They are only needed to distcheck the package
2832 if false; then
2833   AC_CONFIG_FILES([
2834     INSTALL
2835     README
2836     config.h.win32
2837     glibconfig.h.win32
2838     glib/makefile.msc
2839     glib/glib.rc
2840     gmodule/makefile.msc
2841     gmodule/gmodule.rc
2842     gobject/makefile.msc
2843     gobject/gobject.rc
2844     gthread/makefile.msc
2845     gthread/gthread.rc
2846     tests/makefile.msc
2847   ])
2848 fi
2849
2850 AC_OUTPUT