configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.13)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_AUX_DIR(scripts)
   7
   8 # This will get text that should go into config.make.
   9 config_vars=
  10
  11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  12 AC_ARG_WITH(gmp, dnl
  13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  14             [dnl
  15 case "$with_gmp" in
  16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  17 ''|no) ;;
  18 *) config_vars="$config_vars
  19 gmp-srcdir = $withval" ;;
  20 esac
  21 ])
  22 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  23 AC_ARG_WITH(gettext, dnl
  24   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  25             [dnl
  26 case "$with_gettext" in
  27 yes)
  28   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  29 ''|no) ;;
  30 *)
  31   config_vars="$config_vars
  32 gettext-srcdir = $withval" ;;
  33 esac
  34 ])
  35 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  36 AC_ARG_WITH(gd, dnl
  37   --with-gd=DIR           find libgd include dir and library with prefix DIR,
  38             [dnl
  39 case "$with_gd" in
  40 yes|''|no) ;;
  41 *) libgd_include="-I$withval/include"
  42    libgd_ldflags="-L$withval/lib" ;;
  43 esac
  44 ])
  45 AC_ARG_WITH(gd-include, dnl
  46   --with-gd-include=DIR   find libgd include files in DIR,
  47             [dnl
  48 case "$with_gd_include" in
  49 ''|no) ;;
  50 *) libgd_include="-I$withval" ;;
  51 esac
  52 ])
  53 AC_ARG_WITH(gd-lib, dnl
  54   --with-gd-lib=DIR       find libgd library files in DIR,
  55             [dnl
  56 case "$with_gd_lib" in
  57 ''|no) ;;
  58 *) libgd_ldflags="-L$withval" ;;
  59 esac
  60 ])
  61
  62 if test -n "$libgd_include"; then
  63   config_vars="$config_vars
  64 CFLAGS-memprofstat.c = $libgd_include"
  65 fi
  66 if test -n "$libgd_ldflags"; then
  67   config_vars="$config_vars
  68 libgd-LDFLAGS = $libgd_ldflags"
  69 fi
  70
  71 dnl Arguments to specify presence of other packages/features.
  72 AC_ARG_WITH(fp, dnl
  73 [  --with-fp              if using floating-point hardware [default=yes]],
  74             with_fp=$withval, with_fp=yes)
  75 AC_ARG_WITH(binutils, dnl
  76   --with-binutils=PATH    specify location of binutils (as and ld),
  77             path_binutils=$withval, path_binutils='')
  78 AC_ARG_WITH(elf, dnl
  79   --with-elf              if using the ELF object format,
  80             elf=$withval, elf=no)
  81 AC_ARG_WITH(cvs, dnl
  82 [  --without-cvs          if CVS should not be used],
  83             with_cvs=$withval, with_cvs=yes)
  84 AC_SUBST(with_cvs)
  85
  86 AC_ARG_WITH(headers, dnl
  87 [  --with-headers=PATH     location of system headers to use
  88                           [e.g. /usr/src/linux/include]
  89                           [default=compiler default]],
  90             sysheaders=$withval, sysheaders='')
  91
  92 AC_ARG_ENABLE(libio, dnl
  93 [  --enable-libio          build in GNU libio instead of GNU stdio],
  94               [if test $enableval = yes; then
  95                  stdio=libio
  96                else
  97                  stdio=stdio
  98                fi],
  99               stdio=default)
 100
 101 AC_ARG_ENABLE(sanity-checks, dnl
 102 [  --disable-sanity-checks really do not use threads (should not be used
 103                           except in special situations) [default=yes]],
 104               enable_sanity=$enableval, enable_sanity=yes)
 105
 106 dnl Arguments to enable or disable building the static, shared, profiled,
 107 dnl and -fomit-frame-pointer libraries.
 108 dnl I've disabled this for now since we cannot build glibc without static
 109 dnl libraries built in the moment.
 110 dnl AC_ARG_ENABLE(static, dnl
 111 dnl [  --enable-static         build static library [default=yes]],
 112 dnl           static=$enableval, static=yes)
 113 static=yes
 114 AC_ARG_ENABLE(shared, dnl
 115 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
 116               shared=$enableval, shared=default)
 117 AC_ARG_ENABLE(profile, dnl
 118 [  --enable-profile        build profiled library [default=yes]],
 119               profile=$enableval, profile=yes)
 120 AC_ARG_ENABLE(omitfp, dnl
 121 [  --enable-omitfp         build undebuggable optimized library [default=no]],
 122               omitfp=$enableval, omitfp=no)
 123 AC_ARG_ENABLE(bounded, dnl
 124 [  --enable-bounded        build with runtime bounds checking [default=no]],
 125               bounded=$enableval, bounded=no)
 126 AC_ARG_ENABLE(versioning, dnl
 127 [  --disable-versioning    do not include versioning information in the
 128                           library objects [default=yes if supported]],
 129              enable_versioning=$enableval, enable_versioning=yes)
 130
 131 dnl Generic infrastructure for drop-in additions to libc.
 132 AC_ARG_ENABLE(add-ons, dnl
 133 [  --enable-add-ons[=DIR1,DIR2]...
 134                           configure and build add-ons in DIR1,DIR2,...
 135                           search for add-ons if no parameter given],
 136   [case "$enableval" in
 137     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
 138          test "$add_ons" = "*" && add_ons= ;;
 139     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 140    esac],
 141   [add_ons=])
 142
 143 AC_CONFIG_SUBDIRS($add_ons)
 144 add_ons_pfx=
 145 if test x"$add_ons" != x; then
 146   for f in $add_ons; do
 147     # Test whether such a subdir really exists.
 148     if test -d $srcdir/$f; then
 149       add_ons_pfx="$add_ons_pfx $f/"
 150     else
 151       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 152     fi
 153   done
 154 fi
 155
 156 dnl On some platforms we cannot use dynamic loading.  We must provide
 157 dnl static NSS modules.
 158 AC_ARG_ENABLE(static-nss, dnl
 159 [  --enable-static-nss     build static NSS modules [default=no]],
 160               static_nss=$enableval, static_nss=no)
 161 if test x"$static_nss" = xyes; then
 162   AC_DEFINE(DO_STATIC_NSS)
 163 fi
 164
 165 AC_ARG_ENABLE(force-install,
 166 [  --disable-force-install don't force installation of files from this package,
 167                           even if they are older than the installed files],
 168               force_install=$enableval, force_install=yes)
 169 AC_SUBST(force_install)
 170
 171 dnl On some platforms we allow dropping compatibility with all kernel
 172 dnl versions.
 173 AC_ARG_ENABLE(kernel,
 174 [  --enable-kernel=VERSION compile for compatibility with kernel not older
 175                            than VERSION],
 176               minimum_kernel=$enableval)
 177 dnl Prevent unreasonable values.
 178 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 179   # Better nothing than this.
 180   minimum_kernel=""
 181 else
 182   if test "$minimum_kernel" = current; then
 183     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 184   fi
 185 fi
 186
 187 AC_CANONICAL_HOST
 188
 189 # The way shlib-versions is used to generate soversions.mk uses a
 190 # fairly simplistic model for name recognition that can't distinguish
 191 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 192 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 193 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 194 case "$host_os" in
 195 linux*)
 196   ;;
 197 gnu*)
 198   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 199   ;;
 200 esac
 201
 202 # We keep the original values in `$config_*' and never modify them, so we
 203 # can write them unchanged into config.make.  Everything else uses
 204 # $machine, $vendor, and $os, and changes them whenever convenient.
 205 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 206
 207 # Some configurations imply other options.
 208 case "$host_os" in
 209 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 210   # These systems always use GNU tools.
 211   gnu_ld=yes gnu_as=yes ;;
 212 esac
 213 case "$host_os" in
 214 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 215 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 216   ;;
 217 gnu* | linux* | sysv4* | solaris2* | irix6*)
 218   # These systems (almost) always use the ELF format.
 219   elf=yes
 220   ;;
 221 esac
 222
 223 machine=$config_machine
 224 vendor=$config_vendor
 225 os=$config_os
 226
 227 ###
 228 ### I put this here to prevent those annoying emails from people who cannot
 229 ### read and try to compile glibc on unsupported platforms.  --drepper
 230 ###
 231 ### By using the undocumented --enable-hacker-mode option for configure
 232 ### one can skip this test to make the configuration not fail for unsupported
 233 ### platforms.
 234 ###
 235 if test -z "$enable_hacker_mode"; then
 236   case "$machine-$host_os" in
 237   *-linux* | *-gnu* | arm*-none* | powerpc-aix4.3.*)
 238     ;;
 239   *)
 240     echo "*** The GNU C library is currently not available for this platform."
 241     echo "*** So far nobody cared to port it and if there is no volunteer it"
 242     echo "*** might never happen.  So, if you have interest to see glibc on"
 243     echo "*** this platform visit"
 244     echo "***   http://www.gnu.org/software/libc/porting.html"
 245     echo "*** and join the group of porters"
 246     exit 1
 247     ;;
 248   esac
 249 fi
 250
 251 dnl We need to use [ and ] for other purposes for a while now.
 252 changequote(,)dnl
 253 # Expand the configuration machine name into a subdirectory by architecture
 254 # type and particular chip.
 255 case "$machine" in
 256 a29k | am29000) base_machine=a29k machine=a29k ;;
 257 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 258 arm*)           base_machine=arm machine=arm/$machine ;;
 259 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 260 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 261 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 262 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 263 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 264 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 265 m88???)         base_machine=m88k machine=m88k/$machine ;;
 266 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 267 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 268 mips*)          base_machine=mips
 269                 case "`uname -m`" in
 270                 IP22) machine=mips/mips3 ;;
 271                 *)    machine=mips/$machine ;;
 272                 esac ;;
 273 sparc | sparcv[67])
 274                 base_machine=sparc machine=sparc/sparc32 ;;
 275 sparcv8 | supersparc | hypersparc)
 276                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 277 sparcv8plus | sparcv8plusa | sparcv9)
 278                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 279 sparc64 | ultrasparc)
 280                 base_machine=sparc machine=sparc/sparc64 ;;
 281 esac
 282 changequote([,])dnl
 283 AC_SUBST(base_machine)
 284
 285 if test "$base_machine" = "i386"; then
 286   AC_DEFINE(USE_REGPARMS)
 287 fi
 288
 289 # Compute the list of sysdep directories for this configuration.
 290 # This can take a while to compute.
 291 sysdep_dir=$srcdir/sysdeps
 292 AC_MSG_CHECKING(sysdep dirs)
 293 dnl We need to use [ and ] for other purposes for a while now.
 294 changequote(,)dnl
 295 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 296 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 297
 298 case "$os" in
 299 gnu*)
 300   base_os=mach/hurd ;;
 301 netbsd* | 386bsd* | freebsd* | bsdi*)
 302   base_os=unix/bsd/bsd4.4 ;;
 303 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 304   base_os=unix/bsd ;;
 305 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 306   base_os=unix/sysv ;;
 307 irix6*)
 308   base_os=unix/sysv/irix6/$os ;;
 309 solaris[2-9]*)
 310   base_os=unix/sysv/sysv4 ;;
 311 hpux*)
 312   base_os=unix/sysv/hpux/$os ;;
 313 aix4.3*)
 314   base_os=unix/sysv/aix/aix4.3 ;;
 315 none)
 316   base_os=standalone ;;
 317 *)
 318   base_os='' ;;
 319 esac
 320
 321 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 322 tail=$os
 323 ostry=$os
 324 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 325   ostry="$ostry /$o"
 326   tail=$o
 327 done
 328 o=`echo $tail | sed 's/[0-9]*$//'`
 329 if test $o != $tail; then
 330   ostry="$ostry /$o"
 331 fi
 332 # For linux-gnu, try linux-gnu, then linux.
 333 o=`echo $tail | sed 's/-.*$//'`
 334 if test $o != $tail; then
 335   ostry="$ostry /$o"
 336 fi
 337
 338 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 339 base=
 340 tail=$base_os
 341 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 342   set $b
 343   base="$base /$1"
 344   tail="$2"
 345 done
 346
 347 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 348 mach=
 349 tail=$machine
 350 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 351   set $m
 352   # Prepend the machine's FPU directory unless --without-fp.
 353   if test "$with_fp" = yes; then
 354     mach="$mach /$1/fpu"
 355   fi
 356   mach="$mach /$1"
 357   tail="$2"
 358 done
 359
 360 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 361 changequote([,])dnl
 362
 363 # Find what sysdep directories exist.
 364 sysnames=
 365 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 366 for d in $add_ons_pfx ''; do
 367   for b in $base ''; do
 368     for m0 in $mach ''; do
 369       for v in /$vendor ''; do
 370         test "$v" = / && continue
 371         for o in /$ostry ''; do
 372           test "$o" = / && continue
 373           for m in $mach ''; do
 374             if test "$m0$b$v$o$m"; then
 375               try="${d}sysdeps$m0$b$v$o$m"
 376               test -n "$enable_debug_configure" &&
 377               echo "$0 [DEBUG]: try $try" >&2
 378               if test -d $srcdir/$try; then
 379                 sysnames="$sysnames $try"
 380                 { test -n "$o" || test -n "$b"; } && os_used=t
 381                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 382               fi
 383             fi
 384           done
 385         done
 386       done
 387     done
 388   done
 389 done
 390 IFS="$ac_save_ifs"
 391
 392 if test -z "$os_used" && test "$os" != none; then
 393   AC_MSG_ERROR(Operating system $os is not supported.)
 394 fi
 395 if test -z "$machine_used" && test "$machine" != none; then
 396   AC_MSG_ERROR(The $machine is not supported.)
 397 fi
 398
 399 # We have now validated the configuration.
 400
 401
 402 # If using ELF, look for an `elf' subdirectory of each machine directory.
 403 # We prepend these rather than inserting them whereever the machine appears
 404 # because things specified by the machine's ELF ABI should override
 405 # OS-specific things, and should always be the same for any OS on the
 406 # machine (otherwise what's the point of an ABI?).
 407 if test "$elf" = yes; then
 408   elf_dirs=
 409   for d in $add_ons_pfx ''; do
 410     for m in $mach; do
 411       if test -d $srcdir/${d}sysdeps$m/elf; then
 412         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 413       fi
 414     done
 415   done
 416   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 417 fi
 418
 419
 420 # Expand the list of system names into a full list of directories
 421 # from each element's parent name and Implies file (if present).
 422 set $sysnames
 423 names=
 424 while test $# -gt 0; do
 425   name=$1
 426   shift
 427
 428   case " $names " in *" $name "*)
 429     # Already in the list.
 430     continue
 431   esac
 432
 433   # Report each name as we discover it, so there is no long pause in output.
 434   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 435
 436   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 437
 438   case $name in
 439     /*) xsrcdir= ;;
 440     *)  xsrcdir=$srcdir/ ;;
 441   esac
 442   test -n "$enable_debug_configure" &&
 443   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 444
 445   if test -f $xsrcdir$name/Implies; then
 446     # Collect more names from the `Implies' file (removing comments).
 447     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 448     implied=
 449     for x in $implied_candidate; do
 450       if test -d $xsrcdir$name_base/$x; then
 451         implied="$implied $name_base/$x";
 452       else
 453         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 454       fi
 455     done
 456   else
 457     implied=
 458   fi
 459
 460   # Add NAME to the list of names.
 461   names="$names $name"
 462
 463   # Find the parent of NAME, using the empty string if it has none.
 464 changequote(,)dnl
 465   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 466 changequote([,])dnl
 467
 468   # Add the names implied by NAME, and NAME's parent (if it has one), to
 469   # the list of names to be processed (the argument list).  We prepend the
 470   # implied names to the list and append the parent.  We want implied
 471   # directories to come before further directories inferred from the
 472   # configuration components; this ensures that for sysv4, unix/common
 473   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 474   # after sysv4).
 475   sysnames="`echo $implied $* $parent`"
 476   test -n "$sysnames" && set $sysnames
 477 done
 478
 479 # Add the default directories.
 480 default_sysnames=sysdeps/generic
 481 if test "$elf" = yes; then
 482   default_sysnames="sysdeps/generic/elf $default_sysnames"
 483 fi
 484 sysnames="$names $default_sysnames"
 485 AC_SUBST(sysnames)
 486 # The other names were emitted during the scan.
 487 AC_MSG_RESULT($default_sysnames)
 488
 489
 490 ### Locate tools.
 491
 492 AC_PROG_INSTALL
 493 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 494   # The makefiles need to use a different form to find it in $srcdir.
 495   INSTALL='\$(..)./scripts/install-sh -c'
 496 fi
 497 AC_PROG_LN_S
 498
 499 # These programs are version sensitive.
 500 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
 501 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 502   [version \([egcygnustp-]*[0-9.]*\)],
 503   [egcs-2.9[1-9].*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|*gcc-2.9[1-9].*|pgcc-2.90.2[789]|pgcc-2.90.[3-9][0-9]|*2.8.[1-9]*|*2.9|*2.9.[0-9]*|2.9[5-9]*|cygnus-2.9[1-9]*|gcc-2.9[5-9]|gcc-2.1[0-9][0-9]],
 504   critic_missing=t)
 505 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 506   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 507   [3.75 | 3.76.[1-9]* | 3.7[789]* | 3.[89]*], critic_missing=t)
 508
 509 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 510   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 511   [0.[1-9][0-9].* | [1-9].*], MSGFMT=: aux_missing=t)
 512 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 513   [GNU texinfo.* \([0-9][0-9.]*\)],
 514   [3.1[1-9] | 3.[2-9][0-9] | 4.* | 1.6[89] | 1.7[0-9]], MAKEINFO=: aux_missing=t)
 515
 516 if test -n "$critic_missing"; then
 517 AC_MSG_ERROR([
 518 *** Some critical program is missing or too old.
 519 *** Check the INSTALL file for required versions.])
 520 fi
 521
 522 test -n "$aux_missing" && AC_MSG_WARN([
 523 *** An auxiliary program is missing or too old;
 524 *** some features will be disabled.
 525 *** Check the INSTALL file for required versions.])
 526
 527 # glibcbug.in wants to know the compiler version.
 528 CCVERSION=`$CC -v 2>&1 | sed -n 's/gcc version //p'`
 529 AC_SUBST(CCVERSION)
 530
 531 AC_PROG_CC_LOCAL
 532 AC_CANONICAL_BUILD
 533 if test $host != $build; then
 534   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 535 fi
 536 AC_SUBST(cross_compiling)
 537 AC_PROG_CPP
 538 LIBC_PROG_BINUTILS
 539 AC_CHECK_TOOL(MIG, mig)
 540
 541 # if using special system headers, find out the compiler's sekrit
 542 # header directory and add that to the list.  NOTE: Only does the right
 543 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 544 if test -n "$sysheaders"; then
 545   ccheaders=`$CC -print-file-name=include`
 546   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 547 fi
 548 AC_SUBST(SYSINCLUDES)
 549
 550 # check if ranlib is necessary
 551 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 552 cat > conftest.c <<EOF
 553 int a;
 554 char b;
 555 void c(void) {}
 556 EOF
 557 $CC $CFLAGS -c conftest.c
 558 $AR cr conftest.a conftest.c
 559 cp conftest.a conftest2.a
 560 $RANLIB conftest.a
 561 if cmp -s conftest.a conftest2.a; then
 562   libc_cv_ranlib_necessary=no
 563 else
 564   libc_cv_ranlib_necessary=yes
 565 fi
 566 rm -rf conftest*])
 567 if test "$libc_cv_ranlib_necessary" = no; then
 568  RANLIB=:
 569 fi
 570
 571 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 572 # since this would lead to problems installing/building glibc.
 573 # LD_LIBRARY_PATH contains the current directory if one of the following
 574 # is true:
 575 # - one of the terminals (":" and ";") is the first or last sign
 576 # - two terminals occur directly after each other
 577 # - the path contains an element with a dot in it
 578 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 579 changequote(,)dnl
 580 case ${LD_LIBRARY_PATH} in
 581   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 582     ld_library_path_setting="contains current directory"
 583     ;;
 584   *)
 585     ld_library_path_setting="ok"
 586     ;;
 587 esac
 588 changequote([,])dnl
 589 AC_MSG_RESULT($ld_library_path_setting)
 590 if test "$ld_library_path_setting" != "ok"; then
 591 AC_MSG_ERROR([
 592 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 593 *** building glibc. Please change the environment variable
 594 *** and run configure again.])
 595 fi
 596
 597 AC_PATH_PROG(BASH, bash, no)
 598 if test "$BASH" != no &&
 599    $BASH -c 'test "$BASH_VERSINFO" \
 600              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 601   libc_cv_have_bash2=yes
 602 else
 603   libc_cv_have_bash2=no
 604 fi
 605 AC_SUBST(libc_cv_have_bash2)
 606
 607 dnl We need a ksh compatible shell for tzselect.
 608 if test "$BASH" = no; then
 609   AC_PATH_PROG(KSH, ksh, no)
 610   if test "$KSH" = no; then
 611     libc_cv_have_ksh=no
 612   else
 613     libc_cv_have_ksh=yes
 614   fi
 615 else
 616   KSH="$BASH"
 617   AC_SUBST(KSH)
 618   libc_cv_have_ksh=yes
 619 fi
 620 AC_SUBST(libc_cv_have_ksh)
 621
 622 AC_PROG_AWK
 623 AC_PATH_PROG(PERL, perl, no)
 624 AC_SUBST(PERL)
 625 AC_PATH_PROG(INSTALL_INFO, install-info, no,
 626              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
 627 AC_SUBST(INSTALL_INFO)
 628 if test "$INSTALL_INFO" != "no"; then
 629 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
 630  [mkdir conftest.d
 631   # There is a hard ^_ on the next line.  I am open to better ideas.
 632   (echo '\1f'
 633   echo 'File: dir       Node: Top       This is the top of the INFO tree'
 634   echo '* Menu:') >conftest.d/dir
 635   (echo 'INFO-DIR-SECTION i-d-s works'
 636   echo 'START-INFO-DIR-ENTRY'
 637   echo '* Prog: (prog).   Program.'
 638   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
 639   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AC_FD_CC 2>&1
 640   then
 641     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
 642     then libc_cv_old_debian_install_info=no
 643     else libc_cv_old_debian_install_info=yes
 644     fi
 645   else libc_cv_old_debian_install_info=no testfailed=t
 646   fi
 647   rm -fr conftest.d])
 648 if test -n "$testfailed"
 649 then AC_MSG_WARN([install-info errored out, check config.log])
 650 fi
 651 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
 652 fi
 653 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
 654
 655 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 656 echo '#include <stddef.h>
 657 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 658 if eval "$ac_cpp conftest.c 2>/dev/null" \
 659 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 660   libc_cv_signed_size_t=no
 661 else
 662   libc_cv_signed_size_t=yes
 663 fi
 664 rm -f conftest*])
 665 if test $libc_cv_signed_size_t = yes; then
 666   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 667   cat >> confdefs.h <<\EOF
 668 #undef __SIZE_TYPE__
 669 #define __SIZE_TYPE__ unsigned
 670 EOF
 671 fi
 672
 673 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 674 AC_TRY_COMPILE(dnl
 675 [#define __need_size_t
 676 #define __need_wchar_t
 677 #include <stddef.h>
 678 #define __need_NULL
 679 #include <stddef.h>], [size_t size; wchar_t wchar;
 680 #ifdef offsetof
 681 #error stddef.h ignored __need_*
 682 #endif
 683 if (&size == NULL || &wchar == NULL) abort ();],
 684                libc_cv_friendly_stddef=yes,
 685                libc_cv_friendly_stddef=no)])
 686 if test $libc_cv_friendly_stddef = yes; then
 687   config_vars="$config_vars
 688 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 689 fi
 690
 691 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 692                libc_cv_need_minus_P, [dnl
 693 cat > conftest.S <<EOF
 694 #include "confdefs.h"
 695 /* Nothing whatsoever.  */
 696 EOF
 697 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 698   libc_cv_need_minus_P=no
 699 else
 700   libc_cv_need_minus_P=yes
 701 fi
 702 rm -f conftest*])
 703 if test $libc_cv_need_minus_P = yes; then
 704   config_vars="$config_vars
 705 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 706 fi
 707
 708 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 709 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 710 cat > conftest.s <<EOF
 711 .text
 712 EOF
 713 libc_cv_dot_text=
 714 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 715   libc_cv_dot_text=.text
 716 fi
 717 rm -f conftest*])
 718 if test -z "$libc_cv_dot_text"; then
 719   AC_MSG_RESULT(no)
 720 else
 721   AC_MSG_RESULT(yes)
 722 fi
 723
 724 AC_CACHE_CHECK(for assembler global-symbol directive,
 725                libc_cv_asm_global_directive, [dnl
 726 libc_cv_asm_global_directive=UNKNOWN
 727 for ac_globl in .globl .global .EXPORT; do
 728   cat > conftest.s <<EOF
 729         ${libc_cv_dot_text}
 730         ${ac_globl} foo
 731 foo:
 732 EOF
 733   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 734     libc_cv_asm_global_directive=${ac_globl}
 735   fi
 736   rm -f conftest*
 737   test $libc_cv_asm_global_directive != UNKNOWN && break
 738 done])
 739 if test $libc_cv_asm_global_directive = UNKNOWN; then
 740   AC_MSG_ERROR(cannot determine asm global directive)
 741 else
 742   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 743 fi
 744
 745 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 746 cat > conftest.s <<EOF
 747 ${libc_cv_dot_text}
 748 foo:
 749 .set glibc_conftest_frobozz,foo
 750 $libc_cv_asm_global_directive glibc_conftest_frobozz
 751 EOF
 752 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 753 # (but it doesn't work), so we must do a linking check to be sure.
 754 cat > conftest1.c <<\EOF
 755 extern int glibc_conftest_frobozz;
 756 main () { printf ("%d\n", glibc_conftest_frobozz); }
 757 EOF
 758 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 759             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 760   libc_cv_asm_set_directive=yes
 761 else
 762   libc_cv_asm_set_directive=no
 763 fi
 764 rm -f conftest*])
 765 if test $libc_cv_asm_set_directive = yes; then
 766   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 767 fi
 768
 769 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 770 [cat > conftest.s <<EOF
 771 ${libc_cv_dot_text}
 772 _sym:
 773 .symver _sym,sym@VERS
 774 EOF
 775 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 776   libc_cv_asm_symver_directive=yes
 777 else
 778   libc_cv_asm_symver_directive=no
 779 fi
 780 rm -f conftest*])
 781 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 782 if test $libc_cv_asm_symver_directive = yes; then
 783   cat > conftest.s <<EOF
 784 ${libc_cv_dot_text}
 785 _sym:
 786 .symver _sym,sym@VERS
 787 EOF
 788   cat > conftest.map <<EOF
 789 VERS_1 {
 790         global: sym;
 791 };
 792
 793 VERS_2 {
 794         global: sym;
 795 } VERS_1;
 796 EOF
 797   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 798     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 799                                         -nostartfiles -nostdlib
 800                                         -Wl,--version-script,conftest.map
 801                        1>&AC_FD_CC]);
 802     then
 803       libc_cv_ld_version_script_option=yes
 804     else
 805       libc_cv_ld_version_script_option=no
 806     fi
 807   else
 808     libc_cv_ld_version_script_option=no
 809   fi
 810 else
 811   libc_cv_ld_version_script_option=no
 812 fi
 813 rm -f conftest*])
 814 if test $libc_cv_asm_symver_directive = yes &&
 815    test $libc_cv_ld_version_script_option = yes &&
 816    test $enable_versioning = yes; then
 817   VERSIONING=yes
 818   AC_DEFINE(DO_VERSIONING)
 819 else
 820   VERSIONING=no
 821 fi
 822 AC_SUBST(VERSIONING)
 823
 824 if test $VERSIONING = no; then
 825   echo "\
 826 *** WARNING: You should not compile GNU libc without versioning. Not using
 827 *** versioning will introduce incompatibilities so that old binaries
 828 *** will not run anymore.
 829 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
 830 fi
 831 if test $elf = yes; then
 832   AC_CACHE_CHECK(for .previous assembler directive,
 833                  libc_cv_asm_previous_directive, [dnl
 834   cat > conftest.s <<EOF
 835 .section foo_section
 836 .previous
 837 EOF
 838   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 839     libc_cv_asm_previous_directive=yes
 840   else
 841     libc_cv_asm_previous_directive=no
 842   fi
 843   rm -f conftest*])
 844   if test $libc_cv_asm_previous_directive = yes; then
 845     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 846   else
 847     AC_CACHE_CHECK(for .popsection assembler directive,
 848                    libc_cv_asm_popsection_directive, [dnl
 849     cat > conftest.s <<EOF
 850 .pushsection foo_section
 851 .popsection
 852 EOF
 853     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 854       libc_cv_asm_popsection_directive=yes
 855     else
 856       libc_cv_asm_popsection_directive=no
 857     fi
 858     rm -f conftest*])
 859     if test $libc_cv_asm_popsection_directive = yes; then
 860       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 861     fi
 862   fi
 863 fi
 864
 865 if test $elf != yes; then
 866   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 867                  [AC_TRY_COMPILE(, [asm (".section .init");
 868                                     asm (".section .fini");
 869                                     asm ("${libc_cv_dot_text}");],
 870                                  libc_cv_have_initfini=yes,
 871                                  libc_cv_have_initfini=no)])
 872   AC_SUBST(libc_cv_have_initfini)dnl
 873   if test $libc_cv_have_initfini = yes; then
 874     AC_DEFINE(HAVE_INITFINI)
 875   fi
 876 fi
 877
 878 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 879 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 880 [cat > conftest.$ac_ext <<EOF
 881 dnl This sometimes fails to find confdefs.h, for some reason.
 882 dnl [#]line __oline__ "[$]0"
 883 [#]line __oline__ "configure"
 884 #include "confdefs.h"
 885 void underscore_test(void) {
 886 return; }
 887 EOF
 888 if AC_TRY_EVAL(ac_compile); then
 889   if grep _underscore_test conftest* >/dev/null; then
 890     ifelse([$1], , :, [rm -f conftest*
 891     $1])
 892   else
 893     ifelse([$2], , , [rm -f conftest*
 894     $2])
 895   fi
 896 else
 897   echo "configure: failed program was:" >&AC_FD_CC
 898   cat conftest.$ac_ext >&AC_FD_CC
 899   ifelse([$2], , , [rm -f conftest*
 900   $2])
 901 fi
 902 rm -f conftest*])
 903
 904 if test $elf = yes; then
 905   libc_cv_asm_underscores=no
 906 else
 907   if test $ac_cv_prog_cc_works = yes; then
 908     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 909                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 910                                 libc_cv_asm_underscores=yes,
 911                                 libc_cv_asm_underscores=no)])
 912   else
 913     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 914                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 915                                             libc_cv_asm_underscores=no)])
 916   fi
 917 fi
 918 if test $libc_cv_asm_underscores = no; then
 919   AC_DEFINE(NO_UNDERSCORES)
 920 fi
 921
 922 if test $elf = yes; then
 923   libc_cv_weak_symbols=yes
 924 fi
 925
 926 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 927                [dnl
 928 cat > conftest.s <<EOF
 929 ${libc_cv_dot_text}
 930 ${libc_cv_asm_global_directive} foo
 931 foo:
 932 .weak foo
 933 .weak bar; bar = foo
 934 EOF
 935 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 936   libc_cv_asm_weak_directive=yes
 937 else
 938   libc_cv_asm_weak_directive=no
 939 fi
 940 rm -f conftest*])
 941
 942 if test $libc_cv_asm_weak_directive = no; then
 943   AC_CACHE_CHECK(for assembler .weakext directive,
 944                  libc_cv_asm_weakext_directive,
 945                  [dnl
 946 cat > conftest.s <<EOF
 947 ${libc_cv_dot_text}
 948 ${libc_cv_asm_global_directive} foo
 949 foo:
 950 .weakext bar foo
 951 .weakext baz
 952 ${libc_cv_asm_global_directive} baz
 953 baz:
 954 EOF
 955   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 956     libc_cv_asm_weakext_directive=yes
 957   else
 958     libc_cv_asm_weakext_directive=no
 959   fi
 960   rm -f conftest*])
 961
 962 fi # no .weak
 963
 964 if test $libc_cv_asm_weak_directive = yes; then
 965   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 966 elif test $libc_cv_asm_weakext_directive = yes; then
 967   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 968 fi
 969
 970 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 971 cat > conftest.c <<\EOF
 972 _start () {}
 973 int __eh_pc;
 974 __throw () {}
 975 EOF
 976 dnl No \ in command here because it ends up inside ''.
 977 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 978                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 979                             -o conftest conftest.c 1>&AC_FD_CC]); then
 980   libc_cv_ld_no_whole_archive=yes
 981 else
 982   libc_cv_ld_no_whole_archive=no
 983 fi
 984 rm -f conftest*])
 985 if test $libc_cv_ld_no_whole_archive = yes; then
 986   no_whole_archive=-Wl,--no-whole-archive
 987 fi
 988 AC_SUBST(no_whole_archive)dnl
 989
 990 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
 991 cat > conftest.c <<\EOF
 992 _start () {}
 993 int __eh_pc;
 994 __throw () {}
 995 EOF
 996 dnl No \ in command here because it ends up inside ''.
 997 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 998                             -nostdlib -nostartfiles -fexceptions
 999                             -o conftest conftest.c 1>&AC_FD_CC]); then
