configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5
   6 # Process this file with autoconf to produce a configure script.
   7 AC_INIT(glist.c)
   8
   9 # Save this value here, since automake will set cflags later
  10 cflags_set=${CFLAGS+set}
  11
  12 # we rewrite this file
  13 rm -f glibconfig-sysdefs.h
  14
  15 # The following version number definitions apply to GLib and GModule
  16 # as a whole, so if changes occoured in either of them, they are both
  17 # treated with the same interface and binary age.
  18 #
  19 # Making releases:
  20 #   GLIB_MICRO_VERSION += 1;
  21 #   GLIB_INTERFACE_AGE += 1;
  22 #   GLIB_BINARY_AGE += 1;
  23 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  24 # if backwards compatibility has been broken,
  25 # set GLIB_BINARY_AGE and GLIB_INTERFACE_AGE to 0.
  26 #
  27 GLIB_MAJOR_VERSION=1
  28 GLIB_MINOR_VERSION=1
  29 GLIB_MICRO_VERSION=13
  30 GLIB_INTERFACE_AGE=0
  31 GLIB_BINARY_AGE=0
  32 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  33 AC_SUBST(GLIB_VERSION)
  34
  35 # libtool versioning
  36 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  37 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  38 LT_REVISION=$GLIB_INTERFACE_AGE
  39 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  40 AC_SUBST(LT_RELEASE)
  41 AC_SUBST(LT_CURRENT)
  42 AC_SUBST(LT_REVISION)
  43 AC_SUBST(LT_AGE)
  44
  45 VERSION=$GLIB_VERSION
  46 PACKAGE=glib
  47
  48 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  49
  50 # Specify a configuration file
  51 AM_CONFIG_HEADER(config.h)
  52
  53 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION)
  54 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION)
  55 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION)
  56 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE)
  57 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE)
  58
  59 dnl Initialize libtool
  60 AM_PROG_LIBTOOL
  61
  62 dnl Initialize maintainer mode
  63 AM_MAINTAINER_MODE
  64
  65 AC_CANONICAL_HOST
  66
  67 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=minimum]],,enable_debug=minimum)
  68 AC_ARG_ENABLE(mem_check, [  --enable-mem-check      turn on malloc/free sanity checking [default=no]],,enable_mem_check=no)
  69 AC_ARG_ENABLE(mem_profile, [  --enable-mem-profile    turn on malloc profiling atexit [default=no]],,enable_mem_profile=no)
  70 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
  71                     , enable_ansi=no)
  72 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
  73                           ([=no] will override --with-threads)],,enable_threads=yes)
  74
  75 if test "x$enable_threads" != "xyes"; then
  76   enable_threads=no
  77 fi
  78
  79 AC_MSG_CHECKING(whether to enable memory checking)
  80 if test "x$enable_mem_check" = "xyes"; then
  81   AC_DEFINE(ENABLE_MEM_CHECK, 1)
  82   AC_SUBST(ENABLE_MEM_CHECK)
  83   AC_MSG_RESULT(yes)
  84 else
  85   AC_MSG_RESULT(no)
  86 fi
  87
  88 AC_MSG_CHECKING(whether to enable memory profiling)
  89 if test "x$enable_mem_profile" = "xyes"; then
  90   AC_DEFINE(ENABLE_MEM_PROFILE, 1)
  91   AC_SUBST(ENABLE_MEM_PROFILE)
  92   AC_MSG_RESULT(yes)
  93 else
  94   AC_MSG_RESULT(no)
  95 fi
  96
  97 if test "x$enable_debug" = "xyes"; then
  98   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
  99   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 100 else
 101   if test "x$enable_debug" = "xno"; then
 102     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 103   fi
 104 fi
 105
 106 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 107
 108 # Checks for programs.
 109 AC_PROG_CC
 110 AM_PROG_CC_STDC
 111 AC_PROG_INSTALL
 112
 113 changequote(,)dnl
 114 if test "x$GCC" = "xyes"; then
 115   case " $CFLAGS " in
 116   *[\ \ ]-Wall[\ \      ]*) ;;
 117   *) CFLAGS="$CFLAGS -Wall" ;;
 118   esac
 119
 120   if test "x$enable_ansi" = "xyes"; then
 121     case " $CFLAGS " in
 122     *[\ \       ]-ansi[\ \      ]*) ;;
 123     *) CFLAGS="$CFLAGS -ansi" ;;
 124     esac
 125
 126     case " $CFLAGS " in
 127     *[\ \       ]-pedantic[\ \  ]*) ;;
 128     *) CFLAGS="$CFLAGS -pedantic" ;;
 129     esac
 130   fi
 131 fi
 132 changequote([,])dnl
 133
 134 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 135 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 136 glib_save_LIBS=$LIBS
 137 LIBS="$LIBS -lm"
 138 AC_TRY_RUN([#include <math.h>
 139              int main (void) { return (log(1) != log(1.)); }],
 140      AC_MSG_RESULT(none needed),
 141      glib_save_CFLAGS=$CFLAGS
 142      CFLAGS="$CFLAGS -std1"
 143      AC_TRY_RUN([#include <math.h>
 144                  int main (void) { return (log(1) != log(1.)); }],
 145          AC_MSG_RESULT(-std1),
 146          AC_MSG_RESULT()
 147          CFLAGS=$glib_save_CFLAGS
 148          AC_MSG_WARN(
 149                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 150      )
 151 )
 152 LIBS=$glib_save_LIBS
 153
 154 dnl NeXTStep cc seems to need this
 155 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 156 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 157   AC_MSG_RESULT(none needed),
 158   glib_save_CFLAGS=$CFLAGS
 159   CFLAGS="$CFLAGS -posix"
 160   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 161     AC_MSG_RESULT(-posix),
 162     AC_MSG_RESULT()
 163     CFLAGS=$glib_save_CFLAGS
 164     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 165
 166 # Checks for header files.
 167 AC_HEADER_STDC
 168
 169 # Checks for library functions.
 170 AC_FUNC_VPRINTF
 171
 172 AC_CHECK_FUNCS(atexit on_exit)
 173
 174 AC_CHECK_SIZEOF(char)
 175 AC_CHECK_SIZEOF(short)
 176 AC_CHECK_SIZEOF(long)
 177 AC_CHECK_SIZEOF(int)
 178 AC_CHECK_SIZEOF(void *)
 179 AC_CHECK_SIZEOF(long long)
 180
 181 dnl long doubles were not used, and a portability problem
 182 dnl AC_C_LONG_DOUBLE
 183 AC_C_CONST
 184
 185 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 186 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 187 dnl actually supported.
 188 AC_MSG_CHECKING(for __inline)
 189 AC_CACHE_VAL(glib_cv_has__inline,[
 190         AC_TRY_RUN([
 191         __inline int foo () { return 0; }
 192         int main () { return foo (); }
 193         ],
 194         glib_cv_has__inline=yes
 195         ,
 196         glib_cv_has__inline=no
 197         ,)
 198 ])
 199 AC_MSG_RESULT($glib_cv_has__inline)
 200 case x$glib_cv_has__inline in
 201 xyes) AC_DEFINE(G_HAVE___INLINE)
 202 esac
 203 AC_MSG_CHECKING(for __inline__)
 204 AC_CACHE_VAL(glib_cv_has__inline__,[
 205         AC_TRY_RUN([
 206         __inline__ int foo () { return 0; }
 207         int main () { return foo (); }
 208         ],
 209         glib_cv_has__inline__=yes
 210         ,
 211         glib_cv_has__inline__=no
 212         ,)
 213 ])
 214 AC_MSG_RESULT($glib_cv_has__inline__)
 215 case x$glib_cv_has__inline__ in
 216 xyes) AC_DEFINE(G_HAVE___INLINE__)
 217 esac
 218 AC_MSG_CHECKING(for inline)
 219 AC_CACHE_VAL(glib_cv_hasinline,[
 220         AC_TRY_RUN([
 221         inline int foo () { return 0; }
 222         int main () { return foo (); }
 223         ],
 224         glib_cv_hasinline=yes
 225         ,
 226         glib_cv_hasinline=no
 227         ,)
 228 ])
 229 AC_MSG_RESULT($glib_cv_hasinline)
 230 case x$glib_cv_hasinline in
 231 xyes) AC_DEFINE(G_HAVE_INLINE)
 232 esac
 233
 234 dnl for bytesex stuff
 235 AC_C_BIGENDIAN
 236
 237 dnl header file checks
 238 AC_CHECK_HEADERS(float.h, AC_DEFINE(HAVE_FLOAT_H))
 239 AC_CHECK_HEADERS(limits.h, AC_DEFINE(HAVE_LIMITS_H))
 240 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 241 AC_CHECK_HEADERS(sys/param.h, AC_DEFINE(HAVE_SYS_PARAM_H))
 242 AC_CHECK_HEADERS(sys/poll.h, AC_DEFINE(HAVE_SYS_POLL_H))
 243 AC_CHECK_HEADERS(sys/select.h, AC_DEFINE(HAVE_SYS_SELECT_H))
 244 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 245 AC_CHECK_HEADERS(sys/times.h, AC_DEFINE(HAVE_SYS_TIMES_H))
 246 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 247 AC_CHECK_HEADERS(values.h, AC_DEFINE(HAVE_VALUES_H))
 248
 249 # Check for some functions
 250 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf strcasecmp strncasecmp poll)
 251
 252 # Check for sys_errlist
 253 AC_MSG_CHECKING(for sys_errlist)
 254 AC_TRY_LINK(, [
 255 extern char *sys_errlist[];
 256 extern int sys_nerr;
 257 sys_errlist[sys_nerr-1][0] = 0;
 258 ], glib_ok=yes, glib_ok=no)
 259 AC_MSG_RESULT($glib_ok)
 260 if test $glib_ok = no; then
 261     AC_DEFINE(NO_SYS_ERRLIST)
 262 fi
 263
 264 # Check for sys_siglist
 265 AC_MSG_CHECKING(for sys_siglist)
 266 AC_TRY_LINK(, [
 267 extern char *sys_siglist[];
 268 strlen (sys_siglist[0]);
 269 ], glib_ok=yes, glib_ok=no)
 270 AC_MSG_RESULT($glib_ok)
 271 if test $glib_ok = no; then
 272     AC_DEFINE(NO_SYS_SIGLIST)
 273 fi
 274
 275 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 276 AC_MSG_CHECKING(for sys_siglist declaration)
 277 AC_TRY_COMPILE([#include <signal.h>], [
 278 strlen (sys_siglist[0]);
 279 ], glib_ok=yes, glib_ok=no)
 280 AC_MSG_RESULT($glib_ok)
 281 if test $glib_ok = yes; then
 282     AC_DEFINE(NO_SYS_SIGLIST_DECL)
 283 fi
 284
 285 # Check if <sys/select.h> needs to be included for fd_set
 286 AC_MSG_CHECKING([for fd_set])
 287 AC_TRY_COMPILE([#include <sys/types.h>],
 288         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 289 if test $gtk_ok = yes; then
 290     AC_MSG_RESULT([yes, found in sys/types.h])
 291 else
 292     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 293     if test $gtk_ok = yes; then
 294         AC_DEFINE(HAVE_SYS_SELECT_H)
 295         AC_MSG_RESULT([yes, found in sys/select.h])
 296     else
 297         AC_DEFINE(NO_FD_SET)
 298         AC_MSG_RESULT(no)
 299     fi
 300 fi
 301
 302 # These are used only in GDK (gdki18n.h)
 303 # This stuff is here only so that we can define these
 304 # things in glibconfig.h. If gtk+ started using an installed
 305 # gdkconfig.h file, then the definitions would belong there.
 306
 307 # Check for wchar.h
 308
 309 AC_MSG_CHECKING(for wchar.h)
 310 AC_TRY_CPP([#include <wchar.h>], glib_wchar_h=yes, glib_wchar_h=no)
 311 if test $glib_wchar_h = yes; then
 312    AC_DEFINE(HAVE_WCHAR_H)
 313 fi
 314 AC_MSG_RESULT($glib_wchar_h)
 315
 316 # Check for wctype.h (for iswalnum)
 317
 318 AC_MSG_CHECKING(for wctype.h)
 319 AC_TRY_CPP([#include <wctype.h>], glib_wctype_h=yes, glib_wctype_h=no)
 320 if test $glib_wctype_h = yes; then
 321    AC_DEFINE(HAVE_WCTYPE_H)
 322 fi
 323 AC_MSG_RESULT($glib_wctype_h)
 324
 325 oLIBS="$LIBS"
 326 # in Solaris 2.5, `iswalnum' is in -lw
 327 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum)])
 328
 329 # The following is necessary for Linux libc-5.4.38
 330 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 331 AC_TRY_LINK([#include <stdlib.h>],[
 332 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 333 #  ifdef HAVE_WCTYPE_H
 334 #    include <wctype.h>
 335 #  else
 336 #    ifdef HAVE_WCHAR_H
 337 #      include <wchar.h>
 338 #    endif
 339 #  endif
 340 #else
 341 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 342 #endif
 343 iswalnum((wchar_t) 0);
 344 ], glib_working_wctype=yes, glib_working_wctype=no)
 345 LIBS="$oLIBS"
 346
 347 if test $glib_working_wctype = no; then
 348    AC_DEFINE(HAVE_BROKEN_WCTYPE)
 349 fi
 350 AC_MSG_RESULT($glib_working_wctype)
 351
 352
 353 dnl **********************
 354 dnl *** va_copy checks ***
 355 dnl **********************
 356 dnl we currently check for all three va_copy possibilities, so we get
 357 dnl all results in config.log for bug reports.
 358 AC_MSG_CHECKING(for an implementation of va_copy())
 359 AC_CACHE_VAL(glib_cv_va_copy,[
 360         AC_TRY_RUN([
 361         #include <stdarg.h>
 362         void f (int i, ...) {
 363         va_list args1, args2;
 364         va_start (args1, i);
 365         va_copy (args2, args1);
 366         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 367           exit (1);
 368         va_end (args1); va_end (args2);
 369         }
 370         int main() {
 371           f (0, 42);
 372           return 0;
 373         }],
 374         glib_cv_va_copy=yes
 375         ,
 376         glib_cv_va_copy=no
 377         ,)
 378 ])
 379 AC_MSG_RESULT($glib_cv_va_copy)
 380 AC_MSG_CHECKING(for an implementation of __va_copy())
 381 AC_CACHE_VAL(glib_cv___va_copy,[
 382         AC_TRY_RUN([
 383         #include <stdarg.h>
 384         void f (int i, ...) {
 385         va_list args1, args2;
 386         va_start (args1, i);
 387         __va_copy (args2, args1);
 388         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 389           exit (1);
 390         va_end (args1); va_end (args2);
 391         }
 392         int main() {
 393           f (0, 42);
 394           return 0;
 395         }],
 396         glib_cv___va_copy=yes
 397         ,
 398         glib_cv___va_copy=no
 399         ,)
 400 ])
 401 AC_MSG_RESULT($glib_cv___va_copy)
 402 AC_MSG_CHECKING(whether va_lists can be copied by value)
 403 AC_CACHE_VAL(glib_cv_va_val_copy,[
 404         AC_TRY_RUN([
 405         #include <stdarg.h>
 406         void f (int i, ...) {
 407         va_list args1, args2;
 408         va_start (args1, i);
 409         args2 = args1;
 410         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 411           exit (1);
 412         va_end (args1); va_end (args2);
 413         }
 414         int main() {
 415           f (0, 42);
 416           return 0;
 417         }],
 418         glib_cv_va_val_copy=yes
 419         ,
 420         glib_cv_va_val_copy=no
 421         ,)
 422 ])
 423 if test "x$glib_cv_va_copy" = "xyes"; then
 424   AC_DEFINE(G_VA_COPY, va_copy)
 425 else if test "x$glib_cv___va_copy" = "xyes"; then
 426   AC_DEFINE(G_VA_COPY, __va_copy)
 427 fi
 428 fi
 429 if test "x$glib_cv_va_val_copy" = "xno"; then
 430   AC_DEFINE(G_VA_COPY_AS_ARRAY)
 431 fi
 432 AC_MSG_RESULT($glib_cv_va_val_copy)
 433
 434
 435 dnl ***********************
 436 dnl *** g_module checks ***
 437 dnl ***********************
 438 G_MODULE_LIBS=
 439 G_MODULE_LDFLAGS=
 440 G_MODULE_IMPL=
 441 G_MODULE_NEED_USCORE=0
 442 G_MODULE_HAVE_DLERROR=0
 443 dnl *** dlopen() in system libraries
 444 if test -z "$G_MODULE_IMPL"; then
 445         AC_CHECK_FUNC(dlopen,
 446                 G_MODULE_IMPL=G_MODULE_IMPL_DL
 447         ,)
 448 fi
 449 dnl *** dlopen() in libdl
 450 if test -z "$G_MODULE_IMPL"; then
 451         AC_CHECK_LIB(dl, dlopen,
 452                 G_MODULE_LIBS=-ldl
 453                 G_MODULE_IMPL=G_MODULE_IMPL_DL
 454         ,)
 455 fi
 456 dnl *** shl_load() in libdld (HP-UX)
 457 if test -z "$G_MODULE_IMPL"; then
 458         AC_MSG_CHECKING(how to export all symbols)
 459         SAVED_LDFLAGS=$LDFLAGS
 460         LDFLAGS="$LDFLAGS -Wl,-E"
 461         AC_TRY_LINK(,[ return 0; ],
 462                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 463                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 464                 AC_TRY_LINK(,[ return 0; ],
 465                         G_MODULE_LDFLAGS="-bexpall",
 466                         G_MODULE_LDFLAGS="none"
 467                 )
 468         ])
 469         LDFLAGS=$SAVED_LDFLAGS
 470         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 471         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 472                 G_MODULE_LDFLAGS=
 473         fi
 474         AC_CHECK_LIB(dld, shl_load,
 475                 G_MODULE_LIBS=-ldld
 476                 G_MODULE_IMPL=G_MODULE_IMPL_DLD
 477         ,)
 478 fi
 479 dnl *** additional checks for G_MODULE_IMPL_DL
 480 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 481         case "$host_os" in
 482           linux*)
 483             G_MODULE_LDFLAGS='-rdynamic'
 484             ;;
 485         esac
 486         LIBS_orig="$LIBS"
 487         LDFLAGS_orig="$LDFLAGS"
 488         LIBS="$LIBS $G_MODULE_LIBS"
 489         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 490 dnl *** check whether we need preceeding underscores
 491         AC_MSG_CHECKING(for preceeding underscore in symbols)
 492         AC_CACHE_VAL(glib_cv_uscore,[
 493                 AC_TRY_RUN([
 494                 #include <dlfcn.h>
 495                 int glib_underscore_test (void) { return 42; }
 496                 int main() {
 497                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 498                   handle = dlopen ((void*)0, 0);
 499                   if (handle) {
 500                     f1 = dlsym (handle, "glib_underscore_test");
 501                     f2 = dlsym (handle, "_glib_underscore_test");
 502                   } return (!f2 || f1);
 503                 }],
 504                         glib_cv_uscore=yes,
 505                         glib_cv_uscore=no,
 506                 )
 507                 rm -f plugin.c plugin.o plugin.lo
 508         ])
 509         AC_MSG_RESULT($glib_cv_uscore)
 510         if test "x$glib_cv_uscore" = "xyes"; then
 511                 G_MODULE_NEED_USCORE=1
 512         else
 513                 G_MODULE_NEED_USCORE=0
 514         fi
 515
 516         LDFLAGS="$LDFLAGS_orig"
 517 dnl *** check for having dlerror()
 518         AC_CHECK_FUNC(dlerror,
 519                 G_MODULE_HAVE_DLERROR=1,
 520                 G_MODULE_HAVE_DLERROR=0)
 521         LIBS="$LIBS_orig"
 522 fi
 523 dnl *** done, have e got an implementation?
 524 if test -z "$G_MODULE_IMPL"; then
 525         G_MODULE_IMPL=0
 526 fi
 527 AC_SUBST(G_MODULE_IMPL)
 528 AC_SUBST(G_MODULE_LIBS)
 529 AC_SUBST(G_MODULE_LDFLAGS)
 530 AC_SUBST(G_MODULE_HAVE_DLERROR)
 531 AC_SUBST(G_MODULE_NEED_USCORE)
 532 AC_SUBST(GLIB_DEBUG_FLAGS)
 533
 534
 535 dnl ***********************
 536 dnl *** g_thread checks ***
 537 dnl ***********************
 538
 539 AC_ARG_WITH(threads, [  --with-threads=[none/posix/solaris/nspr] specify a thread implementation to use],
 540         if test "x$with_threads" = x; then
 541                 want_threads=yes
 542         else
 543                 want_threads=$with_threads
 544         fi,
 545         want_threads=yes)
 546 if test "x$enable_threads" = "xno"; then
 547         want_threads=no
 548 fi
 549 if test "x$want_threads" = "xnone"; then
 550         want_threads=no
 551 fi
 552
 553 dnl error and warning message
 554 dnl *************************
 555
 556 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
 557                 computer. glib will not be thread safe on your computer."
 558
 559 FLAG_DOES_NOT_WORK="I can't find the MACRO, that enables thread safety on your
 560                 platform (normaly it's "_REENTRANT"). I'll not use any flag on
 561                 compilation now, but then your programs might not work.
 562                 Please provide information on how it is done on your system."
 563
 564 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
 565                 "
 566
 567 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
 568                 provide informationon your thread implementation."
 569
 570 dnl determination of thread implementation
 571 dnl ***************************************
 572
 573 have_threads=none
 574 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
 575         case $host in
 576                 *-*-solaris*)
 577                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
 578                 ;;
 579         esac
 580 fi
 581 if test "x$want_threads" = xyes || test "x$want_threads" = xposix; then
 582         if test "x$have_threads" = xnone; then
 583                 AC_CHECK_LIB(pthread, pthread_attr_init, have_threads=posix)
 584         fi
 585         if test "x$have_threads" = xnone; then
 586                 AC_CHECK_LIB(pthreads, pthread_attr_init, have_threads=posix)
 587         fi
 588         if test "x$have_threads" = xnone; then
 589                 AC_CHECK_LIB(c_r, pthread_attr_init, have_threads=posix)
 590         fi
 591         if test "x$have_threads" = xnone; then
 592                 AC_CHECK_FUNC(pthread_attr_init, have_threads=posix)
 593         fi
 594         dnl ********** DG/UX ************
 595         if test "x$have_threads" = xnone; then
 596                 AC_CHECK_LIB(thread, __d10_pthread_attr_init,
 597                         have_threads=posix)
 598         fi
 599 fi
 600 if test "x$want_threads" = xyes || test "x$want_threads" = xnspr; then
 601         if test "x$have_threads" = xnone; then
 602                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar, have_threads=nspr)
 603         fi
 604 fi
 605
 606 AC_MSG_CHECKING(for thread implementation)
 607
 608 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
 609         AC_MSG_RESULT(none available)
 610         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
 611 else
 612         AC_MSG_RESULT($have_threads)
 613 fi
 614
 615
 616 dnl determination of G_THREAD_LIBS
 617 dnl ******************************
 618
 619 G_THREAD_LIBS=
 620 G_THREAD_CFLAGS=
 621
 622 mutex_has_default=no
 623 case $have_threads in
 624         posix)
 625                 G_THREAD_LIBS=error
 626                 AC_CHECK_LIB(pthread, pthread_attr_init,
 627                              G_THREAD_LIBS="-lpthread")
 628                 if test "x$G_THREAD_LIBS" = xerror; then
 629                         AC_CHECK_LIB(pthreads, pthread_attr_init,
 630                                 G_THREAD_LIBS="-lpthreads")
 631                 fi
 632                 if test "x$G_THREAD_LIBS" = xerror; then
 633                         AC_CHECK_LIB(c_r, pthread_attr_init,
 634                                 G_THREAD_LIBS="-lc_r")
 635                 fi
 636                 if test "x$G_THREAD_LIBS" = xerror; then
 637                         AC_CHECK_FUNC(pthread_attr_init, G_THREAD_LIBS="")
 638                 fi
 639                 dnl ********** DG/UX ************
 640                 if test "x$G_THREAD_LIBS" = xerror; then
 641                         AC_CHECK_LIB(thread, __d10_pthread_attr_init,
 642                                 G_THREAD_LIBS="-lthread"
 643                                 G_THREAD_CFLAGS="-D_POSIX4A_DRAFT10_SOURCE")
 644                 fi
 645                 mutex_has_default=yes
 646                 mutex_default_type='pthread_mutex_t'
 647                 mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
 648                 mutex_header_file='pthread.h'
 649                 g_threads_impl="POSIX"
 650                 ;;
 651         solaris)
 652                 G_THREAD_LIBS=error
 653                 AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
 654                 mutex_has_default=yes
 655                 mutex_default_type='mutex_t'
 656                 mutex_default_init="DEFAULTMUTEX"
 657                 mutex_header_file='thread.h'
 658                 g_threads_impl="SOLARIS"
 659                 ;;
 660         nspr)
 661                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar,
 662                              G_THREAD_LIBS="-lnspr21")
 663                 g_threads_impl="NSPR"
 664                 ;;
 665         none)
 666                 g_threads_impl="NONE"
 667                 ;;
 668         *)
 669                 g_threads_impl="NONE"
 670                 G_THREAD_LIBS=error
 671                 ;;
 672 esac
 673
 674 if test "x$G_THREAD_LIBS" = xerror; then
 675         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 676 fi
 677
 678 AC_MSG_CHECKING(necessary linker options)
 679 AC_MSG_RESULT($G_THREAD_LIBS)
 680
 681 dnl check for mt safe function variants
 682 dnl ***********************************
 683
 684 if test x"$have_threads" != xnone; then
 685         glib_save_LIBS="$LIBS"
 686         LIBS="$LIBS $G_THREAD_LIBS"
 687         AC_CHECK_FUNCS(localtime_r rand_r)
 688         LIBS="$glib_save_LIBS"
 689 fi
 690
 691 dnl determination of G_THREAD_CFLAGS
 692 dnl ********************************
 693
 694 if test x"$have_threads" != xnone; then
 695 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_REENTRANT" # good default guess
 696
 697     case $host in
 698         *-aix*)
 699                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 700                 if test x"$GCC" = xyes; then
 701                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
 702                 fi
 703                 ;;
 704         *-freebsd2.2*)
 705                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 706
 707                 # FreeBSD 2.2.x shiped with gcc 2.7.2.x, which doesn't support
 708                 # -mthreads flag.
 709                 ;;
 710     esac
 711
 712     # if we are not finding the ctime_r function, then we probably are
 713     # not using the proper multithread flag
 714     old_CPPFLAGS=$CPPFLAGS
 715     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
 716     AC_EGREP_HEADER([[^a-zA-Z_]ctime_r[^a-zA-Z_]], time.h, ,
 717     G_THREAD_CFLAGS=
 718     AC_MSG_WARN($FLAG_DOES_NOT_WORK))
 719     CPPFLAGS=$old_CPPFLAGS
 720
 721     AC_MSG_CHECKING(necessary compiler options)
 722
 723     AC_MSG_RESULT($G_THREAD_CFLAGS)
 724 else
 725     G_THREAD_CFLAGS=
 726 fi
 727
 728 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c")
 729 AC_SUBST(G_THREAD_CFLAGS)
 730 AC_SUBST(G_THREAD_LIBS)
 731
 732 CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 733
 734 dnl **********************************************
 735 dnl *** GDefaultMutex setup and initialization ***
 736 dnl **********************************************
 737 dnl
 738 dnl if mutex_has_default = yes, we also got
 739 dnl mutex_default_type, mutex_default_init and mutex_header_file
 740 GLIB_IF_VAR_EQ(mutex_has_default, yes,
 741         GLIB_SIZEOF([#include <$mutex_header_file>],
 742                     $mutex_default_type,
 743                     gmutex,
 744                     )
 745         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
 746                            $mutex_default_type,
 747                            gmutex,
 748                            $glib_cv_sizeof_gmutex,
 749                            $mutex_default_init)
 750         ,
 751 )
 752
 753
 754 dnl ****************************************
 755 dnl *** GLib POLL* compatibility defines ***
 756 dnl ****************************************
 757 GLIB_SYSDEFS(
 758 [#include <sys/types.h>
 759 #include <sys/poll.h>],
 760         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
 761         glibconfig-sysdefs.h,
 762         =)
 763
 764
 765 dnl ******************************
 766 dnl *** output the whole stuff ***
 767 dnl ******************************
 768
 769 AC_OUTPUT_COMMANDS([
 770
 771 ## Generate `glibconfig.h' in two cases
 772 ## 1. `config.status' is run either explicitly, or via configure.
 773 ##     Esp. not when it is run in `Makefile' to generate makefiles and
 774 ##     config.h
 775 ## 2. CONFIG_OTHER is set explicitly
 776 ##
 777 ## Case 1 is difficult.  We know that `automake' sets one of
 778 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
 779 ## only when AM_CONFIG_HEADER is set, however.
 780
 781 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
 782   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
 783   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
 784 fi
 785 case "$CONFIG_OTHER" in
 786 *glibconfig.h*)
 787         echo creating glibconfig.h
 788         outfile=glibconfig.h-tmp
 789         cat > $outfile <<\_______EOF
 790 /* glibconfig.h
 791  *
 792  * This is a generated file.  Please modify `configure.in'
 793  */
 794
 795 #ifndef GLIBCONFIG_H
 796 #define GLIBCONFIG_H
 797
 798 #ifdef __cplusplus
 799 extern "C" {
 800 #endif /* __cplusplus */
 801
 802 _______EOF
 803
 804         if test x$glib_limits_h = xyes; then
 805           echo '#include <limits.h>' >> $outfile
 806         fi
 807         if test x$glib_float_h = xyes; then
 808           echo '#include <float.h>' >> $outfile
 809         fi
 810         if test x$glib_values_h = xyes; then
 811           echo '#include <values.h>' >> $outfile
 812         fi
 813         if test x$g_mutex_header_file != x; then
 814           echo '#include <'"$g_mutex_header_file"'>' >> $outfile
 815         fi
 816         if test x$glib_sys_poll_h = xyes; then
 817           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
 818         fi
 819
 820         cat >> $outfile <<_______EOF
 821
 822 #define G_MINFLOAT      $glib_mf
 823 #define G_MAXFLOAT      $glib_Mf
 824 #define G_MINDOUBLE     $glib_md
 825 #define G_MAXDOUBLE     $glib_Md
 826 #define G_MINSHORT      $glib_ms
 827 #define G_MAXSHORT      $glib_Ms
 828 #define G_MININT        $glib_mi
 829 #define G_MAXINT        $glib_Mi
 830 #define G_MINLONG       $glib_ml
 831 #define G_MAXLONG       $glib_Ml
 832
 833 _______EOF
 834
 835
 836         ### this should always be true in a modern C/C++ compiler
 837         cat >>$outfile <<_______EOF
 838 typedef signed char gint8;
 839 typedef unsigned char guint8;
 840 _______EOF
 841
 842
 843         if test -n "$gint16"; then
 844           cat >>$outfile <<_______EOF
 845 typedef signed $gint16 gint16;
 846 typedef unsigned $gint16 guint16;
 847 _______EOF
 848         fi
 849
 850
 851         if test -n "$gint32"; then
 852           cat >>$outfile <<_______EOF
 853 typedef signed $gint32 gint32;
 854 typedef unsigned $gint32 guint32;
 855 _______EOF
 856         fi
 857
 858
 859         if test -n "$gint64"; then
 860           cat >>$outfile <<_______EOF
 861 ${glib_warning_guard}#define G_HAVE_GINT64 1
 862
 863 ${glib_extension}typedef signed $gint64 gint64;
 864 ${glib_extension}typedef unsigned $gint64 guint64;
 865
 866 #define G_GINT64_CONSTANT(val)  $gint64_constant
 867 _______EOF
 868         fi
 869
 870
 871         if test -z "$glib_unknown_void_p"; then
 872           cat >>$outfile <<_______EOF
 873
 874 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
 875 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
 876
 877 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
 878 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
 879 _______EOF
 880         else
 881           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
 882         fi
 883
 884
 885
 886         cat >>$outfile <<_______EOF
 887 $glib_atexit
 888 $glib_memmove
 889 $glib_defines
 890
 891 $glib_vacopy
 892
 893 #ifdef  __cplusplus
 894 #define G_HAVE_INLINE   1
 895 #else   /* !__cplusplus */
 896 $glib_inline
 897 #endif  /* !__cplusplus */
 898 _______EOF
 899
 900         echo >>$outfile
 901         if test x$g_mutex_has_default = xyes; then
 902                 cat >>$outfile <<_______EOF
 903 $g_enable_threads_def G_THREADS_ENABLED
 904 #define G_THREADS_IMPL_$g_threads_impl_def
 905 typedef struct _GStaticMutex GStaticMutex;
 906 struct _GStaticMutex
 907 {
 908   struct _GMutex *runtime_mutex;
 909   union {
 910     char   pad[$g_mutex_sizeof];
 911     double dummy_double;
 912     void  *dummy_pointer;
 913     long   dummy_long;
 914   } aligned_pad_u;
 915 };
 916 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
 917 #define g_static_mutex_get_mutex(mutex) \
 918   (g_thread_use_default_impl ? ((GMutex*) &(mutex).aligned_pad_u) : \
 919    g_static_mutex_get_mutex_impl (&(mutex).runtime_mutex))
 920 _______EOF
 921         else
 922                 cat >>$outfile <<_______EOF
 923 $g_enable_threads_def G_THREADS_ENABLED
 924 #define $g_threads_impl_def
 925 typedef struct _GMutex* GStaticMutex;
 926 #define G_STATIC_MUTEX_INIT NULL
 927 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (&(mutex)))
 928 _______EOF
 929         fi
 930
 931         echo >>$outfile
 932         g_bit_sizes="16 32"
 933         if test -n "$gint64"; then
 934           g_bit_sizes="$g_bit_sizes 64"
 935         fi
 936         for bits in $g_bit_sizes; do
 937           cat >>$outfile <<_______EOF
 938 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
 939 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
 940 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
 941 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
 942 _______EOF
 943         done
 944
 945         cat >>$outfile <<_______EOF
 946 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
 947 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
 948 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
 949 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
 950 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
 951 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
 952 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
 953 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
 954 #define G_BYTE_ORDER $g_byte_order
 955
 956 _______EOF
 957
 958         if test -r glibconfig-sysdefs.h; then
 959           cat glibconfig-sysdefs.h >>$outfile
 960         fi
 961
 962
 963         cat >>$outfile <<_______EOF
 964
 965 $glib_wc
 966
 967
 968 #ifdef __cplusplus
 969 }
 970 #endif /* __cplusplus */
 971
 972 #endif /* GLIBCONFIG_H */
 973 _______EOF
 974
 975
 976         if cmp -s $outfile glibconfig.h; then
 977           echo glibconfig.h is unchanged
 978           rm -f $outfile
 979         else
 980           mv $outfile glibconfig.h
 981         fi ;;
 982 esac
 983 ],[
 984
 985 # Note that if two cases are the same, case goes with the first one.
 986 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
 987 # on variable expansion in case labels.  Look at the generated config.status
 988 # for a hint.
 989
 990 case xyes in
 991 x$ac_cv_header_float_h)
 992   glib_float_h=yes
 993   glib_mf=FLT_MIN glib_Mf=FLT_MAX
 994   glib_md=DBL_MIN glib_Md=DBL_MAX
 995   ;;
 996 x$ac_cv_header_values_h)
 997   glib_values_h=yes
 998   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
 999   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
