configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5
   6 # require autoconf 2.13
   7 AC_PREREQ(2.13)
   8
   9 # Process this file with autoconf to produce a configure script.
  10 AC_INIT(glist.c)
  11
  12 # Save this value here, since automake will set cflags later
  13 cflags_set=${CFLAGS+set}
  14
  15 # we rewrite this file
  16 rm -f glibconfig-sysdefs.h
  17
  18 dnl we to AC_DIVERT_PUSH/AC_DIVERT_POP these variable definitions so they
  19 dnl are available for $ac_help expansion (don't we all *love* autoconf?)
  20 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  21 #
  22 # The following version number definitions apply to GLib and GModule
  23 # as a whole, so if changes occoured in either of them, they are both
  24 # treated with the same interface and binary age.
  25 #
  26 # Making releases:
  27 #   GLIB_MICRO_VERSION += 1;
  28 #   GLIB_INTERFACE_AGE += 1;
  29 #   GLIB_BINARY_AGE += 1;
  30 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  31 # if backwards compatibility has been broken,
  32 # set GLIB_BINARY_AGE and GLIB_INTERFACE_AGE to 0.
  33 #
  34 GLIB_MAJOR_VERSION=1
  35 GLIB_MINOR_VERSION=3
  36 GLIB_MICRO_VERSION=0
  37 GLIB_INTERFACE_AGE=0
  38 GLIB_BINARY_AGE=0
  39 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  40 dnl
  41 AC_DIVERT_POP()dnl
  42
  43 AC_SUBST(GLIB_VERSION)
  44
  45 # libtool versioning
  46 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  47 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  48 LT_REVISION=$GLIB_INTERFACE_AGE
  49 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  50 AC_SUBST(LT_RELEASE)
  51 AC_SUBST(LT_CURRENT)
  52 AC_SUBST(LT_REVISION)
  53 AC_SUBST(LT_AGE)
  54
  55 VERSION=$GLIB_VERSION
  56 PACKAGE=glib
  57
  58 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  59
  60 # Specify a configuration file
  61 AM_CONFIG_HEADER(config.h)
  62
  63 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION)
  64 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION)
  65 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION)
  66 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE)
  67 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE)
  68
  69 dnl Initialize libtool
  70 AM_PROG_LIBTOOL
  71
  72 dnl Initialize maintainer mode
  73 AM_MAINTAINER_MODE
  74
  75 AC_CANONICAL_HOST
  76
  77 dnl figure debugging default, prior to $ac_help setup
  78 dnl
  79 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  80 if test `expr $GLIB_MINOR_VERSION \% 2` = 1 ; then
  81         debug_default=yes
  82 else
  83         debug_default=minimum
  84 fi
  85 AC_DIVERT_POP()dnl
  86
  87 dnl declare --enable-* args and collect ac_help strings
  88 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
  89 AC_ARG_ENABLE(mem_check, [  --enable-mem-check      turn on malloc/free sanity checking [default=no]],,enable_mem_check=no)
  90 AC_ARG_ENABLE(mem_profile, [  --enable-mem-profile    turn on malloc profiling atexit [default=no]],,enable_mem_profile=no)
  91 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
  92                     , enable_ansi=no)
  93 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
  94                           ([=no] will override --with-threads)],,enable_threads=yes)
  95
  96 if test "x$enable_threads" != "xyes"; then
  97   enable_threads=no
  98 fi
  99
 100 AC_MSG_CHECKING(whether to enable memory checking)
 101 if test "x$enable_mem_check" = "xyes"; then
 102   AC_DEFINE(ENABLE_MEM_CHECK, 1)
 103   AC_SUBST(ENABLE_MEM_CHECK)
 104   AC_MSG_RESULT(yes)
 105 else
 106   AC_MSG_RESULT(no)
 107 fi
 108
 109 AC_MSG_CHECKING(whether to enable memory profiling)
 110 if test "x$enable_mem_profile" = "xyes"; then
 111   AC_DEFINE(ENABLE_MEM_PROFILE, 1)
 112   AC_SUBST(ENABLE_MEM_PROFILE)
 113   AC_MSG_RESULT(yes)
 114 else
 115   AC_MSG_RESULT(no)
 116 fi
 117
 118 if test "x$enable_debug" = "xyes"; then
 119   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 120   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 121 else
 122   if test "x$enable_debug" = "xno"; then
 123     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 124   fi
 125 fi
 126
 127 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 128
 129 # Checks for programs.
 130 AC_PROG_CC
 131 AM_PROG_CC_STDC
 132 AC_PROG_INSTALL
 133
 134 changequote(,)dnl
 135 if test "x$GCC" = "xyes"; then
 136   case " $CFLAGS " in
 137   *[\ \ ]-Wall[\ \      ]*) ;;
 138   *) CFLAGS="$CFLAGS -Wall" ;;
 139   esac
 140
 141   if test "x$enable_ansi" = "xyes"; then
 142     case " $CFLAGS " in
 143     *[\ \       ]-ansi[\ \      ]*) ;;
 144     *) CFLAGS="$CFLAGS -ansi" ;;
 145     esac
 146
 147     case " $CFLAGS " in
 148     *[\ \       ]-pedantic[\ \  ]*) ;;
 149     *) CFLAGS="$CFLAGS -pedantic" ;;
 150     esac
 151   fi
 152 fi
 153 changequote([,])dnl
 154
 155 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 156 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 157 glib_save_LIBS=$LIBS
 158 LIBS="$LIBS -lm"
 159 AC_TRY_RUN([#include <math.h>
 160              int main (void) { return (log(1) != log(1.)); }],
 161      AC_MSG_RESULT(none needed),
 162      glib_save_CFLAGS=$CFLAGS
 163      CFLAGS="$CFLAGS -std1"
 164      AC_TRY_RUN([#include <math.h>
 165                  int main (void) { return (log(1) != log(1.)); }],
 166          AC_MSG_RESULT(-std1),
 167          AC_MSG_RESULT()
 168          CFLAGS=$glib_save_CFLAGS
 169          AC_MSG_WARN(
 170                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 171      )
 172 )
 173 LIBS=$glib_save_LIBS
 174
 175 dnl NeXTStep cc seems to need this
 176 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 177 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 178   AC_MSG_RESULT(none needed),
 179   glib_save_CFLAGS=$CFLAGS
 180   CFLAGS="$CFLAGS -posix"
 181   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 182     AC_MSG_RESULT(-posix),
 183     AC_MSG_RESULT()
 184     CFLAGS=$glib_save_CFLAGS
 185     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 186
 187 # Checks for header files.
 188 AC_HEADER_STDC
 189
 190 # Checks for library functions.
 191 AC_FUNC_VPRINTF
 192
 193 AC_CHECK_FUNCS(atexit on_exit)
 194
 195 AC_CHECK_SIZEOF(char)
 196 AC_CHECK_SIZEOF(short)
 197 AC_CHECK_SIZEOF(long)
 198 AC_CHECK_SIZEOF(int)
 199 AC_CHECK_SIZEOF(void *)
 200 AC_CHECK_SIZEOF(long long)
 201
 202 dnl long doubles were not used, and a portability problem
 203 dnl AC_C_LONG_DOUBLE
 204 AC_C_CONST
 205
 206 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 207 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 208 dnl actually supported.
 209 AC_MSG_CHECKING(for __inline)
 210 AC_CACHE_VAL(glib_cv_has__inline,[
 211         AC_TRY_RUN([
 212         __inline int foo () { return 0; }
 213         int main () { return foo (); }
 214         ],
 215         glib_cv_has__inline=yes
 216         ,
 217         glib_cv_has__inline=no
 218         ,)
 219 ])
 220 AC_MSG_RESULT($glib_cv_has__inline)
 221 case x$glib_cv_has__inline in
 222 xyes) AC_DEFINE(G_HAVE___INLINE)
 223 esac
 224 AC_MSG_CHECKING(for __inline__)
 225 AC_CACHE_VAL(glib_cv_has__inline__,[
 226         AC_TRY_RUN([
 227         __inline__ int foo () { return 0; }
 228         int main () { return foo (); }
 229         ],
 230         glib_cv_has__inline__=yes
 231         ,
 232         glib_cv_has__inline__=no
 233         ,)
 234 ])
 235 AC_MSG_RESULT($glib_cv_has__inline__)
 236 case x$glib_cv_has__inline__ in
 237 xyes) AC_DEFINE(G_HAVE___INLINE__)
 238 esac
 239 AC_MSG_CHECKING(for inline)
 240 AC_CACHE_VAL(glib_cv_hasinline,[
 241         AC_TRY_RUN([
 242         inline int foo () { return 0; }
 243         int main () { return foo (); }
 244         ],
 245         glib_cv_hasinline=yes
 246         ,
 247         glib_cv_hasinline=no
 248         ,)
 249 ])
 250 AC_MSG_RESULT($glib_cv_hasinline)
 251 case x$glib_cv_hasinline in
 252 xyes) AC_DEFINE(G_HAVE_INLINE)
 253 esac
 254
 255 dnl for bytesex stuff
 256 AC_C_BIGENDIAN
 257
 258 dnl header file checks
 259 AC_CHECK_HEADERS(float.h, AC_DEFINE(HAVE_FLOAT_H))
 260 AC_CHECK_HEADERS(limits.h, AC_DEFINE(HAVE_LIMITS_H))
 261 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 262 AC_CHECK_HEADERS(sys/param.h, AC_DEFINE(HAVE_SYS_PARAM_H))
 263 AC_CHECK_HEADERS(sys/poll.h, AC_DEFINE(HAVE_SYS_POLL_H))
 264 AC_CHECK_HEADERS(sys/select.h, AC_DEFINE(HAVE_SYS_SELECT_H))
 265 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 266 AC_CHECK_HEADERS(sys/times.h, AC_DEFINE(HAVE_SYS_TIMES_H))
 267 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 268 AC_CHECK_HEADERS(values.h, AC_DEFINE(HAVE_VALUES_H))
 269
 270 # Check for some functions
 271 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf strcasecmp strncasecmp poll)
 272
 273 # Check for sys_errlist
 274 AC_MSG_CHECKING(for sys_errlist)
 275 AC_TRY_LINK(, [
 276 extern char *sys_errlist[];
 277 extern int sys_nerr;
 278 sys_errlist[sys_nerr-1][0] = 0;
 279 ], glib_ok=yes, glib_ok=no)
 280 AC_MSG_RESULT($glib_ok)
 281 if test $glib_ok = no; then
 282     AC_DEFINE(NO_SYS_ERRLIST)
 283 fi
 284
 285 # Check for sys_siglist
 286 AC_MSG_CHECKING(for sys_siglist)
 287 AC_TRY_LINK(, [
 288 extern char *sys_siglist[];
 289 strlen (sys_siglist[0]);
 290 ], glib_ok=yes, glib_ok=no)
 291 AC_MSG_RESULT($glib_ok)
 292 if test $glib_ok = no; then
 293     AC_DEFINE(NO_SYS_SIGLIST)
 294 fi
 295
 296 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 297 AC_MSG_CHECKING(for sys_siglist declaration)
 298 AC_TRY_COMPILE([#include <signal.h>], [
 299 strlen (sys_siglist[0]);
 300 ], glib_ok=yes, glib_ok=no)
 301 AC_MSG_RESULT($glib_ok)
 302 if test $glib_ok = no; then
 303     AC_DEFINE(NO_SYS_SIGLIST_DECL)
 304 fi
 305
 306 # Check if <sys/select.h> needs to be included for fd_set
 307 AC_MSG_CHECKING([for fd_set])
 308 AC_TRY_COMPILE([#include <sys/types.h>],
 309         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 310 if test $gtk_ok = yes; then
 311     AC_MSG_RESULT([yes, found in sys/types.h])
 312 else
 313     AC_HEADER_EGREP(fd_set, sys/select.h, gtk_ok=yes)
 314     if test $gtk_ok = yes; then
 315         AC_DEFINE(HAVE_SYS_SELECT_H)
 316         AC_MSG_RESULT([yes, found in sys/select.h])
 317     else
 318         AC_DEFINE(NO_FD_SET)
 319         AC_MSG_RESULT(no)
 320     fi
 321 fi
 322
 323 dnl *** check for sane realloc() ***
 324 AC_MSG_CHECKING(whether realloc (NULL,) will work)
 325 AC_CACHE_VAL(glib_cv_sane_realloc,[
 326         AC_TRY_RUN([
 327         #include <stdlib.h>
 328         int main() {
 329           return realloc (0, sizeof (int)) == 0;
 330         }],
 331         glib_cv_sane_realloc=yes
 332         AC_DEFINE(REALLOC_0_WORKS)
 333         ,
 334         glib_cv_sane_realloc=no
 335         ,)
 336 ])
 337 AC_MSG_RESULT($glib_cv_sane_realloc)
 338
 339
 340 dnl **********************
 341 dnl *** va_copy checks ***
 342 dnl **********************
 343 dnl we currently check for all three va_copy possibilities, so we get
 344 dnl all results in config.log for bug reports.
 345 AC_MSG_CHECKING(for an implementation of va_copy())
 346 AC_CACHE_VAL(glib_cv_va_copy,[
 347         AC_TRY_RUN([
 348         #include <stdarg.h>
 349         void f (int i, ...) {
 350         va_list args1, args2;
 351         va_start (args1, i);
 352         va_copy (args2, args1);
 353         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 354           exit (1);
 355         va_end (args1); va_end (args2);
 356         }
 357         int main() {
 358           f (0, 42);
 359           return 0;
 360         }],
 361         glib_cv_va_copy=yes
 362         ,
 363         glib_cv_va_copy=no
 364         ,)
 365 ])
 366 AC_MSG_RESULT($glib_cv_va_copy)
 367 AC_MSG_CHECKING(for an implementation of __va_copy())
 368 AC_CACHE_VAL(glib_cv___va_copy,[
 369         AC_TRY_RUN([
 370         #include <stdarg.h>
 371         void f (int i, ...) {
 372         va_list args1, args2;
 373         va_start (args1, i);
 374         __va_copy (args2, args1);
 375         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 376           exit (1);
 377         va_end (args1); va_end (args2);
 378         }
 379         int main() {
 380           f (0, 42);
 381           return 0;
 382         }],
 383         glib_cv___va_copy=yes
 384         ,
 385         glib_cv___va_copy=no
 386         ,)
 387 ])
 388 AC_MSG_RESULT($glib_cv___va_copy)
 389 AC_MSG_CHECKING(whether va_lists can be copied by value)
 390 AC_CACHE_VAL(glib_cv_va_val_copy,[
 391         AC_TRY_RUN([
 392         #include <stdarg.h>
 393         void f (int i, ...) {
 394         va_list args1, args2;
 395         va_start (args1, i);
 396         args2 = args1;
 397         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 398           exit (1);
 399         va_end (args1); va_end (args2);
 400         }
 401         int main() {
 402           f (0, 42);
 403           return 0;
 404         }],
 405         glib_cv_va_val_copy=yes
 406         ,
 407         glib_cv_va_val_copy=no
 408         ,)
 409 ])
 410 if test "x$glib_cv_va_copy" = "xyes"; then
 411   AC_DEFINE(G_VA_COPY, va_copy)
 412 else if test "x$glib_cv___va_copy" = "xyes"; then
 413   AC_DEFINE(G_VA_COPY, __va_copy)
 414 fi
 415 fi
 416 if test "x$glib_cv_va_val_copy" = "xno"; then
 417   AC_DEFINE(G_VA_COPY_AS_ARRAY)
 418 fi
 419 AC_MSG_RESULT($glib_cv_va_val_copy)
 420
 421
 422 dnl ***********************
 423 dnl *** g_module checks ***
 424 dnl ***********************
 425 G_MODULE_LIBS=
 426 G_MODULE_LDFLAGS=
 427 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
 428 G_MODULE_NEED_USCORE=0
 429 G_MODULE_HAVE_DLERROR=0
 430 dnl *** dlopen() and dlsym() in system libraries
 431 if test -z "$G_MODULE_IMPL"; then
 432         AC_CHECK_FUNC(dlopen,
 433                 AC_CHECK_FUNC(dlsym,
 434                         G_MODULE_IMPL=G_MODULE_IMPL_DL
 435                 ,)
 436         ,)
 437 fi
 438 dnl *** dlopen() and dlsym() in libdl
 439 if test -z "$G_MODULE_IMPL"; then
 440         AC_CHECK_LIB(dl, dlopen,
 441                 AC_CHECK_LIB(dl, dlsym,
 442                         G_MODULE_LIBS=-ldl
 443                         G_MODULE_IMPL=G_MODULE_IMPL_DL
 444                 ,)
 445         ,)
 446 fi
 447 dnl *** shl_load() in libdld (HP-UX)
 448 if test -z "$G_MODULE_IMPL"; then
 449         AC_MSG_CHECKING(how to export all symbols)
 450         SAVED_LDFLAGS=$LDFLAGS
 451         LDFLAGS="$LDFLAGS -Wl,-E"
 452         AC_TRY_LINK(,[ return 0; ],
 453                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 454                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 455                 AC_TRY_LINK(,[ return 0; ],
 456                         G_MODULE_LDFLAGS="-bexpall",
 457                         G_MODULE_LDFLAGS="none"
 458                 )
 459         ])
 460         LDFLAGS=$SAVED_LDFLAGS
 461         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 462         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 463                 G_MODULE_LDFLAGS=
 464         fi
 465         AC_CHECK_LIB(dld, shl_load,
 466                 G_MODULE_LIBS=-ldld
 467                 G_MODULE_IMPL=G_MODULE_IMPL_DLD
 468         ,)
 469 fi
 470 dnl *** additional checks for G_MODULE_IMPL_DL
 471 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 472         case "$host_os" in
 473           linux*)
 474             G_MODULE_LDFLAGS='-rdynamic'
 475             ;;
 476         esac
 477         LIBS_orig="$LIBS"
 478         LDFLAGS_orig="$LDFLAGS"
 479         LIBS="$LIBS $G_MODULE_LIBS"
 480         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 481 dnl *** check whether we need preceeding underscores
 482         AC_MSG_CHECKING(for preceeding underscore in symbols)
 483         AC_CACHE_VAL(glib_cv_uscore,[
 484                 AC_TRY_RUN([
 485                 #include <dlfcn.h>
 486                 int glib_underscore_test (void) { return 42; }
 487                 int main() {
 488                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 489                   handle = dlopen ((void*)0, 0);
 490                   if (handle) {
 491                     f1 = dlsym (handle, "glib_underscore_test");
 492                     f2 = dlsym (handle, "_glib_underscore_test");
 493                   } return (!f2 || f1);
 494                 }],
 495                         glib_cv_uscore=yes,
 496                         glib_cv_uscore=no,
 497                 )
 498                 rm -f plugin.c plugin.o plugin.lo
 499         ])
 500         AC_MSG_RESULT($glib_cv_uscore)
 501         if test "x$glib_cv_uscore" = "xyes"; then
 502                 G_MODULE_NEED_USCORE=1
 503         else
 504                 G_MODULE_NEED_USCORE=0
 505         fi
 506
 507         LDFLAGS="$LDFLAGS_orig"
 508 dnl *** check for having dlerror()
 509         AC_CHECK_FUNC(dlerror,
 510                 G_MODULE_HAVE_DLERROR=1,
 511                 G_MODULE_HAVE_DLERROR=0)
 512         LIBS="$LIBS_orig"
 513 fi
 514 dnl *** done, have e got an implementation?
 515 if test -z "$G_MODULE_IMPL"; then
 516         G_MODULE_IMPL=0
 517 fi
 518 AC_SUBST(G_MODULE_IMPL)
 519 AC_SUBST(G_MODULE_LIBS)
 520 AC_SUBST(G_MODULE_LDFLAGS)
 521 AC_SUBST(G_MODULE_HAVE_DLERROR)
 522 AC_SUBST(G_MODULE_NEED_USCORE)
 523 AC_SUBST(GLIB_DEBUG_FLAGS)
 524
 525
 526 dnl ***********************
 527 dnl *** g_thread checks ***
 528 dnl ***********************
 529
 530 AC_ARG_WITH(threads, [  --with-threads=[none/posix/dce/solaris/nspr] specify a thread implementation to use],
 531         if test "x$with_threads" = x; then
 532                 want_threads=yes
 533         else
 534                 want_threads=$with_threads
 535         fi,
 536         want_threads=yes)
 537 if test "x$enable_threads" = "xno"; then
 538         want_threads=no
 539 fi
 540 if test "x$want_threads" = "xnone"; then
 541         want_threads=no
 542 fi
 543
 544 dnl error and warning message
 545 dnl *************************
 546
 547 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
 548                 computer. GLib will not have a default thread implementation."
 549
 550 FLAG_DOES_NOT_WORK="I can't find the MACRO, that enables thread safety on your
 551                 platform (normaly it's "_REENTRANT"). I'll not use any flag on
 552                 compilation now, but then your programs might not work.
 553                 Please provide information on how it is done on your system."
 554
 555 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
 556                 "
 557
 558 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
 559                 provide information on your thread implementation.
 560                 You can also run 'configure --disable-threads'
 561                 to compile without thread support."
 562
 563 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
 564                 functions will not be MT-safe during their first call because
 565                 there is no working 'getpwuid_r' on your system."
 566
 567 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
 568                 because there is no 'localtime_r' on your system."
 569
 570 dnl determination of thread implementation
 571 dnl ***************************************
 572
 573 have_threads=none
 574 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
 575         case $host in
 576                 *-*-solaris*)
 577                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
 578                 ;;
 579         esac
 580 fi
 581 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
 582                                 || test "x$want_threads" = xdce; then
 583         if test "x$have_threads" = xnone; then
 584                 AC_EGREP_HEADER([[^a-zA-Z_]pthread_attr_init[^a-zA-Z_]],
 585                         pthread.h,
 586                         have_threads=posix)
 587         fi
 588         if test "x$have_threads" = xnone; then
 589                 AC_EGREP_HEADER([[^a-zA-Z_]pthread_attr_create[^a-zA-Z_]],
 590                         pthread.h,
 591                         have_threads=dce)
 592         fi
 593 fi
 594 if test "x$want_threads" = xyes || test "x$want_threads" = xnspr; then
 595         if test "x$have_threads" = xnone; then
 596                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar, have_threads=nspr)
 597         fi
 598 fi
 599
 600 AC_MSG_CHECKING(for thread implementation)
 601
 602 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
 603         AC_MSG_RESULT(none available)
 604         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
 605 else
 606         AC_MSG_RESULT($have_threads)
 607 fi
 608
 609
 610 dnl determination of G_THREAD_LIBS
 611 dnl ******************************
 612
 613 G_THREAD_LIBS=
 614 G_THREAD_CFLAGS=
 615
 616 mutex_has_default=no
 617 case $have_threads in
 618         posix|dce)
 619                 G_THREAD_LIBS=error
 620                 glib_save_LIBS="$LIBS"
 621                 for thread_lib in "" pthread pthreads c_r thread; do
 622                         # This is not AC_CHECK_LIB to also work with function
 623                         # name mangling in header files.
 624                         if test x"$thread_lib" = x; then
 625                                 add_thread_lib=""
 626                                 IN=""
 627                         else
 628                                 add_thread_lib="-l$thread_lib"
 629                                 IN=" in -l$thread_lib"
 630                         fi
 631
 632                         LIBS="$glib_save_LIBS $add_thread_lib"
 633
 634                         AC_MSG_CHECKING(for pthread_create$IN)
 635                         AC_TRY_LINK([#include <pthread.h>],
 636                                 [pthread_create(NULL,NULL,NULL,NULL)],
 637                                 [AC_MSG_RESULT(yes)
 638                                 G_THREAD_LIBS="$add_thread_lib"
 639                                 break],
 640                                 [AC_MSG_RESULT(no)])
 641                 done
 642                 LIBS="$glib_save_LIBS"
 643                 dnl ********** DG/UX ************
 644                 AC_CHECK_LIB(thread, __d10_pthread_create,
 645                         G_THREAD_CFLAGS="-D_POSIX4A_DRAFT10_SOURCE")
 646                 mutex_has_default=yes
 647                 mutex_default_type='pthread_mutex_t'
 648                 mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
 649                 mutex_header_file='pthread.h'
 650                 if test "x$have_threads" = "xposix"; then
 651                         g_threads_impl="POSIX"
 652                 else
 653                         g_threads_impl="DCE"
 654                         have_threads="posix"
 655                 fi
 656                 ;;
 657         solaris)
 658                 G_THREAD_LIBS=error
 659                 AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
 660                 mutex_has_default=yes
 661                 mutex_default_type='mutex_t'
 662                 mutex_default_init="DEFAULTMUTEX"
 663                 mutex_header_file='thread.h'
 664                 g_threads_impl="SOLARIS"
 665                 ;;
 666         nspr)
 667                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar,
 668                              G_THREAD_LIBS="-lnspr21")
 669                 g_threads_impl="NSPR"
 670                 ;;
 671         none)
 672                 g_threads_impl="NONE"
 673                 ;;
 674         *)
 675                 g_threads_impl="NONE"
 676                 G_THREAD_LIBS=error
 677                 ;;
 678 esac
 679
 680 if test "x$G_THREAD_LIBS" = xerror; then
 681         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 682 fi
 683
 684 AC_MSG_CHECKING(thread related libraries)
 685 AC_MSG_RESULT($G_THREAD_LIBS)
 686
 687 dnl determination of G_THREAD_CFLAGS
 688 dnl ********************************
 689
 690 if test x"$enable_threads" = xyes; then
 691
 692     G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_REENTRANT" # good default guess
 693
 694     case $host in
 695         *-aix*)
 696                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 697                 if test x"$GCC" = xyes; then
 698                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
 699                 fi
 700                 ;;
 701         *-freebsd2.2*)
 702                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 703
 704                 # FreeBSD 2.2.x shiped with gcc 2.7.2.x, which doesn't support
 705                 # -mthreads flag.
 706                 ;;
 707     esac
 708
 709     # if we are not finding the ctime_r function, then we probably are
 710     # not using the proper multithread flag
 711     old_CPPFLAGS=$CPPFLAGS
 712     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
 713     AC_EGREP_HEADER([[^a-zA-Z_]ctime_r[^a-zA-Z_]], time.h, ,
 714     G_THREAD_CFLAGS=
 715     AC_MSG_WARN($FLAG_DOES_NOT_WORK))
 716     CPPFLAGS=$old_CPPFLAGS
 717
 718     AC_MSG_CHECKING(thread related cflags)
 719
 720     AC_MSG_RESULT($G_THREAD_CFLAGS)
 721 else
 722     G_THREAD_CFLAGS=
 723 fi
 724
 725 dnl check for mt safe function variants and some posix functions
 726 dnl ************************************************************
 727
 728 if test x"$enable_threads" = xyes; then
 729         glib_save_LIBS="$LIBS"
 730         glib_save_CFLAGS="$CFLAGS"
 731         # we are not doing the following for now, as this might require glib
 732         # to always be linked with the thread libs on some platforms.
 733         # LIBS="$LIBS $G_THREAD_LIBS"
 734         CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 735         AC_CHECK_FUNCS(localtime_r rand_r)
 736         if test "$ac_cv_header_pwd_h" = "yes"; then
 737                 AC_MSG_CHECKING([for getpwuid_r])
 738                 AC_CACHE_VAL(ac_cv_func_getpwuid_r,
 739                         [AC_TRY_RUN([#include <errno.h>
 740                                 int main () { char buffer[10000], *pointer;
 741                                 char getpwuid_r (long, void*, void*,
 742                                         int, void*);
 743                                 errno = 0;
 744                                 getpwuid_r (0, &buffer, &buffer,
 745                                         sizeof (buffer), &pointer);
 746                                 return errno == ENOSYS;}],
 747                                 [ac_cv_func_getpwuid_r=yes],
 748                                 [ac_cv_func_getpwuid_r=no])])
 749                 if test "$ac_cv_func_getpwuid_r" = yes; then
 750                         AC_MSG_RESULT(yes)
 751                         AC_DEFINE(HAVE_GETPWUID_R)
 752                 else
 753                         AC_MSG_RESULT(no)
 754                 fi
 755                 if test "$ac_cv_func_getpwuid_r" = "yes"; then
 756                         AC_MSG_CHECKING(whether getpwuid_r is posix like)
 757                         # getpwuid_r(0, NULL, NULL, 0) is the signature on
 758                         # solaris, if that is not found, the prog below won't
 759                         # compile, then the posix signature is assumed as
 760                         # the default.
 761                         AC_TRY_COMPILE([#include <pwd.h>],
 762                                 [getpwuid_r(0, NULL, NULL, 0);],
 763                                 [AC_MSG_RESULT(no)],
 764                                 [AC_MSG_RESULT(yes)
 765                                 AC_DEFINE(HAVE_GETPWUID_R_POSIX)])
 766                 fi
 767         fi
 768         LIBS="$glib_save_LIBS"
 769         CFLAGS="$glib_save_CFLAGS"
 770
 771         # now spit out all the warnings.
 772         if test "$ac_cv_func_getpwuid_r" != "yes"; then
 773                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
 774         fi
 775         if test "$ac_cv_func_localtime_r" != "yes"; then
 776                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
 777         fi
 778 fi
 779
 780 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c")
 781 AC_SUBST(G_THREAD_CFLAGS)
 782 AC_SUBST(G_THREAD_LIBS)
 783
 784 CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 785
 786 dnl **********************************************
 787 dnl *** GDefaultMutex setup and initialization ***
 788 dnl **********************************************
 789 dnl
 790 dnl if mutex_has_default = yes, we also got
 791 dnl mutex_default_type, mutex_default_init and mutex_header_file
 792 GLIB_IF_VAR_EQ(mutex_has_default, yes,
 793         GLIB_SIZEOF([#include <$mutex_header_file>],
 794                     $mutex_default_type,
 795                     gmutex,
 796                     )
 797         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
 798                            $mutex_default_type,
 799                            gmutex,
 800                            $glib_cv_sizeof_gmutex,
 801                            $mutex_default_init)
 802         ,
 803 )
 804
 805
 806 dnl ****************************************
 807 dnl *** GLib POLL* compatibility defines ***
 808 dnl ****************************************
 809 GLIB_SYSDEFS(
 810 [#include <sys/types.h>
 811 #include <sys/poll.h>],
 812         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
 813         glibconfig-sysdefs.h,
 814         =)
 815
 816
 817 dnl ******************************
 818 dnl *** output the whole stuff ***
 819 dnl ******************************
 820
 821 AC_OUTPUT_COMMANDS([
 822
 823 ## Generate `glibconfig.h' in two cases
 824 ## 1. `config.status' is run either explicitly, or via configure.
 825 ##     Esp. not when it is run in `Makefile' to generate makefiles and
 826 ##     config.h
 827 ## 2. CONFIG_OTHER is set explicitly
 828 ##
 829 ## Case 1 is difficult.  We know that `automake' sets one of
 830 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
 831 ## only when AM_CONFIG_HEADER is set, however.
 832
 833 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
 834   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
 835   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
 836 fi
 837 case "$CONFIG_OTHER" in
 838 *glibconfig.h*)
 839         echo creating glibconfig.h
 840         outfile=glibconfig.h-tmp
 841         cat > $outfile <<\_______EOF
 842 /* glibconfig.h
 843  *
 844  * This is a generated file.  Please modify `configure.in'
 845  */
 846
 847 #ifndef GLIBCONFIG_H
 848 #define GLIBCONFIG_H
 849
 850 #ifdef __cplusplus
 851 extern "C" {
 852 #endif /* __cplusplus */
 853
 854 _______EOF
 855
 856         if test x$glib_limits_h = xyes; then
 857           echo '#include <limits.h>' >> $outfile
 858         fi
 859         if test x$glib_float_h = xyes; then
 860           echo '#include <float.h>' >> $outfile
 861         fi
 862         if test x$glib_values_h = xyes; then
 863           echo '#include <values.h>' >> $outfile
 864         fi
 865         if test x$g_mutex_header_file != x; then
 866           echo '#include <'"$g_mutex_header_file"'>' >> $outfile
 867         fi
 868         if test x$glib_sys_poll_h = xyes; then
 869           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
 870         fi
 871
 872         cat >> $outfile <<_______EOF
 873
 874 #define G_MINFLOAT      $glib_mf
 875 #define G_MAXFLOAT      $glib_Mf
 876 #define G_MINDOUBLE     $glib_md
 877 #define G_MAXDOUBLE     $glib_Md
 878 #define G_MINSHORT      $glib_ms
 879 #define G_MAXSHORT      $glib_Ms
 880 #define G_MAXUSHORT     $glib_Mus
 881 #define G_MININT        $glib_mi
 882 #define G_MAXINT        $glib_Mi
 883 #define G_MAXUINT       $glib_Mui
 884 #define G_MINLONG       $glib_ml
 885 #define G_MAXLONG       $glib_Ml
 886 #define G_MAXULONG      $glib_Mul
 887
 888 _______EOF
 889
 890
 891         ### this should always be true in a modern C/C++ compiler
 892         cat >>$outfile <<_______EOF
 893 typedef signed char gint8;
 894 typedef unsigned char guint8;
 895 _______EOF
 896
 897
 898         if test -n "$gint16"; then
 899           cat >>$outfile <<_______EOF
 900 typedef signed $gint16 gint16;
 901 typedef unsigned $gint16 guint16;
 902 #define G_GINT16_FORMAT $gint16_format
 903 #define G_GUINT16_FORMAT $guint16_format
 904 _______EOF
 905         fi
 906
 907
 908         if test -n "$gint32"; then
 909           cat >>$outfile <<_______EOF
 910 typedef signed $gint32 gint32;
 911 typedef unsigned $gint32 guint32;
 912 #define G_GINT32_FORMAT $gint32_format
 913 #define G_GUINT32_FORMAT $guint32_format
 914 _______EOF
 915         fi
 916
 917
 918         if test -n "$gint64"; then
 919           cat >>$outfile <<_______EOF
 920 ${glib_warning_guard}#define G_HAVE_GINT64 1
 921
 922 ${glib_extension}typedef signed $gint64 gint64;
 923 ${glib_extension}typedef unsigned $gint64 guint64;
 924
 925 #define G_GINT64_FORMAT $gint64_format
 926 #define G_GUINT64_FORMAT $guint64_format
 927 #define G_GINT64_CONSTANT(val)  $gint64_constant
 928 _______EOF
 929         fi
 930
 931
 932         if test -z "$glib_unknown_void_p"; then
 933           cat >>$outfile <<_______EOF
 934
 935 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
 936 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
 937
 938 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
 939 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
 940 _______EOF
 941         else
 942           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
 943         fi
 944
 945
 946
 947         cat >>$outfile <<_______EOF
 948 $glib_atexit
 949 $glib_memmove
 950 $glib_defines
 951
 952 $glib_vacopy
 953
 954 #ifdef  __cplusplus
 955 #define G_HAVE_INLINE   1
 956 #else   /* !__cplusplus */
 957 $glib_inline
 958 #endif  /* !__cplusplus */
 959 _______EOF
 960
 961         echo >>$outfile
 962         if test x$g_mutex_has_default = xyes; then
 963                 cat >>$outfile <<_______EOF
 964 $g_enable_threads_def G_THREADS_ENABLED
 965 #define G_THREADS_IMPL_$g_threads_impl_def
 966 typedef struct _GStaticMutex GStaticMutex;
 967 struct _GStaticMutex
 968 {
 969   struct _GMutex *runtime_mutex;
 970   union {
 971     char   pad[$g_mutex_sizeof];
 972     double dummy_double;
 973     void  *dummy_pointer;
 974     long   dummy_long;
 975   } aligned_pad_u;
 976 };
 977 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
 978 #define g_static_mutex_get_mutex(mutex) \
 979   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->aligned_pad_u)) : \
 980    g_static_mutex_get_mutex_impl (&((mutex)->runtime_mutex)))
 981 _______EOF
 982         else
 983                 cat >>$outfile <<_______EOF
 984 $g_enable_threads_def G_THREADS_ENABLED
 985 #define G_THREADS_IMPL_$g_threads_impl_def
 986 typedef struct _GMutex* GStaticMutex;
 987 #define G_STATIC_MUTEX_INIT NULL
 988 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (mutex))
 989 _______EOF
 990         fi
 991
 992         echo >>$outfile
 993         g_bit_sizes="16 32"
 994         if test -n "$gint64"; then
 995           g_bit_sizes="$g_bit_sizes 64"
 996         fi
 997         for bits in $g_bit_sizes; do
 998           cat >>$outfile <<_______EOF
 999 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
