configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5
   6 # require autoconf 2.13
   7 AC_PREREQ(2.13)
   8
   9 # Process this file with autoconf to produce a configure script.
  10 AC_INIT(glist.c)
  11
  12 # Save this value here, since automake will set cflags later
  13 cflags_set=${CFLAGS+set}
  14
  15 # we rewrite this file
  16 rm -f glibconfig-sysdefs.h
  17
  18 dnl we to AC_DIVERT_PUSH/AC_DIVERT_POP these variable definitions so they
  19 dnl are available for $ac_help expansion (don't we all *love* autoconf?)
  20 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  21 #
  22 # The following version number definitions apply to GLib and GModule
  23 # as a whole, so if changes occoured in either of them, they are both
  24 # treated with the same interface and binary age.
  25 #
  26 # Making releases:
  27 #   GLIB_MICRO_VERSION += 1;
  28 #   GLIB_INTERFACE_AGE += 1;
  29 #   GLIB_BINARY_AGE += 1;
  30 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  31 # if backwards compatibility has been broken,
  32 # set GLIB_BINARY_AGE and GLIB_INTERFACE_AGE to 0.
  33 #
  34 GLIB_MAJOR_VERSION=1
  35 GLIB_MINOR_VERSION=3
  36 GLIB_MICRO_VERSION=0
  37 GLIB_INTERFACE_AGE=0
  38 GLIB_BINARY_AGE=0
  39 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  40 dnl
  41 AC_DIVERT_POP()dnl
  42
  43 AC_SUBST(GLIB_VERSION)
  44
  45 # libtool versioning
  46 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  47 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  48 LT_REVISION=$GLIB_INTERFACE_AGE
  49 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  50 AC_SUBST(LT_RELEASE)
  51 AC_SUBST(LT_CURRENT)
  52 AC_SUBST(LT_REVISION)
  53 AC_SUBST(LT_AGE)
  54
  55 VERSION=$GLIB_VERSION
  56 PACKAGE=glib
  57
  58 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  59
  60 # Specify a configuration file
  61 AM_CONFIG_HEADER(config.h)
  62
  63 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION)
  64 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION)
  65 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION)
  66 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE)
  67 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE)
  68
  69 dnl Initialize libtool
  70 AM_PROG_LIBTOOL
  71
  72 dnl Initialize maintainer mode
  73 AM_MAINTAINER_MODE
  74
  75 AC_CANONICAL_HOST
  76
  77 dnl figure debugging default, prior to $ac_help setup
  78 dnl
  79 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  80 if test `expr $GLIB_MINOR_VERSION \% 2` = 1 ; then
  81         debug_default=yes
  82 else
  83         debug_default=minimum
  84 fi
  85 AC_DIVERT_POP()dnl
  86
  87 dnl declare --enable-* args and collect ac_help strings
  88 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
  89 AC_ARG_ENABLE(mem_check, [  --enable-mem-check      turn on malloc/free sanity checking [default=no]],,enable_mem_check=no)
  90 AC_ARG_ENABLE(mem_profile, [  --enable-mem-profile    turn on malloc profiling atexit [default=no]],,enable_mem_profile=no)
  91 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
  92                     , enable_ansi=no)
  93 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
  94                           ([=no] will override --with-threads)],,enable_threads=yes)
  95
  96 if test "x$enable_threads" != "xyes"; then
  97   enable_threads=no
  98 fi
  99
 100 AC_MSG_CHECKING(whether to enable memory checking)
 101 if test "x$enable_mem_check" = "xyes"; then
 102   AC_DEFINE(ENABLE_MEM_CHECK, 1)
 103   AC_SUBST(ENABLE_MEM_CHECK)
 104   AC_MSG_RESULT(yes)
 105 else
 106   AC_MSG_RESULT(no)
 107 fi
 108
 109 AC_MSG_CHECKING(whether to enable memory profiling)
 110 if test "x$enable_mem_profile" = "xyes"; then
 111   AC_DEFINE(ENABLE_MEM_PROFILE, 1)
 112   AC_SUBST(ENABLE_MEM_PROFILE)
 113   AC_MSG_RESULT(yes)
 114 else
 115   AC_MSG_RESULT(no)
 116 fi
 117
 118 if test "x$enable_debug" = "xyes"; then
 119   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 120   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 121 else
 122   if test "x$enable_debug" = "xno"; then
 123     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 124   fi
 125 fi
 126
 127 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 128
 129 # Checks for programs.
 130 AC_PROG_CC
 131 AM_PROG_CC_STDC
 132 AC_PROG_INSTALL
 133
 134 changequote(,)dnl
 135 if test "x$GCC" = "xyes"; then
 136   case " $CFLAGS " in
 137   *[\ \ ]-Wall[\ \      ]*) ;;
 138   *) CFLAGS="$CFLAGS -Wall" ;;
 139   esac
 140
 141   if test "x$enable_ansi" = "xyes"; then
 142     case " $CFLAGS " in
 143     *[\ \       ]-ansi[\ \      ]*) ;;
 144     *) CFLAGS="$CFLAGS -ansi" ;;
 145     esac
 146
 147     case " $CFLAGS " in
 148     *[\ \       ]-pedantic[\ \  ]*) ;;
 149     *) CFLAGS="$CFLAGS -pedantic" ;;
 150     esac
 151   fi
 152 fi
 153 changequote([,])dnl
 154
 155 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 156 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 157 glib_save_LIBS=$LIBS
 158 LIBS="$LIBS -lm"
 159 AC_TRY_RUN([#include <math.h>
 160              int main (void) { return (log(1) != log(1.)); }],
 161      AC_MSG_RESULT(none needed),
 162      glib_save_CFLAGS=$CFLAGS
 163      CFLAGS="$CFLAGS -std1"
 164      AC_TRY_RUN([#include <math.h>
 165                  int main (void) { return (log(1) != log(1.)); }],
 166          AC_MSG_RESULT(-std1),
 167          AC_MSG_RESULT()
 168          CFLAGS=$glib_save_CFLAGS
 169          AC_MSG_WARN(
 170                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 171      )
 172 )
 173 LIBS=$glib_save_LIBS
 174
 175 dnl NeXTStep cc seems to need this
 176 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 177 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 178   AC_MSG_RESULT(none needed),
 179   glib_save_CFLAGS=$CFLAGS
 180   CFLAGS="$CFLAGS -posix"
 181   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 182     AC_MSG_RESULT(-posix),
 183     AC_MSG_RESULT()
 184     CFLAGS=$glib_save_CFLAGS
 185     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 186
 187 # Checks for header files.
 188 AC_HEADER_STDC
 189
 190 # Checks for library functions.
 191 AC_FUNC_VPRINTF
 192
 193 AC_CHECK_FUNCS(atexit on_exit)
 194
 195 AC_CHECK_SIZEOF(char)
 196 AC_CHECK_SIZEOF(short)
 197 AC_CHECK_SIZEOF(long)
 198 AC_CHECK_SIZEOF(int)
 199 AC_CHECK_SIZEOF(void *)
 200 AC_CHECK_SIZEOF(long long)
 201
 202 dnl long doubles were not used, and a portability problem
 203 dnl AC_C_LONG_DOUBLE
 204 AC_C_CONST
 205
 206 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 207 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 208 dnl actually supported.
 209 AC_MSG_CHECKING(for __inline)
 210 AC_CACHE_VAL(glib_cv_has__inline,[
 211         AC_TRY_RUN([
 212         __inline int foo () { return 0; }
 213         int main () { return foo (); }
 214         ],
 215         glib_cv_has__inline=yes
 216         ,
 217         glib_cv_has__inline=no
 218         ,)
 219 ])
 220 AC_MSG_RESULT($glib_cv_has__inline)
 221 case x$glib_cv_has__inline in
 222 xyes) AC_DEFINE(G_HAVE___INLINE)
 223 esac
 224 AC_MSG_CHECKING(for __inline__)
 225 AC_CACHE_VAL(glib_cv_has__inline__,[
 226         AC_TRY_RUN([
 227         __inline__ int foo () { return 0; }
 228         int main () { return foo (); }
 229         ],
 230         glib_cv_has__inline__=yes
 231         ,
 232         glib_cv_has__inline__=no
 233         ,)
 234 ])
 235 AC_MSG_RESULT($glib_cv_has__inline__)
 236 case x$glib_cv_has__inline__ in
 237 xyes) AC_DEFINE(G_HAVE___INLINE__)
 238 esac
 239 AC_MSG_CHECKING(for inline)
 240 AC_CACHE_VAL(glib_cv_hasinline,[
 241         AC_TRY_RUN([
 242         inline int foo () { return 0; }
 243         int main () { return foo (); }
 244         ],
 245         glib_cv_hasinline=yes
 246         ,
 247         glib_cv_hasinline=no
 248         ,)
 249 ])
 250 AC_MSG_RESULT($glib_cv_hasinline)
 251 case x$glib_cv_hasinline in
 252 xyes) AC_DEFINE(G_HAVE_INLINE)
 253 esac
 254
 255 dnl for bytesex stuff
 256 AC_C_BIGENDIAN
 257
 258 dnl header file checks
 259 AC_CHECK_HEADERS(float.h, AC_DEFINE(HAVE_FLOAT_H))
 260 AC_CHECK_HEADERS(limits.h, AC_DEFINE(HAVE_LIMITS_H))
 261 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 262 AC_CHECK_HEADERS(sys/param.h, AC_DEFINE(HAVE_SYS_PARAM_H))
 263 AC_CHECK_HEADERS(sys/poll.h, AC_DEFINE(HAVE_SYS_POLL_H))
 264 AC_CHECK_HEADERS(sys/select.h, AC_DEFINE(HAVE_SYS_SELECT_H))
 265 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 266 AC_CHECK_HEADERS(sys/times.h, AC_DEFINE(HAVE_SYS_TIMES_H))
 267 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 268 AC_CHECK_HEADERS(values.h, AC_DEFINE(HAVE_VALUES_H))
 269
 270 # Check for some functions
 271 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf strcasecmp strncasecmp poll)
 272
 273 # Check for sys_errlist
 274 AC_MSG_CHECKING(for sys_errlist)
 275 AC_TRY_LINK(, [
 276 extern char *sys_errlist[];
 277 extern int sys_nerr;
 278 sys_errlist[sys_nerr-1][0] = 0;
 279 ], glib_ok=yes, glib_ok=no)
 280 AC_MSG_RESULT($glib_ok)
 281 if test $glib_ok = no; then
 282     AC_DEFINE(NO_SYS_ERRLIST)
 283 fi
 284
 285 # Check for sys_siglist
 286 AC_MSG_CHECKING(for sys_siglist)
 287 AC_TRY_LINK(, [
 288 extern char *sys_siglist[];
 289 strlen (sys_siglist[0]);
 290 ], glib_ok=yes, glib_ok=no)
 291 AC_MSG_RESULT($glib_ok)
 292 if test $glib_ok = no; then
 293     AC_DEFINE(NO_SYS_SIGLIST)
 294 fi
 295
 296 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 297 AC_MSG_CHECKING(for sys_siglist declaration)
 298 AC_TRY_COMPILE([#include <signal.h>], [
 299 strlen (sys_siglist[0]);
 300 ], glib_ok=yes, glib_ok=no)
 301 AC_MSG_RESULT($glib_ok)
 302 if test $glib_ok = no; then
 303     AC_DEFINE(NO_SYS_SIGLIST_DECL)
 304 fi
 305
 306 # Check if <sys/select.h> needs to be included for fd_set
 307 AC_MSG_CHECKING([for fd_set])
 308 AC_TRY_COMPILE([#include <sys/types.h>],
 309         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 310 if test $gtk_ok = yes; then
 311     AC_MSG_RESULT([yes, found in sys/types.h])
 312 else
 313     AC_HEADER_EGREP(fd_set, sys/select.h, gtk_ok=yes)
 314     if test $gtk_ok = yes; then
 315         AC_DEFINE(HAVE_SYS_SELECT_H)
 316         AC_MSG_RESULT([yes, found in sys/select.h])
 317     else
 318         AC_DEFINE(NO_FD_SET)
 319         AC_MSG_RESULT(no)
 320     fi
 321 fi
 322
 323
 324 dnl **********************
 325 dnl *** va_copy checks ***
 326 dnl **********************
 327 dnl we currently check for all three va_copy possibilities, so we get
 328 dnl all results in config.log for bug reports.
 329 AC_MSG_CHECKING(for an implementation of va_copy())
 330 AC_CACHE_VAL(glib_cv_va_copy,[
 331         AC_TRY_RUN([
 332         #include <stdarg.h>
 333         void f (int i, ...) {
 334         va_list args1, args2;
 335         va_start (args1, i);
 336         va_copy (args2, args1);
 337         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 338           exit (1);
 339         va_end (args1); va_end (args2);
 340         }
 341         int main() {
 342           f (0, 42);
 343           return 0;
 344         }],
 345         glib_cv_va_copy=yes
 346         ,
 347         glib_cv_va_copy=no
 348         ,)
 349 ])
 350 AC_MSG_RESULT($glib_cv_va_copy)
 351 AC_MSG_CHECKING(for an implementation of __va_copy())
 352 AC_CACHE_VAL(glib_cv___va_copy,[
 353         AC_TRY_RUN([
 354         #include <stdarg.h>
 355         void f (int i, ...) {
 356         va_list args1, args2;
 357         va_start (args1, i);
 358         __va_copy (args2, args1);
 359         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 360           exit (1);
 361         va_end (args1); va_end (args2);
 362         }
 363         int main() {
 364           f (0, 42);
 365           return 0;
 366         }],
 367         glib_cv___va_copy=yes
 368         ,
 369         glib_cv___va_copy=no
 370         ,)
 371 ])
 372 AC_MSG_RESULT($glib_cv___va_copy)
 373 AC_MSG_CHECKING(whether va_lists can be copied by value)
 374 AC_CACHE_VAL(glib_cv_va_val_copy,[
 375         AC_TRY_RUN([
 376         #include <stdarg.h>
 377         void f (int i, ...) {
 378         va_list args1, args2;
 379         va_start (args1, i);
 380         args2 = args1;
 381         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 382           exit (1);
 383         va_end (args1); va_end (args2);
 384         }
 385         int main() {
 386           f (0, 42);
 387           return 0;
 388         }],
 389         glib_cv_va_val_copy=yes
 390         ,
 391         glib_cv_va_val_copy=no
 392         ,)
 393 ])
 394 if test "x$glib_cv_va_copy" = "xyes"; then
 395   AC_DEFINE(G_VA_COPY, va_copy)
 396 else if test "x$glib_cv___va_copy" = "xyes"; then
 397   AC_DEFINE(G_VA_COPY, __va_copy)
 398 fi
 399 fi
 400 if test "x$glib_cv_va_val_copy" = "xno"; then
 401   AC_DEFINE(G_VA_COPY_AS_ARRAY)
 402 fi
 403 AC_MSG_RESULT($glib_cv_va_val_copy)
 404
 405
 406 dnl ***********************
 407 dnl *** g_module checks ***
 408 dnl ***********************
 409 G_MODULE_LIBS=
 410 G_MODULE_LDFLAGS=
 411 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
 412 G_MODULE_NEED_USCORE=0
 413 G_MODULE_HAVE_DLERROR=0
 414 dnl *** dlopen() and dlsym() in system libraries
 415 if test -z "$G_MODULE_IMPL"; then
 416         AC_CHECK_FUNC(dlopen,
 417                 AC_CHECK_FUNC(dlsym,
 418                         G_MODULE_IMPL=G_MODULE_IMPL_DL
 419                 ,)
 420         ,)
 421 fi
 422 dnl *** dlopen() and dlsym() in libdl
 423 if test -z "$G_MODULE_IMPL"; then
 424         AC_CHECK_LIB(dl, dlopen,
 425                 AC_CHECK_LIB(dl, dlsym,
 426                         G_MODULE_LIBS=-ldl
 427                         G_MODULE_IMPL=G_MODULE_IMPL_DL
 428                 ,)
 429         ,)
 430 fi
 431 dnl *** shl_load() in libdld (HP-UX)
 432 if test -z "$G_MODULE_IMPL"; then
 433         AC_MSG_CHECKING(how to export all symbols)
 434         SAVED_LDFLAGS=$LDFLAGS
 435         LDFLAGS="$LDFLAGS -Wl,-E"
 436         AC_TRY_LINK(,[ return 0; ],
 437                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 438                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 439                 AC_TRY_LINK(,[ return 0; ],
 440                         G_MODULE_LDFLAGS="-bexpall",
 441                         G_MODULE_LDFLAGS="none"
 442                 )
 443         ])
 444         LDFLAGS=$SAVED_LDFLAGS
 445         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 446         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 447                 G_MODULE_LDFLAGS=
 448         fi
 449         AC_CHECK_LIB(dld, shl_load,
 450                 G_MODULE_LIBS=-ldld
 451                 G_MODULE_IMPL=G_MODULE_IMPL_DLD
 452         ,)
 453 fi
 454 dnl *** additional checks for G_MODULE_IMPL_DL
 455 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 456         case "$host_os" in
 457           linux*)
 458             G_MODULE_LDFLAGS='-rdynamic'
 459             ;;
 460         esac
 461         LIBS_orig="$LIBS"
 462         LDFLAGS_orig="$LDFLAGS"
 463         LIBS="$LIBS $G_MODULE_LIBS"
 464         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 465 dnl *** check whether we need preceeding underscores
 466         AC_MSG_CHECKING(for preceeding underscore in symbols)
 467         AC_CACHE_VAL(glib_cv_uscore,[
 468                 AC_TRY_RUN([
 469                 #include <dlfcn.h>
 470                 int glib_underscore_test (void) { return 42; }
 471                 int main() {
 472                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 473                   handle = dlopen ((void*)0, 0);
 474                   if (handle) {
 475                     f1 = dlsym (handle, "glib_underscore_test");
 476                     f2 = dlsym (handle, "_glib_underscore_test");
 477                   } return (!f2 || f1);
 478                 }],
 479                         glib_cv_uscore=yes,
 480                         glib_cv_uscore=no,
 481                 )
 482                 rm -f plugin.c plugin.o plugin.lo
 483         ])
 484         AC_MSG_RESULT($glib_cv_uscore)
 485         if test "x$glib_cv_uscore" = "xyes"; then
 486                 G_MODULE_NEED_USCORE=1
 487         else
 488                 G_MODULE_NEED_USCORE=0
 489         fi
 490
 491         LDFLAGS="$LDFLAGS_orig"
 492 dnl *** check for having dlerror()
 493         AC_CHECK_FUNC(dlerror,
 494                 G_MODULE_HAVE_DLERROR=1,
 495                 G_MODULE_HAVE_DLERROR=0)
 496         LIBS="$LIBS_orig"
 497 fi
 498 dnl *** done, have e got an implementation?
 499 if test -z "$G_MODULE_IMPL"; then
 500         G_MODULE_IMPL=0
 501 fi
 502 AC_SUBST(G_MODULE_IMPL)
 503 AC_SUBST(G_MODULE_LIBS)
 504 AC_SUBST(G_MODULE_LDFLAGS)
 505 AC_SUBST(G_MODULE_HAVE_DLERROR)
 506 AC_SUBST(G_MODULE_NEED_USCORE)
 507 AC_SUBST(GLIB_DEBUG_FLAGS)
 508
 509
 510 dnl ***********************
 511 dnl *** g_thread checks ***
 512 dnl ***********************
 513
 514 AC_ARG_WITH(threads, [  --with-threads=[none/posix/dce/solaris/nspr] specify a thread implementation to use],
 515         if test "x$with_threads" = x; then
 516                 want_threads=yes
 517         else
 518                 want_threads=$with_threads
 519         fi,
 520         want_threads=yes)
 521 if test "x$enable_threads" = "xno"; then
 522         want_threads=no
 523 fi
 524 if test "x$want_threads" = "xnone"; then
 525         want_threads=no
 526 fi
 527
 528 dnl error and warning message
 529 dnl *************************
 530
 531 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
 532                 computer. GLib will not have a default thread implementation."
 533
 534 FLAG_DOES_NOT_WORK="I can't find the MACRO, that enables thread safety on your
 535                 platform (normaly it's "_REENTRANT"). I'll not use any flag on
 536                 compilation now, but then your programs might not work.
 537                 Please provide information on how it is done on your system."
 538
 539 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
 540                 "
 541
 542 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
 543                 provide information on your thread implementation.
 544                 You can also run 'configure --disable-threads'
 545                 to compile without thread support."
 546
 547 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
 548                 functions will not be MT-safe during their first call because
 549                 there is no working 'getpwuid_r' on your system."
 550
 551 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
 552                 because there is no 'localtime_r' on your system."
 553
 554 dnl determination of thread implementation
 555 dnl ***************************************
 556
 557 have_threads=none
 558 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
 559         case $host in
 560                 *-*-solaris*)
 561                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
 562                 ;;
 563         esac
 564 fi
 565 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
 566                                 || test "x$want_threads" = xdce; then
 567         if test "x$have_threads" = xnone; then
 568                 AC_EGREP_HEADER([[^a-zA-Z_]pthread_attr_init[^a-zA-Z_]],
 569                         pthread.h,
 570                         have_threads=posix)
 571         fi
 572         if test "x$have_threads" = xnone; then
 573                 AC_EGREP_HEADER([[^a-zA-Z_]pthread_attr_create[^a-zA-Z_]],
 574                         pthread.h,
 575                         have_threads=dce)
 576         fi
 577 fi
 578 if test "x$want_threads" = xyes || test "x$want_threads" = xnspr; then
 579         if test "x$have_threads" = xnone; then
 580                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar, have_threads=nspr)
 581         fi
 582 fi
 583
 584 AC_MSG_CHECKING(for thread implementation)
 585
 586 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
 587         AC_MSG_RESULT(none available)
 588         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
 589 else
 590         AC_MSG_RESULT($have_threads)
 591 fi
 592
 593
 594 dnl determination of G_THREAD_LIBS
 595 dnl ******************************
 596
 597 G_THREAD_LIBS=
 598 G_THREAD_CFLAGS=
 599
 600 mutex_has_default=no
 601 case $have_threads in
 602         posix|dce)
 603                 G_THREAD_LIBS=error
 604                 glib_save_LIBS="$LIBS"
 605                 for thread_lib in "" pthread pthreads c_r thread; do
 606                         # This is not AC_CHECK_LIB to also work with function
 607                         # name mangling in header files.
 608                         if test x"$thread_lib" = x; then
 609                                 add_thread_lib=""
 610                                 IN=""
 611                         else
 612                                 add_thread_lib="-l$thread_lib"
 613                                 IN=" in -l$thread_lib"
 614                         fi
 615
 616                         LIBS="$glib_save_LIBS $add_thread_lib"
 617
 618                         AC_MSG_CHECKING(for pthread_create$IN)
 619                         AC_TRY_LINK([#include <pthread.h>],
 620                                 [pthread_create(NULL,NULL,NULL,NULL)],
 621                                 [AC_MSG_RESULT(yes)
 622                                 G_THREAD_LIBS="$add_thread_lib"
 623                                 break],
 624                                 [AC_MSG_RESULT(no)])
 625                 done
 626                 LIBS="$glib_save_LIBS"
 627                 dnl ********** DG/UX ************
 628                 AC_CHECK_LIB(thread, __d10_pthread_create,
 629                         G_THREAD_CFLAGS="-D_POSIX4A_DRAFT10_SOURCE")
 630                 mutex_has_default=yes
 631                 mutex_default_type='pthread_mutex_t'
 632                 mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
 633                 mutex_header_file='pthread.h'
 634                 if test "x$have_threads" = "xposix"; then
 635                         g_threads_impl="POSIX"
 636                 else
 637                         g_threads_impl="DCE"
 638                         have_threads="posix"
 639                 fi
 640                 ;;
 641         solaris)
 642                 G_THREAD_LIBS=error
 643                 AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
 644                 mutex_has_default=yes
 645                 mutex_default_type='mutex_t'
 646                 mutex_default_init="DEFAULTMUTEX"
 647                 mutex_header_file='thread.h'
 648                 g_threads_impl="SOLARIS"
 649                 ;;
 650         nspr)
 651                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar,
 652                              G_THREAD_LIBS="-lnspr21")
 653                 g_threads_impl="NSPR"
 654                 ;;
 655         none)
 656                 g_threads_impl="NONE"
 657                 ;;
 658         *)
 659                 g_threads_impl="NONE"
 660                 G_THREAD_LIBS=error
 661                 ;;
 662 esac
 663
 664 if test "x$G_THREAD_LIBS" = xerror; then
 665         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 666 fi
 667
 668 AC_MSG_CHECKING(thread related libraries)
 669 AC_MSG_RESULT($G_THREAD_LIBS)
 670
 671 dnl determination of G_THREAD_CFLAGS
 672 dnl ********************************
 673
 674 if test x"$enable_threads" = xyes; then
 675
 676     G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_REENTRANT" # good default guess
 677
 678     case $host in
 679         *-aix*)
 680                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 681                 if test x"$GCC" = xyes; then
 682                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
 683                 fi
 684                 ;;
 685         *-freebsd2.2*)
 686                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 687
 688                 # FreeBSD 2.2.x shiped with gcc 2.7.2.x, which doesn't support
 689                 # -mthreads flag.
 690                 ;;
 691     esac
 692
 693     # if we are not finding the ctime_r function, then we probably are
 694     # not using the proper multithread flag
 695     old_CPPFLAGS=$CPPFLAGS
 696     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
 697     AC_EGREP_HEADER([[^a-zA-Z_]ctime_r[^a-zA-Z_]], time.h, ,
 698     G_THREAD_CFLAGS=
 699     AC_MSG_WARN($FLAG_DOES_NOT_WORK))
 700     CPPFLAGS=$old_CPPFLAGS
 701
 702     AC_MSG_CHECKING(thread related cflags)
 703
 704     AC_MSG_RESULT($G_THREAD_CFLAGS)
 705 else
 706     G_THREAD_CFLAGS=
 707 fi
 708
 709 dnl check for mt safe function variants and some posix functions
 710 dnl ************************************************************
 711
 712 if test x"$enable_threads" = xyes; then
 713         glib_save_LIBS="$LIBS"
 714         glib_save_CFLAGS="$CFLAGS"
 715         # we are not doing the following for now, as this might require glib
 716         # to always be linked with the thread libs on some platforms.
 717         # LIBS="$LIBS $G_THREAD_LIBS"
 718         CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 719         AC_CHECK_FUNCS(localtime_r rand_r)
 720         if test "$ac_cv_header_pwd_h" = "yes"; then
 721                 AC_MSG_CHECKING([for getpwuid_r])
 722                 AC_CACHE_VAL(ac_cv_func_getpwuid_r,
 723                         [AC_TRY_RUN([#include <errno.h>
 724                                 int main () { char buffer[10000], *pointer;
 725                                 char getpwuid_r (long, void*, void*,
 726                                         int, void*);
 727                                 errno = 0;
 728                                 getpwuid_r (0, &buffer, &buffer,
 729                                         sizeof (buffer), &pointer);
 730                                 return errno == ENOSYS;}],
 731                                 [ac_cv_func_getpwuid_r=yes],
 732                                 [ac_cv_func_getpwuid_r=no])])
 733                 if test "$ac_cv_func_getpwuid_r" = yes; then
 734                         AC_MSG_RESULT(yes)
 735                         AC_DEFINE(HAVE_GETPWUID_R)
 736                 else
 737                         AC_MSG_RESULT(no)
 738                 fi
 739                 if test "$ac_cv_func_getpwuid_r" = "yes"; then
 740                         AC_MSG_CHECKING(whether getpwuid_r is posix like)
 741                         # getpwuid_r(0, NULL, NULL, 0) is the signature on
 742                         # solaris, if that is not found, the prog below won't
 743                         # compile, then the posix signature is assumed as
 744                         # the default.
 745                         AC_TRY_COMPILE([#include <pwd.h>],
 746                                 [getpwuid_r(0, NULL, NULL, 0);],
 747                                 [AC_MSG_RESULT(no)],
 748                                 [AC_MSG_RESULT(yes)
 749                                 AC_DEFINE(HAVE_GETPWUID_R_POSIX)])
 750                 fi
 751         fi
 752         LIBS="$glib_save_LIBS"
 753         CFLAGS="$glib_save_CFLAGS"
 754
 755         # now spit out all the warnings.
 756         if test "$ac_cv_func_getpwuid_r" != "yes"; then
 757                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
 758         fi
 759         if test "$ac_cv_func_localtime_r" != "yes"; then
 760                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
 761         fi
 762 fi
 763
 764 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c")
 765 AC_SUBST(G_THREAD_CFLAGS)
 766 AC_SUBST(G_THREAD_LIBS)
 767
 768 CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 769
 770 dnl **********************************************
 771 dnl *** GDefaultMutex setup and initialization ***
 772 dnl **********************************************
 773 dnl
 774 dnl if mutex_has_default = yes, we also got
 775 dnl mutex_default_type, mutex_default_init and mutex_header_file
 776 GLIB_IF_VAR_EQ(mutex_has_default, yes,
 777         GLIB_SIZEOF([#include <$mutex_header_file>],
 778                     $mutex_default_type,
 779                     gmutex,
 780                     )
 781         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
 782                            $mutex_default_type,
 783                            gmutex,
 784                            $glib_cv_sizeof_gmutex,
 785                            $mutex_default_init)
 786         ,
 787 )
 788
 789
 790 dnl ****************************************
 791 dnl *** GLib POLL* compatibility defines ***
 792 dnl ****************************************
 793 GLIB_SYSDEFS(
 794 [#include <sys/types.h>
 795 #include <sys/poll.h>],
 796         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
 797         glibconfig-sysdefs.h,
 798         =)
 799
 800
 801 dnl ******************************
 802 dnl *** output the whole stuff ***
 803 dnl ******************************
 804
 805 AC_OUTPUT_COMMANDS([
 806
 807 ## Generate `glibconfig.h' in two cases
 808 ## 1. `config.status' is run either explicitly, or via configure.
 809 ##     Esp. not when it is run in `Makefile' to generate makefiles and
 810 ##     config.h
 811 ## 2. CONFIG_OTHER is set explicitly
 812 ##
 813 ## Case 1 is difficult.  We know that `automake' sets one of
 814 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
 815 ## only when AM_CONFIG_HEADER is set, however.
 816
 817 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
 818   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
 819   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
 820 fi
 821 case "$CONFIG_OTHER" in
 822 *glibconfig.h*)
 823         echo creating glibconfig.h
 824         outfile=glibconfig.h-tmp
 825         cat > $outfile <<\_______EOF
 826 /* glibconfig.h
 827  *
 828  * This is a generated file.  Please modify `configure.in'
 829  */
 830
 831 #ifndef GLIBCONFIG_H
 832 #define GLIBCONFIG_H
 833
 834 #ifdef __cplusplus
 835 extern "C" {
 836 #endif /* __cplusplus */
 837
 838 _______EOF
 839
 840         if test x$glib_limits_h = xyes; then
 841           echo '#include <limits.h>' >> $outfile
 842         fi
 843         if test x$glib_float_h = xyes; then
 844           echo '#include <float.h>' >> $outfile
 845         fi
 846         if test x$glib_values_h = xyes; then
 847           echo '#include <values.h>' >> $outfile
 848         fi
 849         if test x$g_mutex_header_file != x; then
 850           echo '#include <'"$g_mutex_header_file"'>' >> $outfile
 851         fi
 852         if test x$glib_sys_poll_h = xyes; then
 853           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
 854         fi
 855
 856         cat >> $outfile <<_______EOF
 857
 858 #define G_MINFLOAT      $glib_mf
 859 #define G_MAXFLOAT      $glib_Mf
 860 #define G_MINDOUBLE     $glib_md
 861 #define G_MAXDOUBLE     $glib_Md
 862 #define G_MINSHORT      $glib_ms
 863 #define G_MAXSHORT      $glib_Ms
 864 #define G_MAXUSHORT     $glib_Mus
 865 #define G_MININT        $glib_mi
 866 #define G_MAXINT        $glib_Mi
 867 #define G_MAXUINT       $glib_Mui
 868 #define G_MINLONG       $glib_ml
 869 #define G_MAXLONG       $glib_Ml
 870 #define G_MAXULONG      $glib_Mul
 871
 872 _______EOF
 873
 874
 875         ### this should always be true in a modern C/C++ compiler
 876         cat >>$outfile <<_______EOF
 877 typedef signed char gint8;
 878 typedef unsigned char guint8;
 879 _______EOF
 880
 881
 882         if test -n "$gint16"; then
 883           cat >>$outfile <<_______EOF
 884 typedef signed $gint16 gint16;
 885 typedef unsigned $gint16 guint16;
 886 #define G_GINT16_FORMAT $gint16_format
 887 #define G_GUINT16_FORMAT $guint16_format
 888 _______EOF
 889         fi
 890
 891
 892         if test -n "$gint32"; then
 893           cat >>$outfile <<_______EOF
 894 typedef signed $gint32 gint32;
 895 typedef unsigned $gint32 guint32;
 896 #define G_GINT32_FORMAT $gint32_format
 897 #define G_GUINT32_FORMAT $guint32_format
 898 _______EOF
 899         fi
 900
 901
 902         if test -n "$gint64"; then
 903           cat >>$outfile <<_______EOF
 904 ${glib_warning_guard}#define G_HAVE_GINT64 1
 905
 906 ${glib_extension}typedef signed $gint64 gint64;
 907 ${glib_extension}typedef unsigned $gint64 guint64;
 908
 909 #define G_GINT64_FORMAT $gint64_format
 910 #define G_GUINT64_FORMAT $guint64_format
 911 #define G_GINT64_CONSTANT(val)  $gint64_constant
 912 _______EOF
 913         fi
 914
 915
 916         if test -z "$glib_unknown_void_p"; then
 917           cat >>$outfile <<_______EOF
 918
 919 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
 920 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
 921
 922 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
 923 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
 924 _______EOF
 925         else
 926           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
 927         fi
 928
 929
 930
 931         cat >>$outfile <<_______EOF
 932 $glib_atexit
 933 $glib_memmove
 934 $glib_defines
 935
 936 $glib_vacopy
 937
 938 #ifdef  __cplusplus
 939 #define G_HAVE_INLINE   1
 940 #else   /* !__cplusplus */
 941 $glib_inline
 942 #endif  /* !__cplusplus */
 943 _______EOF
 944
 945         echo >>$outfile
 946         if test x$g_mutex_has_default = xyes; then
 947                 cat >>$outfile <<_______EOF
 948 $g_enable_threads_def G_THREADS_ENABLED
 949 #define G_THREADS_IMPL_$g_threads_impl_def
 950 typedef struct _GStaticMutex GStaticMutex;
 951 struct _GStaticMutex
 952 {
 953   struct _GMutex *runtime_mutex;
 954   union {
 955     char   pad[$g_mutex_sizeof];
 956     double dummy_double;
 957     void  *dummy_pointer;
 958     long   dummy_long;
 959   } aligned_pad_u;
 960 };
 961 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
 962 #define g_static_mutex_get_mutex(mutex) \
 963   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->aligned_pad_u)) : \
 964    g_static_mutex_get_mutex_impl (&((mutex)->runtime_mutex)))
 965 _______EOF
 966         else
 967                 cat >>$outfile <<_______EOF
 968 $g_enable_threads_def G_THREADS_ENABLED
 969 #define G_THREADS_IMPL_$g_threads_impl_def
 970 typedef struct _GMutex* GStaticMutex;
 971 #define G_STATIC_MUTEX_INIT NULL
 972 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (mutex))
 973 _______EOF
 974         fi
 975
 976         echo >>$outfile
 977         g_bit_sizes="16 32"
 978         if test -n "$gint64"; then
 979           g_bit_sizes="$g_bit_sizes 64"
 980         fi
 981         for bits in $g_bit_sizes; do
 982           cat >>$outfile <<_______EOF
 983 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
 984 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
 985 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
 986 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
 987 _______EOF
 988         done
 989
 990         cat >>$outfile <<_______EOF
 991 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
 992 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
 993 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
 994 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
 995 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
 996 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
 997 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
 998 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
 999 #define G_BYTE_ORDER $g_byte_order