1000   libc_cv_gcc_exceptions=yes
1001 else
1002   libc_cv_gcc_exceptions=no
1003 fi
1004 rm -f conftest*])
1005 if test $libc_cv_gcc_exceptions = yes; then
1006   exceptions=-fexceptions
1007 fi
1008 AC_SUBST(exceptions)dnl
1009
1010 if test "$base_machine" = alpha ; then
1011 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
1012 cat > conftest.c <<\EOF
1013 foo () { }
1014 EOF
1015 dnl
1016 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
1017 then
1018   libc_cv_gcc_alpha_ng_prefix=yes
1019 else
1020   libc_cv_gcc_alpha_ng_prefix=no
1021 fi
1022 rm -f conftest* ])
1023 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
1024   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
1025 else
1026   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
1027 fi
1028 fi
1029
1030 if test "$host_cpu" = powerpc ; then
1031 # Check for a bug present in at least versions 2.8.x of GCC
1032 # and versions 1.0.x of EGCS.
1033 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1034 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1035                libc_cv_c_asmcr0_bug='no',
1036                libc_cv_c_asmcr0_bug='yes')])
1037 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1038   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1039 fi
1040 fi
1041
1042 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
1043 [cat > conftest.c <<EOF
1044 #line __oline__ "configure"
1045 static char __EH_FRAME_BEGIN__[];
1046 _start ()
1047 {
1048 #ifdef CHECK__register_frame
1049   __register_frame (__EH_FRAME_BEGIN__);
1050   __deregister_frame (__EH_FRAME_BEGIN__);
1051 #endif
1052 #ifdef CHECK__register_frame_info
1053   __register_frame_info (__EH_FRAME_BEGIN__);
1054   __deregister_frame_info (__EH_FRAME_BEGIN__);
1055 #endif
1056 }
1057 int __eh_pc;
1058 __throw () {}
1059 /* FIXME: this is fragile.  */
1060 malloc () {}
1061 strcmp () {}
1062 strlen () {}
1063 memcpy () {}
1064 memset () {}
1065 free () {}
1066 abort () {}
1067 __bzero () {}
1068 EOF
1069 dnl No \ in command here because it ends up inside ''.
1070 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
1071                             -nostdlib -nostartfiles
1072                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1073   libc_cv_gcc_dwarf2_unwind_info=static
1074 else
1075   libc_cv_gcc_dwarf2_unwind_info=no
1076 fi
1077 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
1078   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1079                               -nostdlib -nostartfiles
1080                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1081     libc_cv_gcc_dwarf2_unwind_info=yes
1082   else
1083     libc_cv_gcc_dwarf2_unwind_info=no
1084   fi
1085 fi
1086 rm -f conftest*])
1087 case $libc_cv_gcc_dwarf2_unwind_info in
1088 yes)
1089   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1090   ;;
1091 static)
1092   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1093   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1094   ;;
1095 esac
1096
1097 dnl Check whether compiler understands __builtin_expect.
1098 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1099 [cat > conftest.c <<EOF
1100 #line __oline__ "configure"
1101 int foo (int a)
1102 {
1103   a = __builtin_expect (a, 10);
1104   return a == 10 ? 0 : 1;
1105 }
1106 EOF
1107 dnl No \ in command here because it ends up inside ''.
1108 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1109                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1110   libc_cv_gcc_builtin_expect=yes
1111 else
1112   libc_cv_gcc_builtin_expect=no
1113 fi
1114 rm -f conftest*])
1115 if test "$libc_cv_gcc_builtin_expect" = yes; then
1116   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1117 fi
1118
1119 dnl Check whether the compiler supports subtraction of local labels.
1120 AC_CACHE_CHECK(for local label subtraction, libc_cv_gcc_subtract_local_labels,
1121 [cat > conftest.c <<EOF
1122 changequote(,)dnl
1123 #line __oline__ "configure"
1124 int foo (int a)
1125 {
1126   static const int ar[] = { &&l1 - &&l1, &&l2 - &&l1 };
1127   void *p = &&l1 + ar[a];
1128   goto *p;
1129  l1:
1130   return 1;
1131  l2:
1132   return 2;
1133 }
1134 changequote([,])dnl
1135 EOF
1136 dnl No \ in command here because it ends up inside ''.
1137 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1138                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1139   libc_cv_gcc_subtract_local_labels=yes
1140 else
1141   libc_cv_gcc_subtract_local_labels=no
1142 fi
1143 rm -f conftest*])
1144 if test "$libc_cv_gcc_subtract_local_labels" = yes; then
1145   AC_DEFINE(HAVE_SUBTRACT_LOCAL_LABELS)
1146 fi
1147
1148 dnl Check whether we have the gd library available.
1149 AC_MSG_CHECKING(for libgd)
1150 old_CFLAGS="$CFLAGS"
1151 CFLAGS="$CFLAGS $libgd_include"
1152 old_LDFLAGS="$LDFLAGS"
1153 LDFLAGS="$LDFLAGS $libgd_ldflags"
1154 old_LIBS="$LIBS"
1155 LIBS="$LIBS -lgd -lpng -lz"
1156 AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
1157 CFLAGS="$old_CFLAGS"
1158 LDFLAGS="$old_LDFLAGS"
1159 LIBS="$old_LIBS"
1160 AC_MSG_RESULT($LIBGD)
1161 AC_SUBST(LIBGD)
1162
1163 ### End of automated tests.
1164 ### Now run sysdeps configure fragments.
1165
1166 # sysdeps configure fragments may set these with files to be linked below.
1167 libc_link_dests=
1168 libc_link_sources=
1169
1170 # They also can set these variables.
1171 ldd_rewrite_script=no
1172
1173 # Iterate over all the sysdep directories we will use, running their
1174 # configure fragments, and looking for a uname implementation.
1175 uname=
1176 for dir in $sysnames; do
1177   case $dir in
1178     /*) dest=$dir ;;
1179     *)  dest=$srcdir/$dir ;;
1180   esac
1181   if test -r $dest/configure; then
1182     AC_MSG_RESULT(running configure fragment for $dest)
1183     . $dest/configure
1184   fi
1185 [
1186   if test -z "$uname"; then
1187     if test -r $dest/uname.c ||
1188        test -r $dest/uname.S ||
1189        { test -r $dest/syscalls.list &&
1190          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1191       uname=$dir
1192     fi
1193   fi
1194 ]dnl
1195 done
1196
1197 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1198
1199 # If we will use the generic uname implementation, we must figure out what
1200 # it will say by examining the system, and write the results in config-name.h.
1201 if test "$uname" = "sysdeps/generic"; then
1202
1203 changequote(,)dnl
1204   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1205 changequote([,])dnl
1206   if test $uname_sysname != $config_os; then
1207     config_release=`echo $config_os | sed s/$uname_sysname//`
1208   fi
1209 dnl
1210 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1211     if test -r /vmunix; then
1212       kernel_id=`strings /vmunix | grep UNIX`
1213     elif test -r /dynix; then
1214       kernel_id=`strings /dynix | grep DYNIX`
1215     else
1216       kernel_id=
1217     fi
1218 ])dnl
1219
1220   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1221 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1222 changequote(,)dnl
1223   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1224 changequote([,])dnl
1225   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1226          != x$config_release; then
1227     # The configuration release is a substring of the kernel release.
1228     libc_cv_uname_release=$kernel_release
1229   elif test x$config_release != x; then
1230     libc_cv_uname_release=$config_release
1231   elif test x$kernel_release != x; then
1232     libc_cv_uname_release=$kernel_release
1233   else
1234     libc_cv_uname_release=unknown
1235   fi])
1236   uname_release="$libc_cv_uname_release"
1237
1238   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1239 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1240 changequote(,)dnl
1241   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1242 changequote([,])dnl
1243   if test -n "$kernel_version"; then
1244     libc_cv_uname_version="$kernel_version"
1245   else
1246     libc_cv_uname_version=unknown
1247   fi])
1248   uname_version="$libc_cv_uname_version"
1249
1250 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1251   config_uname=config-name.h:config-name.in
1252 else
1253   # For non-generic uname, we don't need to create config-name.h at all.
1254   config_uname=
1255 fi
1256
1257 AC_MSG_CHECKING(stdio selection)
1258 AC_SUBST(stdio)
1259 case $stdio in
1260 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1261 default) stdio=stdio ;;
1262 esac
1263 AC_MSG_RESULT($stdio)
1264
1265 # Test for old glibc 2.0.x headers so that they can be removed properly
1266 # Search only in includedir.
1267 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1268 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1269 then
1270   old_glibc_headers=yes
1271 else
1272   old_glibc_headers=no
1273 fi
1274 AC_MSG_RESULT($old_glibc_headers)
1275 if test ${old_glibc_headers} = yes; then
1276   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1277   AC_MSG_WARN(*** be removed.)
1278 fi
1279 AC_SUBST(old_glibc_headers)
1280
1281 AC_SUBST(libc_cv_slibdir)
1282 AC_SUBST(libc_cv_sysconfdir)
1283 AC_SUBST(libc_cv_rootsbindir)
1284
1285 AC_SUBST(has_ldconfig)
1286 AC_SUBST(ldd_rewrite_script)
1287
1288 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1289 if test $gnu_ld = yes; then
1290   AC_DEFINE(HAVE_GNU_LD)
1291 fi
1292 if test $gnu_as = yes; then
1293   AC_DEFINE(HAVE_GNU_AS)
1294 fi
1295 if test $elf = yes; then
1296   AC_DEFINE(HAVE_ELF)
1297 fi
1298
1299 AC_SUBST(static)
1300 AC_SUBST(shared)
1301 if test $shared = default; then
1302   if test $gnu_ld = yes; then
1303     shared=$elf
1304   else
1305     # For now we do not assume shared libs are available.  In future more
1306     # tests might become available.
1307     shared=no
1308   fi
1309 fi
1310
1311 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1312 [pic_default=yes
1313 cat > conftest.c <<EOF
1314 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1315 # error PIC is default.
1316 #endif
1317 EOF
1318 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1319   pic_default=no
1320 fi
1321 rm -f conftest.*])
1322 AC_SUBST(pic_default)
1323
1324 AC_SUBST(profile)
1325 AC_SUBST(omitfp)
1326 AC_SUBST(bounded)
1327 AC_SUBST(static_nss)
1328 AC_SUBST(nopic_initfini)
1329
1330 AC_SUBST(DEFINES)
1331
1332 case "$add_ons" in
1333   *door*) linux_doors=yes ;;
1334   *) linux_doors=no ;;
1335 esac
1336 AC_SUBST(linux_doors)
1337
1338 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1339   config_makefile=
1340 else
1341   config_makefile=Makefile
1342 fi
1343
1344 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1345 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1346 AC_SUBST(VERSION)
1347 AC_SUBST(RELEASE)
1348
1349 echo '*** Do NOT install this release on any production system!'
1350 echo '*** It is known to be broken and will be so for quite some time.'
1351 echo '*** Use the latest released version instead.'
1352
1353 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1354 case $CONFIG_FILES in *config.make*)
1355 echo "$config_vars" >> config.make;;
1356 esac
1357 test -d bits || mkdir bits], [config_vars='$config_vars'])