1000   ;;
1001 esac
1002
1003 case xyes in
1004 x$ac_cv_header_limits_h)
1005   glib_limits_h=yes
1006   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX
1007   glib_mi=INT_MIN  glib_Mi=INT_MAX
1008   glib_ml=LONG_MIN glib_Ml=LONG_MAX
1009   ;;
1010 x$ac_cv_header_values_h)
1011   glib_values_h=yes
1012   glib_ms=MINSHORT glib_Ms=MAXSHORT
1013   glib_mi=MININT   glib_Mi=MAXINT
1014   glib_ml=MINLONG  glib_Ml=MAXLONG
1015   ;;
1016 esac
1017
1018 if test x$ac_cv_header_sys_poll_h = xyes ; then
1019   glib_sys_poll_h=yes
1020 fi
1021
1022 case 2 in
1023 $ac_cv_sizeof_short)            gint16=short;;
1024 $ac_cv_sizeof_int)              gint16=int;;
1025 esac
1026 case 4 in
1027 $ac_cv_sizeof_short)            gint32=short;;
1028 $ac_cv_sizeof_int)              gint32=int;;
1029 $ac_cv_sizeof_long)             gint32=long;;
1030 esac
1031 case 8 in
1032 $ac_cv_sizeof_int)
1033   gint64=int
1034   glib_extension=
1035   glib_warning_guard=
1036   gint64_constant='(val)'
1037   ;;
1038 $ac_cv_sizeof_long)
1039   gint64=long
1040   glib_extension=
1041   glib_warning_guard=
1042   gint64_constant='(val##L)'
1043   ;;
1044 $ac_cv_sizeof_long_long)
1045   gint64='long long'
1046   glib_extension='G_GNUC_EXTENSION '
1047   glib_warning_guard="
1048 #if defined (__GNUC__) && __GNUC__ >= 2 && __GNUC_MINOR__ >= 8
1049 #  define G_GNUC_EXTENSION __extension__
1050 #else
1051 #  define G_GNUC_EXTENSION
1052 #endif
1053
1054 "
1055   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1056   ;;
1057 esac
1058
1059 gintbits=`expr $ac_cv_sizeof_int \* 8`
1060 glongbits=`expr $ac_cv_sizeof_long \* 8`
1061
1062
1063 case $ac_cv_sizeof_void_p in
1064 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
1065 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
1066 *)                      glib_unknown_void_p=yes ;;
1067 esac
1068
1069
1070 case xyes in
1071 x$ac_cv_func_atexit)
1072   glib_atexit="
1073 #ifdef NeXT /* @#%@! NeXTStep */
1074 # define g_ATEXIT(proc) (!atexit (proc))
1075 #else
1076 # define g_ATEXIT(proc) (atexit (proc))
1077 #endif"
1078   ;;
1079 x$ac_cv_func_on_exit)
1080   glib_atexit="
1081 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
1082   ;;
1083 esac
1084
1085 case xyes in
1086 x$ac_cv_func_memmove)
1087   glib_memmove='
1088 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
1089   ;;
1090 *)
1091   glib_memmove="
1092 /* We make the assumption that if memmove isn't available, then
1093  * bcopy will do the job. This isn't safe everywhere. (bcopy can't
1094  * necessarily handle overlapping copies) */
1095 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
1096   ;;
1097 esac
1098
1099 glib_defines="
1100 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
1101 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
1102 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
1103 "
1104
1105 case xyes in
1106 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
1107 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
1108 *)                      glib_vacopy=''
1109 esac
1110
1111 if test x$glib_cv_va_val_copy = xno; then
1112   glib_vacopy="\$glib_vacopy
1113 #define G_VA_COPY_AS_ARRAY 1"
1114 fi
1115
1116 if test x$glib_cv_hasinline = xyes; then
1117     glib_inline='#define G_HAVE_INLINE 1'
1118 fi
1119 if test x$glib_cv_has__inline = xyes; then
1120     glib_inline="\$glib_inline
1121 #define G_HAVE___INLINE 1"
1122 fi
1123 if test x$glib_cv_has__inline__ = xyes; then
1124     glib_inline="\$glib_inline
1125 #define G_HAVE___INLINE__ 1"
1126 fi
1127
1128 case xyes in
1129 x$ac_cv_c_bigendian)
1130   g_byte_order=G_BIG_ENDIAN
1131   g_bs_native=BE
1132   g_bs_alien=LE
1133   ;;
1134 *)
1135   g_byte_order=G_LITTLE_ENDIAN
1136   g_bs_native=LE
1137   g_bs_alien=BE
1138   ;;
1139 esac
1140
1141 if test x$glib_wchar_h = xyes; then
1142   glib_wc='
1143 #define G_HAVE_WCHAR_H 1'
1144 fi
1145 if test x$glib_wctype_h = xyes; then
1146   glib_wc="\$glib_wc
1147 #define G_HAVE_WCTYPE_H 1"
1148 fi
1149 if test x$glib_working_wctype = xno; then
1150   glib_wc="\$glib_wc
1151 #define G_HAVE_BROKEN_WCTYPE 1"
1152 fi
1153
1154 case x$enable_threads in
1155 xyes)   g_enable_threads_def="#define";;
1156 *)      g_enable_threads_def="#undef ";;
1157 esac
1158
1159 g_threads_impl_def=$g_threads_impl
1160
1161 g_mutex_has_default="$mutex_has_default"
1162 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
1163 g_mutex_contents="$glib_cv_byte_contents_gmutex"
1164 ])
1165
1166 AC_OUTPUT([
1167 Makefile
1168 glib-config
1169 gmodule/gmoduleconf.h
1170 gmodule/Makefile
1171 gthread/Makefile
1172 docs/Makefile
1173 tests/Makefile
1174 ],[case "$CONFIG_FILES" in
1175 *glib-config*)chmod +x glib-config;;
1176 esac])