configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5
   6 # require autoconf 2.13
   7 AC_PREREQ(2.13)
   8
   9 # Process this file with autoconf to produce a configure script.
  10 AC_INIT(glist.c)
  11
  12 # Save this value here, since automake will set cflags later
  13 cflags_set=${CFLAGS+set}
  14
  15 # we rewrite this file
  16 rm -f glibconfig-sysdefs.h
  17
  18 GLIB_AC_DIVERT_BEFORE_HELP([
  19 #
  20 # The following version number definitions apply to GLib, GModule, GObject
  21 # and GThread as a whole, so if changes occoured in any of them, they are all
  22 # treated with the same interface and binary age.
  23 #
  24 # Making releases:
  25 #   GLIB_MICRO_VERSION += 1;
  26 #   GLIB_INTERFACE_AGE += 1;
  27 #   GLIB_BINARY_AGE += 1;
  28 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  29 # if backwards compatibility has been broken,
  30 # set GLIB_BINARY_AGE _and_ GLIB_INTERFACE_AGE to 0.
  31 #
  32 GLIB_MAJOR_VERSION=1
  33 GLIB_MINOR_VERSION=3
  34 GLIB_MICRO_VERSION=2
  35 GLIB_INTERFACE_AGE=0
  36 GLIB_BINARY_AGE=0
  37 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  38 ])dnl
  39
  40 AC_SUBST(GLIB_MAJOR_VERSION)
  41 AC_SUBST(GLIB_MINOR_VERSION)
  42 AC_SUBST(GLIB_MICRO_VERSION)
  43 AC_SUBST(GLIB_VERSION)
  44 AC_SUBST(GLIB_INTERFACE_AGE)
  45 AC_SUBST(GLIB_BINARY_AGE)
  46
  47 # libtool versioning
  48 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  49 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  50 LT_REVISION=$GLIB_INTERFACE_AGE
  51 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  52 AC_SUBST(LT_RELEASE)
  53 AC_SUBST(LT_CURRENT)
  54 AC_SUBST(LT_REVISION)
  55 AC_SUBST(LT_AGE)
  56
  57 VERSION=$GLIB_VERSION
  58 PACKAGE=glib
  59
  60 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  61
  62 # Specify a configuration file
  63 AM_CONFIG_HEADER(config.h)
  64
  65 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION,
  66                    [Define to the GLIB major version])
  67 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION,
  68                    [Define to the GLIB minor version])
  69 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION,
  70                    [Define to the GLIB micro version])
  71 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE,
  72                    [Define to the GLIB interface age])
  73 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE,
  74                    [Define to the GLIB binary age])
  75
  76 dnl Initialize maintainer mode
  77 AM_MAINTAINER_MODE
  78
  79 AC_CANONICAL_HOST
  80
  81 AC_MSG_CHECKING(for the BeOS)
  82 case $host in
  83   *-*-beos*)
  84     glib_native_beos="yes"
  85     ;;
  86   *)
  87     glib_native_beos="no"
  88     ;;
  89 esac
  90 AC_MSG_RESULT([$glib_native_beos])
  91
  92 dnl
  93
  94 GLIB_AC_DIVERT_BEFORE_HELP([
  95 # figure debugging default, prior to $ac_help setup
  96 case $GLIB_MINOR_VERSION in
  97 *[[13579]]) debug_default=yes ;;
  98 *)          debug_default=minimum ;;
  99 esac[]dnl
 100 ])
 101
 102 dnl declare --enable-* args and collect ac_help strings
 103 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
 104 AC_ARG_ENABLE(msg-prefix, [  --enable-msg-prefix     turn on program name and PID prefixing of messages and warnings],,enable_msg_prefix=no)
 105 AC_ARG_ENABLE(mem_check, [  --enable-mem-check      turn on malloc/free sanity checking [default=no]],,enable_mem_check=no)
 106 AC_ARG_ENABLE(mem_profile, [  --enable-mem-profile    turn on malloc profiling atexit [default=no]],,enable_mem_profile=no)
 107 AC_ARG_ENABLE(gc_friendly, [  --enable-gc-friendly    turn on garbage collector friendliness [default=no]],,enable_gc_friendly=no)
 108 AC_ARG_ENABLE(mem_pools, [  --disable-mem-pools     disable all glib memory pools],,disable_mem_pools=no)
 109 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
 110                     , enable_ansi=no)
 111 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
 112                           ([=no] will override --with-threads)],,enable_threads=yes)
 113 AC_ARG_ENABLE(rebuilds, [  --disable-rebuilds      disable all source autogeneration rules],,enable_rebuilds=yes)
 114
 115 if test "x$enable_threads" != "xyes"; then
 116   enable_threads=no
 117 fi
 118
 119 AC_MSG_CHECKING(whether to enable memory checking)
 120 if test "x$enable_mem_check" = "xyes"; then
 121   AC_DEFINE(ENABLE_MEM_CHECK, 1, [Whether to enable memory checking])
 122   AC_SUBST(ENABLE_MEM_CHECK)
 123   AC_MSG_RESULT(yes)
 124 else
 125   AC_MSG_RESULT(no)
 126 fi
 127
 128 AC_MSG_CHECKING(whether to enable memory profiling)
 129 if test "x$enable_mem_profile" = "xyes"; then
 130   AC_DEFINE(ENABLE_MEM_PROFILE, 1, [Whether to enable memory profiling])
 131   AC_SUBST(ENABLE_MEM_PROFILE)
 132   AC_MSG_RESULT(yes)
 133 else
 134   AC_MSG_RESULT(no)
 135 fi
 136
 137 AC_MSG_CHECKING(whether to enable garbage collector friendliness)
 138 if test "x$enable_gc_friendly" = "xyes"; then
 139   AC_DEFINE(ENABLE_GC_FRIENDLY, 1, [Whether to enable GC friendliness])
 140   AC_SUBST(ENABLE_GC_FRIENDLY)
 141   AC_MSG_RESULT(yes)
 142 else
 143   AC_MSG_RESULT(no)
 144 fi
 145
 146 AC_MSG_CHECKING(whether to disable memory pools)
 147 if test "x$disable_mem_pools" = "xno"; then
 148   AC_MSG_RESULT(no)
 149 else
 150   AC_DEFINE(DISABLE_MEM_POOLS, 1, [Whether to disable memory pools])
 151   AC_SUBST(DISABLE_MEM_POOLS)
 152   AC_MSG_RESULT(yes)
 153 fi
 154
 155
 156 if test "x$enable_debug" = "xyes"; then
 157   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 158   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 159 else
 160   if test "x$enable_debug" = "xno"; then
 161     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 162   fi
 163 fi
 164
 165 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 166         [Whether glib was compiled with debugging enabled])
 167
 168 if test "x$enable_msg_prefix" = "xyes"; then
 169   AC_DEFINE_UNQUOTED(G_ENABLE_MSG_PREFIX, 1,
 170                      [Enable prefixing of error messages with program names])
 171 fi
 172
 173 # Checks for programs.
 174 AC_PROG_CC
 175 AM_PROG_CC_STDC
 176 AC_PROG_INSTALL
 177
 178 # define a MAINT-like variable REBUILD which is set if Perl
 179 # and awk are found, so autogenerated sources can be rebuilt
 180 AC_PROG_AWK
 181 AC_CHECK_PROGS(PERL, perl5 perl)
 182 # We would like indent, but don't require it.
 183 AC_CHECK_PROG(INDENT, indent, indent)
 184 REBUILD=\#
 185 if test "x$enable_rebuilds" = "xyes" && \
 186      test -n "$PERL" && \
 187      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 188      test -n "$AWK" ; then
 189   REBUILD=
 190 fi
 191 AC_SUBST(REBUILD)
 192
 193 dnl Initialize libtool
 194 AM_PROG_LIBTOOL
 195
 196 if test "x$GCC" = "xyes"; then
 197   case " $CFLAGS " in
 198   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 199   *) CFLAGS="$CFLAGS -Wall" ;;
 200   esac
 201
 202   if test "x$enable_ansi" = "xyes"; then
 203     case " $CFLAGS " in
 204     *[[\ \      ]]-ansi[[\ \    ]]*) ;;
 205     *) CFLAGS="$CFLAGS -ansi" ;;
 206     esac
 207
 208     case " $CFLAGS " in
 209     *[[\ \      ]]-pedantic[[\ \        ]]*) ;;
 210     *) CFLAGS="$CFLAGS -pedantic" ;;
 211     esac
 212   fi
 213 fi
 214
 215 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 216 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 217 glib_save_LIBS=$LIBS
 218 LIBS="$LIBS -lm"
 219 AC_TRY_RUN([#include <math.h>
 220              int main (void) { return (log(1) != log(1.)); }],
 221      AC_MSG_RESULT(none needed),
 222      glib_save_CFLAGS=$CFLAGS
 223      CFLAGS="$CFLAGS -std1"
 224      AC_TRY_RUN([#include <math.h>
 225                  int main (void) { return (log(1) != log(1.)); }],
 226          AC_MSG_RESULT(-std1),
 227          AC_MSG_RESULT()
 228          CFLAGS=$glib_save_CFLAGS
 229          AC_MSG_WARN(
 230                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 231      )
 232 )
 233 LIBS=$glib_save_LIBS
 234
 235 dnl NeXTStep cc seems to need this
 236 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 237 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 238   AC_MSG_RESULT(none needed),
 239   glib_save_CFLAGS=$CFLAGS
 240   CFLAGS="$CFLAGS -posix"
 241   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 242     AC_MSG_RESULT(-posix),
 243     AC_MSG_RESULT()
 244     CFLAGS=$glib_save_CFLAGS
 245     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 246
 247 # Checks for header files.
 248 AC_HEADER_STDC
 249
 250 # Checks for library functions.
 251 AC_FUNC_VPRINTF
 252
 253 AC_FUNC_ALLOCA
 254
 255 AC_CHECK_FUNCS(atexit on_exit)
 256
 257 AC_CHECK_SIZEOF(char)
 258 AC_CHECK_SIZEOF(short)
 259 AC_CHECK_SIZEOF(long)
 260 AC_CHECK_SIZEOF(int)
 261 AC_CHECK_SIZEOF(void *)
 262 AC_CHECK_SIZEOF(long long)
 263
 264 if test x$ac_cv_sizeof_long_long = x8; then
 265         # long long is a 64 bit integer.
 266         AC_MSG_CHECKING(for format to printf and scanf a gint64)
 267         AC_CACHE_VAL(glib_cv_long_long_format,[
 268                 for format in ll q; do
 269                   AC_TRY_RUN([#include <stdio.h>
 270                         int main()
 271                         {
 272                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 273                           char buffer[1000];
 274                           sprintf (buffer, "%${format}u", a);
 275                           sscanf (buffer, "%${format}u", &b);
 276                           exit (b!=a);
 277                         }
 278                         ],
 279                         glib_cv_long_long_format=${format}
 280                         break)
 281                 done])
 282         if test -n "$glib_cv_long_long_format"; then
 283           AC_MSG_RESULT(%${glib_cv_long_long_format}i)
 284         else
 285           AC_MSG_RESULT(none)
 286         fi
 287 fi
 288
 289 dnl long doubles were not used, and a portability problem
 290 dnl AC_C_LONG_DOUBLE
 291 AC_C_CONST
 292
 293 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 294 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 295 dnl actually supported.
 296 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 297         AC_TRY_RUN([
 298         __inline int foo () { return 0; }
 299         int main () { return foo (); }
 300         ],
 301         glib_cv_has__inline=yes
 302         ,
 303         glib_cv_has__inline=no
 304         ,)
 305 ])
 306 case x$glib_cv_has__inline in
 307 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 308 esac
 309 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 310         AC_TRY_RUN([
 311         __inline__ int foo () { return 0; }
 312         int main () { return foo (); }
 313         ],
 314         glib_cv_has__inline__=yes
 315         ,
 316         glib_cv_has__inline__=no
 317         ,)
 318 ])
 319 case x$glib_cv_has__inline__ in
 320 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 321 esac
 322 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 323         AC_TRY_RUN([
 324         inline int foo () { return 0; }
 325         int main () { return foo (); }
 326         ],
 327         glib_cv_hasinline=yes
 328         ,
 329         glib_cv_hasinline=no
 330         ,)
 331 ])
 332 case x$glib_cv_hasinline in
 333 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 334 esac
 335
 336 # check for bytesex stuff
 337 AC_C_BIGENDIAN
 338
 339 # check for header files
 340 AC_CHECK_HEADERS([float.h limits.h pwd.h sys/param.h sys/poll.h sys/select.h])
 341 AC_CHECK_HEADERS([sys/time.h sys/times.h unistd.h values.h stdint.h sched.h])
 342
 343 AC_MSG_CHECKING(whether make is GNU Make)
 344 STRIP_BEGIN=
 345 STRIP_END=
 346 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 347         STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
 348         STRIP_END=')'
 349         AC_MSG_RESULT(yes)
 350 else
 351         AC_MSG_RESULT(no)
 352 fi
 353 STRIP_DUMMY=
 354 AC_SUBST(STRIP_DUMMY)
 355 AC_SUBST(STRIP_BEGIN)
 356 AC_SUBST(STRIP_END)
 357
 358 # check additional type sizes
 359 size_includes=["
 360 #include <stdarg.h>
 361 #include <stdio.h>
 362 #include <ctype.h>
 363 #include <string.h>
 364 "]
 365 if test "x$ac_cv_header_stdint_h" = "xyes"; then
 366   size_includes=["$size_includes
 367 #include <stdint.h>
 368 "]
 369 fi
 370 if test "x$ac_cv_header_unistd_h" = "xyes"; then
 371   size_includes=["$size_includes
 372 #include <unistd.h>
 373 "]
 374 fi
 375 GLIB_SIZEOF([$size_includes], size_t, size_t)
 376 GLIB_SIZEOF([$size_includes], ptrdiff_t, ptrdiff_t)
 377 GLIB_SIZEOF([$size_includes], intmax_t, intmax_t)
 378
 379 # Check for some functions
 380 AC_CHECK_FUNCS(lstat strerror strsignal memmove mkstemp vsnprintf strcasecmp strncasecmp poll getcwd)
 381
 382 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 383 # The check is borrowed from the PERL Configure script.
 384 if test "$ac_cv_func_memmove" != "yes"; then
 385   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 386     glib_cv_working_bcopy,[AC_TRY_RUN([
 387       int main() {
 388         char buf[128], abc[128], *b;
 389         int len, off, align;
 390         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 391         for (align = 7; align >= 0; align--) {
 392           for (len = 36; len; len--) {
 393             b = buf+align; bcopy(abc, b, len);
 394             for (off = 1; off <= len; off++) {
 395               bcopy(b, b+off, len); bcopy(b+off, b, len);
 396                 if (bcmp(b, abc, len)) return(1);
 397             }
 398           }
 399         }
 400         return(0);
 401       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 402   if test "$glib_cv_working_bcopy" = "yes"; then
 403     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 404   fi
 405 fi
 406
 407 # Check for sys_errlist
 408 AC_MSG_CHECKING(for sys_errlist)
 409 AC_TRY_LINK(, [
 410 extern char *sys_errlist[];
 411 extern int sys_nerr;
 412 sys_errlist[sys_nerr-1][0] = 0;
 413 ], glib_ok=yes, glib_ok=no)
 414 AC_MSG_RESULT($glib_ok)
 415 if test $glib_ok = no; then
 416     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 417 fi
 418
 419 # Check for sys_siglist
 420 AC_MSG_CHECKING(for sys_siglist)
 421 AC_TRY_LINK(, [
 422 extern char *sys_siglist[];
 423 exit (sys_siglist[0]);
 424 ], glib_ok=yes, glib_ok=no)
 425 AC_MSG_RESULT($glib_ok)
 426 if test $glib_ok = no; then
 427     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 428 fi
 429
 430 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 431 AC_MSG_CHECKING(for sys_siglist declaration)
 432 AC_TRY_COMPILE([#include <signal.h>], [
 433 strlen (sys_siglist[0]);
 434 ], glib_ok=yes, glib_ok=no)
 435 AC_MSG_RESULT($glib_ok)
 436 if test $glib_ok = no; then
 437     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 438 fi
 439
 440 # Check if <sys/select.h> needs to be included for fd_set
 441 AC_MSG_CHECKING([for fd_set])
 442 AC_TRY_COMPILE([#include <sys/types.h>],
 443         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 444 if test $gtk_ok = yes; then
 445     AC_MSG_RESULT([yes, found in sys/types.h])
 446 else
 447     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
 448     if test $gtk_ok = yes; then
 449         # *** FIXME: give it a different name
 450         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
 451         AC_MSG_RESULT([yes, found in sys/select.h])
 452     else
 453         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
 454         AC_MSG_RESULT(no)
 455     fi
 456 fi
 457
 458 dnl *** check for sane realloc() ***
 459 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
 460         AC_TRY_RUN([
 461         #include <stdlib.h>
 462         int main() {
 463           return realloc (0, sizeof (int)) == 0;
 464         }],
 465         [glib_cv_sane_realloc=yes],
 466         [glib_cv_sane_realloc=no],
 467         [])
 468 ])
 469 if test x$glib_cv_sane_realloc = xyes; then
 470   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
 471 fi
 472
 473 dnl Check for nl_langinfo and CODESET
 474
 475 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
 476 AC_TRY_COMPILE([#include <langinfo.h>],
 477         [char *codeset = nl_langinfo (CODESET);],
 478    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
 479    have_codeset=yes,
 480    have_codeset=no)
 481 AC_MSG_RESULT($have_codeset)
 482
 483
 484 dnl ****************************************
 485 dnl *** strlcpy/strlcat                  ***
 486 dnl ****************************************
 487 # Check for strlcpy
 488 AC_MSG_CHECKING(for strlcpy/strlcat)
 489 AC_TRY_LINK([#include <stdlib.h>
 490 #include <string.h>], [
 491 char *p = malloc(10);
 492 (void) strlcpy(p, "hi", 10);
 493 (void) strlcat(p, "bye", 10);
 494 ], glib_ok=yes, glib_ok=no)
 495 AC_MSG_RESULT($glib_ok)
 496 if test $glib_ok = yes; then
 497     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
 498 fi
 499
 500
 501 dnl **********************
 502 dnl *** va_copy checks ***
 503 dnl **********************
 504 dnl we currently check for all three va_copy possibilities, so we get
 505 dnl all results in config.log for bug reports.
 506 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
 507         AC_TRY_RUN([
 508         #include <stdarg.h>
 509         void f (int i, ...) {
 510         va_list args1, args2;
 511         va_start (args1, i);
 512         va_copy (args2, args1);
 513         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 514           exit (1);
 515         va_end (args1); va_end (args2);
 516         }
 517         int main() {
 518           f (0, 42);
 519           return 0;
 520         }],
 521         [glib_cv_va_copy=yes],
 522         [glib_cv_va_copy=no],
 523         [])
 524 ])
 525 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
 526         AC_TRY_RUN([
 527         #include <stdarg.h>
 528         void f (int i, ...) {
 529         va_list args1, args2;
 530         va_start (args1, i);
 531         __va_copy (args2, args1);
 532         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 533           exit (1);
 534         va_end (args1); va_end (args2);
 535         }
 536         int main() {
 537           f (0, 42);
 538           return 0;
 539         }],
 540         [glib_cv___va_copy=yes],
 541         [glib_cv___va_copy=no],
 542         [])
 543 ])
 544
 545 if test "x$glib_cv_va_copy" = "xyes"; then
 546   g_va_copy_func=va_copy
 547 else if test "x$glib_cv___va_copy" = "xyes"; then
 548   g_va_copy_func=__va_copy
 549 fi
 550 fi
 551
 552 if test -n "$g_va_copy_func"; then
 553   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
 554 fi
 555
 556 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
 557         AC_TRY_RUN([
 558         #include <stdarg.h>
 559         void f (int i, ...) {
 560         va_list args1, args2;
 561         va_start (args1, i);
 562         args2 = args1;
 563         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 564           exit (1);
 565         va_end (args1); va_end (args2);
 566         }
 567         int main() {
 568           f (0, 42);
 569           return 0;
 570         }],
 571         [glib_cv_va_val_copy=yes],
 572         [glib_cv_va_val_copy=no],
 573         [])
 574 ])
 575
 576 if test "x$glib_cv_va_val_copy" = "xno"; then
 577   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 578 fi
 579
 580 dnl ***********************
 581 dnl *** g_module checks ***
 582 dnl ***********************
 583 G_MODULE_LIBS=
 584 G_MODULE_LIBS_EXTRA=
 585 G_MODULE_PLUGIN_LIBS=
 586 G_MODULE_LDFLAGS=
 587 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
 588 G_MODULE_NEED_USCORE=0
 589 G_MODULE_HAVE_DLERROR=0
 590 dnl *** dlopen() and dlsym() in system libraries
 591 if test -z "$G_MODULE_IMPL"; then
 592         AC_CHECK_FUNC(dlopen,
 593                       [AC_CHECK_FUNC(dlsym,
 594                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 595                       [])
 596 fi
 597 dnl *** load_image (BeOS)
 598 if test -z "$G_MODULE_IMPL" -a "x$glib_native_beos" = "xyes"; then
 599   AC_CHECK_LIB(root, load_image,
 600       [G_MODULE_LIBS="-lbe -lroot -lglib"
 601       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
 602       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
 603       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
 604       [])
 605 fi
 606 # *** dlopen() and dlsym() in libdl
 607 if test -z "$G_MODULE_IMPL"; then
 608         AC_CHECK_LIB(dl, dlopen,
 609                      [AC_CHECK_LIB(dl, dlsym,
 610                                    [G_MODULE_LIBS=-ldl
 611                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 612                      [])
 613 fi
 614 dnl *** shl_load() in libdld (HP-UX)
 615 if test -z "$G_MODULE_IMPL"; then
 616         AC_MSG_CHECKING(how to export all symbols)
 617         SAVED_LDFLAGS=$LDFLAGS
 618         LDFLAGS="$LDFLAGS -Wl,-E"
 619         AC_TRY_LINK(,[ return 0; ],
 620                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 621                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 622                 AC_TRY_LINK(,[ return 0; ],
 623                         [G_MODULE_LDFLAGS="-bexpall"],
 624                         [G_MODULE_LDFLAGS="none"])
 625         ])
 626         LDFLAGS=$SAVED_LDFLAGS
 627         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 628         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 629                 G_MODULE_LDFLAGS=
 630         fi
 631         AC_CHECK_LIB(dld, shl_load,
 632                 [G_MODULE_LIBS=-ldld
 633                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
 634                 [])
 635 fi
 636 dnl *** additional checks for G_MODULE_IMPL_DL
 637 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 638         case "$host_os" in
 639           linux*)
 640             G_MODULE_LDFLAGS='-rdynamic'
 641             ;;
 642         esac
 643         LIBS_orig="$LIBS"
 644         LDFLAGS_orig="$LDFLAGS"
 645         LIBS="$LIBS $G_MODULE_LIBS"
 646         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 647 dnl *** check whether we need preceeding underscores
 648         AC_CACHE_CHECK([for preceeding underscore in symbols],
 649                 glib_cv_uscore,[
 650                 AC_TRY_RUN([
 651                 #include <dlfcn.h>
 652                 int glib_underscore_test (void) { return 42; }
 653                 int main() {
 654                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 655                   handle = dlopen ((void*)0, 0);
 656                   if (handle) {
 657                     f1 = dlsym (handle, "glib_underscore_test");
 658                     f2 = dlsym (handle, "_glib_underscore_test");
 659                   } return (!f2 || f1);
 660                 }],
 661                         [glib_cv_uscore=yes],
 662                         [glib_cv_uscore=no],
 663                         [])
 664                 rm -f plugin.c plugin.o plugin.lo
 665         ])
 666         if test "x$glib_cv_uscore" = "xyes"; then
 667                 G_MODULE_NEED_USCORE=1
 668         else
 669                 G_MODULE_NEED_USCORE=0
 670         fi
 671
 672         LDFLAGS="$LDFLAGS_orig"
 673 dnl *** check for having dlerror()
 674         AC_CHECK_FUNC(dlerror,
 675                 [G_MODULE_HAVE_DLERROR=1],
 676                 [G_MODULE_HAVE_DLERROR=0])
 677         LIBS="$LIBS_orig"
 678 fi
 679 dnl *** done, have e got an implementation?
 680 if test -z "$G_MODULE_IMPL"; then
 681         G_MODULE_IMPL=0
 682 fi
 683
 684 AC_MSG_CHECKING(for the suffix of shared libraries)
 685 case "$host_os" in
 686   hpux9* | hpux10* | hpux11*)  # taken from ltconfig
 687     glib_gmodule_suffix='sl'
 688     ;;
 689   cygwin* | mingw*)
 690     glib_gmodule_suffix='dll'
 691     ;;
 692   *)
 693     glib_gmodule_suffix='so'
 694     ;;
 695 esac
 696 AC_MSG_RESULT(.$glib_gmodule_suffix)
 697
 698 AC_SUBST(G_MODULE_IMPL)
 699 AC_SUBST(G_MODULE_LIBS)
 700 AC_SUBST(G_MODULE_LIBS_EXTRA)
 701 AC_SUBST(G_MODULE_PLUGIN_LIBS)
 702 AC_SUBST(G_MODULE_LDFLAGS)
 703 AC_SUBST(G_MODULE_HAVE_DLERROR)
 704 AC_SUBST(G_MODULE_NEED_USCORE)
 705 AC_SUBST(GLIB_DEBUG_FLAGS)
 706
 707
 708 dnl ***********************
 709 dnl *** g_thread checks ***
 710 dnl ***********************
 711
 712 AC_ARG_WITH(threads, [  --with-threads=[none/posix/dce/solaris] specify a thread implementation to use],
 713         if test "x$with_threads" = x; then
 714                 want_threads=yes
 715         else
 716                 want_threads=$with_threads
 717         fi,
 718         want_threads=yes)
 719 if test "x$enable_threads" = "xno"; then
 720         want_threads=no
 721 fi
 722 if test "x$want_threads" = "xnone"; then
 723         want_threads=no
 724 fi
 725
 726 dnl error and warning message
 727 dnl *************************
 728
 729 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
 730                 computer. GLib will not have a default thread implementation."
 731
 732 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
 733                 platform (normaly it's "_REENTRANT"). I'll not use any flag on
 734                 compilation now, but then your programs might not work.
 735                 Please provide information on how it is done on your system."
 736
 737 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
 738                 "
 739
 740 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
 741                 provide information on your thread implementation.
 742                 You can also run 'configure --disable-threads'
 743                 to compile without thread support."
 744
 745 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
 746                 functions will not be MT-safe during their first call because
 747                 there is no working 'getpwuid_r' on your system."
 748
 749 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
 750                 because there is no 'localtime_r' on your system."
 751
 752 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
 753                 crude surrogate will be used. If you happen to know a
 754                 yield function for your system, please inform the GLib
 755                 developers."
 756
 757 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
 758                 threads on your system. Thus threads can only have the default
 759                 priority. If you happen to know these main/max
 760                 priorities, please inform the GLib developers."
 761
 762
 763 dnl determination of thread implementation
 764 dnl ***************************************
 765
 766 have_threads=none
 767 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
 768         case $host in
 769                 *-*-solaris*)
 770                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
 771                 ;;
 772         esac
 773 fi
 774 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
 775                                 || test "x$want_threads" = xdce; then
 776         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
 777         # -U_OSF_SOURCE is for Digital UNIX 4.0d
 778         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
 779         glib_save_CPPFLAGS="$CPPFLAGS"
 780         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
 781         if test "x$have_threads" = xnone; then
 782                 AC_TRY_COMPILE([#include <pthread.h>],
 783                         [pthread_attr_t attr; pthread_attr_init(&attr);],
 784                         have_threads=posix)
 785         fi
 786         if test "x$have_threads" = xnone; then
 787                 AC_TRY_COMPILE([#include <pthread.h>],
 788                         [pthread_attr_t attr; pthread_attr_create(&attr);],
 789                         have_threads=posix)
 790         fi
 791         CPPFLAGS="$glib_save_CPPFLAGS"
 792 fi
 793
 794 AC_MSG_CHECKING(for thread implementation)
 795
 796 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
 797         AC_MSG_RESULT(none available)
 798         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
 799 else
 800         AC_MSG_RESULT($have_threads)
 801 fi
 802
 803
 804 dnl determination of G_THREAD_CFLAGS
 805 dnl ********************************
 806
 807 G_THREAD_LIBS=
 808 G_THREAD_LIBS_EXTRA=
 809 G_THREAD_CFLAGS=
 810
 811 if test x"$have_threads" != xnone; then
 812
 813     G_THREAD_CFLAGS="-D_REENTRANT" # good default guess
 814
 815     case $host in
 816         *-aix*)
 817                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 818                 if test x"$GCC" = xyes; then
 819                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
 820                 fi
 821                 ;;
 822         *-freebsd2.2*)
 823                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 824
 825                 # FreeBSD 2.2.x shiped with gcc 2.7.2.x, which doesn't support
 826                 # -mthreads flag.
 827                 ;;
 828         *-sysv5uw7*)  # UnixWare 7
 829                 if test "$GCC" != "yes"; then
 830                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -Kthread"
 831                 else
 832                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -pthread"
 833                 fi
 834                 ;;
 835         *-dg-dgux*)  # DG/UX
 836                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
 837     esac
 838
 839     # if we are not finding the ctime_r function, then we probably are
 840     # not using the proper multithread flag
 841
 842     glib_save_CPPFLAGS="$CPPFLAGS"
 843     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
 844
 845     AC_TRY_COMPILE([#include <time.h>],
 846         [time_t t; char b[30]; ctime_r (&t, b);], ,
 847             [AC_TRY_COMPILE([#include <time.h>],
 848                 [time_t t; char b[30]; ctime_r (&t, b, 30);], ,
 849                         AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
 850
 851     CPPFLAGS="$glib_save_CPPFLAGS"
 852
 853     AC_MSG_CHECKING(thread related cflags)
 854     AC_MSG_RESULT($G_THREAD_CFLAGS)
 855     CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 856 fi
 857
 858 dnl determination of G_THREAD_LIBS
 859 dnl ******************************
 860
 861 mutex_has_default=no
 862 case $have_threads in
 863         posix|dce)
 864            glib_save_CPPFLAGS="$CPPFLAGS"
 865            CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
 866            G_THREAD_LIBS=error
 867            glib_save_LIBS="$LIBS"
 868            case $host in
 869              *-sysv5uw7*) # UnixWare 7
 870                 if test "$GCC" != "yes"; then
 871                         G_THREAD_LIBS="-Kthread"
 872                 else
 873                         G_THREAD_LIBS="-pthread"
 874                 fi
 875                 ;;
 876              *)
 877                 for thread_lib in "" pthread pthreads c_r thread dce; do
 878                         if test x"$thread_lib" = x; then
 879                                 add_thread_lib=""
 880                                 IN=""
 881                         else
 882                                 add_thread_lib="-l$thread_lib"
 883                                 IN=" in -l$thread_lib"
 884                         fi
 885                         if test x"$have_threads" = xposix; then
 886                                 defattr=0
 887                         else
 888                                 defattr=pthread_attr_default
 889                         fi
 890
 891                         LIBS="$glib_save_LIBS $add_thread_lib"
 892
 893                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
 894                         AC_TRY_RUN([#include <pthread.h>
 895                                 int check_me = 0;
 896                                 void* func(void* data) {check_me = 42;}
 897                                 main()
 898                                 { pthread_t t;
 899                                   void *ret;
 900                                   pthread_create (&t, $defattr, func, 0);
 901                                   pthread_join (t, &ret);
 902                                   exit (check_me != 42);
 903                                 }],
 904                                 [AC_MSG_RESULT(yes)
 905                                 G_THREAD_LIBS="$add_thread_lib"
 906                                 break],
 907                                 [AC_MSG_RESULT(no)])
 908                 done
 909                 if test "x$G_THREAD_LIBS" = xerror; then
 910                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 911                 fi
 912                 for thread_lib in "" rt rte; do
 913                         if test x"$thread_lib" = x; then
 914                                 add_thread_lib=""
 915                                 IN=""
 916                         else
 917                                 add_thread_lib="-l$thread_lib"
 918                                 IN=" in -l$thread_lib"
 919                         fi
 920                         LIBS="$glib_save_LIBS $add_thread_lib"
 921
 922                         AC_MSG_CHECKING(for sched_get_priority_min$IN)
 923                         AC_TRY_RUN([#include <sched.h>
 924                                 #include <errno.h>
 925                                 int main() {
 926                                 errno = 0;
 927                                 return sched_get_priority_min(SCHED_OTHER)==-1
 928                                         && errno != 0;
 929                                 }],
 930                                 [AC_MSG_RESULT(yes)
 931                                 G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
 932                                 posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
 933                                 posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
 934                                 break],
 935                                 [AC_MSG_RESULT(no)])
 936                 done
 937                 LIBS="$glib_save_LIBS"
 938                 ;;
 939            esac
 940            mutex_has_default=yes
 941            mutex_default_type='pthread_mutex_t'
 942            mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
 943            mutex_header_file='pthread.h'
 944            if test "x$have_threads" = "xposix"; then
 945              g_threads_impl="POSIX"
 946            else
 947              g_threads_impl="DCE"
 948              have_threads="posix"
 949            fi
 950            AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
 951            CPPFLAGS="$glib_save_CPPFLAGS"
 952            ;;
 953         solaris)
 954            G_THREAD_LIBS=error
 955            AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
 956            mutex_has_default=yes
 957            mutex_default_type='mutex_t'
 958            mutex_default_init="DEFAULTMUTEX"
 959            mutex_header_file='thread.h'
 960            g_threads_impl="SOLARIS"
 961            ;;
 962         none)
 963            g_threads_impl="NONE"
 964            ;;
 965         *)
 966            g_threads_impl="NONE"
 967            G_THREAD_LIBS=error
 968            ;;
 969 esac
 970
 971 if test "x$G_THREAD_LIBS" = xerror; then
 972         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 973 fi
 974
 975 case $host in
 976   *-*-beos*)
 977     G_THREAD_LIBS="-lbe -lroot -lglib "
 978     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
 979     ;;
 980   *)
 981     ;;
 982 esac
 983
 984 AC_MSG_CHECKING(thread related libraries)
 985 AC_MSG_RESULT($G_THREAD_LIBS)
 986
 987 dnl check for mt safe function variants and some posix functions
 988 dnl ************************************************************
 989
 990 if test x"$have_threads" != xnone; then
 991         glib_save_LIBS="$LIBS"
 992         # we are not doing the following for now, as this might require glib
 993         # to always be linked with the thread libs on some platforms.
 994         # LIBS="$LIBS $G_THREAD_LIBS"
 995         AC_CHECK_FUNCS(localtime_r)
 996         if test "$ac_cv_header_pwd_h" = "yes"; then
 997                 AC_CACHE_CHECK([for posix getpwuid_r],
 998                         ac_cv_func_posix_getpwuid_r,
 999                         [AC_TRY_RUN([#include <errno.h>
1000                                 #include <pwd.h>
1001                                 int main () { char buffer[10000];
1002                                 struct passwd pwd, *pwptr = &pwd;
1003                                 int error;
1004                                 errno = 0;
1005                                 error = getpwuid_r (0, &pwd, buffer,
1006                                         sizeof (buffer), &pwptr);
1007                                 return (error < 0 && errno == ENOSYS)
1008                                         || error == ENOSYS; }],
1009                                 [ac_cv_func_posix_getpwuid_r=yes],
1010                                 [ac_cv_func_posix_getpwuid_r=no])])
1011                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
1012                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
1013                                 [Have POSIX function getpwuid_r])
1014                 else
1015                         AC_CACHE_CHECK([for nonposix getpwuid_r],
1016                                 ac_cv_func_nonposix_getpwuid_r,
1017                                 [AC_TRY_COMPILE([#include <pwd.h>],
1018                                         [char buffer[10000];
1019                                         struct passwd pwd;
1020                                         getpwuid_r (0, &pwd, buffer,
1021                                                         sizeof (buffer));],
1022                                         [ac_cv_func_nonposix_getpwuid_r=yes],
1023                                         [ac_cv_func_nonposix_getpwuid_r=no])])
1024                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
1025                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
1026                                         [Have non-POSIX function getpwuid_r])
1027                         fi
1028                 fi
1029         fi
1030         LIBS="$LIBS $G_THREAD_LIBS"
1031         if test x"$have_threads" = xposix; then
1032                 glib_save_CPPFLAGS="$CPPFLAGS"
1033                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1034                 GLIB_SIZEOF([#include <pthread.h>],
1035                         pthread_t,
1036                         system_thread)
1037                 # This is not AC_CHECK_FUNC to also work with function
1038                 # name mangling in header files.
1039                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1040                 AC_TRY_LINK([#include <pthread.h>],
1041                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1042                         [AC_MSG_RESULT(yes)
1043                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1044                                   [Have function pthread_attr_setstacksize])],
1045                         [AC_MSG_RESULT(no)])
1046                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1047                 if test x"$posix_priority_min" = xnone; then
1048                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1049                                 PX_PRIO_MIN],,[
1050                                 posix_priority_min=PX_PRIO_MIN
1051                                 posix_priority_max=PX_PRIO_MAX])
1052                 fi
1053                 if test x"$posix_priority_min" = xnone; then
1054                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1055                                 PRI_OTHER_MIN],,[
1056                                 posix_priority_min=PRI_OTHER_MIN
1057                                 posix_priority_max=PRI_OTHER_MAX])
1058                 fi
1059                 if test x"$posix_priority_min" = x; then
1060                         AC_MSG_RESULT(none found)
1061                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1062                         posix_priority_min=-1
1063                         posix_priority_max=-1
1064                 else
1065                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1066                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1067                         AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])
1068                 fi
1069                 posix_yield_func=none
1070                 AC_MSG_CHECKING(for posix yield function)
1071                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1072                                                         thr_yield; do
1073                         AC_TRY_LINK([#include <pthread.h>],
1074                                 [$yield_func()],
1075                                 [posix_yield_func="$yield_func"
1076                                 break])
1077                 done
1078                 if test x"$posix_yield_func" = xnone; then
1079                         AC_MSG_RESULT(none found)
1080                         AC_MSG_WARN($POSIX_NO_YIELD)
1081                         posix_yield_func="g_usleep(1000)"
1082                 else
1083                         AC_MSG_RESULT($posix_yield_func)
1084                         posix_yield_func="$posix_yield_func()"
1085                 fi
1086                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1087                 CPPFLAGS="$glib_save_CPPFLAGS"
1088
1089                 AC_MSG_CHECKING(whether to use the PID niceness surrogate for thread priorities)
1090                 AC_TRY_RUN([#include <pthread.h>
1091                         #include <sys/types.h>
1092                         #include <unistd.h>
1093                         pid_t other_pid = 0;
1094
1095                         void* func(void* data) {other_pid = getpid();}
1096                         main()
1097                         { pthread_t t;
1098                           void *ret;
1099                           pthread_create (&t, $defattr, func, NULL);
1100                           pthread_join (t, &ret);
1101                           exit (getpid()==other_pid ||
1102                                 $posix_priority_min != $posix_priority_max);
1103                         }],
1104                         [AC_MSG_RESULT(yes),
1105                          AC_DEFINE(G_THREAD_USE_PID_SURROGATE, 1,
1106                                 [whether to use the PID niceness surrogate for thread priorities])
1107
1108                          glib_cv_sizeof_system_thread=`expr $glib_cv_sizeof_system_thread + $ac_cv_sizeof_long`],
1109                         [AC_MSG_RESULT(no)])
1110
1111         else # solaris threads
1112                 GLIB_SIZEOF([#include <thread.h>],
1113                         thread_t,
1114                         system_thread)
1115         fi
1116
1117         LIBS="$glib_save_LIBS"
1118
1119         # now spit out all the warnings.
1120         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1121            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1122                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1123         fi
1124         if test "$ac_cv_func_localtime_r" != "yes"; then
1125                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1126         fi
1127 else
1128         # If no thread implementation exists, we will provide enough
1129         # space for a pointer
1130         GLIB_SIZEOF(, void*, system_thread)
1131 fi
1132
1133 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1134                    [Source file containing theread implementation])
1135 AC_SUBST(G_THREAD_CFLAGS)
1136 AC_SUBST(G_THREAD_LIBS)
1137 AC_SUBST(G_THREAD_LIBS_EXTRA)
1138
1139 dnl **********************************************
1140 dnl *** GDefaultMutex setup and initialization ***
1141 dnl **********************************************
1142 dnl
1143 dnl if mutex_has_default = yes, we also got
1144 dnl mutex_default_type, mutex_default_init and mutex_header_file
1145 GLIB_IF_VAR_EQ(mutex_has_default, yes,
1146         glib_save_CPPFLAGS="$CPPFLAGS"
1147         glib_save_LIBS="$LIBS"
1148         LIBS="$LIBS $G_THREAD_LIBS"
1149         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1150         GLIB_SIZEOF([#include <$mutex_header_file>],
1151                     $mutex_default_type,
1152                     gmutex,
1153                     )
1154         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1155                            $mutex_default_type,
1156                            gmutex,
1157                            $glib_cv_sizeof_gmutex,
1158                            $mutex_default_init)
1159         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1160                 mutex_has_default=no
1161         fi
1162         CPPFLAGS="$glib_save_CPPFLAGS"
1163         LIBS="$glib_save_LIBS"
1164         ,
1165 )
1166
1167
1168 dnl ****************************************
1169 dnl *** GLib POLL* compatibility defines ***
1170 dnl ****************************************
1171 GLIB_SYSDEFS(
1172 [#include <sys/types.h>
1173 #include <sys/poll.h>],
1174         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
1175         glibconfig-sysdefs.h,
1176         =)
1177
1178 dnl ***********************
1179 dnl *** Tests for iconv ***
1180 dnl ***********************
1181
1182 AC_ARG_WITH(libiconv, [ --with-libiconv     Use the libiconv library ],,with_libiconv=maybe)
1183
1184 found_iconv=no
1185
1186 if test "x$with_libiconv" != "xyes" ; then
1187    #
1188    # Check in the C library
1189    #
1190    AC_CHECK_FUNC(iconv_open, with_libiconv=no; found_iconv=yes)
1191 fi
1192
1193 if test "x$with_libiconv" != "xno" ; then
1194    #
1195    # Check for libiconv
1196    #
1197    AC_CHECK_LIB(iconv, libiconv_open, with_libiconv=yes; found_iconv=yes)
1198 fi
1199
1200 if test "x$found_iconv" = "xno" ; then
1201    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
1202 fi
1203
1204 if test "x$with_libiconv" = "xyes" ; then
1205   ICONV_LIBS="-liconv"
1206   AC_DEFINE(USE_LIBICONV)
1207 fi
1208 AC_SUBST(ICONV_LIBS)
1209
1210 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
1211 dnl since we need it for g_iconv()
1212
1213 AC_MSG_CHECKING([for EILSEQ])
1214 AC_TRY_COMPILE([
1215 #include <errno.h>
1216 ],
1217 [
1218 int error = EILSEQ;
1219 ], have_eilseq=yes, have_eilseq=no);
1220 AC_MSG_RESULT($have_eilseq)
1221
1222 dnl **************************
1223 dnl *** Checks for gtk-doc ***
1224 dnl **************************
1225
1226 AC_ARG_WITH(html-dir, [  --with-html-dir=PATH path to installed docs ])
1227
1228 if test "x$with_html_dir" = "x" ; then
1229   HTML_DIR='${datadir}/gtk-doc/html'
1230 else
1231   HTML_DIR=$with_html_dir
1232 fi
1233
1234 AC_SUBST(HTML_DIR)
1235
1236
1237 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
1238 AM_CONDITIONAL(HAVE_GTK_DOC, $GTKDOC)
1239 AC_SUBST(HAVE_GTK_DOC)
1240
1241 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1242 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1243
1244 dnl Let people disable the gtk-doc stuff.
1245 AC_ARG_ENABLE(gtk-doc, [  --enable-gtk-doc  Use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)
1246
1247 if test x$enable_gtk_doc = xauto ; then
1248   if test x$GTKDOC = xtrue ; then
1249     enable_gtk_doc=yes
1250   else
1251     enable_gtk_doc=no
1252   fi
1253 fi
1254
1255 dnl NOTE: We need to use a separate automake conditional for this
1256 dnl       to make this work with the tarballs.
1257 AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
1258
1259 dnl ******************************
1260 dnl *** output the whole stuff ***
1261 dnl ******************************
1262
1263 AC_OUTPUT_COMMANDS([
1264
1265 ## Generate `glibconfig.h' in two cases
1266 ## 1. `config.status' is run either explicitly, or via configure.
1267 ##     Esp. not when it is run in `Makefile' to generate makefiles and
1268 ##     config.h
1269 ## 2. CONFIG_OTHER is set explicitly
1270 ##
1271 ## Case 1 is difficult.  We know that `automake' sets one of
1272 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
1273 ## only when AM_CONFIG_HEADER is set, however.
1274
1275 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
1276   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
1277   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
1278 fi
1279 case "$CONFIG_OTHER" in
1280 *glibconfig.h*)
1281         echo creating glibconfig.h
1282         outfile=glibconfig.h-tmp
1283         cat > $outfile <<\_______EOF
1284 /* glibconfig.h
1285  *
1286  * This is a generated file.  Please modify 'configure.in'
1287  */
1288
1289 #ifndef __G_LIBCONFIG_H__
1290 #define __G_LIBCONFIG_H__
1291
1292 #include <gmacros.h>
1293
1294 _______EOF
1295
1296         if test x$glib_limits_h = xyes; then
1297           echo '#include <limits.h>' >> $outfile
1298         fi
1299         if test x$glib_float_h = xyes; then
1300           echo '#include <float.h>' >> $outfile
1301         fi
1302         if test x$glib_values_h = xyes; then
1303           echo '#include <values.h>' >> $outfile
1304         fi
1305         if test "$glib_header_alloca_h" = "yes"; then
1306           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
1307         fi
1308         if test x$glib_sys_poll_h = xyes; then
1309           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
1310         fi
1311
1312         cat >> $outfile <<_______EOF
1313
1314 G_BEGIN_DECLS
1315
1316 #define G_MINFLOAT      $glib_mf
1317 #define G_MAXFLOAT      $glib_Mf
1318 #define G_MINDOUBLE     $glib_md
1319 #define G_MAXDOUBLE     $glib_Md
1320 #define G_MINSHORT      $glib_ms
1321 #define G_MAXSHORT      $glib_Ms
1322 #define G_MAXUSHORT     $glib_Mus
1323 #define G_MININT        $glib_mi
1324 #define G_MAXINT        $glib_Mi
1325 #define G_MAXUINT       $glib_Mui
1326 #define G_MINLONG       $glib_ml
1327 #define G_MAXLONG       $glib_Ml
1328 #define G_MAXULONG      $glib_Mul
1329
1330 _______EOF
1331
1332
1333         ### this should always be true in a modern C/C++ compiler
1334         cat >>$outfile <<_______EOF
1335 typedef signed char gint8;
1336 typedef unsigned char guint8;
1337 _______EOF
1338
1339
1340         if test -n "$gint16"; then
1341           cat >>$outfile <<_______EOF
1342 typedef signed $gint16 gint16;
1343 typedef unsigned $gint16 guint16;
1344 #define G_GINT16_FORMAT $gint16_format
1345 #define G_GUINT16_FORMAT $guint16_format
1346 _______EOF
1347         fi
1348
1349
1350         if test -n "$gint32"; then
1351           cat >>$outfile <<_______EOF
1352 typedef signed $gint32 gint32;
1353 typedef unsigned $gint32 guint32;
1354 #define G_GINT32_FORMAT $gint32_format
1355 #define G_GUINT32_FORMAT $guint32_format
1356 _______EOF
1357         fi
1358
1359
1360         if test -n "$gint64"; then
1361           cat >>$outfile <<_______EOF
1362 #define G_HAVE_GINT64 1
1363
1364 ${glib_extension}typedef signed $gint64 gint64;
1365 ${glib_extension}typedef unsigned $gint64 guint64;
1366
1367 #define G_GINT64_CONSTANT(val)  $gint64_constant
1368 _______EOF
1369                 if test -n "$gint64_format"; then
1370           cat >>$outfile <<_______EOF
1371 #define G_GINT64_FORMAT $gint64_format
1372 #define G_GUINT64_FORMAT $guint64_format
1373 _______EOF
1374                 fi
1375         fi
1376
1377         case x$glib_size_t in
1378         x2) echo "typedef gint16  gssize;" >> $outfile
1379             echo "typedef guint16 gsize;"  >> $outfile
1380             ;;
1381         x4) echo "typedef gint32  gssize;" >> $outfile
1382             echo "typedef guint32 gsize;"  >> $outfile
1383             ;;
1384         x8) echo "typedef gint64  gssize;" >> $outfile
1385             echo "typedef guint64 gsize;"  >> $outfile
1386             ;;
1387         *)  echo "#error size of size_t is unknown" >> $outfile
1388             ;;
1389         esac
1390
1391         if test -z "$glib_unknown_void_p"; then
1392           cat >>$outfile <<_______EOF
1393
1394 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
1395 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
1396
1397 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
1398 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
1399 _______EOF
1400         else
1401           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
1402         fi
1403
1404
1405
1406         cat >>$outfile <<_______EOF
1407 $glib_atexit
1408 $glib_memmove
1409 $glib_defines
1410 $glib_os
1411
1412 $glib_vacopy
1413
1414 #ifdef  __cplusplus
1415 #define G_HAVE_INLINE   1
1416 #else   /* !__cplusplus */
1417 $glib_inline
1418 #endif  /* !__cplusplus */
1419 _______EOF
1420
1421         echo >>$outfile
1422         if test x$g_have_eilseq = xno; then
1423                 cat >>$outfile <<_______EOF
1424 #ifndef EILSEQ
1425 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
1426  * The correspondence between this and the corresponding definition
1427  * in libiconv is essential.
1428  */
1429 #  define EILSEQ ENOENT
1430 #endif
1431 _______EOF
1432
1433         fi
1434
1435         echo >>$outfile
1436         if test x$g_mutex_has_default = xyes; then
1437                 cat >>$outfile <<_______EOF
1438 $g_enable_threads_def G_THREADS_ENABLED
1439 #define G_THREADS_IMPL_$g_threads_impl_def
1440 typedef struct _GStaticMutex GStaticMutex;
1441 struct _GStaticMutex
1442 {
1443   struct _GMutex *runtime_mutex;
1444   struct {
1445     union {
1446       char   pad[$g_mutex_sizeof];
1447       double dummy_double;
1448       void  *dummy_pointer;
1449       long   dummy_long;
1450     } mutex;
1451     void *debug_info;
1452   } static_mutex;
1453 };
1454 #define G_STATIC_MUTEX_INIT     { NULL, { { { $g_mutex_contents} }, NULL } }
1455 #define g_static_mutex_get_mutex(mutex) \
1456   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->static_mutex)) : \
1457    g_static_mutex_get_mutex_impl (&((mutex)->runtime_mutex)))
1458 _______EOF
1459         else
1460                 cat >>$outfile <<_______EOF
1461 $g_enable_threads_def G_THREADS_ENABLED
1462 #define G_THREADS_IMPL_$g_threads_impl_def
1463 typedef struct _GMutex* GStaticMutex;
1464 #define G_STATIC_MUTEX_INIT NULL
1465 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (mutex))
1466 _______EOF
1467         fi
1468
1469         cat >>$outfile <<_______EOF
1470 /* This represents a system thread as used by the implementation. An
1471  * alien implementaion, as loaded by g_thread_init can only count on
1472  * "sizeof (gpointer)" bytes to store their info. We however need more
1473  * for some of our native implementations. */
1474 typedef union _GSystemThread GSystemThread;
1475 union _GSystemThread
1476 {
1477   char   data[$g_system_thread_sizeof];
1478   double dummy_double;
1479   void  *dummy_pointer;
1480   long   dummy_long;
1481 };
1482 _______EOF
1483
1484         echo >>$outfile
1485         g_bit_sizes="16 32"
1486         if test -n "$gint64"; then
1487           g_bit_sizes="$g_bit_sizes 64"
1488         fi
1489         for bits in $g_bit_sizes; do
1490           cat >>$outfile <<_______EOF
1491 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
1492 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
1493 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
1494 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
1495 _______EOF
1496         done
1497
1498         cat >>$outfile <<_______EOF
1499 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
1500 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
1501 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
1502 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
1503 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
1504 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
1505 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
1506 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
1507 #define G_BYTE_ORDER $g_byte_order
1508
1509 _______EOF
1510
1511         if test -r glibconfig-sysdefs.h; then
1512           cat glibconfig-sysdefs.h >>$outfile
1513         fi
1514
1515         cat >>$outfile <<_______EOF
1516
1517 #define G_MODULE_SUFFIX "$g_module_suffix"
1518
1519 G_END_DECLS
1520
1521 #endif /* GLIBCONFIG_H */
1522 _______EOF
1523
1524
1525         if cmp -s $outfile glibconfig.h; then
1526           echo glibconfig.h is unchanged
1527           rm -f $outfile
1528         else
1529           mv $outfile glibconfig.h
1530         fi ;;
1531 esac
1532 ],[
1533
1534 # Note that if two cases are the same, case goes with the first one.
1535 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
1536 # on variable expansion in case labels.  Look at the generated config.status
1537 # for a hint.
1538
1539 glib_header_alloca_h="$ac_cv_header_alloca_h"
1540
1541 case xyes in
1542 x$ac_cv_header_float_h)
1543   glib_float_h=yes
1544   glib_mf=FLT_MIN glib_Mf=FLT_MAX
1545   glib_md=DBL_MIN glib_Md=DBL_MAX
1546   ;;
1547 x$ac_cv_header_values_h)
1548   glib_values_h=yes
1549   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
1550   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
1551   ;;
1552 esac
1553
1554 case xyes in
1555 x$ac_cv_header_limits_h)
1556   glib_limits_h=yes
1557   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
1558   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
1559   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
1560   ;;
1561 x$ac_cv_header_values_h)
1562   glib_values_h=yes
1563   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
1564   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
1565   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
1566   ;;
1567 esac
1568
1569 if test x$ac_cv_header_sys_poll_h = xyes ; then
1570   glib_sys_poll_h=yes
1571 fi
1572
1573 case 2 in
1574 $ac_cv_sizeof_short)
1575   gint16=short
1576   gint16_format='"hi"'
1577   guint16_format='"hu"'
1578   ;;
1579 $ac_cv_sizeof_int)
1580   gint16=int
1581   gint16_format='"i"'
1582   guint16_format='"u"'
1583   ;;
1584 esac
1585 case 4 in
1586 $ac_cv_sizeof_short)
1587   gint32=short
1588   gint32_format='"hi"'
1589   guint32_format='"hu"'
1590   ;;
1591 $ac_cv_sizeof_int)
1592   gint32=int
1593   gint32_format='"i"'
1594   guint32_format='"u"'
1595   ;;
1596 $ac_cv_sizeof_long)
1597   gint32=long
1598   gint32_format='"li"'
1599   guint32_format='"lu"'
1600   ;;
1601 esac
1602 case 8 in
1603 $ac_cv_sizeof_int)
1604   gint64=int
1605   gint64_format='"i"'
1606   guint64_format='"u"'
1607   glib_extension=
1608   gint64_constant='(val)'
1609   ;;
1610 $ac_cv_sizeof_long)
1611   gint64=long
1612   gint64_format='"li"'
1613   guint64_format='"lu"'
1614   glib_extension=
1615   gint64_constant='(val##L)'
1616   ;;
1617 $ac_cv_sizeof_long_long)
1618   gint64='long long'
1619   if test -n "$glib_cv_long_long_format"; then
1620     gint64_format='"'$glib_cv_long_long_format'i"'
1621     guint64_format='"'$glib_cv_long_long_format'u"'
1622   fi
1623   glib_extension='G_GNUC_EXTENSION '
1624   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1625   ;;
1626 esac
1627 glib_size_t=$glib_cv_sizeof_size_t
1628
1629 gintbits=`expr $ac_cv_sizeof_int \* 8`
1630 glongbits=`expr $ac_cv_sizeof_long \* 8`
1631
1632
1633 case $ac_cv_sizeof_void_p in
1634 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
1635 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
1636 *)                      glib_unknown_void_p=yes ;;
1637 esac
1638
1639
1640 case xyes in
1641 x$ac_cv_func_atexit)
1642   glib_atexit="
1643 #ifdef NeXT /* @#%@! NeXTStep */
1644 # define g_ATEXIT(proc) (!atexit (proc))
1645 #else
1646 # define g_ATEXIT(proc) (atexit (proc))
1647 #endif"
1648   ;;
1649 x$ac_cv_func_on_exit)
1650   glib_atexit="
1651 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
1652   ;;
1653 esac
1654
1655 case xyes in
1656 x$ac_cv_func_memmove)
1657   glib_memmove='
1658 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
1659   ;;
1660 x$glib_cv_working_bcopy)
1661   glib_memmove="
1662 /* memmove isn't available, but bcopy can copy overlapping memory regions */
1663 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
1664   ;;
1665 *)
1666   glib_memmove="
1667 /* memmove isn't found and bcopy can't copy overlapping memory regions,
1668  * so we have to roll our own copy routine. */
1669 void g_memmove (void* dest, const void * src, unsigned long len);"
1670   ;;
1671 esac
1672
1673 glib_defines="
1674 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
1675 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
1676 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
1677 "
1678
1679 case xyes in
1680 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
1681 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
1682 *)                      glib_vacopy=''
1683 esac
1684
1685 if test x$glib_cv_va_val_copy = xno; then
1686   glib_vacopy="\$glib_vacopy
1687 #define G_VA_COPY_AS_ARRAY 1"
1688 fi
1689
1690 if test x$glib_cv_hasinline = xyes; then
1691     glib_inline='#define G_HAVE_INLINE 1'
1692 fi
1693 if test x$glib_cv_has__inline = xyes; then
1694     glib_inline="\$glib_inline
1695 #define G_HAVE___INLINE 1"
1696 fi
1697 if test x$glib_cv_has__inline__ = xyes; then
1698     glib_inline="\$glib_inline
1699 #define G_HAVE___INLINE__ 1"
1700 fi
1701
1702 case xyes in
1703 x$ac_cv_c_bigendian)
1704   g_byte_order=G_BIG_ENDIAN
1705   g_bs_native=BE
1706   g_bs_alien=LE
1707   ;;
1708 *)
1709   g_byte_order=G_LITTLE_ENDIAN
1710   g_bs_native=LE
1711   g_bs_alien=BE
1712   ;;
1713 esac
1714
1715 g_have_eilseq=$have_eilseq
1716
1717 case x$have_threads in
1718 xnone)  g_enable_threads_def="#undef";;
1719 *)      g_enable_threads_def="#define";;
1720 esac
1721
1722 g_threads_impl_def=$g_threads_impl
1723
1724 g_mutex_has_default="$mutex_has_default"
1725 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
1726 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
1727 g_mutex_contents="$glib_cv_byte_contents_gmutex"
1728
1729 g_module_suffix="$glib_gmodule_suffix"
1730
1731 case $host in
1732   *-*-beos*)
1733     glib_os="#define G_OS_BEOS"
1734     ;;
1735   *-*-cygwin*)
1736     glib_os="#define G_OS_UNIX
1737 #define G_WITH_CYGWIN"
1738 v    ;;
1739   *)
1740     glib_os="#define G_OS_UNIX"
1741     ;;
1742 esac
1743 ])
1744
1745 AC_OUTPUT([
1746 glib-2.0.pc
1747 gmodule-2.0.pc
1748 gthread-2.0.pc
1749 gobject-2.0.pc
1750 glib.spec
1751 Makefile
1752 glib-config-2.0
1753 build/Makefile
1754 build/win32/Makefile
1755 gmodule/gmoduleconf.h
1756 gmodule/Makefile
1757 gobject/Makefile
1758 gthread/Makefile
1759 docs/Makefile
1760 docs/glib-config.1
1761 docs/reference/Makefile
1762 docs/reference/glib/Makefile
1763 docs/reference/gobject/Makefile
1764 tests/Makefile
1765 ],[case "$CONFIG_FILES" in
1766 *glib-config-2.0*)chmod +x glib-config-2.0;;
1767 esac
1768 echo ""
1769 echo " *** IMPORTANT *** "
1770 echo ""
1771 echo "This is a development version of GLib.  You should be using a stable"
1772 echo "version, which is available at ftp://ftp.gtk.org/pub/gtk/v1.2/.  The"
1773 echo "version you just configured is meant for developers of GLib only:"
1774 echo ""
1775 echo "  * You should not base stable software on this version of GLib."
1776 echo "  * GNOME developers should use a stable version of GLib."
1777 echo ""
1778 echo "If you install this version of GLib, we strongly recommend that you"
1779 echo "install it in a different prefix than GLib 1.2.  Use --prefix as an"
1780 echo "argument to configure to do this.  Otherwise, you will not be able to"
1781 echo "do development with GLib 1.2 any longer."
1782 echo ""
1783 echo " *** You should be using GLib 1.2 instead. ***"
1784 ])