configure.in

   1 #  FLAC - Free Lossless Audio Codec
   2 #  Copyright (C) 2001,2002,2003  Josh Coalson
   3 #
   4 #  This program is part of FLAC; you can redistribute it and/or
   5 #  modify it under the terms of the GNU General Public License
   6 #  as published by the Free Software Foundation; either version 2
   7 #  of the License, or (at your option) any later version.
   8 #
   9 #  This program is distributed in the hope that it will be useful,
  10 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 #  GNU General Public License for more details.
  13 #
  14 #  You should have received a copy of the GNU General Public License
  15 #  along with this program; if not, write to the Free Software
  16 #  Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
  17
  18 # NOTE that for many of the AM_CONDITIONALs we use the prefix FLaC__
  19 # instead of FLAC__ since autoconf triggers off 'AC_' in strings
  20
  21 AC_INIT(src/flac/main.c)
  22 AM_INIT_AUTOMAKE(flac, 1.0.5_beta2)
  23
  24 # Don't automagically regenerate autoconf/automake generated files unless
  25 # explicitly requested.  Eases autobuilding -mdz
  26 AM_MAINTAINER_MODE
  27
  28 # Function to configure paths for id3lib; search for 'meat' to get to the end.
  29 # adapted from ogg.m4
  30 # This is here until id3lib comes with an equivalent.
  31 # It is inline with configure.in instead of a separate file as a courtesy to users unaware of the -I flag to aclocal
  32 dnl LOCAL__PATH_ID3LIB([ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]])
  33 dnl Test for libid3, and define ID3LIB_CFLAGS and ID3LIB_LIBS
  34 dnl
  35 AC_DEFUN(LOCAL__PATH_ID3LIB,
  36 [dnl
  37 dnl Get the cflags and libraries
  38 dnl
  39 AC_ARG_WITH(id3lib,[  --with-id3lib=PFX   Prefix where libid3 is installed (optional)], id3lib_prefix="$withval", id3lib_prefix="")
  40 AC_ARG_WITH(id3lib-libraries,[  --with-id3lib-libraries=DIR   Directory where libid3 library is installed (optional)], id3lib_libraries="$withval", id3lib_libraries="")
  41 AC_ARG_WITH(id3lib-includes,[  --with-id3lib-includes=DIR   Directory where libid3 header files are installed (optional)], id3lib_includes="$withval", id3lib_includes="")
  42 AC_ARG_ENABLE(id3libtest, [  --disable-id3libtest       Do not try to compile and run a test id3lib program],, enable_id3libtest=yes)
  43
  44         if test "x$id3lib_libraries" != "x" ; then
  45                 ID3LIB_LIBS="-L$id3lib_libraries"
  46         elif test "x$id3lib_prefix" != "x" ; then
  47                 ID3LIB_LIBS="-L$id3lib_prefix/lib"
  48         elif test "x$prefix" != "xNONE" ; then
  49                 ID3LIB_LIBS="-L$prefix/lib"
  50         fi
  51
  52         ID3LIB_LIBS="$ID3LIB_LIBS -lid3"
  53
  54         if test "x$id3lib_includes" != "x" ; then
  55                 ID3LIB_CFLAGS="-I$id3lib_includes"
  56         elif test "x$id3lib_prefix" != "x" ; then
  57                 ID3LIB_CFLAGS="-I$id3lib_prefix/include"
  58         elif test "$prefix" != "xNONE"; then
  59                 ID3LIB_CFLAGS="-I$prefix/include"
  60         fi
  61
  62         AC_MSG_CHECKING(for id3lib)
  63
  64
  65         if test "x$enable_id3libtest" = "xyes" ; then
  66                 id3lib_found=""
  67         else
  68                 id3lib_found="yes"
  69         fi
  70         dnl There is some confusion over what libraries libid3 needs
  71         dnl so we must be pessimistic and try all permutations:
  72         dnl "-lid3" "-lid3 -lstdc++" "-lid3 -lz" "-lid3 -lz -lstdc++"
  73         for xtra_stdcpp in "" " -lstdc++" ; do
  74                 for xtra_z in "" " -lz" ; do
  75                         if test "x$id3lib_found" = "x" ; then
  76                                 ac_save_CFLAGS="$CFLAGS"
  77                                 ac_save_LIBS="$LIBS"
  78                                 CFLAGS="$CFLAGS $ID3LIB_CFLAGS"
  79                                 LIBS="$LIBS $ID3LIB_LIBS$xtra_stdcpp$xtra_z"
  80                                 rm -f conf.id3libtest
  81                                 AC_TRY_RUN([
  82 #include <stdio.h>
  83 #include <stdlib.h>
  84 #include <string.h>
  85 #include <id3.h>
  86 int main () { system("touch conf.id3libtest"); return 0; }
  87 ], id3lib_found=yes,,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
  88                                 CFLAGS="$ac_save_CFLAGS"
  89                                 LIBS="$ac_save_LIBS"
  90                         fi
  91                         if test "x$id3lib_found" = "xyes" ; then
  92                                 ID3LIB_LIBS="$ID3LIB_LIBS$xtra_stdcpp$xtra_z"
  93                         fi
  94                 done
  95         done
  96
  97         if test "x$id3lib_found" = "xyes" ; then
  98                 AC_MSG_RESULT(yes)
  99                 ifelse([$1], , :, [$1])
 100         else
 101                 AC_MSG_RESULT(no)
 102                 if test -f conf.id3libtest ; then
 103                         :
 104                 else
 105                         echo "*** Could not run id3lib test program, checking why..."
 106                         CFLAGS="$CFLAGS $ID3LIB_CFLAGS"
 107                         LIBS="$LIBS $ID3LIB_LIBS"
 108                         AC_TRY_LINK([
 109 #include <stdio.h>
 110 #include <id3.h>
 111 ],     [ return 0; ],
 112                         [ echo "*** The test program compiled, but did not run. This usually means"
 113                         echo "*** that the run-time linker is not finding id3lib or finding the wrong"
 114                         echo "*** version of id3lib. If it is not finding id3lib, you'll need to set your"
 115                         echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
 116                         echo "*** to the installed location  Also, make sure you have run ldconfig if that"
 117                         echo "*** is required on your system"
 118                         echo "***"
 119                         echo "*** If you have an old version installed, it is best to remove it, although"
 120                         echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH"],
 121                         [ echo "*** The test program failed to compile or link. See the file config.log for the"
 122                         echo "*** exact error that occured. This usually means id3lib was incorrectly installed"
 123                         echo "*** or that you have moved id3lib since it was installed." ])
 124                         CFLAGS="$ac_save_CFLAGS"
 125                         LIBS="$ac_save_LIBS"
 126                 fi
 127                 ID3LIB_CFLAGS=""
 128                 ID3LIB_LIBS=""
 129                 ifelse([$2], , :, [$2])
 130         fi
 131         AC_SUBST(ID3LIB_CFLAGS)
 132         AC_SUBST(ID3LIB_LIBS)
 133         rm -f conf.id3libtest
 134 ])
 135
 136
 137 dnl Now the meat of configure.in:
 138
 139 # We need two libtools, one that builds both shared and static, and
 140 # one that builds only static.  This is because the resulting libtool
 141 # does not allow us to choose which to build at runtime.
 142 AM_PROG_LIBTOOL
 143 sed -e 's/^build_old_libs=yes/build_old_libs=no/' libtool > libtool-disable-static
 144 chmod +x libtool-disable-static
 145
 146 AC_PROG_CXX
 147 AC_PROG_MAKE_SET
 148
 149 dnl check for getopt in standard library
 150 dnl AC_CHECK_FUNCS(getopt_long , , [LIBOBJS="$LIBOBJS getopt.o getopt1.o"] )
 151 AC_CHECK_FUNCS(getopt_long, [], [])
 152
 153 AC_CANONICAL_HOST
 154 case "$host_cpu" in
 155         i*86)   cpu_ia32=true ; AC_DEFINE(FLAC__CPU_IA32) ;;
 156         powerpc)        cpu_ppc=true ; AC_DEFINE(FLAC__CPU_PPC) ;;
 157         sparc)  cpu_sparc=true ; AC_DEFINE(FLAC__CPU_SPARC) ;;
 158 esac
 159 AM_CONDITIONAL(FLaC__CPU_IA32, test x$cpu_ia32 = xtrue)
 160 AM_CONDITIONAL(FLaC__CPU_PPC, test x$cpu_ppc = xtrue)
 161 AM_CONDITIONAL(FLaC__CPU_SPARC, test x$cpu_sparc = xtrue)
 162 case "$host" in
 163         i[[3-6]]86-*-openbsd*) OBJ_FORMAT=aoutb ;;
 164         *) OBJ_FORMAT=elf ;;
 165 esac
 166 AC_SUBST(OBJ_FORMAT)
 167
 168 if test x$cpu_ia32 = xtrue ; then
 169 AC_DEFINE(FLAC__ALIGN_MALLOC_DATA)
 170 fi
 171
 172 AC_ARG_ENABLE(asm-optimizations, [  --disable-asm-optimizations    Don't use any assembly optimization routines], asm_opt=no, asm_opt=yes)
 173 AM_CONDITIONAL(FLaC__NO_ASM, test x$asm_opt = xno)
 174 if test x$asm_opt = xno ; then
 175 AC_DEFINE(FLAC__NO_ASM)
 176 fi
 177
 178 AC_ARG_ENABLE(debug,
 179 [  --enable-debug                 Turn on debugging],
 180 [case "${enableval}" in
 181         yes) debug=true ;;
 182         no)  debug=false ;;
 183         *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
 184 esac],[debug=false])
 185 AM_CONDITIONAL(DEBUG, test x$debug = xtrue)
 186
 187 AC_ARG_ENABLE(sse,
 188 [  --enable-sse                   Enable SSE support by asserting that the OS supports SSE instructions],
 189 [case "${enableval}" in
 190         yes) sse_os=true ;;
 191         no)  sse_os=false ;;
 192         *) AC_MSG_ERROR(bad value ${enableval} for --enable-sse) ;;
 193 esac],[sse_os=false])
 194 AM_CONDITIONAL(FLaC__SSE_OS, test x$sse_os = xtrue)
 195 if test x$sse_os = xtrue ; then
 196 AC_DEFINE(FLAC__SSE_OS)
 197 fi
 198
 199 AC_ARG_ENABLE(3dnow,
 200 [  --disable-3dnow                Disable 3DNOW! optimizations],
 201 [case "${enableval}" in
 202         yes) use_3dnow=true ;;
 203         no)  use_3dnow=false ;;
 204         *) AC_MSG_ERROR(bad value ${enableval} for --enable-3dnow) ;;
 205 esac],[use_3dnow=true])
 206 AM_CONDITIONAL(FLaC__USE_3DNOW, test x$use_3dnow = xtrue)
 207 if test x$use_3dnow = xtrue ; then
 208 AC_DEFINE(FLAC__USE_3DNOW)
 209 fi
 210
 211 AC_ARG_ENABLE(exhaustive-tests,
 212 [  --enable-exhaustive-tests      Enable exhaustive testing],
 213 [case "${enableval}" in
 214         yes) exhaustive_tests=true ;;
 215         no)  exhaustive_tests=false ;;
 216         *) AC_MSG_ERROR(bad value ${enableval} for --enable-exhaustive-tests) ;;
 217 esac],[exhaustive_tests=false])
 218 AM_CONDITIONAL(FLaC__EXHAUSTIVE_TESTS, test x$exhaustive_tests = xtrue)
 219 if test x$exhaustive_tests = xtrue ; then
 220 AC_DEFINE(FLAC__EXHAUSTIVE_TESTS)
 221 fi
 222
 223 AC_ARG_ENABLE(valgrind-testing,
 224 [  --enable-valgrind-testing      Run all tests inside Valgrind],
 225 [case "${enableval}" in
 226         yes) valgrind_testing=true ;;
 227         no)  valgrind_testing=false ;;
 228         *) AC_MSG_ERROR(bad value ${enableval} for --enable-valgrind-testing) ;;
 229 esac],[valgrind_testing=false])
 230 AM_CONDITIONAL(FLaC__VALGRIND_TESTING, test x$valgrind_testing = xtrue)
 231 if test x$valgrind_testing = xtrue ; then
 232 AC_DEFINE(FLAC__VALGRIND_TESTING)
 233 fi
 234
 235 dnl check for ogg library
 236 XIPH_PATH_OGG(have_ogg=yes, AC_MSG_WARN([*** Ogg development enviroment not installed - Ogg support will not be built]))
 237 AM_CONDITIONAL(FLaC__HAS_OGG, [test x$have_ogg = xyes])
 238 if test x$have_ogg = xyes ; then
 239 AC_DEFINE(FLAC__HAS_OGG)
 240 fi
 241
 242 AM_PATH_XMMS(0.9.5.1, , AC_MSG_WARN([*** XMMS >= 0.9.5.1 not installed - xmms support will not be built]))
 243 AM_CONDITIONAL(FLaC__HAS_XMMS, test x$XMMS_INPUT_PLUGIN_DIR != x)
 244
 245 dnl check for i18n(internationalization); these are from libiconv/gettext
 246 AM_ICONV
 247 AM_LANGINFO_CODESET
 248
 249 dnl check for id3lib library
 250 dnl LOCAL__PATH_ID3LIB is defined by us, and will be until such time as id3lib supplies one
 251 LOCAL__PATH_ID3LIB(have_id3lib=yes, AC_MSG_WARN([*** id3lib not found - id3v2 support will not be built]))
 252 AM_CONDITIONAL(FLaC__HAS_ID3LIB, [test x$have_id3lib = xyes])
 253 if test x$have_id3lib = xyes ; then
 254 AC_DEFINE(FLAC__HAS_ID3LIB)
 255
 256 dnl expected id3lib version for cross compiling
 257 ID3LIB_MAJOR=3
 258 ID3LIB_MINOR=8
 259 ID3LIB_PATCH=0
 260
 261 CFLAGS_save_blah_blah_blah=$CFLAGS
 262 CFLAGS="$ID3LIB_CFLAGS $CFLAGS"
 263 LIBS_save_blah_blah_blah=$LIBS
 264 LIBS="$ID3LIB_LIBS $LIBS"
 265 AC_MSG_CHECKING(for id3lib version)
 266       AC_TRY_RUN([
 267 #include <id3.h>
 268 #include <stdio.h>
 269 int
 270 main ()
 271 {
 272         FILE *output;
 273         output=fopen("conftest.id3","w");
 274         fprintf(output,"ID3LIB_MAJOR=%d\nID3LIB_MINOR=%d\nID3LIB_PATCH=%d\n",ID3LIB_MAJOR_VERSION,ID3LIB_MINOR_VERSION,ID3LIB_PATCH_VERSION);
 275         fclose(output);
 276         exit(0);
 277 }
 278 ], . ./conftest.id3; echo "${ID3LIB_MAJOR}.${ID3LIB_MINOR}.${ID3LIB_PATCH}", AC_MSG_WARN(could not determine id3lib version),[echo $ac_n "cross compiling; assuming ${ID3LIB_MAJOR}.${ID3LIB_MINOR}.${ID3LIB_PATCH} $ac_c"])
 279 AC_DEFINE_UNQUOTED(ID3LIB_MAJOR, $ID3LIB_MAJOR)
 280 AC_DEFINE_UNQUOTED(ID3LIB_MINOR, $ID3LIB_MINOR)
 281 AC_DEFINE_UNQUOTED(ID3LIB_PATCH, $ID3LIB_PATCH)
 282 CFLAGS=$CFLAGS_save_blah_blah_blah
 283 LIBS=$LIBS_save_blah_blah_blah
 284 fi
 285
 286 AC_CHECK_PROGS(DOXYGEN, doxygen)
 287 AM_CONDITIONAL(FLaC__HAS_DOXYGEN, test -n "$DOXYGEN")
 288 if test -n "$DOXYGEN" ; then
 289 AC_DEFINE(FLAC__HAS_DOXYGEN)
 290 fi
 291
 292 AC_CHECK_PROGS(NASM, nasm)
 293 AM_CONDITIONAL(FLaC__HAS_NASM, test -n "$NASM")
 294 if test -n "$NASM" ; then
 295 AC_DEFINE(FLAC__HAS_NASM)
 296 fi
 297
 298 dnl Check for type sizes
 299
 300 AC_CHECK_SIZEOF(short)
 301 AC_CHECK_SIZEOF(int)
 302 AC_CHECK_SIZEOF(long)
 303 AC_CHECK_SIZEOF(long long)
 304
 305 case 2 in
 306         $ac_cv_sizeof_short) FLaC__SIZE16="short" ; FLaC__USIZE16="unsigned short";;
 307         $ac_cv_sizeof_int) FLaC__SIZE16="int" ; FLaC__USIZE16="unsigned int";;
 308 esac
 309
 310 case 4 in
 311         $ac_cv_sizeof_short) FLaC__SIZE32="short" ; FLaC__USIZE32="unsigned short";;
 312         $ac_cv_sizeof_int) FLaC__SIZE32="int" ; FLaC__USIZE32="unsigned int";;
 313         $ac_cv_sizeof_long) FLaC__SIZE32="long" ; FLaC__USIZE32="unsigned long";;
 314 esac
 315
 316 case 8 in
 317         $ac_cv_sizeof_int) FLaC__SIZE64="int" ; FLaC__USIZE64="unsigned int";;
 318         $ac_cv_sizeof_long) FLaC__SIZE64="long" ; FLaC__USIZE64="unsigned long";;
 319         $ac_cv_sizeof_long_long) FLaC__SIZE64="long long" ; FLaC__USIZE64="unsigned long long";;
 320 esac
 321
 322 if test -z "$FLaC__SIZE16"; then
 323         AC_MSG_ERROR(No 16 bit type found on this platform!)
 324 fi
 325 if test -z "$FLaC__USIZE16"; then
 326         AC_MSG_ERROR(No unsigned 16 bit type found on this platform!)
 327 fi
 328 if test -z "$FLaC__SIZE32"; then
 329         AC_MSG_ERROR(No 32 bit type found on this platform!)
 330 fi
 331 if test -z "$FLaC__USIZE32"; then
 332         AC_MSG_ERROR(No unsigned 32 bit type found on this platform!)
 333 fi
 334 if test -z "$FLaC__SIZE64"; then
 335         AC_MSG_WARN(No 64 bit type found on this platform!)
 336 fi
 337 if test -z "$FLaC__USIZE64"; then
 338         AC_MSG_ERROR(No unsigned 64 bit type found on this platform!)
 339 fi
 340
 341 AC_SUBST(FLaC__SIZE16)
 342 AC_SUBST(FLaC__USIZE16)
 343 AC_SUBST(FLaC__SIZE32)
 344 AC_SUBST(FLaC__USIZE32)
 345 AC_SUBST(FLaC__SIZE64)
 346 AC_SUBST(FLaC__USIZE64)
 347
 348 OUR_CFLAGS_HEAD='-I$(top_builddir) -I$(srcdir)/include -I$(top_srcdir)/include'
 349 if test x$debug = xtrue; then
 350         OUR_CFLAGS_HEAD="$OUR_CFLAGS_HEAD -g -O0 -DDEBUG"
 351 else
 352         OUR_CFLAGS_HEAD="$OUR_CFLAGS_HEAD -O3 -DNDEBUG"
 353         if test x$GCC = xyes; then
 354                 OUR_CFLAGS_HEAD="$OUR_CFLAGS_HEAD -fomit-frame-pointer -funroll-loops -finline-functions -Wall -W -Winline -DFLaC__INLINE=__inline__"
 355         fi
 356 fi
 357 CFLAGS="$OUR_CFLAGS_HEAD $CFLAGS"
 358 CXXFLAGS="$OUR_CFLAGS_HEAD $CXXFLAGS"
 359
 360 AM_CONFIG_HEADER(config.h)
 361 AH_TEMPLATE(FLAC__ALIGN_MALLOC_DATA,  [define if XXX])
 362 AH_TEMPLATE(FLAC__CPU_IA32,  [define if building for ia32/i386])
 363 AH_TEMPLATE(FLAC__CPU_PPC,  [define if building for PowerPC])
 364 AH_TEMPLATE(FLAC__CPU_SPARC,  [define if building for SPARC])
 365 AH_TEMPLATE(FLAC__EXHAUSTIVE_TESTS,  [define to run even more tests])
 366 AH_TEMPLATE(FLAC__VALGRIND_TESTING,  [define to enable use of Valgrind in testers])
 367 AH_TEMPLATE(FLAC__HAS_DOXYGEN,  [define if you have Doxygen])
 368 AH_TEMPLATE(FLAC__HAS_ID3LIB,  [define if you have the id3lib library])
 369 AH_TEMPLATE(FLAC__HAS_NASM,  [define if you have the NASM assembler])
 370 AH_TEMPLATE(FLAC__HAS_OGG,  [define if you have the ogg library])
 371 AH_TEMPLATE(FLAC__NO_ASM,  [define to disable use of assembly code])
 372 AH_TEMPLATE(FLAC__SSE_OS,  [define if your operating system supports SSE instructions])
 373 AH_TEMPLATE(FLAC__USE_3DNOW,  [define to enable use of 3Dnow! instructions])
 374 AH_TEMPLATE(ID3LIB_MAJOR,  [define to major version number of id3lib])
 375 AH_TEMPLATE(ID3LIB_MINOR,  [define to minor version number of id3lib])
 376 AH_TEMPLATE(ID3LIB_PATCH,  [define to patch level of id3lib])
 377
 378 AC_OUTPUT( \
 379         Makefile \
 380         src/Makefile \
 381         src/libFLAC/Makefile \
 382         src/libFLAC/ia32/Makefile \
 383         src/libFLAC/include/Makefile \
 384         src/libFLAC/include/private/Makefile \
 385         src/libFLAC/include/protected/Makefile \
 386         src/libFLAC++/Makefile \
 387         src/libOggFLAC/Makefile \
 388         src/libOggFLAC/include/Makefile \
 389         src/libOggFLAC/include/protected/Makefile \
 390         src/libOggFLAC++/Makefile \
 391         src/flac/Makefile \
 392         src/metaflac/Makefile \
 393         src/monkeys_audio_utilities/Makefile \
 394         src/monkeys_audio_utilities/flac_mac/Makefile \
 395         src/monkeys_audio_utilities/flac_ren/Makefile \
 396         src/plugin_common/Makefile \
 397         src/plugin_common/include/Makefile \
 398         src/plugin_common/include/private/Makefile \
 399         src/plugin_winamp2/Makefile \
 400         src/plugin_winamp2/include/Makefile \
 401         src/plugin_winamp2/include/winamp2/Makefile \
 402         src/plugin_winamp3/Makefile \
 403         src/plugin_xmms/Makefile \
 404         src/share/Makefile \
 405         src/share/gain_analysis/Makefile \
 406         src/share/getopt/Makefile \
 407         src/share/grabbag/Makefile \
 408         src/share/utf8/Makefile \
 409         src/test_grabbag/Makefile \
 410         src/test_grabbag/cuesheet/Makefile \
 411         src/test_libFLAC/Makefile \
 412         src/test_libFLAC++/Makefile \
 413         src/test_libOggFLAC/Makefile \
 414         src/test_libOggFLAC++/Makefile \
 415         src/test_streams/Makefile \
 416         include/Makefile \
 417         include/FLAC/Makefile \
 418         include/FLAC/ordinals.h \
 419         include/FLAC++/Makefile \
 420         include/OggFLAC/Makefile \
 421         include/OggFLAC++/Makefile \
 422         include/share/Makefile \
 423         include/share/grabbag/Makefile \
 424         doc/Makefile \
 425         doc/html/Makefile \
 426         doc/html/images/Makefile \
 427         doc/html/ru/Makefile \
 428         man/Makefile \
 429         test/Makefile \
 430         test/cuesheets/Makefile \
 431         build/Makefile \
 432         obj/Makefile \
 433         obj/debug/Makefile \
 434         obj/debug/bin/Makefile \
 435         obj/debug/lib/Makefile \
 436         obj/release/Makefile \
 437         obj/release/bin/Makefile \
 438         obj/release/lib/Makefile \
 439         flac.pbproj/Makefile \
 440 )