configure.in

   1 dnl Process this file with autoconf 2.61 or later to produce
   2 dnl a configure script.
   3 AC_PREREQ(2.61)
   4 AC_INIT(config.h.in)
   5 AC_CONFIG_HEADERS(config.h)
   6
   7 dnl Check for broken VPATH handling on older NetBSD makes.
   8 AC_DEFUN(AC_PROG_MAKE_VPATHOK,
   9 [AC_MSG_CHECKING(whether ${MAKE-make} has sane VPATH handling)
  10 set dummy ${MAKE-make}; ac_make=`echo "[$]2" | sed 'y%./+-%__p_%'`
  11 AC_CACHE_VAL(ac_cv_prog_make_vpathok,
  12 [mkdir conftestdir
  13 cat > conftestdir/conftestmake <<\EOF
  14 VPATH = ..
  15 conftestfoo: conftestbar
  16         @echo ac_make2temp=ok
  17 conftestbar: conftestbaz
  18         @echo ac_maketemp=broken
  19         @touch conftestbar
  20 EOF
  21 echo > conftestbaz # these two lines need to be...
  22 echo > conftestbar # ... in this order not the other
  23 changequote(, )dnl
  24 unset ac_maketemp
  25 unset ac_make2temp
  26 # GNU make sometimes prints "make[1]: Entering...", which would confuse us.
  27 eval `cd conftestdir; ${MAKE-make} -f conftestmake 2>/dev/null | grep temp=`
  28 changequote([, ])dnl
  29 if test -n "$ac_maketemp"; then
  30   ac_cv_prog_make_vpathok=no
  31 else
  32   if test -n "$ac_make2temp"; then
  33     ac_cv_prog_make_vpathok=yes
  34   else
  35     ac_cv_prog_make_vpathok=no
  36   fi
  37 fi
  38 rm -rf conftestdir
  39 rm -f conftestbar conftestbaz])dnl
  40 if test $ac_cv_prog_make_vpathok = yes; then
  41   AC_MSG_RESULT(yes)
  42 else
  43   AC_MSG_RESULT(no)
  44 fi
  45 ])
  46
  47 AC_PREFIX_PROGRAM(nasm)
  48
  49 dnl Checks for programs.
  50 AC_USE_SYSTEM_EXTENSIONS
  51 AC_ISC_POSIX
  52 AC_PROG_CC
  53 AC_PROG_LN_S
  54 AC_PROG_MAKE_SET
  55 if test -f nasm.c; then
  56   # we're building in the source dir, so we don't need this check at all
  57   ac_cv_prog_make_vpathok=yes
  58 else
  59   AC_PROG_MAKE_VPATHOK
  60 fi
  61 AC_PROG_INSTALL
  62
  63 dnl If we have gcc, add appropriate options
  64 PA_ADD_CFLAGS([-W])
  65 PA_ADD_CFLAGS([-Wall])
  66 PA_ADD_CFLAGS([-std=c99])
  67 PA_ADD_CFLAGS([-pedantic])
  68
  69 dnl Look for "nroff" or "groff"
  70 AC_CHECK_PROGS(NROFF, nroff, echo)
  71 AC_SUBST(NROFF)
  72
  73 dnl Checks for header files.
  74 AC_HEADER_STDC
  75 if test $ac_cv_header_stdc = no; then
  76   AC_MSG_ERROR([NASM requires ANSI C header files to compile])
  77 fi
  78
  79 AC_CHECK_HEADERS(limits.h)
  80 if test $ac_cv_header_limits_h = no; then
  81   AC_MSG_ERROR([NASM requires '<limits.h>' to compile])
  82 fi
  83
  84 dnl Check for <inttypes.h> or add a substitute version
  85 AC_CHECK_HEADERS(inttypes.h, , CFLAGS="$CFLAGS -I\$(top_srcdir)/inttypes")
  86
  87 dnl The standard header for str*casecmp is <strings.h>
  88 AC_CHECK_HEADERS(strings.h)
  89
  90 dnl Look for <stdbool.h>
  91 AC_CHECK_HEADERS(stdbool.h)
  92
  93 dnl Checks for typedefs, structures, and compiler characteristics.
  94 AC_C_CONST
  95 AC_TYPE_SIZE_T
  96
  97 dnl Checks for library functions.
  98 AC_SUBST(XOBJS)
  99
 100 AC_CHECK_FUNCS(strcspn, ,
 101   AC_MSG_ERROR([NASM requires ANSI C (specifically, "strcspn")]))
 102
 103 AC_CHECK_FUNCS(strspn, ,
 104   AC_MSG_ERROR([NASM requires ANSI C (specifically, "strspn")]))
 105
 106 missing=true
 107 AC_CHECK_FUNCS([vsnprintf _vsnprintf], missing=false)
 108 if $missing; then
 109    XOBJS="$XOBJS lib/vsnprintf.o"
 110 fi
 111
 112 missing=true
 113 AC_CHECK_FUNCS([snprintf _snprintf], missing=false)
 114 if $missing; then
 115    XOBJS="$XOBJS lib/snprintf.o"
 116 fi
 117
 118 AC_CHECK_FUNCS(strcasecmp stricmp)
 119 AC_CHECK_FUNCS(strncasecmp strnicmp)
 120 AC_CHECK_FUNCS(strsep)
 121
 122 AC_CHECK_FUNCS(getuid)
 123 AC_CHECK_FUNCS(getgid)
 124
 125 if test $ac_cv_prog_make_vpathok = no; then
 126   echo Copying generated srcs into build directory to compensate for VPATH breakage
 127   for file in macros.c insnsa.c insnsd.c insnsn.c insnsi.h version.h version.mac; do
 128     if test ! -f $file; then cp -p ${srcdir}/${file} .; fi
 129   done
 130 fi
 131
 132 AC_OUTPUT_COMMANDS([mkdir -p output])
 133 AC_OUTPUT(Makefile rdoff/Makefile doc/Makefile)