configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5 builtin(include, glib/libcharset/codeset.m4)dnl
   6 builtin(include, glib/libcharset/glibc21.m4)dnl
   7
   8 # require autoconf 2.13
   9 AC_PREREQ(2.13)
  10
  11 # Process this file with autoconf to produce a configure script.
  12 AC_INIT(glib/glib.h)
  13
  14 # Save this value here, since automake will set cflags later
  15 cflags_set=${CFLAGS+set}
  16
  17 # we rewrite this file
  18 rm -f glibconfig-sysdefs.h
  19
  20 GLIB_AC_DIVERT_BEFORE_HELP([
  21 #
  22 # The following version number definitions apply to GLib, GModule, GObject
  23 # and GThread as a whole, so if changes occoured in any of them, they are all
  24 # treated with the same interface and binary age.
  25 #
  26 # Making releases:
  27 #   GLIB_MICRO_VERSION += 1;
  28 #   GLIB_INTERFACE_AGE += 1;
  29 #   GLIB_BINARY_AGE += 1;
  30 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  31 # if backwards compatibility has been broken,
  32 # set GLIB_BINARY_AGE _and_ GLIB_INTERFACE_AGE to 0.
  33 #
  34 GLIB_MAJOR_VERSION=1
  35 GLIB_MINOR_VERSION=3
  36 GLIB_MICRO_VERSION=11
  37 GLIB_INTERFACE_AGE=0
  38 GLIB_BINARY_AGE=0
  39 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  40 ])dnl
  41
  42 AC_SUBST(GLIB_MAJOR_VERSION)
  43 AC_SUBST(GLIB_MINOR_VERSION)
  44 AC_SUBST(GLIB_MICRO_VERSION)
  45 AC_SUBST(GLIB_VERSION)
  46 AC_SUBST(GLIB_INTERFACE_AGE)
  47 AC_SUBST(GLIB_BINARY_AGE)
  48
  49 # libtool versioning
  50 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  51 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  52 LT_REVISION=$GLIB_INTERFACE_AGE
  53 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  54 LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  55 AC_SUBST(LT_RELEASE)
  56 AC_SUBST(LT_CURRENT)
  57 AC_SUBST(LT_REVISION)
  58 AC_SUBST(LT_AGE)
  59 AC_SUBST(LT_CURRENT_MINUS_AGE)
  60
  61 VERSION=$GLIB_VERSION
  62 PACKAGE=glib
  63
  64 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  65
  66 # Specify a configuration file
  67 AM_CONFIG_HEADER(config.h)
  68
  69 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION,
  70                    [Define to the GLIB major version])
  71 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION,
  72                    [Define to the GLIB minor version])
  73 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION,
  74                    [Define to the GLIB micro version])
  75 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE,
  76                    [Define to the GLIB interface age])
  77 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE,
  78                    [Define to the GLIB binary age])
  79
  80 dnl Initialize maintainer mode
  81 AM_MAINTAINER_MODE
  82
  83 AC_CANONICAL_HOST
  84
  85 AC_MSG_CHECKING(for the BeOS)
  86 case $host in
  87   *-*-beos*)
  88     glib_native_beos="yes"
  89     ;;
  90   *)
  91     glib_native_beos="no"
  92     ;;
  93 esac
  94 AC_MSG_RESULT([$glib_native_beos])
  95
  96 dnl
  97
  98 AC_MSG_CHECKING([for Win32])
  99 case "$host" in
 100   *-*-mingw*)
 101     glib_native_win32=yes
 102     G_LIB_WIN32_RESOURCE=glib-win32res.lo
 103     G_MODULE_WIN32_RESOURCE=gmodule-win32res.lo
 104     G_OBJECT_WIN32_RESOURCE=gobject-win32res.lo
 105     G_THREAD_WIN32_RESOURCE=gthread-win32res.lo
 106     GLIB_DEF=glib.def
 107     GMODULE_DEF=gmodule.def
 108     GOBJECT_DEF=gobject.def
 109     GTHREAD_DEF=gthread.def
 110     TESTGMODULE_EXP=testgmodule.exp
 111     ;;
 112   *)
 113     glib_native_win32=no
 114     G_LIB_WIN32_RESOURCE=
 115     G_MODULE_WIN32_RESOURCE=
 116     G_OBJECT_WIN32_RESOURCE=
 117     G_THREAD_WIN32_RESOURCE=
 118     GLIB_DEF=
 119     GMODULE_DEF=
 120     GOBJECT_DEF=
 121     GTHREAD_DEF=
 122     TESTGMODULE_EXP=
 123     ;;
 124 esac
 125 AC_MSG_RESULT([$glib_native_win32])
 126 AM_CONDITIONAL(OS_WIN32, test "$glib_native_win32" = "yes")
 127 AC_SUBST(G_LIB_WIN32_RESOURCE)
 128 AC_SUBST(G_MODULE_WIN32_RESOURCE)
 129 AC_SUBST(G_OBJECT_WIN32_RESOURCE)
 130 AC_SUBST(G_THREAD_WIN32_RESOURCE)
 131 AC_SUBST(GLIB_DEF)
 132 AC_SUBST(GMODULE_DEF)
 133 AC_SUBST(GOBJECT_DEF)
 134 AC_SUBST(GTHREAD_DEF)
 135 AC_SUBST(TESTGMODULE_EXP)
 136
 137 if test "$glib_native_win32" = "yes"; then
 138   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 139 fi
 140 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 141
 142 GLIB_AC_DIVERT_BEFORE_HELP([
 143 # figure debugging default, prior to $ac_help setup
 144 case $GLIB_MINOR_VERSION in
 145 *[[13579]]) debug_default=yes ;;
 146 *)          debug_default=minimum ;;
 147 esac[]dnl
 148 ])
 149
 150 dnl declare --enable-* args and collect ac_help strings
 151 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
 152 AC_ARG_ENABLE(gc_friendly, [  --enable-gc-friendly    turn on garbage collector friendliness [default=no]],,enable_gc_friendly=no)
 153 AC_ARG_ENABLE(mem_pools, [  --disable-mem-pools     disable all glib memory pools],,disable_mem_pools=no)
 154 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
 155                     , enable_ansi=no)
 156 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
 157                           ([=no] will override --with-threads)],,enable_threads=yes)
 158 AC_ARG_ENABLE(rebuilds, [  --disable-rebuilds      disable all source autogeneration rules],,enable_rebuilds=yes)
 159
 160 if test "x$enable_threads" != "xyes"; then
 161   enable_threads=no
 162 fi
 163
 164 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 165         [Whether glib was compiled with debugging enabled])
 166
 167 AC_MSG_CHECKING(whether to enable garbage collector friendliness)
 168 if test "x$enable_gc_friendly" = "xyes"; then
 169   AC_DEFINE(ENABLE_GC_FRIENDLY, 1, [Whether to enable GC friendliness])
 170   AC_SUBST(ENABLE_GC_FRIENDLY)
 171   AC_MSG_RESULT(yes)
 172 else
 173   AC_MSG_RESULT(no)
 174 fi
 175
 176 AC_MSG_CHECKING(whether to disable memory pools)
 177 if test "x$disable_mem_pools" = "xno"; then
 178   AC_MSG_RESULT(no)
 179 else
 180   AC_DEFINE(DISABLE_MEM_POOLS, 1, [Whether to disable memory pools])
 181   AC_SUBST(DISABLE_MEM_POOLS)
 182   AC_MSG_RESULT(yes)
 183 fi
 184
 185 dnl Checks for programs.
 186 AC_PROG_CC
 187
 188 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 189 AC_CHECK_PROGS(CXX, $CCC c++ g++ gcc CC cxx cc++ cl, gcc)
 190 AC_LANG_SAVE
 191 AC_LANG_CPLUSPLUS
 192 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 193 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 194 AC_LANG_RESTORE
 195
 196 AM_PROG_CC_STDC
 197 AC_PROG_INSTALL
 198
 199 #
 200 # Find pkg-config
 201 #
 202 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 203 if test x$PKG_CONFIG = xno ; then
 204   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
 205 fi
 206
 207 if pkg-config --atleast-pkgconfig-version 0.5 ; then
 208   :
 209 else
 210   AC_MSG_ERROR([*** pkg-config too old; version 0.5 or better required.])
 211 fi
 212
 213 if test "x$enable_debug" = "xyes"; then
 214   if test x$cflags_set != xset ; then
 215       case " $CFLAGS " in
 216       *[[\ \    ]]-g[[\ \       ]]*) ;;
 217       *) CFLAGS="$CFLAGS -g" ;;
 218       esac
 219   fi
 220
 221   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 222 else
 223   if test "x$enable_debug" = "xno"; then
 224     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 225   fi
 226 fi
 227
 228 # Ensure -fnative-struct is used when compiling for Win32
 229 if test "x$glib_native_win32" = "xyes"; then
 230   if test "x$GCC" = "xyes"; then
 231     case " $CFLAGS " in
 232     *[[\ \      ]]-fnative-struct[[\ \  ]]*) ;;
 233     *) CFLAGS="$CFLAGS -fnative-struct" ;;
 234     esac
 235   fi
 236 fi
 237
 238 AC_CYGWIN
 239 AC_EXEEXT
 240
 241 # define a MAINT-like variable REBUILD which is set if Perl
 242 # and awk are found, so autogenerated sources can be rebuilt
 243 AC_PROG_AWK
 244 AC_CHECK_PROGS(PERL, perl5 perl)
 245 # We would like indent, but don't require it.
 246 AC_CHECK_PROG(INDENT, indent, indent)
 247 REBUILD=\#
 248 if test "x$enable_rebuilds" = "xyes" && \
 249      test -n "$PERL" && \
 250      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 251      test -n "$AWK" ; then
 252   REBUILD=
 253 fi
 254 AC_SUBST(REBUILD)
 255
 256 # Need full path to Perl for glib-mkenums
 257 #
 258 if test "x$PERL" != x ; then
 259   AC_PATH_PROG(PERL_PATH, $PERL)
 260 else
 261   PERL_PATH="/usr/bin/env perl"
 262 fi
 263 AC_SUBST(PERL_PATH)
 264
 265 dnl
 266 dnl gettext support
 267 dnl
 268
 269 ALL_LINGUAS="az ca de es eu fr gl ja nl nn no ro ru sk sl sv ta tr uk zh_CN zh_TW"
 270 AM_GLIB_GNU_GETTEXT
 271
 272 if test "$gt_cv_func_dgettext_libc" = "yes" || test "$gt_cv_func_dgettext_libintl" = "yes"; then
 273   :
 274 else
 275   AC_MSG_ERROR([
 276 *** You must have either have gettext support in your C library, or use the
 277 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 278 ])
 279 fi
 280
 281 LIBS="$LIBS $INTLLIBS"
 282
 283 GETTEXT_PACKAGE=glib20
 284 AC_SUBST(GETTEXT_PACKAGE)
 285 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE")
 286
 287 # AM_GLIB_GNU_GETTEXT above substs $DATADIRNAME
 288 # this is the directory where the *.{mo,gmo} files are installed
 289 GLIB_LOCALE_DIR="${prefix}/${DATADIRNAME}/locale"
 290 AC_DEFINE_UNQUOTED(GLIB_LOCALE_DIR,"$GLIB_LOCALE_DIR")
 291
 292 dnl Initialize libtool
 293 AC_LIBTOOL_WIN32_DLL
 294 AM_PROG_LIBTOOL
 295
 296 if test "x$GCC" = "xyes"; then
 297   case " $CFLAGS " in
 298   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 299   *) CFLAGS="$CFLAGS -Wall" ;;
 300   esac
 301
 302   if test "x$enable_ansi" = "xyes"; then
 303     case " $CFLAGS " in
 304     *[[\ \      ]]-ansi[[\ \    ]]*) ;;
 305     *) CFLAGS="$CFLAGS -ansi" ;;
 306     esac
 307
 308     case " $CFLAGS " in
 309     *[[\ \      ]]-pedantic[[\ \        ]]*) ;;
 310     *) CFLAGS="$CFLAGS -pedantic" ;;
 311     esac
 312   fi
 313 fi
 314
 315 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 316 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 317 glib_save_LIBS=$LIBS
 318 LIBS="$LIBS -lm"
 319 AC_TRY_RUN([#include <math.h>
 320              int main (void) { return (log(1) != log(1.)); }],
 321      AC_MSG_RESULT(none needed),
 322      glib_save_CFLAGS=$CFLAGS
 323      CFLAGS="$CFLAGS -std1"
 324      AC_TRY_RUN([#include <math.h>
 325                  int main (void) { return (log(1) != log(1.)); }],
 326          AC_MSG_RESULT(-std1),
 327          AC_MSG_RESULT()
 328          CFLAGS=$glib_save_CFLAGS
 329          AC_MSG_WARN(
 330                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 331      )
 332 )
 333 LIBS=$glib_save_LIBS
 334
 335 dnl NeXTStep cc seems to need this
 336 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 337 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 338   AC_MSG_RESULT(none needed),
 339   glib_save_CFLAGS=$CFLAGS
 340   CFLAGS="$CFLAGS -posix"
 341   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 342     AC_MSG_RESULT(-posix),
 343     AC_MSG_RESULT()
 344     CFLAGS=$glib_save_CFLAGS
 345     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 346
 347 # Checks for header files.
 348 AC_HEADER_STDC
 349
 350 # Checks for library functions.
 351 AC_FUNC_VPRINTF
 352
 353 AC_FUNC_ALLOCA
 354
 355 AC_CHECK_FUNCS(atexit on_exit)
 356
 357 AC_CHECK_SIZEOF(char)
 358 AC_CHECK_SIZEOF(short)
 359 AC_CHECK_SIZEOF(long)
 360 AC_CHECK_SIZEOF(int)
 361 AC_CHECK_SIZEOF(void *)
 362 AC_CHECK_SIZEOF(long long)
 363 AC_CHECK_SIZEOF(__int64)
 364
 365 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 366   :
 367 else
 368   AC_MSG_ERROR([
 369 *** GLib requires a 64 bit type. You might want to consider
 370 *** using the GNU C compiler.
 371 ])
 372 fi
 373
 374 if test x$ac_cv_sizeof_long_long = x8; then
 375         # long long is a 64 bit integer.
 376         AC_MSG_CHECKING(for format to printf and scanf a gint64)
 377         AC_CACHE_VAL(glib_cv_long_long_format,[
 378                 for format in ll q I64; do
 379                   AC_TRY_RUN([#include <stdio.h>
 380                         int main()
 381                         {
 382                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 383                           char buffer[1000];
 384                           sprintf (buffer, "%${format}u", a);
 385                           sscanf (buffer, "%${format}u", &b);
 386                           exit (b!=a);
 387                         }
 388                         ],
 389                         glib_cv_long_long_format=${format}
 390                         break)
 391                 done])
 392         if test -n "$glib_cv_long_long_format"; then
 393           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 394         else
 395           AC_MSG_RESULT(none)
 396         fi
 397 elif test x$ac_cv_sizeof___int64 = x8; then
 398         # __int64 is a 64 bit integer.
 399         AC_MSG_CHECKING(for format to printf and scanf a gint64)
 400         # We know this is MSVC, and what the formats are
 401         glib_cv_long_long_format=I64
 402         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 403 fi
 404
 405 dnl long doubles were not used, and a portability problem
 406 dnl AC_C_LONG_DOUBLE
 407 AC_C_CONST
 408
 409 dnl ok, here we try to check whether the systems prototypes for
 410 dnl malloc and friends actually match the prototypes provided
 411 dnl by gmem.h (keep in sync). i currently only know how to check
 412 dnl this reliably with gcc (-Werror), improvements for other
 413 dnl compilers are apprechiated.
 414 SANE_MALLOC_PROTOS=no
 415 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 416 glib_save_CFLAGS=$CFLAGS
 417 if test "x$GCC" = "xyes"; then
 418   CFLAGS="$CFLAGS -Werror"
 419   AC_TRY_COMPILE([#include <stdlib.h>], [
 420     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 421     void* (*my_malloc_p)  (size_t)         = malloc;
 422     void  (*my_free_p)    (void*)          = free;
 423     void* (*my_realloc_p) (void*, size_t)  = realloc;
 424     my_calloc_p = 0;
 425     my_malloc_p = 0;
 426     my_free_p = 0;
 427     my_realloc_p = 0;
 428   ],
 429     AC_DEFINE(SANE_MALLOC_PROTOS)
 430     SANE_MALLOC_PROTOS=yes)
 431 fi
 432 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 433 CFLAGS=$glib_save_CFLAGS
 434
 435
 436 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 437 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 438 dnl actually supported.
 439 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 440         AC_TRY_RUN([
 441         __inline int foo () { return 0; }
 442         int main () { return foo (); }
 443         ],
 444         glib_cv_has__inline=yes
 445         ,
 446         glib_cv_has__inline=no
 447         ,)
 448 ])
 449 case x$glib_cv_has__inline in
 450 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 451 esac
 452 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 453         AC_TRY_RUN([
 454         __inline__ int foo () { return 0; }
 455         int main () { return foo (); }
 456         ],
 457         glib_cv_has__inline__=yes
 458         ,
 459         glib_cv_has__inline__=no
 460         ,)
 461 ])
 462 case x$glib_cv_has__inline__ in
 463 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 464 esac
 465 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 466         AC_TRY_RUN([
 467         #undef inline
 468         inline int foo () { return 0; }
 469         int main () { return foo (); }
 470         ],
 471         glib_cv_hasinline=yes
 472         ,
 473         glib_cv_hasinline=no
 474         ,)
 475 ])
 476 case x$glib_cv_hasinline in
 477 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 478 esac
 479
 480 # check for flavours of varargs macros
 481 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 482 AC_TRY_COMPILE([],[
 483 int a(int p1, int p2, int p3);
 484 #define call_a(...) a(1,__VA_ARGS__)
 485 call_a(2,3);
 486 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 487 AC_MSG_RESULT($g_have_iso_c_varargs)
 488
 489 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 490 if test "$CXX" = ""; then
 491 dnl No C++ compiler
 492   g_have_iso_cxx_varargs=no
 493 else
 494   AC_LANG_CPLUSPLUS
 495   AC_TRY_COMPILE([],[
 496 int a(int p1, int p2, int p3);
 497 #define call_a(...) a(1,__VA_ARGS__)
 498 call_a(2,3);
 499 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 500   AC_LANG_C
 501 fi
 502 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 503
 504 AC_MSG_CHECKING(for GNUC varargs macros)
 505 AC_TRY_COMPILE([],[
 506 int a(int p1, int p2, int p3);
 507 #define call_a(params...) a(1,params)
 508 call_a(2,3);
 509 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 510 AC_MSG_RESULT($g_have_gnuc_varargs)
 511
 512 # check for bytesex stuff
 513 AC_C_BIGENDIAN
 514
 515 # check for header files
 516 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h sys/param.h sys/poll.h sys/select.h])
 517 AC_CHECK_HEADERS([sys/time.h sys/times.h unistd.h values.h stdint.h sched.h])
 518
 519 # Checks for libcharset
 520 jm_LANGINFO_CODESET
 521 jm_GLIBC21
 522 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 523 AC_CHECK_FUNCS(setlocale)
 524
 525 AC_MSG_CHECKING(whether make is GNU Make)
 526 STRIP_BEGIN=
 527 STRIP_END=
 528 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 529         STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
 530         STRIP_END=')'
 531         AC_MSG_RESULT(yes)
 532 else
 533         AC_MSG_RESULT(no)
 534 fi
 535 STRIP_DUMMY=
 536 AC_SUBST(STRIP_DUMMY)
 537 AC_SUBST(STRIP_BEGIN)
 538 AC_SUBST(STRIP_END)
 539
 540 # check additional type sizes
 541 size_includes=["
 542 #include <stdarg.h>
 543 #include <stdio.h>
 544 #include <ctype.h>
 545 #include <string.h>
 546 "]
 547 if test "x$ac_cv_header_stdint_h" = "xyes"; then
 548   size_includes=["$size_includes
 549 #include <stdint.h>
 550 "]
 551 fi
 552 if test "x$ac_cv_header_unistd_h" = "xyes"; then
 553   size_includes=["$size_includes
 554 #include <unistd.h>
 555 "]
 556 fi
 557 GLIB_SIZEOF([$size_includes], size_t, size_t)
 558 GLIB_SIZEOF([$size_includes], ptrdiff_t, ptrdiff_t)
 559 GLIB_SIZEOF([$size_includes], intmax_t, intmax_t)
 560
 561 # Check for some functions
 562 AC_CHECK_FUNCS(lstat strerror strsignal memmove mkstemp vsnprintf stpcpy strcasecmp strncasecmp poll getcwd nanosleep vasprintf)
 563
 564 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 565 # The check is borrowed from the PERL Configure script.
 566 if test "$ac_cv_func_memmove" != "yes"; then
 567   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 568     glib_cv_working_bcopy,[AC_TRY_RUN([
 569       int main() {
 570         char buf[128], abc[128], *b;
 571         int len, off, align;
 572         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 573         for (align = 7; align >= 0; align--) {
 574           for (len = 36; len; len--) {
 575             b = buf+align; bcopy(abc, b, len);
 576             for (off = 1; off <= len; off++) {
 577               bcopy(b, b+off, len); bcopy(b+off, b, len);
 578                 if (bcmp(b, abc, len)) return(1);
 579             }
 580           }
 581         }
 582         return(0);
 583       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 584   if test "$glib_cv_working_bcopy" = "yes"; then
 585     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 586   fi
 587 fi
 588
 589 # Check for sys_errlist
 590 AC_MSG_CHECKING(for sys_errlist)
 591 AC_TRY_LINK(, [
 592 extern char *sys_errlist[];
 593 extern int sys_nerr;
 594 sys_errlist[sys_nerr-1][0] = 0;
 595 ], glib_ok=yes, glib_ok=no)
 596 AC_MSG_RESULT($glib_ok)
 597 if test "$glib_ok" = "no"; then
 598     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 599 fi
 600
 601 # Check for sys_siglist
 602 AC_MSG_CHECKING(for sys_siglist)
 603 AC_TRY_LINK(, [
 604 extern char *sys_siglist[];
 605 exit (sys_siglist[0]);
 606 ], glib_ok=yes, glib_ok=no)
 607 AC_MSG_RESULT($glib_ok)
 608 if test "$glib_ok" = "no"; then
 609     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 610 fi
 611
 612 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 613 AC_MSG_CHECKING(for sys_siglist declaration)
 614 AC_TRY_COMPILE([#include <signal.h>], [
 615 strlen (sys_siglist[0]);
 616 ], glib_ok=yes, glib_ok=no)
 617 AC_MSG_RESULT($glib_ok)
 618 if test "$glib_ok" = "no"; then
 619     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 620 fi
 621
 622 # Check if <sys/select.h> needs to be included for fd_set
 623 AC_MSG_CHECKING([for fd_set])
 624 AC_TRY_COMPILE([#include <sys/types.h>],
 625         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 626 if test "$gtk_ok" = "yes"; then
 627     AC_MSG_RESULT([yes, found in sys/types.h])
 628 else
 629     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
 630     if test "$gtk_ok" = "yes"; then
 631         # *** FIXME: give it a different name
 632         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
 633         AC_MSG_RESULT([yes, found in sys/select.h])
 634     else
 635         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
 636         AC_MSG_RESULT(no)
 637     fi
 638 fi
 639
 640 dnl *** check for sane realloc() ***
 641 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
 642         AC_TRY_RUN([
 643         #include <stdlib.h>
 644         int main() {
 645           return realloc (0, sizeof (int)) == 0;
 646         }],
 647         [glib_cv_sane_realloc=yes],
 648         [glib_cv_sane_realloc=no],
 649         [])
 650 ])
 651 if test x$glib_cv_sane_realloc = xyes; then
 652   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
 653 fi
 654
 655 dnl Check for nl_langinfo and CODESET
 656
 657 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
 658 AC_TRY_COMPILE([#include <langinfo.h>],
 659         [char *codeset = nl_langinfo (CODESET);],
 660    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
 661    have_codeset=yes,
 662    have_codeset=no)
 663 AC_MSG_RESULT($have_codeset)
 664
 665
 666 dnl ****************************************
 667 dnl *** strlcpy/strlcat                  ***
 668 dnl ****************************************
 669 # Check for strlcpy
 670 AC_MSG_CHECKING(for strlcpy/strlcat)
 671 AC_TRY_LINK([#include <stdlib.h>
 672 #include <string.h>], [
 673 char *p = malloc(10);
 674 (void) strlcpy(p, "hi", 10);
 675 (void) strlcat(p, "bye", 10);
 676 ], glib_ok=yes, glib_ok=no)
 677 AC_MSG_RESULT($glib_ok)
 678 if test "$glib_ok" = "yes"; then
 679     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
 680 fi
 681
 682
 683 dnl **********************
 684 dnl *** va_copy checks ***
 685 dnl **********************
 686 dnl we currently check for all three va_copy possibilities, so we get
 687 dnl all results in config.log for bug reports.
 688 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
 689         AC_TRY_RUN([
 690         #include <stdarg.h>
 691         void f (int i, ...) {
 692         va_list args1, args2;
 693         va_start (args1, i);
 694         va_copy (args2, args1);
 695         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 696           exit (1);
 697         va_end (args1); va_end (args2);
 698         }
 699         int main() {
 700           f (0, 42);
 701           return 0;
 702         }],
 703         [glib_cv_va_copy=yes],
 704         [glib_cv_va_copy=no],
 705         [])
 706 ])
 707 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
 708         AC_TRY_RUN([
 709         #include <stdarg.h>
 710         void f (int i, ...) {
 711         va_list args1, args2;
 712         va_start (args1, i);
 713         __va_copy (args2, args1);
 714         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 715           exit (1);
 716         va_end (args1); va_end (args2);
 717         }
 718         int main() {
 719           f (0, 42);
 720           return 0;
 721         }],
 722         [glib_cv___va_copy=yes],
 723         [glib_cv___va_copy=no],
 724         [])
 725 ])
 726
 727 if test "x$glib_cv_va_copy" = "xyes"; then
 728   g_va_copy_func=va_copy
 729 else if test "x$glib_cv___va_copy" = "xyes"; then
 730   g_va_copy_func=__va_copy
 731 fi
 732 fi
 733
 734 if test -n "$g_va_copy_func"; then
 735   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
 736 fi
 737
 738 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
 739         AC_TRY_RUN([
 740         #include <stdarg.h>
 741         void f (int i, ...) {
 742         va_list args1, args2;
 743         va_start (args1, i);
 744         args2 = args1;
 745         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 746           exit (1);
 747         va_end (args1); va_end (args2);
 748         }
 749         int main() {
 750           f (0, 42);
 751           return 0;
 752         }],
 753         [glib_cv_va_val_copy=yes],
 754         [glib_cv_va_val_copy=no],
 755         [])
 756 ])
 757
 758 if test "x$glib_cv_va_val_copy" = "xno"; then
 759   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 760 fi
 761
 762 dnl ***********************
 763 dnl *** g_module checks ***
 764 dnl ***********************
 765 G_MODULE_LIBS=
 766 G_MODULE_LIBS_EXTRA=
 767 G_MODULE_PLUGIN_LIBS=
 768 G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
 769 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
 770 G_MODULE_NEED_USCORE=0
 771 G_MODULE_BROKEN_RTLD_GLOBAL=0
 772 G_MODULE_HAVE_DLERROR=0
 773 dnl *** force native WIN32 shared lib loader
 774 if test -z "$G_MODULE_IMPL"; then
 775   case "$host" in
 776   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
 777   esac
 778 fi
 779 dnl *** dlopen() and dlsym() in system libraries
 780 if test -z "$G_MODULE_IMPL"; then
 781         AC_CHECK_FUNC(dlopen,
 782                       [AC_CHECK_FUNC(dlsym,
 783                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 784                       [])
 785 fi
 786 dnl *** load_image (BeOS)
 787 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
 788   AC_CHECK_LIB(root, load_image,
 789       [G_MODULE_LIBS="-lbe -lroot -lglib"
 790       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
 791       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
 792       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
 793       [])
 794 fi
 795 dnl *** dlopen() and dlsym() in libdl
 796 if test -z "$G_MODULE_IMPL"; then
 797         AC_CHECK_LIB(dl, dlopen,
 798                      [AC_CHECK_LIB(dl, dlsym,
 799                                    [G_MODULE_LIBS=-ldl
 800                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 801                      [])
 802 fi
 803 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
 804 if test -z "$G_MODULE_IMPL"; then
 805         AC_CHECK_FUNC(NSLinkModule,
 806                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
 807                        G_MODULE_NEED_USCORE=1],
 808                       [])
 809 fi
 810 dnl *** shl_load() in libdld (HP-UX)
 811 if test -z "$G_MODULE_IMPL"; then
 812         AC_CHECK_LIB(dld, shl_load,
 813                 [G_MODULE_LIBS=-ldld
 814                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
 815                 [])
 816 fi
 817 dnl *** additional checks for G_MODULE_IMPL_DL
 818 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 819         LIBS_orig="$LIBS"
 820         LDFLAGS_orig="$LDFLAGS"
 821         LIBS="$LIBS $G_MODULE_LIBS"
 822         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 823 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
 824         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
 825                 glib_cv_rtldglobal_broken,[
 826                 AC_TRY_RUN([
 827                 #include <dlfcn.h>
 828                 #ifndef RTLD_GLOBAL
 829                 #define RTLD_GLOBAL 0
 830                 #endif
 831                 #ifndef RTLD_LAZY
 832                 #define RTLD_LAZY 0
 833                 #endif
 834                 int pthread_create;
 835                 int main () {
 836                 void *handle, *global, *local;
 837                 global = &pthread_create;
 838                 handle = dlopen ("libpthread.so", RTLD_GLOBAL | RTLD_LAZY);
 839                 if (!handle) return 0;
 840                 local = dlsym (handle, "pthread_create");
 841                 return global == local;
 842                 }],
 843                         [glib_cv_rtldglobal_broken=no],
 844                         [glib_cv_rtldglobal_broken=yes],
 845                         [])
 846                 rm -f plugin.c plugin.o plugin.lo
 847         ])
 848         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
 849                 G_MODULE_BROKEN_RTLD_GLOBAL=1
 850         else
 851                 G_MODULE_BROKEN_RTLD_GLOBAL=0
 852         fi
 853 dnl *** check whether we need preceeding underscores
 854         AC_CACHE_CHECK([for preceeding underscore in symbols],
 855                 glib_cv_uscore,[
 856                 AC_TRY_RUN([
 857                 #include <dlfcn.h>
 858                 int glib_underscore_test (void) { return 42; }
 859                 int main() {
 860                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 861                   handle = dlopen ((void*)0, 0);
 862                   if (handle) {
 863                     f1 = dlsym (handle, "glib_underscore_test");
 864                     f2 = dlsym (handle, "_glib_underscore_test");
 865                   } return (!f2 || f1);
 866                 }],
 867                         [glib_cv_uscore=yes],
 868                         [glib_cv_uscore=no],
 869                         [])
 870                 rm -f plugin.c plugin.$ac_objext plugin.lo
 871         ])
 872         if test "x$glib_cv_uscore" = "xyes"; then
 873                 G_MODULE_NEED_USCORE=1
 874         else
 875                 G_MODULE_NEED_USCORE=0
 876         fi
 877
 878         LDFLAGS="$LDFLAGS_orig"
 879 dnl *** check for having dlerror()
 880         AC_CHECK_FUNC(dlerror,
 881                 [G_MODULE_HAVE_DLERROR=1],
 882                 [G_MODULE_HAVE_DLERROR=0])
 883         LIBS="$LIBS_orig"
 884 fi
 885 dnl *** done, have we got an implementation?
 886 if test -z "$G_MODULE_IMPL"; then
 887         G_MODULE_IMPL=0
 888         G_MODULE_SUPPORTED=false
 889 else
 890         G_MODULE_SUPPORTED=true
 891 fi
 892
 893 AC_MSG_CHECKING(for the suffix of shared libraries)
 894 case "$host_os" in
 895   hpux9* | hpux10* | hpux11*)  # taken from ltconfig
 896     glib_gmodule_suffix='sl'
 897     ;;
 898   cygwin* | mingw*)
 899     glib_gmodule_suffix='dll'
 900     ;;
 901   *)
 902     glib_gmodule_suffix='so'
 903     ;;
 904 esac
 905 AC_MSG_RESULT(.$glib_gmodule_suffix)
 906
 907 AC_SUBST(G_MODULE_SUPPORTED)
 908 AC_SUBST(G_MODULE_IMPL)
 909 AC_SUBST(G_MODULE_LIBS)
 910 AC_SUBST(G_MODULE_LIBS_EXTRA)
 911 AC_SUBST(G_MODULE_PLUGIN_LIBS)
 912 AC_SUBST(G_MODULE_LDFLAGS)
 913 AC_SUBST(G_MODULE_HAVE_DLERROR)
 914 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
 915 AC_SUBST(G_MODULE_NEED_USCORE)
 916 AC_SUBST(GLIB_DEBUG_FLAGS)
 917
 918 dnl **********************
 919 dnl *** g_spawn checks ***
 920 dnl **********************
 921
 922 AC_MSG_CHECKING(for gspawn implementation)
 923 case "$host" in
 924   *-*-mingw*)
 925     GSPAWN=gspawn-win32.lo
 926     ;;
 927   *)
 928     GSPAWN=gspawn.lo
 929     ;;
 930 esac
 931 AC_MSG_RESULT($GSPAWN)
 932 AC_SUBST(GSPAWN)
 933
 934 dnl *************************
 935 dnl *** GIOChannel checks ***
 936 dnl *************************
 937
 938 AC_MSG_CHECKING(for GIOChannel implementation)
 939 case "$host" in
 940   *-*-mingw*)
 941     GIO=giowin32.lo
 942     ;;
 943   *)
 944     GIO=giounix.lo
 945     ;;
 946 esac
 947 AC_MSG_RESULT($GIO)
 948 AC_SUBST(GIO)
 949
 950 dnl ****************************************
 951 dnl *** platform dependent source checks ***
 952 dnl ****************************************
 953
 954 AC_MSG_CHECKING(for platform-dependent source)
 955 case "$host" in
 956   *-*-cygwin*|*-*-mingw*)
 957     PLATFORMDEP=gwin32.lo
 958     ;;
 959   *)
 960     PLATFORMDEP=
 961     ;;
 962 esac
 963 AC_MSG_RESULT($PLATFORMDEP)
 964 AC_SUBST(PLATFORMDEP)
 965
 966 AC_MSG_CHECKING([whether to compile timeloop])
 967 case "$host" in
 968   *-*-cygwin*|*-*-mingw*)
 969     enable_timeloop=no
 970     ;;
 971   *)
 972     enable_timeloop=yes
 973     ;;
 974 esac
 975 AC_MSG_RESULT($enable_timeloop)
 976 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
 977
 978 AC_MSG_CHECKING([if building for some Win32 platform])
 979 case "$host" in
 980   *-*-mingw*|*-*-cygwin*)
 981     platform_win32=yes
 982     ;;
 983   *)
 984     platform_win32=no
 985     ;;
 986 esac
 987 AC_MSG_RESULT($platform_win32)
 988 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
 989
 990 dnl ***********************
 991 dnl *** g_thread checks ***
 992 dnl ***********************
 993
 994 AC_ARG_WITH(threads, [  --with-threads=[none/posix/dce/solaris/win32] specify a thread implementation to use],
 995         if test "x$with_threads" = x; then
 996                 want_threads=yes
 997         else
 998                 want_threads=$with_threads
 999         fi,
1000         want_threads=yes)
1001 if test "x$enable_threads" = "xno"; then
1002         want_threads=no
1003 fi
1004
1005 dnl error and warning message
1006 dnl *************************
1007
1008 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1009                 computer. GLib will not have a default thread implementation."
1010
1011 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1012                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1013                 compilation now, but then your programs might not work.
1014                 Please provide information on how it is done on your system."
1015
1016 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1017                 "
1018
1019 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1020                 provide information on your thread implementation.
1021                 You can also run 'configure --disable-threads'
1022                 to compile without thread support."
1023
1024 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1025                 functions will not be MT-safe during their first call because
1026                 there is no working 'getpwuid_r' on your system."
1027
1028 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1029                 because there is no 'localtime_r' on your system."
1030
1031 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1032                 crude surrogate will be used. If you happen to know a
1033                 yield function for your system, please inform the GLib
1034                 developers."
1035
1036 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1037                 threads on your system. Thus threads can only have the default
1038                 priority. If you happen to know these main/max
1039                 priorities, please inform the GLib developers."
1040
1041
1042 dnl determination of thread implementation
1043 dnl ***************************************
1044
1045 # have_threads=no   means no thread support
1046 # have_threads=none means no default thread implementation
1047
1048 have_threads=no
1049 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
1050         case $host in
1051                 *-*-solaris*)
1052                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
1053                 ;;
1054         esac
1055 fi
1056 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1057                                 || test "x$want_threads" = xdce; then
1058         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1059         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1060         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1061         glib_save_CPPFLAGS="$CPPFLAGS"
1062         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1063         if test "x$have_threads" = xno; then
1064                 AC_TRY_COMPILE([#include <pthread.h>],
1065                         [pthread_attr_t attr; pthread_attr_init(&attr);],
1066                         have_threads=posix)
1067         fi
1068         if test "x$have_threads" = xno; then
1069                 AC_TRY_COMPILE([#include <pthread.h>],
1070                         [pthread_attr_t attr; pthread_attr_create(&attr);],
1071                         have_threads=posix)
1072         fi
1073         CPPFLAGS="$glib_save_CPPFLAGS"
1074 fi
1075 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1076         case $host in
1077                 *-*-mingw*)
1078                 have_threads=win32
1079                 ;;
1080         esac
1081 fi
1082 if test "x$want_threads" = xnone; then
1083         have_threads=none
1084 fi
1085
1086 AC_MSG_CHECKING(for thread implementation)
1087
1088 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1089         AC_MSG_RESULT(none available)
1090         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1091 else
1092         AC_MSG_RESULT($have_threads)
1093 fi
1094
1095
1096 dnl determination of G_THREAD_CFLAGS
1097 dnl ********************************
1098
1099 G_THREAD_LIBS=
1100 G_THREAD_LIBS_EXTRA=
1101 G_THREAD_CFLAGS=
1102
1103 if test x"$have_threads" != xno; then
1104
1105     G_THREAD_CFLAGS="-D_REENTRANT" # good default guess
1106
1107     case $host in
1108         *-aix*)
1109                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
1110                 if test x"$GCC" = xyes; then
1111                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
1112                 fi
1113                 ;;
1114         *-freebsd2.2*)
1115                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
1116
1117                 # FreeBSD 2.2.x shiped with gcc 2.7.2.x, which doesn't support
1118                 # -mthreads flag.
1119                 ;;
1120         *-sysv5uw7*)  # UnixWare 7
1121                 if test "$GCC" != "yes"; then
1122                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -Kthread"
1123                 else
1124                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -pthread"
1125                 fi
1126                 ;;
1127         *-dg-dgux*)  # DG/UX
1128                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
1129     esac
1130
1131     # if we are not finding the localtime_r function, then we probably are
1132     # not using the proper multithread flag
1133
1134     glib_save_CPPFLAGS="$CPPFLAGS"
1135     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1136
1137     # First we test, whether localtime_r is declared in time.h
1138     # directly. Then we test whether a macro localtime_r exists, in
1139     # which case localtime_r in the test program is replaced and thus
1140     # if we still find localtime_r in the output, it is not defined as
1141     # a macro.
1142
1143     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1144       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1145                                                            localtime_r(a,b)],
1146                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1147
1148     CPPFLAGS="$glib_save_CPPFLAGS"
1149
1150     AC_MSG_CHECKING(thread related cflags)
1151     AC_MSG_RESULT($G_THREAD_CFLAGS)
1152     CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
1153 fi
1154
1155 dnl determination of G_THREAD_LIBS
1156 dnl ******************************
1157
1158 mutex_has_default=no
1159 case $have_threads in
1160         posix|dce)
1161            glib_save_CPPFLAGS="$CPPFLAGS"
1162            CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1163            G_THREAD_LIBS=error
1164            glib_save_LIBS="$LIBS"
1165            case $host in
1166              *-sysv5uw7*) # UnixWare 7
1167                 if test "$GCC" != "yes"; then
1168                         G_THREAD_LIBS="-Kthread"
1169                 else
1170                         G_THREAD_LIBS="-pthread"
1171                 fi
1172                 ;;
1173              *)
1174                 for thread_lib in "" pthread pthread32 pthreads c_r thread dce; do
1175                         if test x"$thread_lib" = x; then
1176                                 add_thread_lib=""
1177                                 IN=""
1178                         else
1179                                 add_thread_lib="-l$thread_lib"
1180                                 IN=" in -l$thread_lib"
1181                         fi
1182                         if test x"$have_threads" = xposix; then
1183                                 defattr=0
1184                         else
1185                                 defattr=pthread_attr_default
1186                         fi
1187
1188                         LIBS="$glib_save_LIBS $add_thread_lib"
1189
1190                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
1191                         AC_TRY_RUN([#include <pthread.h>
1192                                 int check_me = 0;
1193                                 void* func(void* data) {check_me = 42;}
1194                                 main()
1195                                 { pthread_t t;
1196                                   void *ret;
1197                                   pthread_create (&t, $defattr, func, 0);
1198                                   pthread_join (t, &ret);
1199                                   exit (check_me != 42);
1200                                 }],
1201                                 [AC_MSG_RESULT(yes)
1202                                 G_THREAD_LIBS="$add_thread_lib"
1203                                 break],
1204                                 [AC_MSG_RESULT(no)])
1205                 done
1206                 if test "x$G_THREAD_LIBS" = xerror; then
1207                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1208                 fi
1209                 for thread_lib in "" rt rte; do
1210                         if test x"$thread_lib" = x; then
1211                                 add_thread_lib=""
1212                                 IN=""
1213                         else
1214                                 add_thread_lib="-l$thread_lib"
1215                                 IN=" in -l$thread_lib"
1216                         fi
1217                         LIBS="$glib_save_LIBS $add_thread_lib"
1218
1219                         AC_MSG_CHECKING(for sched_get_priority_min$IN)
1220                         AC_TRY_RUN([#include <sched.h>
1221                                 #include <errno.h>
1222                                 int main() {
1223                                 errno = 0;
1224                                 return sched_get_priority_min(SCHED_OTHER)==-1
1225                                         && errno != 0;
1226                                 }],
1227                                 [AC_MSG_RESULT(yes)
1228                                 G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
1229                                 posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
1230                                 posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
1231                                 break],
1232                                 [AC_MSG_RESULT(no)])
1233                 done
1234                 LIBS="$glib_save_LIBS"
1235                 ;;
1236            esac
1237            mutex_has_default=yes
1238            mutex_default_type='pthread_mutex_t'
1239            mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
1240            mutex_header_file='pthread.h'
1241            if test "x$have_threads" = "xposix"; then
1242              g_threads_impl="POSIX"
1243            else
1244              g_threads_impl="DCE"
1245              have_threads="posix"
1246            fi
1247            AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
1248            CPPFLAGS="$glib_save_CPPFLAGS"
1249            ;;
1250         solaris)
1251            G_THREAD_LIBS=error
1252            AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
1253            mutex_has_default=yes
1254            mutex_default_type='mutex_t'
1255            mutex_default_init="DEFAULTMUTEX"
1256            mutex_header_file='thread.h'
1257            g_threads_impl="SOLARIS"
1258            ;;
1259         win32)
1260            g_threads_impl="WIN32"
1261            G_THREAD_LIBS=""
1262            ;;
1263         none)
1264            g_threads_impl="NONE"
1265            ;;
1266         *)
1267            g_threads_impl="NONE"
1268            G_THREAD_LIBS=error
1269            ;;
1270 esac
1271
1272 if test "x$G_THREAD_LIBS" = xerror; then
1273         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1274 fi
1275
1276 case $host in
1277   *-*-beos*)
1278     G_THREAD_LIBS="-lbe -lroot -lglib "
1279     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1280     ;;
1281   *)
1282     ;;
1283 esac
1284
1285 AC_MSG_CHECKING(thread related libraries)
1286 AC_MSG_RESULT($G_THREAD_LIBS)
1287
1288 dnl check for mt safe function variants and some posix functions
1289 dnl ************************************************************
1290
1291 if test x"$have_threads" != xno; then
1292         glib_save_LIBS="$LIBS"
1293         # we are not doing the following for now, as this might require glib
1294         # to always be linked with the thread libs on some platforms.
1295         # LIBS="$LIBS $G_THREAD_LIBS"
1296         AC_CHECK_FUNCS(localtime_r)
1297         if test "$ac_cv_header_pwd_h" = "yes"; then
1298                 AC_CACHE_CHECK([for posix getpwuid_r],
1299                         ac_cv_func_posix_getpwuid_r,
1300                         [AC_TRY_RUN([#include <errno.h>
1301                                 #include <pwd.h>
1302                                 int main () { char buffer[10000];
1303                                 struct passwd pwd, *pwptr = &pwd;
1304                                 int error;
1305                                 errno = 0;
1306                                 error = getpwuid_r (0, &pwd, buffer,
1307                                         sizeof (buffer), &pwptr);
1308                                 return (error < 0 && errno == ENOSYS)
1309                                         || error == ENOSYS; }],
1310                                 [ac_cv_func_posix_getpwuid_r=yes],
1311                                 [ac_cv_func_posix_getpwuid_r=no])])
1312                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
1313                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
1314                                 [Have POSIX function getpwuid_r])
1315                 else
1316                         AC_CACHE_CHECK([for nonposix getpwuid_r],
1317                                 ac_cv_func_nonposix_getpwuid_r,
1318                                 [AC_TRY_LINK([#include <pwd.h>],
1319                                         [char buffer[10000];
1320                                         struct passwd pwd;
1321                                         getpwuid_r (0, &pwd, buffer,
1322                                                         sizeof (buffer));],
1323                                         [ac_cv_func_nonposix_getpwuid_r=yes],
1324                                         [ac_cv_func_nonposix_getpwuid_r=no])])
1325                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
1326                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
1327                                         [Have non-POSIX function getpwuid_r])
1328                         fi
1329                 fi
1330         fi
1331         LIBS="$LIBS $G_THREAD_LIBS"
1332         if test x"$have_threads" = xposix; then
1333                 glib_save_CPPFLAGS="$CPPFLAGS"
1334                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1335                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
1336                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
1337                 # This is not AC_CHECK_FUNC to also work with function
1338                 # name mangling in header files.
1339                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1340                 AC_TRY_LINK([#include <pthread.h>],
1341                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1342                         [AC_MSG_RESULT(yes)
1343                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1344                                   [Have function pthread_attr_setstacksize])],
1345                         [AC_MSG_RESULT(no)])
1346                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1347                 if test x"$posix_priority_min" = xnone; then
1348                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1349                                 PX_PRIO_MIN],,[
1350                                 posix_priority_min=PX_PRIO_MIN
1351                                 posix_priority_max=PX_PRIO_MAX])
1352                 fi
1353                 if test x"$posix_priority_min" = xnone; then
1354                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1355                                 PRI_OTHER_MIN],,[
1356                                 posix_priority_min=PRI_OTHER_MIN
1357                                 posix_priority_max=PRI_OTHER_MAX])
1358                 fi
1359                 if test x"$posix_priority_min" = x; then
1360                         AC_MSG_RESULT(none found)
1361                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1362                         posix_priority_min=-1
1363                         posix_priority_max=-1
1364                 else
1365                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1366                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1367                         AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])
1368                 fi
1369                 posix_yield_func=none
1370                 AC_MSG_CHECKING(for posix yield function)
1371                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1372                                                         thr_yield; do
1373                         AC_TRY_LINK([#include <pthread.h>],
1374                                 [$yield_func()],
1375                                 [posix_yield_func="$yield_func"
1376                                 break])
1377                 done
1378                 if test x"$posix_yield_func" = xnone; then
1379                         AC_MSG_RESULT(none found)
1380                         AC_MSG_WARN($POSIX_NO_YIELD)
1381                         posix_yield_func="g_usleep(1000)"
1382                 else
1383                         AC_MSG_RESULT($posix_yield_func)
1384                         posix_yield_func="$posix_yield_func()"
1385                 fi
1386                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1387                 CPPFLAGS="$glib_save_CPPFLAGS"
1388
1389                 AC_MSG_CHECKING(whether to use the PID niceness surrogate for thread priorities)
1390                 AC_TRY_RUN([#include <pthread.h>
1391                         #include <sys/types.h>
1392                         #include <unistd.h>
1393                         pid_t other_pid = 0;
1394
1395                         void* func(void* data) {other_pid = getpid();}
1396                         main()
1397                         { pthread_t t;
1398                           void *ret;
1399                           pthread_create (&t, $defattr, func, NULL);
1400                           pthread_join (t, &ret);
1401                           exit (getpid()==other_pid ||
1402                                 $posix_priority_min != $posix_priority_max);
1403                         }],
1404                         [AC_MSG_RESULT(yes)
1405                           AC_DEFINE(G_THREAD_USE_PID_SURROGATE, 1, [whether to use the PID niceness surrogate for thread priorities])
1406                         ],
1407                         [AC_MSG_RESULT(no)])
1408         elif test x"$have_threads" = xwin32; then
1409                 # It's a pointer to a private struct
1410                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
1411         elif test x"$have_threads" = xsolaris; then
1412                 GLIB_SIZEOF([#include <thread.h>], thread_t, system_thread)
1413         fi
1414
1415         LIBS="$glib_save_LIBS"
1416
1417         # now spit out all the warnings.
1418         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1419            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1420                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1421         fi
1422         if test "$ac_cv_func_localtime_r" != "yes"; then
1423                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1424         fi
1425 fi
1426
1427 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1428                    [Source file containing theread implementation])
1429 AC_SUBST(G_THREAD_CFLAGS)
1430 AC_SUBST(G_THREAD_LIBS)
1431 AC_SUBST(G_THREAD_LIBS_EXTRA)
1432
1433 dnl **********************************************
1434 dnl *** GDefaultMutex setup and initialization ***
1435 dnl **********************************************
1436 dnl
1437 dnl if mutex_has_default = yes, we also got
1438 dnl mutex_default_type, mutex_default_init and mutex_header_file
1439 GLIB_IF_VAR_EQ(mutex_has_default, yes,
1440         glib_save_CPPFLAGS="$CPPFLAGS"
1441         glib_save_LIBS="$LIBS"
1442         LIBS="$LIBS $G_THREAD_LIBS"
1443         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1444         GLIB_SIZEOF([#include <$mutex_header_file>],
1445                     $mutex_default_type,
1446                     gmutex,
1447                     )
1448         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1449                            $mutex_default_type,
1450                            gmutex,
1451                            $glib_cv_sizeof_gmutex,
1452                            $mutex_default_init)
1453         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1454                 mutex_has_default=no
1455         fi
1456         CPPFLAGS="$glib_save_CPPFLAGS"
1457         LIBS="$glib_save_LIBS"
1458         ,
1459 )
1460
1461
1462 dnl ****************************************
1463 dnl *** GLib POLL* compatibility defines ***
1464 dnl ****************************************
1465 GLIB_SYSDEFS(
1466 [#include <sys/types.h>
1467 #include <sys/poll.h>],
1468         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
1469         glibconfig-sysdefs.h,
1470         =)
1471
1472 dnl **********************
1473 dnl *** Win32 API libs ***
1474 dnl **********************
1475
1476 case $host in
1477   *-*-cygwin*)
1478         G_LIBS_EXTRA="-luser32 -lwsock32 -lkernel32"
1479     ;;
1480   *-*-mingw*)
1481         G_LIBS_EXTRA="-lwsock32"
1482     ;;
1483   *)
1484         G_LIBS_EXTRA=""
1485     ;;
1486 esac
1487 AC_SUBST(G_LIBS_EXTRA)
1488
1489 dnl ***********************
1490 dnl *** Tests for iconv ***
1491 dnl ***********************
1492
1493 AC_ARG_WITH(libiconv, [ --with-libiconv     Use the libiconv library ],,with_libiconv=maybe)
1494
1495 found_iconv=no
1496
1497 if test "x$with_libiconv" != "xyes" ; then
1498    #
1499    # Check in the C library
1500    #
1501    AC_CHECK_FUNC(iconv_open, with_libiconv=no; found_iconv=yes)
1502 fi
1503
1504 if test "x$with_libiconv" != "xno" ; then
1505    #
1506    # Check for libiconv
1507    #
1508    AC_CHECK_LIB(iconv, libiconv_open, with_libiconv=yes; found_iconv=yes)
1509 fi
1510
1511 if test "x$found_iconv" = "xno" ; then
1512    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
1513 fi
1514
1515 if test "x$with_libiconv" = "xyes" ; then
1516   ICONV_LIBS="-liconv"
1517   AC_DEFINE(USE_LIBICONV)
1518 fi
1519 AC_SUBST(ICONV_LIBS)
1520
1521 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
1522 dnl since we need it for g_iconv()
1523
1524 AC_MSG_CHECKING([for EILSEQ])
1525 AC_TRY_COMPILE([
1526 #include <errno.h>
1527 ],
1528 [
1529 int error = EILSEQ;
1530 ], have_eilseq=yes, have_eilseq=no);
1531 AC_MSG_RESULT($have_eilseq)
1532
1533 dnl **************************
1534 dnl *** Checks for gtk-doc ***
1535 dnl **************************
1536
1537 AC_ARG_WITH(html-dir, [  --with-html-dir=PATH    path to installed docs])
1538
1539 if test "x$with_html_dir" = "x" ; then
1540   HTML_DIR='${datadir}/gtk-doc/html'
1541 else
1542   HTML_DIR=$with_html_dir
1543 fi
1544
1545 AC_SUBST(HTML_DIR)
1546
1547 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
1548
1549 gtk_doc_min_version=0.6
1550 if $GTKDOC ; then
1551     gtk_doc_version=`gtkdoc-mkdb --version`
1552     AC_MSG_CHECKING([gtk-doc version ($gtk_doc_version) >= $gtk_doc_min_version])
1553     if perl <<EOF ; then
1554       exit (("$gtk_doc_version" =~ /^[[0-9]]+\.[[0-9]]+$/) &&
1555             ("$gtk_doc_version" >= "$gtk_doc_min_version") ? 0 : 1);
1556 EOF
1557       AC_MSG_RESULT(yes)
1558    else
1559       AC_MSG_RESULT(no)
1560       GTKDOC=false
1561    fi
1562 fi
1563
1564 AM_CONDITIONAL(HAVE_GTK_DOC, $GTKDOC)
1565 AC_SUBST(HAVE_GTK_DOC)
1566
1567 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1568 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1569
1570 dnl Let people disable the gtk-doc stuff.
1571 AC_ARG_ENABLE(gtk-doc, [  --enable-gtk-doc        use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)
1572
1573 if test x$enable_gtk_doc = xauto ; then
1574   if test x$GTKDOC = xtrue ; then
1575     enable_gtk_doc=yes
1576   else
1577     enable_gtk_doc=no
1578   fi
1579 fi
1580
1581 dnl NOTE: We need to use a separate automake conditional for this
1582 dnl       to make this work with the tarballs.
1583 AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
1584
1585 dnl ******************************
1586 dnl *** output the whole stuff ***
1587 dnl ******************************
1588
1589 AC_OUTPUT_COMMANDS([
1590
1591 ## Generate `glibconfig.h' in two cases
1592 ## 1. `config.status' is run either explicitly, or via configure.
1593 ##     Esp. not when it is run in `Makefile' to generate makefiles and
1594 ##     config.h
1595 ## 2. CONFIG_OTHER is set explicitly
1596 ##
1597 ## Case 1 is difficult.  We know that `automake' sets one of
1598 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
1599 ## only when AM_CONFIG_HEADER is set, however.
1600
1601 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
1602   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
1603   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
1604 fi
1605 case "$CONFIG_OTHER" in
1606 *glibconfig.h*)
1607         echo creating glibconfig.h
1608         outfile=glibconfig.h-tmp
1609         cat > $outfile <<\_______EOF
1610 /* glibconfig.h
1611  *
1612  * This is a generated file.  Please modify 'configure.in'
1613  */
1614
1615 #ifndef __G_LIBCONFIG_H__
1616 #define __G_LIBCONFIG_H__
1617
1618 #include <glib/gmacros.h>
1619
1620 _______EOF
1621
1622         if test x$glib_limits_h = xyes; then
1623           echo '#include <limits.h>' >> $outfile
1624         fi
1625         if test x$glib_float_h = xyes; then
1626           echo '#include <float.h>' >> $outfile
1627         fi
1628         if test x$glib_values_h = xyes; then
1629           echo '#include <values.h>' >> $outfile
1630         fi
1631         if test "$glib_header_alloca_h" = "yes"; then
1632           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
1633         fi
1634         if test x$glib_sys_poll_h = xyes; then
1635           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
1636         fi
1637
1638         cat >> $outfile <<_______EOF
1639
1640 G_BEGIN_DECLS
1641
1642 #define G_MINFLOAT      $glib_mf
1643 #define G_MAXFLOAT      $glib_Mf
1644 #define G_MINDOUBLE     $glib_md
1645 #define G_MAXDOUBLE     $glib_Md
1646 #define G_MINSHORT      $glib_ms
1647 #define G_MAXSHORT      $glib_Ms
1648 #define G_MAXUSHORT     $glib_Mus
1649 #define G_MININT        $glib_mi
1650 #define G_MAXINT        $glib_Mi
1651 #define G_MAXUINT       $glib_Mui
1652 #define G_MINLONG       $glib_ml
1653 #define G_MAXLONG       $glib_Ml
1654 #define G_MAXULONG      $glib_Mul
1655
1656 #define G_MININT64      ((gint64)  0x8000000000000000)
1657 #define G_MAXINT64      ((gint64)  0x7fffffffffffffff)
1658 #define G_MAXUINT64     ((guint64) 0xffffffffffffffff)
1659
1660 _______EOF
1661
1662
1663         ### this should always be true in a modern C/C++ compiler
1664         cat >>$outfile <<_______EOF
1665 typedef signed char gint8;
1666 typedef unsigned char guint8;
1667 _______EOF
1668
1669
1670         if test -n "$gint16"; then
1671           cat >>$outfile <<_______EOF
1672 typedef signed $gint16 gint16;
1673 typedef unsigned $gint16 guint16;
1674 #define G_GINT16_FORMAT $gint16_format
1675 #define G_GUINT16_FORMAT $guint16_format
1676 _______EOF
1677         fi
1678
1679
1680         if test -n "$gint32"; then
1681           cat >>$outfile <<_______EOF
1682 typedef signed $gint32 gint32;
1683 typedef unsigned $gint32 guint32;
1684 #define G_GINT32_FORMAT $gint32_format
1685 #define G_GUINT32_FORMAT $guint32_format
1686 _______EOF
1687         fi
1688
1689         cat >>$outfile <<_______EOF
1690 #define G_HAVE_GINT64 1          /* deprecated, always true */
1691
1692 ${glib_extension}typedef signed $gint64 gint64;
1693 ${glib_extension}typedef unsigned $gint64 guint64;
1694
1695 #define G_GINT64_CONSTANT(val)  $gint64_constant
1696
1697 #define G_GINT64_FORMAT $gint64_format
1698 #define G_GUINT64_FORMAT $guint64_format
1699 _______EOF
1700
1701         cat >>$outfile <<_______EOF
1702
1703 #define GLIB_SIZEOF_VOID_P $glib_void_p
1704 #define GLIB_SIZEOF_LONG   $glib_long
1705 #define GLIB_SIZEOF_SIZE_T $glib_size_t
1706
1707 _______EOF
1708
1709         case x$glib_size_t in
1710         x2) echo "typedef gint16  gssize;" >> $outfile
1711             echo "typedef guint16 gsize;"  >> $outfile
1712             ;;
1713         x4) echo "typedef gint32  gssize;" >> $outfile
1714             echo "typedef guint32 gsize;"  >> $outfile
1715             ;;
1716         x8) echo "typedef gint64  gssize;" >> $outfile
1717             echo "typedef guint64 gsize;"  >> $outfile
1718             ;;
1719         *)  echo "#error size of size_t is unknown" >> $outfile
1720             ;;
1721         esac
1722
1723         if test -z "$glib_unknown_void_p"; then
1724           cat >>$outfile <<_______EOF
1725
1726 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
1727 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
1728
1729 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
1730 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
1731 _______EOF
1732         else
1733           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
1734         fi
1735
1736
1737
1738         cat >>$outfile <<_______EOF
1739 $glib_atexit
1740 $glib_memmove
1741 $glib_defines
1742 $glib_os
1743
1744 $glib_vacopy
1745
1746 #ifdef  __cplusplus
1747 #define G_HAVE_INLINE   1
1748 #else   /* !__cplusplus */
1749 $glib_inline
1750 #endif  /* !__cplusplus */
1751
1752 _______EOF
1753
1754         if test x$g_have_iso_c_varargs = xyes ; then
1755                 cat >>$outfile <<_______EOF
1756 #ifndef __cplusplus
1757 # define G_HAVE_ISO_VARARGS 1
1758 #endif
1759 _______EOF
1760         fi
1761         if test x$g_have_iso_cxx_varargs = xyes ; then
1762                 cat >>$outfile <<_______EOF
1763 #ifdef __cplusplus
1764 # define G_HAVE_ISO_VARARGS 1
1765 #endif
1766 _______EOF
1767         fi
1768         if test x$g_have_gnuc_varargs = xyes ; then
1769                 cat >>$outfile <<_______EOF
1770
1771 #define G_HAVE_GNUC_VARARGS 1
1772 _______EOF
1773         fi
1774
1775         echo >>$outfile
1776         if test x$g_have_eilseq = xno; then
1777                 cat >>$outfile <<_______EOF
1778 #ifndef EILSEQ
1779 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
1780  * The correspondence between this and the corresponding definition
1781  * in libiconv is essential.
1782  */
1783 #  define EILSEQ ENOENT
1784 #endif
1785 _______EOF
1786
1787         fi
1788
1789         echo >>$outfile
1790         if test x$g_mutex_has_default = xyes; then
1791                 cat >>$outfile <<_______EOF
1792 $g_enable_threads_def G_THREADS_ENABLED
1793 #define G_THREADS_IMPL_$g_threads_impl_def
1794 typedef struct _GStaticMutex GStaticMutex;
1795 struct _GStaticMutex
1796 {
1797   struct _GMutex *runtime_mutex;
1798   union {
1799     char   pad[$g_mutex_sizeof];
1800     double dummy_double;
1801     void  *dummy_pointer;
1802     long   dummy_long;
1803   } static_mutex;
1804 };
1805 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
1806 #define g_static_mutex_get_mutex(mutex) \
1807   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->static_mutex)) : \
1808    g_static_mutex_get_mutex_impl (&((mutex)->runtime_mutex)))
1809 _______EOF
1810         else
1811                 cat >>$outfile <<_______EOF
1812 $g_enable_threads_def G_THREADS_ENABLED
1813 #define G_THREADS_IMPL_$g_threads_impl_def
1814 typedef struct _GMutex* GStaticMutex;
1815 #define G_STATIC_MUTEX_INIT NULL
1816 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (mutex))
1817 _______EOF
1818         fi
1819
1820         cat >>$outfile <<_______EOF
1821 /* This represents a system thread as used by the implementation. An
1822  * alien implementaion, as loaded by g_thread_init can only count on
1823  * "sizeof (gpointer)" bytes to store their info. We however need more
1824  * for some of our native implementations. */
1825 typedef union _GSystemThread GSystemThread;
1826 union _GSystemThread
1827 {
1828   char   data[$g_system_thread_sizeof];
1829   double dummy_double;
1830   void  *dummy_pointer;
1831   long   dummy_long;
1832 };
1833 _______EOF
1834
1835         echo >>$outfile
1836         g_bit_sizes="16 32 64"
1837         for bits in $g_bit_sizes; do
1838           cat >>$outfile <<_______EOF
1839 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
1840 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
1841 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
1842 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
1843 _______EOF
1844         done
1845
1846         cat >>$outfile <<_______EOF
1847 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
1848 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
1849 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
1850 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
1851 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
1852 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
1853 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
1854 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
1855 #define G_BYTE_ORDER $g_byte_order
1856
1857 _______EOF
1858
1859         if test -r glibconfig-sysdefs.h; then
1860           cat glibconfig-sysdefs.h >>$outfile
1861         fi
1862
1863         cat >>$outfile <<_______EOF
1864
1865 #define G_MODULE_SUFFIX "$g_module_suffix"
1866
1867 G_END_DECLS
1868
1869 #endif /* GLIBCONFIG_H */
1870 _______EOF
1871
1872
1873         if cmp -s $outfile glibconfig.h; then
1874           echo glibconfig.h is unchanged
1875           rm -f $outfile
1876         else
1877           mv $outfile glibconfig.h
1878         fi ;;
1879 esac
1880 ],[
1881
1882 # Note that if two cases are the same, case goes with the first one.
1883 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
1884 # on variable expansion in case labels.  Look at the generated config.status
1885 # for a hint.
1886
1887 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
1888   glib_header_alloca_h="$ac_cv_working_alloca_h"
1889 else
1890   glib_header_alloca_h="$ac_cv_header_alloca_h"
1891 fi
1892
1893 case xyes in
1894 x$ac_cv_header_float_h)
1895   glib_float_h=yes
1896   glib_mf=FLT_MIN glib_Mf=FLT_MAX
1897   glib_md=DBL_MIN glib_Md=DBL_MAX
1898   ;;
1899 x$ac_cv_header_values_h)
1900   glib_values_h=yes
1901   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
1902   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
1903   ;;
1904 esac
1905
1906 case xyes in
1907 x$ac_cv_header_limits_h)
1908   glib_limits_h=yes
1909   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
1910   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
1911   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
1912   ;;
1913 x$ac_cv_header_values_h)
1914   glib_values_h=yes
1915   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
1916   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
1917   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
1918   ;;
1919 esac
1920
1921 if test x$ac_cv_header_sys_poll_h = xyes ; then
1922   glib_sys_poll_h=yes
1923 fi
1924
1925 case 2 in
1926 $ac_cv_sizeof_short)
1927   gint16=short
1928   gint16_format='"hi"'
1929   guint16_format='"hu"'
1930   ;;
1931 $ac_cv_sizeof_int)
1932   gint16=int
1933   gint16_format='"i"'
1934   guint16_format='"u"'
1935   ;;
1936 esac
1937 case 4 in
1938 $ac_cv_sizeof_short)
1939   gint32=short
1940   gint32_format='"hi"'
1941   guint32_format='"hu"'
1942   ;;
1943 $ac_cv_sizeof_int)
1944   gint32=int
1945   gint32_format='"i"'
1946   guint32_format='"u"'
1947   ;;
1948 $ac_cv_sizeof_long)
1949   gint32=long
1950   gint32_format='"li"'
1951   guint32_format='"lu"'
1952   ;;
1953 esac
1954 case 8 in
1955 $ac_cv_sizeof_int)
1956   gint64=int
1957   gint64_format='"i"'
1958   guint64_format='"u"'
1959   glib_extension=
1960   gint64_constant='(val)'
1961   ;;
1962 $ac_cv_sizeof_long)
1963   gint64=long
1964   gint64_format='"li"'
1965   guint64_format='"lu"'
1966   glib_extension=
1967   gint64_constant='(val##L)'
1968   ;;
1969 $ac_cv_sizeof_long_long)
1970   gint64='long long'
1971   if test -n "$glib_cv_long_long_format"; then
1972     gint64_format='"'$glib_cv_long_long_format'i"'
1973     guint64_format='"'$glib_cv_long_long_format'u"'
1974   fi
1975   glib_extension='G_GNUC_EXTENSION '
1976   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1977   ;;
1978 $ac_cv_sizeof___int64)
1979   gint64='__int64'
1980   if test -n "$glib_cv_long_long_format"; then
1981     gint64_format='"'$glib_cv_long_long_format'i"'
1982     guint64_format='"'$glib_cv_long_long_format'u"'
1983   fi
1984   glib_extension=
1985   gint64_constant='(val##i64)'
1986   ;;
1987 esac
1988 glib_size_t=$glib_cv_sizeof_size_t
1989 glib_void_p=$ac_cv_sizeof_long
1990 glib_long=$ac_cv_sizeof_void_p
1991
1992 gintbits=`expr $ac_cv_sizeof_int \* 8`
1993 glongbits=`expr $ac_cv_sizeof_long \* 8`
1994
1995
1996 case $ac_cv_sizeof_void_p in
1997 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
1998 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
1999 *)                      glib_unknown_void_p=yes ;;
2000 esac
2001
2002
2003 case xyes in
2004 x$ac_cv_func_atexit)
2005   glib_atexit="
2006 #ifdef NeXT /* @#%@! NeXTStep */
2007 # define g_ATEXIT(proc) (!atexit (proc))
2008 #else
2009 # define g_ATEXIT(proc) (atexit (proc))
2010 #endif"
2011   ;;
2012 x$ac_cv_func_on_exit)
2013   glib_atexit="
2014 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
2015   ;;
2016 esac
2017
2018 case xyes in
2019 x$ac_cv_func_memmove)
2020   glib_memmove='
2021 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
2022   ;;
2023 x$glib_cv_working_bcopy)
2024   glib_memmove="
2025 /* memmove isn't available, but bcopy can copy overlapping memory regions */
2026 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
2027   ;;
2028 *)
2029   glib_memmove="
2030 /* memmove isn't found and bcopy can't copy overlapping memory regions,
2031  * so we have to roll our own copy routine. */
2032 void g_memmove (void* dest, const void * src, unsigned long len);"
2033   ;;
2034 esac
2035
2036 glib_defines="
2037 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
2038 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
2039 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
2040 "
2041
2042 case xyes in
2043 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
2044 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
2045 *)                      glib_vacopy=''
2046 esac
2047
2048 if test x$glib_cv_va_val_copy = xno; then
2049   glib_vacopy="\$glib_vacopy
2050 #define G_VA_COPY_AS_ARRAY 1"
2051 fi
2052
2053 if test x$glib_cv_hasinline = xyes; then
2054     glib_inline='#define G_HAVE_INLINE 1'
2055 fi
2056 if test x$glib_cv_has__inline = xyes; then
2057     glib_inline="\$glib_inline
2058 #define G_HAVE___INLINE 1"
2059 fi
2060 if test x$glib_cv_has__inline__ = xyes; then
2061     glib_inline="\$glib_inline
2062 #define G_HAVE___INLINE__ 1"
2063 fi
2064
2065 g_have_gnuc_varargs=$g_have_gnuc_varargs
2066 g_have_iso_c_varargs=$g_have_iso_c_varargs
2067 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
2068
2069 case xyes in
2070 x$ac_cv_c_bigendian)
2071   g_byte_order=G_BIG_ENDIAN
2072   g_bs_native=BE
2073   g_bs_alien=LE
2074   ;;
2075 *)
2076   g_byte_order=G_LITTLE_ENDIAN
2077   g_bs_native=LE
2078   g_bs_alien=BE
2079   ;;
2080 esac
2081
2082 g_have_eilseq=$have_eilseq
2083
2084 case x$have_threads in
2085 xno)    g_enable_threads_def="#undef";;
2086 *)      g_enable_threads_def="#define";;
2087 esac
2088
2089 g_threads_impl_def=$g_threads_impl
2090
2091 g_mutex_has_default="$mutex_has_default"
2092 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
2093 if test x"$glib_cv_sizeof_system_thread" != x; then
2094   g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
2095 else
2096   g_system_thread_sizeof="$ac_cv_sizeof_void_p"
2097 fi
2098 g_mutex_contents="$glib_cv_byte_contents_gmutex"
2099
2100 g_module_suffix="$glib_gmodule_suffix"
2101
2102 case $host in
2103   *-*-beos*)
2104     glib_os="#define G_OS_BEOS"
2105     ;;
2106   *-*-cygwin*)
2107     glib_os="#define G_OS_UNIX
2108 #define G_PLATFORM_WIN32
2109 #define G_WITH_CYGWIN"
2110     ;;
2111   *-*-mingw*)
2112     glib_os="#define G_OS_WIN32
2113 #define G_PLATFORM_WIN32"
2114     ;;
2115   *)
2116     glib_os="#define G_OS_UNIX"
2117     ;;
2118 esac
2119 ])
2120
2121 AC_OUTPUT([
2122 glib-2.0.pc
2123 glib-2.0-uninstalled.pc
2124 gmodule-2.0.pc
2125 gmodule-2.0-uninstalled.pc
2126 gthread-2.0.pc
2127 gthread-2.0-uninstalled.pc
2128 gobject-2.0.pc
2129 gobject-2.0-uninstalled.pc
2130 glib.spec
2131 glib-zip
2132 glib-gettextize
2133 Makefile
2134 build/Makefile
2135 build/win32/Makefile
2136 build/win32/dirent/Makefile
2137 glib/Makefile
2138 glib/libcharset/Makefile
2139 gmodule/gmoduleconf.h
2140 gmodule/Makefile
2141 gobject/Makefile
2142 gobject/glib-mkenums
2143 gthread/Makefile
2144 po/Makefile.in
2145 docs/Makefile
2146 docs/reference/Makefile
2147 docs/reference/glib/Makefile
2148 docs/reference/gobject/Makefile
2149 tests/Makefile
2150 m4macros/Makefile
2151 ],[echo ""
2152 echo " *** IMPORTANT *** "
2153 echo ""
2154 echo "This is a development version of GLib.  You should be using a stable"
2155 echo "version, which is available at ftp://ftp.gtk.org/pub/gtk/v1.2/.  The"
2156 echo "version you just configured is meant for developers of GLib only:"
2157 echo ""
2158 echo "  * You should not base stable software on this version of GLib."
2159 echo "  * GNOME developers should use a stable version of GLib."
2160 echo ""
2161 echo " *** You should be using GLib 1.2 instead. ***"
2162 ])