configure.in

   1 dnl $Id$
   2 dnl Process this file with autoconf to produce a configure script.
   3 AC_INIT(lib/urldata.h)
   4 AM_CONFIG_HEADER(config.h src/config.h)
   5
   6 VERSION=`sed -ne 's/^#define LIBCURL_VERSION "\(.*\)"/\1/p' ${srcdir}/include/curl/curl.h`
   7 AM_INIT_AUTOMAKE(curl,$VERSION)
   8 AM_PROG_LIBTOOL
   9
  10 dnl
  11 dnl Detect the canonical host and target build environment
  12 dnl
  13 AC_CANONICAL_HOST
  14 AC_CANONICAL_TARGET
  15
  16 dnl Checks for programs.
  17 AC_PROG_CC
  18
  19 dnl Check for AIX weirdos
  20 AC_AIX
  21
  22 dnl check for how to do large files
  23 AC_SYS_LARGEFILE
  24
  25 dnl The install stuff has already been taken care of by the automake stuff
  26 dnl AC_PROG_INSTALL
  27 AC_PROG_MAKE_SET
  28
  29 AC_DEFUN(CURL_CHECK_LOCALTIME_R,
  30 [
  31   dnl check for a few thread-safe functions
  32   AC_CHECK_FUNCS(localtime_r,[
  33     AC_MSG_CHECKING(whether localtime_r is declared)
  34     AC_EGREP_CPP(localtime_r,[
  35 #include <time.h>],[
  36       AC_MSG_RESULT(yes)],[
  37       AC_MSG_RESULT(no)
  38       AC_MSG_CHECKING(whether localtime_r with -D_REENTRANT is declared)
  39       AC_EGREP_CPP(localtime_r,[
  40 #define _REENTRANT
  41 #include <time.h>],[
  42         AC_DEFINE(NEED_REENTRANT)
  43         AC_MSG_RESULT(yes)],
  44         AC_MSG_RESULT(no))])])
  45 ])
  46
  47 AC_DEFUN(CURL_CHECK_INET_NTOA_R,
  48 [
  49   dnl determine if function definition for inet_ntoa_r exists.
  50   AC_CHECK_FUNCS(inet_ntoa_r,[
  51     AC_MSG_CHECKING(whether inet_ntoa_r is declared)
  52     AC_EGREP_CPP(inet_ntoa_r,[
  53 #include <arpa/inet.h>],[
  54       AC_DEFINE(HAVE_INET_NTOA_R_DECL)
  55       AC_MSG_RESULT(yes)],[
  56       AC_MSG_RESULT(no)
  57       AC_MSG_CHECKING(whether inet_ntoa_r with -D_REENTRANT is declared)
  58       AC_EGREP_CPP(inet_ntoa_r,[
  59 #define _REENTRANT
  60 #include <arpa/inet.h>],[
  61         AC_DEFINE(HAVE_INET_NTOA_R_DECL)
  62         AC_DEFINE(NEED_REENTRANT)
  63         AC_MSG_RESULT(yes)],
  64         AC_MSG_RESULT(no))])])
  65
  66 ])
  67
  68 AC_DEFUN(CURL_CHECK_GETHOSTBYADDR_R,
  69 [
  70   dnl check for number of arguments to gethostbyaddr_r. it might take
  71   dnl either 5, 7, or 8 arguments.
  72   AC_CHECK_FUNCS(gethostbyaddr_r,[
  73     AC_MSG_CHECKING(if gethostbyaddr_r takes 5 arguments)
  74     AC_TRY_COMPILE([
  75 #include <sys/types.h>
  76 #include <netdb.h>],[
  77 char * address;
  78 int length;
  79 int type;
  80 struct hostent h;
  81 struct hostent_data hdata;
  82 int rc;
  83 rc = gethostbyaddr_r(address, length, type, &h, &hdata);],[
  84       AC_MSG_RESULT(yes)
  85       AC_DEFINE(HAVE_GETHOSTBYADDR_R_5)
  86       ac_cv_gethostbyaddr_args=5],[
  87       AC_MSG_RESULT(no)
  88       AC_MSG_CHECKING(if gethostbyaddr_r with -D_REENTRANT takes 5 arguments)
  89       AC_TRY_COMPILE([
  90 #define _REENTRANT
  91 #include <sys/types.h>
  92 #include <netdb.h>],[
  93 char * address;
  94 int length;
  95 int type;
  96 struct hostent h;
  97 struct hostent_data hdata;
  98 int rc;
  99 rc = gethostbyaddr_r(address, length, type, &h, &hdata);],[
 100         AC_MSG_RESULT(yes)
 101         AC_DEFINE(HAVE_GETHOSTBYADDR_R_5)
 102         AC_DEFINE(NEED_REENTRANT)
 103         ac_cv_gethostbyaddr_args=5],[
 104         AC_MSG_RESULT(no)
 105         AC_MSG_CHECKING(if gethostbyaddr_r takes 7 arguments)
 106         AC_TRY_COMPILE([
 107 #include <sys/types.h>
 108 #include <netdb.h>],[
 109 char * address;
 110 int length;
 111 int type;
 112 struct hostent h;
 113 char buffer[8192];
 114 int h_errnop;
 115 struct hostent * hp;
 116
 117 hp = gethostbyaddr_r(address, length, type, &h,
 118                      buffer, 8192, &h_errnop);],[
 119           AC_MSG_RESULT(yes)
 120           AC_DEFINE(HAVE_GETHOSTBYADDR_R_7)
 121           ac_cv_gethostbyaddr_args=7],[
 122           AC_MSG_RESULT(no)
 123           AC_MSG_CHECKING(if gethostbyaddr_r takes 8 arguments)
 124           AC_TRY_COMPILE([
 125 #include <sys/types.h>
 126 #include <netdb.h>],[
 127 char * address;
 128 int length;
 129 int type;
 130 struct hostent h;
 131 char buffer[8192];
 132 int h_errnop;
 133 struct hostent * hp;
 134 int rc;
 135
 136 rc = gethostbyaddr_r(address, length, type, &h,
 137                      buffer, 8192, &hp, &h_errnop);],[
 138             AC_MSG_RESULT(yes)
 139             AC_DEFINE(HAVE_GETHOSTBYADDR_R_8)
 140             ac_cv_gethostbyaddr_args=8],[
 141             AC_MSG_RESULT(no)
 142             have_missing_r_funcs="$have_missing_r_funcs gethostbyaddr_r"])])])])])
 143
 144
 145 ])
 146
 147 AC_DEFUN(CURL_CHECK_GETHOSTBYNAME_R,
 148 [
 149   dnl check for number of arguments to gethostbyname_r. it might take
 150   dnl either 3, 5, or 6 arguments.
 151   AC_CHECK_FUNCS(gethostbyname_r,[
 152     AC_MSG_CHECKING(if gethostbyname_r takes 3 arguments)
 153     AC_TRY_RUN([
 154 #include <string.h>
 155 #include <sys/types.h>
 156 #include <netdb.h>
 157
 158 int
 159 main () {
 160 struct hostent h;
 161 struct hostent_data hdata;
 162 char *name = "localhost";
 163 int rc;
 164 memset(&h, 0, sizeof(struct hostent));
 165 memset(&hdata, 0, sizeof(struct hostent_data));
 166 rc = gethostbyname_r(name, &h, &hdata);
 167 exit (rc != 0 ? 1 : 0); }],[
 168       AC_MSG_RESULT(yes)
 169       AC_DEFINE(HAVE_GETHOSTBYNAME_R_3)
 170       ac_cv_gethostbyname_args=3],[
 171       AC_MSG_RESULT(no)
 172       AC_MSG_CHECKING(if gethostbyname_r with -D_REENTRANT takes 3 arguments)
 173       AC_TRY_RUN([
 174 #define _REENTRANT
 175
 176 #include <string.h>
 177 #include <sys/types.h>
 178 #include <netdb.h>
 179
 180 int
 181 main () {
 182 struct hostent h;
 183 struct hostent_data hdata;
 184 char *name = "localhost";
 185 int rc;
 186 memset(&h, 0, sizeof(struct hostent));
 187 memset(&hdata, 0, sizeof(struct hostent_data));
 188 rc = gethostbyname_r(name, &h, &hdata);
 189 exit (rc != 0 ? 1 : 0); }],[
 190         AC_MSG_RESULT(yes)
 191         AC_DEFINE(HAVE_GETHOSTBYNAME_R_3)
 192         AC_DEFINE(NEED_REENTRANT)
 193         ac_cv_gethostbyname_args=3],[
 194         AC_MSG_RESULT(no)
 195         AC_MSG_CHECKING(if gethostbyname_r takes 5 arguments)
 196         AC_TRY_RUN([
 197 #include <sys/types.h>
 198 #include <netdb.h>
 199
 200 int
 201 main () {
 202 struct hostent *hp;
 203 struct hostent h;
 204 char *name = "localhost";
 205 char buffer[8192];
 206 int h_errno;
 207 hp = gethostbyname_r(name, &h, buffer, 8192, &h_errno);
 208 exit (hp == NULL ? 1 : 0); }],[
 209           AC_MSG_RESULT(yes)
 210           AC_DEFINE(HAVE_GETHOSTBYNAME_R_5)
 211           ac_cv_gethostbyname_args=5],[
 212           AC_MSG_RESULT(no)
 213           AC_MSG_CHECKING(if gethostbyname_r takes 6 arguments)
 214           AC_TRY_RUN([
 215 #include <sys/types.h>
 216 #include <netdb.h>
 217
 218 int
 219 main () {
 220 struct hostent h;
 221 struct hostent *hp;
 222 char *name = "localhost";
 223 char buf[8192];
 224 int rc;
 225 int h_errno;
 226 rc = gethostbyname_r(name, &h, buf, 8192, &hp, &h_errno);
 227 exit (rc != 0 ? 1 : 0); }],[
 228             AC_MSG_RESULT(yes)
 229             AC_DEFINE(HAVE_GETHOSTBYNAME_R_6)
 230             ac_cv_gethostbyname_args=6],[
 231             AC_MSG_RESULT(no)
 232             have_missing_r_funcs="$have_missing_r_funcs gethostbyname_r"],
 233             [ac_cv_gethostbyname_args=0])],
 234           [ac_cv_gethostbyname_args=0])],
 235         [ac_cv_gethostbyname_args=0])],
 236       [ac_cv_gethostbyname_args=0])])
 237
 238 ])
 239
 240 dnl **********************************************************************
 241 dnl Checks for IPv6
 242 dnl **********************************************************************
 243
 244 AC_MSG_CHECKING([whether to enable ipv6])
 245 AC_ARG_ENABLE(ipv6,
 246 [  --enable-ipv6                Enable ipv6 (with ipv4) support
 247   --disable-ipv6                Disable ipv6 support],
 248 [ case "$enableval" in
 249   no)
 250        AC_MSG_RESULT(no)
 251        ipv6=no
 252        ;;
 253   *)   AC_MSG_RESULT(yes)
 254        AC_DEFINE(ENABLE_IPV6)
 255        ipv6=yes
 256        ;;
 257   esac ],
 258
 259   AC_TRY_RUN([ /* is AF_INET6 available? */
 260 #include <sys/types.h>
 261 #include <sys/socket.h>
 262 main()
 263 {
 264  if (socket(AF_INET6, SOCK_STREAM, 0) < 0)
 265    exit(1);
 266  else
 267    exit(0);
 268 }
 269 ],
 270   AC_MSG_RESULT(yes)
 271   AC_DEFINE(ENABLE_IPV6)
 272   ipv6=yes,
 273   AC_MSG_RESULT(no)
 274   ipv6=no,
 275   AC_MSG_RESULT(no)
 276   ipv6=no
 277 ))
 278
 279 dnl **********************************************************************
 280 dnl Checks for libraries.
 281 dnl **********************************************************************
 282
 283 dnl gethostbyname in the nsl lib?
 284 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname))
 285
 286 if test "$ac_cv_lib_nsl_gethostbyname" != "yes" -a "$ac_cv_func_gethostbyname" != "yes"; then
 287   dnl gethostbyname in the socket lib?
 288   AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(socket, gethostbyname))
 289 fi
 290
 291 dnl At least one system has been identified to require BOTH nsl and
 292 dnl socket libs to link properly.
 293 if test "$ac_cv_lib_nsl_gethostbyname" = "$ac_cv_func_gethostbyname"; then
 294   AC_MSG_CHECKING([trying both nsl and socket libs])
 295   my_ac_save_LIBS=$LIBS
 296   LIBS="-lnsl -lsocket $LIBS"
 297   AC_TRY_LINK( ,
 298              [gethostbyname();],
 299              my_ac_link_result=success,
 300              my_ac_link_result=failure )
 301
 302   if test "$my_ac_link_result" = "failure"; then
 303     AC_MSG_RESULT([no])
 304     AC_MSG_ERROR([couldn't find libraries for gethostbyname()])
 305     dnl restore LIBS
 306     LIBS=$my_ac_save_LIBS
 307   else
 308     AC_MSG_RESULT([yes])
 309   fi
 310 fi
 311
 312 dnl resolve lib?
 313 AC_CHECK_FUNC(strcasecmp, , AC_CHECK_LIB(resolve, strcasecmp))
 314
 315 if test "$ac_cv_lib_resolve_strcasecmp" = "$ac_cv_func_strcasecmp"; then
 316   AC_CHECK_LIB(resolve, strcasecmp,
 317               [LIBS="-lresolve $LIBS"],
 318                ,
 319                -lnsl)
 320 fi
 321
 322 dnl socket lib?
 323 AC_CHECK_FUNC(connect, , AC_CHECK_LIB(socket, connect))
 324
 325 dnl ucb lib?
 326 AC_CHECK_FUNC(gethostname, , AC_CHECK_LIB(ucb, gethostname))
 327
 328 dnl dl lib?
 329 AC_CHECK_FUNC(dlopen, , AC_CHECK_LIB(dl, dlopen))
 330
 331 dnl **********************************************************************
 332 dnl Check for the presence of Kerberos4 libraries and headers
 333 dnl **********************************************************************
 334
 335 AC_ARG_WITH(krb4-includes,
 336  [  --with-krb4-includes[=DIR]   Specify location of kerberos4 headers],[
 337  CPPFLAGS="$CPPFLAGS -I$withval"
 338  KRB4INC="$withval"
 339  want_krb4=yes
 340  ])
 341
 342 AC_ARG_WITH(krb4-libs,
 343  [  --with-krb4-libs[=DIR]   Specify location of kerberos4 libs],[
 344  LDFLAGS="$LDFLAGS -L$withval"
 345  KRB4LIB="$withval"
 346  want_krb4=yes
 347  ])
 348
 349
 350 OPT_KRB4=off
 351 AC_ARG_WITH(krb4,dnl
 352 [  --with-krb4[=DIR]       where to look for Kerberos4],[
 353   OPT_KRB4="$withval"
 354   if test X"$OPT_KRB4" != Xyes
 355   then
 356     LDFLAGS="$LDFLAGS -L$OPT_KRB4/lib"
 357     KRB4LIB="$OPT_KRB4/lib"
 358     CPPFLAGS="$CPPFLAGS -I$OPT_KRB4/include"
 359     KRB4INC="$OPT_KRB4/include"
 360   fi
 361   want_krb4="yes"
 362  ])
 363
 364 AC_MSG_CHECKING([if Kerberos4 support is requested])
 365
 366 if test "$want_krb4" = yes
 367 then
 368   AC_MSG_RESULT(yes)
 369
 370   dnl Check for & handle argument to --with-krb4
 371
 372   AC_MSG_CHECKING(where to look for Kerberos4)
 373   if test X"$OPT_KRB4" = Xyes
 374   then
 375     AC_MSG_RESULT([defaults])
 376   else
 377     AC_MSG_RESULT([libs in $KRB4LIB, headers in $KRB4INC])
 378   fi
 379
 380   dnl Check for DES library
 381   AC_CHECK_LIB(des, des_pcbc_encrypt,
 382   [
 383     AC_CHECK_HEADERS(des.h)
 384
 385     dnl resolv lib?
 386     AC_CHECK_FUNC(res_search, , AC_CHECK_LIB(resolv, res_search))
 387
 388     dnl Check for the Kerberos4 library
 389     AC_CHECK_LIB(krb, krb_net_read,
 390     [
 391       dnl Check for header files
 392       AC_CHECK_HEADERS(krb.h)
 393
 394       dnl we found the required libraries, add to LIBS
 395       LIBS="-lkrb -ldes $LIBS"
 396
 397       dnl Check for function krb_get_our_ip_for_realm
 398       dnl this is needed for NAT networks
 399       AC_CHECK_FUNCS(krb_get_our_ip_for_realm)
 400
 401       dnl add define KRB4
 402       AC_DEFINE(KRB4)
 403
 404       dnl the krb4 stuff needs a strlcpy()
 405       AC_CHECK_FUNCS(strlcpy)
 406
 407     ])
 408   ])
 409 else
 410   AC_MSG_RESULT(no)
 411 fi
 412
 413 dnl **********************************************************************
 414 dnl Check for the presence of SSL libraries and headers
 415 dnl **********************************************************************
 416
 417 dnl Default to compiler & linker defaults for SSL files & libraries.
 418 OPT_SSL=off
 419 AC_ARG_WITH(ssl,dnl
 420 [  --with-ssl[=DIR]        where to look for SSL [compiler/linker default paths]
 421                           DIR points to the SSL installation [/usr/local/ssl]],
 422   OPT_SSL=$withval
 423 )
 424
 425 if test X"$OPT_SSL" = Xno
 426 then
 427   AC_MSG_WARN(SSL/https support disabled)
 428 else
 429
 430   dnl Check for & handle argument to --with-ssl.
 431
 432   AC_MSG_CHECKING(where to look for SSL)
 433   if test X"$OPT_SSL" = Xoff
 434   then
 435         AC_MSG_RESULT([defaults (or given in environment)])
 436   else
 437         test X"$OPT_SSL" = Xyes && OPT_SSL=/usr/local/ssl
 438         dnl     LIBS="$LIBS -L$OPT_SSL/lib"
 439         LDFLAGS="$LDFLAGS -L$OPT_SSL/lib"
 440         CPPFLAGS="$CPPFLAGS -I$OPT_SSL/include/openssl -I$OPT_SSL/include"
 441         AC_MSG_RESULT([$OPT_SSL])
 442   fi
 443
 444   dnl check for crypto libs (part of SSLeay)
 445   AC_CHECK_LIB(crypto, CRYPTO_lock)
 446
 447   if test $ac_cv_lib_crypto_CRYPTO_lock = yes; then
 448     dnl This is only reasonable to do if crypto actually is there: check for
 449     dnl SSL libs NOTE: it is important to do this AFTER the crypto lib
 450     AC_CHECK_LIB(ssl, SSL_connect)
 451
 452     if test "$ac_cv_lib_ssl_SSL_connect" != yes; then
 453         dnl we didn't find the SSL lib, try the RSAglue/rsaref stuff
 454         AC_MSG_CHECKING(for ssl with RSAglue/rsaref libs in use);
 455         OLIBS=$LIBS
 456         LIBS="$LIBS -lRSAglue -lrsaref"
 457         AC_CHECK_LIB(ssl, SSL_connect)
 458         if test "$ac_cv_lib_ssl_SSL_connect" != yes; then
 459             dnl still no SSL_connect
 460             AC_MSG_RESULT(no)
 461             LIBS=$OLIBS
 462         else
 463             AC_MSG_RESULT(yes)
 464         fi
 465     fi
 466
 467
 468
 469     dnl Check for SSLeay headers
 470     AC_CHECK_HEADERS(openssl/x509.h openssl/rsa.h openssl/crypto.h openssl/pem.h openssl/ssl.h openssl/err.h)
 471
 472     if test $ac_cv_header_openssl_x509_h = no; then
 473       AC_CHECK_HEADERS(x509.h rsa.h crypto.h pem.h ssl.h err.h)
 474     fi
 475
 476   fi
 477
 478   dnl these can only exist if openssl exists
 479
 480   AC_CHECK_FUNCS( RAND_status \
 481                   RAND_screen )
 482
 483 fi
 484
 485 dnl **********************************************************************
 486 dnl Check for the presence of ZLIB libraries and headers
 487 dnl **********************************************************************
 488
 489 dnl Default to compiler & linker defaults for files & libraries.
 490 dnl OPT_ZLIB=no
 491 dnl AC_ARG_WITH(zlib,dnl
 492 dnl [  --with-zlib[=DIR]  where to look for ZLIB [compiler/linker default paths]
 493 dnl                      DIR points to the ZLIB installation prefix [/usr/local]],
 494 dnl  OPT_ZLIB=$withval,
 495 dnl )
 496
 497 dnl Check for & handle argument to --with-zlib.
 498 dnl
 499 dnl NOTE:  We *always* look for ZLIB headers & libraries, all this option
 500 dnl        does is change where we look (by adjusting LIBS and CPPFLAGS.)
 501 dnl
 502
 503 dnl AC_MSG_CHECKING(where to look for ZLIB)
 504 dnl if test X"$OPT_ZLIB" = Xno
 505 dnl then
 506 dnl     AC_MSG_RESULT([defaults (or given in environment)])
 507 dnl else
 508 dnl     test X"$OPT_ZLIB" = Xyes && OPT_ZLIB=/usr/local
 509 dnl     LIBS="$LIBS -L$OPT_ZLIB/lib"
 510 dnl     CPPFLAGS="$CPPFLAGS -I$OPT_ZLIB/include"
 511 dnl     AC_MSG_RESULT([$OPT_ZLIB])
 512 dnl fi
 513
 514 dnl z lib?
 515 dnl AC_CHECK_FUNC(gzread, , AC_CHECK_LIB(z, gzread))
 516
 517
 518 dnl Default is to try the thread-safe versions of a few functions
 519 OPT_THREAD=on
 520 AC_ARG_ENABLE(thread,dnl
 521 [  --disable-thread       tell configure to not look for thread-safe functions],
 522   OPT_THREAD=off
 523 )
 524
 525 if test X"$OPT_THREAD" = Xoff
 526 then
 527   AC_MSG_WARN(libcurl will not get built using thread-safe functions)
 528   AC_DEFINE(DISABLED_THREADSAFE, 1, \
 529 Set to explicitly specify we don't want to use thread-safe functions)
 530 else
 531
 532   dnl dig around for gethostbyname_r()
 533   CURL_CHECK_GETHOSTBYNAME_R()
 534
 535   dnl dig around for gethostbyaddr_r()
 536   CURL_CHECK_GETHOSTBYADDR_R()
 537
 538   dnl poke around for inet_ntoa_r()
 539   CURL_CHECK_INET_NTOA_R()
 540
 541   dnl is there a localtime_r()
 542   CURL_CHECK_LOCALTIME_R()
 543
 544 fi
 545
 546 dnl **********************************************************************
 547 dnl Back to "normal" configuring
 548 dnl **********************************************************************
 549
 550 dnl Checks for header files.
 551 AC_HEADER_STDC
 552 AC_CHECK_HEADERS( \
 553         unistd.h \
 554         malloc.h \
 555         stdlib.h \
 556         arpa/inet.h \
 557         net/if.h \
 558         netinet/in.h \
 559         netinet/if_ether.h \
 560         netdb.h \
 561         sys/select.h \
 562         sys/socket.h \
 563         sys/sockio.h \
 564         sys/stat.h \
 565         sys/types.h \
 566         sys/time.h \
 567         getopt.h \
 568         sys/param.h \
 569         termios.h \
 570         termio.h \
 571         sgtty.h \
 572         fcntl.h \
 573         dlfcn.h \
 574         alloca.h \
 575         winsock.h \
 576         time.h \
 577         io.h \
 578 )
 579
 580 dnl Check for libz header
 581 dnl AC_CHECK_HEADERS(zlib.h)
 582
 583 dnl Checks for typedefs, structures, and compiler characteristics.
 584 AC_C_CONST
 585 AC_TYPE_SIZE_T
 586 AC_HEADER_TIME
 587
 588 # mprintf() checks:
 589
 590 # check for 'long double'
 591 AC_CHECK_SIZEOF(long double, 8)
 592 # check for 'long long'
 593 AC_CHECK_SIZEOF(long long, 4)
 594
 595 dnl Get system canonical name
 596 AC_CANONICAL_HOST
 597 AC_DEFINE_UNQUOTED(OS, "${host}")
 598
 599 dnl Checks for library functions.
 600 dnl AC_PROG_GCC_TRADITIONAL
 601 AC_TYPE_SIGNAL
 602 dnl AC_FUNC_VPRINTF
 603 AC_CHECK_FUNCS( socket \
 604                 select \
 605                 strdup \
 606                 strstr \
 607                 strftime \
 608                 uname \
 609                 strcasecmp \
 610                 stricmp \
 611                 strcmpi \
 612                 gethostname \
 613                 gethostbyaddr \
 614                 getservbyname \
 615                 gettimeofday \
 616                 inet_addr \
 617                 inet_ntoa \
 618                 tcsetattr \
 619                 tcgetattr \
 620                 perror \
 621                 closesocket \
 622                 setvbuf \
 623                 sigaction \
 624                 signal \
 625                 getpass_r
 626 )
 627
 628 dnl removed 'getpass' check on October 26, 2000
 629
 630 if test "$ac_cv_func_select" != "yes"; then
 631   AC_MSG_ERROR(Can't work without an existing select() function)
 632 fi
 633 if test "$ac_cv_func_socket" != "yes"; then
 634   AC_MSG_ERROR(Can't work without an existing socket() function)
 635 fi
 636
 637 AC_PATH_PROG( PERL, perl, ,
 638   $PATH:/usr/local/bin/perl:/usr/bin/:/usr/local/bin )
 639 AC_SUBST(PERL)
 640
 641 AC_PATH_PROGS( NROFF, gnroff nroff, ,
 642   $PATH:/usr/bin/:/usr/local/bin )
 643 AC_SUBST(NROFF)
 644
 645 AC_PROG_YACC
 646
 647 dnl AC_PATH_PROG( RANLIB, ranlib, /usr/bin/ranlib,
 648 dnl   $PATH:/usr/bin/:/usr/local/bin )
 649 dnl AC_SUBST(RANLIB)
 650
 651 AC_OUTPUT( Makefile \
 652            docs/Makefile \
 653            docs/examples/Makefile \
 654            include/Makefile \
 655            include/curl/Makefile \
 656            src/Makefile \
 657            lib/Makefile \
 658            tests/Makefile \
 659            tests/data/Makefile \
 660            packages/Makefile \
 661            packages/Win32/Makefile \
 662            packages/Linux/Makefile \
 663            packages/Linux/RPM/Makefile \
 664            packages/Linux/RPM/curl.spec \
 665            packages/Linux/RPM/curl-ssl.spec )
 666