1000
1001 _______EOF
1002
1003         if test -r glibconfig-sysdefs.h; then
1004           cat glibconfig-sysdefs.h >>$outfile
1005         fi
1006
1007         cat >>$outfile <<_______EOF
1008 #ifdef __cplusplus
1009 }
1010 #endif /* __cplusplus */
1011
1012 #endif /* GLIBCONFIG_H */
1013 _______EOF
1014
1015
1016         if cmp -s $outfile glibconfig.h; then
1017           echo glibconfig.h is unchanged
1018           rm -f $outfile
1019         else
1020           mv $outfile glibconfig.h
1021         fi ;;
1022 esac
1023 ],[
1024
1025 # Note that if two cases are the same, case goes with the first one.
1026 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
1027 # on variable expansion in case labels.  Look at the generated config.status
1028 # for a hint.
1029
1030 case xyes in
1031 x$ac_cv_header_float_h)
1032   glib_float_h=yes
1033   glib_mf=FLT_MIN glib_Mf=FLT_MAX
1034   glib_md=DBL_MIN glib_Md=DBL_MAX
1035   ;;
1036 x$ac_cv_header_values_h)
1037   glib_values_h=yes
1038   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
1039   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
1040   ;;
1041 esac
1042
1043 case xyes in
1044 x$ac_cv_header_limits_h)
1045   glib_limits_h=yes
1046   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
1047   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
1048   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
1049   ;;
1050 x$ac_cv_header_values_h)
1051   glib_values_h=yes
1052   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus=unknown  # Please insert the right
1053   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui=unknown  # values from
1054   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul=unknown  # /usr/include/values.h
1055   ;;
1056 esac
1057
1058 if test x$ac_cv_header_sys_poll_h = xyes ; then
1059   glib_sys_poll_h=yes
1060 fi
1061
1062 case 2 in
1063 $ac_cv_sizeof_short)
1064   gint16=short
1065   gint16_format='"hi"'
1066   guint16_format='"hu"'
1067   ;;
1068 $ac_cv_sizeof_int)
1069   gint16=int
1070   gint16_format='"i"'
1071   guint16_format='"u"'
1072   ;;
1073 esac
1074 case 4 in
1075 $ac_cv_sizeof_short)
1076   gint32=short
1077   gint32_format='"hi"'
1078   guint32_format='"hu"'
1079   ;;
1080 $ac_cv_sizeof_int)
1081   gint32=int
1082   gint32_format='"i"'
1083   guint32_format='"u"'
1084   ;;
1085 $ac_cv_sizeof_long)
1086   gint32=long
1087   gint32_format='"li"'
1088   guint32_format='"lu"'
1089   ;;
1090 esac
1091 case 8 in
1092 $ac_cv_sizeof_int)
1093   gint64=int
1094   gint64_format='"i"'
1095   guint64_format='"u"'
1096   glib_extension=
1097   glib_warning_guard=
1098   gint64_constant='(val)'
1099   ;;
1100 $ac_cv_sizeof_long)
1101   gint64=long
1102   gint64_format='"li"'
1103   guint64_format='"lu"'
1104   glib_extension=
1105   glib_warning_guard=
1106   gint64_constant='(val##L)'
1107   ;;
1108 $ac_cv_sizeof_long_long)
1109   gint64='long long'
1110   gint64_format='"lli"'
1111   guint64_format='"llu"'
1112   glib_extension='G_GNUC_EXTENSION '
1113   glib_warning_guard="
1114 #if defined (__GNUC__) && __GNUC__ >= 2 && __GNUC_MINOR__ >= 8
1115 #  define G_GNUC_EXTENSION __extension__
1116 #else
1117 #  define G_GNUC_EXTENSION
1118 #endif
1119
1120 "
1121   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1122   ;;
1123 esac
1124
1125 gintbits=`expr $ac_cv_sizeof_int \* 8`
1126 glongbits=`expr $ac_cv_sizeof_long \* 8`
1127
1128
1129 case $ac_cv_sizeof_void_p in
1130 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
1131 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
1132 *)                      glib_unknown_void_p=yes ;;
1133 esac
1134
1135
1136 case xyes in
1137 x$ac_cv_func_atexit)
1138   glib_atexit="
1139 #ifdef NeXT /* @#%@! NeXTStep */
1140 # define g_ATEXIT(proc) (!atexit (proc))
1141 #else
1142 # define g_ATEXIT(proc) (atexit (proc))
1143 #endif"
1144   ;;
1145 x$ac_cv_func_on_exit)
1146   glib_atexit="
1147 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
1148   ;;
1149 esac
1150
1151 case xyes in
1152 x$ac_cv_func_memmove)
1153   glib_memmove='
1154 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
1155   ;;
1156 *)
1157   glib_memmove="
1158 /* We make the assumption that if memmove isn't available, then
1159  * bcopy will do the job. This isn't safe everywhere. (bcopy can't
1160  * necessarily handle overlapping copies) */
1161 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
1162   ;;
1163 esac
1164
1165 glib_defines="
1166 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
1167 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
1168 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
1169 "
1170
1171 case xyes in
1172 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
1173 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
1174 *)                      glib_vacopy=''
1175 esac
1176
1177 if test x$glib_cv_va_val_copy = xno; then
1178   glib_vacopy="\$glib_vacopy
1179 #define G_VA_COPY_AS_ARRAY 1"
1180 fi
1181
1182 if test x$glib_cv_hasinline = xyes; then
1183     glib_inline='#define G_HAVE_INLINE 1'
1184 fi
1185 if test x$glib_cv_has__inline = xyes; then
1186     glib_inline="\$glib_inline
1187 #define G_HAVE___INLINE 1"
1188 fi
1189 if test x$glib_cv_has__inline__ = xyes; then
1190     glib_inline="\$glib_inline
1191 #define G_HAVE___INLINE__ 1"
1192 fi
1193
1194 case xyes in
1195 x$ac_cv_c_bigendian)
1196   g_byte_order=G_BIG_ENDIAN
1197   g_bs_native=BE
1198   g_bs_alien=LE
1199   ;;
1200 *)
1201   g_byte_order=G_LITTLE_ENDIAN
1202   g_bs_native=LE
1203   g_bs_alien=BE
1204   ;;
1205 esac
1206
1207 case x$enable_threads in
1208 xyes)   g_enable_threads_def="#define";;
1209 *)      g_enable_threads_def="#undef ";;
1210 esac
1211
1212 g_threads_impl_def=$g_threads_impl
1213
1214 g_mutex_has_default="$mutex_has_default"
1215 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
1216 g_mutex_contents="$glib_cv_byte_contents_gmutex"
1217 ])
1218
1219 AC_OUTPUT([
1220 glib.spec
1221 Makefile
1222 glib-config
1223 gmodule/gmoduleconf.h
1224 gmodule/Makefile
1225 gthread/Makefile
1226 docs/Makefile
1227 tests/Makefile
1228 ],[case "$CONFIG_FILES" in
1229 *glib-config*)chmod +x glib-config;;
1230 esac])