configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5
   6 # require autoconf 2.13
   7 AC_PREREQ(2.13)
   8
   9 # Process this file with autoconf to produce a configure script.
  10 AC_INIT(glist.c)
  11
  12 # Save this value here, since automake will set cflags later
  13 cflags_set=${CFLAGS+set}
  14
  15 # we rewrite this file
  16 rm -f glibconfig-sysdefs.h
  17
  18 dnl we need to AC_DIVERT_PUSH/AC_DIVERT_POP these variable definitions so they
  19 dnl are available for $ac_help expansion (don't we all *love* autoconf?)
  20 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  21 #
  22 # The following version number definitions apply to GLib, GModule, GObject and GThread
  23 # as a whole, so if changes occoured in any of them, they are all
  24 # treated with the same interface and binary age.
  25 #
  26 # Making releases:
  27 #   GLIB_MICRO_VERSION += 1;
  28 #   GLIB_INTERFACE_AGE += 1;
  29 #   GLIB_BINARY_AGE += 1;
  30 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  31 # if backwards compatibility has been broken,
  32 # set GLIB_BINARY_AGE _and_ GLIB_INTERFACE_AGE to 0.
  33 #
  34 GLIB_MAJOR_VERSION=1
  35 GLIB_MINOR_VERSION=3
  36 GLIB_MICRO_VERSION=1
  37 GLIB_INTERFACE_AGE=0
  38 GLIB_BINARY_AGE=0
  39 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  40 dnl
  41 AC_DIVERT_POP()dnl
  42
  43 AC_SUBST(GLIB_MAJOR_VERSION)
  44 AC_SUBST(GLIB_MINOR_VERSION)
  45 AC_SUBST(GLIB_MICRO_VERSION)
  46 AC_SUBST(GLIB_VERSION)
  47 AC_SUBST(GLIB_INTERFACE_AGE)
  48 AC_SUBST(GLIB_BINARY_AGE)
  49
  50 # libtool versioning
  51 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  52 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  53 LT_REVISION=$GLIB_INTERFACE_AGE
  54 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  55 AC_SUBST(LT_RELEASE)
  56 AC_SUBST(LT_CURRENT)
  57 AC_SUBST(LT_REVISION)
  58 AC_SUBST(LT_AGE)
  59
  60 VERSION=$GLIB_VERSION
  61 PACKAGE=glib
  62
  63 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  64
  65 # Specify a configuration file
  66 AM_CONFIG_HEADER(config.h)
  67
  68 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION)
  69 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION)
  70 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION)
  71 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE)
  72 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE)
  73
  74 dnl Initialize libtool
  75 AM_PROG_LIBTOOL
  76
  77 dnl Initialize maintainer mode
  78 AM_MAINTAINER_MODE
  79
  80 AC_CANONICAL_HOST
  81
  82 AC_MSG_CHECKING(for the BeOS)
  83 case $host in
  84   *-*-beos*)
  85     glib_native_beos="yes"
  86     ;;
  87   *)
  88     glib_native_beos="no"
  89     ;;
  90 esac
  91 AC_MSG_RESULT([$glib_native_beos])
  92
  93 dnl figure debugging default, prior to $ac_help setup
  94 dnl
  95 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  96 if test `expr $GLIB_MINOR_VERSION \% 2` = 1 ; then
  97         debug_default=yes
  98 else
  99         debug_default=minimum
 100 fi
 101 AC_DIVERT_POP()dnl
 102
 103 dnl declare --enable-* args and collect ac_help strings
 104 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
 105 AC_ARG_ENABLE(msg-prefix, [  --enable-msg-prefix     turn on program name and PID prefixing of messages and warnings],,enable_msg_prefix=no)
 106 AC_ARG_ENABLE(mem_check, [  --enable-mem-check      turn on malloc/free sanity checking [default=no]],,enable_mem_check=no)
 107 AC_ARG_ENABLE(mem_profile, [  --enable-mem-profile    turn on malloc profiling atexit [default=no]],,enable_mem_profile=no)
 108 AC_ARG_ENABLE(gc_friendly, [  --enable-gc-friendly    turn on garbage collector friendliness [default=no]],,enable_gc_friendly=no)
 109 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
 110                     , enable_ansi=no)
 111 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
 112                           ([=no] will override --with-threads)],,enable_threads=yes)
 113
 114 if test "x$enable_threads" != "xyes"; then
 115   enable_threads=no
 116 fi
 117
 118 AC_MSG_CHECKING(whether to enable memory checking)
 119 if test "x$enable_mem_check" = "xyes"; then
 120   AC_DEFINE(ENABLE_MEM_CHECK, 1)
 121   AC_SUBST(ENABLE_MEM_CHECK)
 122   AC_MSG_RESULT(yes)
 123 else
 124   AC_MSG_RESULT(no)
 125 fi
 126
 127 AC_MSG_CHECKING(whether to enable memory profiling)
 128 if test "x$enable_mem_profile" = "xyes"; then
 129   AC_DEFINE(ENABLE_MEM_PROFILE, 1)
 130   AC_SUBST(ENABLE_MEM_PROFILE)
 131   AC_MSG_RESULT(yes)
 132 else
 133   AC_MSG_RESULT(no)
 134 fi
 135
 136 AC_MSG_CHECKING(whether to enable garbage collector friendliness)
 137 if test "x$enable_gc_friendly" = "xyes"; then
 138   AC_DEFINE(ENABLE_GC_FRIENDLY, 1)
 139   AC_SUBST(ENABLE_GC_FRIENDLY)
 140   AC_MSG_RESULT(yes)
 141 else
 142   AC_MSG_RESULT(no)
 143 fi
 144
 145 if test "x$enable_debug" = "xyes"; then
 146   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 147   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 148 else
 149   if test "x$enable_debug" = "xno"; then
 150     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 151   fi
 152 fi
 153
 154 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 155
 156 if test "x$enable_msg_prefix" = "xyes"; then
 157   AC_DEFINE_UNQUOTED(G_ENABLE_MSG_PREFIX, 1)
 158 fi
 159
 160 # Checks for programs.
 161 AC_PROG_CC
 162 AM_PROG_CC_STDC
 163 AC_PROG_INSTALL
 164
 165 changequote(,)dnl
 166 if test "x$GCC" = "xyes"; then
 167   case " $CFLAGS " in
 168   *[\ \ ]-Wall[\ \      ]*) ;;
 169   *) CFLAGS="$CFLAGS -Wall" ;;
 170   esac
 171
 172   if test "x$enable_ansi" = "xyes"; then
 173     case " $CFLAGS " in
 174     *[\ \       ]-ansi[\ \      ]*) ;;
 175     *) CFLAGS="$CFLAGS -ansi" ;;
 176     esac
 177
 178     case " $CFLAGS " in
 179     *[\ \       ]-pedantic[\ \  ]*) ;;
 180     *) CFLAGS="$CFLAGS -pedantic" ;;
 181     esac
 182   fi
 183 fi
 184 changequote([,])dnl
 185
 186 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 187 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 188 glib_save_LIBS=$LIBS
 189 LIBS="$LIBS -lm"
 190 AC_TRY_RUN([#include <math.h>
 191              int main (void) { return (log(1) != log(1.)); }],
 192      AC_MSG_RESULT(none needed),
 193      glib_save_CFLAGS=$CFLAGS
 194      CFLAGS="$CFLAGS -std1"
 195      AC_TRY_RUN([#include <math.h>
 196                  int main (void) { return (log(1) != log(1.)); }],
 197          AC_MSG_RESULT(-std1),
 198          AC_MSG_RESULT()
 199          CFLAGS=$glib_save_CFLAGS
 200          AC_MSG_WARN(
 201                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 202      )
 203 )
 204 LIBS=$glib_save_LIBS
 205
 206 dnl NeXTStep cc seems to need this
 207 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 208 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 209   AC_MSG_RESULT(none needed),
 210   glib_save_CFLAGS=$CFLAGS
 211   CFLAGS="$CFLAGS -posix"
 212   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 213     AC_MSG_RESULT(-posix),
 214     AC_MSG_RESULT()
 215     CFLAGS=$glib_save_CFLAGS
 216     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 217
 218 # Checks for header files.
 219 AC_HEADER_STDC
 220
 221 # Checks for library functions.
 222 AC_FUNC_VPRINTF
 223
 224 AC_FUNC_ALLOCA
 225
 226 AC_CHECK_FUNCS(atexit on_exit)
 227
 228 AC_CHECK_SIZEOF(char)
 229 AC_CHECK_SIZEOF(short)
 230 AC_CHECK_SIZEOF(long)
 231 AC_CHECK_SIZEOF(int)
 232 AC_CHECK_SIZEOF(void *)
 233 AC_CHECK_SIZEOF(long long)
 234
 235 if test x$ac_cv_sizeof_long_long = x8; then
 236         # long long is a 64 bit integer.
 237         AC_MSG_CHECKING(for format to printf and scanf a gint64)
 238         AC_CACHE_VAL(glib_cv_long_long_format,[
 239                 for format in ll q; do
 240                   AC_TRY_RUN([#include <stdio.h>
 241                         int main()
 242                         {
 243                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 244                           char buffer[1000];
 245                           sprintf (buffer, "%${format}u", a);
 246                           sscanf (buffer, "%${format}u", &b);
 247                           exit (b!=a);
 248                         }
 249                         ],
 250                         glib_cv_long_long_format=${format}
 251                         break)
 252                 done])
 253         if test -n "$glib_cv_long_long_format"; then
 254           AC_MSG_RESULT(%${glib_cv_long_long_format}i)
 255         else
 256           AC_MSG_RESULT(none)
 257         fi
 258 fi
 259
 260 dnl long doubles were not used, and a portability problem
 261 dnl AC_C_LONG_DOUBLE
 262 AC_C_CONST
 263
 264 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 265 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 266 dnl actually supported.
 267 AC_MSG_CHECKING(for __inline)
 268 AC_CACHE_VAL(glib_cv_has__inline,[
 269         AC_TRY_RUN([
 270         __inline int foo () { return 0; }
 271         int main () { return foo (); }
 272         ],
 273         glib_cv_has__inline=yes
 274         ,
 275         glib_cv_has__inline=no
 276         ,)
 277 ])
 278 AC_MSG_RESULT($glib_cv_has__inline)
 279 case x$glib_cv_has__inline in
 280 xyes) AC_DEFINE(G_HAVE___INLINE)
 281 esac
 282 AC_MSG_CHECKING(for __inline__)
 283 AC_CACHE_VAL(glib_cv_has__inline__,[
 284         AC_TRY_RUN([
 285         __inline__ int foo () { return 0; }
 286         int main () { return foo (); }
 287         ],
 288         glib_cv_has__inline__=yes
 289         ,
 290         glib_cv_has__inline__=no
 291         ,)
 292 ])
 293 AC_MSG_RESULT($glib_cv_has__inline__)
 294 case x$glib_cv_has__inline__ in
 295 xyes) AC_DEFINE(G_HAVE___INLINE__)
 296 esac
 297 AC_MSG_CHECKING(for inline)
 298 AC_CACHE_VAL(glib_cv_hasinline,[
 299         AC_TRY_RUN([
 300         inline int foo () { return 0; }
 301         int main () { return foo (); }
 302         ],
 303         glib_cv_hasinline=yes
 304         ,
 305         glib_cv_hasinline=no
 306         ,)
 307 ])
 308 AC_MSG_RESULT($glib_cv_hasinline)
 309 case x$glib_cv_hasinline in
 310 xyes) AC_DEFINE(G_HAVE_INLINE)
 311 esac
 312
 313 # check for bytesex stuff
 314 AC_C_BIGENDIAN
 315
 316 # check for header files
 317 AC_CHECK_HEADERS(float.h, AC_DEFINE(HAVE_FLOAT_H))
 318 AC_CHECK_HEADERS(limits.h, AC_DEFINE(HAVE_LIMITS_H))
 319 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 320 AC_CHECK_HEADERS(sys/param.h, AC_DEFINE(HAVE_SYS_PARAM_H))
 321 AC_CHECK_HEADERS(sys/poll.h, AC_DEFINE(HAVE_SYS_POLL_H))
 322 AC_CHECK_HEADERS(sys/select.h, AC_DEFINE(HAVE_SYS_SELECT_H))
 323 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 324 AC_CHECK_HEADERS(sys/times.h, AC_DEFINE(HAVE_SYS_TIMES_H))
 325 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 326 AC_CHECK_HEADERS(values.h, AC_DEFINE(HAVE_VALUES_H))
 327 AC_CHECK_HEADERS(stdint.h, AC_DEFINE(HAVE_VALUES_H))
 328
 329 AC_MSG_CHECKING(whether make is GNU Make)
 330 STRIP_BEGIN=
 331 STRIP_END=
 332 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 333         STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
 334         STRIP_END=')'
 335         AC_MSG_RESULT(yes)
 336 else
 337         AC_MSG_RESULT(no)
 338 fi
 339 STRIP_DUMMY=
 340 AC_SUBST(STRIP_DUMMY)
 341 AC_SUBST(STRIP_BEGIN)
 342 AC_SUBST(STRIP_END)
 343
 344 # check additional type sizes
 345 size_includes=["
 346 #include <stdarg.h>
 347 #include <stdio.h>
 348 #include <ctype.h>
 349 #include <string.h>
 350 "]
 351 if test "x$ac_cv_header_stdint_h" = "xyes"; then
 352   size_includes=["$size_includes
 353 #include <stdint.h>
 354 "]
 355 fi
 356 if test "x$ac_cv_header_unistd_h" = "xyes"; then
 357   size_includes=["$size_includes
 358 #include <unistd.h>
 359 "]
 360 fi
 361 GLIB_SIZEOF([$size_includes], size_t, size_t)
 362 GLIB_SIZEOF([$size_includes], ptrdiff_t, ptrdiff_t)
 363 GLIB_SIZEOF([$size_includes], intmax_t, intmax_t)
 364
 365 # Check for some functions
 366 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf strcasecmp strncasecmp poll getcwd)
 367
 368 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 369 # The check is borrowed from the PERL Configure script.
 370 if test "$ac_cv_func_memmove" != "yes"; then
 371   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 372     glib_cv_working_bcopy,[AC_TRY_RUN([
 373       int main() {
 374         char buf[128], abc[128], *b;
 375         int len, off, align;
 376         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 377         for (align = 7; align >= 0; align--) {
 378           for (len = 36; len; len--) {
 379             b = buf+align; bcopy(abc, b, len);
 380             for (off = 1; off <= len; off++) {
 381               bcopy(b, b+off, len); bcopy(b+off, b, len);
 382                 if (bcmp(b, abc, len)) return(1);
 383             }
 384           }
 385         }
 386         return(0);
 387       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 388   if test "$glib_cv_working_bcopy" == "yes"; then
 389     AC_DEFINE(HAVE_WORKING_BCOPY)
 390   fi
 391 fi
 392
 393 # Check for sys_errlist
 394 AC_MSG_CHECKING(for sys_errlist)
 395 AC_TRY_LINK(, [
 396 extern char *sys_errlist[];
 397 extern int sys_nerr;
 398 sys_errlist[sys_nerr-1][0] = 0;
 399 ], glib_ok=yes, glib_ok=no)
 400 AC_MSG_RESULT($glib_ok)
 401 if test $glib_ok = no; then
 402     AC_DEFINE(NO_SYS_ERRLIST)
 403 fi
 404
 405 # Check for sys_siglist
 406 AC_MSG_CHECKING(for sys_siglist)
 407 AC_TRY_LINK(, [
 408 extern char *sys_siglist[];
 409 exit (sys_siglist[0]);
 410 ], glib_ok=yes, glib_ok=no)
 411 AC_MSG_RESULT($glib_ok)
 412 if test $glib_ok = no; then
 413     AC_DEFINE(NO_SYS_SIGLIST)
 414 fi
 415
 416 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 417 AC_MSG_CHECKING(for sys_siglist declaration)
 418 AC_TRY_COMPILE([#include <signal.h>], [
 419 strlen (sys_siglist[0]);
 420 ], glib_ok=yes, glib_ok=no)
 421 AC_MSG_RESULT($glib_ok)
 422 if test $glib_ok = no; then
 423     AC_DEFINE(NO_SYS_SIGLIST_DECL)
 424 fi
 425
 426 # Check if <sys/select.h> needs to be included for fd_set
 427 AC_MSG_CHECKING([for fd_set])
 428 AC_TRY_COMPILE([#include <sys/types.h>],
 429         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 430 if test $gtk_ok = yes; then
 431     AC_MSG_RESULT([yes, found in sys/types.h])
 432 else
 433     AC_HEADER_EGREP(fd_set, sys/select.h, gtk_ok=yes)
 434     if test $gtk_ok = yes; then
 435         AC_DEFINE(HAVE_SYS_SELECT_H)
 436         AC_MSG_RESULT([yes, found in sys/select.h])
 437     else
 438         AC_DEFINE(NO_FD_SET)
 439         AC_MSG_RESULT(no)
 440     fi
 441 fi
 442
 443 dnl *** check for sane realloc() ***
 444 AC_MSG_CHECKING(whether realloc (NULL,) will work)
 445 AC_CACHE_VAL(glib_cv_sane_realloc,[
 446         AC_TRY_RUN([
 447         #include <stdlib.h>
 448         int main() {
 449           return realloc (0, sizeof (int)) == 0;
 450         }],
 451         glib_cv_sane_realloc=yes
 452         AC_DEFINE(REALLOC_0_WORKS)
 453         ,
 454         glib_cv_sane_realloc=no
 455         ,)
 456 ])
 457 AC_MSG_RESULT($glib_cv_sane_realloc)
 458
 459 dnl Check for nl_langinfo and CODESET
 460
 461 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
 462 AC_TRY_COMPILE([#include <langinfo.h>],
 463         [char *codeset = nl_langinfo (CODESET);],
 464    AC_DEFINE(HAVE_CODESET)
 465    have_codeset=yes,
 466    have_codeset=no)
 467 AC_MSG_RESULT($have_codeset)
 468
 469
 470 dnl ****************************************
 471 dnl *** strlcpy/strlcat                  ***
 472 dnl ****************************************
 473 # Check for strlcpy
 474 AC_MSG_CHECKING(for strlcpy/strlcat)
 475 AC_TRY_LINK([#include <stdlib.h>
 476 #include <string.h>], [
 477 char *p = malloc(10);
 478 (void) strlcpy(p, "hi", 10);
 479 (void) strlcat(p, "bye", 10);
 480 ], glib_ok=yes, glib_ok=no)
 481 AC_MSG_RESULT($glib_ok)
 482 if test $glib_ok = yes; then
 483     AC_DEFINE(HAVE_STRLCPY)
 484 fi
 485
 486
 487 dnl **********************
 488 dnl *** va_copy checks ***
 489 dnl **********************
 490 dnl we currently check for all three va_copy possibilities, so we get
 491 dnl all results in config.log for bug reports.
 492 AC_MSG_CHECKING(for an implementation of va_copy())
 493 AC_CACHE_VAL(glib_cv_va_copy,[
 494         AC_TRY_RUN([
 495         #include <stdarg.h>
 496         void f (int i, ...) {
 497         va_list args1, args2;
 498         va_start (args1, i);
 499         va_copy (args2, args1);
 500         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 501           exit (1);
 502         va_end (args1); va_end (args2);
 503         }
 504         int main() {
 505           f (0, 42);
 506           return 0;
 507         }],
 508         glib_cv_va_copy=yes
 509         ,
 510         glib_cv_va_copy=no
 511         ,)
 512 ])
 513 AC_MSG_RESULT($glib_cv_va_copy)
 514 AC_MSG_CHECKING(for an implementation of __va_copy())
 515 AC_CACHE_VAL(glib_cv___va_copy,[
 516         AC_TRY_RUN([
 517         #include <stdarg.h>
 518         void f (int i, ...) {
 519         va_list args1, args2;
 520         va_start (args1, i);
 521         __va_copy (args2, args1);
 522         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 523           exit (1);
 524         va_end (args1); va_end (args2);
 525         }
 526         int main() {
 527           f (0, 42);
 528           return 0;
 529         }],
 530         glib_cv___va_copy=yes
 531         ,
 532         glib_cv___va_copy=no
 533         ,)
 534 ])
 535 AC_MSG_RESULT($glib_cv___va_copy)
 536 AC_MSG_CHECKING(whether va_lists can be copied by value)
 537 AC_CACHE_VAL(glib_cv_va_val_copy,[
 538         AC_TRY_RUN([
 539         #include <stdarg.h>
 540         void f (int i, ...) {
 541         va_list args1, args2;
 542         va_start (args1, i);
 543         args2 = args1;
 544         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 545           exit (1);
 546         va_end (args1); va_end (args2);
 547         }
 548         int main() {
 549           f (0, 42);
 550           return 0;
 551         }],
 552         glib_cv_va_val_copy=yes
 553         ,
 554         glib_cv_va_val_copy=no
 555         ,)
 556 ])
 557 if test "x$glib_cv_va_copy" = "xyes"; then
 558   AC_DEFINE(G_VA_COPY, va_copy)
 559 else if test "x$glib_cv___va_copy" = "xyes"; then
 560   AC_DEFINE(G_VA_COPY, __va_copy)
 561 fi
 562 fi
 563 if test "x$glib_cv_va_val_copy" = "xno"; then
 564   AC_DEFINE(G_VA_COPY_AS_ARRAY)
 565 fi
 566 AC_MSG_RESULT($glib_cv_va_val_copy)
 567
 568
 569 dnl ***********************
 570 dnl *** g_module checks ***
 571 dnl ***********************
 572 G_MODULE_LIBS=
 573 G_MODULE_LIBS_EXTRA=
 574 G_MODULE_PLUGIN_LIBS=
 575 G_MODULE_LDFLAGS=
 576 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
 577 G_MODULE_NEED_USCORE=0
 578 G_MODULE_HAVE_DLERROR=0
 579 dnl *** dlopen() and dlsym() in system libraries
 580 if test -z "$G_MODULE_IMPL"; then
 581         AC_CHECK_FUNC(dlopen,
 582                 AC_CHECK_FUNC(dlsym,
 583                         G_MODULE_IMPL=G_MODULE_IMPL_DL
 584                 ,)
 585         ,)
 586 fi
 587 dnl *** load_image (BeOS)
 588 if test -z "$G_MODULE_IMPL" -a "x$glib_native_beos" = "xyes"; then
 589   AC_CHECK_LIB(root, load_image,
 590       G_MODULE_LIBS="-lbe -lroot -lglib"
 591       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
 592       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
 593       G_MODULE_IMPL=G_MODULE_IMPL_BEOS
 594 ,)
 595 fi
 596 dnl *** dlopen() and dlsym() in libdl
 597 if test -z "$G_MODULE_IMPL"; then
 598         AC_CHECK_LIB(dl, dlopen,
 599                 AC_CHECK_LIB(dl, dlsym,
 600                         G_MODULE_LIBS=-ldl
 601                         G_MODULE_IMPL=G_MODULE_IMPL_DL
 602                 ,)
 603         ,)
 604 fi
 605 dnl *** shl_load() in libdld (HP-UX)
 606 if test -z "$G_MODULE_IMPL"; then
 607         AC_MSG_CHECKING(how to export all symbols)
 608         SAVED_LDFLAGS=$LDFLAGS
 609         LDFLAGS="$LDFLAGS -Wl,-E"
 610         AC_TRY_LINK(,[ return 0; ],
 611                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 612                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 613                 AC_TRY_LINK(,[ return 0; ],
 614                         G_MODULE_LDFLAGS="-bexpall",
 615                         G_MODULE_LDFLAGS="none"
 616                 )
 617         ])
 618         LDFLAGS=$SAVED_LDFLAGS
 619         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 620         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 621                 G_MODULE_LDFLAGS=
 622         fi
 623         AC_CHECK_LIB(dld, shl_load,
 624                 G_MODULE_LIBS=-ldld
 625                 G_MODULE_IMPL=G_MODULE_IMPL_DLD
 626         ,)
 627 fi
 628 dnl *** additional checks for G_MODULE_IMPL_DL
 629 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 630         case "$host_os" in
 631           linux*)
 632             G_MODULE_LDFLAGS='-rdynamic'
 633             ;;
 634         esac
 635         LIBS_orig="$LIBS"
 636         LDFLAGS_orig="$LDFLAGS"
 637         LIBS="$LIBS $G_MODULE_LIBS"
 638         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 639 dnl *** check whether we need preceeding underscores
 640         AC_MSG_CHECKING(for preceeding underscore in symbols)
 641         AC_CACHE_VAL(glib_cv_uscore,[
 642                 AC_TRY_RUN([
 643                 #include <dlfcn.h>
 644                 int glib_underscore_test (void) { return 42; }
 645                 int main() {
 646                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 647                   handle = dlopen ((void*)0, 0);
 648                   if (handle) {
 649                     f1 = dlsym (handle, "glib_underscore_test");
 650                     f2 = dlsym (handle, "_glib_underscore_test");
 651                   } return (!f2 || f1);
 652                 }],
 653                         glib_cv_uscore=yes,
 654                         glib_cv_uscore=no,
 655                 )
 656                 rm -f plugin.c plugin.o plugin.lo
 657         ])
 658         AC_MSG_RESULT($glib_cv_uscore)
 659         if test "x$glib_cv_uscore" = "xyes"; then
 660                 G_MODULE_NEED_USCORE=1
 661         else
 662                 G_MODULE_NEED_USCORE=0
 663         fi
 664
 665         LDFLAGS="$LDFLAGS_orig"
 666 dnl *** check for having dlerror()
 667         AC_CHECK_FUNC(dlerror,
 668                 G_MODULE_HAVE_DLERROR=1,
 669                 G_MODULE_HAVE_DLERROR=0)
 670         LIBS="$LIBS_orig"
 671 fi
 672 dnl *** done, have e got an implementation?
 673 if test -z "$G_MODULE_IMPL"; then
 674         G_MODULE_IMPL=0
 675 fi
 676 AC_SUBST(G_MODULE_IMPL)
 677 AC_SUBST(G_MODULE_LIBS)
 678 AC_SUBST(G_MODULE_LIBS_EXTRA)
 679 AC_SUBST(G_MODULE_PLUGIN_LIBS)
 680 AC_SUBST(G_MODULE_LDFLAGS)
 681 AC_SUBST(G_MODULE_HAVE_DLERROR)
 682 AC_SUBST(G_MODULE_NEED_USCORE)
 683 AC_SUBST(GLIB_DEBUG_FLAGS)
 684
 685
 686 dnl ***********************
 687 dnl *** g_thread checks ***
 688 dnl ***********************
 689
 690 AC_ARG_WITH(threads, [  --with-threads=[none/posix/dce/solaris] specify a thread implementation to use],
 691         if test "x$with_threads" = x; then
 692                 want_threads=yes
 693         else
 694                 want_threads=$with_threads
 695         fi,
 696         want_threads=yes)
 697 if test "x$enable_threads" = "xno"; then
 698         want_threads=no
 699 fi
 700 if test "x$want_threads" = "xnone"; then
 701         want_threads=no
 702 fi
 703
 704 dnl error and warning message
 705 dnl *************************
 706
 707 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
 708                 computer. GLib will not have a default thread implementation."
 709
 710 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
 711                 platform (normaly it's "_REENTRANT"). I'll not use any flag on
 712                 compilation now, but then your programs might not work.
 713                 Please provide information on how it is done on your system."
 714
 715 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
 716                 "
 717
 718 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
 719                 provide information on your thread implementation.
 720                 You can also run 'configure --disable-threads'
 721                 to compile without thread support."
 722
 723 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
 724                 functions will not be MT-safe during their first call because
 725                 there is no working 'getpwuid_r' on your system."
 726
 727 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
 728                 because there is no 'localtime_r' on your system."
 729
 730 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
 731                 crude surrogate will be used. If you happen to know a
 732                 yield function for your system, please inform the GLib
 733                 developers."
 734
 735 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
 736                 threads on your system. Thus threads can only have the default
 737                 priority. If you happen to know these main/max
 738                 priorities, please inform the GLib developers."
 739
 740
 741 dnl determination of thread implementation
 742 dnl ***************************************
 743
 744 have_threads=none
 745 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
 746         case $host in
 747                 *-*-solaris*)
 748                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
 749                 ;;
 750         esac
 751 fi
 752 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
 753                                 || test "x$want_threads" = xdce; then
 754         # -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
 755         # -U_OSF_SOURCE is for Digital UNIX 4.0d
 756         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
 757         glib_save_CPPFLAGS="$CPPFLAGS"
 758         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
 759         if test "x$have_threads" = xnone; then
 760                 AC_EGREP_HEADER([(^|[^a-zA-Z_])pthread_attr_init[^a-zA-Z_]],
 761                         pthread.h,
 762                         have_threads=posix)
 763         fi
 764         if test "x$have_threads" = xnone; then
 765                 AC_EGREP_HEADER([(^|[^a-zA-Z_])pthread_attr_create[^a-zA-Z_]],
 766                         pthread.h,
 767                         have_threads=dce)
 768         fi
 769         CPPFLAGS="$glib_save_CPPFLAGS"
 770 fi
 771
 772 AC_MSG_CHECKING(for thread implementation)
 773
 774 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
 775         AC_MSG_RESULT(none available)
 776         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
 777 else
 778         AC_MSG_RESULT($have_threads)
 779 fi
 780 AM_CONDITIONAL(HAVE_THREADS, test "x$have_threads" != xnone && test "x$want_threads" != xno)
 781
 782
 783 dnl determination of G_THREAD_CFLAGS
 784 dnl ********************************
 785
 786 G_THREAD_LIBS=
 787 G_THREAD_LIBS_EXTRA=
 788 G_THREAD_CFLAGS=
 789
 790 if test x"$have_threads" != xnone; then
 791
 792     G_THREAD_CFLAGS="-D_REENTRANT" # good default guess
 793
 794     case $host in
 795         *-aix*)
 796                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 797                 if test x"$GCC" = xyes; then
 798                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
 799                 fi
 800                 ;;
 801         *-freebsd2.2*)
 802                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 803
 804                 # FreeBSD 2.2.x shiped with gcc 2.7.2.x, which doesn't support
 805                 # -mthreads flag.
 806                 ;;
 807         *-sysv5uw7*)  # UnixWare 7
 808                 if test "$GCC" != "yes"; then
 809                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -Kthread"
 810                 else
 811                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -pthread"
 812                 fi
 813                 ;;
 814     esac
 815
 816     # if we are not finding the ctime_r function, then we probably are
 817     # not using the proper multithread flag
 818
 819     glib_save_CPPFLAGS="$CPPFLAGS"
 820     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
 821
 822     # Note: Digital UNIX 4.0d #defines ctime_r to _Pctime_r for gcc.
 823     AC_EGREP_HEADER([[^a-zA-Z_](_P)?ctime_r[^a-zA-Z_]], time.h, ,
 824         AC_MSG_WARN($FLAG_DOES_NOT_WORK))
 825
 826     CPPFLAGS="$glib_save_CPPFLAGS"
 827
 828     AC_MSG_CHECKING(thread related cflags)
 829     AC_MSG_RESULT($G_THREAD_CFLAGS)
 830     CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 831 fi
 832
 833 dnl determination of G_THREAD_LIBS
 834 dnl ******************************
 835
 836 mutex_has_default=no
 837 case $have_threads in
 838         posix|dce)
 839            G_THREAD_LIBS=error
 840            glib_save_LIBS="$LIBS"
 841            case $host in
 842              *-sysv5uw7*) # UnixWare 7
 843                 if test "$GCC" != "yes"; then
 844                         G_THREAD_LIBS="-Kthread"
 845                 else
 846                         G_THREAD_LIBS="-pthread"
 847                 fi
 848                 ;;
 849              *)
 850                 for thread_lib in "" pthread pthreads c_r thread dce; do
 851                         if test x"$thread_lib" = x; then
 852                                 add_thread_lib=""
 853                                 IN=""
 854                         else
 855                                 add_thread_lib="-l$thread_lib"
 856                                 IN=" in -l$thread_lib"
 857                         fi
 858                         if test x"$have_threads" = xposix; then
 859                                 defattr=NULL
 860                         else
 861                                 defattr=pthread_attr_default
 862                         fi
 863
 864                         LIBS="$glib_save_LIBS $add_thread_lib"
 865
 866                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
 867                         AC_TRY_RUN([#include <pthread.h>
 868                                 int check_me = 0;
 869                                 void* func(void* data) {check_me = 42;}
 870                                 main()
 871                                 { pthread_t t;
 872                                   void *ret;
 873                                   pthread_create (&t, $defattr, func, NULL);
 874                                   pthread_join (t, &ret);
 875                                   exit (check_me != 42);
 876                                 }],
 877                                 [AC_MSG_RESULT(yes)
 878                                 G_THREAD_LIBS="$add_thread_lib"
 879                                 break],
 880                                 [AC_MSG_RESULT(no)])
 881                 done
 882                 if test "x$G_THREAD_LIBS" = xerror; then
 883                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 884                 fi
 885                 for thread_lib in "" rt; do
 886                         if test x"$thread_lib" = x; then
 887                                 add_thread_lib=""
 888                                 IN=""
 889                         else
 890                                 add_thread_lib="-l$thread_lib"
 891                                 IN=" in -l$thread_lib"
 892                         fi
 893                         LIBS="$glib_save_LIBS $add_thread_lib"
 894
 895                         AC_MSG_CHECKING(for sched_get_priority_min$IN)
 896                         AC_TRY_RUN([#include <sched.h>
 897                                 #include <errno.h>
 898                                 int main() {
 899                                 errno = 0;
 900                                 return sched_get_priority_min(SCHED_OTHER)==-1
 901                                         && errno != 0;
 902                                 }],
 903                                 [AC_MSG_RESULT(yes)
 904                                 G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
 905                                 posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
 906                                 posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
 907                                 break],
 908                                 [AC_MSG_RESULT(no)])
 909                 done
 910                 LIBS="$glib_save_LIBS"
 911                 ;;
 912            esac
 913            mutex_has_default=yes
 914            mutex_default_type='pthread_mutex_t'
 915            mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
 916            mutex_header_file='pthread.h'
 917            if test "x$have_threads" = "xposix"; then
 918              g_threads_impl="POSIX"
 919            else
 920              g_threads_impl="DCE"
 921              have_threads="posix"
 922            fi
 923            AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
 924            ;;
 925         solaris)
 926            G_THREAD_LIBS=error
 927            AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
 928            mutex_has_default=yes
 929            mutex_default_type='mutex_t'
 930            mutex_default_init="DEFAULTMUTEX"
 931            mutex_header_file='thread.h'
 932            g_threads_impl="SOLARIS"
 933            ;;
 934         none)
 935            g_threads_impl="NONE"
 936            ;;
 937         *)
 938            g_threads_impl="NONE"
 939            G_THREAD_LIBS=error
 940            ;;
 941 esac
 942
 943 if test "x$G_THREAD_LIBS" = xerror; then
 944         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 945 fi
 946
 947 case $host in
 948   *-*-beos*)
 949     G_THREAD_LIBS="-lbe -lroot -lglib "
 950     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
 951     ;;
 952   *)
 953     ;;
 954 esac
 955
 956 AC_MSG_CHECKING(thread related libraries)
 957 AC_MSG_RESULT($G_THREAD_LIBS)
 958
 959 dnl check for mt safe function variants and some posix functions
 960 dnl ************************************************************
 961
 962 if test x"$have_threads" != xnone; then
 963         glib_save_LIBS="$LIBS"
 964         # we are not doing the following for now, as this might require glib
 965         # to always be linked with the thread libs on some platforms.
 966         # LIBS="$LIBS $G_THREAD_LIBS"
 967         AC_CHECK_FUNCS(localtime_r)
 968         if test "$ac_cv_header_pwd_h" = "yes"; then
 969                 AC_MSG_CHECKING([for getpwuid_r])
 970                 AC_CACHE_VAL(ac_cv_func_getpwuid_r,
 971                         [AC_TRY_RUN([#include <errno.h>
 972                                 int main () { char buffer[10000], *pointer;
 973                                 char getpwuid_r (long, void*, void*,
 974                                         int, void*);
 975                                 int error;
 976                                 errno = 0;
 977                                 error = getpwuid_r (0, &buffer, &buffer,
 978                                         sizeof (buffer), &pointer);
 979                                 return errno == ENOSYS || error == ENOSYS;}],
 980                                 [ac_cv_func_getpwuid_r=yes],
 981                                 [ac_cv_func_getpwuid_r=no])])
 982                 if test "$ac_cv_func_getpwuid_r" = yes; then
 983                         AC_MSG_RESULT(yes)
 984                         AC_DEFINE(HAVE_GETPWUID_R)
 985                 else
 986                         AC_MSG_RESULT(no)
 987                 fi
 988                 if test "$ac_cv_func_getpwuid_r" = "yes"; then
 989                         AC_MSG_CHECKING(whether getpwuid_r is posix like)
 990                         # The signature for the POSIX version is:
 991                         # int getpwuid_r(uid_t, struct passwd *, char *, size_t, struct passwd **)
 992                         AC_TRY_COMPILE([#include <pwd.h>
 993                                 #include <sys/types.h>
 994                                 #include <stdlib.h>],
 995                                 [getpwuid_r((uid_t)0, NULL, NULL, (size_t)0, NULL);],
 996                                 [AC_DEFINE(HAVE_GETPWUID_R_POSIX)
 997                                 AC_MSG_RESULT(yes)],
 998                                 [AC_MSG_RESULT(no)])
 999                 fi
1000         fi
1001         LIBS="$LIBS $G_THREAD_LIBS"
1002         if test x"$have_threads" = xposix; then
1003                 glib_save_CPPFLAGS="$CPPFLAGS"
1004                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1005                 GLIB_SIZEOF([#include <pthread.h>],
1006                         pthread_t,
1007                         system_thread)
1008                 # This is not AC_CHECK_FUNC to also work with function
1009                 # name mangling in header files.
1010                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1011                 AC_TRY_LINK([#include <pthread.h>],
1012                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1013                         [AC_MSG_RESULT(yes)
1014                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE)],
1015                         [AC_MSG_RESULT(no)])
1016                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1017                 if test x"$posix_priority_min" = xnone; then
1018                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1019                                 PX_PRIO_MIN],,[
1020                                 posix_priority_min=PX_PRIO_MIN
1021                                 posix_priority_max=PX_PRIO_MAX])
1022                 fi
1023                 if test x"$posix_priority_min" = xnone; then
1024                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1025                                 PRI_OTHER_MIN],,[
1026                                 posix_priority_min=PRI_OTHER_MIN
1027                                 posix_priority_max=PRI_OTHER_MAX])
1028                 fi
1029                 if test x"$posix_priority_min" = x; then
1030                         AC_MSG_RESULT(none found)
1031                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1032                         posix_priority_min=-1
1033                         posix_priority_max=-1
1034                 else
1035                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1036                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min)
1037                         AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max)
1038                 fi
1039                 posix_yield_func=none
1040                 AC_MSG_CHECKING(for posix yield function)
1041                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1042                                                         thr_yield; do
1043                         AC_TRY_LINK([#include <pthread.h>],
1044                                 [$yield_func()],
1045                                 [posix_yield_func="$yield_func"
1046                                 break])
1047                 done
1048                 if test x"$posix_yield_func" = xnone; then
1049                         AC_MSG_RESULT(none found)
1050                         AC_MSG_WARN($POSIX_NO_YIELD)
1051                         posix_yield_func="g_usleep(1000)"
1052                 else
1053                         AC_MSG_RESULT($posix_yield_func)
1054                         posix_yield_func="$posix_yield_func()"
1055                 fi
1056                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func)
1057                 CPPFLAGS="$glib_save_CPPFLAGS"
1058         else # solaris threads
1059                 GLIB_SIZEOF([#include <thread.h>],
1060                         thread_t,
1061                         system_thread)
1062         fi
1063
1064         LIBS="$glib_save_LIBS"
1065
1066         # now spit out all the warnings.
1067         if test "$ac_cv_func_getpwuid_r" != "yes"; then
1068                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1069         fi
1070         if test "$ac_cv_func_localtime_r" != "yes"; then
1071                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1072         fi
1073 else
1074         # If no thread implementation exists, we will provide enough
1075         # space for a pointer
1076         GLIB_SIZEOF(, void*, system_thread)
1077 fi
1078
1079 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c")
1080 AC_SUBST(G_THREAD_CFLAGS)
1081 AC_SUBST(G_THREAD_LIBS)
1082 AC_SUBST(G_THREAD_LIBS_EXTRA)
1083
1084 dnl **********************************************
1085 dnl *** GDefaultMutex setup and initialization ***
1086 dnl **********************************************
1087 dnl
1088 dnl if mutex_has_default = yes, we also got
1089 dnl mutex_default_type, mutex_default_init and mutex_header_file
1090 GLIB_IF_VAR_EQ(mutex_has_default, yes,
1091         glib_save_CPPFLAGS="$CPPFLAGS"
1092         glib_save_LIBS="$LIBS"
1093         LIBS="$LIBS $G_THREAD_LIBS"
1094         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1095         GLIB_SIZEOF([#include <$mutex_header_file>],
1096                     $mutex_default_type,
1097                     gmutex,
1098                     )
1099         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1100                            $mutex_default_type,
1101                            gmutex,
1102                            $glib_cv_sizeof_gmutex,
1103                            $mutex_default_init)
1104         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1105                 mutex_has_default=no
1106         fi
1107         CPPFLAGS="$glib_save_CPPFLAGS"
1108         LIBS="$glib_save_LIBS"
1109         ,
1110 )
1111
1112
1113 dnl ****************************************
1114 dnl *** GLib POLL* compatibility defines ***
1115 dnl ****************************************
1116 GLIB_SYSDEFS(
1117 [#include <sys/types.h>
1118 #include <sys/poll.h>],
1119         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
1120         glibconfig-sysdefs.h,
1121         =)
1122
1123 dnl **************************
1124 dnl *** Checks for gtk-doc ***
1125 dnl **************************
1126
1127 AC_ARG_WITH(html-dir, [  --with-html-dir=PATH path to installed docs ])
1128
1129 if test "x$with_html_dir" = "x" ; then
1130   HTML_DIR='${datadir}/gtk-doc/html'
1131 else
1132   HTML_DIR=$with_html_dir
1133 fi
1134
1135 AC_SUBST(HTML_DIR)
1136
1137
1138 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
1139 AM_CONDITIONAL(HAVE_GTK_DOC, $GTKDOC)
1140 AC_SUBST(HAVE_GTK_DOC)
1141
1142 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1143 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1144
1145 dnl Let people disable the gtk-doc stuff.
1146 AC_ARG_ENABLE(gtk-doc, [  --enable-gtk-doc  Use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)
1147
1148 if test x$enable_gtk_doc = xauto ; then
1149   if test x$GTKDOC = xtrue ; then
1150     enable_gtk_doc=yes
1151   else
1152     enable_gtk_doc=no
1153   fi
1154 fi
1155
1156 dnl NOTE: We need to use a separate automake conditional for this
1157 dnl       to make this work with the tarballs.
1158 AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
1159
1160 dnl ******************************
1161 dnl *** output the whole stuff ***
1162 dnl ******************************
1163
1164 AC_OUTPUT_COMMANDS([
1165
1166 ## Generate `glibconfig.h' in two cases
1167 ## 1. `config.status' is run either explicitly, or via configure.
1168 ##     Esp. not when it is run in `Makefile' to generate makefiles and
1169 ##     config.h
1170 ## 2. CONFIG_OTHER is set explicitly
1171 ##
1172 ## Case 1 is difficult.  We know that `automake' sets one of
1173 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
1174 ## only when AM_CONFIG_HEADER is set, however.
1175
1176 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
1177   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
1178   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
1179 fi
1180 case "$CONFIG_OTHER" in
1181 *glibconfig.h*)
1182         echo creating glibconfig.h
1183         outfile=glibconfig.h-tmp
1184         cat > $outfile <<\_______EOF
1185 /* glibconfig.h
1186  *
1187  * This is a generated file.  Please modify `configure.in'
1188  */
1189
1190 #ifndef GLIBCONFIG_H
1191 #define GLIBCONFIG_H
1192
1193 _______EOF
1194
1195         if test x$glib_limits_h = xyes; then
1196           echo '#include <limits.h>' >> $outfile
1197         fi
1198         if test x$glib_float_h = xyes; then
1199           echo '#include <float.h>' >> $outfile
1200         fi
1201         if test x$glib_values_h = xyes; then
1202           echo '#include <values.h>' >> $outfile
1203         fi
1204         if test x$g_mutex_header_file != x; then
1205           echo '#include <'"$g_mutex_header_file"'>' >> $outfile
1206         fi
1207         if test "$glib_header_alloca_h" = "yes"; then
1208           echo  '#include <alloca.h>' >> $outfile
1209         fi
1210         if test x$glib_sys_poll_h = xyes; then
1211           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
1212         fi
1213
1214         cat >> $outfile <<_______EOF
1215
1216 #ifdef __cplusplus
1217 extern "C" {
1218 #endif /* __cplusplus */
1219
1220 #define G_MINFLOAT      $glib_mf
1221 #define G_MAXFLOAT      $glib_Mf
1222 #define G_MINDOUBLE     $glib_md
1223 #define G_MAXDOUBLE     $glib_Md
1224 #define G_MINSHORT      $glib_ms
1225 #define G_MAXSHORT      $glib_Ms
1226 #define G_MAXUSHORT     $glib_Mus
1227 #define G_MININT        $glib_mi
1228 #define G_MAXINT        $glib_Mi
1229 #define G_MAXUINT       $glib_Mui
1230 #define G_MINLONG       $glib_ml
1231 #define G_MAXLONG       $glib_Ml
1232 #define G_MAXULONG      $glib_Mul
1233
1234 _______EOF
1235
1236
1237         ### this should always be true in a modern C/C++ compiler
1238         cat >>$outfile <<_______EOF
1239 typedef signed char gint8;
1240 typedef unsigned char guint8;
1241 _______EOF
1242
1243
1244         if test -n "$gint16"; then
1245           cat >>$outfile <<_______EOF
1246 typedef signed $gint16 gint16;
1247 typedef unsigned $gint16 guint16;
1248 #define G_GINT16_FORMAT $gint16_format
1249 #define G_GUINT16_FORMAT $guint16_format
1250 _______EOF
1251         fi
1252
1253
1254         if test -n "$gint32"; then
1255           cat >>$outfile <<_______EOF
1256 typedef signed $gint32 gint32;
1257 typedef unsigned $gint32 guint32;
1258 #define G_GINT32_FORMAT $gint32_format
1259 #define G_GUINT32_FORMAT $guint32_format
1260 _______EOF
1261         fi
1262
1263
1264         if test -n "$gint64"; then
1265           cat >>$outfile <<_______EOF
1266 #define G_HAVE_GINT64 1
1267
1268 ${glib_extension}typedef signed $gint64 gint64;
1269 ${glib_extension}typedef unsigned $gint64 guint64;
1270
1271 #define G_GINT64_CONSTANT(val)  $gint64_constant
1272 _______EOF
1273                 if test -n "$gint64_format"; then
1274           cat >>$outfile <<_______EOF
1275 #define G_GINT64_FORMAT $gint64_format
1276 #define G_GUINT64_FORMAT $guint64_format
1277 _______EOF
1278                 fi
1279         fi
1280
1281         case x$glib_size_t in
1282         x2) echo "typedef gint16  gssize;" >> $outfile
1283             echo "typedef guint16 gsize;"  >> $outfile
1284             ;;
1285         x4) echo "typedef gint32  gssize;" >> $outfile
1286             echo "typedef guint32 gsize;"  >> $outfile
1287             ;;
1288         x8) echo "typedef gint64  gssize;" >> $outfile
1289             echo "typedef guint64 gsize;"  >> $outfile
1290             ;;
1291         *)  echo "#error size of size_t is unknown" >> $outfile
1292             ;;
1293         esac
1294
1295         if test -z "$glib_unknown_void_p"; then
1296           cat >>$outfile <<_______EOF
1297
1298 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
1299 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
1300
1301 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
1302 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
1303 _______EOF
1304         else
1305           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
1306         fi
1307
1308
1309
1310         cat >>$outfile <<_______EOF
1311 $glib_atexit
1312 $glib_memmove
1313 $glib_defines
1314 $glib_os
1315
1316 $glib_vacopy
1317
1318 #ifdef  __cplusplus
1319 #define G_HAVE_INLINE   1
1320 #else   /* !__cplusplus */
1321 $glib_inline
1322 #endif  /* !__cplusplus */
1323 _______EOF
1324
1325         echo >>$outfile
1326         if test x$g_mutex_has_default = xyes; then
1327                 cat >>$outfile <<_______EOF
1328 $g_enable_threads_def G_THREADS_ENABLED
1329 #define G_THREADS_IMPL_$g_threads_impl_def
1330 typedef struct _GStaticMutex GStaticMutex;
1331 struct _GStaticMutex
1332 {
1333   struct _GMutex *runtime_mutex;
1334   struct {
1335     union {
1336       char   pad[$g_mutex_sizeof];
1337       double dummy_double;
1338       void  *dummy_pointer;
1339       long   dummy_long;
1340     } mutex;
1341     void *debug_info;
1342   } static_mutex;
1343 };
1344 #define G_STATIC_MUTEX_INIT     { NULL, { { { $g_mutex_contents} }, NULL } }
1345 #define g_static_mutex_get_mutex(mutex) \
1346   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->static_mutex)) : \
1347    g_static_mutex_get_mutex_impl (&((mutex)->runtime_mutex)))
1348 _______EOF
1349         else
1350                 cat >>$outfile <<_______EOF
1351 $g_enable_threads_def G_THREADS_ENABLED
1352 #define G_THREADS_IMPL_$g_threads_impl_def
1353 typedef struct _GMutex* GStaticMutex;
1354 #define G_STATIC_MUTEX_INIT NULL
1355 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (mutex))
1356 _______EOF
1357         fi
1358
1359         cat >>$outfile <<_______EOF
1360 /* This represents a system thread as used by the implementation. An
1361  * alien implementaion, as loaded by g_thread_init can only count on
1362  * "sizeof (gpointer)" bytes to store their info. We however need more
1363  * for some of our native implementations. */
1364 typedef union _GSystemThread GSystemThread;
1365 union _GSystemThread
1366 {
1367   char   data[$g_system_thread_sizeof];
1368   double dummy_double;
1369   void  *dummy_pointer;
1370   long   dummy_long;
1371 };
1372 _______EOF
1373
1374         echo >>$outfile
1375         g_bit_sizes="16 32"
1376         if test -n "$gint64"; then
1377           g_bit_sizes="$g_bit_sizes 64"
1378         fi
1379         for bits in $g_bit_sizes; do
1380           cat >>$outfile <<_______EOF
1381 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
1382 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
1383 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
1384 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
1385 _______EOF
1386         done
1387
1388         cat >>$outfile <<_______EOF
1389 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
1390 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
1391 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
1392 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
1393 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
1394 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
1395 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
1396 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
1397 #define G_BYTE_ORDER $g_byte_order
1398
1399 _______EOF
1400
1401         if test -r glibconfig-sysdefs.h; then
1402           cat glibconfig-sysdefs.h >>$outfile
1403         fi
1404
1405         cat >>$outfile <<_______EOF
1406
1407 #ifdef __cplusplus
1408 }
1409 #endif /* __cplusplus */
1410
1411 #endif /* GLIBCONFIG_H */
1412 _______EOF
1413
1414
1415         if cmp -s $outfile glibconfig.h; then
1416           echo glibconfig.h is unchanged
1417           rm -f $outfile
1418         else
1419           mv $outfile glibconfig.h
1420         fi ;;
1421 esac
1422 ],[
1423
1424 # Note that if two cases are the same, case goes with the first one.
1425 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
1426 # on variable expansion in case labels.  Look at the generated config.status
1427 # for a hint.
1428
1429 glib_header_alloca_h="$ac_cv_header_alloca_h"
1430
1431 case xyes in
1432 x$ac_cv_header_float_h)
1433   glib_float_h=yes
1434   glib_mf=FLT_MIN glib_Mf=FLT_MAX
1435   glib_md=DBL_MIN glib_Md=DBL_MAX
1436   ;;
1437 x$ac_cv_header_values_h)
1438   glib_values_h=yes
1439   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
1440   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
1441   ;;
1442 esac
1443
1444 case xyes in
1445 x$ac_cv_header_limits_h)
1446   glib_limits_h=yes
1447   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
1448   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
1449   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
1450   ;;
1451 x$ac_cv_header_values_h)
1452   glib_values_h=yes
1453   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
1454   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
1455   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
1456   ;;
1457 esac
1458
1459 if test x$ac_cv_header_sys_poll_h = xyes ; then
1460   glib_sys_poll_h=yes
1461 fi
1462
1463 case 2 in
1464 $ac_cv_sizeof_short)
1465   gint16=short
1466   gint16_format='"hi"'
1467   guint16_format='"hu"'
1468   ;;
1469 $ac_cv_sizeof_int)
1470   gint16=int
1471   gint16_format='"i"'
1472   guint16_format='"u"'
1473   ;;
1474 esac
1475 case 4 in
1476 $ac_cv_sizeof_short)
1477   gint32=short
1478   gint32_format='"hi"'
1479   guint32_format='"hu"'
1480   ;;
1481 $ac_cv_sizeof_int)
1482   gint32=int
1483   gint32_format='"i"'
1484   guint32_format='"u"'
1485   ;;
1486 $ac_cv_sizeof_long)
1487   gint32=long
1488   gint32_format='"li"'
1489   guint32_format='"lu"'
1490   ;;
1491 esac
1492 case 8 in
1493 $ac_cv_sizeof_int)
1494   gint64=int
1495   gint64_format='"i"'
1496   guint64_format='"u"'
1497   glib_extension=
1498   gint64_constant='(val)'
1499   ;;
1500 $ac_cv_sizeof_long)
1501   gint64=long
1502   gint64_format='"li"'
1503   guint64_format='"lu"'
1504   glib_extension=
1505   gint64_constant='(val##L)'
1506   ;;
1507 $ac_cv_sizeof_long_long)
1508   gint64='long long'
1509   if test -n "$glib_cv_long_long_format"; then
1510     gint64_format='"'$glib_cv_long_long_format'i"'
1511     guint64_format='"'$glib_cv_long_long_format'u"'
1512   fi
1513   glib_extension='G_GNUC_EXTENSION '
1514   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1515   ;;
1516 esac
1517 glib_size_t=$glib_cv_sizeof_size_t
1518
1519 gintbits=`expr $ac_cv_sizeof_int \* 8`
1520 glongbits=`expr $ac_cv_sizeof_long \* 8`
1521
1522
1523 case $ac_cv_sizeof_void_p in
1524 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
1525 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
1526 *)                      glib_unknown_void_p=yes ;;
1527 esac
1528
1529
1530 case xyes in
1531 x$ac_cv_func_atexit)
1532   glib_atexit="
1533 #ifdef NeXT /* @#%@! NeXTStep */
1534 # define g_ATEXIT(proc) (!atexit (proc))
1535 #else
1536 # define g_ATEXIT(proc) (atexit (proc))
1537 #endif"
1538   ;;
1539 x$ac_cv_func_on_exit)
1540   glib_atexit="
1541 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
1542   ;;
1543 esac
1544
1545 case xyes in
1546 x$ac_cv_func_memmove)
1547   glib_memmove='
1548 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
1549   ;;
1550 x$glib_cv_working_bcopy)
1551   glib_memmove="
1552 /* memmove isn't available, but bcopy can copy overlapping memory regions */
1553 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
1554   ;;
1555 *)
1556   glib_memmove="
1557 /* memmove isn't found and bcopy can't copy overlapping memory regions,
1558  * so we have to roll our own copy routine. */
1559 void g_memmove (void* dest, const void * src, unsigned long len);"
1560   ;;
1561 esac
1562
1563 glib_defines="
1564 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
1565 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
1566 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
1567 "
1568
1569 case xyes in
1570 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
1571 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
1572 *)                      glib_vacopy=''
1573 esac
1574
1575 if test x$glib_cv_va_val_copy = xno; then
1576   glib_vacopy="\$glib_vacopy
1577 #define G_VA_COPY_AS_ARRAY 1"
1578 fi
1579
1580 if test x$glib_cv_hasinline = xyes; then
1581     glib_inline='#define G_HAVE_INLINE 1'
1582 fi
1583 if test x$glib_cv_has__inline = xyes; then
1584     glib_inline="\$glib_inline
1585 #define G_HAVE___INLINE 1"
1586 fi
1587 if test x$glib_cv_has__inline__ = xyes; then
1588     glib_inline="\$glib_inline
1589 #define G_HAVE___INLINE__ 1"
1590 fi
1591
1592 case xyes in
1593 x$ac_cv_c_bigendian)
1594   g_byte_order=G_BIG_ENDIAN
1595   g_bs_native=BE
1596   g_bs_alien=LE
1597   ;;
1598 *)
1599   g_byte_order=G_LITTLE_ENDIAN
1600   g_bs_native=LE
1601   g_bs_alien=BE
1602   ;;
1603 esac
1604
1605 case x$have_threads in
1606 xnone)  g_enable_threads_def="#undef";;
1607 *)      g_enable_threads_def="#define";;
1608 esac
1609
1610 g_threads_impl_def=$g_threads_impl
1611
1612 g_mutex_has_default="$mutex_has_default"
1613 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
1614 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
1615 g_mutex_contents="$glib_cv_byte_contents_gmutex"
1616
1617 case $host in
1618   *-*-beos*)
1619     glib_os="#define G_OS_BEOS"
1620     ;;
1621   *-*-cygwin*)
1622     glib_os="#define G_OS_UNIX
1623 #define G_WITH_CYGWIN"
1624 v    ;;
1625   *)
1626     glib_os="#define G_OS_UNIX"
1627     ;;
1628 esac
1629 ])
1630
1631 AC_OUTPUT([
1632 glib-2.0.pc
1633 gmodule-2.0.pc
1634 gthread-2.0.pc
1635 gobject-2.0.pc
1636 glib.spec
1637 Makefile
1638 glib-config-2.0
1639 build/Makefile
1640 build/win32/Makefile
1641 gmodule/gmoduleconf.h
1642 gmodule/Makefile
1643 gobject/Makefile
1644 gthread/Makefile
1645 docs/Makefile
1646 docs/glib-config.1
1647 docs/reference/Makefile
1648 docs/reference/glib/Makefile
1649 docs/reference/gobject/Makefile
1650 tests/Makefile
1651 ],[case "$CONFIG_FILES" in
1652 *glib-config-2.0*)chmod +x glib-config-2.0;;
1653 esac
1654 echo ""
1655 echo " *** IMPORTANT *** "
1656 echo ""
1657 echo "This is a development version of GLib.  You should be using a stable"
1658 echo "version, which is available at ftp://ftp.gtk.org/pub/gtk/v1.2/.  The"
1659 echo "version you just configured is meant for developers of GLib only:"
1660 echo ""
1661 echo "  * You should not base stable software on this version of GLib."
1662 echo "  * GNOME developers should use a stable version of GLib."
1663 echo ""
1664 echo "If you install this version of GLib, we strongly recommend that you"
1665 echo "install it in a different prefix than GLib 1.2.  Use --prefix as an"
1666 echo "argument to configure to do this.  Otherwise, you will not be able to"
1667 echo "do development with GLib 1.2 any longer."
1668 echo ""
1669 echo " *** You should be using GLib 1.2 instead. ***"
1670 ])
1671