configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 dnl ***********************************
   6 dnl *** include special GLib macros ***
   7 dnl ***********************************
   8
   9 m4_define(glib_configure_in)
  10
  11 #
  12 # The following version number definitions apply to GLib, GModule, GObject,
  13 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  14 # all treated with the same interface and binary age.
  15 #
  16 # Making releases:
  17 #   glib_micro_version += 1;
  18 #   glib_interface_age += 1;
  19 #   glib_binary_age += 1;
  20 # if any functions have been added, set glib_interface_age to 0.
  21 # if backwards compatibility has been broken,
  22 # set glib_binary_age _and_ glib_interface_age to 0.
  23 #
  24 m4_define([glib_major_version], [2])
  25 m4_define([glib_minor_version], [21])
  26 m4_define([glib_micro_version], [2])
  27 m4_define([glib_interface_age], [0])
  28 m4_define([glib_binary_age],
  29           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  30 m4_define([glib_version],
  31           [glib_major_version.glib_minor_version.glib_micro_version])
  32
  33 # libtool version related macros
  34 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  35 m4_define([glib_lt_current],
  36           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  37 m4_define([glib_lt_revision], [glib_interface_age])
  38 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  39 m4_define([glib_lt_current_minus_age],
  40           [m4_eval(glib_lt_current - glib_lt_age)])
  41
  42 # if the minor version number is odd, then we want debugging.  Otherwise
  43 # we only want minimal debugging support.
  44 m4_define([glib_debug_default],
  45           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  46
  47
  48 AC_INIT(glib, [glib_version],
  49         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  50
  51 AC_CONFIG_SRCDIR([glib/glib.h])
  52
  53 # Save this value here, since automake will set cflags later
  54 cflags_set=${CFLAGS+set}
  55
  56 AM_INIT_AUTOMAKE([no-define])
  57
  58 # Specify a configuration file
  59 AM_CONFIG_HEADER([config.h])
  60
  61
  62 GLIB_MAJOR_VERSION=glib_major_version
  63 GLIB_MINOR_VERSION=glib_minor_version
  64 GLIB_MICRO_VERSION=glib_micro_version
  65 GLIB_INTERFACE_AGE=glib_interface_age
  66 GLIB_BINARY_AGE=glib_binary_age
  67 GLIB_VERSION=glib_version
  68
  69 AC_SUBST(GLIB_MAJOR_VERSION)
  70 AC_SUBST(GLIB_MINOR_VERSION)
  71 AC_SUBST(GLIB_MICRO_VERSION)
  72 AC_SUBST(GLIB_VERSION)
  73 AC_SUBST(GLIB_INTERFACE_AGE)
  74 AC_SUBST(GLIB_BINARY_AGE)
  75
  76 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  77           [Define to the GLIB major version])
  78 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  79           [Define to the GLIB minor version])
  80 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  81           [Define to the GLIB micro version])
  82 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  83           [Define to the GLIB interface age])
  84 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  85           [Define to the GLIB binary age])
  86
  87 # libtool versioning
  88 LT_RELEASE=glib_lt_release
  89 LT_CURRENT=glib_lt_current
  90 LT_REVISION=glib_lt_revision
  91 LT_AGE=glib_lt_age
  92 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
  93 AC_SUBST(LT_RELEASE)
  94 AC_SUBST(LT_CURRENT)
  95 AC_SUBST(LT_REVISION)
  96 AC_SUBST(LT_AGE)
  97 AC_SUBST(LT_CURRENT_MINUS_AGE)
  98
  99 dnl Initialize maintainer mode
 100 AM_MAINTAINER_MODE
 101
 102 AC_CANONICAL_HOST
 103
 104 AC_MSG_CHECKING([for the BeOS])
 105 case $host in
 106   *-*-beos*)
 107     glib_native_beos="yes"
 108     ;;
 109   *)
 110     glib_native_beos="no"
 111     ;;
 112 esac
 113 AC_MSG_RESULT([$glib_native_beos])
 114
 115 dnl
 116
 117 AC_MSG_CHECKING([for Win32])
 118 LIB_EXE_MACHINE_FLAG=X86
 119 case "$host" in
 120   *-*-mingw*)
 121     glib_native_win32=yes
 122     glib_pid_type='void *'
 123     glib_cv_stack_grows=no
 124     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 125     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 126     # (Sorry, I don't know exactly what is the problem, but it is related to
 127     # floating point formatting and decimal point vs. comma.)
 128     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 129     # rigorous enough to notice, though.
 130     # So preset the autoconf cache variables.
 131     ac_cv_func_vsnprintf_c99=no
 132     ac_cv_func_snprintf_c99=no
 133     case "$host" in
 134     x86_64-*-*)
 135       LIB_EXE_MACHINE_FLAG=X64
 136       ;;
 137     esac
 138     ;;
 139   *)
 140     glib_native_win32=no
 141     glib_pid_type=int
 142     ;;
 143 esac
 144 case $host in
 145   *-*-linux*)
 146     glib_os_linux=yes
 147     ;;
 148 esac
 149
 150 AC_MSG_RESULT([$glib_native_win32])
 151
 152 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 153
 154 glib_have_carbon=no
 155 AC_MSG_CHECKING([for Mac OS X Carbon support])
 156 AC_TRY_CPP([
 157 #include <Carbon/Carbon.h>
 158 #include <CoreServices/CoreServices.h>
 159 ], glib_have_carbon=yes)
 160
 161 AC_MSG_RESULT([$glib_have_carbon])
 162
 163 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 164 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 165 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 166 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 167 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 168
 169 if test "$glib_native_win32" = "yes"; then
 170   AC_CHECK_TOOL(WINDRES, windres, no)
 171   if test "$WINDRES" = no; then
 172     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 173   fi
 174   AC_CHECK_TOOL(NM, nm, no)
 175   if test "$NM" = no; then
 176     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 177   fi
 178   AC_CHECK_TOOL(RANLIB, ranlib, :)
 179   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 180 fi
 181 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 182
 183 if test "$glib_native_win32" != yes; then
 184     # libtool option to control which symbols are exported
 185     # right now, symbols starting with _ are not exported
 186     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 187 else
 188     # We currently use .def files on Windows
 189     LIBTOOL_EXPORT_OPTIONS=
 190 fi
 191 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 192
 193 if test "x$glib_have_carbon" = "xyes"; then
 194   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 195   LDFLAGS="$LDFLAGS -framework Carbon"
 196 fi
 197
 198
 199 dnl declare --enable-* args and collect ac_help strings
 200 AC_ARG_ENABLE(debug,
 201               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 202                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 203               enable_debug=glib_debug_default)
 204
 205 AC_ARG_ENABLE(gc_friendly,
 206               [AC_HELP_STRING([--enable-gc-friendly],
 207                               [turn on garbage collector friendliness [default=no]])],,
 208               [enable_gc_friendly=no])
 209 AC_ARG_ENABLE(mem_pools,
 210               [AC_HELP_STRING([--disable-mem-pools],
 211                               [disable all glib memory pools])],,
 212               [disable_mem_pools=no])
 213 AC_ARG_ENABLE(threads,
 214               [AC_HELP_STRING([--enable-threads],
 215                               [turn on basic thread support [default=yes]
 216 ([=no] will override --with-threads)])],,
 217               [enable_threads=yes])
 218 AC_ARG_ENABLE(rebuilds,
 219               [AC_HELP_STRING([--disable-rebuilds],
 220                               [disable all source autogeneration rules])],,
 221               [enable_rebuilds=yes])
 222 AC_ARG_ENABLE(visibility,
 223               [AC_HELP_STRING([--disable-visibility],
 224                               [don't use ELF visibility attributes])],,
 225               [enable_visibility=yes])
 226
 227 if test "x$enable_threads" != "xyes"; then
 228   enable_threads=no
 229 fi
 230
 231 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 232 if test "x$enable_gc_friendly" = "xyes"; then
 233   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 234   AC_MSG_RESULT([yes])
 235 else
 236   AC_MSG_RESULT([no])
 237 fi
 238
 239 AC_MSG_CHECKING([whether to disable memory pools])
 240 if test "x$disable_mem_pools" = "xno"; then
 241   AC_MSG_RESULT([no])
 242 else
 243   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 244   AC_SUBST(DISABLE_MEM_POOLS)
 245   AC_MSG_RESULT([yes])
 246 fi
 247
 248 dnl Checks for programs.
 249 AC_PROG_CC
 250 AC_PROG_CPP
 251
 252 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 253 AC_CHECK_PROGS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 254 AC_LANG_SAVE
 255 AC_LANG_CPLUSPLUS
 256 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 257 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 258 AC_LANG_RESTORE
 259
 260 AM_PROG_CC_STDC
 261 AM_PROG_CC_C_O
 262 AC_PROG_INSTALL
 263
 264 AC_SYS_LARGEFILE
 265
 266 #
 267 # Find pkg-config
 268 #
 269 AC_PATH_PROG(PKG_CONFIG, [pkg-config], [no])
 270 if test x$PKG_CONFIG = xno ; then
 271   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
 272 fi
 273
 274 if $PKG_CONFIG --atleast-pkgconfig-version 0.16 ; then
 275   :
 276 else
 277   AC_MSG_ERROR([*** pkg-config too old; version 0.16 or better required.])
 278 fi
 279
 280 if test "x$enable_debug" = "xyes"; then
 281   if test x$cflags_set != xset ; then
 282       case " $CFLAGS " in
 283       *[[\ \    ]]-g[[\ \       ]]*) ;;
 284       *) CFLAGS="$CFLAGS -g" ;;
 285       esac
 286   fi
 287
 288   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 289 else
 290   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 291
 292   if test "x$enable_debug" = "xno"; then
 293     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 294   fi
 295 fi
 296
 297 if test "x$enable_visibility" = "xno"; then
 298   GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DDISABLE_VISIBILITY"
 299 fi
 300
 301 # Ensure MSVC-compatible struct packing convention is used when
 302 # compiling for Win32 with gcc.
 303 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 304 # gcc2 uses "-fnative-struct".
 305 if test x"$glib_native_win32" = xyes; then
 306   if test x"$GCC" = xyes; then
 307     msnative_struct=''
 308     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 309     if test -z "$ac_cv_prog_CC"; then
 310       our_gcc="$CC"
 311     else
 312       our_gcc="$ac_cv_prog_CC"
 313     fi
 314     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 315       2.)
 316         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 317           msnative_struct='-fnative-struct'
 318         fi
 319         ;;
 320       *)
 321         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 322           msnative_struct='-mms-bitfields'
 323         fi
 324         ;;
 325     esac
 326     if test x"$msnative_struct" = x ; then
 327       AC_MSG_RESULT([no way])
 328       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 329     else
 330       CFLAGS="$CFLAGS $msnative_struct"
 331       AC_MSG_RESULT([${msnative_struct}])
 332     fi
 333   fi
 334 fi
 335 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 336 AC_SUBST(GLIB_EXTRA_CFLAGS)
 337
 338 AC_EXEEXT
 339
 340 # define a MAINT-like variable REBUILD which is set if Perl
 341 # and awk are found, so autogenerated sources can be rebuilt
 342 AC_PROG_AWK
 343 AC_CHECK_PROGS(PERL, [perl5 perl])
 344 # We would like indent, but don't require it.
 345 AC_CHECK_PROG(INDENT, indent, indent)
 346 REBUILD=\#
 347 if test "x$enable_rebuilds" = "xyes" && \
 348      test -n "$PERL" && \
 349      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 350      test -n "$AWK" ; then
 351   REBUILD=
 352 fi
 353 AC_SUBST(REBUILD)
 354
 355 # Need full path to Perl for glib-mkenums
 356 #
 357 if test "x$PERL" != x ; then
 358   AC_PATH_PROG(PERL_PATH, [$PERL])
 359 fi
 360 if test "x$PERL_PATH" = x ; then
 361   PERL_PATH="/usr/bin/env perl"
 362 fi
 363 AC_SUBST(PERL_PATH)
 364
 365 # Need suitable python path for greport
 366 AM_PATH_PYTHON(2.4,,PYTHON="/usr/bin/env python2.4")
 367
 368
 369 dnl ***********************
 370 dnl *** Tests for iconv ***
 371 dnl ***********************
 372 dnl
 373 dnl We do this before the gettext checks, to avoid distortion
 374
 375 dnl On Windows we use a native implementation
 376
 377 if test x"$glib_native_win32" = xyes; then
 378   with_libiconv=native
 379 else
 380   AC_ARG_WITH(libiconv,
 381               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 382                               [use the libiconv library])],,
 383               [with_libiconv=maybe])
 384
 385   found_iconv=no
 386   case $with_libiconv in
 387     maybe)
 388       # Check in the C library first
 389       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 390       # Check if we have GNU libiconv
 391       if test $found_iconv = "no"; then
 392         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 393       fi
 394       # Check if we have a iconv in -liconv, possibly from vendor
 395       if test $found_iconv = "no"; then
 396         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 397       fi
 398       ;;
 399     no)
 400       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 401       ;;
 402     gnu|yes)
 403       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 404       ;;
 405     native)
 406       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 407       ;;
 408   esac
 409
 410   if test "x$found_iconv" = "xno" ; then
 411      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 412   fi
 413 fi
 414
 415 gl_GLIBC21
 416 AC_ARG_ENABLE(iconv-cache,
 417               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 418                               [cache iconv descriptors [default=auto]])],,
 419               [enable_iconv_cache=auto])
 420
 421 AC_MSG_CHECKING([Whether to cache iconv descriptors])
 422 case $enable_iconv_cache in
 423   auto)
 424     if test $ac_cv_gnu_library_2_1 = yes; then
 425       enable_iconv_cache=no
 426     else
 427       enable_iconv_cache=yes
 428     fi
 429   ;;
 430   yes|no)
 431   ;;
 432   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 433   ;;
 434 esac
 435
 436 if test $enable_iconv_cache = yes; then
 437    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 438 fi
 439
 440 AC_MSG_RESULT($enable_iconv_cache)
 441
 442
 443 dnl
 444 dnl gettext support
 445 dnl
 446
 447 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 448 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 449 GLIB_GNU_GETTEXT
 450
 451 if test "$gt_cv_have_gettext" != "yes" ; then
 452   AC_MSG_ERROR([
 453 *** You must have either have gettext support in your C library, or use the
 454 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 455 ])
 456 fi
 457
 458 LIBS="$INTLLIBS $LIBS"
 459
 460 GETTEXT_PACKAGE=glib20
 461 AC_SUBST(GETTEXT_PACKAGE)
 462 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 463   [Define the gettext package to be used])
 464
 465 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 466
 467 dnl
 468 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 469 dnl
 470
 471 if test x"$glib_native_win32" != xyes; then
 472   if test x$with_libiconv != xno ; then
 473     case " $INTLLIBS " in
 474     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 475     *) ICONV_LIBS="-liconv" ;;
 476     esac
 477   fi
 478 fi
 479 AC_SUBST(ICONV_LIBS)
 480
 481 case $with_libiconv in
 482   gnu)
 483     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 484     ;;
 485   native)
 486     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 487     ;;
 488 esac
 489
 490 dnl Initialize libtool
 491 AM_DISABLE_STATIC
 492 AC_LIBTOOL_WIN32_DLL
 493 AM_PROG_LIBTOOL
 494 dnl when using libtool 2.x create libtool early, because it's used in configure
 495 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 496
 497
 498 if test "x$GCC" = "xyes"; then
 499   case " $CFLAGS " in
 500   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 501   *) CFLAGS="$CFLAGS -Wall" ;;
 502   esac
 503 fi
 504
 505 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES"
 506
 507 if test "$glib_native_win32" = "yes"; then
 508   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 509     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 510   fi
 511   if test x$enable_static = xyes; then
 512     glib_win32_static_compilation=yes
 513     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 514 #define GOBJECT_STATIC_COMPILATION 1"
 515     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 516   fi
 517 fi
 518 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 519
 520 dnl
 521 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 522 dnl
 523 if test $cross_compiling != yes ; then
 524     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 525     glib_save_LIBS=$LIBS
 526     LIBS="$LIBS -lm"
 527     AC_TRY_RUN([#include <math.h>
 528                  int main (void) { return (log(1) != log(1.)); }],
 529          AC_MSG_RESULT(none needed),
 530          glib_save_CFLAGS=$CFLAGS
 531          CFLAGS="$CFLAGS -std1"
 532          AC_TRY_RUN([#include <math.h>
 533                      int main (void) { return (log(1) != log(1.)); }],
 534              AC_MSG_RESULT(-std1),
 535              AC_MSG_RESULT()
 536              CFLAGS=$glib_save_CFLAGS
 537              AC_MSG_WARN(
 538                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 539          )
 540     )
 541     LIBS=$glib_save_LIBS
 542 fi
 543
 544 dnl NeXTStep cc seems to need this
 545 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 546 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 547   AC_MSG_RESULT(none needed),
 548   glib_save_CFLAGS=$CFLAGS
 549   CFLAGS="$CFLAGS -posix"
 550   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 551     AC_MSG_RESULT(-posix),
 552     AC_MSG_RESULT()
 553     CFLAGS=$glib_save_CFLAGS
 554     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 555
 556 # Checks for header files.
 557 AC_HEADER_STDC
 558
 559 # Checks for library functions.
 560 AC_FUNC_VPRINTF
 561 AC_FUNC_ALLOCA
 562 AC_CHECK_FUNCS(mmap)
 563 AC_CHECK_FUNCS(posix_memalign)
 564 AC_CHECK_FUNCS(memalign)
 565 AC_CHECK_FUNCS(valloc)
 566 AC_CHECK_FUNCS(fsync)
 567
 568 AC_CHECK_FUNCS(atexit on_exit)
 569
 570 AC_CHECK_FUNCS(timegm gmtime_r)
 571
 572 AC_CHECK_SIZEOF(char)
 573 AC_CHECK_SIZEOF(short)
 574 AC_CHECK_SIZEOF(long)
 575 AC_CHECK_SIZEOF(int)
 576 AC_CHECK_SIZEOF(void *)
 577 AC_CHECK_SIZEOF(long long)
 578 AC_CHECK_SIZEOF(__int64)
 579
 580 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 581   :
 582 else
 583   AC_MSG_ERROR([
 584 *** GLib requires a 64 bit type. You might want to consider
 585 *** using the GNU C compiler.
 586 ])
 587 fi
 588
 589 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 590         # long long is a 64 bit integer.
 591         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 592         AC_CACHE_VAL(glib_cv_long_long_format,[
 593                 for format in ll q I64; do
 594                   AC_TRY_RUN([#include <stdio.h>
 595                         int main()
 596                         {
 597                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 598                           char buffer[1000];
 599                           sprintf (buffer, "%${format}u", a);
 600                           sscanf (buffer, "%${format}u", &b);
 601                           exit (b!=a);
 602                         }
 603                         ],
 604                         [glib_cv_long_long_format=${format}
 605                         break],
 606                         [],[:])
 607                 done])
 608         if test -n "$glib_cv_long_long_format"; then
 609           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 610           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 611           if test x"$glib_cv_long_long_format" = xI64; then
 612             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 613           fi
 614         else
 615           AC_MSG_RESULT(none)
 616         fi
 617 elif test x$ac_cv_sizeof___int64 = x8; then
 618         # __int64 is a 64 bit integer.
 619         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 620         # We know this is MSVCRT.DLL, and what the formats are
 621         glib_cv_long_long_format=I64
 622         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 623         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 624         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 625 fi
 626
 627 dnl long doubles were not used, and a portability problem
 628 dnl AC_C_LONG_DOUBLE
 629 AC_C_CONST
 630
 631 dnl ok, here we try to check whether the systems prototypes for
 632 dnl malloc and friends actually match the prototypes provided
 633 dnl by gmem.h (keep in sync). i currently only know how to check
 634 dnl this reliably with gcc (-Werror), improvements for other
 635 dnl compilers are apprechiated.
 636 SANE_MALLOC_PROTOS=no
 637 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 638 glib_save_CFLAGS=$CFLAGS
 639 if test "x$GCC" = "xyes"; then
 640   CFLAGS="$CFLAGS -Werror"
 641   AC_TRY_COMPILE([#include <stdlib.h>], [
 642     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 643     void* (*my_malloc_p)  (size_t)         = malloc;
 644     void  (*my_free_p)    (void*)          = free;
 645     void* (*my_realloc_p) (void*, size_t)  = realloc;
 646     my_calloc_p = 0;
 647     my_malloc_p = 0;
 648     my_free_p = 0;
 649     my_realloc_p = 0;
 650   ],
 651     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 652       [Define if you have correct malloc prototypes])
 653     SANE_MALLOC_PROTOS=yes)
 654 fi
 655 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 656 CFLAGS=$glib_save_CFLAGS
 657
 658 dnl
 659 dnl check in which direction the stack grows
 660 dnl
 661 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 662         AC_TRY_RUN([
 663         volatile int *a = 0, *b = 0;
 664         void foo (void);
 665         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 666         void foo (void) { volatile int x = 5; b = &x; }
 667         ],
 668         glib_cv_stack_grows=no
 669         ,
 670         glib_cv_stack_grows=yes
 671         ,)
 672 ])
 673
 674 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 675 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 676 dnl actually supported.
 677 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 678         AC_COMPILE_IFELSE([
 679         __inline int foo () { return 0; }
 680         int main () { return foo (); }
 681         ],
 682         glib_cv_has__inline=yes
 683         ,
 684         glib_cv_has__inline=no
 685         ,)
 686 ])
 687 case x$glib_cv_has__inline in
 688 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 689 esac
 690 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 691         AC_COMPILE_IFELSE([
 692         __inline__ int foo () { return 0; }
 693         int main () { return foo (); }
 694         ],
 695         glib_cv_has__inline__=yes
 696         ,
 697         glib_cv_has__inline__=no
 698         ,)
 699 ])
 700 case x$glib_cv_has__inline__ in
 701 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 702 esac
 703 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 704         AC_COMPILE_IFELSE([
 705         #undef inline
 706         inline int foo () { return 0; }
 707         int main () { return foo (); }
 708         ],
 709         glib_cv_hasinline=yes
 710         ,
 711         glib_cv_hasinline=no
 712         ,)
 713 ])
 714 case x$glib_cv_hasinline in
 715 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 716 esac
 717
 718 # if we can use inline functions in headers
 719 AC_MSG_CHECKING(if inline functions in headers work)
 720 AC_LINK_IFELSE([
 721 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 722 #  undef inline
 723 #  define inline __inline__
 724 #elif !defined (G_HAVE_INLINE)
 725 #  undef inline
 726 #  if defined (G_HAVE___INLINE__)
 727 #    define inline __inline__
 728 #  elif defined (G_HAVE___INLINE)
 729 #    define inline __inline
 730 #  endif
 731 #endif
 732
 733 int glib_test_func2 (int);
 734
 735 static inline int
 736 glib_test_func1 (void) {
 737   return glib_test_func2 (1);
 738 }
 739
 740 int
 741 main (void) {
 742   int i = 1;
 743 }],[g_can_inline=yes],[g_can_inline=no])
 744 AC_MSG_RESULT($g_can_inline)
 745
 746 dnl *** check for working do while(0) macros ***
 747 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 748         AC_TRY_COMPILE([],[
 749         #define STMT_START do
 750         #define STMT_END while(0)
 751         #define STMT_TEST STMT_START { i = 0; } STMT_END
 752         int main(void) { int i = 1; STMT_TEST; return i; }],
 753         [g_cv_support_dowhile_macros=yes],
 754         [g_cv_support_dowhile_macros=no],
 755         [g_cv_support_dowhile_macros=yes])
 756 ])
 757 if test x$g_cv_support_dowhile_macros = xyes; then
 758   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 759 fi
 760
 761 # check for flavours of varargs macros
 762 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 763 AC_TRY_COMPILE([],[
 764 int a(int p1, int p2, int p3);
 765 #define call_a(...) a(1,__VA_ARGS__)
 766 call_a(2,3);
 767 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 768 AC_MSG_RESULT($g_have_iso_c_varargs)
 769
 770 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 771 if test "$CXX" = ""; then
 772 dnl No C++ compiler
 773   g_have_iso_cxx_varargs=no
 774 else
 775   AC_LANG_CPLUSPLUS
 776   AC_TRY_COMPILE([],[
 777 int a(int p1, int p2, int p3);
 778 #define call_a(...) a(1,__VA_ARGS__)
 779 call_a(2,3);
 780 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 781   AC_LANG_C
 782 fi
 783 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 784
 785 AC_MSG_CHECKING(for GNUC varargs macros)
 786 AC_TRY_COMPILE([],[
 787 int a(int p1, int p2, int p3);
 788 #define call_a(params...) a(1,params)
 789 call_a(2,3);
 790 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 791 AC_MSG_RESULT($g_have_gnuc_varargs)
 792
 793 # check for GNUC visibility support
 794 AC_MSG_CHECKING(for GNUC visibility attribute)
 795 GLIB_CHECK_COMPILE_WARNINGS([
 796 void
 797 __attribute__ ((visibility ("hidden")))
 798      f_hidden (void)
 799 {
 800 }
 801 void
 802 __attribute__ ((visibility ("internal")))
 803      f_internal (void)
 804 {
 805 }
 806 void
 807 __attribute__ ((visibility ("protected")))
 808      f_protected (void)
 809 {
 810 }
 811 void
 812 __attribute__ ((visibility ("default")))
 813      f_default (void)
 814 {
 815 }
 816 int main (int argc, char **argv)
 817 {
 818         f_hidden();
 819         f_internal();
 820         f_protected();
 821         f_default();
 822         return 0;
 823 }
 824 ],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 825 AC_MSG_RESULT($g_have_gnuc_visibility)
 826 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 827
 828 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 829 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 830 #else
 831 # include "error: this is not Sun Studio."
 832 #endif
 833 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 834 AC_MSG_RESULT($g_have_sunstudio_visibility)
 835 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 836
 837 # check for bytesex stuff
 838 AC_C_BIGENDIAN
 839 if test x$ac_cv_c_bigendian = xuniversal ; then
 840 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 841 #else
 842 #error Not a big endian.
 843 #endif],
 844     ac_cv_c_bigendian=yes
 845     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 846 #else
 847 #error Not a little endian.
 848 #endif],
 849     ac_cv_c_bigendian=no
 850     ,AC_MSG_WARN([Could not determine endianness.])))
 851 fi
 852
 853
 854 # check for header files
 855 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 856 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 857 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h sched.h malloc.h])
 858 AC_CHECK_HEADERS([sys/vfs.h sys/mount.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 859 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h sys/sysctl.h fstab.h])
 860
 861 # check for structure fields
 862 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 863 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 864 #include <sys/stat.h>
 865 #include <unistd.h>
 866 #ifdef HAVE_SYS_STATFS_H
 867 #include <sys/statfs.h>
 868 #endif
 869 #ifdef HAVE_SYS_PARAM_H
 870 #include <sys/param.h>
 871 #endif
 872 #ifdef HAVE_SYS_MOUNT_H
 873 #include <sys/mount.h>
 874 #endif])
 875 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 876 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 877
 878 # Checks for libcharset
 879 AM_LANGINFO_CODESET
 880 gl_GLIBC21
 881 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 882 AC_CHECK_FUNCS(setlocale)
 883
 884 # check additional type sizes
 885 AC_CHECK_SIZEOF(size_t)
 886
 887 dnl Try to figure out whether gsize, gssize should be long or int
 888 AC_MSG_CHECKING([for the appropriate definition for size_t])
 889
 890 case $ac_cv_sizeof_size_t in
 891   $ac_cv_sizeof_short)
 892       glib_size_type=short
 893       ;;
 894   $ac_cv_sizeof_int)
 895       glib_size_type=int
 896       ;;
 897   $ac_cv_sizeof_long)
 898       glib_size_type=long
 899       ;;
 900   $ac_cv_sizeof_long_long)
 901       glib_size_type='long long'
 902       ;;
 903   $ac_cv_sizeof__int64)
 904       glib_size_type='__int64'
 905       ;;
 906   *)  AC_MSG_ERROR([No type matching size_t in size])
 907       ;;
 908 esac
 909
 910 dnl If int/long are the same size, we see which one produces
 911 dnl warnings when used in the location as size_t. (This matters
 912 dnl on AIX with xlc)
 913 dnl
 914 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 915    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 916   GLIB_CHECK_COMPILE_WARNINGS([
 917 #if defined(_AIX) && !defined(__GNUC__)
 918 #pragma options langlvl=stdc89
 919 #endif
 920 #include <stddef.h>
 921 int main ()
 922 {
 923   size_t s = 1;
 924   unsigned int *size_int = &s;
 925   return (int)*size_int;
 926 }
 927     ],glib_size_type=int,
 928       [GLIB_CHECK_COMPILE_WARNINGS([
 929 #if defined(_AIX) && !defined(__GNUC__)
 930 #pragma options langlvl=stdc89
 931 #endif
 932 #include <stddef.h>
 933 int main ()
 934 {
 935    size_t s = 1;
 936    unsigned long *size_long = &s;
 937    return (int)*size_long;
 938 }
 939         ],glib_size_type=long)])
 940 fi
 941
 942 AC_MSG_RESULT(unsigned $glib_size_type)
 943
 944 # Check for some functions
 945 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk)
 946 AC_CHECK_FUNCS(chown lchown fchmod fchown link statvfs statfs utimes getgrgid getpwuid)
 947 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getmntinfo)
 948 # Check for high-resolution sleep functions
 949 AC_CHECK_FUNCS(nanosleep nsleep)
 950
 951 AC_CHECK_HEADERS(crt_externs.h)
 952 AC_CHECK_FUNCS(_NSGetEnviron)
 953
 954 AC_FUNC_VSNPRINTF_C99
 955 AC_FUNC_PRINTF_UNIX98
 956
 957 # Internet address families
 958 if test $glib_native_win32 = yes; then
 959   glib_inet_includes=["
 960 #include <winsock2.h>
 961   "]
 962 else
 963   glib_inet_includes=["
 964 #include <sys/types.h>
 965 #include <sys/socket.h>
 966   "]
 967 fi
 968
 969 glib_failed=false
 970 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
 971 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
 972 # winsock defines this even though it doesn't support it
 973 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
 974 if $glib_failed ; then
 975   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
 976 fi
 977
 978 glib_failed=false
 979 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
 980 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
 981 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
 982 if $glib_failed ; then
 983   AC_MSG_ERROR([Could not determine values for MSG_* constants])
 984 fi
 985
 986 AC_CHECK_FUNCS(getprotobyname_r endservent)
 987 AC_CHECK_HEADERS([netdb.h winsock2.h mswsock.h])
 988
 989 # For gio/libasyncns
 990 if test $glib_native_win32 = no; then
 991   AC_CHECK_FUNCS(strndup setresuid setreuid)
 992   AC_CHECK_HEADERS(sys/prctl.h arpa/nameser_compat.h)
 993   AC_CHECK_FUNC(res_query, ,
 994     [AC_CHECK_LIB(resolv, res_query, [ LIBASYNCNS_LIBADD="-lresolv" ],
 995       [ save_libs="$LIBS"
 996         LIBS="-lresolv $LIBS"
 997         AC_MSG_CHECKING([for res_query in -lresolv (alternate version)])
 998         AC_LINK_IFELSE(
 999           [AC_LANG_PROGRAM([[#include <resolv.h>]], [[res_query(0,0,0,0,0)]])],
1000           [ AC_MSG_RESULT(yes)
1001           LIBASYNCNS_LIBADD="-lresolv" ],
1002           [ AC_MSG_RESULT(no)
1003             AC_CHECK_LIB(bind, res_query,
1004               [ LIBASYNCNS_LIBADD="-lbind" ],
1005             [ AC_MSG_ERROR(res_query not found) ] ) ] )
1006         LIBS="$save_libs"
1007       ] )
1008     ]
1009   )
1010   AC_SUBST(LIBASYNCNS_LIBADD)
1011 fi
1012
1013 case $host in
1014   *-*-solaris* )
1015      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1016      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1017      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1018      ;;
1019 esac
1020
1021 dnl
1022 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1023 dnl
1024 if test "$ac_cv_func_statfs" = yes ; then
1025   AC_MSG_CHECKING([number of arguments to statfs()])
1026   AC_TRY_COMPILE([#include <unistd.h>
1027   #ifdef HAVE_SYS_PARAM_H
1028   #include <sys/param.h>
1029   #endif
1030   #ifdef HAVE_SYS_VFS_H
1031   #include <sys/vfs.h>
1032   #endif
1033   #ifdef HAVE_SYS_MOUNT_H
1034   #include <sys/mount.h>
1035   #endif
1036   #ifdef HAVE_SYS_STATFS_H
1037   #include <sys/statfs.h>
1038   #endif], [struct statfs st;
1039   statfs(NULL, &st);],[
1040     AC_MSG_RESULT([2])
1041     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1042     AC_TRY_COMPILE([#include <unistd.h>
1043   #ifdef HAVE_SYS_PARAM_H
1044   #include <sys/param.h>
1045   #endif
1046   #ifdef HAVE_SYS_VFS_H
1047   #include <sys/vfs.h>
1048   #endif
1049   #ifdef HAVE_SYS_MOUNT_H
1050   #include <sys/mount.h>
1051   #endif
1052   #ifdef HAVE_SYS_STATFS_H
1053   #include <sys/statfs.h>
1054   #endif], [struct statfs st;
1055   statfs(NULL, &st, sizeof (st), 0);],[
1056       AC_MSG_RESULT([4])
1057       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1058       AC_MSG_RESULT(unknown)
1059       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1060 fi
1061
1062 #
1063 # Check whether to use an included printf
1064 #
1065
1066 AC_ARG_ENABLE(included-printf,
1067               [AC_HELP_STRING([--enable-included-printf],
1068                               [use included printf [default=auto]])],
1069               enable_included_printf="$enableval")
1070
1071 need_included_printf=no
1072 if test "x$enable_included_printf" = "xyes" ; then
1073   need_included_printf=yes
1074 fi
1075 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1076   need_included_printf=yes
1077 fi
1078 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1079   need_included_printf=yes
1080 fi
1081 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1082    test -z "$glib_cv_long_long_format" ; then
1083   need_included_printf=yes
1084 fi
1085
1086 if test "x$enable_included_printf" = "xno" &&
1087    test "x$need_included_printf" = "xyes" ; then
1088   AC_MSG_ERROR([
1089 *** Your C library's printf doesn't appear to have the features that
1090 *** GLib needs, but you specified --enable-included-printf=no.])
1091 fi
1092
1093 enable_included_printf=$need_included_printf
1094
1095 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1096 if test "$enable_included_printf" != "yes" ; then
1097   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1098 else
1099   if test -z "$glib_cv_long_long_format" ; then
1100     glib_cv_long_long_format="ll"
1101   fi
1102   AC_DEFINE(HAVE_VASPRINTF,1)
1103 fi
1104
1105 # Checks needed for gnulib vasnprintf
1106 bh_C_SIGNED
1107 jm_AC_TYPE_LONG_LONG
1108 gt_TYPE_LONGDOUBLE
1109 gt_TYPE_WCHAR_T
1110 gt_TYPE_WINT_T
1111 AC_TYPE_SIZE_T
1112 AC_CHECK_TYPES(ptrdiff_t)
1113 jm_AC_TYPE_INTMAX_T
1114 AC_CHECK_FUNCS([snprintf wcslen])
1115 AC_FUNC_SNPRINTF_C99
1116
1117 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1118 # The check is borrowed from the PERL Configure script.
1119 if test "$ac_cv_func_memmove" != "yes"; then
1120   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1121     glib_cv_working_bcopy,[AC_TRY_RUN([
1122       int main() {
1123         char buf[128], abc[128], *b;
1124         int len, off, align;
1125         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1126         for (align = 7; align >= 0; align--) {
1127           for (len = 36; len; len--) {
1128             b = buf+align; bcopy(abc, b, len);
1129             for (off = 1; off <= len; off++) {
1130               bcopy(b, b+off, len); bcopy(b+off, b, len);
1131                 if (bcmp(b, abc, len)) return(1);
1132             }
1133           }
1134         }
1135         return(0);
1136       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1137
1138   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1139   if test "$glib_cv_working_bcopy" = "yes"; then
1140     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1141   fi
1142 fi
1143
1144 # Check for sys_errlist
1145 AC_MSG_CHECKING(for sys_errlist)
1146 AC_TRY_LINK(, [
1147 extern char *sys_errlist[];
1148 extern int sys_nerr;
1149 sys_errlist[sys_nerr-1][0] = 0;
1150 ], glib_ok=yes, glib_ok=no)
1151 AC_MSG_RESULT($glib_ok)
1152 if test "$glib_ok" = "no"; then
1153     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
1154 fi
1155
1156 # Check for sys_siglist
1157 AC_MSG_CHECKING(for sys_siglist)
1158 AC_TRY_LINK(, [
1159 extern char *sys_siglist[];
1160 exit (sys_siglist[0]);
1161 ], glib_ok=yes, glib_ok=no)
1162 AC_MSG_RESULT($glib_ok)
1163 if test "$glib_ok" = "no"; then
1164     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
1165 fi
1166
1167 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
1168 AC_MSG_CHECKING(for sys_siglist declaration)
1169 AC_TRY_COMPILE([#include <signal.h>], [
1170 strlen (sys_siglist[0]);
1171 ], glib_ok=yes, glib_ok=no)
1172 AC_MSG_RESULT($glib_ok)
1173 if test "$glib_ok" = "no"; then
1174     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
1175 fi
1176
1177 # Check if <sys/select.h> needs to be included for fd_set
1178 AC_MSG_CHECKING([for fd_set])
1179 AC_TRY_COMPILE([#include <sys/types.h>],
1180         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1181 if test "$gtk_ok" = "yes"; then
1182     AC_MSG_RESULT([yes, found in sys/types.h])
1183 else
1184     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1185     if test "$gtk_ok" = "yes"; then
1186         # *** FIXME: give it a different name
1187         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1188         AC_MSG_RESULT([yes, found in sys/select.h])
1189     else
1190         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1191         AC_MSG_RESULT(no)
1192     fi
1193 fi
1194
1195 dnl *** check for sane realloc() ***
1196 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1197         AC_TRY_RUN([#include <stdlib.h>
1198         int main() {
1199           return realloc (0, sizeof (int)) == 0;
1200         }],
1201         [glib_cv_sane_realloc=yes],
1202         [glib_cv_sane_realloc=no],
1203         [glib_cv_sane_realloc=yes])
1204 ])
1205 if test x$glib_cv_sane_realloc = xyes; then
1206   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1207 fi
1208
1209 dnl Check for nl_langinfo and CODESET
1210 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1211         AC_TRY_COMPILE([#include <langinfo.h>],
1212                 [char *codeset = nl_langinfo (CODESET);],
1213                 [glib_cv_langinfo_codeset=yes],
1214                 [glib_cv_langinfo_codeset=no])])
1215 if test x$glib_cv_langinfo_codeset = xyes; then
1216   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1217 fi
1218
1219 dnl ****************************************
1220 dnl *** posix_memalign                   ***
1221 dnl ****************************************
1222 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1223 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1224     glib_cv_compliant_posix_memalign=0
1225     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1226         AC_TRY_RUN([
1227                 #define _XOPEN_SOURCE 600
1228                 #include <stdlib.h> /* posix_memalign() should be defined here */
1229                 /* some systems break if #include <malloc.h> used */
1230                 static void test_memalign (size_t boundary, size_t size) {
1231                     void *mem = 0;
1232                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1233                         exit (1);
1234                     else
1235                       free (mem);
1236                 }
1237                 int main() {
1238                     test_memalign (  128,   128 - 2 * sizeof (void*));
1239                     test_memalign (  256,   256 - 2 * sizeof (void*));
1240                     test_memalign (  512,   512 - 2 * sizeof (void*));
1241                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1242                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1243                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1244                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1245                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1246                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1247                     exit (0); /* success */
1248                 }
1249                 ],
1250             [glib_cv_compliant_posix_memalign=1], [], [:])
1251       :
1252     fi
1253     ])
1254 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1255     AC_MSG_RESULT(yes)
1256     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1257 else
1258     AC_MSG_RESULT(no)
1259 fi
1260
1261
1262 dnl ****************************************
1263 dnl *** strlcpy/strlcat                  ***
1264 dnl ****************************************
1265 # Check for strlcpy
1266 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1267 AC_TRY_RUN([#include <stdlib.h>
1268 #include <string.h>
1269 int main() {
1270   char p[10];
1271   (void) strlcpy (p, "hi", 10);
1272   if (strlcat (p, "bye", 0) != 3)
1273     return 1;
1274   return 0;
1275 }], glib_cv_have_strlcpy=yes,
1276     glib_cv_have_strlcpy=no,
1277     glib_cv_have_strlcpy=no)])
1278 if test "$glib_cv_have_strlcpy" = "yes"; then
1279     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1280 fi
1281
1282
1283 dnl **********************
1284 dnl *** va_copy checks ***
1285 dnl **********************
1286 dnl we currently check for all three va_copy possibilities, so we get
1287 dnl all results in config.log for bug reports.
1288 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1289         AC_LINK_IFELSE([#include <stdarg.h>
1290 #include <stdlib.h>
1291         void f (int i, ...) {
1292         va_list args1, args2;
1293         va_start (args1, i);
1294         va_copy (args2, args1);
1295         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1296           exit (1);
1297         va_end (args1); va_end (args2);
1298         }
1299         int main() {
1300           f (0, 42);
1301           return 0;
1302         }],
1303         [glib_cv_va_copy=yes],
1304         [glib_cv_va_copy=no])
1305 ])
1306 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1307         AC_LINK_IFELSE([#include <stdarg.h>
1308 #include <stdlib.h>
1309         void f (int i, ...) {
1310         va_list args1, args2;
1311         va_start (args1, i);
1312         __va_copy (args2, args1);
1313         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1314           exit (1);
1315         va_end (args1); va_end (args2);
1316         }
1317         int main() {
1318           f (0, 42);
1319           return 0;
1320         }],
1321         [glib_cv___va_copy=yes],
1322         [glib_cv___va_copy=no])
1323 ])
1324
1325 if test "x$glib_cv_va_copy" = "xyes"; then
1326   g_va_copy_func=va_copy
1327 else if test "x$glib_cv___va_copy" = "xyes"; then
1328   g_va_copy_func=__va_copy
1329 fi
1330 fi
1331
1332 if test -n "$g_va_copy_func"; then
1333   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1334 fi
1335
1336 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1337         AC_TRY_RUN([#include <stdarg.h>
1338 #include <stdlib.h>
1339         void f (int i, ...) {
1340         va_list args1, args2;
1341         va_start (args1, i);
1342         args2 = args1;
1343         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1344           exit (1);
1345         va_end (args1); va_end (args2);
1346         }
1347         int main() {
1348           f (0, 42);
1349           return 0;
1350         }],
1351         [glib_cv_va_val_copy=yes],
1352         [glib_cv_va_val_copy=no],
1353         [glib_cv_va_val_copy=yes])
1354 ])
1355
1356 if test "x$glib_cv_va_val_copy" = "xno"; then
1357   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1358 fi
1359
1360 dnl ***********************
1361 dnl *** g_module checks ***
1362 dnl ***********************
1363 G_MODULE_LIBS=
1364 G_MODULE_LIBS_EXTRA=
1365 G_MODULE_PLUGIN_LIBS=
1366 if test x"$glib_native_win32" = xyes; then
1367   dnl No use for this on Win32
1368   G_MODULE_LDFLAGS=
1369 else
1370   export SED
1371   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1372 fi
1373 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1374 G_MODULE_NEED_USCORE=0
1375 G_MODULE_BROKEN_RTLD_GLOBAL=0
1376 G_MODULE_HAVE_DLERROR=0
1377 dnl *** force native WIN32 shared lib loader
1378 if test -z "$G_MODULE_IMPL"; then
1379   case "$host" in
1380   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1381   esac
1382 fi
1383 dnl *** force native AIX library loader
1384 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1385 if test -z "$G_MODULE_IMPL"; then
1386   case "$host" in
1387   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1388   esac
1389 fi
1390 dnl *** dlopen() and dlsym() in system libraries
1391 if test -z "$G_MODULE_IMPL"; then
1392         AC_CHECK_FUNC(dlopen,
1393                       [AC_CHECK_FUNC(dlsym,
1394                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1395                       [])
1396 fi
1397 dnl *** load_image (BeOS)
1398 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1399   AC_CHECK_LIB(root, load_image,
1400       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1401       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1402       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1403       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1404       [])
1405 fi
1406 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1407 if test -z "$G_MODULE_IMPL"; then
1408         AC_CHECK_FUNC(NSLinkModule,
1409                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1410                        G_MODULE_NEED_USCORE=1],
1411                       [])
1412 fi
1413 dnl *** dlopen() and dlsym() in libdl
1414 if test -z "$G_MODULE_IMPL"; then
1415         AC_CHECK_LIB(dl, dlopen,
1416                      [AC_CHECK_LIB(dl, dlsym,
1417                                    [G_MODULE_LIBS=-ldl
1418                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1419                      [])
1420 fi
1421 dnl *** shl_load() in libdld (HP-UX)
1422 if test -z "$G_MODULE_IMPL"; then
1423         AC_CHECK_LIB(dld, shl_load,
1424                 [G_MODULE_LIBS=-ldld
1425                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1426                 [])
1427 fi
1428 dnl *** additional checks for G_MODULE_IMPL_DL
1429 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1430         LIBS_orig="$LIBS"
1431         LDFLAGS_orig="$LDFLAGS"
1432         LIBS="$G_MODULE_LIBS $LIBS"
1433         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1434 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1435         echo "void glib_plugin_test(void) { }" > plugin.c
1436         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1437                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1438         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1439                 glib_cv_rtldglobal_broken,[
1440                 AC_TRY_RUN([
1441 #include <dlfcn.h>
1442 #ifndef RTLD_GLOBAL
1443 #  define RTLD_GLOBAL 0
1444 #endif
1445 #ifndef RTLD_LAZY
1446 #  define RTLD_LAZY 0
1447 #endif
1448 int glib_plugin_test;
1449 int main () {
1450     void *handle, *global, *local;
1451     global = &glib_plugin_test;
1452     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1453     if (!handle) return 0;
1454     local = dlsym (handle, "glib_plugin_test");
1455     return global == local;
1456 }                       ],
1457                         [glib_cv_rtldglobal_broken=no],
1458                         [glib_cv_rtldglobal_broken=yes],
1459                         [glib_cv_rtldglobal_broken=no])
1460                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1461                 rmdir .libs 2>/dev/null
1462         ])
1463         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1464                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1465         else
1466                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1467         fi
1468 dnl *** check whether we need preceeding underscores
1469         AC_CACHE_CHECK([for preceeding underscore in symbols],
1470                 glib_cv_uscore,[
1471                 AC_TRY_RUN([#include <dlfcn.h>
1472                 int glib_underscore_test (void) { return 42; }
1473                 int main() {
1474                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1475                   handle = dlopen ((void*)0, 0);
1476                   if (handle) {
1477                     f1 = dlsym (handle, "glib_underscore_test");
1478                     f2 = dlsym (handle, "_glib_underscore_test");
1479                   } return (!f2 || f1);
1480                 }],
1481                         [glib_cv_uscore=yes],
1482                         [glib_cv_uscore=no],
1483                         [])
1484                 rm -f plugin.c plugin.$ac_objext plugin.lo
1485         ])
1486         GLIB_ASSERT_SET(glib_cv_uscore)
1487         if test "x$glib_cv_uscore" = "xyes"; then
1488                 G_MODULE_NEED_USCORE=1
1489         else
1490                 G_MODULE_NEED_USCORE=0
1491         fi
1492
1493         LDFLAGS="$LDFLAGS_orig"
1494 dnl *** check for having dlerror()
1495         AC_CHECK_FUNC(dlerror,
1496                 [G_MODULE_HAVE_DLERROR=1],
1497                 [G_MODULE_HAVE_DLERROR=0])
1498         LIBS="$LIBS_orig"
1499 fi
1500 dnl *** done, have we got an implementation?
1501 if test -z "$G_MODULE_IMPL"; then
1502         G_MODULE_IMPL=0
1503         G_MODULE_SUPPORTED=false
1504 else
1505         G_MODULE_SUPPORTED=true
1506 fi
1507
1508 AC_MSG_CHECKING(for the suffix of module shared libraries)
1509 export SED
1510 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1511 eval $shrext_cmds
1512 module=yes eval std_shrext=$shrext_cmds
1513 # chop the initial dot
1514 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1515 AC_MSG_RESULT(.$glib_gmodule_suffix)
1516 # any reason it may fail?
1517 if test "x$glib_gmodule_suffix" = x; then
1518         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1519 fi
1520
1521 AC_SUBST(G_MODULE_SUPPORTED)
1522 AC_SUBST(G_MODULE_IMPL)
1523 AC_SUBST(G_MODULE_LIBS)
1524 AC_SUBST(G_MODULE_LIBS_EXTRA)
1525 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1526 AC_SUBST(G_MODULE_LDFLAGS)
1527 AC_SUBST(G_MODULE_HAVE_DLERROR)
1528 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1529 AC_SUBST(G_MODULE_NEED_USCORE)
1530 AC_SUBST(GLIB_DEBUG_FLAGS)
1531
1532 dnl **********************
1533 dnl *** g_spawn checks ***
1534 dnl **********************
1535
1536 AC_MSG_CHECKING(for gspawn implementation)
1537 case "$host" in
1538   *-*-mingw*)
1539     GSPAWN=gspawn-win32.lo
1540     ;;
1541   *)
1542     GSPAWN=gspawn.lo
1543     ;;
1544 esac
1545 AC_MSG_RESULT($GSPAWN)
1546 AC_SUBST(GSPAWN)
1547
1548 dnl *************************
1549 dnl *** GIOChannel checks ***
1550 dnl *************************
1551
1552 AC_MSG_CHECKING(for GIOChannel implementation)
1553 case "$host" in
1554   *-*-mingw*)
1555     GIO=giowin32.lo
1556     ;;
1557   *)
1558     GIO=giounix.lo
1559     ;;
1560 esac
1561 AC_MSG_RESULT($GIO)
1562 AC_SUBST(GIO)
1563
1564 dnl *********************************
1565 dnl *** Directory for GIO modules ***
1566 dnl *********************************
1567
1568 AC_ARG_WITH(gio-module-dir,
1569            [AC_HELP_STRING([--with-gio-module-dir=PATH],
1570                            [Load gio modules from this directory [LIBDIR/gio/modules]])],
1571            [],
1572            [with_gio_module_dir='${libdir}/gio/modules'])
1573 GIO_MODULE_DIR=$with_gio_module_dir
1574 AC_SUBST(GIO_MODULE_DIR)
1575
1576 dnl **********************************
1577 dnl *** Check for libselinux (GIO) ***
1578 dnl **********************************
1579 AC_ARG_ENABLE(selinux, [  --disable-selinux       build without selinux support])
1580 msg_selinux=no
1581 SELINUX_LIBS=
1582 if test "x$enable_selinux" != "xno"; then
1583
1584  AC_CHECK_LIB(selinux, is_selinux_enabled,
1585    [AC_CHECK_HEADERS(selinux/selinux.h,
1586      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1587        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1588         SELINUX_LIBS="-lselinux"
1589         msg_selinux=yes])
1590      ])
1591    ])
1592 fi
1593 AC_SUBST(SELINUX_LIBS)
1594
1595 dnl *****************************
1596 dnl ** Check for inotify (GIO) **
1597 dnl *****************************
1598 inotify_support=no
1599 AC_CHECK_HEADERS([sys/inotify.h],
1600 [
1601         inotify_support=yes
1602 ])
1603
1604 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1605
1606 dnl *********************************
1607 dnl ** Check for Solaris FEN (GIO) **
1608 dnl *********************************
1609 fen_support=no
1610 AC_COMPILE_IFELSE([
1611 #include <port.h>
1612 #ifndef PORT_SOURCE_FILE
1613 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1614 #endif
1615 int main() { return 0; } ],
1616 [
1617         fen_support=yes
1618 ],)
1619
1620 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1621
1622 dnl ****************************
1623 dnl *** Checks for FAM (GIO) ***
1624 dnl ****************************
1625
1626 should_disable_fam=no
1627
1628 AC_ARG_ENABLE(fam, [  --disable-fam          build without enabling fam for file system monitoring],
1629                          [
1630                                 if test "x$enable_fam" = "xno"; then
1631                                         should_disable_fam=yes
1632                                         echo "Not building FAM support"
1633                                 fi
1634                          ]
1635                          )
1636 fam_support=no
1637 FAM_LIBS=
1638 if test "x$should_disable_fam" = "xno"; then
1639 AC_CHECK_LIB(fam, FAMOpen,
1640   [AC_CHECK_HEADERS(fam.h,
1641     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1642      AC_CHECK_LIB(fam, FAMNoExists,
1643                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1644      FAM_LIBS="-lfam"]
1645      fam_support=yes,
1646     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1647   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1648 AC_SUBST(FAM_LIBS)
1649 fi
1650 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1651
1652
1653 dnl *****************************
1654 dnl *** Check for xattr (GIO) ***
1655 dnl *****************************
1656 AC_ARG_ENABLE(xattr, [  --disable-xattr           build without xattr support])
1657 msg_xattr=no
1658 XATTR_LIBS=
1659 if test "x$enable_xattr" != "xno"; then
1660
1661 dnl either glibc or libattr can provide xattr support
1662
1663 dnl for both of them, we check for getxattr being in
1664 dnl the library and a valid xattr header.
1665
1666 dnl try glibc
1667  AC_CHECK_LIB(c, getxattr,
1668    [AC_CHECK_HEADERS(sys/xattr.h,
1669      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1670       msg_xattr=yes])
1671    ])
1672
1673   if test "x$msg_xattr" != "xyes"; then
1674 dnl   failure. try libattr
1675    AC_CHECK_LIB(attr, getxattr,
1676       [AC_CHECK_HEADERS(attr/xattr.h,
1677        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1678         XATTR_LIBS="-lattr"
1679         msg_xattr=yes])
1680       ])
1681   fi
1682
1683   if test "x$msg_xattr" = "xyes"; then
1684     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1685     AC_TRY_COMPILE([
1686       #include <stdio.h>
1687       #ifdef HAVE_SYS_TYPES_H
1688       #include <sys/types.h>
1689       #endif
1690       #ifdef HAVE_SYS_XATTR_H
1691       #include <sys/xattr.h>
1692       #elif HAVE_ATTR_XATTR_H
1693       #include <attr/xattr.h>
1694       #endif
1695     ],
1696     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1697     [
1698       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1699       AC_MSG_RESULT([yes])
1700     ],
1701     [AC_MSG_RESULT([no])]
1702     )
1703   fi
1704
1705 fi
1706 AC_SUBST(XATTR_LIBS)
1707
1708 dnl ****************************************
1709 dnl *** platform dependent source checks ***
1710 dnl ****************************************
1711
1712 AC_MSG_CHECKING(for platform-dependent source)
1713 case "$host" in
1714   *-*-cygwin*|*-*-mingw*)
1715     PLATFORMDEP=gwin32.lo
1716     ;;
1717   *)
1718     PLATFORMDEP=
1719     ;;
1720 esac
1721 AC_MSG_RESULT($PLATFORMDEP)
1722 AC_SUBST(PLATFORMDEP)
1723
1724 AC_MSG_CHECKING([whether to compile timeloop])
1725 case "$host" in
1726   *-*-cygwin*|*-*-mingw*|*-*-minix)
1727     enable_timeloop=no
1728     ;;
1729   *)
1730     enable_timeloop=yes
1731     ;;
1732 esac
1733 AC_MSG_RESULT($enable_timeloop)
1734 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1735
1736 AC_MSG_CHECKING([if building for some Win32 platform])
1737 case "$host" in
1738   *-*-mingw*|*-*-cygwin*)
1739     platform_win32=yes
1740     ;;
1741   *)
1742     platform_win32=no
1743     ;;
1744 esac
1745 AC_MSG_RESULT($platform_win32)
1746 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1747
1748 dnl ***********************
1749 dnl *** g_thread checks ***
1750 dnl ***********************
1751
1752 AC_ARG_WITH(threads,
1753            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/win32@:>@],
1754                            [specify a thread implementation to use])],
1755            [if test "x$with_threads" = x; then
1756                 want_threads=yes
1757             else
1758                 want_threads=$with_threads
1759             fi],
1760            [want_threads=yes])
1761 if test "x$enable_threads" = "xno"; then
1762         want_threads=no
1763 fi
1764
1765 dnl error and warning message
1766 dnl *************************
1767
1768 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1769                 computer. GLib will not have a default thread implementation."
1770
1771 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1772                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1773                 compilation now, but then your programs might not work.
1774                 Please provide information on how it is done on your system."
1775
1776 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1777                 "
1778
1779 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1780                 provide information on your thread implementation.
1781                 You can also run 'configure --disable-threads'
1782                 to compile without thread support."
1783
1784 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1785                 functions will not be MT-safe during their first call because
1786                 there is no working 'getpwuid_r' on your system."
1787
1788 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1789                 because there is no 'localtime_r' on your system."
1790
1791 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1792                 crude surrogate will be used. If you happen to know a
1793                 yield function for your system, please inform the GLib
1794                 developers."
1795
1796 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1797                 threads on your system. Thus threads can only have the default
1798                 priority. If you happen to know these main/max
1799                 priorities, please inform the GLib developers."
1800
1801 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1802                 linking threaded applications. As GLib cannot do that
1803                 automatically, you will get an linkg error everytime you are
1804                 not using the right compiler. In that case you have to relink
1805                 with the right compiler. Ususally just '_r' is appended
1806                 to the compiler name."
1807
1808 dnl determination of thread implementation
1809 dnl ***************************************
1810
1811 # have_threads=no   means no thread support
1812 # have_threads=none means no default thread implementation
1813
1814 have_threads=no
1815 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1816                                 || test "x$want_threads" = xdce; then
1817         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1818         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1819         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1820         glib_save_CPPFLAGS="$CPPFLAGS"
1821         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1822         if test "x$have_threads" = xno; then
1823                 AC_TRY_COMPILE([#include <pthread.h>],
1824                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1825                         have_threads=posix)
1826         fi
1827         if test "x$have_threads" = xno; then
1828                 AC_TRY_COMPILE([#include <pthread.h>],
1829                         [pthread_mutex_t m;
1830                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1831                         have_threads=dce)
1832         fi
1833         # Tru64Unix requires -pthread to find pthread.h. See #103020
1834         CPPFLAGS="$CPPFLAGS -pthread"
1835         if test "x$have_threads" = xno; then
1836         AC_TRY_COMPILE([#include <pthread.h>],
1837                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1838                        have_threads=posix)
1839         fi
1840         CPPFLAGS="$glib_save_CPPFLAGS"
1841 fi
1842 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1843         case $host in
1844                 *-*-mingw*)
1845                 have_threads=win32
1846                 ;;
1847         esac
1848 fi
1849 if test "x$want_threads" = xnone; then
1850         have_threads=none
1851 fi
1852
1853 AC_MSG_CHECKING(for thread implementation)
1854
1855 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1856         AC_MSG_RESULT(none available)
1857         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1858 else
1859         AC_MSG_RESULT($have_threads)
1860 fi
1861
1862
1863 dnl determination of G_THREAD_CFLAGS
1864 dnl ********************************
1865
1866 G_THREAD_LIBS=
1867 G_THREAD_LIBS_EXTRA=
1868 G_THREAD_CFLAGS=
1869
1870 dnl
1871 dnl Test program for basic POSIX threads functionality
1872 dnl
1873 m4_define([glib_thread_test],[
1874 #include <pthread.h>
1875 int check_me = 0;
1876 void* func(void* data) {check_me = 42; return &check_me;}
1877 int main()
1878  { pthread_t t;
1879    void *ret;
1880    pthread_create (&t, $1, func, 0);
1881    pthread_join (t, &ret);
1882    return (check_me != 42 || ret != &check_me);
1883 }])
1884
1885 dnl
1886 dnl Test program for sched_get_priority_min()
1887 dnl
1888 m4_define([glib_sched_priority_test],[
1889 #include <sched.h>
1890 #include <errno.h>
1891 int main() {
1892     errno = 0;
1893     return sched_get_priority_min(SCHED_OTHER)==-1
1894            && errno != 0;
1895 }])
1896
1897 if test x"$have_threads" != xno; then
1898
1899   if test x"$have_threads" = xposix; then
1900     # First we test for posix, whether -pthread or -pthreads do the trick as
1901     # both CPPFLAG and LIBS.
1902     # One of them does for most gcc versions and some other platforms/compilers
1903     # too and could be considered as the canonical way to go.
1904     case $host in
1905       *-*-cygwin*|*-*-darwin*)
1906          # skip cygwin and darwin -pthread or -pthreads test
1907          ;;
1908       *-solaris*)
1909         # These compiler/linker flags work with both Sun Studio and gcc
1910         # Sun Studio expands -mt to -D_REENTRANT and -lthread
1911         # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1912         G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1913         G_THREAD_LIBS="-lpthread -lthread"
1914         ;;
1915       *)
1916         for flag in pthread pthreads mt; do
1917           glib_save_CFLAGS="$CFLAGS"
1918           CFLAGS="$CFLAGS -$flag"
1919           AC_TRY_RUN(glib_thread_test(0),
1920                      glib_flag_works=yes,
1921                      glib_flag_works=no,
1922                      [AC_LINK_IFELSE(glib_thread_test(0),
1923                                      glib_flag_works=yes,
1924                                      glib_flag_works=no)])
1925           CFLAGS="$glib_save_CFLAGS"
1926           if test $glib_flag_works = yes ; then
1927              G_THREAD_CFLAGS=-$flag
1928              G_THREAD_LIBS=-$flag
1929              break;
1930           fi
1931         done
1932          ;;
1933     esac
1934   fi
1935
1936   if test x"$G_THREAD_CFLAGS" = x; then
1937
1938     # The canonical -pthread[s] does not work. Try something different.
1939
1940     case $host in
1941         *-aix*)
1942                 if test x"$GCC" = xyes; then
1943                         # GCC 3.0 and above needs -pthread.
1944                         # Should be coverd by the case above.
1945                         # GCC 2.x and below needs -mthreads
1946                         G_THREAD_CFLAGS="-mthreads"
1947                         G_THREAD_LIBS=$G_THREAD_CFLAGS
1948                 else
1949                         # We are probably using the aix compiler. Normaly a
1950                         # program would have to be compiled with the _r variant
1951                         # of the corresponding compiler, but we as GLib cannot
1952                         # do that: but the good news is that for compiling the
1953                         # only difference is the added -D_THREAD_SAFE compile
1954                         # option. This is according to the "C for AIX User's
1955                         # Guide".
1956                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
1957                 fi
1958                 ;;
1959         *-dg-dgux*)  # DG/UX
1960                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
1961                 ;;
1962         *-osf*)
1963                 # So we are using dce threads. posix threads are already
1964                 # catched above.
1965                 G_THREAD_CFLAGS="-threads"
1966                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1967                 ;;
1968         *-sysv5uw7*) # UnixWare 7
1969                 # We are not using gcc with -pthread. Catched above.
1970                 G_THREAD_CFLAGS="-Kthread"
1971                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1972                 ;;
1973         *-mingw*)
1974                 # No flag needed when using MSVCRT.DLL
1975                 G_THREAD_CFLAGS=""
1976                 ;;
1977         *)
1978                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1979                 ;;
1980     esac
1981
1982   fi
1983
1984     # if we are not finding the localtime_r function, then we probably are
1985     # not using the proper multithread flag
1986
1987     glib_save_CPPFLAGS="$CPPFLAGS"
1988     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1989
1990     # First we test, whether localtime_r is declared in time.h
1991     # directly. Then we test whether a macro localtime_r exists, in
1992     # which case localtime_r in the test program is replaced and thus
1993     # if we still find localtime_r in the output, it is not defined as
1994     # a macro.
1995
1996     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1997       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1998                                                            localtime_r(a,b)],
1999                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2000
2001     CPPFLAGS="$glib_save_CPPFLAGS"
2002
2003     AC_MSG_CHECKING(thread related cflags)
2004     AC_MSG_RESULT($G_THREAD_CFLAGS)
2005     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2006 fi
2007
2008 dnl determination of G_THREAD_LIBS
2009 dnl ******************************
2010
2011 mutex_has_default=no
2012 case $have_threads in
2013         posix|dce)
2014           glib_save_CPPFLAGS="$CPPFLAGS"
2015           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2016           if test x"$G_THREAD_LIBS" = x; then
2017             case $host in
2018               *-aix*)
2019                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2020                 # probably using the aix compiler.
2021                 AC_MSG_WARN($AIX_COMPILE_INFO)
2022                 ;;
2023               *)
2024                 G_THREAD_LIBS=error
2025                 glib_save_LIBS="$LIBS"
2026                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
2027                         if test x"$thread_lib" = x; then
2028                                 add_thread_lib=""
2029                                 IN=""
2030                         else
2031                                 add_thread_lib="-l$thread_lib"
2032                                 IN=" in -l$thread_lib"
2033                         fi
2034                         if test x"$have_threads" = xposix; then
2035                                 defattr=0
2036                         else
2037                                 defattr=pthread_attr_default
2038                         fi
2039
2040                         LIBS="$add_thread_lib $glib_save_LIBS"
2041
2042                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2043                         AC_TRY_RUN(glib_thread_test($defattr),
2044                                    glib_result=yes,
2045                                    glib_result=no,
2046                                    [AC_LINK_IFELSE(glib_thread_test($defattr),
2047                                                    glib_result=yes,
2048                                                    glib_result=no)])
2049                         AC_MSG_RESULT($glib_result)
2050
2051                         if test "$glib_result" = "yes" ; then
2052                           G_THREAD_LIBS="$add_thread_lib"
2053                           break
2054                         fi
2055                 done
2056                 if test "x$G_THREAD_LIBS" = xerror; then
2057                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2058                 fi
2059                 LIBS="$glib_save_LIBS"
2060                 ;;
2061             esac
2062           fi
2063
2064           glib_save_LIBS="$LIBS"
2065           for thread_lib in "" rt rte; do
2066             if test x"$thread_lib" = x; then
2067               add_thread_lib=""
2068               IN=""
2069             else
2070               add_thread_lib="-l$thread_lib"
2071               IN=" in -l$thread_lib"
2072             fi
2073             LIBS="$add_thread_lib $glib_save_LIBS"
2074
2075             AC_MSG_CHECKING(for sched_get_priority_min$IN)
2076             AC_TRY_RUN(glib_sched_priority_test,
2077                        glib_result=yes,
2078                        glib_result=no,
2079                        [AC_LINK_IFELSE(glib_sched_priority_test,
2080                                        glib_result=yes,
2081                                        glib_result=no)])
2082             AC_MSG_RESULT($glib_result)
2083
2084             if test "$glib_result" = "yes" ; then
2085                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
2086                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
2087                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
2088                break
2089             fi
2090           done
2091           LIBS="$glib_save_LIBS"
2092           mutex_has_default=yes
2093           mutex_default_type='pthread_mutex_t'
2094           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
2095           mutex_header_file='pthread.h'
2096           if test "x$have_threads" = "xposix"; then
2097             g_threads_impl="POSIX"
2098           else
2099             g_threads_impl="DCE"
2100             have_threads="posix"
2101           fi
2102           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2103           CPPFLAGS="$glib_save_CPPFLAGS"
2104           ;;
2105         win32)
2106            g_threads_impl="WIN32"
2107            ;;
2108         none|no)
2109            g_threads_impl="NONE"
2110            ;;
2111         *)
2112            g_threads_impl="NONE"
2113            G_THREAD_LIBS=error
2114            ;;
2115 esac
2116
2117 if test "x$G_THREAD_LIBS" = xerror; then
2118         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2119 fi
2120
2121 case $host in
2122   *-*-beos*)
2123     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2124     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2125     ;;
2126   *)
2127     ;;
2128 esac
2129
2130 AC_MSG_CHECKING(thread related libraries)
2131 AC_MSG_RESULT($G_THREAD_LIBS)
2132
2133 dnl check for mt safe function variants and some posix functions
2134 dnl ************************************************************
2135
2136 if test x"$have_threads" != xno; then
2137         glib_save_LIBS="$LIBS"
2138         # we are not doing the following for now, as this might require glib
2139         # to always be linked with the thread libs on some platforms.
2140         # LIBS="$LIBS $G_THREAD_LIBS"
2141         AC_CHECK_FUNCS(localtime_r gmtime_r)
2142         if test "$ac_cv_header_pwd_h" = "yes"; then
2143                 AC_CACHE_CHECK([for posix getpwuid_r],
2144                         ac_cv_func_posix_getpwuid_r,
2145                         [AC_TRY_RUN([
2146 #include <errno.h>
2147 #include <pwd.h>
2148 int main () {
2149     char buffer[10000];
2150     struct passwd pwd, *pwptr = &pwd;
2151     int error;
2152     errno = 0;
2153     error = getpwuid_r (0, &pwd, buffer,
2154                         sizeof (buffer), &pwptr);
2155    return (error < 0 && errno == ENOSYS)
2156            || error == ENOSYS;
2157 }                               ],
2158                                 [ac_cv_func_posix_getpwuid_r=yes],
2159                                 [ac_cv_func_posix_getpwuid_r=no])])
2160                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2161                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2162                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2163                                 [Have POSIX function getpwuid_r])
2164                 else
2165                         AC_CACHE_CHECK([for nonposix getpwuid_r],
2166                                 ac_cv_func_nonposix_getpwuid_r,
2167                                 [AC_TRY_LINK([#include <pwd.h>],
2168                                         [char buffer[10000];
2169                                         struct passwd pwd;
2170                                         getpwuid_r (0, &pwd, buffer,
2171                                                         sizeof (buffer));],
2172                                         [ac_cv_func_nonposix_getpwuid_r=yes],
2173                                         [ac_cv_func_nonposix_getpwuid_r=no])])
2174                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2175                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2176                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2177                                         [Have non-POSIX function getpwuid_r])
2178                         fi
2179                 fi
2180         fi
2181         if test "$ac_cv_header_grp_h" = "yes"; then
2182                 AC_CACHE_CHECK([for posix getgrgid_r],
2183                         ac_cv_func_posix_getgrgid_r,
2184                         [AC_TRY_RUN([
2185 #include <errno.h>
2186 #include <grp.h>
2187 int main () {
2188     char buffer[10000];
2189     struct group grp, *grpptr = &grp;
2190     int error;
2191     errno = 0;
2192     error = getgrgid_r (0, &grp, buffer,
2193                         sizeof (buffer), &grpptr);
2194    return (error < 0 && errno == ENOSYS)
2195            || error == ENOSYS;
2196 }                              ],
2197                                [ac_cv_func_posix_getgrgid_r=yes],
2198                                [ac_cv_func_posix_getgrgid_r=no])])
2199                 GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2200                 if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2201                         AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2202                                 [Have POSIX function getgrgid_r])
2203                 else
2204                         AC_CACHE_CHECK([for nonposix getgrgid_r],
2205                                 ac_cv_func_nonposix_getgrgid_r,
2206                                 [AC_TRY_LINK([#include <grp.h>],
2207                                         [char buffer[10000];
2208                                         struct group grp;
2209                                         getgrgid_r (0, &grp, buffer,
2210                                         sizeof (buffer));],
2211                                 [ac_cv_func_nonposix_getgrgid_r=yes],
2212                                 [ac_cv_func_nonposix_getgrgid_r=no])])
2213                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2214                         if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2215                                 AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2216                                         [Have non-POSIX function getgrgid_r])
2217                         fi
2218                 fi
2219         fi
2220         LIBS="$G_THREAD_LIBS $LIBS"
2221         if test x"$have_threads" = xposix; then
2222                 glib_save_CPPFLAGS="$CPPFLAGS"
2223                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2224                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
2225                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
2226                 # This is not AC_CHECK_FUNC to also work with function
2227                 # name mangling in header files.
2228                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2229                 AC_TRY_LINK([#include <pthread.h>],
2230                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2231                         [AC_MSG_RESULT(yes)
2232                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2233                                   [Have function pthread_attr_setstacksize])],
2234                         [AC_MSG_RESULT(no)])
2235                 AC_MSG_CHECKING(for minimal/maximal thread priority)
2236                 if test x"$posix_priority_min" = x; then
2237                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
2238                                 PX_PRIO_MIN],,[
2239                                 posix_priority_min=PX_PRIO_MIN
2240                                 posix_priority_max=PX_PRIO_MAX])
2241                 fi
2242                 if test x"$posix_priority_min" = x; then
2243                         # AIX
2244                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
2245                                 PTHREAD_PRIO_MIN],,[
2246                                 posix_priority_min=PTHREAD_PRIO_MIN
2247                                 posix_priority_max=PTHREAD_PRIO_MAX])
2248                 fi
2249                 if test x"$posix_priority_min" = x; then
2250                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
2251                                 PRI_OTHER_MIN],,[
2252                                 posix_priority_min=PRI_OTHER_MIN
2253                                 posix_priority_max=PRI_OTHER_MAX])
2254                 fi
2255                 if test x"$posix_priority_min" = x; then
2256                         AC_MSG_RESULT(none found)
2257                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
2258                         posix_priority_min=-1
2259                         posix_priority_max=-1
2260                 else
2261                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
2262                         AC_MSG_CHECKING(for pthread_setschedparam)
2263                         AC_TRY_LINK([#include <pthread.h>],
2264                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
2265                           [AC_MSG_RESULT(yes)
2266                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
2267                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
2268                           [AC_MSG_RESULT(no)
2269                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
2270                 fi
2271                 posix_yield_func=none
2272                 AC_MSG_CHECKING(for posix yield function)
2273                 for yield_func in sched_yield pthread_yield_np pthread_yield \
2274                                                         thr_yield; do
2275                         AC_TRY_LINK([#include <pthread.h>],
2276                                 [$yield_func()],
2277                                 [posix_yield_func="$yield_func"
2278                                 break])
2279                 done
2280                 if test x"$posix_yield_func" = xnone; then
2281                         AC_MSG_RESULT(none found)
2282                         AC_MSG_WARN($POSIX_NO_YIELD)
2283                         posix_yield_func="g_usleep(1000)"
2284                 else
2285                         AC_MSG_RESULT($posix_yield_func)
2286                         posix_yield_func="$posix_yield_func()"
2287                 fi
2288                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
2289                 CPPFLAGS="$glib_save_CPPFLAGS"
2290
2291         elif test x"$have_threads" = xwin32; then
2292                 # It's a pointer to a private struct
2293                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
2294         fi
2295
2296         LIBS="$glib_save_LIBS"
2297
2298         # now spit out all the warnings.
2299         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2300            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2301                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2302         fi
2303         if test "$ac_cv_func_localtime_r" != "yes"; then
2304                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2305         fi
2306 fi
2307
2308 if test x"$glib_cv_sizeof_system_thread" = x; then
2309    # use a pointer as a fallback.
2310    GLIB_SIZEOF(,void *, system_thread)
2311 fi
2312
2313 #
2314 # Hack to deal with:
2315 #
2316 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2317 #     building shared libraries with linux.
2318 #  b) FreeBSD doesn't do this either.
2319 #
2320 case $host in
2321   *-*-freebsd*|*-*-linux*)
2322     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2323     ;;
2324   *)
2325     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2326     ;;
2327 esac
2328
2329 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
2330                    [Source file containing theread implementation])
2331 AC_SUBST(G_THREAD_CFLAGS)
2332 AC_SUBST(G_THREAD_LIBS)
2333 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2334 AC_SUBST(G_THREAD_LIBS_EXTRA)
2335
2336 dnl **********************************************
2337 dnl *** GDefaultMutex setup and initialization ***
2338 dnl **********************************************
2339 dnl
2340 dnl if mutex_has_default = yes, we also got
2341 dnl mutex_default_type, mutex_default_init and mutex_header_file
2342 if test $mutex_has_default = yes ; then
2343         glib_save_CPPFLAGS="$CPPFLAGS"
2344         glib_save_LIBS="$LIBS"
2345         LIBS="$G_THREAD_LIBS $LIBS"
2346         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2347         GLIB_SIZEOF([#include <$mutex_header_file>],
2348                     $mutex_default_type,
2349                     gmutex)
2350         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
2351                            $mutex_default_type,
2352                            gmutex,
2353                            $glib_cv_sizeof_gmutex,
2354                            $mutex_default_init)
2355         if test x"$glib_cv_byte_contents_gmutex" = xno; then
2356                 mutex_has_default=no
2357         fi
2358         CPPFLAGS="$glib_save_CPPFLAGS"
2359         LIBS="$glib_save_LIBS"
2360 fi
2361
2362 AC_CHECK_FUNCS(clock_gettime, [], [
2363   AC_CHECK_LIB(rt, clock_gettime, [
2364     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2365     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2366     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2367   ])
2368 ])
2369
2370 AC_CACHE_CHECK(for monotonic clocks,
2371     glib_cv_monotonic_clock,AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
2372 #include <time.h>
2373 #include <unistd.h>
2374 int main() {
2375 #if !(defined(_POSIX_MONOTONIC_CLOCK) && _POSIX_MONOTONIC_CLOCK >= 0 && defined(CLOCK_MONOTONIC))
2376         #error No monotonic clock
2377 #endif
2378         return 0;
2379 }
2380 ]])],glib_cv_monotonic_clock=yes,glib_cv_monotonic_clock=no))
2381 if test "$glib_cv_monotonic_clock" = "yes"; then
2382   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
2383 fi
2384
2385
2386 dnl ********************************
2387 dnl *** g_atomic_* tests for gcc ***
2388 dnl ********************************
2389
2390 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
2391
2392 if test x"$GCC" = xyes; then
2393   case $host_cpu in
2394     i386)
2395       AC_MSG_RESULT([none])
2396       glib_memory_barrier_needed=no
2397       ;;
2398     i?86)
2399       AC_MSG_RESULT([i486])
2400       AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
2401                          [i486 atomic implementation])
2402       glib_memory_barrier_needed=no
2403       ;;
2404     sparc*)
2405       SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
2406                 when you are using a sparc with v9 instruction set (most
2407                 sparcs nowadays). This will make the code for atomic
2408                 operations much faster. The resulting code will not run
2409                 on very old sparcs though."
2410
2411       AC_LINK_IFELSE([[
2412         main ()
2413         {
2414           int tmp1, tmp2, tmp3;
2415           __asm__ __volatile__("casx [%2], %0, %1"
2416                                : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
2417         }]],
2418         AC_MSG_RESULT([sparcv9])
2419         AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
2420                            [sparcv9 atomic implementation]),
2421         AC_MSG_RESULT([no])
2422         AC_MSG_WARN([[$SPARCV9_WARNING]]))
2423       glib_memory_barrier_needed=yes
2424       ;;
2425     alpha*)
2426       AC_MSG_RESULT([alpha])
2427       AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
2428                          [alpha atomic implementation])
2429       glib_memory_barrier_needed=yes
2430       ;;
2431     x86_64)
2432       AC_MSG_RESULT([x86_64])
2433       AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
2434                          [x86_64 atomic implementation])
2435       glib_memory_barrier_needed=no
2436      ;;
2437     powerpc*)
2438       AC_MSG_RESULT([powerpc])
2439       AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
2440                          [powerpc atomic implementation])
2441       glib_memory_barrier_needed=yes
2442       AC_MSG_CHECKING([whether asm supports numbered local labels])
2443       AC_TRY_COMPILE(
2444                 ,[
2445                         __asm__ __volatile__ ("1:       nop\n"
2446                                               "         bne-    1b")
2447                 ],[
2448                         AC_DEFINE_UNQUOTED(ASM_NUMERIC_LABELS, 1, [define if asm blocks can use numeric local labels])
2449                         AC_MSG_RESULT([yes])
2450                 ],[
2451                         AC_MSG_RESULT([no])
2452                 ])
2453       ;;
2454     ia64)
2455       AC_MSG_RESULT([ia64])
2456       AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
2457                          [ia64 atomic implementation])
2458       glib_memory_barrier_needed=yes
2459       ;;
2460     s390|s390x)
2461       AC_MSG_RESULT([s390])
2462       AC_DEFINE_UNQUOTED(G_ATOMIC_S390, 1,
2463                          [s390 atomic implementation])
2464       glib_memory_barrier_needed=no
2465       ;;
2466     arm*)
2467       AC_MSG_RESULT([arm])
2468       AC_DEFINE_UNQUOTED(G_ATOMIC_ARM, 1,
2469                          [arm atomic implementation])
2470       glib_memory_barrier_needed=no
2471       ;;
2472     crisv32*|etraxfs*)
2473       AC_MSG_RESULT([crisv32])
2474       AC_DEFINE_UNQUOTED(G_ATOMIC_CRISV32, 1,
2475                          [crisv32 atomic implementation])
2476       glib_memory_barrier_needed=no
2477       ;;
2478     cris*|etrax*)
2479       AC_MSG_RESULT([cris])
2480       AC_DEFINE_UNQUOTED(G_ATOMIC_CRIS, 1,
2481                          [cris atomic implementation])
2482       glib_memory_barrier_needed=no
2483       ;;
2484     *)
2485       AC_MSG_RESULT([none])
2486       glib_memory_barrier_needed=yes
2487       ;;
2488   esac
2489 else
2490   if test $glib_native_win32 = yes; then
2491     # For Windows but not using gcc. No barriers needed then either.
2492     glib_memory_barrier_needed=no
2493   fi
2494 fi
2495
2496 dnl ****************************************
2497 dnl *** GLib POLL* compatibility defines ***
2498 dnl ****************************************
2499
2500 glib_poll_includes=["
2501 #include <sys/types.h>
2502 #include <sys/poll.h>
2503 "]
2504
2505 if test $ac_cv_header_sys_types_h = yes &&
2506    test $ac_cv_header_sys_poll_h = yes ; then
2507   glib_failed=false
2508   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2509   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2510   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2511   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2512   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2513   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2514   if $glib_failed ; then
2515     AC_MSG_ERROR([Could not determine values for POLL* constants])
2516   fi
2517 else
2518   glib_cv_value_POLLIN=1
2519   glib_cv_value_POLLOUT=4
2520   glib_cv_value_POLLPRI=2
2521   glib_cv_value_POLLERR=8
2522   glib_cv_value_POLLHUP=16
2523   glib_cv_value_POLLNVAL=32
2524 fi
2525
2526 AC_MSG_CHECKING([for broken poll])
2527 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2528         #include <stdlib.h>
2529         #include <fcntl.h>
2530         #include <poll.h>
2531         #ifdef HAVE_SYS_POLL_H
2532         #include <sys/poll.h>
2533         #endif
2534         int main(void) {
2535           struct pollfd fds[1];
2536           int fd;
2537           fd = open("/dev/null", 1);
2538           fds[0].fd = fd;
2539           fds[0].events = POLLIN;
2540           fds[0].revents = 0;
2541           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2542                 exit(1);  /* Does not work for devices -- fail */
2543           }
2544           exit(0);
2545         }]])],
2546   [broken_poll=no],
2547   [broken_poll=yes
2548    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2549   [broken_poll="no (cross compiling)"])
2550 AC_MSG_RESULT($broken_poll)
2551
2552 dnl *********************
2553 dnl *** GRegex checks ***
2554 dnl *********************
2555 PCRE_REQUIRED_VERSION=7.2
2556
2557 # Check if we should compile GRegex
2558 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2559               [disable the compilation of GRegex]),
2560 [case "${enableval}" in
2561   yes) enable_regex=true ;;
2562   no)  enable_regex=false ;;
2563   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2564 esac],
2565 [enable_regex=true])
2566
2567 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2568
2569 if test x$enable_regex = xtrue; then
2570   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2571   # Check if we should use the internal or the system-supplied pcre
2572   AC_ARG_WITH(pcre,
2573              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2574                              [specify whether to use the internal or the
2575                               system-supplied PCRE library])])
2576
2577   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2578
2579   if test "x$with_pcre" = xsystem; then
2580     PKG_CHECK_MODULES(PCRE,
2581                       libpcre >= $PCRE_REQUIRED_VERSION)
2582     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2583                    glib_save_CFLAGS="$CFLAGS"
2584                    glib_save_LIBS="$LIBS"
2585                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2586                    AC_TRY_RUN([#include <pcre.h>
2587                                int main () {
2588                                  int support;
2589                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2590                                  if (!support)
2591                                    return 1;
2592                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2593                                  if (!support)
2594                                    return 1;
2595                                  return 0;
2596                                }],
2597                    glib_cv_pcre_has_unicode=yes,
2598                    glib_cv_pcre_has_unicode=no,
2599                    glib_cv_pcre_has_unicode=yes)
2600                    CFLAGS="$glib_save_CFLAGS"
2601                    LIBS="$glib_save_LIBS"
2602         ])
2603     if test "$glib_cv_pcre_has_unicode" = "no"; then
2604       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2605     fi
2606     AC_SUBST(PCRE_CFLAGS)
2607     AC_SUBST(PCRE_LIBS)
2608     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2609     PCRE_REQUIRES=libpcre
2610     AC_SUBST(PCRE_REQUIRES)
2611   else
2612     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2613     if test x"$GCC" = xyes; then
2614       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2615       save_CFLAGS="$CFLAGS"
2616       CFLAGS="$CFLAGS -Wno-pointer-sign"
2617       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2618                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2619       CFLAGS="$save_CFLAGS"
2620     fi
2621   fi
2622   AC_SUBST(PCRE_WARN_CFLAGS)
2623 else
2624   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2625 fi
2626
2627 dnl **********************
2628 dnl *** Win32 API libs ***
2629 dnl **********************
2630
2631 case $host in
2632   *-*-cygwin*)
2633         G_LIBS_EXTRA="-luser32 -lkernel32"
2634     ;;
2635   *-*-mingw*)
2636         G_LIBS_EXTRA="-lws2_32 -lole32"
2637     ;;
2638   *)
2639         G_LIBS_EXTRA=""
2640     ;;
2641 esac
2642 AC_SUBST(G_LIBS_EXTRA)
2643
2644 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2645 dnl since we need it for g_iconv()
2646
2647 AC_MSG_CHECKING([for EILSEQ])
2648 AC_TRY_COMPILE([
2649 #include <errno.h>
2650 ],
2651 [
2652 int error = EILSEQ;
2653 ], have_eilseq=yes, have_eilseq=no);
2654 AC_MSG_RESULT($have_eilseq)
2655
2656 dnl ******************************************************************
2657 dnl *** Look for glib-genmarshal in PATH if we are cross-compiling ***
2658 dnl ******************************************************************
2659
2660 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2661
2662 if test $cross_compiling = yes; then
2663   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2664   if test x$GLIB_GENMARSHAL = xno; then
2665     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2666   fi
2667 fi
2668
2669 dnl **************************
2670 dnl *** Checks for gtk-doc ***
2671 dnl **************************
2672
2673 GTK_DOC_CHECK([1.11])
2674
2675 AC_ARG_ENABLE(man,
2676               [AC_HELP_STRING([--enable-man],
2677                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2678               enable_man=no)
2679
2680 if test "${enable_man}" != no; then
2681 dnl
2682 dnl Check for xsltproc
2683 dnl
2684 AC_PATH_PROG([XSLTPROC], [xsltproc])
2685   if test -z "$XSLTPROC"; then
2686     enable_man=no
2687   fi
2688
2689   dnl check for DocBook DTD and stylesheets in the local catalog.
2690   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2691      [DocBook XML DTD V4.1.2],,enable_man=no)
2692   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2693      [DocBook XSL Stylesheets],,enable_man=no)
2694 fi
2695
2696 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2697
2698 dnl ******************************
2699 dnl *** output the whole stuff ***
2700 dnl ******************************
2701
2702 dnl this section will only be run if config.status is invoked with no
2703 dnl arguments, or with "glibconfig.h" as an argument.
2704 AC_CONFIG_COMMANDS([glibconfig.h],
2705 [
2706         outfile=glibconfig.h-tmp
2707         cat > $outfile <<\_______EOF
2708 /* glibconfig.h
2709  *
2710  * This is a generated file.  Please modify 'configure.in'
2711  */
2712
2713 #ifndef __G_LIBCONFIG_H__
2714 #define __G_LIBCONFIG_H__
2715
2716 #include <glib/gmacros.h>
2717
2718 _______EOF
2719
2720         if test x$glib_limits_h = xyes; then
2721           echo '#include <limits.h>' >> $outfile
2722         fi
2723         if test x$glib_float_h = xyes; then
2724           echo '#include <float.h>' >> $outfile
2725         fi
2726         if test x$glib_values_h = xyes; then
2727           echo '#include <values.h>' >> $outfile
2728         fi
2729         if test "$glib_header_alloca_h" = "yes"; then
2730           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2731         fi
2732         if test x$glib_sys_poll_h = xyes; then
2733           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2734         fi
2735         if test x$glib_included_printf != xyes; then
2736           echo "
2737 /* Specifies that GLib's g_print*() functions wrap the
2738  * system printf functions.  This is useful to know, for example,
2739  * when using glibc's register_printf_function().
2740  */" >> $outfile
2741           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2742         fi
2743
2744         cat >> $outfile <<_______EOF
2745
2746 G_BEGIN_DECLS
2747
2748 #define G_MINFLOAT      $glib_mf
2749 #define G_MAXFLOAT      $glib_Mf
2750 #define G_MINDOUBLE     $glib_md
2751 #define G_MAXDOUBLE     $glib_Md
2752 #define G_MINSHORT      $glib_ms
2753 #define G_MAXSHORT      $glib_Ms
2754 #define G_MAXUSHORT     $glib_Mus
2755 #define G_MININT        $glib_mi
2756 #define G_MAXINT        $glib_Mi
2757 #define G_MAXUINT       $glib_Mui
2758 #define G_MINLONG       $glib_ml
2759 #define G_MAXLONG       $glib_Ml
2760 #define G_MAXULONG      $glib_Mul
2761
2762 _______EOF
2763
2764
2765         ### this should always be true in a modern C/C++ compiler
2766         cat >>$outfile <<_______EOF
2767 typedef signed char gint8;
2768 typedef unsigned char guint8;
2769 _______EOF
2770
2771
2772         if test -n "$gint16"; then
2773           cat >>$outfile <<_______EOF
2774 typedef signed $gint16 gint16;
2775 typedef unsigned $gint16 guint16;
2776 #define G_GINT16_MODIFIER $gint16_modifier
2777 #define G_GINT16_FORMAT $gint16_format
2778 #define G_GUINT16_FORMAT $guint16_format
2779 _______EOF
2780         fi
2781
2782
2783         if test -n "$gint32"; then
2784           cat >>$outfile <<_______EOF
2785 typedef signed $gint32 gint32;
2786 typedef unsigned $gint32 guint32;
2787 #define G_GINT32_MODIFIER $gint32_modifier
2788 #define G_GINT32_FORMAT $gint32_format
2789 #define G_GUINT32_FORMAT $guint32_format
2790 _______EOF
2791         fi
2792
2793         cat >>$outfile <<_______EOF
2794 #define G_HAVE_GINT64 1          /* deprecated, always true */
2795
2796 ${glib_extension}typedef signed $gint64 gint64;
2797 ${glib_extension}typedef unsigned $gint64 guint64;
2798
2799 #define G_GINT64_CONSTANT(val)  $gint64_constant
2800 #define G_GUINT64_CONSTANT(val) $guint64_constant
2801 _______EOF
2802
2803         if test x$gint64_format != x ; then
2804           cat >>$outfile <<_______EOF
2805 #define G_GINT64_MODIFIER $gint64_modifier
2806 #define G_GINT64_FORMAT $gint64_format
2807 #define G_GUINT64_FORMAT $guint64_format
2808 _______EOF
2809         else
2810           cat >>$outfile <<_______EOF
2811 #undef G_GINT64_MODIFIER
2812 #undef G_GINT64_FORMAT
2813 #undef G_GUINT64_FORMAT
2814 _______EOF
2815         fi
2816
2817         cat >>$outfile <<_______EOF
2818
2819 #define GLIB_SIZEOF_VOID_P $glib_void_p
2820 #define GLIB_SIZEOF_LONG   $glib_long
2821 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2822
2823 _______EOF
2824
2825         cat >>$outfile <<_______EOF
2826 typedef signed $glib_size_type_define gssize;
2827 typedef unsigned $glib_size_type_define gsize;
2828 #define G_GSIZE_MODIFIER $gsize_modifier
2829 #define G_GSSIZE_FORMAT $gssize_format
2830 #define G_GSIZE_FORMAT $gsize_format
2831
2832 #define G_MAXSIZE       G_MAXU$glib_msize_type
2833 #define G_MINSSIZE      G_MIN$glib_msize_type
2834 #define G_MAXSSIZE      G_MAX$glib_msize_type
2835
2836 typedef gint64 goffset;
2837 #define G_MINOFFSET     G_MININT64
2838 #define G_MAXOFFSET     G_MAXINT64
2839
2840 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2841 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2842 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2843
2844 _______EOF
2845
2846         if test -z "$glib_unknown_void_p"; then
2847           cat >>$outfile <<_______EOF
2848
2849 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2850 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2851
2852 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2853 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2854
2855 typedef signed $glib_intptr_type_define gintptr;
2856 typedef unsigned $glib_intptr_type_define guintptr;
2857
2858 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2859 #define G_GINTPTR_FORMAT        $gintptr_format
2860 #define G_GUINTPTR_FORMAT       $guintptr_format
2861 _______EOF
2862         else
2863           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2864         fi
2865
2866
2867
2868         cat >>$outfile <<_______EOF
2869 $glib_atexit
2870 $glib_memmove
2871 $glib_defines
2872 $glib_os
2873 $glib_static_compilation
2874
2875 $glib_vacopy
2876
2877 #ifdef  __cplusplus
2878 #define G_HAVE_INLINE   1
2879 #else   /* !__cplusplus */
2880 $glib_inline
2881 #endif  /* !__cplusplus */
2882
2883 #ifdef  __cplusplus
2884 #define G_CAN_INLINE    1
2885 _______EOF
2886
2887         if test x$g_can_inline = xyes ; then
2888                 cat >>$outfile <<_______EOF
2889 #else   /* !__cplusplus */
2890 #define G_CAN_INLINE    1
2891 _______EOF
2892         fi
2893
2894         cat >>$outfile <<_______EOF
2895 #endif
2896
2897 _______EOF
2898
2899         if test x$g_have_iso_c_varargs = xyes ; then
2900                 cat >>$outfile <<_______EOF
2901 #ifndef __cplusplus
2902 # define G_HAVE_ISO_VARARGS 1
2903 #endif
2904 _______EOF
2905         fi
2906         if test x$g_have_iso_cxx_varargs = xyes ; then
2907                 cat >>$outfile <<_______EOF
2908 #ifdef __cplusplus
2909 # define G_HAVE_ISO_VARARGS 1
2910 #endif
2911 _______EOF
2912         fi
2913         if test x$g_have_gnuc_varargs = xyes ; then
2914                 cat >>$outfile <<_______EOF
2915
2916 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2917  * is passed ISO vararg support is turned off, and there is no work
2918  * around to turn it on, so we unconditionally turn it off.
2919  */
2920 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2921 #  undef G_HAVE_ISO_VARARGS
2922 #endif
2923
2924 #define G_HAVE_GNUC_VARARGS 1
2925 _______EOF
2926         fi
2927
2928         case x$g_stack_grows in
2929         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2930         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2931         esac
2932
2933
2934         echo >>$outfile
2935         if test x$g_have_eilseq = xno; then
2936                 cat >>$outfile <<_______EOF
2937 #ifndef EILSEQ
2938 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2939  * The correspondence between this and the corresponding definition
2940  * in libiconv is essential.
2941  */
2942 #  define EILSEQ ENOENT
2943 #endif
2944 _______EOF
2945
2946         fi
2947
2948         if test x$g_have_gnuc_visibility = xyes; then
2949                 cat >>$outfile <<_______EOF
2950 #define G_HAVE_GNUC_VISIBILITY 1
2951 _______EOF
2952         fi
2953                 cat >>$outfile <<_______EOF
2954 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2955 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2956 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2957 #define G_GNUC_INTERNAL __hidden
2958 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2959 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2960 #else
2961 #define G_GNUC_INTERNAL
2962 #endif
2963 _______EOF
2964
2965
2966         echo >>$outfile
2967         if test x$g_mutex_has_default = xyes; then
2968                 cat >>$outfile <<_______EOF
2969 $g_enable_threads_def G_THREADS_ENABLED
2970 #define G_THREADS_IMPL_$g_threads_impl_def
2971 typedef struct _GStaticMutex GStaticMutex;
2972 struct _GStaticMutex
2973 {
2974   struct _GMutex *runtime_mutex;
2975   union {
2976     char   pad[[$g_mutex_sizeof]];
2977     double dummy_double;
2978     void  *dummy_pointer;
2979     long   dummy_long;
2980   } static_mutex;
2981 };
2982 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
2983 #define g_static_mutex_get_mutex(mutex) \\
2984   (g_thread_use_default_impl ? ((GMutex*)(gpointer) ((mutex)->static_mutex.pad)) : \\
2985    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
2986 _______EOF
2987         else
2988                 cat >>$outfile <<_______EOF
2989 $g_enable_threads_def G_THREADS_ENABLED
2990 #define G_THREADS_IMPL_$g_threads_impl_def
2991 typedef struct _GMutex* GStaticMutex;
2992 #define G_STATIC_MUTEX_INIT NULL
2993 #define g_static_mutex_get_mutex(mutex) \\
2994   (g_static_mutex_get_mutex_impl_shortcut (mutex))
2995 _______EOF
2996         fi
2997
2998         cat >>$outfile <<_______EOF
2999 /* This represents a system thread as used by the implementation. An
3000  * alien implementaion, as loaded by g_thread_init can only count on
3001  * "sizeof (gpointer)" bytes to store their info. We however need more
3002  * for some of our native implementations. */
3003 typedef union _GSystemThread GSystemThread;
3004 union _GSystemThread
3005 {
3006   char   data[[$g_system_thread_sizeof]];
3007   double dummy_double;
3008   void  *dummy_pointer;
3009   long   dummy_long;
3010 };
3011 _______EOF
3012         if test x"$g_memory_barrier_needed" != xno; then
3013           echo >>$outfile
3014           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3015         fi
3016
3017         echo >>$outfile
3018         g_bit_sizes="16 32 64"
3019         for bits in $g_bit_sizes; do
3020           cat >>$outfile <<_______EOF
3021 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3022 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3023 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3024 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3025 _______EOF
3026         done
3027
3028         cat >>$outfile <<_______EOF
3029 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3030 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3031 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3032 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3033 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3034 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3035 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3036 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3037 #define G_BYTE_ORDER $g_byte_order
3038
3039 #define GLIB_SYSDEF_POLLIN =$g_pollin
3040 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3041 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3042 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3043 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3044 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3045
3046 #define G_MODULE_SUFFIX "$g_module_suffix"
3047
3048 /* A GPid is an abstraction for a process "handle". It is *not* an
3049  * abstraction for a process identifier in general. GPid is used in
3050  * GLib only for descendant processes spawned with the g_spawn*
3051  * functions. On POSIX there is no "process handle" concept as such,
3052  * but on Windows a GPid is a handle to a process, a kind of pointer,
3053  * not a process identifier.
3054  */
3055 typedef $g_pid_type GPid;
3056
3057 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3058 #define GLIB_SYSDEF_AF_INET $g_af_inet
3059 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3060
3061 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3062 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3063 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3064
3065 G_END_DECLS
3066
3067 #endif /* GLIBCONFIG_H */
3068 _______EOF
3069
3070
3071         if cmp -s $outfile glibconfig.h; then
3072           AC_MSG_NOTICE([glibconfig.h is unchanged])
3073           rm -f $outfile
3074         else
3075           mv $outfile glibconfig.h
3076         fi
3077 ],[
3078
3079 # Note that if two cases are the same, case goes with the first one.
3080 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3081 # on variable expansion in case labels.  Look at the generated config.status
3082 # for a hint.
3083
3084 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3085   glib_header_alloca_h="$ac_cv_working_alloca_h"
3086 else
3087   glib_header_alloca_h="$ac_cv_header_alloca_h"
3088 fi
3089
3090 case xyes in
3091 x$ac_cv_header_float_h)
3092   glib_float_h=yes
3093   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3094   glib_md=DBL_MIN glib_Md=DBL_MAX
3095   ;;
3096 x$ac_cv_header_values_h)
3097   glib_values_h=yes
3098   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3099   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3100   ;;
3101 esac
3102
3103 case xyes in
3104 x$ac_cv_header_limits_h)
3105   glib_limits_h=yes
3106   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3107   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3108   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3109   ;;
3110 x$ac_cv_header_values_h)
3111   glib_values_h=yes
3112   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3113   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3114   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3115   ;;
3116 esac
3117
3118 if test x$ac_cv_header_sys_poll_h = xyes ; then
3119   glib_sys_poll_h=yes
3120 fi
3121
3122 if test x$enable_included_printf = xyes ; then
3123   glib_included_printf=yes
3124 fi
3125
3126 case 2 in
3127 $ac_cv_sizeof_short)
3128   gint16=short
3129   gint16_modifier='"h"'
3130   gint16_format='"hi"'
3131   guint16_format='"hu"'
3132   ;;
3133 $ac_cv_sizeof_int)
3134   gint16=int
3135   gint16_modifier='""'
3136   gint16_format='"i"'
3137   guint16_format='"u"'
3138   ;;
3139 esac
3140 case 4 in
3141 $ac_cv_sizeof_short)
3142   gint32=short
3143   gint32_modifier='"h"'
3144   gint32_format='"hi"'
3145   guint32_format='"hu"'
3146   ;;
3147 $ac_cv_sizeof_int)
3148   gint32=int
3149   gint32_modifier='""'
3150   gint32_format='"i"'
3151   guint32_format='"u"'
3152   ;;
3153 $ac_cv_sizeof_long)
3154   gint32=long
3155   gint32_modifier='"l"'
3156   gint32_format='"li"'
3157   guint32_format='"lu"'
3158   ;;
3159 esac
3160 case 8 in
3161 $ac_cv_sizeof_int)
3162   gint64=int
3163   gint64_modifier='""'
3164   gint64_format='"i"'
3165   guint64_format='"u"'
3166   glib_extension=
3167   gint64_constant='(val)'
3168   guint64_constant='(val)'
3169   ;;
3170 $ac_cv_sizeof_long)
3171   gint64=long
3172   gint64_modifier='"l"'
3173   gint64_format='"li"'
3174   guint64_format='"lu"'
3175   glib_extension=
3176   gint64_constant='(val##L)'
3177   guint64_constant='(val##UL)'
3178   ;;
3179 $ac_cv_sizeof_long_long)
3180   gint64='long long'
3181   if test -n "$glib_cv_long_long_format"; then
3182     gint64_modifier='"'$glib_cv_long_long_format'"'
3183     gint64_format='"'$glib_cv_long_long_format'i"'
3184     guint64_format='"'$glib_cv_long_long_format'u"'
3185   fi
3186   glib_extension='G_GNUC_EXTENSION '
3187   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3188   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3189   ;;
3190 $ac_cv_sizeof___int64)
3191   gint64='__int64'
3192   if test -n "$glib_cv_long_long_format"; then
3193     gint64_modifier='"'$glib_cv_long_long_format'"'
3194     gint64_format='"'$glib_cv_long_long_format'i"'
3195     guint64_format='"'$glib_cv_long_long_format'u"'
3196   fi
3197   glib_extension=
3198   gint64_constant='(val##i64)'
3199   guint64_constant='(val##ui64)'
3200   ;;
3201 esac
3202 glib_size_t=$ac_cv_sizeof_size_t
3203 glib_size_type_define="$glib_size_type"
3204 glib_void_p=$ac_cv_sizeof_void_p
3205 glib_long=$ac_cv_sizeof_long
3206
3207 case "$glib_size_type" in
3208 short)
3209   gsize_modifier='"h"'
3210   gsize_format='"hu"'
3211   gssize_format='"hi"'
3212   glib_msize_type='SHRT'
3213   ;;
3214 int)
3215   gsize_modifier='""'
3216   gsize_format='"u"'
3217   gssize_format='"i"'
3218   glib_msize_type='INT'
3219   ;;
3220 long)
3221   gsize_modifier='"l"'
3222   gsize_format='"lu"'
3223   gssize_format='"li"'
3224   glib_msize_type='LONG'
3225   ;;
3226 "long long"|__int64)
3227   gsize_modifier='"I64"'
3228   gsize_format='"I64u"'
3229   gssize_format='"I64i"'
3230   glib_msize_type='INT64'
3231   ;;
3232 esac
3233
3234 gintbits=`expr $ac_cv_sizeof_int \* 8`
3235 glongbits=`expr $ac_cv_sizeof_long \* 8`
3236
3237 case $ac_cv_sizeof_void_p in
3238 $ac_cv_sizeof_int)
3239   glib_intptr_type_define=int
3240   gintptr_modifier='""'
3241   gintptr_format='"i"'
3242   guintptr_format='"u"'
3243   glib_gpi_cast=''
3244   glib_gpui_cast=''
3245   ;;
3246 $ac_cv_sizeof_long)
3247   glib_intptr_type_define=long
3248   gintptr_modifier='"l"'
3249   gintptr_format='"li"'
3250   guintptr_format='"lu"'
3251   glib_gpi_cast='(glong)'
3252   glib_gpui_cast='(gulong)'
3253   ;;
3254 $ac_cv_sizeof_long_long)
3255   glib_intptr_type_define='long long'
3256   gintptr_modifier='"I64"'
3257   gintptr_format='"I64i"'
3258   guintptr_format='"I64u"'
3259   glib_gpi_cast='(gint64)'
3260   glib_gpui_cast='(guint64)'
3261   ;;
3262 $ac_cv_sizeof___int64)
3263   glib_intptr_type_define=__int64
3264   gintptr_modifier='"I64"'
3265   gintptr_format='"I64i"'
3266   guintptr_format='"I64u"'
3267   glib_gpi_cast='(gint64)'
3268   glib_gpui_cast='(guint64)'
3269   ;;
3270 *)
3271   glib_unknown_void_p=yes
3272   ;;
3273 esac
3274
3275
3276 case xyes in
3277 x$ac_cv_func_atexit)
3278   glib_atexit="
3279 #ifdef NeXT /* @#%@! NeXTStep */
3280 # define g_ATEXIT(proc) (!atexit (proc))
3281 #else
3282 # define g_ATEXIT(proc) (atexit (proc))
3283 #endif"
3284   ;;
3285 x$ac_cv_func_on_exit)
3286   glib_atexit="
3287 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3288   ;;
3289 esac
3290
3291 case xyes in
3292 x$ac_cv_func_memmove)
3293   glib_memmove='
3294 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3295   ;;
3296 x$glib_cv_working_bcopy)
3297   glib_memmove="
3298 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3299 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3300   ;;
3301 *)
3302   glib_memmove="
3303 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3304  * so we have to roll our own copy routine. */
3305 void g_memmove (void* dest, const void * src, unsigned long len);"
3306   ;;
3307 esac
3308
3309 glib_defines="
3310 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3311 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3312 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3313 "
3314
3315 case xyes in
3316 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3317 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3318 *)                      glib_vacopy=''
3319 esac
3320
3321 if test x$glib_cv_va_val_copy = xno; then
3322   glib_vacopy="\$glib_vacopy
3323 #define G_VA_COPY_AS_ARRAY 1"
3324 fi
3325
3326 if test x$glib_cv_hasinline = xyes; then
3327     glib_inline='#define G_HAVE_INLINE 1'
3328 fi
3329 if test x$glib_cv_has__inline = xyes; then
3330     glib_inline="\$glib_inline
3331 #define G_HAVE___INLINE 1"
3332 fi
3333 if test x$glib_cv_has__inline__ = xyes; then
3334     glib_inline="\$glib_inline
3335 #define G_HAVE___INLINE__ 1"
3336 fi
3337
3338 g_have_gnuc_varargs=$g_have_gnuc_varargs
3339 g_have_iso_c_varargs=$g_have_iso_c_varargs
3340 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3341
3342 g_can_inline=$g_can_inline
3343 g_have_gnuc_visibility=$g_have_gnuc_visibility
3344 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3345
3346 if test x$ac_cv_c_bigendian = xyes; then
3347   g_byte_order=G_BIG_ENDIAN
3348   g_bs_native=BE
3349   g_bs_alien=LE
3350 else
3351   g_byte_order=G_LITTLE_ENDIAN
3352   g_bs_native=LE
3353   g_bs_alien=BE
3354 fi
3355
3356 g_pollin=$glib_cv_value_POLLIN
3357 g_pollout=$glib_cv_value_POLLOUT
3358 g_pollpri=$glib_cv_value_POLLPRI
3359 g_pollhup=$glib_cv_value_POLLHUP
3360 g_pollerr=$glib_cv_value_POLLERR
3361 g_pollnval=$glib_cv_value_POLLNVAL
3362
3363 g_af_unix=$glib_cv_value_AF_UNIX
3364 g_af_inet=$glib_cv_value_AF_INET
3365 g_af_inet6=$glib_cv_value_AF_INET6
3366
3367 g_msg_peek=$glib_cv_value_MSG_PEEK
3368 g_msg_oob=$glib_cv_value_MSG_OOB
3369 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3370
3371 g_stack_grows=$glib_cv_stack_grows
3372
3373 g_have_eilseq=$have_eilseq
3374
3375 case x$have_threads in
3376 xno)    g_enable_threads_def="#undef";;
3377 *)      g_enable_threads_def="#define";;
3378 esac
3379
3380 g_threads_impl_def=$g_threads_impl
3381
3382 g_mutex_has_default="$mutex_has_default"
3383 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
3384 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
3385 g_mutex_contents="$glib_cv_byte_contents_gmutex"
3386
3387 g_memory_barrier_needed="$glib_memory_barrier_needed"
3388
3389 g_module_suffix="$glib_gmodule_suffix"
3390
3391 g_pid_type="$glib_pid_type"
3392 case $host in
3393   *-*-beos*)
3394     glib_os="#define G_OS_BEOS"
3395     ;;
3396   *-*-cygwin*)
3397     glib_os="#define G_OS_UNIX
3398 #define G_PLATFORM_WIN32
3399 #define G_WITH_CYGWIN"
3400     ;;
3401   *-*-mingw*)
3402     glib_os="#define G_OS_WIN32
3403 #define G_PLATFORM_WIN32"
3404     ;;
3405   *)
3406     glib_os="#define G_OS_UNIX"
3407     ;;
3408 esac
3409 glib_static_compilation=""
3410 if test x$glib_win32_static_compilation = xyes; then
3411   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3412 #define GOBJECT_STATIC_COMPILATION 1"
3413 fi
3414 ])
3415
3416 AC_CONFIG_FILES([
3417 glib-2.0.pc
3418 glib-2.0-uninstalled.pc
3419 gmodule-2.0.pc
3420 gmodule-export-2.0.pc
3421 gmodule-no-export-2.0.pc
3422 gmodule-2.0-uninstalled.pc
3423 gmodule-no-export-2.0-uninstalled.pc
3424 gthread-2.0.pc
3425 gthread-2.0-uninstalled.pc
3426 gobject-2.0.pc
3427 gobject-2.0-uninstalled.pc
3428 gio-2.0.pc
3429 gio-unix-2.0.pc
3430 gio-2.0-uninstalled.pc
3431 gio-unix-2.0-uninstalled.pc
3432 glib-zip
3433 glib-gettextize
3434 Makefile
3435 build/Makefile
3436 build/win32/Makefile
3437 build/win32/dirent/Makefile
3438 build/win32/vs8/Makefile
3439 build/win32/vs9/Makefile
3440 glib/Makefile
3441 glib/libcharset/Makefile
3442 glib/gnulib/Makefile
3443 glib/pcre/Makefile
3444 glib/update-pcre/Makefile
3445 glib/tests/Makefile
3446 gmodule/Makefile
3447 gmodule/gmoduleconf.h
3448 gobject/Makefile
3449 gobject/glib-mkenums
3450 gobject/tests/Makefile
3451 gthread/Makefile
3452 gio/Makefile
3453 gio/xdgmime/Makefile
3454 gio/inotify/Makefile
3455 gio/libasyncns/Makefile
3456 gio/fen/Makefile
3457 gio/fam/Makefile
3458 gio/win32/Makefile
3459 gio/tests/Makefile
3460 po/Makefile.in
3461 docs/Makefile
3462 docs/reference/Makefile
3463 docs/reference/glib/Makefile
3464 docs/reference/glib/version.xml
3465 docs/reference/gobject/Makefile
3466 docs/reference/gobject/version.xml
3467 docs/reference/gio/Makefile
3468 docs/reference/gio/version.xml
3469 tests/Makefile
3470 tests/gobject/Makefile
3471 tests/refcount/Makefile
3472 m4macros/Makefile
3473 ])
3474
3475 AC_CONFIG_COMMANDS([chmod-scripts],
3476 [chmod 0755 glib-zip
3477 chmod 0755 glib-gettextize
3478 chmod 0755 gobject/glib-mkenums])
3479
3480 # we want to invoke this macro solely so that the config.status script
3481 # and automake generated makefiles know about these generated files.
3482 # They are only needed to distcheck the package
3483 if false; then
3484   AC_CONFIG_FILES([
3485     INSTALL
3486     README
3487     config.h.win32
3488     glibconfig.h.win32
3489     glib/makefile.msc
3490     glib/glib.rc
3491     gmodule/makefile.msc
3492     gmodule/gmodule.rc
3493     gobject/makefile.msc
3494     gobject/gobject.rc
3495     gthread/makefile.msc
3496     gthread/gthread.rc
3497     tests/makefile.msc
3498   ])
3499 fi
3500
3501 AC_OUTPUT