configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5
   6 # require autoconf 2.13
   7 AC_REQUIRE(2.13)
   8
   9 # Process this file with autoconf to produce a configure script.
  10 AC_INIT(glist.c)
  11
  12 # Save this value here, since automake will set cflags later
  13 cflags_set=${CFLAGS+set}
  14
  15 # we rewrite this file
  16 rm -f glibconfig-sysdefs.h
  17
  18 # The following version number definitions apply to GLib and GModule
  19 # as a whole, so if changes occoured in either of them, they are both
  20 # treated with the same interface and binary age.
  21 #
  22 # Making releases:
  23 #   GLIB_MICRO_VERSION += 1;
  24 #   GLIB_INTERFACE_AGE += 1;
  25 #   GLIB_BINARY_AGE += 1;
  26 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  27 # if backwards compatibility has been broken,
  28 # set GLIB_BINARY_AGE and GLIB_INTERFACE_AGE to 0.
  29 #
  30 GLIB_MAJOR_VERSION=1
  31 GLIB_MINOR_VERSION=1
  32 GLIB_MICRO_VERSION=13
  33 GLIB_INTERFACE_AGE=0
  34 GLIB_BINARY_AGE=0
  35 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  36 AC_SUBST(GLIB_VERSION)
  37
  38 # libtool versioning
  39 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  40 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  41 LT_REVISION=$GLIB_INTERFACE_AGE
  42 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  43 AC_SUBST(LT_RELEASE)
  44 AC_SUBST(LT_CURRENT)
  45 AC_SUBST(LT_REVISION)
  46 AC_SUBST(LT_AGE)
  47
  48 VERSION=$GLIB_VERSION
  49 PACKAGE=glib
  50
  51 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  52
  53 # Specify a configuration file
  54 AM_CONFIG_HEADER(config.h)
  55
  56 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION)
  57 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION)
  58 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION)
  59 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE)
  60 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE)
  61
  62 dnl Initialize libtool
  63 AM_PROG_LIBTOOL
  64
  65 dnl Initialize maintainer mode
  66 AM_MAINTAINER_MODE
  67
  68 AC_CANONICAL_HOST
  69
  70 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=minimum]],,enable_debug=minimum)
  71 AC_ARG_ENABLE(mem_check, [  --enable-mem-check      turn on malloc/free sanity checking [default=no]],,enable_mem_check=no)
  72 AC_ARG_ENABLE(mem_profile, [  --enable-mem-profile    turn on malloc profiling atexit [default=no]],,enable_mem_profile=no)
  73 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
  74                     , enable_ansi=no)
  75 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
  76                           ([=no] will override --with-threads)],,enable_threads=yes)
  77
  78 if test "x$enable_threads" != "xyes"; then
  79   enable_threads=no
  80 fi
  81
  82 AC_MSG_CHECKING(whether to enable memory checking)
  83 if test "x$enable_mem_check" = "xyes"; then
  84   AC_DEFINE(ENABLE_MEM_CHECK, 1)
  85   AC_SUBST(ENABLE_MEM_CHECK)
  86   AC_MSG_RESULT(yes)
  87 else
  88   AC_MSG_RESULT(no)
  89 fi
  90
  91 AC_MSG_CHECKING(whether to enable memory profiling)
  92 if test "x$enable_mem_profile" = "xyes"; then
  93   AC_DEFINE(ENABLE_MEM_PROFILE, 1)
  94   AC_SUBST(ENABLE_MEM_PROFILE)
  95   AC_MSG_RESULT(yes)
  96 else
  97   AC_MSG_RESULT(no)
  98 fi
  99
 100 if test "x$enable_debug" = "xyes"; then
 101   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 102   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 103 else
 104   if test "x$enable_debug" = "xno"; then
 105     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 106   fi
 107 fi
 108
 109 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 110
 111 # Checks for programs.
 112 AC_PROG_CC
 113 AM_PROG_CC_STDC
 114 AC_PROG_INSTALL
 115
 116 changequote(,)dnl
 117 if test "x$GCC" = "xyes"; then
 118   case " $CFLAGS " in
 119   *[\ \ ]-Wall[\ \      ]*) ;;
 120   *) CFLAGS="$CFLAGS -Wall" ;;
 121   esac
 122
 123   if test "x$enable_ansi" = "xyes"; then
 124     case " $CFLAGS " in
 125     *[\ \       ]-ansi[\ \      ]*) ;;
 126     *) CFLAGS="$CFLAGS -ansi" ;;
 127     esac
 128
 129     case " $CFLAGS " in
 130     *[\ \       ]-pedantic[\ \  ]*) ;;
 131     *) CFLAGS="$CFLAGS -pedantic" ;;
 132     esac
 133   fi
 134 fi
 135 changequote([,])dnl
 136
 137 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 138 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 139 glib_save_LIBS=$LIBS
 140 LIBS="$LIBS -lm"
 141 AC_TRY_RUN([#include <math.h>
 142              int main (void) { return (log(1) != log(1.)); }],
 143      AC_MSG_RESULT(none needed),
 144      glib_save_CFLAGS=$CFLAGS
 145      CFLAGS="$CFLAGS -std1"
 146      AC_TRY_RUN([#include <math.h>
 147                  int main (void) { return (log(1) != log(1.)); }],
 148          AC_MSG_RESULT(-std1),
 149          AC_MSG_RESULT()
 150          CFLAGS=$glib_save_CFLAGS
 151          AC_MSG_WARN(
 152                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 153      )
 154 )
 155 LIBS=$glib_save_LIBS
 156
 157 dnl NeXTStep cc seems to need this
 158 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 159 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 160   AC_MSG_RESULT(none needed),
 161   glib_save_CFLAGS=$CFLAGS
 162   CFLAGS="$CFLAGS -posix"
 163   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 164     AC_MSG_RESULT(-posix),
 165     AC_MSG_RESULT()
 166     CFLAGS=$glib_save_CFLAGS
 167     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 168
 169 # Checks for header files.
 170 AC_HEADER_STDC
 171
 172 # Checks for library functions.
 173 AC_FUNC_VPRINTF
 174
 175 AC_CHECK_FUNCS(atexit on_exit)
 176
 177 AC_CHECK_SIZEOF(char)
 178 AC_CHECK_SIZEOF(short)
 179 AC_CHECK_SIZEOF(long)
 180 AC_CHECK_SIZEOF(int)
 181 AC_CHECK_SIZEOF(void *)
 182 AC_CHECK_SIZEOF(long long)
 183
 184 dnl long doubles were not used, and a portability problem
 185 dnl AC_C_LONG_DOUBLE
 186 AC_C_CONST
 187
 188 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 189 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 190 dnl actually supported.
 191 AC_MSG_CHECKING(for __inline)
 192 AC_CACHE_VAL(glib_cv_has__inline,[
 193         AC_TRY_RUN([
 194         __inline int foo () { return 0; }
 195         int main () { return foo (); }
 196         ],
 197         glib_cv_has__inline=yes
 198         ,
 199         glib_cv_has__inline=no
 200         ,)
 201 ])
 202 AC_MSG_RESULT($glib_cv_has__inline)
 203 case x$glib_cv_has__inline in
 204 xyes) AC_DEFINE(G_HAVE___INLINE)
 205 esac
 206 AC_MSG_CHECKING(for __inline__)
 207 AC_CACHE_VAL(glib_cv_has__inline__,[
 208         AC_TRY_RUN([
 209         __inline__ int foo () { return 0; }
 210         int main () { return foo (); }
 211         ],
 212         glib_cv_has__inline__=yes
 213         ,
 214         glib_cv_has__inline__=no
 215         ,)
 216 ])
 217 AC_MSG_RESULT($glib_cv_has__inline__)
 218 case x$glib_cv_has__inline__ in
 219 xyes) AC_DEFINE(G_HAVE___INLINE__)
 220 esac
 221 AC_MSG_CHECKING(for inline)
 222 AC_CACHE_VAL(glib_cv_hasinline,[
 223         AC_TRY_RUN([
 224         inline int foo () { return 0; }
 225         int main () { return foo (); }
 226         ],
 227         glib_cv_hasinline=yes
 228         ,
 229         glib_cv_hasinline=no
 230         ,)
 231 ])
 232 AC_MSG_RESULT($glib_cv_hasinline)
 233 case x$glib_cv_hasinline in
 234 xyes) AC_DEFINE(G_HAVE_INLINE)
 235 esac
 236
 237 dnl for bytesex stuff
 238 AC_C_BIGENDIAN
 239
 240 dnl header file checks
 241 AC_CHECK_HEADERS(float.h, AC_DEFINE(HAVE_FLOAT_H))
 242 AC_CHECK_HEADERS(limits.h, AC_DEFINE(HAVE_LIMITS_H))
 243 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 244 AC_CHECK_HEADERS(sys/param.h, AC_DEFINE(HAVE_SYS_PARAM_H))
 245 AC_CHECK_HEADERS(sys/poll.h, AC_DEFINE(HAVE_SYS_POLL_H))
 246 AC_CHECK_HEADERS(sys/select.h, AC_DEFINE(HAVE_SYS_SELECT_H))
 247 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 248 AC_CHECK_HEADERS(sys/times.h, AC_DEFINE(HAVE_SYS_TIMES_H))
 249 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 250 AC_CHECK_HEADERS(values.h, AC_DEFINE(HAVE_VALUES_H))
 251
 252 # Check for some functions
 253 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf strcasecmp strncasecmp poll)
 254
 255 # Check for sys_errlist
 256 AC_MSG_CHECKING(for sys_errlist)
 257 AC_TRY_LINK(, [
 258 extern char *sys_errlist[];
 259 extern int sys_nerr;
 260 sys_errlist[sys_nerr-1][0] = 0;
 261 ], glib_ok=yes, glib_ok=no)
 262 AC_MSG_RESULT($glib_ok)
 263 if test $glib_ok = no; then
 264     AC_DEFINE(NO_SYS_ERRLIST)
 265 fi
 266
 267 # Check for sys_siglist
 268 AC_MSG_CHECKING(for sys_siglist)
 269 AC_TRY_LINK(, [
 270 extern char *sys_siglist[];
 271 strlen (sys_siglist[0]);
 272 ], glib_ok=yes, glib_ok=no)
 273 AC_MSG_RESULT($glib_ok)
 274 if test $glib_ok = no; then
 275     AC_DEFINE(NO_SYS_SIGLIST)
 276 fi
 277
 278 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 279 AC_MSG_CHECKING(for sys_siglist declaration)
 280 AC_TRY_COMPILE([#include <signal.h>], [
 281 strlen (sys_siglist[0]);
 282 ], glib_ok=yes, glib_ok=no)
 283 AC_MSG_RESULT($glib_ok)
 284 if test $glib_ok = yes; then
 285     AC_DEFINE(NO_SYS_SIGLIST_DECL)
 286 fi
 287
 288 # Check if <sys/select.h> needs to be included for fd_set
 289 AC_MSG_CHECKING([for fd_set])
 290 AC_TRY_COMPILE([#include <sys/types.h>],
 291         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 292 if test $gtk_ok = yes; then
 293     AC_MSG_RESULT([yes, found in sys/types.h])
 294 else
 295     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 296     if test $gtk_ok = yes; then
 297         AC_DEFINE(HAVE_SYS_SELECT_H)
 298         AC_MSG_RESULT([yes, found in sys/select.h])
 299     else
 300         AC_DEFINE(NO_FD_SET)
 301         AC_MSG_RESULT(no)
 302     fi
 303 fi
 304
 305 # These are used only in GDK (gdki18n.h)
 306 # This stuff is here only so that we can define these
 307 # things in glibconfig.h. If gtk+ started using an installed
 308 # gdkconfig.h file, then the definitions would belong there.
 309
 310 # Check for wchar.h
 311
 312 AC_MSG_CHECKING(for wchar.h)
 313 AC_TRY_CPP([#include <wchar.h>], glib_wchar_h=yes, glib_wchar_h=no)
 314 if test $glib_wchar_h = yes; then
 315    AC_DEFINE(HAVE_WCHAR_H)
 316 fi
 317 AC_MSG_RESULT($glib_wchar_h)
 318
 319 # Check for wctype.h (for iswalnum)
 320
 321 AC_MSG_CHECKING(for wctype.h)
 322 AC_TRY_CPP([#include <wctype.h>], glib_wctype_h=yes, glib_wctype_h=no)
 323 if test $glib_wctype_h = yes; then
 324    AC_DEFINE(HAVE_WCTYPE_H)
 325 fi
 326 AC_MSG_RESULT($glib_wctype_h)
 327
 328 oLIBS="$LIBS"
 329 # in Solaris 2.5, `iswalnum' is in -lw
 330 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum)])
 331
 332 # The following is necessary for Linux libc-5.4.38
 333 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 334 AC_TRY_LINK([#include <stdlib.h>],[
 335 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 336 #  ifdef HAVE_WCTYPE_H
 337 #    include <wctype.h>
 338 #  else
 339 #    ifdef HAVE_WCHAR_H
 340 #      include <wchar.h>
 341 #    endif
 342 #  endif
 343 #else
 344 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 345 #endif
 346 iswalnum((wchar_t) 0);
 347 ], glib_working_wctype=yes, glib_working_wctype=no)
 348 LIBS="$oLIBS"
 349
 350 if test $glib_working_wctype = no; then
 351    AC_DEFINE(HAVE_BROKEN_WCTYPE)
 352 fi
 353 AC_MSG_RESULT($glib_working_wctype)
 354
 355
 356 dnl **********************
 357 dnl *** va_copy checks ***
 358 dnl **********************
 359 dnl we currently check for all three va_copy possibilities, so we get
 360 dnl all results in config.log for bug reports.
 361 AC_MSG_CHECKING(for an implementation of va_copy())
 362 AC_CACHE_VAL(glib_cv_va_copy,[
 363         AC_TRY_RUN([
 364         #include <stdarg.h>
 365         void f (int i, ...) {
 366         va_list args1, args2;
 367         va_start (args1, i);
 368         va_copy (args2, args1);
 369         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 370           exit (1);
 371         va_end (args1); va_end (args2);
 372         }
 373         int main() {
 374           f (0, 42);
 375           return 0;
 376         }],
 377         glib_cv_va_copy=yes
 378         ,
 379         glib_cv_va_copy=no
 380         ,)
 381 ])
 382 AC_MSG_RESULT($glib_cv_va_copy)
 383 AC_MSG_CHECKING(for an implementation of __va_copy())
 384 AC_CACHE_VAL(glib_cv___va_copy,[
 385         AC_TRY_RUN([
 386         #include <stdarg.h>
 387         void f (int i, ...) {
 388         va_list args1, args2;
 389         va_start (args1, i);
 390         __va_copy (args2, args1);
 391         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 392           exit (1);
 393         va_end (args1); va_end (args2);
 394         }
 395         int main() {
 396           f (0, 42);
 397           return 0;
 398         }],
 399         glib_cv___va_copy=yes
 400         ,
 401         glib_cv___va_copy=no
 402         ,)
 403 ])
 404 AC_MSG_RESULT($glib_cv___va_copy)
 405 AC_MSG_CHECKING(whether va_lists can be copied by value)
 406 AC_CACHE_VAL(glib_cv_va_val_copy,[
 407         AC_TRY_RUN([
 408         #include <stdarg.h>
 409         void f (int i, ...) {
 410         va_list args1, args2;
 411         va_start (args1, i);
 412         args2 = args1;
 413         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 414           exit (1);
 415         va_end (args1); va_end (args2);
 416         }
 417         int main() {
 418           f (0, 42);
 419           return 0;
 420         }],
 421         glib_cv_va_val_copy=yes
 422         ,
 423         glib_cv_va_val_copy=no
 424         ,)
 425 ])
 426 if test "x$glib_cv_va_copy" = "xyes"; then
 427   AC_DEFINE(G_VA_COPY, va_copy)
 428 else if test "x$glib_cv___va_copy" = "xyes"; then
 429   AC_DEFINE(G_VA_COPY, __va_copy)
 430 fi
 431 fi
 432 if test "x$glib_cv_va_val_copy" = "xno"; then
 433   AC_DEFINE(G_VA_COPY_AS_ARRAY)
 434 fi
 435 AC_MSG_RESULT($glib_cv_va_val_copy)
 436
 437
 438 dnl ***********************
 439 dnl *** g_module checks ***
 440 dnl ***********************
 441 G_MODULE_LIBS=
 442 G_MODULE_LDFLAGS=
 443 G_MODULE_IMPL=
 444 G_MODULE_NEED_USCORE=0
 445 G_MODULE_HAVE_DLERROR=0
 446 dnl *** dlopen() in system libraries
 447 if test -z "$G_MODULE_IMPL"; then
 448         AC_CHECK_FUNC(dlopen,
 449                 G_MODULE_IMPL=G_MODULE_IMPL_DL
 450         ,)
 451 fi
 452 dnl *** dlopen() in libdl
 453 if test -z "$G_MODULE_IMPL"; then
 454         AC_CHECK_LIB(dl, dlopen,
 455                 G_MODULE_LIBS=-ldl
 456                 G_MODULE_IMPL=G_MODULE_IMPL_DL
 457         ,)
 458 fi
 459 dnl *** shl_load() in libdld (HP-UX)
 460 if test -z "$G_MODULE_IMPL"; then
 461         AC_MSG_CHECKING(how to export all symbols)
 462         SAVED_LDFLAGS=$LDFLAGS
 463         LDFLAGS="$LDFLAGS -Wl,-E"
 464         AC_TRY_LINK(,[ return 0; ],
 465                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 466                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 467                 AC_TRY_LINK(,[ return 0; ],
 468                         G_MODULE_LDFLAGS="-bexpall",
 469                         G_MODULE_LDFLAGS="none"
 470                 )
 471         ])
 472         LDFLAGS=$SAVED_LDFLAGS
 473         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 474         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 475                 G_MODULE_LDFLAGS=
 476         fi
 477         AC_CHECK_LIB(dld, shl_load,
 478                 G_MODULE_LIBS=-ldld
 479                 G_MODULE_IMPL=G_MODULE_IMPL_DLD
 480         ,)
 481 fi
 482 dnl *** additional checks for G_MODULE_IMPL_DL
 483 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 484         case "$host_os" in
 485           linux*)
 486             G_MODULE_LDFLAGS='-rdynamic'
 487             ;;
 488         esac
 489         LIBS_orig="$LIBS"
 490         LDFLAGS_orig="$LDFLAGS"
 491         LIBS="$LIBS $G_MODULE_LIBS"
 492         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 493 dnl *** check whether we need preceeding underscores
 494         AC_MSG_CHECKING(for preceeding underscore in symbols)
 495         AC_CACHE_VAL(glib_cv_uscore,[
 496                 AC_TRY_RUN([
 497                 #include <dlfcn.h>
 498                 int glib_underscore_test (void) { return 42; }
 499                 int main() {
 500                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 501                   handle = dlopen ((void*)0, 0);
 502                   if (handle) {
 503                     f1 = dlsym (handle, "glib_underscore_test");
 504                     f2 = dlsym (handle, "_glib_underscore_test");
 505                   } return (!f2 || f1);
 506                 }],
 507                         glib_cv_uscore=yes,
 508                         glib_cv_uscore=no,
 509                 )
 510                 rm -f plugin.c plugin.o plugin.lo
 511         ])
 512         AC_MSG_RESULT($glib_cv_uscore)
 513         if test "x$glib_cv_uscore" = "xyes"; then
 514                 G_MODULE_NEED_USCORE=1
 515         else
 516                 G_MODULE_NEED_USCORE=0
 517         fi
 518
 519         LDFLAGS="$LDFLAGS_orig"
 520 dnl *** check for having dlerror()
 521         AC_CHECK_FUNC(dlerror,
 522                 G_MODULE_HAVE_DLERROR=1,
 523                 G_MODULE_HAVE_DLERROR=0)
 524         LIBS="$LIBS_orig"
 525 fi
 526 dnl *** done, have e got an implementation?
 527 if test -z "$G_MODULE_IMPL"; then
 528         G_MODULE_IMPL=0
 529 fi
 530 AC_SUBST(G_MODULE_IMPL)
 531 AC_SUBST(G_MODULE_LIBS)
 532 AC_SUBST(G_MODULE_LDFLAGS)
 533 AC_SUBST(G_MODULE_HAVE_DLERROR)
 534 AC_SUBST(G_MODULE_NEED_USCORE)
 535 AC_SUBST(GLIB_DEBUG_FLAGS)
 536
 537
 538 dnl ***********************
 539 dnl *** g_thread checks ***
 540 dnl ***********************
 541
 542 AC_ARG_WITH(threads, [  --with-threads=[none/posix/solaris/nspr] specify a thread implementation to use],
 543         if test "x$with_threads" = x; then
 544                 want_threads=yes
 545         else
 546                 want_threads=$with_threads
 547         fi,
 548         want_threads=yes)
 549 if test "x$enable_threads" = "xno"; then
 550         want_threads=no
 551 fi
 552 if test "x$want_threads" = "xnone"; then
 553         want_threads=no
 554 fi
 555
 556 dnl error and warning message
 557 dnl *************************
 558
 559 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
 560                 computer. glib will not be thread safe on your computer."
 561
 562 FLAG_DOES_NOT_WORK="I can't find the MACRO, that enables thread safety on your
 563                 platform (normaly it's "_REENTRANT"). I'll not use any flag on
 564                 compilation now, but then your programs might not work.
 565                 Please provide information on how it is done on your system."
 566
 567 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
 568                 "
 569
 570 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
 571                 provide informationon your thread implementation."
 572
 573 dnl determination of thread implementation
 574 dnl ***************************************
 575
 576 have_threads=none
 577 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
 578         case $host in
 579                 *-*-solaris*)
 580                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
 581                 ;;
 582         esac
 583 fi
 584 if test "x$want_threads" = xyes || test "x$want_threads" = xposix; then
 585         if test "x$have_threads" = xnone; then
 586                 AC_CHECK_LIB(pthread, pthread_attr_init, have_threads=posix)
 587         fi
 588         if test "x$have_threads" = xnone; then
 589                 AC_CHECK_LIB(pthreads, pthread_attr_init, have_threads=posix)
 590         fi
 591         if test "x$have_threads" = xnone; then
 592                 AC_CHECK_LIB(c_r, pthread_attr_init, have_threads=posix)
 593         fi
 594         if test "x$have_threads" = xnone; then
 595                 AC_CHECK_FUNC(pthread_attr_init, have_threads=posix)
 596         fi
 597         dnl ********** DG/UX ************
 598         if test "x$have_threads" = xnone; then
 599                 AC_CHECK_LIB(thread, __d10_pthread_attr_init,
 600                         have_threads=posix)
 601         fi
 602 fi
 603 if test "x$want_threads" = xyes || test "x$want_threads" = xnspr; then
 604         if test "x$have_threads" = xnone; then
 605                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar, have_threads=nspr)
 606         fi
 607 fi
 608
 609 AC_MSG_CHECKING(for thread implementation)
 610
 611 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
 612         AC_MSG_RESULT(none available)
 613         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
 614 else
 615         AC_MSG_RESULT($have_threads)
 616 fi
 617
 618
 619 dnl determination of G_THREAD_LIBS
 620 dnl ******************************
 621
 622 G_THREAD_LIBS=
 623 G_THREAD_CFLAGS=
 624
 625 mutex_has_default=no
 626 case $have_threads in
 627         posix)
 628                 G_THREAD_LIBS=error
 629                 AC_CHECK_LIB(pthread, pthread_attr_init,
 630                              G_THREAD_LIBS="-lpthread")
 631                 if test "x$G_THREAD_LIBS" = xerror; then
 632                         AC_CHECK_LIB(pthreads, pthread_attr_init,
 633                                 G_THREAD_LIBS="-lpthreads")
 634                 fi
 635                 if test "x$G_THREAD_LIBS" = xerror; then
 636                         AC_CHECK_LIB(c_r, pthread_attr_init,
 637                                 G_THREAD_LIBS="-lc_r")
 638                 fi
 639                 if test "x$G_THREAD_LIBS" = xerror; then
 640                         AC_CHECK_FUNC(pthread_attr_init, G_THREAD_LIBS="")
 641                 fi
 642                 dnl ********** DG/UX ************
 643                 if test "x$G_THREAD_LIBS" = xerror; then
 644                         AC_CHECK_LIB(thread, __d10_pthread_attr_init,
 645                                 G_THREAD_LIBS="-lthread"
 646                                 G_THREAD_CFLAGS="-D_POSIX4A_DRAFT10_SOURCE")
 647                 fi
 648                 mutex_has_default=yes
 649                 mutex_default_type='pthread_mutex_t'
 650                 mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
 651                 mutex_header_file='pthread.h'
 652                 g_threads_impl="POSIX"
 653                 ;;
 654         solaris)
 655                 G_THREAD_LIBS=error
 656                 AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
 657                 mutex_has_default=yes
 658                 mutex_default_type='mutex_t'
 659                 mutex_default_init="DEFAULTMUTEX"
 660                 mutex_header_file='thread.h'
 661                 g_threads_impl="SOLARIS"
 662                 ;;
 663         nspr)
 664                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar,
 665                              G_THREAD_LIBS="-lnspr21")
 666                 g_threads_impl="NSPR"
 667                 ;;
 668         none)
 669                 g_threads_impl="NONE"
 670                 ;;
 671         *)
 672                 g_threads_impl="NONE"
 673                 G_THREAD_LIBS=error
 674                 ;;
 675 esac
 676
 677 if test "x$G_THREAD_LIBS" = xerror; then
 678         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 679 fi
 680
 681 AC_MSG_CHECKING(necessary linker options)
 682 AC_MSG_RESULT($G_THREAD_LIBS)
 683
 684 dnl check for mt safe function variants
 685 dnl ***********************************
 686
 687 if test x"$have_threads" != xnone; then
 688         glib_save_LIBS="$LIBS"
 689         LIBS="$LIBS $G_THREAD_LIBS"
 690         AC_CHECK_FUNCS(localtime_r rand_r)
 691         if test "$ac_cv_header_pwd_h" = "yes"; then
 692                 AC_CHECK_FUNCS(getpwuid_r)
 693                 if test "$ac_cv_func_getpwuid_r" = "yes"; then
 694                         AC_MSG_CHECKING(whether getpwuid_r is posix like)
 695                         # getpwuid_r(0, NULL, NULL, 0) is the signature on
 696                         # solaris, if that is not found, the prog below won't
 697                         # compile, then the posix signature is assumed as
 698                         # the default.
 699                         AC_TRY_COMPILE([#include <pwd.h>],
 700                                 [getpwuid_r(0, NULL, NULL, 0);],
 701                                 [AC_MSG_RESULT(no)],
 702                                 [AC_MSG_RESULT(yes)
 703                                 AC_DEFINE(HAVE_GETPWUID_R_POSIX)])
 704                 fi
 705         fi
 706         LIBS="$glib_save_LIBS"
 707 fi
 708
 709 dnl determination of G_THREAD_CFLAGS
 710 dnl ********************************
 711
 712 if test x"$have_threads" != xnone; then
 713 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_REENTRANT" # good default guess
 714
 715     case $host in
 716         *-aix*)
 717                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 718                 if test x"$GCC" = xyes; then
 719                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
 720                 fi
 721                 ;;
 722         *-freebsd2.2*)
 723                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 724
 725                 # FreeBSD 2.2.x shiped with gcc 2.7.2.x, which doesn't support
 726                 # -mthreads flag.
 727                 ;;
 728     esac
 729
 730     # if we are not finding the ctime_r function, then we probably are
 731     # not using the proper multithread flag
 732     old_CPPFLAGS=$CPPFLAGS
 733     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
 734     AC_EGREP_HEADER([[^a-zA-Z_]ctime_r[^a-zA-Z_]], time.h, ,
 735     G_THREAD_CFLAGS=
 736     AC_MSG_WARN($FLAG_DOES_NOT_WORK))
 737     CPPFLAGS=$old_CPPFLAGS
 738
 739     AC_MSG_CHECKING(necessary compiler options)
 740
 741     AC_MSG_RESULT($G_THREAD_CFLAGS)
 742 else
 743     G_THREAD_CFLAGS=
 744 fi
 745
 746 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c")
 747 AC_SUBST(G_THREAD_CFLAGS)
 748 AC_SUBST(G_THREAD_LIBS)
 749
 750 CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 751
 752 dnl **********************************************
 753 dnl *** GDefaultMutex setup and initialization ***
 754 dnl **********************************************
 755 dnl
 756 dnl if mutex_has_default = yes, we also got
 757 dnl mutex_default_type, mutex_default_init and mutex_header_file
 758 GLIB_IF_VAR_EQ(mutex_has_default, yes,
 759         GLIB_SIZEOF([#include <$mutex_header_file>],
 760                     $mutex_default_type,
 761                     gmutex,
 762                     )
 763         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
 764                            $mutex_default_type,
 765                            gmutex,
 766                            $glib_cv_sizeof_gmutex,
 767                            $mutex_default_init)
 768         ,
 769 )
 770
 771
 772 dnl ****************************************
 773 dnl *** GLib POLL* compatibility defines ***
 774 dnl ****************************************
 775 GLIB_SYSDEFS(
 776 [#include <sys/types.h>
 777 #include <sys/poll.h>],
 778         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
 779         glibconfig-sysdefs.h,
 780         =)
 781
 782
 783 dnl ******************************
 784 dnl *** output the whole stuff ***
 785 dnl ******************************
 786
 787 AC_OUTPUT_COMMANDS([
 788
 789 ## Generate `glibconfig.h' in two cases
 790 ## 1. `config.status' is run either explicitly, or via configure.
 791 ##     Esp. not when it is run in `Makefile' to generate makefiles and
 792 ##     config.h
 793 ## 2. CONFIG_OTHER is set explicitly
 794 ##
 795 ## Case 1 is difficult.  We know that `automake' sets one of
 796 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
 797 ## only when AM_CONFIG_HEADER is set, however.
 798
 799 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
 800   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
 801   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
 802 fi
 803 case "$CONFIG_OTHER" in
 804 *glibconfig.h*)
 805         echo creating glibconfig.h
 806         outfile=glibconfig.h-tmp
 807         cat > $outfile <<\_______EOF
 808 /* glibconfig.h
 809  *
 810  * This is a generated file.  Please modify `configure.in'
 811  */
 812
 813 #ifndef GLIBCONFIG_H
 814 #define GLIBCONFIG_H
 815
 816 #ifdef __cplusplus
 817 extern "C" {
 818 #endif /* __cplusplus */
 819
 820 _______EOF
 821
 822         if test x$glib_limits_h = xyes; then
 823           echo '#include <limits.h>' >> $outfile
 824         fi
 825         if test x$glib_float_h = xyes; then
 826           echo '#include <float.h>' >> $outfile
 827         fi
 828         if test x$glib_values_h = xyes; then
 829           echo '#include <values.h>' >> $outfile
 830         fi
 831         if test x$g_mutex_header_file != x; then
 832           echo '#include <'"$g_mutex_header_file"'>' >> $outfile
 833         fi
 834         if test x$glib_sys_poll_h = xyes; then
 835           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
 836         fi
 837
 838         cat >> $outfile <<_______EOF
 839
 840 #define G_MINFLOAT      $glib_mf
 841 #define G_MAXFLOAT      $glib_Mf
 842 #define G_MINDOUBLE     $glib_md
 843 #define G_MAXDOUBLE     $glib_Md
 844 #define G_MINSHORT      $glib_ms
 845 #define G_MAXSHORT      $glib_Ms
 846 #define G_MININT        $glib_mi
 847 #define G_MAXINT        $glib_Mi
 848 #define G_MINLONG       $glib_ml
 849 #define G_MAXLONG       $glib_Ml
 850
 851 _______EOF
 852
 853
 854         ### this should always be true in a modern C/C++ compiler
 855         cat >>$outfile <<_______EOF
 856 typedef signed char gint8;
 857 typedef unsigned char guint8;
 858 _______EOF
 859
 860
 861         if test -n "$gint16"; then
 862           cat >>$outfile <<_______EOF
 863 typedef signed $gint16 gint16;
 864 typedef unsigned $gint16 guint16;
 865 _______EOF
 866         fi
 867
 868
 869         if test -n "$gint32"; then
 870           cat >>$outfile <<_______EOF
 871 typedef signed $gint32 gint32;
 872 typedef unsigned $gint32 guint32;
 873 _______EOF
 874         fi
 875
 876
 877         if test -n "$gint64"; then
 878           cat >>$outfile <<_______EOF
 879 ${glib_warning_guard}#define G_HAVE_GINT64 1
 880
 881 ${glib_extension}typedef signed $gint64 gint64;
 882 ${glib_extension}typedef unsigned $gint64 guint64;
 883
 884 #define G_GINT64_CONSTANT(val)  $gint64_constant
 885 _______EOF
 886         fi
 887
 888
 889         if test -z "$glib_unknown_void_p"; then
 890           cat >>$outfile <<_______EOF
 891
 892 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
 893 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
 894
 895 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
 896 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
 897 _______EOF
 898         else
 899           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
 900         fi
 901
 902
 903
 904         cat >>$outfile <<_______EOF
 905 $glib_atexit
 906 $glib_memmove
 907 $glib_defines
 908
 909 $glib_vacopy
 910
 911 #ifdef  __cplusplus
 912 #define G_HAVE_INLINE   1
 913 #else   /* !__cplusplus */
 914 $glib_inline
 915 #endif  /* !__cplusplus */
 916 _______EOF
 917
 918         echo >>$outfile
 919         if test x$g_mutex_has_default = xyes; then
 920                 cat >>$outfile <<_______EOF
 921 $g_enable_threads_def G_THREADS_ENABLED
 922 #define G_THREADS_IMPL_$g_threads_impl_def
 923 typedef struct _GStaticMutex GStaticMutex;
 924 struct _GStaticMutex
 925 {
 926   struct _GMutex *runtime_mutex;
 927   union {
 928     char   pad[$g_mutex_sizeof];
 929     double dummy_double;
 930     void  *dummy_pointer;
 931     long   dummy_long;
 932   } aligned_pad_u;
 933 };
 934 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
 935 #define g_static_mutex_get_mutex(mutex) \
 936   (g_thread_use_default_impl ? ((GMutex*) &(mutex).aligned_pad_u) : \
 937    g_static_mutex_get_mutex_impl (&(mutex).runtime_mutex))
 938 _______EOF
 939         else
 940                 cat >>$outfile <<_______EOF
 941 $g_enable_threads_def G_THREADS_ENABLED
 942 #define $g_threads_impl_def
 943 typedef struct _GMutex* GStaticMutex;
 944 #define G_STATIC_MUTEX_INIT NULL
 945 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (&(mutex)))
 946 _______EOF
 947         fi
 948
 949         echo >>$outfile
 950         g_bit_sizes="16 32"
 951         if test -n "$gint64"; then
 952           g_bit_sizes="$g_bit_sizes 64"
 953         fi
 954         for bits in $g_bit_sizes; do
 955           cat >>$outfile <<_______EOF
 956 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
 957 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
 958 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
 959 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
 960 _______EOF
 961         done
 962
 963         cat >>$outfile <<_______EOF
 964 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
 965 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
 966 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
 967 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
 968 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
 969 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
 970 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
 971 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
 972 #define G_BYTE_ORDER $g_byte_order
 973
 974 _______EOF
 975
 976         if test -r glibconfig-sysdefs.h; then
 977           cat glibconfig-sysdefs.h >>$outfile
 978         fi
 979
 980
 981         cat >>$outfile <<_______EOF
 982
 983 $glib_wc
 984
 985
 986 #ifdef __cplusplus
 987 }
 988 #endif /* __cplusplus */
 989
 990 #endif /* GLIBCONFIG_H */
 991 _______EOF
 992
 993
 994         if cmp -s $outfile glibconfig.h; then
 995           echo glibconfig.h is unchanged
 996           rm -f $outfile
 997         else
 998           mv $outfile glibconfig.h
 999         fi ;;
1000 esac
1001 ],[
1002
1003 # Note that if two cases are the same, case goes with the first one.
1004 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
1005 # on variable expansion in case labels.  Look at the generated config.status
1006 # for a hint.
1007
1008 case xyes in
1009 x$ac_cv_header_float_h)
1010   glib_float_h=yes
1011   glib_mf=FLT_MIN glib_Mf=FLT_MAX
1012   glib_md=DBL_MIN glib_Md=DBL_MAX
1013   ;;
1014 x$ac_cv_header_values_h)
1015   glib_values_h=yes
1016   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
1017   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
1018   ;;
1019 esac
1020
1021 case xyes in
1022 x$ac_cv_header_limits_h)
1023   glib_limits_h=yes
1024   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX
1025   glib_mi=INT_MIN  glib_Mi=INT_MAX
1026   glib_ml=LONG_MIN glib_Ml=LONG_MAX
1027   ;;
1028 x$ac_cv_header_values_h)
1029   glib_values_h=yes
1030   glib_ms=MINSHORT glib_Ms=MAXSHORT
1031   glib_mi=MININT   glib_Mi=MAXINT
1032   glib_ml=MINLONG  glib_Ml=MAXLONG
1033   ;;
1034 esac
1035
1036 if test x$ac_cv_header_sys_poll_h = xyes ; then
1037   glib_sys_poll_h=yes
1038 fi
1039
1040 case 2 in
1041 $ac_cv_sizeof_short)            gint16=short;;
1042 $ac_cv_sizeof_int)              gint16=int;;
1043 esac
1044 case 4 in
1045 $ac_cv_sizeof_short)            gint32=short;;
1046 $ac_cv_sizeof_int)              gint32=int;;
1047 $ac_cv_sizeof_long)             gint32=long;;
1048 esac
1049 case 8 in
1050 $ac_cv_sizeof_int)
1051   gint64=int
1052   glib_extension=
1053   glib_warning_guard=
1054   gint64_constant='(val)'
1055   ;;
1056 $ac_cv_sizeof_long)
1057   gint64=long
1058   glib_extension=
1059   glib_warning_guard=
1060   gint64_constant='(val##L)'
1061   ;;
1062 $ac_cv_sizeof_long_long)
1063   gint64='long long'
1064   glib_extension='G_GNUC_EXTENSION '
1065   glib_warning_guard="
1066 #if defined (__GNUC__) && __GNUC__ >= 2 && __GNUC_MINOR__ >= 8
1067 #  define G_GNUC_EXTENSION __extension__
1068 #else
1069 #  define G_GNUC_EXTENSION
1070 #endif
1071
1072 "
1073   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1074   ;;
1075 esac
1076
1077 gintbits=`expr $ac_cv_sizeof_int \* 8`
1078 glongbits=`expr $ac_cv_sizeof_long \* 8`
1079
1080
1081 case $ac_cv_sizeof_void_p in
1082 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
1083 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
1084 *)                      glib_unknown_void_p=yes ;;
1085 esac
1086
1087
1088 case xyes in
1089 x$ac_cv_func_atexit)
1090   glib_atexit="
1091 #ifdef NeXT /* @#%@! NeXTStep */
1092 # define g_ATEXIT(proc) (!atexit (proc))
1093 #else
1094 # define g_ATEXIT(proc) (atexit (proc))
1095 #endif"
1096   ;;
1097 x$ac_cv_func_on_exit)
1098   glib_atexit="
1099 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
1100   ;;
1101 esac
1102
1103 case xyes in
1104 x$ac_cv_func_memmove)
1105   glib_memmove='
1106 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
1107   ;;
1108 *)
1109   glib_memmove="
1110 /* We make the assumption that if memmove isn't available, then
1111  * bcopy will do the job. This isn't safe everywhere. (bcopy can't
1112  * necessarily handle overlapping copies) */
1113 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
1114   ;;
1115 esac
1116
1117 glib_defines="
1118 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
1119 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
1120 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
1121 "
1122
1123 case xyes in
1124 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
1125 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
1126 *)                      glib_vacopy=''
1127 esac
1128
1129 if test x$glib_cv_va_val_copy = xno; then
1130   glib_vacopy="\$glib_vacopy
1131 #define G_VA_COPY_AS_ARRAY 1"
1132 fi
1133
1134 if test x$glib_cv_hasinline = xyes; then
1135     glib_inline='#define G_HAVE_INLINE 1'
1136 fi
1137 if test x$glib_cv_has__inline = xyes; then
1138     glib_inline="\$glib_inline
1139 #define G_HAVE___INLINE 1"
1140 fi
1141 if test x$glib_cv_has__inline__ = xyes; then
1142     glib_inline="\$glib_inline
1143 #define G_HAVE___INLINE__ 1"
1144 fi
1145
1146 case xyes in
1147 x$ac_cv_c_bigendian)
1148   g_byte_order=G_BIG_ENDIAN
1149   g_bs_native=BE
1150   g_bs_alien=LE
1151   ;;
1152 *)
1153   g_byte_order=G_LITTLE_ENDIAN
1154   g_bs_native=LE
1155   g_bs_alien=BE
1156   ;;
1157 esac
1158
1159 if test x$glib_wchar_h = xyes; then
1160   glib_wc='
1161 #define G_HAVE_WCHAR_H 1'
1162 fi
1163 if test x$glib_wctype_h = xyes; then
1164   glib_wc="\$glib_wc
1165 #define G_HAVE_WCTYPE_H 1"
1166 fi
1167 if test x$glib_working_wctype = xno; then
1168   glib_wc="\$glib_wc
1169 #define G_HAVE_BROKEN_WCTYPE 1"
1170 fi
1171
1172 case x$enable_threads in
1173 xyes)   g_enable_threads_def="#define";;
1174 *)      g_enable_threads_def="#undef ";;
1175 esac
1176
1177 g_threads_impl_def=$g_threads_impl
1178
1179 g_mutex_has_default="$mutex_has_default"
1180 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
1181 g_mutex_contents="$glib_cv_byte_contents_gmutex"
1182 ])
1183
1184 AC_OUTPUT([
1185 Makefile
1186 glib-config
1187 gmodule/gmoduleconf.h
1188 gmodule/Makefile
1189 gthread/Makefile
1190 docs/Makefile
1191 tests/Makefile
1192 ],[case "$CONFIG_FILES" in
1193 *glib-config*)chmod +x glib-config;;
1194 esac])