configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5
   6 # Process this file with autoconf to produce a configure script.
   7 AC_INIT(glist.c)
   8
   9 # Save this value here, since automake will set cflags later
  10 cflags_set=${CFLAGS+set}
  11
  12 # we rewrite this file
  13 rm -f glibconfig-sysdefs.h
  14
  15 # The following version number definitions apply to GLib and GModule
  16 # as a whole, so if changes occoured in either of them, they are both
  17 # treated with the same interface and binary age.
  18 #
  19 # Making releases:
  20 #   GLIB_MICRO_VERSION += 1;
  21 #   GLIB_INTERFACE_AGE += 1;
  22 #   GLIB_BINARY_AGE += 1;
  23 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  24 # if backwards compatibility has been broken,
  25 # set GLIB_BINARY_AGE and GLIB_INTERFACE_AGE to 0.
  26 #
  27 GLIB_MAJOR_VERSION=1
  28 GLIB_MINOR_VERSION=1
  29 GLIB_MICRO_VERSION=12
  30 GLIB_INTERFACE_AGE=0
  31 GLIB_BINARY_AGE=0
  32 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  33 AC_SUBST(GLIB_VERSION)
  34
  35 # libtool versioning
  36 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  37 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  38 LT_REVISION=$GLIB_INTERFACE_AGE
  39 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  40 AC_SUBST(LT_RELEASE)
  41 AC_SUBST(LT_CURRENT)
  42 AC_SUBST(LT_REVISION)
  43 AC_SUBST(LT_AGE)
  44
  45 VERSION=$GLIB_VERSION
  46 PACKAGE=glib
  47
  48 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  49
  50 # Specify a configuration file
  51 AM_CONFIG_HEADER(config.h)
  52
  53 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION)
  54 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION)
  55 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION)
  56 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE)
  57 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE)
  58
  59 dnl Initialize libtool
  60 AM_PROG_LIBTOOL
  61
  62 dnl Initialize maintainer mode
  63 AM_MAINTAINER_MODE
  64
  65 AC_CANONICAL_HOST
  66
  67 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=minimum]],,enable_debug=minimum)
  68 AC_ARG_ENABLE(mem_check, [  --enable-mem-check      turn on malloc/free sanity checking [default=no]],,enable_mem_check=no)
  69 AC_ARG_ENABLE(mem_profile, [  --enable-mem-profile    turn on malloc profiling atexit [default=no]],,enable_mem_profile=no)
  70 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
  71                     , enable_ansi=no)
  72 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
  73                           ([=no] will override --with-threads)],,enable_threads=yes)
  74
  75 if test "x$enable_threads" != "xyes"; then
  76   enable_threads=no
  77 fi
  78
  79 AC_MSG_CHECKING(whether to enable memory checking)
  80 if test "x$enable_mem_check" = "xyes"; then
  81   AC_DEFINE(ENABLE_MEM_CHECK, 1)
  82   AC_SUBST(ENABLE_MEM_CHECK)
  83   AC_MSG_RESULT(yes)
  84 else
  85   AC_MSG_RESULT(no)
  86 fi
  87
  88 AC_MSG_CHECKING(whether to enable memory profiling)
  89 if test "x$enable_mem_profile" = "xyes"; then
  90   AC_DEFINE(ENABLE_MEM_PROFILE, 1)
  91   AC_SUBST(ENABLE_MEM_PROFILE)
  92   AC_MSG_RESULT(yes)
  93 else
  94   AC_MSG_RESULT(no)
  95 fi
  96
  97 if test "x$enable_debug" = "xyes"; then
  98   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
  99   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 100 else
 101   if test "x$enable_debug" = "xno"; then
 102     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 103   fi
 104 fi
 105
 106 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 107
 108 # Checks for programs.
 109 AC_PROG_CC
 110 AM_PROG_CC_STDC
 111 AC_PROG_INSTALL
 112
 113 changequote(,)dnl
 114 if test "x$GCC" = "xyes"; then
 115   case " $CFLAGS " in
 116   *[\ \ ]-Wall[\ \      ]*) ;;
 117   *) CFLAGS="$CFLAGS -Wall" ;;
 118   esac
 119
 120   if test "x$enable_ansi" = "xyes"; then
 121     case " $CFLAGS " in
 122     *[\ \       ]-ansi[\ \      ]*) ;;
 123     *) CFLAGS="$CFLAGS -ansi" ;;
 124     esac
 125
 126     case " $CFLAGS " in
 127     *[\ \       ]-pedantic[\ \  ]*) ;;
 128     *) CFLAGS="$CFLAGS -pedantic" ;;
 129     esac
 130   fi
 131 fi
 132 changequote([,])dnl
 133
 134 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 135 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 136 glib_save_LIBS=$LIBS
 137 LIBS="$LIBS -lm"
 138 AC_TRY_RUN([#include <math.h>
 139              int main (void) { return (log(1) != log(1.)); }],
 140      AC_MSG_RESULT(none needed),
 141      glib_save_CFLAGS=$CFLAGS
 142      CFLAGS="$CFLAGS -std1"
 143      AC_TRY_RUN([#include <math.h>
 144                  int main (void) { return (log(1) != log(1.)); }],
 145          AC_MSG_RESULT(-std1),
 146          AC_MSG_RESULT()
 147          CFLAGS=$glib_save_CFLAGS
 148          AC_MSG_WARN(
 149                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 150      )
 151 )
 152 LIBS=$glib_save_LIBS
 153
 154 dnl NeXTStep cc seems to need this
 155 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 156 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 157   AC_MSG_RESULT(none needed),
 158   glib_save_CFLAGS=$CFLAGS
 159   CFLAGS="$CFLAGS -posix"
 160   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 161     AC_MSG_RESULT(-posix),
 162     AC_MSG_RESULT()
 163     CFLAGS=$glib_save_CFLAGS
 164     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 165
 166 # Checks for header files.
 167 AC_HEADER_STDC
 168
 169 # Checks for library functions.
 170 AC_FUNC_VPRINTF
 171 AC_FUNC_ALLOCA
 172 if test "x$ac_cv_func_alloca_works" = xyes; then
 173         glib_have_alloca=yes
 174 else
 175         glib_have_alloca=no
 176 fi
 177
 178 AC_CHECK_FUNCS(atexit on_exit)
 179
 180 AC_CHECK_SIZEOF(char)
 181 AC_CHECK_SIZEOF(short)
 182 AC_CHECK_SIZEOF(long)
 183 AC_CHECK_SIZEOF(int)
 184 AC_CHECK_SIZEOF(void *)
 185 AC_CHECK_SIZEOF(long long)
 186
 187 dnl long doubles were not used, and a portability problem
 188 dnl AC_C_LONG_DOUBLE
 189 AC_C_CONST
 190
 191 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 192 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 193 dnl actually supported.
 194 AC_MSG_CHECKING(for __inline)
 195 AC_CACHE_VAL(glib_cv_has__inline,[
 196         AC_TRY_RUN([
 197         __inline int foo () { return 0; }
 198         int main () { return foo (); }
 199         ],
 200         glib_cv_has__inline=yes
 201         ,
 202         glib_cv_has__inline=no
 203         ,)
 204 ])
 205 AC_MSG_RESULT($glib_cv_has__inline)
 206 case x$glib_cv_has__inline in
 207 xyes) AC_DEFINE(G_HAVE___INLINE)
 208 esac
 209 AC_MSG_CHECKING(for __inline__)
 210 AC_CACHE_VAL(glib_cv_has__inline__,[
 211         AC_TRY_RUN([
 212         __inline__ int foo () { return 0; }
 213         int main () { return foo (); }
 214         ],
 215         glib_cv_has__inline__=yes
 216         ,
 217         glib_cv_has__inline__=no
 218         ,)
 219 ])
 220 AC_MSG_RESULT($glib_cv_has__inline__)
 221 case x$glib_cv_has__inline__ in
 222 xyes) AC_DEFINE(G_HAVE___INLINE__)
 223 esac
 224 AC_MSG_CHECKING(for inline)
 225 AC_CACHE_VAL(glib_cv_hasinline,[
 226         AC_TRY_RUN([
 227         inline int foo () { return 0; }
 228         int main () { return foo (); }
 229         ],
 230         glib_cv_hasinline=yes
 231         ,
 232         glib_cv_hasinline=no
 233         ,)
 234 ])
 235 AC_MSG_RESULT($glib_cv_hasinline)
 236 case x$glib_cv_hasinline in
 237 xyes) AC_DEFINE(G_HAVE_INLINE)
 238 esac
 239
 240 dnl for bytesex stuff
 241 AC_C_BIGENDIAN
 242
 243 dnl header file checks
 244 AC_CHECK_HEADERS(float.h, AC_DEFINE(HAVE_FLOAT_H))
 245 AC_CHECK_HEADERS(limits.h, AC_DEFINE(HAVE_LIMITS_H))
 246 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 247 AC_CHECK_HEADERS(sys/param.h, AC_DEFINE(HAVE_SYS_PARAM_H))
 248 AC_CHECK_HEADERS(sys/poll.h, AC_DEFINE(HAVE_SYS_POLL_H))
 249 AC_CHECK_HEADERS(sys/select.h, AC_DEFINE(HAVE_SYS_SELECT_H))
 250 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 251 AC_CHECK_HEADERS(sys/times.h, AC_DEFINE(HAVE_SYS_TIMES_H))
 252 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 253 AC_CHECK_HEADERS(values.h, AC_DEFINE(HAVE_VALUES_H))
 254 AC_CHECK_HEADER(alloca.h, glib_have_alloca_h=yes, glib_have_alloca_h=no)
 255
 256 # Check for some functions
 257 AC_CHECK_FUNCS(localtime_r lstat strerror strsignal memmove vsnprintf vasprintf strcasecmp strncasecmp poll)
 258
 259 # Check for sys_errlist
 260 AC_MSG_CHECKING(for sys_errlist)
 261 AC_TRY_LINK(, [
 262 extern char *sys_errlist[];
 263 extern int sys_nerr;
 264 sys_errlist[sys_nerr-1][0] = 0;
 265 ], glib_ok=yes, glib_ok=no)
 266 AC_MSG_RESULT($glib_ok)
 267 if test $glib_ok = no; then
 268     AC_DEFINE(NO_SYS_ERRLIST)
 269 fi
 270
 271 # Check for sys_siglist
 272 AC_MSG_CHECKING(for sys_siglist)
 273 AC_TRY_LINK(, [
 274 extern char *sys_siglist[];
 275 sys_siglist[1][0] = 0;
 276 ], glib_ok=yes, glib_ok=no)
 277 AC_MSG_RESULT($glib_ok)
 278 if test $glib_ok = no; then
 279     AC_DEFINE(NO_SYS_SIGLIST)
 280 fi
 281
 282 # Check if <sys/select.h> needs to be included for fd_set
 283 AC_MSG_CHECKING([for fd_set])
 284 AC_TRY_COMPILE([#include <sys/types.h>],
 285         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 286 if test $gtk_ok = yes; then
 287     AC_MSG_RESULT([yes, found in sys/types.h])
 288 else
 289     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 290     if test $gtk_ok = yes; then
 291         AC_DEFINE(HAVE_SYS_SELECT_H)
 292         AC_MSG_RESULT([yes, found in sys/select.h])
 293     else
 294         AC_DEFINE(NO_FD_SET)
 295         AC_MSG_RESULT(no)
 296     fi
 297 fi
 298
 299 # These are used only in GDK (gdki18n.h)
 300 # This stuff is here only so that we can define these
 301 # things in glibconfig.h. If gtk+ started using an installed
 302 # gdkconfig.h file, then the definitions would belong there.
 303
 304 # Check for wchar.h
 305
 306 AC_MSG_CHECKING(for wchar.h)
 307 AC_TRY_CPP([#include <wchar.h>], glib_wchar_h=yes, glib_wchar_h=no)
 308 if test $glib_wchar_h = yes; then
 309    AC_DEFINE(HAVE_WCHAR_H)
 310 fi
 311 AC_MSG_RESULT($glib_wchar_h)
 312
 313 # Check for wctype.h (for iswalnum)
 314
 315 AC_MSG_CHECKING(for wctype.h)
 316 AC_TRY_CPP([#include <wctype.h>], glib_wctype_h=yes, glib_wctype_h=no)
 317 if test $glib_wctype_h = yes; then
 318    AC_DEFINE(HAVE_WCTYPE_H)
 319 fi
 320 AC_MSG_RESULT($glib_wctype_h)
 321
 322 oLIBS="$LIBS"
 323 # in Solaris 2.5, `iswalnum' is in -lw
 324 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum)])
 325
 326 # The following is necessary for Linux libc-5.4.38
 327 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 328 AC_TRY_LINK([#include <stdlib.h>],[
 329 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 330 #  ifdef HAVE_WCTYPE_H
 331 #    include <wctype.h>
 332 #  else
 333 #    ifdef HAVE_WCHAR_H
 334 #      include <wchar.h>
 335 #    endif
 336 #  endif
 337 #else
 338 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 339 #endif
 340 iswalnum((wchar_t) 0);
 341 ], glib_working_wctype=yes, glib_working_wctype=no)
 342 LIBS="$oLIBS"
 343
 344 if test $glib_working_wctype = no; then
 345    AC_DEFINE(HAVE_BROKEN_WCTYPE)
 346 fi
 347 AC_MSG_RESULT($glib_working_wctype)
 348
 349
 350 dnl **********************
 351 dnl *** va_copy checks ***
 352 dnl **********************
 353 dnl we currently check for all three va_copy possibilities, so we get
 354 dnl all results in config.log for bug reports.
 355 AC_MSG_CHECKING(for an implementation of va_copy())
 356 AC_CACHE_VAL(glib_cv_va_copy,[
 357         AC_TRY_RUN([
 358         #include <stdarg.h>
 359         void f (int i, ...) {
 360         va_list args1, args2;
 361         va_start (args1, i);
 362         va_copy (args2, args1);
 363         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 364           exit (1);
 365         va_end (args1); va_end (args2);
 366         }
 367         int main() {
 368           f (0, 42);
 369           return 0;
 370         }],
 371         glib_cv_va_copy=yes
 372         ,
 373         glib_cv_va_copy=no
 374         ,)
 375 ])
 376 AC_MSG_RESULT($glib_cv_va_copy)
 377 AC_MSG_CHECKING(for an implementation of __va_copy())
 378 AC_CACHE_VAL(glib_cv___va_copy,[
 379         AC_TRY_RUN([
 380         #include <stdarg.h>
 381         void f (int i, ...) {
 382         va_list args1, args2;
 383         va_start (args1, i);
 384         __va_copy (args2, args1);
 385         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 386           exit (1);
 387         va_end (args1); va_end (args2);
 388         }
 389         int main() {
 390           f (0, 42);
 391           return 0;
 392         }],
 393         glib_cv___va_copy=yes
 394         ,
 395         glib_cv___va_copy=no
 396         ,)
 397 ])
 398 AC_MSG_RESULT($glib_cv___va_copy)
 399 AC_MSG_CHECKING(whether va_lists can be copied by value)
 400 AC_CACHE_VAL(glib_cv_va_val_copy,[
 401         AC_TRY_RUN([
 402         #include <stdarg.h>
 403         void f (int i, ...) {
 404         va_list args1, args2;
 405         va_start (args1, i);
 406         args2 = args1;
 407         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 408           exit (1);
 409         va_end (args1); va_end (args2);
 410         }
 411         int main() {
 412           f (0, 42);
 413           return 0;
 414         }],
 415         glib_cv_va_val_copy=yes
 416         ,
 417         glib_cv_va_val_copy=no
 418         ,)
 419 ])
 420 if test "x$glib_cv_va_copy" = "xyes"; then
 421   AC_DEFINE(G_VA_COPY, va_copy)
 422 else if test "x$glib_cv___va_copy" = "xyes"; then
 423   AC_DEFINE(G_VA_COPY, __va_copy)
 424 fi
 425 fi
 426 if test "x$glib_cv_va_val_copy" = "xno"; then
 427   AC_DEFINE(G_VA_COPY_AS_ARRAY)
 428 fi
 429 AC_MSG_RESULT($glib_cv_va_val_copy)
 430
 431
 432 dnl ***********************
 433 dnl *** g_module checks ***
 434 dnl ***********************
 435 G_MODULE_LIBS=
 436 G_MODULE_LDFLAGS=
 437 G_MODULE_IMPL=
 438 G_MODULE_NEED_USCORE=0
 439 G_MODULE_HAVE_DLERROR=0
 440 dnl *** dlopen() in system libraries
 441 if test -z "$G_MODULE_IMPL"; then
 442         AC_CHECK_FUNC(dlopen,
 443                 G_MODULE_IMPL=G_MODULE_IMPL_DL
 444         ,)
 445 fi
 446 dnl *** dlopen() in libdl
 447 if test -z "$G_MODULE_IMPL"; then
 448         AC_CHECK_LIB(dl, dlopen,
 449                 G_MODULE_LIBS=-ldl
 450                 G_MODULE_IMPL=G_MODULE_IMPL_DL
 451         ,)
 452 fi
 453 dnl *** shl_load() in libdld (HP-UX)
 454 if test -z "$G_MODULE_IMPL"; then
 455         AC_MSG_CHECKING(how to export all symbols)
 456         SAVED_LDFLAGS=$LDFLAGS
 457         LDFLAGS="$LDFLAGS -Wl,-E"
 458         AC_TRY_LINK(,[ return 0; ],
 459                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 460                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 461                 AC_TRY_LINK(,[ return 0; ],
 462                         G_MODULE_LDFLAGS="-bexpall",
 463                         G_MODULE_LDFLAGS="none"
 464                 )
 465         ])
 466         LDFLAGS=$SAVED_LDFLAGS
 467         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 468         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 469                 G_MODULE_LDFLAGS=
 470         fi
 471         AC_CHECK_LIB(dld, shl_load,
 472                 G_MODULE_LIBS=-ldld
 473                 G_MODULE_IMPL=G_MODULE_IMPL_DLD
 474         ,)
 475 fi
 476 dnl *** additional checks for G_MODULE_IMPL_DL
 477 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 478         case "$host_os" in
 479           linux*)
 480             G_MODULE_LDFLAGS='-rdynamic'
 481             ;;
 482         esac
 483         LIBS_orig="$LIBS"
 484         LDFLAGS_orig="$LDFLAGS"
 485         LIBS="$LIBS $G_MODULE_LIBS"
 486         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 487 dnl *** check whether we need preceeding underscores
 488         AC_MSG_CHECKING(for preceeding underscore in symbols)
 489         AC_CACHE_VAL(glib_cv_uscore,[
 490                 AC_TRY_RUN([
 491                 #include <dlfcn.h>
 492                 int glib_underscore_test (void) { return 42; }
 493                 int main() {
 494                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 495                   handle = dlopen ((void*)0, 0);
 496                   if (handle) {
 497                     f1 = dlsym (handle, "glib_underscore_test");
 498                     f2 = dlsym (handle, "_glib_underscore_test");
 499                   } return (!f2 || f1);
 500                 }],
 501                         glib_cv_uscore=yes,
 502                         glib_cv_uscore=no,
 503                 )
 504                 rm -f plugin.c plugin.o plugin.lo
 505         ])
 506         AC_MSG_RESULT($glib_cv_uscore)
 507         if test "x$glib_cv_uscore" = "xyes"; then
 508                 G_MODULE_NEED_USCORE=1
 509         else
 510                 G_MODULE_NEED_USCORE=0
 511         fi
 512
 513         LDFLAGS="$LDFLAGS_orig"
 514 dnl *** check for having dlerror()
 515         AC_CHECK_FUNC(dlerror,
 516                 G_MODULE_HAVE_DLERROR=1,
 517                 G_MODULE_HAVE_DLERROR=0)
 518         LIBS="$LIBS_orig"
 519 fi
 520 dnl *** done, have e got an implementation?
 521 if test -z "$G_MODULE_IMPL"; then
 522         G_MODULE_IMPL=0
 523 fi
 524 AC_SUBST(G_MODULE_IMPL)
 525 AC_SUBST(G_MODULE_LIBS)
 526 AC_SUBST(G_MODULE_LDFLAGS)
 527 AC_SUBST(G_MODULE_HAVE_DLERROR)
 528 AC_SUBST(G_MODULE_NEED_USCORE)
 529 AC_SUBST(GLIB_DEBUG_FLAGS)
 530
 531
 532 dnl ***********************
 533 dnl *** g_thread checks ***
 534 dnl ***********************
 535
 536 AC_ARG_WITH(threads, [  --with-threads=[none/posix/solaris/nspr] specify a thread implementation to use],
 537         if test "x$with_threads" = x; then
 538                 want_threads=yes
 539         else
 540                 want_threads=$with_threads
 541         fi,
 542         want_threads=yes)
 543 if test "x$enable_threads" = "xno"; then
 544         want_threads=no
 545 fi
 546 if test "x$want_threads" = "xnone"; then
 547         want_threads=no
 548 fi
 549
 550 dnl error and warning message
 551 dnl *************************
 552
 553 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
 554                 computer. glib will not be thread safe on your computer."
 555
 556 THREAD_UNKNOWN_COMPILER="Your compiler is not known, so I cannot
 557                 determine the necessary compiler options to compile programs
 558                 which are using threads. Please provide such information."
 559
 560 FLAG_DOES_NOT_WORK="I can't find the MACRO, that enables thread safety on your
 561                 platform (normaly it's "_REENTRANT"). I'll not use any flag on
 562                 compilation now, but then your programs might not work.
 563                 Please provide information on how it is done on your system."
 564
 565 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
 566                 "
 567
 568 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
 569                 provide informationon your thread implementation."
 570
 571 dnl determination of thread implementation
 572 dnl ***************************************
 573
 574 have_threads=none
 575 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
 576         case $host in
 577                 *-*-solaris*)
 578                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
 579                 ;;
 580         esac
 581 fi
 582 if test "x$want_threads" = xyes || test "x$want_threads" = xposix; then
 583         if test "x$have_threads" = xnone; then
 584                 AC_CHECK_LIB(pthread, pthread_attr_init, have_threads=posix)
 585         fi
 586         if test "x$have_threads" = xnone; then
 587                 AC_CHECK_LIB(pthreads, pthread_attr_init, have_threads=posix)
 588         fi
 589         if test "x$have_threads" = xnone; then
 590                 AC_CHECK_FUNC(pthread_attr_init, have_threads=posix)
 591         fi
 592 fi
 593 if test "x$want_threads" = xyes || test "x$want_threads" = xnspr; then
 594         if test "x$have_threads" = xnone; then
 595                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar, have_threads=nspr)
 596         fi
 597 fi
 598
 599 AC_MSG_CHECKING(for thread implementation)
 600
 601 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
 602         AC_MSG_RESULT(none available)
 603         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
 604 else
 605         AC_MSG_RESULT($have_threads)
 606 fi
 607
 608
 609 dnl determination of G_THREAD_LIBS
 610 dnl ******************************
 611
 612 G_THREAD_LIBS=
 613
 614 mutex_has_default=no
 615 case $have_threads in
 616         posix)
 617                 G_THREAD_LIBS=error
 618                 AC_CHECK_LIB(pthread, pthread_attr_init,
 619                              G_THREAD_LIBS="-lpthread")
 620                 if test "x$G_THREAD_LIBS" = xerror; then
 621                         AC_CHECK_LIB(pthreads, pthread_attr_init,
 622                                 G_THREAD_LIBS="-lpthreads")
 623                 fi
 624                 if test "x$G_THREAD_LIBS" = xerror; then
 625                         AC_CHECK_FUNC(pthread_attr_init, G_THREAD_LIBS="")
 626                 fi
 627                 mutex_has_default=yes
 628                 mutex_default_type='pthread_mutex_t'
 629                 mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
 630                 mutex_header_file='pthread.h'
 631                 g_threads_impl="POSIX"
 632                 ;;
 633         solaris)
 634                 G_THREAD_LIBS=error
 635                 AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
 636                 mutex_has_default=yes
 637                 mutex_default_type='mutex_t'
 638                 mutex_default_init="DEFAULTMUTEX"
 639                 mutex_header_file='thread.h'
 640                 g_threads_impl="SOLARIS"
 641                 ;;
 642         nspr)
 643                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar,
 644                              G_THREAD_LIBS="-lnspr21")
 645                 g_threads_impl="NSPR"
 646                 ;;
 647         none)
 648                 g_threads_impl="NONE"
 649                 ;;
 650         *)
 651                 g_threads_impl="NONE"
 652                 G_THREAD_LIBS=error
 653                 ;;
 654 esac
 655
 656 if test "x$G_THREAD_LIBS" = xerror; then
 657         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 658 fi
 659
 660 AC_MSG_CHECKING(necessary linker options)
 661 AC_MSG_RESULT($G_THREAD_LIBS)
 662
 663
 664 dnl determination of G_THREAD_CFLAGS
 665 dnl ********************************
 666
 667 if test x"$have_threads" != xnone; then
 668         G_THREAD_CFLAGS="-D_REENTRANT" # good default
 669
 670         case $host in
 671                *-aix*)
 672                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 673                         if test x"$GCC" = xyes; then
 674                                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
 675                         fi
 676                         ;;
 677         esac
 678
 679         # if we are not finding the ctime_r function, then we probably are
 680         # not using the proper multithread flag
 681         old_CPPFLAGS=$CPPFLAGS
 682         CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
 683         AC_EGREP_HEADER([[^a-zA-Z_]ctime_r[^a-zA-Z_]], time.h, ,
 684                 G_THREAD_CFLAGS=
 685                 AC_MSG_WARN($FLAG_DOES_NOT_WORK))
 686         CPPFLAGS=$old_CPPFLAGS
 687
 688 #       if test x"$GCC" = xyes; then
 689 #               # older gcc's do not know the -fstack-check option and will
 690 #               # stop compiling, so just check this here
 691 #               old_CPPFLAGS="$CPPFLAGS"
 692 #               CPPFLAGS="$CPPFLAGS -fstack-check"
 693 #               AC_TRY_COMPILE(,,
 694 #                       G_THREAD_CFLAGS="$G_THREAD_CFLAGS -fstack-check")
 695 #               CPPFLAGS=$old_CPPFLAGS
 696 #       else
 697 #               AC_MSG_WARN($THREAD_UNKNOWN_COMPILER)
 698 #       fi
 699
 700         AC_MSG_CHECKING(necessary compiler options)
 701
 702         AC_MSG_RESULT($G_THREAD_CFLAGS)
 703 else
 704         G_THREAD_CFLAGS=
 705 fi
 706
 707 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c")
 708 AC_SUBST(G_THREAD_CFLAGS)
 709 AC_SUBST(G_THREAD_LIBS)
 710
 711 CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 712
 713 dnl **********************************************
 714 dnl *** GDefaultMutex setup and initialization ***
 715 dnl **********************************************
 716 dnl
 717 dnl if mutex_has_default = yes, we also got
 718 dnl mutex_default_type, mutex_default_init and mutex_header_file
 719 GLIB_IF_VAR_EQ(mutex_has_default, yes,
 720         GLIB_SIZEOF([#include <$mutex_header_file>],
 721                     $mutex_default_type,
 722                     gmutex,
 723                     )
 724         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
 725                            $mutex_default_type,
 726                            gmutex,
 727                            $glib_cv_sizeof_gmutex,
 728                            $mutex_default_init)
 729         ,
 730 )
 731
 732
 733 dnl ****************************************
 734 dnl *** GLib POLL* compatibility defines ***
 735 dnl ****************************************
 736 GLIB_SYSDEFS(
 737 [#include <sys/types.h>
 738 #include <sys/poll.h>],
 739         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
 740         glibconfig-sysdefs.h,
 741         =)
 742
 743
 744 dnl ******************************
 745 dnl *** output the whole stuff ***
 746 dnl ******************************
 747
 748 AC_OUTPUT_COMMANDS([
 749
 750 ## Generate `glibconfig.h' in two cases
 751 ## 1. `config.status' is run either explicitly, or via configure.
 752 ##     Esp. not when it is run in `Makefile' to generate makefiles and
 753 ##     config.h
 754 ## 2. CONFIG_OTHER is set explicitly
 755 ##
 756 ## Case 1 is difficult.  We know that `automake' sets one of
 757 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
 758 ## only when AM_CONFIG_HEADER is set, however.
 759
 760 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
 761   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
 762   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
 763 fi
 764 case "$CONFIG_OTHER" in
 765 *glibconfig.h*)
 766         echo creating glibconfig.h
 767         outfile=glibconfig.h-tmp
 768         cat > $outfile <<\_______EOF
 769 /* glibconfig.h
 770  *
 771  * This is a generated file.  Please modify `configure.in'
 772  */
 773
 774 #ifndef GLIBCONFIG_H
 775 #define GLIBCONFIG_H
 776
 777 #ifdef __cplusplus
 778 extern "C" {
 779 #endif /* __cplusplus */
 780
 781 _______EOF
 782
 783         if test x$glib_limits_h = xyes; then
 784           echo '#include <limits.h>' >> $outfile
 785         fi
 786         if test x$glib_float_h = xyes; then
 787           echo '#include <float.h>' >> $outfile
 788         fi
 789         if test x$glib_values_h = xyes; then
 790           echo '#include <values.h>' >> $outfile
 791         fi
 792         if test x$g_mutex_header_file != x; then
 793           echo '#include <'"$g_mutex_header_file"'>' >> $outfile
 794         fi
 795         if test x$glib_sys_poll_h = xyes; then
 796           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
 797         fi
 798
 799         cat >> $outfile <<_______EOF
 800
 801 #define G_MINFLOAT      $glib_mf
 802 #define G_MAXFLOAT      $glib_Mf
 803 #define G_MINDOUBLE     $glib_md
 804 #define G_MAXDOUBLE     $glib_Md
 805 #define G_MINSHORT      $glib_ms
 806 #define G_MAXSHORT      $glib_Ms
 807 #define G_MININT        $glib_mi
 808 #define G_MAXINT        $glib_Mi
 809 #define G_MINLONG       $glib_ml
 810 #define G_MAXLONG       $glib_Ml
 811
 812 _______EOF
 813
 814
 815         ### this should always be true in a modern C/C++ compiler
 816         cat >>$outfile <<_______EOF
 817 typedef signed char gint8;
 818 typedef unsigned char guint8;
 819 _______EOF
 820
 821
 822         if test -n "$gint16"; then
 823           cat >>$outfile <<_______EOF
 824 typedef signed $gint16 gint16;
 825 typedef unsigned $gint16 guint16;
 826 _______EOF
 827         fi
 828
 829
 830         if test -n "$gint32"; then
 831           cat >>$outfile <<_______EOF
 832 typedef signed $gint32 gint32;
 833 typedef unsigned $gint32 guint32;
 834 _______EOF
 835         fi
 836
 837
 838         if test -n "$gint64"; then
 839           cat >>$outfile <<_______EOF
 840 ${glib_warning_guard}#define G_HAVE_GINT64 1
 841
 842 ${glib_extension}typedef signed $gint64 gint64;
 843 ${glib_extension}typedef unsigned $gint64 guint64;
 844
 845 #define G_GINT64_CONSTANT(val)  $gint64_constant
 846 _______EOF
 847         fi
 848
 849
 850         if test -z "$glib_unknown_void_p"; then
 851           cat >>$outfile <<_______EOF
 852
 853 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
 854 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
 855
 856 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
 857 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
 858 _______EOF
 859         else
 860           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
 861         fi
 862
 863
 864
 865         cat >>$outfile <<_______EOF
 866 $glib_atexit
 867 $glib_memmove
 868 $glib_alloca
 869 $glib_defines
 870
 871 $glib_vacopy
 872
 873 #ifdef  __cplusplus
 874 #define G_HAVE_INLINE   1
 875 #else   /* !__cplusplus */
 876 $glib_inline
 877 #endif  /* !__cplusplus */
 878 _______EOF
 879
 880         echo >>$outfile
 881         if test x$g_mutex_has_default = xyes; then
 882                 cat >>$outfile <<_______EOF
 883 $g_enable_threads_def G_THREADS_ENABLED
 884 #define G_THREADS_IMPL_$g_threads_impl_def
 885 typedef struct _GStaticMutex GStaticMutex;
 886 struct _GStaticMutex
 887 {
 888   struct _GMutex *runtime_mutex;
 889   union {
 890     char   pad[$g_mutex_sizeof];
 891     double dummy_double;
 892     void  *dummy_pointer;
 893     long   dummy_long;
 894   } aligned_pad_u;
 895 };
 896 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
 897 #define g_static_mutex_get_mutex(mutex) \
 898   (g_thread_use_default_impl ? ((GMutex*) &(mutex).aligned_pad_u) : \
 899    g_static_mutex_get_mutex_impl (&(mutex).runtime_mutex))
 900 _______EOF
 901         else
 902                 cat >>$outfile <<_______EOF
 903 $g_enable_threads_def G_THREADS_ENABLED
 904 #define $g_threads_impl_def
 905 typedef struct _GMutex* GStaticMutex;
 906 #define G_STATIC_MUTEX_INIT NULL
 907 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (&(mutex)))
 908 _______EOF
 909         fi
 910
 911         echo >>$outfile
 912         g_bit_sizes="16 32"
 913         if test -n "$gint64"; then
 914           g_bit_sizes="$g_bit_sizes 64"
 915         fi
 916         for bits in $g_bit_sizes; do
 917           cat >>$outfile <<_______EOF
 918 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
 919 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
 920 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
 921 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
 922 _______EOF
 923         done
 924
 925         cat >>$outfile <<_______EOF
 926 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
 927 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
 928 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
 929 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
 930 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
 931 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
 932 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
 933 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
 934 #define G_BYTE_ORDER $g_byte_order
 935
 936 _______EOF
 937
 938         if test -r glibconfig-sysdefs.h; then
 939           cat glibconfig-sysdefs.h >>$outfile
 940         fi
 941
 942
 943         cat >>$outfile <<_______EOF
 944
 945 $glib_wc
 946
 947
 948 #ifdef __cplusplus
 949 }
 950 #endif /* __cplusplus */
 951
 952 #endif /* GLIBCONFIG_H */
 953 _______EOF
 954
 955
 956         if cmp -s $outfile glibconfig.h; then
 957           echo glibconfig.h is unchanged
 958           rm -f $outfile
 959         else
 960           mv $outfile glibconfig.h
 961         fi ;;
 962 esac
 963 ],[
 964
 965 # Note that if two cases are the same, case goes with the first one.
 966 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
 967 # on variable expansion in case labels.  Look at the generated config.status
 968 # for a hint.
 969
 970 case xyes in
 971 x$ac_cv_header_float_h)
 972   glib_float_h=yes
 973   glib_mf=FLT_MIN glib_Mf=FLT_MAX
 974   glib_md=DBL_MIN glib_Md=DBL_MAX
 975   ;;
 976 x$ac_cv_header_values_h)
 977   glib_values_h=yes
 978   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
 979   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
 980   ;;
 981 esac
 982
 983 case xyes in
 984 x$ac_cv_header_limits_h)
 985   glib_limits_h=yes
 986   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX
 987   glib_mi=INT_MIN  glib_Mi=INT_MAX
 988   glib_ml=LONG_MIN glib_Ml=LONG_MAX
 989   ;;
 990 x$ac_cv_header_values_h)
 991   glib_values_h=yes
 992   glib_ms=MINSHORT glib_Ms=MAXSHORT
 993   glib_mi=MININT   glib_Mi=MAXINT
 994   glib_ml=MINLONG  glib_Ml=MAXLONG
 995   ;;
 996 esac
 997
 998 if test x$ac_cv_header_sys_poll_h = xyes ; then
 999   glib_sys_poll_h=yes
