configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5
   6 # Process this file with autoconf to produce a configure script.
   7 AC_INIT(glist.c)
   8
   9 # Save this value here, since automake will set cflags later
  10 cflags_set=${CFLAGS+set}
  11
  12 # we rewrite this file
  13 rm -f glibconfig-sysdefs.h
  14
  15 # The following version number definitions apply to GLib and GModule
  16 # as a whole, so if changes occoured in either of them, they are both
  17 # treated with the same interface and binary age.
  18 #
  19 # Making releases:
  20 #   GLIB_MICRO_VERSION += 1;
  21 #   GLIB_INTERFACE_AGE += 1;
  22 #   GLIB_BINARY_AGE += 1;
  23 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  24 # if backwards compatibility has been broken,
  25 # set GLIB_BINARY_AGE and GLIB_INTERFACE_AGE to 0.
  26 #
  27 GLIB_MAJOR_VERSION=1
  28 GLIB_MINOR_VERSION=1
  29 GLIB_MICRO_VERSION=12
  30 GLIB_INTERFACE_AGE=0
  31 GLIB_BINARY_AGE=0
  32 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  33 AC_SUBST(GLIB_VERSION)
  34
  35 # libtool versioning
  36 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  37 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  38 LT_REVISION=$GLIB_INTERFACE_AGE
  39 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  40 AC_SUBST(LT_RELEASE)
  41 AC_SUBST(LT_CURRENT)
  42 AC_SUBST(LT_REVISION)
  43 AC_SUBST(LT_AGE)
  44
  45 VERSION=$GLIB_VERSION
  46 PACKAGE=glib
  47
  48 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  49
  50 # Specify a configuration file
  51 AM_CONFIG_HEADER(config.h)
  52
  53 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION)
  54 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION)
  55 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION)
  56 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE)
  57 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE)
  58
  59 dnl Initialize libtool
  60 AM_PROG_LIBTOOL
  61
  62 dnl Initialize maintainer mode
  63 AM_MAINTAINER_MODE
  64
  65 AC_CANONICAL_HOST
  66
  67 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=minimum]],,enable_debug=minimum)
  68 AC_ARG_ENABLE(mem_check, [  --enable-mem-check      turn on malloc/free sanity checking [default=no]],,enable_mem_check=no)
  69 AC_ARG_ENABLE(mem_profile, [  --enable-mem-profile    turn on malloc profiling atexit [default=no]],,enable_mem_profile=no)
  70 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
  71                     , enable_ansi=no)
  72 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
  73                           ([=no] will override --with-threads)],,enable_threads=yes)
  74
  75 if test "x$enable_threads" != "xyes"; then
  76   enable_threads=no
  77 fi
  78
  79 AC_MSG_CHECKING(whether to enable memory checking)
  80 if test "x$enable_mem_check" = "xyes"; then
  81   AC_DEFINE(ENABLE_MEM_CHECK, 1)
  82   AC_SUBST(ENABLE_MEM_CHECK)
  83   AC_MSG_RESULT(yes)
  84 else
  85   AC_MSG_RESULT(no)
  86 fi
  87
  88 AC_MSG_CHECKING(whether to enable memory profiling)
  89 if test "x$enable_mem_profile" = "xyes"; then
  90   AC_DEFINE(ENABLE_MEM_PROFILE, 1)
  91   AC_SUBST(ENABLE_MEM_PROFILE)
  92   AC_MSG_RESULT(yes)
  93 else
  94   AC_MSG_RESULT(no)
  95 fi
  96
  97 if test "x$enable_debug" = "xyes"; then
  98   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
  99   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 100 else
 101   if test "x$enable_debug" = "xno"; then
 102     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 103   fi
 104 fi
 105
 106 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 107
 108 # Checks for programs.
 109 AC_PROG_CC
 110 AM_PROG_CC_STDC
 111 AC_PROG_INSTALL
 112
 113 changequote(,)dnl
 114 if test "x$GCC" = "xyes"; then
 115   case " $CFLAGS " in
 116   *[\ \ ]-Wall[\ \      ]*) ;;
 117   *) CFLAGS="$CFLAGS -Wall" ;;
 118   esac
 119
 120   if test "x$enable_ansi" = "xyes"; then
 121     case " $CFLAGS " in
 122     *[\ \       ]-ansi[\ \      ]*) ;;
 123     *) CFLAGS="$CFLAGS -ansi" ;;
 124     esac
 125
 126     case " $CFLAGS " in
 127     *[\ \       ]-pedantic[\ \  ]*) ;;
 128     *) CFLAGS="$CFLAGS -pedantic" ;;
 129     esac
 130   fi
 131 fi
 132 changequote([,])dnl
 133
 134 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 135 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 136 glib_save_LIBS=$LIBS
 137 LIBS="$LIBS -lm"
 138 AC_TRY_RUN([#include <math.h>
 139              int main (void) { return (log(1) != log(1.)); }],
 140      AC_MSG_RESULT(none needed),
 141      glib_save_CFLAGS=$CFLAGS
 142      CFLAGS="$CFLAGS -std1"
 143      AC_TRY_RUN([#include <math.h>
 144                  int main (void) { return (log(1) != log(1.)); }],
 145          AC_MSG_RESULT(-std1),
 146          AC_MSG_RESULT()
 147          CFLAGS=$glib_save_CFLAGS
 148          AC_MSG_WARN(
 149                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 150      )
 151 )
 152 LIBS=$glib_save_LIBS
 153
 154 dnl NeXTStep cc seems to need this
 155 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 156 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 157   AC_MSG_RESULT(none needed),
 158   glib_save_CFLAGS=$CFLAGS
 159   CFLAGS="$CFLAGS -posix"
 160   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 161     AC_MSG_RESULT(-posix),
 162     AC_MSG_RESULT()
 163     CFLAGS=$glib_save_CFLAGS
 164     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 165
 166 # Checks for header files.
 167 AC_HEADER_STDC
 168
 169 # Checks for library functions.
 170 AC_FUNC_VPRINTF
 171 AC_FUNC_ALLOCA
 172 if test "x$ac_cv_func_alloca_works" = xyes; then
 173         glib_have_alloca=yes
 174 else
 175         glib_have_alloca=no
 176 fi
 177
 178 AC_CHECK_FUNCS(atexit on_exit)
 179
 180 AC_CHECK_SIZEOF(char)
 181 AC_CHECK_SIZEOF(short)
 182 AC_CHECK_SIZEOF(long)
 183 AC_CHECK_SIZEOF(int)
 184 AC_CHECK_SIZEOF(void *)
 185 AC_CHECK_SIZEOF(long long)
 186
 187 dnl long doubles were not used, and a portability problem
 188 dnl AC_C_LONG_DOUBLE
 189 AC_C_CONST
 190
 191 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 192 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 193 dnl actually supported.
 194 AC_MSG_CHECKING(for __inline)
 195 AC_CACHE_VAL(glib_cv_has__inline,[
 196         AC_TRY_RUN([
 197         __inline int foo () { return 0; }
 198         int main () { return foo (); }
 199         ],
 200         glib_cv_has__inline=yes
 201         ,
 202         glib_cv_has__inline=no
 203         ,)
 204 ])
 205 AC_MSG_RESULT($glib_cv_has__inline)
 206 case x$glib_cv_has__inline in
 207 xyes) AC_DEFINE(G_HAVE___INLINE)
 208 esac
 209 AC_MSG_CHECKING(for __inline__)
 210 AC_CACHE_VAL(glib_cv_has__inline__,[
 211         AC_TRY_RUN([
 212         __inline__ int foo () { return 0; }
 213         int main () { return foo (); }
 214         ],
 215         glib_cv_has__inline__=yes
 216         ,
 217         glib_cv_has__inline__=no
 218         ,)
 219 ])
 220 AC_MSG_RESULT($glib_cv_has__inline__)
 221 case x$glib_cv_has__inline__ in
 222 xyes) AC_DEFINE(G_HAVE___INLINE__)
 223 esac
 224 AC_MSG_CHECKING(for inline)
 225 AC_CACHE_VAL(glib_cv_hasinline,[
 226         AC_TRY_RUN([
 227         inline int foo () { return 0; }
 228         int main () { return foo (); }
 229         ],
 230         glib_cv_hasinline=yes
 231         ,
 232         glib_cv_hasinline=no
 233         ,)
 234 ])
 235 AC_MSG_RESULT($glib_cv_hasinline)
 236 case x$glib_cv_hasinline in
 237 xyes) AC_DEFINE(G_HAVE_INLINE)
 238 esac
 239
 240 dnl for bytesex stuff
 241 AC_C_BIGENDIAN
 242
 243 dnl header file checks
 244 AC_CHECK_HEADERS(float.h, AC_DEFINE(HAVE_FLOAT_H))
 245 AC_CHECK_HEADERS(limits.h, AC_DEFINE(HAVE_LIMITS_H))
 246 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 247 AC_CHECK_HEADERS(sys/param.h, AC_DEFINE(HAVE_SYS_PARAM_H))
 248 AC_CHECK_HEADERS(sys/poll.h, AC_DEFINE(HAVE_SYS_POLL_H))
 249 AC_CHECK_HEADERS(sys/select.h, AC_DEFINE(HAVE_SYS_SELECT_H))
 250 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 251 AC_CHECK_HEADERS(sys/times.h, AC_DEFINE(HAVE_SYS_TIMES_H))
 252 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 253 AC_CHECK_HEADERS(values.h, AC_DEFINE(HAVE_VALUES_H))
 254 AC_CHECK_HEADER(alloca.h, glib_have_alloca_h=yes, glib_have_alloca_h=no)
 255
 256 # Check for some functions
 257 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf vasprintf strcasecmp strncasecmp poll)
 258
 259 # Check for sys_errlist
 260 AC_MSG_CHECKING(for sys_errlist)
 261 AC_TRY_LINK(, [
 262 extern char *sys_errlist[];
 263 extern int sys_nerr;
 264 sys_errlist[sys_nerr-1][0] = 0;
 265 ], glib_ok=yes, glib_ok=no)
 266 AC_MSG_RESULT($glib_ok)
 267 if test $glib_ok = no; then
 268     AC_DEFINE(NO_SYS_ERRLIST)
 269 fi
 270
 271 # Check for sys_siglist
 272 AC_MSG_CHECKING(for sys_siglist)
 273 AC_TRY_LINK(, [
 274 extern char *sys_siglist[];
 275 sys_siglist[1][0] = 0;
 276 ], glib_ok=yes, glib_ok=no)
 277 AC_MSG_RESULT($glib_ok)
 278 if test $glib_ok = no; then
 279     AC_DEFINE(NO_SYS_SIGLIST)
 280 fi
 281
 282 # Check if <sys/select.h> needs to be included for fd_set
 283 AC_MSG_CHECKING([for fd_set])
 284 AC_TRY_COMPILE([#include <sys/types.h>],
 285         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 286 if test $gtk_ok = yes; then
 287     AC_MSG_RESULT([yes, found in sys/types.h])
 288 else
 289     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 290     if test $gtk_ok = yes; then
 291         AC_DEFINE(HAVE_SYS_SELECT_H)
 292         AC_MSG_RESULT([yes, found in sys/select.h])
 293     else
 294         AC_DEFINE(NO_FD_SET)
 295         AC_MSG_RESULT(no)
 296     fi
 297 fi
 298
 299 # These are used only in GDK (gdki18n.h)
 300 # This stuff is here only so that we can define these
 301 # things in glibconfig.h. If gtk+ started using an installed
 302 # gdkconfig.h file, then the definitions would belong there.
 303
 304 # Check for wchar.h
 305
 306 AC_MSG_CHECKING(for wchar.h)
 307 AC_TRY_CPP([#include <wchar.h>], glib_wchar_h=yes, glib_wchar_h=no)
 308 if test $glib_wchar_h = yes; then
 309    AC_DEFINE(HAVE_WCHAR_H)
 310 fi
 311 AC_MSG_RESULT($glib_wchar_h)
 312
 313 # Check for wctype.h (for iswalnum)
 314
 315 AC_MSG_CHECKING(for wctype.h)
 316 AC_TRY_CPP([#include <wctype.h>], glib_wctype_h=yes, glib_wctype_h=no)
 317 if test $glib_wctype_h = yes; then
 318    AC_DEFINE(HAVE_WCTYPE_H)
 319 fi
 320 AC_MSG_RESULT($glib_wctype_h)
 321
 322 oLIBS="$LIBS"
 323 # in Solaris 2.5, `iswalnum' is in -lw
 324 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum)])
 325
 326 # The following is necessary for Linux libc-5.4.38
 327 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 328 AC_TRY_LINK([#include <stdlib.h>],[
 329 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 330 #  ifdef HAVE_WCTYPE_H
 331 #    include <wctype.h>
 332 #  else
 333 #    ifdef HAVE_WCHAR_H
 334 #      include <wchar.h>
 335 #    endif
 336 #  endif
 337 #else
 338 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 339 #endif
 340 iswalnum((wchar_t) 0);
 341 ], glib_working_wctype=yes, glib_working_wctype=no)
 342 LIBS="$oLIBS"
 343
 344 if test $glib_working_wctype = no; then
 345    AC_DEFINE(HAVE_BROKEN_WCTYPE)
 346 fi
 347 AC_MSG_RESULT($glib_working_wctype)
 348
 349
 350 dnl **********************
 351 dnl *** va_copy checks ***
 352 dnl **********************
 353 dnl we currently check for all three va_copy possibilities, so we get
 354 dnl all results in config.log for bug reports.
 355 AC_MSG_CHECKING(for an implementation of va_copy())
 356 AC_CACHE_VAL(glib_cv_va_copy,[
 357         AC_TRY_RUN([
 358         #include <stdarg.h>
 359         void f (int i, ...) {
 360         va_list args1, args2;
 361         va_start (args1, i);
 362         va_copy (args2, args1);
 363         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 364           exit (1);
 365         va_end (args1); va_end (args2);
 366         }
 367         int main() {
 368           f (0, 42);
 369           return 0;
 370         }],
 371         glib_cv_va_copy=yes
 372         ,
 373         glib_cv_va_copy=no
 374         ,)
 375 ])
 376 AC_MSG_RESULT($glib_cv_va_copy)
 377 AC_MSG_CHECKING(for an implementation of __va_copy())
 378 AC_CACHE_VAL(glib_cv___va_copy,[
 379         AC_TRY_RUN([
 380         #include <stdarg.h>
 381         void f (int i, ...) {
 382         va_list args1, args2;
 383         va_start (args1, i);
 384         __va_copy (args2, args1);
 385         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 386           exit (1);
 387         va_end (args1); va_end (args2);
 388         }
 389         int main() {
 390           f (0, 42);
 391           return 0;
 392         }],
 393         glib_cv___va_copy=yes
 394         ,
 395         glib_cv___va_copy=no
 396         ,)
 397 ])
 398 AC_MSG_RESULT($glib_cv___va_copy)
 399 AC_MSG_CHECKING(whether va_lists can be copied by value)
 400 AC_CACHE_VAL(glib_cv_va_val_copy,[
 401         AC_TRY_RUN([
 402         #include <stdarg.h>
 403         void f (int i, ...) {
 404         va_list args1, args2;
 405         va_start (args1, i);
 406         args2 = args1;
 407         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 408           exit (1);
 409         va_end (args1); va_end (args2);
 410         }
 411         int main() {
 412           f (0, 42);
 413           return 0;
 414         }],
 415         glib_cv_va_val_copy=yes
 416         ,
 417         glib_cv_va_val_copy=no
 418         ,)
 419 ])
 420 if test "x$glib_cv_va_copy" = "xyes"; then
 421   AC_DEFINE(G_VA_COPY, va_copy)
 422 else if test "x$glib_cv___va_copy" = "xyes"; then
 423   AC_DEFINE(G_VA_COPY, __va_copy)
 424 fi
 425 fi
 426 if test "x$glib_cv_va_val_copy" = "xno"; then
 427   AC_DEFINE(G_VA_COPY_AS_ARRAY)
 428 fi
 429 AC_MSG_RESULT($glib_cv_va_val_copy)
 430
 431
 432 dnl ***********************
 433 dnl *** g_module checks ***
 434 dnl ***********************
 435 G_MODULE_LIBS=
 436 G_MODULE_LDFLAGS=
 437 G_MODULE_IMPL=
 438 G_MODULE_NEED_USCORE=0
 439 G_MODULE_HAVE_DLERROR=0
 440 dnl *** dlopen() in system libraries
 441 if test -z "$G_MODULE_IMPL"; then
 442         AC_CHECK_FUNC(dlopen,
 443                 G_MODULE_IMPL=G_MODULE_IMPL_DL
 444         ,)
 445 fi
 446 dnl *** dlopen() in libdl
 447 if test -z "$G_MODULE_IMPL"; then
 448         AC_CHECK_LIB(dl, dlopen,
 449                 G_MODULE_LIBS=-ldl
 450                 G_MODULE_IMPL=G_MODULE_IMPL_DL
 451         ,)
 452 fi
 453 dnl *** shl_load() in libdld (HP-UX)
 454 if test -z "$G_MODULE_IMPL"; then
 455         AC_MSG_CHECKING(how to export all symbols)
 456         SAVED_LDFLAGS=$LDFLAGS
 457         LDFLAGS="$LDFLAGS -Wl,-E"
 458         AC_TRY_LINK(,[ return 0; ],
 459                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 460                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 461                 AC_TRY_LINK(,[ return 0; ],
 462                         G_MODULE_LDFLAGS="-bexpall",
 463                         G_MODULE_LDFLAGS="none"
 464                 )
 465         ])
 466         LDFLAGS=$SAVED_LDFLAGS
 467         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 468         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 469                 G_MODULE_LDFLAGS=
 470         fi
 471         AC_CHECK_LIB(dld, shl_load,
 472                 G_MODULE_LIBS=-ldld
 473                 G_MODULE_IMPL=G_MODULE_IMPL_DLD
 474         ,)
 475 fi
 476 dnl *** additional checks for G_MODULE_IMPL_DL
 477 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 478         case "$host_os" in
 479           linux*)
 480             G_MODULE_LDFLAGS='-rdynamic'
 481             ;;
 482         esac
 483         LIBS_orig="$LIBS"
 484         LDFLAGS_orig="$LDFLAGS"
 485         LIBS="$LIBS $G_MODULE_LIBS"
 486         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 487 dnl *** check whether we need preceeding underscores
 488         AC_MSG_CHECKING(for preceeding underscore in symbols)
 489         AC_CACHE_VAL(glib_cv_uscore,[
 490                 AC_TRY_RUN([
 491                 #include <dlfcn.h>
 492                 int glib_underscore_test (void) { return 42; }
 493                 int main() {
 494                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 495                   handle = dlopen ((void*)0, 0);
 496                   if (handle) {
 497                     f1 = dlsym (handle, "glib_underscore_test");
 498                     f2 = dlsym (handle, "_glib_underscore_test");
 499                   } return (!f2 || f1);
 500                 }],
 501                         glib_cv_uscore=yes,
 502                         glib_cv_uscore=no,
 503                 )
 504                 rm -f plugin.c plugin.o plugin.lo
 505         ])
 506         AC_MSG_RESULT($glib_cv_uscore)
 507         if test "x$glib_cv_uscore" = "xyes"; then
 508                 G_MODULE_NEED_USCORE=1
 509         else
 510                 G_MODULE_NEED_USCORE=0
 511         fi
 512
 513         LDFLAGS="$LDFLAGS_orig"
 514 dnl *** check for having dlerror()
 515         AC_CHECK_FUNC(dlerror,
 516                 G_MODULE_HAVE_DLERROR=1,
 517                 G_MODULE_HAVE_DLERROR=0)
 518         LIBS="$LIBS_orig"
 519 fi
 520 dnl *** done, have e got an implementation?
 521 if test -z "$G_MODULE_IMPL"; then
 522         G_MODULE_IMPL=0
 523 fi
 524 AC_SUBST(G_MODULE_IMPL)
 525 AC_SUBST(G_MODULE_LIBS)
 526 AC_SUBST(G_MODULE_LDFLAGS)
 527 AC_SUBST(G_MODULE_HAVE_DLERROR)
 528 AC_SUBST(G_MODULE_NEED_USCORE)
 529 AC_SUBST(GLIB_DEBUG_FLAGS)
 530
 531
 532 dnl ***********************
 533 dnl *** g_thread checks ***
 534 dnl ***********************
 535
 536 AC_ARG_WITH(threads, [  --with-threads=[none/posix/solaris/nspr] specify a thread implementation to use],
 537         if test "x$with_threads" = x; then
 538                 want_threads=yes
 539         else
 540                 want_threads=$with_threads
 541         fi,
 542         want_threads=yes)
 543 if test "x$enable_threads" = "xno"; then
 544         want_threads=no
 545 fi
 546 if test "x$want_threads" = "xnone"; then
 547         want_threads=no
 548 fi
 549
 550 dnl error and warning message
 551 dnl *************************
 552
 553 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
 554                 computer. glib will not be thread safe on your computer."
 555
 556 FLAG_DOES_NOT_WORK="I can't find the MACRO, that enables thread safety on your
 557                 platform (normaly it's "_REENTRANT"). I'll not use any flag on
 558                 compilation now, but then your programs might not work.
 559                 Please provide information on how it is done on your system."
 560
 561 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
 562                 "
 563
 564 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
 565                 provide informationon your thread implementation."
 566
 567 dnl determination of thread implementation
 568 dnl ***************************************
 569
 570 have_threads=none
 571 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
 572         case $host in
 573                 *-*-solaris*)
 574                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
 575                 ;;
 576         esac
 577 fi
 578 if test "x$want_threads" = xyes || test "x$want_threads" = xposix; then
 579         if test "x$have_threads" = xnone; then
 580                 AC_CHECK_LIB(pthread, pthread_attr_init, have_threads=posix)
 581         fi
 582         if test "x$have_threads" = xnone; then
 583                 AC_CHECK_LIB(pthreads, pthread_attr_init, have_threads=posix)
 584         fi
 585         if test "x$have_threads" = xnone; then
 586                 AC_CHECK_LIB(c_r, pthread_attr_init, have_threads=posix)
 587         fi
 588         if test "x$have_threads" = xnone; then
 589                 AC_CHECK_FUNC(pthread_attr_init, have_threads=posix)
 590         fi
 591         dnl ********** DG/UX ************
 592         if test "x$have_threads" = xnone; then
 593                 AC_CHECK_LIB(thread, __d10_pthread_attr_init,
 594                         have_threads=posix)
 595         fi
 596 fi
 597 if test "x$want_threads" = xyes || test "x$want_threads" = xnspr; then
 598         if test "x$have_threads" = xnone; then
 599                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar, have_threads=nspr)
 600         fi
 601 fi
 602
 603 AC_MSG_CHECKING(for thread implementation)
 604
 605 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
 606         AC_MSG_RESULT(none available)
 607         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
 608 else
 609         AC_MSG_RESULT($have_threads)
 610 fi
 611
 612
 613 dnl determination of G_THREAD_LIBS
 614 dnl ******************************
 615
 616 G_THREAD_LIBS=
 617 G_THREAD_CFLAGS=
 618
 619 mutex_has_default=no
 620 case $have_threads in
 621         posix)
 622                 G_THREAD_LIBS=error
 623                 AC_CHECK_LIB(pthread, pthread_attr_init,
 624                              G_THREAD_LIBS="-lpthread")
 625                 if test "x$G_THREAD_LIBS" = xerror; then
 626                         AC_CHECK_LIB(pthreads, pthread_attr_init,
 627                                 G_THREAD_LIBS="-lpthreads")
 628                 fi
 629                 if test "x$G_THREAD_LIBS" = xerror; then
 630                         AC_CHECK_LIB(c_r, pthread_attr_init,
 631                                 G_THREAD_LIBS="-lc_r")
 632                 fi
 633                 if test "x$G_THREAD_LIBS" = xerror; then
 634                         AC_CHECK_FUNC(pthread_attr_init, G_THREAD_LIBS="")
 635                 fi
 636                 dnl ********** DG/UX ************
 637                 if test "x$G_THREAD_LIBS" = xerror; then
 638                         AC_CHECK_LIB(thread, __d10_pthread_attr_init,
 639                                 G_THREAD_LIBS="-lthread"
 640                                 G_THREAD_CFLAGS="-D_POSIX4A_DRAFT10_SOURCE")
 641                 fi
 642                 mutex_has_default=yes
 643                 mutex_default_type='pthread_mutex_t'
 644                 mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
 645                 mutex_header_file='pthread.h'
 646                 g_threads_impl="POSIX"
 647                 ;;
 648         solaris)
 649                 G_THREAD_LIBS=error
 650                 AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
 651                 mutex_has_default=yes
 652                 mutex_default_type='mutex_t'
 653                 mutex_default_init="DEFAULTMUTEX"
 654                 mutex_header_file='thread.h'
 655                 g_threads_impl="SOLARIS"
 656                 ;;
 657         nspr)
 658                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar,
 659                              G_THREAD_LIBS="-lnspr21")
 660                 g_threads_impl="NSPR"
 661                 ;;
 662         none)
 663                 g_threads_impl="NONE"
 664                 ;;
 665         *)
 666                 g_threads_impl="NONE"
 667                 G_THREAD_LIBS=error
 668                 ;;
 669 esac
 670
 671 if test "x$G_THREAD_LIBS" = xerror; then
 672         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 673 fi
 674
 675 AC_MSG_CHECKING(necessary linker options)
 676 AC_MSG_RESULT($G_THREAD_LIBS)
 677
 678
 679 dnl determination of G_THREAD_CFLAGS
 680 dnl ********************************
 681
 682 if test x"$have_threads" != xnone; then
 683         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_REENTRANT" # good default
 684
 685         case $host in
 686                *-aix*)
 687                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 688                         if test x"$GCC" = xyes; then
 689                                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
 690                         fi
 691                         ;;
 692         esac
 693
 694         # if we are not finding the ctime_r function, then we probably are
 695         # not using the proper multithread flag
 696         old_CPPFLAGS=$CPPFLAGS
 697         CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
 698         AC_EGREP_HEADER([[^a-zA-Z_]ctime_r[^a-zA-Z_]], time.h, ,
 699                 G_THREAD_CFLAGS=
 700                 AC_MSG_WARN($FLAG_DOES_NOT_WORK))
 701         CPPFLAGS=$old_CPPFLAGS
 702
 703         AC_MSG_CHECKING(necessary compiler options)
 704
 705         AC_MSG_RESULT($G_THREAD_CFLAGS)
 706 else
 707         G_THREAD_CFLAGS=
 708 fi
 709
 710 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c")
 711 AC_SUBST(G_THREAD_CFLAGS)
 712 AC_SUBST(G_THREAD_LIBS)
 713
 714 CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 715
 716 AC_CHECK_FUNCS(localtime_r rand_r)
 717
 718 dnl **********************************************
 719 dnl *** GDefaultMutex setup and initialization ***
 720 dnl **********************************************
 721 dnl
 722 dnl if mutex_has_default = yes, we also got
 723 dnl mutex_default_type, mutex_default_init and mutex_header_file
 724 GLIB_IF_VAR_EQ(mutex_has_default, yes,
 725         GLIB_SIZEOF([#include <$mutex_header_file>],
 726                     $mutex_default_type,
 727                     gmutex,
 728                     )
 729         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
 730                            $mutex_default_type,
 731                            gmutex,
 732                            $glib_cv_sizeof_gmutex,
 733                            $mutex_default_init)
 734         ,
 735 )
 736
 737
 738 dnl ****************************************
 739 dnl *** GLib POLL* compatibility defines ***
 740 dnl ****************************************
 741 GLIB_SYSDEFS(
 742 [#include <sys/types.h>
 743 #include <sys/poll.h>],
 744         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
 745         glibconfig-sysdefs.h,
 746         =)
 747
 748
 749 dnl ******************************
 750 dnl *** output the whole stuff ***
 751 dnl ******************************
 752
 753 AC_OUTPUT_COMMANDS([
 754
 755 ## Generate `glibconfig.h' in two cases
 756 ## 1. `config.status' is run either explicitly, or via configure.
 757 ##     Esp. not when it is run in `Makefile' to generate makefiles and
 758 ##     config.h
 759 ## 2. CONFIG_OTHER is set explicitly
 760 ##
 761 ## Case 1 is difficult.  We know that `automake' sets one of
 762 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
 763 ## only when AM_CONFIG_HEADER is set, however.
 764
 765 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
 766   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
 767   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
 768 fi
 769 case "$CONFIG_OTHER" in
 770 *glibconfig.h*)
 771         echo creating glibconfig.h
 772         outfile=glibconfig.h-tmp
 773         cat > $outfile <<\_______EOF
 774 /* glibconfig.h
 775  *
 776  * This is a generated file.  Please modify `configure.in'
 777  */
 778
 779 #ifndef GLIBCONFIG_H
 780 #define GLIBCONFIG_H
 781
 782 #ifdef __cplusplus
 783 extern "C" {
 784 #endif /* __cplusplus */
 785
 786 _______EOF
 787
 788         if test x$glib_limits_h = xyes; then
 789           echo '#include <limits.h>' >> $outfile
 790         fi
 791         if test x$glib_float_h = xyes; then
 792           echo '#include <float.h>' >> $outfile
 793         fi
 794         if test x$glib_values_h = xyes; then
 795           echo '#include <values.h>' >> $outfile
 796         fi
 797         if test x$g_mutex_header_file != x; then
 798           echo '#include <'"$g_mutex_header_file"'>' >> $outfile
 799         fi
 800         if test x$glib_sys_poll_h = xyes; then
 801           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
 802         fi
 803
 804         cat >> $outfile <<_______EOF
 805
 806 #define G_MINFLOAT      $glib_mf
 807 #define G_MAXFLOAT      $glib_Mf
 808 #define G_MINDOUBLE     $glib_md
 809 #define G_MAXDOUBLE     $glib_Md
 810 #define G_MINSHORT      $glib_ms
 811 #define G_MAXSHORT      $glib_Ms
 812 #define G_MININT        $glib_mi
 813 #define G_MAXINT        $glib_Mi
 814 #define G_MINLONG       $glib_ml
 815 #define G_MAXLONG       $glib_Ml
 816
 817 _______EOF
 818
 819
 820         ### this should always be true in a modern C/C++ compiler
 821         cat >>$outfile <<_______EOF
 822 typedef signed char gint8;
 823 typedef unsigned char guint8;
 824 _______EOF
 825
 826
 827         if test -n "$gint16"; then
 828           cat >>$outfile <<_______EOF
 829 typedef signed $gint16 gint16;
 830 typedef unsigned $gint16 guint16;
 831 _______EOF
 832         fi
 833
 834
 835         if test -n "$gint32"; then
 836           cat >>$outfile <<_______EOF
 837 typedef signed $gint32 gint32;
 838 typedef unsigned $gint32 guint32;
 839 _______EOF
 840         fi
 841
 842
 843         if test -n "$gint64"; then
 844           cat >>$outfile <<_______EOF
 845 ${glib_warning_guard}#define G_HAVE_GINT64 1
 846
 847 ${glib_extension}typedef signed $gint64 gint64;
 848 ${glib_extension}typedef unsigned $gint64 guint64;
 849
 850 #define G_GINT64_CONSTANT(val)  $gint64_constant
 851 _______EOF
 852         fi
 853
 854
 855         if test -z "$glib_unknown_void_p"; then
 856           cat >>$outfile <<_______EOF
 857
 858 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
 859 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
 860
 861 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
 862 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
 863 _______EOF
 864         else
 865           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
 866         fi
 867
 868
 869
 870         cat >>$outfile <<_______EOF
 871 $glib_atexit
 872 $glib_memmove
 873 $glib_alloca
 874 $glib_defines
 875
 876 $glib_vacopy
 877
 878 #ifdef  __cplusplus
 879 #define G_HAVE_INLINE   1
 880 #else   /* !__cplusplus */
 881 $glib_inline
 882 #endif  /* !__cplusplus */
 883 _______EOF
 884
 885         echo >>$outfile
 886         if test x$g_mutex_has_default = xyes; then
 887                 cat >>$outfile <<_______EOF
 888 $g_enable_threads_def G_THREADS_ENABLED
 889 #define G_THREADS_IMPL_$g_threads_impl_def
 890 typedef struct _GStaticMutex GStaticMutex;
 891 struct _GStaticMutex
 892 {
 893   struct _GMutex *runtime_mutex;
 894   union {
 895     char   pad[$g_mutex_sizeof];
 896     double dummy_double;
 897     void  *dummy_pointer;
 898     long   dummy_long;
 899   } aligned_pad_u;
 900 };
 901 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
 902 #define g_static_mutex_get_mutex(mutex) \
 903   (g_thread_use_default_impl ? ((GMutex*) &(mutex).aligned_pad_u) : \
 904    g_static_mutex_get_mutex_impl (&(mutex).runtime_mutex))
 905 _______EOF
 906         else
 907                 cat >>$outfile <<_______EOF
 908 $g_enable_threads_def G_THREADS_ENABLED
 909 #define $g_threads_impl_def
 910 typedef struct _GMutex* GStaticMutex;
 911 #define G_STATIC_MUTEX_INIT NULL
 912 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (&(mutex)))
 913 _______EOF
 914         fi
 915
 916         echo >>$outfile
 917         g_bit_sizes="16 32"
 918         if test -n "$gint64"; then
 919           g_bit_sizes="$g_bit_sizes 64"
 920         fi
 921         for bits in $g_bit_sizes; do
 922           cat >>$outfile <<_______EOF
 923 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
 924 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
 925 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
 926 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
 927 _______EOF
 928         done
 929
 930         cat >>$outfile <<_______EOF
 931 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
 932 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
 933 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
 934 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
 935 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
 936 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
 937 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
 938 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
 939 #define G_BYTE_ORDER $g_byte_order
 940
 941 _______EOF
 942
 943         if test -r glibconfig-sysdefs.h; then
 944           cat glibconfig-sysdefs.h >>$outfile
 945         fi
 946
 947
 948         cat >>$outfile <<_______EOF
 949
 950 $glib_wc
 951
 952
 953 #ifdef __cplusplus
 954 }
 955 #endif /* __cplusplus */
 956
 957 #endif /* GLIBCONFIG_H */
 958 _______EOF
 959
 960
 961         if cmp -s $outfile glibconfig.h; then
 962           echo glibconfig.h is unchanged
 963           rm -f $outfile
 964         else
 965           mv $outfile glibconfig.h
 966         fi ;;
 967 esac
 968 ],[
 969
 970 # Note that if two cases are the same, case goes with the first one.
 971 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
 972 # on variable expansion in case labels.  Look at the generated config.status
 973 # for a hint.
 974
 975 case xyes in
 976 x$ac_cv_header_float_h)
 977   glib_float_h=yes
 978   glib_mf=FLT_MIN glib_Mf=FLT_MAX
 979   glib_md=DBL_MIN glib_Md=DBL_MAX
 980   ;;
 981 x$ac_cv_header_values_h)
 982   glib_values_h=yes
 983   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
 984   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
 985   ;;
 986 esac
 987
 988 case xyes in
 989 x$ac_cv_header_limits_h)
 990   glib_limits_h=yes
 991   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX
 992   glib_mi=INT_MIN  glib_Mi=INT_MAX
 993   glib_ml=LONG_MIN glib_Ml=LONG_MAX
 994   ;;
 995 x$ac_cv_header_values_h)
 996   glib_values_h=yes
 997   glib_ms=MINSHORT glib_Ms=MAXSHORT
 998   glib_mi=MININT   glib_Mi=MAXINT
 999   glib_ml=MINLONG  glib_Ml=MAXLONG
