configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.53)dnl              dnl Minimum Autoconf version required.
   3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 dnl This is here so we can set $subdirs directly based on configure fragments.
   9 AC_CONFIG_SUBDIRS()
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_PROG_CC
  14 if test $host != $build; then
  15   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  16 fi
  17 AC_SUBST(cross_compiling)
  18 AC_PROG_CPP
  19 # We need the C++ compiler only for testing.
  20 AC_PROG_CXX
  21
  22 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
  23   AC_MSG_ERROR([you must configure in a separate build directory])
  24 fi
  25
  26 # This will get text that should go into config.make.
  27 config_vars=
  28
  29 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  30 AC_ARG_WITH([gd],
  31             AC_HELP_STRING([--with-gd=DIR],
  32                            [find libgd include dir and library with prefix DIR]),
  33             [dnl
  34 case "$with_gd" in
  35 yes|''|no) ;;
  36 *) libgd_include="-I$withval/include"
  37    libgd_ldflags="-L$withval/lib" ;;
  38 esac
  39 ])
  40 AC_ARG_WITH([gd-include],
  41             AC_HELP_STRING([--with-gd-include=DIR],
  42                            [find libgd include files in DIR]),
  43             [dnl
  44 case "$with_gd_include" in
  45 ''|no) ;;
  46 *) libgd_include="-I$withval" ;;
  47 esac
  48 ])
  49 AC_ARG_WITH([gd-lib],
  50             AC_HELP_STRING([--with-gd-lib=DIR],
  51                            [find libgd library files in DIR]),
  52             [dnl
  53 case "$with_gd_lib" in
  54 ''|no) ;;
  55 *) libgd_ldflags="-L$withval" ;;
  56 esac
  57 ])
  58
  59 if test -n "$libgd_include"; then
  60   config_vars="$config_vars
  61 CFLAGS-memusagestat.c = $libgd_include"
  62 fi
  63 if test -n "$libgd_ldflags"; then
  64   config_vars="$config_vars
  65 libgd-LDFLAGS = $libgd_ldflags"
  66 fi
  67
  68 dnl Arguments to specify presence of other packages/features.
  69 AC_ARG_WITH([fp],
  70             AC_HELP_STRING([--with-fp],
  71                            [if using floating-point hardware @<:@default=yes@:>@]),
  72             [with_fp=$withval],
  73             [with_fp=yes])
  74 AC_SUBST(with_fp)
  75 AC_ARG_WITH([binutils],
  76             AC_HELP_STRING([--with-binutils=PATH],
  77                            [specify location of binutils (as and ld)]),
  78             [path_binutils=$withval],
  79             [path_binutils=''])
  80 AC_ARG_WITH([selinux],
  81             AC_HELP_STRING([--with-selinux],
  82                            [if building with SELinux support]),
  83             [with_selinux=$withval],
  84             [with_selinux=auto])
  85
  86 AC_ARG_WITH([headers],
  87             AC_HELP_STRING([--with-headers=PATH],
  88                            [location of system headers to use
  89                             (for example /usr/src/linux/include)
  90                             @<:@default=compiler default@:>@]),
  91             [sysheaders=$withval],
  92             [sysheaders=''])
  93
  94 AC_SUBST(use_default_link)
  95 AC_ARG_WITH([default-link],
  96             AC_HELP_STRING([--with-default-link],
  97                            [do not use explicit linker scripts]),
  98             [use_default_link=$withval],
  99             [use_default_link=default])
 100
 101 AC_ARG_ENABLE([sanity-checks],
 102               AC_HELP_STRING([--disable-sanity-checks],
 103                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 104               [enable_sanity=$enableval],
 105               [enable_sanity=yes])
 106
 107 AC_SUBST(enable_check_abi)
 108 AC_ARG_ENABLE([check-abi],
 109               AC_HELP_STRING([--enable-check-abi],
 110                              [do "make check-abi" in "make check" (no/warn/yes)
 111                               @<:@default=no@:>@]),
 112               [enable_check_abi=$enableval],
 113               [enable_check_abi=no])
 114
 115 dnl Arguments to enable or disable building the static, shared, profiled,
 116 dnl and -fomit-frame-pointer libraries.
 117 dnl I've disabled this for now since we cannot build glibc without static
 118 dnl libraries built in the moment.
 119 dnl AC_ARG_ENABLE([static],
 120 dnl               AC_HELP_STRING([--enable-static],
 121 dnl                              [build static library @<:@default=yes@:>@]),
 122 dnl               [static=$enableval],
 123 dnl               [static=yes])
 124 static=yes
 125 AC_ARG_ENABLE([shared],
 126               AC_HELP_STRING([--enable-shared],
 127                              [build shared library @<:@default=yes if GNU ld@:>@]),
 128               [shared=$enableval],
 129               [shared=yes])
 130 AC_ARG_ENABLE([profile],
 131               AC_HELP_STRING([--enable-profile],
 132                              [build profiled library @<:@default=no@:>@]),
 133               [profile=$enableval],
 134               [profile=no])
 135 AC_ARG_ENABLE([versioning],
 136               AC_HELP_STRING([--disable-versioning],
 137                              [do not include versioning information in the library objects @<:@default=yes if supported@:>@]),
 138               [enable_versioning=$enableval],
 139               [enable_versioning=yes])
 140
 141 AC_ARG_ENABLE([oldest-abi],
 142               AC_HELP_STRING([--enable-oldest-abi=ABI],
 143                              [configure the oldest ABI supported @<:@e.g. 2.2@:>@ @<:@default=glibc default@:>@]),
 144               [oldest_abi=$enableval],
 145               [oldest_abi=no])
 146 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
 147   oldest_abi=default
 148 else
 149   AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
 150 fi
 151 AC_SUBST(oldest_abi)
 152
 153 AC_ARG_ENABLE([stackguard-randomization],
 154               AC_HELP_STRING([--enable-stackguard-randomization],
 155                              [initialize __stack_chk_guard canary with a random number at program start]),
 156               [enable_stackguard_randomize=$enableval],
 157               [enable_stackguard_randomize=no])
 158 if test "$enable_stackguard_randomize" = yes; then
 159   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 160 fi
 161
 162 dnl Generic infrastructure for drop-in additions to libc.
 163 AC_ARG_ENABLE([add-ons],
 164               AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
 165                              [configure and build add-ons in DIR1,DIR2,...
 166                               search for add-ons if no parameter given]),
 167                              , [enable_add_ons=yes])
 168
 169 AC_ARG_ENABLE([hidden-plt],
 170               AC_HELP_STRING([--disable-hidden-plt],
 171                              [do not hide internal function calls to avoid PLT]),
 172               [hidden=$enableval],
 173               [hidden=yes])
 174 if test "x$hidden" = xno; then
 175   AC_DEFINE(NO_HIDDEN)
 176 fi
 177
 178 AC_ARG_ENABLE([bind-now],
 179               AC_HELP_STRING([--enable-bind-now],
 180                              [disable lazy relocations in DSOs]),
 181               [bindnow=$enableval],
 182               [bindnow=no])
 183 AC_SUBST(bindnow)
 184
 185 dnl On some platforms we cannot use dynamic loading.  We must provide
 186 dnl static NSS modules.
 187 AC_ARG_ENABLE([static-nss],
 188               AC_HELP_STRING([--enable-static-nss],
 189                              [build static NSS modules @<:@default=no@:>@]),
 190               [static_nss=$enableval],
 191               [static_nss=no])
 192 dnl Enable static NSS also if we build no shared objects.
 193 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 194   static_nss=yes
 195   AC_DEFINE(DO_STATIC_NSS)
 196 fi
 197
 198 AC_ARG_ENABLE([force-install],
 199               AC_HELP_STRING([--disable-force-install],
 200                              [don't force installation of files from this package, even if they are older than the installed files]),
 201               [force_install=$enableval],
 202               [force_install=yes])
 203 AC_SUBST(force_install)
 204
 205 dnl On some platforms we allow dropping compatibility with all kernel
 206 dnl versions.
 207 AC_ARG_ENABLE([kernel],
 208               AC_HELP_STRING([--enable-kernel=VERSION],
 209                              [compile for compatibility with kernel not older than VERSION]),
 210               [minimum_kernel=$enableval],
 211               [])
 212 dnl Prevent unreasonable values.
 213 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 214   # Better nothing than this.
 215   minimum_kernel=""
 216 else
 217   if test "$minimum_kernel" = current; then
 218     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 219   fi
 220 fi
 221
 222 dnl For the development we sometimes want gcc to issue even more warnings.
 223 dnl This is not the default since many of the extra warnings are not
 224 dnl appropriate.
 225 AC_ARG_ENABLE([all-warnings],
 226               AC_HELP_STRING([--enable-all-warnings],
 227                              [enable all useful warnings gcc can issue]),
 228               [all_warnings=$enableval],
 229               [])
 230 AC_SUBST(all_warnings)
 231
 232 AC_ARG_ENABLE([multi-arch],
 233               AC_HELP_STRING([--enable-multi-arch],
 234                              [enable single DSO with optimizations for multiple architectures]),
 235               [multi_arch=$enableval],
 236               [multi_arch=default])
 237
 238 AC_ARG_ENABLE([nss-crypt],
 239               AC_HELP_STRING([--enable-nss-crypt],
 240                              [enable libcrypt to use nss]),
 241               [nss_crypt=$enableval],
 242               [nss_crypt=no])
 243 if test x$nss_crypt = xyes; then
 244   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 245   if test $? -ne 0; then
 246     AC_MSG_ERROR([cannot find include directory with nss-config])
 247   fi
 248   old_CFLAGS="$CFLAGS"
 249   CFLAGS="$CFLAGS $nss_includes"
 250   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 251 #include <hasht.h>
 252 #include <nsslowhash.h>
 253 void f (void) { NSSLOW_Init (); }])],
 254              libc_cv_nss_crypt=yes,
 255              AC_MSG_ERROR([
 256 cannot find NSS headers with lowlevel hash function interfaces]))
 257   old_LIBS="$LIBS"
 258   LIBS="$LIBS -lfreebl3"
 259   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 260 #include <hasht.h>
 261 #include <nsslowhash.h>],
 262                                   [NSSLOW_Init();])],
 263                  libc_cv_nss_crypt=yes,
 264                  AC_MSG_ERROR([
 265 cannot link program using lowlevel NSS hash functions]))
 266   CFLAGS="$old_CFLAGS"
 267   LIBS="$old_LIBS"
 268 else
 269   libc_cv_nss_crypt=no
 270 fi
 271 AC_SUBST(libc_cv_nss_crypt)
 272
 273 # The way shlib-versions is used to generate soversions.mk uses a
 274 # fairly simplistic model for name recognition that can't distinguish
 275 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 276 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 277 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 278 case "$host_os" in
 279 linux*)
 280   ;;
 281 gnu*)
 282   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 283   ;;
 284 esac
 285
 286 # We keep the original values in `$config_*' and never modify them, so we
 287 # can write them unchanged into config.make.  Everything else uses
 288 # $machine, $vendor, and $os, and changes them whenever convenient.
 289 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 290
 291 # Don't allow vendor == "unknown"
 292 test "$config_vendor" = unknown && config_vendor=
 293 config_os="`echo $config_os | sed 's/^unknown-//'`"
 294
 295 # Some configurations imply other options.
 296 elf=yes
 297
 298 # The configure fragment of an add-on port can modify these to supplement
 299 # or override the table in the case statement below.  No fragment should
 300 # ever change the config_* variables, however.
 301 machine=$config_machine
 302 vendor=$config_vendor
 303 os=$config_os
 304 base_os=''
 305
 306 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
 307 # Unify this here.
 308 if test "$machine" = rs6000; then
 309   machine="powerpc"
 310 fi
 311
 312 # Braindead PowerPC box with absolutely no FPU.
 313 case "$machine-$host_os" in
 314   powerpc*-*soft)
 315     with_fp=no
 316     ;;
 317 esac
 318
 319 submachine=
 320 AC_ARG_WITH([cpu],
 321             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 322             [dnl
 323   case "$withval" in
 324   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 325   no) ;;
 326   *) submachine="$withval" ;;
 327   esac
 328 ])
 329
 330 # An add-on can set this when it wants to disable the sanity check below.
 331 libc_config_ok=no
 332
 333 dnl Having this here, though empty, makes sure that if add-ons' fragments
 334 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
 335 dnl our AC_OUTPUT will actually use it.
 336 AC_CONFIG_SUBDIRS()
 337
 338 case "$enable_add_ons" in
 339 ''|no) add_ons= ;;
 340 yes|'*')
 341  add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
 342           sed 's@/[[^/]]*$@@' | sort | uniq`
 343          add_ons_automatic=yes
 344          ;;
 345 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
 346        add_ons_automatic=no ;;
 347 esac
 348
 349 configured_add_ons=
 350 add_ons_sfx=
 351 add_ons_pfx=
 352 if test x"$add_ons" != x; then
 353   for f in $add_ons; do
 354     # Some sanity checks
 355     case "$f" in
 356     crypt)
 357       AC_MSG_ERROR([
 358 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 359 *** part of glibc and using the old add-on will not work with this
 360 *** release.  Start again with fresh sources and without the old
 361 *** \`crypt' add-on.])
 362     ;;
 363     localedata)
 364       AC_MSG_ERROR([
 365 *** It seems that you're using an old \`localedata' add-on.  localedata
 366 *** is now part of glibc and using the old add-on will not work with
 367 *** this release.  Start again with fresh sources and without the old
 368 *** \`localedata' add-on.])
 369     ;;
 370     esac
 371   done
 372
 373   # Now source each add-on's configure fragment.
 374   # The fragments can use $srcdir/$libc_add_on to find themselves,
 375   # and test $add_ons_automatic to see if they were explicitly requested.
 376   # A fragment can clear (or even change) $libc_add_on to affect
 377   # whether it goes into the list to be actually used in the build.
 378   use_add_ons=
 379   for libc_add_on in $add_ons; do
 380     # Test whether such a directory really exists.
 381     # It can be absolute, or relative to $srcdir, or relative to the build dir.
 382     case "$libc_add_on" in
 383     /*)
 384       libc_add_on_srcdir=$libc_add_on
 385       ;;
 386     *)
 387       test -d "$srcdir/$libc_add_on" || {
 388         if test -d "$libc_add_on"; then
 389           libc_add_on="`pwd`/$libc_add_on"
 390         else
 391           AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
 392         fi
 393       }
 394       libc_add_on_srcdir=$srcdir/$libc_add_on
 395       ;;
 396     esac
 397
 398     libc_add_on_frag=$libc_add_on_srcdir/configure
 399     libc_add_on_canonical=
 400     libc_add_on_config_subdirs=
 401     if test -r "$libc_add_on_frag"; then
 402       AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
 403       libc_add_on_canonical=unknown
 404       libc_add_on_subdirs=
 405       . "$libc_add_on_frag"
 406       test -z "$libc_add_on" || {
 407         configured_add_ons="$configured_add_ons $libc_add_on"
 408         if test "x$libc_add_on_canonical" = xunknown; then
 409           AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
 410         fi
 411         for d in $libc_add_on_subdirs; do
 412           case "$libc_add_on" in
 413           /*) subdir_srcdir="$libc_add_on" ;;
 414           *) subdir_srcdir="\$(..)$libc_add_on" ;;
 415           esac
 416           case "$d" in
 417           .)
 418             d="${libc_add_on_canonical:-$libc_add_on}"
 419             ;;
 420           /*)
 421             subdir_srcdir="$d"
 422             ;;
 423           *)
 424             subdir_srcdir="$subdir_srcdir/$d"
 425             ;;
 426           esac
 427           d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
 428           add_on_subdirs="$add_on_subdirs $d"
 429           test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
 430 $d-srcdir = $subdir_srcdir"
 431         done
 432         for d in $libc_add_on_config_subdirs; do
 433           case "$d" in
 434           /*) AC_MSG_ERROR(dnl
 435 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
 436           esac
 437           if test ! -d "$libc_add_on_srcdir/$d"; then
 438             AC_MSG_ERROR(fragment wants to configure missing directory $d)
 439           fi
 440           case "$libc_add_on" in
 441           /*) AC_MSG_ERROR(dnl
 442 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
 443           esac
 444           subdirs="$subdirs $libc_add_on/$d"
 445         done
 446       }
 447     fi
 448     if test -n "$libc_add_on"; then
 449       if frags=`ls -d $libc_add_on_srcdir/sysdeps/*/preconfigure 2> /dev/null`
 450       then
 451         AC_MSG_CHECKING(add-on $libc_add_on for preconfigure fragments)
 452         for frag in $frags; do
 453           name=`echo "$frag" | sed 's@/[[^/]]*$@@;s@^.*/@@'`
 454           echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 455           . "$frag"
 456         done
 457         AC_MSG_RESULT()
 458       fi
 459       use_add_ons="$use_add_ons $libc_add_on"
 460       add_ons_pfx="$add_ons_pfx $libc_add_on/"
 461       test -z "$libc_add_on_canonical" ||
 462       add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
 463     fi
 464   done
 465   # Use echo to strip excess whitespace.
 466   add_ons="`echo $use_add_ons`"
 467 fi
 468 AC_SUBST(add_ons)
 469 AC_SUBST(add_on_subdirs)
 470
 471
 472 ###
 473 ### I put this here to prevent those annoying emails from people who cannot
 474 ### read and try to compile glibc on unsupported platforms.  --drepper
 475 ###
 476 ### By using the undocumented --enable-hacker-mode option for configure
 477 ### one can skip this test to make the configuration not fail for unsupported
 478 ### platforms.
 479 ###
 480 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 481   case "$machine-$host_os" in
 482   *-linux* | *-gnu* | arm*-none*)
 483     ;;
 484   *)
 485     echo "*** The GNU C library is currently not available for this platform."
 486     echo "*** So far nobody cared to port it and if there is no volunteer it"
 487     echo "*** might never happen.  So, if you have interest to see glibc on"
 488     echo "*** this platform visit"
 489     echo "***   http://www.gnu.org/software/libc/porting.html"
 490     echo "*** and join the group of porters"
 491     exit 1
 492     ;;
 493   esac
 494 fi
 495
 496 dnl We need to use [ and ] for other purposes for a while now.
 497 changequote(,)dnl
 498 # Expand the configuration machine name into a subdirectory by architecture
 499 # type and particular chip.  If an add-on configure fragment already set
 500 # base_machine, we don't change it.
 501 test -n "$base_machine" || case "$machine" in
 502 i[34567]86)     base_machine=i386 machine=i386/$machine ;;
 503 powerpc)        base_machine=powerpc machine=powerpc/powerpc32 ;;
 504 powerpc64)      base_machine=powerpc machine=powerpc/powerpc64 ;;
 505 s390)           base_machine=s390 machine=s390/s390-32 ;;
 506 s390x)          base_machine=s390 machine=s390/s390-64 ;;
 507 sh3*)           base_machine=sh machine=sh/sh3 ;;
 508 sh4*)           base_machine=sh machine=sh/sh4 ;;
 509 sparc | sparcv[67])
 510                 base_machine=sparc machine=sparc/sparc32 ;;
 511 sparcv8 | supersparc | hypersparc)
 512                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 513 sparcv8plus | sparcv8plusa | sparcv9)
 514                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 515 sparcv8plusb | sparcv9b)
 516                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9b ;;
 517 sparcv9v)
 518                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v ;;
 519 sparcv9v2)
 520                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v2 ;;
 521 sparc64)
 522                 base_machine=sparc machine=sparc/sparc64 ;;
 523 sparc64b)
 524                 base_machine=sparc machine=sparc/sparc64/sparcv9b ;;
 525 sparc64v)
 526                 base_machine=sparc machine=sparc/sparc64/sparcv9v ;;
 527 sparc64v2)
 528                 base_machine=sparc machine=sparc/sparc64/sparcv9v2 ;;
 529 *)              base_machine=$machine ;;
 530 esac
 531 changequote([,])dnl
 532 AC_SUBST(base_machine)
 533
 534 if test "$base_machine" = "i386"; then
 535   AC_DEFINE(USE_REGPARMS)
 536 fi
 537
 538 # For the multi-arch option we need support in the assembler.
 539 AC_CACHE_CHECK([for assembler gnu_indirect_function symbol type support],
 540                libc_cv_asm_gnu_indirect_function, [dnl
 541 cat > conftest.s <<EOF
 542 .type foo,%gnu_indirect_function
 543 EOF
 544 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD;
 545 then
 546   libc_cv_asm_gnu_indirect_function=yes
 547 else
 548   libc_cv_asm_gnu_indirect_function=no
 549 fi
 550 rm -f conftest*])
 551
 552 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 553 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 554 cat > conftest.s <<EOF
 555 .text
 556 EOF
 557 libc_cv_dot_text=
 558 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 559   libc_cv_dot_text=.text
 560 fi
 561 rm -f conftest*])
 562 if test -z "$libc_cv_dot_text"; then
 563   AC_MSG_RESULT(no)
 564 else
 565   AC_MSG_RESULT(yes)
 566 fi
 567
 568 AC_CACHE_CHECK(for assembler global-symbol directive,
 569                libc_cv_asm_global_directive, [dnl
 570 libc_cv_asm_global_directive=UNKNOWN
 571 for ac_globl in .globl .global .EXPORT; do
 572   cat > conftest.s <<EOF
 573         ${libc_cv_dot_text}
 574         ${ac_globl} foo
 575 foo:
 576 EOF
 577   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 578     libc_cv_asm_global_directive=${ac_globl}
 579   fi
 580   rm -f conftest*
 581   test $libc_cv_asm_global_directive != UNKNOWN && break
 582 done])
 583 if test $libc_cv_asm_global_directive = UNKNOWN; then
 584   AC_MSG_ERROR(cannot determine asm global directive)
 585 else
 586   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 587 fi
 588
 589 AC_CACHE_CHECK(for assembler .type directive prefix,
 590                libc_cv_asm_type_prefix, [dnl
 591 libc_cv_asm_type_prefix=no
 592 for ac_try_prefix in '@' '%' '#'; do
 593   cat > conftest.s <<EOF
 594         ${libc_cv_dot_text}
 595         ${libc_cv_asm_global_directive} foo
 596         .type foo, ${ac_try_prefix}object
 597         .size foo, 1
 598 foo:
 599         .byte 1
 600 EOF
 601   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 602     libc_cv_asm_type_prefix=${ac_try_prefix}
 603   fi
 604   rm -f conftest*
 605   test "x$libc_cv_asm_type_prefix" != xno && break
 606 done])
 607 if test "x$libc_cv_asm_type_prefix" != xno; then
 608   AC_DEFINE_UNQUOTED(ASM_TYPE_DIRECTIVE_PREFIX, ${libc_cv_asm_type_prefix})
 609 fi
 610
 611 if test x"$libc_cv_asm_gnu_indirect_function" != xyes -a x"$libc_cv_asm_type_prefix" = xno; then
 612   if test x"$multi_arch" = xyes; then
 613     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 614   else
 615     multi_arch=no
 616   fi
 617 fi
 618 if test x"$multi_arch" != xno; then
 619   multi_arch_d=/multiarch
 620 fi
 621
 622 # Compute the list of sysdep directories for this configuration.
 623 # This can take a while to compute.
 624 sysdep_dir=$srcdir/sysdeps
 625 AC_MSG_CHECKING(sysdep dirs)
 626 dnl We need to use [ and ] for other purposes for a while now.
 627 changequote(,)dnl
 628 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 629 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 630
 631 test "x$base_os" != x || case "$os" in
 632 gnu*)
 633   base_os=mach/hurd ;;
 634 netbsd* | 386bsd* | freebsd* | bsdi*)
 635   base_os=unix/bsd/bsd4.4 ;;
 636 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 637   base_os=unix/bsd ;;
 638 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 639   base_os=unix/sysv ;;
 640 irix6*)
 641   base_os=unix/sysv/irix6/$os ;;
 642 solaris[2-9]*)
 643   base_os=unix/sysv/sysv4 ;;
 644 none)
 645   base_os=standalone ;;
 646 esac
 647
 648 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 649 tail=$os
 650 ostry=$os
 651 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 652   ostry="$ostry /$o"
 653   tail=$o
 654 done
 655 o=`echo $tail | sed 's/[0-9]*$//'`
 656 if test $o != $tail; then
 657   ostry="$ostry /$o"
 658 fi
 659 # For linux-gnu, try linux-gnu, then linux.
 660 o=`echo $tail | sed 's/-.*$//'`
 661 if test $o != $tail; then
 662   ostry="$ostry /$o"
 663 fi
 664
 665 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 666 base=
 667 tail=$base_os
 668 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 669   set $b
 670   base="$base /$1"
 671   tail="$2"
 672 done
 673
 674 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 675 mach=
 676 tail=$machine${submachine:+/$submachine}
 677 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 678   set $m
 679   # Prepend the machine's FPU directory unless --without-fp.
 680   if test "$with_fp" = yes; then
 681     mach="$mach /$1/fpu"
 682   else
 683     mach="$mach /$1/nofpu"
 684   fi
 685   mach="$mach /$1"
 686   tail="$2"
 687 done
 688
 689 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 690 changequote([,])dnl
 691
 692 # Find what sysdep directories exist.
 693 sysnames_add_ons=
 694 sysnames=
 695 for b in $base ''; do
 696   for m0 in $mach ''; do
 697     for v in /$vendor ''; do
 698       test "$v" = / && continue
 699       for o in /$ostry ''; do
 700         test "$o" = / && continue
 701         for m in $multi_arch_d $mach ''; do
 702           for d in $add_ons_pfx ''; do
 703             for a in $add_ons_sfx ''; do
 704               if test -n "$m0$m0sub$b$v$o$m$msub"; then
 705                 try_srcdir="${srcdir}/"
 706                 case "$d" in
 707                 /*) try_srcdir= ;;
 708                 esac
 709                 try="${d}sysdeps$m0$m0sub$b$v$o$m$msub$a"
 710                 test -n "$enable_debug_configure" &&
 711                 echo "$0 [DEBUG]: try $try" >&2
 712                 if test -d "$try_srcdir$try"; then
 713                   sysnames="$sysnames $try"
 714                   { test -n "$o" || test -n "$b"; } && os_used=t
 715                   { test -n "$m" || test -n "$m0"; } && machine_used=t
 716                   case x${m0:-$m} in
 717                   x*/$submachine) submachine_used=t ;;
 718                   esac
 719                   if test -n "$d"; then
 720                     case "$sysnames_add_ons" in
 721                     *" $d "*) ;;
 722                     *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 723                     esac
 724                   fi
 725                 fi
 726               fi
 727             done
 728           done
 729         done
 730       done
 731     done
 732   done
 733 done
 734
 735 # If the assembler supports gnu_indirect_function symbol type and the
 736 # architecture supports multi-arch, we enable multi-arch by default.
 737 case $sysnames_add_ons$sysnames in
 738 *"$multi_arch_d"*)
 739   ;;
 740 *)
 741   test x"$multi_arch" = xdefault && multi_arch=no
 742   ;;
 743 esac
 744 if test x"$multi_arch" != xno; then
 745   AC_DEFINE(USE_MULTIARCH)
 746 fi
 747 AC_SUBST(multi_arch)
 748
 749 if test -z "$os_used" && test "$os" != none; then
 750   AC_MSG_ERROR(Operating system $os is not supported.)
 751 fi
 752 if test -z "$machine_used" && test "$machine" != none; then
 753   AC_MSG_ERROR(The $machine is not supported.)
 754 fi
 755 if test -z "$submachine_used" && test -n "$submachine"; then
 756   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 757 fi
 758 AC_SUBST(submachine)
 759
 760 # We have now validated the configuration.
 761
 762
 763 # Look for an `elf' subdirectory of each machine directory.
 764 # We prepend these rather than inserting them whereever the machine appears
 765 # because things specified by the machine's ELF ABI should override
 766 # OS-specific things, and should always be the same for any OS on the
 767 # machine (otherwise what's the point of an ABI?).
 768 elf_dirs=
 769 for d in $add_ons_pfx ''; do
 770   for m in $mach; do
 771     if test -d $srcdir/${d}sysdeps$m/elf; then
 772       elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 773     fi
 774   done
 775 done
 776 sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 777
 778
 779 # Expand the list of system names into a full list of directories
 780 # from each element's parent name and Implies file (if present).
 781 set $sysnames
 782 names=
 783 while test $# -gt 0; do
 784   name=$1
 785   shift
 786
 787   case " $names " in *" $name "*)
 788     # Already in the list.
 789     continue
 790   esac
 791
 792   # Report each name as we discover it, so there is no long pause in output.
 793   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 794
 795   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 796
 797   case $name in
 798     /*) xsrcdir= ;;
 799     *)  xsrcdir=$srcdir/ ;;
 800   esac
 801   test -n "$enable_debug_configure" &&
 802   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 803
 804   if test -f $xsrcdir$name/Implies; then
 805     # Collect more names from the `Implies' file (removing comments).
 806     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 807     implied=
 808     for x in $implied_candidate; do
 809       found=no
 810       if test -d $xsrcdir$name_base/$x; then
 811         implied="$implied $name_base/$x";
 812         found=yes
 813       fi
 814       for d in $add_ons_pfx ''; do
 815         try="${d}sysdeps/$x"
 816         case $d in
 817          /*) try_srcdir= ;;
 818          *) try_srcdir=$srcdir/ ;;
 819         esac
 820         test -n "$enable_debug_configure" &&
 821          echo "[DEBUG]: $name implied $x try($d) {$try_srcdir}$try" >&2
 822         if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 823         then
 824           implied="$implied $try"
 825           found=yes
 826           case "$sysnames_add_ons" in
 827           *" $d "*) ;;
 828           *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 829           esac
 830         fi
 831       done
 832       if test $found = no; then
 833         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 834       fi
 835     done
 836   else
 837     implied=
 838   fi
 839
 840   # Add NAME to the list of names.
 841   names="$names $name"
 842
 843   # Find the parent of NAME, using the empty string if it has none.
 844 changequote(,)dnl
 845   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 846 changequote([,])dnl
 847
 848   # Add the names implied by NAME, and NAME's parent (if it has one), to
 849   # the list of names to be processed (the argument list).  We prepend the
 850   # implied names to the list and append the parent.  We want implied
 851   # directories to come before further directories inferred from the
 852   # configuration components; this ensures that for sysv4, unix/common
 853   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 854   # after sysv4).
 855   sysnames="`echo $implied $* $parent`"
 856   test -n "$sysnames" && set $sysnames
 857 done
 858
 859 # Add the default directories.
 860 default_sysnames="sysdeps/generic/elf sysdeps/generic"
 861 sysnames="$names $default_sysnames"
 862 AC_SUBST(sysnames)
 863 # The other names were emitted during the scan.
 864 AC_MSG_RESULT($default_sysnames)
 865
 866 # Collect the list of add-ons that supply partial sysdeps trees.
 867 sysdeps_add_ons=
 868 for add_on in $add_ons; do
 869   case "$add_on" in
 870   /*) xsrcdir= ;;
 871   *) xsrcdir="$srcdir/" ;;
 872   esac
 873
 874   test -d "$xsrcdir$add_on/sysdeps" || {
 875     case "$configured_add_ons " in
 876     *" $add_on "*) ;;
 877     *|'')
 878       AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
 879       ;;
 880     esac
 881     continue
 882   }
 883
 884   sysdeps_add_ons="$sysdeps_add_ons $add_on"
 885   case "$sysnames_add_ons" in
 886   *" $add_on/ "*) ;;
 887   *|'')
 888     AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
 889     continue ;;
 890   esac
 891
 892   found=no
 893   for d in $sysnames; do
 894     case "$d" in
 895     $add_on/sysdeps/*) ;;
 896     *) continue ;;
 897     esac
 898     (cd "$xsrcdir$d" && for f in *[[!~]]; do
 899        case "$f" in
 900        sys|bits)
 901          for ff in $f/*.h; do
 902            test -d "$ff" || { test -e "$ff" && exit 88; }
 903          done
 904          ;;
 905        *)
 906          test -d "$f" || { test -e "$f" && exit 88; }
 907          ;;
 908        esac
 909      done)
 910     if test $? -eq 88; then
 911       found=yes
 912       break
 913     fi
 914   done
 915   if test $found = no; then
 916     AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
 917   fi
 918 done
 919 AC_SUBST(sysdeps_add_ons)
 920
 921
 922 ### Locate tools.
 923
 924 AC_PROG_INSTALL
 925 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 926   # The makefiles need to use a different form to find it in $srcdir.
 927   INSTALL='\$(..)./scripts/install-sh -c'
 928 fi
 929 AC_PROG_LN_S
 930
 931 LIBC_PROG_BINUTILS
 932 AC_SUBST(MIG)dnl Needed by sysdeps/mach/configure.in
 933
 934 # Accept binutils 2.13 or newer.
 935 AC_CHECK_PROG_VER(AS, $AS, --version,
 936                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 937                   [2.1[3-9]*|2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], AS=: critic_missing="$critic_missing as")
 938 AC_CHECK_PROG_VER(LD, $LD, --version,
 939                   [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 940                   [2.1[3-9]*|2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], LD=: critic_missing="$critic_missing ld")
 941
 942 # We need the physical current working directory.  We cannot use the
 943 # "pwd -P" shell builtin since that's not portable.  Instead we try to
 944 # find a pwd binary.  Note that assigning to the PWD environment
 945 # variable might have some interesting side effects, so we don't do
 946 # that.
 947 AC_PATH_PROG(PWD_P, pwd, no)
 948 if test "$PWD_P" = no; then
 949   AC_MSG_ERROR(*** A pwd binary could not be found.)
 950 fi
 951
 952 # These programs are version sensitive.
 953 AC_CHECK_TOOL_PREFIX
 954 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 955   [version \([egcygnustpi-]*[0-9.]*\)], [3.4* | 4.[0-9]* ],
 956   critic_missing="$critic_missing gcc")
 957 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 958   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 959   [3.79* | 3.[89]*], critic_missing="$critic_missing make")
 960
 961 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 962   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 963   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 964   MSGFMT=: aux_missing="$aux_missing msgfmt")
 965 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 966   [GNU texinfo.* \([0-9][0-9.]*\)],
 967   [4.*],
 968   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 969 AC_CHECK_PROG_VER(SED, sed, --version,
 970   [GNU sed version \([0-9]*\.[0-9.]*\)],
 971   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 972   SED=: aux_missing="$aux_missing sed")
 973
 974 AC_CHECK_TOOL(READELF, readelf, false)
 975
 976 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
 977 case "x$AUTOCONF" in
 978 xno|x|x:) AUTOCONF=no ;;
 979 *)
 980   AC_CACHE_CHECK(dnl
 981 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
 982   if (cd $srcdir; $AUTOCONF $ACFLAGS configure.in > /dev/null 2>&1); then
 983     libc_cv_autoconf_works=yes
 984   else
 985     libc_cv_autoconf_works=no
 986   fi])
 987   test $libc_cv_autoconf_works = yes || AUTOCONF=no
 988   ;;
 989 esac
 990 if test "x$AUTOCONF" = xno; then
 991   aux_missing="$aux_missing autoconf"
 992 fi
 993
 994 test -n "$critic_missing" && AC_MSG_ERROR([
 995 *** These critical programs are missing or too old:$critic_missing
 996 *** Check the INSTALL file for required versions.])
 997
 998 test -n "$aux_missing" && AC_MSG_WARN([
 999 *** These auxiliary programs are missing or incompatible versions:$aux_missing
1000 *** some features will be disabled.
1001 *** Check the INSTALL file for required versions.])
1002
1003 # if using special system headers, find out the compiler's sekrit
1004 # header directory and add that to the list.  NOTE: Only does the right
1005 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
1006 if test -n "$sysheaders"; then
1007   SYSINCLUDES=-nostdinc
1008   for d in include include-fixed; do
1009     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1010     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1011   done
1012   SYSINCLUDES="$SYSINCLUDES \
1013 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1014   if test -n "$CXX"; then
1015     CXX_SYSINCLUDES=
1016     cxxversion=`$CXX -dumpversion 2>&AS_MESSAGE_LOG_FD` &&
1017     cxxmachine=`$CXX -dumpmachine 2>&AS_MESSAGE_LOG_FD` &&
1018     for d in include "$cxxmachine/include"; do
1019       i=../../../../$d/c++/$cxxversion
1020       cxxheaders=`$CXX -print-file-name="$i"` &&
1021       test "x$cxxheaders" != x && test "x$i" != "x$cxxheaders" &&
1022       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders \
1023 -isystem $cxxheaders/$cxxmachine -isystem $cxxheaders/backward"
1024     done
1025   fi
1026 fi
1027 AC_SUBST(SYSINCLUDES)
1028 AC_SUBST(CXX_SYSINCLUDES)
1029
1030 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1031 # since this would lead to problems installing/building glibc.
1032 # LD_LIBRARY_PATH contains the current directory if one of the following
1033 # is true:
1034 # - one of the terminals (":" and ";") is the first or last sign
1035 # - two terminals occur directly after each other
1036 # - the path contains an element with a dot in it
1037 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1038 changequote(,)dnl
1039 case ${LD_LIBRARY_PATH} in
1040   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1041     ld_library_path_setting="contains current directory"
1042     ;;
1043   *)
1044     ld_library_path_setting="ok"
1045     ;;
1046 esac
1047 changequote([,])dnl
1048 AC_MSG_RESULT($ld_library_path_setting)
1049 if test "$ld_library_path_setting" != "ok"; then
1050 AC_MSG_ERROR([
1051 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1052 *** building glibc. Please change the environment variable
1053 *** and run configure again.])
1054 fi
1055
1056 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1057 if $CC -v -static-libgcc 2>&1 | grep -q 'unrecognized option.*static-libgcc'; then
1058   libc_cv_gcc_static_libgcc=
1059 else
1060   libc_cv_gcc_static_libgcc=-static-libgcc
1061 fi])
1062 AC_SUBST(libc_cv_gcc_static_libgcc)
1063
1064 AC_PATH_PROG(BASH_SHELL, bash, no)
1065 if test "$BASH_SHELL" != no &&
1066    $BASH_SHELL -c 'test "$BASH_VERSINFO" \
1067              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
1068   libc_cv_have_bash2=yes
1069 else
1070   libc_cv_have_bash2=no
1071 fi
1072 AC_SUBST(libc_cv_have_bash2)
1073
1074 dnl We need a ksh compatible shell for tzselect.
1075 if test "$BASH_SHELL" = no; then
1076   AC_PATH_PROG(KSH, ksh, no)
1077   if test "$KSH" = no; then
1078     libc_cv_have_ksh=no
1079   else
1080     libc_cv_have_ksh=yes
1081   fi
1082 else
1083   KSH="$BASH_SHELL"
1084   AC_SUBST(KSH)
1085   libc_cv_have_ksh=yes
1086 fi
1087 AC_SUBST(libc_cv_have_ksh)
1088
1089 AC_PROG_AWK
1090 AC_PATH_PROG(PERL, perl, no)
1091 if test "$PERL" != no &&
1092    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1093   PERL=no
1094 fi
1095 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1096              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1097 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
1098
1099 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
1100 echo '#include <stddef.h>
1101 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
1102 if eval "$ac_cpp conftest.c 2>/dev/null" \
1103 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
1104   libc_cv_signed_size_t=no
1105 else
1106   libc_cv_signed_size_t=yes
1107 fi
1108 rm -f conftest*])
1109 if test $libc_cv_signed_size_t = yes; then
1110   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
1111   cat >> confdefs.h <<\EOF
1112 #undef __SIZE_TYPE__
1113 #define __SIZE_TYPE__ unsigned
1114 EOF
1115 fi
1116
1117 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1118 AC_TRY_COMPILE(dnl
1119 [#define __need_size_t
1120 #define __need_wchar_t
1121 #include <stddef.h>
1122 #define __need_NULL
1123 #include <stddef.h>], [size_t size; wchar_t wchar;
1124 #ifdef offsetof
1125 #error stddef.h ignored __need_*
1126 #endif
1127 if (&size == NULL || &wchar == NULL) abort ();],
1128                libc_cv_friendly_stddef=yes,
1129                libc_cv_friendly_stddef=no)])
1130 if test $libc_cv_friendly_stddef = yes; then
1131   config_vars="$config_vars
1132 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1133 fi
1134
1135 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1136                libc_cv_need_minus_P, [dnl
1137 cat > conftest.S <<EOF
1138 #include "confdefs.h"
1139 /* Nothing whatsoever.  */
1140 EOF
1141 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1142   libc_cv_need_minus_P=no
1143 else
1144   libc_cv_need_minus_P=yes
1145 fi
1146 rm -f conftest*])
1147 if test $libc_cv_need_minus_P = yes; then
1148   config_vars="$config_vars
1149 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1150 fi
1151
1152 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1153 cat > conftest.s <<EOF
1154 ${libc_cv_dot_text}
1155 foo:
1156 .set glibc_conftest_frobozz,foo
1157 $libc_cv_asm_global_directive glibc_conftest_frobozz
1158 EOF
1159 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1160 # (but it doesn't work), so we must do a linking check to be sure.
1161 cat > conftest1.c <<\EOF
1162 extern int glibc_conftest_frobozz;
1163 void _start() { glibc_conftest_frobozz = 1; }
1164 EOF
1165 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1166             -nostartfiles -nostdlib \
1167             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1168   libc_cv_asm_set_directive=yes
1169 else
1170   libc_cv_asm_set_directive=no
1171 fi
1172 rm -f conftest*])
1173 if test $libc_cv_asm_set_directive = yes; then
1174   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1175 fi
1176
1177 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1178                libc_cv_asm_unique_object, [dnl
1179 cat > conftest.s <<EOF
1180 ${libc_cv_dot_text}
1181 _sym:
1182 .type _sym, ${libc_cv_asm_type_prefix}gnu_unique_object
1183 EOF
1184 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1185   libc_cv_asm_unique_object=yes
1186 else
1187   libc_cv_asm_unique_object=no
1188 fi
1189 rm -f conftest*])
1190 if test $libc_cv_asm_unique_object = yes; then
1191   AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1192 fi
1193
1194 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
1195 [cat > conftest.s <<EOF
1196 ${libc_cv_dot_text}
1197 _sym:
1198 .symver _sym,sym@VERS
1199 EOF
1200 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1201   libc_cv_asm_symver_directive=yes
1202 else
1203   libc_cv_asm_symver_directive=no
1204 fi
1205 rm -f conftest*])
1206 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
1207 if test $libc_cv_asm_symver_directive = yes; then
1208   cat > conftest.s <<EOF
1209 ${libc_cv_dot_text}
1210 _sym:
1211 .symver _sym,sym@VERS
1212 EOF
1213   cat > conftest.map <<EOF
1214 VERS_1 {
1215         global: sym;
1216 };
1217
1218 VERS_2 {
1219         global: sym;
1220 } VERS_1;
1221 EOF
1222   if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1223     if AC_TRY_COMMAND([${CC-cc} $CFLAGS $LDFLAGS -shared
1224                                 -o conftest.so conftest.o
1225                                 -nostartfiles -nostdlib
1226                                 -Wl,--version-script,conftest.map
1227                        1>&AS_MESSAGE_LOG_FD]);
1228     then
1229       libc_cv_ld_version_script_option=yes
1230     else
1231       libc_cv_ld_version_script_option=no
1232     fi
1233   else
1234     libc_cv_ld_version_script_option=no
1235   fi
1236 else
1237   libc_cv_ld_version_script_option=no
1238 fi
1239 rm -f conftest*])
1240 if test $shared != no &&
1241    test $libc_cv_asm_symver_directive = yes &&
1242    test $libc_cv_ld_version_script_option = yes &&
1243    test $enable_versioning = yes; then
1244   VERSIONING=yes
1245   AC_DEFINE(DO_VERSIONING)
1246 else
1247   VERSIONING=no
1248 fi
1249 AC_SUBST(VERSIONING)
1250
1251 if test $shared != no && test $VERSIONING = no; then
1252   echo "\
1253 *** WARNING: You should not compile GNU libc without versioning. Not using
1254 *** versioning will introduce incompatibilities so that old binaries
1255 *** will not run anymore.
1256 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
1257 fi
1258 AC_CACHE_CHECK(for .previous assembler directive,
1259                libc_cv_asm_previous_directive, [dnl
1260 cat > conftest.s <<EOF
1261 .section foo_section
1262 .previous
1263 EOF
1264 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1265   libc_cv_asm_previous_directive=yes
1266 else
1267   libc_cv_asm_previous_directive=no
1268 fi
1269 rm -f conftest*])
1270 if test $libc_cv_asm_previous_directive = yes; then
1271   AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1272 else
1273   AC_CACHE_CHECK(for .popsection assembler directive,
1274                  libc_cv_asm_popsection_directive, [dnl
1275   cat > conftest.s <<EOF
1276 .pushsection foo_section
1277 .popsection
1278 EOF
1279   if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1280     libc_cv_asm_popsection_directive=yes
1281   else
1282     libc_cv_asm_popsection_directive=no
1283   fi
1284   rm -f conftest*])
1285   if test $libc_cv_asm_popsection_directive = yes; then
1286     AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1287   fi
1288 fi
1289 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1290                libc_cv_asm_protected_directive, [dnl
1291 cat > conftest.s <<EOF
1292 .protected foo
1293 foo:
1294 .hidden bar
1295 bar:
1296 EOF
1297 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1298   libc_cv_asm_protected_directive=yes
1299 else
1300   AC_MSG_ERROR(assembler support for symbol visibility is required)
1301 fi
1302 rm -f conftest*])
1303
1304 if test $libc_cv_asm_protected_directive = yes; then
1305   AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1306                  libc_cv_visibility_attribute,
1307                  [cat > conftest.c <<EOF
1308                   int foo __attribute__ ((visibility ("hidden"))) = 1;
1309                   int bar __attribute__ ((visibility ("protected"))) = 1;
1310 EOF
1311                   libc_cv_visibility_attribute=no
1312                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1313                     if grep '\.hidden.*foo' conftest.s >/dev/null; then
1314                       if grep '\.protected.*bar' conftest.s >/dev/null; then
1315                         libc_cv_visibility_attribute=yes
1316                       fi
1317                     fi
1318                   fi
1319                   rm -f conftest.{c,s}
1320                  ])
1321   if test $libc_cv_visibility_attribute != yes; then
1322     AC_MSG_ERROR(compiler support for visibility attribute is required)
1323   fi
1324 fi
1325
1326 if test $libc_cv_visibility_attribute = yes; then
1327   AC_CACHE_CHECK(for broken __attribute__((visibility())),
1328                  libc_cv_broken_visibility_attribute,
1329                  [cat > conftest.c <<EOF
1330                   int foo (int x);
1331                   int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1332                   int bar (int x) { return x; }
1333 EOF
1334                   libc_cv_broken_visibility_attribute=yes
1335                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1336 changequote(,)dnl
1337                     if grep '\.hidden[  _]foo' conftest.s >/dev/null; then
1338 changequote([,])dnl
1339                       libc_cv_broken_visibility_attribute=no
1340                     fi
1341                   fi
1342                   rm -f conftest.c conftest.s
1343                  ])
1344   if test $libc_cv_broken_visibility_attribute = yes; then
1345     AC_MSG_ERROR(working compiler support for visibility attribute is required)
1346   fi
1347 fi
1348
1349 AC_CACHE_CHECK(for broken __attribute__((alias())),
1350                libc_cv_broken_alias_attribute,
1351                [cat > conftest.c <<EOF
1352                extern int foo (int x) __asm ("xyzzy");
1353                int bar (int x) { return x; }
1354                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1355                extern int dfoo;
1356                extern __typeof (dfoo) dfoo __asm ("abccb");
1357                int dfoo = 1;
1358 EOF
1359                libc_cv_broken_alias_attribute=yes
1360                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1361                  if grep 'xyzzy' conftest.s >/dev/null &&
1362                     grep 'abccb' conftest.s >/dev/null; then
1363                    libc_cv_broken_alias_attribute=no
1364                  fi
1365                fi
1366                rm -f conftest.c conftest.s
1367                ])
1368 if test $libc_cv_broken_alias_attribute = yes; then
1369   AC_MSG_ERROR(working alias attribute support required)
1370 fi
1371
1372 if test $libc_cv_visibility_attribute = yes; then
1373   AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1374                  libc_cv_have_sdata_section,
1375                  [echo "int i;" > conftest.c
1376                   libc_cv_have_sdata_section=no
1377                   if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1378                      | grep '\.sdata' >/dev/null; then
1379                     libc_cv_have_sdata_section=yes
1380                   fi
1381                   rm -f conftest.c conftest.so
1382                  ])
1383   if test $libc_cv_have_sdata_section = yes; then
1384     AC_DEFINE(HAVE_SDATA_SECTION)
1385   fi
1386 fi
1387
1388 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1389                libc_cv_initfini_array, [dnl
1390 cat > conftest.c <<EOF
1391 int _start (void) { return 0; }
1392 int __start (void) { return 0; }
1393 int foo (void) { return 1; }
1394 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1395 EOF
1396 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -o conftest conftest.c
1397                    -static -nostartfiles -nostdlib 1>&AS_MESSAGE_LOG_FD])
1398 then
1399   if $READELF -S conftest | fgrep INIT_ARRAY > /dev/null; then
1400     libc_cv_initfini_array=yes
1401   else
1402     libc_cv_initfini_array=no
1403   fi
1404 else
1405   libc_cv_initfini_array=no
1406 fi
1407 rm -f conftest*])
1408 if test $libc_cv_initfini_array != yes; then
1409   AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1410 fi
1411
1412 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1413                libc_cv_ctors_header, [dnl
1414   libc_cv_ctors_header=yes
1415   AC_TRY_LINK([], [
1416 __attribute__ ((constructor)) void ctor (void) { puts("ctor"); }
1417 __attribute__ ((destructor))  void dtor (void) { puts("dtor"); }
1418 ],
1419               [dnl
1420       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1421         { gsub(/\@<:@ */, "@<:@") }
1422         $2 == ".ctors" || $2 == ".dtors" {
1423           size = strtonum("0x" $6)
1424           align = strtonum("0x" $NF)
1425           seen@<:@$2@:>@ = 1
1426           stub@<:@$2@:>@ = size == align * 2
1427         }
1428         END {
1429           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1430           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1431           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1432         }
1433       '], [libc_cv_ctors_header=no])
1434     ], [dnl
1435       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1436     ])
1437 ])
1438 if test $libc_cv_ctors_header = no; then
1439   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1440 fi
1441
1442 AC_CACHE_CHECK(for libunwind-support in compiler,
1443                libc_cv_cc_with_libunwind, [
1444   cat > conftest.c <<EOF
1445 int main (void) { return 0; }
1446 EOF
1447   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1448      conftest.c -v 2>&1 >/dev/null | grep -q " -lunwind "; then
1449     libc_cv_cc_with_libunwind=yes
1450   else
1451     libc_cv_cc_with_libunwind=no
1452   fi
1453   rm -f conftest*])
1454 AC_SUBST(libc_cv_cc_with_libunwind)
1455 if test $libc_cv_cc_with_libunwind = yes; then
1456   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1457 fi
1458
1459 AC_CACHE_CHECK(for -z nodelete option,
1460                libc_cv_z_nodelete, [dnl
1461 cat > conftest.c <<EOF
1462 int _start (void) { return 42; }
1463 EOF
1464 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1465                    -fPIC -shared -o conftest.so conftest.c
1466                    -nostartfiles -nostdlib
1467                    -Wl,--enable-new-dtags,-z,nodelete 1>&AS_MESSAGE_LOG_FD])
1468 then
1469   libc_cv_z_nodelete=yes
1470 else
1471   AC_MSG_ERROR(linker with -z nodelete support required)
1472 fi
1473 rm -f conftest*])
1474
1475 AC_CACHE_CHECK(for -z nodlopen option,
1476                libc_cv_z_nodlopen, [dnl
1477 cat > conftest.c <<EOF
1478 int _start (void) { return 42; }
1479 EOF
1480 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1481                         -fPIC -shared -o conftest.so conftest.c
1482                         -nostartfiles -nostdlib
1483                         -Wl,--enable-new-dtags,-z,nodlopen 1>&AS_MESSAGE_LOG_FD])
1484 then
1485   libc_cv_z_nodlopen=yes
1486 else
1487   AC_MSG_ERROR(linker with -z nodlopen support required)
1488 fi
1489 rm -f conftest*])
1490
1491 AC_CACHE_CHECK(for -z initfirst option,
1492                libc_cv_z_initfirst, [dnl
1493 cat > conftest.c <<EOF
1494 int _start (void) { return 42; }
1495 EOF
1496 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1497                         -fPIC -shared -o conftest.so conftest.c
1498                         -nostartfiles -nostdlib
1499                         -Wl,--enable-new-dtags,-z,initfirst 1>&AS_MESSAGE_LOG_FD])
1500 then
1501   libc_cv_z_initfirst=yes
1502 else
1503   AC_MSG_ERROR(linker with -z initfirst support required)
1504 fi
1505 rm -f conftest*])
1506
1507 # Add-on fragments can set these for other machines.
1508 libc_commonpagesize=${libc_commonpagesize:-no}
1509 libc_relro_required=${libc_relro_required:-no}
1510 case "$base_machine" in
1511   i[[34567]]86 | x86_64 | powerpc* | s390*)
1512     libc_commonpagesize=0x1000
1513     libc_relro_required=yes
1514     ;;
1515   sparc*)
1516     libc_commonpagesize=0x2000
1517     libc_relro_required=yes
1518     ;;
1519   ia64*)
1520     libc_commonpagesize=0x4000
1521     ;;
1522   alpha*)
1523     libc_commonpagesize=0x10000
1524     libc_relro_required=yes
1525     ;;
1526 esac
1527
1528 if test $libc_commonpagesize != no; then
1529   AC_CACHE_CHECK(for -z relro option,
1530                  libc_cv_z_relro, [dnl
1531   libc_cv_z_relro=no
1532   AC_LANG_CONFTEST([AC_LANG_SOURCE([[
1533 int _start (void) { return 42; }
1534 extern void _exit (int);
1535 /* Since these pointers are const, they should go in rodata.
1536    Since they refer to functions that have to be resolved by
1537    dynamic linking, they should instead go in RELRO data.  */
1538 const void *const relro[] = { &_start, &_exit, 0 };
1539 /* GNU ld fails to produce RELRO data when it's very small and there is no
1540    normal writable data following it, or if only uninitialized (.bss) data
1541    follows it, or only very small writable data.  */
1542 int data[0x10000] = { 1, };
1543 ]])])
1544   cat > conftest.awk <<\EOF
1545 BEGIN {
1546   result = "no"
1547   commonpagesize = strtonum(commonpagesize)
1548 }
1549 { print "LINE:", $0 > "/dev/stderr" }
1550 $1 == "GNU_RELRO" {
1551   vaddr = strtonum($3)
1552   memsz = strtonum($6)
1553   end = vaddr + memsz
1554   printf "vaddr %#x memsz %#x end %#x commonpagesize %#x\n", \
1555     vaddr, memsz, end, commonpagesize > "/dev/stderr"
1556   result = (end % commonpagesize == 0) ? "yes" : "broken"
1557 }
1558 END { print result }
1559 EOF
1560   AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1561                     -fPIC -shared -o conftest.so conftest.c
1562                     -nostartfiles -nostdlib
1563                     -Wl,-z,relro 1>&AS_MESSAGE_LOG_FD]) &&
1564   AC_TRY_COMMAND([$READELF -Wl conftest.so > conftest.ph]) &&
1565   AC_TRY_COMMAND([
1566       $AWK -v commonpagesize=$libc_commonpagesize -f conftest.awk
1567            conftest.ph > conftest.cps
1568     ]) &&
1569   libc_cv_z_relro=`cat conftest.cps 2>&AS_MESSAGE_LOG_FD`
1570   rm -f conftest*])
1571   if { test "x$libc_relro_required" = xyes &&
1572        test "x$libc_cv_z_relro" != xyes
1573      }
1574   then
1575     AC_MSG_ERROR(linker with -z relro support required)
1576   fi
1577 else
1578   AC_MSG_WARN([missing architecture parameter to check for working -z relro])
1579 fi
1580
1581 AC_CACHE_CHECK(for -Bgroup option,
1582                libc_cv_Bgroup, [dnl
1583 cat > conftest.c <<EOF
1584 int _start (void) { return 42; }
1585 EOF
1586 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1587                             -fPIC -shared -o conftest.so conftest.c
1588                             -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1589 then
1590   libc_cv_Bgroup=yes
1591 else
1592   libc_cv_Bgroup=no
1593 fi
1594 rm -f conftest*])
1595 AC_SUBST(libc_cv_Bgroup)
1596
1597 AC_CACHE_CHECK(for libgcc_s suffix,
1598                libc_cv_libgcc_s_suffix, [dnl
1599 cat > conftest.c <<EOF
1600 int main (void) { return 0; }
1601 EOF
1602 changequote(,)dnl
1603 libc_cv_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1604                            -fPIC -shared -shared-libgcc -o conftest.so \
1605                            conftest.c -v 2>&1 >/dev/null \
1606                            | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
1607 changequote([,])dnl
1608 rm -f conftest*])
1609 AC_SUBST(libc_cv_libgcc_s_suffix)
1610
1611 AC_CACHE_CHECK(for --as-needed option,
1612                libc_cv_as_needed, [dnl
1613 cat > conftest.c <<EOF
1614 int main (void) { return 0; }
1615 EOF
1616 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1617                               -fPIC -shared -o conftest.so conftest.c
1618                               -lgcc_s$libc_cv_libgcc_s_suffix -Wl,--as-needed
1619                               -nostdlib 1>&AS_MESSAGE_LOG_FD])
1620 then
1621   libc_cv_as_needed=yes
1622 else
1623   libc_cv_as_needed=no
1624 fi
1625 rm -f conftest*])
1626 AC_SUBST(libc_cv_as_needed)
1627
1628 ASFLAGS_config=
1629 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1630                libc_cv_as_noexecstack, [dnl
1631 cat > conftest.c <<EOF
1632 void foo (void) { }
1633 EOF
1634 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1635                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1636    && grep -q .note.GNU-stack conftest.s \
1637    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1638                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1639 then
1640   libc_cv_as_noexecstack=yes
1641 else
1642   libc_cv_as_noexecstack=no
1643 fi
1644 rm -f conftest*])
1645 if test $libc_cv_as_noexecstack = yes; then
1646   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1647 fi
1648 AC_SUBST(ASFLAGS_config)
1649
1650 AC_CACHE_CHECK(for -z combreloc,
1651                libc_cv_z_combreloc, [dnl
1652 cat > conftest.c <<EOF
1653 extern int bar (int);
1654 extern int mumble;
1655 int foo (void) { return bar (mumble); }
1656 EOF
1657 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1658                         -fPIC -shared -o conftest.so conftest.c
1659                         -nostdlib -nostartfiles
1660                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1661 then
1662 dnl The following test is a bit weak.  We must use a tool which can test
1663 dnl cross-platform since the gcc used can be a cross compiler.  Without
1664 dnl introducing new options this is not easily doable.  Instead use a tool
1665 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1666 dnl look for a section named .rel.dyn.
1667   if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1668     libc_cv_z_combreloc=yes
1669   else
1670     libc_cv_z_combreloc=no
1671   fi
1672 else
1673   libc_cv_z_combreloc=no
1674 fi
1675 rm -f conftest*])
1676 if test "$libc_cv_z_combreloc" = yes; then
1677   AC_DEFINE(HAVE_Z_COMBRELOC)
1678 fi
1679 AC_SUBST(libc_cv_z_combreloc)
1680
1681 AC_CACHE_CHECK(for -z execstack,
1682                libc_cv_z_execstack, [dnl
1683 cat > conftest.c <<EOF
1684 int _start (void) { return 42; }
1685 EOF
1686 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1687                             -fPIC -shared -o conftest.so conftest.c
1688                             -Wl,-z,execstack -nostdlib
1689                             1>&AS_MESSAGE_LOG_FD])
1690 then
1691   libc_cv_z_execstack=yes
1692 else
1693   libc_cv_z_execstack=no
1694 fi
1695 rm -f conftest*])
1696 AC_SUBST(libc_cv_z_execstack)
1697
1698 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1699 cat > conftest.c <<EOF
1700 int foo;
1701 main () { return 0;}
1702 EOF
1703 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -pie -fpie
1704                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD])
1705 then
1706   libc_cv_fpie=yes
1707 else
1708   libc_cv_fpie=no
1709 fi
1710 rm -f conftest*])
1711
1712 AC_SUBST(libc_cv_fpie)
1713
1714 AC_CACHE_CHECK(for --hash-style option,
1715                libc_cv_hashstyle, [dnl
1716 cat > conftest.c <<EOF
1717 int _start (void) { return 42; }
1718 EOF
1719 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1720                             -fPIC -shared -o conftest.so conftest.c
1721                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1722 then
1723   libc_cv_hashstyle=yes
1724 else
1725   libc_cv_hashstyle=no
1726 fi
1727 rm -f conftest*])
1728 AC_SUBST(libc_cv_hashstyle)
1729
1730 # The linker's default -shared behavior is good enough if it
1731 # does these things that our custom linker scripts ensure that
1732 # all allocated NOTE sections come first.
1733 if test "$use_default_link" = default; then
1734   AC_CACHE_CHECK([for sufficient default -shared layout],
1735                   libc_cv_use_default_link, [dnl
1736   libc_cv_use_default_link=no
1737   cat > conftest.s <<\EOF
1738           .section .note.a,"a",%note
1739           .balign 4
1740           .long 4,4,9
1741           .string "GNU"
1742           .string "foo"
1743           .section .note.b,"a",%note
1744           .balign 4
1745           .long 4,4,9
1746           .string "GNU"
1747           .string "bar"
1748 EOF
1749   if AC_TRY_COMMAND([dnl
1750   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1751        ac_try=`$READELF -S conftest.so | sed -n \
1752          ['${x;p;}
1753           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1754           t a
1755           b
1756           : a
1757           H']`
1758   then
1759     libc_seen_a=no libc_seen_b=no
1760     set -- $ac_try
1761     while test $# -ge 2 -a "$1" = NOTE; do
1762       case "$2" in
1763       .note.a) libc_seen_a=yes ;;
1764       .note.b) libc_seen_b=yes ;;
1765       esac
1766       shift 2
1767     done
1768     case "$libc_seen_a$libc_seen_b" in
1769     yesyes)
1770       libc_cv_use_default_link=yes
1771       ;;
1772     *)
1773       echo >&AS_MESSAGE_LOG_FD "\
1774 $libc_seen_a$libc_seen_b from:
1775 $ac_try"
1776       ;;
1777     esac
1778   fi
1779   rm -f conftest*])
1780   use_default_link=$libc_cv_use_default_link
1781 fi
1782
1783 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1784 if libc_cv_output_format=`
1785 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1786 then
1787   :
1788 else
1789   libc_cv_output_format=
1790 fi
1791 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1792 AC_SUBST(libc_cv_output_format)
1793
1794 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1795 cat > conftest.c <<EOF
1796 int foo;
1797 EOF
1798 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1799                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1800 then
1801   libc_cv_fno_toplevel_reorder=yes
1802 else
1803   libc_cv_fno_toplevel_reorder=no
1804 fi
1805 rm -f conftest*])
1806 if test $libc_cv_fno_toplevel_reorder = yes; then
1807   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1808 else
1809   fno_unit_at_a_time=-fno-unit-at-a-time
1810 fi
1811 AC_SUBST(fno_unit_at_a_time)
1812
1813 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1814 cat > conftest.c <<EOF
1815 int foo;
1816 main () { return 0;}
1817 EOF
1818 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -Werror -fstack-protector
1819                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD])
1820 then
1821   libc_cv_ssp=yes
1822 else
1823   libc_cv_ssp=no
1824 fi
1825 rm -f conftest*])
1826 AC_SUBST(libc_cv_ssp)
1827
1828 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1829 cat > conftest.c <<EOF
1830 int foo;
1831 #ifdef __GNUC_GNU_INLINE__
1832 main () { return 0;}
1833 #else
1834 #error
1835 #endif
1836 EOF
1837 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1838                             -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1839 then
1840   libc_cv_gnu89_inline=yes
1841 else
1842   libc_cv_gnu89_inline=no
1843 fi
1844 rm -f conftest*])
1845 if test $libc_cv_gnu89_inline = yes; then
1846   gnu89_inline=-fgnu89-inline
1847 else
1848   gnu89_inline=
1849 fi
1850 AC_SUBST(gnu89_inline)
1851
1852 AC_CACHE_CHECK(whether cc puts quotes around section names,
1853                libc_cv_have_section_quotes,
1854                [cat > conftest.c <<EOF
1855                 static const int foo
1856                 __attribute__ ((section ("bar"))) = 1;
1857 EOF
1858                 if ${CC-cc} -S conftest.c -o conftest.s; then
1859                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1860                     libc_cv_have_section_quotes=yes
1861                   else
1862                     libc_cv_have_section_quotes=no
1863                   fi
1864                 else
1865                   libc_cv_have_section_quotes=unknown
1866                 fi
1867                 rm -f conftest.{c,s}
1868                 ])
1869 if test $libc_cv_have_section_quotes = yes; then
1870   AC_DEFINE(HAVE_SECTION_QUOTES)
1871 fi
1872
1873 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1874                [dnl
1875 cat > conftest.s <<EOF
1876 ${libc_cv_dot_text}
1877 ${libc_cv_asm_global_directive} foo
1878 foo:
1879 .weak foo
1880 .weak bar; bar = foo
1881 EOF
1882 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1883   libc_cv_asm_weak_directive=yes
1884 else
1885   libc_cv_asm_weak_directive=no
1886 fi
1887 rm -f conftest*])
1888
1889 if test $libc_cv_asm_weak_directive = no; then
1890   AC_CACHE_CHECK(for assembler .weakext directive,
1891                  libc_cv_asm_weakext_directive,
1892                  [dnl
1893 cat > conftest.s <<EOF
1894 ${libc_cv_dot_text}
1895 ${libc_cv_asm_global_directive} foo
1896 foo:
1897 .weakext bar foo
1898 .weakext baz
1899 ${libc_cv_asm_global_directive} baz
1900 baz:
1901 EOF
1902   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1903     libc_cv_asm_weakext_directive=yes
1904   else
1905     libc_cv_asm_weakext_directive=no
1906   fi
1907   rm -f conftest*])
1908
1909 fi # no .weak
1910
1911 if test $libc_cv_asm_weak_directive = yes; then
1912   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1913 elif test $libc_cv_asm_weakext_directive = yes; then
1914   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1915 fi
1916
1917 AC_CACHE_CHECK(whether CFI directives are supported, libc_cv_asm_cfi_directives, [dnl
1918 case $machine in
1919   sparc/sparc64*) cfi_offset=2047;;
1920   *) cfi_offset=0;;
1921 esac
1922 cat > conftest.s <<EOF
1923         .text
1924         .type   func,%function
1925 func:
1926         .cfi_startproc
1927         .cfi_remember_state
1928         .cfi_rel_offset 1, $cfi_offset
1929         .cfi_endproc
1930 EOF
1931 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1932   libc_cv_asm_cfi_directives=yes
1933 else
1934   libc_cv_asm_cfi_directives=no
1935 fi
1936 rm -f conftest*])
1937 if test $libc_cv_asm_cfi_directives = yes; then
1938   AC_DEFINE(HAVE_ASM_CFI_DIRECTIVES)
1939 fi
1940
1941 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1942 cat > conftest.c <<\EOF
1943 _start () {}
1944 int __eh_pc;
1945 __throw () {}
1946 EOF
1947 dnl No \ in command here because it ends up inside ''.
1948 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1949                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1950                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1951   libc_cv_ld_no_whole_archive=yes
1952 else
1953   libc_cv_ld_no_whole_archive=no
1954 fi
1955 rm -f conftest*])
1956 if test $libc_cv_ld_no_whole_archive = no; then
1957   AC_MSG_ERROR([support for --no-whole-archive is needed])
1958 fi
1959
1960 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1961 cat > conftest.c <<\EOF
1962 _start () {}
1963 int __eh_pc;
1964 __throw () {}
1965 EOF
1966 dnl No \ in command here because it ends up inside ''.
1967 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1968                             -nostdlib -nostartfiles -fexceptions
1969                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1970   libc_cv_gcc_exceptions=yes
1971 else
1972   libc_cv_gcc_exceptions=no
1973 fi
1974 rm -f conftest*])
1975 if test $libc_cv_gcc_exceptions = yes; then
1976   exceptions=-fexceptions
1977 fi
1978 AC_SUBST(exceptions)dnl
1979
1980 if test "$host_cpu" = powerpc ; then
1981 # Check for a bug present in at least versions 2.8.x of GCC
1982 # and versions 1.0.x of EGCS.
1983 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1984 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1985                libc_cv_c_asmcr0_bug='no',
1986                libc_cv_c_asmcr0_bug='yes')])
1987 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1988   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1989 fi
1990 fi
1991
1992 dnl Check whether compiler understands __builtin_expect.
1993 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1994 [cat > conftest.c <<EOF
1995 #line $LINENO "configure"
1996 int foo (int a)
1997 {
1998   a = __builtin_expect (a, 10);
1999   return a == 10 ? 0 : 1;
2000 }
2001 EOF
2002 dnl No \ in command here because it ends up inside ''.
2003 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -nostdlib -nostartfiles
2004                             -o conftest conftest.c -lgcc >&AS_MESSAGE_LOG_FD]); then
2005   libc_cv_gcc_builtin_expect=yes
2006 else
2007   libc_cv_gcc_builtin_expect=no
2008 fi
2009 rm -f conftest*])
2010 if test "$libc_cv_gcc_builtin_expect" = no; then
2011   AC_MSG_ERROR([support for __builtin_expect needed])
2012 fi
2013
2014 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
2015 cat > conftest.c <<\EOF
2016 void zero (void *x)
2017 {
2018   __builtin_memset (x, 0, 1000);
2019 }
2020 EOF
2021 dnl
2022 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
2023 then
2024   libc_cv_gcc_builtin_memset=no
2025 else
2026   libc_cv_gcc_builtin_memset=yes
2027 fi
2028 rm -f conftest* ])
2029 if test "$libc_cv_gcc_builtin_memset" = yes ; then
2030   AC_DEFINE(HAVE_BUILTIN_MEMSET)
2031 fi
2032
2033 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
2034 cat > conftest.c <<\EOF
2035 extern char *strstr (const char *, const char *) __asm ("my_strstr");
2036 char *foo (const char *a, const char *b)
2037 {
2038   return __builtin_strstr (a, b);
2039 }
2040 EOF
2041 dnl
2042 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
2043 then
2044   libc_cv_gcc_builtin_redirection=yes
2045 else
2046   libc_cv_gcc_builtin_redirection=no
2047 fi
2048 rm -f conftest* ])
2049 if test "$libc_cv_gcc_builtin_redirection" = no; then
2050   AC_MSG_ERROR([support for the symbol redirection needed])
2051 fi
2052
2053 dnl Check whether the compiler supports the __thread keyword.
2054 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
2055 [cat > conftest.c <<\EOF
2056 __thread int a = 42;
2057 EOF
2058 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
2059   libc_cv_gcc___thread=yes
2060 else
2061   libc_cv_gcc___thread=no
2062 fi
2063 rm -f conftest*])
2064 if test "$libc_cv_gcc___thread" = no; then
2065   AC_MSG_ERROR([support for the __thread keyword is required])
2066 fi
2067
2068 dnl Check whether the compiler supports the tls_model attribute.
2069 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
2070 cat > conftest.c <<\EOF
2071 extern __thread int a __attribute__((tls_model ("initial-exec")));
2072 EOF
2073 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
2074   libc_cv_gcc_tls_model_attr=yes
2075 else
2076   libc_cv_gcc_tls_model_attr=no
2077 fi
2078 rm -f conftest*])
2079 if test "$libc_cv_gcc_tls_model_attr" = no; then
2080   AC_MSG_ERROR([support for the tls_model attribute is required])
2081 fi
2082
2083 if test -n "$submachine"; then
2084   AC_CACHE_CHECK([for compiler option for CPU variant],
2085                  libc_cv_cc_submachine, [dnl
2086   libc_cv_cc_submachine=no
2087   for opt in "-march=$submachine" "-mcpu=$submachine"; do
2088     if AC_TRY_COMMAND([${CC-cc} $opt -xc /dev/null -S -o /dev/null]); then
2089       libc_cv_cc_submachine="$opt"
2090       break
2091     fi
2092   done])
2093   if test "x$libc_cv_cc_submachine" = xno; then
2094     AC_MSG_ERROR([${CC-cc} does not support $submachine])
2095   fi
2096 fi
2097 AC_SUBST(libc_cv_cc_submachine)
2098
2099 dnl Check whether we have the gd library available.
2100 AC_MSG_CHECKING(for libgd)
2101 if test "$with_gd" != "no"; then
2102   old_CFLAGS="$CFLAGS"
2103   CFLAGS="$CFLAGS $libgd_include"
2104   old_LDFLAGS="$LDFLAGS"
2105   LDFLAGS="$LDFLAGS $libgd_ldflags"
2106   old_LIBS="$LIBS"
2107   LIBS="$LIBS -lgd -lpng -lz -lm"
2108   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
2109   CFLAGS="$old_CFLAGS"
2110   LDFLAGS="$old_LDFLAGS"
2111   LIBS="$old_LIBS"
2112 else
2113   LIBGD=no
2114 fi
2115 AC_MSG_RESULT($LIBGD)
2116 AC_SUBST(LIBGD)
2117
2118 # SELinux detection
2119 if test x$with_selinux = xno ; then
2120   have_selinux=no;
2121 else
2122   # See if we have the SELinux library
2123   AC_CHECK_LIB(selinux, is_selinux_enabled,
2124                have_selinux=yes, have_selinux=no)
2125   # See if we have the SELinux header with the NSCD permissions in it.
2126   if test x$have_selinux = xyes ; then
2127     AC_MSG_CHECKING([for NSCD Flask permissions in selinux/av_permissions.h])
2128     AC_TRY_COMPILE([#include <selinux/av_permissions.h>],
2129                     [#ifdef NSCD__SHMEMHOST
2130                      return 0;
2131                      #else
2132                      #error NSCD__SHMEMHOST not defined
2133                      #endif],
2134                     have_selinux=yes, have_selinux=no)
2135     AC_MSG_RESULT($have_selinux)
2136   fi
2137
2138   if test x$with_selinux = xyes ; then
2139     if test x$have_selinux = xno ; then
2140       AC_MSG_ERROR([SELinux explicitly required, but sufficiently recent SELinux library not found])
2141     fi
2142   fi
2143 fi
2144 # Check if we're building with SELinux support.
2145 if test "x$have_selinux" = xyes; then
2146   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
2147
2148   # See if we have the libaudit library
2149   AC_CHECK_LIB(audit, audit_log_user_avc_message,
2150                have_libaudit=yes, have_libaudit=no)
2151   if test "x$have_libaudit" = xyes; then
2152     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
2153   fi
2154   AC_SUBST(have_libaudit)
2155
2156   # See if we have the libcap library
2157   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
2158   if test "x$have_libcap" = xyes; then
2159     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
2160   fi
2161   AC_SUBST(have_libcap)
2162 fi
2163 AC_SUBST(have_selinux)
2164
2165 dnl check for the size of 'long double'.
2166 AC_CHECK_SIZEOF(long double, 0)
2167 sizeof_long_double=$ac_cv_sizeof_long_double
2168 AC_SUBST(sizeof_long_double)
2169
2170 ### End of automated tests.
2171 ### Now run sysdeps configure fragments.
2172
2173 # They also can set these variables.
2174 use_ldconfig=no
2175 ldd_rewrite_script=no
2176 libc_cv_sysconfdir=$sysconfdir
2177 libc_cv_gcc_unwind_find_fde=no
2178 libc_cv_idn=no
2179
2180 # Iterate over all the sysdep directories we will use, running their
2181 # configure fragments.
2182 for dir in $sysnames; do
2183   case $dir in
2184     /*) dest=$dir ;;
2185     *)  dest=$srcdir/$dir ;;
2186   esac
2187   if test -r $dest/configure; then
2188     AC_MSG_RESULT(running configure fragment for $dir)
2189     . $dest/configure
2190   fi
2191 done
2192
2193 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
2194   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
2195 fi
2196 AC_SUBST(libc_cv_gcc_unwind_find_fde)
2197
2198 # Test for old glibc 2.0.x headers so that they can be removed properly
2199 # Search only in includedir.
2200 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2201 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2202 then
2203   old_glibc_headers=yes
2204 else
2205   old_glibc_headers=no
2206 fi
2207 AC_MSG_RESULT($old_glibc_headers)
2208 if test ${old_glibc_headers} = yes; then
2209   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2210   AC_MSG_WARN(*** be removed.)
2211 fi
2212 AC_SUBST(old_glibc_headers)
2213
2214 AC_SUBST(libc_cv_slibdir)
2215 AC_SUBST(libc_cv_localedir)
2216 AC_SUBST(libc_cv_sysconfdir)
2217 AC_SUBST(libc_cv_rootsbindir)
2218 AC_SUBST(libc_cv_forced_unwind)
2219
2220 dnl sysdeps/CPU/configure.in checks set this via arch-specific asm tests
2221 AC_SUBST(libc_cv_cpp_asm_debuginfo)
2222 AC_SUBST(libc_cv_cc_sse4)
2223 AC_SUBST(libc_cv_cc_avx)
2224 AC_SUBST(libc_cv_cc_novzeroupper)
2225 AC_SUBST(libc_cv_cc_fma4)
2226 AC_SUBST(libc_cv_as_i686)
2227
2228 AC_SUBST(use_ldconfig)
2229 AC_SUBST(ldd_rewrite_script)
2230
2231 AC_SUBST(static)
2232 AC_SUBST(shared)
2233
2234 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2235 [libc_cv_pic_default=yes
2236 cat > conftest.c <<EOF
2237 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2238 # error PIC is default.
2239 #endif
2240 EOF
2241 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2242   libc_cv_pic_default=no
2243 fi
2244 rm -f conftest.*])
2245 AC_SUBST(libc_cv_pic_default)
2246
2247 AC_SUBST(profile)
2248 AC_SUBST(bounded)
2249 AC_SUBST(static_nss)
2250 AC_SUBST(nopic_initfini)
2251
2252 AC_SUBST(DEFINES)
2253
2254 dnl See sysdeps/mach/configure.in for this variable.
2255 AC_SUBST(mach_interface_list)
2256
2257 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
2258   config_makefile=
2259 else
2260   config_makefile=Makefile
2261 fi
2262
2263 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2264 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2265 AC_SUBST(VERSION)
2266 AC_SUBST(RELEASE)
2267
2268 AC_CONFIG_FILES([config.make ${config_makefile}])
2269 AC_CONFIG_COMMANDS([default],[[
2270 case $CONFIG_FILES in *config.make*)
2271 echo "$config_vars" >> config.make;;
2272 esac
2273 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2274 AC_OUTPUT