configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.53)dnl              dnl Minimum Autoconf version required.
   3 AC_INIT([GNU C Library], [(see version.h)], [http://sourceware.org/bugzilla/], [glibc])
   4 AC_CONFIG_SRCDIR([include/features.h])
   5 AC_CONFIG_HEADERS([config.h])
   6 AC_CONFIG_AUX_DIR([scripts])
   7
   8 dnl This is here so we can set $subdirs directly based on configure fragments.
   9 AC_CONFIG_SUBDIRS()
  10
  11 AC_CANONICAL_HOST
  12
  13 AC_PROG_CC
  14 if test $host != $build; then
  15   AC_CHECK_PROGS(BUILD_CC, gcc cc)
  16 fi
  17 AC_SUBST(cross_compiling)
  18 AC_PROG_CPP
  19 # We need the C++ compiler only for testing.
  20 AC_PROG_CXX
  21
  22 if test "`cd $srcdir; /bin/pwd`" = "`/bin/pwd`"; then
  23   AC_MSG_ERROR([you must configure in a separate build directory])
  24 fi
  25
  26 # This will get text that should go into config.make.
  27 config_vars=
  28
  29 # Check for a --with-gd argument and set libgd-LDFLAGS in config.make.
  30 AC_ARG_WITH([gd],
  31             AC_HELP_STRING([--with-gd=DIR],
  32                            [find libgd include dir and library with prefix DIR]),
  33             [dnl
  34 case "$with_gd" in
  35 yes|''|no) ;;
  36 *) libgd_include="-I$withval/include"
  37    libgd_ldflags="-L$withval/lib" ;;
  38 esac
  39 ])
  40 AC_ARG_WITH([gd-include],
  41             AC_HELP_STRING([--with-gd-include=DIR],
  42                            [find libgd include files in DIR]),
  43             [dnl
  44 case "$with_gd_include" in
  45 ''|no) ;;
  46 *) libgd_include="-I$withval" ;;
  47 esac
  48 ])
  49 AC_ARG_WITH([gd-lib],
  50             AC_HELP_STRING([--with-gd-lib=DIR],
  51                            [find libgd library files in DIR]),
  52             [dnl
  53 case "$with_gd_lib" in
  54 ''|no) ;;
  55 *) libgd_ldflags="-L$withval" ;;
  56 esac
  57 ])
  58
  59 if test -n "$libgd_include"; then
  60   config_vars="$config_vars
  61 CFLAGS-memusagestat.c = $libgd_include"
  62 fi
  63 if test -n "$libgd_ldflags"; then
  64   config_vars="$config_vars
  65 libgd-LDFLAGS = $libgd_ldflags"
  66 fi
  67
  68 dnl Arguments to specify presence of other packages/features.
  69 AC_ARG_WITH([fp],
  70             AC_HELP_STRING([--with-fp],
  71                            [if using floating-point hardware @<:@default=yes@:>@]),
  72             [with_fp=$withval],
  73             [with_fp=yes])
  74 AC_SUBST(with_fp)
  75 AC_ARG_WITH([binutils],
  76             AC_HELP_STRING([--with-binutils=PATH],
  77                            [specify location of binutils (as and ld)]),
  78             [path_binutils=$withval],
  79             [path_binutils=''])
  80 AC_ARG_WITH([selinux],
  81             AC_HELP_STRING([--with-selinux],
  82                            [if building with SELinux support]),
  83             [with_selinux=$withval],
  84             [with_selinux=auto])
  85
  86 AC_ARG_WITH([headers],
  87             AC_HELP_STRING([--with-headers=PATH],
  88                            [location of system headers to use
  89                             (for example /usr/src/linux/include)
  90                             @<:@default=compiler default@:>@]),
  91             [sysheaders=$withval],
  92             [sysheaders=''])
  93
  94 AC_SUBST(use_default_link)
  95 AC_ARG_WITH([default-link],
  96             AC_HELP_STRING([--with-default-link],
  97                            [do not use explicit linker scripts]),
  98             [use_default_link=$withval],
  99             [use_default_link=default])
 100
 101 AC_ARG_ENABLE([sanity-checks],
 102               AC_HELP_STRING([--disable-sanity-checks],
 103                              [really do not use threads (should not be used except in special situations) @<:@default=yes@:>@]),
 104               [enable_sanity=$enableval],
 105               [enable_sanity=yes])
 106
 107 AC_SUBST(enable_check_abi)
 108 AC_ARG_ENABLE([check-abi],
 109               AC_HELP_STRING([--enable-check-abi],
 110                              [do "make check-abi" in "make check" (no/warn/yes)
 111                               @<:@default=no@:>@]),
 112               [enable_check_abi=$enableval],
 113               [enable_check_abi=no])
 114
 115 dnl Arguments to enable or disable building the static, shared, profiled,
 116 dnl and -fomit-frame-pointer libraries.
 117 dnl I've disabled this for now since we cannot build glibc without static
 118 dnl libraries built in the moment.
 119 dnl AC_ARG_ENABLE([static],
 120 dnl               AC_HELP_STRING([--enable-static],
 121 dnl                              [build static library @<:@default=yes@:>@]),
 122 dnl               [static=$enableval],
 123 dnl               [static=yes])
 124 static=yes
 125 AC_ARG_ENABLE([shared],
 126               AC_HELP_STRING([--enable-shared],
 127                              [build shared library @<:@default=yes if GNU ld@:>@]),
 128               [shared=$enableval],
 129               [shared=yes])
 130 AC_ARG_ENABLE([profile],
 131               AC_HELP_STRING([--enable-profile],
 132                              [build profiled library @<:@default=no@:>@]),
 133               [profile=$enableval],
 134               [profile=no])
 135 AC_ARG_ENABLE([versioning],
 136               AC_HELP_STRING([--disable-versioning],
 137                              [do not include versioning information in the library objects @<:@default=yes if supported@:>@]),
 138               [enable_versioning=$enableval],
 139               [enable_versioning=yes])
 140
 141 AC_ARG_ENABLE([oldest-abi],
 142               AC_HELP_STRING([--enable-oldest-abi=ABI],
 143                              [configure the oldest ABI supported @<:@e.g. 2.2@:>@ @<:@default=glibc default@:>@]),
 144               [oldest_abi=$enableval],
 145               [oldest_abi=no])
 146 if test "$oldest_abi" = yes || test "$oldest_abi" = no; then
 147   oldest_abi=default
 148 else
 149   AC_DEFINE_UNQUOTED(GLIBC_OLDEST_ABI, "$oldest_abi")
 150 fi
 151 AC_SUBST(oldest_abi)
 152
 153 AC_ARG_ENABLE([stackguard-randomization],
 154               AC_HELP_STRING([--enable-stackguard-randomization],
 155                              [initialize __stack_chk_guard canary with a random number at program start]),
 156               [enable_stackguard_randomize=$enableval],
 157               [enable_stackguard_randomize=no])
 158 if test "$enable_stackguard_randomize" = yes; then
 159   AC_DEFINE(ENABLE_STACKGUARD_RANDOMIZE)
 160 fi
 161
 162 dnl Generic infrastructure for drop-in additions to libc.
 163 AC_ARG_ENABLE([add-ons],
 164               AC_HELP_STRING([--enable-add-ons@<:@=DIRS...@:>@],
 165                              [configure and build add-ons in DIR1,DIR2,...
 166                               search for add-ons if no parameter given]),
 167                              , [enable_add_ons=yes])
 168
 169 AC_ARG_ENABLE([hidden-plt],
 170               AC_HELP_STRING([--disable-hidden-plt],
 171                              [do not hide internal function calls to avoid PLT]),
 172               [hidden=$enableval],
 173               [hidden=yes])
 174 if test "x$hidden" = xno; then
 175   AC_DEFINE(NO_HIDDEN)
 176 fi
 177
 178 AC_ARG_ENABLE([bind-now],
 179               AC_HELP_STRING([--enable-bind-now],
 180                              [disable lazy relocations in DSOs]),
 181               [bindnow=$enableval],
 182               [bindnow=no])
 183 AC_SUBST(bindnow)
 184
 185 dnl On some platforms we cannot use dynamic loading.  We must provide
 186 dnl static NSS modules.
 187 AC_ARG_ENABLE([static-nss],
 188               AC_HELP_STRING([--enable-static-nss],
 189                              [build static NSS modules @<:@default=no@:>@]),
 190               [static_nss=$enableval],
 191               [static_nss=no])
 192 dnl Enable static NSS also if we build no shared objects.
 193 if test x"$static_nss" = xyes || test x"$shared" = xno; then
 194   static_nss=yes
 195   AC_DEFINE(DO_STATIC_NSS)
 196 fi
 197
 198 AC_ARG_ENABLE([force-install],
 199               AC_HELP_STRING([--disable-force-install],
 200                              [don't force installation of files from this package, even if they are older than the installed files]),
 201               [force_install=$enableval],
 202               [force_install=yes])
 203 AC_SUBST(force_install)
 204
 205 dnl On some platforms we allow dropping compatibility with all kernel
 206 dnl versions.
 207 AC_ARG_ENABLE([kernel],
 208               AC_HELP_STRING([--enable-kernel=VERSION],
 209                              [compile for compatibility with kernel not older than VERSION]),
 210               [minimum_kernel=$enableval],
 211               [])
 212 dnl Prevent unreasonable values.
 213 if test "$minimum_kernel" = yes || test "$minimum_kernel" = no; then
 214   # Better nothing than this.
 215   minimum_kernel=""
 216 else
 217   if test "$minimum_kernel" = current; then
 218     minimum_kernel=`uname -r 2>/dev/null` || minimum_kernel=
 219   fi
 220 fi
 221
 222 dnl For the development we sometimes want gcc to issue even more warnings.
 223 dnl This is not the default since many of the extra warnings are not
 224 dnl appropriate.
 225 AC_ARG_ENABLE([all-warnings],
 226               AC_HELP_STRING([--enable-all-warnings],
 227                              [enable all useful warnings gcc can issue]),
 228               [all_warnings=$enableval],
 229               [])
 230 AC_SUBST(all_warnings)
 231
 232 AC_ARG_ENABLE([multi-arch],
 233               AC_HELP_STRING([--enable-multi-arch],
 234                              [enable single DSO with optimizations for multiple architectures]),
 235               [multi_arch=$enableval],
 236               [multi_arch=default])
 237
 238 AC_ARG_ENABLE([nss-crypt],
 239               AC_HELP_STRING([--enable-nss-crypt],
 240                              [enable libcrypt to use nss]),
 241               [nss_crypt=$enableval],
 242               [nss_crypt=no])
 243 if test x$nss_crypt = xyes; then
 244   nss_includes=-I$(nss-config --includedir 2>/dev/null)
 245   if test $? -ne 0; then
 246     AC_MSG_ERROR([cannot find include directory with nss-config])
 247   fi
 248   old_CFLAGS="$CFLAGS"
 249   CFLAGS="$CFLAGS $nss_includes"
 250   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 251 #include <hasht.h>
 252 #include <nsslowhash.h>
 253 void f (void) { NSSLOW_Init (); }])],
 254              libc_cv_nss_crypt=yes,
 255              AC_MSG_ERROR([
 256 cannot find NSS headers with lowlevel hash function interfaces]))
 257   old_LIBS="$LIBS"
 258   LIBS="$LIBS -lfreebl3"
 259   AC_LINK_IFELSE([AC_LANG_PROGRAM([typedef int PRBool;
 260 #include <hasht.h>
 261 #include <nsslowhash.h>],
 262                                   [NSSLOW_Init();])],
 263                  libc_cv_nss_crypt=yes,
 264                  AC_MSG_ERROR([
 265 cannot link program using lowlevel NSS hash functions]))
 266   CFLAGS="$old_CFLAGS"
 267   LIBS="$old_LIBS"
 268 else
 269   libc_cv_nss_crypt=no
 270 fi
 271 AC_SUBST(libc_cv_nss_crypt)
 272
 273 # The way shlib-versions is used to generate soversions.mk uses a
 274 # fairly simplistic model for name recognition that can't distinguish
 275 # i486-pc-linux-gnu fully from i486-pc-gnu.  So we mutate a $host_os
 276 # of `gnu*' here to be `gnu-gnu*' just so that shlib-versions can
 277 # tell.  This doesn't get used much beyond that, so it's fairly safe.
 278 case "$host_os" in
 279 linux*)
 280   ;;
 281 gnu*)
 282   host_os=`echo $host_os | sed -e 's/gnu/gnu-gnu/'`
 283   ;;
 284 esac
 285
 286 # We keep the original values in `$config_*' and never modify them, so we
 287 # can write them unchanged into config.make.  Everything else uses
 288 # $machine, $vendor, and $os, and changes them whenever convenient.
 289 config_machine=$host_cpu config_vendor=$host_vendor config_os=$host_os
 290
 291 # Don't allow vendor == "unknown"
 292 test "$config_vendor" = unknown && config_vendor=
 293 config_os="`echo $config_os | sed 's/^unknown-//'`"
 294
 295 # Some configurations imply other options.
 296 elf=yes
 297
 298 # The configure fragment of an add-on port can modify these to supplement
 299 # or override the table in the case statement below.  No fragment should
 300 # ever change the config_* variables, however.
 301 machine=$config_machine
 302 vendor=$config_vendor
 303 os=$config_os
 304 base_os=''
 305
 306 # config.guess on some IBM machines says `rs6000' instead of `powerpc'.
 307 # Unify this here.
 308 if test "$machine" = rs6000; then
 309   machine="powerpc"
 310 fi
 311
 312 # Braindead PowerPC box with absolutely no FPU.
 313 case "$machine-$host_os" in
 314   powerpc*-*soft)
 315     with_fp=no
 316     ;;
 317 esac
 318
 319 submachine=
 320 AC_ARG_WITH([cpu],
 321             AS_HELP_STRING([--with-cpu=CPU], [select code for CPU variant]),
 322             [dnl
 323   case "$withval" in
 324   yes|'') AC_MSG_ERROR([--with-cpu requires an argument]) ;;
 325   no) ;;
 326   *) submachine="$withval" ;;
 327   esac
 328 ])
 329
 330 # An add-on can set this when it wants to disable the sanity check below.
 331 libc_config_ok=no
 332
 333 dnl Having this here, though empty, makes sure that if add-ons' fragments
 334 dnl do AC_CONFIG_SUBDIRS([some-dir]), which just sets $subdirs, then
 335 dnl our AC_OUTPUT will actually use it.
 336 AC_CONFIG_SUBDIRS()
 337
 338 case "$enable_add_ons" in
 339 ''|no) add_ons= ;;
 340 yes|'*')
 341  add_ons=`cd $srcdir && ls -d 2> /dev/null */configure */sysdeps |
 342           sed 's@/[[^/]]*$@@' | sort | uniq`
 343          add_ons_automatic=yes
 344          ;;
 345 *) add_ons=`echo "$enable_add_ons" | sed 's/,/ /g'`
 346        add_ons_automatic=no ;;
 347 esac
 348
 349 configured_add_ons=
 350 add_ons_sfx=
 351 add_ons_pfx=
 352 if test x"$add_ons" != x; then
 353   for f in $add_ons; do
 354     # Some sanity checks
 355     case "$f" in
 356     crypt)
 357       AC_MSG_ERROR([
 358 *** It seems that you're using an old \`crypt' add-on.  crypt is now
 359 *** part of glibc and using the old add-on will not work with this
 360 *** release.  Start again with fresh sources and without the old
 361 *** \`crypt' add-on.])
 362     ;;
 363     localedata)
 364       AC_MSG_ERROR([
 365 *** It seems that you're using an old \`localedata' add-on.  localedata
 366 *** is now part of glibc and using the old add-on will not work with
 367 *** this release.  Start again with fresh sources and without the old
 368 *** \`localedata' add-on.])
 369     ;;
 370     esac
 371   done
 372
 373   # Now source each add-on's configure fragment.
 374   # The fragments can use $srcdir/$libc_add_on to find themselves,
 375   # and test $add_ons_automatic to see if they were explicitly requested.
 376   # A fragment can clear (or even change) $libc_add_on to affect
 377   # whether it goes into the list to be actually used in the build.
 378   use_add_ons=
 379   for libc_add_on in $add_ons; do
 380     # Test whether such a directory really exists.
 381     # It can be absolute, or relative to $srcdir, or relative to the build dir.
 382     case "$libc_add_on" in
 383     /*)
 384       libc_add_on_srcdir=$libc_add_on
 385       ;;
 386     *)
 387       test -d "$srcdir/$libc_add_on" || {
 388         if test -d "$libc_add_on"; then
 389           libc_add_on="`pwd`/$libc_add_on"
 390         else
 391           AC_MSG_ERROR(add-on directory \"$libc_add_on\" does not exist)
 392         fi
 393       }
 394       libc_add_on_srcdir=$srcdir/$libc_add_on
 395       ;;
 396     esac
 397
 398     libc_add_on_frag=$libc_add_on_srcdir/configure
 399     libc_add_on_canonical=
 400     libc_add_on_config_subdirs=
 401     if test -r "$libc_add_on_frag"; then
 402       AC_MSG_NOTICE(running configure fragment for add-on $libc_add_on)
 403       libc_add_on_canonical=unknown
 404       libc_add_on_subdirs=
 405       . "$libc_add_on_frag"
 406       test -z "$libc_add_on" || {
 407         configured_add_ons="$configured_add_ons $libc_add_on"
 408         if test "x$libc_add_on_canonical" = xunknown; then
 409           AC_MSG_ERROR(fragment must set \$libc_add_on_canonical)
 410         fi
 411         for d in $libc_add_on_subdirs; do
 412           case "$libc_add_on" in
 413           /*) subdir_srcdir="$libc_add_on" ;;
 414           *) subdir_srcdir="\$(..)$libc_add_on" ;;
 415           esac
 416           case "$d" in
 417           .)
 418             d="${libc_add_on_canonical:-$libc_add_on}"
 419             ;;
 420           /*)
 421             subdir_srcdir="$d"
 422             ;;
 423           *)
 424             subdir_srcdir="$subdir_srcdir/$d"
 425             ;;
 426           esac
 427           d=`echo "$d" | sed 's@/*$@@;s@^.*/@@'`
 428           add_on_subdirs="$add_on_subdirs $d"
 429           test "$subdir_srcdir" = "\$(..)$d" || config_vars="$config_vars
 430 $d-srcdir = $subdir_srcdir"
 431         done
 432         for d in $libc_add_on_config_subdirs; do
 433           case "$d" in
 434           /*) AC_MSG_ERROR(dnl
 435 fragment uses absolute path in \$libc_add_on_config_subdirs) ;;
 436           esac
 437           if test ! -d "$libc_add_on_srcdir/$d"; then
 438             AC_MSG_ERROR(fragment wants to configure missing directory $d)
 439           fi
 440           case "$libc_add_on" in
 441           /*) AC_MSG_ERROR(dnl
 442 relative path required for add-on using \$libc_add_on_config_subdirs) ;;
 443           esac
 444           subdirs="$subdirs $libc_add_on/$d"
 445         done
 446       }
 447     fi
 448     if test -n "$libc_add_on"; then
 449       if frags=`ls -d $libc_add_on_srcdir/sysdeps/*/preconfigure 2> /dev/null`
 450       then
 451         AC_MSG_CHECKING(add-on $libc_add_on for preconfigure fragments)
 452         for frag in $frags; do
 453           name=`echo "$frag" | sed 's@/[[^/]]*$@@;s@^.*/@@'`
 454           echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 455           . "$frag"
 456         done
 457         AC_MSG_RESULT()
 458       fi
 459       use_add_ons="$use_add_ons $libc_add_on"
 460       add_ons_pfx="$add_ons_pfx $libc_add_on/"
 461       test -z "$libc_add_on_canonical" ||
 462       add_ons_sfx="$add_ons_sfx /$libc_add_on_canonical"
 463     fi
 464   done
 465   # Use echo to strip excess whitespace.
 466   add_ons="`echo $use_add_ons`"
 467 fi
 468 AC_SUBST(add_ons)
 469 AC_SUBST(add_on_subdirs)
 470
 471
 472 ###
 473 ### I put this here to prevent those annoying emails from people who cannot
 474 ### read and try to compile glibc on unsupported platforms.  --drepper
 475 ###
 476 ### By using the undocumented --enable-hacker-mode option for configure
 477 ### one can skip this test to make the configuration not fail for unsupported
 478 ### platforms.
 479 ###
 480 if test -z "$enable_hacker_mode" && test x"$libc_config_ok" != xyes; then
 481   case "$machine-$host_os" in
 482   *-linux* | *-gnu* | arm*-none*)
 483     ;;
 484   *)
 485     echo "*** The GNU C library is currently not available for this platform."
 486     echo "*** So far nobody cared to port it and if there is no volunteer it"
 487     echo "*** might never happen.  So, if you have interest to see glibc on"
 488     echo "*** this platform visit"
 489     echo "***   http://www.gnu.org/software/libc/porting.html"
 490     echo "*** and join the group of porters"
 491     exit 1
 492     ;;
 493   esac
 494 fi
 495
 496 dnl We need to use [ and ] for other purposes for a while now.
 497 changequote(,)dnl
 498 # Expand the configuration machine name into a subdirectory by architecture
 499 # type and particular chip.  If an add-on configure fragment already set
 500 # base_machine, we don't change it.
 501 test -n "$base_machine" || case "$machine" in
 502 i[34567]86)     base_machine=i386 machine=i386/$machine ;;
 503 powerpc)        base_machine=powerpc machine=powerpc/powerpc32 ;;
 504 powerpc64)      base_machine=powerpc machine=powerpc/powerpc64 ;;
 505 s390)           base_machine=s390 machine=s390/s390-32 ;;
 506 s390x)          base_machine=s390 machine=s390/s390-64 ;;
 507 sh3*)           base_machine=sh machine=sh/sh3 ;;
 508 sh4*)           base_machine=sh machine=sh/sh4 ;;
 509 sparc | sparcv[67])
 510                 base_machine=sparc machine=sparc/sparc32 ;;
 511 sparcv8 | supersparc | hypersparc)
 512                 base_machine=sparc machine=sparc/sparc32/sparcv8 ;;
 513 sparcv8plus | sparcv8plusa | sparcv9)
 514                 base_machine=sparc machine=sparc/sparc32/sparcv9 ;;
 515 sparcv8plusb | sparcv9b)
 516                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9b ;;
 517 sparcv9v)
 518                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v ;;
 519 sparcv9v2)
 520                 base_machine=sparc machine=sparc/sparc32/sparcv9/sparcv9v2 ;;
 521 sparc64)
 522                 base_machine=sparc machine=sparc/sparc64 ;;
 523 sparc64b)
 524                 base_machine=sparc machine=sparc/sparc64/sparcv9b ;;
 525 sparc64v)
 526                 base_machine=sparc machine=sparc/sparc64/sparcv9v ;;
 527 sparc64v2)
 528                 base_machine=sparc machine=sparc/sparc64/sparcv9v2 ;;
 529 *)              base_machine=$machine ;;
 530 esac
 531 changequote([,])dnl
 532 AC_SUBST(base_machine)
 533
 534 if test "$base_machine" = "i386"; then
 535   AC_DEFINE(USE_REGPARMS)
 536 fi
 537
 538 # For the multi-arch option we need support in the assembler.
 539 AC_CACHE_CHECK([for assembler gnu_indirect_function symbol type support],
 540                libc_cv_asm_gnu_indirect_function, [dnl
 541 cat > conftest.s <<EOF
 542 .type foo,%gnu_indirect_function
 543 EOF
 544 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD;
 545 then
 546   libc_cv_asm_gnu_indirect_function=yes
 547 else
 548   libc_cv_asm_gnu_indirect_function=no
 549 fi
 550 rm -f conftest*])
 551
 552 AC_MSG_CHECKING(whether .text pseudo-op must be used)
 553 AC_CACHE_VAL(libc_cv_dot_text, [dnl
 554 cat > conftest.s <<EOF
 555 .text
 556 EOF
 557 libc_cv_dot_text=
 558 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 559   libc_cv_dot_text=.text
 560 fi
 561 rm -f conftest*])
 562 if test -z "$libc_cv_dot_text"; then
 563   AC_MSG_RESULT(no)
 564 else
 565   AC_MSG_RESULT(yes)
 566 fi
 567
 568 AC_CACHE_CHECK(for assembler global-symbol directive,
 569                libc_cv_asm_global_directive, [dnl
 570 libc_cv_asm_global_directive=UNKNOWN
 571 for ac_globl in .globl .global .EXPORT; do
 572   cat > conftest.s <<EOF
 573         ${libc_cv_dot_text}
 574         ${ac_globl} foo
 575 foo:
 576 EOF
 577   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 578     libc_cv_asm_global_directive=${ac_globl}
 579   fi
 580   rm -f conftest*
 581   test $libc_cv_asm_global_directive != UNKNOWN && break
 582 done])
 583 if test $libc_cv_asm_global_directive = UNKNOWN; then
 584   AC_MSG_ERROR(cannot determine asm global directive)
 585 else
 586   AC_DEFINE_UNQUOTED(ASM_GLOBAL_DIRECTIVE, ${libc_cv_asm_global_directive})
 587 fi
 588
 589 AC_CACHE_CHECK(for assembler .type directive prefix,
 590                libc_cv_asm_type_prefix, [dnl
 591 libc_cv_asm_type_prefix=no
 592 for ac_try_prefix in '@' '%' '#'; do
 593   cat > conftest.s <<EOF
 594         ${libc_cv_dot_text}
 595         ${libc_cv_asm_global_directive} foo
 596         .type foo, ${ac_try_prefix}object
 597         .size foo, 1
 598 foo:
 599         .byte 1
 600 EOF
 601   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
 602     libc_cv_asm_type_prefix=${ac_try_prefix}
 603   fi
 604   rm -f conftest*
 605   test "x$libc_cv_asm_type_prefix" != xno && break
 606 done])
 607 if test "x$libc_cv_asm_type_prefix" != xno; then
 608   AC_DEFINE_UNQUOTED(ASM_TYPE_DIRECTIVE_PREFIX, ${libc_cv_asm_type_prefix})
 609 fi
 610
 611 if test x"$libc_cv_asm_gnu_indirect_function" != xyes -a x"$libc_cv_asm_type_prefix" = xno; then
 612   if test x"$multi_arch" = xyes; then
 613     AC_MSG_ERROR([--enable-multi-arch support requires assembler and linker support])
 614   else
 615     multi_arch=no
 616   fi
 617 fi
 618 if test x"$multi_arch" != xno; then
 619   multi_arch_d=/multiarch
 620 fi
 621
 622 # Compute the list of sysdep directories for this configuration.
 623 # This can take a while to compute.
 624 sysdep_dir=$srcdir/sysdeps
 625 AC_MSG_CHECKING(sysdep dirs)
 626 dnl We need to use [ and ] for other purposes for a while now.
 627 changequote(,)dnl
 628 # Make sco3.2v4 become sco3.2.4 and sunos4.1.1_U1 become sunos4.1.1.U1.
 629 os="`echo $os | sed 's/\([0-9A-Z]\)[v_]\([0-9A-Z]\)/\1.\2/g'`"
 630
 631 test "x$base_os" != x || case "$os" in
 632 gnu*)
 633   base_os=mach/hurd ;;
 634 netbsd* | 386bsd* | freebsd* | bsdi*)
 635   base_os=unix/bsd/bsd4.4 ;;
 636 osf* | sunos* | ultrix* | newsos* | dynix* | *bsd*)
 637   base_os=unix/bsd ;;
 638 sysv* | isc* | esix* | sco* | minix* | irix4* | linux*)
 639   base_os=unix/sysv ;;
 640 irix6*)
 641   base_os=unix/sysv/irix6/$os ;;
 642 solaris[2-9]*)
 643   base_os=unix/sysv/sysv4 ;;
 644 none)
 645   base_os=standalone ;;
 646 esac
 647
 648 # For sunos4.1.1, try sunos4.1.1, then sunos4.1, then sunos4, then sunos.
 649 tail=$os
 650 ostry=$os
 651 while o=`echo $tail | sed 's/\.[^.]*$//'`; test $o != $tail; do
 652   ostry="$ostry /$o"
 653   tail=$o
 654 done
 655 o=`echo $tail | sed 's/[0-9]*$//'`
 656 if test $o != $tail; then
 657   ostry="$ostry /$o"
 658 fi
 659 # For linux-gnu, try linux-gnu, then linux.
 660 o=`echo $tail | sed 's/-.*$//'`
 661 if test $o != $tail; then
 662   ostry="$ostry /$o"
 663 fi
 664
 665 # For unix/sysv/sysv4, try unix/sysv/sysv4, then unix/sysv, then unix.
 666 base=
 667 tail=$base_os
 668 while b=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$b"; do
 669   set $b
 670   base="$base /$1"
 671   tail="$2"
 672 done
 673
 674 # For sparc/sparc32, try sparc/sparc32 and then sparc.
 675 mach=
 676 tail=$machine${submachine:+/$submachine}
 677 while m=`echo $tail | sed 's@^\(.*\)/\([^/]*\)$@& \1@'`; test -n "$m"; do
 678   set $m
 679   # Prepend the machine's FPU directory unless --without-fp.
 680   if test "$with_fp" = yes; then
 681     mach="$mach /$1/fpu"
 682   else
 683     mach="$mach /$1/nofpu"
 684   fi
 685   mach="$mach /$1"
 686   tail="$2"
 687 done
 688
 689 dnl We are done with glob and regexp uses of [ and ]; return to autoconf.
 690 changequote([,])dnl
 691
 692 # Find what sysdep directories exist.
 693 sysnames_add_ons=
 694 sysnames=
 695 for b in $base ''; do
 696   for m0 in $mach ''; do
 697     for v in /$vendor ''; do
 698       test "$v" = / && continue
 699       for o in /$ostry ''; do
 700         test "$o" = / && continue
 701         for m in $multi_arch_d $mach ''; do
 702           for d in $add_ons_pfx ''; do
 703             for a in $add_ons_sfx ''; do
 704               if test -n "$m0$m0sub$b$v$o$m$msub"; then
 705                 try_srcdir="${srcdir}/"
 706                 case "$d" in
 707                 /*) try_srcdir= ;;
 708                 esac
 709                 try="${d}sysdeps$m0$m0sub$b$v$o$m$msub$a"
 710                 test -n "$enable_debug_configure" &&
 711                 echo "$0 [DEBUG]: try $try" >&2
 712                 if test -d "$try_srcdir$try"; then
 713                   sysnames="$sysnames $try"
 714                   { test -n "$o" || test -n "$b"; } && os_used=t
 715                   { test -n "$m" || test -n "$m0"; } && machine_used=t
 716                   case x${m0:-$m} in
 717                   x*/$submachine) submachine_used=t ;;
 718                   esac
 719                   if test -n "$d"; then
 720                     case "$sysnames_add_ons" in
 721                     *" $d "*) ;;
 722                     *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 723                     esac
 724                   fi
 725                 fi
 726               fi
 727             done
 728           done
 729         done
 730       done
 731     done
 732   done
 733 done
 734
 735 # If the assembler supports gnu_indirect_function symbol type and the
 736 # architecture supports multi-arch, we enable multi-arch by default.
 737 case $sysnames_add_ons$sysnames in
 738 *"$multi_arch_d"*)
 739   ;;
 740 *)
 741   test x"$multi_arch" = xdefault && multi_arch=no
 742   ;;
 743 esac
 744 if test x"$multi_arch" != xno; then
 745   AC_DEFINE(USE_MULTIARCH)
 746 fi
 747 AC_SUBST(multi_arch)
 748
 749 if test -z "$os_used" && test "$os" != none; then
 750   AC_MSG_ERROR(Operating system $os is not supported.)
 751 fi
 752 if test -z "$machine_used" && test "$machine" != none; then
 753   AC_MSG_ERROR(The $machine is not supported.)
 754 fi
 755 if test -z "$submachine_used" && test -n "$submachine"; then
 756   AC_MSG_ERROR(The $submachine subspecies of $host_cpu is not supported.)
 757 fi
 758 AC_SUBST(submachine)
 759
 760 # We have now validated the configuration.
 761
 762
 763 # Look for an `elf' subdirectory of each machine directory.
 764 # We prepend these rather than inserting them whereever the machine appears
 765 # because things specified by the machine's ELF ABI should override
 766 # OS-specific things, and should always be the same for any OS on the
 767 # machine (otherwise what's the point of an ABI?).
 768 elf_dirs=
 769 for d in $add_ons_pfx ''; do
 770   for m in $mach; do
 771     if test -d $srcdir/${d}sysdeps$m/elf; then
 772       elf_dirs="$elf_dirs ${d}sysdeps$m/elf"
 773     fi
 774   done
 775 done
 776 sysnames="`echo $elf_dirs | sed -e 's,//,/,g'` $sysnames"
 777
 778
 779 # Expand the list of system names into a full list of directories
 780 # from each element's parent name and Implies file (if present).
 781 set $sysnames
 782 names=
 783 while test $# -gt 0; do
 784   name=$1
 785   shift
 786
 787   case " $names " in *" $name "*)
 788     # Already in the list.
 789     continue
 790   esac
 791
 792   # Report each name as we discover it, so there is no long pause in output.
 793   echo $ECHO_N "$name $ECHO_C" >&AS_MESSAGE_FD
 794
 795   name_base=`echo $name | sed -e 's@\(.*sysdeps\)/.*@\1@'`
 796
 797   case $name in
 798     /*) xsrcdir= ;;
 799     *)  xsrcdir=$srcdir/ ;;
 800   esac
 801   test -n "$enable_debug_configure" &&
 802   echo "[DEBUG]: name/Implies $xsrcdir$name/Implies" >&2
 803
 804   if test -f $xsrcdir$name/Implies; then
 805     # Collect more names from the `Implies' file (removing comments).
 806     implied_candidate="`sed 's/#.*$//' < $xsrcdir$name/Implies`"
 807     implied=
 808     for x in $implied_candidate; do
 809       found=no
 810       if test -d $xsrcdir$name_base/$x; then
 811         implied="$implied $name_base/$x";
 812         found=yes
 813       fi
 814       for d in $add_ons_pfx ''; do
 815         try="${d}sysdeps/$x"
 816         case $d in
 817          /*) try_srcdir= ;;
 818          *) try_srcdir=$srcdir/ ;;
 819         esac
 820         test -n "$enable_debug_configure" &&
 821          echo "[DEBUG]: $name implied $x try($d) {$try_srcdir}$try" >&2
 822         if test $try != $xsrcdir$name_base/$x && test -d $try_srcdir$try;
 823         then
 824           implied="$implied $try"
 825           found=yes
 826           case "$sysnames_add_ons" in
 827           *" $d "*) ;;
 828           *|'') sysnames_add_ons="$sysnames_add_ons $d" ;;
 829           esac
 830         fi
 831       done
 832       if test $found = no; then
 833         AC_MSG_WARN($name/Implies specifies nonexistent $x)
 834       fi
 835     done
 836   else
 837     implied=
 838   fi
 839
 840   # Add NAME to the list of names.
 841   names="$names $name"
 842
 843   # Find the parent of NAME, using the empty string if it has none.
 844 changequote(,)dnl
 845   parent="`echo $name | sed -n -e 's=/[^/]*$==' -e '/sysdeps$/q' -e p`"
 846 changequote([,])dnl
 847
 848   # Add the names implied by NAME, and NAME's parent (if it has one), to
 849   # the list of names to be processed (the argument list).  We prepend the
 850   # implied names to the list and append the parent.  We want implied
 851   # directories to come before further directories inferred from the
 852   # configuration components; this ensures that for sysv4, unix/common
 853   # (implied by unix/sysv/sysv4) comes before unix/sysv (in ostry (here $*)
 854   # after sysv4).
 855   sysnames="`echo $implied $* $parent`"
 856   test -n "$sysnames" && set $sysnames
 857 done
 858
 859 # Add the default directories.
 860 default_sysnames="sysdeps/generic/elf sysdeps/generic"
 861 sysnames="$names $default_sysnames"
 862 AC_SUBST(sysnames)
 863 # The other names were emitted during the scan.
 864 AC_MSG_RESULT($default_sysnames)
 865
 866 # Collect the list of add-ons that supply partial sysdeps trees.
 867 sysdeps_add_ons=
 868 for add_on in $add_ons; do
 869   case "$add_on" in
 870   /*) xsrcdir= ;;
 871   *) xsrcdir="$srcdir/" ;;
 872   esac
 873
 874   test -d "$xsrcdir$add_on/sysdeps" || {
 875     case "$configured_add_ons " in
 876     *" $add_on "*) ;;
 877     *|'')
 878       AC_MSG_ERROR(add-on $add_on has no configure fragment or sysdeps tree)
 879       ;;
 880     esac
 881     continue
 882   }
 883
 884   sysdeps_add_ons="$sysdeps_add_ons $add_on"
 885   case "$sysnames_add_ons" in
 886   *" $add_on/ "*) ;;
 887   *|'')
 888     AC_MSG_WARN(add-on $add_on contributed no sysdeps directories)
 889     continue ;;
 890   esac
 891
 892   found=no
 893   for d in $sysnames; do
 894     case "$d" in
 895     $add_on/sysdeps/*) ;;
 896     *) continue ;;
 897     esac
 898     (cd "$xsrcdir$d" && for f in *[[!~]]; do
 899        case "$f" in
 900        sys|bits)
 901          for ff in $f/*.h; do
 902            test -d "$ff" || { test -e "$ff" && exit 88; }
 903          done
 904          ;;
 905        *)
 906          test -d "$f" || { test -e "$f" && exit 88; }
 907          ;;
 908        esac
 909      done)
 910     if test $? -eq 88; then
 911       found=yes
 912       break
 913     fi
 914   done
 915   if test $found = no; then
 916     AC_MSG_WARN(add-on $add_on contributed no useful sysdeps directories)
 917   fi
 918 done
 919 AC_SUBST(sysdeps_add_ons)
 920
 921
 922 ### Locate tools.
 923
 924 AC_PROG_INSTALL
 925 if test "$INSTALL" = "${srcdir}/scripts/install-sh -c"; then
 926   # The makefiles need to use a different form to find it in $srcdir.
 927   INSTALL='\$(..)./scripts/install-sh -c'
 928 fi
 929 AC_PROG_LN_S
 930
 931 LIBC_PROG_BINUTILS
 932 AC_SUBST(MIG)dnl Needed by sysdeps/mach/configure.in
 933
 934 # Accept binutils 2.13 or newer.
 935 AC_CHECK_PROG_VER(AS, $AS, --version,
 936                   [GNU assembler.* \([0-9]*\.[0-9.]*\)],
 937                   [2.1[3-9]*|2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], AS=: critic_missing="$critic_missing as")
 938 AC_CHECK_PROG_VER(LD, $LD, --version,
 939                   [GNU ld.* \([0-9][0-9]*\.[0-9.]*\)],
 940                   [2.1[3-9]*|2.1[0-9][0-9]*|2.[2-9][0-9]*|[3-9].*|[1-9][0-9]*], LD=: critic_missing="$critic_missing ld")
 941
 942 # These programs are version sensitive.
 943 AC_CHECK_TOOL_PREFIX
 944 AC_CHECK_PROG_VER(CC, ${ac_tool_prefix}gcc ${ac_tool_prefix}cc, -v,
 945   [version \([egcygnustpi-]*[0-9.]*\)], [3.4* | 4.[0-9]* ],
 946   critic_missing="$critic_missing gcc")
 947 AC_CHECK_PROG_VER(MAKE, gnumake gmake make, --version,
 948   [GNU Make[^0-9]*\([0-9][0-9.]*\)],
 949   [3.79* | 3.[89]*], critic_missing="$critic_missing make")
 950
 951 AC_CHECK_PROG_VER(MSGFMT, gnumsgfmt gmsgfmt msgfmt, --version,
 952   [GNU gettext.* \([0-9]*\.[0-9.]*\)],
 953   [0.10.3[6-9]* | 0.10.[4-9][0-9]* | 0.1[1-9]* | 0.[2-9][0-9]* | [1-9].*],
 954   MSGFMT=: aux_missing="$aux_missing msgfmt")
 955 AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 956   [GNU texinfo.* \([0-9][0-9.]*\)],
 957   [4.*],
 958   MAKEINFO=: aux_missing="$aux_missing makeinfo")
 959 AC_CHECK_PROG_VER(SED, sed, --version,
 960   [GNU sed version \([0-9]*\.[0-9.]*\)],
 961   [3.0[2-9]*|3.[1-9]*|[4-9]*],
 962   SED=: aux_missing="$aux_missing sed")
 963
 964 AC_CHECK_TOOL(READELF, readelf, false)
 965
 966 AC_CHECK_PROGS(AUTOCONF, autoconf, no)
 967 case "x$AUTOCONF" in
 968 xno|x|x:) AUTOCONF=no ;;
 969 *)
 970   AC_CACHE_CHECK(dnl
 971 whether $AUTOCONF${ACFLAGS:+ }$ACFLAGS works, libc_cv_autoconf_works, [dnl
 972   if (cd $srcdir; $AUTOCONF $ACFLAGS configure.in > /dev/null 2>&1); then
 973     libc_cv_autoconf_works=yes
 974   else
 975     libc_cv_autoconf_works=no
 976   fi])
 977   test $libc_cv_autoconf_works = yes || AUTOCONF=no
 978   ;;
 979 esac
 980 if test "x$AUTOCONF" = xno; then
 981   aux_missing="$aux_missing autoconf"
 982 fi
 983
 984 test -n "$critic_missing" && AC_MSG_ERROR([
 985 *** These critical programs are missing or too old:$critic_missing
 986 *** Check the INSTALL file for required versions.])
 987
 988 test -n "$aux_missing" && AC_MSG_WARN([
 989 *** These auxiliary programs are missing or incompatible versions:$aux_missing
 990 *** some features will be disabled.
 991 *** Check the INSTALL file for required versions.])
 992
 993 # if using special system headers, find out the compiler's sekrit
 994 # header directory and add that to the list.  NOTE: Only does the right
 995 # thing on a system that doesn't need fixincludes.  (Not presently a problem.)
 996 if test -n "$sysheaders"; then
 997   SYSINCLUDES=-nostdinc
 998   for d in include include-fixed; do
 999     i=`$CC -print-file-name="$d"` && test "x$i" != x && test "x$i" != "x$d" &&
1000     SYSINCLUDES="$SYSINCLUDES -isystem $i"
1001   done
1002   SYSINCLUDES="$SYSINCLUDES \
1003 -isystem `echo $sysheaders | sed 's/:/ -isystem /g'`"
1004   if test -n "$CXX"; then
1005     CXX_SYSINCLUDES=
1006     cxxversion=`$CXX -dumpversion 2>&AS_MESSAGE_LOG_FD` &&
1007     cxxmachine=`$CXX -dumpmachine 2>&AS_MESSAGE_LOG_FD` &&
1008     for d in include "$cxxmachine/include"; do
1009       i=../../../../$d/c++/$cxxversion
1010       cxxheaders=`$CXX -print-file-name="$i"` &&
1011       test "x$cxxheaders" != x && test "x$i" != "x$cxxheaders" &&
1012       CXX_SYSINCLUDES="$CXX_SYSINCLUDES -isystem $cxxheaders \
1013 -isystem $cxxheaders/$cxxmachine -isystem $cxxheaders/backward"
1014     done
1015   fi
1016 fi
1017 AC_SUBST(SYSINCLUDES)
1018 AC_SUBST(CXX_SYSINCLUDES)
1019
1020 # Test if LD_LIBRARY_PATH contains the notation for the current directory
1021 # since this would lead to problems installing/building glibc.
1022 # LD_LIBRARY_PATH contains the current directory if one of the following
1023 # is true:
1024 # - one of the terminals (":" and ";") is the first or last sign
1025 # - two terminals occur directly after each other
1026 # - the path contains an element with a dot in it
1027 AC_MSG_CHECKING(LD_LIBRARY_PATH variable)
1028 changequote(,)dnl
1029 case ${LD_LIBRARY_PATH} in
1030   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
1031     ld_library_path_setting="contains current directory"
1032     ;;
1033   *)
1034     ld_library_path_setting="ok"
1035     ;;
1036 esac
1037 changequote([,])dnl
1038 AC_MSG_RESULT($ld_library_path_setting)
1039 if test "$ld_library_path_setting" != "ok"; then
1040 AC_MSG_ERROR([
1041 *** LD_LIBRARY_PATH shouldn't contain the current directory when
1042 *** building glibc. Please change the environment variable
1043 *** and run configure again.])
1044 fi
1045
1046 AC_CACHE_CHECK(whether GCC supports -static-libgcc, libc_cv_gcc_static_libgcc, [dnl
1047 if $CC -v -static-libgcc 2>&1 | grep -q 'unrecognized option.*static-libgcc'; then
1048   libc_cv_gcc_static_libgcc=
1049 else
1050   libc_cv_gcc_static_libgcc=-static-libgcc
1051 fi])
1052 AC_SUBST(libc_cv_gcc_static_libgcc)
1053
1054 AC_PATH_PROG(BASH_SHELL, bash, no)
1055 if test "$BASH_SHELL" != no &&
1056    $BASH_SHELL -c 'test "$BASH_VERSINFO" \
1057              && test "$BASH_VERSINFO" -ge 2 >&/dev/null'; then
1058   libc_cv_have_bash2=yes
1059 else
1060   libc_cv_have_bash2=no
1061 fi
1062 AC_SUBST(libc_cv_have_bash2)
1063
1064 dnl We need a ksh compatible shell for tzselect.
1065 if test "$BASH_SHELL" = no; then
1066   AC_PATH_PROG(KSH, ksh, no)
1067   if test "$KSH" = no; then
1068     libc_cv_have_ksh=no
1069   else
1070     libc_cv_have_ksh=yes
1071   fi
1072 else
1073   KSH="$BASH_SHELL"
1074   AC_SUBST(KSH)
1075   libc_cv_have_ksh=yes
1076 fi
1077 AC_SUBST(libc_cv_have_ksh)
1078
1079 AC_PROG_AWK
1080 AC_PATH_PROG(PERL, perl, no)
1081 if test "$PERL" != no &&
1082    (eval `$PERL -V:apiversion`; test `expr "$apiversion" \< 5` -ne 0); then
1083   PERL=no
1084 fi
1085 AC_PATH_PROG(INSTALL_INFO, install-info, no,
1086              $PATH:/usr/local/bin:/usr/local/sbin:/usr/bin:/usr/sbin:/bin:/sbin)
1087 AC_PATH_PROG(BISON, bison, no, $PATH:/usr/local/bin:/usr/bin:/bin)
1088
1089 AC_CACHE_CHECK(for libc-friendly stddef.h, libc_cv_friendly_stddef, [dnl
1090 AC_TRY_COMPILE(dnl
1091 [#define __need_size_t
1092 #define __need_wchar_t
1093 #include <stddef.h>
1094 #define __need_NULL
1095 #include <stddef.h>], [size_t size; wchar_t wchar;
1096 #ifdef offsetof
1097 #error stddef.h ignored __need_*
1098 #endif
1099 if (&size == NULL || &wchar == NULL) abort ();],
1100                libc_cv_friendly_stddef=yes,
1101                libc_cv_friendly_stddef=no)])
1102 if test $libc_cv_friendly_stddef = yes; then
1103   config_vars="$config_vars
1104 override stddef.h = # The installed <stddef.h> seems to be libc-friendly."
1105 fi
1106
1107 AC_CACHE_CHECK(whether we need to use -P to assemble .S files,
1108                libc_cv_need_minus_P, [dnl
1109 cat > conftest.S <<EOF
1110 #include "confdefs.h"
1111 /* Nothing whatsoever.  */
1112 EOF
1113 if AC_TRY_COMMAND(${CC-cc} $CPPFLAGS $ASFLAGS -c conftest.S 1>&AS_MESSAGE_LOG_FD); then
1114   libc_cv_need_minus_P=no
1115 else
1116   libc_cv_need_minus_P=yes
1117 fi
1118 rm -f conftest*])
1119 if test $libc_cv_need_minus_P = yes; then
1120   config_vars="$config_vars
1121 asm-CPPFLAGS = -P # The assembler can't grok cpp's # line directives."
1122 fi
1123
1124 AC_CACHE_CHECK(for .set assembler directive, libc_cv_asm_set_directive, [dnl
1125 cat > conftest.s <<EOF
1126 ${libc_cv_dot_text}
1127 foo:
1128 .set glibc_conftest_frobozz,foo
1129 $libc_cv_asm_global_directive glibc_conftest_frobozz
1130 EOF
1131 # The alpha-dec-osf1 assembler gives only a warning for `.set'
1132 # (but it doesn't work), so we must do a linking check to be sure.
1133 cat > conftest1.c <<\EOF
1134 extern int glibc_conftest_frobozz;
1135 void _start() { glibc_conftest_frobozz = 1; }
1136 EOF
1137 if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1138             -nostartfiles -nostdlib \
1139             -o conftest conftest.s conftest1.c 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1140   libc_cv_asm_set_directive=yes
1141 else
1142   libc_cv_asm_set_directive=no
1143 fi
1144 rm -f conftest*])
1145 if test $libc_cv_asm_set_directive = yes; then
1146   AC_DEFINE(HAVE_ASM_SET_DIRECTIVE)
1147 fi
1148
1149 AC_CACHE_CHECK(for assembler gnu_unique_object symbol type,
1150                libc_cv_asm_unique_object, [dnl
1151 cat > conftest.s <<EOF
1152 ${libc_cv_dot_text}
1153 _sym:
1154 .type _sym, ${libc_cv_asm_type_prefix}gnu_unique_object
1155 EOF
1156 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1157   libc_cv_asm_unique_object=yes
1158 else
1159   libc_cv_asm_unique_object=no
1160 fi
1161 rm -f conftest*])
1162 if test $libc_cv_asm_unique_object = yes; then
1163   AC_DEFINE(HAVE_ASM_UNIQUE_OBJECT)
1164 fi
1165
1166 AC_CACHE_CHECK(for .symver assembler directive, libc_cv_asm_symver_directive,
1167 [cat > conftest.s <<EOF
1168 ${libc_cv_dot_text}
1169 _sym:
1170 .symver _sym,sym@VERS
1171 EOF
1172 if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1173   libc_cv_asm_symver_directive=yes
1174 else
1175   libc_cv_asm_symver_directive=no
1176 fi
1177 rm -f conftest*])
1178 AC_CACHE_CHECK(for ld --version-script, libc_cv_ld_version_script_option, [dnl
1179 if test $libc_cv_asm_symver_directive = yes; then
1180   cat > conftest.s <<EOF
1181 ${libc_cv_dot_text}
1182 _sym:
1183 .symver _sym,sym@VERS
1184 EOF
1185   cat > conftest.map <<EOF
1186 VERS_1 {
1187         global: sym;
1188 };
1189
1190 VERS_2 {
1191         global: sym;
1192 } VERS_1;
1193 EOF
1194   if ${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD 2>&AS_MESSAGE_LOG_FD; then
1195     if AC_TRY_COMMAND([${CC-cc} $CFLAGS $LDFLAGS -shared
1196                                 -o conftest.so conftest.o
1197                                 -nostartfiles -nostdlib
1198                                 -Wl,--version-script,conftest.map
1199                        1>&AS_MESSAGE_LOG_FD]);
1200     then
1201       libc_cv_ld_version_script_option=yes
1202     else
1203       libc_cv_ld_version_script_option=no
1204     fi
1205   else
1206     libc_cv_ld_version_script_option=no
1207   fi
1208 else
1209   libc_cv_ld_version_script_option=no
1210 fi
1211 rm -f conftest*])
1212 if test $shared != no &&
1213    test $libc_cv_asm_symver_directive = yes &&
1214    test $libc_cv_ld_version_script_option = yes &&
1215    test $enable_versioning = yes; then
1216   VERSIONING=yes
1217   AC_DEFINE(DO_VERSIONING)
1218 else
1219   VERSIONING=no
1220 fi
1221 AC_SUBST(VERSIONING)
1222
1223 if test $shared != no && test $VERSIONING = no; then
1224   echo "\
1225 *** WARNING: You should not compile GNU libc without versioning. Not using
1226 *** versioning will introduce incompatibilities so that old binaries
1227 *** will not run anymore.
1228 *** For versioning you need recent binutils (binutils-2.8.1.0.23 or newer)."
1229 fi
1230 AC_CACHE_CHECK(for .previous assembler directive,
1231                libc_cv_asm_previous_directive, [dnl
1232 cat > conftest.s <<EOF
1233 .section foo_section
1234 .previous
1235 EOF
1236 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1237   libc_cv_asm_previous_directive=yes
1238 else
1239   libc_cv_asm_previous_directive=no
1240 fi
1241 rm -f conftest*])
1242 if test $libc_cv_asm_previous_directive = yes; then
1243   AC_DEFINE(HAVE_ASM_PREVIOUS_DIRECTIVE)
1244 else
1245   AC_CACHE_CHECK(for .popsection assembler directive,
1246                  libc_cv_asm_popsection_directive, [dnl
1247   cat > conftest.s <<EOF
1248 .pushsection foo_section
1249 .popsection
1250 EOF
1251   if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1252     libc_cv_asm_popsection_directive=yes
1253   else
1254     libc_cv_asm_popsection_directive=no
1255   fi
1256   rm -f conftest*])
1257   if test $libc_cv_asm_popsection_directive = yes; then
1258     AC_DEFINE(HAVE_ASM_POPSECTION_DIRECTIVE)
1259   fi
1260 fi
1261 AC_CACHE_CHECK(for .protected and .hidden assembler directive,
1262                libc_cv_asm_protected_directive, [dnl
1263 cat > conftest.s <<EOF
1264 .protected foo
1265 foo:
1266 .hidden bar
1267 bar:
1268 EOF
1269 if AC_TRY_COMMAND(${CC-cc} -c $ASFLAGS conftest.s 1>&AS_MESSAGE_LOG_FD); then
1270   libc_cv_asm_protected_directive=yes
1271 else
1272   AC_MSG_ERROR(assembler support for symbol visibility is required)
1273 fi
1274 rm -f conftest*])
1275
1276 if test $libc_cv_asm_protected_directive = yes; then
1277   AC_CACHE_CHECK(whether __attribute__((visibility())) is supported,
1278                  libc_cv_visibility_attribute,
1279                  [cat > conftest.c <<EOF
1280                   int foo __attribute__ ((visibility ("hidden"))) = 1;
1281                   int bar __attribute__ ((visibility ("protected"))) = 1;
1282 EOF
1283                   libc_cv_visibility_attribute=no
1284                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1285                     if grep '\.hidden.*foo' conftest.s >/dev/null; then
1286                       if grep '\.protected.*bar' conftest.s >/dev/null; then
1287                         libc_cv_visibility_attribute=yes
1288                       fi
1289                     fi
1290                   fi
1291                   rm -f conftest.{c,s}
1292                  ])
1293   if test $libc_cv_visibility_attribute != yes; then
1294     AC_MSG_ERROR(compiler support for visibility attribute is required)
1295   fi
1296 fi
1297
1298 if test $libc_cv_visibility_attribute = yes; then
1299   AC_CACHE_CHECK(for broken __attribute__((visibility())),
1300                  libc_cv_broken_visibility_attribute,
1301                  [cat > conftest.c <<EOF
1302                   int foo (int x);
1303                   int bar (int x) __asm__ ("foo") __attribute__ ((visibility ("hidden")));
1304                   int bar (int x) { return x; }
1305 EOF
1306                   libc_cv_broken_visibility_attribute=yes
1307                   if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1308 changequote(,)dnl
1309                     if grep '\.hidden[  _]foo' conftest.s >/dev/null; then
1310 changequote([,])dnl
1311                       libc_cv_broken_visibility_attribute=no
1312                     fi
1313                   fi
1314                   rm -f conftest.c conftest.s
1315                  ])
1316   if test $libc_cv_broken_visibility_attribute = yes; then
1317     AC_MSG_ERROR(working compiler support for visibility attribute is required)
1318   fi
1319 fi
1320
1321 AC_CACHE_CHECK(for broken __attribute__((alias())),
1322                libc_cv_broken_alias_attribute,
1323                [cat > conftest.c <<EOF
1324                extern int foo (int x) __asm ("xyzzy");
1325                int bar (int x) { return x; }
1326                extern __typeof (bar) foo __attribute ((weak, alias ("bar")));
1327                extern int dfoo;
1328                extern __typeof (dfoo) dfoo __asm ("abccb");
1329                int dfoo = 1;
1330 EOF
1331                libc_cv_broken_alias_attribute=yes
1332                if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
1333                  if grep 'xyzzy' conftest.s >/dev/null &&
1334                     grep 'abccb' conftest.s >/dev/null; then
1335                    libc_cv_broken_alias_attribute=no
1336                  fi
1337                fi
1338                rm -f conftest.c conftest.s
1339                ])
1340 if test $libc_cv_broken_alias_attribute = yes; then
1341   AC_MSG_ERROR(working alias attribute support required)
1342 fi
1343
1344 if test $libc_cv_visibility_attribute = yes; then
1345   AC_CACHE_CHECK(whether to put _rtld_local into .sdata section,
1346                  libc_cv_have_sdata_section,
1347                  [echo "int i;" > conftest.c
1348                   libc_cv_have_sdata_section=no
1349                   if ${CC-cc} $LDFLAGS -fPIC -shared -Wl,--verbose conftest.c -o conftest.so 2>&1 \
1350                      | grep '\.sdata' >/dev/null; then
1351                     libc_cv_have_sdata_section=yes
1352                   fi
1353                   rm -f conftest.c conftest.so
1354                  ])
1355   if test $libc_cv_have_sdata_section = yes; then
1356     AC_DEFINE(HAVE_SDATA_SECTION)
1357   fi
1358 fi
1359
1360 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
1361                libc_cv_initfini_array, [dnl
1362 cat > conftest.c <<EOF
1363 int _start (void) { return 0; }
1364 int __start (void) { return 0; }
1365 int foo (void) { return 1; }
1366 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;
1367 EOF
1368 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -o conftest conftest.c
1369                    -static -nostartfiles -nostdlib 1>&AS_MESSAGE_LOG_FD])
1370 then
1371   if $READELF -S conftest | fgrep INIT_ARRAY > /dev/null; then
1372     libc_cv_initfini_array=yes
1373   else
1374     libc_cv_initfini_array=no
1375   fi
1376 else
1377   libc_cv_initfini_array=no
1378 fi
1379 rm -f conftest*])
1380 if test $libc_cv_initfini_array != yes; then
1381   AC_MSG_ERROR([Need linker with .init_array/.fini_array support.])
1382 fi
1383
1384 AC_CACHE_CHECK(whether to use .ctors/.dtors header and trailer,
1385                libc_cv_ctors_header, [dnl
1386   libc_cv_ctors_header=yes
1387   AC_TRY_LINK([], [
1388 __attribute__ ((constructor)) void ctor (void) { puts("ctor"); }
1389 __attribute__ ((destructor))  void dtor (void) { puts("dtor"); }
1390 ],
1391               [dnl
1392       AS_IF([$READELF -WS conftest$ac_exeext | $AWK '
1393         { gsub(/\@<:@ */, "@<:@") }
1394         $2 == ".ctors" || $2 == ".dtors" {
1395           size = strtonum("0x" $6)
1396           align = strtonum("0x" $NF)
1397           seen@<:@$2@:>@ = 1
1398           stub@<:@$2@:>@ = size == align * 2
1399         }
1400         END {
1401           ctors_ok = !seen@<:@".ctors"@:>@ || stub@<:@".ctors"@:>@
1402           dtors_ok = !seen@<:@".dtors"@:>@ || stub@<:@".dtors"@:>@
1403           exit ((ctors_ok && dtors_ok) ? 0 : 1)
1404         }
1405       '], [libc_cv_ctors_header=no])
1406     ], [dnl
1407       AC_MSG_ERROR([missing __attribute__ ((constructor)) support??])
1408     ])
1409 ])
1410 if test $libc_cv_ctors_header = no; then
1411   AC_DEFINE(NO_CTORS_DTORS_SECTIONS)
1412 fi
1413
1414 AC_CACHE_CHECK(for libunwind-support in compiler,
1415                libc_cv_cc_with_libunwind, [
1416   cat > conftest.c <<EOF
1417 int main (void) { return 0; }
1418 EOF
1419   if ${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -static -o conftest \
1420      conftest.c -v 2>&1 >/dev/null | grep -q " -lunwind "; then
1421     libc_cv_cc_with_libunwind=yes
1422   else
1423     libc_cv_cc_with_libunwind=no
1424   fi
1425   rm -f conftest*])
1426 AC_SUBST(libc_cv_cc_with_libunwind)
1427 if test $libc_cv_cc_with_libunwind = yes; then
1428   AC_DEFINE(HAVE_CC_WITH_LIBUNWIND)
1429 fi
1430
1431 AC_CACHE_CHECK(for -z nodelete option,
1432                libc_cv_z_nodelete, [dnl
1433 cat > conftest.c <<EOF
1434 int _start (void) { return 42; }
1435 EOF
1436 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1437                    -fPIC -shared -o conftest.so conftest.c
1438                    -nostartfiles -nostdlib
1439                    -Wl,--enable-new-dtags,-z,nodelete 1>&AS_MESSAGE_LOG_FD])
1440 then
1441   libc_cv_z_nodelete=yes
1442 else
1443   AC_MSG_ERROR(linker with -z nodelete support required)
1444 fi
1445 rm -f conftest*])
1446
1447 AC_CACHE_CHECK(for -z nodlopen option,
1448                libc_cv_z_nodlopen, [dnl
1449 cat > conftest.c <<EOF
1450 int _start (void) { return 42; }
1451 EOF
1452 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1453                         -fPIC -shared -o conftest.so conftest.c
1454                         -nostartfiles -nostdlib
1455                         -Wl,--enable-new-dtags,-z,nodlopen 1>&AS_MESSAGE_LOG_FD])
1456 then
1457   libc_cv_z_nodlopen=yes
1458 else
1459   AC_MSG_ERROR(linker with -z nodlopen support required)
1460 fi
1461 rm -f conftest*])
1462
1463 AC_CACHE_CHECK(for -z initfirst option,
1464                libc_cv_z_initfirst, [dnl
1465 cat > conftest.c <<EOF
1466 int _start (void) { return 42; }
1467 EOF
1468 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1469                         -fPIC -shared -o conftest.so conftest.c
1470                         -nostartfiles -nostdlib
1471                         -Wl,--enable-new-dtags,-z,initfirst 1>&AS_MESSAGE_LOG_FD])
1472 then
1473   libc_cv_z_initfirst=yes
1474 else
1475   AC_MSG_ERROR(linker with -z initfirst support required)
1476 fi
1477 rm -f conftest*])
1478
1479 # Add-on fragments can set these for other machines.
1480 libc_commonpagesize=${libc_commonpagesize:-no}
1481 libc_relro_required=${libc_relro_required:-no}
1482 case "$base_machine" in
1483   i[[34567]]86 | x86_64 | powerpc* | s390*)
1484     libc_commonpagesize=0x1000
1485     libc_relro_required=yes
1486     ;;
1487   sparc*)
1488     libc_commonpagesize=0x2000
1489     libc_relro_required=yes
1490     ;;
1491 esac
1492
1493 if test $libc_commonpagesize != no; then
1494   AC_CACHE_CHECK(for -z relro option,
1495                  libc_cv_z_relro, [dnl
1496   libc_cv_z_relro=no
1497   AC_LANG_CONFTEST([AC_LANG_SOURCE([[
1498 int _start (void) { return 42; }
1499 extern void _exit (int);
1500 /* Since these pointers are const, they should go in rodata.
1501    Since they refer to functions that have to be resolved by
1502    dynamic linking, they should instead go in RELRO data.  */
1503 const void *const relro[] = { &_start, &_exit, 0 };
1504 /* GNU ld fails to produce RELRO data when it's very small and there is no
1505    normal writable data following it, or if only uninitialized (.bss) data
1506    follows it, or only very small writable data.  */
1507 int data[0x10000] = { 1, };
1508 ]])])
1509   cat > conftest.awk <<\EOF
1510 BEGIN {
1511   result = "no"
1512   commonpagesize = strtonum(commonpagesize)
1513 }
1514 { print "LINE:", $0 > "/dev/stderr" }
1515 $1 == "GNU_RELRO" {
1516   vaddr = strtonum($3)
1517   memsz = strtonum($6)
1518   end = vaddr + memsz
1519   printf "vaddr %#x memsz %#x end %#x commonpagesize %#x\n", \
1520     vaddr, memsz, end, commonpagesize > "/dev/stderr"
1521   result = (end % commonpagesize == 0) ? "yes" : "broken"
1522 }
1523 END { print result }
1524 EOF
1525   AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1526                     -fPIC -shared -o conftest.so conftest.c
1527                     -nostartfiles -nostdlib
1528                     -Wl,-z,relro 1>&AS_MESSAGE_LOG_FD]) &&
1529   AC_TRY_COMMAND([$READELF -Wl conftest.so > conftest.ph]) &&
1530   AC_TRY_COMMAND([
1531       $AWK -v commonpagesize=$libc_commonpagesize -f conftest.awk
1532            conftest.ph > conftest.cps
1533     ]) &&
1534   libc_cv_z_relro=`cat conftest.cps 2>&AS_MESSAGE_LOG_FD`
1535   rm -f conftest*])
1536   if { test "x$libc_relro_required" = xyes &&
1537        test "x$libc_cv_z_relro" != xyes
1538      }
1539   then
1540     AC_MSG_ERROR(linker with -z relro support required)
1541   fi
1542 else
1543   AC_MSG_WARN([missing architecture parameter to check for working -z relro])
1544 fi
1545
1546 AC_CACHE_CHECK(for -Bgroup option,
1547                libc_cv_Bgroup, [dnl
1548 cat > conftest.c <<EOF
1549 int _start (void) { return 42; }
1550 EOF
1551 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1552                             -fPIC -shared -o conftest.so conftest.c
1553                             -Wl,-Bgroup -nostdlib 1>&AS_MESSAGE_LOG_FD])
1554 then
1555   libc_cv_Bgroup=yes
1556 else
1557   libc_cv_Bgroup=no
1558 fi
1559 rm -f conftest*])
1560 AC_SUBST(libc_cv_Bgroup)
1561
1562 AC_CACHE_CHECK(for libgcc_s suffix,
1563                libc_cv_libgcc_s_suffix, [dnl
1564 cat > conftest.c <<EOF
1565 int main (void) { return 0; }
1566 EOF
1567 changequote(,)dnl
1568 libc_cv_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
1569                            -fPIC -shared -shared-libgcc -o conftest.so \
1570                            conftest.c -v 2>&1 >/dev/null \
1571                            | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
1572 changequote([,])dnl
1573 rm -f conftest*])
1574 AC_SUBST(libc_cv_libgcc_s_suffix)
1575
1576 AC_CACHE_CHECK(for --as-needed option,
1577                libc_cv_as_needed, [dnl
1578 cat > conftest.c <<EOF
1579 int main (void) { return 0; }
1580 EOF
1581 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1582                               -fPIC -shared -o conftest.so conftest.c
1583                               -lgcc_s$libc_cv_libgcc_s_suffix -Wl,--as-needed
1584                               -nostdlib 1>&AS_MESSAGE_LOG_FD])
1585 then
1586   libc_cv_as_needed=yes
1587 else
1588   libc_cv_as_needed=no
1589 fi
1590 rm -f conftest*])
1591 AC_SUBST(libc_cv_as_needed)
1592
1593 ASFLAGS_config=
1594 AC_CACHE_CHECK(whether --noexecstack is desirable for .S files,
1595                libc_cv_as_noexecstack, [dnl
1596 cat > conftest.c <<EOF
1597 void foo (void) { }
1598 EOF
1599 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS
1600                    -S -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD]) \
1601    && grep -q .note.GNU-stack conftest.s \
1602    && AC_TRY_COMMAND([${CC-cc} $ASFLAGS -Wa,--noexecstack
1603                       -c -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
1604 then
1605   libc_cv_as_noexecstack=yes
1606 else
1607   libc_cv_as_noexecstack=no
1608 fi
1609 rm -f conftest*])
1610 if test $libc_cv_as_noexecstack = yes; then
1611   ASFLAGS_config="$ASFLAGS_config -Wa,--noexecstack"
1612 fi
1613 AC_SUBST(ASFLAGS_config)
1614
1615 AC_CACHE_CHECK(for -z combreloc,
1616                libc_cv_z_combreloc, [dnl
1617 cat > conftest.c <<EOF
1618 extern int bar (int);
1619 extern int mumble;
1620 int foo (void) { return bar (mumble); }
1621 EOF
1622 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1623                         -fPIC -shared -o conftest.so conftest.c
1624                         -nostdlib -nostartfiles
1625                         -Wl,-z,combreloc 1>&AS_MESSAGE_LOG_FD])
1626 then
1627 dnl The following test is a bit weak.  We must use a tool which can test
1628 dnl cross-platform since the gcc used can be a cross compiler.  Without
1629 dnl introducing new options this is not easily doable.  Instead use a tool
1630 dnl which always is cross-platform: readelf.  To detect whether -z combreloc
1631 dnl look for a section named .rel.dyn.
1632   if $READELF -S conftest.so | grep '\.rel\(a\|\)\.dyn' > /dev/null; then
1633     libc_cv_z_combreloc=yes
1634   else
1635     libc_cv_z_combreloc=no
1636   fi
1637 else
1638   libc_cv_z_combreloc=no
1639 fi
1640 rm -f conftest*])
1641 if test "$libc_cv_z_combreloc" = yes; then
1642   AC_DEFINE(HAVE_Z_COMBRELOC)
1643 fi
1644 AC_SUBST(libc_cv_z_combreloc)
1645
1646 AC_CACHE_CHECK(for -z execstack,
1647                libc_cv_z_execstack, [dnl
1648 cat > conftest.c <<EOF
1649 int _start (void) { return 42; }
1650 EOF
1651 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1652                             -fPIC -shared -o conftest.so conftest.c
1653                             -Wl,-z,execstack -nostdlib
1654                             1>&AS_MESSAGE_LOG_FD])
1655 then
1656   libc_cv_z_execstack=yes
1657 else
1658   libc_cv_z_execstack=no
1659 fi
1660 rm -f conftest*])
1661 AC_SUBST(libc_cv_z_execstack)
1662
1663 AC_CACHE_CHECK(for -fpie, libc_cv_fpie, [dnl
1664 cat > conftest.c <<EOF
1665 int foo;
1666 main () { return 0;}
1667 EOF
1668 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -pie -fpie
1669                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD])
1670 then
1671   libc_cv_fpie=yes
1672 else
1673   libc_cv_fpie=no
1674 fi
1675 rm -f conftest*])
1676
1677 AC_SUBST(libc_cv_fpie)
1678
1679 AC_CACHE_CHECK(for --hash-style option,
1680                libc_cv_hashstyle, [dnl
1681 cat > conftest.c <<EOF
1682 int _start (void) { return 42; }
1683 EOF
1684 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1685                             -fPIC -shared -o conftest.so conftest.c
1686                             -Wl,--hash-style=both -nostdlib 1>&AS_MESSAGE_LOG_FD])
1687 then
1688   libc_cv_hashstyle=yes
1689 else
1690   libc_cv_hashstyle=no
1691 fi
1692 rm -f conftest*])
1693 AC_SUBST(libc_cv_hashstyle)
1694
1695 # The linker's default -shared behavior is good enough if it
1696 # does these things that our custom linker scripts ensure that
1697 # all allocated NOTE sections come first.
1698 if test "$use_default_link" = default; then
1699   AC_CACHE_CHECK([for sufficient default -shared layout],
1700                   libc_cv_use_default_link, [dnl
1701   libc_cv_use_default_link=no
1702   cat > conftest.s <<\EOF
1703           .section .note.a,"a",%note
1704           .balign 4
1705           .long 4,4,9
1706           .string "GNU"
1707           .string "foo"
1708           .section .note.b,"a",%note
1709           .balign 4
1710           .long 4,4,9
1711           .string "GNU"
1712           .string "bar"
1713 EOF
1714   if AC_TRY_COMMAND([dnl
1715   ${CC-cc} $ASFLAGS -shared -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD]) &&
1716        ac_try=`$READELF -S conftest.so | sed -n \
1717          ['${x;p;}
1718           s/^ *\[ *[1-9][0-9]*\]  *\([^ ][^ ]*\)  *\([^ ][^ ]*\) .*$/\2 \1/
1719           t a
1720           b
1721           : a
1722           H']`
1723   then
1724     libc_seen_a=no libc_seen_b=no
1725     set -- $ac_try
1726     while test $# -ge 2 -a "$1" = NOTE; do
1727       case "$2" in
1728       .note.a) libc_seen_a=yes ;;
1729       .note.b) libc_seen_b=yes ;;
1730       esac
1731       shift 2
1732     done
1733     case "$libc_seen_a$libc_seen_b" in
1734     yesyes)
1735       libc_cv_use_default_link=yes
1736       ;;
1737     *)
1738       echo >&AS_MESSAGE_LOG_FD "\
1739 $libc_seen_a$libc_seen_b from:
1740 $ac_try"
1741       ;;
1742     esac
1743   fi
1744   rm -f conftest*])
1745   use_default_link=$libc_cv_use_default_link
1746 fi
1747
1748 AC_CACHE_CHECK(linker output format, libc_cv_output_format, [dnl
1749 if libc_cv_output_format=`
1750 ${CC-cc} -nostartfiles -nostdlib -Wl,--print-output-format 2>&AS_MESSAGE_LOG_FD`
1751 then
1752   :
1753 else
1754   libc_cv_output_format=
1755 fi
1756 test -n "$libc_cv_output_format" || libc_cv_output_format=unknown])
1757 AC_SUBST(libc_cv_output_format)
1758
1759 AC_CACHE_CHECK(for -fno-toplevel-reorder -fno-section-anchors, libc_cv_fno_toplevel_reorder, [dnl
1760 cat > conftest.c <<EOF
1761 int foo;
1762 EOF
1763 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -fno-toplevel-reorder -fno-section-anchors
1764                             conftest.c 1>&AS_MESSAGE_LOG_FD])
1765 then
1766   libc_cv_fno_toplevel_reorder=yes
1767 else
1768   libc_cv_fno_toplevel_reorder=no
1769 fi
1770 rm -f conftest*])
1771 if test $libc_cv_fno_toplevel_reorder = yes; then
1772   fno_unit_at_a_time="-fno-toplevel-reorder -fno-section-anchors"
1773 else
1774   fno_unit_at_a_time=-fno-unit-at-a-time
1775 fi
1776 AC_SUBST(fno_unit_at_a_time)
1777
1778 AC_CACHE_CHECK(for -fstack-protector, libc_cv_ssp, [dnl
1779 cat > conftest.c <<EOF
1780 int foo;
1781 main () { return 0;}
1782 EOF
1783 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS -Werror -fstack-protector
1784                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD])
1785 then
1786   libc_cv_ssp=yes
1787 else
1788   libc_cv_ssp=no
1789 fi
1790 rm -f conftest*])
1791 AC_SUBST(libc_cv_ssp)
1792
1793 AC_CACHE_CHECK(for -fgnu89-inline, libc_cv_gnu89_inline, [dnl
1794 cat > conftest.c <<EOF
1795 int foo;
1796 #ifdef __GNUC_GNU_INLINE__
1797 main () { return 0;}
1798 #else
1799 #error
1800 #endif
1801 EOF
1802 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -std=gnu99 -fgnu89-inline
1803                             -o conftest.s conftest.c 1>&AS_MESSAGE_LOG_FD])
1804 then
1805   libc_cv_gnu89_inline=yes
1806 else
1807   libc_cv_gnu89_inline=no
1808 fi
1809 rm -f conftest*])
1810 if test $libc_cv_gnu89_inline = yes; then
1811   gnu89_inline=-fgnu89-inline
1812 else
1813   gnu89_inline=
1814 fi
1815 AC_SUBST(gnu89_inline)
1816
1817 AC_CACHE_CHECK(whether cc puts quotes around section names,
1818                libc_cv_have_section_quotes,
1819                [cat > conftest.c <<EOF
1820                 static const int foo
1821                 __attribute__ ((section ("bar"))) = 1;
1822 EOF
1823                 if ${CC-cc} -S conftest.c -o conftest.s; then
1824                   if grep '\.section.*"bar"' conftest.s >/dev/null; then
1825                     libc_cv_have_section_quotes=yes
1826                   else
1827                     libc_cv_have_section_quotes=no
1828                   fi
1829                 else
1830                   libc_cv_have_section_quotes=unknown
1831                 fi
1832                 rm -f conftest.{c,s}
1833                 ])
1834 if test $libc_cv_have_section_quotes = yes; then
1835   AC_DEFINE(HAVE_SECTION_QUOTES)
1836 fi
1837
1838 AC_CACHE_CHECK(for assembler .weak directive, libc_cv_asm_weak_directive,
1839                [dnl
1840 cat > conftest.s <<EOF
1841 ${libc_cv_dot_text}
1842 ${libc_cv_asm_global_directive} foo
1843 foo:
1844 .weak foo
1845 .weak bar; bar = foo
1846 EOF
1847 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1848   libc_cv_asm_weak_directive=yes
1849 else
1850   libc_cv_asm_weak_directive=no
1851 fi
1852 rm -f conftest*])
1853
1854 if test $libc_cv_asm_weak_directive = no; then
1855   AC_CACHE_CHECK(for assembler .weakext directive,
1856                  libc_cv_asm_weakext_directive,
1857                  [dnl
1858 cat > conftest.s <<EOF
1859 ${libc_cv_dot_text}
1860 ${libc_cv_asm_global_directive} foo
1861 foo:
1862 .weakext bar foo
1863 .weakext baz
1864 ${libc_cv_asm_global_directive} baz
1865 baz:
1866 EOF
1867   if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1868     libc_cv_asm_weakext_directive=yes
1869   else
1870     libc_cv_asm_weakext_directive=no
1871   fi
1872   rm -f conftest*])
1873
1874 fi # no .weak
1875
1876 if test $libc_cv_asm_weak_directive = yes; then
1877   AC_DEFINE(HAVE_ASM_WEAK_DIRECTIVE)
1878 elif test $libc_cv_asm_weakext_directive = yes; then
1879   AC_DEFINE(HAVE_ASM_WEAKEXT_DIRECTIVE)
1880 fi
1881
1882 AC_CACHE_CHECK(whether CFI directives are supported, libc_cv_asm_cfi_directives, [dnl
1883 case $machine in
1884   sparc/sparc64*) cfi_offset=2047;;
1885   *) cfi_offset=0;;
1886 esac
1887 cat > conftest.s <<EOF
1888         .text
1889         .type   func,%function
1890 func:
1891         .cfi_startproc
1892         .cfi_remember_state
1893         .cfi_rel_offset 1, $cfi_offset
1894         .cfi_endproc
1895 EOF
1896 if AC_TRY_COMMAND(${CC-cc} $ASFLAGS -c conftest.s 1>&AS_MESSAGE_LOG_FD); then
1897   libc_cv_asm_cfi_directives=yes
1898 else
1899   libc_cv_asm_cfi_directives=no
1900 fi
1901 rm -f conftest*])
1902 if test $libc_cv_asm_cfi_directives = yes; then
1903   AC_DEFINE(HAVE_ASM_CFI_DIRECTIVES)
1904 fi
1905
1906 AC_CACHE_CHECK(for ld --no-whole-archive, libc_cv_ld_no_whole_archive, [dnl
1907 cat > conftest.c <<\EOF
1908 _start () {}
1909 int __eh_pc;
1910 __throw () {}
1911 EOF
1912 dnl No \ in command here because it ends up inside ''.
1913 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1914                             -nostdlib -nostartfiles -Wl,--no-whole-archive
1915                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1916   libc_cv_ld_no_whole_archive=yes
1917 else
1918   libc_cv_ld_no_whole_archive=no
1919 fi
1920 rm -f conftest*])
1921 if test $libc_cv_ld_no_whole_archive = no; then
1922   AC_MSG_ERROR([support for --no-whole-archive is needed])
1923 fi
1924
1925 AC_CACHE_CHECK(for gcc -fexceptions, libc_cv_gcc_exceptions, [dnl
1926 cat > conftest.c <<\EOF
1927 _start () {}
1928 int __eh_pc;
1929 __throw () {}
1930 EOF
1931 dnl No \ in command here because it ends up inside ''.
1932 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS
1933                             -nostdlib -nostartfiles -fexceptions
1934                             -o conftest conftest.c 1>&AS_MESSAGE_LOG_FD]); then
1935   libc_cv_gcc_exceptions=yes
1936 else
1937   libc_cv_gcc_exceptions=no
1938 fi
1939 rm -f conftest*])
1940 if test $libc_cv_gcc_exceptions = yes; then
1941   exceptions=-fexceptions
1942 fi
1943 AC_SUBST(exceptions)dnl
1944
1945 if test "$host_cpu" = powerpc ; then
1946 # Check for a bug present in at least versions 2.8.x of GCC
1947 # and versions 1.0.x of EGCS.
1948 AC_CACHE_CHECK(whether clobbering cr0 causes problems,libc_cv_c_asmcr0_bug,[dnl
1949 AC_TRY_COMPILE([int tester(int x) { asm ("" : : : "cc"); return x & 123; }],,
1950                libc_cv_c_asmcr0_bug='no',
1951                libc_cv_c_asmcr0_bug='yes')])
1952 if test "$libc_cv_c_asmcr0_bug" != 'no'; then
1953   AC_DEFINE(BROKEN_PPC_ASM_CR0)
1954 fi
1955 fi
1956
1957 AC_CACHE_CHECK(for __builtin_memset, libc_cv_gcc_builtin_memset, [dnl
1958 cat > conftest.c <<\EOF
1959 void zero (void *x)
1960 {
1961   __builtin_memset (x, 0, 1000);
1962 }
1963 EOF
1964 dnl
1965 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "memset" > /dev/null]);
1966 then
1967   libc_cv_gcc_builtin_memset=no
1968 else
1969   libc_cv_gcc_builtin_memset=yes
1970 fi
1971 rm -f conftest* ])
1972 if test "$libc_cv_gcc_builtin_memset" = yes ; then
1973   AC_DEFINE(HAVE_BUILTIN_MEMSET)
1974 fi
1975
1976 AC_CACHE_CHECK(for redirection of built-in functions, libc_cv_gcc_builtin_redirection, [dnl
1977 cat > conftest.c <<\EOF
1978 extern char *strstr (const char *, const char *) __asm ("my_strstr");
1979 char *foo (const char *a, const char *b)
1980 {
1981   return __builtin_strstr (a, b);
1982 }
1983 EOF
1984 dnl
1985 if AC_TRY_COMMAND([${CC-cc} -O3 -S conftest.c -o - | fgrep "my_strstr" > /dev/null]);
1986 then
1987   libc_cv_gcc_builtin_redirection=yes
1988 else
1989   libc_cv_gcc_builtin_redirection=no
1990 fi
1991 rm -f conftest* ])
1992 if test "$libc_cv_gcc_builtin_redirection" = no; then
1993   AC_MSG_ERROR([support for the symbol redirection needed])
1994 fi
1995
1996 dnl Check whether the compiler supports the __thread keyword.
1997 AC_CACHE_CHECK([for __thread], libc_cv_gcc___thread,
1998 [cat > conftest.c <<\EOF
1999 __thread int a = 42;
2000 EOF
2001 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
2002   libc_cv_gcc___thread=yes
2003 else
2004   libc_cv_gcc___thread=no
2005 fi
2006 rm -f conftest*])
2007 if test "$libc_cv_gcc___thread" = no; then
2008   AC_MSG_ERROR([support for the __thread keyword is required])
2009 fi
2010
2011 dnl Check whether the compiler supports the tls_model attribute.
2012 AC_CACHE_CHECK([for tls_model attribute], libc_cv_gcc_tls_model_attr, [dnl
2013 cat > conftest.c <<\EOF
2014 extern __thread int a __attribute__((tls_model ("initial-exec")));
2015 EOF
2016 if AC_TRY_COMMAND([${CC-cc} $CFLAGS $CPPFLAGS -S -Werror conftest.c >&AS_MESSAGE_LOG_FD]); then
2017   libc_cv_gcc_tls_model_attr=yes
2018 else
2019   libc_cv_gcc_tls_model_attr=no
2020 fi
2021 rm -f conftest*])
2022 if test "$libc_cv_gcc_tls_model_attr" = no; then
2023   AC_MSG_ERROR([support for the tls_model attribute is required])
2024 fi
2025
2026 if test -n "$submachine"; then
2027   AC_CACHE_CHECK([for compiler option for CPU variant],
2028                  libc_cv_cc_submachine, [dnl
2029   libc_cv_cc_submachine=no
2030   for opt in "-march=$submachine" "-mcpu=$submachine"; do
2031     if AC_TRY_COMMAND([${CC-cc} $opt -xc /dev/null -S -o /dev/null]); then
2032       libc_cv_cc_submachine="$opt"
2033       break
2034     fi
2035   done])
2036   if test "x$libc_cv_cc_submachine" = xno; then
2037     AC_MSG_ERROR([${CC-cc} does not support $submachine])
2038   fi
2039 fi
2040 AC_SUBST(libc_cv_cc_submachine)
2041
2042 dnl Check whether we have the gd library available.
2043 AC_MSG_CHECKING(for libgd)
2044 if test "$with_gd" != "no"; then
2045   old_CFLAGS="$CFLAGS"
2046   CFLAGS="$CFLAGS $libgd_include"
2047   old_LDFLAGS="$LDFLAGS"
2048   LDFLAGS="$LDFLAGS $libgd_ldflags"
2049   old_LIBS="$LIBS"
2050   LIBS="$LIBS -lgd -lpng -lz -lm"
2051   AC_TRY_LINK([#include <gd.h>], [gdImagePng (0, 0)], LIBGD=yes, LIBGD=no)
2052   CFLAGS="$old_CFLAGS"
2053   LDFLAGS="$old_LDFLAGS"
2054   LIBS="$old_LIBS"
2055 else
2056   LIBGD=no
2057 fi
2058 AC_MSG_RESULT($LIBGD)
2059 AC_SUBST(LIBGD)
2060
2061 # SELinux detection
2062 if test x$with_selinux = xno ; then
2063   have_selinux=no;
2064 else
2065   # See if we have the SELinux library
2066   AC_CHECK_LIB(selinux, is_selinux_enabled,
2067                have_selinux=yes, have_selinux=no)
2068   # See if we have the SELinux header with the NSCD permissions in it.
2069   if test x$have_selinux = xyes ; then
2070     AC_MSG_CHECKING([for NSCD Flask permissions in selinux/av_permissions.h])
2071     AC_TRY_COMPILE([#include <selinux/av_permissions.h>],
2072                     [#ifdef NSCD__SHMEMHOST
2073                      return 0;
2074                      #else
2075                      #error NSCD__SHMEMHOST not defined
2076                      #endif],
2077                     have_selinux=yes, have_selinux=no)
2078     AC_MSG_RESULT($have_selinux)
2079   fi
2080
2081   if test x$with_selinux = xyes ; then
2082     if test x$have_selinux = xno ; then
2083       AC_MSG_ERROR([SELinux explicitly required, but sufficiently recent SELinux library not found])
2084     fi
2085   fi
2086 fi
2087 # Check if we're building with SELinux support.
2088 if test "x$have_selinux" = xyes; then
2089   AC_DEFINE(HAVE_SELINUX, 1, [SELinux support])
2090
2091   # See if we have the libaudit library
2092   AC_CHECK_LIB(audit, audit_log_user_avc_message,
2093                have_libaudit=yes, have_libaudit=no)
2094   if test "x$have_libaudit" = xyes; then
2095     AC_DEFINE(HAVE_LIBAUDIT, 1, [SELinux libaudit support])
2096   fi
2097   AC_SUBST(have_libaudit)
2098
2099   # See if we have the libcap library
2100   AC_CHECK_LIB(cap, cap_init, have_libcap=yes, have_libcap=no)
2101   if test "x$have_libcap" = xyes; then
2102     AC_DEFINE(HAVE_LIBCAP, 1, [SELinux libcap support])
2103   fi
2104   AC_SUBST(have_libcap)
2105 fi
2106 AC_SUBST(have_selinux)
2107
2108 dnl check for the size of 'long double'.
2109 AC_CHECK_SIZEOF(long double, 0)
2110 sizeof_long_double=$ac_cv_sizeof_long_double
2111 AC_SUBST(sizeof_long_double)
2112
2113 ### End of automated tests.
2114 ### Now run sysdeps configure fragments.
2115
2116 # They also can set these variables.
2117 use_ldconfig=no
2118 ldd_rewrite_script=no
2119 libc_cv_sysconfdir=$sysconfdir
2120 libc_cv_gcc_unwind_find_fde=no
2121 libc_cv_idn=no
2122
2123 # Iterate over all the sysdep directories we will use, running their
2124 # configure fragments.
2125 for dir in $sysnames; do
2126   case $dir in
2127     /*) dest=$dir ;;
2128     *)  dest=$srcdir/$dir ;;
2129   esac
2130   if test -r $dest/configure; then
2131     AC_MSG_RESULT(running configure fragment for $dir)
2132     . $dest/configure
2133   fi
2134 done
2135
2136 if test x$libc_cv_gcc_unwind_find_fde = xyes; then
2137   AC_DEFINE(EXPORT_UNWIND_FIND_FDE)
2138 fi
2139 AC_SUBST(libc_cv_gcc_unwind_find_fde)
2140
2141 # Test for old glibc 2.0.x headers so that they can be removed properly
2142 # Search only in includedir.
2143 AC_MSG_CHECKING(for old glibc 2.0.x headers)
2144 if eval test -f "${includedir}/elfclass.h" -a -f "${includedir}/fcntlbits.h"
2145 then
2146   old_glibc_headers=yes
2147 else
2148   old_glibc_headers=no
2149 fi
2150 AC_MSG_RESULT($old_glibc_headers)
2151 if test ${old_glibc_headers} = yes; then
2152   AC_MSG_WARN(*** During \"make install\" old headers from glibc 2.0.x will)
2153   AC_MSG_WARN(*** be removed.)
2154 fi
2155 AC_SUBST(old_glibc_headers)
2156
2157 AC_SUBST(libc_cv_slibdir)
2158 AC_SUBST(libc_cv_localedir)
2159 AC_SUBST(libc_cv_sysconfdir)
2160 AC_SUBST(libc_cv_rootsbindir)
2161 AC_SUBST(libc_cv_forced_unwind)
2162
2163 dnl sysdeps/CPU/configure.in checks set this via arch-specific asm tests
2164 AC_SUBST(libc_cv_cpp_asm_debuginfo)
2165 AC_SUBST(libc_cv_cc_sse4)
2166 AC_SUBST(libc_cv_cc_avx)
2167 AC_SUBST(libc_cv_cc_novzeroupper)
2168 AC_SUBST(libc_cv_cc_fma4)
2169 AC_SUBST(libc_cv_as_i686)
2170
2171 AC_SUBST(use_ldconfig)
2172 AC_SUBST(ldd_rewrite_script)
2173
2174 AC_SUBST(static)
2175 AC_SUBST(shared)
2176
2177 AC_CACHE_CHECK([whether -fPIC is default], libc_cv_pic_default,
2178 [libc_cv_pic_default=yes
2179 cat > conftest.c <<EOF
2180 #if defined __PIC__ || defined __pic__ || defined PIC || defined pic
2181 # error PIC is default.
2182 #endif
2183 EOF
2184 if eval "${CC-cc} -S conftest.c 2>&AS_MESSAGE_LOG_FD 1>&AS_MESSAGE_LOG_FD"; then
2185   libc_cv_pic_default=no
2186 fi
2187 rm -f conftest.*])
2188 AC_SUBST(libc_cv_pic_default)
2189
2190 AC_SUBST(profile)
2191 AC_SUBST(static_nss)
2192 AC_SUBST(nopic_initfini)
2193
2194 AC_SUBST(DEFINES)
2195
2196 dnl See sysdeps/mach/configure.in for this variable.
2197 AC_SUBST(mach_interface_list)
2198
2199 if test "`(cd $srcdir; pwd)`" = "`pwd`"; then
2200   config_makefile=
2201 else
2202   config_makefile=Makefile
2203 fi
2204
2205 VERSION=`sed -n -e 's/^#define VERSION "\([^"]*\)"/\1/p' < $srcdir/version.h`
2206 RELEASE=`sed -n -e 's/^#define RELEASE "\([^"]*\)"/\1/p' < $srcdir/version.h`
2207 AC_SUBST(VERSION)
2208 AC_SUBST(RELEASE)
2209
2210 AC_CONFIG_FILES([config.make ${config_makefile}])
2211 AC_CONFIG_COMMANDS([default],[[
2212 case $CONFIG_FILES in *config.make*)
2213 echo "$config_vars" >> config.make;;
2214 esac
2215 test -d bits || mkdir bits]],[[config_vars='$config_vars']])
2216 AC_OUTPUT