configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5
   6 # require autoconf 2.13
   7 AC_PREREQ(2.13)
   8
   9 # Process this file with autoconf to produce a configure script.
  10 AC_INIT(glist.c)
  11
  12 # Save this value here, since automake will set cflags later
  13 cflags_set=${CFLAGS+set}
  14
  15 # we rewrite this file
  16 rm -f glibconfig-sysdefs.h
  17
  18 GLIB_AC_DIVERT_BEFORE_HELP([
  19 #
  20 # The following version number definitions apply to GLib, GModule, GObject
  21 # and GThread as a whole, so if changes occoured in any of them, they are all
  22 # treated with the same interface and binary age.
  23 #
  24 # Making releases:
  25 #   GLIB_MICRO_VERSION += 1;
  26 #   GLIB_INTERFACE_AGE += 1;
  27 #   GLIB_BINARY_AGE += 1;
  28 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  29 # if backwards compatibility has been broken,
  30 # set GLIB_BINARY_AGE _and_ GLIB_INTERFACE_AGE to 0.
  31 #
  32 GLIB_MAJOR_VERSION=1
  33 GLIB_MINOR_VERSION=3
  34 GLIB_MICRO_VERSION=5
  35 GLIB_INTERFACE_AGE=0
  36 GLIB_BINARY_AGE=0
  37 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  38 ])dnl
  39
  40 AC_SUBST(GLIB_MAJOR_VERSION)
  41 AC_SUBST(GLIB_MINOR_VERSION)
  42 AC_SUBST(GLIB_MICRO_VERSION)
  43 AC_SUBST(GLIB_VERSION)
  44 AC_SUBST(GLIB_INTERFACE_AGE)
  45 AC_SUBST(GLIB_BINARY_AGE)
  46
  47 # libtool versioning
  48 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  49 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  50 LT_REVISION=$GLIB_INTERFACE_AGE
  51 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  52 AC_SUBST(LT_RELEASE)
  53 AC_SUBST(LT_CURRENT)
  54 AC_SUBST(LT_REVISION)
  55 AC_SUBST(LT_AGE)
  56
  57 VERSION=$GLIB_VERSION
  58 PACKAGE=glib
  59
  60 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  61
  62 # Specify a configuration file
  63 AM_CONFIG_HEADER(config.h)
  64
  65 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION,
  66                    [Define to the GLIB major version])
  67 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION,
  68                    [Define to the GLIB minor version])
  69 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION,
  70                    [Define to the GLIB micro version])
  71 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE,
  72                    [Define to the GLIB interface age])
  73 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE,
  74                    [Define to the GLIB binary age])
  75
  76 dnl Initialize maintainer mode
  77 AM_MAINTAINER_MODE
  78
  79 AC_CANONICAL_HOST
  80
  81 AC_MSG_CHECKING(for the BeOS)
  82 case $host in
  83   *-*-beos*)
  84     glib_native_beos="yes"
  85     ;;
  86   *)
  87     glib_native_beos="no"
  88     ;;
  89 esac
  90 AC_MSG_RESULT([$glib_native_beos])
  91
  92 dnl
  93
  94 GLIB_AC_DIVERT_BEFORE_HELP([
  95 # figure debugging default, prior to $ac_help setup
  96 case $GLIB_MINOR_VERSION in
  97 *[[13579]]) debug_default=yes ;;
  98 *)          debug_default=minimum ;;
  99 esac[]dnl
 100 ])
 101
 102 dnl declare --enable-* args and collect ac_help strings
 103 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
 104 AC_ARG_ENABLE(gc_friendly, [  --enable-gc-friendly    turn on garbage collector friendliness [default=no]],,enable_gc_friendly=no)
 105 AC_ARG_ENABLE(mem_pools, [  --disable-mem-pools     disable all glib memory pools],,disable_mem_pools=no)
 106 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
 107                     , enable_ansi=no)
 108 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
 109                           ([=no] will override --with-threads)],,enable_threads=yes)
 110 AC_ARG_ENABLE(rebuilds, [  --disable-rebuilds      disable all source autogeneration rules],,enable_rebuilds=yes)
 111
 112 if test "x$enable_threads" != "xyes"; then
 113   enable_threads=no
 114 fi
 115
 116 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 117         [Whether glib was compiled with debugging enabled])
 118
 119 AC_MSG_CHECKING(whether to enable garbage collector friendliness)
 120 if test "x$enable_gc_friendly" = "xyes"; then
 121   AC_DEFINE(ENABLE_GC_FRIENDLY, 1, [Whether to enable GC friendliness])
 122   AC_SUBST(ENABLE_GC_FRIENDLY)
 123   AC_MSG_RESULT(yes)
 124 else
 125   AC_MSG_RESULT(no)
 126 fi
 127
 128 AC_MSG_CHECKING(whether to disable memory pools)
 129 if test "x$disable_mem_pools" = "xno"; then
 130   AC_MSG_RESULT(no)
 131 else
 132   AC_DEFINE(DISABLE_MEM_POOLS, 1, [Whether to disable memory pools])
 133   AC_SUBST(DISABLE_MEM_POOLS)
 134   AC_MSG_RESULT(yes)
 135 fi
 136
 137 dnl Checks for programs.
 138 AC_PROG_CC
 139
 140 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 141 AC_CHECK_PROGS(CXX, $CCC c++ g++ gcc CC cxx cc++ cl, gcc)
 142 AC_LANG_SAVE
 143 AC_LANG_CPLUSPLUS
 144 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 145 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 146 AC_LANG_RESTORE
 147
 148 AM_PROG_CC_STDC
 149 AC_PROG_INSTALL
 150
 151 #
 152 # Find pkg-config
 153 #
 154 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 155 if test x$PKG_CONFIG = xno ; then
 156   AC_MSG_ERROR([*** pkg-config not found. See http://pkgconfig.sourceforge.net])
 157 fi
 158
 159 if pkg-config --atleast-pkgconfig-version 0.5 ; then
 160   :
 161 else
 162   AC_MSG_ERROR([*** pkg-config too old; version 0.5 or better required.])
 163 fi
 164
 165 if test "x$enable_debug" = "xyes"; then
 166   if test x$cflags_set != xset ; then
 167       case " $CFLAGS " in
 168       *[[\ \    ]]-g[[\ \       ]]*) ;;
 169       *) CFLAGS="$CFLAGS -g" ;;
 170       esac
 171   fi
 172
 173   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 174 else
 175   if test "x$enable_debug" = "xno"; then
 176     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 177   fi
 178 fi
 179
 180 AC_CYGWIN
 181 AC_EXEEXT
 182
 183 # define a MAINT-like variable REBUILD which is set if Perl
 184 # and awk are found, so autogenerated sources can be rebuilt
 185 AC_PROG_AWK
 186 AC_CHECK_PROGS(PERL, perl5 perl)
 187 # We would like indent, but don't require it.
 188 AC_CHECK_PROG(INDENT, indent, indent)
 189 REBUILD=\#
 190 if test "x$enable_rebuilds" = "xyes" && \
 191      test -n "$PERL" && \
 192      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 193      test -n "$AWK" ; then
 194   REBUILD=
 195 fi
 196 AC_SUBST(REBUILD)
 197
 198
 199 dnl
 200 dnl gettext support
 201 dnl
 202
 203 ALL_LINGUAS="ca de fr no ru sl sv tr uk"
 204 AM_GLIB_GNU_GETTEXT
 205 LIBS="$LIBS $INTLLIBS"
 206
 207 GETTEXT_PACKAGE=glib20
 208 AC_SUBST(GETTEXT_PACKAGE)
 209 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE")
 210
 211 # AM_GLIB_GNU_GETTEXT above substs $DATADIRNAME
 212 # this is the directory where the *.{mo,gmo} files are installed
 213 GLIB_LOCALE_DIR="${prefix}/${DATADIRNAME}/locale"
 214 AC_DEFINE_UNQUOTED(GLIB_LOCALE_DIR,"$GLIB_LOCALE_DIR")
 215
 216 dnl Initialize libtool
 217 AC_LIBTOOL_WIN32_DLL
 218 AM_PROG_LIBTOOL
 219
 220 if test "x$GCC" = "xyes"; then
 221   case " $CFLAGS " in
 222   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 223   *) CFLAGS="$CFLAGS -Wall" ;;
 224   esac
 225
 226   if test "x$enable_ansi" = "xyes"; then
 227     case " $CFLAGS " in
 228     *[[\ \      ]]-ansi[[\ \    ]]*) ;;
 229     *) CFLAGS="$CFLAGS -ansi" ;;
 230     esac
 231
 232     case " $CFLAGS " in
 233     *[[\ \      ]]-pedantic[[\ \        ]]*) ;;
 234     *) CFLAGS="$CFLAGS -pedantic" ;;
 235     esac
 236   fi
 237 fi
 238
 239 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 240 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 241 glib_save_LIBS=$LIBS
 242 LIBS="$LIBS -lm"
 243 AC_TRY_RUN([#include <math.h>
 244              int main (void) { return (log(1) != log(1.)); }],
 245      AC_MSG_RESULT(none needed),
 246      glib_save_CFLAGS=$CFLAGS
 247      CFLAGS="$CFLAGS -std1"
 248      AC_TRY_RUN([#include <math.h>
 249                  int main (void) { return (log(1) != log(1.)); }],
 250          AC_MSG_RESULT(-std1),
 251          AC_MSG_RESULT()
 252          CFLAGS=$glib_save_CFLAGS
 253          AC_MSG_WARN(
 254                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 255      )
 256 )
 257 LIBS=$glib_save_LIBS
 258
 259 dnl NeXTStep cc seems to need this
 260 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 261 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 262   AC_MSG_RESULT(none needed),
 263   glib_save_CFLAGS=$CFLAGS
 264   CFLAGS="$CFLAGS -posix"
 265   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 266     AC_MSG_RESULT(-posix),
 267     AC_MSG_RESULT()
 268     CFLAGS=$glib_save_CFLAGS
 269     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 270
 271 # Checks for header files.
 272 AC_HEADER_STDC
 273
 274 # Checks for library functions.
 275 AC_FUNC_VPRINTF
 276
 277 AC_FUNC_ALLOCA
 278
 279 AC_CHECK_FUNCS(atexit on_exit)
 280
 281 AC_CHECK_SIZEOF(char)
 282 AC_CHECK_SIZEOF(short)
 283 AC_CHECK_SIZEOF(long)
 284 AC_CHECK_SIZEOF(int)
 285 AC_CHECK_SIZEOF(void *)
 286 AC_CHECK_SIZEOF(long long)
 287
 288 if test x$ac_cv_sizeof_long_long = x8; then
 289         # long long is a 64 bit integer.
 290         AC_MSG_CHECKING(for format to printf and scanf a gint64)
 291         AC_CACHE_VAL(glib_cv_long_long_format,[
 292                 for format in ll q I64; do
 293                   AC_TRY_RUN([#include <stdio.h>
 294                         int main()
 295                         {
 296                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 297                           char buffer[1000];
 298                           sprintf (buffer, "%${format}u", a);
 299                           sscanf (buffer, "%${format}u", &b);
 300                           exit (b!=a);
 301                         }
 302                         ],
 303                         glib_cv_long_long_format=${format}
 304                         break)
 305                 done])
 306         if test -n "$glib_cv_long_long_format"; then
 307           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 308         else
 309           AC_MSG_RESULT(none)
 310         fi
 311 fi
 312
 313 dnl long doubles were not used, and a portability problem
 314 dnl AC_C_LONG_DOUBLE
 315 AC_C_CONST
 316
 317 dnl ok, here we try to check whether the systems prototypes for
 318 dnl malloc and friends actually match the prototypes provided
 319 dnl by gmem.h (keep in sync). i currently only know how to check
 320 dnl this reliably with gcc (-Werror), improvements for other
 321 dnl compilers are apprechiated.
 322 SANE_MALLOC_PROTOS=no
 323 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 324 glib_save_CFLAGS=$CFLAGS
 325 if test "x$GCC" = "xyes"; then
 326   CFLAGS="$CFLAGS -Werror"
 327   AC_TRY_COMPILE([#include <stdlib.h>], [
 328     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 329     void* (*my_malloc_p)  (size_t)         = malloc;
 330     void  (*my_free_p)    (void*)          = free;
 331     void* (*my_realloc_p) (void*, size_t)  = realloc;
 332     my_calloc_p = 0;
 333     my_malloc_p = 0;
 334     my_free_p = 0;
 335     my_realloc_p = 0;
 336   ],
 337     AC_DEFINE(SANE_MALLOC_PROTOS)
 338     SANE_MALLOC_PROTOS=yes)
 339 fi
 340 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 341 CFLAGS=$glib_save_CFLAGS
 342
 343
 344 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 345 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 346 dnl actually supported.
 347 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 348         AC_TRY_RUN([
 349         __inline int foo () { return 0; }
 350         int main () { return foo (); }
 351         ],
 352         glib_cv_has__inline=yes
 353         ,
 354         glib_cv_has__inline=no
 355         ,)
 356 ])
 357 case x$glib_cv_has__inline in
 358 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 359 esac
 360 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 361         AC_TRY_RUN([
 362         __inline__ int foo () { return 0; }
 363         int main () { return foo (); }
 364         ],
 365         glib_cv_has__inline__=yes
 366         ,
 367         glib_cv_has__inline__=no
 368         ,)
 369 ])
 370 case x$glib_cv_has__inline__ in
 371 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 372 esac
 373 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 374         AC_TRY_RUN([
 375         inline int foo () { return 0; }
 376         int main () { return foo (); }
 377         ],
 378         glib_cv_hasinline=yes
 379         ,
 380         glib_cv_hasinline=no
 381         ,)
 382 ])
 383 case x$glib_cv_hasinline in
 384 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 385 esac
 386
 387 # check for flavours of varargs macros
 388 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 389 AC_TRY_COMPILE([],[
 390 int a(int p1, int p2, int p3);
 391 #define call_a(...) a(1,__VA_ARGS__)
 392 call_a(2,3);
 393 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 394 AC_MSG_RESULT($g_have_iso_c_varargs)
 395
 396 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 397 if test "$CXX" = ""; then
 398 dnl No C++ compiler
 399   g_have_iso_cxx_varargs=no
 400 else
 401   AC_LANG_CPLUSPLUS
 402   AC_TRY_COMPILE([],[
 403 int a(int p1, int p2, int p3);
 404 #define call_a(...) a(1,__VA_ARGS__)
 405 call_a(2,3);
 406 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 407   AC_LANG_C
 408 fi
 409 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 410
 411 AC_MSG_CHECKING(for GNUC varargs macros)
 412 AC_TRY_COMPILE([],[
 413 int a(int p1, int p2, int p3);
 414 #define call_a(params...) a(1,params)
 415 call_a(2,3);
 416 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 417 AC_MSG_RESULT($g_have_gnuc_varargs)
 418
 419 # check for bytesex stuff
 420 AC_C_BIGENDIAN
 421
 422 # check for header files
 423 AC_CHECK_HEADERS([float.h limits.h pwd.h sys/param.h sys/poll.h sys/select.h])
 424 AC_CHECK_HEADERS([sys/time.h sys/times.h unistd.h values.h stdint.h sched.h])
 425
 426 AC_MSG_CHECKING(whether make is GNU Make)
 427 STRIP_BEGIN=
 428 STRIP_END=
 429 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 430         STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
 431         STRIP_END=')'
 432         AC_MSG_RESULT(yes)
 433 else
 434         AC_MSG_RESULT(no)
 435 fi
 436 STRIP_DUMMY=
 437 AC_SUBST(STRIP_DUMMY)
 438 AC_SUBST(STRIP_BEGIN)
 439 AC_SUBST(STRIP_END)
 440
 441 # check additional type sizes
 442 size_includes=["
 443 #include <stdarg.h>
 444 #include <stdio.h>
 445 #include <ctype.h>
 446 #include <string.h>
 447 "]
 448 if test "x$ac_cv_header_stdint_h" = "xyes"; then
 449   size_includes=["$size_includes
 450 #include <stdint.h>
 451 "]
 452 fi
 453 if test "x$ac_cv_header_unistd_h" = "xyes"; then
 454   size_includes=["$size_includes
 455 #include <unistd.h>
 456 "]
 457 fi
 458 GLIB_SIZEOF([$size_includes], size_t, size_t)
 459 GLIB_SIZEOF([$size_includes], ptrdiff_t, ptrdiff_t)
 460 GLIB_SIZEOF([$size_includes], intmax_t, intmax_t)
 461
 462 # Check for some functions
 463 AC_CHECK_FUNCS(lstat strerror strsignal memmove mkstemp vsnprintf stpcpy strcasecmp strncasecmp poll getcwd)
 464
 465 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 466 # The check is borrowed from the PERL Configure script.
 467 if test "$ac_cv_func_memmove" != "yes"; then
 468   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 469     glib_cv_working_bcopy,[AC_TRY_RUN([
 470       int main() {
 471         char buf[128], abc[128], *b;
 472         int len, off, align;
 473         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 474         for (align = 7; align >= 0; align--) {
 475           for (len = 36; len; len--) {
 476             b = buf+align; bcopy(abc, b, len);
 477             for (off = 1; off <= len; off++) {
 478               bcopy(b, b+off, len); bcopy(b+off, b, len);
 479                 if (bcmp(b, abc, len)) return(1);
 480             }
 481           }
 482         }
 483         return(0);
 484       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 485   if test "$glib_cv_working_bcopy" = "yes"; then
 486     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 487   fi
 488 fi
 489
 490 # Check for sys_errlist
 491 AC_MSG_CHECKING(for sys_errlist)
 492 AC_TRY_LINK(, [
 493 extern char *sys_errlist[];
 494 extern int sys_nerr;
 495 sys_errlist[sys_nerr-1][0] = 0;
 496 ], glib_ok=yes, glib_ok=no)
 497 AC_MSG_RESULT($glib_ok)
 498 if test $glib_ok = no; then
 499     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 500 fi
 501
 502 # Check for sys_siglist
 503 AC_MSG_CHECKING(for sys_siglist)
 504 AC_TRY_LINK(, [
 505 extern char *sys_siglist[];
 506 exit (sys_siglist[0]);
 507 ], glib_ok=yes, glib_ok=no)
 508 AC_MSG_RESULT($glib_ok)
 509 if test $glib_ok = no; then
 510     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 511 fi
 512
 513 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 514 AC_MSG_CHECKING(for sys_siglist declaration)
 515 AC_TRY_COMPILE([#include <signal.h>], [
 516 strlen (sys_siglist[0]);
 517 ], glib_ok=yes, glib_ok=no)
 518 AC_MSG_RESULT($glib_ok)
 519 if test $glib_ok = no; then
 520     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 521 fi
 522
 523 # Check if <sys/select.h> needs to be included for fd_set
 524 AC_MSG_CHECKING([for fd_set])
 525 AC_TRY_COMPILE([#include <sys/types.h>],
 526         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 527 if test $gtk_ok = yes; then
 528     AC_MSG_RESULT([yes, found in sys/types.h])
 529 else
 530     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
 531     if test $gtk_ok = yes; then
 532         # *** FIXME: give it a different name
 533         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
 534         AC_MSG_RESULT([yes, found in sys/select.h])
 535     else
 536         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
 537         AC_MSG_RESULT(no)
 538     fi
 539 fi
 540
 541 dnl *** check for sane realloc() ***
 542 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
 543         AC_TRY_RUN([
 544         #include <stdlib.h>
 545         int main() {
 546           return realloc (0, sizeof (int)) == 0;
 547         }],
 548         [glib_cv_sane_realloc=yes],
 549         [glib_cv_sane_realloc=no],
 550         [])
 551 ])
 552 if test x$glib_cv_sane_realloc = xyes; then
 553   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
 554 fi
 555
 556 dnl Check for nl_langinfo and CODESET
 557
 558 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
 559 AC_TRY_COMPILE([#include <langinfo.h>],
 560         [char *codeset = nl_langinfo (CODESET);],
 561    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
 562    have_codeset=yes,
 563    have_codeset=no)
 564 AC_MSG_RESULT($have_codeset)
 565
 566
 567 dnl ****************************************
 568 dnl *** strlcpy/strlcat                  ***
 569 dnl ****************************************
 570 # Check for strlcpy
 571 AC_MSG_CHECKING(for strlcpy/strlcat)
 572 AC_TRY_LINK([#include <stdlib.h>
 573 #include <string.h>], [
 574 char *p = malloc(10);
 575 (void) strlcpy(p, "hi", 10);
 576 (void) strlcat(p, "bye", 10);
 577 ], glib_ok=yes, glib_ok=no)
 578 AC_MSG_RESULT($glib_ok)
 579 if test $glib_ok = yes; then
 580     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
 581 fi
 582
 583
 584 dnl **********************
 585 dnl *** va_copy checks ***
 586 dnl **********************
 587 dnl we currently check for all three va_copy possibilities, so we get
 588 dnl all results in config.log for bug reports.
 589 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
 590         AC_TRY_RUN([
 591         #include <stdarg.h>
 592         void f (int i, ...) {
 593         va_list args1, args2;
 594         va_start (args1, i);
 595         va_copy (args2, args1);
 596         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 597           exit (1);
 598         va_end (args1); va_end (args2);
 599         }
 600         int main() {
 601           f (0, 42);
 602           return 0;
 603         }],
 604         [glib_cv_va_copy=yes],
 605         [glib_cv_va_copy=no],
 606         [])
 607 ])
 608 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
 609         AC_TRY_RUN([
 610         #include <stdarg.h>
 611         void f (int i, ...) {
 612         va_list args1, args2;
 613         va_start (args1, i);
 614         __va_copy (args2, args1);
 615         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 616           exit (1);
 617         va_end (args1); va_end (args2);
 618         }
 619         int main() {
 620           f (0, 42);
 621           return 0;
 622         }],
 623         [glib_cv___va_copy=yes],
 624         [glib_cv___va_copy=no],
 625         [])
 626 ])
 627
 628 if test "x$glib_cv_va_copy" = "xyes"; then
 629   g_va_copy_func=va_copy
 630 else if test "x$glib_cv___va_copy" = "xyes"; then
 631   g_va_copy_func=__va_copy
 632 fi
 633 fi
 634
 635 if test -n "$g_va_copy_func"; then
 636   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
 637 fi
 638
 639 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
 640         AC_TRY_RUN([
 641         #include <stdarg.h>
 642         void f (int i, ...) {
 643         va_list args1, args2;
 644         va_start (args1, i);
 645         args2 = args1;
 646         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 647           exit (1);
 648         va_end (args1); va_end (args2);
 649         }
 650         int main() {
 651           f (0, 42);
 652           return 0;
 653         }],
 654         [glib_cv_va_val_copy=yes],
 655         [glib_cv_va_val_copy=no],
 656         [])
 657 ])
 658
 659 if test "x$glib_cv_va_val_copy" = "xno"; then
 660   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 661 fi
 662
 663 dnl ***********************
 664 dnl *** g_module checks ***
 665 dnl ***********************
 666 G_MODULE_LIBS=
 667 G_MODULE_LIBS_EXTRA=
 668 G_MODULE_PLUGIN_LIBS=
 669 G_MODULE_LDFLAGS=
 670 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
 671 G_MODULE_NEED_USCORE=0
 672 G_MODULE_BROKEN_RTLD_GLOBAL=0
 673 G_MODULE_HAVE_DLERROR=0
 674 dnl *** force native WIN32 shared lib loader
 675 if test -z "$G_MODULE_IMPL"; then
 676   case "$host" in
 677   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
 678   esac
 679 fi
 680 dnl *** dlopen() and dlsym() in system libraries
 681 if test -z "$G_MODULE_IMPL"; then
 682         AC_CHECK_FUNC(dlopen,
 683                       [AC_CHECK_FUNC(dlsym,
 684                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 685                       [])
 686 fi
 687 dnl *** load_image (BeOS)
 688 if test -z "$G_MODULE_IMPL" -a "x$glib_native_beos" = "xyes"; then
 689   AC_CHECK_LIB(root, load_image,
 690       [G_MODULE_LIBS="-lbe -lroot -lglib"
 691       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
 692       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
 693       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
 694       [])
 695 fi
 696 dnl *** dlopen() and dlsym() in libdl
 697 if test -z "$G_MODULE_IMPL"; then
 698         AC_CHECK_LIB(dl, dlopen,
 699                      [AC_CHECK_LIB(dl, dlsym,
 700                                    [G_MODULE_LIBS=-ldl
 701                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 702                      [])
 703 fi
 704 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
 705 if test -z "$G_MODULE_IMPL"; then
 706         AC_CHECK_FUNC(NSLinkModule,
 707                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
 708                        G_MODULE_NEED_USCORE=1],
 709                       [])
 710 fi
 711 dnl *** shl_load() in libdld (HP-UX)
 712 if test -z "$G_MODULE_IMPL"; then
 713         AC_MSG_CHECKING(how to export all symbols)
 714         SAVED_LDFLAGS=$LDFLAGS
 715         LDFLAGS="$LDFLAGS -Wl,-E"
 716         AC_TRY_LINK(,[ return 0; ],
 717                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 718                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 719                 AC_TRY_LINK(,[ return 0; ],
 720                         [G_MODULE_LDFLAGS="-bexpall"],
 721                         [G_MODULE_LDFLAGS="none"])
 722         ])
 723         LDFLAGS=$SAVED_LDFLAGS
 724         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 725         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 726                 G_MODULE_LDFLAGS=
 727         fi
 728         AC_CHECK_LIB(dld, shl_load,
 729                 [G_MODULE_LIBS=-ldld
 730                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
 731                 [])
 732 fi
 733 dnl *** additional checks for G_MODULE_IMPL_DL
 734 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 735         case "$host_os" in
 736           linux*)
 737             G_MODULE_LDFLAGS='-rdynamic'
 738             ;;
 739         esac
 740         LIBS_orig="$LIBS"
 741         LDFLAGS_orig="$LDFLAGS"
 742         LIBS="$LIBS $G_MODULE_LIBS"
 743         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 744 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
 745         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
 746                 glib_cv_rtldglobal_broken,[
 747                 AC_TRY_RUN([
 748                 #include <dlfcn.h>
 749                 #ifndef RTLD_GLOBAL
 750                 #define RTLD_GLOBAL 0
 751                 #endif
 752                 #ifndef RTLD_LAZY
 753                 #define RTLD_LAZY 0
 754                 #endif
 755                 int pthread_create;
 756                 int main () {
 757                 void *handle, *global, *local;
 758                 global = &pthread_create;
 759                 handle = dlopen ("libpthread.so", RTLD_GLOBAL | RTLD_LAZY);
 760                 if (!handle) return 0;
 761                 local = dlsym (handle, "pthread_create");
 762                 return global == local;
 763                 }],
 764                         [glib_cv_rtldglobal_broken=no],
 765                         [glib_cv_rtldglobal_broken=yes],
 766                         [])
 767                 rm -f plugin.c plugin.o plugin.lo
 768         ])
 769         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
 770                 G_MODULE_BROKEN_RTLD_GLOBAL=1
 771         else
 772                 G_MODULE_BROKEN_RTLD_GLOBAL=0
 773         fi
 774 dnl *** check whether we need preceeding underscores
 775         AC_CACHE_CHECK([for preceeding underscore in symbols],
 776                 glib_cv_uscore,[
 777                 AC_TRY_RUN([
 778                 #include <dlfcn.h>
 779                 int glib_underscore_test (void) { return 42; }
 780                 int main() {
 781                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 782                   handle = dlopen ((void*)0, 0);
 783                   if (handle) {
 784                     f1 = dlsym (handle, "glib_underscore_test");
 785                     f2 = dlsym (handle, "_glib_underscore_test");
 786                   } return (!f2 || f1);
 787                 }],
 788                         [glib_cv_uscore=yes],
 789                         [glib_cv_uscore=no],
 790                         [])
 791                 rm -f plugin.c plugin.$ac_objext plugin.lo
 792         ])
 793         if test "x$glib_cv_uscore" = "xyes"; then
 794                 G_MODULE_NEED_USCORE=1
 795         else
 796                 G_MODULE_NEED_USCORE=0
 797         fi
 798
 799         LDFLAGS="$LDFLAGS_orig"
 800 dnl *** check for having dlerror()
 801         AC_CHECK_FUNC(dlerror,
 802                 [G_MODULE_HAVE_DLERROR=1],
 803                 [G_MODULE_HAVE_DLERROR=0])
 804         LIBS="$LIBS_orig"
 805 fi
 806 dnl *** done, have we got an implementation?
 807 if test -z "$G_MODULE_IMPL"; then
 808         G_MODULE_IMPL=0
 809 fi
 810
 811 AC_MSG_CHECKING(for the suffix of shared libraries)
 812 case "$host_os" in
 813   hpux9* | hpux10* | hpux11*)  # taken from ltconfig
 814     glib_gmodule_suffix='sl'
 815     ;;
 816   cygwin* | mingw*)
 817     glib_gmodule_suffix='dll'
 818     ;;
 819   *)
 820     glib_gmodule_suffix='so'
 821     ;;
 822 esac
 823 AC_MSG_RESULT(.$glib_gmodule_suffix)
 824
 825 AC_SUBST(G_MODULE_IMPL)
 826 AC_SUBST(G_MODULE_LIBS)
 827 AC_SUBST(G_MODULE_LIBS_EXTRA)
 828 AC_SUBST(G_MODULE_PLUGIN_LIBS)
 829 AC_SUBST(G_MODULE_LDFLAGS)
 830 AC_SUBST(G_MODULE_HAVE_DLERROR)
 831 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
 832 AC_SUBST(G_MODULE_NEED_USCORE)
 833 AC_SUBST(GLIB_DEBUG_FLAGS)
 834
 835 dnl **********************
 836 dnl *** g_spawn checks ***
 837 dnl **********************
 838
 839 AC_MSG_CHECKING(for gspawn implementation)
 840 case "$host" in
 841   *-*-mingw*)
 842     GSPAWN=gspawn-win32.lo
 843     ;;
 844   *)
 845     GSPAWN=gspawn.lo
 846     ;;
 847 esac
 848 AC_MSG_RESULT($GSPAWN)
 849 AC_SUBST(GSPAWN)
 850
 851 dnl *************************
 852 dnl *** GIOChannel checks ***
 853 dnl *************************
 854
 855 AC_MSG_CHECKING(for GIOChannel implementation)
 856 case "$host" in
 857   *-*-mingw*)
 858     GIO=giowin32.lo
 859     ;;
 860   *)
 861     GIO=giounix.lo
 862     ;;
 863 esac
 864 AC_MSG_RESULT($GIO)
 865 AC_SUBST(GIO)
 866
 867 dnl ****************************************
 868 dnl *** platform dependent source checks ***
 869 dnl ****************************************
 870
 871 AC_MSG_CHECKING(for platform-dependent source)
 872 case "$host" in
 873   *-*-cygwin*|*-*-mingw*)
 874     PLATFORMDEP=gwin32.lo
 875     ;;
 876   *)
 877     PLATFORMDEP=
 878     ;;
 879 esac
 880 AC_MSG_RESULT($PLATFORMDEP)
 881 AC_SUBST(PLATFORMDEP)
 882
 883 AC_MSG_CHECKING([whether to compile timeloop])
 884 case "$host" in
 885   *-*-cygwin*|*-*-mingw*)
 886     enable_timeloop=no
 887     ;;
 888   *)
 889     enable_timeloop=yes
 890     ;;
 891 esac
 892 AC_MSG_RESULT($enable_timeloop)
 893 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
 894
 895 AC_MSG_CHECKING([if building for some Win32 platform])
 896 case "$host" in
 897   *-*-mingw*|*-*-cygwin*)
 898     platform_win32=yes
 899     ;;
 900   *)
 901     platform_win32=no
 902     ;;
 903 esac
 904 AC_MSG_RESULT($platform_win32)
 905 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
 906
 907 AC_MSG_CHECKING([if building for pure Win32])
 908 case "$host" in
 909   *-*-mingw*)
 910     os_win32=yes
 911     ;;
 912   *)
 913     os_win32=no
 914     ;;
 915 esac
 916 AC_MSG_RESULT($os_win32)
 917 AM_CONDITIONAL(OS_WIN32, test x$os_win32 = xyes)
 918
 919 dnl ***********************
 920 dnl *** g_thread checks ***
 921 dnl ***********************
 922
 923 AC_ARG_WITH(threads, [  --with-threads=[none/posix/dce/solaris] specify a thread implementation to use],
 924         if test "x$with_threads" = x; then
 925                 want_threads=yes
 926         else
 927                 want_threads=$with_threads
 928         fi,
 929         want_threads=yes)
 930 if test "x$enable_threads" = "xno"; then
 931         want_threads=no
 932 fi
 933 if test "x$want_threads" = "xnone"; then
 934         want_threads=no
 935 fi
 936
 937 dnl error and warning message
 938 dnl *************************
 939
 940 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
 941                 computer. GLib will not have a default thread implementation."
 942
 943 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
 944                 platform (normally it's "_REENTRANT"). I'll not use any flag on
 945                 compilation now, but then your programs might not work.
 946                 Please provide information on how it is done on your system."
 947
 948 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
 949                 "
 950
 951 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
 952                 provide information on your thread implementation.
 953                 You can also run 'configure --disable-threads'
 954                 to compile without thread support."
 955
 956 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
 957                 functions will not be MT-safe during their first call because
 958                 there is no working 'getpwuid_r' on your system."
 959
 960 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
 961                 because there is no 'localtime_r' on your system."
 962
 963 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
 964                 crude surrogate will be used. If you happen to know a
 965                 yield function for your system, please inform the GLib
 966                 developers."
 967
 968 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
 969                 threads on your system. Thus threads can only have the default
 970                 priority. If you happen to know these main/max
 971                 priorities, please inform the GLib developers."
 972
 973
 974 dnl determination of thread implementation
 975 dnl ***************************************
 976
 977 have_threads=none
 978 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
 979         case $host in
 980                 *-*-solaris*)
 981                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
 982                 ;;
 983         esac
 984 fi
 985 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
 986                                 || test "x$want_threads" = xdce; then
 987         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
 988         # -U_OSF_SOURCE is for Digital UNIX 4.0d
 989         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
 990         glib_save_CPPFLAGS="$CPPFLAGS"
 991         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
 992         if test "x$have_threads" = xnone; then
 993                 AC_TRY_COMPILE([#include <pthread.h>],
 994                         [pthread_attr_t attr; pthread_attr_init(&attr);],
 995                         have_threads=posix)
 996         fi
 997         if test "x$have_threads" = xnone; then
 998                 AC_TRY_COMPILE([#include <pthread.h>],
 999                         [pthread_attr_t attr; pthread_attr_create(&attr);],
1000                         have_threads=posix)
1001         fi
1002         CPPFLAGS="$glib_save_CPPFLAGS"
1003 fi
1004
1005 AC_MSG_CHECKING(for thread implementation)
1006
1007 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
1008         AC_MSG_RESULT(none available)
1009         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1010 else
1011         AC_MSG_RESULT($have_threads)
1012 fi
1013
1014
1015 dnl determination of G_THREAD_CFLAGS
1016 dnl ********************************
1017
1018 G_THREAD_LIBS=
1019 G_THREAD_LIBS_EXTRA=
1020 G_THREAD_CFLAGS=
1021
1022 if test x"$have_threads" != xnone; then
1023
1024     G_THREAD_CFLAGS="-D_REENTRANT" # good default guess
1025
1026     case $host in
1027         *-aix*)
1028                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
1029                 if test x"$GCC" = xyes; then
1030                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
1031                 fi
1032                 ;;
1033         *-freebsd2.2*)
1034                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
1035
1036                 # FreeBSD 2.2.x shiped with gcc 2.7.2.x, which doesn't support
1037                 # -mthreads flag.
1038                 ;;
1039         *-sysv5uw7*)  # UnixWare 7
1040                 if test "$GCC" != "yes"; then
1041                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -Kthread"
1042                 else
1043                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -pthread"
1044                 fi
1045                 ;;
1046         *-dg-dgux*)  # DG/UX
1047                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
1048     esac
1049
1050     # if we are not finding the localtime_r function, then we probably are
1051     # not using the proper multithread flag
1052
1053     glib_save_CPPFLAGS="$CPPFLAGS"
1054     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1055
1056     # First we test, whether localtime_r is declared in time.h
1057     # directly. Then we test whether a macro localtime_r exists, in
1058     # which case localtime_r in the test program is replaced and thus
1059     # if we still find localtime_r in the output, it is not defined as
1060     # a macro.
1061
1062     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1063       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1064                                                            localtime_r(a,b)],
1065                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1066
1067     CPPFLAGS="$glib_save_CPPFLAGS"
1068
1069     AC_MSG_CHECKING(thread related cflags)
1070     AC_MSG_RESULT($G_THREAD_CFLAGS)
1071     CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
1072 fi
1073
1074 dnl determination of G_THREAD_LIBS
1075 dnl ******************************
1076
1077 mutex_has_default=no
1078 case $have_threads in
1079         posix|dce)
1080            glib_save_CPPFLAGS="$CPPFLAGS"
1081            CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1082            G_THREAD_LIBS=error
1083            glib_save_LIBS="$LIBS"
1084            case $host in
1085              *-sysv5uw7*) # UnixWare 7
1086                 if test "$GCC" != "yes"; then
1087                         G_THREAD_LIBS="-Kthread"
1088                 else
1089                         G_THREAD_LIBS="-pthread"
1090                 fi
1091                 ;;
1092              *)
1093                 for thread_lib in "" pthread pthread32 pthreads c_r thread dce; do
1094                         if test x"$thread_lib" = x; then
1095                                 add_thread_lib=""
1096                                 IN=""
1097                         else
1098                                 add_thread_lib="-l$thread_lib"
1099                                 IN=" in -l$thread_lib"
1100                         fi
1101                         if test x"$have_threads" = xposix; then
1102                                 defattr=0
1103                         else
1104                                 defattr=pthread_attr_default
1105                         fi
1106
1107                         LIBS="$glib_save_LIBS $add_thread_lib"
1108
1109                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
1110                         AC_TRY_RUN([#include <pthread.h>
1111                                 int check_me = 0;
1112                                 void* func(void* data) {check_me = 42;}
1113                                 main()
1114                                 { pthread_t t;
1115                                   void *ret;
1116                                   pthread_create (&t, $defattr, func, 0);
1117                                   pthread_join (t, &ret);
1118                                   exit (check_me != 42);
1119                                 }],
1120                                 [AC_MSG_RESULT(yes)
1121                                 G_THREAD_LIBS="$add_thread_lib"
1122                                 break],
1123                                 [AC_MSG_RESULT(no)])
1124                 done
1125                 if test "x$G_THREAD_LIBS" = xerror; then
1126                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1127                 fi
1128                 for thread_lib in "" rt rte; do
1129                         if test x"$thread_lib" = x; then
1130                                 add_thread_lib=""
1131                                 IN=""
1132                         else
1133                                 add_thread_lib="-l$thread_lib"
1134                                 IN=" in -l$thread_lib"
1135                         fi
1136                         LIBS="$glib_save_LIBS $add_thread_lib"
1137
1138                         AC_MSG_CHECKING(for sched_get_priority_min$IN)
1139                         AC_TRY_RUN([#include <sched.h>
1140                                 #include <errno.h>
1141                                 int main() {
1142                                 errno = 0;
1143                                 return sched_get_priority_min(SCHED_OTHER)==-1
1144                                         && errno != 0;
1145                                 }],
1146                                 [AC_MSG_RESULT(yes)
1147                                 G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
1148                                 posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
1149                                 posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
1150                                 break],
1151                                 [AC_MSG_RESULT(no)])
1152                 done
1153                 LIBS="$glib_save_LIBS"
1154                 ;;
1155            esac
1156            mutex_has_default=yes
1157            mutex_default_type='pthread_mutex_t'
1158            mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
1159            mutex_header_file='pthread.h'
1160            if test "x$have_threads" = "xposix"; then
1161              g_threads_impl="POSIX"
1162            else
1163              g_threads_impl="DCE"
1164              have_threads="posix"
1165            fi
1166            AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
1167            CPPFLAGS="$glib_save_CPPFLAGS"
1168            ;;
1169         solaris)
1170            G_THREAD_LIBS=error
1171            AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
1172            mutex_has_default=yes
1173            mutex_default_type='mutex_t'
1174            mutex_default_init="DEFAULTMUTEX"
1175            mutex_header_file='thread.h'
1176            g_threads_impl="SOLARIS"
1177            ;;
1178         none)
1179            g_threads_impl="NONE"
1180            ;;
1181         *)
1182            g_threads_impl="NONE"
1183            G_THREAD_LIBS=error
1184            ;;
1185 esac
1186
1187 if test "x$G_THREAD_LIBS" = xerror; then
1188         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1189 fi
1190
1191 case $host in
1192   *-*-beos*)
1193     G_THREAD_LIBS="-lbe -lroot -lglib "
1194     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1195     ;;
1196   *)
1197     ;;
1198 esac
1199
1200 AC_MSG_CHECKING(thread related libraries)
1201 AC_MSG_RESULT($G_THREAD_LIBS)
1202
1203 dnl check for mt safe function variants and some posix functions
1204 dnl ************************************************************
1205
1206 if test x"$have_threads" != xnone; then
1207         glib_save_LIBS="$LIBS"
1208         # we are not doing the following for now, as this might require glib
1209         # to always be linked with the thread libs on some platforms.
1210         # LIBS="$LIBS $G_THREAD_LIBS"
1211         AC_CHECK_FUNCS(localtime_r)
1212         if test "$ac_cv_header_pwd_h" = "yes"; then
1213                 AC_CACHE_CHECK([for posix getpwuid_r],
1214                         ac_cv_func_posix_getpwuid_r,
1215                         [AC_TRY_RUN([#include <errno.h>
1216                                 #include <pwd.h>
1217                                 int main () { char buffer[10000];
1218                                 struct passwd pwd, *pwptr = &pwd;
1219                                 int error;
1220                                 errno = 0;
1221                                 error = getpwuid_r (0, &pwd, buffer,
1222                                         sizeof (buffer), &pwptr);
1223                                 return (error < 0 && errno == ENOSYS)
1224                                         || error == ENOSYS; }],
1225                                 [ac_cv_func_posix_getpwuid_r=yes],
1226                                 [ac_cv_func_posix_getpwuid_r=no])])
1227                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
1228                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
1229                                 [Have POSIX function getpwuid_r])
1230                 else
1231                         AC_CACHE_CHECK([for nonposix getpwuid_r],
1232                                 ac_cv_func_nonposix_getpwuid_r,
1233                                 [AC_TRY_LINK([#include <pwd.h>],
1234                                         [char buffer[10000];
1235                                         struct passwd pwd;
1236                                         getpwuid_r (0, &pwd, buffer,
1237                                                         sizeof (buffer));],
1238                                         [ac_cv_func_nonposix_getpwuid_r=yes],
1239                                         [ac_cv_func_nonposix_getpwuid_r=no])])
1240                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
1241                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
1242                                         [Have non-POSIX function getpwuid_r])
1243                         fi
1244                 fi
1245         fi
1246         LIBS="$LIBS $G_THREAD_LIBS"
1247         if test x"$have_threads" = xposix; then
1248                 glib_save_CPPFLAGS="$CPPFLAGS"
1249                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1250                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
1251                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
1252                 # This is not AC_CHECK_FUNC to also work with function
1253                 # name mangling in header files.
1254                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1255                 AC_TRY_LINK([#include <pthread.h>],
1256                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1257                         [AC_MSG_RESULT(yes)
1258                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1259                                   [Have function pthread_attr_setstacksize])],
1260                         [AC_MSG_RESULT(no)])
1261                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1262                 if test x"$posix_priority_min" = xnone; then
1263                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1264                                 PX_PRIO_MIN],,[
1265                                 posix_priority_min=PX_PRIO_MIN
1266                                 posix_priority_max=PX_PRIO_MAX])
1267                 fi
1268                 if test x"$posix_priority_min" = xnone; then
1269                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1270                                 PRI_OTHER_MIN],,[
1271                                 posix_priority_min=PRI_OTHER_MIN
1272                                 posix_priority_max=PRI_OTHER_MAX])
1273                 fi
1274                 if test x"$posix_priority_min" = x; then
1275                         AC_MSG_RESULT(none found)
1276                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1277                         posix_priority_min=-1
1278                         posix_priority_max=-1
1279                 else
1280                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1281                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1282                         AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])
1283                 fi
1284                 posix_yield_func=none
1285                 AC_MSG_CHECKING(for posix yield function)
1286                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1287                                                         thr_yield; do
1288                         AC_TRY_LINK([#include <pthread.h>],
1289                                 [$yield_func()],
1290                                 [posix_yield_func="$yield_func"
1291                                 break])
1292                 done
1293                 if test x"$posix_yield_func" = xnone; then
1294                         AC_MSG_RESULT(none found)
1295                         AC_MSG_WARN($POSIX_NO_YIELD)
1296                         posix_yield_func="g_usleep(1000)"
1297                 else
1298                         AC_MSG_RESULT($posix_yield_func)
1299                         posix_yield_func="$posix_yield_func()"
1300                 fi
1301                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1302                 CPPFLAGS="$glib_save_CPPFLAGS"
1303
1304                 AC_MSG_CHECKING(whether to use the PID niceness surrogate for thread priorities)
1305                 AC_TRY_RUN([#include <pthread.h>
1306                         #include <sys/types.h>
1307                         #include <unistd.h>
1308                         pid_t other_pid = 0;
1309
1310                         void* func(void* data) {other_pid = getpid();}
1311                         main()
1312                         { pthread_t t;
1313                           void *ret;
1314                           pthread_create (&t, $defattr, func, NULL);
1315                           pthread_join (t, &ret);
1316                           exit (getpid()==other_pid ||
1317                                 $posix_priority_min != $posix_priority_max);
1318                         }],
1319                         [AC_MSG_RESULT(yes)
1320                           AC_DEFINE(G_THREAD_USE_PID_SURROGATE, 1, [whether to use the PID niceness surrogate for thread priorities])
1321                         ],
1322                         [AC_MSG_RESULT(no)])
1323         else # solaris threads
1324                 GLIB_SIZEOF([#include <thread.h>], thread_t, system_thread)
1325         fi
1326
1327         LIBS="$glib_save_LIBS"
1328
1329         # now spit out all the warnings.
1330         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1331            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1332                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1333         fi
1334         if test "$ac_cv_func_localtime_r" != "yes"; then
1335                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1336         fi
1337 else
1338         # If no thread implementation exists, we will provide enough
1339         # space for a pointer
1340         GLIB_SIZEOF(, void*, system_thread)
1341 fi
1342
1343 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1344                    [Source file containing theread implementation])
1345 AC_SUBST(G_THREAD_CFLAGS)
1346 AC_SUBST(G_THREAD_LIBS)
1347 AC_SUBST(G_THREAD_LIBS_EXTRA)
1348
1349 dnl **********************************************
1350 dnl *** GDefaultMutex setup and initialization ***
1351 dnl **********************************************
1352 dnl
1353 dnl if mutex_has_default = yes, we also got
1354 dnl mutex_default_type, mutex_default_init and mutex_header_file
1355 GLIB_IF_VAR_EQ(mutex_has_default, yes,
1356         glib_save_CPPFLAGS="$CPPFLAGS"
1357         glib_save_LIBS="$LIBS"
1358         LIBS="$LIBS $G_THREAD_LIBS"
1359         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1360         GLIB_SIZEOF([#include <$mutex_header_file>],
1361                     $mutex_default_type,
1362                     gmutex,
1363                     )
1364         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1365                            $mutex_default_type,
1366                            gmutex,
1367                            $glib_cv_sizeof_gmutex,
1368                            $mutex_default_init)
1369         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1370                 mutex_has_default=no
1371         fi
1372         CPPFLAGS="$glib_save_CPPFLAGS"
1373         LIBS="$glib_save_LIBS"
1374         ,
1375 )
1376
1377
1378 dnl ****************************************
1379 dnl *** GLib POLL* compatibility defines ***
1380 dnl ****************************************
1381 GLIB_SYSDEFS(
1382 [#include <sys/types.h>
1383 #include <sys/poll.h>],
1384         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
1385         glibconfig-sysdefs.h,
1386         =)
1387
1388 dnl **********************
1389 dnl *** Win32 API libs ***
1390 dnl **********************
1391
1392 case $host in
1393   *-*-cygwin*)
1394         G_LIBS_EXTRA="-luser32 -lwsock32 -lkernel32"
1395     ;;
1396   *-*-mingw*)
1397         G_LIBS_EXTRA="-lwsock32"
1398     ;;
1399   *)
1400         G_LIBS_EXTRA=""
1401     ;;
1402 esac
1403 AC_SUBST(G_LIBS_EXTRA)
1404
1405 dnl ***********************
1406 dnl *** Tests for iconv ***
1407 dnl ***********************
1408
1409 AC_ARG_WITH(libiconv, [ --with-libiconv     Use the libiconv library ],,with_libiconv=maybe)
1410
1411 found_iconv=no
1412
1413 if test "x$with_libiconv" != "xyes" ; then
1414    #
1415    # Check in the C library
1416    #
1417    AC_CHECK_FUNC(iconv_open, with_libiconv=no; found_iconv=yes)
1418 fi
1419
1420 if test "x$with_libiconv" != "xno" ; then
1421    #
1422    # Check for libiconv
1423    #
1424    AC_CHECK_LIB(iconv, libiconv_open, with_libiconv=yes; found_iconv=yes)
1425 fi
1426
1427 if test "x$found_iconv" = "xno" ; then
1428    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
1429 fi
1430
1431 if test "x$with_libiconv" = "xyes" ; then
1432   ICONV_LIBS="-liconv"
1433   AC_DEFINE(USE_LIBICONV)
1434 fi
1435 AC_SUBST(ICONV_LIBS)
1436
1437 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
1438 dnl since we need it for g_iconv()
1439
1440 AC_MSG_CHECKING([for EILSEQ])
1441 AC_TRY_COMPILE([
1442 #include <errno.h>
1443 ],
1444 [
1445 int error = EILSEQ;
1446 ], have_eilseq=yes, have_eilseq=no);
1447 AC_MSG_RESULT($have_eilseq)
1448
1449 dnl **************************
1450 dnl *** Checks for gtk-doc ***
1451 dnl **************************
1452
1453 AC_ARG_WITH(html-dir, [  --with-html-dir=PATH path to installed docs ])
1454
1455 if test "x$with_html_dir" = "x" ; then
1456   HTML_DIR='${datadir}/gtk-doc/html'
1457 else
1458   HTML_DIR=$with_html_dir
1459 fi
1460
1461 AC_SUBST(HTML_DIR)
1462
1463 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
1464
1465 gtk_doc_min_version=0.6
1466 if $GTKDOC ; then
1467     gtk_doc_version=`gtkdoc-mkdb --version`
1468     AC_MSG_CHECKING([gtk-doc version ($gtk_doc_version) >= $gtk_doc_min_version])
1469     if perl <<EOF ; then
1470       exit (("$gtk_doc_version" =~ /^[[0-9]]+\.[[0-9]]+$/) &&
1471             ("$gtk_doc_version" >= "$gtk_doc_min_version") ? 0 : 1);
1472 EOF
1473       AC_MSG_RESULT(yes)
1474    else
1475       AC_MSG_RESULT(no)
1476       GTKDOC=false
1477    fi
1478 fi
1479
1480 AM_CONDITIONAL(HAVE_GTK_DOC, $GTKDOC)
1481 AC_SUBST(HAVE_GTK_DOC)
1482
1483 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1484 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1485
1486 dnl Let people disable the gtk-doc stuff.
1487 AC_ARG_ENABLE(gtk-doc, [  --enable-gtk-doc  Use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)
1488
1489 if test x$enable_gtk_doc = xauto ; then
1490   if test x$GTKDOC = xtrue ; then
1491     enable_gtk_doc=yes
1492   else
1493     enable_gtk_doc=no
1494   fi
1495 fi
1496
1497 dnl NOTE: We need to use a separate automake conditional for this
1498 dnl       to make this work with the tarballs.
1499 AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
1500
1501 dnl ******************************
1502 dnl *** output the whole stuff ***
1503 dnl ******************************
1504
1505 AC_OUTPUT_COMMANDS([
1506
1507 ## Generate `glibconfig.h' in two cases
1508 ## 1. `config.status' is run either explicitly, or via configure.
1509 ##     Esp. not when it is run in `Makefile' to generate makefiles and
1510 ##     config.h
1511 ## 2. CONFIG_OTHER is set explicitly
1512 ##
1513 ## Case 1 is difficult.  We know that `automake' sets one of
1514 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
1515 ## only when AM_CONFIG_HEADER is set, however.
1516
1517 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
1518   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
1519   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
1520 fi
1521 case "$CONFIG_OTHER" in
1522 *glibconfig.h*)
1523         echo creating glibconfig.h
1524         outfile=glibconfig.h-tmp
1525         cat > $outfile <<\_______EOF
1526 /* glibconfig.h
1527  *
1528  * This is a generated file.  Please modify 'configure.in'
1529  */
1530
1531 #ifndef __G_LIBCONFIG_H__
1532 #define __G_LIBCONFIG_H__
1533
1534 #include <gmacros.h>
1535
1536 _______EOF
1537
1538         if test x$glib_limits_h = xyes; then
1539           echo '#include <limits.h>' >> $outfile
1540         fi
1541         if test x$glib_float_h = xyes; then
1542           echo '#include <float.h>' >> $outfile
1543         fi
1544         if test x$glib_values_h = xyes; then
1545           echo '#include <values.h>' >> $outfile
1546         fi
1547         if test "$glib_header_alloca_h" = "yes"; then
1548           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
1549         fi
1550         if test x$glib_sys_poll_h = xyes; then
1551           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
1552         fi
1553
1554         cat >> $outfile <<_______EOF
1555
1556 G_BEGIN_DECLS
1557
1558 #define G_MINFLOAT      $glib_mf
1559 #define G_MAXFLOAT      $glib_Mf
1560 #define G_MINDOUBLE     $glib_md
1561 #define G_MAXDOUBLE     $glib_Md
1562 #define G_MINSHORT      $glib_ms
1563 #define G_MAXSHORT      $glib_Ms
1564 #define G_MAXUSHORT     $glib_Mus
1565 #define G_MININT        $glib_mi
1566 #define G_MAXINT        $glib_Mi
1567 #define G_MAXUINT       $glib_Mui
1568 #define G_MINLONG       $glib_ml
1569 #define G_MAXLONG       $glib_Ml
1570 #define G_MAXULONG      $glib_Mul
1571
1572 _______EOF
1573
1574
1575         ### this should always be true in a modern C/C++ compiler
1576         cat >>$outfile <<_______EOF
1577 typedef signed char gint8;
1578 typedef unsigned char guint8;
1579 _______EOF
1580
1581
1582         if test -n "$gint16"; then
1583           cat >>$outfile <<_______EOF
1584 typedef signed $gint16 gint16;
1585 typedef unsigned $gint16 guint16;
1586 #define G_GINT16_FORMAT $gint16_format
1587 #define G_GUINT16_FORMAT $guint16_format
1588 _______EOF
1589         fi
1590
1591
1592         if test -n "$gint32"; then
1593           cat >>$outfile <<_______EOF
1594 typedef signed $gint32 gint32;
1595 typedef unsigned $gint32 guint32;
1596 #define G_GINT32_FORMAT $gint32_format
1597 #define G_GUINT32_FORMAT $guint32_format
1598 _______EOF
1599         fi
1600
1601
1602         if test -n "$gint64"; then
1603           cat >>$outfile <<_______EOF
1604 #define G_HAVE_GINT64 1
1605
1606 ${glib_extension}typedef signed $gint64 gint64;
1607 ${glib_extension}typedef unsigned $gint64 guint64;
1608
1609 #define G_GINT64_CONSTANT(val)  $gint64_constant
1610 _______EOF
1611                 if test -n "$gint64_format"; then
1612           cat >>$outfile <<_______EOF
1613 #define G_GINT64_FORMAT $gint64_format
1614 #define G_GUINT64_FORMAT $guint64_format
1615 _______EOF
1616                 fi
1617         fi
1618
1619         cat >>$outfile <<_______EOF
1620
1621 #define GLIB_SIZEOF_VOID_P $glib_void_p
1622 #define GLIB_SIZEOF_LONG   $glib_long
1623
1624 _______EOF
1625
1626         case x$glib_size_t in
1627         x2) echo "typedef gint16  gssize;" >> $outfile
1628             echo "typedef guint16 gsize;"  >> $outfile
1629             ;;
1630         x4) echo "typedef gint32  gssize;" >> $outfile
1631             echo "typedef guint32 gsize;"  >> $outfile
1632             ;;
1633         x8) echo "typedef gint64  gssize;" >> $outfile
1634             echo "typedef guint64 gsize;"  >> $outfile
1635             ;;
1636         *)  echo "#error size of size_t is unknown" >> $outfile
1637             ;;
1638         esac
1639
1640         if test -z "$glib_unknown_void_p"; then
1641           cat >>$outfile <<_______EOF
1642
1643 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
1644 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
1645
1646 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
1647 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
1648 _______EOF
1649         else
1650           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
1651         fi
1652
1653
1654
1655         cat >>$outfile <<_______EOF
1656 $glib_atexit
1657 $glib_memmove
1658 $glib_defines
1659 $glib_os
1660
1661 $glib_vacopy
1662
1663 #ifdef  __cplusplus
1664 #define G_HAVE_INLINE   1
1665 #else   /* !__cplusplus */
1666 $glib_inline
1667 #endif  /* !__cplusplus */
1668 _______EOF
1669
1670         if test x$g_have_iso_c_varargs = xyes ; then
1671                 cat >>$outfile <<_______EOF
1672
1673 #define G_HAVE_ISO_C_VARARGS 1
1674 _______EOF
1675         fi
1676         if test x$g_have_iso_cxx_varargs = xyes ; then
1677                 cat >>$outfile <<_______EOF
1678
1679 #define G_HAVE_ISO_CXX_VARARGS 1
1680 _______EOF
1681         fi
1682         cat >>$outfile <<_______EOF
1683
1684 #if (defined(__cplusplus) ? defined(G_HAVE_ISO_CXX_VARARGS) : defined(G_HAVE_ISO_C_VARARGS))
1685 # define G_HAVE_ISO_VARARGS 1
1686 #endif
1687 _______EOF
1688
1689         if test x$g_have_gnuc_varargs = xyes ; then
1690                 cat >>$outfile <<_______EOF
1691
1692 #define G_HAVE_GNUC_VARARGS 1
1693 _______EOF
1694         fi
1695
1696         echo >>$outfile
1697         if test x$g_have_eilseq = xno; then
1698                 cat >>$outfile <<_______EOF
1699 #ifndef EILSEQ
1700 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
1701  * The correspondence between this and the corresponding definition
1702  * in libiconv is essential.
1703  */
1704 #  define EILSEQ ENOENT
1705 #endif
1706 _______EOF
1707
1708         fi
1709
1710         echo >>$outfile
1711         if test x$g_mutex_has_default = xyes; then
1712                 cat >>$outfile <<_______EOF
1713 $g_enable_threads_def G_THREADS_ENABLED
1714 #define G_THREADS_IMPL_$g_threads_impl_def
1715 typedef struct _GStaticMutex GStaticMutex;
1716 struct _GStaticMutex
1717 {
1718   struct _GMutex *runtime_mutex;
1719   union {
1720     char   pad[$g_mutex_sizeof];
1721     double dummy_double;
1722     void  *dummy_pointer;
1723     long   dummy_long;
1724   } static_mutex;
1725 };
1726 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
1727 #define g_static_mutex_get_mutex(mutex) \
1728   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->static_mutex)) : \
1729    g_static_mutex_get_mutex_impl (&((mutex)->runtime_mutex)))
1730 _______EOF
1731         else
1732                 cat >>$outfile <<_______EOF
1733 $g_enable_threads_def G_THREADS_ENABLED
1734 #define G_THREADS_IMPL_$g_threads_impl_def
1735 typedef struct _GMutex* GStaticMutex;
1736 #define G_STATIC_MUTEX_INIT NULL
1737 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (mutex))
1738 _______EOF
1739         fi
1740
1741         cat >>$outfile <<_______EOF
1742 /* This represents a system thread as used by the implementation. An
1743  * alien implementaion, as loaded by g_thread_init can only count on
1744  * "sizeof (gpointer)" bytes to store their info. We however need more
1745  * for some of our native implementations. */
1746 typedef union _GSystemThread GSystemThread;
1747 union _GSystemThread
1748 {
1749   char   data[$g_system_thread_sizeof];
1750   double dummy_double;
1751   void  *dummy_pointer;
1752   long   dummy_long;
1753 };
1754 _______EOF
1755
1756         echo >>$outfile
1757         g_bit_sizes="16 32"
1758         if test -n "$gint64"; then
1759           g_bit_sizes="$g_bit_sizes 64"
1760         fi
1761         for bits in $g_bit_sizes; do
1762           cat >>$outfile <<_______EOF
1763 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
1764 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
1765 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
1766 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
1767 _______EOF
1768         done
1769
1770         cat >>$outfile <<_______EOF
1771 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
1772 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
1773 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
1774 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
1775 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
1776 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
1777 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
1778 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
1779 #define G_BYTE_ORDER $g_byte_order
1780
1781 _______EOF
1782
1783         if test -r glibconfig-sysdefs.h; then
1784           cat glibconfig-sysdefs.h >>$outfile
1785         fi
1786
1787         cat >>$outfile <<_______EOF
1788
1789 #define G_MODULE_SUFFIX "$g_module_suffix"
1790
1791 G_END_DECLS
1792
1793 #endif /* GLIBCONFIG_H */
1794 _______EOF
1795
1796
1797         if cmp -s $outfile glibconfig.h; then
1798           echo glibconfig.h is unchanged
1799           rm -f $outfile
1800         else
1801           mv $outfile glibconfig.h
1802         fi ;;
1803 esac
1804 ],[
1805
1806 # Note that if two cases are the same, case goes with the first one.
1807 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
1808 # on variable expansion in case labels.  Look at the generated config.status
1809 # for a hint.
1810
1811 glib_header_alloca_h="$ac_cv_header_alloca_h"
1812
1813 case xyes in
1814 x$ac_cv_header_float_h)
1815   glib_float_h=yes
1816   glib_mf=FLT_MIN glib_Mf=FLT_MAX
1817   glib_md=DBL_MIN glib_Md=DBL_MAX
1818   ;;
1819 x$ac_cv_header_values_h)
1820   glib_values_h=yes
1821   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
1822   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
1823   ;;
1824 esac
1825
1826 case xyes in
1827 x$ac_cv_header_limits_h)
1828   glib_limits_h=yes
1829   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
1830   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
1831   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
1832   ;;
1833 x$ac_cv_header_values_h)
1834   glib_values_h=yes
1835   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
1836   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
1837   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
1838   ;;
1839 esac
1840
1841 if test x$ac_cv_header_sys_poll_h = xyes ; then
1842   glib_sys_poll_h=yes
1843 fi
1844
1845 case 2 in
1846 $ac_cv_sizeof_short)
1847   gint16=short
1848   gint16_format='"hi"'
1849   guint16_format='"hu"'
1850   ;;
1851 $ac_cv_sizeof_int)
1852   gint16=int
1853   gint16_format='"i"'
1854   guint16_format='"u"'
1855   ;;
1856 esac
1857 case 4 in
1858 $ac_cv_sizeof_short)
1859   gint32=short
1860   gint32_format='"hi"'
1861   guint32_format='"hu"'
1862   ;;
1863 $ac_cv_sizeof_int)
1864   gint32=int
1865   gint32_format='"i"'
1866   guint32_format='"u"'
1867   ;;
1868 $ac_cv_sizeof_long)
1869   gint32=long
1870   gint32_format='"li"'
1871   guint32_format='"lu"'
1872   ;;
1873 esac
1874 case 8 in
1875 $ac_cv_sizeof_int)
1876   gint64=int
1877   gint64_format='"i"'
1878   guint64_format='"u"'
1879   glib_extension=
1880   gint64_constant='(val)'
1881   ;;
1882 $ac_cv_sizeof_long)
1883   gint64=long
1884   gint64_format='"li"'
1885   guint64_format='"lu"'
1886   glib_extension=
1887   gint64_constant='(val##L)'
1888   ;;
1889 $ac_cv_sizeof_long_long)
1890   gint64='long long'
1891   if test -n "$glib_cv_long_long_format"; then
1892     gint64_format='"'$glib_cv_long_long_format'i"'
1893     guint64_format='"'$glib_cv_long_long_format'u"'
1894   fi
1895   glib_extension='G_GNUC_EXTENSION '
1896   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1897   ;;
1898 esac
1899 glib_size_t=$glib_cv_sizeof_size_t
1900 glib_void_p=$ac_cv_sizeof_long
1901 glib_long=$ac_cv_sizeof_void_p
1902
1903 gintbits=`expr $ac_cv_sizeof_int \* 8`
1904 glongbits=`expr $ac_cv_sizeof_long \* 8`
1905
1906
1907 case $ac_cv_sizeof_void_p in
1908 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
1909 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
1910 *)                      glib_unknown_void_p=yes ;;
1911 esac
1912
1913
1914 case xyes in
1915 x$ac_cv_func_atexit)
1916   glib_atexit="
1917 #ifdef NeXT /* @#%@! NeXTStep */
1918 # define g_ATEXIT(proc) (!atexit (proc))
1919 #else
1920 # define g_ATEXIT(proc) (atexit (proc))
1921 #endif"
1922   ;;
1923 x$ac_cv_func_on_exit)
1924   glib_atexit="
1925 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
1926   ;;
1927 esac
1928
1929 case xyes in
1930 x$ac_cv_func_memmove)
1931   glib_memmove='
1932 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
1933   ;;
1934 x$glib_cv_working_bcopy)
1935   glib_memmove="
1936 /* memmove isn't available, but bcopy can copy overlapping memory regions */
1937 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
1938   ;;
1939 *)
1940   glib_memmove="
1941 /* memmove isn't found and bcopy can't copy overlapping memory regions,
1942  * so we have to roll our own copy routine. */
1943 void g_memmove (void* dest, const void * src, unsigned long len);"
1944   ;;
1945 esac
1946
1947 glib_defines="
1948 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
1949 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
1950 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
1951 "
1952
1953 case xyes in
1954 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
1955 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
1956 *)                      glib_vacopy=''
1957 esac
1958
1959 if test x$glib_cv_va_val_copy = xno; then
1960   glib_vacopy="\$glib_vacopy
1961 #define G_VA_COPY_AS_ARRAY 1"
1962 fi
1963
1964 if test x$glib_cv_hasinline = xyes; then
1965     glib_inline='#define G_HAVE_INLINE 1'
1966 fi
1967 if test x$glib_cv_has__inline = xyes; then
1968     glib_inline="\$glib_inline
1969 #define G_HAVE___INLINE 1"
1970 fi
1971 if test x$glib_cv_has__inline__ = xyes; then
1972     glib_inline="\$glib_inline
1973 #define G_HAVE___INLINE__ 1"
1974 fi
1975
1976 g_have_gnuc_varargs=$g_have_gnuc_varargs
1977 g_have_iso_c_varargs=$g_have_iso_c_varargs
1978 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
1979
1980 case xyes in
1981 x$ac_cv_c_bigendian)
1982   g_byte_order=G_BIG_ENDIAN
1983   g_bs_native=BE
1984   g_bs_alien=LE
1985   ;;
1986 *)
1987   g_byte_order=G_LITTLE_ENDIAN
1988   g_bs_native=LE
1989   g_bs_alien=BE
1990   ;;
1991 esac
1992
1993 g_have_eilseq=$have_eilseq
1994
1995 case x$have_threads in
1996 xnone)  g_enable_threads_def="#undef";;
1997 *)      g_enable_threads_def="#define";;
1998 esac
1999
2000 g_threads_impl_def=$g_threads_impl
2001
2002 g_mutex_has_default="$mutex_has_default"
2003 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
2004 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
2005 g_mutex_contents="$glib_cv_byte_contents_gmutex"
2006
2007 g_module_suffix="$glib_gmodule_suffix"
2008
2009 case $host in
2010   *-*-beos*)
2011     glib_os="#define G_OS_BEOS"
2012     ;;
2013   *-*-cygwin*)
2014     glib_os="#define G_OS_UNIX
2015 #define G_PLATFORM_WIN32
2016 #define G_WITH_CYGWIN"
2017     ;;
2018   *-*-mingw*)
2019     glib_os="#define G_OS_WIN32
2020 #define G_PLATFORM_WIN32"
2021     ;;
2022   *)
2023     glib_os="#define G_OS_UNIX"
2024     ;;
2025 esac
2026 ])
2027
2028 AC_OUTPUT([
2029 glib-2.0.pc
2030 glib-config-2.0
2031 gmodule-2.0.pc
2032 gthread-2.0.pc
2033 gobject-2.0.pc
2034 glib.spec
2035 Makefile
2036 build/Makefile
2037 build/win32/Makefile
2038 gmodule/gmoduleconf.h
2039 gmodule/Makefile
2040 gobject/Makefile
2041 gthread/Makefile
2042 po/Makefile.in
2043 docs/Makefile
2044 docs/glib-config.1
2045 docs/reference/Makefile
2046 docs/reference/glib/Makefile
2047 docs/reference/gobject/Makefile
2048 tests/Makefile
2049 m4macros/Makefile
2050 ],[case "$CONFIG_FILES" in
2051 *glib-config-2.0*)chmod +x glib-config-2.0;;
2052 esac
2053 echo ""
2054 echo " *** IMPORTANT *** "
2055 echo ""
2056 echo "This is a development version of GLib.  You should be using a stable"
2057 echo "version, which is available at ftp://ftp.gtk.org/pub/gtk/v1.2/.  The"
2058 echo "version you just configured is meant for developers of GLib only:"
2059 echo ""
2060 echo "  * You should not base stable software on this version of GLib."
2061 echo "  * GNOME developers should use a stable version of GLib."
2062 echo ""
2063 echo " *** You should be using GLib 1.2 instead. ***"
2064 ])