configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5
   6 # require autoconf 2.13
   7 AC_PREREQ(2.13)
   8
   9 # Process this file with autoconf to produce a configure script.
  10 AC_INIT(glist.c)
  11
  12 # Save this value here, since automake will set cflags later
  13 cflags_set=${CFLAGS+set}
  14
  15 # we rewrite this file
  16 rm -f glibconfig-sysdefs.h
  17
  18 dnl we to AC_DIVERT_PUSH/AC_DIVERT_POP these variable definitions so they
  19 dnl are available for $ac_help expansion (don't we all *love* autoconf?)
  20 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  21 #
  22 # The following version number definitions apply to GLib and GModule
  23 # as a whole, so if changes occoured in either of them, they are both
  24 # treated with the same interface and binary age.
  25 #
  26 # Making releases:
  27 #   GLIB_MICRO_VERSION += 1;
  28 #   GLIB_INTERFACE_AGE += 1;
  29 #   GLIB_BINARY_AGE += 1;
  30 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  31 # if backwards compatibility has been broken,
  32 # set GLIB_BINARY_AGE and GLIB_INTERFACE_AGE to 0.
  33 #
  34 GLIB_MAJOR_VERSION=1
  35 GLIB_MINOR_VERSION=3
  36 GLIB_MICRO_VERSION=0
  37 GLIB_INTERFACE_AGE=0
  38 GLIB_BINARY_AGE=0
  39 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  40 dnl
  41 AC_DIVERT_POP()dnl
  42
  43 AC_SUBST(GLIB_VERSION)
  44
  45 # libtool versioning
  46 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  47 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  48 LT_REVISION=$GLIB_INTERFACE_AGE
  49 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  50 AC_SUBST(LT_RELEASE)
  51 AC_SUBST(LT_CURRENT)
  52 AC_SUBST(LT_REVISION)
  53 AC_SUBST(LT_AGE)
  54
  55 VERSION=$GLIB_VERSION
  56 PACKAGE=glib
  57
  58 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  59
  60 # Specify a configuration file
  61 AM_CONFIG_HEADER(config.h)
  62
  63 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION)
  64 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION)
  65 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION)
  66 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE)
  67 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE)
  68
  69 dnl Initialize libtool
  70 AM_PROG_LIBTOOL
  71
  72 dnl Initialize maintainer mode
  73 AM_MAINTAINER_MODE
  74
  75 AC_CANONICAL_HOST
  76
  77 dnl figure debugging default, prior to $ac_help setup
  78 dnl
  79 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  80 if test `expr $GLIB_MINOR_VERSION \% 2` = 1 ; then
  81         debug_default=yes
  82 else
  83         debug_default=minimum
  84 fi
  85 AC_DIVERT_POP()dnl
  86
  87 dnl declare --enable-* args and collect ac_help strings
  88 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
  89 AC_ARG_ENABLE(mem_check, [  --enable-mem-check      turn on malloc/free sanity checking [default=no]],,enable_mem_check=no)
  90 AC_ARG_ENABLE(mem_profile, [  --enable-mem-profile    turn on malloc profiling atexit [default=no]],,enable_mem_profile=no)
  91 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
  92                     , enable_ansi=no)
  93 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
  94                           ([=no] will override --with-threads)],,enable_threads=yes)
  95
  96 if test "x$enable_threads" != "xyes"; then
  97   enable_threads=no
  98 fi
  99
 100 AC_MSG_CHECKING(whether to enable memory checking)
 101 if test "x$enable_mem_check" = "xyes"; then
 102   AC_DEFINE(ENABLE_MEM_CHECK, 1)
 103   AC_SUBST(ENABLE_MEM_CHECK)
 104   AC_MSG_RESULT(yes)
 105 else
 106   AC_MSG_RESULT(no)
 107 fi
 108
 109 AC_MSG_CHECKING(whether to enable memory profiling)
 110 if test "x$enable_mem_profile" = "xyes"; then
 111   AC_DEFINE(ENABLE_MEM_PROFILE, 1)
 112   AC_SUBST(ENABLE_MEM_PROFILE)
 113   AC_MSG_RESULT(yes)
 114 else
 115   AC_MSG_RESULT(no)
 116 fi
 117
 118 if test "x$enable_debug" = "xyes"; then
 119   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 120   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 121 else
 122   if test "x$enable_debug" = "xno"; then
 123     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 124   fi
 125 fi
 126
 127 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 128
 129 # Checks for programs.
 130 AC_PROG_CC
 131 AM_PROG_CC_STDC
 132 AC_PROG_INSTALL
 133
 134 changequote(,)dnl
 135 if test "x$GCC" = "xyes"; then
 136   case " $CFLAGS " in
 137   *[\ \ ]-Wall[\ \      ]*) ;;
 138   *) CFLAGS="$CFLAGS -Wall" ;;
 139   esac
 140
 141   if test "x$enable_ansi" = "xyes"; then
 142     case " $CFLAGS " in
 143     *[\ \       ]-ansi[\ \      ]*) ;;
 144     *) CFLAGS="$CFLAGS -ansi" ;;
 145     esac
 146
 147     case " $CFLAGS " in
 148     *[\ \       ]-pedantic[\ \  ]*) ;;
 149     *) CFLAGS="$CFLAGS -pedantic" ;;
 150     esac
 151   fi
 152 fi
 153 changequote([,])dnl
 154
 155 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 156 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 157 glib_save_LIBS=$LIBS
 158 LIBS="$LIBS -lm"
 159 AC_TRY_RUN([#include <math.h>
 160              int main (void) { return (log(1) != log(1.)); }],
 161      AC_MSG_RESULT(none needed),
 162      glib_save_CFLAGS=$CFLAGS
 163      CFLAGS="$CFLAGS -std1"
 164      AC_TRY_RUN([#include <math.h>
 165                  int main (void) { return (log(1) != log(1.)); }],
 166          AC_MSG_RESULT(-std1),
 167          AC_MSG_RESULT()
 168          CFLAGS=$glib_save_CFLAGS
 169          AC_MSG_WARN(
 170                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 171      )
 172 )
 173 LIBS=$glib_save_LIBS
 174
 175 dnl NeXTStep cc seems to need this
 176 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 177 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 178   AC_MSG_RESULT(none needed),
 179   glib_save_CFLAGS=$CFLAGS
 180   CFLAGS="$CFLAGS -posix"
 181   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 182     AC_MSG_RESULT(-posix),
 183     AC_MSG_RESULT()
 184     CFLAGS=$glib_save_CFLAGS
 185     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 186
 187 # Checks for header files.
 188 AC_HEADER_STDC
 189
 190 # Checks for library functions.
 191 AC_FUNC_VPRINTF
 192
 193 AC_CHECK_FUNCS(atexit on_exit)
 194
 195 AC_CHECK_SIZEOF(char)
 196 AC_CHECK_SIZEOF(short)
 197 AC_CHECK_SIZEOF(long)
 198 AC_CHECK_SIZEOF(int)
 199 AC_CHECK_SIZEOF(void *)
 200 AC_CHECK_SIZEOF(long long)
 201
 202 dnl long doubles were not used, and a portability problem
 203 dnl AC_C_LONG_DOUBLE
 204 AC_C_CONST
 205
 206 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 207 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 208 dnl actually supported.
 209 AC_MSG_CHECKING(for __inline)
 210 AC_CACHE_VAL(glib_cv_has__inline,[
 211         AC_TRY_RUN([
 212         __inline int foo () { return 0; }
 213         int main () { return foo (); }
 214         ],
 215         glib_cv_has__inline=yes
 216         ,
 217         glib_cv_has__inline=no
 218         ,)
 219 ])
 220 AC_MSG_RESULT($glib_cv_has__inline)
 221 case x$glib_cv_has__inline in
 222 xyes) AC_DEFINE(G_HAVE___INLINE)
 223 esac
 224 AC_MSG_CHECKING(for __inline__)
 225 AC_CACHE_VAL(glib_cv_has__inline__,[
 226         AC_TRY_RUN([
 227         __inline__ int foo () { return 0; }
 228         int main () { return foo (); }
 229         ],
 230         glib_cv_has__inline__=yes
 231         ,
 232         glib_cv_has__inline__=no
 233         ,)
 234 ])
 235 AC_MSG_RESULT($glib_cv_has__inline__)
 236 case x$glib_cv_has__inline__ in
 237 xyes) AC_DEFINE(G_HAVE___INLINE__)
 238 esac
 239 AC_MSG_CHECKING(for inline)
 240 AC_CACHE_VAL(glib_cv_hasinline,[
 241         AC_TRY_RUN([
 242         inline int foo () { return 0; }
 243         int main () { return foo (); }
 244         ],
 245         glib_cv_hasinline=yes
 246         ,
 247         glib_cv_hasinline=no
 248         ,)
 249 ])
 250 AC_MSG_RESULT($glib_cv_hasinline)
 251 case x$glib_cv_hasinline in
 252 xyes) AC_DEFINE(G_HAVE_INLINE)
 253 esac
 254
 255 dnl for bytesex stuff
 256 AC_C_BIGENDIAN
 257
 258 dnl header file checks
 259 AC_CHECK_HEADERS(float.h, AC_DEFINE(HAVE_FLOAT_H))
 260 AC_CHECK_HEADERS(limits.h, AC_DEFINE(HAVE_LIMITS_H))
 261 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 262 AC_CHECK_HEADERS(sys/param.h, AC_DEFINE(HAVE_SYS_PARAM_H))
 263 AC_CHECK_HEADERS(sys/poll.h, AC_DEFINE(HAVE_SYS_POLL_H))
 264 AC_CHECK_HEADERS(sys/select.h, AC_DEFINE(HAVE_SYS_SELECT_H))
 265 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 266 AC_CHECK_HEADERS(sys/times.h, AC_DEFINE(HAVE_SYS_TIMES_H))
 267 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 268 AC_CHECK_HEADERS(values.h, AC_DEFINE(HAVE_VALUES_H))
 269
 270 # Check for some functions
 271 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf strcasecmp strncasecmp poll)
 272
 273 # Check for sys_errlist
 274 AC_MSG_CHECKING(for sys_errlist)
 275 AC_TRY_LINK(, [
 276 extern char *sys_errlist[];
 277 extern int sys_nerr;
 278 sys_errlist[sys_nerr-1][0] = 0;
 279 ], glib_ok=yes, glib_ok=no)
 280 AC_MSG_RESULT($glib_ok)
 281 if test $glib_ok = no; then
 282     AC_DEFINE(NO_SYS_ERRLIST)
 283 fi
 284
 285 # Check for sys_siglist
 286 AC_MSG_CHECKING(for sys_siglist)
 287 AC_TRY_LINK(, [
 288 extern char *sys_siglist[];
 289 strlen (sys_siglist[0]);
 290 ], glib_ok=yes, glib_ok=no)
 291 AC_MSG_RESULT($glib_ok)
 292 if test $glib_ok = no; then
 293     AC_DEFINE(NO_SYS_SIGLIST)
 294 fi
 295
 296 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 297 AC_MSG_CHECKING(for sys_siglist declaration)
 298 AC_TRY_COMPILE([#include <signal.h>], [
 299 strlen (sys_siglist[0]);
 300 ], glib_ok=yes, glib_ok=no)
 301 AC_MSG_RESULT($glib_ok)
 302 if test $glib_ok = no; then
 303     AC_DEFINE(NO_SYS_SIGLIST_DECL)
 304 fi
 305
 306 # Check if <sys/select.h> needs to be included for fd_set
 307 AC_MSG_CHECKING([for fd_set])
 308 AC_TRY_COMPILE([#include <sys/types.h>],
 309         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 310 if test $gtk_ok = yes; then
 311     AC_MSG_RESULT([yes, found in sys/types.h])
 312 else
 313     AC_HEADER_EGREP(fd_set, sys/select.h, gtk_ok=yes)
 314     if test $gtk_ok = yes; then
 315         AC_DEFINE(HAVE_SYS_SELECT_H)
 316         AC_MSG_RESULT([yes, found in sys/select.h])
 317     else
 318         AC_DEFINE(NO_FD_SET)
 319         AC_MSG_RESULT(no)
 320     fi
 321 fi
 322
 323 dnl *** check for sane realloc() ***
 324 AC_MSG_CHECKING(whether realloc (NULL,) will work)
 325 AC_CACHE_VAL(glib_cv_sane_realloc,[
 326         AC_TRY_RUN([
 327         #include <stdlib.h>
 328         int main() {
 329           return realloc (0, sizeof (int)) == 0;
 330         }],
 331         glib_cv_sane_realloc=yes
 332         AC_DEFINE(REALLOC_0_WORKS)
 333         ,
 334         glib_cv_sane_realloc=no
 335         ,)
 336 ])
 337 AC_MSG_RESULT($glib_cv_sane_realloc)
 338
 339
 340 dnl **********************
 341 dnl *** va_copy checks ***
 342 dnl **********************
 343 dnl we currently check for all three va_copy possibilities, so we get
 344 dnl all results in config.log for bug reports.
 345 AC_MSG_CHECKING(for an implementation of va_copy())
 346 AC_CACHE_VAL(glib_cv_va_copy,[
 347         AC_TRY_RUN([
 348         #include <stdarg.h>
 349         void f (int i, ...) {
 350         va_list args1, args2;
 351         va_start (args1, i);
 352         va_copy (args2, args1);
 353         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 354           exit (1);
 355         va_end (args1); va_end (args2);
 356         }
 357         int main() {
 358           f (0, 42);
 359           return 0;
 360         }],
 361         glib_cv_va_copy=yes
 362         ,
 363         glib_cv_va_copy=no
 364         ,)
 365 ])
 366 AC_MSG_RESULT($glib_cv_va_copy)
 367 AC_MSG_CHECKING(for an implementation of __va_copy())
 368 AC_CACHE_VAL(glib_cv___va_copy,[
 369         AC_TRY_RUN([
 370         #include <stdarg.h>
 371         void f (int i, ...) {
 372         va_list args1, args2;
 373         va_start (args1, i);
 374         __va_copy (args2, args1);
 375         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 376           exit (1);
 377         va_end (args1); va_end (args2);
 378         }
 379         int main() {
 380           f (0, 42);
 381           return 0;
 382         }],
 383         glib_cv___va_copy=yes
 384         ,
 385         glib_cv___va_copy=no
 386         ,)
 387 ])
 388 AC_MSG_RESULT($glib_cv___va_copy)
 389 AC_MSG_CHECKING(whether va_lists can be copied by value)
 390 AC_CACHE_VAL(glib_cv_va_val_copy,[
 391         AC_TRY_RUN([
 392         #include <stdarg.h>
 393         void f (int i, ...) {
 394         va_list args1, args2;
 395         va_start (args1, i);
 396         args2 = args1;
 397         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 398           exit (1);
 399         va_end (args1); va_end (args2);
 400         }
 401         int main() {
 402           f (0, 42);
 403           return 0;
 404         }],
 405         glib_cv_va_val_copy=yes
 406         ,
 407         glib_cv_va_val_copy=no
 408         ,)
 409 ])
 410 if test "x$glib_cv_va_copy" = "xyes"; then
 411   AC_DEFINE(G_VA_COPY, va_copy)
 412 else if test "x$glib_cv___va_copy" = "xyes"; then
 413   AC_DEFINE(G_VA_COPY, __va_copy)
 414 fi
 415 fi
 416 if test "x$glib_cv_va_val_copy" = "xno"; then
 417   AC_DEFINE(G_VA_COPY_AS_ARRAY)
 418 fi
 419 AC_MSG_RESULT($glib_cv_va_val_copy)
 420
 421
 422 dnl ***********************
 423 dnl *** g_module checks ***
 424 dnl ***********************
 425 G_MODULE_LIBS=
 426 G_MODULE_LDFLAGS=
 427 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
 428 G_MODULE_NEED_USCORE=0
 429 G_MODULE_HAVE_DLERROR=0
 430 dnl *** dlopen() and dlsym() in system libraries
 431 if test -z "$G_MODULE_IMPL"; then
 432         AC_CHECK_FUNC(dlopen,
 433                 AC_CHECK_FUNC(dlsym,
 434                         G_MODULE_IMPL=G_MODULE_IMPL_DL
 435                 ,)
 436         ,)
 437 fi
 438 dnl *** dlopen() and dlsym() in libdl
 439 if test -z "$G_MODULE_IMPL"; then
 440         AC_CHECK_LIB(dl, dlopen,
 441                 AC_CHECK_LIB(dl, dlsym,
 442                         G_MODULE_LIBS=-ldl
 443                         G_MODULE_IMPL=G_MODULE_IMPL_DL
 444                 ,)
 445         ,)
 446 fi
 447 dnl *** shl_load() in libdld (HP-UX)
 448 if test -z "$G_MODULE_IMPL"; then
 449         AC_MSG_CHECKING(how to export all symbols)
 450         SAVED_LDFLAGS=$LDFLAGS
 451         LDFLAGS="$LDFLAGS -Wl,-E"
 452         AC_TRY_LINK(,[ return 0; ],
 453                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 454                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 455                 AC_TRY_LINK(,[ return 0; ],
 456                         G_MODULE_LDFLAGS="-bexpall",
 457                         G_MODULE_LDFLAGS="none"
 458                 )
 459         ])
 460         LDFLAGS=$SAVED_LDFLAGS
 461         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 462         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 463                 G_MODULE_LDFLAGS=
 464         fi
 465         AC_CHECK_LIB(dld, shl_load,
 466                 G_MODULE_LIBS=-ldld
 467                 G_MODULE_IMPL=G_MODULE_IMPL_DLD
 468         ,)
 469 fi
 470 dnl *** additional checks for G_MODULE_IMPL_DL
 471 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 472         case "$host_os" in
 473           linux*)
 474             G_MODULE_LDFLAGS='-rdynamic'
 475             ;;
 476         esac
 477         LIBS_orig="$LIBS"
 478         LDFLAGS_orig="$LDFLAGS"
 479         LIBS="$LIBS $G_MODULE_LIBS"
 480         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 481 dnl *** check whether we need preceeding underscores
 482         AC_MSG_CHECKING(for preceeding underscore in symbols)
 483         AC_CACHE_VAL(glib_cv_uscore,[
 484                 AC_TRY_RUN([
 485                 #include <dlfcn.h>
 486                 int glib_underscore_test (void) { return 42; }
 487                 int main() {
 488                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 489                   handle = dlopen ((void*)0, 0);
 490                   if (handle) {
 491                     f1 = dlsym (handle, "glib_underscore_test");
 492                     f2 = dlsym (handle, "_glib_underscore_test");
 493                   } return (!f2 || f1);
 494                 }],
 495                         glib_cv_uscore=yes,
 496                         glib_cv_uscore=no,
 497                 )
 498                 rm -f plugin.c plugin.o plugin.lo
 499         ])
 500         AC_MSG_RESULT($glib_cv_uscore)
 501         if test "x$glib_cv_uscore" = "xyes"; then
 502                 G_MODULE_NEED_USCORE=1
 503         else
 504                 G_MODULE_NEED_USCORE=0
 505         fi
 506
 507         LDFLAGS="$LDFLAGS_orig"
 508 dnl *** check for having dlerror()
 509         AC_CHECK_FUNC(dlerror,
 510                 G_MODULE_HAVE_DLERROR=1,
 511                 G_MODULE_HAVE_DLERROR=0)
 512         LIBS="$LIBS_orig"
 513 fi
 514 dnl *** done, have e got an implementation?
 515 if test -z "$G_MODULE_IMPL"; then
 516         G_MODULE_IMPL=0
 517 fi
 518 AC_SUBST(G_MODULE_IMPL)
 519 AC_SUBST(G_MODULE_LIBS)
 520 AC_SUBST(G_MODULE_LDFLAGS)
 521 AC_SUBST(G_MODULE_HAVE_DLERROR)
 522 AC_SUBST(G_MODULE_NEED_USCORE)
 523 AC_SUBST(GLIB_DEBUG_FLAGS)
 524
 525
 526 dnl ***********************
 527 dnl *** g_thread checks ***
 528 dnl ***********************
 529
 530 AC_ARG_WITH(threads, [  --with-threads=[none/posix/dce/solaris/nspr] specify a thread implementation to use],
 531         if test "x$with_threads" = x; then
 532                 want_threads=yes
 533         else
 534                 want_threads=$with_threads
 535         fi,
 536         want_threads=yes)
 537 if test "x$enable_threads" = "xno"; then
 538         want_threads=no
 539 fi
 540 if test "x$want_threads" = "xnone"; then
 541         want_threads=no
 542 fi
 543
 544 dnl error and warning message
 545 dnl *************************
 546
 547 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
 548                 computer. GLib will not have a default thread implementation."
 549
 550 FLAG_DOES_NOT_WORK="I can't find the MACRO, that enables thread safety on your
 551                 platform (normaly it's "_REENTRANT"). I'll not use any flag on
 552                 compilation now, but then your programs might not work.
 553                 Please provide information on how it is done on your system."
 554
 555 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
 556                 "
 557
 558 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
 559                 provide information on your thread implementation.
 560                 You can also run 'configure --disable-threads'
 561                 to compile without thread support."
 562
 563 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
 564                 functions will not be MT-safe during their first call because
 565                 there is no working 'getpwuid_r' on your system."
 566
 567 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
 568                 because there is no 'localtime_r' on your system."
 569
 570 dnl determination of thread implementation
 571 dnl ***************************************
 572
 573 have_threads=none
 574 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
 575         case $host in
 576                 *-*-solaris*)
 577                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
 578                 ;;
 579         esac
 580 fi
 581 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
 582                                 || test "x$want_threads" = xdce; then
 583         # -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
 584         # -U_OSF_SOURCE if for Digital UNIX 4.0d
 585         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
 586         glib_save_CPPFLAGS="$CPPFLAGS"
 587         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
 588         if test "x$have_threads" = xnone; then
 589                 AC_EGREP_HEADER([[^a-zA-Z_]pthread_attr_init[^a-zA-Z_]],
 590                         pthread.h,
 591                         have_threads=posix)
 592         fi
 593         if test "x$have_threads" = xnone; then
 594                 AC_EGREP_HEADER([[^a-zA-Z_]pthread_attr_create[^a-zA-Z_]],
 595                         pthread.h,
 596                         have_threads=dce)
 597         fi
 598         CPPFLAGS="$glib_save_CPPFLAGS"
 599 fi
 600 if test "x$want_threads" = xyes || test "x$want_threads" = xnspr; then
 601         if test "x$have_threads" = xnone; then
 602                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar, have_threads=nspr)
 603         fi
 604 fi
 605
 606 AC_MSG_CHECKING(for thread implementation)
 607
 608 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
 609         AC_MSG_RESULT(none available)
 610         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
 611 else
 612         AC_MSG_RESULT($have_threads)
 613 fi
 614
 615
 616 dnl determination of G_THREAD_LIBS
 617 dnl ******************************
 618
 619 G_THREAD_LIBS=
 620 G_THREAD_CFLAGS=
 621
 622 mutex_has_default=no
 623 case $have_threads in
 624         posix|dce)
 625                 G_THREAD_LIBS=error
 626                 glib_save_LIBS="$LIBS"
 627                 for thread_lib in "" pthread pthreads c_r thread dce; do
 628                         # This is not AC_CHECK_LIB to also work with function
 629                         # name mangling in header files.
 630                         if test x"$thread_lib" = x; then
 631                                 add_thread_lib=""
 632                                 IN=""
 633                         else
 634                                 add_thread_lib="-l$thread_lib"
 635                                 IN=" in -l$thread_lib"
 636                         fi
 637
 638                         LIBS="$glib_save_LIBS $add_thread_lib"
 639
 640                         AC_MSG_CHECKING(for pthread_create$IN)
 641                         AC_TRY_LINK([#include <pthread.h>],
 642                                 [pthread_create(NULL,NULL,NULL,NULL)],
 643                                 [AC_MSG_RESULT(yes)
 644                                 G_THREAD_LIBS="$add_thread_lib"
 645                                 break],
 646                                 [AC_MSG_RESULT(no)])
 647                 done
 648                 LIBS="$glib_save_LIBS"
 649                 mutex_has_default=yes
 650                 mutex_default_type='pthread_mutex_t'
 651                 mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
 652                 mutex_header_file='pthread.h'
 653                 if test "x$have_threads" = "xposix"; then
 654                         g_threads_impl="POSIX"
 655                 else
 656                         g_threads_impl="DCE"
 657                         have_threads="posix"
 658                 fi
 659                 AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
 660                 ;;
 661         solaris)
 662                 G_THREAD_LIBS=error
 663                 AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
 664                 mutex_has_default=yes
 665                 mutex_default_type='mutex_t'
 666                 mutex_default_init="DEFAULTMUTEX"
 667                 mutex_header_file='thread.h'
 668                 g_threads_impl="SOLARIS"
 669                 ;;
 670         nspr)
 671                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar,
 672                              G_THREAD_LIBS="-lnspr21")
 673                 g_threads_impl="NSPR"
 674                 ;;
 675         none)
 676                 g_threads_impl="NONE"
 677                 ;;
 678         *)
 679                 g_threads_impl="NONE"
 680                 G_THREAD_LIBS=error
 681                 ;;
 682 esac
 683
 684 if test "x$G_THREAD_LIBS" = xerror; then
 685         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 686 fi
 687
 688 AC_MSG_CHECKING(thread related libraries)
 689 AC_MSG_RESULT($G_THREAD_LIBS)
 690
 691 dnl determination of G_THREAD_CFLAGS
 692 dnl ********************************
 693
 694 if test x"$enable_threads" = xyes; then
 695
 696     G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_REENTRANT" # good default guess
 697
 698     case $host in
 699         *-aix*)
 700                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 701                 if test x"$GCC" = xyes; then
 702                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
 703                 fi
 704                 ;;
 705         *-freebsd2.2*)
 706                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 707
 708                 # FreeBSD 2.2.x shiped with gcc 2.7.2.x, which doesn't support
 709                 # -mthreads flag.
 710                 ;;
 711     esac
 712
 713     # if we are not finding the ctime_r function, then we probably are
 714     # not using the proper multithread flag
 715     old_CPPFLAGS=$CPPFLAGS
 716     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
 717     # Note: Digital UNIX 4.0d #defines ctime_r to _Pctime_r for gcc.
 718     AC_EGREP_HEADER([[^a-zA-Z_](_P)?ctime_r[^a-zA-Z_]], time.h, ,
 719     G_THREAD_CFLAGS=
 720     AC_MSG_WARN($FLAG_DOES_NOT_WORK))
 721     CPPFLAGS=$old_CPPFLAGS
 722
 723     AC_MSG_CHECKING(thread related cflags)
 724
 725     AC_MSG_RESULT($G_THREAD_CFLAGS)
 726 else
 727     G_THREAD_CFLAGS=
 728 fi
 729
 730 dnl check for mt safe function variants and some posix functions
 731 dnl ************************************************************
 732
 733 if test x"$enable_threads" = xyes; then
 734         glib_save_LIBS="$LIBS"
 735         glib_save_CFLAGS="$CFLAGS"
 736         # we are not doing the following for now, as this might require glib
 737         # to always be linked with the thread libs on some platforms.
 738         # LIBS="$LIBS $G_THREAD_LIBS"
 739         CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 740         AC_CHECK_FUNCS(localtime_r rand_r)
 741         if test "$ac_cv_header_pwd_h" = "yes"; then
 742                 AC_MSG_CHECKING([for getpwuid_r])
 743                 AC_CACHE_VAL(ac_cv_func_getpwuid_r,
 744                         [AC_TRY_RUN([#include <errno.h>
 745                                 int main () { char buffer[10000], *pointer;
 746                                 char getpwuid_r (long, void*, void*,
 747                                         int, void*);
 748                                 errno = 0;
 749                                 getpwuid_r (0, &buffer, &buffer,
 750                                         sizeof (buffer), &pointer);
 751                                 return errno == ENOSYS;}],
 752                                 [ac_cv_func_getpwuid_r=yes],
 753                                 [ac_cv_func_getpwuid_r=no])])
 754                 if test "$ac_cv_func_getpwuid_r" = yes; then
 755                         AC_MSG_RESULT(yes)
 756                         AC_DEFINE(HAVE_GETPWUID_R)
 757                 else
 758                         AC_MSG_RESULT(no)
 759                 fi
 760                 if test "$ac_cv_func_getpwuid_r" = "yes"; then
 761                         AC_MSG_CHECKING(whether getpwuid_r is posix like)
 762                         # getpwuid_r(0, NULL, NULL, 0) is the signature on
 763                         # solaris, if that is not found, the prog below won't
 764                         # compile, then the posix signature is assumed as
 765                         # the default.
 766                         AC_TRY_COMPILE([#include <pwd.h>],
 767                                 [getpwuid_r(0, NULL, NULL, 0);],
 768                                 [AC_MSG_RESULT(no)],
 769                                 [AC_MSG_RESULT(yes)
 770                                 AC_DEFINE(HAVE_GETPWUID_R_POSIX)])
 771                 fi
 772         fi
 773         LIBS="$glib_save_LIBS"
 774         CFLAGS="$glib_save_CFLAGS"
 775
 776         # now spit out all the warnings.
 777         if test "$ac_cv_func_getpwuid_r" != "yes"; then
 778                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
 779         fi
 780         if test "$ac_cv_func_localtime_r" != "yes"; then
 781                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
 782         fi
 783 fi
 784
 785 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c")
 786 AC_SUBST(G_THREAD_CFLAGS)
 787 AC_SUBST(G_THREAD_LIBS)
 788
 789 CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 790
 791 dnl **********************************************
 792 dnl *** GDefaultMutex setup and initialization ***
 793 dnl **********************************************
 794 dnl
 795 dnl if mutex_has_default = yes, we also got
 796 dnl mutex_default_type, mutex_default_init and mutex_header_file
 797 GLIB_IF_VAR_EQ(mutex_has_default, yes,
 798         GLIB_SIZEOF([#include <$mutex_header_file>],
 799                     $mutex_default_type,
 800                     gmutex,
 801                     )
 802         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
 803                            $mutex_default_type,
 804                            gmutex,
 805                            $glib_cv_sizeof_gmutex,
 806                            $mutex_default_init)
 807         ,
 808 )
 809
 810
 811 dnl ****************************************
 812 dnl *** GLib POLL* compatibility defines ***
 813 dnl ****************************************
 814 GLIB_SYSDEFS(
 815 [#include <sys/types.h>
 816 #include <sys/poll.h>],
 817         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
 818         glibconfig-sysdefs.h,
 819         =)
 820
 821
 822 dnl ******************************
 823 dnl *** output the whole stuff ***
 824 dnl ******************************
 825
 826 AC_OUTPUT_COMMANDS([
 827
 828 ## Generate `glibconfig.h' in two cases
 829 ## 1. `config.status' is run either explicitly, or via configure.
 830 ##     Esp. not when it is run in `Makefile' to generate makefiles and
 831 ##     config.h
 832 ## 2. CONFIG_OTHER is set explicitly
 833 ##
 834 ## Case 1 is difficult.  We know that `automake' sets one of
 835 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
 836 ## only when AM_CONFIG_HEADER is set, however.
 837
 838 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
 839   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
 840   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
 841 fi
 842 case "$CONFIG_OTHER" in
 843 *glibconfig.h*)
 844         echo creating glibconfig.h
 845         outfile=glibconfig.h-tmp
 846         cat > $outfile <<\_______EOF
 847 /* glibconfig.h
 848  *
 849  * This is a generated file.  Please modify `configure.in'
 850  */
 851
 852 #ifndef GLIBCONFIG_H
 853 #define GLIBCONFIG_H
 854
 855 #ifdef __cplusplus
 856 extern "C" {
 857 #endif /* __cplusplus */
 858
 859 _______EOF
 860
 861         if test x$glib_limits_h = xyes; then
 862           echo '#include <limits.h>' >> $outfile
 863         fi
 864         if test x$glib_float_h = xyes; then
 865           echo '#include <float.h>' >> $outfile
 866         fi
 867         if test x$glib_values_h = xyes; then
 868           echo '#include <values.h>' >> $outfile
 869         fi
 870         if test x$g_mutex_header_file != x; then
 871           echo '#include <'"$g_mutex_header_file"'>' >> $outfile
 872         fi
 873         if test x$glib_sys_poll_h = xyes; then
 874           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
 875         fi
 876
 877         cat >> $outfile <<_______EOF
 878
 879 #define G_MINFLOAT      $glib_mf
 880 #define G_MAXFLOAT      $glib_Mf
 881 #define G_MINDOUBLE     $glib_md
 882 #define G_MAXDOUBLE     $glib_Md
 883 #define G_MINSHORT      $glib_ms
 884 #define G_MAXSHORT      $glib_Ms
 885 #define G_MAXUSHORT     $glib_Mus
 886 #define G_MININT        $glib_mi
 887 #define G_MAXINT        $glib_Mi
 888 #define G_MAXUINT       $glib_Mui
 889 #define G_MINLONG       $glib_ml
 890 #define G_MAXLONG       $glib_Ml
 891 #define G_MAXULONG      $glib_Mul
 892
 893 _______EOF
 894
 895
 896         ### this should always be true in a modern C/C++ compiler
 897         cat >>$outfile <<_______EOF
 898 typedef signed char gint8;
 899 typedef unsigned char guint8;
 900 _______EOF
 901
 902
 903         if test -n "$gint16"; then
 904           cat >>$outfile <<_______EOF
 905 typedef signed $gint16 gint16;
 906 typedef unsigned $gint16 guint16;
 907 #define G_GINT16_FORMAT $gint16_format
 908 #define G_GUINT16_FORMAT $guint16_format
 909 _______EOF
 910         fi
 911
 912
 913         if test -n "$gint32"; then
 914           cat >>$outfile <<_______EOF
 915 typedef signed $gint32 gint32;
 916 typedef unsigned $gint32 guint32;
 917 #define G_GINT32_FORMAT $gint32_format
 918 #define G_GUINT32_FORMAT $guint32_format
 919 _______EOF
 920         fi
 921
 922
 923         if test -n "$gint64"; then
 924           cat >>$outfile <<_______EOF
 925 ${glib_warning_guard}#define G_HAVE_GINT64 1
 926
 927 ${glib_extension}typedef signed $gint64 gint64;
 928 ${glib_extension}typedef unsigned $gint64 guint64;
 929
 930 #define G_GINT64_FORMAT $gint64_format
 931 #define G_GUINT64_FORMAT $guint64_format
 932 #define G_GINT64_CONSTANT(val)  $gint64_constant
 933 _______EOF
 934         fi
 935
 936
 937         if test -z "$glib_unknown_void_p"; then
 938           cat >>$outfile <<_______EOF
 939
 940 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
 941 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
 942
 943 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
 944 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
 945 _______EOF
 946         else
 947           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
 948         fi
 949
 950
 951
 952         cat >>$outfile <<_______EOF
 953 $glib_atexit
 954 $glib_memmove
 955 $glib_defines
 956
 957 $glib_vacopy
 958
 959 #ifdef  __cplusplus
 960 #define G_HAVE_INLINE   1
 961 #else   /* !__cplusplus */
 962 $glib_inline
 963 #endif  /* !__cplusplus */
 964 _______EOF
 965
 966         echo >>$outfile
 967         if test x$g_mutex_has_default = xyes; then
 968                 cat >>$outfile <<_______EOF
 969 $g_enable_threads_def G_THREADS_ENABLED
 970 #define G_THREADS_IMPL_$g_threads_impl_def
 971 typedef struct _GStaticMutex GStaticMutex;
 972 struct _GStaticMutex
 973 {
 974   struct _GMutex *runtime_mutex;
 975   union {
 976     char   pad[$g_mutex_sizeof];
 977     double dummy_double;
 978     void  *dummy_pointer;
 979     long   dummy_long;
 980   } aligned_pad_u;
 981 };
 982 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
 983 #define g_static_mutex_get_mutex(mutex) \
 984   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->aligned_pad_u)) : \
 985    g_static_mutex_get_mutex_impl (&((mutex)->runtime_mutex)))
 986 _______EOF
 987         else
 988                 cat >>$outfile <<_______EOF
 989 $g_enable_threads_def G_THREADS_ENABLED
 990 #define G_THREADS_IMPL_$g_threads_impl_def
 991 typedef struct _GMutex* GStaticMutex;
 992 #define G_STATIC_MUTEX_INIT NULL
 993 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (mutex))
 994 _______EOF
 995         fi
 996
 997         echo >>$outfile
 998         g_bit_sizes="16 32"
 999         if test -n "$gint64"; then
