configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION([$CVSid$])
   3 AC_PREREQ(2.13)dnl              dnl Minimum Autoconf version required.
   4 AC_INIT(include/features.h)
   5 AC_CONFIG_HEADER(config.h)
   6 AC_CONFIG_AUX_DIR(scripts)
   7
   8 # This will get text that should go into config.make.
   9 config_vars=
  10
  11 # Check for a --with-gmp argument and set gmp-srcdir in config.make.
  12 AC_ARG_WITH(gmp, dnl
  13   --with-gmp=DIRECTORY    find GMP source code in DIRECTORY (not needed),
  14             [dnl
  15 case "$with_gmp" in
  16 yes) AC_MSG_ERROR(--with-gmp requires an argument; use --with-gmp=DIRECTORY) ;;
  17 ''|no) ;;
  18 *) config_vars="$config_vars
  19 gmp-srcdir = $withval" ;;
  20 esac
  21 ])
  22 # Check for a --with-gettext argument and set gettext-srcdir in config.make.
  23 AC_ARG_WITH(gettext, dnl
  24   --with-gettext=DIR      find GNU gettext source code in DIR (not needed),
  25             [dnl
  26 case "$with_gettext" in
  27 yes)
  28   AC_MSG_ERROR(--with-gettext requires an argument; use --with-gettext=DIR) ;;
  29 ''|no) ;;
  30 *)
  31   config_vars="$config_vars
  32 gettext-srcdir = $withval" ;;
  33 esac
  34 ])
  35
  36 dnl Arguments to specify presence of other packages/features.
  37 AC_ARG_WITH(fp, dnl
  38 [  --with-fp              if using floating-point hardware [default=yes]],
  39             with_fp=$withval, with_fp=yes)
  40 AC_ARG_WITH(binutils, dnl
  41   --with-binutils=PATH    specify location of binutils (as and ld),
  42             path_binutils=$withval, path_binutils='')
  43 AC_ARG_WITH(elf, dnl
  44   --with-elf              if using the ELF object format,
  45             elf=$withval, elf=no)
  46 AC_ARG_WITH(cvs, dnl
  47 [  --without-cvs          if CVS should not be used],
  48             with_cvs=$withval, with_cvs=yes)
  49 AC_SUBST(with_cvs)
  50
  51 AC_ARG_WITH(headers, dnl
  52 [  --with-headers=PATH     location of system headers to use
  53                           [e.g. /usr/src/linux/include]
  54                           [default=compiler default]],
  55             sysheaders=$withval, sysheaders='')
  56
  57 AC_ARG_ENABLE(libio, dnl
  58 [  --enable-libio          build in GNU libio instead of GNU stdio],
  59               [if test $enableval = yes; then
  60                  stdio=libio
  61                else
  62                  stdio=stdio
  63                fi],
  64               stdio=default)
  65
  66 AC_ARG_ENABLE(sanity-checks, dnl
  67 [  --disable-sanity-checks really do not use threads (should not be used
  68                           except in special situations) [default=yes]],
  69               enable_sanity=$enableval, enable_sanity=yes)
  70
  71 dnl Arguments to enable or disable building the static, shared, profiled,
  72 dnl and -fomit-frame-pointer libraries.
  73 dnl I've disabled this for now since we cannot build glibc without static
  74 dnl libraries built in the moment.
  75 dnl AC_ARG_ENABLE(static, dnl
  76 dnl [  --enable-static         build static library [default=yes]],
  77 dnl           static=$enableval, static=yes)
  78 static=yes
  79 AC_ARG_ENABLE(shared, dnl
  80 [  --enable-shared         build shared library [default=yes if GNU ld & ELF]],
  81               shared=$enableval, shared=default)
  82 AC_ARG_ENABLE(profile, dnl
  83 [  --enable-profile        build profiled library [default=yes]],
  84               profile=$enableval, profile=yes)
  85 AC_ARG_ENABLE(omitfp, dnl
  86 [  --enable-omitfp         build undebuggable optimized library [default=no]],
  87               omitfp=$enableval, omitfp=no)
  88 AC_ARG_ENABLE(bounded, dnl
  89 [  --enable-bounded        build with runtime bounds checking [default=no]],
  90               bounded=$enableval, bounded=no)
  91 AC_ARG_ENABLE(versioning, dnl
  92 [  --disable-versioning    do not include versioning information in the
  93                           library objects [default=yes if supported]],
  94              enable_versioning=$enableval, enable_versioning=yes)
  95
  96 dnl Generic infrastructure for drop-in additions to libc.
  97 AC_ARG_ENABLE(add-ons, dnl
  98 [  --enable-add-ons[=DIR1,DIR2]...
  99                           configure and build add-ons in DIR1,DIR2,...
 100                           search for add-ons if no parameter given],
 101   [case "$enableval" in
 102     yes) add_ons=`cd $srcdir && echo */configure | sed -e 's!/configure!!g'`
 103          test "$add_ons" = "*" && add_ons= ;;
 104     *) add_ons=`echo "$enableval" | sed 's/,/ /g'`;;
 105    esac],
 106   [add_ons=])
 107
 108 AC_CONFIG_SUBDIRS($add_ons)
 109 add_ons_pfx=
 110 if test x"$add_ons" != x; then
 111   for f in $add_ons; do
 112     # Test whether such a subdir really exists.
 113     if test -d $srcdir/$f; then
 114       add_ons_pfx="$add_ons_pfx $f/"
 115     else
 116       AC_MSG_ERROR(add-on directory \"$f\" does not exist)
 117     fi
 118   done
 119 fi
 120
 121 dnl On some platforms we cannot use dynamic loading.  We must provide
 122 dnl static NSS modules.
 123 AC_ARG_ENABLE(static-nss, dnl
 124 [  --enable-static-nss     build static NSS modules [default=no]],
 125               static_nss=$enableval, static_nss=no)
 126 if test x"$static_nss" = xyes; then
 127   AC_DEFINE(DO_STATIC_NSS)
 128 fi
 129
 130 AC_ARG_ENABLE(force-install,
 131 [  --disable-force-install don't force installation of files from this package,
 132                           even if they are older than the installed files],
 133               force_install=$enableval, force_install=yes)
 134 AC_SUBST(force_install)
 135
 136 dnl On some platforms we allow dropping compatibility with all kernel
 137 dnl versions.
 138 AC_ARG_ENABLE(kernel,
 139 [  --enable-kernel=VERSION compile for compatibility with kernel not older
 140                            than VERSION],
 141               minimum_kernel=$enableval)
 142
 143 AC_CANONICAL_HOST
 144
 145 # The way shlib-versions is used to generate soversions.mk uses a
 146 # fairly simplistic model for name recognition that can't distinguish
 147 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 148 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 149 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 150 case "$host_os" in
 151 linux*)
 152   ;;
 153 gnu*)
 154   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 155   ;;
 156 esac
 157
 158 # We keep the original values in `$config_*' and never modify them, so we
 159 # can write them unchanged into config.make.  Everything else uses
 160 # $machine, $vendor, and $os, and changes them whenever convenient.
 161 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 162
 163 # Some configurations imply other options.
 164 case "$host_os" in
 165 gnu* | linux* | bsd4.4* | netbsd* | freebsd*)
 166   # These systems always use GNU tools.
 167   gnu_ld=yes gnu_as=yes ;;
 168 esac
 169 case "$host_os" in
 170 # i586-linuxaout is mangled into i586-pc-linux-gnuaout
 171 linux*ecoff* | linux*aout* | gnu*aout* | gnu*ecoff*)
 172   ;;
 173 gnu* | linux* | sysv4* | solaris2* | irix6*)
 174   # These systems (almost) always use the ELF format.
 175   elf=yes
 176   ;;
 177 esac
 178
 179 machine=$config_machine
 180 vendor=$config_vendor
 181 os=$config_os
 182
 183 ###
 184 ### I put this here to prevent those annoying emails from people who cannot
 185 ### read and try to compile glibc on unsupported platforms.  --drepper
 186 ###
 187 ### By using the undocumented --enable-hacker-mode option for configure
 188 ### one can skip this test to make the configuration not fail for unsupported
 189 ### platforms.
 190 ###
 191 if test -z "$enable_hacker_mode"; then
 192   case "$machine-$host_os" in
 193   *-linux* | *-gnu* | arm*-none*)
 194     ;;
 195   *)
 196     echo "*** The GNU C library is currently not available for this platform."
 197     echo "*** So far nobody cared to port it and if there is no volunteer it"
 198     echo "*** might never happen.  So, if you have interest to see glibc on"
 199     echo "*** this platform visit"
 200     echo "***   http://www.gnu.org/software/libc/porting.html"
 201     echo "*** and join the group of porters"
 202     exit 1
 203     ;;
 204   esac
 205 fi
 206
 207 dnl We need to use [ and ] for other purposes for a while now.
 208 changequote(,)dnl
 209 # Expand the configuration machine name into a subdirectory by architecture
 210 # type and particular chip.
 211 case "$machine" in
 212 a29k | am29000) base_machine=a29k machine=a29k ;;
 213 alpha*)         base_machine=alpha machine=alpha/$machine ;;
 214 arm*)           base_machine=arm machine=arm/$machine ;;
 215 c3[012])        base_machine=cx0 machine=cx0/c30 ;;
 216 c4[04])         base_machine=cx0 machine=cx0/c40 ;;
 217 hppa*)          base_machine=hppa machine=hppa/$machine ;;
 218 i[3456]86)      base_machine=i386 machine=i386/$machine ;;
 219 m680?0)         base_machine=m68k machine=m68k/$machine ;;
 220 m68k)           base_machine=m68k machine=m68k/m68020 ;;
 221 m88???)         base_machine=m88k machine=m88k/$machine ;;
 222 m88k)           base_machine=m88k machine=m88k/m88100 ;;
 223 mips64*)        base_machine=mips64 machine=mips/mips64/$machine ;;
 224 mips*)          base_machine=mips
 225                 case "`uname -m`" in
 226                 IP22) machine=mips/mips3 ;;
 227                 *)    machine=mips/$machine ;;
 228                 esac ;;
 229 sparc | sparcv[67])
 230                 base_machine=sparc machine=sparc/sparc32 ;;
 231 sparcv8 | supersparc | hypersparc)
 232                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 233 sparcv8plus | sparcv8plusa | sparcv9)
 234                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 235 sparc64 | ultrasparc)
 236                 base_machine=sparc machine=sparc/sparc64 ;;
 237 esac
 238 changequote([,])dnl
 239 AC_SUBST(base_machine)
 240
 241 if test "$base_machine" = "i386"; then
 242   AC_DEFINE(USE_REGPARMS)
 243 fi
 244
 245 # Compute the list of sysdep directories for this configuration.
 246 # This can take a while to compute.
 247 sysdep_dir=$srcdir/sysdeps
 248 AC_MSG_CHECKING(sysdep dirs)
 249 dnl We need to use [ and ] for other purposes for a while now.
 250 changequote(,)dnl
 251 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 252 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 253
 254 case "$os" in
 255 gnu*)
 256   base_os=mach/hurd ;;
 257 netbsd* | 386bsd* | freebsd* | bsdi*)
 258   base_os=unix/bsd/bsd4.4 ;;
 259 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 260   base_os=unix/bsd ;;
 261 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 262   base_os=unix/sysv ;;
 263 irix6*)
 264   base_os=unix/sysv/irix6/$os ;;
 265 solaris[2-9]*)
 266   base_os=unix/sysv/sysv4 ;;
 267 hpux*)
 268   base_os=unix/sysv/hpux/$os ;;
 269 none)
 270   base_os=standalone ;;
 271 *)
 272   base_os='' ;;
 273 esac
 274
 275 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 276 tail=$os
 277 ostry=$os
 278 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 279   ostry="$ostry /$o"
 280   tail=$o
 281 done
 282 o=`echo $tail | sed 's/[0-9]*$//'`
 283 if test $o != $tail; then
 284   ostry="$ostry /$o"
 285 fi
 286 # For linux-gnu, try linux-gnu, then linux.
 287 o=`echo $tail | sed 's/-.*$//'`
 288 if test $o != $tail; then
 289   ostry="$ostry /$o"
 290 fi
 291
 292 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 293 base=
 294 tail=$base_os
 295 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 296   set $b
 297   base="$base /$1"
 298   tail="$2"
 299 done
 300
 301 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 302 mach=
 303 tail=$machine
 304 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 305   set $m
 306   # Prepend the machine's FPU directory unless --without-fp.
 307   if test "$with_fp" = yes; then
 308     mach="$mach /$1/fpu"
 309   fi
 310   mach="$mach /$1"
 311   tail="$2"
 312 done
 313
 314 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 315 changequote([,])dnl
 316
 317 # Find what sysdep directories exist.
 318 sysnames=
 319 IFS="${IFS=     }"; ac_save_ifs="$IFS"; IFS="${IFS}:"
 320 for d in $add_ons_pfx ''; do
 321   for b in $base ''; do
 322     for m0 in $mach ''; do
 323       for v in /$vendor ''; do
 324         test "$v" = / && continue
 325         for o in /$ostry ''; do
 326           test "$o" = / && continue
 327           for m in $mach ''; do
 328             if test "$m0$b$v$o$m"; then
 329               try="${d}sysdeps$m0$b$v$o$m"
 330               test -n "$enable_debug_configure" &&
 331               echo "$0 [DEBUG]: try $try" >&2
 332               if test -d $srcdir/$try; then
 333                 sysnames="$sysnames $try"
 334                 { test -n "$o" || test -n "$b"; } && os_used=t
 335                 { test -n "$m" || test -n "$m0"; } && machine_used=t
 336               fi
 337             fi
 338           done
 339         done
 340       done
 341     done
 342   done
 343 done
 344 IFS="$ac_save_ifs"
 345
 346 if test -z "$os_used" && test "$os" != none; then
 347   AC_MSG_ERROR(Operating system $os is not supported.)
 348 fi
 349 if test -z "$machine_used" && test "$machine" != none; then
 350   AC_MSG_ERROR(The $machine is not supported.)
 351 fi
 352
 353 # We have now validated the configuration.
 354
 355
 356 # If using ELF, look for an `elf' subdirectory of each machine directory.
 357 # We prepend these rather than inserting them whereever the machine appears
 358 # because things specified by the machine's ELF ABI should override
 359 # OS-specific things, and should always be the same for any OS on the
 360 # machine (otherwise what's the point of an ABI?).
 361 if test "$elf" = yes; then
 362   elf_dirs=
 363   for d in $add_ons_pfx ''; do
 364     for m in $mach; do
 365       if test -d $srcdir/${d}sysdeps$m/elf; then
 366         elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 367       fi
 368     done
 369   done
 370   sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 371 fi
 372
 373
 374 # Expand the list of system names into a full list of directories
 375 # from each element's parent name and Implies file (if present).
 376 set $sysnames
 377 names=
 378 while test $# -gt 0; do
 379   name=$1
 380   shift
 381
 382   case " $names " in *" $name "*)
 383     # Already in the list.
 384     continue
 385   esac
 386
 387   # Report each name as we discover it, so there is no long pause in output.
 388   echo $ac_n "$name $ac_c" >&AC_FD_MSG
 389
 390   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 391
 392   case $name in
 393     /*) xsrcdir= ;;
 394     *)  xsrcdir=$srcdir/ ;;
 395   esac
 396   test -n "$enable_debug_configure" &&
 397   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 398
 399   if test -f $xsrcdir$name/Implies; then
 400     # Collect more names from the `Implies' file (removing comments).
 401     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 402     implied=
 403     for x in $implied_candidate; do
 404       if test -d $xsrcdir$name_base/$x; then
 405         implied="$implied $name_base/$x";
 406       else
 407         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 408       fi
 409     done
 410   else
 411     implied=
 412   fi
 413
 414   # Add NAME to the list of names.
 415   names="$names $name"
 416
 417   # Find the parent of NAME, using the empty string if it has none.
 418 changequote(,)dnl
 419   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 420 changequote([,])dnl
 421
 422   # Add the names implied by NAME, and NAME's parent (if it has one), to
 423   # the list of names to be processed (the argument list).  We prepend the
 424   # implied names to the list and append the parent.  We want implied
 425   # directories to come before further directories inferred from the
 426   # configuration components; this ensures that for sysv4, unix/common
 427   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 428   # after sysv4).
 429   sysnames="`echo $implied $* $parent`"
 430   test -n "$sysnames" && set $sysnames
 431 done
 432
 433 # Add the default directories.
 434 default_sysnames=sysdeps/generic
 435 if test "$elf" = yes; then
 436   default_sysnames="sysdeps/generic/elf $default_sysnames"
 437 fi
 438 sysnames="$names $default_sysnames"
 439 AC_SUBST(sysnames)
 440 # The other names were emitted during the scan.
 441 AC_MSG_RESULT($default_sysnames)
 442
 443
 444 ### Locate tools.
 445
 446 AC_PROG_INSTALL
 447 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
 448   # The makefiles need to use a different form to find it in $srcdir.
 449   INSTALL='\$(..)./install-sh -c'
 450 fi
 451 AC_PROG_LN_S
 452
 453 # These programs are version sensitive.
 454 AC_REQUIRE([AC_CHECK_TOOL_PREFIX])dnl
 455 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 456   [version \([egcygnustp-]*[0-9.]*\)],
 457   [egcs-2.9[1-9].*|egcs-2.90.2[789]|egcs-2.90.[3-9][0-9]|*gcc-2.9[1-9].*|pgcc-2.90.2[789]|pgcc-2.90.[3-9][0-9]|*2.8.[1-9]*|*2.9|*2.9.[0-9]*|2.9[5-9]*|cygnus-2.9[1-9].*|gcc-2.9[5-9]|gcc-2.1[0-9][0-9]],
 458   critic_missing=t)
 459 AC_CHECK_PROG_VER(MAKE, make gmake, --version,
 460   [version \([0-9][0-9.]*\), by],
 461   [3.75 | 3.76.[1-9]* | 3.7[789]* | 3.[89]*], critic_missing=t)
 462
 463 AC_CHECK_PROG_VER(MSGFMT, msgfmt gmsgfmt, --version,
 464   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 465   [0.[1-9][0-9].* | [1-9].*], MSGFMT=: aux_missing=t)
 466 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 467   [GNU texinfo.* \([0-9][0-9.]*\)],
 468   [3.1[1-9] | 3.[2-9][0-9] | 1.6[89] | 1.7[0-9]], MAKEINFO=: aux_missing=t)
 469
 470 if test -n "$critic_missing"; then
 471 AC_MSG_ERROR([
 472 *** Some critical program is missing or too old.
 473 *** Check the INSTALL file for required versions.])
 474 fi
 475
 476 test -n "$aux_missing" && AC_MSG_WARN([
 477 *** An auxiliary program is missing or too old;
 478 *** some features will be disabled.
 479 *** Check the INSTALL file for required versions.])
 480
 481 AC_PROG_CC_LOCAL
 482 AC_CANONICAL_BUILD
 483 if test $host != $build; then
 484   AC_CHECK_PROGS(BUILD_CC, gcc cc)
 485 fi
 486 AC_SUBST(cross_compiling)
 487 AC_PROG_CPP
 488 LIBC_PROG_BINUTILS
 489 AC_CHECK_TOOL(MIG, mig)
 490
 491 # if using special system headers, find out the compiler's sekrit
 492 # header directory and add that to the list.  NOTE: Only does the right
 493 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 494 if test -n "$sysheaders"; then
 495   ccheaders=`$CC -print-file-name=include`
 496   SYSINCLUDES="-nostdinc -isystem $ccheaders -isystem $sysheaders"
 497 fi
 498 AC_SUBST(SYSINCLUDES)
 499
 500 # check if ranlib is necessary
 501 AC_CACHE_CHECK(whether ranlib is necessary, libc_cv_ranlib_necessary, [dnl
 502 cat > conftest.c <<EOF
 503 int a;
 504 char b;
 505 void c(void) {}
 506 EOF
 507 $CC $CFLAGS -c conftest.c
 508 $AR cr conftest.a conftest.c
 509 cp conftest.a conftest2.a
 510 $RANLIB conftest.a
 511 if cmp -s conftest.a conftest2.a; then
 512   libc_cv_ranlib_necessary=no
 513 else
 514   libc_cv_ranlib_necessary=yes
 515 fi
 516 rm -rf conftest*])
 517 if test "$libc_cv_ranlib_necessary" = no; then
 518  RANLIB=:
 519 fi
 520
 521 # Test if LD_LIBRARY_PATH contains the notation for the current directory
 522 # since this would lead to problems installing/building glibc.
 523 # LD_LIBRARY_PATH contains the current directory if one of the following
 524 # is true:
 525 # - one of the terminals (":" and ";") is the first or last sign
 526 # - two terminals occur directly after each other
 527 # - the path contains an element with a dot in it
 528 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
 529 changequote(,)dnl
 530 case ${LD_LIBRARY_PATH} in
 531   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
 532     ld_library_path_setting="contains current directory"
 533     ;;
 534   *)
 535     ld_library_path_setting="ok"
 536     ;;
 537 esac
 538 changequote([,])dnl
 539 AC_MSG_RESULT($ld_library_path_setting)
 540 if test "$ld_library_path_setting" != "ok"; then
 541 AC_MSG_ERROR([
 542 *** LD_LIBRARY_PATH shouldn't contain the current directory when
 543 *** building glibc. Please change the environment variable
 544 *** and run configure again.])
 545 fi
 546
 547 AC_PATH_PROG(BASH, bash, no)
 548 if test "$BASH" != no &&
 549    $BASH -c 'test "$BASH_VERSINFO" \
 550              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
 551   libc_cv_have_bash2=yes
 552 else
 553   libc_cv_have_bash2=no
 554 fi
 555 AC_SUBST(libc_cv_have_bash2)
 556
 557 dnl We need a ksh compatible shell for tzselect.
 558 if test "$BASH" = no; then
 559   AC_PATH_PROG(KSH, ksh, no)
 560   if test "$KSH" = no; then
 561     libc_cv_have_ksh=no
 562   else
 563     libc_cv_have_ksh=yes
 564   fi
 565 else
 566   KSH="$BASH"
 567   AC_SUBST(KSH)
 568   libc_cv_have_ksh=yes
 569 fi
 570 AC_SUBST(libc_cv_have_ksh)
 571
 572 AC_PROG_AWK
 573 AC_PATH_PROG(PERL, perl, no)
 574 AC_SUBST(PERL)
 575 AC_PATH_PROG(INSTALL_INFO, install-info, no,
 576              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
 577 AC_SUBST(INSTALL_INFO)
 578 if test "$INSTALL_INFO" != "no"; then
 579 AC_CACHE_CHECK(for old Debian install-info, libc_cv_old_debian_install_info,
 580  [mkdir conftest.d
 581   # There is a hard ^_ on the next line.  I am open to better ideas.
 582   (echo '\1f'
 583   echo 'File: dir       Node: Top       This is the top of the INFO tree'
 584   echo '* Menu:') >conftest.d/dir
 585   (echo 'INFO-DIR-SECTION i-d-s works'
 586   echo 'START-INFO-DIR-ENTRY'
 587   echo '* Prog: (prog).   Program.'
 588   echo 'END-INFO-DIR-ENTRY') >conftest.d/prog.info
 589   if $INSTALL_INFO --info-dir=conftest.d conftest.d/prog.info >&AC_FD_CC 2>&1
 590   then
 591     if grep -s 'i-d-s works' conftest.d/dir >/dev/null
 592     then libc_cv_old_debian_install_info=no
 593     else libc_cv_old_debian_install_info=yes
 594     fi
 595   else libc_cv_old_debian_install_info=no testfailed=t
 596   fi
 597   rm -fr conftest.d])
 598 if test -n "$testfailed"
 599 then AC_MSG_WARN([install-info errored out, check config.log])
 600 fi
 601 OLD_DEBIAN_INSTALL_INFO=$libc_cv_old_debian_install_info
 602 fi
 603 AC_SUBST(OLD_DEBIAN_INSTALL_INFO)
 604
 605 AC_CACHE_CHECK(for signed size_t type, libc_cv_signed_size_t, [dnl
 606 echo '#include <stddef.h>
 607 FOOBAR __SIZE_TYPE__ FOOBAR' > conftest.c
 608 if eval "$ac_cpp conftest.c 2>/dev/null" \
 609 | grep '^FOOBAR.*unsigned.*FOOBAR$' >/dev/null; then
 610   libc_cv_signed_size_t=no
 611 else
 612   libc_cv_signed_size_t=yes
 613 fi
 614 rm -f conftest*])
 615 if test $libc_cv_signed_size_t = yes; then
 616   dnl Do this by hand instead of AC_DEFINE so can add #undef to avoid warnings.
 617   cat >> confdefs.h <<\EOF
 618 #undef __SIZE_TYPE__
 619 #define __SIZE_TYPE__ unsigned
 620 EOF
 621 fi
 622
 623 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
 624 AC_TRY_COMPILE(dnl
 625 [#define __need_size_t
 626 #define __need_wchar_t
 627 #include <stddef.h>
 628 #define __need_NULL
 629 #include <stddef.h>], [size_t size; wchar_t wchar;
 630 #ifdef offsetof
 631 #error stddef.h ignored __need_*
 632 #endif
 633 if (&size == NULL || &wchar == NULL) abort ();],
 634                libc_cv_friendly_stddef=yes,
 635                libc_cv_friendly_stddef=no)])
 636 if test $libc_cv_friendly_stddef = yes; then
 637   config_vars="$config_vars
 638 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
 639 fi
 640
 641 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
 642                libc_cv_need_minus_P, [dnl
 643 cat > conftest.S <<EOF
 644 #include "confdefs.h"
 645 /* Nothing whatsoever.  */
 646 EOF
 647 if ${CC-cc} $CFLAGS -c conftest.S 2>/dev/null; then
 648   libc_cv_need_minus_P=no
 649 else
 650   libc_cv_need_minus_P=yes
 651 fi
 652 rm -f conftest*])
 653 if test $libc_cv_need_minus_P = yes; then
 654   config_vars="$config_vars
 655 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
 656 fi
 657
 658 AC_CACHE_CHECK(for assembler global-symbol directive,
 659                libc_cv_asm_global_directive, [dnl
 660 libc_cv_asm_global_directive=UNKNOWN
 661 for ac_globl in .globl .global .EXPORT; do
 662   cat > conftest.s <<EOF
 663 .text
 664         ${ac_globl} foo
 665 foo:
 666 EOF
 667   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 668     libc_cv_asm_global_directive=${ac_globl}
 669   fi
 670   rm -f conftest*
 671   test $libc_cv_asm_global_directive != UNKNOWN && break
 672 done])
 673 if test $libc_cv_asm_global_directive = UNKNOWN; then
 674   AC_MSG_ERROR(cannot determine asm global directive)
 675 else
 676   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 677 fi
 678
 679 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
 680 cat > conftest.s <<EOF
 681 .text
 682 foo:
 683 .set glibc_conftest_frobozz,foo
 684 $libc_cv_asm_global_directive glibc_conftest_frobozz
 685 EOF
 686 # The alpha-dec-osf1 assembler gives only a warning for `.set'
 687 # (but it doesn't work), so we must do a linking check to be sure.
 688 cat > conftest1.c <<\EOF
 689 extern int glibc_conftest_frobozz;
 690 main () { printf ("%d\n", glibc_conftest_frobozz); }
 691 EOF
 692 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
 693             -o conftest conftest.s conftest1.c 1>&AC_FD_CC 2>&AC_FD_CC; then
 694   libc_cv_asm_set_directive=yes
 695 else
 696   libc_cv_asm_set_directive=no
 697 fi
 698 rm -f conftest*])
 699 if test $libc_cv_asm_set_directive = yes; then
 700   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
 701 fi
 702
 703 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
 704 [cat > conftest.s <<EOF
 705 .text
 706 _sym:
 707 .symver _sym,sym@VERS
 708 EOF
 709 if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 710   libc_cv_asm_symver_directive=yes
 711 else
 712   libc_cv_asm_symver_directive=no
 713 fi
 714 rm -f conftest*])
 715 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
 716 if test $libc_cv_asm_symver_directive = yes; then
 717   cat > conftest.s <<EOF
 718 .text
 719 _sym:
 720 .symver _sym,sym@VERS
 721 EOF
 722   cat > conftest.map <<EOF
 723 VERS_1 {
 724         global: sym;
 725 };
 726
 727 VERS_2 {
 728         global: sym;
 729 } VERS_1;
 730 EOF
 731   if ${CC-cc} -c $CFLAGS $CPPFLAGS conftest.s 1>&AC_FD_CC 2>&AC_FD_CC; then
 732     if AC_TRY_COMMAND([${CC-cc} $CFLAGS -shared -o conftest.so conftest.o
 733                                         -nostartfiles -nostdlib
 734                                         -Wl,--version-script,conftest.map
 735                        1>&AC_FD_CC]);
 736     then
 737       libc_cv_ld_version_script_option=yes
 738     else
 739       libc_cv_ld_version_script_option=no
 740     fi
 741   else
 742     libc_cv_ld_version_script_option=no
 743   fi
 744 else
 745   libc_cv_ld_version_script_option=no
 746 fi
 747 rm -f conftest*])
 748 if test $libc_cv_asm_symver_directive = yes &&
 749    test $libc_cv_ld_version_script_option = yes &&
 750    test $enable_versioning = yes; then
 751   VERSIONING=yes
 752   AC_DEFINE(DO_VERSIONING)
 753 else
 754   VERSIONING=no
 755 fi
 756 AC_SUBST(VERSIONING)
 757
 758 if test $VERSIONING = no; then
 759   echo "\
 760 *** WARNING: You should not compile GNU libc without versioning. Not using
 761 *** versioning will introduce incompatibilities so that old binaries
 762 *** will not run anymore.
 763 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
 764 fi
 765 if test $elf = yes; then
 766   AC_CACHE_CHECK(for .previous assembler directive,
 767                  libc_cv_asm_previous_directive, [dnl
 768   cat > conftest.s <<EOF
 769 .section foo_section
 770 .previous
 771 EOF
 772   if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 773     libc_cv_asm_previous_directive=yes
 774   else
 775     libc_cv_asm_previous_directive=no
 776   fi
 777   rm -f conftest*])
 778   if test $libc_cv_asm_previous_directive = yes; then
 779     AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
 780   else
 781     AC_CACHE_CHECK(for .popsection assembler directive,
 782                    libc_cv_asm_popsection_directive, [dnl
 783     cat > conftest.s <<EOF
 784 .pushsection foo_section
 785 .popsection
 786 EOF
 787     if AC_TRY_COMMAND(${CC-cc} -c $CFLAGS conftest.s 1>&AC_FD_CC); then
 788       libc_cv_asm_popsection_directive=yes
 789     else
 790       libc_cv_asm_popsection_directive=no
 791     fi
 792     rm -f conftest*])
 793     if test $libc_cv_asm_popsection_directive = yes; then
 794       AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
 795     fi
 796   fi
 797 fi
 798
 799 if test $elf != yes; then
 800   AC_CACHE_CHECK(for .init and .fini sections, libc_cv_have_initfini,
 801                  [AC_TRY_COMPILE(, [asm (".section .init");
 802                                     asm (".section .fini");
 803                                     asm (".text");],
 804                                  libc_cv_have_initfini=yes,
 805                                  libc_cv_have_initfini=no)])
 806   AC_SUBST(libc_cv_have_initfini)dnl
 807   if test $libc_cv_have_initfini = yes; then
 808     AC_DEFINE(HAVE_INITFINI)
 809   fi
 810 fi
 811
 812 dnl AC_CHECK_ASM_UNDERSCORE([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
 813 AC_DEFUN(AC_CHECK_ASM_UNDERSCORE,
 814 [cat > conftest.$ac_ext <<EOF
 815 dnl This sometimes fails to find confdefs.h, for some reason.
 816 dnl [#]line __oline__ "[$]0"
 817 [#]line __oline__ "configure"
 818 #include "confdefs.h"
 819 void underscore_test(void) {
 820 return; }
 821 EOF
 822 if AC_TRY_EVAL(ac_compile); then
 823   if grep _underscore_test conftest* >/dev/null; then
 824     ifelse([$1], , :, [rm -f conftest*
 825     $1])
 826   else
 827     ifelse([$2], , , [rm -f conftest*
 828     $2])
 829   fi
 830 else
 831   echo "configure: failed program was:" >&AC_FD_CC
 832   cat conftest.$ac_ext >&AC_FD_CC
 833   ifelse([$2], , , [rm -f conftest*
 834   $2])
 835 fi
 836 rm -f conftest*])
 837
 838 if test $elf = yes; then
 839   libc_cv_asm_underscores=no
 840 else
 841   if test $ac_cv_prog_cc_works = yes; then
 842     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 843                    [AC_TRY_LINK([asm ("_glibc_foobar:");], [glibc_foobar ();],
 844                                 libc_cv_asm_underscores=yes,
 845                                 libc_cv_asm_underscores=no)])
 846   else
 847     AC_CACHE_CHECK(for _ prefix on C symbol names, libc_cv_asm_underscores,
 848                    [AC_CHECK_ASM_UNDERSCORE(libc_cv_asm_underscores=yes,
 849                                             libc_cv_asm_underscores=no)])
 850   fi
 851 fi
 852 if test $libc_cv_asm_underscores = no; then
 853   AC_DEFINE(NO_UNDERSCORES)
 854 fi
 855
 856 if test $elf = yes; then
 857   libc_cv_weak_symbols=yes
 858 fi
 859
 860 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
 861                  [dnl
 862 cat > conftest.s <<EOF
 863 .text
 864 ${libc_cv_asm_global_directive} foo
 865 foo:
 866 .weak foo
 867 .weak bar; bar = foo
 868 EOF
 869 if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 870   libc_cv_asm_weak_directive=yes
 871 else
 872   libc_cv_asm_weak_directive=no
 873 fi
 874 rm -f conftest*])
 875
 876 if test $libc_cv_asm_weak_directive = no; then
 877   AC_CACHE_CHECK(for assembler .weakext directive,
 878                  libc_cv_asm_weakext_directive,
 879                  [dnl
 880 cat > conftest.s <<EOF
 881 .text
 882 ${libc_cv_asm_global_directive} foo
 883 foo:
 884 .weakext bar foo
 885 .weakext baz
 886 ${libc_cv_asm_global_directive} baz
 887 baz:
 888 EOF
 889   if ${CC-cc} $CFLAGS -c conftest.s 2>/dev/null; then
 890     libc_cv_asm_weakext_directive=yes
 891   else
 892     libc_cv_asm_weakext_directive=no
 893   fi
 894   rm -f conftest*])
 895
 896 fi # no .weak
 897
 898 if test $libc_cv_asm_weak_directive = yes; then
 899   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
 900 elif test $libc_cv_asm_weakext_directive = yes; then
 901   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
 902 fi
 903
 904 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
 905 cat > conftest.c <<\EOF
 906 _start () {}
 907 int __eh_pc;
 908 __throw () {}
 909 EOF
 910 dnl No \ in command here because it ends up inside ''.
 911 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 912                             -nostdlib -nostartfiles -Wl,--no-whole-archive
 913                             -o conftest conftest.c 1>&AC_FD_CC]); then
 914   libc_cv_ld_no_whole_archive=yes
 915 else
 916   libc_cv_ld_no_whole_archive=no
 917 fi
 918 rm -f conftest*])
 919 if test $libc_cv_ld_no_whole_archive = yes; then
 920   no_whole_archive=-Wl,--no-whole-archive
 921 fi
 922 AC_SUBST(no_whole_archive)dnl
 923
 924 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
 925 cat > conftest.c <<\EOF
 926 _start () {}
 927 int __eh_pc;
 928 __throw () {}
 929 EOF
 930 dnl No \ in command here because it ends up inside ''.
 931 if AC_TRY_COMMAND([${CC-cc} $CFLAGS
 932                             -nostdlib -nostartfiles -fexceptions
 933                             -o conftest conftest.c 1>&AC_FD_CC]); then
 934   libc_cv_gcc_exceptions=yes
 935 else
 936   libc_cv_gcc_exceptions=no
 937 fi
 938 rm -f conftest*])
 939 if test $libc_cv_gcc_exceptions = yes; then
 940   exceptions=-fexceptions
 941 fi
 942 AC_SUBST(exceptions)dnl
 943
 944 if test "$base_machine" = alpha ; then
 945 AC_CACHE_CHECK(for function ..ng prefix, libc_cv_gcc_alpha_ng_prefix, [dnl
 946 cat > conftest.c <<\EOF
 947 foo () { }
 948 EOF
 949 dnl
 950 if AC_TRY_COMMAND([${CC-cc} -S conftest.c -o - | fgrep "\$foo..ng" > /dev/null]);
 951 then
 952   libc_cv_gcc_alpha_ng_prefix=yes
 953 else
 954   libc_cv_gcc_alpha_ng_prefix=no
 955 fi
 956 rm -f conftest* ])
 957 if test $libc_cv_gcc_alpha_ng_prefix = yes ; then
 958   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "$")
 959 else
 960   AC_DEFINE(ASM_ALPHA_NG_SYMBOL_PREFIX, "")
 961 fi
 962 fi
 963
 964 if test "$host_cpu" = powerpc ; then
 965 # Check for a bug present in at least versions 2.8.x of GCC
 966 # and versions 1.0.x of EGCS.
 967 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
 968 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
 969                libc_cv_c_asmcr0_bug='no',
 970                libc_cv_c_asmcr0_bug='yes')])
 971 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
 972   AC_DEFINE(BROKEN_PPC_ASM_CR0)
 973 fi
 974 fi
 975
 976 AC_CACHE_CHECK(for DWARF2 unwind info support, libc_cv_gcc_dwarf2_unwind_info,
 977 [cat > conftest.c <<EOF
 978 #line __oline__ "configure"
 979 static char __EH_FRAME_BEGIN__[];
 980 _start ()
 981 {
 982 #ifdef CHECK__register_frame
 983   __register_frame (__EH_FRAME_BEGIN__);
 984   __deregister_frame (__EH_FRAME_BEGIN__);
 985 #endif
 986 #ifdef CHECK__register_frame_info
 987   __register_frame_info (__EH_FRAME_BEGIN__);
 988   __deregister_frame_info (__EH_FRAME_BEGIN__);
 989 #endif
 990 }
 991 int __eh_pc;
 992 __throw () {}
 993 /* FIXME: this is fragile.  */
 994 malloc () {}
 995 strcmp () {}
 996 strlen () {}
 997 memcpy () {}
 998 memset () {}
 999 free () {}
1000 abort () {}
1001 __bzero () {}
1002 EOF
1003 dnl No \ in command here because it ends up inside ''.
1004 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame_info
1005                             -nostdlib -nostartfiles
1006                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1007   libc_cv_gcc_dwarf2_unwind_info=static
1008 else
1009   libc_cv_gcc_dwarf2_unwind_info=no
1010 fi
1011 if test $libc_cv_gcc_dwarf2_unwind_info = no; then
1012   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -DCHECK__register_frame
1013                               -nostdlib -nostartfiles
1014                               -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1015     libc_cv_gcc_dwarf2_unwind_info=yes
1016   else
1017     libc_cv_gcc_dwarf2_unwind_info=no
1018   fi
1019 fi
1020 rm -f conftest*])
1021 case $libc_cv_gcc_dwarf2_unwind_info in
1022 yes)
1023   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1024   ;;
1025 static)
1026   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO)
1027   AC_DEFINE(HAVE_DWARF2_UNWIND_INFO_STATIC)
1028   ;;
1029 esac
1030
1031 dnl Check whether compiler understands __builtin_expect.
1032 AC_CACHE_CHECK(for __builtin_expect, libc_cv_gcc_builtin_expect,
1033 [cat > conftest.c <<EOF
1034 #line __oline__ "configure"
1035 int foo (int a)
1036 {
1037   a = __builtin_expect (a, 10);
1038   return a == 10 ? 0 : 1;
1039 }
1040 EOF
1041 dnl No \ in command here because it ends up inside ''.
1042 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1043                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1044   libc_cv_gcc_builtin_expect=yes
1045 else
1046   libc_cv_gcc_builtin_expect=no
1047 fi
1048 rm -f conftest*])
1049 if test "$libc_cv_gcc_builtin_expect" = yes; then
1050   AC_DEFINE(HAVE_BUILTIN_EXPECT)
1051 fi
1052
1053 dnl Check whether the compiler supports subtraction of local labels.
1054 AC_CACHE_CHECK(for local label subtraction, libc_cv_gcc_subtract_local_labels,
1055 [cat > conftest.c <<EOF
1056 changequote(,)dnl
1057 #line __oline__ "configure"
1058 int foo (int a)
1059 {
1060   static const int ar[] = { &&l1 - &&l1, &&l2 - &&l1 };
1061   void *p = &&l1 + ar[a];
1062   goto *p;
1063  l1:
1064   return 1;
1065  l2:
1066   return 2;
1067 }
1068 changequote([,])dnl
1069 EOF
1070 dnl No \ in command here because it ends up inside ''.
1071 if AC_TRY_COMMAND([${CC-cc} $CFLAGS -nostdlib -nostartfiles
1072                             -o conftest conftest.c -lgcc >&AC_FD_CC]); then
1073   libc_cv_gcc_subtract_local_labels=yes
1074 else
1075   libc_cv_gcc_subtract_local_labels=no
1076 fi
1077 rm -f conftest*])
1078 if test "$libc_cv_gcc_subtract_local_labels" = yes; then
1079   AC_DEFINE(HAVE_SUBTRACT_LOCAL_LABELS)
1080 fi
1081
1082
1083 ### End of automated tests.
1084 ### Now run sysdeps configure fragments.
1085
1086 # sysdeps configure fragments may set these with files to be linked below.
1087 libc_link_dests=
1088 libc_link_sources=
1089
1090 # They also can set these variables.
1091 ldd_rewrite_script=no
1092
1093 # Iterate over all the sysdep directories we will use, running their
1094 # configure fragments, and looking for a uname implementation.
1095 uname=
1096 for dir in $sysnames; do
1097   case $dir in
1098     /*) dest=$dir ;;
1099     *)  dest=$srcdir/$dir ;;
1100   esac
1101   if test -r $dest/configure; then
1102     AC_MSG_RESULT(running configure fragment for $dest)
1103     . $dest/configure
1104   fi
1105 [
1106   if test -z "$uname"; then
1107     if test -r $dest/uname.c ||
1108        test -r $dest/uname.S ||
1109        { test -r $dest/syscalls.list &&
1110          grep '^uname[  ]' $dest/syscalls.list >/dev/null; }; then
1111       uname=$dir
1112     fi
1113   fi
1114 ]dnl
1115 done
1116
1117 AC_LINK_FILES(`echo $libc_link_sources`, `echo $libc_link_dests`)
1118
1119 # If we will use the generic uname implementation, we must figure out what
1120 # it will say by examining the system, and write the results in config-name.h.
1121 if test "$uname" = "sysdeps/generic"; then
1122
1123 changequote(,)dnl
1124   uname_sysname=`echo $config_os | sed 's/[0-9.]*$//'`
1125 changequote([,])dnl
1126   if test $uname_sysname != $config_os; then
1127     config_release=`echo $config_os | sed s/$uname_sysname//`
1128   fi
1129 dnl
1130 AC_DEFUN(LIBC_KERNEL_ID, [dnl
1131     if test -r /vmunix; then
1132       kernel_id=`strings /vmunix | grep UNIX`
1133     elif test -r /dynix; then
1134       kernel_id=`strings /dynix | grep DYNIX`
1135     else
1136       kernel_id=
1137     fi
1138 ])dnl
1139
1140   AC_CACHE_CHECK(OS release for uname, libc_cv_uname_release, [dnl
1141 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1142 changequote(,)dnl
1143   kernel_release=`echo "$kernel_id" | sed 's/^[^0-9.]*\([0-9.]*\).*$/\1/'`
1144 changequote([,])dnl
1145   if test x`echo "$config_release" | sed "s/^$kernel_release//"` \
1146          != x$config_release; then
1147     # The configuration release is a substring of the kernel release.
1148     libc_cv_uname_release=$kernel_release
1149   elif test x$config_release != x; then
1150     libc_cv_uname_release=$config_release
1151   elif test x$kernel_release != x; then
1152     libc_cv_uname_release=$kernel_release
1153   else
1154     libc_cv_uname_release=unknown
1155   fi])
1156   uname_release="$libc_cv_uname_release"
1157
1158   AC_CACHE_CHECK(OS version for uname, libc_cv_uname_version, [dnl
1159 AC_REQUIRE([LIBC_KERNEL_ID])dnl
1160 changequote(,)dnl
1161   kernel_version=`echo "$kernel_id" | sed 's/^[^#]*#\([0-9]*\).*$/\1/'`
1162 changequote([,])dnl
1163   if test -n "$kernel_version"; then
1164     libc_cv_uname_version="$kernel_version"
1165   else
1166     libc_cv_uname_version=unknown
1167   fi])
1168   uname_version="$libc_cv_uname_version"
1169
1170 AC_SUBST(uname_sysname) AC_SUBST(uname_release) AC_SUBST(uname_version)dnl
1171   config_uname=config-name.h:config-name.in
1172 else
1173   # For non-generic uname, we don't need to create config-name.h at all.
1174   config_uname=
1175 fi
1176
1177 AC_MSG_CHECKING(stdio selection)
1178 AC_SUBST(stdio)
1179 case $stdio in
1180 libio) AC_DEFINE(USE_IN_LIBIO) ;;
1181 default) stdio=stdio ;;
1182 esac
1183 AC_MSG_RESULT($stdio)
1184
1185 # Test for old glibc 2.0.x headers so that they can be removed properly
1186 # Search only in includedir.
1187 AC_MSG_CHECKING(for old glibc 2.0.x headers)
1188 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
1189 then
1190   old_glibc_headers=yes
1191 else
1192   old_glibc_headers=no
1193 fi
1194 AC_MSG_RESULT($old_glibc_headers)
1195 if test ${old_glibc_headers} = yes; then
1196   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
1197   AC_MSG_WARN(*** be removed.)
1198 fi
1199 AC_SUBST(old_glibc_headers)
1200
1201 AC_SUBST(libc_cv_slibdir)
1202 AC_SUBST(libc_cv_sysconfdir)
1203 AC_SUBST(libc_cv_rootsbindir)
1204
1205 AC_SUBST(has_ldconfig)
1206 AC_SUBST(ldd_rewrite_script)
1207
1208 AC_SUBST(gnu_ld) AC_SUBST(gnu_as) AC_SUBST(elf)
1209 if test $gnu_ld = yes; then
1210   AC_DEFINE(HAVE_GNU_LD)
1211 fi
1212 if test $gnu_as = yes; then
1213   AC_DEFINE(HAVE_GNU_AS)
1214 fi
1215 if test $elf = yes; then
1216   AC_DEFINE(HAVE_ELF)
1217 fi
1218
1219 AC_SUBST(static)
1220 AC_SUBST(shared)
1221 if test $shared = default; then
1222   if test $gnu_ld = yes; then
1223     shared=$elf
1224   else
1225     # For now we do not assume shared libs are available.  In future more
1226     # tests might become available.
1227     shared=no
1228   fi
1229 fi
1230
1231 AC_CACHE_CHECK([whether -fPIC is default], pic_default,
1232 [pic_default=yes
1233 cat > conftest.c <<EOF
1234 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
1235 # error PIC is default.
1236 #endif
1237 EOF
1238 if eval "${CC-cc} -S conftest.c 2>&AC_FD_CC 1>&AC_FD_CC"; then
1239   pic_default=no
1240 fi
1241 rm -f conftest.*])
1242 AC_SUBST(pic_default)
1243
1244 AC_SUBST(profile)
1245 AC_SUBST(omitfp)
1246 AC_SUBST(bounded)
1247 AC_SUBST(static_nss)
1248 AC_SUBST(nopic_initfini)
1249
1250 AC_SUBST(DEFINES)
1251
1252 case "$add_ons" in
1253   *door*) linux_doors=yes ;;
1254   *) linux_doors=no ;;
1255 esac
1256 AC_SUBST(linux_doors)
1257
1258 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
1259   config_makefile=
1260 else
1261   config_makefile=Makefile
1262 fi
1263
1264 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
1265 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
1266 AC_SUBST(VERSION)
1267 AC_SUBST(RELEASE)
1268
1269 echo '*** Do NOT install this release on any production system!'
1270 echo '*** It is known to be broken and will be so for quite some time.'
1271 echo '*** Use the latest released version instead.'
1272
1273 AC_OUTPUT(config.make glibcbug ${config_makefile} ${config_uname}, [
1274 case $CONFIG_FILES in *config.make*)
1275 echo "$config_vars" >> config.make;;
1276 esac
1277 test -d bits || mkdir bits], [config_vars='$config_vars'])