configure.in

   1 AC_PREREQ(2.57)
   2 AC_INIT(cryptsetup,1.1.3)
   3
   4 dnl library version from <major>.<minor>.<release>[-<suffix>]
   5 LIBCRYPTSETUP_VERSION=$(echo $PACKAGE_VERSION | cut -f1 -d-)
   6 LIBCRYPTSETUP_VERSION_INFO=1:0:0
   7
   8 AC_CONFIG_SRCDIR(src/cryptsetup.c)
   9 AC_CONFIG_MACRO_DIR([m4])
  10
  11 AM_CONFIG_HEADER([config.h:config.h.in])
  12 AM_INIT_AUTOMAKE(dist-bzip2)
  13
  14 if test "x$prefix" = "xNONE"; then
  15         sysconfdir=/etc
  16 fi
  17 AC_PREFIX_DEFAULT(/usr)
  18
  19 AC_CANONICAL_HOST
  20 AC_GNU_SOURCE
  21 AC_PROG_CC
  22 AM_PROG_CC_C_O
  23 AC_PROG_CPP
  24 AC_PROG_INSTALL
  25 AC_PROG_MAKE_SET
  26 AC_ENABLE_STATIC(no)
  27 AM_PROG_LIBTOOL
  28
  29 AC_HEADER_DIRENT
  30 AC_HEADER_STDC
  31 AC_CHECK_HEADERS(fcntl.h malloc.h inttypes.h sys/ioctl.h sys/mman.h \
  32         ctype.h unistd.h locale.h)
  33
  34 AC_CHECK_HEADERS(uuid/uuid.h,,[AC_MSG_ERROR('You need the uuid library')])
  35 AC_CHECK_HEADER(libdevmapper.h,,[AC_MSG_ERROR('You need the device-mapper library')])
  36
  37 saved_LIBS=$LIBS
  38 AC_CHECK_LIB(uuid, uuid_clear, ,[AC_MSG_ERROR('You need the uuid library')])
  39 AC_SUBST(UUID_LIBS, $LIBS)
  40 LIBS=$saved_LIBS
  41
  42
  43 AM_PATH_LIBGCRYPT(1.1.42,,[AC_MSG_ERROR('You need the gcrypt library')])
  44
  45 AC_CHECK_FUNCS([posix_memalign])
  46
  47 AC_C_CONST
  48 AC_C_BIGENDIAN
  49 AC_TYPE_OFF_T
  50 AC_STRUCT_ST_RDEV
  51 AC_SYS_LARGEFILE
  52
  53 AC_PROG_GCC_TRADITIONAL
  54
  55 dnl ==========================================================================
  56
  57 AM_GNU_GETTEXT([external],[need-ngettext])
  58 AM_GNU_GETTEXT_VERSION([0.15])
  59
  60 dnl ==========================================================================
  61
  62 saved_LIBS=$LIBS
  63 AC_CHECK_LIB(popt, poptConfigFileToString,,
  64         [AC_MSG_ERROR([You need popt 1.7 or newer to compile.])])
  65 AC_SUBST(POPT_LIBS, $LIBS)
  66 LIBS=$saved_LIBS
  67
  68 dnl ==========================================================================
  69 saved_LIBS=$LIBS
  70
  71 AC_ARG_ENABLE([static-cryptsetup],
  72         AS_HELP_STRING([--enable-static-cryptsetup],
  73         [enable build of static cryptsetup binary]), [
  74         if test x$enable_static = xno; then
  75                 AC_MSG_WARN([Requested static cryptsetup build, enabling static library.])
  76                 enable_static=yes
  77         fi
  78         enable_static_cryptsetup=yes])
  79 AM_CONDITIONAL(STATIC_CRYPTSETUP, test x$enable_static_cryptsetup = xyes)
  80
  81 AC_ARG_ENABLE(selinux,
  82         AS_HELP_STRING([--disable-selinux],
  83         [disable selinux support [default=auto]]),[], [])
  84
  85 AC_ARG_ENABLE([udev],
  86         AS_HELP_STRING([--disable-udev],
  87         [disable udev support]),[], enable_udev=yes)
  88
  89 dnl Try to use pkg-config for devmapper, but fallback to old detection
  90 PKG_CHECK_MODULES([DEVMAPPER], [devmapper >= 1.02.03],, [
  91         AC_CHECK_LIB(devmapper, dm_task_set_name,,
  92                 [AC_MSG_ERROR([You need the device-mapper library.])])
  93         AC_CHECK_LIB(devmapper, dm_task_set_message,,
  94                 [AC_MSG_ERROR([The device-mapper library on your system is too old.])])
  95         DEVMAPPER_LIBS=$LIBS
  96 ])
  97 LIBS=$saved_LIBS
  98
  99 LIBS="$LIBS $DEVMAPPER_LIBS"
 100 AC_CHECK_DECLS([DM_UDEV_DISABLE_DISK_RULES_FLAG], [have_cookie=yes], [have_cookie=no], [#include <libdevmapper.h>])
 101 if test "x$enable_udev" = xyes; then
 102         if test "x$have_cookie" = xno; then
 103                 AC_MSG_WARN([The device-mapper library on your system has no udev support, udev support disabled.])
 104         else
 105                 AC_DEFINE(USE_UDEV, 1, [Try to use udev synchronisation?])
 106         fi
 107 fi
 108 LIBS=$saved_LIBS
 109
 110 dnl Magic for cryptsetup.static build.
 111 if test x$enable_static_cryptsetup = xyes; then
 112         saved_PKG_CONFIG=$PKG_CONFIG
 113         PKG_CONFIG="$PKG_CONFIG --static"
 114
 115         LIBS="$saved_LIBS $LIBGCRYPT_LIBS -static"
 116         AC_CHECK_LIB(gcrypt, gcry_check_version,,
 117                 AC_MSG_ERROR([Cannot find static gcrypt library.]),
 118                 [-lgpg-error])
 119         LIBGCRYPT_STATIC_LIBS="$LIBGCRYPT_LIBS -lgpg-error"
 120
 121         LIBS="$saved_LIBS -static"
 122         AC_CHECK_LIB(popt, poptGetContext,,
 123                 AC_MSG_ERROR([Cannot find static popt library.]))
 124
 125         dnl Try to detect needed device-mapper static libraries, try pkg-config first.
 126         LIBS="$saved_LIBS -static"
 127         PKG_CHECK_MODULES([DEVMAPPER_STATIC], [devmapper >= 1.02.27],,[
 128                 DEVMAPPER_STATIC_LIBS=$DEVMAPPER_LIBS
 129                 if test "x$enable_selinux" != xno; then
 130                         AC_CHECK_LIB(sepol, sepol_bool_set)
 131                         AC_CHECK_LIB(selinux, is_selinux_enabled)
 132                         DEVMAPPER_STATIC_LIBS="$DEVMAPPER_STATIC_LIBS $LIBS"
 133                 fi
 134         ])
 135         LIBS="$saved_LIBS $DEVMAPPER_STATIC_LIBS"
 136         AC_CHECK_LIB(devmapper, dm_task_set_uuid,,
 137                 AC_MSG_ERROR([Cannot link with static device-mapper library.]))
 138
 139         LIBS=$saved_LIBS
 140         PKG_CONFIG=$saved_PKG_CONFIG
 141 fi
 142
 143 AC_SUBST([DEVMAPPER_LIBS])
 144 AC_SUBST([DEVMAPPER_STATIC_LIBS])
 145 AC_SUBST([LIBGCRYPT_STATIC_LIBS])
 146 AC_SUBST([LIBCRYPTSETUP_VERSION])
 147 AC_SUBST([LIBCRYPTSETUP_VERSION_INFO])
 148
 149 dnl ==========================================================================
 150 AC_DEFUN([CS_DEFINE],
 151         [AC_DEFINE_UNQUOTED(DEFAULT_[]m4_translit([$1], [-a-z], [_A-Z]), [$2], [$3])
 152 ])
 153
 154 AC_DEFUN([CS_STR_WITH], [AC_ARG_WITH([$1],
 155         [AS_HELP_STRING(--with-[$1], [default $2 [$3]])],
 156         [CS_DEFINE([$1], ["$withval"], [$2])],
 157         [CS_DEFINE([$1], ["$3"], [$2])]
 158 )])
 159
 160 AC_DEFUN([CS_NUM_WITH], [AC_ARG_WITH([$1],
 161         [AS_HELP_STRING(--with-[$1], [default $2 [$3]])],
 162         [CS_DEFINE([$1], [$withval], [$2])],
 163         [CS_DEFINE([$1], [$3], [$2])]
 164 )])
 165
 166 CS_STR_WITH([plain-hash],   [password hashing function for plain mode], [ripemd160])
 167 CS_STR_WITH([plain-cipher], [cipher for plain mode], [aes])
 168 CS_STR_WITH([plain-mode],   [cipher mode for plain mode], [cbc-essiv:sha256])
 169 CS_NUM_WITH([plain-keybits],[key length in bits for plain mode], [256])
 170
 171 CS_STR_WITH([luks1-hash],   [hash function for LUKS1 header], [sha1])
 172 CS_STR_WITH([luks1-cipher], [cipher for LUKS1], [aes])
 173 CS_STR_WITH([luks1-mode],   [cipher mode for LUKS1], [cbc-essiv:sha256])
 174 CS_NUM_WITH([luks1-keybits],[key length in bits for LUKS1], [256])
 175
 176
 177 dnl ==========================================================================
 178
 179 AC_OUTPUT([ Makefile
 180 lib/Makefile
 181 lib/libcryptsetup.pc
 182 src/Makefile
 183 po/Makefile.in
 184 luks/Makefile
 185 man/Makefile
 186 tests/Makefile
 187 ])