configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5 builtin(include, glib/libcharset/codeset.m4)dnl
   6 builtin(include, glib/libcharset/glibc21.m4)dnl
   7
   8 # require autoconf 2.13
   9 AC_PREREQ(2.13)
  10
  11 # Process this file with autoconf to produce a configure script.
  12 AC_INIT(glib/glib.h)
  13
  14 # Save this value here, since automake will set cflags later
  15 cflags_set=${CFLAGS+set}
  16
  17 # we rewrite this file
  18 rm -f glibconfig-sysdefs.h
  19
  20 GLIB_AC_DIVERT_BEFORE_HELP([
  21 #
  22 # The following version number definitions apply to GLib, GModule, GObject
  23 # and GThread as a whole, so if changes occoured in any of them, they are all
  24 # treated with the same interface and binary age.
  25 #
  26 # Making releases:
  27 #   GLIB_MICRO_VERSION += 1;
  28 #   GLIB_INTERFACE_AGE += 1;
  29 #   GLIB_BINARY_AGE += 1;
  30 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  31 # if backwards compatibility has been broken,
  32 # set GLIB_BINARY_AGE _and_ GLIB_INTERFACE_AGE to 0.
  33 #
  34 GLIB_MAJOR_VERSION=1
  35 GLIB_MINOR_VERSION=3
  36 GLIB_MICRO_VERSION=10
  37 GLIB_INTERFACE_AGE=0
  38 GLIB_BINARY_AGE=0
  39 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  40 ])dnl
  41
  42 AC_SUBST(GLIB_MAJOR_VERSION)
  43 AC_SUBST(GLIB_MINOR_VERSION)
  44 AC_SUBST(GLIB_MICRO_VERSION)
  45 AC_SUBST(GLIB_VERSION)
  46 AC_SUBST(GLIB_INTERFACE_AGE)
  47 AC_SUBST(GLIB_BINARY_AGE)
  48
  49 # libtool versioning
  50 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  51 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  52 LT_REVISION=$GLIB_INTERFACE_AGE
  53 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  54 LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  55 AC_SUBST(LT_RELEASE)
  56 AC_SUBST(LT_CURRENT)
  57 AC_SUBST(LT_REVISION)
  58 AC_SUBST(LT_AGE)
  59 AC_SUBST(LT_CURRENT_MINUS_AGE)
  60
  61 VERSION=$GLIB_VERSION
  62 PACKAGE=glib
  63
  64 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  65
  66 # Specify a configuration file
  67 AM_CONFIG_HEADER(config.h)
  68
  69 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION,
  70                    [Define to the GLIB major version])
  71 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION,
  72                    [Define to the GLIB minor version])
  73 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION,
  74                    [Define to the GLIB micro version])
  75 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE,
  76                    [Define to the GLIB interface age])
  77 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE,
  78                    [Define to the GLIB binary age])
  79
  80 dnl Initialize maintainer mode
  81 AM_MAINTAINER_MODE
  82
  83 AC_CANONICAL_HOST
  84
  85 AC_MSG_CHECKING(for the BeOS)
  86 case $host in
  87   *-*-beos*)
  88     glib_native_beos="yes"
  89     ;;
  90   *)
  91     glib_native_beos="no"
  92     ;;
  93 esac
  94 AC_MSG_RESULT([$glib_native_beos])
  95
  96 dnl
  97
  98 AC_MSG_CHECKING([for Win32])
  99 case "$host" in
 100   *-*-mingw*)
 101     glib_native_win32=yes
 102     G_LIB_WIN32_RESOURCE=glib-win32res.lo
 103     G_MODULE_WIN32_RESOURCE=gmodule-win32res.lo
 104     G_OBJECT_WIN32_RESOURCE=gobject-win32res.lo
 105     G_THREAD_WIN32_RESOURCE=gthread-win32res.lo
 106     GLIB_DEF=glib.def
 107     GMODULE_DEF=gmodule.def
 108     GOBJECT_DEF=gobject.def
 109     GTHREAD_DEF=gthread.def
 110     TESTGMODULE_EXP=testgmodule.exp
 111     ;;
 112   *)
 113     glib_native_win32=no
 114     G_LIB_WIN32_RESOURCE=
 115     G_MODULE_WIN32_RESOURCE=
 116     G_OBJECT_WIN32_RESOURCE=
 117     G_THREAD_WIN32_RESOURCE=
 118     GLIB_DEF=
 119     GMODULE_DEF=
 120     GOBJECT_DEF=
 121     GTHREAD_DEF=
 122     TESTGMODULE_EXP=
 123     ;;
 124 esac
 125 AC_MSG_RESULT([$glib_native_win32])
 126 AM_CONDITIONAL(OS_WIN32, test "$glib_native_win32" = "yes")
 127 AC_SUBST(G_LIB_WIN32_RESOURCE)
 128 AC_SUBST(G_MODULE_WIN32_RESOURCE)
 129 AC_SUBST(G_OBJECT_WIN32_RESOURCE)
 130 AC_SUBST(G_THREAD_WIN32_RESOURCE)
 131 AC_SUBST(GLIB_DEF)
 132 AC_SUBST(GMODULE_DEF)
 133 AC_SUBST(GOBJECT_DEF)
 134 AC_SUBST(GTHREAD_DEF)
 135 AC_SUBST(TESTGMODULE_EXP)
 136
 137 if test "$glib_native_win32" = "yes"; then
 138   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 139 fi
 140 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 141
 142 GLIB_AC_DIVERT_BEFORE_HELP([
 143 # figure debugging default, prior to $ac_help setup
 144 case $GLIB_MINOR_VERSION in
 145 *[[13579]]) debug_default=yes ;;
 146 *)          debug_default=minimum ;;
 147 esac[]dnl
 148 ])
 149
 150 dnl declare --enable-* args and collect ac_help strings
 151 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
 152 AC_ARG_ENABLE(gc_friendly, [  --enable-gc-friendly    turn on garbage collector friendliness [default=no]],,enable_gc_friendly=no)
 153 AC_ARG_ENABLE(mem_pools, [  --disable-mem-pools     disable all glib memory pools],,disable_mem_pools=no)
 154 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
 155                     , enable_ansi=no)
 156 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
 157                           ([=no] will override --with-threads)],,enable_threads=yes)
 158 AC_ARG_ENABLE(rebuilds, [  --disable-rebuilds      disable all source autogeneration rules],,enable_rebuilds=yes)
 159
 160 if test "x$enable_threads" != "xyes"; then
 161   enable_threads=no
 162 fi
 163
 164 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 165         [Whether glib was compiled with debugging enabled])
 166
 167 AC_MSG_CHECKING(whether to enable garbage collector friendliness)
 168 if test "x$enable_gc_friendly" = "xyes"; then
 169   AC_DEFINE(ENABLE_GC_FRIENDLY, 1, [Whether to enable GC friendliness])
 170   AC_SUBST(ENABLE_GC_FRIENDLY)
 171   AC_MSG_RESULT(yes)
 172 else
 173   AC_MSG_RESULT(no)
 174 fi
 175
 176 AC_MSG_CHECKING(whether to disable memory pools)
 177 if test "x$disable_mem_pools" = "xno"; then
 178   AC_MSG_RESULT(no)
 179 else
 180   AC_DEFINE(DISABLE_MEM_POOLS, 1, [Whether to disable memory pools])
 181   AC_SUBST(DISABLE_MEM_POOLS)
 182   AC_MSG_RESULT(yes)
 183 fi
 184
 185 dnl Checks for programs.
 186 AC_PROG_CC
 187
 188 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 189 AC_CHECK_PROGS(CXX, $CCC c++ g++ gcc CC cxx cc++ cl, gcc)
 190 AC_LANG_SAVE
 191 AC_LANG_CPLUSPLUS
 192 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 193 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 194 AC_LANG_RESTORE
 195
 196 AM_PROG_CC_STDC
 197 AC_PROG_INSTALL
 198
 199 #
 200 # Find pkg-config
 201 #
 202 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 203 if test x$PKG_CONFIG = xno ; then
 204   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
 205 fi
 206
 207 if pkg-config --atleast-pkgconfig-version 0.5 ; then
 208   :
 209 else
 210   AC_MSG_ERROR([*** pkg-config too old; version 0.5 or better required.])
 211 fi
 212
 213 if test "x$enable_debug" = "xyes"; then
 214   if test x$cflags_set != xset ; then
 215       case " $CFLAGS " in
 216       *[[\ \    ]]-g[[\ \       ]]*) ;;
 217       *) CFLAGS="$CFLAGS -g" ;;
 218       esac
 219   fi
 220
 221   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 222 else
 223   if test "x$enable_debug" = "xno"; then
 224     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 225   fi
 226 fi
 227
 228 # Ensure -fnative-struct is used when compiling for Win32
 229 if test "x$glib_native_win32" = "xyes"; then
 230   if test "x$GCC" = "xyes"; then
 231     case " $CFLAGS " in
 232     *[[\ \      ]]-fnative-struct[[\ \  ]]*) ;;
 233     *) CFLAGS="$CFLAGS -fnative-struct" ;;
 234     esac
 235   fi
 236 fi
 237
 238 AC_CYGWIN
 239 AC_EXEEXT
 240
 241 # define a MAINT-like variable REBUILD which is set if Perl
 242 # and awk are found, so autogenerated sources can be rebuilt
 243 AC_PROG_AWK
 244 AC_CHECK_PROGS(PERL, perl5 perl)
 245 # We would like indent, but don't require it.
 246 AC_CHECK_PROG(INDENT, indent, indent)
 247 REBUILD=\#
 248 if test "x$enable_rebuilds" = "xyes" && \
 249      test -n "$PERL" && \
 250      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 251      test -n "$AWK" ; then
 252   REBUILD=
 253 fi
 254 AC_SUBST(REBUILD)
 255
 256 # Need full path to Perl for glib-mkenums
 257 #
 258 if test "x$PERL" != x ; then
 259   AC_PATH_PROG(PERL_PATH, $PERL)
 260 else
 261   PERL_PATH="/usr/bin/env perl"
 262 fi
 263 AC_SUBST(PERL_PATH)
 264
 265 dnl
 266 dnl gettext support
 267 dnl
 268
 269 ALL_LINGUAS="az ca de es eu fr nn no ro ru sk sl sv ta tr uk zh_TW"
 270 AM_GLIB_GNU_GETTEXT
 271
 272 if test "$gt_cv_func_dgettext_libc" = "yes" || test "$gt_cv_func_dgettext_libintl" = "yes"; then
 273   :
 274 else
 275   AC_MSG_ERROR([
 276 *** You must have either have gettext support in your C library, or use the
 277 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 278 ])
 279 fi
 280
 281 LIBS="$LIBS $INTLLIBS"
 282
 283 GETTEXT_PACKAGE=glib20
 284 AC_SUBST(GETTEXT_PACKAGE)
 285 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE")
 286
 287 # AM_GLIB_GNU_GETTEXT above substs $DATADIRNAME
 288 # this is the directory where the *.{mo,gmo} files are installed
 289 GLIB_LOCALE_DIR="${prefix}/${DATADIRNAME}/locale"
 290 AC_DEFINE_UNQUOTED(GLIB_LOCALE_DIR,"$GLIB_LOCALE_DIR")
 291
 292 dnl Initialize libtool
 293 AC_LIBTOOL_WIN32_DLL
 294 AM_PROG_LIBTOOL
 295
 296 if test "x$GCC" = "xyes"; then
 297   case " $CFLAGS " in
 298   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 299   *) CFLAGS="$CFLAGS -Wall" ;;
 300   esac
 301
 302   if test "x$enable_ansi" = "xyes"; then
 303     case " $CFLAGS " in
 304     *[[\ \      ]]-ansi[[\ \    ]]*) ;;
 305     *) CFLAGS="$CFLAGS -ansi" ;;
 306     esac
 307
 308     case " $CFLAGS " in
 309     *[[\ \      ]]-pedantic[[\ \        ]]*) ;;
 310     *) CFLAGS="$CFLAGS -pedantic" ;;
 311     esac
 312   fi
 313 fi
 314
 315 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 316 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 317 glib_save_LIBS=$LIBS
 318 LIBS="$LIBS -lm"
 319 AC_TRY_RUN([#include <math.h>
 320              int main (void) { return (log(1) != log(1.)); }],
 321      AC_MSG_RESULT(none needed),
 322      glib_save_CFLAGS=$CFLAGS
 323      CFLAGS="$CFLAGS -std1"
 324      AC_TRY_RUN([#include <math.h>
 325                  int main (void) { return (log(1) != log(1.)); }],
 326          AC_MSG_RESULT(-std1),
 327          AC_MSG_RESULT()
 328          CFLAGS=$glib_save_CFLAGS
 329          AC_MSG_WARN(
 330                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 331      )
 332 )
 333 LIBS=$glib_save_LIBS
 334
 335 dnl NeXTStep cc seems to need this
 336 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 337 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 338   AC_MSG_RESULT(none needed),
 339   glib_save_CFLAGS=$CFLAGS
 340   CFLAGS="$CFLAGS -posix"
 341   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 342     AC_MSG_RESULT(-posix),
 343     AC_MSG_RESULT()
 344     CFLAGS=$glib_save_CFLAGS
 345     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 346
 347 # Checks for header files.
 348 AC_HEADER_STDC
 349
 350 # Checks for library functions.
 351 AC_FUNC_VPRINTF
 352
 353 AC_FUNC_ALLOCA
 354
 355 AC_CHECK_FUNCS(atexit on_exit)
 356
 357 AC_CHECK_SIZEOF(char)
 358 AC_CHECK_SIZEOF(short)
 359 AC_CHECK_SIZEOF(long)
 360 AC_CHECK_SIZEOF(int)
 361 AC_CHECK_SIZEOF(void *)
 362 AC_CHECK_SIZEOF(long long)
 363 AC_CHECK_SIZEOF(__int64)
 364
 365 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 366   :
 367 else
 368   AC_MSG_ERROR([
 369 *** GLib requires a 64 bit type. You might want to consider
 370 *** using the GNU C compiler.
 371 ])
 372 fi
 373
 374 if test x$ac_cv_sizeof_long_long = x8; then
 375         # long long is a 64 bit integer.
 376         AC_MSG_CHECKING(for format to printf and scanf a gint64)
 377         AC_CACHE_VAL(glib_cv_long_long_format,[
 378                 for format in ll q I64; do
 379                   AC_TRY_RUN([#include <stdio.h>
 380                         int main()
 381                         {
 382                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 383                           char buffer[1000];
 384                           sprintf (buffer, "%${format}u", a);
 385                           sscanf (buffer, "%${format}u", &b);
 386                           exit (b!=a);
 387                         }
 388                         ],
 389                         glib_cv_long_long_format=${format}
 390                         break)
 391                 done])
 392         if test -n "$glib_cv_long_long_format"; then
 393           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 394         else
 395           AC_MSG_RESULT(none)
 396         fi
 397 elif test x$ac_cv_sizeof___int64 = x8; then
 398         # __int64 is a 64 bit integer.
 399         AC_MSG_CHECKING(for format to printf and scanf a gint64)
 400         # We know this is MSVC, and what the formats are
 401         glib_cv_long_long_format=I64
 402         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 403 fi
 404
 405 dnl long doubles were not used, and a portability problem
 406 dnl AC_C_LONG_DOUBLE
 407 AC_C_CONST
 408
 409 dnl ok, here we try to check whether the systems prototypes for
 410 dnl malloc and friends actually match the prototypes provided
 411 dnl by gmem.h (keep in sync). i currently only know how to check
 412 dnl this reliably with gcc (-Werror), improvements for other
 413 dnl compilers are apprechiated.
 414 SANE_MALLOC_PROTOS=no
 415 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 416 glib_save_CFLAGS=$CFLAGS
 417 if test "x$GCC" = "xyes"; then
 418   CFLAGS="$CFLAGS -Werror"
 419   AC_TRY_COMPILE([#include <stdlib.h>], [
 420     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 421     void* (*my_malloc_p)  (size_t)         = malloc;
 422     void  (*my_free_p)    (void*)          = free;
 423     void* (*my_realloc_p) (void*, size_t)  = realloc;
 424     my_calloc_p = 0;
 425     my_malloc_p = 0;
 426     my_free_p = 0;
 427     my_realloc_p = 0;
 428   ],
 429     AC_DEFINE(SANE_MALLOC_PROTOS)
 430     SANE_MALLOC_PROTOS=yes)
 431 fi
 432 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 433 CFLAGS=$glib_save_CFLAGS
 434
 435
 436 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 437 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 438 dnl actually supported.
 439 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 440         AC_TRY_RUN([
 441         __inline int foo () { return 0; }
 442         int main () { return foo (); }
 443         ],
 444         glib_cv_has__inline=yes
 445         ,
 446         glib_cv_has__inline=no
 447         ,)
 448 ])
 449 case x$glib_cv_has__inline in
 450 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 451 esac
 452 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 453         AC_TRY_RUN([
 454         __inline__ int foo () { return 0; }
 455         int main () { return foo (); }
 456         ],
 457         glib_cv_has__inline__=yes
 458         ,
 459         glib_cv_has__inline__=no
 460         ,)
 461 ])
 462 case x$glib_cv_has__inline__ in
 463 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 464 esac
 465 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 466         AC_TRY_RUN([
 467         #undef inline
 468         inline int foo () { return 0; }
 469         int main () { return foo (); }
 470         ],
 471         glib_cv_hasinline=yes
 472         ,
 473         glib_cv_hasinline=no
 474         ,)
 475 ])
 476 case x$glib_cv_hasinline in
 477 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 478 esac
 479
 480 # check for flavours of varargs macros
 481 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 482 AC_TRY_COMPILE([],[
 483 int a(int p1, int p2, int p3);
 484 #define call_a(...) a(1,__VA_ARGS__)
 485 call_a(2,3);
 486 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 487 AC_MSG_RESULT($g_have_iso_c_varargs)
 488
 489 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 490 if test "$CXX" = ""; then
 491 dnl No C++ compiler
 492   g_have_iso_cxx_varargs=no
 493 else
 494   AC_LANG_CPLUSPLUS
 495   AC_TRY_COMPILE([],[
 496 int a(int p1, int p2, int p3);
 497 #define call_a(...) a(1,__VA_ARGS__)
 498 call_a(2,3);
 499 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 500   AC_LANG_C
 501 fi
 502 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 503
 504 AC_MSG_CHECKING(for GNUC varargs macros)
 505 AC_TRY_COMPILE([],[
 506 int a(int p1, int p2, int p3);
 507 #define call_a(params...) a(1,params)
 508 call_a(2,3);
 509 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 510 AC_MSG_RESULT($g_have_gnuc_varargs)
 511
 512 # check for bytesex stuff
 513 AC_C_BIGENDIAN
 514
 515 # check for header files
 516 AC_CHECK_HEADERS([float.h limits.h pwd.h sys/param.h sys/poll.h sys/select.h])
 517 AC_CHECK_HEADERS([sys/time.h sys/times.h unistd.h values.h stdint.h sched.h])
 518
 519 # Checks for libcharset
 520 jm_LANGINFO_CODESET
 521 jm_GLIBC21
 522 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 523 AC_CHECK_FUNCS(setlocale)
 524
 525 AC_MSG_CHECKING(whether make is GNU Make)
 526 STRIP_BEGIN=
 527 STRIP_END=
 528 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 529         STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
 530         STRIP_END=')'
 531         AC_MSG_RESULT(yes)
 532 else
 533         AC_MSG_RESULT(no)
 534 fi
 535 STRIP_DUMMY=
 536 AC_SUBST(STRIP_DUMMY)
 537 AC_SUBST(STRIP_BEGIN)
 538 AC_SUBST(STRIP_END)
 539
 540 # check additional type sizes
 541 size_includes=["
 542 #include <stdarg.h>
 543 #include <stdio.h>
 544 #include <ctype.h>
 545 #include <string.h>
 546 "]
 547 if test "x$ac_cv_header_stdint_h" = "xyes"; then
 548   size_includes=["$size_includes
 549 #include <stdint.h>
 550 "]
 551 fi
 552 if test "x$ac_cv_header_unistd_h" = "xyes"; then
 553   size_includes=["$size_includes
 554 #include <unistd.h>
 555 "]
 556 fi
 557 GLIB_SIZEOF([$size_includes], size_t, size_t)
 558 GLIB_SIZEOF([$size_includes], ptrdiff_t, ptrdiff_t)
 559 GLIB_SIZEOF([$size_includes], intmax_t, intmax_t)
 560
 561 # Check for some functions
 562 AC_CHECK_FUNCS(lstat strerror strsignal memmove mkstemp vsnprintf stpcpy strcasecmp strncasecmp poll getcwd nanosleep vasprintf)
 563
 564 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 565 # The check is borrowed from the PERL Configure script.
 566 if test "$ac_cv_func_memmove" != "yes"; then
 567   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 568     glib_cv_working_bcopy,[AC_TRY_RUN([
 569       int main() {
 570         char buf[128], abc[128], *b;
 571         int len, off, align;
 572         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 573         for (align = 7; align >= 0; align--) {
 574           for (len = 36; len; len--) {
 575             b = buf+align; bcopy(abc, b, len);
 576             for (off = 1; off <= len; off++) {
 577               bcopy(b, b+off, len); bcopy(b+off, b, len);
 578                 if (bcmp(b, abc, len)) return(1);
 579             }
 580           }
 581         }
 582         return(0);
 583       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 584   if test "$glib_cv_working_bcopy" = "yes"; then
 585     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 586   fi
 587 fi
 588
 589 # Check for sys_errlist
 590 AC_MSG_CHECKING(for sys_errlist)
 591 AC_TRY_LINK(, [
 592 extern char *sys_errlist[];
 593 extern int sys_nerr;
 594 sys_errlist[sys_nerr-1][0] = 0;
 595 ], glib_ok=yes, glib_ok=no)
 596 AC_MSG_RESULT($glib_ok)
 597 if test "$glib_ok" = "no"; then
 598     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 599 fi
 600
 601 # Check for sys_siglist
 602 AC_MSG_CHECKING(for sys_siglist)
 603 AC_TRY_LINK(, [
 604 extern char *sys_siglist[];
 605 exit (sys_siglist[0]);
 606 ], glib_ok=yes, glib_ok=no)
 607 AC_MSG_RESULT($glib_ok)
 608 if test "$glib_ok" = "no"; then
 609     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 610 fi
 611
 612 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 613 AC_MSG_CHECKING(for sys_siglist declaration)
 614 AC_TRY_COMPILE([#include <signal.h>], [
 615 strlen (sys_siglist[0]);
 616 ], glib_ok=yes, glib_ok=no)
 617 AC_MSG_RESULT($glib_ok)
 618 if test "$glib_ok" = "no"; then
 619     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 620 fi
 621
 622 # Check if <sys/select.h> needs to be included for fd_set
 623 AC_MSG_CHECKING([for fd_set])
 624 AC_TRY_COMPILE([#include <sys/types.h>],
 625         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 626 if test "$gtk_ok" = "yes"; then
 627     AC_MSG_RESULT([yes, found in sys/types.h])
 628 else
 629     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
 630     if test "$gtk_ok" = "yes"; then
 631         # *** FIXME: give it a different name
 632         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
 633         AC_MSG_RESULT([yes, found in sys/select.h])
 634     else
 635         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
 636         AC_MSG_RESULT(no)
 637     fi
 638 fi
 639
 640 dnl *** check for sane realloc() ***
 641 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
 642         AC_TRY_RUN([
 643         #include <stdlib.h>
 644         int main() {
 645           return realloc (0, sizeof (int)) == 0;
 646         }],
 647         [glib_cv_sane_realloc=yes],
 648         [glib_cv_sane_realloc=no],
 649         [])
 650 ])
 651 if test x$glib_cv_sane_realloc = xyes; then
 652   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
 653 fi
 654
 655 dnl Check for nl_langinfo and CODESET
 656
 657 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
 658 AC_TRY_COMPILE([#include <langinfo.h>],
 659         [char *codeset = nl_langinfo (CODESET);],
 660    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
 661    have_codeset=yes,
 662    have_codeset=no)
 663 AC_MSG_RESULT($have_codeset)
 664
 665
 666 dnl ****************************************
 667 dnl *** strlcpy/strlcat                  ***
 668 dnl ****************************************
 669 # Check for strlcpy
 670 AC_MSG_CHECKING(for strlcpy/strlcat)
 671 AC_TRY_LINK([#include <stdlib.h>
 672 #include <string.h>], [
 673 char *p = malloc(10);
 674 (void) strlcpy(p, "hi", 10);
 675 (void) strlcat(p, "bye", 10);
 676 ], glib_ok=yes, glib_ok=no)
 677 AC_MSG_RESULT($glib_ok)
 678 if test "$glib_ok" = "yes"; then
 679     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
 680 fi
 681
 682
 683 dnl **********************
 684 dnl *** va_copy checks ***
 685 dnl **********************
 686 dnl we currently check for all three va_copy possibilities, so we get
 687 dnl all results in config.log for bug reports.
 688 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
 689         AC_TRY_RUN([
 690         #include <stdarg.h>
 691         void f (int i, ...) {
 692         va_list args1, args2;
 693         va_start (args1, i);
 694         va_copy (args2, args1);
 695         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 696           exit (1);
 697         va_end (args1); va_end (args2);
 698         }
 699         int main() {
 700           f (0, 42);
 701           return 0;
 702         }],
 703         [glib_cv_va_copy=yes],
 704         [glib_cv_va_copy=no],
 705         [])
 706 ])
 707 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
 708         AC_TRY_RUN([
 709         #include <stdarg.h>
 710         void f (int i, ...) {
 711         va_list args1, args2;
 712         va_start (args1, i);
 713         __va_copy (args2, args1);
 714         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 715           exit (1);
 716         va_end (args1); va_end (args2);
 717         }
 718         int main() {
 719           f (0, 42);
 720           return 0;
 721         }],
 722         [glib_cv___va_copy=yes],
 723         [glib_cv___va_copy=no],
 724         [])
 725 ])
 726
 727 if test "x$glib_cv_va_copy" = "xyes"; then
 728   g_va_copy_func=va_copy
 729 else if test "x$glib_cv___va_copy" = "xyes"; then
 730   g_va_copy_func=__va_copy
 731 fi
 732 fi
 733
 734 if test -n "$g_va_copy_func"; then
 735   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
 736 fi
 737
 738 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
 739         AC_TRY_RUN([
 740         #include <stdarg.h>
 741         void f (int i, ...) {
 742         va_list args1, args2;
 743         va_start (args1, i);
 744         args2 = args1;
 745         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 746           exit (1);
 747         va_end (args1); va_end (args2);
 748         }
 749         int main() {
 750           f (0, 42);
 751           return 0;
 752         }],
 753         [glib_cv_va_val_copy=yes],
 754         [glib_cv_va_val_copy=no],
 755         [])
 756 ])
 757
 758 if test "x$glib_cv_va_val_copy" = "xno"; then
 759   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 760 fi
 761
 762 dnl ***********************
 763 dnl *** g_module checks ***
 764 dnl ***********************
 765 G_MODULE_LIBS=
 766 G_MODULE_LIBS_EXTRA=
 767 G_MODULE_PLUGIN_LIBS=
 768 G_MODULE_LDFLAGS=
 769 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
 770 G_MODULE_NEED_USCORE=0
 771 G_MODULE_BROKEN_RTLD_GLOBAL=0
 772 G_MODULE_HAVE_DLERROR=0
 773 dnl *** force native WIN32 shared lib loader
 774 if test -z "$G_MODULE_IMPL"; then
 775   case "$host" in
 776   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
 777   esac
 778 fi
 779 dnl *** dlopen() and dlsym() in system libraries
 780 if test -z "$G_MODULE_IMPL"; then
 781         AC_CHECK_FUNC(dlopen,
 782                       [AC_CHECK_FUNC(dlsym,
 783                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 784                       [])
 785 fi
 786 dnl *** load_image (BeOS)
 787 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
 788   AC_CHECK_LIB(root, load_image,
 789       [G_MODULE_LIBS="-lbe -lroot -lglib"
 790       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
 791       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
 792       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
 793       [])
 794 fi
 795 dnl *** dlopen() and dlsym() in libdl
 796 if test -z "$G_MODULE_IMPL"; then
 797         AC_CHECK_LIB(dl, dlopen,
 798                      [AC_CHECK_LIB(dl, dlsym,
 799                                    [G_MODULE_LIBS=-ldl
 800                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 801                      [])
 802 fi
 803 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
 804 if test -z "$G_MODULE_IMPL"; then
 805         AC_CHECK_FUNC(NSLinkModule,
 806                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
 807                        G_MODULE_NEED_USCORE=1],
 808                       [])
 809 fi
 810 dnl *** shl_load() in libdld (HP-UX)
 811 if test -z "$G_MODULE_IMPL"; then
 812         AC_MSG_CHECKING(how to export all symbols)
 813         SAVED_LDFLAGS=$LDFLAGS
 814         LDFLAGS="$LDFLAGS -Wl,-E"
 815         AC_TRY_LINK(,[ return 0; ],
 816                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 817                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 818                 AC_TRY_LINK(,[ return 0; ],
 819                         [G_MODULE_LDFLAGS="-bexpall"],
 820                         [G_MODULE_LDFLAGS="none"])
 821         ])
 822         LDFLAGS=$SAVED_LDFLAGS
 823         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 824         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 825                 G_MODULE_LDFLAGS=
 826         fi
 827         AC_CHECK_LIB(dld, shl_load,
 828                 [G_MODULE_LIBS=-ldld
 829                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
 830                 [])
 831 fi
 832 dnl *** additional checks for G_MODULE_IMPL_DL
 833 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 834         case "$host_os" in
 835           linux*)
 836             G_MODULE_LDFLAGS='-rdynamic'
 837             ;;
 838         esac
 839         LIBS_orig="$LIBS"
 840         LDFLAGS_orig="$LDFLAGS"
 841         LIBS="$LIBS $G_MODULE_LIBS"
 842         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 843 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
 844         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
 845                 glib_cv_rtldglobal_broken,[
 846                 AC_TRY_RUN([
 847                 #include <dlfcn.h>
 848                 #ifndef RTLD_GLOBAL
 849                 #define RTLD_GLOBAL 0
 850                 #endif
 851                 #ifndef RTLD_LAZY
 852                 #define RTLD_LAZY 0
 853                 #endif
 854                 int pthread_create;
 855                 int main () {
 856                 void *handle, *global, *local;
 857                 global = &pthread_create;
 858                 handle = dlopen ("libpthread.so", RTLD_GLOBAL | RTLD_LAZY);
 859                 if (!handle) return 0;
 860                 local = dlsym (handle, "pthread_create");
 861                 return global == local;
 862                 }],
 863                         [glib_cv_rtldglobal_broken=no],
 864                         [glib_cv_rtldglobal_broken=yes],
 865                         [])
 866                 rm -f plugin.c plugin.o plugin.lo
 867         ])
 868         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
 869                 G_MODULE_BROKEN_RTLD_GLOBAL=1
 870         else
 871                 G_MODULE_BROKEN_RTLD_GLOBAL=0
 872         fi
 873 dnl *** check whether we need preceeding underscores
 874         AC_CACHE_CHECK([for preceeding underscore in symbols],
 875                 glib_cv_uscore,[
 876                 AC_TRY_RUN([
 877                 #include <dlfcn.h>
 878                 int glib_underscore_test (void) { return 42; }
 879                 int main() {
 880                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 881                   handle = dlopen ((void*)0, 0);
 882                   if (handle) {
 883                     f1 = dlsym (handle, "glib_underscore_test");
 884                     f2 = dlsym (handle, "_glib_underscore_test");
 885                   } return (!f2 || f1);
 886                 }],
 887                         [glib_cv_uscore=yes],
 888                         [glib_cv_uscore=no],
 889                         [])
 890                 rm -f plugin.c plugin.$ac_objext plugin.lo
 891         ])
 892         if test "x$glib_cv_uscore" = "xyes"; then
 893                 G_MODULE_NEED_USCORE=1
 894         else
 895                 G_MODULE_NEED_USCORE=0
 896         fi
 897
 898         LDFLAGS="$LDFLAGS_orig"
 899 dnl *** check for having dlerror()
 900         AC_CHECK_FUNC(dlerror,
 901                 [G_MODULE_HAVE_DLERROR=1],
 902                 [G_MODULE_HAVE_DLERROR=0])
 903         LIBS="$LIBS_orig"
 904 fi
 905 dnl *** done, have we got an implementation?
 906 if test -z "$G_MODULE_IMPL"; then
 907         G_MODULE_IMPL=0
 908         G_MODULE_SUPPORTED=false
 909 else
 910         G_MODULE_SUPPORTED=true
 911 fi
 912
 913 AC_MSG_CHECKING(for the suffix of shared libraries)
 914 case "$host_os" in
 915   hpux9* | hpux10* | hpux11*)  # taken from ltconfig
 916     glib_gmodule_suffix='sl'
 917     ;;
 918   cygwin* | mingw*)
 919     glib_gmodule_suffix='dll'
 920     ;;
 921   *)
 922     glib_gmodule_suffix='so'
 923     ;;
 924 esac
 925 AC_MSG_RESULT(.$glib_gmodule_suffix)
 926
 927 AC_SUBST(G_MODULE_SUPPORTED)
 928 AC_SUBST(G_MODULE_IMPL)
 929 AC_SUBST(G_MODULE_LIBS)
 930 AC_SUBST(G_MODULE_LIBS_EXTRA)
 931 AC_SUBST(G_MODULE_PLUGIN_LIBS)
 932 AC_SUBST(G_MODULE_LDFLAGS)
 933 AC_SUBST(G_MODULE_HAVE_DLERROR)
 934 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
 935 AC_SUBST(G_MODULE_NEED_USCORE)
 936 AC_SUBST(GLIB_DEBUG_FLAGS)
 937
 938 dnl **********************
 939 dnl *** g_spawn checks ***
 940 dnl **********************
 941
 942 AC_MSG_CHECKING(for gspawn implementation)
 943 case "$host" in
 944   *-*-mingw*)
 945     GSPAWN=gspawn-win32.lo
 946     ;;
 947   *)
 948     GSPAWN=gspawn.lo
 949     ;;
 950 esac
 951 AC_MSG_RESULT($GSPAWN)
 952 AC_SUBST(GSPAWN)
 953
 954 dnl *************************
 955 dnl *** GIOChannel checks ***
 956 dnl *************************
 957
 958 AC_MSG_CHECKING(for GIOChannel implementation)
 959 case "$host" in
 960   *-*-mingw*)
 961     GIO=giowin32.lo
 962     ;;
 963   *)
 964     GIO=giounix.lo
 965     ;;
 966 esac
 967 AC_MSG_RESULT($GIO)
 968 AC_SUBST(GIO)
 969
 970 dnl ****************************************
 971 dnl *** platform dependent source checks ***
 972 dnl ****************************************
 973
 974 AC_MSG_CHECKING(for platform-dependent source)
 975 case "$host" in
 976   *-*-cygwin*|*-*-mingw*)
 977     PLATFORMDEP=gwin32.lo
 978     ;;
 979   *)
 980     PLATFORMDEP=
 981     ;;
 982 esac
 983 AC_MSG_RESULT($PLATFORMDEP)
 984 AC_SUBST(PLATFORMDEP)
 985
 986 AC_MSG_CHECKING([whether to compile timeloop])
 987 case "$host" in
 988   *-*-cygwin*|*-*-mingw*)
 989     enable_timeloop=no
 990     ;;
 991   *)
 992     enable_timeloop=yes
 993     ;;
 994 esac
 995 AC_MSG_RESULT($enable_timeloop)
 996 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
 997
 998 AC_MSG_CHECKING([if building for some Win32 platform])
 999 case "$host" in
