configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5
   6 # require autoconf 2.13
   7 AC_PREREQ(2.13)
   8
   9 # Process this file with autoconf to produce a configure script.
  10 AC_INIT(glist.c)
  11
  12 # Save this value here, since automake will set cflags later
  13 cflags_set=${CFLAGS+set}
  14
  15 # we rewrite this file
  16 rm -f glibconfig-sysdefs.h
  17
  18 GLIB_AC_DIVERT_BEFORE_HELP([
  19 #
  20 # The following version number definitions apply to GLib, GModule, GObject
  21 # and GThread as a whole, so if changes occoured in any of them, they are all
  22 # treated with the same interface and binary age.
  23 #
  24 # Making releases:
  25 #   GLIB_MICRO_VERSION += 1;
  26 #   GLIB_INTERFACE_AGE += 1;
  27 #   GLIB_BINARY_AGE += 1;
  28 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  29 # if backwards compatibility has been broken,
  30 # set GLIB_BINARY_AGE _and_ GLIB_INTERFACE_AGE to 0.
  31 #
  32 GLIB_MAJOR_VERSION=1
  33 GLIB_MINOR_VERSION=3
  34 GLIB_MICRO_VERSION=2
  35 GLIB_INTERFACE_AGE=0
  36 GLIB_BINARY_AGE=0
  37 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  38 ])dnl
  39
  40 AC_SUBST(GLIB_MAJOR_VERSION)
  41 AC_SUBST(GLIB_MINOR_VERSION)
  42 AC_SUBST(GLIB_MICRO_VERSION)
  43 AC_SUBST(GLIB_VERSION)
  44 AC_SUBST(GLIB_INTERFACE_AGE)
  45 AC_SUBST(GLIB_BINARY_AGE)
  46
  47 # libtool versioning
  48 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  49 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  50 LT_REVISION=$GLIB_INTERFACE_AGE
  51 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  52 AC_SUBST(LT_RELEASE)
  53 AC_SUBST(LT_CURRENT)
  54 AC_SUBST(LT_REVISION)
  55 AC_SUBST(LT_AGE)
  56
  57 VERSION=$GLIB_VERSION
  58 PACKAGE=glib
  59
  60 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  61
  62 # Specify a configuration file
  63 AM_CONFIG_HEADER(config.h)
  64
  65 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION,
  66                    [Define to the GLIB major version])
  67 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION,
  68                    [Define to the GLIB minor version])
  69 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION,
  70                    [Define to the GLIB micro version])
  71 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE,
  72                    [Define to the GLIB interface age])
  73 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE,
  74                    [Define to the GLIB binary age])
  75
  76 dnl Initialize maintainer mode
  77 AM_MAINTAINER_MODE
  78
  79 AC_CANONICAL_HOST
  80
  81 AC_MSG_CHECKING(for the BeOS)
  82 case $host in
  83   *-*-beos*)
  84     glib_native_beos="yes"
  85     ;;
  86   *)
  87     glib_native_beos="no"
  88     ;;
  89 esac
  90 AC_MSG_RESULT([$glib_native_beos])
  91
  92 dnl
  93
  94 GLIB_AC_DIVERT_BEFORE_HELP([
  95 # figure debugging default, prior to $ac_help setup
  96 case $GLIB_MINOR_VERSION in
  97 *[[13579]]) debug_default=yes ;;
  98 *)          debug_default=minimum ;;
  99 esac[]dnl
 100 ])
 101
 102 dnl declare --enable-* args and collect ac_help strings
 103 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
 104 AC_ARG_ENABLE(msg-prefix, [  --enable-msg-prefix     turn on program name and PID prefixing of messages and warnings],,enable_msg_prefix=no)
 105 AC_ARG_ENABLE(mem_check, [  --enable-mem-check      turn on malloc/free sanity checking [default=no]],,enable_mem_check=no)
 106 AC_ARG_ENABLE(mem_profile, [  --enable-mem-profile    turn on malloc profiling atexit [default=no]],,enable_mem_profile=no)
 107 AC_ARG_ENABLE(gc_friendly, [  --enable-gc-friendly    turn on garbage collector friendliness [default=no]],,enable_gc_friendly=no)
 108 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
 109                     , enable_ansi=no)
 110 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
 111                           ([=no] will override --with-threads)],,enable_threads=yes)
 112
 113 if test "x$enable_threads" != "xyes"; then
 114   enable_threads=no
 115 fi
 116
 117 AC_MSG_CHECKING(whether to enable memory checking)
 118 if test "x$enable_mem_check" = "xyes"; then
 119   AC_DEFINE(ENABLE_MEM_CHECK, 1, [Whether to enable memory checking])
 120   AC_SUBST(ENABLE_MEM_CHECK)
 121   AC_MSG_RESULT(yes)
 122 else
 123   AC_MSG_RESULT(no)
 124 fi
 125
 126 AC_MSG_CHECKING(whether to enable memory profiling)
 127 if test "x$enable_mem_profile" = "xyes"; then
 128   AC_DEFINE(ENABLE_MEM_PROFILE, 1, [Whether to enable memory profiling])
 129   AC_SUBST(ENABLE_MEM_PROFILE)
 130   AC_MSG_RESULT(yes)
 131 else
 132   AC_MSG_RESULT(no)
 133 fi
 134
 135 AC_MSG_CHECKING(whether to enable garbage collector friendliness)
 136 if test "x$enable_gc_friendly" = "xyes"; then
 137   AC_DEFINE(ENABLE_GC_FRIENDLY, 1, [Whether to enable GC friendliness])
 138   AC_SUBST(ENABLE_GC_FRIENDLY)
 139   AC_MSG_RESULT(yes)
 140 else
 141   AC_MSG_RESULT(no)
 142 fi
 143
 144 if test "x$enable_debug" = "xyes"; then
 145   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 146   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 147 else
 148   if test "x$enable_debug" = "xno"; then
 149     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 150   fi
 151 fi
 152
 153 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 154         [Whether glib was compiled with debugging enabled])
 155
 156 if test "x$enable_msg_prefix" = "xyes"; then
 157   AC_DEFINE_UNQUOTED(G_ENABLE_MSG_PREFIX, 1,
 158                      [Enable prefixing of error messages with program names])
 159 fi
 160
 161 # Checks for programs.
 162 AC_PROG_CC
 163 AM_PROG_CC_STDC
 164 AC_PROG_INSTALL
 165
 166 dnl Initialize libtool
 167 AM_PROG_LIBTOOL
 168
 169 if test "x$GCC" = "xyes"; then
 170   case " $CFLAGS " in
 171   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 172   *) CFLAGS="$CFLAGS -Wall" ;;
 173   esac
 174
 175   if test "x$enable_ansi" = "xyes"; then
 176     case " $CFLAGS " in
 177     *[[\ \      ]]-ansi[[\ \    ]]*) ;;
 178     *) CFLAGS="$CFLAGS -ansi" ;;
 179     esac
 180
 181     case " $CFLAGS " in
 182     *[[\ \      ]]-pedantic[[\ \        ]]*) ;;
 183     *) CFLAGS="$CFLAGS -pedantic" ;;
 184     esac
 185   fi
 186 fi
 187
 188 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 189 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 190 glib_save_LIBS=$LIBS
 191 LIBS="$LIBS -lm"
 192 AC_TRY_RUN([#include <math.h>
 193              int main (void) { return (log(1) != log(1.)); }],
 194      AC_MSG_RESULT(none needed),
 195      glib_save_CFLAGS=$CFLAGS
 196      CFLAGS="$CFLAGS -std1"
 197      AC_TRY_RUN([#include <math.h>
 198                  int main (void) { return (log(1) != log(1.)); }],
 199          AC_MSG_RESULT(-std1),
 200          AC_MSG_RESULT()
 201          CFLAGS=$glib_save_CFLAGS
 202          AC_MSG_WARN(
 203                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 204      )
 205 )
 206 LIBS=$glib_save_LIBS
 207
 208 dnl NeXTStep cc seems to need this
 209 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 210 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 211   AC_MSG_RESULT(none needed),
 212   glib_save_CFLAGS=$CFLAGS
 213   CFLAGS="$CFLAGS -posix"
 214   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 215     AC_MSG_RESULT(-posix),
 216     AC_MSG_RESULT()
 217     CFLAGS=$glib_save_CFLAGS
 218     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 219
 220 # Checks for header files.
 221 AC_HEADER_STDC
 222
 223 # Checks for library functions.
 224 AC_FUNC_VPRINTF
 225
 226 AC_FUNC_ALLOCA
 227
 228 AC_CHECK_FUNCS(atexit on_exit)
 229
 230 AC_CHECK_SIZEOF(char)
 231 AC_CHECK_SIZEOF(short)
 232 AC_CHECK_SIZEOF(long)
 233 AC_CHECK_SIZEOF(int)
 234 AC_CHECK_SIZEOF(void *)
 235 AC_CHECK_SIZEOF(long long)
 236
 237 if test x$ac_cv_sizeof_long_long = x8; then
 238         # long long is a 64 bit integer.
 239         AC_MSG_CHECKING(for format to printf and scanf a gint64)
 240         AC_CACHE_VAL(glib_cv_long_long_format,[
 241                 for format in ll q; do
 242                   AC_TRY_RUN([#include <stdio.h>
 243                         int main()
 244                         {
 245                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 246                           char buffer[1000];
 247                           sprintf (buffer, "%${format}u", a);
 248                           sscanf (buffer, "%${format}u", &b);
 249                           exit (b!=a);
 250                         }
 251                         ],
 252                         glib_cv_long_long_format=${format}
 253                         break)
 254                 done])
 255         if test -n "$glib_cv_long_long_format"; then
 256           AC_MSG_RESULT(%${glib_cv_long_long_format}i)
 257         else
 258           AC_MSG_RESULT(none)
 259         fi
 260 fi
 261
 262 dnl long doubles were not used, and a portability problem
 263 dnl AC_C_LONG_DOUBLE
 264 AC_C_CONST
 265
 266 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 267 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 268 dnl actually supported.
 269 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 270         AC_TRY_RUN([
 271         __inline int foo () { return 0; }
 272         int main () { return foo (); }
 273         ],
 274         glib_cv_has__inline=yes
 275         ,
 276         glib_cv_has__inline=no
 277         ,)
 278 ])
 279 case x$glib_cv_has__inline in
 280 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 281 esac
 282 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 283         AC_TRY_RUN([
 284         __inline__ int foo () { return 0; }
 285         int main () { return foo (); }
 286         ],
 287         glib_cv_has__inline__=yes
 288         ,
 289         glib_cv_has__inline__=no
 290         ,)
 291 ])
 292 case x$glib_cv_has__inline__ in
 293 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 294 esac
 295 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 296         AC_TRY_RUN([
 297         inline int foo () { return 0; }
 298         int main () { return foo (); }
 299         ],
 300         glib_cv_hasinline=yes
 301         ,
 302         glib_cv_hasinline=no
 303         ,)
 304 ])
 305 case x$glib_cv_hasinline in
 306 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 307 esac
 308
 309 # check for bytesex stuff
 310 AC_C_BIGENDIAN
 311
 312 # check for header files
 313 AC_CHECK_HEADERS([float.h limits.h pwd.h sys/param.h sys/poll.h sys/select.h])
 314 AC_CHECK_HEADERS([sys/time.h sys/times.h unistd.h values.h stdint.h sched.h])
 315
 316 AC_MSG_CHECKING(whether make is GNU Make)
 317 STRIP_BEGIN=
 318 STRIP_END=
 319 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 320         STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
 321         STRIP_END=')'
 322         AC_MSG_RESULT(yes)
 323 else
 324         AC_MSG_RESULT(no)
 325 fi
 326 STRIP_DUMMY=
 327 AC_SUBST(STRIP_DUMMY)
 328 AC_SUBST(STRIP_BEGIN)
 329 AC_SUBST(STRIP_END)
 330
 331 # check additional type sizes
 332 size_includes=["
 333 #include <stdarg.h>
 334 #include <stdio.h>
 335 #include <ctype.h>
 336 #include <string.h>
 337 "]
 338 if test "x$ac_cv_header_stdint_h" = "xyes"; then
 339   size_includes=["$size_includes
 340 #include <stdint.h>
 341 "]
 342 fi
 343 if test "x$ac_cv_header_unistd_h" = "xyes"; then
 344   size_includes=["$size_includes
 345 #include <unistd.h>
 346 "]
 347 fi
 348 GLIB_SIZEOF([$size_includes], size_t, size_t)
 349 GLIB_SIZEOF([$size_includes], ptrdiff_t, ptrdiff_t)
 350 GLIB_SIZEOF([$size_includes], intmax_t, intmax_t)
 351
 352 # Check for some functions
 353 AC_CHECK_FUNCS(lstat strerror strsignal memmove mkstemp vsnprintf strcasecmp strncasecmp poll getcwd)
 354
 355 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 356 # The check is borrowed from the PERL Configure script.
 357 if test "$ac_cv_func_memmove" != "yes"; then
 358   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 359     glib_cv_working_bcopy,[AC_TRY_RUN([
 360       int main() {
 361         char buf[128], abc[128], *b;
 362         int len, off, align;
 363         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 364         for (align = 7; align >= 0; align--) {
 365           for (len = 36; len; len--) {
 366             b = buf+align; bcopy(abc, b, len);
 367             for (off = 1; off <= len; off++) {
 368               bcopy(b, b+off, len); bcopy(b+off, b, len);
 369                 if (bcmp(b, abc, len)) return(1);
 370             }
 371           }
 372         }
 373         return(0);
 374       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 375   if test "$glib_cv_working_bcopy" = "yes"; then
 376     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 377   fi
 378 fi
 379
 380 # Check for sys_errlist
 381 AC_MSG_CHECKING(for sys_errlist)
 382 AC_TRY_LINK(, [
 383 extern char *sys_errlist[];
 384 extern int sys_nerr;
 385 sys_errlist[sys_nerr-1][0] = 0;
 386 ], glib_ok=yes, glib_ok=no)
 387 AC_MSG_RESULT($glib_ok)
 388 if test $glib_ok = no; then
 389     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 390 fi
 391
 392 # Check for sys_siglist
 393 AC_MSG_CHECKING(for sys_siglist)
 394 AC_TRY_LINK(, [
 395 extern char *sys_siglist[];
 396 exit (sys_siglist[0]);
 397 ], glib_ok=yes, glib_ok=no)
 398 AC_MSG_RESULT($glib_ok)
 399 if test $glib_ok = no; then
 400     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 401 fi
 402
 403 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 404 AC_MSG_CHECKING(for sys_siglist declaration)
 405 AC_TRY_COMPILE([#include <signal.h>], [
 406 strlen (sys_siglist[0]);
 407 ], glib_ok=yes, glib_ok=no)
 408 AC_MSG_RESULT($glib_ok)
 409 if test $glib_ok = no; then
 410     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 411 fi
 412
 413 # Check if <sys/select.h> needs to be included for fd_set
 414 AC_MSG_CHECKING([for fd_set])
 415 AC_TRY_COMPILE([#include <sys/types.h>],
 416         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 417 if test $gtk_ok = yes; then
 418     AC_MSG_RESULT([yes, found in sys/types.h])
 419 else
 420     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
 421     if test $gtk_ok = yes; then
 422         # *** FIXME: give it a different name
 423         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
 424         AC_MSG_RESULT([yes, found in sys/select.h])
 425     else
 426         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
 427         AC_MSG_RESULT(no)
 428     fi
 429 fi
 430
 431 dnl *** check for sane realloc() ***
 432 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
 433         AC_TRY_RUN([
 434         #include <stdlib.h>
 435         int main() {
 436           return realloc (0, sizeof (int)) == 0;
 437         }],
 438         [glib_cv_sane_realloc=yes],
 439         [glib_cv_sane_realloc=no],
 440         [])
 441 ])
 442 if test x$glib_cv_sane_realloc = xyes; then
 443   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
 444 fi
 445
 446 dnl Check for nl_langinfo and CODESET
 447
 448 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
 449 AC_TRY_COMPILE([#include <langinfo.h>],
 450         [char *codeset = nl_langinfo (CODESET);],
 451    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
 452    have_codeset=yes,
 453    have_codeset=no)
 454 AC_MSG_RESULT($have_codeset)
 455
 456
 457 dnl ****************************************
 458 dnl *** strlcpy/strlcat                  ***
 459 dnl ****************************************
 460 # Check for strlcpy
 461 AC_MSG_CHECKING(for strlcpy/strlcat)
 462 AC_TRY_LINK([#include <stdlib.h>
 463 #include <string.h>], [
 464 char *p = malloc(10);
 465 (void) strlcpy(p, "hi", 10);
 466 (void) strlcat(p, "bye", 10);
 467 ], glib_ok=yes, glib_ok=no)
 468 AC_MSG_RESULT($glib_ok)
 469 if test $glib_ok = yes; then
 470     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
 471 fi
 472
 473
 474 dnl **********************
 475 dnl *** va_copy checks ***
 476 dnl **********************
 477 dnl we currently check for all three va_copy possibilities, so we get
 478 dnl all results in config.log for bug reports.
 479 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
 480         AC_TRY_RUN([
 481         #include <stdarg.h>
 482         void f (int i, ...) {
 483         va_list args1, args2;
 484         va_start (args1, i);
 485         va_copy (args2, args1);
 486         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 487           exit (1);
 488         va_end (args1); va_end (args2);
 489         }
 490         int main() {
 491           f (0, 42);
 492           return 0;
 493         }],
 494         [glib_cv_va_copy=yes],
 495         [glib_cv_va_copy=no],
 496         [])
 497 ])
 498 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
 499         AC_TRY_RUN([
 500         #include <stdarg.h>
 501         void f (int i, ...) {
 502         va_list args1, args2;
 503         va_start (args1, i);
 504         __va_copy (args2, args1);
 505         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 506           exit (1);
 507         va_end (args1); va_end (args2);
 508         }
 509         int main() {
 510           f (0, 42);
 511           return 0;
 512         }],
 513         [glib_cv___va_copy=yes],
 514         [glib_cv___va_copy=no],
 515         [])
 516 ])
 517
 518 if test "x$glib_cv_va_copy" = "xyes"; then
 519   g_va_copy_func=va_copy
 520 else if test "x$glib_cv___va_copy" = "xyes"; then
 521   g_va_copy_func=__va_copy
 522 fi
 523 fi
 524
 525 if test -n "$g_va_copy_func"; then
 526   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
 527 fi
 528
 529 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
 530         AC_TRY_RUN([
 531         #include <stdarg.h>
 532         void f (int i, ...) {
 533         va_list args1, args2;
 534         va_start (args1, i);
 535         args2 = args1;
 536         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 537           exit (1);
 538         va_end (args1); va_end (args2);
 539         }
 540         int main() {
 541           f (0, 42);
 542           return 0;
 543         }],
 544         [glib_cv_va_val_copy=yes],
 545         [glib_cv_va_val_copy=no],
 546         [])
 547 ])
 548
 549 if test "x$glib_cv_va_val_copy" = "xno"; then
 550   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 551 fi
 552
 553 dnl ***********************
 554 dnl *** g_module checks ***
 555 dnl ***********************
 556 G_MODULE_LIBS=
 557 G_MODULE_LIBS_EXTRA=
 558 G_MODULE_PLUGIN_LIBS=
 559 G_MODULE_LDFLAGS=
 560 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
 561 G_MODULE_NEED_USCORE=0
 562 G_MODULE_HAVE_DLERROR=0
 563 dnl *** dlopen() and dlsym() in system libraries
 564 if test -z "$G_MODULE_IMPL"; then
 565         AC_CHECK_FUNC(dlopen,
 566                       [AC_CHECK_FUNC(dlsym,
 567                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 568                       [])
 569 fi
 570 dnl *** load_image (BeOS)
 571 if test -z "$G_MODULE_IMPL" -a "x$glib_native_beos" = "xyes"; then
 572   AC_CHECK_LIB(root, load_image,
 573       [G_MODULE_LIBS="-lbe -lroot -lglib"
 574       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
 575       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
 576       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
 577       [])
 578 fi
 579 # *** dlopen() and dlsym() in libdl
 580 if test -z "$G_MODULE_IMPL"; then
 581         AC_CHECK_LIB(dl, dlopen,
 582                      [AC_CHECK_LIB(dl, dlsym,
 583                                    [G_MODULE_LIBS=-ldl
 584                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 585                      [])
 586 fi
 587 dnl *** shl_load() in libdld (HP-UX)
 588 if test -z "$G_MODULE_IMPL"; then
 589         AC_MSG_CHECKING(how to export all symbols)
 590         SAVED_LDFLAGS=$LDFLAGS
 591         LDFLAGS="$LDFLAGS -Wl,-E"
 592         AC_TRY_LINK(,[ return 0; ],
 593                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 594                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 595                 AC_TRY_LINK(,[ return 0; ],
 596                         [G_MODULE_LDFLAGS="-bexpall"],
 597                         [G_MODULE_LDFLAGS="none"])
 598         ])
 599         LDFLAGS=$SAVED_LDFLAGS
 600         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 601         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 602                 G_MODULE_LDFLAGS=
 603         fi
 604         AC_CHECK_LIB(dld, shl_load,
 605                 [G_MODULE_LIBS=-ldld
 606                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
 607                 [])
 608 fi
 609 dnl *** additional checks for G_MODULE_IMPL_DL
 610 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 611         case "$host_os" in
 612           linux*)
 613             G_MODULE_LDFLAGS='-rdynamic'
 614             ;;
 615         esac
 616         LIBS_orig="$LIBS"
 617         LDFLAGS_orig="$LDFLAGS"
 618         LIBS="$LIBS $G_MODULE_LIBS"
 619         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 620 dnl *** check whether we need preceeding underscores
 621         AC_CACHE_CHECK([for preceeding underscore in symbols],
 622                 glib_cv_uscore,[
 623                 AC_TRY_RUN([
 624                 #include <dlfcn.h>
 625                 int glib_underscore_test (void) { return 42; }
 626                 int main() {
 627                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 628                   handle = dlopen ((void*)0, 0);
 629                   if (handle) {
 630                     f1 = dlsym (handle, "glib_underscore_test");
 631                     f2 = dlsym (handle, "_glib_underscore_test");
 632                   } return (!f2 || f1);
 633                 }],
 634                         [glib_cv_uscore=yes],
 635                         [glib_cv_uscore=no],
 636                         [])
 637                 rm -f plugin.c plugin.o plugin.lo
 638         ])
 639         if test "x$glib_cv_uscore" = "xyes"; then
 640                 G_MODULE_NEED_USCORE=1
 641         else
 642                 G_MODULE_NEED_USCORE=0
 643         fi
 644
 645         LDFLAGS="$LDFLAGS_orig"
 646 dnl *** check for having dlerror()
 647         AC_CHECK_FUNC(dlerror,
 648                 [G_MODULE_HAVE_DLERROR=1],
 649                 [G_MODULE_HAVE_DLERROR=0])
 650         LIBS="$LIBS_orig"
 651 fi
 652 dnl *** done, have e got an implementation?
 653 if test -z "$G_MODULE_IMPL"; then
 654         G_MODULE_IMPL=0
 655 fi
 656 AC_SUBST(G_MODULE_IMPL)
 657 AC_SUBST(G_MODULE_LIBS)
 658 AC_SUBST(G_MODULE_LIBS_EXTRA)
 659 AC_SUBST(G_MODULE_PLUGIN_LIBS)
 660 AC_SUBST(G_MODULE_LDFLAGS)
 661 AC_SUBST(G_MODULE_HAVE_DLERROR)
 662 AC_SUBST(G_MODULE_NEED_USCORE)
 663 AC_SUBST(GLIB_DEBUG_FLAGS)
 664
 665
 666 dnl ***********************
 667 dnl *** g_thread checks ***
 668 dnl ***********************
 669
 670 AC_ARG_WITH(threads, [  --with-threads=[none/posix/dce/solaris] specify a thread implementation to use],
 671         if test "x$with_threads" = x; then
 672                 want_threads=yes
 673         else
 674                 want_threads=$with_threads
 675         fi,
 676         want_threads=yes)
 677 if test "x$enable_threads" = "xno"; then
 678         want_threads=no
 679 fi
 680 if test "x$want_threads" = "xnone"; then
 681         want_threads=no
 682 fi
 683
 684 dnl error and warning message
 685 dnl *************************
 686
 687 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
 688                 computer. GLib will not have a default thread implementation."
 689
 690 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
 691                 platform (normaly it's "_REENTRANT"). I'll not use any flag on
 692                 compilation now, but then your programs might not work.
 693                 Please provide information on how it is done on your system."
 694
 695 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
 696                 "
 697
 698 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
 699                 provide information on your thread implementation.
 700                 You can also run 'configure --disable-threads'
 701                 to compile without thread support."
 702
 703 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
 704                 functions will not be MT-safe during their first call because
 705                 there is no working 'getpwuid_r' on your system."
 706
 707 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
 708                 because there is no 'localtime_r' on your system."
 709
 710 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
 711                 crude surrogate will be used. If you happen to know a
 712                 yield function for your system, please inform the GLib
 713                 developers."
 714
 715 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
 716                 threads on your system. Thus threads can only have the default
 717                 priority. If you happen to know these main/max
 718                 priorities, please inform the GLib developers."
 719
 720
 721 dnl determination of thread implementation
 722 dnl ***************************************
 723
 724 have_threads=none
 725 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
 726         case $host in
 727                 *-*-solaris*)
 728                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
 729                 ;;
 730         esac
 731 fi
 732 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
 733                                 || test "x$want_threads" = xdce; then
 734         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
 735         # -U_OSF_SOURCE is for Digital UNIX 4.0d
 736         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
 737         glib_save_CPPFLAGS="$CPPFLAGS"
 738         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
 739         if test "x$have_threads" = xnone; then
 740                 AC_TRY_COMPILE([#include <pthread.h>],
 741                         [pthread_attr_t attr; pthread_attr_init(&attr);],
 742                         have_threads=posix)
 743         fi
 744         if test "x$have_threads" = xnone; then
 745                 AC_TRY_COMPILE([#include <pthread.h>],
 746                         [pthread_attr_t attr; pthread_attr_create(&attr);],
 747                         have_threads=posix)
 748         fi
 749         CPPFLAGS="$glib_save_CPPFLAGS"
 750 fi
 751
 752 AC_MSG_CHECKING(for thread implementation)
 753
 754 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
 755         AC_MSG_RESULT(none available)
 756         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
 757 else
 758         AC_MSG_RESULT($have_threads)
 759 fi
 760
 761
 762 dnl determination of G_THREAD_CFLAGS
 763 dnl ********************************
 764
 765 G_THREAD_LIBS=
 766 G_THREAD_LIBS_EXTRA=
 767 G_THREAD_CFLAGS=
 768
 769 if test x"$have_threads" != xnone; then
 770
 771     G_THREAD_CFLAGS="-D_REENTRANT" # good default guess
 772
 773     case $host in
 774         *-aix*)
 775                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 776                 if test x"$GCC" = xyes; then
 777                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
 778                 fi
 779                 ;;
 780         *-freebsd2.2*)
 781                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 782
 783                 # FreeBSD 2.2.x shiped with gcc 2.7.2.x, which doesn't support
 784                 # -mthreads flag.
 785                 ;;
 786         *-sysv5uw7*)  # UnixWare 7
 787                 if test "$GCC" != "yes"; then
 788                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -Kthread"
 789                 else
 790                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -pthread"
 791                 fi
 792                 ;;
 793         *-dg-dgux*)  # DG/UX
 794                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
 795     esac
 796
 797     # if we are not finding the ctime_r function, then we probably are
 798     # not using the proper multithread flag
 799
 800     glib_save_CPPFLAGS="$CPPFLAGS"
 801     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
 802
 803     AC_TRY_COMPILE([#include <time.h>],
 804         [time_t t; char b[30]; ctime_r (&t, b);], ,
 805             [AC_TRY_COMPILE([#include <time.h>],
 806                 [time_t t; char b[30]; ctime_r (&t, b, 30);], ,
 807                         AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
 808
 809     CPPFLAGS="$glib_save_CPPFLAGS"
 810
 811     AC_MSG_CHECKING(thread related cflags)
 812     AC_MSG_RESULT($G_THREAD_CFLAGS)
 813     CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 814 fi
 815
 816 dnl determination of G_THREAD_LIBS
 817 dnl ******************************
 818
 819 mutex_has_default=no
 820 case $have_threads in
 821         posix|dce)
 822            glib_save_CPPFLAGS="$CPPFLAGS"
 823            CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
 824            G_THREAD_LIBS=error
 825            glib_save_LIBS="$LIBS"
 826            case $host in
 827              *-sysv5uw7*) # UnixWare 7
 828                 if test "$GCC" != "yes"; then
 829                         G_THREAD_LIBS="-Kthread"
 830                 else
 831                         G_THREAD_LIBS="-pthread"
 832                 fi
 833                 ;;
 834              *)
 835                 for thread_lib in "" pthread pthreads c_r thread dce; do
 836                         if test x"$thread_lib" = x; then
 837                                 add_thread_lib=""
 838                                 IN=""
 839                         else
 840                                 add_thread_lib="-l$thread_lib"
 841                                 IN=" in -l$thread_lib"
 842                         fi
 843                         if test x"$have_threads" = xposix; then
 844                                 defattr=0
 845                         else
 846                                 defattr=pthread_attr_default
 847                         fi
 848
 849                         LIBS="$glib_save_LIBS $add_thread_lib"
 850
 851                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
 852                         AC_TRY_RUN([#include <pthread.h>
 853                                 int check_me = 0;
 854                                 void* func(void* data) {check_me = 42;}
 855                                 main()
 856                                 { pthread_t t;
 857                                   void *ret;
 858                                   pthread_create (&t, $defattr, func, 0);
 859                                   pthread_join (t, &ret);
 860                                   exit (check_me != 42);
 861                                 }],
 862                                 [AC_MSG_RESULT(yes)
 863                                 G_THREAD_LIBS="$add_thread_lib"
 864                                 break],
 865                                 [AC_MSG_RESULT(no)])
 866                 done
 867                 if test "x$G_THREAD_LIBS" = xerror; then
 868                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 869                 fi
 870                 for thread_lib in "" rt rte; do
 871                         if test x"$thread_lib" = x; then
 872                                 add_thread_lib=""
 873                                 IN=""
 874                         else
 875                                 add_thread_lib="-l$thread_lib"
 876                                 IN=" in -l$thread_lib"
 877                         fi
 878                         LIBS="$glib_save_LIBS $add_thread_lib"
 879
 880                         AC_MSG_CHECKING(for sched_get_priority_min$IN)
 881                         AC_TRY_RUN([#include <sched.h>
 882                                 #include <errno.h>
 883                                 int main() {
 884                                 errno = 0;
 885                                 return sched_get_priority_min(SCHED_OTHER)==-1
 886                                         && errno != 0;
 887                                 }],
 888                                 [AC_MSG_RESULT(yes)
 889                                 G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
 890                                 posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
 891                                 posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
 892                                 break],
 893                                 [AC_MSG_RESULT(no)])
 894                 done
 895                 LIBS="$glib_save_LIBS"
 896                 ;;
 897            esac
 898            mutex_has_default=yes
 899            mutex_default_type='pthread_mutex_t'
 900            mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
 901            mutex_header_file='pthread.h'
 902            if test "x$have_threads" = "xposix"; then
 903              g_threads_impl="POSIX"
 904            else
 905              g_threads_impl="DCE"
 906              have_threads="posix"
 907            fi
 908            AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
 909            CPPFLAGS="$glib_save_CPPFLAGS"
 910            ;;
 911         solaris)
 912            G_THREAD_LIBS=error
 913            AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
 914            mutex_has_default=yes
 915            mutex_default_type='mutex_t'
 916            mutex_default_init="DEFAULTMUTEX"
 917            mutex_header_file='thread.h'
 918            g_threads_impl="SOLARIS"
 919            ;;
 920         none)
 921            g_threads_impl="NONE"
 922            ;;
 923         *)
 924            g_threads_impl="NONE"
 925            G_THREAD_LIBS=error
 926            ;;
 927 esac
 928
 929 if test "x$G_THREAD_LIBS" = xerror; then
 930         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 931 fi
 932
 933 case $host in
 934   *-*-beos*)
 935     G_THREAD_LIBS="-lbe -lroot -lglib "
 936     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
 937     ;;
 938   *)
 939     ;;
 940 esac
 941
 942 AC_MSG_CHECKING(thread related libraries)
 943 AC_MSG_RESULT($G_THREAD_LIBS)
 944
 945 dnl check for mt safe function variants and some posix functions
 946 dnl ************************************************************
 947
 948 if test x"$have_threads" != xnone; then
 949         glib_save_LIBS="$LIBS"
 950         # we are not doing the following for now, as this might require glib
 951         # to always be linked with the thread libs on some platforms.
 952         # LIBS="$LIBS $G_THREAD_LIBS"
 953         AC_CHECK_FUNCS(localtime_r)
 954         if test "$ac_cv_header_pwd_h" = "yes"; then
 955                 AC_CACHE_CHECK([for posix getpwuid_r],
 956                         ac_cv_func_posix_getpwuid_r,
 957                         [AC_TRY_RUN([#include <errno.h>
 958                                 #include <pwd.h>
 959                                 int main () { char buffer[10000];
 960                                 struct passwd pwd, *pwptr = &pwd;
 961                                 int error;
 962                                 errno = 0;
 963                                 error = getpwuid_r (0, &pwd, buffer,
 964                                         sizeof (buffer), &pwptr);
 965                                 return (error < 0 && errno == ENOSYS)
 966                                         || error == ENOSYS; }],
 967                                 [ac_cv_func_posix_getpwuid_r=yes],
 968                                 [ac_cv_func_posix_getpwuid_r=no])])
 969                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
 970                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
 971                                 [Have POSIX function getpwuid_r])
 972                 else
 973                         AC_CACHE_CHECK([for nonposix getpwuid_r],
 974                                 ac_cv_func_nonposix_getpwuid_r,
 975                                 [AC_TRY_COMPILE([#include <pwd.h>],
 976                                         [char buffer[10000];
 977                                         struct passwd pwd;
 978                                         getpwuid_r (0, &pwd, buffer,
 979                                                         sizeof (buffer));],
 980                                         [ac_cv_func_nonposix_getpwuid_r=yes],
 981                                         [ac_cv_func_nonposix_getpwuid_r=no])])
 982                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
 983                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
 984                                         [Have non-POSIX function getpwuid_r])
 985                         fi
 986                 fi
 987         fi
 988         LIBS="$LIBS $G_THREAD_LIBS"
 989         if test x"$have_threads" = xposix; then
 990                 glib_save_CPPFLAGS="$CPPFLAGS"
 991                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
 992                 GLIB_SIZEOF([#include <pthread.h>],
 993                         pthread_t,
 994                         system_thread)
 995                 # This is not AC_CHECK_FUNC to also work with function
 996                 # name mangling in header files.
 997                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
 998                 AC_TRY_LINK([#include <pthread.h>],
 999                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1000                         [AC_MSG_RESULT(yes)
1001                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1002                                   [Have function pthread_attr_setstacksize])],
1003                         [AC_MSG_RESULT(no)])
1004                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1005                 if test x"$posix_priority_min" = xnone; then
1006                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1007                                 PX_PRIO_MIN],,[
1008                                 posix_priority_min=PX_PRIO_MIN
1009                                 posix_priority_max=PX_PRIO_MAX])
1010                 fi
1011                 if test x"$posix_priority_min" = xnone; then
1012                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1013                                 PRI_OTHER_MIN],,[
1014                                 posix_priority_min=PRI_OTHER_MIN
1015                                 posix_priority_max=PRI_OTHER_MAX])
1016                 fi
1017                 if test x"$posix_priority_min" = x; then
1018                         AC_MSG_RESULT(none found)
1019                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1020                         posix_priority_min=-1
1021                         posix_priority_max=-1
1022                 else
1023                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1024                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1025                         AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])
1026                 fi
1027                 posix_yield_func=none
1028                 AC_MSG_CHECKING(for posix yield function)
1029                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1030                                                         thr_yield; do
1031                         AC_TRY_LINK([#include <pthread.h>],
1032                                 [$yield_func()],
1033                                 [posix_yield_func="$yield_func"
1034                                 break])
1035                 done
1036                 if test x"$posix_yield_func" = xnone; then
1037                         AC_MSG_RESULT(none found)
1038                         AC_MSG_WARN($POSIX_NO_YIELD)
1039                         posix_yield_func="g_usleep(1000)"
1040                 else
1041                         AC_MSG_RESULT($posix_yield_func)
1042                         posix_yield_func="$posix_yield_func()"
1043                 fi
1044                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1045                 CPPFLAGS="$glib_save_CPPFLAGS"
1046
1047                 AC_MSG_CHECKING(whether to use the PID niceness surrogate for thread priorities)
1048                 AC_TRY_RUN([#include <pthread.h>
1049                         #include <sys/types.h>
1050                         #include <unistd.h>
1051                         pid_t other_pid = 0;
1052
1053                         void* func(void* data) {other_pid = getpid();}
1054                         main()
1055                         { pthread_t t;
1056                           void *ret;
1057                           pthread_create (&t, $defattr, func, NULL);
1058                           pthread_join (t, &ret);
1059                           exit (getpid()==other_pid ||
1060                                 $posix_priority_min != $posix_priority_max);
1061                         }],
1062                         [AC_MSG_RESULT(yes),
1063                          AC_DEFINE(G_THREAD_USE_PID_SURROGATE, 1,
1064                                 [whether to use the PID niceness surrogate for thread priorities])
1065
1066                          glib_cv_sizeof_system_thread=`expr $glib_cv_sizeof_system_thread + $ac_cv_sizeof_long`],
1067                         [AC_MSG_RESULT(no)])
1068
1069         else # solaris threads
1070                 GLIB_SIZEOF([#include <thread.h>],
1071                         thread_t,
1072                         system_thread)
1073         fi
1074
1075         LIBS="$glib_save_LIBS"
1076
1077         # now spit out all the warnings.
1078         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1079            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1080                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1081         fi
1082         if test "$ac_cv_func_localtime_r" != "yes"; then
1083                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1084         fi
1085 else
1086         # If no thread implementation exists, we will provide enough
1087         # space for a pointer
1088         GLIB_SIZEOF(, void*, system_thread)
1089 fi
1090
1091 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1092                    [Source file containing theread implementation])
1093 AC_SUBST(G_THREAD_CFLAGS)
1094 AC_SUBST(G_THREAD_LIBS)
1095 AC_SUBST(G_THREAD_LIBS_EXTRA)
1096
1097 dnl **********************************************
1098 dnl *** GDefaultMutex setup and initialization ***
1099 dnl **********************************************
1100 dnl
1101 dnl if mutex_has_default = yes, we also got
1102 dnl mutex_default_type, mutex_default_init and mutex_header_file
1103 GLIB_IF_VAR_EQ(mutex_has_default, yes,
1104         glib_save_CPPFLAGS="$CPPFLAGS"
1105         glib_save_LIBS="$LIBS"
1106         LIBS="$LIBS $G_THREAD_LIBS"
1107         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1108         GLIB_SIZEOF([#include <$mutex_header_file>],
1109                     $mutex_default_type,
1110                     gmutex,
1111                     )
1112         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1113                            $mutex_default_type,
1114                            gmutex,
1115                            $glib_cv_sizeof_gmutex,
1116                            $mutex_default_init)
1117         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1118                 mutex_has_default=no
1119         fi
1120         CPPFLAGS="$glib_save_CPPFLAGS"
1121         LIBS="$glib_save_LIBS"
1122         ,
1123 )
1124
1125
1126 dnl ****************************************
1127 dnl *** GLib POLL* compatibility defines ***
1128 dnl ****************************************
1129 GLIB_SYSDEFS(
1130 [#include <sys/types.h>
1131 #include <sys/poll.h>],
1132         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
1133         glibconfig-sysdefs.h,
1134         =)
1135
1136 dnl ***********************
1137 dnl *** Tests for iconv ***
1138 dnl ***********************
1139
1140 AC_ARG_WITH(libiconv, [ --with-libiconv     Use the libiconv library ],,with_libiconv=maybe)
1141
1142 found_iconv=no
1143
1144 if test "x$with_libiconv" != "xyes" ; then
1145    #
1146    # Check in the C library
1147    #
1148    AC_CHECK_FUNC(iconv_open, with_libiconv=no; found_iconv=yes)
1149 fi
1150
1151 if test "x$with_libiconv" != "xno" ; then
1152    #
1153    # Check for libiconv
1154    #
1155    AC_CHECK_LIB(iconv, libiconv_open, with_libiconv=yes; found_iconv=yes)
1156 fi
1157
1158 if test "x$found_iconv" = "xno" ; then
1159    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
1160 fi
1161
1162 if test "x$with_libiconv" = "xyes" ; then
1163   ICONV_LIBS="-liconv"
1164   AC_DEFINE(USE_LIBICONV)
1165 fi
1166 AC_SUBST(ICONV_LIBS)
1167
1168 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
1169 dnl since we need it for g_iconv()
1170
1171 AC_MSG_CHECKING([for EILSEQ])
1172 AC_TRY_COMPILE([
1173 #include <errno.h>
1174 ],
1175 [
1176 int error = EILSEQ;
1177 ], have_eilseq=yes, have_eilseq=no);
1178 AC_MSG_RESULT($have_eilseq)
1179
1180 dnl **************************
1181 dnl *** Checks for gtk-doc ***
1182 dnl **************************
1183
1184 AC_ARG_WITH(html-dir, [  --with-html-dir=PATH path to installed docs ])
1185
1186 if test "x$with_html_dir" = "x" ; then
1187   HTML_DIR='${datadir}/gtk-doc/html'
1188 else
1189   HTML_DIR=$with_html_dir
1190 fi
1191
1192 AC_SUBST(HTML_DIR)
1193
1194
1195 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
1196 AM_CONDITIONAL(HAVE_GTK_DOC, $GTKDOC)
1197 AC_SUBST(HAVE_GTK_DOC)
1198
1199 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1200 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1201
1202 dnl Let people disable the gtk-doc stuff.
1203 AC_ARG_ENABLE(gtk-doc, [  --enable-gtk-doc  Use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)
1204
1205 if test x$enable_gtk_doc = xauto ; then
1206   if test x$GTKDOC = xtrue ; then
1207     enable_gtk_doc=yes
1208   else
1209     enable_gtk_doc=no
1210   fi
1211 fi
1212
1213 dnl NOTE: We need to use a separate automake conditional for this
1214 dnl       to make this work with the tarballs.
1215 AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
1216
1217 dnl ******************************
1218 dnl *** output the whole stuff ***
1219 dnl ******************************
1220
1221 AC_OUTPUT_COMMANDS([
1222
1223 ## Generate `glibconfig.h' in two cases
1224 ## 1. `config.status' is run either explicitly, or via configure.
1225 ##     Esp. not when it is run in `Makefile' to generate makefiles and
1226 ##     config.h
1227 ## 2. CONFIG_OTHER is set explicitly
1228 ##
1229 ## Case 1 is difficult.  We know that `automake' sets one of
1230 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
1231 ## only when AM_CONFIG_HEADER is set, however.
1232
1233 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
1234   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
1235   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
1236 fi
1237 case "$CONFIG_OTHER" in
1238 *glibconfig.h*)
1239         echo creating glibconfig.h
1240         outfile=glibconfig.h-tmp
1241         cat > $outfile <<\_______EOF
1242 /* glibconfig.h
1243  *
1244  * This is a generated file.  Please modify 'configure.in'
1245  */
1246
1247 #ifndef __G_LIBCONFIG_H__
1248 #define __G_LIBCONFIG_H__
1249
1250 #include <gmacros.h>
1251
1252 _______EOF
1253
1254         if test x$glib_limits_h = xyes; then
1255           echo '#include <limits.h>' >> $outfile
1256         fi
1257         if test x$glib_float_h = xyes; then
1258           echo '#include <float.h>' >> $outfile
1259         fi
1260         if test x$glib_values_h = xyes; then
1261           echo '#include <values.h>' >> $outfile
1262         fi
1263         if test "$glib_header_alloca_h" = "yes"; then
1264           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
1265         fi
1266         if test x$glib_sys_poll_h = xyes; then
1267           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
1268         fi
1269
1270         cat >> $outfile <<_______EOF
1271
1272 G_BEGIN_DECLS
1273
1274 #define G_MINFLOAT      $glib_mf
1275 #define G_MAXFLOAT      $glib_Mf
1276 #define G_MINDOUBLE     $glib_md
1277 #define G_MAXDOUBLE     $glib_Md
1278 #define G_MINSHORT      $glib_ms
1279 #define G_MAXSHORT      $glib_Ms
1280 #define G_MAXUSHORT     $glib_Mus
1281 #define G_MININT        $glib_mi
1282 #define G_MAXINT        $glib_Mi
1283 #define G_MAXUINT       $glib_Mui
1284 #define G_MINLONG       $glib_ml
1285 #define G_MAXLONG       $glib_Ml
1286 #define G_MAXULONG      $glib_Mul
1287
1288 _______EOF
1289
1290
1291         ### this should always be true in a modern C/C++ compiler
1292         cat >>$outfile <<_______EOF
1293 typedef signed char gint8;
1294 typedef unsigned char guint8;
1295 _______EOF
1296
1297
1298         if test -n "$gint16"; then
1299           cat >>$outfile <<_______EOF
1300 typedef signed $gint16 gint16;
1301 typedef unsigned $gint16 guint16;
1302 #define G_GINT16_FORMAT $gint16_format
1303 #define G_GUINT16_FORMAT $guint16_format
1304 _______EOF
1305         fi
1306
1307
1308         if test -n "$gint32"; then
1309           cat >>$outfile <<_______EOF
1310 typedef signed $gint32 gint32;
1311 typedef unsigned $gint32 guint32;
1312 #define G_GINT32_FORMAT $gint32_format
1313 #define G_GUINT32_FORMAT $guint32_format
1314 _______EOF
1315         fi
1316
1317
1318         if test -n "$gint64"; then
1319           cat >>$outfile <<_______EOF
1320 #define G_HAVE_GINT64 1
1321
1322 ${glib_extension}typedef signed $gint64 gint64;
1323 ${glib_extension}typedef unsigned $gint64 guint64;
1324
1325 #define G_GINT64_CONSTANT(val)  $gint64_constant
1326 _______EOF
1327                 if test -n "$gint64_format"; then
1328           cat >>$outfile <<_______EOF
1329 #define G_GINT64_FORMAT $gint64_format
1330 #define G_GUINT64_FORMAT $guint64_format
1331 _______EOF
1332                 fi
1333         fi
1334
1335         case x$glib_size_t in
1336         x2) echo "typedef gint16  gssize;" >> $outfile
1337             echo "typedef guint16 gsize;"  >> $outfile
1338             ;;
1339         x4) echo "typedef gint32  gssize;" >> $outfile
1340             echo "typedef guint32 gsize;"  >> $outfile
1341             ;;
1342         x8) echo "typedef gint64  gssize;" >> $outfile
1343             echo "typedef guint64 gsize;"  >> $outfile
1344             ;;
1345         *)  echo "#error size of size_t is unknown" >> $outfile
1346             ;;
1347         esac
1348
1349         if test -z "$glib_unknown_void_p"; then
1350           cat >>$outfile <<_______EOF
1351
1352 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
1353 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
1354
1355 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
1356 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
1357 _______EOF
1358         else
1359           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
1360         fi
1361
1362
1363
1364         cat >>$outfile <<_______EOF
1365 $glib_atexit
1366 $glib_memmove
1367 $glib_defines
1368 $glib_os
1369
1370 $glib_vacopy
1371
1372 #ifdef  __cplusplus
1373 #define G_HAVE_INLINE   1
1374 #else   /* !__cplusplus */
1375 $glib_inline
1376 #endif  /* !__cplusplus */
1377 _______EOF
1378
1379         echo >>$outfile
1380         if test x$g_have_eilseq = xno; then
1381                 cat >>$outfile <<_______EOF
1382 #ifndef EILSEQ
1383 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
1384  * The correspondence between this and the corresponding definition
1385  * in libiconv is essential.
1386  */
1387 #  define EILSEQ ENOENT
1388 #endif
1389 _______EOF
1390
1391         fi
1392
1393         echo >>$outfile
1394         if test x$g_mutex_has_default = xyes; then
1395                 cat >>$outfile <<_______EOF
1396 $g_enable_threads_def G_THREADS_ENABLED
1397 #define G_THREADS_IMPL_$g_threads_impl_def
1398 typedef struct _GStaticMutex GStaticMutex;
1399 struct _GStaticMutex
1400 {
1401   struct _GMutex *runtime_mutex;
1402   struct {
1403     union {
1404       char   pad[$g_mutex_sizeof];
1405       double dummy_double;
1406       void  *dummy_pointer;
1407       long   dummy_long;
1408     } mutex;
1409     void *debug_info;
1410   } static_mutex;
1411 };
1412 #define G_STATIC_MUTEX_INIT     { NULL, { { { $g_mutex_contents} }, NULL } }
1413 #define g_static_mutex_get_mutex(mutex) \
1414   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->static_mutex)) : \
1415    g_static_mutex_get_mutex_impl (&((mutex)->runtime_mutex)))
1416 _______EOF
1417         else
1418                 cat >>$outfile <<_______EOF
1419 $g_enable_threads_def G_THREADS_ENABLED
1420 #define G_THREADS_IMPL_$g_threads_impl_def
1421 typedef struct _GMutex* GStaticMutex;
1422 #define G_STATIC_MUTEX_INIT NULL
1423 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (mutex))
1424 _______EOF
1425         fi
1426
1427         cat >>$outfile <<_______EOF
1428 /* This represents a system thread as used by the implementation. An
1429  * alien implementaion, as loaded by g_thread_init can only count on
1430  * "sizeof (gpointer)" bytes to store their info. We however need more
1431  * for some of our native implementations. */
1432 typedef union _GSystemThread GSystemThread;
1433 union _GSystemThread
1434 {
1435   char   data[$g_system_thread_sizeof];
1436   double dummy_double;
1437   void  *dummy_pointer;
1438   long   dummy_long;
1439 };
1440 _______EOF
1441
1442         echo >>$outfile
1443         g_bit_sizes="16 32"
1444         if test -n "$gint64"; then
1445           g_bit_sizes="$g_bit_sizes 64"
1446         fi
1447         for bits in $g_bit_sizes; do
1448           cat >>$outfile <<_______EOF
1449 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
1450 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
1451 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
1452 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
1453 _______EOF
1454         done
1455
1456         cat >>$outfile <<_______EOF
1457 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
1458 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
1459 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
1460 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
1461 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
1462 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
1463 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
1464 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
1465 #define G_BYTE_ORDER $g_byte_order
1466
1467 _______EOF
1468
1469         if test -r glibconfig-sysdefs.h; then
1470           cat glibconfig-sysdefs.h >>$outfile
1471         fi
1472
1473         cat >>$outfile <<_______EOF
1474
1475 G_END_DECLS
1476
1477 #endif /* GLIBCONFIG_H */
1478 _______EOF
1479
1480
1481         if cmp -s $outfile glibconfig.h; then
1482           echo glibconfig.h is unchanged
1483           rm -f $outfile
1484         else
1485           mv $outfile glibconfig.h
1486         fi ;;
1487 esac
1488 ],[
1489
1490 # Note that if two cases are the same, case goes with the first one.
1491 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
1492 # on variable expansion in case labels.  Look at the generated config.status
1493 # for a hint.
1494
1495 glib_header_alloca_h="$ac_cv_header_alloca_h"
1496
1497 case xyes in
1498 x$ac_cv_header_float_h)
1499   glib_float_h=yes
1500   glib_mf=FLT_MIN glib_Mf=FLT_MAX
1501   glib_md=DBL_MIN glib_Md=DBL_MAX
1502   ;;
1503 x$ac_cv_header_values_h)
1504   glib_values_h=yes
1505   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
1506   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
1507   ;;
1508 esac
1509
1510 case xyes in
1511 x$ac_cv_header_limits_h)
1512   glib_limits_h=yes
1513   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
1514   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
1515   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
1516   ;;
1517 x$ac_cv_header_values_h)
1518   glib_values_h=yes
1519   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
1520   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
1521   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
1522   ;;
1523 esac
1524
1525 if test x$ac_cv_header_sys_poll_h = xyes ; then
1526   glib_sys_poll_h=yes
1527 fi
1528
1529 case 2 in
1530 $ac_cv_sizeof_short)
1531   gint16=short
1532   gint16_format='"hi"'
1533   guint16_format='"hu"'
1534   ;;
1535 $ac_cv_sizeof_int)
1536   gint16=int
1537   gint16_format='"i"'
1538   guint16_format='"u"'
1539   ;;
1540 esac
1541 case 4 in
1542 $ac_cv_sizeof_short)
1543   gint32=short
1544   gint32_format='"hi"'
1545   guint32_format='"hu"'
1546   ;;
1547 $ac_cv_sizeof_int)
1548   gint32=int
1549   gint32_format='"i"'
1550   guint32_format='"u"'
1551   ;;
1552 $ac_cv_sizeof_long)
1553   gint32=long
1554   gint32_format='"li"'
1555   guint32_format='"lu"'
1556   ;;
1557 esac
1558 case 8 in
1559 $ac_cv_sizeof_int)
1560   gint64=int
1561   gint64_format='"i"'
1562   guint64_format='"u"'
1563   glib_extension=
1564   gint64_constant='(val)'
1565   ;;
1566 $ac_cv_sizeof_long)
1567   gint64=long
1568   gint64_format='"li"'
1569   guint64_format='"lu"'
1570   glib_extension=
1571   gint64_constant='(val##L)'
1572   ;;
1573 $ac_cv_sizeof_long_long)
1574   gint64='long long'
1575   if test -n "$glib_cv_long_long_format"; then
1576     gint64_format='"'$glib_cv_long_long_format'i"'
1577     guint64_format='"'$glib_cv_long_long_format'u"'
1578   fi
1579   glib_extension='G_GNUC_EXTENSION '
1580   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1581   ;;
1582 esac
1583 glib_size_t=$glib_cv_sizeof_size_t
1584
1585 gintbits=`expr $ac_cv_sizeof_int \* 8`
1586 glongbits=`expr $ac_cv_sizeof_long \* 8`
1587
1588
1589 case $ac_cv_sizeof_void_p in
1590 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
1591 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
1592 *)                      glib_unknown_void_p=yes ;;
1593 esac
1594
1595
1596 case xyes in
1597 x$ac_cv_func_atexit)
1598   glib_atexit="
1599 #ifdef NeXT /* @#%@! NeXTStep */
1600 # define g_ATEXIT(proc) (!atexit (proc))
1601 #else
1602 # define g_ATEXIT(proc) (atexit (proc))
1603 #endif"
1604   ;;
1605 x$ac_cv_func_on_exit)
1606   glib_atexit="
1607 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
1608   ;;
1609 esac
1610
1611 case xyes in
1612 x$ac_cv_func_memmove)
1613   glib_memmove='
1614 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
1615   ;;
1616 x$glib_cv_working_bcopy)
1617   glib_memmove="
1618 /* memmove isn't available, but bcopy can copy overlapping memory regions */
1619 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
1620   ;;
1621 *)
1622   glib_memmove="
1623 /* memmove isn't found and bcopy can't copy overlapping memory regions,
1624  * so we have to roll our own copy routine. */
1625 void g_memmove (void* dest, const void * src, unsigned long len);"
1626   ;;
1627 esac
1628
1629 glib_defines="
1630 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
1631 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
1632 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
1633 "
1634
1635 case xyes in
1636 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
1637 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
1638 *)                      glib_vacopy=''
1639 esac
1640
1641 if test x$glib_cv_va_val_copy = xno; then
1642   glib_vacopy="\$glib_vacopy
1643 #define G_VA_COPY_AS_ARRAY 1"
1644 fi
1645
1646 if test x$glib_cv_hasinline = xyes; then
1647     glib_inline='#define G_HAVE_INLINE 1'
1648 fi
1649 if test x$glib_cv_has__inline = xyes; then
1650     glib_inline="\$glib_inline
1651 #define G_HAVE___INLINE 1"
1652 fi
1653 if test x$glib_cv_has__inline__ = xyes; then
1654     glib_inline="\$glib_inline
1655 #define G_HAVE___INLINE__ 1"
1656 fi
1657
1658 case xyes in
1659 x$ac_cv_c_bigendian)
1660   g_byte_order=G_BIG_ENDIAN
1661   g_bs_native=BE
1662   g_bs_alien=LE
1663   ;;
1664 *)
1665   g_byte_order=G_LITTLE_ENDIAN
1666   g_bs_native=LE
1667   g_bs_alien=BE
1668   ;;
1669 esac
1670
1671 g_have_eilseq=$have_eilseq
1672
1673 case x$have_threads in
1674 xnone)  g_enable_threads_def="#undef";;
1675 *)      g_enable_threads_def="#define";;
1676 esac
1677
1678 g_threads_impl_def=$g_threads_impl
1679
1680 g_mutex_has_default="$mutex_has_default"
1681 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
1682 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
1683 g_mutex_contents="$glib_cv_byte_contents_gmutex"
1684
1685 case $host in
1686   *-*-beos*)
1687     glib_os="#define G_OS_BEOS"
1688     ;;
1689   *-*-cygwin*)
1690     glib_os="#define G_OS_UNIX
1691 #define G_WITH_CYGWIN"
1692 v    ;;
1693   *)
1694     glib_os="#define G_OS_UNIX"
1695     ;;
1696 esac
1697 ])
1698
1699 AC_OUTPUT([
1700 glib-2.0.pc
1701 gmodule-2.0.pc
1702 gthread-2.0.pc
1703 gobject-2.0.pc
1704 glib.spec
1705 Makefile
1706 glib-config-2.0
1707 build/Makefile
1708 build/win32/Makefile
1709 gmodule/gmoduleconf.h
1710 gmodule/Makefile
1711 gobject/Makefile
1712 gthread/Makefile
1713 docs/Makefile
1714 docs/glib-config.1
1715 docs/reference/Makefile
1716 docs/reference/glib/Makefile
1717 docs/reference/gobject/Makefile
1718 tests/Makefile
1719 ],[case "$CONFIG_FILES" in
1720 *glib-config-2.0*)chmod +x glib-config-2.0;;
1721 esac
1722 echo ""
1723 echo " *** IMPORTANT *** "
1724 echo ""
1725 echo "This is a development version of GLib.  You should be using a stable"
1726 echo "version, which is available at ftp://ftp.gtk.org/pub/gtk/v1.2/.  The"
1727 echo "version you just configured is meant for developers of GLib only:"
1728 echo ""
1729 echo "  * You should not base stable software on this version of GLib."
1730 echo "  * GNOME developers should use a stable version of GLib."
1731 echo ""
1732 echo "If you install this version of GLib, we strongly recommend that you"
1733 echo "install it in a different prefix than GLib 1.2.  Use --prefix as an"
1734 echo "argument to configure to do this.  Otherwise, you will not be able to"
1735 echo "do development with GLib 1.2 any longer."
1736 echo ""
1737 echo " *** You should be using GLib 1.2 instead. ***"
1738 ])