configure.in

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002
   4 # Free Software Foundation, Inc.
   5 #
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  19 # 02111-1307, USA.
  20
  21 AC_PREREQ(2.54)
  22 AC_INIT([GNU Automake], [1.6g], [bug-automake@gnu.org])
  23
  24 AC_CONFIG_SRCDIR(automake.in)
  25 AC_CONFIG_AUX_DIR(lib)
  26
  27 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  28
  29 # The API version is the base version.  We must guarantee
  30 # compatibility for all releases with the same API version.
  31 # Our current rule is that:
  32 # * All releases, including the prereleases, in an X.Y series
  33 #   are compatible.  So 1.5.1c is compatible with 1.5.
  34 # * Prereleases on the trunk are all incompatible -- 1.5b and 1.5c
  35 #   aren't the same.
  36 APIVERSION=`echo "$VERSION" | sed -e 's/^\([[0-9]]*\.[[0-9]]*[[a-z]]*\).*$/\1/'`
  37 AC_SUBST(APIVERSION)
  38
  39 # A versioned directory, defined here for convenience.
  40 pkgvdatadir="\${datadir}/automake-${APIVERSION}"
  41 AC_SUBST(pkgvdatadir)
  42
  43 # $AUTOMAKE and $ACLOCAL are always run after a `cd $top_srcdir',
  44 # hence `.' is really what we want for perllibdir and libdir.
  45 ACLOCAL="perllibdir=./lib `pwd`/aclocal --acdir=m4 -I `pwd`/m4"
  46 AUTOMAKE="perllibdir=./lib `pwd`/automake --libdir=lib"
  47
  48 AC_PATH_PROG(PERL, perl)
  49 if test -z "$PERL"; then
  50    AC_MSG_ERROR([perl not found])
  51 fi
  52 $PERL -e 'require 5.005;' || {
  53    AC_MSG_ERROR([perl 5.005 or better is required])
  54 }
  55
  56 # The test suite will skip some tests if tex is absent.
  57 AC_CHECK_PROG([TEX], [tex], [tex])
  58
  59 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
  60 # deletion of any files created (such as those added to
  61 # autom4te.cache).
  62 mkdir conftest
  63 echo 'AC''_PREREQ(2.54)' > conftest/conftest.ac
  64 AM_RUN_LOG([cd conftest && eval $AUTOCONF -o /dev/null conftest.ac]) || {
  65    AC_MSG_ERROR([Autoconf 2.54 or better is required])
  66 }
  67 rm -rf conftest
  68
  69 # Test for ln.  We need use it to install the versioned binaries.
  70 AC_MSG_CHECKING([whether ln works])
  71 AC_CACHE_VAL([am_cv_prog_ln], [
  72 rm -f conftest conftest.file
  73 : >conftest.file
  74 if ln conftest.file conftest 2>/dev/null; then
  75   am_cv_prog_ln=ln
  76 else
  77   am_cv_prog_ln='cp -p'
  78 fi
  79 rm -f conftest conftest.file])
  80 AC_SUBST([LN], [$am_cv_prog_ln])
  81 result=no
  82 test "x$am_cv_prog_ln" = xln && result=yes
  83 AC_MSG_RESULT([$result])
  84
  85 # Test for things needed by the test suite.
  86 AC_PROG_EGREP
  87 AC_PROG_FGREP
  88
  89 AC_CONFIG_FILES([
  90   Makefile
  91   lib/Automake/Makefile
  92   lib/Makefile
  93   lib/am/Makefile
  94   m4/Makefile
  95   m4/amversion.m4:m4/amversion.in
  96   tests/Makefile
  97   tests/defs
  98 ])
  99
 100 AC_OUTPUT