configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5
   6 # require autoconf 2.13
   7 AC_PREREQ(2.13)
   8
   9 # Process this file with autoconf to produce a configure script.
  10 AC_INIT(glist.c)
  11
  12 # Save this value here, since automake will set cflags later
  13 cflags_set=${CFLAGS+set}
  14
  15 # we rewrite this file
  16 rm -f glibconfig-sysdefs.h
  17
  18 # The following version number definitions apply to GLib and GModule
  19 # as a whole, so if changes occoured in either of them, they are both
  20 # treated with the same interface and binary age.
  21 #
  22 # Making releases:
  23 #   GLIB_MICRO_VERSION += 1;
  24 #   GLIB_INTERFACE_AGE += 1;
  25 #   GLIB_BINARY_AGE += 1;
  26 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  27 # if backwards compatibility has been broken,
  28 # set GLIB_BINARY_AGE and GLIB_INTERFACE_AGE to 0.
  29 #
  30 GLIB_MAJOR_VERSION=1
  31 GLIB_MINOR_VERSION=1
  32 GLIB_MICRO_VERSION=15
  33 GLIB_INTERFACE_AGE=2
  34 GLIB_BINARY_AGE=2
  35 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  36 AC_SUBST(GLIB_VERSION)
  37
  38 # libtool versioning
  39 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  40 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  41 LT_REVISION=$GLIB_INTERFACE_AGE
  42 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  43 AC_SUBST(LT_RELEASE)
  44 AC_SUBST(LT_CURRENT)
  45 AC_SUBST(LT_REVISION)
  46 AC_SUBST(LT_AGE)
  47
  48 VERSION=$GLIB_VERSION
  49 PACKAGE=glib
  50
  51 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  52
  53 # Specify a configuration file
  54 AM_CONFIG_HEADER(config.h)
  55
  56 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION)
  57 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION)
  58 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION)
  59 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE)
  60 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE)
  61
  62 dnl Initialize libtool
  63 AM_PROG_LIBTOOL
  64
  65 dnl Initialize maintainer mode
  66 AM_MAINTAINER_MODE
  67
  68 AC_CANONICAL_HOST
  69
  70 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=minimum]],,enable_debug=minimum)
  71 AC_ARG_ENABLE(mem_check, [  --enable-mem-check      turn on malloc/free sanity checking [default=no]],,enable_mem_check=no)
  72 AC_ARG_ENABLE(mem_profile, [  --enable-mem-profile    turn on malloc profiling atexit [default=no]],,enable_mem_profile=no)
  73 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
  74                     , enable_ansi=no)
  75 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
  76                           ([=no] will override --with-threads)],,enable_threads=yes)
  77
  78 if test "x$enable_threads" != "xyes"; then
  79   enable_threads=no
  80 fi
  81
  82 AC_MSG_CHECKING(whether to enable memory checking)
  83 if test "x$enable_mem_check" = "xyes"; then
  84   AC_DEFINE(ENABLE_MEM_CHECK, 1)
  85   AC_SUBST(ENABLE_MEM_CHECK)
  86   AC_MSG_RESULT(yes)
  87 else
  88   AC_MSG_RESULT(no)
  89 fi
  90
  91 AC_MSG_CHECKING(whether to enable memory profiling)
  92 if test "x$enable_mem_profile" = "xyes"; then
  93   AC_DEFINE(ENABLE_MEM_PROFILE, 1)
  94   AC_SUBST(ENABLE_MEM_PROFILE)
  95   AC_MSG_RESULT(yes)
  96 else
  97   AC_MSG_RESULT(no)
  98 fi
  99
 100 if test "x$enable_debug" = "xyes"; then
 101   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 102   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 103 else
 104   if test "x$enable_debug" = "xno"; then
 105     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 106   fi
 107 fi
 108
 109 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 110
 111 # Checks for programs.
 112 AC_PROG_CC
 113 AM_PROG_CC_STDC
 114 AC_PROG_INSTALL
 115
 116 changequote(,)dnl
 117 if test "x$GCC" = "xyes"; then
 118   case " $CFLAGS " in
 119   *[\ \ ]-Wall[\ \      ]*) ;;
 120   *) CFLAGS="$CFLAGS -Wall" ;;
 121   esac
 122
 123   if test "x$enable_ansi" = "xyes"; then
 124     case " $CFLAGS " in
 125     *[\ \       ]-ansi[\ \      ]*) ;;
 126     *) CFLAGS="$CFLAGS -ansi" ;;
 127     esac
 128
 129     case " $CFLAGS " in
 130     *[\ \       ]-pedantic[\ \  ]*) ;;
 131     *) CFLAGS="$CFLAGS -pedantic" ;;
 132     esac
 133   fi
 134 fi
 135 changequote([,])dnl
 136
 137 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 138 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 139 glib_save_LIBS=$LIBS
 140 LIBS="$LIBS -lm"
 141 AC_TRY_RUN([#include <math.h>
 142              int main (void) { return (log(1) != log(1.)); }],
 143      AC_MSG_RESULT(none needed),
 144      glib_save_CFLAGS=$CFLAGS
 145      CFLAGS="$CFLAGS -std1"
 146      AC_TRY_RUN([#include <math.h>
 147                  int main (void) { return (log(1) != log(1.)); }],
 148          AC_MSG_RESULT(-std1),
 149          AC_MSG_RESULT()
 150          CFLAGS=$glib_save_CFLAGS
 151          AC_MSG_WARN(
 152                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 153      )
 154 )
 155 LIBS=$glib_save_LIBS
 156
 157 dnl NeXTStep cc seems to need this
 158 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 159 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 160   AC_MSG_RESULT(none needed),
 161   glib_save_CFLAGS=$CFLAGS
 162   CFLAGS="$CFLAGS -posix"
 163   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 164     AC_MSG_RESULT(-posix),
 165     AC_MSG_RESULT()
 166     CFLAGS=$glib_save_CFLAGS
 167     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 168
 169 # Checks for header files.
 170 AC_HEADER_STDC
 171
 172 # Checks for library functions.
 173 AC_FUNC_VPRINTF
 174
 175 AC_CHECK_FUNCS(atexit on_exit)
 176
 177 AC_CHECK_SIZEOF(char)
 178 AC_CHECK_SIZEOF(short)
 179 AC_CHECK_SIZEOF(long)
 180 AC_CHECK_SIZEOF(int)
 181 AC_CHECK_SIZEOF(void *)
 182 AC_CHECK_SIZEOF(long long)
 183
 184 dnl long doubles were not used, and a portability problem
 185 dnl AC_C_LONG_DOUBLE
 186 AC_C_CONST
 187
 188 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 189 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 190 dnl actually supported.
 191 AC_MSG_CHECKING(for __inline)
 192 AC_CACHE_VAL(glib_cv_has__inline,[
 193         AC_TRY_RUN([
 194         __inline int foo () { return 0; }
 195         int main () { return foo (); }
 196         ],
 197         glib_cv_has__inline=yes
 198         ,
 199         glib_cv_has__inline=no
 200         ,)
 201 ])
 202 AC_MSG_RESULT($glib_cv_has__inline)
 203 case x$glib_cv_has__inline in
 204 xyes) AC_DEFINE(G_HAVE___INLINE)
 205 esac
 206 AC_MSG_CHECKING(for __inline__)
 207 AC_CACHE_VAL(glib_cv_has__inline__,[
 208         AC_TRY_RUN([
 209         __inline__ int foo () { return 0; }
 210         int main () { return foo (); }
 211         ],
 212         glib_cv_has__inline__=yes
 213         ,
 214         glib_cv_has__inline__=no
 215         ,)
 216 ])
 217 AC_MSG_RESULT($glib_cv_has__inline__)
 218 case x$glib_cv_has__inline__ in
 219 xyes) AC_DEFINE(G_HAVE___INLINE__)
 220 esac
 221 AC_MSG_CHECKING(for inline)
 222 AC_CACHE_VAL(glib_cv_hasinline,[
 223         AC_TRY_RUN([
 224         inline int foo () { return 0; }
 225         int main () { return foo (); }
 226         ],
 227         glib_cv_hasinline=yes
 228         ,
 229         glib_cv_hasinline=no
 230         ,)
 231 ])
 232 AC_MSG_RESULT($glib_cv_hasinline)
 233 case x$glib_cv_hasinline in
 234 xyes) AC_DEFINE(G_HAVE_INLINE)
 235 esac
 236
 237 dnl for bytesex stuff
 238 AC_C_BIGENDIAN
 239
 240 dnl header file checks
 241 AC_CHECK_HEADERS(float.h, AC_DEFINE(HAVE_FLOAT_H))
 242 AC_CHECK_HEADERS(limits.h, AC_DEFINE(HAVE_LIMITS_H))
 243 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 244 AC_CHECK_HEADERS(sys/param.h, AC_DEFINE(HAVE_SYS_PARAM_H))
 245 AC_CHECK_HEADERS(sys/poll.h, AC_DEFINE(HAVE_SYS_POLL_H))
 246 AC_CHECK_HEADERS(sys/select.h, AC_DEFINE(HAVE_SYS_SELECT_H))
 247 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 248 AC_CHECK_HEADERS(sys/times.h, AC_DEFINE(HAVE_SYS_TIMES_H))
 249 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 250 AC_CHECK_HEADERS(values.h, AC_DEFINE(HAVE_VALUES_H))
 251
 252 # Check for some functions
 253 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf strcasecmp strncasecmp poll)
 254
 255 # Check for sys_errlist
 256 AC_MSG_CHECKING(for sys_errlist)
 257 AC_TRY_LINK(, [
 258 extern char *sys_errlist[];
 259 extern int sys_nerr;
 260 sys_errlist[sys_nerr-1][0] = 0;
 261 ], glib_ok=yes, glib_ok=no)
 262 AC_MSG_RESULT($glib_ok)
 263 if test $glib_ok = no; then
 264     AC_DEFINE(NO_SYS_ERRLIST)
 265 fi
 266
 267 # Check for sys_siglist
 268 AC_MSG_CHECKING(for sys_siglist)
 269 AC_TRY_LINK(, [
 270 extern char *sys_siglist[];
 271 strlen (sys_siglist[0]);
 272 ], glib_ok=yes, glib_ok=no)
 273 AC_MSG_RESULT($glib_ok)
 274 if test $glib_ok = no; then
 275     AC_DEFINE(NO_SYS_SIGLIST)
 276 fi
 277
 278 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 279 AC_MSG_CHECKING(for sys_siglist declaration)
 280 AC_TRY_COMPILE([#include <signal.h>], [
 281 strlen (sys_siglist[0]);
 282 ], glib_ok=yes, glib_ok=no)
 283 AC_MSG_RESULT($glib_ok)
 284 if test $glib_ok = no; then
 285     AC_DEFINE(NO_SYS_SIGLIST_DECL)
 286 fi
 287
 288 # Check if <sys/select.h> needs to be included for fd_set
 289 AC_MSG_CHECKING([for fd_set])
 290 AC_TRY_COMPILE([#include <sys/types.h>],
 291         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 292 if test $gtk_ok = yes; then
 293     AC_MSG_RESULT([yes, found in sys/types.h])
 294 else
 295     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 296     if test $gtk_ok = yes; then
 297         AC_DEFINE(HAVE_SYS_SELECT_H)
 298         AC_MSG_RESULT([yes, found in sys/select.h])
 299     else
 300         AC_DEFINE(NO_FD_SET)
 301         AC_MSG_RESULT(no)
 302     fi
 303 fi
 304
 305 # These are used only in GDK (gdki18n.h)
 306 # This stuff is here only so that we can define these
 307 # things in glibconfig.h. If gtk+ started using an installed
 308 # gdkconfig.h file, then the definitions would belong there.
 309
 310 # Check for wchar.h
 311
 312 AC_MSG_CHECKING(for wchar.h)
 313 AC_TRY_CPP([#include <wchar.h>], glib_wchar_h=yes, glib_wchar_h=no)
 314 if test $glib_wchar_h = yes; then
 315    AC_DEFINE(HAVE_WCHAR_H)
 316 fi
 317 AC_MSG_RESULT($glib_wchar_h)
 318
 319 # Check for wctype.h (for iswalnum)
 320
 321 AC_MSG_CHECKING(for wctype.h)
 322 AC_TRY_CPP([#include <wctype.h>], glib_wctype_h=yes, glib_wctype_h=no)
 323 if test $glib_wctype_h = yes; then
 324    AC_DEFINE(HAVE_WCTYPE_H)
 325 fi
 326 AC_MSG_RESULT($glib_wctype_h)
 327
 328 oLIBS="$LIBS"
 329 # in Solaris 2.5, `iswalnum' is in -lw
 330 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum)])
 331
 332 # The following is necessary for Linux libc-5.4.38
 333 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 334 AC_TRY_LINK([#include <stdlib.h>],[
 335 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 336 #  ifdef HAVE_WCTYPE_H
 337 #    include <wctype.h>
 338 #  else
 339 #    ifdef HAVE_WCHAR_H
 340 #      include <wchar.h>
 341 #    endif
 342 #  endif
 343 #else
 344 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 345 #endif
 346 iswalnum((wchar_t) 0);
 347 ], glib_working_wctype=yes, glib_working_wctype=no)
 348 LIBS="$oLIBS"
 349
 350 if test $glib_working_wctype = no; then
 351    AC_DEFINE(HAVE_BROKEN_WCTYPE)
 352 fi
 353 AC_MSG_RESULT($glib_working_wctype)
 354
 355
 356 dnl **********************
 357 dnl *** va_copy checks ***
 358 dnl **********************
 359 dnl we currently check for all three va_copy possibilities, so we get
 360 dnl all results in config.log for bug reports.
 361 AC_MSG_CHECKING(for an implementation of va_copy())
 362 AC_CACHE_VAL(glib_cv_va_copy,[
 363         AC_TRY_RUN([
 364         #include <stdarg.h>
 365         void f (int i, ...) {
 366         va_list args1, args2;
 367         va_start (args1, i);
 368         va_copy (args2, args1);
 369         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 370           exit (1);
 371         va_end (args1); va_end (args2);
 372         }
 373         int main() {
 374           f (0, 42);
 375           return 0;
 376         }],
 377         glib_cv_va_copy=yes
 378         ,
 379         glib_cv_va_copy=no
 380         ,)
 381 ])
 382 AC_MSG_RESULT($glib_cv_va_copy)
 383 AC_MSG_CHECKING(for an implementation of __va_copy())
 384 AC_CACHE_VAL(glib_cv___va_copy,[
 385         AC_TRY_RUN([
 386         #include <stdarg.h>
 387         void f (int i, ...) {
 388         va_list args1, args2;
 389         va_start (args1, i);
 390         __va_copy (args2, args1);
 391         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 392           exit (1);
 393         va_end (args1); va_end (args2);
 394         }
 395         int main() {
 396           f (0, 42);
 397           return 0;
 398         }],
 399         glib_cv___va_copy=yes
 400         ,
 401         glib_cv___va_copy=no
 402         ,)
 403 ])
 404 AC_MSG_RESULT($glib_cv___va_copy)
 405 AC_MSG_CHECKING(whether va_lists can be copied by value)
 406 AC_CACHE_VAL(glib_cv_va_val_copy,[
 407         AC_TRY_RUN([
 408         #include <stdarg.h>
 409         void f (int i, ...) {
 410         va_list args1, args2;
 411         va_start (args1, i);
 412         args2 = args1;
 413         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 414           exit (1);
 415         va_end (args1); va_end (args2);
 416         }
 417         int main() {
 418           f (0, 42);
 419           return 0;
 420         }],
 421         glib_cv_va_val_copy=yes
 422         ,
 423         glib_cv_va_val_copy=no
 424         ,)
 425 ])
 426 if test "x$glib_cv_va_copy" = "xyes"; then
 427   AC_DEFINE(G_VA_COPY, va_copy)
 428 else if test "x$glib_cv___va_copy" = "xyes"; then
 429   AC_DEFINE(G_VA_COPY, __va_copy)
 430 fi
 431 fi
 432 if test "x$glib_cv_va_val_copy" = "xno"; then
 433   AC_DEFINE(G_VA_COPY_AS_ARRAY)
 434 fi
 435 AC_MSG_RESULT($glib_cv_va_val_copy)
 436
 437
 438 dnl ***********************
 439 dnl *** g_module checks ***
 440 dnl ***********************
 441 G_MODULE_LIBS=
 442 G_MODULE_LDFLAGS=
 443 G_MODULE_IMPL=
 444 G_MODULE_NEED_USCORE=0
 445 G_MODULE_HAVE_DLERROR=0
 446 dnl *** dlopen() and dlsym() in system libraries
 447 if test -z "$G_MODULE_IMPL"; then
 448         AC_CHECK_FUNC(dlopen,
 449                 AC_CHECK_FUNC(dlsym,
 450                         G_MODULE_IMPL=G_MODULE_IMPL_DL
 451                 ,)
 452         ,)
 453 fi
 454 dnl *** dlopen() and dlsym() in libdl
 455 if test -z "$G_MODULE_IMPL"; then
 456         AC_CHECK_LIB(dl, dlopen,
 457                 AC_CHECK_LIB(dl, dlsym,
 458                         G_MODULE_LIBS=-ldl
 459                         G_MODULE_IMPL=G_MODULE_IMPL_DL
 460                 ,)
 461         ,)
 462 fi
 463 dnl *** shl_load() in libdld (HP-UX)
 464 if test -z "$G_MODULE_IMPL"; then
 465         AC_MSG_CHECKING(how to export all symbols)
 466         SAVED_LDFLAGS=$LDFLAGS
 467         LDFLAGS="$LDFLAGS -Wl,-E"
 468         AC_TRY_LINK(,[ return 0; ],
 469                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 470                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 471                 AC_TRY_LINK(,[ return 0; ],
 472                         G_MODULE_LDFLAGS="-bexpall",
 473                         G_MODULE_LDFLAGS="none"
 474                 )
 475         ])
 476         LDFLAGS=$SAVED_LDFLAGS
 477         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 478         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 479                 G_MODULE_LDFLAGS=
 480         fi
 481         AC_CHECK_LIB(dld, shl_load,
 482                 G_MODULE_LIBS=-ldld
 483                 G_MODULE_IMPL=G_MODULE_IMPL_DLD
 484         ,)
 485 fi
 486 dnl *** additional checks for G_MODULE_IMPL_DL
 487 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 488         case "$host_os" in
 489           linux*)
 490             G_MODULE_LDFLAGS='-rdynamic'
 491             ;;
 492         esac
 493         LIBS_orig="$LIBS"
 494         LDFLAGS_orig="$LDFLAGS"
 495         LIBS="$LIBS $G_MODULE_LIBS"
 496         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 497 dnl *** check whether we need preceeding underscores
 498         AC_MSG_CHECKING(for preceeding underscore in symbols)
 499         AC_CACHE_VAL(glib_cv_uscore,[
 500                 AC_TRY_RUN([
 501                 #include <dlfcn.h>
 502                 int glib_underscore_test (void) { return 42; }
 503                 int main() {
 504                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 505                   handle = dlopen ((void*)0, 0);
 506                   if (handle) {
 507                     f1 = dlsym (handle, "glib_underscore_test");
 508                     f2 = dlsym (handle, "_glib_underscore_test");
 509                   } return (!f2 || f1);
 510                 }],
 511                         glib_cv_uscore=yes,
 512                         glib_cv_uscore=no,
 513                 )
 514                 rm -f plugin.c plugin.o plugin.lo
 515         ])
 516         AC_MSG_RESULT($glib_cv_uscore)
 517         if test "x$glib_cv_uscore" = "xyes"; then
 518                 G_MODULE_NEED_USCORE=1
 519         else
 520                 G_MODULE_NEED_USCORE=0
 521         fi
 522
 523         LDFLAGS="$LDFLAGS_orig"
 524 dnl *** check for having dlerror()
 525         AC_CHECK_FUNC(dlerror,
 526                 G_MODULE_HAVE_DLERROR=1,
 527                 G_MODULE_HAVE_DLERROR=0)
 528         LIBS="$LIBS_orig"
 529 fi
 530 dnl *** done, have e got an implementation?
 531 if test -z "$G_MODULE_IMPL"; then
 532         G_MODULE_IMPL=0
 533 fi
 534 AC_SUBST(G_MODULE_IMPL)
 535 AC_SUBST(G_MODULE_LIBS)
 536 AC_SUBST(G_MODULE_LDFLAGS)
 537 AC_SUBST(G_MODULE_HAVE_DLERROR)
 538 AC_SUBST(G_MODULE_NEED_USCORE)
 539 AC_SUBST(GLIB_DEBUG_FLAGS)
 540
 541
 542 dnl ***********************
 543 dnl *** g_thread checks ***
 544 dnl ***********************
 545
 546 AC_ARG_WITH(threads, [  --with-threads=[none/posix/solaris/nspr] specify a thread implementation to use],
 547         if test "x$with_threads" = x; then
 548                 want_threads=yes
 549         else
 550                 want_threads=$with_threads
 551         fi,
 552         want_threads=yes)
 553 if test "x$enable_threads" = "xno"; then
 554         want_threads=no
 555 fi
 556 if test "x$want_threads" = "xnone"; then
 557         want_threads=no
 558 fi
 559
 560 dnl error and warning message
 561 dnl *************************
 562
 563 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
 564                 computer. glib will not be thread safe on your computer."
 565
 566 FLAG_DOES_NOT_WORK="I can't find the MACRO, that enables thread safety on your
 567                 platform (normaly it's "_REENTRANT"). I'll not use any flag on
 568                 compilation now, but then your programs might not work.
 569                 Please provide information on how it is done on your system."
 570
 571 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
 572                 "
 573
 574 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
 575                 provide information on your thread implementation."
 576
 577 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
 578                 functions will not be MT-safe during their first call because
 579                 there is no 'getpwuid_r' on your system."
 580
 581 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
 582                 because there is no 'localtime_r' on your system."
 583
 584 dnl determination of thread implementation
 585 dnl ***************************************
 586
 587 have_threads=none
 588 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
 589         case $host in
 590                 *-*-solaris*)
 591                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
 592                 ;;
 593         esac
 594 fi
 595 if test "x$want_threads" = xyes || test "x$want_threads" = xposix; then
 596         if test "x$have_threads" = xnone; then
 597                 AC_CHECK_HEADER(pthread.h, have_threads=posix)
 598         fi
 599 fi
 600 if test "x$want_threads" = xyes || test "x$want_threads" = xnspr; then
 601         if test "x$have_threads" = xnone; then
 602                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar, have_threads=nspr)
 603         fi
 604 fi
 605
 606 AC_MSG_CHECKING(for thread implementation)
 607
 608 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
 609         AC_MSG_RESULT(none available)
 610         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
 611 else
 612         AC_MSG_RESULT($have_threads)
 613 fi
 614
 615
 616 dnl determination of G_THREAD_LIBS
 617 dnl ******************************
 618
 619 G_THREAD_LIBS=
 620 G_THREAD_CFLAGS=
 621
 622 mutex_has_default=no
 623 case $have_threads in
 624         posix)
 625                 G_THREAD_LIBS=error
 626                 AC_CHECK_LIB(pthread, pthread_attr_init,
 627                              G_THREAD_LIBS="-lpthread")
 628                 if test "x$G_THREAD_LIBS" = xerror; then
 629                         AC_CHECK_LIB(pthreads, pthread_attr_init,
 630                                 G_THREAD_LIBS="-lpthreads")
 631                 fi
 632                 if test "x$G_THREAD_LIBS" = xerror; then
 633                         AC_CHECK_LIB(c_r, pthread_attr_init,
 634                                 G_THREAD_LIBS="-lc_r")
 635                 fi
 636                 if test "x$G_THREAD_LIBS" = xerror; then
 637                         AC_CHECK_FUNC(pthread_attr_init, G_THREAD_LIBS="")
 638                 fi
 639                 dnl ********** DG/UX ************
 640                 if test "x$G_THREAD_LIBS" = xerror; then
 641                         AC_CHECK_LIB(thread, __d10_pthread_attr_init,
 642                                 G_THREAD_LIBS="-lthread"
 643                                 G_THREAD_CFLAGS="-D_POSIX4A_DRAFT10_SOURCE")
 644                 fi
 645                 dnl ********* HPUX 11 ***********
 646                 if test "x$G_THREAD_LIBS" = xerror; then
 647                         AC_CHECK_LIB(pthread, __pthread_attr_init_system,
 648                                 G_THREAD_LIBS="-lpthread")
 649                 fi
 650                 mutex_has_default=yes
 651                 mutex_default_type='pthread_mutex_t'
 652                 mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
 653                 mutex_header_file='pthread.h'
 654                 g_threads_impl="POSIX"
 655                 ;;
 656         solaris)
 657                 G_THREAD_LIBS=error
 658                 AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
 659                 mutex_has_default=yes
 660                 mutex_default_type='mutex_t'
 661                 mutex_default_init="DEFAULTMUTEX"
 662                 mutex_header_file='thread.h'
 663                 g_threads_impl="SOLARIS"
 664                 ;;
 665         nspr)
 666                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar,
 667                              G_THREAD_LIBS="-lnspr21")
 668                 g_threads_impl="NSPR"
 669                 ;;
 670         none)
 671                 g_threads_impl="NONE"
 672                 ;;
 673         *)
 674                 g_threads_impl="NONE"
 675                 G_THREAD_LIBS=error
 676                 ;;
 677 esac
 678
 679 if test "x$G_THREAD_LIBS" = xerror; then
 680         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 681 fi
 682
 683 AC_MSG_CHECKING(necessary linker options)
 684 AC_MSG_RESULT($G_THREAD_LIBS)
 685
 686 dnl determination of G_THREAD_CFLAGS
 687 dnl ********************************
 688
 689 if test x"$have_threads" != xnone; then
 690 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_REENTRANT" # good default guess
 691
 692     case $host in
 693         *-aix*)
 694                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 695                 if test x"$GCC" = xyes; then
 696                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
 697                 fi
 698                 ;;
 699         *-freebsd2.2*)
 700                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 701
 702                 # FreeBSD 2.2.x shiped with gcc 2.7.2.x, which doesn't support
 703                 # -mthreads flag.
 704                 ;;
 705     esac
 706
 707     # if we are not finding the ctime_r function, then we probably are
 708     # not using the proper multithread flag
 709     old_CPPFLAGS=$CPPFLAGS
 710     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
 711     AC_EGREP_HEADER([[^a-zA-Z_]ctime_r[^a-zA-Z_]], time.h, ,
 712     G_THREAD_CFLAGS=
 713     AC_MSG_WARN($FLAG_DOES_NOT_WORK))
 714     CPPFLAGS=$old_CPPFLAGS
 715
 716     AC_MSG_CHECKING(necessary compiler options)
 717
 718     AC_MSG_RESULT($G_THREAD_CFLAGS)
 719 else
 720     G_THREAD_CFLAGS=
 721 fi
 722
 723 dnl check for mt safe function variants
 724 dnl ***********************************
 725
 726 if test x"$have_threads" != xnone; then
 727         glib_save_LIBS="$LIBS"
 728         glib_save_CFLAGS="$CFLAGS"
 729         # we are not doing the following for now, as this might require glib
 730         # to always be linked with the thread libs on some platforms.
 731         # LIBS="$LIBS $G_THREAD_LIBS"
 732         CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 733         AC_CHECK_FUNCS(localtime_r rand_r)
 734         if test "$ac_cv_header_pwd_h" = "yes"; then
 735                 AC_CHECK_FUNCS(getpwuid_r)
 736                 if test "$ac_cv_func_getpwuid_r" = "yes"; then
 737                         AC_MSG_CHECKING(whether getpwuid_r is posix like)
 738                         # getpwuid_r(0, NULL, NULL, 0) is the signature on
 739                         # solaris, if that is not found, the prog below won't
 740                         # compile, then the posix signature is assumed as
 741                         # the default.
 742                         AC_TRY_COMPILE([#include <pwd.h>],
 743                                 [getpwuid_r(0, NULL, NULL, 0);],
 744                                 [AC_MSG_RESULT(no)],
 745                                 [AC_MSG_RESULT(yes)
 746                                 AC_DEFINE(HAVE_GETPWUID_R_POSIX)])
 747                 fi
 748         fi
 749         LIBS="$glib_save_LIBS"
 750         CFLAGS="$glib_save_CFLAGS"
 751 fi
 752
 753 if test "x$enable_threads" = "xyes"; then
 754         if test "$ac_cv_func_getpwuid_r" != "yes"; then
 755                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
 756         fi
 757         if test "$ac_cv_func_localtime_r" != "yes"; then
 758                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
 759         fi
 760 fi
 761
 762 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c")
 763 AC_SUBST(G_THREAD_CFLAGS)
 764 AC_SUBST(G_THREAD_LIBS)
 765
 766 CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 767
 768 dnl **********************************************
 769 dnl *** GDefaultMutex setup and initialization ***
 770 dnl **********************************************
 771 dnl
 772 dnl if mutex_has_default = yes, we also got
 773 dnl mutex_default_type, mutex_default_init and mutex_header_file
 774 GLIB_IF_VAR_EQ(mutex_has_default, yes,
 775         GLIB_SIZEOF([#include <$mutex_header_file>],
 776                     $mutex_default_type,
 777                     gmutex,
 778                     )
 779         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
 780                            $mutex_default_type,
 781                            gmutex,
 782                            $glib_cv_sizeof_gmutex,
 783                            $mutex_default_init)
 784         ,
 785 )
 786
 787
 788 dnl ****************************************
 789 dnl *** GLib POLL* compatibility defines ***
 790 dnl ****************************************
 791 GLIB_SYSDEFS(
 792 [#include <sys/types.h>
 793 #include <sys/poll.h>],
 794         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
 795         glibconfig-sysdefs.h,
 796         =)
 797
 798
 799 dnl ******************************
 800 dnl *** output the whole stuff ***
 801 dnl ******************************
 802
 803 AC_OUTPUT_COMMANDS([
 804
 805 ## Generate `glibconfig.h' in two cases
 806 ## 1. `config.status' is run either explicitly, or via configure.
 807 ##     Esp. not when it is run in `Makefile' to generate makefiles and
 808 ##     config.h
 809 ## 2. CONFIG_OTHER is set explicitly
 810 ##
 811 ## Case 1 is difficult.  We know that `automake' sets one of
 812 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
 813 ## only when AM_CONFIG_HEADER is set, however.
 814
 815 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
 816   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
 817   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
 818 fi
 819 case "$CONFIG_OTHER" in
 820 *glibconfig.h*)
 821         echo creating glibconfig.h
 822         outfile=glibconfig.h-tmp
 823         cat > $outfile <<\_______EOF
 824 /* glibconfig.h
 825  *
 826  * This is a generated file.  Please modify `configure.in'
 827  */
 828
 829 #ifndef GLIBCONFIG_H
 830 #define GLIBCONFIG_H
 831
 832 #ifdef __cplusplus
 833 extern "C" {
 834 #endif /* __cplusplus */
 835
 836 _______EOF
 837
 838         if test x$glib_limits_h = xyes; then
 839           echo '#include <limits.h>' >> $outfile
 840         fi
 841         if test x$glib_float_h = xyes; then
 842           echo '#include <float.h>' >> $outfile
 843         fi
 844         if test x$glib_values_h = xyes; then
 845           echo '#include <values.h>' >> $outfile
 846         fi
 847         if test x$g_mutex_header_file != x; then
 848           echo '#include <'"$g_mutex_header_file"'>' >> $outfile
 849         fi
 850         if test x$glib_sys_poll_h = xyes; then
 851           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
 852         fi
 853
 854         cat >> $outfile <<_______EOF
 855
 856 #define G_MINFLOAT      $glib_mf
 857 #define G_MAXFLOAT      $glib_Mf
 858 #define G_MINDOUBLE     $glib_md
 859 #define G_MAXDOUBLE     $glib_Md
 860 #define G_MINSHORT      $glib_ms
 861 #define G_MAXSHORT      $glib_Ms
 862 #define G_MININT        $glib_mi
 863 #define G_MAXINT        $glib_Mi
 864 #define G_MINLONG       $glib_ml
 865 #define G_MAXLONG       $glib_Ml
 866
 867 _______EOF
 868
 869
 870         ### this should always be true in a modern C/C++ compiler
 871         cat >>$outfile <<_______EOF
 872 typedef signed char gint8;
 873 typedef unsigned char guint8;
 874 _______EOF
 875
 876
 877         if test -n "$gint16"; then
 878           cat >>$outfile <<_______EOF
 879 typedef signed $gint16 gint16;
 880 typedef unsigned $gint16 guint16;
 881 _______EOF
 882         fi
 883
 884
 885         if test -n "$gint32"; then
 886           cat >>$outfile <<_______EOF
 887 typedef signed $gint32 gint32;
 888 typedef unsigned $gint32 guint32;
 889 _______EOF
 890         fi
 891
 892
 893         if test -n "$gint64"; then
 894           cat >>$outfile <<_______EOF
 895 ${glib_warning_guard}#define G_HAVE_GINT64 1
 896
 897 ${glib_extension}typedef signed $gint64 gint64;
 898 ${glib_extension}typedef unsigned $gint64 guint64;
 899
 900 #define G_GINT64_CONSTANT(val)  $gint64_constant
 901 _______EOF
 902         fi
 903
 904
 905         if test -z "$glib_unknown_void_p"; then
 906           cat >>$outfile <<_______EOF
 907
 908 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
 909 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
 910
 911 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
 912 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
 913 _______EOF
 914         else
 915           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
 916         fi
 917
 918
 919
 920         cat >>$outfile <<_______EOF
 921 $glib_atexit
 922 $glib_memmove
 923 $glib_defines
 924
 925 $glib_vacopy
 926
 927 #ifdef  __cplusplus
 928 #define G_HAVE_INLINE   1
 929 #else   /* !__cplusplus */
 930 $glib_inline
 931 #endif  /* !__cplusplus */
 932 _______EOF
 933
 934         echo >>$outfile
 935         if test x$g_mutex_has_default = xyes; then
 936                 cat >>$outfile <<_______EOF
 937 $g_enable_threads_def G_THREADS_ENABLED
 938 #define G_THREADS_IMPL_$g_threads_impl_def
 939 typedef struct _GStaticMutex GStaticMutex;
 940 struct _GStaticMutex
 941 {
 942   struct _GMutex *runtime_mutex;
 943   union {
 944     char   pad[$g_mutex_sizeof];
 945     double dummy_double;
 946     void  *dummy_pointer;
 947     long   dummy_long;
 948   } aligned_pad_u;
 949 };
 950 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
 951 #define g_static_mutex_get_mutex(mutex) \
 952   (g_thread_use_default_impl ? ((GMutex*) &(mutex).aligned_pad_u) : \
 953    g_static_mutex_get_mutex_impl (&(mutex).runtime_mutex))
 954 _______EOF
 955         else
 956                 cat >>$outfile <<_______EOF
 957 $g_enable_threads_def G_THREADS_ENABLED
 958 #define G_THREADS_IMPL_$g_threads_impl_def
 959 typedef struct _GMutex* GStaticMutex;
 960 #define G_STATIC_MUTEX_INIT NULL
 961 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (&(mutex)))
 962 _______EOF
 963         fi
 964
 965         echo >>$outfile
 966         g_bit_sizes="16 32"
 967         if test -n "$gint64"; then
 968           g_bit_sizes="$g_bit_sizes 64"
 969         fi
 970         for bits in $g_bit_sizes; do
 971           cat >>$outfile <<_______EOF
 972 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
 973 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
 974 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
 975 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
 976 _______EOF
 977         done
 978
 979         cat >>$outfile <<_______EOF
 980 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
 981 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
 982 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
 983 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
 984 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
 985 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
 986 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
 987 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
 988 #define G_BYTE_ORDER $g_byte_order
 989
 990 _______EOF
 991
 992         if test -r glibconfig-sysdefs.h; then
 993           cat glibconfig-sysdefs.h >>$outfile
 994         fi
 995
 996
 997         cat >>$outfile <<_______EOF
 998
 999 $glib_wc
1000
1001
1002 #ifdef __cplusplus
1003 }
1004 #endif /* __cplusplus */
1005
1006 #endif /* GLIBCONFIG_H */
1007 _______EOF
1008
1009
1010         if cmp -s $outfile glibconfig.h; then
1011           echo glibconfig.h is unchanged
1012           rm -f $outfile
1013         else
1014           mv $outfile glibconfig.h
1015         fi ;;
1016 esac
1017 ],[
1018
1019 # Note that if two cases are the same, case goes with the first one.
1020 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
1021 # on variable expansion in case labels.  Look at the generated config.status
1022 # for a hint.
1023
1024 case xyes in
1025 x$ac_cv_header_float_h)
1026   glib_float_h=yes
1027   glib_mf=FLT_MIN glib_Mf=FLT_MAX
1028   glib_md=DBL_MIN glib_Md=DBL_MAX
1029   ;;
1030 x$ac_cv_header_values_h)
1031   glib_values_h=yes
1032   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
1033   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
1034   ;;
1035 esac
1036
1037 case xyes in
1038 x$ac_cv_header_limits_h)
1039   glib_limits_h=yes
1040   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX
1041   glib_mi=INT_MIN  glib_Mi=INT_MAX
1042   glib_ml=LONG_MIN glib_Ml=LONG_MAX
1043   ;;
1044 x$ac_cv_header_values_h)
1045   glib_values_h=yes
1046   glib_ms=MINSHORT glib_Ms=MAXSHORT
1047   glib_mi=MININT   glib_Mi=MAXINT
1048   glib_ml=MINLONG  glib_Ml=MAXLONG
1049   ;;
1050 esac
1051
1052 if test x$ac_cv_header_sys_poll_h = xyes ; then
1053   glib_sys_poll_h=yes
1054 fi
1055
1056 case 2 in
1057 $ac_cv_sizeof_short)            gint16=short;;
1058 $ac_cv_sizeof_int)              gint16=int;;
1059 esac
1060 case 4 in
1061 $ac_cv_sizeof_short)            gint32=short;;
1062 $ac_cv_sizeof_int)              gint32=int;;
1063 $ac_cv_sizeof_long)             gint32=long;;
1064 esac
1065 case 8 in
1066 $ac_cv_sizeof_int)
1067   gint64=int
1068   glib_extension=
1069   glib_warning_guard=
1070   gint64_constant='(val)'
1071   ;;
1072 $ac_cv_sizeof_long)
1073   gint64=long
1074   glib_extension=
1075   glib_warning_guard=
1076   gint64_constant='(val##L)'
1077   ;;
1078 $ac_cv_sizeof_long_long)
1079   gint64='long long'
1080   glib_extension='G_GNUC_EXTENSION '
1081   glib_warning_guard="
1082 #if defined (__GNUC__) && __GNUC__ >= 2 && __GNUC_MINOR__ >= 8
1083 #  define G_GNUC_EXTENSION __extension__
1084 #else
1085 #  define G_GNUC_EXTENSION
1086 #endif
1087
1088 "
1089   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1090   ;;
1091 esac
1092
1093 gintbits=`expr $ac_cv_sizeof_int \* 8`
1094 glongbits=`expr $ac_cv_sizeof_long \* 8`
1095
1096
1097 case $ac_cv_sizeof_void_p in
1098 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
1099 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
1100 *)                      glib_unknown_void_p=yes ;;
1101 esac
1102
1103
1104 case xyes in
1105 x$ac_cv_func_atexit)
1106   glib_atexit="
1107 #ifdef NeXT /* @#%@! NeXTStep */
1108 # define g_ATEXIT(proc) (!atexit (proc))
1109 #else
1110 # define g_ATEXIT(proc) (atexit (proc))
1111 #endif"
1112   ;;
1113 x$ac_cv_func_on_exit)
1114   glib_atexit="
1115 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
1116   ;;
1117 esac
1118
1119 case xyes in
1120 x$ac_cv_func_memmove)
1121   glib_memmove='
1122 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
1123   ;;
1124 *)
1125   glib_memmove="
1126 /* We make the assumption that if memmove isn't available, then
1127  * bcopy will do the job. This isn't safe everywhere. (bcopy can't
1128  * necessarily handle overlapping copies) */
1129 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
1130   ;;
1131 esac
1132
1133 glib_defines="
1134 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
1135 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
1136 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
1137 "
1138
1139 case xyes in
1140 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
1141 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
1142 *)                      glib_vacopy=''
1143 esac
1144
1145 if test x$glib_cv_va_val_copy = xno; then
1146   glib_vacopy="\$glib_vacopy
1147 #define G_VA_COPY_AS_ARRAY 1"
1148 fi
1149
1150 if test x$glib_cv_hasinline = xyes; then
1151     glib_inline='#define G_HAVE_INLINE 1'
1152 fi
1153 if test x$glib_cv_has__inline = xyes; then
1154     glib_inline="\$glib_inline
1155 #define G_HAVE___INLINE 1"
1156 fi
1157 if test x$glib_cv_has__inline__ = xyes; then
1158     glib_inline="\$glib_inline
1159 #define G_HAVE___INLINE__ 1"
1160 fi
1161
1162 case xyes in
1163 x$ac_cv_c_bigendian)
1164   g_byte_order=G_BIG_ENDIAN
1165   g_bs_native=BE
1166   g_bs_alien=LE
1167   ;;
1168 *)
1169   g_byte_order=G_LITTLE_ENDIAN
1170   g_bs_native=LE
1171   g_bs_alien=BE
1172   ;;
1173 esac
1174
1175 if test x$glib_wchar_h = xyes; then
1176   glib_wc='
1177 #define G_HAVE_WCHAR_H 1'
1178 fi
1179 if test x$glib_wctype_h = xyes; then
1180   glib_wc="\$glib_wc
1181 #define G_HAVE_WCTYPE_H 1"
1182 fi
1183 if test x$glib_working_wctype = xno; then
1184   glib_wc="\$glib_wc
1185 #define G_HAVE_BROKEN_WCTYPE 1"
1186 fi
1187
1188 case x$enable_threads in
1189 xyes)   g_enable_threads_def="#define";;
1190 *)      g_enable_threads_def="#undef ";;
1191 esac
1192
1193 g_threads_impl_def=$g_threads_impl
1194
1195 g_mutex_has_default="$mutex_has_default"
1196 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
1197 g_mutex_contents="$glib_cv_byte_contents_gmutex"
1198 ])
1199
1200 AC_OUTPUT([
1201 Makefile
1202 glib-config
1203 gmodule/gmoduleconf.h
1204 gmodule/Makefile
1205 gthread/Makefile
1206 docs/Makefile
1207 tests/Makefile
1208 ],[case "$CONFIG_FILES" in
1209 *glib-config*)chmod +x glib-config;;
1210 esac])