1000 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
1001 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
1002 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
1003 _______EOF
1004         done
1005
1006         cat >>$outfile <<_______EOF
1007 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
1008 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
1009 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
1010 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
1011 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
1012 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
1013 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
1014 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
1015 #define G_BYTE_ORDER $g_byte_order
1016
1017 _______EOF
1018
1019         if test -r glibconfig-sysdefs.h; then
1020           cat glibconfig-sysdefs.h >>$outfile
1021         fi
1022
1023         cat >>$outfile <<_______EOF
1024 #ifdef __cplusplus
1025 }
1026 #endif /* __cplusplus */
1027
1028 #endif /* GLIBCONFIG_H */
1029 _______EOF
1030
1031
1032         if cmp -s $outfile glibconfig.h; then
1033           echo glibconfig.h is unchanged
1034           rm -f $outfile
1035         else
1036           mv $outfile glibconfig.h
1037         fi ;;
1038 esac
1039 ],[
1040
1041 # Note that if two cases are the same, case goes with the first one.
1042 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
1043 # on variable expansion in case labels.  Look at the generated config.status
1044 # for a hint.
1045
1046 case xyes in
1047 x$ac_cv_header_float_h)
1048   glib_float_h=yes
1049   glib_mf=FLT_MIN glib_Mf=FLT_MAX
1050   glib_md=DBL_MIN glib_Md=DBL_MAX
1051   ;;
1052 x$ac_cv_header_values_h)
1053   glib_values_h=yes
1054   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
1055   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
1056   ;;
1057 esac
1058
1059 case xyes in
1060 x$ac_cv_header_limits_h)
1061   glib_limits_h=yes
1062   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
1063   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
1064   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
1065   ;;
1066 x$ac_cv_header_values_h)
1067   glib_values_h=yes
1068   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus=unknown  # Please insert the right
1069   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui=unknown  # values from
1070   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul=unknown  # /usr/include/values.h
1071   ;;
1072 esac
1073
1074 if test x$ac_cv_header_sys_poll_h = xyes ; then
1075   glib_sys_poll_h=yes
1076 fi
1077
1078 case 2 in
1079 $ac_cv_sizeof_short)
1080   gint16=short
1081   gint16_format='"hi"'
1082   guint16_format='"hu"'
1083   ;;
1084 $ac_cv_sizeof_int)
1085   gint16=int
1086   gint16_format='"i"'
1087   guint16_format='"u"'
1088   ;;
1089 esac
1090 case 4 in
1091 $ac_cv_sizeof_short)
1092   gint32=short
1093   gint32_format='"hi"'
1094   guint32_format='"hu"'
1095   ;;
1096 $ac_cv_sizeof_int)
1097   gint32=int
1098   gint32_format='"i"'
1099   guint32_format='"u"'
1100   ;;
1101 $ac_cv_sizeof_long)
1102   gint32=long
1103   gint32_format='"li"'
1104   guint32_format='"lu"'
1105   ;;
1106 esac
1107 case 8 in
1108 $ac_cv_sizeof_int)
1109   gint64=int
1110   gint64_format='"i"'
1111   guint64_format='"u"'
1112   glib_extension=
1113   glib_warning_guard=
1114   gint64_constant='(val)'
1115   ;;
1116 $ac_cv_sizeof_long)
1117   gint64=long
1118   gint64_format='"li"'
1119   guint64_format='"lu"'
1120   glib_extension=
1121   glib_warning_guard=
1122   gint64_constant='(val##L)'
1123   ;;
1124 $ac_cv_sizeof_long_long)
1125   gint64='long long'
1126   gint64_format='"lli"'
1127   guint64_format='"llu"'
1128   glib_extension='G_GNUC_EXTENSION '
1129   glib_warning_guard="
1130 #if defined (__GNUC__) && __GNUC__ >= 2 && __GNUC_MINOR__ >= 8
1131 #  define G_GNUC_EXTENSION __extension__
1132 #else
1133 #  define G_GNUC_EXTENSION
1134 #endif
1135
1136 "
1137   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1138   ;;
1139 esac
1140
1141 gintbits=`expr $ac_cv_sizeof_int \* 8`
1142 glongbits=`expr $ac_cv_sizeof_long \* 8`
1143
1144
1145 case $ac_cv_sizeof_void_p in
1146 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
1147 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
1148 *)                      glib_unknown_void_p=yes ;;
1149 esac
1150
1151
1152 case xyes in
1153 x$ac_cv_func_atexit)
1154   glib_atexit="
1155 #ifdef NeXT /* @#%@! NeXTStep */
1156 # define g_ATEXIT(proc) (!atexit (proc))
1157 #else
1158 # define g_ATEXIT(proc) (atexit (proc))
1159 #endif"
1160   ;;
1161 x$ac_cv_func_on_exit)
1162   glib_atexit="
1163 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
1164   ;;
1165 esac
1166
1167 case xyes in
1168 x$ac_cv_func_memmove)
1169   glib_memmove='
1170 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
1171   ;;
1172 *)
1173   glib_memmove="
1174 /* We make the assumption that if memmove isn't available, then
1175  * bcopy will do the job. This isn't safe everywhere. (bcopy can't
1176  * necessarily handle overlapping copies) */
1177 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
1178   ;;
1179 esac
1180
1181 glib_defines="
1182 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
1183 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
1184 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
1185 "
1186
1187 case xyes in
1188 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
1189 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
1190 *)                      glib_vacopy=''
1191 esac
1192
1193 if test x$glib_cv_va_val_copy = xno; then
1194   glib_vacopy="\$glib_vacopy
1195 #define G_VA_COPY_AS_ARRAY 1"
1196 fi
1197
1198 if test x$glib_cv_hasinline = xyes; then
1199     glib_inline='#define G_HAVE_INLINE 1'
1200 fi
1201 if test x$glib_cv_has__inline = xyes; then
1202     glib_inline="\$glib_inline
1203 #define G_HAVE___INLINE 1"
1204 fi
1205 if test x$glib_cv_has__inline__ = xyes; then
1206     glib_inline="\$glib_inline
1207 #define G_HAVE___INLINE__ 1"
1208 fi
1209
1210 case xyes in
1211 x$ac_cv_c_bigendian)
1212   g_byte_order=G_BIG_ENDIAN
1213   g_bs_native=BE
1214   g_bs_alien=LE
1215   ;;
1216 *)
1217   g_byte_order=G_LITTLE_ENDIAN
1218   g_bs_native=LE
1219   g_bs_alien=BE
1220   ;;
1221 esac
1222
1223 case x$enable_threads in
1224 xyes)   g_enable_threads_def="#define";;
1225 *)      g_enable_threads_def="#undef ";;
1226 esac
1227
1228 g_threads_impl_def=$g_threads_impl
1229
1230 g_mutex_has_default="$mutex_has_default"
1231 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
1232 g_mutex_contents="$glib_cv_byte_contents_gmutex"
1233 ])
1234
1235 AC_OUTPUT([
1236 glib.spec
1237 Makefile
1238 glib-config
1239 gmodule/gmoduleconf.h
1240 gmodule/Makefile
1241 gthread/Makefile
1242 docs/Makefile
1243 tests/Makefile
1244 ],[case "$CONFIG_FILES" in
1245 *glib-config*)chmod +x glib-config;;
1246 esac])