configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.53)dnl              dnl Minimum Autoconf version required.
   3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 dnl This is here so we can set $subdirs directly based on configure fragments.
   9 AC_CONFIG_SUBDIRS()
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_PROG_CC
  14 if test $host != $build; then
  15   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  16 fi
  17 AC_SUBST(cross_compiling)
  18 AC_PROG_CPP
  19 # We need the C++ compiler only for testing.
  20 AC_PROG_CXX
  21
  22 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
  23   AC_MSG_ERROR([you must configure in a separate build directory])
  24 fi
  25
  26 # This will get text that should go into config.make.
  27 config_vars=
  28
  29 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  30 AC_ARG_WITH([gd],
  31             AC_HELP_STRING([--with-gd=DIR],
  32                            [find libgd include dir and library with prefix DIR]),
  33             [dnl
  34 case "$with_gd" in
  35 yes|''|no) ;;
  36 *) libgd_include="-I$withval/include"
  37    libgd_ldflags="-L$withval/lib" ;;
  38 esac
  39 ])
  40 AC_ARG_WITH([gd-include],
  41             AC_HELP_STRING([--with-gd-include=DIR],
  42                            [find libgd include files in DIR]),
  43             [dnl
  44 case "$with_gd_include" in
  45 ''|no) ;;
  46 *) libgd_include="-I$withval" ;;
  47 esac
  48 ])
  49 AC_ARG_WITH([gd-lib],
  50             AC_HELP_STRING([--with-gd-lib=DIR],
  51                            [find libgd library files in DIR]),
  52             [dnl
  53 case "$with_gd_lib" in
  54 ''|no) ;;
  55 *) libgd_ldflags="-L$withval" ;;
  56 esac
  57 ])
  58
  59 if test -n "$libgd_include"; then
  60   config_vars="$config_vars
  61 CFLAGS-memusagestat.c = $libgd_include"
  62 fi
  63 if test -n "$libgd_ldflags"; then
  64   config_vars="$config_vars
  65 libgd-LDFLAGS = $libgd_ldflags"
  66 fi
  67
  68 dnl Arguments to specify presence of other packages/features.
  69 AC_ARG_WITH([fp],
  70             AC_HELP_STRING([--with-fp],
  71                            [if using floating-point hardware @<:@default=yes@:>@]),
  72             [with_fp=$withval],
  73             [with_fp=yes])
  74 AC_SUBST(with_fp)
  75 AC_ARG_WITH([binutils],
  76             AC_HELP_STRING([--with-binutils=PATH],
  77                            [specify location of binutils (as and ld)]),
  78             [path_binutils=$withval],
  79             [path_binutils=''])
  80 AC_ARG_WITH([selinux],
  81             AC_HELP_STRING([--with-selinux],
  82                            [if building with SELinux support]),
  83             [with_selinux=$withval],
  84             [with_selinux=auto])
  85
  86 AC_ARG_WITH([headers],
  87             AC_HELP_STRING([--with-headers=PATH],
  88                            [location of system headers to use
  89                             (for example /usr/src/linux/include)
  90                             @<:@default=compiler default@:>@]),
  91             [sysheaders=$withval],
  92             [sysheaders=''])
  93
  94 AC_SUBST(use_default_link)
  95 AC_ARG_WITH([default-link],
  96             AC_HELP_STRING([--with-default-link],
  97                            [do not use explicit linker scripts]),
  98             [use_default_link=$withval],
  99             [use_default_link=default])
 100
 101 AC_ARG_ENABLE([sanity-checks],
 102               AC_HELP_STRING([--disable-sanity-checks],
 103                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 104               [enable_sanity=$enableval],
 105               [enable_sanity=yes])
 106
 107 AC_SUBST(enable_check_abi)
 108 AC_ARG_ENABLE([check-abi],
 109               AC_HELP_STRING([--enable-check-abi],
 110                              [do "make check-abi" in "make check" (no/warn/yes)
 111                               @<:@default=no@:>@]),
 112               [enable_check_abi=$enableval],
 113               [enable_check_abi=no])
 114
 115 dnl Arguments to enable or disable building the static, shared, profiled,
 116 dnl and -fomit-frame-pointer libraries.
 117 dnl I've disabled this for now since we cannot build glibc without static
 118 dnl libraries built in the moment.
 119 dnl AC_ARG_ENABLE([static],
 120 dnl               AC_HELP_STRING([--enable-static],
 121 dnl                              [build static library @<:@default=yes@:>@]),
 122 dnl               [static=$enableval],
 123 dnl               [static=yes])
 124 static=yes
 125 AC_ARG_ENABLE([shared],
 126               AC_HELP_STRING([--enable-shared],
 127                              [build shared library @<:@default=yes if GNU ld@:>@]),
 128               [shared=$enableval],
 129               [shared=yes])
 130 AC_ARG_ENABLE([profile],
 131               AC_HELP_STRING([--enable-profile],
 132                              [build profiled library @<:@default=no@:>@]),
 133               [profile=$enableval],
 134               [profile=no])
 135 AC_ARG_ENABLE([versioning],
 136               AC_HELP_STRING([--disable-versioning],
 137                              [do not include versioning information in the library objects @<:@default=yes if supported@:>@]),
 138               [enable_versioning=$enableval],
 139               [enable_versioning=yes])
 140
 141 AC_ARG_ENABLE([oldest-abi],
 142               AC_HELP_STRING([--enable-oldest-abi=ABI],
 143                              [configure the oldest ABI supported @<:@e.g. 2.2@:>@ @<:@default=glibc default@:>@]),
 144               [oldest_abi=$enableval],
 145               [oldest_abi=no])
 146 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
 147   oldest_abi=default
 148 else
 149   AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
 150 fi
 151 AC_SUBST(oldest_abi)
 152
 153 AC_ARG_ENABLE([stackguard-randomization],
 154               AC_HELP_STRING([--enable-stackguard-randomization],
 155                              [initialize __stack_chk_guard canary with a random number at program start]),
 156               [enable_stackguard_randomize=$enableval],
 157               [enable_stackguard_randomize=no])
 158 if test "$enable_stackguard_randomize" = yes; then
 159   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 160 fi
 161
 162 dnl Generic infrastructure for drop-in additions to libc.
 163 AC_ARG_ENABLE([add-ons],
 164               AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
 165                              [configure and build add-ons in DIR1,DIR2,...
 166                               search for add-ons if no parameter given]),
 167                              , [enable_add_ons=yes])
 168
 169 AC_ARG_ENABLE([hidden-plt],
 170               AC_HELP_STRING([--disable-hidden-plt],
 171                              [do not hide internal function calls to avoid PLT]),
 172               [hidden=$enableval],
 173               [hidden=yes])
 174 if test "x$hidden" = xno; then
 175   AC_DEFINE(NO_HIDDEN)
 176 fi
 177
 178 AC_ARG_ENABLE([bind-now],
 179               AC_HELP_STRING([--enable-bind-now],
 180                              [disable lazy relocations in DSOs]),
 181               [bindnow=$enableval],
 182               [bindnow=no])
 183 AC_SUBST(bindnow)
 184
 185 dnl On some platforms we cannot use dynamic loading.  We must provide
 186 dnl static NSS modules.
 187 AC_ARG_ENABLE([static-nss],
 188               AC_HELP_STRING([--enable-static-nss],
 189                              [build static NSS modules @<:@default=no@:>@]),
 190               [static_nss=$enableval],
 191               [static_nss=no])
 192 dnl Enable static NSS also if we build no shared objects.
 193 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 194   static_nss=yes
 195   AC_DEFINE(DO_STATIC_NSS)
 196 fi
 197
 198 AC_ARG_ENABLE([force-install],
 199               AC_HELP_STRING([--disable-force-install],
 200                              [don't force installation of files from this package, even if they are older than the installed files]),
 201               [force_install=$enableval],
 202               [force_install=yes])
 203 AC_SUBST(force_install)
 204
 205 dnl On some platforms we allow dropping compatibility with all kernel
 206 dnl versions.
 207 AC_ARG_ENABLE([kernel],
 208               AC_HELP_STRING([--enable-kernel=VERSION],
 209                              [compile for compatibility with kernel not older than VERSION]),
 210               [minimum_kernel=$enableval],
 211               [])
 212 dnl Prevent unreasonable values.
 213 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 214   # Better nothing than this.
 215   minimum_kernel=""
 216 else
 217   if test "$minimum_kernel" = current; then
 218     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 219   fi
 220 fi
 221
 222 dnl For the development we sometimes want gcc to issue even more warnings.
 223 dnl This is not the default since many of the extra warnings are not
 224 dnl appropriate.
 225 AC_ARG_ENABLE([all-warnings],
 226               AC_HELP_STRING([--enable-all-warnings],
 227                              [enable all useful warnings gcc can issue]),
 228               [all_warnings=$enableval],
 229               [])
 230 AC_SUBST(all_warnings)
 231
 232 AC_ARG_ENABLE([multi-arch],
 233               AC_HELP_STRING([--enable-multi-arch],
 234                              [enable single DSO with optimizations for multiple architectures]),
 235               [multi_arch=$enableval],
 236               [multi_arch=default])
 237
 238 AC_ARG_ENABLE([nss-crypt],
 239               AC_HELP_STRING([--enable-nss-crypt],
 240                              [enable libcrypt to use nss]),
 241               [nss_crypt=$enableval],
 242               [nss_crypt=no])
 243 if test x$nss_crypt = xyes; then
 244   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 245   if test $? -ne 0; then
 246     AC_MSG_ERROR([cannot find include directory with nss-config])
 247   fi
 248   old_CFLAGS="$CFLAGS"
 249   CFLAGS="$CFLAGS $nss_includes"
 250   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 251 #include <hasht.h>
 252 #include <nsslowhash.h>
 253 void f (void) { NSSLOW_Init (); }])],
 254              libc_cv_nss_crypt=yes,
 255              AC_MSG_ERROR([
 256 cannot find NSS headers with lowlevel hash function interfaces]))
 257   old_LIBS="$LIBS"
 258   LIBS="$LIBS -lfreebl3"
 259   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 260 #include <hasht.h>
 261 #include <nsslowhash.h>],
 262                                   [NSSLOW_Init();])],
 263                  libc_cv_nss_crypt=yes,
 264                  AC_MSG_ERROR([
 265 cannot link program using lowlevel NSS hash functions]))
 266   CFLAGS="$old_CFLAGS"
 267   LIBS="$old_LIBS"
 268 else
 269   libc_cv_nss_crypt=no
 270 fi
 271 AC_SUBST(libc_cv_nss_crypt)
 272
 273 # The way shlib-versions is used to generate soversions.mk uses a
 274 # fairly simplistic model for name recognition that can't distinguish
 275 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 276 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 277 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 278 case "$host_os" in
 279 linux*)
 280   ;;
 281 gnu*)
 282   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 283   ;;
 284 esac
 285
 286 # We keep the original values in `$config_*' and never modify them, so we
 287 # can write them unchanged into config.make.  Everything else uses
 288 # $machine, $vendor, and $os, and changes them whenever convenient.
 289 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 290
 291 # Don't allow vendor == "unknown"
 292 test "$config_vendor" = unknown && config_vendor=
 293 config_os="`echo $config_os | sed 's/^unknown-//'`"
 294
 295 # Some configurations imply other options.
 296 elf=yes
 297
 298 # The configure fragment of an add-on port can modify these to supplement
 299 # or override the table in the case statement below.  No fragment should
 300 # ever change the config_* variables, however.
 301 machine=$config_machine
 302 vendor=$config_vendor
 303 os=$config_os
 304 base_os=''
 305
 306 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
 307 # Unify this here.
 308 if test "$machine" = rs6000; then
 309   machine="powerpc"
 310 fi
 311
 312 # Braindead PowerPC box with absolutely no FPU.
 313 case "$machine-$host_os" in
 314   powerpc*-*soft)
 315     with_fp=no
 316     ;;
 317 esac
 318
 319 submachine=
 320 AC_ARG_WITH([cpu],
 321             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 322             [dnl
 323   case "$withval" in
 324   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 325   no) ;;
 326   *) submachine="$withval" ;;
 327   esac
 328 ])
 329
 330 # An add-on can set this when it wants to disable the sanity check below.
 331 libc_config_ok=no
 332
 333 dnl Having this here, though empty, makes sure that if add-ons' fragments
 334 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
 335 dnl our AC_OUTPUT will actually use it.
 336 AC_CONFIG_SUBDIRS()
 337
 338 case "$enable_add_ons" in
 339 ''|no) add_ons= ;;
 340 yes|'*')
 341  add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
 342           sed 's@/[[^/]]*$@@' | sort | uniq`
 343          add_ons_automatic=yes
 344          ;;
 345 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
 346        add_ons_automatic=no ;;
 347 esac
 348
 349 configured_add_ons=
 350 add_ons_sfx=
 351 add_ons_pfx=
 352 if test x"$add_ons" != x; then
 353   for f in $add_ons; do
 354     # Some sanity checks
 355     case "$f" in
 356     crypt)
 357       AC_MSG_ERROR([
 358 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 359 *** part of glibc and using the old add-on will not work with this
 360 *** release.  Start again with fresh sources and without the old
 361 *** \`crypt' add-on.])
 362     ;;
 363     localedata)
 364       AC_MSG_ERROR([
 365 *** It seems that you're using an old \`localedata' add-on.  localedata
 366 *** is now part of glibc and using the old add-on will not work with
 367 *** this release.  Start again with fresh sources and without the old
 368 *** \`localedata' add-on.])
 369     ;;
 370     esac
 371   done
 372
 373   # Now source each add-on's configure fragment.
 374   # The fragments can use $srcdir/$libc_add_on to find themselves,
 375   # and test $add_ons_automatic to see if they were explicitly requested.
 376   # A fragment can clear (or even change) $libc_add_on to affect
 377   # whether it goes into the list to be actually used in the build.
 378   use_add_ons=
 379   for libc_add_on in $add_ons; do
 380     # Test whether such a directory really exists.
 381     # It can be absolute, or relative to $srcdir, or relative to the build dir.
 382     case "$libc_add_on" in
 383     /*)
 384       libc_add_on_srcdir=$libc_add_on
 385       ;;
 386     *)
 387       test -d "$srcdir/$libc_add_on" || {
 388         if test -d "$libc_add_on"; then
 389           libc_add_on="`pwd`/$libc_add_on"
 390         else
 391           AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
 392         fi
 393       }
 394       libc_add_on_srcdir=$srcdir/$libc_add_on
 395       ;;
 396     esac
 397
 398     libc_add_on_frag=$libc_add_on_srcdir/configure
 399     libc_add_on_canonical=
 400     libc_add_on_config_subdirs=
 401     if test -r "$libc_add_on_frag"; then
 402       AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
 403       libc_add_on_canonical=unknown
 404       libc_add_on_subdirs=
 405       . "$libc_add_on_frag"
 406       test -z "$libc_add_on" || {
 407         configured_add_ons="$configured_add_ons $libc_add_on"
 408         if test "x$libc_add_on_canonical" = xunknown; then
 409           AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
 410         fi
 411         for d in $libc_add_on_subdirs; do
 412           case "$libc_add_on" in
 413           /*) subdir_srcdir="$libc_add_on" ;;
 414           *) subdir_srcdir="\$(..)$libc_add_on" ;;
 415           esac
 416           case "$d" in
 417           .)
 418             d="${libc_add_on_canonical:-$libc_add_on}"
 419             ;;
 420           /*)
 421             subdir_srcdir="$d"
 422             ;;
 423           *)
 424             subdir_srcdir="$subdir_srcdir/$d"
 425             ;;
 426           esac
 427           d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
 428           add_on_subdirs="$add_on_subdirs $d"
 429           test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
 430 $d-srcdir = $subdir_srcdir"
 431         done
 432         for d in $libc_add_on_config_subdirs; do
 433           case "$d" in
 434           /*) AC_MSG_ERROR(dnl
 435 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
 436           esac
 437           if test ! -d "$libc_add_on_srcdir/$d"; then
 438             AC_MSG_ERROR(fragment wants to configure missing directory $d)
 439           fi
 440           case "$libc_add_on" in
 441           /*) AC_MSG_ERROR(dnl
 442 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
 443           esac
 444           subdirs="$subdirs $libc_add_on/$d"
 445         done
 446       }
 447     fi
 448     if test -n "$libc_add_on"; then
 449       if frags=`ls -d $libc_add_on_srcdir/sysdeps/*/preconfigure 2> /dev/null`
 450       then
 451         AC_MSG_CHECKING(add-on $libc_add_on for preconfigure fragments)
 452         for frag in $frags; do
 453           name=`echo "$frag" | sed 's@/[[^/]]*$@@;s@^.*/@@'`
 454           echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 455           . "$frag"
 456         done
 457         AC_MSG_RESULT()
 458       fi
 459       use_add_ons="$use_add_ons $libc_add_on"
 460       add_ons_pfx="$add_ons_pfx $libc_add_on/"
 461       test -z "$libc_add_on_canonical" ||
 462       add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
 463     fi
 464   done
 465   # Use echo to strip excess whitespace.
 466   add_ons="`echo $use_add_ons`"
 467 fi
 468 AC_SUBST(add_ons)
 469 AC_SUBST(add_on_subdirs)
 470
 471
 472 ###
 473 ### I put this here to prevent those annoying emails from people who cannot
 474 ### read and try to compile glibc on unsupported platforms.  --drepper
 475 ###
 476 ### By using the undocumented --enable-hacker-mode option for configure
 477 ### one can skip this test to make the configuration not fail for unsupported
 478 ### platforms.
 479 ###
 480 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 481   case "$machine-$host_os" in
 482   *-linux* | *-gnu* | arm*-none*)
 483     ;;
 484   *)
 485     echo "*** The GNU C library is currently not available for this platform."
 486     echo "*** So far nobody cared to port it and if there is no volunteer it"
 487     echo "*** might never happen.  So, if you have interest to see glibc on"
 488     echo "*** this platform visit"
 489     echo "***   http://www.gnu.org/software/libc/porting.html"
 490     echo "*** and join the group of porters"
 491     exit 1
 492     ;;
 493   esac
 494 fi
 495
 496 dnl We need to use [ and ] for other purposes for a while now.
 497 changequote(,)dnl
 498 # Expand the configuration machine name into a subdirectory by architecture
 499 # type and particular chip.  If an add-on configure fragment already set
 500 # base_machine, we don't change it.
 501 test -n "$base_machine" || case "$machine" in
 502 i[34567]86)     base_machine=i386 machine=i386/$machine ;;
 503 powerpc)        base_machine=powerpc machine=powerpc/powerpc32 ;;
 504 powerpc64)      base_machine=powerpc machine=powerpc/powerpc64 ;;
 505 s390)           base_machine=s390 machine=s390/s390-32 ;;
 506 s390x)          base_machine=s390 machine=s390/s390-64 ;;
 507 sh3*)           base_machine=sh machine=sh/sh3 ;;
 508 sh4*)           base_machine=sh machine=sh/sh4 ;;
 509 sparc | sparcv[67])
 510                 base_machine=sparc machine=sparc/sparc32 ;;
 511 sparcv8 | supersparc | hypersparc)
 512                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 513 sparcv8plus | sparcv8plusa | sparcv9)
 514                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 515 sparcv8plusb | sparcv9b)
 516                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9b ;;
 517 sparcv9v)
 518                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v ;;
 519 sparcv9v2)
 520                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v2 ;;
 521 sparc64)
 522                 base_machine=sparc machine=sparc/sparc64 ;;
 523 sparc64b)
 524                 base_machine=sparc machine=sparc/sparc64/sparcv9b ;;
 525 sparc64v)
 526                 base_machine=sparc machine=sparc/sparc64/sparcv9v ;;
 527 sparc64v2)
 528                 base_machine=sparc machine=sparc/sparc64/sparcv9v2 ;;
 529 *)              base_machine=$machine ;;
 530 esac
 531 changequote([,])dnl
 532 AC_SUBST(base_machine)
 533
 534 if test "$base_machine" = "i386"; then
 535   AC_DEFINE(USE_REGPARMS)
 536 fi
 537
 538 # For the multi-arch option we need support in the assembler.
 539 AC_CACHE_CHECK([for assembler gnu_indirect_function symbol type support],
 540                libc_cv_asm_gnu_indirect_function, [dnl
 541 cat > conftest.s <<EOF
 542 .type foo,%gnu_indirect_function
 543 EOF
 544 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD;
 545 then
 546   libc_cv_asm_gnu_indirect_function=yes
 547 else
 548   libc_cv_asm_gnu_indirect_function=no
 549 fi
 550 rm -f conftest*])
 551
 552 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 553 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 554 cat > conftest.s <<EOF
 555 .text
 556 EOF
 557 libc_cv_dot_text=
 558 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 559   libc_cv_dot_text=.text
 560 fi
 561 rm -f conftest*])
 562 if test -z "$libc_cv_dot_text"; then
 563   AC_MSG_RESULT(no)
 564 else
 565   AC_MSG_RESULT(yes)
 566 fi
 567
 568 AC_CACHE_CHECK(for assembler global-symbol directive,
 569                libc_cv_asm_global_directive, [dnl
 570 libc_cv_asm_global_directive=UNKNOWN
 571 for ac_globl in .globl .global .EXPORT; do
 572   cat > conftest.s <<EOF
 573         ${libc_cv_dot_text}
 574         ${ac_globl} foo
 575 foo:
 576 EOF
 577   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 578     libc_cv_asm_global_directive=${ac_globl}
 579   fi
 580   rm -f conftest*
 581   test $libc_cv_asm_global_directive != UNKNOWN && break
 582 done])
 583 if test $libc_cv_asm_global_directive = UNKNOWN; then
 584   AC_MSG_ERROR(cannot determine asm global directive)
 585 else
 586   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 587 fi
 588
 589 AC_CACHE_CHECK(for assembler .type directive prefix,
 590                libc_cv_asm_type_prefix, [dnl
 591 libc_cv_asm_type_prefix=no
 592 for ac_try_prefix in '@' '%' '#'; do
 593   cat > conftest.s <<EOF
 594         ${libc_cv_dot_text}
 595         ${libc_cv_asm_global_directive} foo
 596         .type foo, ${ac_try_prefix}object
 597         .size foo, 1
 598 foo:
 599         .byte 1
 600 EOF
 601   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 602     libc_cv_asm_type_prefix=${ac_try_prefix}
 603   fi
 604   rm -f conftest*
 605   test "x$libc_cv_asm_type_prefix" != xno && break
 606 done])
 607 if test "x$libc_cv_asm_type_prefix" != xno; then
 608   AC_DEFINE_UNQUOTED(ASM_TYPE_DIRECTIVE_PREFIX, ${libc_cv_asm_type_prefix})
 609 fi
 610
 611 if test x"$libc_cv_asm_gnu_indirect_function" != xyes -a x"$libc_cv_asm_type_prefix" = xno; then
 612   if test x"$multi_arch" = xyes; then
 613     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 614   else
 615     multi_arch=no
 616   fi
 617 fi
 618 if test x"$multi_arch" != xno; then
 619   multi_arch_d=/multiarch
 620 fi
 621
 622 # Compute the list of sysdep directories for this configuration.
 623 # This can take a while to compute.
 624 sysdep_dir=$srcdir/sysdeps
 625 AC_MSG_CHECKING(sysdep dirs)
 626 dnl We need to use [ and ] for other purposes for a while now.
 627 changequote(,)dnl
 628 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 629 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 630
 631 test "x$base_os" != x || case "$os" in
 632 gnu*)
 633   base_os=mach/hurd ;;
 634 netbsd* | 386bsd* | freebsd* | bsdi*)
 635   base_os=unix/bsd/bsd4.4 ;;
 636 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 637   base_os=unix/bsd ;;
 638 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 639   base_os=unix/sysv ;;
 640 irix6*)
 641   base_os=unix/sysv/irix6/$os ;;
 642 solaris[2-9]*)
 643   base_os=unix/sysv/sysv4 ;;
 644 none)
 645   base_os=standalone ;;
 646 esac
 647
 648 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 649 tail=$os
 650 ostry=$os
 651 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 652   ostry="$ostry /$o"
 653   tail=$o
 654 done
 655 o=`echo $tail | sed 's/[0-9]*$//'`
 656 if test $o != $tail; then
 657   ostry="$ostry /$o"
 658 fi
 659 # For linux-gnu, try linux-gnu, then linux.
 660 o=`echo $tail | sed 's/-.*$//'`
 661 if test $o != $tail; then
 662   ostry="$ostry /$o"
 663 fi
 664
 665 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 666 base=
 667 tail=$base_os
 668 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 669   set $b
 670   base="$base /$1"
 671   tail="$2"
 672 done
 673
 674 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 675 mach=
 676 tail=$machine${submachine:+/$submachine}
 677 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 678   set $m
 679   # Prepend the machine's FPU directory unless --without-fp.
 680   if test "$with_fp" = yes; then
 681     mach="$mach /$1/fpu"
 682   else
 683     mach="$mach /$1/nofpu"
 684   fi
 685   mach="$mach /$1"
 686   tail="$2"
 687 done
 688
 689 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 690 changequote([,])dnl
 691
 692 # Find what sysdep directories exist.
 693 sysnames_add_ons=
 694 sysnames=
 695 for b in $base ''; do
 696   for m0 in $mach ''; do
 697     for v in /$vendor ''; do
 698       test "$v" = / && continue
 699       for o in /$ostry ''; do
 700         test "$o" = / && continue
 701         for m in $multi_arch_d $mach ''; do
 702           for d in $add_ons_pfx ''; do
 703             for a in $add_ons_sfx ''; do
 704               if test -n "$m0$m0sub$b$v$o$m$msub"; then
 705                 try_srcdir="${srcdir}/"
 706                 case "$d" in
 707                 /*) try_srcdir= ;;
 708                 esac
 709                 try="${d}sysdeps$m0$m0sub$b$v$o$m$msub$a"
 710                 test -n "$enable_debug_configure" &&
 711                 echo "$0 [DEBUG]: try $try" >&2
 712                 if test -d "$try_srcdir$try"; then
 713                   sysnames="$sysnames $try"
 714                   { test -n "$o" || test -n "$b"; } && os_used=t
 715                   { test -n "$m" || test -n "$m0"; } && machine_used=t
 716                   case x${m0:-$m} in
 717                   x*/$submachine) submachine_used=t ;;
 718                   esac
 719                   if test -n "$d"; then
 720                     case "$sysnames_add_ons" in
 721                     *" $d "*) ;;
 722                     *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 723                     esac
 724                   fi
 725                 fi
 726               fi
 727             done
 728           done
 729         done
 730       done
 731     done
 732   done
 733 done
 734
 735 # If the assembler supports gnu_indirect_function symbol type and the
 736 # architecture supports multi-arch, we enable multi-arch by default.
 737 case $sysnames_add_ons$sysnames in
 738 *"$multi_arch_d"*)
 739   ;;
 740 *)
 741   test x"$multi_arch" = xdefault && multi_arch=no
 742   ;;
 743 esac
 744 if test x"$multi_arch" != xno; then
 745   AC_DEFINE(USE_MULTIARCH)
 746 fi
 747 AC_SUBST(multi_arch)
 748
 749 if test -z "$os_used" && test "$os" != none; then
 750   AC_MSG_ERROR(Operating system $os is not supported.)
 751 fi
 752 if test -z "$machine_used" && test "$machine" != none; then
 753   AC_MSG_ERROR(The $machine is not supported.)
 754 fi
 755 if test -z "$submachine_used" && test -n "$submachine"; then
 756   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 757 fi
 758 AC_SUBST(submachine)
 759
 760 # We have now validated the configuration.
 761
 762
 763 # Look for an `elf' subdirectory of each machine directory.
 764 # We prepend these rather than inserting them whereever the machine appears
 765 # because things specified by the machine's ELF ABI should override
 766 # OS-specific things, and should always be the same for any OS on the
 767 # machine (otherwise what's the point of an ABI?).
 768 elf_dirs=
 769 for d in $add_ons_pfx ''; do
 770   for m in $mach; do
 771     if test -d $srcdir/${d}sysdeps$m/elf; then
 772       elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 773     fi
 774   done
 775 done
 776 sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 777
 778
 779 # Expand the list of system names into a full list of directories
 780 # from each element's parent name and Implies file (if present).
 781 set $sysnames
 782 names=
 783 while test $# -gt 0; do
 784   name=$1
 785   shift
 786
 787   case " $names " in *" $name "*)
 788     # Already in the list.
 789     continue
 790   esac
 791
 792   # Report each name as we discover it, so there is no long pause in output.
 793   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 794
 795   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 796
 797   case $name in
 798     /*) xsrcdir= ;;
 799     *)  xsrcdir=$srcdir/ ;;
 800   esac
 801   test -n "$enable_debug_configure" &&
 802   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 803
 804   if test -f $xsrcdir$name/Implies; then
 805     # Collect more names from the `Implies' file (removing comments).
 806     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 807     implied=
 808     for x in $implied_candidate; do
 809       found=no
 810       if test -d $xsrcdir$name_base/$x; then
 811         implied="$implied $name_base/$x";
 812         found=yes
 813       fi
 814       for d in $add_ons_pfx ''; do
 815         try="${d}sysdeps/$x"
 816         case $d in
 817          /*) try_srcdir= ;;
 818          *) try_srcdir=$srcdir/ ;;
 819         esac
 820         test -n "$enable_debug_configure" &&
 821          echo "[DEBUG]: $name implied $x try($d) {$try_srcdir}$try" >&2
 822         if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 823         then
 824           implied="$implied $try"
 825           found=yes
 826           case "$sysnames_add_ons" in
 827           *" $d "*) ;;
 828           *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 829           esac
 830         fi
 831       done
 832       if test $found = no; then
 833         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 834       fi
 835     done
 836   else
 837     implied=
 838   fi
 839
 840   # Add NAME to the list of names.
 841   names="$names $name"
 842
 843   # Find the parent of NAME, using the empty string if it has none.
 844 changequote(,)dnl
 845   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 846 changequote([,])dnl
 847
 848   # Add the names implied by NAME, and NAME's parent (if it has one), to
 849   # the list of names to be processed (the argument list).  We prepend the
 850   # implied names to the list and append the parent.  We want implied
 851   # directories to come before further directories inferred from the
 852   # configuration components; this ensures that for sysv4, unix/common
 853   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 854   # after sysv4).
 855   sysnames="`echo $implied $* $parent`"
 856   test -n "$sysnames" && set $sysnames
 857 done
 858
 859 # Add the default directories.
 860 default_sysnames="sysdeps/generic/elf sysdeps/generic"
 861 sysnames="$names $default_sysnames"
 862 AC_SUBST(sysnames)
 863 # The other names were emitted during the scan.
 864 AC_MSG_RESULT($default_sysnames)
 865
 866 # Collect the list of add-ons that supply partial sysdeps trees.
 867 sysdeps_add_ons=
 868 for add_on in $add_ons; do
 869   case "$add_on" in
 870   /*) xsrcdir= ;;
 871   *) xsrcdir="$srcdir/" ;;
 872   esac
 873
 874   test -d "$xsrcdir$add_on/sysdeps" || {
 875     case "$configured_add_ons " in
 876     *" $add_on "*) ;;
 877     *|'')
 878       AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
 879       ;;
 880     esac
 881     continue
 882   }
 883
 884   sysdeps_add_ons="$sysdeps_add_ons $add_on"
 885   case "$sysnames_add_ons" in
 886   *" $add_on/ "*) ;;
 887   *|'')
 888     AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
 889     continue ;;
 890   esac
 891
 892   found=no
 893   for d in $sysnames; do
 894     case "$d" in
 895     $add_on/sysdeps/*) ;;
 896     *) continue ;;
 897     esac
 898     (cd "$xsrcdir$d" && for f in *[[!~]]; do
 899        case "$f" in
 900        sys|bits)
 901          for ff in $f/*.h; do
 902            test -d "$ff" || { test -e "$ff" && exit 88; }
 903          done
 904          ;;
 905        *)
 906          test -d "$f" || { test -e "$f" && exit 88; }
 907          ;;
 908        esac
 909      done)
 910     if test $? -eq 88; then
 911       found=yes
 912       break
 913     fi
 914   done
 915   if test $found = no; then
 916     AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
 917   fi
 918 done
 919 AC_SUBST(sysdeps_add_ons)
 920
 921
 922 ### Locate tools.
 923
 924 AC_PROG_INSTALL
 925 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 926   # The makefiles need to use a different form to find it in $srcdir.
 927   INSTALL='\$(..)./scripts/install-sh -c'
 928 fi
 929 AC_PROG_LN_S
 930
 931 LIBC_PROG_BINUTILS
 932 AC_SUBST(MIG)dnl Needed by sysdeps/mach/configure.in
 933
 934 # Accept binutils 2.13 or newer.
 935 AC_CHECK_PROG_VER(AS, $AS, --version,
 936                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 937                   [2.1[3-9]*|2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], AS=: critic_missing="$critic_missing as")
 938 AC_CHECK_PROG_VER(LD, $LD, --version,
 939                   [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 940                   [2.1[3-9]*|2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], LD=: critic_missing="$critic_missing ld")
 941
 942 # We need the physical current working directory.  We cannot use the
 943 # "pwd -P" shell builtin since that's not portable.  Instead we try to
 944 # find a pwd binary.  Note that assigning to the PWD environment
 945 # variable might have some interesting side effects, so we don't do
 946 # that.
 947 AC_PATH_PROG(PWD_P, pwd, no)
 948 if test "$PWD_P" = no; then
 949   AC_MSG_ERROR(*** A pwd binary could not be found.)
 950 fi
 951
 952 # These programs are version sensitive.
 953 AC_CHECK_TOOL_PREFIX
 954 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 955   [version \([egcygnustpi-]*[0-9.]*\)], [3.4* | 4.[0-9]* ],
 956   critic_missing="$critic_missing gcc")
 957 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 958   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 959   [3.79* | 3.[89]*], critic_missing="$critic_missing make")
 960
 961 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 962   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 963   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 964   MSGFMT=: aux_missing="$aux_missing msgfmt")
 965 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 966   [GNU texinfo.* \([0-9][0-9.]*\)],
 967   [4.*],
 968   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 969 AC_CHECK_PROG_VER(SED, sed, --version,
 970   [GNU sed version \([0-9]*\.[0-9.]*\)],
 971   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 972   SED=: aux_missing="$aux_missing sed")
 973
 974 AC_CHECK_TOOL(READELF, readelf, false)
 975
 976 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
 977 case "x$AUTOCONF" in
 978 xno|x|x:) AUTOCONF=no ;;
 979 *)
 980   AC_CACHE_CHECK(dnl
 981 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
 982   if (cd $srcdir; $AUTOCONF $ACFLAGS configure.in > /dev/null 2>&1); then
 983     libc_cv_autoconf_works=yes
 984   else
 985     libc_cv_autoconf_works=no
 986   fi])
 987   test $libc_cv_autoconf_works = yes || AUTOCONF=no
 988   ;;
 989 esac
 990 if test "x$AUTOCONF" = xno; then
 991   aux_missing="$aux_missing autoconf"
 992 fi
 993
 994 test -n "$critic_missing" && AC_MSG_ERROR([
 995 *** These critical programs are missing or too old:$critic_missing
 996 *** Check the INSTALL file for required versions.])
 997
 998 test -n "$aux_missing" && AC_MSG_WARN([
 999 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1000 *** some features will be disabled.
1001 *** Check the INSTALL file for required versions.])
1002
1003 # if using special system headers, find out the compiler's sekrit
1004 # header directory and add that to the list.  NOTE: Only does the right
1005 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1006 if test -n "$sysheaders"; then
1007   SYSINCLUDES=-nostdinc
1008   for d in include include-fixed; do
1009     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1010     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1011   done
1012   SYSINCLUDES="$SYSINCLUDES \
1013 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1014   if test -n "$CXX"; then
1015     CXX_SYSINCLUDES=
1016     cxxversion=`$CXX -dumpversion 2>&AS_MESSAGE_LOG_FD` &&
1017     cxxmachine=`$CXX -dumpmachine 2>&AS_MESSAGE_LOG_FD` &&
1018     for d in include "$cxxmachine/include"; do
1019       i=../../../../$d/c++/$cxxversion
1020       cxxheaders=`$CXX -print-file-name="$i"` &&
1021       test "x$cxxheaders" != x && test "x$i" != "x$cxxheaders" &&
1022       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders \
1023 -isystem $cxxheaders/$cxxmachine -isystem $cxxheaders/backward"
1024     done
1025   fi
1026 fi
1027 AC_SUBST(SYSINCLUDES)
1028 AC_SUBST(CXX_SYSINCLUDES)
1029
1030 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1031 # since this would lead to problems installing/building glibc.
1032 # LD_LIBRARY_PATH contains the current directory if one of the following
1033 # is true:
1034 # - one of the terminals (":" and ";") is the first or last sign
1035 # - two terminals occur directly after each other
1036 # - the path contains an element with a dot in it
1037 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1038 changequote(,)dnl
1039 case ${LD_LIBRARY_PATH} in
1040   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1041     ld_library_path_setting="contains current directory"
1042     ;;
1043   *)
1044     ld_library_path_setting="ok"
1045     ;;
1046 esac
1047 changequote([,])dnl
1048 AC_MSG_RESULT($ld_library_path_setting)
1049 if test "$ld_library_path_setting" != "ok"; then
1050 AC_MSG_ERROR([
1051 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1052 *** building glibc. Please change the environment variable
1053 *** and run configure again.])
1054 fi
1055
1056 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1057 if $CC -v -static-libgcc 2>&1 | grep -q 'unrecognized option.*static-libgcc'; then
1058   libc_cv_gcc_static_libgcc=
1059 else
1060   libc_cv_gcc_static_libgcc=-static-libgcc
1061 fi])
1062 AC_SUBST(libc_cv_gcc_static_libgcc)
1063
1064 AC_PATH_PROG(BASH_SHELL, bash, no)
1065 if test "$BASH_SHELL" != no &&
1066    $BASH_SHELL -c 'test "$BASH_VERSINFO" \
1067              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
1068   libc_cv_have_bash2=yes
1069 else
1070   libc_cv_have_bash2=no
1071 fi
1072 AC_SUBST(libc_cv_have_bash2)
1073
1074 dnl We need a ksh compatible shell for tzselect.
1075 if test "$BASH_SHELL" = no; then
1076   AC_PATH_PROG(KSH, ksh, no)
1077   if test "$KSH" = no; then
1078     libc_cv_have_ksh=no
1079   else
1080     libc_cv_have_ksh=yes
1081   fi
1082 else
1083   KSH="$BASH_SHELL"
1084   AC_SUBST(KSH)
1085   libc_cv_have_ksh=yes
1086 fi
1087 AC_SUBST(libc_cv_have_ksh)
1088
1089 AC_PROG_AWK
1090 AC_PATH_PROG(PERL, perl, no)
1091 if test "$PERL" != no &&
1092    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1093   PERL=no
1094 fi
1095 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1096              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1097 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
1098
1099 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1100 AC_TRY_COMPILE(dnl
1101 [#define __need_size_t
1102 #define __need_wchar_t
1103 #include <stddef.h>
1104 #define __need_NULL
1105 #include <stddef.h>], [size_t size; wchar_t wchar;
1106 #ifdef offsetof
1107 #error stddef.h ignored __need_*
1108 #endif
1109 if (&size == NULL || &wchar == NULL) abort ();],
1110                libc_cv_friendly_stddef=yes,
1111                libc_cv_friendly_stddef=no)])
1112 if test $libc_cv_friendly_stddef = yes; then
1113   config_vars="$config_vars
1114 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1115 fi
1116
1117 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1118                libc_cv_need_minus_P, [dnl
1119 cat > conftest.S <<EOF
1120 #include "confdefs.h"
1121 /* Nothing whatsoever.  */
1122 EOF
1123 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1124   libc_cv_need_minus_P=no
1125 else
1126   libc_cv_need_minus_P=yes
1127 fi
1128 rm -f conftest*])
1129 if test $libc_cv_need_minus_P = yes; then
1130   config_vars="$config_vars
1131 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1132 fi
1133
1134 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1135 cat > conftest.s <<EOF
1136 ${libc_cv_dot_text}
1137 foo:
1138 .set glibc_conftest_frobozz,foo
1139 $libc_cv_asm_global_directive glibc_conftest_frobozz
1140 EOF
1141 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1142 # (but it doesn't work), so we must do a linking check to be sure.
1143 cat > conftest1.c <<\EOF
1144 extern int glibc_conftest_frobozz;
1145 void _start() { glibc_conftest_frobozz = 1; }
1146 EOF
1147 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1148             -nostartfiles -nostdlib \
1149             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1150   libc_cv_asm_set_directive=yes
1151 else
1152   libc_cv_asm_set_directive=no
1153 fi
1154 rm -f conftest*])
1155 if test $libc_cv_asm_set_directive = yes; then
1156   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1157 fi
1158
1159 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1160                libc_cv_asm_unique_object, [dnl
1161 cat > conftest.s <<EOF
1162 ${libc_cv_dot_text}
1163 _sym:
1164 .type _sym, ${libc_cv_asm_type_prefix}gnu_unique_object
1165 EOF
1166 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1167   libc_cv_asm_unique_object=yes
1168 else
1169   libc_cv_asm_unique_object=no
1170 fi
1171 rm -f conftest*])
1172 if test $libc_cv_asm_unique_object = yes; then
1173   AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1174 fi
1175
1176 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
1177 [cat > conftest.s <<EOF
1178 ${libc_cv_dot_text}
1179 _sym:
1180 .symver _sym,sym@VERS
1181 EOF
1182 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1183   libc_cv_asm_symver_directive=yes
1184 else
1185   libc_cv_asm_symver_directive=no
1186 fi
1187 rm -f conftest*])
1188 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
1189 if test $libc_cv_asm_symver_directive = yes; then
1190   cat > conftest.s <<EOF
1191 ${libc_cv_dot_text}
1192 _sym:
1193 .symver _sym,sym@VERS
1194 EOF
1195   cat > conftest.map <<EOF
1196 VERS_1 {
1197         global: sym;
1198 };
1199
1200 VERS_2 {
1201         global: sym;
1202 } VERS_1;
1203 EOF
1204   if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1205     if AC_TRY_COMMAND([${CC-cc} $CFLAGS $LDFLAGS -shared
1206                                 -o conftest.so conftest.o
1207                                 -nostartfiles -nostdlib
1208                                 -Wl,--version-script,conftest.map
1209                        1>&AS_MESSAGE_LOG_FD]);
1210     then
1211       libc_cv_ld_version_script_option=yes
1212     else
1213       libc_cv_ld_version_script_option=no
1214     fi
1215   else
1216     libc_cv_ld_version_script_option=no
1217   fi
1218 else
1219   libc_cv_ld_version_script_option=no
1220 fi
1221 rm -f conftest*])
1222 if test $shared != no &&
1223    test $libc_cv_asm_symver_directive = yes &&
1224    test $libc_cv_ld_version_script_option = yes &&
1225    test $enable_versioning = yes; then
1226   VERSIONING=yes
1227   AC_DEFINE(DO_VERSIONING)
1228 else
1229   VERSIONING=no
1230 fi
1231 AC_SUBST(VERSIONING)
1232
1233 if test $shared != no && test $VERSIONING = no; then
1234   echo "\
1235 *** WARNING: You should not compile GNU libc without versioning. Not using
1236 *** versioning will introduce incompatibilities so that old binaries
1237 *** will not run anymore.
1238 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
1239 fi
1240 AC_CACHE_CHECK(for .previous assembler directive,
1241                libc_cv_asm_previous_directive, [dnl
1242 cat > conftest.s <<EOF
1243 .section foo_section
1244 .previous
1245 EOF
1246 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1247   libc_cv_asm_previous_directive=yes
1248 else
1249   libc_cv_asm_previous_directive=no
1250 fi
1251 rm -f conftest*])
1252 if test $libc_cv_asm_previous_directive = yes; then
1253   AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1254 else
1255   AC_CACHE_CHECK(for .popsection assembler directive,
1256                  libc_cv_asm_popsection_directive, [dnl
1257   cat > conftest.s <<EOF
1258 .pushsection foo_section
1259 .popsection
1260 EOF
1261   if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1262     libc_cv_asm_popsection_directive=yes
1263   else
1264     libc_cv_asm_popsection_directive=no
1265   fi
1266   rm -f conftest*])
1267   if test $libc_cv_asm_popsection_directive = yes; then
1268     AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1269   fi
1270 fi
1271 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1272                libc_cv_asm_protected_directive, [dnl
1273 cat > conftest.s <<EOF
1274 .protected foo
1275 foo:
1276 .hidden bar
1277 bar:
1278 EOF
1279 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1280   libc_cv_asm_protected_directive=yes
1281 else
1282   AC_MSG_ERROR(assembler support for symbol visibility is required)
1283 fi
1284 rm -f conftest*])
1285
1286 if test $libc_cv_asm_protected_directive = yes; then
1287   AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1288                  libc_cv_visibility_attribute,
1289                  [cat > conftest.c <<EOF
1290                   int foo __attribute__ ((visibility ("hidden"))) = 1;
1291                   int bar __attribute__ ((visibility ("protected"))) = 1;
1292 EOF
1293                   libc_cv_visibility_attribute=no
1294                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1295                     if grep '\.hidden.*foo' conftest.s >/dev/null; then
1296                       if grep '\.protected.*bar' conftest.s >/dev/null; then
1297                         libc_cv_visibility_attribute=yes
1298                       fi
1299                     fi
1300                   fi
1301                   rm -f conftest.{c,s}
1302                  ])
1303   if test $libc_cv_visibility_attribute != yes; then
1304     AC_MSG_ERROR(compiler support for visibility attribute is required)
1305   fi
1306 fi
1307
1308 if test $libc_cv_visibility_attribute = yes; then
1309   AC_CACHE_CHECK(for broken __attribute__((visibility())),
1310                  libc_cv_broken_visibility_attribute,
1311                  [cat > conftest.c <<EOF
1312                   int foo (int x);
1313                   int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1314                   int bar (int x) { return x; }
1315 EOF
1316                   libc_cv_broken_visibility_attribute=yes
1317                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1318 changequote(,)dnl
1319                     if grep '\.hidden[  _]foo' conftest.s >/dev/null; then
1320 changequote([,])dnl
1321                       libc_cv_broken_visibility_attribute=no
1322                     fi
1323                   fi
1324                   rm -f conftest.c conftest.s
1325                  ])
1326   if test $libc_cv_broken_visibility_attribute = yes; then
1327     AC_MSG_ERROR(working compiler support for visibility attribute is required)
1328   fi
1329 fi
1330
1331 AC_CACHE_CHECK(for broken __attribute__((alias())),
1332                libc_cv_broken_alias_attribute,
1333                [cat > conftest.c <<EOF
1334                extern int foo (int x) __asm ("xyzzy");
1335                int bar (int x) { return x; }
1336                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1337                extern int dfoo;
1338                extern __typeof (dfoo) dfoo __asm ("abccb");
1339                int dfoo = 1;
1340 EOF
1341                libc_cv_broken_alias_attribute=yes
1342                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1343                  if grep 'xyzzy' conftest.s >/dev/null &&
1344                     grep 'abccb' conftest.s >/dev/null; then
1345                    libc_cv_broken_alias_attribute=no
1346                  fi
1347                fi
1348                rm -f conftest.c conftest.s
1349                ])
1350 if test $libc_cv_broken_alias_attribute = yes; then
1351   AC_MSG_ERROR(working alias attribute support required)
1352 fi
1353
1354 if test $libc_cv_visibility_attribute = yes; then
1355   AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1356                  libc_cv_have_sdata_section,
1357                  [echo "int i;" > conftest.c
1358                   libc_cv_have_sdata_section=no
1359                   if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1360                      | grep '\.sdata' >/dev/null; then
1361                     libc_cv_have_sdata_section=yes
1362                   fi
1363                   rm -f conftest.c conftest.so
1364                  ])
1365   if test $libc_cv_have_sdata_section = yes; then
1366     AC_DEFINE(HAVE_SDATA_SECTION)
1367   fi
1368 fi
1369
1370 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1371                libc_cv_initfini_array, [dnl
1372 cat > conftest.c <<EOF
1373 int _start (void) { return 0; }
1374 int __start (void) { return 0; }
1375 int foo (void) { return 1; }
1376 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1377 EOF
1378 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -o conftest conftest.c
1379                    -static -nostartfiles -nostdlib 1>&AS_MESSAGE_LOG_FD])
1380 then
1381   if $READELF -S conftest | fgrep INIT_ARRAY > /dev/null; then
1382     libc_cv_initfini_array=yes
1383   else
1384     libc_cv_initfini_array=no
1385   fi
1386 else
1387   libc_cv_initfini_array=no
1388 fi
1389 rm -f conftest*])
1390 if test $libc_cv_initfini_array != yes; then
1391   AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1392 fi
1393
1394 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1395                libc_cv_ctors_header, [dnl
1396   libc_cv_ctors_header=yes
1397   AC_TRY_LINK([], [
1398 __attribute__ ((constructor)) void ctor (void) { puts("ctor"); }
1399 __attribute__ ((destructor))  void dtor (void) { puts("dtor"); }
1400 ],
1401               [dnl
1402       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1403         { gsub(/\@<:@ */, "@<:@") }
1404         $2 == ".ctors" || $2 == ".dtors" {
1405           size = strtonum("0x" $6)
1406           align = strtonum("0x" $NF)
1407           seen@<:@$2@:>@ = 1
1408           stub@<:@$2@:>@ = size == align * 2
1409         }
1410         END {
1411           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1412           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1413           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1414         }
1415       '], [libc_cv_ctors_header=no])
1416     ], [dnl
1417       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1418     ])
1419 ])
1420 if test $libc_cv_ctors_header = no; then
1421   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1422 fi
1423
1424 AC_CACHE_CHECK(for libunwind-support in compiler,
1425                libc_cv_cc_with_libunwind, [
1426   cat > conftest.c <<EOF
1427 int main (void) { return 0; }
1428 EOF
1429   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1430      conftest.c -v 2>&1 >/dev/null | grep -q " -lunwind "; then
1431     libc_cv_cc_with_libunwind=yes
1432   else
1433     libc_cv_cc_with_libunwind=no
1434   fi
1435   rm -f conftest*])
1436 AC_SUBST(libc_cv_cc_with_libunwind)
1437 if test $libc_cv_cc_with_libunwind = yes; then
1438   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1439 fi
1440
1441 AC_CACHE_CHECK(for -z nodelete option,
1442                libc_cv_z_nodelete, [dnl
1443 cat > conftest.c <<EOF
1444 int _start (void) { return 42; }
1445 EOF
1446 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1447                    -fPIC -shared -o conftest.so conftest.c
1448                    -nostartfiles -nostdlib
1449                    -Wl,--enable-new-dtags,-z,nodelete 1>&AS_MESSAGE_LOG_FD])
1450 then
1451   libc_cv_z_nodelete=yes
1452 else
1453   AC_MSG_ERROR(linker with -z nodelete support required)
1454 fi
1455 rm -f conftest*])
1456
1457 AC_CACHE_CHECK(for -z nodlopen option,
1458                libc_cv_z_nodlopen, [dnl
1459 cat > conftest.c <<EOF
1460 int _start (void) { return 42; }
1461 EOF
1462 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1463                         -fPIC -shared -o conftest.so conftest.c
1464                         -nostartfiles -nostdlib
1465                         -Wl,--enable-new-dtags,-z,nodlopen 1>&AS_MESSAGE_LOG_FD])
1466 then
1467   libc_cv_z_nodlopen=yes
1468 else
1469   AC_MSG_ERROR(linker with -z nodlopen support required)
1470 fi
1471 rm -f conftest*])
1472
1473 AC_CACHE_CHECK(for -z initfirst option,
1474                libc_cv_z_initfirst, [dnl
1475 cat > conftest.c <<EOF
1476 int _start (void) { return 42; }
1477 EOF
1478 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1479                         -fPIC -shared -o conftest.so conftest.c
1480                         -nostartfiles -nostdlib
1481                         -Wl,--enable-new-dtags,-z,initfirst 1>&AS_MESSAGE_LOG_FD])
1482 then
1483   libc_cv_z_initfirst=yes
1484 else
1485   AC_MSG_ERROR(linker with -z initfirst support required)
1486 fi
1487 rm -f conftest*])
1488
1489 # Add-on fragments can set these for other machines.
1490 libc_commonpagesize=${libc_commonpagesize:-no}
1491 libc_relro_required=${libc_relro_required:-no}
1492 case "$base_machine" in
1493   i[[34567]]86 | x86_64 | powerpc* | s390*)
1494     libc_commonpagesize=0x1000
1495     libc_relro_required=yes
1496     ;;
1497   sparc*)
1498     libc_commonpagesize=0x2000
1499     libc_relro_required=yes
1500     ;;
1501   ia64*)
1502     libc_commonpagesize=0x4000
1503     ;;
1504   alpha*)
1505     libc_commonpagesize=0x10000
1506     libc_relro_required=yes
1507     ;;
1508 esac
1509
1510 if test $libc_commonpagesize != no; then
1511   AC_CACHE_CHECK(for -z relro option,
1512                  libc_cv_z_relro, [dnl
1513   libc_cv_z_relro=no
1514   AC_LANG_CONFTEST([AC_LANG_SOURCE([[
1515 int _start (void) { return 42; }
1516 extern void _exit (int);
1517 /* Since these pointers are const, they should go in rodata.
1518    Since they refer to functions that have to be resolved by
1519    dynamic linking, they should instead go in RELRO data.  */
1520 const void *const relro[] = { &_start, &_exit, 0 };
1521 /* GNU ld fails to produce RELRO data when it's very small and there is no
1522    normal writable data following it, or if only uninitialized (.bss) data
1523    follows it, or only very small writable data.  */
1524 int data[0x10000] = { 1, };
1525 ]])])
1526   cat > conftest.awk <<\EOF
1527 BEGIN {
1528   result = "no"
1529   commonpagesize = strtonum(commonpagesize)
1530 }
1531 { print "LINE:", $0 > "/dev/stderr" }
1532 $1 == "GNU_RELRO" {
1533   vaddr = strtonum($3)
1534   memsz = strtonum($6)
1535   end = vaddr + memsz
1536   printf "vaddr %#x memsz %#x end %#x commonpagesize %#x\n", \
1537     vaddr, memsz, end, commonpagesize > "/dev/stderr"
1538   result = (end % commonpagesize == 0) ? "yes" : "broken"
1539 }
1540 END { print result }
1541 EOF
1542   AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1543                     -fPIC -shared -o conftest.so conftest.c
1544                     -nostartfiles -nostdlib
1545                     -Wl,-z,relro 1>&AS_MESSAGE_LOG_FD]) &&
1546   AC_TRY_COMMAND([$READELF -Wl conftest.so > conftest.ph]) &&
1547   AC_TRY_COMMAND([
1548       $AWK -v commonpagesize=$libc_commonpagesize -f conftest.awk
1549            conftest.ph > conftest.cps
1550     ]) &&
1551   libc_cv_z_relro=`cat conftest.cps 2>&AS_MESSAGE_LOG_FD`
1552   rm -f conftest*])
1553   if { test "x$libc_relro_required" = xyes &&
1554        test "x$libc_cv_z_relro" != xyes
1555      }
1556   then
1557     AC_MSG_ERROR(linker with -z relro support required)
1558   fi
1559 else
1560   AC_MSG_WARN([missing architecture parameter to check for working -z relro])
1561 fi
1562
1563 AC_CACHE_CHECK(for -Bgroup option,
1564                libc_cv_Bgroup, [dnl
1565 cat > conftest.c <<EOF
1566 int _start (void) { return 42; }
1567 EOF
1568 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1569                             -fPIC -shared -o conftest.so conftest.c
1570                             -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1571 then
1572   libc_cv_Bgroup=yes
1573 else
1574   libc_cv_Bgroup=no
1575 fi
1576 rm -f conftest*])
1577 AC_SUBST(libc_cv_Bgroup)
1578
1579 AC_CACHE_CHECK(for libgcc_s suffix,
1580                libc_cv_libgcc_s_suffix, [dnl
1581 cat > conftest.c <<EOF
1582 int main (void) { return 0; }
1583 EOF
1584 changequote(,)dnl
1585 libc_cv_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1586                            -fPIC -shared -shared-libgcc -o conftest.so \
1587                            conftest.c -v 2>&1 >/dev/null \
1588                            | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
1589 changequote([,])dnl
1590 rm -f conftest*])
1591 AC_SUBST(libc_cv_libgcc_s_suffix)
1592
1593 AC_CACHE_CHECK(for --as-needed option,
1594                libc_cv_as_needed, [dnl
1595 cat > conftest.c <<EOF
1596 int main (void) { return 0; }
1597 EOF
1598 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1599                               -fPIC -shared -o conftest.so conftest.c
1600                               -lgcc_s$libc_cv_libgcc_s_suffix -Wl,--as-needed
1601                               -nostdlib 1>&AS_MESSAGE_LOG_FD])
1602 then
1603   libc_cv_as_needed=yes
1604 else
1605   libc_cv_as_needed=no
1606 fi
1607 rm -f conftest*])
1608 AC_SUBST(libc_cv_as_needed)
1609
1610 ASFLAGS_config=
1611 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1612                libc_cv_as_noexecstack, [dnl
1613 cat > conftest.c <<EOF
1614 void foo (void) { }
1615 EOF
1616 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1617                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1618    && grep -q .note.GNU-stack conftest.s \
1619    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1620                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1621 then
1622   libc_cv_as_noexecstack=yes
1623 else
1624   libc_cv_as_noexecstack=no
1625 fi
1626 rm -f conftest*])
1627 if test $libc_cv_as_noexecstack = yes; then
1628   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1629 fi
1630 AC_SUBST(ASFLAGS_config)
1631
1632 AC_CACHE_CHECK(for -z combreloc,
1633                libc_cv_z_combreloc, [dnl
1634 cat > conftest.c <<EOF
1635 extern int bar (int);
1636 extern int mumble;
1637 int foo (void) { return bar (mumble); }
1638 EOF
1639 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1640                         -fPIC -shared -o conftest.so conftest.c
1641                         -nostdlib -nostartfiles
1642                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1643 then
1644 dnl The following test is a bit weak.  We must use a tool which can test
1645 dnl cross-platform since the gcc used can be a cross compiler.  Without
1646 dnl introducing new options this is not easily doable.  Instead use a tool
1647 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1648 dnl look for a section named .rel.dyn.
1649   if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1650     libc_cv_z_combreloc=yes
1651   else
1652     libc_cv_z_combreloc=no
1653   fi
1654 else
1655   libc_cv_z_combreloc=no
1656 fi
1657 rm -f conftest*])
1658 if test "$libc_cv_z_combreloc" = yes; then
1659   AC_DEFINE(HAVE_Z_COMBRELOC)
1660 fi
1661 AC_SUBST(libc_cv_z_combreloc)
1662
1663 AC_CACHE_CHECK(for -z execstack,
1664                libc_cv_z_execstack, [dnl
1665 cat > conftest.c <<EOF
1666 int _start (void) { return 42; }
1667 EOF
1668 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1669                             -fPIC -shared -o conftest.so conftest.c
1670                             -Wl,-z,execstack -nostdlib
1671                             1>&AS_MESSAGE_LOG_FD])
1672 then
1673   libc_cv_z_execstack=yes
1674 else
1675   libc_cv_z_execstack=no
1676 fi
1677 rm -f conftest*])
1678 AC_SUBST(libc_cv_z_execstack)
1679
1680 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1681 cat > conftest.c <<EOF
1682 int foo;
1683 main () { return 0;}
1684 EOF
1685 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -pie -fpie
1686                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD])
1687 then
1688   libc_cv_fpie=yes
1689 else
1690   libc_cv_fpie=no
1691 fi
1692 rm -f conftest*])
1693
1694 AC_SUBST(libc_cv_fpie)
1695
1696 AC_CACHE_CHECK(for --hash-style option,
1697                libc_cv_hashstyle, [dnl
1698 cat > conftest.c <<EOF
1699 int _start (void) { return 42; }
1700 EOF
1701 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1702                             -fPIC -shared -o conftest.so conftest.c
1703                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1704 then
1705   libc_cv_hashstyle=yes
1706 else
1707   libc_cv_hashstyle=no
1708 fi
1709 rm -f conftest*])
1710 AC_SUBST(libc_cv_hashstyle)
1711
1712 # The linker's default -shared behavior is good enough if it
1713 # does these things that our custom linker scripts ensure that
1714 # all allocated NOTE sections come first.
1715 if test "$use_default_link" = default; then
1716   AC_CACHE_CHECK([for sufficient default -shared layout],
1717                   libc_cv_use_default_link, [dnl
1718   libc_cv_use_default_link=no
1719   cat > conftest.s <<\EOF
1720           .section .note.a,"a",%note
1721           .balign 4
1722           .long 4,4,9
1723           .string "GNU"
1724           .string "foo"
1725           .section .note.b,"a",%note
1726           .balign 4
1727           .long 4,4,9
1728           .string "GNU"
1729           .string "bar"
1730 EOF
1731   if AC_TRY_COMMAND([dnl
1732   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1733        ac_try=`$READELF -S conftest.so | sed -n \
1734          ['${x;p;}
1735           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1736           t a
1737           b
1738           : a
1739           H']`
1740   then
1741     libc_seen_a=no libc_seen_b=no
1742     set -- $ac_try
1743     while test $# -ge 2 -a "$1" = NOTE; do
1744       case "$2" in
1745       .note.a) libc_seen_a=yes ;;
1746       .note.b) libc_seen_b=yes ;;
1747       esac
1748       shift 2
1749     done
1750     case "$libc_seen_a$libc_seen_b" in
1751     yesyes)
1752       libc_cv_use_default_link=yes
1753       ;;
1754     *)
1755       echo >&AS_MESSAGE_LOG_FD "\
1756 $libc_seen_a$libc_seen_b from:
1757 $ac_try"
1758       ;;
1759     esac
1760   fi
1761   rm -f conftest*])
1762   use_default_link=$libc_cv_use_default_link
1763 fi
1764
1765 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1766 if libc_cv_output_format=`
1767 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1768 then
1769   :
1770 else
1771   libc_cv_output_format=
1772 fi
1773 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1774 AC_SUBST(libc_cv_output_format)
1775
1776 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1777 cat > conftest.c <<EOF
1778 int foo;
1779 EOF
1780 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1781                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1782 then
1783   libc_cv_fno_toplevel_reorder=yes
1784 else
1785   libc_cv_fno_toplevel_reorder=no
1786 fi
1787 rm -f conftest*])
1788 if test $libc_cv_fno_toplevel_reorder = yes; then
1789   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1790 else
1791   fno_unit_at_a_time=-fno-unit-at-a-time
1792 fi
1793 AC_SUBST(fno_unit_at_a_time)
1794
1795 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1796 cat > conftest.c <<EOF
1797 int foo;
1798 main () { return 0;}
1799 EOF
1800 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -Werror -fstack-protector
1801                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD])
1802 then
1803   libc_cv_ssp=yes
1804 else
1805   libc_cv_ssp=no
1806 fi
1807 rm -f conftest*])
1808 AC_SUBST(libc_cv_ssp)
1809
1810 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1811 cat > conftest.c <<EOF
1812 int foo;
1813 #ifdef __GNUC_GNU_INLINE__
1814 main () { return 0;}
1815 #else
1816 #error
1817 #endif
1818 EOF
1819 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1820                             -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1821 then
1822   libc_cv_gnu89_inline=yes
1823 else
1824   libc_cv_gnu89_inline=no
1825 fi
1826 rm -f conftest*])
1827 if test $libc_cv_gnu89_inline = yes; then
1828   gnu89_inline=-fgnu89-inline
1829 else
1830   gnu89_inline=
1831 fi
1832 AC_SUBST(gnu89_inline)
1833
1834 AC_CACHE_CHECK(whether cc puts quotes around section names,
1835                libc_cv_have_section_quotes,
1836                [cat > conftest.c <<EOF
1837                 static const int foo
1838                 __attribute__ ((section ("bar"))) = 1;
1839 EOF
1840                 if ${CC-cc} -S conftest.c -o conftest.s; then
1841                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1842                     libc_cv_have_section_quotes=yes
1843                   else
1844                     libc_cv_have_section_quotes=no
1845                   fi
1846                 else
1847                   libc_cv_have_section_quotes=unknown
1848                 fi
1849                 rm -f conftest.{c,s}
1850                 ])
1851 if test $libc_cv_have_section_quotes = yes; then
1852   AC_DEFINE(HAVE_SECTION_QUOTES)
1853 fi
1854
1855 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1856                [dnl
1857 cat > conftest.s <<EOF
1858 ${libc_cv_dot_text}
1859 ${libc_cv_asm_global_directive} foo
1860 foo:
1861 .weak foo
1862 .weak bar; bar = foo
1863 EOF
1864 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1865   libc_cv_asm_weak_directive=yes
1866 else
1867   libc_cv_asm_weak_directive=no
1868 fi
1869 rm -f conftest*])
1870
1871 if test $libc_cv_asm_weak_directive = no; then
1872   AC_CACHE_CHECK(for assembler .weakext directive,
1873                  libc_cv_asm_weakext_directive,
1874                  [dnl
1875 cat > conftest.s <<EOF
1876 ${libc_cv_dot_text}
1877 ${libc_cv_asm_global_directive} foo
1878 foo:
1879 .weakext bar foo
1880 .weakext baz
1881 ${libc_cv_asm_global_directive} baz
1882 baz:
1883 EOF
1884   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1885     libc_cv_asm_weakext_directive=yes
1886   else
1887     libc_cv_asm_weakext_directive=no
1888   fi
1889   rm -f conftest*])
1890
1891 fi # no .weak
1892
1893 if test $libc_cv_asm_weak_directive = yes; then
1894   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1895 elif test $libc_cv_asm_weakext_directive = yes; then
1896   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1897 fi
1898
1899 AC_CACHE_CHECK(whether CFI directives are supported, libc_cv_asm_cfi_directives, [dnl
1900 case $machine in
1901   sparc/sparc64*) cfi_offset=2047;;
1902   *) cfi_offset=0;;
1903 esac
1904 cat > conftest.s <<EOF
1905         .text
1906         .type   func,%function
1907 func:
1908         .cfi_startproc
1909         .cfi_remember_state
1910         .cfi_rel_offset 1, $cfi_offset
1911         .cfi_endproc
1912 EOF
1913 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1914   libc_cv_asm_cfi_directives=yes
1915 else
1916   libc_cv_asm_cfi_directives=no
1917 fi
1918 rm -f conftest*])
1919 if test $libc_cv_asm_cfi_directives = yes; then
1920   AC_DEFINE(HAVE_ASM_CFI_DIRECTIVES)
1921 fi
1922
1923 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1924 cat > conftest.c <<\EOF
1925 _start () {}
1926 int __eh_pc;
1927 __throw () {}
1928 EOF
1929 dnl No \ in command here because it ends up inside ''.
1930 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1931                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1932                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1933   libc_cv_ld_no_whole_archive=yes
1934 else
1935   libc_cv_ld_no_whole_archive=no
1936 fi
1937 rm -f conftest*])
1938 if test $libc_cv_ld_no_whole_archive = no; then
1939   AC_MSG_ERROR([support for --no-whole-archive is needed])
1940 fi
1941
1942 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1943 cat > conftest.c <<\EOF
1944 _start () {}
1945 int __eh_pc;
1946 __throw () {}
1947 EOF
1948 dnl No \ in command here because it ends up inside ''.
1949 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1950                             -nostdlib -nostartfiles -fexceptions
1951                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1952   libc_cv_gcc_exceptions=yes
1953 else
1954   libc_cv_gcc_exceptions=no
1955 fi
1956 rm -f conftest*])
1957 if test $libc_cv_gcc_exceptions = yes; then
1958   exceptions=-fexceptions
1959 fi
1960 AC_SUBST(exceptions)dnl
1961
1962 if test "$host_cpu" = powerpc ; then
1963 # Check for a bug present in at least versions 2.8.x of GCC
1964 # and versions 1.0.x of EGCS.
1965 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1966 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1967                libc_cv_c_asmcr0_bug='no',
1968                libc_cv_c_asmcr0_bug='yes')])
1969 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1970   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1971 fi
1972 fi
1973
1974 dnl Check whether compiler understands __builtin_expect.
1975 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1976 [cat > conftest.c <<EOF
1977 #line $LINENO "configure"
1978 int foo (int a)
1979 {
1980   a = __builtin_expect (a, 10);
1981   return a == 10 ? 0 : 1;
1982 }
1983 EOF
1984 dnl No \ in command here because it ends up inside ''.
1985 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -nostdlib -nostartfiles
1986                             -o conftest conftest.c -lgcc >&AS_MESSAGE_LOG_FD]); then
1987   libc_cv_gcc_builtin_expect=yes
1988 else
1989   libc_cv_gcc_builtin_expect=no
1990 fi
1991 rm -f conftest*])
1992 if test "$libc_cv_gcc_builtin_expect" = no; then
1993   AC_MSG_ERROR([support for __builtin_expect needed])
1994 fi
1995
1996 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1997 cat > conftest.c <<\EOF
1998 void zero (void *x)
1999 {
2000   __builtin_memset (x, 0, 1000);
2001 }
2002 EOF
2003 dnl
2004 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
2005 then
2006   libc_cv_gcc_builtin_memset=no
2007 else
2008   libc_cv_gcc_builtin_memset=yes
2009 fi
2010 rm -f conftest* ])
2011 if test "$libc_cv_gcc_builtin_memset" = yes ; then
2012   AC_DEFINE(HAVE_BUILTIN_MEMSET)
2013 fi
2014
2015 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
2016 cat > conftest.c <<\EOF
2017 extern char *strstr (const char *, const char *) __asm ("my_strstr");
2018 char *foo (const char *a, const char *b)
2019 {
2020   return __builtin_strstr (a, b);
2021 }
2022 EOF
2023 dnl
2024 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
2025 then
2026   libc_cv_gcc_builtin_redirection=yes
2027 else
2028   libc_cv_gcc_builtin_redirection=no
2029 fi
2030 rm -f conftest* ])
2031 if test "$libc_cv_gcc_builtin_redirection" = no; then
2032   AC_MSG_ERROR([support for the symbol redirection needed])
2033 fi
2034
2035 dnl Check whether the compiler supports the __thread keyword.
2036 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
2037 [cat > conftest.c <<\EOF
2038 __thread int a = 42;
2039 EOF
2040 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
2041   libc_cv_gcc___thread=yes
2042 else
2043   libc_cv_gcc___thread=no
2044 fi
2045 rm -f conftest*])
2046 if test "$libc_cv_gcc___thread" = no; then
2047   AC_MSG_ERROR([support for the __thread keyword is required])
2048 fi
2049
2050 dnl Check whether the compiler supports the tls_model attribute.
2051 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
2052 cat > conftest.c <<\EOF
2053 extern __thread int a __attribute__((tls_model ("initial-exec")));
2054 EOF
2055 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
2056   libc_cv_gcc_tls_model_attr=yes
2057 else
2058   libc_cv_gcc_tls_model_attr=no
2059 fi
2060 rm -f conftest*])
2061 if test "$libc_cv_gcc_tls_model_attr" = no; then
2062   AC_MSG_ERROR([support for the tls_model attribute is required])
2063 fi
2064
2065 if test -n "$submachine"; then
2066   AC_CACHE_CHECK([for compiler option for CPU variant],
2067                  libc_cv_cc_submachine, [dnl
2068   libc_cv_cc_submachine=no
2069   for opt in "-march=$submachine" "-mcpu=$submachine"; do
2070     if AC_TRY_COMMAND([${CC-cc} $opt -xc /dev/null -S -o /dev/null]); then
2071       libc_cv_cc_submachine="$opt"
2072       break
2073     fi
2074   done])
2075   if test "x$libc_cv_cc_submachine" = xno; then
2076     AC_MSG_ERROR([${CC-cc} does not support $submachine])
2077   fi
2078 fi
2079 AC_SUBST(libc_cv_cc_submachine)
2080
2081 dnl Check whether we have the gd library available.
2082 AC_MSG_CHECKING(for libgd)
2083 if test "$with_gd" != "no"; then
2084   old_CFLAGS="$CFLAGS"
2085   CFLAGS="$CFLAGS $libgd_include"
2086   old_LDFLAGS="$LDFLAGS"
2087   LDFLAGS="$LDFLAGS $libgd_ldflags"
2088   old_LIBS="$LIBS"
2089   LIBS="$LIBS -lgd -lpng -lz -lm"
2090   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
2091   CFLAGS="$old_CFLAGS"
2092   LDFLAGS="$old_LDFLAGS"
2093   LIBS="$old_LIBS"
2094 else
2095   LIBGD=no
2096 fi
2097 AC_MSG_RESULT($LIBGD)
2098 AC_SUBST(LIBGD)
2099
2100 # SELinux detection
2101 if test x$with_selinux = xno ; then
2102   have_selinux=no;
2103 else
2104   # See if we have the SELinux library
2105   AC_CHECK_LIB(selinux, is_selinux_enabled,
2106                have_selinux=yes, have_selinux=no)
2107   # See if we have the SELinux header with the NSCD permissions in it.
2108   if test x$have_selinux = xyes ; then
2109     AC_MSG_CHECKING([for NSCD Flask permissions in selinux/av_permissions.h])
2110     AC_TRY_COMPILE([#include <selinux/av_permissions.h>],
2111                     [#ifdef NSCD__SHMEMHOST
2112                      return 0;
2113                      #else
2114                      #error NSCD__SHMEMHOST not defined
2115                      #endif],
2116                     have_selinux=yes, have_selinux=no)
2117     AC_MSG_RESULT($have_selinux)
2118   fi
2119
2120   if test x$with_selinux = xyes ; then
2121     if test x$have_selinux = xno ; then
2122       AC_MSG_ERROR([SELinux explicitly required, but sufficiently recent SELinux library not found])
2123     fi
2124   fi
2125 fi
2126 # Check if we're building with SELinux support.
2127 if test "x$have_selinux" = xyes; then
2128   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
2129
2130   # See if we have the libaudit library
2131   AC_CHECK_LIB(audit, audit_log_user_avc_message,
2132                have_libaudit=yes, have_libaudit=no)
2133   if test "x$have_libaudit" = xyes; then
2134     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
2135   fi
2136   AC_SUBST(have_libaudit)
2137
2138   # See if we have the libcap library
2139   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
2140   if test "x$have_libcap" = xyes; then
2141     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
2142   fi
2143   AC_SUBST(have_libcap)
2144 fi
2145 AC_SUBST(have_selinux)
2146
2147 dnl check for the size of 'long double'.
2148 AC_CHECK_SIZEOF(long double, 0)
2149 sizeof_long_double=$ac_cv_sizeof_long_double
2150 AC_SUBST(sizeof_long_double)
2151
2152 ### End of automated tests.
2153 ### Now run sysdeps configure fragments.
2154
2155 # They also can set these variables.
2156 use_ldconfig=no
2157 ldd_rewrite_script=no
2158 libc_cv_sysconfdir=$sysconfdir
2159 libc_cv_gcc_unwind_find_fde=no
2160 libc_cv_idn=no
2161
2162 # Iterate over all the sysdep directories we will use, running their
2163 # configure fragments.
2164 for dir in $sysnames; do
2165   case $dir in
2166     /*) dest=$dir ;;
2167     *)  dest=$srcdir/$dir ;;
2168   esac
2169   if test -r $dest/configure; then
2170     AC_MSG_RESULT(running configure fragment for $dir)
2171     . $dest/configure
2172   fi
2173 done
2174
2175 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
2176   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
2177 fi
2178 AC_SUBST(libc_cv_gcc_unwind_find_fde)
2179
2180 # Test for old glibc 2.0.x headers so that they can be removed properly
2181 # Search only in includedir.
2182 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2183 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2184 then
2185   old_glibc_headers=yes
2186 else
2187   old_glibc_headers=no
2188 fi
2189 AC_MSG_RESULT($old_glibc_headers)
2190 if test ${old_glibc_headers} = yes; then
2191   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2192   AC_MSG_WARN(*** be removed.)
2193 fi
2194 AC_SUBST(old_glibc_headers)
2195
2196 AC_SUBST(libc_cv_slibdir)
2197 AC_SUBST(libc_cv_localedir)
2198 AC_SUBST(libc_cv_sysconfdir)
2199 AC_SUBST(libc_cv_rootsbindir)
2200 AC_SUBST(libc_cv_forced_unwind)
2201
2202 dnl sysdeps/CPU/configure.in checks set this via arch-specific asm tests
2203 AC_SUBST(libc_cv_cpp_asm_debuginfo)
2204 AC_SUBST(libc_cv_cc_sse4)
2205 AC_SUBST(libc_cv_cc_avx)
2206 AC_SUBST(libc_cv_cc_novzeroupper)
2207 AC_SUBST(libc_cv_cc_fma4)
2208 AC_SUBST(libc_cv_as_i686)
2209
2210 AC_SUBST(use_ldconfig)
2211 AC_SUBST(ldd_rewrite_script)
2212
2213 AC_SUBST(static)
2214 AC_SUBST(shared)
2215
2216 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2217 [libc_cv_pic_default=yes
2218 cat > conftest.c <<EOF
2219 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2220 # error PIC is default.
2221 #endif
2222 EOF
2223 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2224   libc_cv_pic_default=no
2225 fi
2226 rm -f conftest.*])
2227 AC_SUBST(libc_cv_pic_default)
2228
2229 AC_SUBST(profile)
2230 AC_SUBST(bounded)
2231 AC_SUBST(static_nss)
2232 AC_SUBST(nopic_initfini)
2233
2234 AC_SUBST(DEFINES)
2235
2236 dnl See sysdeps/mach/configure.in for this variable.
2237 AC_SUBST(mach_interface_list)
2238
2239 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
2240   config_makefile=
2241 else
2242   config_makefile=Makefile
2243 fi
2244
2245 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2246 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2247 AC_SUBST(VERSION)
2248 AC_SUBST(RELEASE)
2249
2250 AC_CONFIG_FILES([config.make ${config_makefile}])
2251 AC_CONFIG_COMMANDS([default],[[
2252 case $CONFIG_FILES in *config.make*)
2253 echo "$config_vars" >> config.make;;
2254 esac
2255 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2256 AC_OUTPUT