1000           g_bit_sizes="$g_bit_sizes 64"
1001         fi
1002         for bits in $g_bit_sizes; do
1003           cat >>$outfile <<_______EOF
1004 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
1005 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
1006 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
1007 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
1008 _______EOF
1009         done
1010
1011         cat >>$outfile <<_______EOF
1012 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
1013 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
1014 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
1015 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
1016 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
1017 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
1018 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
1019 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
1020 #define G_BYTE_ORDER $g_byte_order
1021
1022 _______EOF
1023
1024         if test -r glibconfig-sysdefs.h; then
1025           cat glibconfig-sysdefs.h >>$outfile
1026         fi
1027
1028         cat >>$outfile <<_______EOF
1029 #ifdef __cplusplus
1030 }
1031 #endif /* __cplusplus */
1032
1033 #endif /* GLIBCONFIG_H */
1034 _______EOF
1035
1036
1037         if cmp -s $outfile glibconfig.h; then
1038           echo glibconfig.h is unchanged
1039           rm -f $outfile
1040         else
1041           mv $outfile glibconfig.h
1042         fi ;;
1043 esac
1044 ],[
1045
1046 # Note that if two cases are the same, case goes with the first one.
1047 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
1048 # on variable expansion in case labels.  Look at the generated config.status
1049 # for a hint.
1050
1051 case xyes in
1052 x$ac_cv_header_float_h)
1053   glib_float_h=yes
1054   glib_mf=FLT_MIN glib_Mf=FLT_MAX
1055   glib_md=DBL_MIN glib_Md=DBL_MAX
1056   ;;
1057 x$ac_cv_header_values_h)
1058   glib_values_h=yes
1059   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
1060   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
1061   ;;
1062 esac
1063
1064 case xyes in
1065 x$ac_cv_header_limits_h)
1066   glib_limits_h=yes
1067   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
1068   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
1069   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
1070   ;;
1071 x$ac_cv_header_values_h)
1072   glib_values_h=yes
1073   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
1074   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
1075   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
1076   ;;
1077 esac
1078
1079 if test x$ac_cv_header_sys_poll_h = xyes ; then
1080   glib_sys_poll_h=yes
1081 fi
1082
1083 case 2 in
1084 $ac_cv_sizeof_short)
1085   gint16=short
1086   gint16_format='"hi"'
1087   guint16_format='"hu"'
1088   ;;
1089 $ac_cv_sizeof_int)
1090   gint16=int
1091   gint16_format='"i"'
1092   guint16_format='"u"'
1093   ;;
1094 esac
1095 case 4 in
1096 $ac_cv_sizeof_short)
1097   gint32=short
1098   gint32_format='"hi"'
1099   guint32_format='"hu"'
1100   ;;
1101 $ac_cv_sizeof_int)
1102   gint32=int
1103   gint32_format='"i"'
1104   guint32_format='"u"'
1105   ;;
1106 $ac_cv_sizeof_long)
1107   gint32=long
1108   gint32_format='"li"'
1109   guint32_format='"lu"'
1110   ;;
1111 esac
1112 case 8 in
1113 $ac_cv_sizeof_int)
1114   gint64=int
1115   gint64_format='"i"'
1116   guint64_format='"u"'
1117   glib_extension=
1118   glib_warning_guard=
1119   gint64_constant='(val)'
1120   ;;
1121 $ac_cv_sizeof_long)
1122   gint64=long
1123   gint64_format='"li"'
1124   guint64_format='"lu"'
1125   glib_extension=
1126   glib_warning_guard=
1127   gint64_constant='(val##L)'
1128   ;;
1129 $ac_cv_sizeof_long_long)
1130   gint64='long long'
1131   gint64_format='"lli"'
1132   guint64_format='"llu"'
1133   glib_extension='G_GNUC_EXTENSION '
1134   glib_warning_guard="
1135 #if defined (__GNUC__) && __GNUC__ >= 2 && __GNUC_MINOR__ >= 8
1136 #  define G_GNUC_EXTENSION __extension__
1137 #else
1138 #  define G_GNUC_EXTENSION
1139 #endif
1140
1141 "
1142   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1143   ;;
1144 esac
1145
1146 gintbits=`expr $ac_cv_sizeof_int \* 8`
1147 glongbits=`expr $ac_cv_sizeof_long \* 8`
1148
1149
1150 case $ac_cv_sizeof_void_p in
1151 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
1152 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
1153 *)                      glib_unknown_void_p=yes ;;
1154 esac
1155
1156
1157 case xyes in
1158 x$ac_cv_func_atexit)
1159   glib_atexit="
1160 #ifdef NeXT /* @#%@! NeXTStep */
1161 # define g_ATEXIT(proc) (!atexit (proc))
1162 #else
1163 # define g_ATEXIT(proc) (atexit (proc))
1164 #endif"
1165   ;;
1166 x$ac_cv_func_on_exit)
1167   glib_atexit="
1168 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
1169   ;;
1170 esac
1171
1172 case xyes in
1173 x$ac_cv_func_memmove)
1174   glib_memmove='
1175 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
1176   ;;
1177 *)
1178   glib_memmove="
1179 /* We make the assumption that if memmove isn't available, then
1180  * bcopy will do the job. This isn't safe everywhere. (bcopy can't
1181  * necessarily handle overlapping copies) */
1182 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
1183   ;;
1184 esac
1185
1186 glib_defines="
1187 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
1188 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
1189 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
1190 "
1191
1192 case xyes in
1193 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
1194 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
1195 *)                      glib_vacopy=''
1196 esac
1197
1198 if test x$glib_cv_va_val_copy = xno; then
1199   glib_vacopy="\$glib_vacopy
1200 #define G_VA_COPY_AS_ARRAY 1"
1201 fi
1202
1203 if test x$glib_cv_hasinline = xyes; then
1204     glib_inline='#define G_HAVE_INLINE 1'
1205 fi
1206 if test x$glib_cv_has__inline = xyes; then
1207     glib_inline="\$glib_inline
1208 #define G_HAVE___INLINE 1"
1209 fi
1210 if test x$glib_cv_has__inline__ = xyes; then
1211     glib_inline="\$glib_inline
1212 #define G_HAVE___INLINE__ 1"
1213 fi
1214
1215 case xyes in
1216 x$ac_cv_c_bigendian)
1217   g_byte_order=G_BIG_ENDIAN
1218   g_bs_native=BE
1219   g_bs_alien=LE
1220   ;;
1221 *)
1222   g_byte_order=G_LITTLE_ENDIAN
1223   g_bs_native=LE
1224   g_bs_alien=BE
1225   ;;
1226 esac
1227
1228 case x$enable_threads in
1229 xyes)   g_enable_threads_def="#define";;
1230 *)      g_enable_threads_def="#undef ";;
1231 esac
1232
1233 g_threads_impl_def=$g_threads_impl
1234
1235 g_mutex_has_default="$mutex_has_default"
1236 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
1237 g_mutex_contents="$glib_cv_byte_contents_gmutex"
1238 ])
1239
1240 AC_OUTPUT([
1241 glib.spec
1242 Makefile
1243 glib-config
1244 gmodule/gmoduleconf.h
1245 gmodule/Makefile
1246 gthread/Makefile
1247 docs/Makefile
1248 tests/Makefile
1249 ],[case "$CONFIG_FILES" in
1250 *glib-config*)chmod +x glib-config;;
1251 esac])