1000 fi
1001
1002 case 2 in
1003 $ac_cv_sizeof_short)            gint16=short;;
1004 $ac_cv_sizeof_int)              gint16=int;;
1005 esac
1006 case 4 in
1007 $ac_cv_sizeof_short)            gint32=short;;
1008 $ac_cv_sizeof_int)              gint32=int;;
1009 $ac_cv_sizeof_long)             gint32=long;;
1010 esac
1011 case 8 in
1012 $ac_cv_sizeof_int)
1013   gint64=int
1014   glib_extension=
1015   glib_warning_guard=
1016   gint64_constant='(val)'
1017   ;;
1018 $ac_cv_sizeof_long)
1019   gint64=long
1020   glib_extension=
1021   glib_warning_guard=
1022   gint64_constant='(val##L)'
1023   ;;
1024 $ac_cv_sizeof_long_long)
1025   gint64='long long'
1026   glib_extension='G_GNUC_EXTENSION '
1027   glib_warning_guard="
1028 #if defined (__GNUC__) && __GNUC__ >= 2 && __GNUC_MINOR__ >= 8
1029 #  define G_GNUC_EXTENSION __extension__
1030 #else
1031 #  define G_GNUC_EXTENSION
1032 #endif
1033
1034 "
1035   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1036   ;;
1037 esac
1038
1039 gintbits=`expr $ac_cv_sizeof_int \* 8`
1040 glongbits=`expr $ac_cv_sizeof_long \* 8`
1041
1042
1043 case $ac_cv_sizeof_void_p in
1044 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
1045 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
1046 *)                      glib_unknown_void_p=yes ;;
1047 esac
1048
1049
1050 case xyes in
1051 x$ac_cv_func_atexit)
1052   glib_atexit="
1053 #ifdef NeXT /* @#%@! NeXTStep */
1054 # define g_ATEXIT(proc) (!atexit (proc))
1055 #else
1056 # define g_ATEXIT(proc) (atexit (proc))
1057 #endif"
1058   ;;
1059 x$ac_cv_func_on_exit)
1060   glib_atexit="
1061 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
1062   ;;
1063 esac
1064
1065 case xyes in
1066 x$ac_cv_func_memmove)
1067   glib_memmove='
1068 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
1069   ;;
1070 *)
1071   glib_memmove="
1072 /* We make the assumption that if memmove isn't available, then
1073  * bcopy will do the job. This isn't safe everywhere. (bcopy can't
1074  * necessarily handle overlapping copies) */
1075 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
1076   ;;
1077 esac
1078
1079 glib_defines="
1080 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
1081 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
1082 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
1083 "
1084
1085 case xyes in
1086 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
1087 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
1088 *)                      glib_vacopy=''
1089 esac
1090
1091 if test x$glib_cv_va_val_copy = xno; then
1092   glib_vacopy="\$glib_vacopy
1093 #define G_VA_COPY_AS_ARRAY 1"
1094 fi
1095
1096 if test x$glib_cv_hasinline = xyes; then
1097     glib_inline='#define G_HAVE_INLINE 1'
1098 fi
1099 if test x$glib_cv_has__inline = xyes; then
1100     glib_inline="\$glib_inline
1101 #define G_HAVE___INLINE 1"
1102 fi
1103 if test x$glib_cv_has__inline__ = xyes; then
1104     glib_inline="\$glib_inline
1105 #define G_HAVE___INLINE__ 1"
1106 fi
1107
1108 case xyes in
1109 x$ac_cv_c_bigendian)
1110   g_byte_order=G_BIG_ENDIAN
1111   g_bs_native=BE
1112   g_bs_alien=LE
1113   ;;
1114 *)
1115   g_byte_order=G_LITTLE_ENDIAN
1116   g_bs_native=LE
1117   g_bs_alien=BE
1118   ;;
1119 esac
1120
1121 if test x$glib_wchar_h = xyes; then
1122   glib_wc='
1123 #define G_HAVE_WCHAR_H 1'
1124 fi
1125 if test x$glib_wctype_h = xyes; then
1126   glib_wc="\$glib_wc
1127 #define G_HAVE_WCTYPE_H 1"
1128 fi
1129 if test x$glib_working_wctype = xno; then
1130   glib_wc="\$glib_wc
1131 #define G_HAVE_BROKEN_WCTYPE 1"
1132 fi
1133
1134 if test x$glib_have_alloca = xyes; then
1135   glib_alloca="
1136
1137 /* alloca support */"
1138
1139   if test x$glib_have_alloca_h = xyes; then
1140     glib_alloca="\$glib_alloca
1141 #define G_HAVE_ALLOCA_H 1"
1142   fi
1143
1144   glib_alloca="\$glib_alloca
1145 #define G_HAVE_ALLOCA 1
1146
1147 /* BEGIN autoconf 2.13 alloca incantation
1148          NOTE: Do not un-indent the #pragma below. */
1149 /* AIX requires this to be the first thing in the file.  */
1150 #ifdef __GNUC__
1151 # ifndef alloca
1152 #  define alloca __builtin_alloca
1153 # endif
1154 #else
1155 # if G_HAVE_ALLOCA_H
1156 #  include <alloca.h>
1157 # else
1158 #  ifdef _AIX
1159  #pragma alloca
1160 #  else
1161 #   ifndef alloca /* predefined by HP cc +Olibcalls */
1162 char *alloca ();
1163 #   endif
1164 #  endif
1165 # endif
1166 #endif
1167 /* END autoconf 2.13 alloca incantation */
1168
1169
1170 "
1171 fi
1172
1173 case x$enable_threads in
1174 xyes)   g_enable_threads_def="#define";;
1175 *)      g_enable_threads_def="#undef ";;
1176 esac
1177
1178 g_threads_impl_def=$g_threads_impl
1179
1180 g_mutex_has_default="$mutex_has_default"
1181 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
1182 g_mutex_contents="$glib_cv_byte_contents_gmutex"
1183 ])
1184
1185 AC_OUTPUT([
1186 Makefile
1187 glib-config
1188 gmodule/gmoduleconf.h
1189 gmodule/Makefile
1190 gthread/Makefile
1191 docs/Makefile
1192 tests/Makefile
1193 ],[case "$CONFIG_FILES" in
1194 *glib-config*)chmod +x glib-config;;
1195 esac])