configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 dnl ***********************************
   6 dnl *** include special GLib macros ***
   7 dnl ***********************************
   8
   9 m4_define(glib_configure_in)
  10
  11 #
  12 # The following version number definitions apply to GLib, GModule, GObject,
  13 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  14 # all treated with the same interface and binary age.
  15 #
  16 # Making releases:
  17 #   glib_micro_version += 1;
  18 #   glib_interface_age += 1;
  19 #   glib_binary_age += 1;
  20 # if any functions have been added, set glib_interface_age to 0.
  21 # if backwards compatibility has been broken,
  22 # set glib_binary_age _and_ glib_interface_age to 0.
  23 #
  24 m4_define([glib_major_version], [2])
  25 m4_define([glib_minor_version], [21])
  26 m4_define([glib_micro_version], [3])
  27 m4_define([glib_interface_age], [0])
  28 m4_define([glib_binary_age],
  29           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  30 m4_define([glib_version],
  31           [glib_major_version.glib_minor_version.glib_micro_version])
  32
  33 # libtool version related macros
  34 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  35 m4_define([glib_lt_current],
  36           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  37 m4_define([glib_lt_revision], [glib_interface_age])
  38 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  39 m4_define([glib_lt_current_minus_age],
  40           [m4_eval(glib_lt_current - glib_lt_age)])
  41
  42 # if the minor version number is odd, then we want debugging.  Otherwise
  43 # we only want minimal debugging support.
  44 m4_define([glib_debug_default],
  45           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  46
  47
  48 AC_INIT(glib, [glib_version],
  49         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  50
  51 AC_CONFIG_SRCDIR([glib/glib.h])
  52
  53 # Save this value here, since automake will set cflags later
  54 cflags_set=${CFLAGS+set}
  55
  56 AM_INIT_AUTOMAKE([no-define])
  57
  58 # Specify a configuration file
  59 AM_CONFIG_HEADER([config.h])
  60
  61
  62 GLIB_MAJOR_VERSION=glib_major_version
  63 GLIB_MINOR_VERSION=glib_minor_version
  64 GLIB_MICRO_VERSION=glib_micro_version
  65 GLIB_INTERFACE_AGE=glib_interface_age
  66 GLIB_BINARY_AGE=glib_binary_age
  67 GLIB_VERSION=glib_version
  68
  69 AC_SUBST(GLIB_MAJOR_VERSION)
  70 AC_SUBST(GLIB_MINOR_VERSION)
  71 AC_SUBST(GLIB_MICRO_VERSION)
  72 AC_SUBST(GLIB_VERSION)
  73 AC_SUBST(GLIB_INTERFACE_AGE)
  74 AC_SUBST(GLIB_BINARY_AGE)
  75
  76 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  77           [Define to the GLIB major version])
  78 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  79           [Define to the GLIB minor version])
  80 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  81           [Define to the GLIB micro version])
  82 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  83           [Define to the GLIB interface age])
  84 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  85           [Define to the GLIB binary age])
  86
  87 # libtool versioning
  88 LT_RELEASE=glib_lt_release
  89 LT_CURRENT=glib_lt_current
  90 LT_REVISION=glib_lt_revision
  91 LT_AGE=glib_lt_age
  92 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
  93 AC_SUBST(LT_RELEASE)
  94 AC_SUBST(LT_CURRENT)
  95 AC_SUBST(LT_REVISION)
  96 AC_SUBST(LT_AGE)
  97 AC_SUBST(LT_CURRENT_MINUS_AGE)
  98
  99 dnl Initialize maintainer mode
 100 AM_MAINTAINER_MODE
 101
 102 AC_CANONICAL_HOST
 103
 104 AC_MSG_CHECKING([for the BeOS])
 105 case $host in
 106   *-*-beos*)
 107     glib_native_beos="yes"
 108     ;;
 109   *)
 110     glib_native_beos="no"
 111     ;;
 112 esac
 113 AC_MSG_RESULT([$glib_native_beos])
 114
 115 dnl
 116
 117 AC_MSG_CHECKING([for Win32])
 118 LIB_EXE_MACHINE_FLAG=X86
 119 case "$host" in
 120   *-*-mingw*)
 121     glib_native_win32=yes
 122     glib_pid_type='void *'
 123     glib_cv_stack_grows=no
 124     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 125     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 126     # (Sorry, I don't know exactly what is the problem, but it is related to
 127     # floating point formatting and decimal point vs. comma.)
 128     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 129     # rigorous enough to notice, though.
 130     # So preset the autoconf cache variables.
 131     ac_cv_func_vsnprintf_c99=no
 132     ac_cv_func_snprintf_c99=no
 133     case "$host" in
 134     x86_64-*-*)
 135       LIB_EXE_MACHINE_FLAG=X64
 136       ;;
 137     esac
 138     ;;
 139   *)
 140     glib_native_win32=no
 141     glib_pid_type=int
 142     ;;
 143 esac
 144 case $host in
 145   *-*-linux*)
 146     glib_os_linux=yes
 147     ;;
 148 esac
 149
 150 AC_MSG_RESULT([$glib_native_win32])
 151
 152 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 153
 154 glib_have_carbon=no
 155 AC_MSG_CHECKING([for Mac OS X Carbon support])
 156 AC_TRY_CPP([
 157 #include <Carbon/Carbon.h>
 158 #include <CoreServices/CoreServices.h>
 159 ], glib_have_carbon=yes)
 160
 161 AC_MSG_RESULT([$glib_have_carbon])
 162
 163 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 164 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 165 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 166 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 167 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 168
 169 if test "$glib_native_win32" = "yes"; then
 170   AC_CHECK_TOOL(WINDRES, windres, no)
 171   if test "$WINDRES" = no; then
 172     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 173   fi
 174   AC_CHECK_TOOL(NM, nm, no)
 175   if test "$NM" = no; then
 176     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 177   fi
 178   AC_CHECK_TOOL(RANLIB, ranlib, :)
 179   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 180 fi
 181 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 182
 183 if test "$glib_native_win32" != yes; then
 184     # libtool option to control which symbols are exported
 185     # right now, symbols starting with _ are not exported
 186     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 187 else
 188     # We currently use .def files on Windows
 189     LIBTOOL_EXPORT_OPTIONS=
 190 fi
 191 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 192
 193 if test "x$glib_have_carbon" = "xyes"; then
 194   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 195   LDFLAGS="$LDFLAGS -framework Carbon"
 196 fi
 197
 198
 199 dnl declare --enable-* args and collect ac_help strings
 200 AC_ARG_ENABLE(debug,
 201               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 202                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 203               enable_debug=glib_debug_default)
 204
 205 AC_ARG_ENABLE(gc_friendly,
 206               [AC_HELP_STRING([--enable-gc-friendly],
 207                               [turn on garbage collector friendliness [default=no]])],,
 208               [enable_gc_friendly=no])
 209 AC_ARG_ENABLE(mem_pools,
 210               [AC_HELP_STRING([--disable-mem-pools],
 211                               [disable all glib memory pools])],,
 212               [disable_mem_pools=no])
 213 AC_ARG_ENABLE(threads,
 214               [AC_HELP_STRING([--enable-threads],
 215                               [turn on basic thread support [default=yes]
 216 ([=no] will override --with-threads)])],,
 217               [enable_threads=yes])
 218 AC_ARG_ENABLE(rebuilds,
 219               [AC_HELP_STRING([--disable-rebuilds],
 220                               [disable all source autogeneration rules])],,
 221               [enable_rebuilds=yes])
 222 AC_ARG_ENABLE(visibility,
 223               [AC_HELP_STRING([--disable-visibility],
 224                               [don't use ELF visibility attributes])],,
 225               [enable_visibility=yes])
 226
 227 if test "x$enable_threads" != "xyes"; then
 228   enable_threads=no
 229 fi
 230
 231 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 232 if test "x$enable_gc_friendly" = "xyes"; then
 233   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 234   AC_MSG_RESULT([yes])
 235 else
 236   AC_MSG_RESULT([no])
 237 fi
 238
 239 AC_MSG_CHECKING([whether to disable memory pools])
 240 if test "x$disable_mem_pools" = "xno"; then
 241   AC_MSG_RESULT([no])
 242 else
 243   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 244   AC_SUBST(DISABLE_MEM_POOLS)
 245   AC_MSG_RESULT([yes])
 246 fi
 247
 248 dnl Checks for programs.
 249 AC_PROG_CC
 250 AC_PROG_CPP
 251
 252 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 253 AC_CHECK_PROGS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 254 AC_LANG_SAVE
 255 AC_LANG_CPLUSPLUS
 256 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 257 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 258 AC_LANG_RESTORE
 259
 260 AM_PROG_CC_STDC
 261 AM_PROG_CC_C_O
 262 AC_PROG_INSTALL
 263
 264 AC_SYS_LARGEFILE
 265
 266 #
 267 # Find pkg-config
 268 #
 269 AC_PATH_PROG(PKG_CONFIG, [pkg-config], [no])
 270 if test x$PKG_CONFIG = xno ; then
 271   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
 272 fi
 273
 274 if $PKG_CONFIG --atleast-pkgconfig-version 0.16 ; then
 275   :
 276 else
 277   AC_MSG_ERROR([*** pkg-config too old; version 0.16 or better required.])
 278 fi
 279
 280 if test "x$enable_debug" = "xyes"; then
 281   if test x$cflags_set != xset ; then
 282       case " $CFLAGS " in
 283       *[[\ \    ]]-g[[\ \       ]]*) ;;
 284       *) CFLAGS="$CFLAGS -g" ;;
 285       esac
 286   fi
 287
 288   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 289 else
 290   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 291
 292   if test "x$enable_debug" = "xno"; then
 293     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 294   fi
 295 fi
 296
 297 if test "x$enable_visibility" = "xno"; then
 298   GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DDISABLE_VISIBILITY"
 299 fi
 300
 301 # Ensure MSVC-compatible struct packing convention is used when
 302 # compiling for Win32 with gcc.
 303 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 304 # gcc2 uses "-fnative-struct".
 305 if test x"$glib_native_win32" = xyes; then
 306   if test x"$GCC" = xyes; then
 307     msnative_struct=''
 308     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 309     if test -z "$ac_cv_prog_CC"; then
 310       our_gcc="$CC"
 311     else
 312       our_gcc="$ac_cv_prog_CC"
 313     fi
 314     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 315       2.)
 316         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 317           msnative_struct='-fnative-struct'
 318         fi
 319         ;;
 320       *)
 321         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 322           msnative_struct='-mms-bitfields'
 323         fi
 324         ;;
 325     esac
 326     if test x"$msnative_struct" = x ; then
 327       AC_MSG_RESULT([no way])
 328       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 329     else
 330       CFLAGS="$CFLAGS $msnative_struct"
 331       AC_MSG_RESULT([${msnative_struct}])
 332     fi
 333   fi
 334 fi
 335 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 336 AC_SUBST(GLIB_EXTRA_CFLAGS)
 337
 338 AC_EXEEXT
 339
 340 # define a MAINT-like variable REBUILD which is set if Perl
 341 # and awk are found, so autogenerated sources can be rebuilt
 342 AC_PROG_AWK
 343 AC_CHECK_PROGS(PERL, [perl5 perl])
 344 # We would like indent, but don't require it.
 345 AC_CHECK_PROG(INDENT, indent, indent)
 346 REBUILD=\#
 347 if test "x$enable_rebuilds" = "xyes" && \
 348      test -n "$PERL" && \
 349      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 350      test -n "$AWK" ; then
 351   REBUILD=
 352 fi
 353 AC_SUBST(REBUILD)
 354
 355 # Need full path to Perl for glib-mkenums
 356 #
 357 if test "x$PERL" != x ; then
 358   AC_PATH_PROG(PERL_PATH, [$PERL])
 359 fi
 360 if test "x$PERL_PATH" = x ; then
 361   PERL_PATH="/usr/bin/env perl"
 362 fi
 363 AC_SUBST(PERL_PATH)
 364
 365 # Need suitable python path for greport
 366 AM_PATH_PYTHON(2.4,,PYTHON="/usr/bin/env python2.4")
 367
 368
 369 dnl ***********************
 370 dnl *** Tests for iconv ***
 371 dnl ***********************
 372 dnl
 373 dnl We do this before the gettext checks, to avoid distortion
 374
 375 dnl On Windows we use a native implementation
 376
 377 if test x"$glib_native_win32" = xyes; then
 378   with_libiconv=native
 379 else
 380   AC_ARG_WITH(libiconv,
 381               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 382                               [use the libiconv library])],,
 383               [with_libiconv=maybe])
 384
 385   found_iconv=no
 386   case $with_libiconv in
 387     maybe)
 388       # Check in the C library first
 389       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 390       # Check if we have GNU libiconv
 391       if test $found_iconv = "no"; then
 392         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 393       fi
 394       # Check if we have a iconv in -liconv, possibly from vendor
 395       if test $found_iconv = "no"; then
 396         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 397       fi
 398       ;;
 399     no)
 400       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 401       ;;
 402     gnu|yes)
 403       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 404       ;;
 405     native)
 406       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 407       ;;
 408   esac
 409
 410   if test "x$found_iconv" = "xno" ; then
 411      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 412   fi
 413 fi
 414
 415 gl_GLIBC21
 416 AC_ARG_ENABLE(iconv-cache,
 417               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 418                               [cache iconv descriptors [default=auto]])],,
 419               [enable_iconv_cache=auto])
 420
 421 AC_MSG_CHECKING([Whether to cache iconv descriptors])
 422 case $enable_iconv_cache in
 423   auto)
 424     if test $ac_cv_gnu_library_2_1 = yes; then
 425       enable_iconv_cache=no
 426     else
 427       enable_iconv_cache=yes
 428     fi
 429   ;;
 430   yes|no)
 431   ;;
 432   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 433   ;;
 434 esac
 435
 436 if test $enable_iconv_cache = yes; then
 437    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 438 fi
 439
 440 AC_MSG_RESULT($enable_iconv_cache)
 441
 442
 443 dnl
 444 dnl gettext support
 445 dnl
 446
 447 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 448 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 449 GLIB_GNU_GETTEXT
 450
 451 if test "$gt_cv_have_gettext" != "yes" ; then
 452   AC_MSG_ERROR([
 453 *** You must have either have gettext support in your C library, or use the
 454 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 455 ])
 456 fi
 457
 458 LIBS="$INTLLIBS $LIBS"
 459
 460 GETTEXT_PACKAGE=glib20
 461 AC_SUBST(GETTEXT_PACKAGE)
 462 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 463   [Define the gettext package to be used])
 464
 465 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 466
 467 dnl
 468 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 469 dnl
 470
 471 if test x"$glib_native_win32" != xyes; then
 472   if test x$with_libiconv != xno ; then
 473     case " $INTLLIBS " in
 474     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 475     *) ICONV_LIBS="-liconv" ;;
 476     esac
 477   fi
 478 fi
 479 AC_SUBST(ICONV_LIBS)
 480
 481 case $with_libiconv in
 482   gnu)
 483     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 484     ;;
 485   native)
 486     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 487     ;;
 488 esac
 489
 490 dnl Initialize libtool
 491 AM_DISABLE_STATIC
 492 AC_LIBTOOL_WIN32_DLL
 493 AM_PROG_LIBTOOL
 494 dnl when using libtool 2.x create libtool early, because it's used in configure
 495 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 496
 497
 498 if test "x$GCC" = "xyes"; then
 499   case " $CFLAGS " in
 500   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 501   *) CFLAGS="$CFLAGS -Wall" ;;
 502   esac
 503 fi
 504
 505 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES"
 506
 507 if test "$glib_native_win32" = "yes"; then
 508   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 509     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 510   fi
 511   if test x$enable_static = xyes; then
 512     glib_win32_static_compilation=yes
 513     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 514 #define GOBJECT_STATIC_COMPILATION 1"
 515     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 516   fi
 517 fi
 518 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 519
 520 dnl
 521 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 522 dnl
 523 if test $cross_compiling != yes ; then
 524     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 525     glib_save_LIBS=$LIBS
 526     LIBS="$LIBS -lm"
 527     AC_TRY_RUN([#include <math.h>
 528                  int main (void) { return (log(1) != log(1.)); }],
 529          AC_MSG_RESULT(none needed),
 530          glib_save_CFLAGS=$CFLAGS
 531          CFLAGS="$CFLAGS -std1"
 532          AC_TRY_RUN([#include <math.h>
 533                      int main (void) { return (log(1) != log(1.)); }],
 534              AC_MSG_RESULT(-std1),
 535              AC_MSG_RESULT()
 536              CFLAGS=$glib_save_CFLAGS
 537              AC_MSG_WARN(
 538                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 539          )
 540     )
 541     LIBS=$glib_save_LIBS
 542 fi
 543
 544 dnl NeXTStep cc seems to need this
 545 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 546 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 547   AC_MSG_RESULT(none needed),
 548   glib_save_CFLAGS=$CFLAGS
 549   CFLAGS="$CFLAGS -posix"
 550   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 551     AC_MSG_RESULT(-posix),
 552     AC_MSG_RESULT()
 553     CFLAGS=$glib_save_CFLAGS
 554     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 555
 556 # Checks for header files.
 557 AC_HEADER_STDC
 558
 559 # Checks for library functions.
 560 AC_FUNC_VPRINTF
 561 AC_FUNC_ALLOCA
 562 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 563 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 564
 565 AC_CHECK_SIZEOF(char)
 566 AC_CHECK_SIZEOF(short)
 567 AC_CHECK_SIZEOF(long)
 568 AC_CHECK_SIZEOF(int)
 569 AC_CHECK_SIZEOF(void *)
 570 AC_CHECK_SIZEOF(long long)
 571 AC_CHECK_SIZEOF(__int64)
 572
 573 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 574   :
 575 else
 576   AC_MSG_ERROR([
 577 *** GLib requires a 64 bit type. You might want to consider
 578 *** using the GNU C compiler.
 579 ])
 580 fi
 581
 582 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 583         # long long is a 64 bit integer.
 584         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 585         AC_CACHE_VAL(glib_cv_long_long_format,[
 586                 for format in ll q I64; do
 587                   AC_TRY_RUN([#include <stdio.h>
 588                         int main()
 589                         {
 590                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 591                           char buffer[1000];
 592                           sprintf (buffer, "%${format}u", a);
 593                           sscanf (buffer, "%${format}u", &b);
 594                           exit (b!=a);
 595                         }
 596                         ],
 597                         [glib_cv_long_long_format=${format}
 598                         break],
 599                         [],[:])
 600                 done])
 601         if test -n "$glib_cv_long_long_format"; then
 602           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 603           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 604           if test x"$glib_cv_long_long_format" = xI64; then
 605             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 606           fi
 607         else
 608           AC_MSG_RESULT(none)
 609         fi
 610 elif test x$ac_cv_sizeof___int64 = x8; then
 611         # __int64 is a 64 bit integer.
 612         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 613         # We know this is MSVCRT.DLL, and what the formats are
 614         glib_cv_long_long_format=I64
 615         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 616         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 617         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 618 fi
 619
 620 dnl long doubles were not used, and a portability problem
 621 dnl AC_C_LONG_DOUBLE
 622 AC_C_CONST
 623
 624 dnl ok, here we try to check whether the systems prototypes for
 625 dnl malloc and friends actually match the prototypes provided
 626 dnl by gmem.h (keep in sync). i currently only know how to check
 627 dnl this reliably with gcc (-Werror), improvements for other
 628 dnl compilers are apprechiated.
 629 SANE_MALLOC_PROTOS=no
 630 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 631 glib_save_CFLAGS=$CFLAGS
 632 if test "x$GCC" = "xyes"; then
 633   CFLAGS="$CFLAGS -Werror"
 634   AC_TRY_COMPILE([#include <stdlib.h>], [
 635     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 636     void* (*my_malloc_p)  (size_t)         = malloc;
 637     void  (*my_free_p)    (void*)          = free;
 638     void* (*my_realloc_p) (void*, size_t)  = realloc;
 639     my_calloc_p = 0;
 640     my_malloc_p = 0;
 641     my_free_p = 0;
 642     my_realloc_p = 0;
 643   ],
 644     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 645       [Define if you have correct malloc prototypes])
 646     SANE_MALLOC_PROTOS=yes)
 647 fi
 648 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 649 CFLAGS=$glib_save_CFLAGS
 650
 651 dnl
 652 dnl check in which direction the stack grows
 653 dnl
 654 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 655         AC_TRY_RUN([
 656         volatile int *a = 0, *b = 0;
 657         void foo (void);
 658         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 659         void foo (void) { volatile int x = 5; b = &x; }
 660         ],
 661         glib_cv_stack_grows=no
 662         ,
 663         glib_cv_stack_grows=yes
 664         ,)
 665 ])
 666
 667 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 668 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 669 dnl actually supported.
 670 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 671         AC_COMPILE_IFELSE([
 672         __inline int foo () { return 0; }
 673         int main () { return foo (); }
 674         ],
 675         glib_cv_has__inline=yes
 676         ,
 677         glib_cv_has__inline=no
 678         ,)
 679 ])
 680 case x$glib_cv_has__inline in
 681 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 682 esac
 683 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 684         AC_COMPILE_IFELSE([
 685         __inline__ int foo () { return 0; }
 686         int main () { return foo (); }
 687         ],
 688         glib_cv_has__inline__=yes
 689         ,
 690         glib_cv_has__inline__=no
 691         ,)
 692 ])
 693 case x$glib_cv_has__inline__ in
 694 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 695 esac
 696 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 697         AC_COMPILE_IFELSE([
 698         #undef inline
 699         inline int foo () { return 0; }
 700         int main () { return foo (); }
 701         ],
 702         glib_cv_hasinline=yes
 703         ,
 704         glib_cv_hasinline=no
 705         ,)
 706 ])
 707 case x$glib_cv_hasinline in
 708 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 709 esac
 710
 711 # if we can use inline functions in headers
 712 AC_MSG_CHECKING(if inline functions in headers work)
 713 AC_LINK_IFELSE([
 714 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 715 #  undef inline
 716 #  define inline __inline__
 717 #elif !defined (G_HAVE_INLINE)
 718 #  undef inline
 719 #  if defined (G_HAVE___INLINE__)
 720 #    define inline __inline__
 721 #  elif defined (G_HAVE___INLINE)
 722 #    define inline __inline
 723 #  endif
 724 #endif
 725
 726 int glib_test_func2 (int);
 727
 728 static inline int
 729 glib_test_func1 (void) {
 730   return glib_test_func2 (1);
 731 }
 732
 733 int
 734 main (void) {
 735   int i = 1;
 736 }],[g_can_inline=yes],[g_can_inline=no])
 737 AC_MSG_RESULT($g_can_inline)
 738
 739 dnl *** check for working do while(0) macros ***
 740 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 741         AC_TRY_COMPILE([],[
 742         #define STMT_START do
 743         #define STMT_END while(0)
 744         #define STMT_TEST STMT_START { i = 0; } STMT_END
 745         int main(void) { int i = 1; STMT_TEST; return i; }],
 746         [g_cv_support_dowhile_macros=yes],
 747         [g_cv_support_dowhile_macros=no],
 748         [g_cv_support_dowhile_macros=yes])
 749 ])
 750 if test x$g_cv_support_dowhile_macros = xyes; then
 751   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 752 fi
 753
 754 # check for flavours of varargs macros
 755 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 756 AC_TRY_COMPILE([],[
 757 int a(int p1, int p2, int p3);
 758 #define call_a(...) a(1,__VA_ARGS__)
 759 call_a(2,3);
 760 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 761 AC_MSG_RESULT($g_have_iso_c_varargs)
 762
 763 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 764 if test "$CXX" = ""; then
 765 dnl No C++ compiler
 766   g_have_iso_cxx_varargs=no
 767 else
 768   AC_LANG_CPLUSPLUS
 769   AC_TRY_COMPILE([],[
 770 int a(int p1, int p2, int p3);
 771 #define call_a(...) a(1,__VA_ARGS__)
 772 call_a(2,3);
 773 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 774   AC_LANG_C
 775 fi
 776 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 777
 778 AC_MSG_CHECKING(for GNUC varargs macros)
 779 AC_TRY_COMPILE([],[
 780 int a(int p1, int p2, int p3);
 781 #define call_a(params...) a(1,params)
 782 call_a(2,3);
 783 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 784 AC_MSG_RESULT($g_have_gnuc_varargs)
 785
 786 # check for GNUC visibility support
 787 AC_MSG_CHECKING(for GNUC visibility attribute)
 788 GLIB_CHECK_COMPILE_WARNINGS([
 789 void
 790 __attribute__ ((visibility ("hidden")))
 791      f_hidden (void)
 792 {
 793 }
 794 void
 795 __attribute__ ((visibility ("internal")))
 796      f_internal (void)
 797 {
 798 }
 799 void
 800 __attribute__ ((visibility ("protected")))
 801      f_protected (void)
 802 {
 803 }
 804 void
 805 __attribute__ ((visibility ("default")))
 806      f_default (void)
 807 {
 808 }
 809 int main (int argc, char **argv)
 810 {
 811         f_hidden();
 812         f_internal();
 813         f_protected();
 814         f_default();
 815         return 0;
 816 }
 817 ],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 818 AC_MSG_RESULT($g_have_gnuc_visibility)
 819 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 820
 821 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 822 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 823 #else
 824 # include "error: this is not Sun Studio."
 825 #endif
 826 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 827 AC_MSG_RESULT($g_have_sunstudio_visibility)
 828 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 829
 830 # check for bytesex stuff
 831 AC_C_BIGENDIAN
 832 if test x$ac_cv_c_bigendian = xuniversal ; then
 833 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 834 #else
 835 #error Not a big endian.
 836 #endif],
 837     ac_cv_c_bigendian=yes
 838     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 839 #else
 840 #error Not a little endian.
 841 #endif],
 842     ac_cv_c_bigendian=no
 843     ,AC_MSG_WARN([Could not determine endianness.])))
 844 fi
 845
 846
 847 # check for header files
 848 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 849 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 850 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h sched.h malloc.h])
 851 AC_CHECK_HEADERS([sys/vfs.h sys/mount.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 852 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h sys/sysctl.h fstab.h])
 853 AC_CHECK_HEADERS([sys/uio.h])
 854
 855 # check for structure fields
 856 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 857 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 858 #include <sys/stat.h>
 859 #include <unistd.h>
 860 #ifdef HAVE_SYS_STATFS_H
 861 #include <sys/statfs.h>
 862 #endif
 863 #ifdef HAVE_SYS_PARAM_H
 864 #include <sys/param.h>
 865 #endif
 866 #ifdef HAVE_SYS_MOUNT_H
 867 #include <sys/mount.h>
 868 #endif])
 869 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 870 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 871
 872 # Checks for libcharset
 873 AM_LANGINFO_CODESET
 874 gl_GLIBC21
 875 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 876 AC_CHECK_FUNCS(setlocale)
 877
 878 # check additional type sizes
 879 AC_CHECK_SIZEOF(size_t)
 880
 881 dnl Try to figure out whether gsize, gssize should be long or int
 882 AC_MSG_CHECKING([for the appropriate definition for size_t])
 883
 884 case $ac_cv_sizeof_size_t in
 885   $ac_cv_sizeof_short)
 886       glib_size_type=short
 887       ;;
 888   $ac_cv_sizeof_int)
 889       glib_size_type=int
 890       ;;
 891   $ac_cv_sizeof_long)
 892       glib_size_type=long
 893       ;;
 894   $ac_cv_sizeof_long_long)
 895       glib_size_type='long long'
 896       ;;
 897   $ac_cv_sizeof__int64)
 898       glib_size_type='__int64'
 899       ;;
 900   *)  AC_MSG_ERROR([No type matching size_t in size])
 901       ;;
 902 esac
 903
 904 dnl If int/long are the same size, we see which one produces
 905 dnl warnings when used in the location as size_t. (This matters
 906 dnl on AIX with xlc)
 907 dnl
 908 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 909    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 910   GLIB_CHECK_COMPILE_WARNINGS([
 911 #if defined(_AIX) && !defined(__GNUC__)
 912 #pragma options langlvl=stdc89
 913 #endif
 914 #include <stddef.h>
 915 int main ()
 916 {
 917   size_t s = 1;
 918   unsigned int *size_int = &s;
 919   return (int)*size_int;
 920 }
 921     ],glib_size_type=int,
 922       [GLIB_CHECK_COMPILE_WARNINGS([
 923 #if defined(_AIX) && !defined(__GNUC__)
 924 #pragma options langlvl=stdc89
 925 #endif
 926 #include <stddef.h>
 927 int main ()
 928 {
 929    size_t s = 1;
 930    unsigned long *size_long = &s;
 931    return (int)*size_long;
 932 }
 933         ],glib_size_type=long)])
 934 fi
 935
 936 AC_MSG_RESULT(unsigned $glib_size_type)
 937
 938 # Check for some functions
 939 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk)
 940 AC_CHECK_FUNCS(chown lchown fchmod fchown link statvfs statfs utimes getgrgid getpwuid)
 941 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getmntinfo)
 942 # Check for high-resolution sleep functions
 943 AC_CHECK_FUNCS(nanosleep nsleep)
 944
 945 AC_CHECK_HEADERS(crt_externs.h)
 946 AC_CHECK_FUNCS(_NSGetEnviron)
 947
 948 AC_FUNC_VSNPRINTF_C99
 949 AC_FUNC_PRINTF_UNIX98
 950
 951 # Internet address families
 952 if test $glib_native_win32 = yes; then
 953   glib_inet_includes=["
 954 #include <winsock2.h>
 955   "]
 956 else
 957   glib_inet_includes=["
 958 #include <sys/types.h>
 959 #include <sys/socket.h>
 960   "]
 961 fi
 962
 963 glib_failed=false
 964 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
 965 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
 966 # winsock defines this even though it doesn't support it
 967 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
 968 if $glib_failed ; then
 969   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
 970 fi
 971
 972 glib_failed=false
 973 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
 974 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
 975 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
 976 if $glib_failed ; then
 977   AC_MSG_ERROR([Could not determine values for MSG_* constants])
 978 fi
 979
 980 AC_CHECK_FUNCS(getprotobyname_r endservent)
 981 AC_CHECK_HEADERS([netdb.h winsock2.h mswsock.h])
 982
 983 # For gio/libasyncns
 984 if test $glib_native_win32 = no; then
 985   AC_CHECK_FUNCS(strndup setresuid setreuid)
 986   AC_CHECK_HEADERS(sys/prctl.h arpa/nameser_compat.h)
 987   AC_CHECK_FUNC(res_query, ,
 988     [AC_CHECK_LIB(resolv, res_query, [ LIBASYNCNS_LIBADD="-lresolv" ],
 989       [ save_libs="$LIBS"
 990         LIBS="-lresolv $LIBS"
 991         AC_MSG_CHECKING([for res_query in -lresolv (alternate version)])
 992         AC_LINK_IFELSE(
 993           [AC_LANG_PROGRAM([[#include <resolv.h>]], [[res_query(0,0,0,0,0)]])],
 994           [ AC_MSG_RESULT(yes)
 995           LIBASYNCNS_LIBADD="-lresolv" ],
 996           [ AC_MSG_RESULT(no)
 997             AC_CHECK_LIB(bind, res_query,
 998               [ LIBASYNCNS_LIBADD="-lbind" ],
 999             [ AC_MSG_ERROR(res_query not found) ] ) ] )
1000         LIBS="$save_libs"
1001       ] )
1002     ]
1003   )
1004   AC_SUBST(LIBASYNCNS_LIBADD)
1005 fi
1006
1007 case $host in
1008   *-*-solaris* )
1009      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1010      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1011      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1012      ;;
1013 esac
1014
1015 dnl
1016 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1017 dnl
1018 if test "$ac_cv_func_statfs" = yes ; then
1019   AC_MSG_CHECKING([number of arguments to statfs()])
1020   AC_TRY_COMPILE([#include <unistd.h>
1021   #ifdef HAVE_SYS_PARAM_H
1022   #include <sys/param.h>
1023   #endif
1024   #ifdef HAVE_SYS_VFS_H
1025   #include <sys/vfs.h>
1026   #endif
1027   #ifdef HAVE_SYS_MOUNT_H
1028   #include <sys/mount.h>
1029   #endif
1030   #ifdef HAVE_SYS_STATFS_H
1031   #include <sys/statfs.h>
1032   #endif], [struct statfs st;
1033   statfs(NULL, &st);],[
1034     AC_MSG_RESULT([2])
1035     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1036     AC_TRY_COMPILE([#include <unistd.h>
1037   #ifdef HAVE_SYS_PARAM_H
1038   #include <sys/param.h>
1039   #endif
1040   #ifdef HAVE_SYS_VFS_H
1041   #include <sys/vfs.h>
1042   #endif
1043   #ifdef HAVE_SYS_MOUNT_H
1044   #include <sys/mount.h>
1045   #endif
1046   #ifdef HAVE_SYS_STATFS_H
1047   #include <sys/statfs.h>
1048   #endif], [struct statfs st;
1049   statfs(NULL, &st, sizeof (st), 0);],[
1050       AC_MSG_RESULT([4])
1051       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1052       AC_MSG_RESULT(unknown)
1053       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1054 fi
1055
1056 #
1057 # Check whether to use an included printf
1058 #
1059
1060 AC_ARG_ENABLE(included-printf,
1061               [AC_HELP_STRING([--enable-included-printf],
1062                               [use included printf [default=auto]])],
1063               enable_included_printf="$enableval")
1064
1065 need_included_printf=no
1066 if test "x$enable_included_printf" = "xyes" ; then
1067   need_included_printf=yes
1068 fi
1069 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1070   need_included_printf=yes
1071 fi
1072 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1073   need_included_printf=yes
1074 fi
1075 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1076    test -z "$glib_cv_long_long_format" ; then
1077   need_included_printf=yes
1078 fi
1079
1080 if test "x$enable_included_printf" = "xno" &&
1081    test "x$need_included_printf" = "xyes" ; then
1082   AC_MSG_ERROR([
1083 *** Your C library's printf doesn't appear to have the features that
1084 *** GLib needs, but you specified --enable-included-printf=no.])
1085 fi
1086
1087 enable_included_printf=$need_included_printf
1088
1089 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1090 if test "$enable_included_printf" != "yes" ; then
1091   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1092 else
1093   if test -z "$glib_cv_long_long_format" ; then
1094     glib_cv_long_long_format="ll"
1095   fi
1096   AC_DEFINE(HAVE_VASPRINTF,1)
1097 fi
1098
1099 # Checks needed for gnulib vasnprintf
1100 bh_C_SIGNED
1101 jm_AC_TYPE_LONG_LONG
1102 gt_TYPE_LONGDOUBLE
1103 gt_TYPE_WCHAR_T
1104 gt_TYPE_WINT_T
1105 AC_TYPE_SIZE_T
1106 AC_CHECK_TYPES(ptrdiff_t)
1107 jm_AC_TYPE_INTMAX_T
1108 AC_CHECK_FUNCS([snprintf wcslen])
1109 AC_FUNC_SNPRINTF_C99
1110
1111 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1112 # The check is borrowed from the PERL Configure script.
1113 if test "$ac_cv_func_memmove" != "yes"; then
1114   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1115     glib_cv_working_bcopy,[AC_TRY_RUN([
1116       int main() {
1117         char buf[128], abc[128], *b;
1118         int len, off, align;
1119         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1120         for (align = 7; align >= 0; align--) {
1121           for (len = 36; len; len--) {
1122             b = buf+align; bcopy(abc, b, len);
1123             for (off = 1; off <= len; off++) {
1124               bcopy(b, b+off, len); bcopy(b+off, b, len);
1125                 if (bcmp(b, abc, len)) return(1);
1126             }
1127           }
1128         }
1129         return(0);
1130       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1131
1132   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1133   if test "$glib_cv_working_bcopy" = "yes"; then
1134     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1135   fi
1136 fi
1137
1138 # Check for sys_errlist
1139 AC_MSG_CHECKING(for sys_errlist)
1140 AC_TRY_LINK(, [
1141 extern char *sys_errlist[];
1142 extern int sys_nerr;
1143 sys_errlist[sys_nerr-1][0] = 0;
1144 ], glib_ok=yes, glib_ok=no)
1145 AC_MSG_RESULT($glib_ok)
1146 if test "$glib_ok" = "no"; then
1147     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
1148 fi
1149
1150 # Check for sys_siglist
1151 AC_MSG_CHECKING(for sys_siglist)
1152 AC_TRY_LINK(, [
1153 extern char *sys_siglist[];
1154 exit (sys_siglist[0]);
1155 ], glib_ok=yes, glib_ok=no)
1156 AC_MSG_RESULT($glib_ok)
1157 if test "$glib_ok" = "no"; then
1158     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
1159 fi
1160
1161 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
1162 AC_MSG_CHECKING(for sys_siglist declaration)
1163 AC_TRY_COMPILE([#include <signal.h>], [
1164 strlen (sys_siglist[0]);
1165 ], glib_ok=yes, glib_ok=no)
1166 AC_MSG_RESULT($glib_ok)
1167 if test "$glib_ok" = "no"; then
1168     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
1169 fi
1170
1171 # Check if <sys/select.h> needs to be included for fd_set
1172 AC_MSG_CHECKING([for fd_set])
1173 AC_TRY_COMPILE([#include <sys/types.h>],
1174         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1175 if test "$gtk_ok" = "yes"; then
1176     AC_MSG_RESULT([yes, found in sys/types.h])
1177 else
1178     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1179     if test "$gtk_ok" = "yes"; then
1180         # *** FIXME: give it a different name
1181         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1182         AC_MSG_RESULT([yes, found in sys/select.h])
1183     else
1184         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1185         AC_MSG_RESULT(no)
1186     fi
1187 fi
1188
1189 dnl *** check for sane realloc() ***
1190 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1191         AC_TRY_RUN([#include <stdlib.h>
1192         int main() {
1193           return realloc (0, sizeof (int)) == 0;
1194         }],
1195         [glib_cv_sane_realloc=yes],
1196         [glib_cv_sane_realloc=no],
1197         [glib_cv_sane_realloc=yes])
1198 ])
1199 if test x$glib_cv_sane_realloc = xyes; then
1200   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1201 fi
1202
1203 dnl Check for nl_langinfo and CODESET
1204 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1205         AC_TRY_COMPILE([#include <langinfo.h>],
1206                 [char *codeset = nl_langinfo (CODESET);],
1207                 [glib_cv_langinfo_codeset=yes],
1208                 [glib_cv_langinfo_codeset=no])])
1209 if test x$glib_cv_langinfo_codeset = xyes; then
1210   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1211 fi
1212
1213 dnl ****************************************
1214 dnl *** posix_memalign                   ***
1215 dnl ****************************************
1216 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1217 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1218     glib_cv_compliant_posix_memalign=0
1219     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1220         AC_TRY_RUN([
1221                 #define _XOPEN_SOURCE 600
1222                 #include <stdlib.h> /* posix_memalign() should be defined here */
1223                 /* some systems break if #include <malloc.h> used */
1224                 static void test_memalign (size_t boundary, size_t size) {
1225                     void *mem = 0;
1226                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1227                         exit (1);
1228                     else
1229                       free (mem);
1230                 }
1231                 int main() {
1232                     test_memalign (  128,   128 - 2 * sizeof (void*));
1233                     test_memalign (  256,   256 - 2 * sizeof (void*));
1234                     test_memalign (  512,   512 - 2 * sizeof (void*));
1235                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1236                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1237                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1238                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1239                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1240                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1241                     exit (0); /* success */
1242                 }
1243                 ],
1244             [glib_cv_compliant_posix_memalign=1], [], [:])
1245       :
1246     fi
1247     ])
1248 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1249     AC_MSG_RESULT(yes)
1250     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1251 else
1252     AC_MSG_RESULT(no)
1253 fi
1254
1255
1256 dnl ****************************************
1257 dnl *** strlcpy/strlcat                  ***
1258 dnl ****************************************
1259 # Check for strlcpy
1260 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1261 AC_TRY_RUN([#include <stdlib.h>
1262 #include <string.h>
1263 int main() {
1264   char p[10];
1265   (void) strlcpy (p, "hi", 10);
1266   if (strlcat (p, "bye", 0) != 3)
1267     return 1;
1268   return 0;
1269 }], glib_cv_have_strlcpy=yes,
1270     glib_cv_have_strlcpy=no,
1271     glib_cv_have_strlcpy=no)])
1272 if test "$glib_cv_have_strlcpy" = "yes"; then
1273     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1274 fi
1275
1276
1277 dnl **********************
1278 dnl *** va_copy checks ***
1279 dnl **********************
1280 dnl we currently check for all three va_copy possibilities, so we get
1281 dnl all results in config.log for bug reports.
1282 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1283         AC_LINK_IFELSE([#include <stdarg.h>
1284 #include <stdlib.h>
1285         void f (int i, ...) {
1286         va_list args1, args2;
1287         va_start (args1, i);
1288         va_copy (args2, args1);
1289         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1290           exit (1);
1291         va_end (args1); va_end (args2);
1292         }
1293         int main() {
1294           f (0, 42);
1295           return 0;
1296         }],
1297         [glib_cv_va_copy=yes],
1298         [glib_cv_va_copy=no])
1299 ])
1300 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1301         AC_LINK_IFELSE([#include <stdarg.h>
1302 #include <stdlib.h>
1303         void f (int i, ...) {
1304         va_list args1, args2;
1305         va_start (args1, i);
1306         __va_copy (args2, args1);
1307         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1308           exit (1);
1309         va_end (args1); va_end (args2);
1310         }
1311         int main() {
1312           f (0, 42);
1313           return 0;
1314         }],
1315         [glib_cv___va_copy=yes],
1316         [glib_cv___va_copy=no])
1317 ])
1318
1319 if test "x$glib_cv_va_copy" = "xyes"; then
1320   g_va_copy_func=va_copy
1321 else if test "x$glib_cv___va_copy" = "xyes"; then
1322   g_va_copy_func=__va_copy
1323 fi
1324 fi
1325
1326 if test -n "$g_va_copy_func"; then
1327   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1328 fi
1329
1330 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1331         AC_TRY_RUN([#include <stdarg.h>
1332 #include <stdlib.h>
1333         void f (int i, ...) {
1334         va_list args1, args2;
1335         va_start (args1, i);
1336         args2 = args1;
1337         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1338           exit (1);
1339         va_end (args1); va_end (args2);
1340         }
1341         int main() {
1342           f (0, 42);
1343           return 0;
1344         }],
1345         [glib_cv_va_val_copy=yes],
1346         [glib_cv_va_val_copy=no],
1347         [glib_cv_va_val_copy=yes])
1348 ])
1349
1350 if test "x$glib_cv_va_val_copy" = "xno"; then
1351   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1352 fi
1353
1354 dnl ***********************
1355 dnl *** g_module checks ***
1356 dnl ***********************
1357 G_MODULE_LIBS=
1358 G_MODULE_LIBS_EXTRA=
1359 G_MODULE_PLUGIN_LIBS=
1360 if test x"$glib_native_win32" = xyes; then
1361   dnl No use for this on Win32
1362   G_MODULE_LDFLAGS=
1363 else
1364   export SED
1365   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1366 fi
1367 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1368 G_MODULE_NEED_USCORE=0
1369 G_MODULE_BROKEN_RTLD_GLOBAL=0
1370 G_MODULE_HAVE_DLERROR=0
1371 dnl *** force native WIN32 shared lib loader
1372 if test -z "$G_MODULE_IMPL"; then
1373   case "$host" in
1374   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1375   esac
1376 fi
1377 dnl *** force native AIX library loader
1378 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1379 if test -z "$G_MODULE_IMPL"; then
1380   case "$host" in
1381   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1382   esac
1383 fi
1384 dnl *** dlopen() and dlsym() in system libraries
1385 if test -z "$G_MODULE_IMPL"; then
1386         AC_CHECK_FUNC(dlopen,
1387                       [AC_CHECK_FUNC(dlsym,
1388                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1389                       [])
1390 fi
1391 dnl *** load_image (BeOS)
1392 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1393   AC_CHECK_LIB(root, load_image,
1394       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1395       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1396       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1397       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1398       [])
1399 fi
1400 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1401 if test -z "$G_MODULE_IMPL"; then
1402         AC_CHECK_FUNC(NSLinkModule,
1403                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1404                        G_MODULE_NEED_USCORE=1],
1405                       [])
1406 fi
1407 dnl *** dlopen() and dlsym() in libdl
1408 if test -z "$G_MODULE_IMPL"; then
1409         AC_CHECK_LIB(dl, dlopen,
1410                      [AC_CHECK_LIB(dl, dlsym,
1411                                    [G_MODULE_LIBS=-ldl
1412                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1413                      [])
1414 fi
1415 dnl *** shl_load() in libdld (HP-UX)
1416 if test -z "$G_MODULE_IMPL"; then
1417         AC_CHECK_LIB(dld, shl_load,
1418                 [G_MODULE_LIBS=-ldld
1419                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1420                 [])
1421 fi
1422 dnl *** additional checks for G_MODULE_IMPL_DL
1423 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1424         LIBS_orig="$LIBS"
1425         LDFLAGS_orig="$LDFLAGS"
1426         LIBS="$G_MODULE_LIBS $LIBS"
1427         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1428 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1429         echo "void glib_plugin_test(void) { }" > plugin.c
1430         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1431                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1432         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1433                 glib_cv_rtldglobal_broken,[
1434                 AC_TRY_RUN([
1435 #include <dlfcn.h>
1436 #ifndef RTLD_GLOBAL
1437 #  define RTLD_GLOBAL 0
1438 #endif
1439 #ifndef RTLD_LAZY
1440 #  define RTLD_LAZY 0
1441 #endif
1442 int glib_plugin_test;
1443 int main () {
1444     void *handle, *global, *local;
1445     global = &glib_plugin_test;
1446     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1447     if (!handle) return 0;
1448     local = dlsym (handle, "glib_plugin_test");
1449     return global == local;
1450 }                       ],
1451                         [glib_cv_rtldglobal_broken=no],
1452                         [glib_cv_rtldglobal_broken=yes],
1453                         [glib_cv_rtldglobal_broken=no])
1454                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1455                 rmdir .libs 2>/dev/null
1456         ])
1457         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1458                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1459         else
1460                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1461         fi
1462 dnl *** check whether we need preceeding underscores
1463         AC_CACHE_CHECK([for preceeding underscore in symbols],
1464                 glib_cv_uscore,[
1465                 AC_TRY_RUN([#include <dlfcn.h>
1466                 int glib_underscore_test (void) { return 42; }
1467                 int main() {
1468                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1469                   handle = dlopen ((void*)0, 0);
1470                   if (handle) {
1471                     f1 = dlsym (handle, "glib_underscore_test");
1472                     f2 = dlsym (handle, "_glib_underscore_test");
1473                   } return (!f2 || f1);
1474                 }],
1475                         [glib_cv_uscore=yes],
1476                         [glib_cv_uscore=no],
1477                         [])
1478                 rm -f plugin.c plugin.$ac_objext plugin.lo
1479         ])
1480         GLIB_ASSERT_SET(glib_cv_uscore)
1481         if test "x$glib_cv_uscore" = "xyes"; then
1482                 G_MODULE_NEED_USCORE=1
1483         else
1484                 G_MODULE_NEED_USCORE=0
1485         fi
1486
1487         LDFLAGS="$LDFLAGS_orig"
1488 dnl *** check for having dlerror()
1489         AC_CHECK_FUNC(dlerror,
1490                 [G_MODULE_HAVE_DLERROR=1],
1491                 [G_MODULE_HAVE_DLERROR=0])
1492         LIBS="$LIBS_orig"
1493 fi
1494 dnl *** done, have we got an implementation?
1495 if test -z "$G_MODULE_IMPL"; then
1496         G_MODULE_IMPL=0
1497         G_MODULE_SUPPORTED=false
1498 else
1499         G_MODULE_SUPPORTED=true
1500 fi
1501
1502 AC_MSG_CHECKING(for the suffix of module shared libraries)
1503 export SED
1504 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1505 eval $shrext_cmds
1506 module=yes eval std_shrext=$shrext_cmds
1507 # chop the initial dot
1508 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1509 AC_MSG_RESULT(.$glib_gmodule_suffix)
1510 # any reason it may fail?
1511 if test "x$glib_gmodule_suffix" = x; then
1512         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1513 fi
1514
1515 AC_SUBST(G_MODULE_SUPPORTED)
1516 AC_SUBST(G_MODULE_IMPL)
1517 AC_SUBST(G_MODULE_LIBS)
1518 AC_SUBST(G_MODULE_LIBS_EXTRA)
1519 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1520 AC_SUBST(G_MODULE_LDFLAGS)
1521 AC_SUBST(G_MODULE_HAVE_DLERROR)
1522 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1523 AC_SUBST(G_MODULE_NEED_USCORE)
1524 AC_SUBST(GLIB_DEBUG_FLAGS)
1525
1526 dnl **********************
1527 dnl *** g_spawn checks ***
1528 dnl **********************
1529
1530 AC_MSG_CHECKING(for gspawn implementation)
1531 case "$host" in
1532   *-*-mingw*)
1533     GSPAWN=gspawn-win32.lo
1534     ;;
1535   *)
1536     GSPAWN=gspawn.lo
1537     ;;
1538 esac
1539 AC_MSG_RESULT($GSPAWN)
1540 AC_SUBST(GSPAWN)
1541
1542 dnl *************************
1543 dnl *** GIOChannel checks ***
1544 dnl *************************
1545
1546 AC_MSG_CHECKING(for GIOChannel implementation)
1547 case "$host" in
1548   *-*-mingw*)
1549     GIO=giowin32.lo
1550     ;;
1551   *)
1552     GIO=giounix.lo
1553     ;;
1554 esac
1555 AC_MSG_RESULT($GIO)
1556 AC_SUBST(GIO)
1557
1558 dnl *********************************
1559 dnl *** Directory for GIO modules ***
1560 dnl *********************************
1561
1562 AC_ARG_WITH(gio-module-dir,
1563            [AC_HELP_STRING([--with-gio-module-dir=PATH],
1564                            [Load gio modules from this directory [LIBDIR/gio/modules]])],
1565            [],
1566            [with_gio_module_dir='${libdir}/gio/modules'])
1567 GIO_MODULE_DIR=$with_gio_module_dir
1568 AC_SUBST(GIO_MODULE_DIR)
1569
1570 dnl **********************************
1571 dnl *** Check for libselinux (GIO) ***
1572 dnl **********************************
1573 AC_ARG_ENABLE(selinux, [  --disable-selinux       build without selinux support])
1574 msg_selinux=no
1575 SELINUX_LIBS=
1576 if test "x$enable_selinux" != "xno"; then
1577
1578  AC_CHECK_LIB(selinux, is_selinux_enabled,
1579    [AC_CHECK_HEADERS(selinux/selinux.h,
1580      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1581        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1582         SELINUX_LIBS="-lselinux"
1583         msg_selinux=yes])
1584      ])
1585    ])
1586 fi
1587 AC_SUBST(SELINUX_LIBS)
1588
1589 dnl *****************************
1590 dnl ** Check for inotify (GIO) **
1591 dnl *****************************
1592 inotify_support=no
1593 AC_CHECK_HEADERS([sys/inotify.h],
1594 [
1595         inotify_support=yes
1596         AC_CHECK_FUNCS(inotify_init1)
1597 ])
1598
1599 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1600
1601 dnl *********************************
1602 dnl ** Check for Solaris FEN (GIO) **
1603 dnl *********************************
1604 fen_support=no
1605 AC_COMPILE_IFELSE([
1606 #include <port.h>
1607 #ifndef PORT_SOURCE_FILE
1608 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1609 #endif
1610 int main() { return 0; } ],
1611 [
1612         fen_support=yes
1613 ],)
1614
1615 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1616
1617 dnl ****************************
1618 dnl *** Checks for FAM (GIO) ***
1619 dnl ****************************
1620
1621 should_disable_fam=no
1622
1623 AC_ARG_ENABLE(fam, [  --disable-fam          build without enabling fam for file system monitoring],
1624                          [
1625                                 if test "x$enable_fam" = "xno"; then
1626                                         should_disable_fam=yes
1627                                         echo "Not building FAM support"
1628                                 fi
1629                          ]
1630                          )
1631 fam_support=no
1632 FAM_LIBS=
1633 if test "x$should_disable_fam" = "xno"; then
1634 AC_CHECK_LIB(fam, FAMOpen,
1635   [AC_CHECK_HEADERS(fam.h,
1636     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1637      AC_CHECK_LIB(fam, FAMNoExists,
1638                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1639      FAM_LIBS="-lfam"]
1640      fam_support=yes,
1641     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1642   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1643 AC_SUBST(FAM_LIBS)
1644 fi
1645 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1646
1647
1648 dnl *****************************
1649 dnl *** Check for xattr (GIO) ***
1650 dnl *****************************
1651 AC_ARG_ENABLE(xattr, [  --disable-xattr           build without xattr support])
1652 msg_xattr=no
1653 XATTR_LIBS=
1654 if test "x$enable_xattr" != "xno"; then
1655
1656 dnl either glibc or libattr can provide xattr support
1657
1658 dnl for both of them, we check for getxattr being in
1659 dnl the library and a valid xattr header.
1660
1661 dnl try glibc
1662  AC_CHECK_LIB(c, getxattr,
1663    [AC_CHECK_HEADERS(sys/xattr.h,
1664      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1665       msg_xattr=yes])
1666    ])
1667
1668   if test "x$msg_xattr" != "xyes"; then
1669 dnl   failure. try libattr
1670    AC_CHECK_LIB(attr, getxattr,
1671       [AC_CHECK_HEADERS(attr/xattr.h,
1672        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1673         XATTR_LIBS="-lattr"
1674         msg_xattr=yes])
1675       ])
1676   fi
1677
1678   if test "x$msg_xattr" = "xyes"; then
1679     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1680     AC_TRY_COMPILE([
1681       #include <stdio.h>
1682       #ifdef HAVE_SYS_TYPES_H
1683       #include <sys/types.h>
1684       #endif
1685       #ifdef HAVE_SYS_XATTR_H
1686       #include <sys/xattr.h>
1687       #elif HAVE_ATTR_XATTR_H
1688       #include <attr/xattr.h>
1689       #endif
1690     ],
1691     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1692     [
1693       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1694       AC_MSG_RESULT([yes])
1695     ],
1696     [AC_MSG_RESULT([no])]
1697     )
1698   fi
1699
1700 fi
1701 AC_SUBST(XATTR_LIBS)
1702
1703 dnl ****************************************
1704 dnl *** platform dependent source checks ***
1705 dnl ****************************************
1706
1707 AC_MSG_CHECKING(for platform-dependent source)
1708 case "$host" in
1709   *-*-cygwin*|*-*-mingw*)
1710     PLATFORMDEP=gwin32.lo
1711     ;;
1712   *)
1713     PLATFORMDEP=
1714     ;;
1715 esac
1716 AC_MSG_RESULT($PLATFORMDEP)
1717 AC_SUBST(PLATFORMDEP)
1718
1719 AC_MSG_CHECKING([whether to compile timeloop])
1720 case "$host" in
1721   *-*-cygwin*|*-*-mingw*|*-*-minix)
1722     enable_timeloop=no
1723     ;;
1724   *)
1725     enable_timeloop=yes
1726     ;;
1727 esac
1728 AC_MSG_RESULT($enable_timeloop)
1729 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1730
1731 AC_MSG_CHECKING([if building for some Win32 platform])
1732 case "$host" in
1733   *-*-mingw*|*-*-cygwin*)
1734     platform_win32=yes
1735     ;;
1736   *)
1737     platform_win32=no
1738     ;;
1739 esac
1740 AC_MSG_RESULT($platform_win32)
1741 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1742
1743 dnl ***********************
1744 dnl *** g_thread checks ***
1745 dnl ***********************
1746
1747 AC_ARG_WITH(threads,
1748            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/win32@:>@],
1749                            [specify a thread implementation to use])],
1750            [if test "x$with_threads" = x; then
1751                 want_threads=yes
1752             else
1753                 want_threads=$with_threads
1754             fi],
1755            [want_threads=yes])
1756 if test "x$enable_threads" = "xno"; then
1757         want_threads=no
1758 fi
1759
1760 dnl error and warning message
1761 dnl *************************
1762
1763 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1764                 computer. GLib will not have a default thread implementation."
1765
1766 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1767                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1768                 compilation now, but then your programs might not work.
1769                 Please provide information on how it is done on your system."
1770
1771 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1772                 "
1773
1774 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1775                 provide information on your thread implementation.
1776                 You can also run 'configure --disable-threads'
1777                 to compile without thread support."
1778
1779 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1780                 functions will not be MT-safe during their first call because
1781                 there is no working 'getpwuid_r' on your system."
1782
1783 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1784                 because there is no 'localtime_r' on your system."
1785
1786 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1787                 crude surrogate will be used. If you happen to know a
1788                 yield function for your system, please inform the GLib
1789                 developers."
1790
1791 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1792                 threads on your system. Thus threads can only have the default
1793                 priority. If you happen to know these main/max
1794                 priorities, please inform the GLib developers."
1795
1796 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1797                 linking threaded applications. As GLib cannot do that
1798                 automatically, you will get an linkg error everytime you are
1799                 not using the right compiler. In that case you have to relink
1800                 with the right compiler. Ususally just '_r' is appended
1801                 to the compiler name."
1802
1803 dnl determination of thread implementation
1804 dnl ***************************************
1805
1806 # have_threads=no   means no thread support
1807 # have_threads=none means no default thread implementation
1808
1809 have_threads=no
1810 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1811                                 || test "x$want_threads" = xdce; then
1812         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1813         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1814         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1815         glib_save_CPPFLAGS="$CPPFLAGS"
1816         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1817         if test "x$have_threads" = xno; then
1818                 AC_TRY_COMPILE([#include <pthread.h>],
1819                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1820                         have_threads=posix)
1821         fi
1822         if test "x$have_threads" = xno; then
1823                 AC_TRY_COMPILE([#include <pthread.h>],
1824                         [pthread_mutex_t m;
1825                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1826                         have_threads=dce)
1827         fi
1828         # Tru64Unix requires -pthread to find pthread.h. See #103020
1829         CPPFLAGS="$CPPFLAGS -pthread"
1830         if test "x$have_threads" = xno; then
1831         AC_TRY_COMPILE([#include <pthread.h>],
1832                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1833                        have_threads=posix)
1834         fi
1835         CPPFLAGS="$glib_save_CPPFLAGS"
1836 fi
1837 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1838         case $host in
1839                 *-*-mingw*)
1840                 have_threads=win32
1841                 ;;
1842         esac
1843 fi
1844 if test "x$want_threads" = xnone; then
1845         have_threads=none
1846 fi
1847
1848 AC_MSG_CHECKING(for thread implementation)
1849
1850 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1851         AC_MSG_RESULT(none available)
1852         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1853 else
1854         AC_MSG_RESULT($have_threads)
1855 fi
1856
1857
1858 dnl determination of G_THREAD_CFLAGS
1859 dnl ********************************
1860
1861 G_THREAD_LIBS=
1862 G_THREAD_LIBS_EXTRA=
1863 G_THREAD_CFLAGS=
1864
1865 dnl
1866 dnl Test program for basic POSIX threads functionality
1867 dnl
1868 m4_define([glib_thread_test],[
1869 #include <pthread.h>
1870 int check_me = 0;
1871 void* func(void* data) {check_me = 42; return &check_me;}
1872 int main()
1873  { pthread_t t;
1874    void *ret;
1875    pthread_create (&t, $1, func, 0);
1876    pthread_join (t, &ret);
1877    return (check_me != 42 || ret != &check_me);
1878 }])
1879
1880 dnl
1881 dnl Test program for sched_get_priority_min()
1882 dnl
1883 m4_define([glib_sched_priority_test],[
1884 #include <sched.h>
1885 #include <errno.h>
1886 int main() {
1887     errno = 0;
1888     return sched_get_priority_min(SCHED_OTHER)==-1
1889            && errno != 0;
1890 }])
1891
1892 if test x"$have_threads" != xno; then
1893
1894   if test x"$have_threads" = xposix; then
1895     # First we test for posix, whether -pthread or -pthreads do the trick as
1896     # both CPPFLAG and LIBS.
1897     # One of them does for most gcc versions and some other platforms/compilers
1898     # too and could be considered as the canonical way to go.
1899     case $host in
1900       *-*-cygwin*|*-*-darwin*)
1901          # skip cygwin and darwin -pthread or -pthreads test
1902          ;;
1903       *-solaris*)
1904         # These compiler/linker flags work with both Sun Studio and gcc
1905         # Sun Studio expands -mt to -D_REENTRANT and -lthread
1906         # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1907         G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1908         G_THREAD_LIBS="-lpthread -lthread"
1909         ;;
1910       *)
1911         for flag in pthread pthreads mt; do
1912           glib_save_CFLAGS="$CFLAGS"
1913           CFLAGS="$CFLAGS -$flag"
1914           AC_TRY_RUN(glib_thread_test(0),
1915                      glib_flag_works=yes,
1916                      glib_flag_works=no,
1917                      [AC_LINK_IFELSE(glib_thread_test(0),
1918                                      glib_flag_works=yes,
1919                                      glib_flag_works=no)])
1920           CFLAGS="$glib_save_CFLAGS"
1921           if test $glib_flag_works = yes ; then
1922              G_THREAD_CFLAGS=-$flag
1923              G_THREAD_LIBS=-$flag
1924              break;
1925           fi
1926         done
1927          ;;
1928     esac
1929   fi
1930
1931   if test x"$G_THREAD_CFLAGS" = x; then
1932
1933     # The canonical -pthread[s] does not work. Try something different.
1934
1935     case $host in
1936         *-aix*)
1937                 if test x"$GCC" = xyes; then
1938                         # GCC 3.0 and above needs -pthread.
1939                         # Should be coverd by the case above.
1940                         # GCC 2.x and below needs -mthreads
1941                         G_THREAD_CFLAGS="-mthreads"
1942                         G_THREAD_LIBS=$G_THREAD_CFLAGS
1943                 else
1944                         # We are probably using the aix compiler. Normaly a
1945                         # program would have to be compiled with the _r variant
1946                         # of the corresponding compiler, but we as GLib cannot
1947                         # do that: but the good news is that for compiling the
1948                         # only difference is the added -D_THREAD_SAFE compile
1949                         # option. This is according to the "C for AIX User's
1950                         # Guide".
1951                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
1952                 fi
1953                 ;;
1954         *-dg-dgux*)  # DG/UX
1955                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
1956                 ;;
1957         *-osf*)
1958                 # So we are using dce threads. posix threads are already
1959                 # catched above.
1960                 G_THREAD_CFLAGS="-threads"
1961                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1962                 ;;
1963         *-sysv5uw7*) # UnixWare 7
1964                 # We are not using gcc with -pthread. Catched above.
1965                 G_THREAD_CFLAGS="-Kthread"
1966                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1967                 ;;
1968         *-mingw*)
1969                 # No flag needed when using MSVCRT.DLL
1970                 G_THREAD_CFLAGS=""
1971                 ;;
1972         *)
1973                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1974                 ;;
1975     esac
1976
1977   fi
1978
1979     # if we are not finding the localtime_r function, then we probably are
1980     # not using the proper multithread flag
1981
1982     glib_save_CPPFLAGS="$CPPFLAGS"
1983     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1984
1985     # First we test, whether localtime_r is declared in time.h
1986     # directly. Then we test whether a macro localtime_r exists, in
1987     # which case localtime_r in the test program is replaced and thus
1988     # if we still find localtime_r in the output, it is not defined as
1989     # a macro.
1990
1991     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1992       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1993                                                            localtime_r(a,b)],
1994                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1995
1996     CPPFLAGS="$glib_save_CPPFLAGS"
1997
1998     AC_MSG_CHECKING(thread related cflags)
1999     AC_MSG_RESULT($G_THREAD_CFLAGS)
2000     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2001 fi
2002
2003 dnl determination of G_THREAD_LIBS
2004 dnl ******************************
2005
2006 mutex_has_default=no
2007 case $have_threads in
2008         posix|dce)
2009           glib_save_CPPFLAGS="$CPPFLAGS"
2010           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2011           if test x"$G_THREAD_LIBS" = x; then
2012             case $host in
2013               *-aix*)
2014                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2015                 # probably using the aix compiler.
2016                 AC_MSG_WARN($AIX_COMPILE_INFO)
2017                 ;;
2018               *)
2019                 G_THREAD_LIBS=error
2020                 glib_save_LIBS="$LIBS"
2021                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
2022                         if test x"$thread_lib" = x; then
2023                                 add_thread_lib=""
2024                                 IN=""
2025                         else
2026                                 add_thread_lib="-l$thread_lib"
2027                                 IN=" in -l$thread_lib"
2028                         fi
2029                         if test x"$have_threads" = xposix; then
2030                                 defattr=0
2031                         else
2032                                 defattr=pthread_attr_default
2033                         fi
2034
2035                         LIBS="$add_thread_lib $glib_save_LIBS"
2036
2037                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2038                         AC_TRY_RUN(glib_thread_test($defattr),
2039                                    glib_result=yes,
2040                                    glib_result=no,
2041                                    [AC_LINK_IFELSE(glib_thread_test($defattr),
2042                                                    glib_result=yes,
2043                                                    glib_result=no)])
2044                         AC_MSG_RESULT($glib_result)
2045
2046                         if test "$glib_result" = "yes" ; then
2047                           G_THREAD_LIBS="$add_thread_lib"
2048                           break
2049                         fi
2050                 done
2051                 if test "x$G_THREAD_LIBS" = xerror; then
2052                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2053                 fi
2054                 LIBS="$glib_save_LIBS"
2055                 ;;
2056             esac
2057           fi
2058
2059           glib_save_LIBS="$LIBS"
2060           for thread_lib in "" rt rte; do
2061             if test x"$thread_lib" = x; then
2062               add_thread_lib=""
2063               IN=""
2064             else
2065               add_thread_lib="-l$thread_lib"
2066               IN=" in -l$thread_lib"
2067             fi
2068             LIBS="$add_thread_lib $glib_save_LIBS"
2069
2070             AC_MSG_CHECKING(for sched_get_priority_min$IN)
2071             AC_TRY_RUN(glib_sched_priority_test,
2072                        glib_result=yes,
2073                        glib_result=no,
2074                        [AC_LINK_IFELSE(glib_sched_priority_test,
2075                                        glib_result=yes,
2076                                        glib_result=no)])
2077             AC_MSG_RESULT($glib_result)
2078
2079             if test "$glib_result" = "yes" ; then
2080                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
2081                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
2082                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
2083                break
2084             fi
2085           done
2086           LIBS="$glib_save_LIBS"
2087           mutex_has_default=yes
2088           mutex_default_type='pthread_mutex_t'
2089           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
2090           mutex_header_file='pthread.h'
2091           if test "x$have_threads" = "xposix"; then
2092             g_threads_impl="POSIX"
2093           else
2094             g_threads_impl="DCE"
2095             have_threads="posix"
2096           fi
2097           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2098           CPPFLAGS="$glib_save_CPPFLAGS"
2099           ;;
2100         win32)
2101            g_threads_impl="WIN32"
2102            ;;
2103         none|no)
2104            g_threads_impl="NONE"
2105            ;;
2106         *)
2107            g_threads_impl="NONE"
2108            G_THREAD_LIBS=error
2109            ;;
2110 esac
2111
2112 if test "x$G_THREAD_LIBS" = xerror; then
2113         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2114 fi
2115
2116 case $host in
2117   *-*-beos*)
2118     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2119     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2120     ;;
2121   *)
2122     ;;
2123 esac
2124
2125 AC_MSG_CHECKING(thread related libraries)
2126 AC_MSG_RESULT($G_THREAD_LIBS)
2127
2128 dnl check for mt safe function variants and some posix functions
2129 dnl ************************************************************
2130
2131 if test x"$have_threads" != xno; then
2132         glib_save_LIBS="$LIBS"
2133         # we are not doing the following for now, as this might require glib
2134         # to always be linked with the thread libs on some platforms.
2135         # LIBS="$LIBS $G_THREAD_LIBS"
2136         AC_CHECK_FUNCS(localtime_r gmtime_r)
2137         if test "$ac_cv_header_pwd_h" = "yes"; then
2138                 AC_CACHE_CHECK([for posix getpwuid_r],
2139                         ac_cv_func_posix_getpwuid_r,
2140                         [AC_TRY_RUN([
2141 #include <errno.h>
2142 #include <pwd.h>
2143 int main () {
2144     char buffer[10000];
2145     struct passwd pwd, *pwptr = &pwd;
2146     int error;
2147     errno = 0;
2148     error = getpwuid_r (0, &pwd, buffer,
2149                         sizeof (buffer), &pwptr);
2150    return (error < 0 && errno == ENOSYS)
2151            || error == ENOSYS;
2152 }                               ],
2153                                 [ac_cv_func_posix_getpwuid_r=yes],
2154                                 [ac_cv_func_posix_getpwuid_r=no])])
2155                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2156                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2157                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2158                                 [Have POSIX function getpwuid_r])
2159                 else
2160                         AC_CACHE_CHECK([for nonposix getpwuid_r],
2161                                 ac_cv_func_nonposix_getpwuid_r,
2162                                 [AC_TRY_LINK([#include <pwd.h>],
2163                                         [char buffer[10000];
2164                                         struct passwd pwd;
2165                                         getpwuid_r (0, &pwd, buffer,
2166                                                         sizeof (buffer));],
2167                                         [ac_cv_func_nonposix_getpwuid_r=yes],
2168                                         [ac_cv_func_nonposix_getpwuid_r=no])])
2169                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2170                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2171                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2172                                         [Have non-POSIX function getpwuid_r])
2173                         fi
2174                 fi
2175         fi
2176         if test "$ac_cv_header_grp_h" = "yes"; then
2177                 AC_CACHE_CHECK([for posix getgrgid_r],
2178                         ac_cv_func_posix_getgrgid_r,
2179                         [AC_TRY_RUN([
2180 #include <errno.h>
2181 #include <grp.h>
2182 int main () {
2183     char buffer[10000];
2184     struct group grp, *grpptr = &grp;
2185     int error;
2186     errno = 0;
2187     error = getgrgid_r (0, &grp, buffer,
2188                         sizeof (buffer), &grpptr);
2189    return (error < 0 && errno == ENOSYS)
2190            || error == ENOSYS;
2191 }                              ],
2192                                [ac_cv_func_posix_getgrgid_r=yes],
2193                                [ac_cv_func_posix_getgrgid_r=no])])
2194                 GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2195                 if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2196                         AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2197                                 [Have POSIX function getgrgid_r])
2198                 else
2199                         AC_CACHE_CHECK([for nonposix getgrgid_r],
2200                                 ac_cv_func_nonposix_getgrgid_r,
2201                                 [AC_TRY_LINK([#include <grp.h>],
2202                                         [char buffer[10000];
2203                                         struct group grp;
2204                                         getgrgid_r (0, &grp, buffer,
2205                                         sizeof (buffer));],
2206                                 [ac_cv_func_nonposix_getgrgid_r=yes],
2207                                 [ac_cv_func_nonposix_getgrgid_r=no])])
2208                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2209                         if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2210                                 AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2211                                         [Have non-POSIX function getgrgid_r])
2212                         fi
2213                 fi
2214         fi
2215         LIBS="$G_THREAD_LIBS $LIBS"
2216         if test x"$have_threads" = xposix; then
2217                 glib_save_CPPFLAGS="$CPPFLAGS"
2218                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2219                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
2220                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
2221                 # This is not AC_CHECK_FUNC to also work with function
2222                 # name mangling in header files.
2223                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2224                 AC_TRY_LINK([#include <pthread.h>],
2225                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2226                         [AC_MSG_RESULT(yes)
2227                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2228                                   [Have function pthread_attr_setstacksize])],
2229                         [AC_MSG_RESULT(no)])
2230                 AC_MSG_CHECKING(for minimal/maximal thread priority)
2231                 if test x"$posix_priority_min" = x; then
2232                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
2233                                 PX_PRIO_MIN],,[
2234                                 posix_priority_min=PX_PRIO_MIN
2235                                 posix_priority_max=PX_PRIO_MAX])
2236                 fi
2237                 if test x"$posix_priority_min" = x; then
2238                         # AIX
2239                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
2240                                 PTHREAD_PRIO_MIN],,[
2241                                 posix_priority_min=PTHREAD_PRIO_MIN
2242                                 posix_priority_max=PTHREAD_PRIO_MAX])
2243                 fi
2244                 if test x"$posix_priority_min" = x; then
2245                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
2246                                 PRI_OTHER_MIN],,[
2247                                 posix_priority_min=PRI_OTHER_MIN
2248                                 posix_priority_max=PRI_OTHER_MAX])
2249                 fi
2250                 if test x"$posix_priority_min" = x; then
2251                         AC_MSG_RESULT(none found)
2252                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
2253                         posix_priority_min=-1
2254                         posix_priority_max=-1
2255                 else
2256                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
2257                         AC_MSG_CHECKING(for pthread_setschedparam)
2258                         AC_TRY_LINK([#include <pthread.h>],
2259                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
2260                           [AC_MSG_RESULT(yes)
2261                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
2262                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
2263                           [AC_MSG_RESULT(no)
2264                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
2265                 fi
2266                 posix_yield_func=none
2267                 AC_MSG_CHECKING(for posix yield function)
2268                 for yield_func in sched_yield pthread_yield_np pthread_yield \
2269                                                         thr_yield; do
2270                         AC_TRY_LINK([#include <pthread.h>],
2271                                 [$yield_func()],
2272                                 [posix_yield_func="$yield_func"
2273                                 break])
2274                 done
2275                 if test x"$posix_yield_func" = xnone; then
2276                         AC_MSG_RESULT(none found)
2277                         AC_MSG_WARN($POSIX_NO_YIELD)
2278                         posix_yield_func="g_usleep(1000)"
2279                 else
2280                         AC_MSG_RESULT($posix_yield_func)
2281                         posix_yield_func="$posix_yield_func()"
2282                 fi
2283                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
2284                 CPPFLAGS="$glib_save_CPPFLAGS"
2285
2286         elif test x"$have_threads" = xwin32; then
2287                 # It's a pointer to a private struct
2288                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
2289         fi
2290
2291         LIBS="$glib_save_LIBS"
2292
2293         # now spit out all the warnings.
2294         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2295            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2296                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2297         fi
2298         if test "$ac_cv_func_localtime_r" != "yes"; then
2299                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2300         fi
2301 fi
2302
2303 if test x"$glib_cv_sizeof_system_thread" = x; then
2304    # use a pointer as a fallback.
2305    GLIB_SIZEOF(,void *, system_thread)
2306 fi
2307
2308 #
2309 # Hack to deal with:
2310 #
2311 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2312 #     building shared libraries with linux.
2313 #  b) FreeBSD doesn't do this either.
2314 #
2315 case $host in
2316   *-*-freebsd*|*-*-linux*)
2317     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2318     ;;
2319   *)
2320     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2321     ;;
2322 esac
2323
2324 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
2325                    [Source file containing theread implementation])
2326 AC_SUBST(G_THREAD_CFLAGS)
2327 AC_SUBST(G_THREAD_LIBS)
2328 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2329 AC_SUBST(G_THREAD_LIBS_EXTRA)
2330
2331 dnl **********************************************
2332 dnl *** GDefaultMutex setup and initialization ***
2333 dnl **********************************************
2334 dnl
2335 dnl if mutex_has_default = yes, we also got
2336 dnl mutex_default_type, mutex_default_init and mutex_header_file
2337 if test $mutex_has_default = yes ; then
2338         glib_save_CPPFLAGS="$CPPFLAGS"
2339         glib_save_LIBS="$LIBS"
2340         LIBS="$G_THREAD_LIBS $LIBS"
2341         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2342         GLIB_SIZEOF([#include <$mutex_header_file>],
2343                     $mutex_default_type,
2344                     gmutex)
2345         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
2346                            $mutex_default_type,
2347                            gmutex,
2348                            $glib_cv_sizeof_gmutex,
2349                            $mutex_default_init)
2350         if test x"$glib_cv_byte_contents_gmutex" = xno; then
2351                 mutex_has_default=no
2352         fi
2353         CPPFLAGS="$glib_save_CPPFLAGS"
2354         LIBS="$glib_save_LIBS"
2355 fi
2356
2357 AC_CHECK_FUNCS(clock_gettime, [], [
2358   AC_CHECK_LIB(rt, clock_gettime, [
2359     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2360     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2361     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2362   ])
2363 ])
2364
2365 AC_CACHE_CHECK(for monotonic clocks,
2366     glib_cv_monotonic_clock,AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
2367 #include <time.h>
2368 #include <unistd.h>
2369 int main() {
2370 #if !(defined(_POSIX_MONOTONIC_CLOCK) && _POSIX_MONOTONIC_CLOCK >= 0 && defined(CLOCK_MONOTONIC))
2371         #error No monotonic clock
2372 #endif
2373         return 0;
2374 }
2375 ]])],glib_cv_monotonic_clock=yes,glib_cv_monotonic_clock=no))
2376 if test "$glib_cv_monotonic_clock" = "yes"; then
2377   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
2378 fi
2379
2380
2381 dnl ********************************
2382 dnl *** g_atomic_* tests for gcc ***
2383 dnl ********************************
2384
2385 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
2386
2387 if test x"$GCC" = xyes; then
2388   case $host_cpu in
2389     i386)
2390       AC_MSG_RESULT([none])
2391       glib_memory_barrier_needed=no
2392       ;;
2393     i?86)
2394       AC_MSG_RESULT([i486])
2395       AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
2396                          [i486 atomic implementation])
2397       glib_memory_barrier_needed=no
2398       ;;
2399     sparc*)
2400       SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
2401                 when you are using a sparc with v9 instruction set (most
2402                 sparcs nowadays). This will make the code for atomic
2403                 operations much faster. The resulting code will not run
2404                 on very old sparcs though."
2405
2406       AC_LINK_IFELSE([[
2407         main ()
2408         {
2409           int tmp1, tmp2, tmp3;
2410           __asm__ __volatile__("casx [%2], %0, %1"
2411                                : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
2412         }]],
2413         AC_MSG_RESULT([sparcv9])
2414         AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
2415                            [sparcv9 atomic implementation]),
2416         AC_MSG_RESULT([no])
2417         AC_MSG_WARN([[$SPARCV9_WARNING]]))
2418       glib_memory_barrier_needed=yes
2419       ;;
2420     alpha*)
2421       AC_MSG_RESULT([alpha])
2422       AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
2423                          [alpha atomic implementation])
2424       glib_memory_barrier_needed=yes
2425       ;;
2426     x86_64)
2427       AC_MSG_RESULT([x86_64])
2428       AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
2429                          [x86_64 atomic implementation])
2430       glib_memory_barrier_needed=no
2431      ;;
2432     powerpc*)
2433       AC_MSG_RESULT([powerpc])
2434       AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
2435                          [powerpc atomic implementation])
2436       glib_memory_barrier_needed=yes
2437       AC_MSG_CHECKING([whether asm supports numbered local labels])
2438       AC_TRY_COMPILE(
2439                 ,[
2440                         __asm__ __volatile__ ("1:       nop\n"
2441                                               "         bne-    1b")
2442                 ],[
2443                         AC_DEFINE_UNQUOTED(ASM_NUMERIC_LABELS, 1, [define if asm blocks can use numeric local labels])
2444                         AC_MSG_RESULT([yes])
2445                 ],[
2446                         AC_MSG_RESULT([no])
2447                 ])
2448       ;;
2449     ia64)
2450       AC_MSG_RESULT([ia64])
2451       AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
2452                          [ia64 atomic implementation])
2453       glib_memory_barrier_needed=yes
2454       ;;
2455     s390|s390x)
2456       AC_MSG_RESULT([s390])
2457       AC_DEFINE_UNQUOTED(G_ATOMIC_S390, 1,
2458                          [s390 atomic implementation])
2459       glib_memory_barrier_needed=no
2460       ;;
2461     arm*)
2462       AC_MSG_RESULT([arm])
2463       AC_DEFINE_UNQUOTED(G_ATOMIC_ARM, 1,
2464                          [arm atomic implementation])
2465       glib_memory_barrier_needed=no
2466       ;;
2467     crisv32*|etraxfs*)
2468       AC_MSG_RESULT([crisv32])
2469       AC_DEFINE_UNQUOTED(G_ATOMIC_CRISV32, 1,
2470                          [crisv32 atomic implementation])
2471       glib_memory_barrier_needed=no
2472       ;;
2473     cris*|etrax*)
2474       AC_MSG_RESULT([cris])
2475       AC_DEFINE_UNQUOTED(G_ATOMIC_CRIS, 1,
2476                          [cris atomic implementation])
2477       glib_memory_barrier_needed=no
2478       ;;
2479     *)
2480       AC_MSG_RESULT([none])
2481       glib_memory_barrier_needed=yes
2482       ;;
2483   esac
2484 else
2485   if test $glib_native_win32 = yes; then
2486     # For Windows but not using gcc. No barriers needed then either.
2487     glib_memory_barrier_needed=no
2488   fi
2489 fi
2490
2491 dnl ****************************************
2492 dnl *** GLib POLL* compatibility defines ***
2493 dnl ****************************************
2494
2495 glib_poll_includes=["
2496 #include <sys/types.h>
2497 #include <sys/poll.h>
2498 "]
2499
2500 if test $ac_cv_header_sys_types_h = yes &&
2501    test $ac_cv_header_sys_poll_h = yes ; then
2502   glib_failed=false
2503   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2504   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2505   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2506   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2507   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2508   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2509   if $glib_failed ; then
2510     AC_MSG_ERROR([Could not determine values for POLL* constants])
2511   fi
2512 else
2513   glib_cv_value_POLLIN=1
2514   glib_cv_value_POLLOUT=4
2515   glib_cv_value_POLLPRI=2
2516   glib_cv_value_POLLERR=8
2517   glib_cv_value_POLLHUP=16
2518   glib_cv_value_POLLNVAL=32
2519 fi
2520
2521 AC_MSG_CHECKING([for broken poll])
2522 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2523         #include <stdlib.h>
2524         #include <fcntl.h>
2525         #include <poll.h>
2526         #ifdef HAVE_SYS_POLL_H
2527         #include <sys/poll.h>
2528         #endif
2529         int main(void) {
2530           struct pollfd fds[1];
2531           int fd;
2532           fd = open("/dev/null", 1);
2533           fds[0].fd = fd;
2534           fds[0].events = POLLIN;
2535           fds[0].revents = 0;
2536           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2537                 exit(1);  /* Does not work for devices -- fail */
2538           }
2539           exit(0);
2540         }]])],
2541   [broken_poll=no],
2542   [broken_poll=yes
2543    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2544   [broken_poll="no (cross compiling)"])
2545 AC_MSG_RESULT($broken_poll)
2546
2547 dnl *********************
2548 dnl *** GRegex checks ***
2549 dnl *********************
2550 PCRE_REQUIRED_VERSION=7.2
2551
2552 # Check if we should compile GRegex
2553 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2554               [disable the compilation of GRegex]),
2555 [case "${enableval}" in
2556   yes) enable_regex=true ;;
2557   no)  enable_regex=false ;;
2558   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2559 esac],
2560 [enable_regex=true])
2561
2562 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2563
2564 if test x$enable_regex = xtrue; then
2565   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2566   # Check if we should use the internal or the system-supplied pcre
2567   AC_ARG_WITH(pcre,
2568              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2569                              [specify whether to use the internal or the
2570                               system-supplied PCRE library])])
2571
2572   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2573
2574   if test "x$with_pcre" = xsystem; then
2575     PKG_CHECK_MODULES(PCRE,
2576                       libpcre >= $PCRE_REQUIRED_VERSION)
2577     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2578                    glib_save_CFLAGS="$CFLAGS"
2579                    glib_save_LIBS="$LIBS"
2580                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2581                    AC_TRY_RUN([#include <pcre.h>
2582                                int main () {
2583                                  int support;
2584                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2585                                  if (!support)
2586                                    return 1;
2587                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2588                                  if (!support)
2589                                    return 1;
2590                                  return 0;
2591                                }],
2592                    glib_cv_pcre_has_unicode=yes,
2593                    glib_cv_pcre_has_unicode=no,
2594                    glib_cv_pcre_has_unicode=yes)
2595                    CFLAGS="$glib_save_CFLAGS"
2596                    LIBS="$glib_save_LIBS"
2597         ])
2598     if test "$glib_cv_pcre_has_unicode" = "no"; then
2599       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2600     fi
2601     AC_SUBST(PCRE_CFLAGS)
2602     AC_SUBST(PCRE_LIBS)
2603     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2604     PCRE_REQUIRES=libpcre
2605     AC_SUBST(PCRE_REQUIRES)
2606   else
2607     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2608     if test x"$GCC" = xyes; then
2609       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2610       save_CFLAGS="$CFLAGS"
2611       CFLAGS="$CFLAGS -Wno-pointer-sign"
2612       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2613                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2614       CFLAGS="$save_CFLAGS"
2615     fi
2616   fi
2617   AC_SUBST(PCRE_WARN_CFLAGS)
2618 else
2619   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2620 fi
2621
2622 dnl **********************
2623 dnl *** Win32 API libs ***
2624 dnl **********************
2625
2626 case $host in
2627   *-*-cygwin*)
2628         G_LIBS_EXTRA="-luser32 -lkernel32"
2629     ;;
2630   *-*-mingw*)
2631         G_LIBS_EXTRA="-lws2_32 -lole32"
2632     ;;
2633   *)
2634         G_LIBS_EXTRA=""
2635     ;;
2636 esac
2637 AC_SUBST(G_LIBS_EXTRA)
2638
2639 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2640 dnl since we need it for g_iconv()
2641
2642 AC_MSG_CHECKING([for EILSEQ])
2643 AC_TRY_COMPILE([
2644 #include <errno.h>
2645 ],
2646 [
2647 int error = EILSEQ;
2648 ], have_eilseq=yes, have_eilseq=no);
2649 AC_MSG_RESULT($have_eilseq)
2650
2651 dnl ******************************************************************
2652 dnl *** Look for glib-genmarshal in PATH if we are cross-compiling ***
2653 dnl ******************************************************************
2654
2655 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2656
2657 if test $cross_compiling = yes; then
2658   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2659   if test x$GLIB_GENMARSHAL = xno; then
2660     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2661   fi
2662 fi
2663
2664 dnl **************************
2665 dnl *** Checks for gtk-doc ***
2666 dnl **************************
2667
2668 GTK_DOC_CHECK([1.11])
2669
2670 AC_ARG_ENABLE(man,
2671               [AC_HELP_STRING([--enable-man],
2672                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2673               enable_man=no)
2674
2675 if test "${enable_man}" != no; then
2676 dnl
2677 dnl Check for xsltproc
2678 dnl
2679 AC_PATH_PROG([XSLTPROC], [xsltproc])
2680   if test -z "$XSLTPROC"; then
2681     enable_man=no
2682   fi
2683
2684   dnl check for DocBook DTD and stylesheets in the local catalog.
2685   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2686      [DocBook XML DTD V4.1.2],,enable_man=no)
2687   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2688      [DocBook XSL Stylesheets],,enable_man=no)
2689 fi
2690
2691 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2692
2693 dnl ******************************
2694 dnl *** output the whole stuff ***
2695 dnl ******************************
2696
2697 dnl this section will only be run if config.status is invoked with no
2698 dnl arguments, or with "glibconfig.h" as an argument.
2699 AC_CONFIG_COMMANDS([glibconfig.h],
2700 [
2701         outfile=glibconfig.h-tmp
2702         cat > $outfile <<\_______EOF
2703 /* glibconfig.h
2704  *
2705  * This is a generated file.  Please modify 'configure.in'
2706  */
2707
2708 #ifndef __G_LIBCONFIG_H__
2709 #define __G_LIBCONFIG_H__
2710
2711 #include <glib/gmacros.h>
2712
2713 _______EOF
2714
2715         if test x$glib_limits_h = xyes; then
2716           echo '#include <limits.h>' >> $outfile
2717         fi
2718         if test x$glib_float_h = xyes; then
2719           echo '#include <float.h>' >> $outfile
2720         fi
2721         if test x$glib_values_h = xyes; then
2722           echo '#include <values.h>' >> $outfile
2723         fi
2724         if test "$glib_header_alloca_h" = "yes"; then
2725           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2726         fi
2727         if test x$glib_sys_poll_h = xyes; then
2728           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2729         fi
2730         if test x$glib_included_printf != xyes; then
2731           echo "
2732 /* Specifies that GLib's g_print*() functions wrap the
2733  * system printf functions.  This is useful to know, for example,
2734  * when using glibc's register_printf_function().
2735  */" >> $outfile
2736           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2737         fi
2738
2739         cat >> $outfile <<_______EOF
2740
2741 G_BEGIN_DECLS
2742
2743 #define G_MINFLOAT      $glib_mf
2744 #define G_MAXFLOAT      $glib_Mf
2745 #define G_MINDOUBLE     $glib_md
2746 #define G_MAXDOUBLE     $glib_Md
2747 #define G_MINSHORT      $glib_ms
2748 #define G_MAXSHORT      $glib_Ms
2749 #define G_MAXUSHORT     $glib_Mus
2750 #define G_MININT        $glib_mi
2751 #define G_MAXINT        $glib_Mi
2752 #define G_MAXUINT       $glib_Mui
2753 #define G_MINLONG       $glib_ml
2754 #define G_MAXLONG       $glib_Ml
2755 #define G_MAXULONG      $glib_Mul
2756
2757 _______EOF
2758
2759
2760         ### this should always be true in a modern C/C++ compiler
2761         cat >>$outfile <<_______EOF
2762 typedef signed char gint8;
2763 typedef unsigned char guint8;
2764 _______EOF
2765
2766
2767         if test -n "$gint16"; then
2768           cat >>$outfile <<_______EOF
2769 typedef signed $gint16 gint16;
2770 typedef unsigned $gint16 guint16;
2771 #define G_GINT16_MODIFIER $gint16_modifier
2772 #define G_GINT16_FORMAT $gint16_format
2773 #define G_GUINT16_FORMAT $guint16_format
2774 _______EOF
2775         fi
2776
2777
2778         if test -n "$gint32"; then
2779           cat >>$outfile <<_______EOF
2780 typedef signed $gint32 gint32;
2781 typedef unsigned $gint32 guint32;
2782 #define G_GINT32_MODIFIER $gint32_modifier
2783 #define G_GINT32_FORMAT $gint32_format
2784 #define G_GUINT32_FORMAT $guint32_format
2785 _______EOF
2786         fi
2787
2788         cat >>$outfile <<_______EOF
2789 #define G_HAVE_GINT64 1          /* deprecated, always true */
2790
2791 ${glib_extension}typedef signed $gint64 gint64;
2792 ${glib_extension}typedef unsigned $gint64 guint64;
2793
2794 #define G_GINT64_CONSTANT(val)  $gint64_constant
2795 #define G_GUINT64_CONSTANT(val) $guint64_constant
2796 _______EOF
2797
2798         if test x$gint64_format != x ; then
2799           cat >>$outfile <<_______EOF
2800 #define G_GINT64_MODIFIER $gint64_modifier
2801 #define G_GINT64_FORMAT $gint64_format
2802 #define G_GUINT64_FORMAT $guint64_format
2803 _______EOF
2804         else
2805           cat >>$outfile <<_______EOF
2806 #undef G_GINT64_MODIFIER
2807 #undef G_GINT64_FORMAT
2808 #undef G_GUINT64_FORMAT
2809 _______EOF
2810         fi
2811
2812         cat >>$outfile <<_______EOF
2813
2814 #define GLIB_SIZEOF_VOID_P $glib_void_p
2815 #define GLIB_SIZEOF_LONG   $glib_long
2816 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2817
2818 _______EOF
2819
2820         cat >>$outfile <<_______EOF
2821 typedef signed $glib_size_type_define gssize;
2822 typedef unsigned $glib_size_type_define gsize;
2823 #define G_GSIZE_MODIFIER $gsize_modifier
2824 #define G_GSSIZE_FORMAT $gssize_format
2825 #define G_GSIZE_FORMAT $gsize_format
2826
2827 #define G_MAXSIZE       G_MAXU$glib_msize_type
2828 #define G_MINSSIZE      G_MIN$glib_msize_type
2829 #define G_MAXSSIZE      G_MAX$glib_msize_type
2830
2831 typedef gint64 goffset;
2832 #define G_MINOFFSET     G_MININT64
2833 #define G_MAXOFFSET     G_MAXINT64
2834
2835 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2836 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2837 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2838
2839 _______EOF
2840
2841         if test -z "$glib_unknown_void_p"; then
2842           cat >>$outfile <<_______EOF
2843
2844 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2845 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2846
2847 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2848 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2849
2850 typedef signed $glib_intptr_type_define gintptr;
2851 typedef unsigned $glib_intptr_type_define guintptr;
2852
2853 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2854 #define G_GINTPTR_FORMAT        $gintptr_format
2855 #define G_GUINTPTR_FORMAT       $guintptr_format
2856 _______EOF
2857         else
2858           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2859         fi
2860
2861
2862
2863         cat >>$outfile <<_______EOF
2864 $glib_atexit
2865 $glib_memmove
2866 $glib_defines
2867 $glib_os
2868 $glib_static_compilation
2869
2870 $glib_vacopy
2871
2872 #ifdef  __cplusplus
2873 #define G_HAVE_INLINE   1
2874 #else   /* !__cplusplus */
2875 $glib_inline
2876 #endif  /* !__cplusplus */
2877
2878 #ifdef  __cplusplus
2879 #define G_CAN_INLINE    1
2880 _______EOF
2881
2882         if test x$g_can_inline = xyes ; then
2883                 cat >>$outfile <<_______EOF
2884 #else   /* !__cplusplus */
2885 #define G_CAN_INLINE    1
2886 _______EOF
2887         fi
2888
2889         cat >>$outfile <<_______EOF
2890 #endif
2891
2892 _______EOF
2893
2894         if test x$g_have_iso_c_varargs = xyes ; then
2895                 cat >>$outfile <<_______EOF
2896 #ifndef __cplusplus
2897 # define G_HAVE_ISO_VARARGS 1
2898 #endif
2899 _______EOF
2900         fi
2901         if test x$g_have_iso_cxx_varargs = xyes ; then
2902                 cat >>$outfile <<_______EOF
2903 #ifdef __cplusplus
2904 # define G_HAVE_ISO_VARARGS 1
2905 #endif
2906 _______EOF
2907         fi
2908         if test x$g_have_gnuc_varargs = xyes ; then
2909                 cat >>$outfile <<_______EOF
2910
2911 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2912  * is passed ISO vararg support is turned off, and there is no work
2913  * around to turn it on, so we unconditionally turn it off.
2914  */
2915 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2916 #  undef G_HAVE_ISO_VARARGS
2917 #endif
2918
2919 #define G_HAVE_GNUC_VARARGS 1
2920 _______EOF
2921         fi
2922
2923         case x$g_stack_grows in
2924         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2925         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2926         esac
2927
2928
2929         echo >>$outfile
2930         if test x$g_have_eilseq = xno; then
2931                 cat >>$outfile <<_______EOF
2932 #ifndef EILSEQ
2933 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2934  * The correspondence between this and the corresponding definition
2935  * in libiconv is essential.
2936  */
2937 #  define EILSEQ ENOENT
2938 #endif
2939 _______EOF
2940
2941         fi
2942
2943         if test x$g_have_gnuc_visibility = xyes; then
2944                 cat >>$outfile <<_______EOF
2945 #define G_HAVE_GNUC_VISIBILITY 1
2946 _______EOF
2947         fi
2948                 cat >>$outfile <<_______EOF
2949 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2950 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2951 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2952 #define G_GNUC_INTERNAL __hidden
2953 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2954 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2955 #else
2956 #define G_GNUC_INTERNAL
2957 #endif
2958 _______EOF
2959
2960
2961         echo >>$outfile
2962         if test x$g_mutex_has_default = xyes; then
2963                 cat >>$outfile <<_______EOF
2964 $g_enable_threads_def G_THREADS_ENABLED
2965 #define G_THREADS_IMPL_$g_threads_impl_def
2966 typedef struct _GStaticMutex GStaticMutex;
2967 struct _GStaticMutex
2968 {
2969   struct _GMutex *runtime_mutex;
2970   union {
2971     char   pad[[$g_mutex_sizeof]];
2972     double dummy_double;
2973     void  *dummy_pointer;
2974     long   dummy_long;
2975   } static_mutex;
2976 };
2977 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
2978 #define g_static_mutex_get_mutex(mutex) \\
2979   (g_thread_use_default_impl ? ((GMutex*)(gpointer) ((mutex)->static_mutex.pad)) : \\
2980    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
2981 _______EOF
2982         else
2983                 cat >>$outfile <<_______EOF
2984 $g_enable_threads_def G_THREADS_ENABLED
2985 #define G_THREADS_IMPL_$g_threads_impl_def
2986 typedef struct _GMutex* GStaticMutex;
2987 #define G_STATIC_MUTEX_INIT NULL
2988 #define g_static_mutex_get_mutex(mutex) \\
2989   (g_static_mutex_get_mutex_impl_shortcut (mutex))
2990 _______EOF
2991         fi
2992
2993         cat >>$outfile <<_______EOF
2994 /* This represents a system thread as used by the implementation. An
2995  * alien implementaion, as loaded by g_thread_init can only count on
2996  * "sizeof (gpointer)" bytes to store their info. We however need more
2997  * for some of our native implementations. */
2998 typedef union _GSystemThread GSystemThread;
2999 union _GSystemThread
3000 {
3001   char   data[[$g_system_thread_sizeof]];
3002   double dummy_double;
3003   void  *dummy_pointer;
3004   long   dummy_long;
3005 };
3006 _______EOF
3007         if test x"$g_memory_barrier_needed" != xno; then
3008           echo >>$outfile
3009           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3010         fi
3011
3012         echo >>$outfile
3013         g_bit_sizes="16 32 64"
3014         for bits in $g_bit_sizes; do
3015           cat >>$outfile <<_______EOF
3016 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3017 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3018 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3019 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3020 _______EOF
3021         done
3022
3023         cat >>$outfile <<_______EOF
3024 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3025 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3026 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3027 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3028 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3029 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3030 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3031 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3032 #define G_BYTE_ORDER $g_byte_order
3033
3034 #define GLIB_SYSDEF_POLLIN =$g_pollin
3035 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3036 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3037 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3038 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3039 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3040
3041 #define G_MODULE_SUFFIX "$g_module_suffix"
3042
3043 /* A GPid is an abstraction for a process "handle". It is *not* an
3044  * abstraction for a process identifier in general. GPid is used in
3045  * GLib only for descendant processes spawned with the g_spawn*
3046  * functions. On POSIX there is no "process handle" concept as such,
3047  * but on Windows a GPid is a handle to a process, a kind of pointer,
3048  * not a process identifier.
3049  */
3050 typedef $g_pid_type GPid;
3051
3052 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3053 #define GLIB_SYSDEF_AF_INET $g_af_inet
3054 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3055
3056 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3057 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3058 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3059
3060 G_END_DECLS
3061
3062 #endif /* GLIBCONFIG_H */
3063 _______EOF
3064
3065
3066         if cmp -s $outfile glibconfig.h; then
3067           AC_MSG_NOTICE([glibconfig.h is unchanged])
3068           rm -f $outfile
3069         else
3070           mv $outfile glibconfig.h
3071         fi
3072 ],[
3073
3074 # Note that if two cases are the same, case goes with the first one.
3075 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3076 # on variable expansion in case labels.  Look at the generated config.status
3077 # for a hint.
3078
3079 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3080   glib_header_alloca_h="$ac_cv_working_alloca_h"
3081 else
3082   glib_header_alloca_h="$ac_cv_header_alloca_h"
3083 fi
3084
3085 case xyes in
3086 x$ac_cv_header_float_h)
3087   glib_float_h=yes
3088   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3089   glib_md=DBL_MIN glib_Md=DBL_MAX
3090   ;;
3091 x$ac_cv_header_values_h)
3092   glib_values_h=yes
3093   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3094   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3095   ;;
3096 esac
3097
3098 case xyes in
3099 x$ac_cv_header_limits_h)
3100   glib_limits_h=yes
3101   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3102   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3103   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3104   ;;
3105 x$ac_cv_header_values_h)
3106   glib_values_h=yes
3107   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3108   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3109   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3110   ;;
3111 esac
3112
3113 if test x$ac_cv_header_sys_poll_h = xyes ; then
3114   glib_sys_poll_h=yes
3115 fi
3116
3117 if test x$enable_included_printf = xyes ; then
3118   glib_included_printf=yes
3119 fi
3120
3121 case 2 in
3122 $ac_cv_sizeof_short)
3123   gint16=short
3124   gint16_modifier='"h"'
3125   gint16_format='"hi"'
3126   guint16_format='"hu"'
3127   ;;
3128 $ac_cv_sizeof_int)
3129   gint16=int
3130   gint16_modifier='""'
3131   gint16_format='"i"'
3132   guint16_format='"u"'
3133   ;;
3134 esac
3135 case 4 in
3136 $ac_cv_sizeof_short)
3137   gint32=short
3138   gint32_modifier='"h"'
3139   gint32_format='"hi"'
3140   guint32_format='"hu"'
3141   ;;
3142 $ac_cv_sizeof_int)
3143   gint32=int
3144   gint32_modifier='""'
3145   gint32_format='"i"'
3146   guint32_format='"u"'
3147   ;;
3148 $ac_cv_sizeof_long)
3149   gint32=long
3150   gint32_modifier='"l"'
3151   gint32_format='"li"'
3152   guint32_format='"lu"'
3153   ;;
3154 esac
3155 case 8 in
3156 $ac_cv_sizeof_int)
3157   gint64=int
3158   gint64_modifier='""'
3159   gint64_format='"i"'
3160   guint64_format='"u"'
3161   glib_extension=
3162   gint64_constant='(val)'
3163   guint64_constant='(val)'
3164   ;;
3165 $ac_cv_sizeof_long)
3166   gint64=long
3167   gint64_modifier='"l"'
3168   gint64_format='"li"'
3169   guint64_format='"lu"'
3170   glib_extension=
3171   gint64_constant='(val##L)'
3172   guint64_constant='(val##UL)'
3173   ;;
3174 $ac_cv_sizeof_long_long)
3175   gint64='long long'
3176   if test -n "$glib_cv_long_long_format"; then
3177     gint64_modifier='"'$glib_cv_long_long_format'"'
3178     gint64_format='"'$glib_cv_long_long_format'i"'
3179     guint64_format='"'$glib_cv_long_long_format'u"'
3180   fi
3181   glib_extension='G_GNUC_EXTENSION '
3182   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3183   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3184   ;;
3185 $ac_cv_sizeof___int64)
3186   gint64='__int64'
3187   if test -n "$glib_cv_long_long_format"; then
3188     gint64_modifier='"'$glib_cv_long_long_format'"'
3189     gint64_format='"'$glib_cv_long_long_format'i"'
3190     guint64_format='"'$glib_cv_long_long_format'u"'
3191   fi
3192   glib_extension=
3193   gint64_constant='(val##i64)'
3194   guint64_constant='(val##ui64)'
3195   ;;
3196 esac
3197 glib_size_t=$ac_cv_sizeof_size_t
3198 glib_size_type_define="$glib_size_type"
3199 glib_void_p=$ac_cv_sizeof_void_p
3200 glib_long=$ac_cv_sizeof_long
3201
3202 case "$glib_size_type" in
3203 short)
3204   gsize_modifier='"h"'
3205   gsize_format='"hu"'
3206   gssize_format='"hi"'
3207   glib_msize_type='SHRT'
3208   ;;
3209 int)
3210   gsize_modifier='""'
3211   gsize_format='"u"'
3212   gssize_format='"i"'
3213   glib_msize_type='INT'
3214   ;;
3215 long)
3216   gsize_modifier='"l"'
3217   gsize_format='"lu"'
3218   gssize_format='"li"'
3219   glib_msize_type='LONG'
3220   ;;
3221 "long long"|__int64)
3222   gsize_modifier='"I64"'
3223   gsize_format='"I64u"'
3224   gssize_format='"I64i"'
3225   glib_msize_type='INT64'
3226   ;;
3227 esac
3228
3229 gintbits=`expr $ac_cv_sizeof_int \* 8`
3230 glongbits=`expr $ac_cv_sizeof_long \* 8`
3231
3232 case $ac_cv_sizeof_void_p in
3233 $ac_cv_sizeof_int)
3234   glib_intptr_type_define=int
3235   gintptr_modifier='""'
3236   gintptr_format='"i"'
3237   guintptr_format='"u"'
3238   glib_gpi_cast=''
3239   glib_gpui_cast=''
3240   ;;
3241 $ac_cv_sizeof_long)
3242   glib_intptr_type_define=long
3243   gintptr_modifier='"l"'
3244   gintptr_format='"li"'
3245   guintptr_format='"lu"'
3246   glib_gpi_cast='(glong)'
3247   glib_gpui_cast='(gulong)'
3248   ;;
3249 $ac_cv_sizeof_long_long)
3250   glib_intptr_type_define='long long'
3251   gintptr_modifier='"I64"'
3252   gintptr_format='"I64i"'
3253   guintptr_format='"I64u"'
3254   glib_gpi_cast='(gint64)'
3255   glib_gpui_cast='(guint64)'
3256   ;;
3257 $ac_cv_sizeof___int64)
3258   glib_intptr_type_define=__int64
3259   gintptr_modifier='"I64"'
3260   gintptr_format='"I64i"'
3261   guintptr_format='"I64u"'
3262   glib_gpi_cast='(gint64)'
3263   glib_gpui_cast='(guint64)'
3264   ;;
3265 *)
3266   glib_unknown_void_p=yes
3267   ;;
3268 esac
3269
3270
3271 case xyes in
3272 x$ac_cv_func_atexit)
3273   glib_atexit="
3274 #ifdef NeXT /* @#%@! NeXTStep */
3275 # define g_ATEXIT(proc) (!atexit (proc))
3276 #else
3277 # define g_ATEXIT(proc) (atexit (proc))
3278 #endif"
3279   ;;
3280 x$ac_cv_func_on_exit)
3281   glib_atexit="
3282 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3283   ;;
3284 esac
3285
3286 case xyes in
3287 x$ac_cv_func_memmove)
3288   glib_memmove='
3289 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3290   ;;
3291 x$glib_cv_working_bcopy)
3292   glib_memmove="
3293 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3294 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3295   ;;
3296 *)
3297   glib_memmove="
3298 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3299  * so we have to roll our own copy routine. */
3300 void g_memmove (void* dest, const void * src, unsigned long len);"
3301   ;;
3302 esac
3303
3304 glib_defines="
3305 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3306 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3307 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3308 "
3309
3310 case xyes in
3311 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3312 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3313 *)                      glib_vacopy=''
3314 esac
3315
3316 if test x$glib_cv_va_val_copy = xno; then
3317   glib_vacopy="\$glib_vacopy
3318 #define G_VA_COPY_AS_ARRAY 1"
3319 fi
3320
3321 if test x$glib_cv_hasinline = xyes; then
3322     glib_inline='#define G_HAVE_INLINE 1'
3323 fi
3324 if test x$glib_cv_has__inline = xyes; then
3325     glib_inline="\$glib_inline
3326 #define G_HAVE___INLINE 1"
3327 fi
3328 if test x$glib_cv_has__inline__ = xyes; then
3329     glib_inline="\$glib_inline
3330 #define G_HAVE___INLINE__ 1"
3331 fi
3332
3333 g_have_gnuc_varargs=$g_have_gnuc_varargs
3334 g_have_iso_c_varargs=$g_have_iso_c_varargs
3335 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3336
3337 g_can_inline=$g_can_inline
3338 g_have_gnuc_visibility=$g_have_gnuc_visibility
3339 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3340
3341 if test x$ac_cv_c_bigendian = xyes; then
3342   g_byte_order=G_BIG_ENDIAN
3343   g_bs_native=BE
3344   g_bs_alien=LE
3345 else
3346   g_byte_order=G_LITTLE_ENDIAN
3347   g_bs_native=LE
3348   g_bs_alien=BE
3349 fi
3350
3351 g_pollin=$glib_cv_value_POLLIN
3352 g_pollout=$glib_cv_value_POLLOUT
3353 g_pollpri=$glib_cv_value_POLLPRI
3354 g_pollhup=$glib_cv_value_POLLHUP
3355 g_pollerr=$glib_cv_value_POLLERR
3356 g_pollnval=$glib_cv_value_POLLNVAL
3357
3358 g_af_unix=$glib_cv_value_AF_UNIX
3359 g_af_inet=$glib_cv_value_AF_INET
3360 g_af_inet6=$glib_cv_value_AF_INET6
3361
3362 g_msg_peek=$glib_cv_value_MSG_PEEK
3363 g_msg_oob=$glib_cv_value_MSG_OOB
3364 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3365
3366 g_stack_grows=$glib_cv_stack_grows
3367
3368 g_have_eilseq=$have_eilseq
3369
3370 case x$have_threads in
3371 xno)    g_enable_threads_def="#undef";;
3372 *)      g_enable_threads_def="#define";;
3373 esac
3374
3375 g_threads_impl_def=$g_threads_impl
3376
3377 g_mutex_has_default="$mutex_has_default"
3378 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
3379 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
3380 g_mutex_contents="$glib_cv_byte_contents_gmutex"
3381
3382 g_memory_barrier_needed="$glib_memory_barrier_needed"
3383
3384 g_module_suffix="$glib_gmodule_suffix"
3385
3386 g_pid_type="$glib_pid_type"
3387 case $host in
3388   *-*-beos*)
3389     glib_os="#define G_OS_BEOS"
3390     ;;
3391   *-*-cygwin*)
3392     glib_os="#define G_OS_UNIX
3393 #define G_PLATFORM_WIN32
3394 #define G_WITH_CYGWIN"
3395     ;;
3396   *-*-mingw*)
3397     glib_os="#define G_OS_WIN32
3398 #define G_PLATFORM_WIN32"
3399     ;;
3400   *)
3401     glib_os="#define G_OS_UNIX"
3402     ;;
3403 esac
3404 glib_static_compilation=""
3405 if test x$glib_win32_static_compilation = xyes; then
3406   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3407 #define GOBJECT_STATIC_COMPILATION 1"
3408 fi
3409 ])
3410
3411 AC_CONFIG_FILES([
3412 glib-2.0.pc
3413 glib-2.0-uninstalled.pc
3414 gmodule-2.0.pc
3415 gmodule-export-2.0.pc
3416 gmodule-no-export-2.0.pc
3417 gmodule-2.0-uninstalled.pc
3418 gmodule-no-export-2.0-uninstalled.pc
3419 gthread-2.0.pc
3420 gthread-2.0-uninstalled.pc
3421 gobject-2.0.pc
3422 gobject-2.0-uninstalled.pc
3423 gio-2.0.pc
3424 gio-unix-2.0.pc
3425 gio-2.0-uninstalled.pc
3426 gio-unix-2.0-uninstalled.pc
3427 glib-zip
3428 glib-gettextize
3429 Makefile
3430 build/Makefile
3431 build/win32/Makefile
3432 build/win32/dirent/Makefile
3433 build/win32/vs8/Makefile
3434 build/win32/vs9/Makefile
3435 glib/Makefile
3436 glib/libcharset/Makefile
3437 glib/gnulib/Makefile
3438 glib/pcre/Makefile
3439 glib/update-pcre/Makefile
3440 glib/tests/Makefile
3441 gmodule/Makefile
3442 gmodule/gmoduleconf.h
3443 gobject/Makefile
3444 gobject/glib-mkenums
3445 gobject/tests/Makefile
3446 gthread/Makefile
3447 gio/Makefile
3448 gio/xdgmime/Makefile
3449 gio/inotify/Makefile
3450 gio/libasyncns/Makefile
3451 gio/fen/Makefile
3452 gio/fam/Makefile
3453 gio/win32/Makefile
3454 gio/tests/Makefile
3455 po/Makefile.in
3456 docs/Makefile
3457 docs/reference/Makefile
3458 docs/reference/glib/Makefile
3459 docs/reference/glib/version.xml
3460 docs/reference/gobject/Makefile
3461 docs/reference/gobject/version.xml
3462 docs/reference/gio/Makefile
3463 docs/reference/gio/version.xml
3464 tests/Makefile
3465 tests/gobject/Makefile
3466 tests/refcount/Makefile
3467 m4macros/Makefile
3468 ])
3469
3470 AC_CONFIG_COMMANDS([chmod-scripts],
3471 [chmod 0755 glib-zip
3472 chmod 0755 glib-gettextize
3473 chmod 0755 gobject/glib-mkenums])
3474
3475 # we want to invoke this macro solely so that the config.status script
3476 # and automake generated makefiles know about these generated files.
3477 # They are only needed to distcheck the package
3478 if false; then
3479   AC_CONFIG_FILES([
3480     INSTALL
3481     README
3482     config.h.win32
3483     glibconfig.h.win32
3484     glib/makefile.msc
3485     glib/glib.rc
3486     gmodule/makefile.msc
3487     gmodule/gmodule.rc
3488     gobject/makefile.msc
3489     gobject/gobject.rc
3490     gthread/makefile.msc
3491     gthread/gthread.rc
3492     tests/makefile.msc
3493   ])
3494 fi
3495
3496 AC_OUTPUT