configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 dnl ***********************************
   6 dnl *** include special GLib macros ***
   7 dnl ***********************************
   8
   9 m4_define(glib_configure_in)
  10
  11 #
  12 # The following version number definitions apply to GLib, GModule, GObject
  13 # and GThread as a whole, so if changes occoured in any of them, they are all
  14 # treated with the same interface and binary age.
  15 #
  16 # Making releases:
  17 #   glib_micro_version += 1;
  18 #   glib_interface_age += 1;
  19 #   glib_binary_age += 1;
  20 # if any functions have been added, set glib_interface_age to 0.
  21 # if backwards compatibility has been broken,
  22 # set glib_binary_age _and_ glib_interface_age to 0.
  23 #
  24 m4_define([glib_major_version], [2])
  25 m4_define([glib_minor_version], [19])
  26 m4_define([glib_micro_version], [1])
  27 m4_define([glib_interface_age], [0])
  28 m4_define([glib_binary_age],
  29           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  30 m4_define([glib_version],
  31           [glib_major_version.glib_minor_version.glib_micro_version])
  32
  33 # libtool version related macros
  34 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  35 m4_define([glib_lt_current],
  36           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  37 m4_define([glib_lt_revision], [glib_interface_age])
  38 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  39 m4_define([glib_lt_current_minus_age],
  40           [m4_eval(glib_lt_current - glib_lt_age)])
  41
  42 # if the minor version number is odd, then we want debugging.  Otherwise
  43 # we only want minimal debugging support.
  44 m4_define([glib_debug_default],
  45           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  46
  47
  48 AC_INIT(glib, [glib_version],
  49         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  50
  51 AC_CONFIG_SRCDIR([glib/glib.h])
  52
  53 # Save this value here, since automake will set cflags later
  54 cflags_set=${CFLAGS+set}
  55
  56 AM_INIT_AUTOMAKE([no-define])
  57
  58 # Specify a configuration file
  59 AM_CONFIG_HEADER([config.h])
  60
  61
  62 GLIB_MAJOR_VERSION=glib_major_version
  63 GLIB_MINOR_VERSION=glib_minor_version
  64 GLIB_MICRO_VERSION=glib_micro_version
  65 GLIB_INTERFACE_AGE=glib_interface_age
  66 GLIB_BINARY_AGE=glib_binary_age
  67 GLIB_VERSION=glib_version
  68
  69 AC_SUBST(GLIB_MAJOR_VERSION)
  70 AC_SUBST(GLIB_MINOR_VERSION)
  71 AC_SUBST(GLIB_MICRO_VERSION)
  72 AC_SUBST(GLIB_VERSION)
  73 AC_SUBST(GLIB_INTERFACE_AGE)
  74 AC_SUBST(GLIB_BINARY_AGE)
  75
  76 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  77           [Define to the GLIB major version])
  78 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  79           [Define to the GLIB minor version])
  80 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  81           [Define to the GLIB micro version])
  82 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  83           [Define to the GLIB interface age])
  84 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  85           [Define to the GLIB binary age])
  86
  87 # libtool versioning
  88 LT_RELEASE=glib_lt_release
  89 LT_CURRENT=glib_lt_current
  90 LT_REVISION=glib_lt_revision
  91 LT_AGE=glib_lt_age
  92 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
  93 AC_SUBST(LT_RELEASE)
  94 AC_SUBST(LT_CURRENT)
  95 AC_SUBST(LT_REVISION)
  96 AC_SUBST(LT_AGE)
  97 AC_SUBST(LT_CURRENT_MINUS_AGE)
  98
  99 dnl Initialize maintainer mode
 100 AM_MAINTAINER_MODE
 101
 102 AC_CANONICAL_HOST
 103
 104 AC_MSG_CHECKING([for the BeOS])
 105 case $host in
 106   *-*-beos*)
 107     glib_native_beos="yes"
 108     ;;
 109   *)
 110     glib_native_beos="no"
 111     ;;
 112 esac
 113 AC_MSG_RESULT([$glib_native_beos])
 114
 115 dnl
 116
 117 AC_MSG_CHECKING([for Win32])
 118 LIB_EXE_MACHINE_FLAG=X86
 119 case "$host" in
 120   *-*-mingw*)
 121     glib_native_win32=yes
 122     glib_pid_type='void *'
 123     glib_cv_stack_grows=no
 124     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 125     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 126     # (Sorry, I don't know exactly what is the problem, but it is related to
 127     # floating point formatting and decimal point vs. comma.)
 128     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 129     # rigorous enough to notice, though.
 130     # So preset the autoconf cache variables.
 131     ac_cv_func_vsnprintf_c99=no
 132     ac_cv_func_snprintf_c99=no
 133     case "$host" in
 134     x86_64-*-*)
 135       LIB_EXE_MACHINE_FLAG=X64
 136       ;;
 137     esac
 138     ;;
 139   *)
 140     glib_native_win32=no
 141     glib_pid_type=int
 142     ;;
 143 esac
 144 case $host in
 145   *-*-linux*)
 146     glib_os_linux=yes
 147     ;;
 148 esac
 149
 150 AC_MSG_RESULT([$glib_native_win32])
 151
 152 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 153
 154 glib_have_carbon=no
 155 AC_MSG_CHECKING([for Mac OS X Carbon support])
 156 AC_TRY_CPP([
 157 #include <Carbon/Carbon.h>
 158 #include <CoreServices/CoreServices.h>
 159 ], glib_have_carbon=yes)
 160
 161 AC_MSG_RESULT([$glib_have_carbon])
 162
 163 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 164 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 165 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 166 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 167 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 168
 169 if test "$glib_native_win32" = "yes"; then
 170   AC_CHECK_TOOL(WINDRES, windres, no)
 171   if test "$WINDRES" = no; then
 172     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 173   fi
 174   AC_CHECK_TOOL(NM, nm, no)
 175   if test "$NM" = no; then
 176     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 177   fi
 178   AC_CHECK_TOOL(RANLIB, ranlib, :)
 179   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 180 fi
 181 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 182
 183 if test "$glib_native_win32" != yes; then
 184     # libtool option to control which symbols are exported
 185     # right now, symbols starting with _ are not exported
 186     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 187 else
 188     # We currently use .def files on Windows
 189     LIBTOOL_EXPORT_OPTIONS=
 190 fi
 191 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 192
 193 if test "x$glib_have_carbon" = "xyes"; then
 194   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 195   LDFLAGS="$LDFLAGS -framework Carbon"
 196 fi
 197
 198
 199 dnl declare --enable-* args and collect ac_help strings
 200 AC_ARG_ENABLE(debug,
 201               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 202                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 203               enable_debug=glib_debug_default)
 204
 205 AC_ARG_ENABLE(gc_friendly,
 206               [AC_HELP_STRING([--enable-gc-friendly],
 207                               [turn on garbage collector friendliness [default=no]])],,
 208               [enable_gc_friendly=no])
 209 AC_ARG_ENABLE(mem_pools,
 210               [AC_HELP_STRING([--disable-mem-pools],
 211                               [disable all glib memory pools])],,
 212               [disable_mem_pools=no])
 213 AC_ARG_ENABLE(threads,
 214               [AC_HELP_STRING([--enable-threads],
 215                               [turn on basic thread support [default=yes]
 216 ([=no] will override --with-threads)])],,
 217               [enable_threads=yes])
 218 AC_ARG_ENABLE(rebuilds,
 219               [AC_HELP_STRING([--disable-rebuilds],
 220                               [disable all source autogeneration rules])],,
 221               [enable_rebuilds=yes])
 222 AC_ARG_ENABLE(visibility,
 223               [AC_HELP_STRING([--disable-visibility],
 224                               [don't use ELF visibility attributes])],,
 225               [enable_visibility=yes])
 226
 227 if test "x$enable_threads" != "xyes"; then
 228   enable_threads=no
 229 fi
 230
 231 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 232 if test "x$enable_gc_friendly" = "xyes"; then
 233   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 234   AC_MSG_RESULT([yes])
 235 else
 236   AC_MSG_RESULT([no])
 237 fi
 238
 239 AC_MSG_CHECKING([whether to disable memory pools])
 240 if test "x$disable_mem_pools" = "xno"; then
 241   AC_MSG_RESULT([no])
 242 else
 243   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 244   AC_SUBST(DISABLE_MEM_POOLS)
 245   AC_MSG_RESULT([yes])
 246 fi
 247
 248 dnl Checks for programs.
 249 AC_PROG_CC
 250 AC_PROG_CPP
 251
 252 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 253 AC_CHECK_PROGS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 254 AC_LANG_SAVE
 255 AC_LANG_CPLUSPLUS
 256 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 257 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 258 AC_LANG_RESTORE
 259
 260 AM_PROG_CC_STDC
 261 AM_PROG_CC_C_O
 262 AC_PROG_INSTALL
 263
 264 AC_SYS_LARGEFILE
 265
 266 #
 267 # Find pkg-config
 268 #
 269 AC_PATH_PROG(PKG_CONFIG, [pkg-config], [no])
 270 if test x$PKG_CONFIG = xno ; then
 271   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
 272 fi
 273
 274 if $PKG_CONFIG --atleast-pkgconfig-version 0.16 ; then
 275   :
 276 else
 277   AC_MSG_ERROR([*** pkg-config too old; version 0.16 or better required.])
 278 fi
 279
 280 if test "x$enable_debug" = "xyes"; then
 281   if test x$cflags_set != xset ; then
 282       case " $CFLAGS " in
 283       *[[\ \    ]]-g[[\ \       ]]*) ;;
 284       *) CFLAGS="$CFLAGS -g" ;;
 285       esac
 286   fi
 287
 288   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 289 else
 290   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 291
 292   if test "x$enable_debug" = "xno"; then
 293     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 294   fi
 295 fi
 296
 297 if test "x$enable_visibility" = "xno"; then
 298   GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DDISABLE_VISIBILITY"
 299 fi
 300
 301 # Ensure MSVC-compatible struct packing convention is used when
 302 # compiling for Win32 with gcc.
 303 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 304 # gcc2 uses "-fnative-struct".
 305 if test x"$glib_native_win32" = xyes; then
 306   if test x"$GCC" = xyes; then
 307     msnative_struct=''
 308     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 309     if test -z "$ac_cv_prog_CC"; then
 310       our_gcc="$CC"
 311     else
 312       our_gcc="$ac_cv_prog_CC"
 313     fi
 314     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 315       2.)
 316         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 317           msnative_struct='-fnative-struct'
 318         fi
 319         ;;
 320       *)
 321         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 322           msnative_struct='-mms-bitfields'
 323         fi
 324         ;;
 325     esac
 326     if test x"$msnative_struct" = x ; then
 327       AC_MSG_RESULT([no way])
 328       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 329     else
 330       CFLAGS="$CFLAGS $msnative_struct"
 331       AC_MSG_RESULT([${msnative_struct}])
 332     fi
 333   fi
 334 fi
 335 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 336 AC_SUBST(GLIB_EXTRA_CFLAGS)
 337
 338 AC_EXEEXT
 339
 340 # define a MAINT-like variable REBUILD which is set if Perl
 341 # and awk are found, so autogenerated sources can be rebuilt
 342 AC_PROG_AWK
 343 AC_CHECK_PROGS(PERL, [perl5 perl])
 344 # We would like indent, but don't require it.
 345 AC_CHECK_PROG(INDENT, indent, indent)
 346 REBUILD=\#
 347 if test "x$enable_rebuilds" = "xyes" && \
 348      test -n "$PERL" && \
 349      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 350      test -n "$AWK" ; then
 351   REBUILD=
 352 fi
 353 AC_SUBST(REBUILD)
 354
 355 # Need full path to Perl for glib-mkenums
 356 #
 357 if test "x$PERL" != x ; then
 358   AC_PATH_PROG(PERL_PATH, [$PERL])
 359 fi
 360 if test "x$PERL_PATH" = x ; then
 361   PERL_PATH="/usr/bin/env perl"
 362 fi
 363 AC_SUBST(PERL_PATH)
 364
 365 # Need suitable python path for greport
 366 AM_PATH_PYTHON(2.4,,PYTHON="/usr/bin/env python2.4")
 367
 368
 369 dnl ***********************
 370 dnl *** Tests for iconv ***
 371 dnl ***********************
 372 dnl
 373 dnl We do this before the gettext checks, to avoid distortion
 374
 375 dnl On Windows we use a native implementation
 376
 377 if test x"$glib_native_win32" = xyes; then
 378   with_libiconv=native
 379 else
 380   AC_ARG_WITH(libiconv,
 381               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 382                               [use the libiconv library])],,
 383               [with_libiconv=maybe])
 384
 385   found_iconv=no
 386   case $with_libiconv in
 387     maybe)
 388       # Check in the C library first
 389       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 390       # Check if we have GNU libiconv
 391       if test $found_iconv = "no"; then
 392         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 393       fi
 394       # Check if we have a iconv in -liconv, possibly from vendor
 395       if test $found_iconv = "no"; then
 396         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 397       fi
 398       ;;
 399     no)
 400       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 401       ;;
 402     gnu|yes)
 403       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 404       ;;
 405     native)
 406       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 407       ;;
 408   esac
 409
 410   if test "x$found_iconv" = "xno" ; then
 411      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 412   fi
 413 fi
 414
 415 gl_GLIBC21
 416 AC_ARG_ENABLE(iconv-cache,
 417               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 418                               [cache iconv descriptors [default=auto]])],,
 419               [enable_iconv_cache=auto])
 420
 421 AC_MSG_CHECKING([Whether to cache iconv descriptors])
 422 case $enable_iconv_cache in
 423   auto)
 424     if test $ac_cv_gnu_library_2_1 = yes; then
 425       enable_iconv_cache=no
 426     else
 427       enable_iconv_cache=yes
 428     fi
 429   ;;
 430   yes|no)
 431   ;;
 432   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 433   ;;
 434 esac
 435
 436 if test $enable_iconv_cache = yes; then
 437    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 438 fi
 439
 440 AC_MSG_RESULT($enable_iconv_cache)
 441
 442
 443 dnl
 444 dnl gettext support
 445 dnl
 446
 447 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 448 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 449 GLIB_GNU_GETTEXT
 450
 451 if test "$gt_cv_have_gettext" != "yes" ; then
 452   AC_MSG_ERROR([
 453 *** You must have either have gettext support in your C library, or use the
 454 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 455 ])
 456 fi
 457
 458 LIBS="$INTLLIBS $LIBS"
 459
 460 GETTEXT_PACKAGE=glib20
 461 AC_SUBST(GETTEXT_PACKAGE)
 462 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 463   [Define the gettext package to be used])
 464
 465 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 466
 467 dnl
 468 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 469 dnl
 470
 471 if test x"$glib_native_win32" != xyes; then
 472   if test x$with_libiconv != xno ; then
 473     case " $INTLLIBS " in
 474     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 475     *) ICONV_LIBS="-liconv" ;;
 476     esac
 477   fi
 478 fi
 479 AC_SUBST(ICONV_LIBS)
 480
 481 case $with_libiconv in
 482   gnu)
 483     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 484     ;;
 485   native)
 486     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 487     ;;
 488 esac
 489
 490 dnl Initialize libtool
 491 AM_DISABLE_STATIC
 492 AC_LIBTOOL_WIN32_DLL
 493 AM_PROG_LIBTOOL
 494 dnl when using libtool 2.x create libtool early, because it's used in configure
 495 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 496
 497
 498 if test "x$GCC" = "xyes"; then
 499   case " $CFLAGS " in
 500   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 501   *) CFLAGS="$CFLAGS -Wall" ;;
 502   esac
 503 fi
 504
 505 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES"
 506
 507 if test "$glib_native_win32" = "yes"; then
 508   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 509     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 510   fi
 511   if test x$enable_static = xyes; then
 512     glib_win32_static_compilation=yes
 513     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 514 #define GOBJECT_STATIC_COMPILATION 1"
 515     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 516   fi
 517 fi
 518 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 519
 520 dnl
 521 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 522 dnl
 523 if test $cross_compiling != yes ; then
 524     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 525     glib_save_LIBS=$LIBS
 526     LIBS="$LIBS -lm"
 527     AC_TRY_RUN([#include <math.h>
 528                  int main (void) { return (log(1) != log(1.)); }],
 529          AC_MSG_RESULT(none needed),
 530          glib_save_CFLAGS=$CFLAGS
 531          CFLAGS="$CFLAGS -std1"
 532          AC_TRY_RUN([#include <math.h>
 533                      int main (void) { return (log(1) != log(1.)); }],
 534              AC_MSG_RESULT(-std1),
 535              AC_MSG_RESULT()
 536              CFLAGS=$glib_save_CFLAGS
 537              AC_MSG_WARN(
 538                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 539          )
 540     )
 541     LIBS=$glib_save_LIBS
 542 fi
 543
 544 dnl NeXTStep cc seems to need this
 545 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 546 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 547   AC_MSG_RESULT(none needed),
 548   glib_save_CFLAGS=$CFLAGS
 549   CFLAGS="$CFLAGS -posix"
 550   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 551     AC_MSG_RESULT(-posix),
 552     AC_MSG_RESULT()
 553     CFLAGS=$glib_save_CFLAGS
 554     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 555
 556 # Checks for header files.
 557 AC_HEADER_STDC
 558
 559 # Checks for library functions.
 560 AC_FUNC_VPRINTF
 561 AC_FUNC_ALLOCA
 562 AC_CHECK_FUNCS(mmap)
 563 AC_CHECK_FUNCS(posix_memalign)
 564 AC_CHECK_FUNCS(memalign)
 565 AC_CHECK_FUNCS(valloc)
 566
 567 AC_CHECK_FUNCS(atexit on_exit)
 568
 569 AC_CHECK_FUNCS(timegm gmtime_r)
 570
 571 AC_CHECK_SIZEOF(char)
 572 AC_CHECK_SIZEOF(short)
 573 AC_CHECK_SIZEOF(long)
 574 AC_CHECK_SIZEOF(int)
 575 AC_CHECK_SIZEOF(void *)
 576 AC_CHECK_SIZEOF(long long)
 577 AC_CHECK_SIZEOF(__int64)
 578
 579 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 580   :
 581 else
 582   AC_MSG_ERROR([
 583 *** GLib requires a 64 bit type. You might want to consider
 584 *** using the GNU C compiler.
 585 ])
 586 fi
 587
 588 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 589         # long long is a 64 bit integer.
 590         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 591         AC_CACHE_VAL(glib_cv_long_long_format,[
 592                 for format in ll q I64; do
 593                   AC_TRY_RUN([#include <stdio.h>
 594                         int main()
 595                         {
 596                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 597                           char buffer[1000];
 598                           sprintf (buffer, "%${format}u", a);
 599                           sscanf (buffer, "%${format}u", &b);
 600                           exit (b!=a);
 601                         }
 602                         ],
 603                         [glib_cv_long_long_format=${format}
 604                         break],
 605                         [],[:])
 606                 done])
 607         if test -n "$glib_cv_long_long_format"; then
 608           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 609           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 610           if test x"$glib_cv_long_long_format" = xI64; then
 611             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 612           fi
 613         else
 614           AC_MSG_RESULT(none)
 615         fi
 616 elif test x$ac_cv_sizeof___int64 = x8; then
 617         # __int64 is a 64 bit integer.
 618         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 619         # We know this is MSVCRT.DLL, and what the formats are
 620         glib_cv_long_long_format=I64
 621         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 622         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 623         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 624 fi
 625
 626 dnl long doubles were not used, and a portability problem
 627 dnl AC_C_LONG_DOUBLE
 628 AC_C_CONST
 629
 630 dnl ok, here we try to check whether the systems prototypes for
 631 dnl malloc and friends actually match the prototypes provided
 632 dnl by gmem.h (keep in sync). i currently only know how to check
 633 dnl this reliably with gcc (-Werror), improvements for other
 634 dnl compilers are apprechiated.
 635 SANE_MALLOC_PROTOS=no
 636 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 637 glib_save_CFLAGS=$CFLAGS
 638 if test "x$GCC" = "xyes"; then
 639   CFLAGS="$CFLAGS -Werror"
 640   AC_TRY_COMPILE([#include <stdlib.h>], [
 641     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 642     void* (*my_malloc_p)  (size_t)         = malloc;
 643     void  (*my_free_p)    (void*)          = free;
 644     void* (*my_realloc_p) (void*, size_t)  = realloc;
 645     my_calloc_p = 0;
 646     my_malloc_p = 0;
 647     my_free_p = 0;
 648     my_realloc_p = 0;
 649   ],
 650     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 651       [Define if you have correct malloc prototypes])
 652     SANE_MALLOC_PROTOS=yes)
 653 fi
 654 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 655 CFLAGS=$glib_save_CFLAGS
 656
 657 dnl
 658 dnl check in which direction the stack grows
 659 dnl
 660 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 661         AC_TRY_RUN([
 662         volatile int *a = 0, *b = 0;
 663         void foo (void);
 664         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 665         void foo (void) { volatile int x = 5; b = &x; }
 666         ],
 667         glib_cv_stack_grows=no
 668         ,
 669         glib_cv_stack_grows=yes
 670         ,)
 671 ])
 672
 673 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 674 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 675 dnl actually supported.
 676 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 677         AC_COMPILE_IFELSE([
 678         __inline int foo () { return 0; }
 679         int main () { return foo (); }
 680         ],
 681         glib_cv_has__inline=yes
 682         ,
 683         glib_cv_has__inline=no
 684         ,)
 685 ])
 686 case x$glib_cv_has__inline in
 687 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 688 esac
 689 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 690         AC_COMPILE_IFELSE([
 691         __inline__ int foo () { return 0; }
 692         int main () { return foo (); }
 693         ],
 694         glib_cv_has__inline__=yes
 695         ,
 696         glib_cv_has__inline__=no
 697         ,)
 698 ])
 699 case x$glib_cv_has__inline__ in
 700 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 701 esac
 702 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 703         AC_COMPILE_IFELSE([
 704         #undef inline
 705         inline int foo () { return 0; }
 706         int main () { return foo (); }
 707         ],
 708         glib_cv_hasinline=yes
 709         ,
 710         glib_cv_hasinline=no
 711         ,)
 712 ])
 713 case x$glib_cv_hasinline in
 714 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 715 esac
 716
 717 # if we can use inline functions in headers
 718 AC_MSG_CHECKING(if inline functions in headers work)
 719 AC_LINK_IFELSE([
 720 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 721 #  undef inline
 722 #  define inline __inline__
 723 #elif !defined (G_HAVE_INLINE)
 724 #  undef inline
 725 #  if defined (G_HAVE___INLINE__)
 726 #    define inline __inline__
 727 #  elif defined (G_HAVE___INLINE)
 728 #    define inline __inline
 729 #  endif
 730 #endif
 731
 732 int glib_test_func2 (int);
 733
 734 static inline int
 735 glib_test_func1 (void) {
 736   return glib_test_func2 (1);
 737 }
 738
 739 int
 740 main (void) {
 741   int i = 1;
 742 }],[g_can_inline=yes],[g_can_inline=no])
 743 AC_MSG_RESULT($g_can_inline)
 744
 745 dnl *** check for working do while(0) macros ***
 746 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 747         AC_TRY_COMPILE([],[
 748         #define STMT_START do
 749         #define STMT_END while(0)
 750         #define STMT_TEST STMT_START { i = 0; } STMT_END
 751         int main(void) { int i = 1; STMT_TEST; return i; }],
 752         [g_cv_support_dowhile_macros=yes],
 753         [g_cv_support_dowhile_macros=no],
 754         [g_cv_support_dowhile_macros=yes])
 755 ])
 756 if test x$g_cv_support_dowhile_macros = xyes; then
 757   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 758 fi
 759
 760 # check for flavours of varargs macros
 761 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 762 AC_TRY_COMPILE([],[
 763 int a(int p1, int p2, int p3);
 764 #define call_a(...) a(1,__VA_ARGS__)
 765 call_a(2,3);
 766 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 767 AC_MSG_RESULT($g_have_iso_c_varargs)
 768
 769 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 770 if test "$CXX" = ""; then
 771 dnl No C++ compiler
 772   g_have_iso_cxx_varargs=no
 773 else
 774   AC_LANG_CPLUSPLUS
 775   AC_TRY_COMPILE([],[
 776 int a(int p1, int p2, int p3);
 777 #define call_a(...) a(1,__VA_ARGS__)
 778 call_a(2,3);
 779 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 780   AC_LANG_C
 781 fi
 782 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 783
 784 AC_MSG_CHECKING(for GNUC varargs macros)
 785 AC_TRY_COMPILE([],[
 786 int a(int p1, int p2, int p3);
 787 #define call_a(params...) a(1,params)
 788 call_a(2,3);
 789 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 790 AC_MSG_RESULT($g_have_gnuc_varargs)
 791
 792 # check for GNUC visibility support
 793 AC_MSG_CHECKING(for GNUC visibility attribute)
 794 GLIB_CHECK_COMPILE_WARNINGS([
 795 void
 796 __attribute__ ((visibility ("hidden")))
 797      f_hidden (void)
 798 {
 799 }
 800 void
 801 __attribute__ ((visibility ("internal")))
 802      f_internal (void)
 803 {
 804 }
 805 void
 806 __attribute__ ((visibility ("protected")))
 807      f_protected (void)
 808 {
 809 }
 810 void
 811 __attribute__ ((visibility ("default")))
 812      f_default (void)
 813 {
 814 }
 815 int main (int argc, char **argv)
 816 {
 817         f_hidden();
 818         f_internal();
 819         f_protected();
 820         f_default();
 821         return 0;
 822 }
 823 ],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 824 AC_MSG_RESULT($g_have_gnuc_visibility)
 825 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 826
 827 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 828 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 829 #else
 830 # include "error: this is not Sun Studio."
 831 #endif
 832 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 833 AC_MSG_RESULT($g_have_sunstudio_visibility)
 834 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 835
 836 # check for bytesex stuff
 837 AC_C_BIGENDIAN
 838 if test x$ac_cv_c_bigendian = xuniversal ; then
 839 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 840 #else
 841 #error Not a big endian.
 842 #endif],
 843     ac_cv_c_bigendian=yes
 844     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 845 #else
 846 #error Not a little endian.
 847 #endif],
 848     ac_cv_c_bigendian=no
 849     ,AC_MSG_WARN([Could not determine endianness.])))
 850 fi
 851
 852
 853 # check for header files
 854 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 855 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 856 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h sched.h malloc.h])
 857 AC_CHECK_HEADERS([sys/vfs.h sys/mount.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 858 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h sys/sysctl.h fstab.h])
 859
 860 # check for structure fields
 861 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 862 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 863 #include <sys/stat.h>
 864 #include <unistd.h>
 865 #ifdef HAVE_SYS_STATFS_H
 866 #include <sys/statfs.h>
 867 #endif
 868 #ifdef HAVE_SYS_PARAM_H
 869 #include <sys/param.h>
 870 #endif
 871 #ifdef HAVE_SYS_MOUNT_H
 872 #include <sys/mount.h>
 873 #endif])
 874 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 875 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 876
 877 # Checks for libcharset
 878 AM_LANGINFO_CODESET
 879 gl_GLIBC21
 880 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 881 AC_CHECK_FUNCS(setlocale)
 882
 883 # check additional type sizes
 884 AC_CHECK_SIZEOF(size_t)
 885
 886 dnl Try to figure out whether gsize, gssize should be long or int
 887 AC_MSG_CHECKING([for the appropriate definition for size_t])
 888
 889 case $ac_cv_sizeof_size_t in
 890   $ac_cv_sizeof_short)
 891       glib_size_type=short
 892       ;;
 893   $ac_cv_sizeof_int)
 894       glib_size_type=int
 895       ;;
 896   $ac_cv_sizeof_long)
 897       glib_size_type=long
 898       ;;
 899   $ac_cv_sizeof_long_long)
 900       glib_size_type='long long'
 901       ;;
 902   $ac_cv_sizeof__int64)
 903       glib_size_type='__int64'
 904       ;;
 905   *)  AC_MSG_ERROR([No type matching size_t in size])
 906       ;;
 907 esac
 908
 909 dnl If int/long are the same size, we see which one produces
 910 dnl warnings when used in the location as size_t. (This matters
 911 dnl on AIX with xlc)
 912 dnl
 913 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 914    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 915   GLIB_CHECK_COMPILE_WARNINGS([
 916 #if defined(_AIX) && !defined(__GNUC__)
 917 #pragma options langlvl=stdc89
 918 #endif
 919 #include <stddef.h>
 920 int main ()
 921 {
 922   size_t s = 1;
 923   unsigned int *size_int = &s;
 924   return (int)*size_int;
 925 }
 926     ],glib_size_type=int,
 927       [GLIB_CHECK_COMPILE_WARNINGS([
 928 #if defined(_AIX) && !defined(__GNUC__)
 929 #pragma options langlvl=stdc89
 930 #endif
 931 #include <stddef.h>
 932 int main ()
 933 {
 934    size_t s = 1;
 935    unsigned long *size_long = &s;
 936    return (int)*size_long;
 937 }
 938         ],glib_size_type=long)])
 939 fi
 940
 941 AC_MSG_RESULT(unsigned $glib_size_type)
 942
 943 # Check for some functions
 944 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk)
 945 AC_CHECK_FUNCS(chown lchown fchmod fchown link statvfs statfs utimes getgrgid getpwuid)
 946 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getmntinfo)
 947 # Check for high-resolution sleep functions
 948 AC_CHECK_FUNCS(nanosleep nsleep)
 949
 950 AC_CHECK_HEADERS(crt_externs.h)
 951 AC_CHECK_FUNCS(_NSGetEnviron)
 952
 953 AC_FUNC_VSNPRINTF_C99
 954 AC_FUNC_PRINTF_UNIX98
 955
 956 dnl
 957 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
 958 dnl
 959 if test "$ac_cv_func_statfs" = yes ; then
 960   AC_MSG_CHECKING([number of arguments to statfs()])
 961   AC_TRY_COMPILE([#include <unistd.h>
 962   #ifdef HAVE_SYS_PARAM_H
 963   #include <sys/param.h>
 964   #endif
 965   #ifdef HAVE_SYS_VFS_H
 966   #include <sys/vfs.h>
 967   #endif
 968   #ifdef HAVE_SYS_MOUNT_H
 969   #include <sys/mount.h>
 970   #endif
 971   #ifdef HAVE_SYS_STATFS_H
 972   #include <sys/statfs.h>
 973   #endif], [struct statfs st;
 974   statfs(NULL, &st);],[
 975     AC_MSG_RESULT([2])
 976     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
 977     AC_TRY_COMPILE([#include <unistd.h>
 978   #ifdef HAVE_SYS_PARAM_H
 979   #include <sys/param.h>
 980   #endif
 981   #ifdef HAVE_SYS_VFS_H
 982   #include <sys/vfs.h>
 983   #endif
 984   #ifdef HAVE_SYS_MOUNT_H
 985   #include <sys/mount.h>
 986   #endif
 987   #ifdef HAVE_SYS_STATFS_H
 988   #include <sys/statfs.h>
 989   #endif], [struct statfs st;
 990   statfs(NULL, &st, sizeof (st), 0);],[
 991       AC_MSG_RESULT([4])
 992       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
 993       AC_MSG_RESULT(unknown)
 994       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
 995 fi
 996
 997 #
 998 # Check whether to use an included printf
 999 #
1000
1001 AC_ARG_ENABLE(included-printf,
1002               [AC_HELP_STRING([--enable-included-printf],
1003                               [use included printf [default=auto]])],
1004               enable_included_printf="$enableval")
1005
1006 need_included_printf=no
1007 if test "x$enable_included_printf" = "xyes" ; then
1008   need_included_printf=yes
1009 fi
1010 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1011   need_included_printf=yes
1012 fi
1013 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1014   need_included_printf=yes
1015 fi
1016 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1017    test -z "$glib_cv_long_long_format" ; then
1018   need_included_printf=yes
1019 fi
1020
1021 if test "x$enable_included_printf" = "xno" &&
1022    test "x$need_included_printf" = "xyes" ; then
1023   AC_MSG_ERROR([
1024 *** Your C library's printf doesn't appear to have the features that
1025 *** GLib needs, but you specified --enable-included-printf=no.])
1026 fi
1027
1028 enable_included_printf=$need_included_printf
1029
1030 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1031 if test "$enable_included_printf" != "yes" ; then
1032   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1033 else
1034   if test -z "$glib_cv_long_long_format" ; then
1035     glib_cv_long_long_format="ll"
1036   fi
1037   AC_DEFINE(HAVE_VASPRINTF,1)
1038 fi
1039
1040 # Checks needed for gnulib vasnprintf
1041 bh_C_SIGNED
1042 jm_AC_TYPE_LONG_LONG
1043 gt_TYPE_LONGDOUBLE
1044 gt_TYPE_WCHAR_T
1045 gt_TYPE_WINT_T
1046 AC_TYPE_SIZE_T
1047 AC_CHECK_TYPES(ptrdiff_t)
1048 jm_AC_TYPE_INTMAX_T
1049 AC_CHECK_FUNCS([snprintf wcslen])
1050 AC_FUNC_SNPRINTF_C99
1051
1052 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1053 # The check is borrowed from the PERL Configure script.
1054 if test "$ac_cv_func_memmove" != "yes"; then
1055   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1056     glib_cv_working_bcopy,[AC_TRY_RUN([
1057       int main() {
1058         char buf[128], abc[128], *b;
1059         int len, off, align;
1060         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1061         for (align = 7; align >= 0; align--) {
1062           for (len = 36; len; len--) {
1063             b = buf+align; bcopy(abc, b, len);
1064             for (off = 1; off <= len; off++) {
1065               bcopy(b, b+off, len); bcopy(b+off, b, len);
1066                 if (bcmp(b, abc, len)) return(1);
1067             }
1068           }
1069         }
1070         return(0);
1071       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1072
1073   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1074   if test "$glib_cv_working_bcopy" = "yes"; then
1075     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1076   fi
1077 fi
1078
1079 # Check for sys_errlist
1080 AC_MSG_CHECKING(for sys_errlist)
1081 AC_TRY_LINK(, [
1082 extern char *sys_errlist[];
1083 extern int sys_nerr;
1084 sys_errlist[sys_nerr-1][0] = 0;
1085 ], glib_ok=yes, glib_ok=no)
1086 AC_MSG_RESULT($glib_ok)
1087 if test "$glib_ok" = "no"; then
1088     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
1089 fi
1090
1091 # Check for sys_siglist
1092 AC_MSG_CHECKING(for sys_siglist)
1093 AC_TRY_LINK(, [
1094 extern char *sys_siglist[];
1095 exit (sys_siglist[0]);
1096 ], glib_ok=yes, glib_ok=no)
1097 AC_MSG_RESULT($glib_ok)
1098 if test "$glib_ok" = "no"; then
1099     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
1100 fi
1101
1102 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
1103 AC_MSG_CHECKING(for sys_siglist declaration)
1104 AC_TRY_COMPILE([#include <signal.h>], [
1105 strlen (sys_siglist[0]);
1106 ], glib_ok=yes, glib_ok=no)
1107 AC_MSG_RESULT($glib_ok)
1108 if test "$glib_ok" = "no"; then
1109     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
1110 fi
1111
1112 # Check if <sys/select.h> needs to be included for fd_set
1113 AC_MSG_CHECKING([for fd_set])
1114 AC_TRY_COMPILE([#include <sys/types.h>],
1115         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1116 if test "$gtk_ok" = "yes"; then
1117     AC_MSG_RESULT([yes, found in sys/types.h])
1118 else
1119     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1120     if test "$gtk_ok" = "yes"; then
1121         # *** FIXME: give it a different name
1122         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1123         AC_MSG_RESULT([yes, found in sys/select.h])
1124     else
1125         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1126         AC_MSG_RESULT(no)
1127     fi
1128 fi
1129
1130 dnl *** check for sane realloc() ***
1131 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1132         AC_TRY_RUN([#include <stdlib.h>
1133         int main() {
1134           return realloc (0, sizeof (int)) == 0;
1135         }],
1136         [glib_cv_sane_realloc=yes],
1137         [glib_cv_sane_realloc=no],
1138         [glib_cv_sane_realloc=yes])
1139 ])
1140 if test x$glib_cv_sane_realloc = xyes; then
1141   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1142 fi
1143
1144 dnl Check for nl_langinfo and CODESET
1145 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1146         AC_TRY_COMPILE([#include <langinfo.h>],
1147                 [char *codeset = nl_langinfo (CODESET);],
1148                 [glib_cv_langinfo_codeset=yes],
1149                 [glib_cv_langinfo_codeset=no])])
1150 if test x$glib_cv_langinfo_codeset = xyes; then
1151   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1152 fi
1153
1154 dnl ****************************************
1155 dnl *** posix_memalign                   ***
1156 dnl ****************************************
1157 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1158 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1159     glib_cv_compliant_posix_memalign=0
1160     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1161         AC_TRY_RUN([
1162                 #define _XOPEN_SOURCE 600
1163                 #include <stdlib.h> /* posix_memalign() should be defined here */
1164                 /* some systems break if #include <malloc.h> used */
1165                 static void test_memalign (size_t boundary, size_t size) {
1166                     void *mem = 0;
1167                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1168                         exit (1);
1169                     else
1170                       free (mem);
1171                 }
1172                 int main() {
1173                     test_memalign (  128,   128 - 2 * sizeof (void*));
1174                     test_memalign (  256,   256 - 2 * sizeof (void*));
1175                     test_memalign (  512,   512 - 2 * sizeof (void*));
1176                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1177                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1178                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1179                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1180                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1181                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1182                     exit (0); /* success */
1183                 }
1184                 ],
1185             [glib_cv_compliant_posix_memalign=1], [], [:])
1186       :
1187     fi
1188     ])
1189 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1190     AC_MSG_RESULT(yes)
1191     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1192 else
1193     AC_MSG_RESULT(no)
1194 fi
1195
1196
1197 dnl ****************************************
1198 dnl *** strlcpy/strlcat                  ***
1199 dnl ****************************************
1200 # Check for strlcpy
1201 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1202 AC_TRY_RUN([#include <stdlib.h>
1203 #include <string.h>
1204 int main() {
1205   char p[10];
1206   (void) strlcpy (p, "hi", 10);
1207   if (strlcat (p, "bye", 0) != 3)
1208     return 1;
1209   return 0;
1210 }], glib_cv_have_strlcpy=yes,
1211     glib_cv_have_strlcpy=no,
1212     glib_cv_have_strlcpy=no)])
1213 if test "$glib_cv_have_strlcpy" = "yes"; then
1214     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1215 fi
1216
1217
1218 dnl **********************
1219 dnl *** va_copy checks ***
1220 dnl **********************
1221 dnl we currently check for all three va_copy possibilities, so we get
1222 dnl all results in config.log for bug reports.
1223 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1224         AC_LINK_IFELSE([#include <stdarg.h>
1225 #include <stdlib.h>
1226         void f (int i, ...) {
1227         va_list args1, args2;
1228         va_start (args1, i);
1229         va_copy (args2, args1);
1230         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1231           exit (1);
1232         va_end (args1); va_end (args2);
1233         }
1234         int main() {
1235           f (0, 42);
1236           return 0;
1237         }],
1238         [glib_cv_va_copy=yes],
1239         [glib_cv_va_copy=no])
1240 ])
1241 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1242         AC_LINK_IFELSE([#include <stdarg.h>
1243 #include <stdlib.h>
1244         void f (int i, ...) {
1245         va_list args1, args2;
1246         va_start (args1, i);
1247         __va_copy (args2, args1);
1248         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1249           exit (1);
1250         va_end (args1); va_end (args2);
1251         }
1252         int main() {
1253           f (0, 42);
1254           return 0;
1255         }],
1256         [glib_cv___va_copy=yes],
1257         [glib_cv___va_copy=no])
1258 ])
1259
1260 if test "x$glib_cv_va_copy" = "xyes"; then
1261   g_va_copy_func=va_copy
1262 else if test "x$glib_cv___va_copy" = "xyes"; then
1263   g_va_copy_func=__va_copy
1264 fi
1265 fi
1266
1267 if test -n "$g_va_copy_func"; then
1268   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1269 fi
1270
1271 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1272         AC_TRY_RUN([#include <stdarg.h>
1273 #include <stdlib.h>
1274         void f (int i, ...) {
1275         va_list args1, args2;
1276         va_start (args1, i);
1277         args2 = args1;
1278         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1279           exit (1);
1280         va_end (args1); va_end (args2);
1281         }
1282         int main() {
1283           f (0, 42);
1284           return 0;
1285         }],
1286         [glib_cv_va_val_copy=yes],
1287         [glib_cv_va_val_copy=no],
1288         [glib_cv_va_val_copy=yes])
1289 ])
1290
1291 if test "x$glib_cv_va_val_copy" = "xno"; then
1292   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1293 fi
1294
1295 dnl ***********************
1296 dnl *** g_module checks ***
1297 dnl ***********************
1298 G_MODULE_LIBS=
1299 G_MODULE_LIBS_EXTRA=
1300 G_MODULE_PLUGIN_LIBS=
1301 if test x"$glib_native_win32" = xyes; then
1302   dnl No use for this on Win32
1303   G_MODULE_LDFLAGS=
1304 else
1305   export SED
1306   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1307 fi
1308 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1309 G_MODULE_NEED_USCORE=0
1310 G_MODULE_BROKEN_RTLD_GLOBAL=0
1311 G_MODULE_HAVE_DLERROR=0
1312 dnl *** force native WIN32 shared lib loader
1313 if test -z "$G_MODULE_IMPL"; then
1314   case "$host" in
1315   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1316   esac
1317 fi
1318 dnl *** force native AIX library loader
1319 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1320 if test -z "$G_MODULE_IMPL"; then
1321   case "$host" in
1322   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1323   esac
1324 fi
1325 dnl *** dlopen() and dlsym() in system libraries
1326 if test -z "$G_MODULE_IMPL"; then
1327         AC_CHECK_FUNC(dlopen,
1328                       [AC_CHECK_FUNC(dlsym,
1329                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1330                       [])
1331 fi
1332 dnl *** load_image (BeOS)
1333 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1334   AC_CHECK_LIB(root, load_image,
1335       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1336       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1337       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1338       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1339       [])
1340 fi
1341 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1342 if test -z "$G_MODULE_IMPL"; then
1343         AC_CHECK_FUNC(NSLinkModule,
1344                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1345                        G_MODULE_NEED_USCORE=1],
1346                       [])
1347 fi
1348 dnl *** dlopen() and dlsym() in libdl
1349 if test -z "$G_MODULE_IMPL"; then
1350         AC_CHECK_LIB(dl, dlopen,
1351                      [AC_CHECK_LIB(dl, dlsym,
1352                                    [G_MODULE_LIBS=-ldl
1353                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1354                      [])
1355 fi
1356 dnl *** shl_load() in libdld (HP-UX)
1357 if test -z "$G_MODULE_IMPL"; then
1358         AC_CHECK_LIB(dld, shl_load,
1359                 [G_MODULE_LIBS=-ldld
1360                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1361                 [])
1362 fi
1363 dnl *** additional checks for G_MODULE_IMPL_DL
1364 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1365         LIBS_orig="$LIBS"
1366         LDFLAGS_orig="$LDFLAGS"
1367         LIBS="$G_MODULE_LIBS $LIBS"
1368         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1369 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1370         echo "void glib_plugin_test(void) { }" > plugin.c
1371         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1372                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1373         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1374                 glib_cv_rtldglobal_broken,[
1375                 AC_TRY_RUN([
1376 #include <dlfcn.h>
1377 #ifndef RTLD_GLOBAL
1378 #  define RTLD_GLOBAL 0
1379 #endif
1380 #ifndef RTLD_LAZY
1381 #  define RTLD_LAZY 0
1382 #endif
1383 int glib_plugin_test;
1384 int main () {
1385     void *handle, *global, *local;
1386     global = &glib_plugin_test;
1387     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1388     if (!handle) return 0;
1389     local = dlsym (handle, "glib_plugin_test");
1390     return global == local;
1391 }                       ],
1392                         [glib_cv_rtldglobal_broken=no],
1393                         [glib_cv_rtldglobal_broken=yes],
1394                         [glib_cv_rtldglobal_broken=no])
1395                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1396                 rmdir .libs 2>/dev/null
1397         ])
1398         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1399                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1400         else
1401                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1402         fi
1403 dnl *** check whether we need preceeding underscores
1404         AC_CACHE_CHECK([for preceeding underscore in symbols],
1405                 glib_cv_uscore,[
1406                 AC_TRY_RUN([#include <dlfcn.h>
1407                 int glib_underscore_test (void) { return 42; }
1408                 int main() {
1409                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1410                   handle = dlopen ((void*)0, 0);
1411                   if (handle) {
1412                     f1 = dlsym (handle, "glib_underscore_test");
1413                     f2 = dlsym (handle, "_glib_underscore_test");
1414                   } return (!f2 || f1);
1415                 }],
1416                         [glib_cv_uscore=yes],
1417                         [glib_cv_uscore=no],
1418                         [])
1419                 rm -f plugin.c plugin.$ac_objext plugin.lo
1420         ])
1421         GLIB_ASSERT_SET(glib_cv_uscore)
1422         if test "x$glib_cv_uscore" = "xyes"; then
1423                 G_MODULE_NEED_USCORE=1
1424         else
1425                 G_MODULE_NEED_USCORE=0
1426         fi
1427
1428         LDFLAGS="$LDFLAGS_orig"
1429 dnl *** check for having dlerror()
1430         AC_CHECK_FUNC(dlerror,
1431                 [G_MODULE_HAVE_DLERROR=1],
1432                 [G_MODULE_HAVE_DLERROR=0])
1433         LIBS="$LIBS_orig"
1434 fi
1435 dnl *** done, have we got an implementation?
1436 if test -z "$G_MODULE_IMPL"; then
1437         G_MODULE_IMPL=0
1438         G_MODULE_SUPPORTED=false
1439 else
1440         G_MODULE_SUPPORTED=true
1441 fi
1442
1443 AC_MSG_CHECKING(for the suffix of module shared libraries)
1444 export SED
1445 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1446 eval $shrext_cmds
1447 module=yes eval std_shrext=$shrext_cmds
1448 # chop the initial dot
1449 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1450 AC_MSG_RESULT(.$glib_gmodule_suffix)
1451 # any reason it may fail?
1452 if test "x$glib_gmodule_suffix" = x; then
1453         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1454 fi
1455
1456 AC_SUBST(G_MODULE_SUPPORTED)
1457 AC_SUBST(G_MODULE_IMPL)
1458 AC_SUBST(G_MODULE_LIBS)
1459 AC_SUBST(G_MODULE_LIBS_EXTRA)
1460 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1461 AC_SUBST(G_MODULE_LDFLAGS)
1462 AC_SUBST(G_MODULE_HAVE_DLERROR)
1463 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1464 AC_SUBST(G_MODULE_NEED_USCORE)
1465 AC_SUBST(GLIB_DEBUG_FLAGS)
1466
1467 dnl **********************
1468 dnl *** g_spawn checks ***
1469 dnl **********************
1470
1471 AC_MSG_CHECKING(for gspawn implementation)
1472 case "$host" in
1473   *-*-mingw*)
1474     GSPAWN=gspawn-win32.lo
1475     ;;
1476   *)
1477     GSPAWN=gspawn.lo
1478     ;;
1479 esac
1480 AC_MSG_RESULT($GSPAWN)
1481 AC_SUBST(GSPAWN)
1482
1483 dnl *************************
1484 dnl *** GIOChannel checks ***
1485 dnl *************************
1486
1487 AC_MSG_CHECKING(for GIOChannel implementation)
1488 case "$host" in
1489   *-*-mingw*)
1490     GIO=giowin32.lo
1491     ;;
1492   *)
1493     GIO=giounix.lo
1494     ;;
1495 esac
1496 AC_MSG_RESULT($GIO)
1497 AC_SUBST(GIO)
1498
1499 dnl *********************************
1500 dnl *** Directory for GIO modules ***
1501 dnl *********************************
1502
1503 AC_ARG_WITH(gio-module-dir,
1504            [AC_HELP_STRING([--with-gio-module-dir=PATH],
1505                            [Load gio modules from this directory [LIBDIR/gio/modules]])],
1506            [],
1507            [with_gio_module_dir='${libdir}/gio/modules'])
1508 GIO_MODULE_DIR=$with_gio_module_dir
1509 AC_SUBST(GIO_MODULE_DIR)
1510
1511 dnl **********************************
1512 dnl *** Check for libselinux (GIO) ***
1513 dnl **********************************
1514 AC_ARG_ENABLE(selinux, [  --disable-selinux       build without selinux support])
1515 msg_selinux=no
1516 SELINUX_LIBS=
1517 if test "x$enable_selinux" != "xno"; then
1518
1519  AC_CHECK_LIB(selinux, is_selinux_enabled,
1520    [AC_CHECK_HEADERS(selinux/selinux.h,
1521      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1522        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1523         SELINUX_LIBS="-lselinux"
1524         msg_selinux=yes])
1525      ])
1526    ])
1527 fi
1528 AC_SUBST(SELINUX_LIBS)
1529
1530 dnl *****************************
1531 dnl ** Check for inotify (GIO) **
1532 dnl *****************************
1533 inotify_support=no
1534 AC_CHECK_HEADERS([sys/inotify.h],
1535 [
1536         inotify_support=yes
1537 ])
1538
1539 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1540
1541 dnl *********************************
1542 dnl ** Check for Solaris FEN (GIO) **
1543 dnl *********************************
1544 fen_support=no
1545 AC_COMPILE_IFELSE([
1546 #include <port.h>
1547 #ifndef PORT_SOURCE_FILE
1548 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1549 #endif
1550 int main() { return 0; } ],
1551 [
1552         fen_support=yes
1553 ],)
1554
1555 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1556
1557 dnl ****************************
1558 dnl *** Checks for FAM (GIO) ***
1559 dnl ****************************
1560
1561 should_disable_fam=no
1562
1563 AC_ARG_ENABLE(fam, [  --disable-fam          build without enabling fam for file system monitoring],
1564                          [
1565                                 if test "x$enable_fam" = "xno"; then
1566                                         should_disable_fam=yes
1567                                         echo "Not building FAM support"
1568                                 fi
1569                          ]
1570                          )
1571 fam_support=no
1572 FAM_LIBS=
1573 if test "x$should_disable_fam" = "xno"; then
1574 AC_CHECK_LIB(fam, FAMOpen,
1575   [AC_CHECK_HEADERS(fam.h,
1576     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1577      AC_CHECK_LIB(fam, FAMNoExists,
1578                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1579      FAM_LIBS="-lfam"]
1580      fam_support=yes,
1581     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1582   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1583 AC_SUBST(FAM_LIBS)
1584 fi
1585 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1586
1587
1588 dnl *****************************
1589 dnl *** Check for xattr (GIO) ***
1590 dnl *****************************
1591 AC_ARG_ENABLE(xattr, [  --disable-xattr           build without xattr support])
1592 msg_xattr=no
1593 XATTR_LIBS=
1594 if test "x$enable_xattr" != "xno"; then
1595
1596 dnl either glibc or libattr can provide xattr support
1597
1598 dnl for both of them, we check for getxattr being in
1599 dnl the library and a valid xattr header.
1600
1601 dnl try glibc
1602  AC_CHECK_LIB(c, getxattr,
1603    [AC_CHECK_HEADERS(sys/xattr.h,
1604      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1605       msg_xattr=yes])
1606    ])
1607
1608   if test "x$msg_xattr" != "xyes"; then
1609 dnl   failure. try libattr
1610    AC_CHECK_LIB(attr, getxattr,
1611       [AC_CHECK_HEADERS(attr/xattr.h,
1612        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1613         XATTR_LIBS="-lattr"
1614         msg_xattr=yes])
1615       ])
1616   fi
1617
1618   if test "x$msg_xattr" = "xyes"; then
1619     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1620     AC_TRY_COMPILE([
1621       #include <stdio.h>
1622       #ifdef HAVE_SYS_TYPES_H
1623       #include <sys/types.h>
1624       #endif
1625       #ifdef HAVE_SYS_XATTR_H
1626       #include <sys/xattr.h>
1627       #elif HAVE_ATTR_XATTR_H
1628       #include <attr/xattr.h>
1629       #endif
1630     ],
1631     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1632     [
1633       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1634       AC_MSG_RESULT([yes])
1635     ],
1636     [AC_MSG_RESULT([no])]
1637     )
1638   fi
1639
1640 fi
1641 AC_SUBST(XATTR_LIBS)
1642
1643 dnl ****************************************
1644 dnl *** platform dependent source checks ***
1645 dnl ****************************************
1646
1647 AC_MSG_CHECKING(for platform-dependent source)
1648 case "$host" in
1649   *-*-cygwin*|*-*-mingw*)
1650     PLATFORMDEP=gwin32.lo
1651     ;;
1652   *)
1653     PLATFORMDEP=
1654     ;;
1655 esac
1656 AC_MSG_RESULT($PLATFORMDEP)
1657 AC_SUBST(PLATFORMDEP)
1658
1659 AC_MSG_CHECKING([whether to compile timeloop])
1660 case "$host" in
1661   *-*-cygwin*|*-*-mingw*|*-*-minix)
1662     enable_timeloop=no
1663     ;;
1664   *)
1665     enable_timeloop=yes
1666     ;;
1667 esac
1668 AC_MSG_RESULT($enable_timeloop)
1669 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1670
1671 AC_MSG_CHECKING([if building for some Win32 platform])
1672 case "$host" in
1673   *-*-mingw*|*-*-cygwin*)
1674     platform_win32=yes
1675     ;;
1676   *)
1677     platform_win32=no
1678     ;;
1679 esac
1680 AC_MSG_RESULT($platform_win32)
1681 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1682
1683 dnl ***********************
1684 dnl *** g_thread checks ***
1685 dnl ***********************
1686
1687 AC_ARG_WITH(threads,
1688            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/win32@:>@],
1689                            [specify a thread implementation to use])],
1690            [if test "x$with_threads" = x; then
1691                 want_threads=yes
1692             else
1693                 want_threads=$with_threads
1694             fi],
1695            [want_threads=yes])
1696 if test "x$enable_threads" = "xno"; then
1697         want_threads=no
1698 fi
1699
1700 dnl error and warning message
1701 dnl *************************
1702
1703 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1704                 computer. GLib will not have a default thread implementation."
1705
1706 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1707                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1708                 compilation now, but then your programs might not work.
1709                 Please provide information on how it is done on your system."
1710
1711 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1712                 "
1713
1714 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1715                 provide information on your thread implementation.
1716                 You can also run 'configure --disable-threads'
1717                 to compile without thread support."
1718
1719 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1720                 functions will not be MT-safe during their first call because
1721                 there is no working 'getpwuid_r' on your system."
1722
1723 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1724                 because there is no 'localtime_r' on your system."
1725
1726 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1727                 crude surrogate will be used. If you happen to know a
1728                 yield function for your system, please inform the GLib
1729                 developers."
1730
1731 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1732                 threads on your system. Thus threads can only have the default
1733                 priority. If you happen to know these main/max
1734                 priorities, please inform the GLib developers."
1735
1736 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1737                 linking threaded applications. As GLib cannot do that
1738                 automatically, you will get an linkg error everytime you are
1739                 not using the right compiler. In that case you have to relink
1740                 with the right compiler. Ususally just '_r' is appended
1741                 to the compiler name."
1742
1743 dnl determination of thread implementation
1744 dnl ***************************************
1745
1746 # have_threads=no   means no thread support
1747 # have_threads=none means no default thread implementation
1748
1749 have_threads=no
1750 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1751                                 || test "x$want_threads" = xdce; then
1752         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1753         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1754         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1755         glib_save_CPPFLAGS="$CPPFLAGS"
1756         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1757         if test "x$have_threads" = xno; then
1758                 AC_TRY_COMPILE([#include <pthread.h>],
1759                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1760                         have_threads=posix)
1761         fi
1762         if test "x$have_threads" = xno; then
1763                 AC_TRY_COMPILE([#include <pthread.h>],
1764                         [pthread_mutex_t m;
1765                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1766                         have_threads=dce)
1767         fi
1768         # Tru64Unix requires -pthread to find pthread.h. See #103020
1769         CPPFLAGS="$CPPFLAGS -pthread"
1770         if test "x$have_threads" = xno; then
1771         AC_TRY_COMPILE([#include <pthread.h>],
1772                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1773                        have_threads=posix)
1774         fi
1775         CPPFLAGS="$glib_save_CPPFLAGS"
1776 fi
1777 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1778         case $host in
1779                 *-*-mingw*)
1780                 have_threads=win32
1781                 ;;
1782         esac
1783 fi
1784 if test "x$want_threads" = xnone; then
1785         have_threads=none
1786 fi
1787
1788 AC_MSG_CHECKING(for thread implementation)
1789
1790 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1791         AC_MSG_RESULT(none available)
1792         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1793 else
1794         AC_MSG_RESULT($have_threads)
1795 fi
1796
1797
1798 dnl determination of G_THREAD_CFLAGS
1799 dnl ********************************
1800
1801 G_THREAD_LIBS=
1802 G_THREAD_LIBS_EXTRA=
1803 G_THREAD_CFLAGS=
1804
1805 dnl
1806 dnl Test program for basic POSIX threads functionality
1807 dnl
1808 m4_define([glib_thread_test],[
1809 #include <pthread.h>
1810 int check_me = 0;
1811 void* func(void* data) {check_me = 42; return &check_me;}
1812 int main()
1813  { pthread_t t;
1814    void *ret;
1815    pthread_create (&t, $1, func, 0);
1816    pthread_join (t, &ret);
1817    return (check_me != 42 || ret != &check_me);
1818 }])
1819
1820 dnl
1821 dnl Test program for sched_get_priority_min()
1822 dnl
1823 m4_define([glib_sched_priority_test],[
1824 #include <sched.h>
1825 #include <errno.h>
1826 int main() {
1827     errno = 0;
1828     return sched_get_priority_min(SCHED_OTHER)==-1
1829            && errno != 0;
1830 }])
1831
1832 if test x"$have_threads" != xno; then
1833
1834   if test x"$have_threads" = xposix; then
1835     # First we test for posix, whether -pthread or -pthreads do the trick as
1836     # both CPPFLAG and LIBS.
1837     # One of them does for most gcc versions and some other platforms/compilers
1838     # too and could be considered as the canonical way to go.
1839     case $host in
1840       *-*-cygwin*|*-*-darwin*)
1841          # skip cygwin and darwin -pthread or -pthreads test
1842          ;;
1843       *-solaris*)
1844         # These compiler/linker flags work with both Sun Studio and gcc
1845         # Sun Studio expands -mt to -D_REENTRANT and -lthread
1846         # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1847         G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1848         G_THREAD_LIBS="-lpthread -lthread"
1849         ;;
1850       *)
1851         for flag in pthread pthreads mt; do
1852           glib_save_CFLAGS="$CFLAGS"
1853           CFLAGS="$CFLAGS -$flag"
1854           AC_TRY_RUN(glib_thread_test(0),
1855                      glib_flag_works=yes,
1856                      glib_flag_works=no,
1857                      [AC_LINK_IFELSE(glib_thread_test(0),
1858                                      glib_flag_works=yes,
1859                                      glib_flag_works=no)])
1860           CFLAGS="$glib_save_CFLAGS"
1861           if test $glib_flag_works = yes ; then
1862              G_THREAD_CFLAGS=-$flag
1863              G_THREAD_LIBS=-$flag
1864              break;
1865           fi
1866         done
1867          ;;
1868     esac
1869   fi
1870
1871   if test x"$G_THREAD_CFLAGS" = x; then
1872
1873     # The canonical -pthread[s] does not work. Try something different.
1874
1875     case $host in
1876         *-aix*)
1877                 if test x"$GCC" = xyes; then
1878                         # GCC 3.0 and above needs -pthread.
1879                         # Should be coverd by the case above.
1880                         # GCC 2.x and below needs -mthreads
1881                         G_THREAD_CFLAGS="-mthreads"
1882                         G_THREAD_LIBS=$G_THREAD_CFLAGS
1883                 else
1884                         # We are probably using the aix compiler. Normaly a
1885                         # program would have to be compiled with the _r variant
1886                         # of the corresponding compiler, but we as GLib cannot
1887                         # do that: but the good news is that for compiling the
1888                         # only difference is the added -D_THREAD_SAFE compile
1889                         # option. This is according to the "C for AIX User's
1890                         # Guide".
1891                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
1892                 fi
1893                 ;;
1894         *-dg-dgux*)  # DG/UX
1895                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
1896                 ;;
1897         *-osf*)
1898                 # So we are using dce threads. posix threads are already
1899                 # catched above.
1900                 G_THREAD_CFLAGS="-threads"
1901                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1902                 ;;
1903         *-sysv5uw7*) # UnixWare 7
1904                 # We are not using gcc with -pthread. Catched above.
1905                 G_THREAD_CFLAGS="-Kthread"
1906                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1907                 ;;
1908         *-mingw*)
1909                 # No flag needed when using MSVCRT.DLL
1910                 G_THREAD_CFLAGS=""
1911                 ;;
1912         *)
1913                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1914                 ;;
1915     esac
1916
1917   fi
1918
1919     # if we are not finding the localtime_r function, then we probably are
1920     # not using the proper multithread flag
1921
1922     glib_save_CPPFLAGS="$CPPFLAGS"
1923     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1924
1925     # First we test, whether localtime_r is declared in time.h
1926     # directly. Then we test whether a macro localtime_r exists, in
1927     # which case localtime_r in the test program is replaced and thus
1928     # if we still find localtime_r in the output, it is not defined as
1929     # a macro.
1930
1931     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1932       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1933                                                            localtime_r(a,b)],
1934                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1935
1936     CPPFLAGS="$glib_save_CPPFLAGS"
1937
1938     AC_MSG_CHECKING(thread related cflags)
1939     AC_MSG_RESULT($G_THREAD_CFLAGS)
1940     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1941 fi
1942
1943 dnl determination of G_THREAD_LIBS
1944 dnl ******************************
1945
1946 mutex_has_default=no
1947 case $have_threads in
1948         posix|dce)
1949           glib_save_CPPFLAGS="$CPPFLAGS"
1950           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1951           if test x"$G_THREAD_LIBS" = x; then
1952             case $host in
1953               *-aix*)
1954                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
1955                 # probably using the aix compiler.
1956                 AC_MSG_WARN($AIX_COMPILE_INFO)
1957                 ;;
1958               *)
1959                 G_THREAD_LIBS=error
1960                 glib_save_LIBS="$LIBS"
1961                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
1962                         if test x"$thread_lib" = x; then
1963                                 add_thread_lib=""
1964                                 IN=""
1965                         else
1966                                 add_thread_lib="-l$thread_lib"
1967                                 IN=" in -l$thread_lib"
1968                         fi
1969                         if test x"$have_threads" = xposix; then
1970                                 defattr=0
1971                         else
1972                                 defattr=pthread_attr_default
1973                         fi
1974
1975                         LIBS="$add_thread_lib $glib_save_LIBS"
1976
1977                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
1978                         AC_TRY_RUN(glib_thread_test($defattr),
1979                                    glib_result=yes,
1980                                    glib_result=no,
1981                                    [AC_LINK_IFELSE(glib_thread_test($defattr),
1982                                                    glib_result=yes,
1983                                                    glib_result=no)])
1984                         AC_MSG_RESULT($glib_result)
1985
1986                         if test "$glib_result" = "yes" ; then
1987                           G_THREAD_LIBS="$add_thread_lib"
1988                           break
1989                         fi
1990                 done
1991                 if test "x$G_THREAD_LIBS" = xerror; then
1992                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1993                 fi
1994                 LIBS="$glib_save_LIBS"
1995                 ;;
1996             esac
1997           fi
1998
1999           glib_save_LIBS="$LIBS"
2000           for thread_lib in "" rt rte; do
2001             if test x"$thread_lib" = x; then
2002               add_thread_lib=""
2003               IN=""
2004             else
2005               add_thread_lib="-l$thread_lib"
2006               IN=" in -l$thread_lib"
2007             fi
2008             LIBS="$add_thread_lib $glib_save_LIBS"
2009
2010             AC_MSG_CHECKING(for sched_get_priority_min$IN)
2011             AC_TRY_RUN(glib_sched_priority_test,
2012                        glib_result=yes,
2013                        glib_result=no,
2014                        [AC_LINK_IFELSE(glib_sched_priority_test,
2015                                        glib_result=yes,
2016                                        glib_result=no)])
2017             AC_MSG_RESULT($glib_result)
2018
2019             if test "$glib_result" = "yes" ; then
2020                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
2021                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
2022                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
2023                break
2024             fi
2025           done
2026           LIBS="$glib_save_LIBS"
2027           mutex_has_default=yes
2028           mutex_default_type='pthread_mutex_t'
2029           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
2030           mutex_header_file='pthread.h'
2031           if test "x$have_threads" = "xposix"; then
2032             g_threads_impl="POSIX"
2033           else
2034             g_threads_impl="DCE"
2035             have_threads="posix"
2036           fi
2037           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2038           CPPFLAGS="$glib_save_CPPFLAGS"
2039           ;;
2040         win32)
2041            g_threads_impl="WIN32"
2042            ;;
2043         none|no)
2044            g_threads_impl="NONE"
2045            ;;
2046         *)
2047            g_threads_impl="NONE"
2048            G_THREAD_LIBS=error
2049            ;;
2050 esac
2051
2052 if test "x$G_THREAD_LIBS" = xerror; then
2053         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2054 fi
2055
2056 case $host in
2057   *-*-beos*)
2058     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2059     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2060     ;;
2061   *)
2062     ;;
2063 esac
2064
2065 AC_MSG_CHECKING(thread related libraries)
2066 AC_MSG_RESULT($G_THREAD_LIBS)
2067
2068 dnl check for mt safe function variants and some posix functions
2069 dnl ************************************************************
2070
2071 if test x"$have_threads" != xno; then
2072         glib_save_LIBS="$LIBS"
2073         # we are not doing the following for now, as this might require glib
2074         # to always be linked with the thread libs on some platforms.
2075         # LIBS="$LIBS $G_THREAD_LIBS"
2076         AC_CHECK_FUNCS(localtime_r gmtime_r)
2077         if test "$ac_cv_header_pwd_h" = "yes"; then
2078                 AC_CACHE_CHECK([for posix getpwuid_r],
2079                         ac_cv_func_posix_getpwuid_r,
2080                         [AC_TRY_RUN([
2081 #include <errno.h>
2082 #include <pwd.h>
2083 int main () {
2084     char buffer[10000];
2085     struct passwd pwd, *pwptr = &pwd;
2086     int error;
2087     errno = 0;
2088     error = getpwuid_r (0, &pwd, buffer,
2089                         sizeof (buffer), &pwptr);
2090    return (error < 0 && errno == ENOSYS)
2091            || error == ENOSYS;
2092 }                               ],
2093                                 [ac_cv_func_posix_getpwuid_r=yes],
2094                                 [ac_cv_func_posix_getpwuid_r=no])])
2095                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2096                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2097                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2098                                 [Have POSIX function getpwuid_r])
2099                 else
2100                         AC_CACHE_CHECK([for nonposix getpwuid_r],
2101                                 ac_cv_func_nonposix_getpwuid_r,
2102                                 [AC_TRY_LINK([#include <pwd.h>],
2103                                         [char buffer[10000];
2104                                         struct passwd pwd;
2105                                         getpwuid_r (0, &pwd, buffer,
2106                                                         sizeof (buffer));],
2107                                         [ac_cv_func_nonposix_getpwuid_r=yes],
2108                                         [ac_cv_func_nonposix_getpwuid_r=no])])
2109                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2110                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2111                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2112                                         [Have non-POSIX function getpwuid_r])
2113                         fi
2114                 fi
2115         fi
2116         if test "$ac_cv_header_grp_h" = "yes"; then
2117                 AC_CACHE_CHECK([for posix getgrgid_r],
2118                         ac_cv_func_posix_getgrgid_r,
2119                         [AC_TRY_RUN([
2120 #include <errno.h>
2121 #include <grp.h>
2122 int main () {
2123     char buffer[10000];
2124     struct group grp, *grpptr = &grp;
2125     int error;
2126     errno = 0;
2127     error = getgrgid_r (0, &grp, buffer,
2128                         sizeof (buffer), &grpptr);
2129    return (error < 0 && errno == ENOSYS)
2130            || error == ENOSYS;
2131 }                              ],
2132                                [ac_cv_func_posix_getgrgid_r=yes],
2133                                [ac_cv_func_posix_getgrgid_r=no])])
2134                 GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2135                 if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2136                         AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2137                                 [Have POSIX function getgrgid_r])
2138                 else
2139                         AC_CACHE_CHECK([for nonposix getgrgid_r],
2140                                 ac_cv_func_nonposix_getgrgid_r,
2141                                 [AC_TRY_LINK([#include <grp.h>],
2142                                         [char buffer[10000];
2143                                         struct group grp;
2144                                         getgrgid_r (0, &grp, buffer,
2145                                         sizeof (buffer));],
2146                                 [ac_cv_func_nonposix_getgrgid_r=yes],
2147                                 [ac_cv_func_nonposix_getgrgid_r=no])])
2148                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2149                         if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2150                                 AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2151                                         [Have non-POSIX function getgrgid_r])
2152                         fi
2153                 fi
2154         fi
2155         LIBS="$G_THREAD_LIBS $LIBS"
2156         if test x"$have_threads" = xposix; then
2157                 glib_save_CPPFLAGS="$CPPFLAGS"
2158                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2159                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
2160                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
2161                 # This is not AC_CHECK_FUNC to also work with function
2162                 # name mangling in header files.
2163                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2164                 AC_TRY_LINK([#include <pthread.h>],
2165                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2166                         [AC_MSG_RESULT(yes)
2167                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2168                                   [Have function pthread_attr_setstacksize])],
2169                         [AC_MSG_RESULT(no)])
2170                 AC_MSG_CHECKING(for minimal/maximal thread priority)
2171                 if test x"$posix_priority_min" = x; then
2172                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
2173                                 PX_PRIO_MIN],,[
2174                                 posix_priority_min=PX_PRIO_MIN
2175                                 posix_priority_max=PX_PRIO_MAX])
2176                 fi
2177                 if test x"$posix_priority_min" = x; then
2178                         # AIX
2179                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
2180                                 PTHREAD_PRIO_MIN],,[
2181                                 posix_priority_min=PTHREAD_PRIO_MIN
2182                                 posix_priority_max=PTHREAD_PRIO_MAX])
2183                 fi
2184                 if test x"$posix_priority_min" = x; then
2185                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
2186                                 PRI_OTHER_MIN],,[
2187                                 posix_priority_min=PRI_OTHER_MIN
2188                                 posix_priority_max=PRI_OTHER_MAX])
2189                 fi
2190                 if test x"$posix_priority_min" = x; then
2191                         AC_MSG_RESULT(none found)
2192                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
2193                         posix_priority_min=-1
2194                         posix_priority_max=-1
2195                 else
2196                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
2197                         AC_MSG_CHECKING(for pthread_setschedparam)
2198                         AC_TRY_LINK([#include <pthread.h>],
2199                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
2200                           [AC_MSG_RESULT(yes)
2201                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
2202                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
2203                           [AC_MSG_RESULT(no)
2204                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
2205                 fi
2206                 posix_yield_func=none
2207                 AC_MSG_CHECKING(for posix yield function)
2208                 for yield_func in sched_yield pthread_yield_np pthread_yield \
2209                                                         thr_yield; do
2210                         AC_TRY_LINK([#include <pthread.h>],
2211                                 [$yield_func()],
2212                                 [posix_yield_func="$yield_func"
2213                                 break])
2214                 done
2215                 if test x"$posix_yield_func" = xnone; then
2216                         AC_MSG_RESULT(none found)
2217                         AC_MSG_WARN($POSIX_NO_YIELD)
2218                         posix_yield_func="g_usleep(1000)"
2219                 else
2220                         AC_MSG_RESULT($posix_yield_func)
2221                         posix_yield_func="$posix_yield_func()"
2222                 fi
2223                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
2224                 CPPFLAGS="$glib_save_CPPFLAGS"
2225
2226         elif test x"$have_threads" = xwin32; then
2227                 # It's a pointer to a private struct
2228                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
2229         fi
2230
2231         LIBS="$glib_save_LIBS"
2232
2233         # now spit out all the warnings.
2234         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2235            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2236                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2237         fi
2238         if test "$ac_cv_func_localtime_r" != "yes"; then
2239                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2240         fi
2241 fi
2242
2243 if test x"$glib_cv_sizeof_system_thread" = x; then
2244    # use a pointer as a fallback.
2245    GLIB_SIZEOF(,void *, system_thread)
2246 fi
2247
2248 #
2249 # Hack to deal with:
2250 #
2251 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2252 #     building shared libraries with linux.
2253 #  b) FreeBSD doesn't do this either.
2254 #
2255 case $host in
2256   *-*-freebsd*|*-*-linux*)
2257     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2258     ;;
2259   *)
2260     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2261     ;;
2262 esac
2263
2264 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
2265                    [Source file containing theread implementation])
2266 AC_SUBST(G_THREAD_CFLAGS)
2267 AC_SUBST(G_THREAD_LIBS)
2268 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2269 AC_SUBST(G_THREAD_LIBS_EXTRA)
2270
2271 dnl **********************************************
2272 dnl *** GDefaultMutex setup and initialization ***
2273 dnl **********************************************
2274 dnl
2275 dnl if mutex_has_default = yes, we also got
2276 dnl mutex_default_type, mutex_default_init and mutex_header_file
2277 if test $mutex_has_default = yes ; then
2278         glib_save_CPPFLAGS="$CPPFLAGS"
2279         glib_save_LIBS="$LIBS"
2280         LIBS="$G_THREAD_LIBS $LIBS"
2281         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2282         GLIB_SIZEOF([#include <$mutex_header_file>],
2283                     $mutex_default_type,
2284                     gmutex)
2285         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
2286                            $mutex_default_type,
2287                            gmutex,
2288                            $glib_cv_sizeof_gmutex,
2289                            $mutex_default_init)
2290         if test x"$glib_cv_byte_contents_gmutex" = xno; then
2291                 mutex_has_default=no
2292         fi
2293         CPPFLAGS="$glib_save_CPPFLAGS"
2294         LIBS="$glib_save_LIBS"
2295 fi
2296
2297 AC_CHECK_FUNCS(clock_gettime, [], [
2298   AC_CHECK_LIB(rt, clock_gettime, [
2299     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2300     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2301     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2302   ])
2303 ])
2304
2305 AC_CACHE_CHECK(for monotonic clocks,
2306     glib_cv_monotonic_clock,AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
2307 #include <time.h>
2308 #include <unistd.h>
2309 int main() {
2310 #if !(defined(_POSIX_MONOTONIC_CLOCK) && _POSIX_MONOTONIC_CLOCK >= 0 && defined(CLOCK_MONOTONIC))
2311         #error No monotonic clock
2312 #endif
2313         return 0;
2314 }
2315 ]])],glib_cv_monotonic_clock=yes,glib_cv_monotonic_clock=no))
2316 if test "$glib_cv_monotonic_clock" = "yes"; then
2317   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
2318 fi
2319
2320
2321 dnl ********************************
2322 dnl *** g_atomic_* tests for gcc ***
2323 dnl ********************************
2324
2325 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
2326
2327 if test x"$GCC" = xyes; then
2328   case $host_cpu in
2329     i386)
2330       AC_MSG_RESULT([none])
2331       glib_memory_barrier_needed=no
2332       ;;
2333     i?86)
2334       AC_MSG_RESULT([i486])
2335       AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
2336                          [i486 atomic implementation])
2337       glib_memory_barrier_needed=no
2338       ;;
2339     sparc*)
2340       SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
2341                 when you are using a sparc with v9 instruction set (most
2342                 sparcs nowadays). This will make the code for atomic
2343                 operations much faster. The resulting code will not run
2344                 on very old sparcs though."
2345
2346       AC_LINK_IFELSE([[
2347         main ()
2348         {
2349           int tmp1, tmp2, tmp3;
2350           __asm__ __volatile__("casx [%2], %0, %1"
2351                                : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
2352         }]],
2353         AC_MSG_RESULT([sparcv9])
2354         AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
2355                            [sparcv9 atomic implementation]),
2356         AC_MSG_RESULT([no])
2357         AC_MSG_WARN([[$SPARCV9_WARNING]]))
2358       glib_memory_barrier_needed=yes
2359       ;;
2360     alpha*)
2361       AC_MSG_RESULT([alpha])
2362       AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
2363                          [alpha atomic implementation])
2364       glib_memory_barrier_needed=yes
2365       ;;
2366     x86_64)
2367       AC_MSG_RESULT([x86_64])
2368       AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
2369                          [x86_64 atomic implementation])
2370       glib_memory_barrier_needed=no
2371      ;;
2372     powerpc*)
2373       AC_MSG_RESULT([powerpc])
2374       AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
2375                          [powerpc atomic implementation])
2376       glib_memory_barrier_needed=yes
2377       AC_MSG_CHECKING([whether asm supports numbered local labels])
2378       AC_TRY_COMPILE(
2379                 ,[
2380                         __asm__ __volatile__ ("1:       nop\n"
2381                                               "         bne-    1b")
2382                 ],[
2383                         AC_DEFINE_UNQUOTED(ASM_NUMERIC_LABELS, 1, [define if asm blocks can use numeric local labels])
2384                         AC_MSG_RESULT([yes])
2385                 ],[
2386                         AC_MSG_RESULT([no])
2387                 ])
2388       ;;
2389     ia64)
2390       AC_MSG_RESULT([ia64])
2391       AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
2392                          [ia64 atomic implementation])
2393       glib_memory_barrier_needed=yes
2394       ;;
2395     s390|s390x)
2396       AC_MSG_RESULT([s390])
2397       AC_DEFINE_UNQUOTED(G_ATOMIC_S390, 1,
2398                          [s390 atomic implementation])
2399       glib_memory_barrier_needed=no
2400       ;;
2401     arm*)
2402       AC_MSG_RESULT([arm])
2403       AC_DEFINE_UNQUOTED(G_ATOMIC_ARM, 1,
2404                          [arm atomic implementation])
2405       glib_memory_barrier_needed=no
2406       ;;
2407     *)
2408       AC_MSG_RESULT([none])
2409       glib_memory_barrier_needed=yes
2410       ;;
2411   esac
2412 else
2413   if test $glib_native_win32 = yes; then
2414     # For Windows but not using gcc. No barriers needed then either.
2415     glib_memory_barrier_needed=no
2416   fi
2417 fi
2418
2419 dnl ****************************************
2420 dnl *** GLib POLL* compatibility defines ***
2421 dnl ****************************************
2422
2423 glib_poll_includes=["
2424 #include <sys/types.h>
2425 #include <sys/poll.h>
2426 "]
2427
2428 if test $ac_cv_header_sys_types_h = yes &&
2429    test $ac_cv_header_sys_poll_h = yes ; then
2430   glib_failed=false
2431   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2432   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2433   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2434   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2435   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2436   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2437   if $glib_failed ; then
2438     AC_MSG_ERROR([Could not determine values for POLL* constants])
2439   fi
2440 else
2441   glib_cv_value_POLLIN=1
2442   glib_cv_value_POLLOUT=4
2443   glib_cv_value_POLLPRI=2
2444   glib_cv_value_POLLERR=8
2445   glib_cv_value_POLLHUP=16
2446   glib_cv_value_POLLNVAL=32
2447 fi
2448
2449 AC_MSG_CHECKING([for broken poll])
2450 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2451         #include <stdlib.h>
2452         #include <fcntl.h>
2453         #include <poll.h>
2454         #ifdef HAVE_SYS_POLL_H
2455         #include <sys/poll.h>
2456         #endif
2457         int main(void) {
2458           struct pollfd fds[1];
2459           int fd;
2460           fd = open("/dev/null", 1);
2461           fds[0].fd = fd;
2462           fds[0].events = POLLIN;
2463           fds[0].revents = 0;
2464           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2465                 exit(1);  /* Does not work for devices -- fail */
2466           }
2467           exit(0);
2468         }]])],
2469   [broken_poll=no],
2470   [broken_poll=yes
2471    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2472   [broken_poll="no (cross compiling)"])
2473 AC_MSG_RESULT($broken_poll)
2474
2475 dnl *********************
2476 dnl *** GRegex checks ***
2477 dnl *********************
2478 PCRE_REQUIRED_VERSION=7.2
2479
2480 # Check if we should compile GRegex
2481 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2482               [disable the compilation of GRegex]),
2483 [case "${enableval}" in
2484   yes) enable_regex=true ;;
2485   no)  enable_regex=false ;;
2486   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2487 esac],
2488 [enable_regex=true])
2489
2490 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2491
2492 if test x$enable_regex = xtrue; then
2493   # Check if we should use the internal or the system-supplied pcre
2494   AC_ARG_WITH(pcre,
2495              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2496                              [specify whether to use the internal or the
2497                               system-supplied PCRE library])])
2498
2499   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2500
2501   if test "x$with_pcre" = xsystem; then
2502     PKG_CHECK_MODULES(PCRE,
2503                       libpcre >= $PCRE_REQUIRED_VERSION)
2504     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2505                    glib_save_CFLAGS="$CFLAGS"
2506                    glib_save_LIBS="$LIBS"
2507                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2508                    AC_TRY_RUN([#include <pcre.h>
2509                                int main () {
2510                                  int support;
2511                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2512                                  if (!support)
2513                                    return 1;
2514                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2515                                  if (!support)
2516                                    return 1;
2517                                  return 0;
2518                                }],
2519                    glib_cv_pcre_has_unicode=yes,
2520                    glib_cv_pcre_has_unicode=no,
2521                    glib_cv_pcre_has_unicode=yes)
2522                    CFLAGS="$glib_save_CFLAGS"
2523                    LIBS="$glib_save_LIBS"
2524         ])
2525     if test "$glib_cv_pcre_has_unicode" = "no"; then
2526       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2527     fi
2528     AC_SUBST(PCRE_CFLAGS)
2529     AC_SUBST(PCRE_LIBS)
2530     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2531     PCRE_REQUIRES=libpcre
2532     AC_SUBST(PCRE_REQUIRES)
2533   else
2534     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2535     if test x"$GCC" = xyes; then
2536       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2537       save_CFLAGS="$CFLAGS"
2538       CFLAGS="$CFLAGS -Wno-pointer-sign"
2539       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2540                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2541       CFLAGS="$save_CFLAGS"
2542     fi
2543   fi
2544   AC_SUBST(PCRE_WARN_CFLAGS)
2545 else
2546   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2547 fi
2548
2549 dnl **********************
2550 dnl *** Win32 API libs ***
2551 dnl **********************
2552
2553 case $host in
2554   *-*-cygwin*)
2555         G_LIBS_EXTRA="-luser32 -lkernel32"
2556     ;;
2557   *-*-mingw*)
2558         G_LIBS_EXTRA="-lws2_32 -lole32"
2559     ;;
2560   *)
2561         G_LIBS_EXTRA=""
2562     ;;
2563 esac
2564 AC_SUBST(G_LIBS_EXTRA)
2565
2566 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2567 dnl since we need it for g_iconv()
2568
2569 AC_MSG_CHECKING([for EILSEQ])
2570 AC_TRY_COMPILE([
2571 #include <errno.h>
2572 ],
2573 [
2574 int error = EILSEQ;
2575 ], have_eilseq=yes, have_eilseq=no);
2576 AC_MSG_RESULT($have_eilseq)
2577
2578 dnl ******************************************************************
2579 dnl *** Look for glib-genmarshal in PATH if we are cross-compiling ***
2580 dnl ******************************************************************
2581
2582 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2583
2584 if test $cross_compiling = yes; then
2585   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2586   if test x$GLIB_GENMARSHAL = xno; then
2587     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2588   fi
2589 fi
2590
2591 dnl **************************
2592 dnl *** Checks for gtk-doc ***
2593 dnl **************************
2594
2595 GTK_DOC_CHECK([1.11])
2596
2597 AC_ARG_ENABLE(man,
2598               [AC_HELP_STRING([--enable-man],
2599                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2600               enable_man=no)
2601
2602 if test "${enable_man}" != no; then
2603 dnl
2604 dnl Check for xsltproc
2605 dnl
2606 AC_PATH_PROG([XSLTPROC], [xsltproc])
2607   if test -z "$XSLTPROC"; then
2608     enable_man=no
2609   fi
2610
2611   dnl check for DocBook DTD and stylesheets in the local catalog.
2612   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2613      [DocBook XML DTD V4.1.2],,enable_man=no)
2614   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2615      [DocBook XSL Stylesheets],,enable_man=no)
2616 fi
2617
2618 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2619
2620 dnl ******************************
2621 dnl *** output the whole stuff ***
2622 dnl ******************************
2623
2624 dnl this section will only be run if config.status is invoked with no
2625 dnl arguments, or with "glibconfig.h" as an argument.
2626 AC_CONFIG_COMMANDS([glibconfig.h],
2627 [
2628         outfile=glibconfig.h-tmp
2629         cat > $outfile <<\_______EOF
2630 /* glibconfig.h
2631  *
2632  * This is a generated file.  Please modify 'configure.in'
2633  */
2634
2635 #ifndef __G_LIBCONFIG_H__
2636 #define __G_LIBCONFIG_H__
2637
2638 #include <glib/gmacros.h>
2639
2640 _______EOF
2641
2642         if test x$glib_limits_h = xyes; then
2643           echo '#include <limits.h>' >> $outfile
2644         fi
2645         if test x$glib_float_h = xyes; then
2646           echo '#include <float.h>' >> $outfile
2647         fi
2648         if test x$glib_values_h = xyes; then
2649           echo '#include <values.h>' >> $outfile
2650         fi
2651         if test "$glib_header_alloca_h" = "yes"; then
2652           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2653         fi
2654         if test x$glib_sys_poll_h = xyes; then
2655           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2656         fi
2657         if test x$glib_included_printf != xyes; then
2658           echo "
2659 /* Specifies that GLib's g_print*() functions wrap the
2660  * system printf functions.  This is useful to know, for example,
2661  * when using glibc's register_printf_function().
2662  */" >> $outfile
2663           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2664         fi
2665
2666         cat >> $outfile <<_______EOF
2667
2668 G_BEGIN_DECLS
2669
2670 #define G_MINFLOAT      $glib_mf
2671 #define G_MAXFLOAT      $glib_Mf
2672 #define G_MINDOUBLE     $glib_md
2673 #define G_MAXDOUBLE     $glib_Md
2674 #define G_MINSHORT      $glib_ms
2675 #define G_MAXSHORT      $glib_Ms
2676 #define G_MAXUSHORT     $glib_Mus
2677 #define G_MININT        $glib_mi
2678 #define G_MAXINT        $glib_Mi
2679 #define G_MAXUINT       $glib_Mui
2680 #define G_MINLONG       $glib_ml
2681 #define G_MAXLONG       $glib_Ml
2682 #define G_MAXULONG      $glib_Mul
2683
2684 _______EOF
2685
2686
2687         ### this should always be true in a modern C/C++ compiler
2688         cat >>$outfile <<_______EOF
2689 typedef signed char gint8;
2690 typedef unsigned char guint8;
2691 _______EOF
2692
2693
2694         if test -n "$gint16"; then
2695           cat >>$outfile <<_______EOF
2696 typedef signed $gint16 gint16;
2697 typedef unsigned $gint16 guint16;
2698 #define G_GINT16_MODIFIER $gint16_modifier
2699 #define G_GINT16_FORMAT $gint16_format
2700 #define G_GUINT16_FORMAT $guint16_format
2701 _______EOF
2702         fi
2703
2704
2705         if test -n "$gint32"; then
2706           cat >>$outfile <<_______EOF
2707 typedef signed $gint32 gint32;
2708 typedef unsigned $gint32 guint32;
2709 #define G_GINT32_MODIFIER $gint32_modifier
2710 #define G_GINT32_FORMAT $gint32_format
2711 #define G_GUINT32_FORMAT $guint32_format
2712 _______EOF
2713         fi
2714
2715         cat >>$outfile <<_______EOF
2716 #define G_HAVE_GINT64 1          /* deprecated, always true */
2717
2718 ${glib_extension}typedef signed $gint64 gint64;
2719 ${glib_extension}typedef unsigned $gint64 guint64;
2720
2721 #define G_GINT64_CONSTANT(val)  $gint64_constant
2722 #define G_GUINT64_CONSTANT(val) $guint64_constant
2723 _______EOF
2724
2725         if test x$gint64_format != x ; then
2726           cat >>$outfile <<_______EOF
2727 #define G_GINT64_MODIFIER $gint64_modifier
2728 #define G_GINT64_FORMAT $gint64_format
2729 #define G_GUINT64_FORMAT $guint64_format
2730 _______EOF
2731         else
2732           cat >>$outfile <<_______EOF
2733 #undef G_GINT64_MODIFIER
2734 #undef G_GINT64_FORMAT
2735 #undef G_GUINT64_FORMAT
2736 _______EOF
2737         fi
2738
2739         cat >>$outfile <<_______EOF
2740
2741 #define GLIB_SIZEOF_VOID_P $glib_void_p
2742 #define GLIB_SIZEOF_LONG   $glib_long
2743 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2744
2745 _______EOF
2746
2747         cat >>$outfile <<_______EOF
2748 typedef signed $glib_size_type_define gssize;
2749 typedef unsigned $glib_size_type_define gsize;
2750 #define G_GSIZE_MODIFIER $gsize_modifier
2751 #define G_GSSIZE_FORMAT $gssize_format
2752 #define G_GSIZE_FORMAT $gsize_format
2753
2754 #define G_MAXSIZE       G_MAXU$glib_msize_type
2755 #define G_MINSSIZE      G_MIN$glib_msize_type
2756 #define G_MAXSSIZE      G_MAX$glib_msize_type
2757
2758 typedef gint64 goffset;
2759 #define G_MINOFFSET     G_MININT64
2760 #define G_MAXOFFSET     G_MAXINT64
2761
2762 _______EOF
2763
2764         if test -z "$glib_unknown_void_p"; then
2765           cat >>$outfile <<_______EOF
2766
2767 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2768 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2769
2770 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2771 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2772
2773 typedef signed $glib_intptr_type_define gintptr;
2774 typedef unsigned $glib_intptr_type_define guintptr;
2775 _______EOF
2776         else
2777           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2778         fi
2779
2780
2781
2782         cat >>$outfile <<_______EOF
2783 $glib_atexit
2784 $glib_memmove
2785 $glib_defines
2786 $glib_os
2787 $glib_static_compilation
2788
2789 $glib_vacopy
2790
2791 #ifdef  __cplusplus
2792 #define G_HAVE_INLINE   1
2793 #else   /* !__cplusplus */
2794 $glib_inline
2795 #endif  /* !__cplusplus */
2796
2797 #ifdef  __cplusplus
2798 #define G_CAN_INLINE    1
2799 _______EOF
2800
2801         if test x$g_can_inline = xyes ; then
2802                 cat >>$outfile <<_______EOF
2803 #else   /* !__cplusplus */
2804 #define G_CAN_INLINE    1
2805 _______EOF
2806         fi
2807
2808         cat >>$outfile <<_______EOF
2809 #endif
2810
2811 _______EOF
2812
2813         if test x$g_have_iso_c_varargs = xyes ; then
2814                 cat >>$outfile <<_______EOF
2815 #ifndef __cplusplus
2816 # define G_HAVE_ISO_VARARGS 1
2817 #endif
2818 _______EOF
2819         fi
2820         if test x$g_have_iso_cxx_varargs = xyes ; then
2821                 cat >>$outfile <<_______EOF
2822 #ifdef __cplusplus
2823 # define G_HAVE_ISO_VARARGS 1
2824 #endif
2825 _______EOF
2826         fi
2827         if test x$g_have_gnuc_varargs = xyes ; then
2828                 cat >>$outfile <<_______EOF
2829
2830 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2831  * is passed ISO vararg support is turned off, and there is no work
2832  * around to turn it on, so we unconditionally turn it off.
2833  */
2834 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2835 #  undef G_HAVE_ISO_VARARGS
2836 #endif
2837
2838 #define G_HAVE_GNUC_VARARGS 1
2839 _______EOF
2840         fi
2841
2842         case x$g_stack_grows in
2843         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2844         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2845         esac
2846
2847
2848         echo >>$outfile
2849         if test x$g_have_eilseq = xno; then
2850                 cat >>$outfile <<_______EOF
2851 #ifndef EILSEQ
2852 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2853  * The correspondence between this and the corresponding definition
2854  * in libiconv is essential.
2855  */
2856 #  define EILSEQ ENOENT
2857 #endif
2858 _______EOF
2859
2860         fi
2861
2862         if test x$g_have_gnuc_visibility = xyes; then
2863                 cat >>$outfile <<_______EOF
2864 #define G_HAVE_GNUC_VISIBILITY 1
2865 _______EOF
2866         fi
2867                 cat >>$outfile <<_______EOF
2868 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2869 #define G_GNUC_INTERNAL __hidden
2870 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2871 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2872 #else
2873 #define G_GNUC_INTERNAL
2874 #endif
2875 _______EOF
2876
2877
2878         echo >>$outfile
2879         if test x$g_mutex_has_default = xyes; then
2880                 cat >>$outfile <<_______EOF
2881 $g_enable_threads_def G_THREADS_ENABLED
2882 #define G_THREADS_IMPL_$g_threads_impl_def
2883 typedef struct _GStaticMutex GStaticMutex;
2884 struct _GStaticMutex
2885 {
2886   struct _GMutex *runtime_mutex;
2887   union {
2888     char   pad[[$g_mutex_sizeof]];
2889     double dummy_double;
2890     void  *dummy_pointer;
2891     long   dummy_long;
2892   } static_mutex;
2893 };
2894 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
2895 #define g_static_mutex_get_mutex(mutex) \\
2896   (g_thread_use_default_impl ? ((GMutex*)(gpointer) ((mutex)->static_mutex.pad)) : \\
2897    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
2898 _______EOF
2899         else
2900                 cat >>$outfile <<_______EOF
2901 $g_enable_threads_def G_THREADS_ENABLED
2902 #define G_THREADS_IMPL_$g_threads_impl_def
2903 typedef struct _GMutex* GStaticMutex;
2904 #define G_STATIC_MUTEX_INIT NULL
2905 #define g_static_mutex_get_mutex(mutex) \\
2906   (g_static_mutex_get_mutex_impl_shortcut (mutex))
2907 _______EOF
2908         fi
2909
2910         cat >>$outfile <<_______EOF
2911 /* This represents a system thread as used by the implementation. An
2912  * alien implementaion, as loaded by g_thread_init can only count on
2913  * "sizeof (gpointer)" bytes to store their info. We however need more
2914  * for some of our native implementations. */
2915 typedef union _GSystemThread GSystemThread;
2916 union _GSystemThread
2917 {
2918   char   data[[$g_system_thread_sizeof]];
2919   double dummy_double;
2920   void  *dummy_pointer;
2921   long   dummy_long;
2922 };
2923 _______EOF
2924         if test x"$g_memory_barrier_needed" != xno; then
2925           echo >>$outfile
2926           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2927         fi
2928
2929         echo >>$outfile
2930         g_bit_sizes="16 32 64"
2931         for bits in $g_bit_sizes; do
2932           cat >>$outfile <<_______EOF
2933 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
2934 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
2935 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2936 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
2937 _______EOF
2938         done
2939
2940         cat >>$outfile <<_______EOF
2941 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
2942 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
2943 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
2944 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
2945 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
2946 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
2947 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
2948 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
2949 #define G_BYTE_ORDER $g_byte_order
2950
2951 #define GLIB_SYSDEF_POLLIN =$g_pollin
2952 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2953 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2954 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2955 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2956 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2957
2958 #define G_MODULE_SUFFIX "$g_module_suffix"
2959
2960 /* A GPid is an abstraction for a process "handle". It is *not* an
2961  * abstraction for a process identifier in general. GPid is used in
2962  * GLib only for descendant processes spawned with the g_spawn*
2963  * functions. On POSIX there is no "process handle" concept as such,
2964  * but on Windows a GPid is a handle to a process, a kind of pointer,
2965  * not a process identifier.
2966  */
2967 typedef $g_pid_type GPid;
2968
2969 G_END_DECLS
2970
2971 #endif /* GLIBCONFIG_H */
2972 _______EOF
2973
2974
2975         if cmp -s $outfile glibconfig.h; then
2976           AC_MSG_NOTICE([glibconfig.h is unchanged])
2977           rm -f $outfile
2978         else
2979           mv $outfile glibconfig.h
2980         fi
2981 ],[
2982
2983 # Note that if two cases are the same, case goes with the first one.
2984 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
2985 # on variable expansion in case labels.  Look at the generated config.status
2986 # for a hint.
2987
2988 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2989   glib_header_alloca_h="$ac_cv_working_alloca_h"
2990 else
2991   glib_header_alloca_h="$ac_cv_header_alloca_h"
2992 fi
2993
2994 case xyes in
2995 x$ac_cv_header_float_h)
2996   glib_float_h=yes
2997   glib_mf=FLT_MIN glib_Mf=FLT_MAX
2998   glib_md=DBL_MIN glib_Md=DBL_MAX
2999   ;;
3000 x$ac_cv_header_values_h)
3001   glib_values_h=yes
3002   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3003   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3004   ;;
3005 esac
3006
3007 case xyes in
3008 x$ac_cv_header_limits_h)
3009   glib_limits_h=yes
3010   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3011   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3012   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3013   ;;
3014 x$ac_cv_header_values_h)
3015   glib_values_h=yes
3016   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3017   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3018   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3019   ;;
3020 esac
3021
3022 if test x$ac_cv_header_sys_poll_h = xyes ; then
3023   glib_sys_poll_h=yes
3024 fi
3025
3026 if test x$enable_included_printf = xyes ; then
3027   glib_included_printf=yes
3028 fi
3029
3030 case 2 in
3031 $ac_cv_sizeof_short)
3032   gint16=short
3033   gint16_modifier='"h"'
3034   gint16_format='"hi"'
3035   guint16_format='"hu"'
3036   ;;
3037 $ac_cv_sizeof_int)
3038   gint16=int
3039   gint16_modifier='""'
3040   gint16_format='"i"'
3041   guint16_format='"u"'
3042   ;;
3043 esac
3044 case 4 in
3045 $ac_cv_sizeof_short)
3046   gint32=short
3047   gint32_modifier='"h"'
3048   gint32_format='"hi"'
3049   guint32_format='"hu"'
3050   ;;
3051 $ac_cv_sizeof_int)
3052   gint32=int
3053   gint32_modifier='""'
3054   gint32_format='"i"'
3055   guint32_format='"u"'
3056   ;;
3057 $ac_cv_sizeof_long)
3058   gint32=long
3059   gint32_modifier='"l"'
3060   gint32_format='"li"'
3061   guint32_format='"lu"'
3062   ;;
3063 esac
3064 case 8 in
3065 $ac_cv_sizeof_int)
3066   gint64=int
3067   gint64_modifier='""'
3068   gint64_format='"i"'
3069   guint64_format='"u"'
3070   glib_extension=
3071   gint64_constant='(val)'
3072   guint64_constant='(val)'
3073   ;;
3074 $ac_cv_sizeof_long)
3075   gint64=long
3076   gint64_modifier='"l"'
3077   gint64_format='"li"'
3078   guint64_format='"lu"'
3079   glib_extension=
3080   gint64_constant='(val##L)'
3081   guint64_constant='(val##UL)'
3082   ;;
3083 $ac_cv_sizeof_long_long)
3084   gint64='long long'
3085   if test -n "$glib_cv_long_long_format"; then
3086     gint64_modifier='"'$glib_cv_long_long_format'"'
3087     gint64_format='"'$glib_cv_long_long_format'i"'
3088     guint64_format='"'$glib_cv_long_long_format'u"'
3089   fi
3090   glib_extension='G_GNUC_EXTENSION '
3091   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3092   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3093   ;;
3094 $ac_cv_sizeof___int64)
3095   gint64='__int64'
3096   if test -n "$glib_cv_long_long_format"; then
3097     gint64_modifier='"'$glib_cv_long_long_format'"'
3098     gint64_format='"'$glib_cv_long_long_format'i"'
3099     guint64_format='"'$glib_cv_long_long_format'u"'
3100   fi
3101   glib_extension=
3102   gint64_constant='(val##i64)'
3103   guint64_constant='(val##ui64)'
3104   ;;
3105 esac
3106 glib_size_t=$ac_cv_sizeof_size_t
3107 glib_size_type_define="$glib_size_type"
3108 glib_void_p=$ac_cv_sizeof_void_p
3109 glib_long=$ac_cv_sizeof_long
3110
3111 case "$glib_size_type" in
3112 short)
3113   gsize_modifier='"h"'
3114   gsize_format='"hu"'
3115   gssize_format='"hi"'
3116   glib_msize_type='SHRT'
3117   ;;
3118 int)
3119   gsize_modifier='""'
3120   gsize_format='"u"'
3121   gssize_format='"i"'
3122   glib_msize_type='INT'
3123   ;;
3124 long)
3125   gsize_modifier='"l"'
3126   gsize_format='"lu"'
3127   gssize_format='"li"'
3128   glib_msize_type='LONG'
3129   ;;
3130 "long long"|__int64)
3131   gsize_modifier='"I64"'
3132   gsize_format='"I64u"'
3133   gssize_format='"I64i"'
3134   glib_msize_type='INT64'
3135   ;;
3136 esac
3137
3138 gintbits=`expr $ac_cv_sizeof_int \* 8`
3139 glongbits=`expr $ac_cv_sizeof_long \* 8`
3140
3141 case $ac_cv_sizeof_void_p in
3142 $ac_cv_sizeof_int)
3143   glib_intptr_type_define=int
3144   glib_gpi_cast=''
3145   glib_gpui_cast=''
3146   ;;
3147 $ac_cv_sizeof_long)
3148   glib_intptr_type_define=long
3149   glib_gpi_cast='(glong)'
3150   glib_gpui_cast='(gulong)'
3151   ;;
3152 $ac_cv_sizeof_long_long)
3153   glib_intptr_type_define='long long'
3154   glib_gpi_cast='(gint64)'
3155   glib_gpui_cast='(guint64)'
3156   ;;
3157 $ac_cv_sizeof___int64)
3158   glib_intptr_type_define=__int64
3159   glib_gpi_cast='(gint64)'
3160   glib_gpui_cast='(guint64)'
3161   ;;
3162 *)
3163   glib_unknown_void_p=yes
3164   ;;
3165 esac
3166
3167
3168 case xyes in
3169 x$ac_cv_func_atexit)
3170   glib_atexit="
3171 #ifdef NeXT /* @#%@! NeXTStep */
3172 # define g_ATEXIT(proc) (!atexit (proc))
3173 #else
3174 # define g_ATEXIT(proc) (atexit (proc))
3175 #endif"
3176   ;;
3177 x$ac_cv_func_on_exit)
3178   glib_atexit="
3179 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3180   ;;
3181 esac
3182
3183 case xyes in
3184 x$ac_cv_func_memmove)
3185   glib_memmove='
3186 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3187   ;;
3188 x$glib_cv_working_bcopy)
3189   glib_memmove="
3190 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3191 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3192   ;;
3193 *)
3194   glib_memmove="
3195 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3196  * so we have to roll our own copy routine. */
3197 void g_memmove (void* dest, const void * src, unsigned long len);"
3198   ;;
3199 esac
3200
3201 glib_defines="
3202 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3203 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3204 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3205 "
3206
3207 case xyes in
3208 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3209 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3210 *)                      glib_vacopy=''
3211 esac
3212
3213 if test x$glib_cv_va_val_copy = xno; then
3214   glib_vacopy="\$glib_vacopy
3215 #define G_VA_COPY_AS_ARRAY 1"
3216 fi
3217
3218 if test x$glib_cv_hasinline = xyes; then
3219     glib_inline='#define G_HAVE_INLINE 1'
3220 fi
3221 if test x$glib_cv_has__inline = xyes; then
3222     glib_inline="\$glib_inline
3223 #define G_HAVE___INLINE 1"
3224 fi
3225 if test x$glib_cv_has__inline__ = xyes; then
3226     glib_inline="\$glib_inline
3227 #define G_HAVE___INLINE__ 1"
3228 fi
3229
3230 g_have_gnuc_varargs=$g_have_gnuc_varargs
3231 g_have_iso_c_varargs=$g_have_iso_c_varargs
3232 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3233
3234 g_can_inline=$g_can_inline
3235 g_have_gnuc_visibility=$g_have_gnuc_visibility
3236 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3237
3238 if test x$ac_cv_c_bigendian = xyes; then
3239   g_byte_order=G_BIG_ENDIAN
3240   g_bs_native=BE
3241   g_bs_alien=LE
3242 else
3243   g_byte_order=G_LITTLE_ENDIAN
3244   g_bs_native=LE
3245   g_bs_alien=BE
3246 fi
3247
3248 g_pollin=$glib_cv_value_POLLIN
3249 g_pollout=$glib_cv_value_POLLOUT
3250 g_pollpri=$glib_cv_value_POLLPRI
3251 g_pollhup=$glib_cv_value_POLLHUP
3252 g_pollerr=$glib_cv_value_POLLERR
3253 g_pollnval=$glib_cv_value_POLLNVAL
3254
3255 g_stack_grows=$glib_cv_stack_grows
3256
3257 g_have_eilseq=$have_eilseq
3258
3259 case x$have_threads in
3260 xno)    g_enable_threads_def="#undef";;
3261 *)      g_enable_threads_def="#define";;
3262 esac
3263
3264 g_threads_impl_def=$g_threads_impl
3265
3266 g_mutex_has_default="$mutex_has_default"
3267 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
3268 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
3269 g_mutex_contents="$glib_cv_byte_contents_gmutex"
3270
3271 g_memory_barrier_needed="$glib_memory_barrier_needed"
3272
3273 g_module_suffix="$glib_gmodule_suffix"
3274
3275 g_pid_type="$glib_pid_type"
3276 case $host in
3277   *-*-beos*)
3278     glib_os="#define G_OS_BEOS"
3279     ;;
3280   *-*-cygwin*)
3281     glib_os="#define G_OS_UNIX
3282 #define G_PLATFORM_WIN32
3283 #define G_WITH_CYGWIN"
3284     ;;
3285   *-*-mingw*)
3286     glib_os="#define G_OS_WIN32
3287 #define G_PLATFORM_WIN32"
3288     ;;
3289   *)
3290     glib_os="#define G_OS_UNIX"
3291     ;;
3292 esac
3293 glib_static_compilation=""
3294 if test x$glib_win32_static_compilation = xyes; then
3295   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3296 #define GOBJECT_STATIC_COMPILATION 1"
3297 fi
3298 ])
3299
3300 AC_CONFIG_FILES([
3301 glib-2.0.pc
3302 glib-2.0-uninstalled.pc
3303 gmodule-2.0.pc
3304 gmodule-export-2.0.pc
3305 gmodule-no-export-2.0.pc
3306 gmodule-2.0-uninstalled.pc
3307 gmodule-no-export-2.0-uninstalled.pc
3308 gthread-2.0.pc
3309 gthread-2.0-uninstalled.pc
3310 gobject-2.0.pc
3311 gobject-2.0-uninstalled.pc
3312 gio-2.0.pc
3313 gio-unix-2.0.pc
3314 gio-2.0-uninstalled.pc
3315 gio-unix-2.0-uninstalled.pc
3316 glib-zip
3317 glib-gettextize
3318 Makefile
3319 build/Makefile
3320 build/win32/Makefile
3321 build/win32/dirent/Makefile
3322 build/win32/vs8/Makefile
3323 build/win32/vs9/Makefile
3324 glib/Makefile
3325 glib/libcharset/Makefile
3326 glib/gnulib/Makefile
3327 glib/pcre/Makefile
3328 glib/update-pcre/Makefile
3329 glib/tests/Makefile
3330 gmodule/Makefile
3331 gmodule/gmoduleconf.h
3332 gobject/Makefile
3333 gobject/glib-mkenums
3334 gobject/tests/Makefile
3335 gthread/Makefile
3336 gio/Makefile
3337 gio/xdgmime/Makefile
3338 gio/inotify/Makefile
3339 gio/fen/Makefile
3340 gio/fam/Makefile
3341 gio/win32/Makefile
3342 gio/tests/Makefile
3343 po/Makefile.in
3344 docs/Makefile
3345 docs/reference/Makefile
3346 docs/reference/glib/Makefile
3347 docs/reference/glib/version.xml
3348 docs/reference/gobject/Makefile
3349 docs/reference/gobject/version.xml
3350 docs/reference/gio/Makefile
3351 docs/reference/gio/version.xml
3352 tests/Makefile
3353 tests/gobject/Makefile
3354 tests/refcount/Makefile
3355 m4macros/Makefile
3356 ])
3357
3358 AC_CONFIG_COMMANDS([chmod-scripts],
3359 [chmod 0755 glib-zip
3360 chmod 0755 glib-gettextize
3361 chmod 0755 gobject/glib-mkenums])
3362
3363 # we want to invoke this macro solely so that the config.status script
3364 # and automake generated makefiles know about these generated files.
3365 # They are only needed to distcheck the package
3366 if false; then
3367   AC_CONFIG_FILES([
3368     INSTALL
3369     README
3370     config.h.win32
3371     glibconfig.h.win32
3372     glib/makefile.msc
3373     glib/glib.rc
3374     gmodule/makefile.msc
3375     gmodule/gmodule.rc
3376     gobject/makefile.msc
3377     gobject/gobject.rc
3378     gthread/makefile.msc
3379     gthread/gthread.rc
3380     tests/makefile.msc
3381   ])
3382 fi
3383
3384 AC_OUTPUT