configure.in

   1 AC_PREREQ(2.57)
   2 AC_INIT(cryptsetup,1.1.3)
   3
   4 dnl library version from <major>.<minor>.<release>[-<suffix>]
   5 LIBCRYPTSETUP_VERSION=$(echo $PACKAGE_VERSION | cut -f1 -d-)
   6 LIBCRYPTSETUP_VERSION_INFO=1:0:0
   7
   8 AC_CONFIG_SRCDIR(src/cryptsetup.c)
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 AM_CONFIG_HEADER([config.h:config.h.in])
  12 AM_INIT_AUTOMAKE(dist-bzip2)
  13
  14 if test "x$prefix" = "xNONE"; then
  15         sysconfdir=/etc
  16 fi
  17 AC_PREFIX_DEFAULT(/usr)
  18
  19 AC_CANONICAL_HOST
  20 AC_GNU_SOURCE
  21 AC_PROG_CC
  22 AM_PROG_CC_C_O
  23 AC_PROG_CPP
  24 AC_PROG_INSTALL
  25 AC_PROG_MAKE_SET
  26 AC_ENABLE_STATIC(no)
  27 AM_PROG_LIBTOOL
  28
  29 AC_HEADER_DIRENT
  30 AC_HEADER_STDC
  31 AC_CHECK_HEADERS(fcntl.h malloc.h inttypes.h sys/ioctl.h sys/mman.h \
  32         ctype.h unistd.h locale.h)
  33
  34 AC_CHECK_HEADERS(uuid/uuid.h,,[AC_MSG_ERROR('You need the uuid library')])
  35 AC_CHECK_HEADER(libdevmapper.h,,[AC_MSG_ERROR('You need the device-mapper library')])
  36
  37 saved_LIBS=$LIBS
  38 AC_CHECK_LIB(uuid, uuid_clear, ,[AC_MSG_ERROR('You need the uuid library')])
  39 AC_SUBST(UUID_LIBS, $LIBS)
  40 LIBS=$saved_LIBS
  41
  42
  43 AM_PATH_LIBGCRYPT(1.1.42,,[AC_MSG_ERROR('You need the gcrypt library')])
  44
  45 AC_CHECK_FUNCS([posix_memalign])
  46
  47 AC_C_CONST
  48 AC_C_BIGENDIAN
  49 AC_TYPE_OFF_T
  50 AC_STRUCT_ST_RDEV
  51 AC_SYS_LARGEFILE
  52
  53 AC_PROG_GCC_TRADITIONAL
  54
  55 dnl ==========================================================================
  56
  57 AM_GNU_GETTEXT([external],[need-ngettext])
  58 AM_GNU_GETTEXT_VERSION([0.15])
  59
  60 dnl ==========================================================================
  61
  62 saved_LIBS=$LIBS
  63 AC_CHECK_LIB(popt, poptConfigFileToString,,
  64         [AC_MSG_ERROR([You need popt 1.7 or newer to compile.])])
  65 AC_SUBST(POPT_LIBS, $LIBS)
  66 LIBS=$saved_LIBS
  67
  68 dnl ==========================================================================
  69 saved_LIBS=$LIBS
  70
  71 AC_ARG_ENABLE(shared-library,
  72 [  --disable-shared-library
  73                           disable building of shared cryptsetup library],,
  74 enable_shared_library=yes)
  75 AM_CONDITIONAL(STATIC_LIBRARY, test x$enable_shared_library = xno)
  76
  77 AC_ARG_ENABLE(selinux,
  78 [  --disable-selinux       disable selinux support [[default=auto]]],[], [])
  79
  80 AC_ARG_ENABLE([udev],AS_HELP_STRING([--disable-udev],[disable udev support]),[], enable_udev=yes)
  81
  82 dnl Try to use pkg-config for devmapper, but fallback to old detection
  83 PKG_CHECK_MODULES([DEVMAPPER], [devmapper >= 1.02.03],, [
  84         AC_CHECK_LIB(devmapper, dm_task_set_name,,
  85                 [AC_MSG_ERROR([You need the device-mapper library.])])
  86         AC_CHECK_LIB(devmapper, dm_task_set_message,,
  87                 [AC_MSG_ERROR([The device-mapper library on your system is too old.])])
  88         DEVMAPPER_LIBS=$LIBS
  89 ])
  90 LIBS=$saved_LIBS
  91
  92 LIBS="$LIBS $DEVMAPPER_LIBS"
  93 AC_CHECK_DECLS([DM_UDEV_DISABLE_DISK_RULES_FLAG], [have_cookie=yes], [have_cookie=no], [#include <libdevmapper.h>])
  94 if test "x$enable_udev" = xyes; then
  95         if test "x$have_cookie" = xno; then
  96                 AC_MSG_WARN([The device-mapper library on your system has no udev support, udev support disabled.])
  97         else
  98                 AC_DEFINE(USE_UDEV, 1, [Try to use udev synchronisation?])
  99         fi
 100 fi
 101 LIBS=$saved_LIBS
 102
 103 dnl Magic for cryptsetup.static build.
 104 if test x$enable_static = xyes; then
 105         saved_PKG_CONFIG=$PKG_CONFIG
 106         PKG_CONFIG="$PKG_CONFIG --static"
 107
 108         LIBS="$saved_LIBS $LIBGCRYPT_LIBS -static"
 109         AC_CHECK_LIB(gcrypt, gcry_check_version,,
 110                 AC_MSG_ERROR([Cannot find static gcrypt library.]),
 111                 [-lgpg-error])
 112         LIBGCRYPT_STATIC_LIBS="$LIBGCRYPT_LIBS -lgpg-error"
 113
 114         LIBS="$saved_LIBS -static"
 115         AC_CHECK_LIB(popt, poptGetContext,,
 116                 AC_MSG_ERROR([Cannot find static popt library.]))
 117
 118         dnl Try to detect needed device-mapper static libraries, try pkg-config first.
 119         LIBS="$saved_LIBS -static"
 120         PKG_CHECK_MODULES([DEVMAPPER_STATIC], [devmapper >= 1.02.27],,[
 121                 DEVMAPPER_STATIC_LIBS=$DEVMAPPER_LIBS
 122                 if test "x$enable_selinux" != xno; then
 123                         AC_CHECK_LIB(sepol, sepol_bool_set)
 124                         AC_CHECK_LIB(selinux, is_selinux_enabled)
 125                         DEVMAPPER_STATIC_LIBS="$DEVMAPPER_STATIC_LIBS $LIBS"
 126                 fi
 127         ])
 128         LIBS="$saved_LIBS $DEVMAPPER_STATIC_LIBS"
 129         AC_CHECK_LIB(devmapper, dm_task_set_uuid,,
 130                 AC_MSG_ERROR([Cannot link with static device-mapper library.]))
 131
 132         LIBS=$saved_LIBS
 133         PKG_CONFIG=$saved_PKG_CONFIG
 134 fi
 135
 136 AC_SUBST([DEVMAPPER_LIBS])
 137 AC_SUBST([DEVMAPPER_STATIC_LIBS])
 138 AC_SUBST([LIBGCRYPT_STATIC_LIBS])
 139 AC_SUBST([LIBCRYPTSETUP_VERSION])
 140 AC_SUBST([LIBCRYPTSETUP_VERSION_INFO])
 141
 142 dnl ==========================================================================
 143 AC_DEFUN([CS_DEFINE],
 144         [AC_DEFINE_UNQUOTED(DEFAULT_[]m4_translit([$1], [-a-z], [_A-Z]), [$2], [$3])
 145 ])
 146
 147 AC_DEFUN([CS_STR_WITH], [AC_ARG_WITH([$1],
 148         [AS_HELP_STRING(--with-[$1], [default $2 [$3]])],
 149         [CS_DEFINE([$1], ["$withval"], [$2])],
 150         [CS_DEFINE([$1], ["$3"], [$2])]
 151 )])
 152
 153 AC_DEFUN([CS_NUM_WITH], [AC_ARG_WITH([$1],
 154         [AS_HELP_STRING(--with-[$1], [default $2 [$3]])],
 155         [CS_DEFINE([$1], [$withval], [$2])],
 156         [CS_DEFINE([$1], [$3], [$2])]
 157 )])
 158
 159 CS_STR_WITH([plain-hash],   [password hashing function for plain mode], [ripemd160])
 160 CS_STR_WITH([plain-cipher], [cipher for plain mode], [aes])
 161 CS_STR_WITH([plain-mode],   [cipher mode for plain mode], [cbc-essiv:sha256])
 162 CS_NUM_WITH([plain-keybits],[key length in bits for plain mode], [256])
 163
 164 CS_STR_WITH([luks1-hash],   [hash function for LUKS1 header], [sha1])
 165 CS_STR_WITH([luks1-cipher], [cipher for LUKS1], [aes])
 166 CS_STR_WITH([luks1-mode],   [cipher mode for LUKS1], [cbc-essiv:sha256])
 167 CS_NUM_WITH([luks1-keybits],[key length in bits for LUKS1], [256])
 168
 169 dnl ==========================================================================
 170
 171 AM_CONDITIONAL(STATIC_CRYPTSETUP, test x$enable_static = xyes)
 172 AM_CONDITIONAL(DYNAMIC_CRYPTSETUP, test x$enable_static = xno)
 173
 174 dnl ==========================================================================
 175
 176 AC_OUTPUT([ Makefile
 177 lib/Makefile
 178 lib/libcryptsetup.pc
 179 src/Makefile
 180 po/Makefile.in
 181 luks/Makefile
 182 man/Makefile
 183 tests/Makefile
 184 ])