1000   *-*-mingw*|*-*-cygwin*)
1001     platform_win32=yes
1002     ;;
1003   *)
1004     platform_win32=no
1005     ;;
1006 esac
1007 AC_MSG_RESULT($platform_win32)
1008 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1009
1010 dnl ***********************
1011 dnl *** g_thread checks ***
1012 dnl ***********************
1013
1014 AC_ARG_WITH(threads, [  --with-threads=[none/posix/dce/solaris/win32] specify a thread implementation to use],
1015         if test "x$with_threads" = x; then
1016                 want_threads=yes
1017         else
1018                 want_threads=$with_threads
1019         fi,
1020         want_threads=yes)
1021 if test "x$enable_threads" = "xno"; then
1022         want_threads=no
1023 fi
1024
1025 dnl error and warning message
1026 dnl *************************
1027
1028 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1029                 computer. GLib will not have a default thread implementation."
1030
1031 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1032                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1033                 compilation now, but then your programs might not work.
1034                 Please provide information on how it is done on your system."
1035
1036 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1037                 "
1038
1039 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1040                 provide information on your thread implementation.
1041                 You can also run 'configure --disable-threads'
1042                 to compile without thread support."
1043
1044 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1045                 functions will not be MT-safe during their first call because
1046                 there is no working 'getpwuid_r' on your system."
1047
1048 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1049                 because there is no 'localtime_r' on your system."
1050
1051 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1052                 crude surrogate will be used. If you happen to know a
1053                 yield function for your system, please inform the GLib
1054                 developers."
1055
1056 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1057                 threads on your system. Thus threads can only have the default
1058                 priority. If you happen to know these main/max
1059                 priorities, please inform the GLib developers."
1060
1061
1062 dnl determination of thread implementation
1063 dnl ***************************************
1064
1065 # have_threads=no   means no thread support
1066 # have_threads=none means no default thread implementation
1067
1068 have_threads=no
1069 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
1070         case $host in
1071                 *-*-solaris*)
1072                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
1073                 ;;
1074         esac
1075 fi
1076 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1077                                 || test "x$want_threads" = xdce; then
1078         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1079         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1080         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1081         glib_save_CPPFLAGS="$CPPFLAGS"
1082         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1083         if test "x$have_threads" = xno; then
1084                 AC_TRY_COMPILE([#include <pthread.h>],
1085                         [pthread_attr_t attr; pthread_attr_init(&attr);],
1086                         have_threads=posix)
1087         fi
1088         if test "x$have_threads" = xno; then
1089                 AC_TRY_COMPILE([#include <pthread.h>],
1090                         [pthread_attr_t attr; pthread_attr_create(&attr);],
1091                         have_threads=posix)
1092         fi
1093         CPPFLAGS="$glib_save_CPPFLAGS"
1094 fi
1095 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1096         case $host in
1097                 *-*-mingw*)
1098                 have_threads=win32
1099                 ;;
1100         esac
1101 fi
1102 if test "x$want_threads" = xnone; then
1103         have_threads=none
1104 fi
1105
1106 AC_MSG_CHECKING(for thread implementation)
1107
1108 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1109         AC_MSG_RESULT(none available)
1110         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1111 else
1112         AC_MSG_RESULT($have_threads)
1113 fi
1114
1115
1116 dnl determination of G_THREAD_CFLAGS
1117 dnl ********************************
1118
1119 G_THREAD_LIBS=
1120 G_THREAD_LIBS_EXTRA=
1121 G_THREAD_CFLAGS=
1122
1123 if test x"$have_threads" != xno; then
1124
1125     G_THREAD_CFLAGS="-D_REENTRANT" # good default guess
1126
1127     case $host in
1128         *-aix*)
1129                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
1130                 if test x"$GCC" = xyes; then
1131                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
1132                 fi
1133                 ;;
1134         *-freebsd2.2*)
1135                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
1136
1137                 # FreeBSD 2.2.x shiped with gcc 2.7.2.x, which doesn't support
1138                 # -mthreads flag.
1139                 ;;
1140         *-sysv5uw7*)  # UnixWare 7
1141                 if test "$GCC" != "yes"; then
1142                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -Kthread"
1143                 else
1144                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -pthread"
1145                 fi
1146                 ;;
1147         *-dg-dgux*)  # DG/UX
1148                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
1149     esac
1150
1151     # if we are not finding the localtime_r function, then we probably are
1152     # not using the proper multithread flag
1153
1154     glib_save_CPPFLAGS="$CPPFLAGS"
1155     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1156
1157     # First we test, whether localtime_r is declared in time.h
1158     # directly. Then we test whether a macro localtime_r exists, in
1159     # which case localtime_r in the test program is replaced and thus
1160     # if we still find localtime_r in the output, it is not defined as
1161     # a macro.
1162
1163     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1164       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1165                                                            localtime_r(a,b)],
1166                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1167
1168     CPPFLAGS="$glib_save_CPPFLAGS"
1169
1170     AC_MSG_CHECKING(thread related cflags)
1171     AC_MSG_RESULT($G_THREAD_CFLAGS)
1172     CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
1173 fi
1174
1175 dnl determination of G_THREAD_LIBS
1176 dnl ******************************
1177
1178 mutex_has_default=no
1179 case $have_threads in
1180         posix|dce)
1181            glib_save_CPPFLAGS="$CPPFLAGS"
1182            CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1183            G_THREAD_LIBS=error
1184            glib_save_LIBS="$LIBS"
1185            case $host in
1186              *-sysv5uw7*) # UnixWare 7
1187                 if test "$GCC" != "yes"; then
1188                         G_THREAD_LIBS="-Kthread"
1189                 else
1190                         G_THREAD_LIBS="-pthread"
1191                 fi
1192                 ;;
1193              *)
1194                 for thread_lib in "" pthread pthread32 pthreads c_r thread dce; do
1195                         if test x"$thread_lib" = x; then
1196                                 add_thread_lib=""
1197                                 IN=""
1198                         else
1199                                 add_thread_lib="-l$thread_lib"
1200                                 IN=" in -l$thread_lib"
1201                         fi
1202                         if test x"$have_threads" = xposix; then
1203                                 defattr=0
1204                         else
1205                                 defattr=pthread_attr_default
1206                         fi
1207
1208                         LIBS="$glib_save_LIBS $add_thread_lib"
1209
1210                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
1211                         AC_TRY_RUN([#include <pthread.h>
1212                                 int check_me = 0;
1213                                 void* func(void* data) {check_me = 42;}
1214                                 main()
1215                                 { pthread_t t;
1216                                   void *ret;
1217                                   pthread_create (&t, $defattr, func, 0);
1218                                   pthread_join (t, &ret);
1219                                   exit (check_me != 42);
1220                                 }],
1221                                 [AC_MSG_RESULT(yes)
1222                                 G_THREAD_LIBS="$add_thread_lib"
1223                                 break],
1224                                 [AC_MSG_RESULT(no)])
1225                 done
1226                 if test "x$G_THREAD_LIBS" = xerror; then
1227                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1228                 fi
1229                 for thread_lib in "" rt rte; do
1230                         if test x"$thread_lib" = x; then
1231                                 add_thread_lib=""
1232                                 IN=""
1233                         else
1234                                 add_thread_lib="-l$thread_lib"
1235                                 IN=" in -l$thread_lib"
1236                         fi
1237                         LIBS="$glib_save_LIBS $add_thread_lib"
1238
1239                         AC_MSG_CHECKING(for sched_get_priority_min$IN)
1240                         AC_TRY_RUN([#include <sched.h>
1241                                 #include <errno.h>
1242                                 int main() {
1243                                 errno = 0;
1244                                 return sched_get_priority_min(SCHED_OTHER)==-1
1245                                         && errno != 0;
1246                                 }],
1247                                 [AC_MSG_RESULT(yes)
1248                                 G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
1249                                 posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
1250                                 posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
1251                                 break],
1252                                 [AC_MSG_RESULT(no)])
1253                 done
1254                 LIBS="$glib_save_LIBS"
1255                 ;;
1256            esac
1257            mutex_has_default=yes
1258            mutex_default_type='pthread_mutex_t'
1259            mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
1260            mutex_header_file='pthread.h'
1261            if test "x$have_threads" = "xposix"; then
1262              g_threads_impl="POSIX"
1263            else
1264              g_threads_impl="DCE"
1265              have_threads="posix"
1266            fi
1267            AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
1268            CPPFLAGS="$glib_save_CPPFLAGS"
1269            ;;
1270         solaris)
1271            G_THREAD_LIBS=error
1272            AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
1273            mutex_has_default=yes
1274            mutex_default_type='mutex_t'
1275            mutex_default_init="DEFAULTMUTEX"
1276            mutex_header_file='thread.h'
1277            g_threads_impl="SOLARIS"
1278            ;;
1279         win32)
1280            g_threads_impl="WIN32"
1281            G_THREAD_LIBS=""
1282            ;;
1283         none)
1284            g_threads_impl="NONE"
1285            ;;
1286         *)
1287            g_threads_impl="NONE"
1288            G_THREAD_LIBS=error
1289            ;;
1290 esac
1291
1292 if test "x$G_THREAD_LIBS" = xerror; then
1293         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1294 fi
1295
1296 case $host in
1297   *-*-beos*)
1298     G_THREAD_LIBS="-lbe -lroot -lglib "
1299     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1300     ;;
1301   *)
1302     ;;
1303 esac
1304
1305 AC_MSG_CHECKING(thread related libraries)
1306 AC_MSG_RESULT($G_THREAD_LIBS)
1307
1308 dnl check for mt safe function variants and some posix functions
1309 dnl ************************************************************
1310
1311 if test x"$have_threads" != xno; then
1312         glib_save_LIBS="$LIBS"
1313         # we are not doing the following for now, as this might require glib
1314         # to always be linked with the thread libs on some platforms.
1315         # LIBS="$LIBS $G_THREAD_LIBS"
1316         AC_CHECK_FUNCS(localtime_r)
1317         if test "$ac_cv_header_pwd_h" = "yes"; then
1318                 AC_CACHE_CHECK([for posix getpwuid_r],
1319                         ac_cv_func_posix_getpwuid_r,
1320                         [AC_TRY_RUN([#include <errno.h>
1321                                 #include <pwd.h>
1322                                 int main () { char buffer[10000];
1323                                 struct passwd pwd, *pwptr = &pwd;
1324                                 int error;
1325                                 errno = 0;
1326                                 error = getpwuid_r (0, &pwd, buffer,
1327                                         sizeof (buffer), &pwptr);
1328                                 return (error < 0 && errno == ENOSYS)
1329                                         || error == ENOSYS; }],
1330                                 [ac_cv_func_posix_getpwuid_r=yes],
1331                                 [ac_cv_func_posix_getpwuid_r=no])])
1332                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
1333                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
1334                                 [Have POSIX function getpwuid_r])
1335                 else
1336                         AC_CACHE_CHECK([for nonposix getpwuid_r],
1337                                 ac_cv_func_nonposix_getpwuid_r,
1338                                 [AC_TRY_LINK([#include <pwd.h>],
1339                                         [char buffer[10000];
1340                                         struct passwd pwd;
1341                                         getpwuid_r (0, &pwd, buffer,
1342                                                         sizeof (buffer));],
1343                                         [ac_cv_func_nonposix_getpwuid_r=yes],
1344                                         [ac_cv_func_nonposix_getpwuid_r=no])])
1345                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
1346                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
1347                                         [Have non-POSIX function getpwuid_r])
1348                         fi
1349                 fi
1350         fi
1351         LIBS="$LIBS $G_THREAD_LIBS"
1352         if test x"$have_threads" = xposix; then
1353                 glib_save_CPPFLAGS="$CPPFLAGS"
1354                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1355                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
1356                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
1357                 # This is not AC_CHECK_FUNC to also work with function
1358                 # name mangling in header files.
1359                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1360                 AC_TRY_LINK([#include <pthread.h>],
1361                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1362                         [AC_MSG_RESULT(yes)
1363                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1364                                   [Have function pthread_attr_setstacksize])],
1365                         [AC_MSG_RESULT(no)])
1366                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1367                 if test x"$posix_priority_min" = xnone; then
1368                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1369                                 PX_PRIO_MIN],,[
1370                                 posix_priority_min=PX_PRIO_MIN
1371                                 posix_priority_max=PX_PRIO_MAX])
1372                 fi
1373                 if test x"$posix_priority_min" = xnone; then
1374                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1375                                 PRI_OTHER_MIN],,[
1376                                 posix_priority_min=PRI_OTHER_MIN
1377                                 posix_priority_max=PRI_OTHER_MAX])
1378                 fi
1379                 if test x"$posix_priority_min" = x; then
1380                         AC_MSG_RESULT(none found)
1381                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1382                         posix_priority_min=-1
1383                         posix_priority_max=-1
1384                 else
1385                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1386                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1387                         AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])
1388                 fi
1389                 posix_yield_func=none
1390                 AC_MSG_CHECKING(for posix yield function)
1391                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1392                                                         thr_yield; do
1393                         AC_TRY_LINK([#include <pthread.h>],
1394                                 [$yield_func()],
1395                                 [posix_yield_func="$yield_func"
1396                                 break])
1397                 done
1398                 if test x"$posix_yield_func" = xnone; then
1399                         AC_MSG_RESULT(none found)
1400                         AC_MSG_WARN($POSIX_NO_YIELD)
1401                         posix_yield_func="g_usleep(1000)"
1402                 else
1403                         AC_MSG_RESULT($posix_yield_func)
1404                         posix_yield_func="$posix_yield_func()"
1405                 fi
1406                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1407                 CPPFLAGS="$glib_save_CPPFLAGS"
1408
1409                 AC_MSG_CHECKING(whether to use the PID niceness surrogate for thread priorities)
1410                 AC_TRY_RUN([#include <pthread.h>
1411                         #include <sys/types.h>
1412                         #include <unistd.h>
1413                         pid_t other_pid = 0;
1414
1415                         void* func(void* data) {other_pid = getpid();}
1416                         main()
1417                         { pthread_t t;
1418                           void *ret;
1419                           pthread_create (&t, $defattr, func, NULL);
1420                           pthread_join (t, &ret);
1421                           exit (getpid()==other_pid ||
1422                                 $posix_priority_min != $posix_priority_max);
1423                         }],
1424                         [AC_MSG_RESULT(yes)
1425                           AC_DEFINE(G_THREAD_USE_PID_SURROGATE, 1, [whether to use the PID niceness surrogate for thread priorities])
1426                         ],
1427                         [AC_MSG_RESULT(no)])
1428         elif test x"$have_threads" = xwin32; then
1429                 # It's a pointer to a private struct
1430                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
1431         elif test x"$have_threads" = xsolaris; then
1432                 GLIB_SIZEOF([#include <thread.h>], thread_t, system_thread)
1433         fi
1434
1435         LIBS="$glib_save_LIBS"
1436
1437         # now spit out all the warnings.
1438         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1439            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1440                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1441         fi
1442         if test "$ac_cv_func_localtime_r" != "yes"; then
1443                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1444         fi
1445 fi
1446
1447 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1448                    [Source file containing theread implementation])
1449 AC_SUBST(G_THREAD_CFLAGS)
1450 AC_SUBST(G_THREAD_LIBS)
1451 AC_SUBST(G_THREAD_LIBS_EXTRA)
1452
1453 dnl **********************************************
1454 dnl *** GDefaultMutex setup and initialization ***
1455 dnl **********************************************
1456 dnl
1457 dnl if mutex_has_default = yes, we also got
1458 dnl mutex_default_type, mutex_default_init and mutex_header_file
1459 GLIB_IF_VAR_EQ(mutex_has_default, yes,
1460         glib_save_CPPFLAGS="$CPPFLAGS"
1461         glib_save_LIBS="$LIBS"
1462         LIBS="$LIBS $G_THREAD_LIBS"
1463         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1464         GLIB_SIZEOF([#include <$mutex_header_file>],
1465                     $mutex_default_type,
1466                     gmutex,
1467                     )
1468         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1469                            $mutex_default_type,
1470                            gmutex,
1471                            $glib_cv_sizeof_gmutex,
1472                            $mutex_default_init)
1473         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1474                 mutex_has_default=no
1475         fi
1476         CPPFLAGS="$glib_save_CPPFLAGS"
1477         LIBS="$glib_save_LIBS"
1478         ,
1479 )
1480
1481
1482 dnl ****************************************
1483 dnl *** GLib POLL* compatibility defines ***
1484 dnl ****************************************
1485 GLIB_SYSDEFS(
1486 [#include <sys/types.h>
1487 #include <sys/poll.h>],
1488         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
1489         glibconfig-sysdefs.h,
1490         =)
1491
1492 dnl **********************
1493 dnl *** Win32 API libs ***
1494 dnl **********************
1495
1496 case $host in
1497   *-*-cygwin*)
1498         G_LIBS_EXTRA="-luser32 -lwsock32 -lkernel32"
1499     ;;
1500   *-*-mingw*)
1501         G_LIBS_EXTRA="-lwsock32"
1502     ;;
1503   *)
1504         G_LIBS_EXTRA=""
1505     ;;
1506 esac
1507 AC_SUBST(G_LIBS_EXTRA)
1508
1509 dnl ***********************
1510 dnl *** Tests for iconv ***
1511 dnl ***********************
1512
1513 AC_ARG_WITH(libiconv, [ --with-libiconv     Use the libiconv library ],,with_libiconv=maybe)
1514
1515 found_iconv=no
1516
1517 if test "x$with_libiconv" != "xyes" ; then
1518    #
1519    # Check in the C library
1520    #
1521    AC_CHECK_FUNC(iconv_open, with_libiconv=no; found_iconv=yes)
1522 fi
1523
1524 if test "x$with_libiconv" != "xno" ; then
1525    #
1526    # Check for libiconv
1527    #
1528    AC_CHECK_LIB(iconv, libiconv_open, with_libiconv=yes; found_iconv=yes)
1529 fi
1530
1531 if test "x$found_iconv" = "xno" ; then
1532    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
1533 fi
1534
1535 if test "x$with_libiconv" = "xyes" ; then
1536   ICONV_LIBS="-liconv"
1537   AC_DEFINE(USE_LIBICONV)
1538 fi
1539 AC_SUBST(ICONV_LIBS)
1540
1541 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
1542 dnl since we need it for g_iconv()
1543
1544 AC_MSG_CHECKING([for EILSEQ])
1545 AC_TRY_COMPILE([
1546 #include <errno.h>
1547 ],
1548 [
1549 int error = EILSEQ;
1550 ], have_eilseq=yes, have_eilseq=no);
1551 AC_MSG_RESULT($have_eilseq)
1552
1553 dnl **************************
1554 dnl *** Checks for gtk-doc ***
1555 dnl **************************
1556
1557 AC_ARG_WITH(html-dir, [  --with-html-dir=PATH    path to installed docs])
1558
1559 if test "x$with_html_dir" = "x" ; then
1560   HTML_DIR='${datadir}/gtk-doc/html'
1561 else
1562   HTML_DIR=$with_html_dir
1563 fi
1564
1565 AC_SUBST(HTML_DIR)
1566
1567 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
1568
1569 gtk_doc_min_version=0.6
1570 if $GTKDOC ; then
1571     gtk_doc_version=`gtkdoc-mkdb --version`
1572     AC_MSG_CHECKING([gtk-doc version ($gtk_doc_version) >= $gtk_doc_min_version])
1573     if perl <<EOF ; then
1574       exit (("$gtk_doc_version" =~ /^[[0-9]]+\.[[0-9]]+$/) &&
1575             ("$gtk_doc_version" >= "$gtk_doc_min_version") ? 0 : 1);
1576 EOF
1577       AC_MSG_RESULT(yes)
1578    else
1579       AC_MSG_RESULT(no)
1580       GTKDOC=false
1581    fi
1582 fi
1583
1584 AM_CONDITIONAL(HAVE_GTK_DOC, $GTKDOC)
1585 AC_SUBST(HAVE_GTK_DOC)
1586
1587 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1588 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1589
1590 dnl Let people disable the gtk-doc stuff.
1591 AC_ARG_ENABLE(gtk-doc, [  --enable-gtk-doc        use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)
1592
1593 if test x$enable_gtk_doc = xauto ; then
1594   if test x$GTKDOC = xtrue ; then
1595     enable_gtk_doc=yes
1596   else
1597     enable_gtk_doc=no
1598   fi
1599 fi
1600
1601 dnl NOTE: We need to use a separate automake conditional for this
1602 dnl       to make this work with the tarballs.
1603 AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
1604
1605 dnl ******************************
1606 dnl *** output the whole stuff ***
1607 dnl ******************************
1608
1609 AC_OUTPUT_COMMANDS([
1610
1611 ## Generate `glibconfig.h' in two cases
1612 ## 1. `config.status' is run either explicitly, or via configure.
1613 ##     Esp. not when it is run in `Makefile' to generate makefiles and
1614 ##     config.h
1615 ## 2. CONFIG_OTHER is set explicitly
1616 ##
1617 ## Case 1 is difficult.  We know that `automake' sets one of
1618 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
1619 ## only when AM_CONFIG_HEADER is set, however.
1620
1621 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
1622   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
1623   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
1624 fi
1625 case "$CONFIG_OTHER" in
1626 *glibconfig.h*)
1627         echo creating glibconfig.h
1628         outfile=glibconfig.h-tmp
1629         cat > $outfile <<\_______EOF
1630 /* glibconfig.h
1631  *
1632  * This is a generated file.  Please modify 'configure.in'
1633  */
1634
1635 #ifndef __G_LIBCONFIG_H__
1636 #define __G_LIBCONFIG_H__
1637
1638 #include <glib/gmacros.h>
1639
1640 _______EOF
1641
1642         if test x$glib_limits_h = xyes; then
1643           echo '#include <limits.h>' >> $outfile
1644         fi
1645         if test x$glib_float_h = xyes; then
1646           echo '#include <float.h>' >> $outfile
1647         fi
1648         if test x$glib_values_h = xyes; then
1649           echo '#include <values.h>' >> $outfile
1650         fi
1651         if test "$glib_header_alloca_h" = "yes"; then
1652           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
1653         fi
1654         if test x$glib_sys_poll_h = xyes; then
1655           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
1656         fi
1657
1658         cat >> $outfile <<_______EOF
1659
1660 G_BEGIN_DECLS
1661
1662 #define G_MINFLOAT      $glib_mf
1663 #define G_MAXFLOAT      $glib_Mf
1664 #define G_MINDOUBLE     $glib_md
1665 #define G_MAXDOUBLE     $glib_Md
1666 #define G_MINSHORT      $glib_ms
1667 #define G_MAXSHORT      $glib_Ms
1668 #define G_MAXUSHORT     $glib_Mus
1669 #define G_MININT        $glib_mi
1670 #define G_MAXINT        $glib_Mi
1671 #define G_MAXUINT       $glib_Mui
1672 #define G_MINLONG       $glib_ml
1673 #define G_MAXLONG       $glib_Ml
1674 #define G_MAXULONG      $glib_Mul
1675
1676 #define G_MININT64      ((gint64)  0x8000000000000000)
1677 #define G_MAXINT64      ((gint64)  0x7fffffffffffffff)
1678 #define G_MAXUINT64     ((guint64) 0xffffffffffffffff)
1679
1680 _______EOF
1681
1682
1683         ### this should always be true in a modern C/C++ compiler
1684         cat >>$outfile <<_______EOF
1685 typedef signed char gint8;
1686 typedef unsigned char guint8;
1687 _______EOF
1688
1689
1690         if test -n "$gint16"; then
1691           cat >>$outfile <<_______EOF
1692 typedef signed $gint16 gint16;
1693 typedef unsigned $gint16 guint16;
1694 #define G_GINT16_FORMAT $gint16_format
1695 #define G_GUINT16_FORMAT $guint16_format
1696 _______EOF
1697         fi
1698
1699
1700         if test -n "$gint32"; then
1701           cat >>$outfile <<_______EOF
1702 typedef signed $gint32 gint32;
1703 typedef unsigned $gint32 guint32;
1704 #define G_GINT32_FORMAT $gint32_format
1705 #define G_GUINT32_FORMAT $guint32_format
1706 _______EOF
1707         fi
1708
1709         cat >>$outfile <<_______EOF
1710 #define G_HAVE_GINT64 1          /* deprecated, always true */
1711
1712 ${glib_extension}typedef signed $gint64 gint64;
1713 ${glib_extension}typedef unsigned $gint64 guint64;
1714
1715 #define G_GINT64_CONSTANT(val)  $gint64_constant
1716
1717 #define G_GINT64_FORMAT $gint64_format
1718 #define G_GUINT64_FORMAT $guint64_format
1719 _______EOF
1720
1721         cat >>$outfile <<_______EOF
1722
1723 #define GLIB_SIZEOF_VOID_P $glib_void_p
1724 #define GLIB_SIZEOF_LONG   $glib_long
1725
1726 _______EOF
1727
1728         case x$glib_size_t in
1729         x2) echo "typedef gint16  gssize;" >> $outfile
1730             echo "typedef guint16 gsize;"  >> $outfile
1731             ;;
1732         x4) echo "typedef gint32  gssize;" >> $outfile
1733             echo "typedef guint32 gsize;"  >> $outfile
1734             ;;
1735         x8) echo "typedef gint64  gssize;" >> $outfile
1736             echo "typedef guint64 gsize;"  >> $outfile
1737             ;;
1738         *)  echo "#error size of size_t is unknown" >> $outfile
1739             ;;
1740         esac
1741
1742         if test -z "$glib_unknown_void_p"; then
1743           cat >>$outfile <<_______EOF
1744
1745 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
1746 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
1747
1748 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
1749 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
1750 _______EOF
1751         else
1752           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
1753         fi
1754
1755
1756
1757         cat >>$outfile <<_______EOF
1758 $glib_atexit
1759 $glib_memmove
1760 $glib_defines
1761 $glib_os
1762
1763 $glib_vacopy
1764
1765 #ifdef  __cplusplus
1766 #define G_HAVE_INLINE   1
1767 #else   /* !__cplusplus */
1768 $glib_inline
1769 #endif  /* !__cplusplus */
1770
1771 _______EOF
1772
1773         if test x$g_have_iso_c_varargs = xyes ; then
1774                 cat >>$outfile <<_______EOF
1775 #ifndef __cplusplus
1776 # define G_HAVE_ISO_VARARGS 1
1777 #endif
1778 _______EOF
1779         fi
1780         if test x$g_have_iso_cxx_varargs = xyes ; then
1781                 cat >>$outfile <<_______EOF
1782 #ifdef __cplusplus
1783 # define G_HAVE_ISO_VARARGS 1
1784 #endif
1785 _______EOF
1786         fi
1787         if test x$g_have_gnuc_varargs = xyes ; then
1788                 cat >>$outfile <<_______EOF
1789
1790 #define G_HAVE_GNUC_VARARGS 1
1791 _______EOF
1792         fi
1793
1794         echo >>$outfile
1795         if test x$g_have_eilseq = xno; then
1796                 cat >>$outfile <<_______EOF
1797 #ifndef EILSEQ
1798 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
1799  * The correspondence between this and the corresponding definition
1800  * in libiconv is essential.
1801  */
1802 #  define EILSEQ ENOENT
1803 #endif
1804 _______EOF
1805
1806         fi
1807
1808         echo >>$outfile
1809         if test x$g_mutex_has_default = xyes; then
1810                 cat >>$outfile <<_______EOF
1811 $g_enable_threads_def G_THREADS_ENABLED
1812 #define G_THREADS_IMPL_$g_threads_impl_def
1813 typedef struct _GStaticMutex GStaticMutex;
1814 struct _GStaticMutex
1815 {
1816   struct _GMutex *runtime_mutex;
1817   union {
1818     char   pad[$g_mutex_sizeof];
1819     double dummy_double;
1820     void  *dummy_pointer;
1821     long   dummy_long;
1822   } static_mutex;
1823 };
1824 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
1825 #define g_static_mutex_get_mutex(mutex) \
1826   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->static_mutex)) : \
1827    g_static_mutex_get_mutex_impl (&((mutex)->runtime_mutex)))
1828 _______EOF
1829         else
1830                 cat >>$outfile <<_______EOF
1831 $g_enable_threads_def G_THREADS_ENABLED
1832 #define G_THREADS_IMPL_$g_threads_impl_def
1833 typedef struct _GMutex* GStaticMutex;
1834 #define G_STATIC_MUTEX_INIT NULL
1835 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (mutex))
1836 _______EOF
1837         fi
1838
1839         cat >>$outfile <<_______EOF
1840 /* This represents a system thread as used by the implementation. An
1841  * alien implementaion, as loaded by g_thread_init can only count on
1842  * "sizeof (gpointer)" bytes to store their info. We however need more
1843  * for some of our native implementations. */
1844 typedef union _GSystemThread GSystemThread;
1845 union _GSystemThread
1846 {
1847   char   data[$g_system_thread_sizeof];
1848   double dummy_double;
1849   void  *dummy_pointer;
1850   long   dummy_long;
1851 };
1852 _______EOF
1853
1854         echo >>$outfile
1855         g_bit_sizes="16 32 64"
1856         for bits in $g_bit_sizes; do
1857           cat >>$outfile <<_______EOF
1858 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
1859 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
1860 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
1861 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
1862 _______EOF
1863         done
1864
1865         cat >>$outfile <<_______EOF
1866 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
1867 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
1868 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
1869 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
1870 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
1871 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
1872 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
1873 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
1874 #define G_BYTE_ORDER $g_byte_order
1875
1876 _______EOF
1877
1878         if test -r glibconfig-sysdefs.h; then
1879           cat glibconfig-sysdefs.h >>$outfile
1880         fi
1881
1882         cat >>$outfile <<_______EOF
1883
1884 #define G_MODULE_SUFFIX "$g_module_suffix"
1885
1886 G_END_DECLS
1887
1888 #endif /* GLIBCONFIG_H */
1889 _______EOF
1890
1891
1892         if cmp -s $outfile glibconfig.h; then
1893           echo glibconfig.h is unchanged
1894           rm -f $outfile
1895         else
1896           mv $outfile glibconfig.h
1897         fi ;;
1898 esac
1899 ],[
1900
1901 # Note that if two cases are the same, case goes with the first one.
1902 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
1903 # on variable expansion in case labels.  Look at the generated config.status
1904 # for a hint.
1905
1906 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
1907   glib_header_alloca_h="$ac_cv_working_alloca_h"
1908 else
1909   glib_header_alloca_h="$ac_cv_header_alloca_h"
1910 fi
1911
1912 case xyes in
1913 x$ac_cv_header_float_h)
1914   glib_float_h=yes
1915   glib_mf=FLT_MIN glib_Mf=FLT_MAX
1916   glib_md=DBL_MIN glib_Md=DBL_MAX
1917   ;;
1918 x$ac_cv_header_values_h)
1919   glib_values_h=yes
1920   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
1921   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
1922   ;;
1923 esac
1924
1925 case xyes in
1926 x$ac_cv_header_limits_h)
1927   glib_limits_h=yes
1928   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
1929   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
1930   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
1931   ;;
1932 x$ac_cv_header_values_h)
1933   glib_values_h=yes
1934   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
1935   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
1936   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
1937   ;;
1938 esac
1939
1940 if test x$ac_cv_header_sys_poll_h = xyes ; then
1941   glib_sys_poll_h=yes
1942 fi
1943
1944 case 2 in
1945 $ac_cv_sizeof_short)
1946   gint16=short
1947   gint16_format='"hi"'
1948   guint16_format='"hu"'
1949   ;;
1950 $ac_cv_sizeof_int)
1951   gint16=int
1952   gint16_format='"i"'
1953   guint16_format='"u"'
1954   ;;
1955 esac
1956 case 4 in
1957 $ac_cv_sizeof_short)
1958   gint32=short
1959   gint32_format='"hi"'
1960   guint32_format='"hu"'
1961   ;;
1962 $ac_cv_sizeof_int)
1963   gint32=int
1964   gint32_format='"i"'
1965   guint32_format='"u"'
1966   ;;
1967 $ac_cv_sizeof_long)
1968   gint32=long
1969   gint32_format='"li"'
1970   guint32_format='"lu"'
1971   ;;
1972 esac
1973 case 8 in
1974 $ac_cv_sizeof_int)
1975   gint64=int
1976   gint64_format='"i"'
1977   guint64_format='"u"'
1978   glib_extension=
1979   gint64_constant='(val)'
1980   ;;
1981 $ac_cv_sizeof_long)
1982   gint64=long
1983   gint64_format='"li"'
1984   guint64_format='"lu"'
1985   glib_extension=
1986   gint64_constant='(val##L)'
1987   ;;
1988 $ac_cv_sizeof_long_long)
1989   gint64='long long'
1990   if test -n "$glib_cv_long_long_format"; then
1991     gint64_format='"'$glib_cv_long_long_format'i"'
1992     guint64_format='"'$glib_cv_long_long_format'u"'
1993   fi
1994   glib_extension='G_GNUC_EXTENSION '
1995   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1996   ;;
1997 $ac_cv_sizeof___int64)
1998   gint64='__int64'
1999   if test -n "$glib_cv_long_long_format"; then
2000     gint64_format='"'$glib_cv_long_long_format'i"'
2001     guint64_format='"'$glib_cv_long_long_format'u"'
2002   fi
2003   glib_extension=
2004   gint64_constant='(val##i64)'
2005   ;;
2006 esac
2007 glib_size_t=$glib_cv_sizeof_size_t
2008 glib_void_p=$ac_cv_sizeof_long
2009 glib_long=$ac_cv_sizeof_void_p
2010
2011 gintbits=`expr $ac_cv_sizeof_int \* 8`
2012 glongbits=`expr $ac_cv_sizeof_long \* 8`
2013
2014
2015 case $ac_cv_sizeof_void_p in
2016 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
2017 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
2018 *)                      glib_unknown_void_p=yes ;;
2019 esac
2020
2021
2022 case xyes in
2023 x$ac_cv_func_atexit)
2024   glib_atexit="
2025 #ifdef NeXT /* @#%@! NeXTStep */
2026 # define g_ATEXIT(proc) (!atexit (proc))
2027 #else
2028 # define g_ATEXIT(proc) (atexit (proc))
2029 #endif"
2030   ;;
2031 x$ac_cv_func_on_exit)
2032   glib_atexit="
2033 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
2034   ;;
2035 esac
2036
2037 case xyes in
2038 x$ac_cv_func_memmove)
2039   glib_memmove='
2040 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
2041   ;;
2042 x$glib_cv_working_bcopy)
2043   glib_memmove="
2044 /* memmove isn't available, but bcopy can copy overlapping memory regions */
2045 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
2046   ;;
2047 *)
2048   glib_memmove="
2049 /* memmove isn't found and bcopy can't copy overlapping memory regions,
2050  * so we have to roll our own copy routine. */
2051 void g_memmove (void* dest, const void * src, unsigned long len);"
2052   ;;
2053 esac
2054
2055 glib_defines="
2056 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
2057 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
2058 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
2059 "
2060
2061 case xyes in
2062 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
2063 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
2064 *)                      glib_vacopy=''
2065 esac
2066
2067 if test x$glib_cv_va_val_copy = xno; then
2068   glib_vacopy="\$glib_vacopy
2069 #define G_VA_COPY_AS_ARRAY 1"
2070 fi
2071
2072 if test x$glib_cv_hasinline = xyes; then
2073     glib_inline='#define G_HAVE_INLINE 1'
2074 fi
2075 if test x$glib_cv_has__inline = xyes; then
2076     glib_inline="\$glib_inline
2077 #define G_HAVE___INLINE 1"
2078 fi
2079 if test x$glib_cv_has__inline__ = xyes; then
2080     glib_inline="\$glib_inline
2081 #define G_HAVE___INLINE__ 1"
2082 fi
2083
2084 g_have_gnuc_varargs=$g_have_gnuc_varargs
2085 g_have_iso_c_varargs=$g_have_iso_c_varargs
2086 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
2087
2088 case xyes in
2089 x$ac_cv_c_bigendian)
2090   g_byte_order=G_BIG_ENDIAN
2091   g_bs_native=BE
2092   g_bs_alien=LE
2093   ;;
2094 *)
2095   g_byte_order=G_LITTLE_ENDIAN
2096   g_bs_native=LE
2097   g_bs_alien=BE
2098   ;;
2099 esac
2100
2101 g_have_eilseq=$have_eilseq
2102
2103 case x$have_threads in
2104 xno)    g_enable_threads_def="#undef";;
2105 *)      g_enable_threads_def="#define";;
2106 esac
2107
2108 g_threads_impl_def=$g_threads_impl
2109
2110 g_mutex_has_default="$mutex_has_default"
2111 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
2112 if test x"$glib_cv_sizeof_system_thread" != x; then
2113   g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
2114 else
2115   g_system_thread_sizeof="$ac_cv_sizeof_void_p"
2116 fi
2117 g_mutex_contents="$glib_cv_byte_contents_gmutex"
2118
2119 g_module_suffix="$glib_gmodule_suffix"
2120
2121 case $host in
2122   *-*-beos*)
2123     glib_os="#define G_OS_BEOS"
2124     ;;
2125   *-*-cygwin*)
2126     glib_os="#define G_OS_UNIX
2127 #define G_PLATFORM_WIN32
2128 #define G_WITH_CYGWIN"
2129     ;;
2130   *-*-mingw*)
2131     glib_os="#define G_OS_WIN32
2132 #define G_PLATFORM_WIN32"
2133     ;;
2134   *)
2135     glib_os="#define G_OS_UNIX"
2136     ;;
2137 esac
2138 ])
2139
2140 AC_OUTPUT([
2141 glib-2.0.pc
2142 glib-2.0-uninstalled.pc
2143 gmodule-2.0.pc
2144 gmodule-2.0-uninstalled.pc
2145 gthread-2.0.pc
2146 gthread-2.0-uninstalled.pc
2147 gobject-2.0.pc
2148 gobject-2.0-uninstalled.pc
2149 glib.spec
2150 glib-zip
2151 glib-gettextize
2152 Makefile
2153 build/Makefile
2154 build/win32/Makefile
2155 build/win32/dirent/Makefile
2156 glib/Makefile
2157 glib/libcharset/Makefile
2158 gmodule/gmoduleconf.h
2159 gmodule/Makefile
2160 gobject/Makefile
2161 gobject/glib-mkenums
2162 gthread/Makefile
2163 po/Makefile.in
2164 docs/Makefile
2165 docs/reference/Makefile
2166 docs/reference/glib/Makefile
2167 docs/reference/gobject/Makefile
2168 tests/Makefile
2169 m4macros/Makefile
2170 ],[echo ""
2171 echo " *** IMPORTANT *** "
2172 echo ""
2173 echo "This is a development version of GLib.  You should be using a stable"
2174 echo "version, which is available at ftp://ftp.gtk.org/pub/gtk/v1.2/.  The"
2175 echo "version you just configured is meant for developers of GLib only:"
2176 echo ""
2177 echo "  * You should not base stable software on this version of GLib."
2178 echo "  * GNOME developers should use a stable version of GLib."
2179 echo ""
2180 echo " *** You should be using GLib 1.2 instead. ***"
2181 ])