1000   ;;
1001 esac
1002
1003 if test x$ac_cv_header_sys_poll_h = xyes ; then
1004   glib_sys_poll_h=yes
1005 fi
1006
1007 case 2 in
1008 $ac_cv_sizeof_short)            gint16=short;;
1009 $ac_cv_sizeof_int)              gint16=int;;
1010 esac
1011 case 4 in
1012 $ac_cv_sizeof_short)            gint32=short;;
1013 $ac_cv_sizeof_int)              gint32=int;;
1014 $ac_cv_sizeof_long)             gint32=long;;
1015 esac
1016 case 8 in
1017 $ac_cv_sizeof_int)
1018   gint64=int
1019   glib_extension=
1020   glib_warning_guard=
1021   gint64_constant='(val)'
1022   ;;
1023 $ac_cv_sizeof_long)
1024   gint64=long
1025   glib_extension=
1026   glib_warning_guard=
1027   gint64_constant='(val##L)'
1028   ;;
1029 $ac_cv_sizeof_long_long)
1030   gint64='long long'
1031   glib_extension='G_GNUC_EXTENSION '
1032   glib_warning_guard="
1033 #if defined (__GNUC__) && __GNUC__ >= 2 && __GNUC_MINOR__ >= 8
1034 #  define G_GNUC_EXTENSION __extension__
1035 #else
1036 #  define G_GNUC_EXTENSION
1037 #endif
1038
1039 "
1040   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1041   ;;
1042 esac
1043
1044 gintbits=`expr $ac_cv_sizeof_int \* 8`
1045 glongbits=`expr $ac_cv_sizeof_long \* 8`
1046
1047
1048 case $ac_cv_sizeof_void_p in
1049 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
1050 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
1051 *)                      glib_unknown_void_p=yes ;;
1052 esac
1053
1054
1055 case xyes in
1056 x$ac_cv_func_atexit)
1057   glib_atexit="
1058 #ifdef NeXT /* @#%@! NeXTStep */
1059 # define g_ATEXIT(proc) (!atexit (proc))
1060 #else
1061 # define g_ATEXIT(proc) (atexit (proc))
1062 #endif"
1063   ;;
1064 x$ac_cv_func_on_exit)
1065   glib_atexit="
1066 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
1067   ;;
1068 esac
1069
1070 case xyes in
1071 x$ac_cv_func_memmove)
1072   glib_memmove='
1073 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
1074   ;;
1075 *)
1076   glib_memmove="
1077 /* We make the assumption that if memmove isn't available, then
1078  * bcopy will do the job. This isn't safe everywhere. (bcopy can't
1079  * necessarily handle overlapping copies) */
1080 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
1081   ;;
1082 esac
1083
1084 glib_defines="
1085 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
1086 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
1087 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
1088 "
1089
1090 case xyes in
1091 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
1092 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
1093 *)                      glib_vacopy=''
1094 esac
1095
1096 if test x$glib_cv_va_val_copy = xno; then
1097   glib_vacopy="\$glib_vacopy
1098 #define G_VA_COPY_AS_ARRAY 1"
1099 fi
1100
1101 if test x$glib_cv_hasinline = xyes; then
1102     glib_inline='#define G_HAVE_INLINE 1'
1103 fi
1104 if test x$glib_cv_has__inline = xyes; then
1105     glib_inline="\$glib_inline
1106 #define G_HAVE___INLINE 1"
1107 fi
1108 if test x$glib_cv_has__inline__ = xyes; then
1109     glib_inline="\$glib_inline
1110 #define G_HAVE___INLINE__ 1"
1111 fi
1112
1113 case xyes in
1114 x$ac_cv_c_bigendian)
1115   g_byte_order=G_BIG_ENDIAN
1116   g_bs_native=BE
1117   g_bs_alien=LE
1118   ;;
1119 *)
1120   g_byte_order=G_LITTLE_ENDIAN
1121   g_bs_native=LE
1122   g_bs_alien=BE
1123   ;;
1124 esac
1125
1126 if test x$glib_wchar_h = xyes; then
1127   glib_wc='
1128 #define G_HAVE_WCHAR_H 1'
1129 fi
1130 if test x$glib_wctype_h = xyes; then
1131   glib_wc="\$glib_wc
1132 #define G_HAVE_WCTYPE_H 1"
1133 fi
1134 if test x$glib_working_wctype = xno; then
1135   glib_wc="\$glib_wc
1136 #define G_HAVE_BROKEN_WCTYPE 1"
1137 fi
1138
1139 if test x$glib_have_alloca = xyes; then
1140   glib_alloca="
1141
1142 /* alloca support */"
1143
1144   if test x$glib_have_alloca_h = xyes; then
1145     glib_alloca="\$glib_alloca
1146 #define G_HAVE_ALLOCA_H 1"
1147   fi
1148
1149   glib_alloca="\$glib_alloca
1150 #define G_HAVE_ALLOCA 1
1151
1152 /* BEGIN autoconf 2.13 alloca incantation
1153          NOTE: Do not un-indent the #pragma below. */
1154 /* AIX requires this to be the first thing in the file.  */
1155 #ifdef __GNUC__
1156 # ifndef alloca
1157 #  define alloca __builtin_alloca
1158 # endif
1159 #else
1160 # if G_HAVE_ALLOCA_H
1161 #  include <alloca.h>
1162 # else
1163 #  ifdef _AIX
1164  #pragma alloca
1165 #  else
1166 #   ifndef alloca /* predefined by HP cc +Olibcalls */
1167 char *alloca ();
1168 #   endif
1169 #  endif
1170 # endif
1171 #endif
1172 /* END autoconf 2.13 alloca incantation */
1173
1174
1175 "
1176 fi
1177
1178 case x$enable_threads in
1179 xyes)   g_enable_threads_def="#define";;
1180 *)      g_enable_threads_def="#undef ";;
1181 esac
1182
1183 g_threads_impl_def=$g_threads_impl
1184
1185 g_mutex_has_default="$mutex_has_default"
1186 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
1187 g_mutex_contents="$glib_cv_byte_contents_gmutex"
1188 ])
1189
1190 AC_OUTPUT([
1191 Makefile
1192 glib-config
1193 gmodule/gmoduleconf.h
1194 gmodule/Makefile
1195 gthread/Makefile
1196 docs/Makefile
1197 tests/Makefile
1198 ],[case "$CONFIG_FILES" in
1199 *glib-config*)chmod +x glib-config;;
1200 esac])