configure.in

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002
   4 # Free Software Foundation, Inc.
   5 #
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  19 # 02111-1307, USA.
  20
  21 AC_PREREQ(2.54)
  22 AC_INIT([GNU Automake], [1.7a], [bug-automake@gnu.org])
  23
  24 AC_CONFIG_SRCDIR(automake.in)
  25 AC_CONFIG_AUX_DIR(lib)
  26
  27 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it;
  28 # this way we can run Autoconf tests from configure without being
  29 # bothered by `missing'.
  30 am_AUTOCONF=${AUTOCONF-autoconf}
  31
  32 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  33
  34 # The API version is the base version.  We must guarantee
  35 # compatibility for all releases with the same API version.
  36 # Our current rule is that:
  37 # * All releases, including the prereleases, in an X.Y series
  38 #   are compatible.  So 1.5.1c is compatible with 1.5.
  39 # * Prereleases on the trunk are all incompatible -- 1.5b and 1.5c
  40 #   aren't the same.
  41 APIVERSION=`echo "$VERSION" | sed -e 's/^\([[0-9]]*\.[[0-9]]*[[a-z]]*\).*$/\1/'`
  42 AC_SUBST(APIVERSION)
  43
  44 # A versioned directory, defined here for convenience.
  45 pkgvdatadir="\${datadir}/automake-${APIVERSION}"
  46 AC_SUBST(pkgvdatadir)
  47
  48 # $AUTOMAKE and $ACLOCAL are always run after a `cd $top_srcdir',
  49 # hence `.' is really what we want for perllibdir and libdir.
  50 ACLOCAL="perllibdir=./lib `pwd`/aclocal --acdir=m4 -I `pwd`/m4"
  51 AUTOMAKE="perllibdir=./lib `pwd`/automake --libdir=lib"
  52
  53 AC_PATH_PROG(PERL, perl)
  54 if test -z "$PERL"; then
  55    AC_MSG_ERROR([perl not found])
  56 fi
  57 $PERL -e 'require 5.005;' || {
  58    AC_MSG_ERROR([perl 5.005 or better is required])
  59 }
  60
  61 # The test suite will skip some tests if tex is absent.
  62 AC_CHECK_PROG([TEX], [tex], [tex])
  63
  64 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
  65 # deletion of any files created (such as those added to
  66 # autom4te.cache).
  67 mkdir conftest
  68 echo 'AC''_PREREQ(2.54)' > conftest/conftest.ac
  69 AM_RUN_LOG([cd conftest && eval $am_AUTOCONF -o /dev/null conftest.ac]) || {
  70    AC_MSG_ERROR([Autoconf 2.54 or better is required.
  71   Is it installed?  Is it in your PATH?  (try running `autoconf --version')
  72   Is it working?  See also config.log for error messages before this one.])
  73 }
  74 rm -rf conftest
  75
  76 # Test for ln.  We need use it to install the versioned binaries.
  77 AC_MSG_CHECKING([whether ln works])
  78 AC_CACHE_VAL([am_cv_prog_ln], [
  79 rm -f conftest conftest.file
  80 : >conftest.file
  81 if ln conftest.file conftest 2>/dev/null; then
  82   am_cv_prog_ln=ln
  83 else
  84   am_cv_prog_ln='cp -p'
  85 fi
  86 rm -f conftest conftest.file])
  87 AC_SUBST([LN], [$am_cv_prog_ln])
  88 result=no
  89 test "x$am_cv_prog_ln" = xln && result=yes
  90 AC_MSG_RESULT([$result])
  91
  92 # Test for things needed by the test suite.
  93 AC_PROG_EGREP
  94 AC_PROG_FGREP
  95
  96 AC_CONFIG_FILES([
  97   Makefile
  98   lib/Automake/Makefile
  99   lib/Automake/tests/Makefile
 100   lib/Makefile
 101   lib/am/Makefile
 102   m4/Makefile
 103   m4/amversion.m4:m4/amversion.in
 104   tests/Makefile
 105   tests/defs
 106 ])
 107
 108 AC_OUTPUT