configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 dnl ***********************************
   6 dnl *** include special GLib macros ***
   7 dnl ***********************************
   8
   9 m4_define(glib_configure_in)
  10 m4_include(acglib.m4)dnl
  11 m4_include(glib/libcharset/codeset.m4)dnl
  12 m4_include(glib/libcharset/glibc21.m4)dnl
  13 m4_include(m4macros/glib-gettext.m4)dnl
  14
  15 #
  16 # The following version number definitions apply to GLib, GModule, GObject
  17 # and GThread as a whole, so if changes occoured in any of them, they are all
  18 # treated with the same interface and binary age.
  19 #
  20 # Making releases:
  21 #   glib_micro_version += 1;
  22 #   glib_interface_age += 1;
  23 #   glib_binary_age += 1;
  24 # if any functions have been added, set glib_interface_age to 0.
  25 # if backwards compatibility has been broken,
  26 # set glib_binary_age _and_ glib_interface_age to 0.
  27 #
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [13])
  30 m4_define([glib_micro_version], [0])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_SRCDIR([glib/glib.h])
  56
  57 # Save this value here, since automake will set cflags later
  58 cflags_set=${CFLAGS+set}
  59
  60 AM_INIT_AUTOMAKE([no-define])
  61
  62 # Specify a configuration file
  63 AM_CONFIG_HEADER([config.h])
  64
  65
  66 GLIB_MAJOR_VERSION=glib_major_version
  67 GLIB_MINOR_VERSION=glib_minor_version
  68 GLIB_MICRO_VERSION=glib_micro_version
  69 GLIB_INTERFACE_AGE=glib_interface_age
  70 GLIB_BINARY_AGE=glib_binary_age
  71 GLIB_VERSION=glib_version
  72
  73 AC_SUBST(GLIB_MAJOR_VERSION)
  74 AC_SUBST(GLIB_MINOR_VERSION)
  75 AC_SUBST(GLIB_MICRO_VERSION)
  76 AC_SUBST(GLIB_VERSION)
  77 AC_SUBST(GLIB_INTERFACE_AGE)
  78 AC_SUBST(GLIB_BINARY_AGE)
  79
  80 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  81           [Define to the GLIB major version])
  82 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  83           [Define to the GLIB minor version])
  84 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  85           [Define to the GLIB micro version])
  86 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  87           [Define to the GLIB interface age])
  88 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  89           [Define to the GLIB binary age])
  90
  91 # libtool versioning
  92 LT_RELEASE=glib_lt_release
  93 LT_CURRENT=glib_lt_current
  94 LT_REVISION=glib_lt_revision
  95 LT_AGE=glib_lt_age
  96 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
  97 AC_SUBST(LT_RELEASE)
  98 AC_SUBST(LT_CURRENT)
  99 AC_SUBST(LT_REVISION)
 100 AC_SUBST(LT_AGE)
 101 AC_SUBST(LT_CURRENT_MINUS_AGE)
 102
 103 dnl Initialize maintainer mode
 104 AM_MAINTAINER_MODE
 105
 106 AC_CANONICAL_HOST
 107
 108 AC_MSG_CHECKING([for the BeOS])
 109 case $host in
 110   *-*-beos*)
 111     glib_native_beos="yes"
 112     ;;
 113   *)
 114     glib_native_beos="no"
 115     ;;
 116 esac
 117 AC_MSG_RESULT([$glib_native_beos])
 118
 119 dnl
 120
 121 AC_MSG_CHECKING([for Win32])
 122 case "$host" in
 123   *-*-mingw*)
 124     glib_native_win32=yes
 125     GLIB_DEF=glib.def
 126     GMODULE_DEF=gmodule.def
 127     GOBJECT_DEF=gobject.def
 128     GTHREAD_DEF=gthread.def
 129     TESTGMODULE_EXP=testgmodule.exp
 130     glib_pid_type='void *'
 131     ;;
 132   *)
 133     glib_native_win32=no
 134     GLIB_DEF=
 135     GMODULE_DEF=
 136     GOBJECT_DEF=
 137     GTHREAD_DEF=
 138     TESTGMODULE_EXP=
 139     glib_pid_type=int
 140     ;;
 141 esac
 142 case $host in
 143   *-*-linux*)
 144     glib_os_linux=yes
 145     ;;
 146 esac
 147
 148
 149 AC_MSG_RESULT([$glib_native_win32])
 150 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 151 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 152 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 153 AC_SUBST(GLIB_DEF)
 154 AC_SUBST(GMODULE_DEF)
 155 AC_SUBST(GOBJECT_DEF)
 156 AC_SUBST(GTHREAD_DEF)
 157 AC_SUBST(TESTGMODULE_EXP)
 158
 159 if test "$glib_native_win32" = "yes"; then
 160   AC_CHECK_TOOL(WINDRES, windres, no)
 161   if test "$WINDRES" = no; then
 162     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 163   fi
 164   AC_CHECK_TOOL(NM, nm, no)
 165   if test "$NM" = no; then
 166     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 167   fi
 168   AC_CHECK_TOOL(RANLIB, ranlib, :)
 169   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 170 fi
 171 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 172
 173 if test "$glib_native_win32" != yes; then
 174     # libtool option to control which symbols are exported
 175     # right now, symbols starting with _ are not exported
 176     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 177 else
 178     # We currently use .def files on Windows
 179     LIBTOOL_EXPORT_OPTIONS=
 180 fi
 181 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 182
 183 dnl declare --enable-* args and collect ac_help strings
 184 AC_ARG_ENABLE(debug,
 185               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 186                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 187               enable_debug=glib_debug_default)
 188
 189 AC_ARG_ENABLE(gc_friendly,
 190               [AC_HELP_STRING([--enable-gc-friendly],
 191                               [turn on garbage collector friendliness [default=no]])],,
 192               [enable_gc_friendly=no])
 193 AC_ARG_ENABLE(mem_pools,
 194               [AC_HELP_STRING([--disable-mem-pools],
 195                               [disable all glib memory pools])],,
 196               [disable_mem_pools=no])
 197 AC_ARG_ENABLE(threads,
 198               [AC_HELP_STRING([--enable-threads],
 199                               [turn on basic thread support [default=yes]
 200 ([=no] will override --with-threads)])],,
 201               [enable_threads=yes])
 202 AC_ARG_ENABLE(rebuilds,
 203               [AC_HELP_STRING([--disable-rebuilds],
 204                               [disable all source autogeneration rules])],,
 205               [enable_rebuilds=yes])
 206 AC_ARG_ENABLE(visibility,
 207               [AC_HELP_STRING([--disable-visibility],
 208                               [don't use ELF visibility attributes])],,
 209               [enable_visibility=yes])
 210
 211 if test "x$enable_threads" != "xyes"; then
 212   enable_threads=no
 213 fi
 214
 215 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, ["${enable_debug}"],
 216         [Whether glib was compiled with debugging enabled])
 217
 218 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 219 if test "x$enable_gc_friendly" = "xyes"; then
 220   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 221   AC_MSG_RESULT([yes])
 222 else
 223   AC_MSG_RESULT([no])
 224 fi
 225
 226 AC_MSG_CHECKING([whether to disable memory pools])
 227 if test "x$disable_mem_pools" = "xno"; then
 228   AC_MSG_RESULT([no])
 229 else
 230   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 231   AC_SUBST(DISABLE_MEM_POOLS)
 232   AC_MSG_RESULT([yes])
 233 fi
 234
 235 if test "$glib_native_win32" = "yes"; then
 236   if test x$enable_static = xyes -o x$enable_static = x; then
 237     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 238     enable_static=no
 239   fi
 240   if test x$enable_shared = xno; then
 241     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 242   fi
 243   enable_shared=yes
 244 fi
 245
 246 dnl Checks for programs.
 247 AC_PROG_CC
 248
 249 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 250 AC_CHECK_PROGS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 251 AC_LANG_SAVE
 252 AC_LANG_CPLUSPLUS
 253 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 254 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 255 AC_LANG_RESTORE
 256
 257 AM_PROG_CC_STDC
 258 AC_PROG_INSTALL
 259
 260 AC_SYS_LARGEFILE
 261
 262 #
 263 # Find pkg-config
 264 #
 265 AC_PATH_PROG(PKG_CONFIG, [pkg-config], [no])
 266 if test x$PKG_CONFIG = xno ; then
 267   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
 268 fi
 269
 270 if $PKG_CONFIG --atleast-pkgconfig-version 0.14 ; then
 271   :
 272 else
 273   AC_MSG_ERROR([*** pkg-config too old; version 0.14 or better required.])
 274 fi
 275
 276 if test "x$enable_debug" = "xyes"; then
 277   if test x$cflags_set != xset ; then
 278       case " $CFLAGS " in
 279       *[[\ \    ]]-g[[\ \       ]]*) ;;
 280       *) CFLAGS="$CFLAGS -g" ;;
 281       esac
 282   fi
 283
 284   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 285 else
 286   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 287
 288   if test "x$enable_debug" = "xno"; then
 289     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 290   fi
 291 fi
 292
 293 if test "x$enable_visibility" = "xno"; then
 294   GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DDISABLE_VISIBILITY"
 295 fi
 296
 297 # Ensure MSVC-compatible struct packing convention is used when
 298 # compiling for Win32 with gcc.
 299 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 300 # gcc2 uses "-fnative-struct".
 301 if test x"$glib_native_win32" = xyes; then
 302   if test x"$GCC" = xyes; then
 303     msnative_struct=''
 304     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 305     if test -z "$ac_cv_prog_CC"; then
 306       our_gcc="$CC"
 307     else
 308       our_gcc="$ac_cv_prog_CC"
 309     fi
 310     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 311       2.)
 312         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 313           msnative_struct='-fnative-struct'
 314         fi
 315         ;;
 316       *)
 317         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 318           msnative_struct='-mms-bitfields'
 319         fi
 320         ;;
 321     esac
 322     if test x"$msnative_struct" = x ; then
 323       AC_MSG_RESULT([no way])
 324       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 325     else
 326       CFLAGS="$CFLAGS $msnative_struct"
 327       AC_MSG_RESULT([${msnative_struct}])
 328     fi
 329   fi
 330 fi
 331
 332 AC_EXEEXT
 333
 334 # define a MAINT-like variable REBUILD which is set if Perl
 335 # and awk are found, so autogenerated sources can be rebuilt
 336 AC_PROG_AWK
 337 AC_CHECK_PROGS(PERL, [perl5 perl])
 338 # We would like indent, but don't require it.
 339 AC_CHECK_PROG(INDENT, indent, indent)
 340 REBUILD=\#
 341 if test "x$enable_rebuilds" = "xyes" && \
 342      test -n "$PERL" && \
 343      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 344      test -n "$AWK" ; then
 345   REBUILD=
 346 fi
 347 AC_SUBST(REBUILD)
 348
 349 # Need full path to Perl for glib-mkenums
 350 #
 351 if test "x$PERL" != x ; then
 352   AC_PATH_PROG(PERL_PATH, [$PERL])
 353 else
 354   PERL_PATH="/usr/bin/env perl"
 355 fi
 356 AC_SUBST(PERL_PATH)
 357
 358 dnl ***********************
 359 dnl *** Tests for iconv ***
 360 dnl ***********************
 361 dnl
 362 dnl We do this before the gettext checks, to avoid distortion
 363
 364 AC_ARG_WITH(libiconv,
 365             [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 366                             [use the libiconv library])],,
 367             [with_libiconv=maybe])
 368
 369 found_iconv=no
 370 case $with_libiconv in
 371   maybe)
 372     # Check in the C library first
 373     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 374     # Check if we have GNU libiconv
 375     if test $found_iconv = "no"; then
 376       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 377     fi
 378     # Check if we have a iconv in -liconv, possibly from vendor
 379     if test $found_iconv = "no"; then
 380       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 381     fi
 382     ;;
 383   no)
 384     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 385     ;;
 386   gnu|yes)
 387     AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 388     ;;
 389   native)
 390     AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 391     ;;
 392 esac
 393
 394 if test "x$found_iconv" = "xno" ; then
 395    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 396 fi
 397
 398 jm_GLIBC21
 399 AC_ARG_ENABLE(iconv-cache,
 400               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 401                               [cache iconv descriptors [default=auto]])],,
 402               [enable_iconv_cache=auto])
 403
 404 AC_MSG_CHECKING([Whether to cache iconv descriptors])
 405 case $enable_iconv_cache in
 406   auto)
 407     if test $ac_cv_gnu_library_2_1 = yes; then
 408       enable_iconv_cache=no
 409     else
 410       enable_iconv_cache=yes
 411     fi
 412   ;;
 413   yes|no)
 414   ;;
 415   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 416   ;;
 417 esac
 418
 419 if test $enable_iconv_cache = yes; then
 420    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 421 fi
 422
 423 AC_MSG_RESULT($enable_iconv_cache)
 424
 425
 426 dnl
 427 dnl gettext support
 428 dnl
 429
 430 ALL_LINGUAS="am ar az be bg bn bn_IN bs ca cs cy da de dz el en_CA en_GB eo es et eu fa fi fr ga gl gu he hi hr hu hy id is it ja ka ko ku lt lv mk ml mn ms nb ne nl nn or pa pl pt pt_BR ro ru rw sk sl sq sr sr@Latn sr@ije sv ta te th tl tr tt uk vi wa xh yi zh_CN zh_HK zh_TW"
 431 GLIB_GNU_GETTEXT
 432
 433 if test "$gt_cv_have_gettext" != "yes" ; then
 434   AC_MSG_ERROR([
 435 *** You must have either have gettext support in your C library, or use the
 436 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 437 ])
 438 fi
 439
 440 LIBS="$INTLLIBS $LIBS"
 441
 442 GETTEXT_PACKAGE=glib20
 443 AC_SUBST(GETTEXT_PACKAGE)
 444 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 445   [Define the gettext package to be used])
 446
 447 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 448
 449 dnl
 450 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 451 dnl
 452
 453 if test x$with_libiconv != xno ; then
 454   case " $INTLLIBS " in
 455   *[[\ \        ]]-liconv[[\ \  ]]*) ;;
 456   *) ICONV_LIBS="-liconv" ;;
 457   esac
 458 fi
 459 AC_SUBST(ICONV_LIBS)
 460
 461 case $with_libiconv in
 462   gnu)
 463     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 464     ;;
 465   native)
 466     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 467     ;;
 468 esac
 469
 470 dnl Initialize libtool
 471 AM_DISABLE_STATIC
 472 AC_LIBTOOL_WIN32_DLL
 473 AM_PROG_LIBTOOL
 474
 475 if test "x$GCC" = "xyes"; then
 476   case " $CFLAGS " in
 477   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 478   *) CFLAGS="$CFLAGS -Wall" ;;
 479   esac
 480 fi
 481
 482 dnl
 483 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 484 dnl
 485 if test $cross_compiling != yes ; then
 486     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 487     glib_save_LIBS=$LIBS
 488     LIBS="$LIBS -lm"
 489     AC_TRY_RUN([#include <math.h>
 490                  int main (void) { return (log(1) != log(1.)); }],
 491          AC_MSG_RESULT(none needed),
 492          glib_save_CFLAGS=$CFLAGS
 493          CFLAGS="$CFLAGS -std1"
 494          AC_TRY_RUN([#include <math.h>
 495                      int main (void) { return (log(1) != log(1.)); }],
 496              AC_MSG_RESULT(-std1),
 497              AC_MSG_RESULT()
 498              CFLAGS=$glib_save_CFLAGS
 499              AC_MSG_WARN(
 500                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 501          )
 502     )
 503     LIBS=$glib_save_LIBS
 504 fi
 505
 506 dnl NeXTStep cc seems to need this
 507 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 508 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 509   AC_MSG_RESULT(none needed),
 510   glib_save_CFLAGS=$CFLAGS
 511   CFLAGS="$CFLAGS -posix"
 512   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 513     AC_MSG_RESULT(-posix),
 514     AC_MSG_RESULT()
 515     CFLAGS=$glib_save_CFLAGS
 516     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 517
 518 # Checks for header files.
 519 AC_HEADER_STDC
 520
 521 # Checks for library functions.
 522 AC_FUNC_VPRINTF
 523 AC_FUNC_MMAP
 524 AC_FUNC_ALLOCA
 525 AC_CHECK_FUNCS(posix_memalign)
 526 AC_CHECK_FUNCS(memalign)
 527 AC_CHECK_FUNCS(valloc)
 528
 529 AC_CHECK_FUNCS(atexit on_exit)
 530
 531 AC_CHECK_FUNCS(timegm)
 532
 533 AC_CHECK_SIZEOF(char)
 534 AC_CHECK_SIZEOF(short)
 535 AC_CHECK_SIZEOF(long)
 536 AC_CHECK_SIZEOF(int)
 537 AC_CHECK_SIZEOF(void *)
 538 AC_CHECK_SIZEOF(long long)
 539 AC_CHECK_SIZEOF(__int64)
 540
 541 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 542   :
 543 else
 544   AC_MSG_ERROR([
 545 *** GLib requires a 64 bit type. You might want to consider
 546 *** using the GNU C compiler.
 547 ])
 548 fi
 549
 550 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 551         # long long is a 64 bit integer.
 552         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 553         AC_CACHE_VAL(glib_cv_long_long_format,[
 554                 for format in ll q I64; do
 555                   AC_TRY_RUN([#include <stdio.h>
 556                         int main()
 557                         {
 558                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 559                           char buffer[1000];
 560                           sprintf (buffer, "%${format}u", a);
 561                           sscanf (buffer, "%${format}u", &b);
 562                           exit (b!=a);
 563                         }
 564                         ],
 565                         [glib_cv_long_long_format=${format}
 566                         break],
 567                         [],[:])
 568                 done])
 569         if test -n "$glib_cv_long_long_format"; then
 570           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 571           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 572           if test x"$glib_cv_long_long_format" = xI64; then
 573             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 574           fi
 575         else
 576           AC_MSG_RESULT(none)
 577         fi
 578 elif test x$ac_cv_sizeof___int64 = x8; then
 579         # __int64 is a 64 bit integer.
 580         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 581         # We know this is MSVCRT.DLL, and what the formats are
 582         glib_cv_long_long_format=I64
 583         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 584         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 585         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 586 fi
 587
 588 dnl long doubles were not used, and a portability problem
 589 dnl AC_C_LONG_DOUBLE
 590 AC_C_CONST
 591
 592 dnl ok, here we try to check whether the systems prototypes for
 593 dnl malloc and friends actually match the prototypes provided
 594 dnl by gmem.h (keep in sync). i currently only know how to check
 595 dnl this reliably with gcc (-Werror), improvements for other
 596 dnl compilers are apprechiated.
 597 SANE_MALLOC_PROTOS=no
 598 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 599 glib_save_CFLAGS=$CFLAGS
 600 if test "x$GCC" = "xyes"; then
 601   CFLAGS="$CFLAGS -Werror"
 602   AC_TRY_COMPILE([#include <stdlib.h>], [
 603     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 604     void* (*my_malloc_p)  (size_t)         = malloc;
 605     void  (*my_free_p)    (void*)          = free;
 606     void* (*my_realloc_p) (void*, size_t)  = realloc;
 607     my_calloc_p = 0;
 608     my_malloc_p = 0;
 609     my_free_p = 0;
 610     my_realloc_p = 0;
 611   ],
 612     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 613       [Define if you have correct malloc prototypes])
 614     SANE_MALLOC_PROTOS=yes)
 615 fi
 616 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 617 CFLAGS=$glib_save_CFLAGS
 618
 619 dnl
 620 dnl check in which direction the stack grows
 621 dnl
 622 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 623         AC_TRY_RUN([
 624         volatile int *a = 0, *b = 0;
 625         void foo (void);
 626         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 627         void foo (void) { volatile int x = 5; b = &x; }
 628         ],
 629         glib_cv_stack_grows=no
 630         ,
 631         glib_cv_stack_grows=yes
 632         ,)
 633 ])
 634
 635 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 636 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 637 dnl actually supported.
 638 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 639         AC_COMPILE_IFELSE([
 640         __inline int foo () { return 0; }
 641         int main () { return foo (); }
 642         ],
 643         glib_cv_has__inline=yes
 644         ,
 645         glib_cv_has__inline=no
 646         ,)
 647 ])
 648 case x$glib_cv_has__inline in
 649 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 650 esac
 651 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 652         AC_COMPILE_IFELSE([
 653         __inline__ int foo () { return 0; }
 654         int main () { return foo (); }
 655         ],
 656         glib_cv_has__inline__=yes
 657         ,
 658         glib_cv_has__inline__=no
 659         ,)
 660 ])
 661 case x$glib_cv_has__inline__ in
 662 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 663 esac
 664 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 665         AC_COMPILE_IFELSE([
 666         #undef inline
 667         inline int foo () { return 0; }
 668         int main () { return foo (); }
 669         ],
 670         glib_cv_hasinline=yes
 671         ,
 672         glib_cv_hasinline=no
 673         ,)
 674 ])
 675 case x$glib_cv_hasinline in
 676 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 677 esac
 678
 679 # if we can use inline functions in headers
 680 AC_MSG_CHECKING(if inline functions in headers work)
 681 AC_LINK_IFELSE([
 682 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 683 #  undef inline
 684 #  define inline __inline__
 685 #elif !defined (G_HAVE_INLINE)
 686 #  undef inline
 687 #  if defined (G_HAVE___INLINE__)
 688 #    define inline __inline__
 689 #  elif defined (G_HAVE___INLINE)
 690 #    define inline __inline
 691 #  endif
 692 #endif
 693
 694 int glib_test_func2 (int);
 695
 696 static inline int
 697 glib_test_func1 (void) {
 698   return glib_test_func2 (1);
 699 }
 700
 701 int
 702 main (void) {
 703   int i = 1;
 704 }],[g_can_inline=yes],[g_can_inline=no])
 705 AC_MSG_RESULT($g_can_inline)
 706
 707 dnl *** check for working do while(0) macros ***
 708 AC_CACHE_CHECK([for working do while(0) macros], g_support_dowhile_macros, [
 709         AC_TRY_COMPILE([],[
 710         #define STMT_START do
 711         #define STMT_END while(0)
 712         #define STMT_TEST STMT_START { i = 0; } STMT_END
 713         int main(void) { int i = 1; STMT_TEST; return i; }],
 714         [g_support_dowhile_macros=yes],
 715         [g_support_dowhile_macros=no],
 716         [g_support_dowhile_macros=yes])
 717 ])
 718 if test x$g_support_dowhile_macros = xyes; then
 719   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 720 fi
 721
 722 # check for flavours of varargs macros
 723 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 724 AC_TRY_COMPILE([],[
 725 int a(int p1, int p2, int p3);
 726 #define call_a(...) a(1,__VA_ARGS__)
 727 call_a(2,3);
 728 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 729 AC_MSG_RESULT($g_have_iso_c_varargs)
 730
 731 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 732 if test "$CXX" = ""; then
 733 dnl No C++ compiler
 734   g_have_iso_cxx_varargs=no
 735 else
 736   AC_LANG_CPLUSPLUS
 737   AC_TRY_COMPILE([],[
 738 int a(int p1, int p2, int p3);
 739 #define call_a(...) a(1,__VA_ARGS__)
 740 call_a(2,3);
 741 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 742   AC_LANG_C
 743 fi
 744 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 745
 746 AC_MSG_CHECKING(for GNUC varargs macros)
 747 AC_TRY_COMPILE([],[
 748 int a(int p1, int p2, int p3);
 749 #define call_a(params...) a(1,params)
 750 call_a(2,3);
 751 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 752 AC_MSG_RESULT($g_have_gnuc_varargs)
 753
 754 # check for GNUC visibility support
 755 AC_MSG_CHECKING(for GNUC visibility attribute)
 756 GLIB_CHECK_COMPILE_WARNINGS([
 757 void
 758 __attribute__ ((visibility ("hidden")))
 759      f_hidden (void)
 760 {
 761 }
 762 void
 763 __attribute__ ((visibility ("internal")))
 764      f_internal (void)
 765 {
 766 }
 767 void
 768 __attribute__ ((visibility ("protected")))
 769      f_protected (void)
 770 {
 771 }
 772 void
 773 __attribute__ ((visibility ("default")))
 774      f_default (void)
 775 {
 776 }
 777 int main (int argc, char **argv)
 778 {
 779         f_hidden();
 780         f_internal();
 781         f_protected();
 782         f_default();
 783         return 0;
 784 }
 785 ],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 786 AC_MSG_RESULT($g_have_gnuc_visibility)
 787 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 788
 789 # check for bytesex stuff
 790 AC_C_BIGENDIAN
 791
 792 # check for header files
 793 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h sys/param.h sys/poll.h])
 794 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 795 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h sched.h malloc.h])
 796
 797 # Checks for libcharset
 798 jm_LANGINFO_CODESET
 799 jm_GLIBC21
 800 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 801 AC_CHECK_FUNCS(setlocale)
 802
 803 # check additional type sizes
 804 AC_CHECK_SIZEOF(size_t)
 805
 806 dnl Try to figure out whether gsize, gssize should be long or int
 807 AC_MSG_CHECKING([for the appropriate definition for size_t])
 808
 809 case $ac_cv_sizeof_size_t in
 810   $ac_cv_sizeof_short)
 811       glib_size_type=short
 812       ;;
 813   $ac_cv_sizeof_int)
 814       glib_size_type=int
 815       ;;
 816   $ac_cv_sizeof_long)
 817       glib_size_type=long
 818       ;;
 819   *)  AC_MSG_ERROR([No type matching size_t in size])
 820       ;;
 821 esac
 822
 823 dnl If int/long are the same size, we see which one produces
 824 dnl warnings when used in the location as size_t. (This matters
 825 dnl on AIX with xlc)
 826 dnl
 827 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 828    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 829   GLIB_CHECK_COMPILE_WARNINGS([
 830 #if defined(_AIX) && !defined(__GNUC__)
 831 #pragma options langlvl=stdc89
 832 #endif
 833 #include <stddef.h>
 834 int main ()
 835 {
 836   size_t s = 1;
 837   unsigned int *size_int = &s;
 838   return (int)*size_int;
 839 }
 840     ],glib_size_type=int,
 841       [GLIB_CHECK_COMPILE_WARNINGS([
 842 #if defined(_AIX) && !defined(__GNUC__)
 843 #pragma options langlvl=stdc89
 844 #endif
 845 #include <stddef.h>
 846 int main ()
 847 {
 848    size_t s = 1;
 849    unsigned long *size_long = &s;
 850    return (int)*size_long;
 851 }
 852         ],glib_size_type=long)])
 853 fi
 854
 855 AC_MSG_RESULT(unsigned $glib_size_type)
 856
 857 # Check for some functions
 858 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk)
 859 # Check for high-resolution sleep functions
 860 AC_CHECK_FUNCS(nanosleep nsleep)
 861
 862 AC_CHECK_FUNCS(clock_gettime, [], [
 863   AC_CHECK_LIB(rt, clock_gettime, [
 864     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
 865     LIBS="$LIBS -lrt"
 866   ])
 867 ])
 868
 869 AC_CACHE_CHECK(for monotonic clocks,
 870     glib_cv_monotonic_clock,AC_TRY_RUN([
 871 #include <time.h>
 872 #ifdef HAVE_UNISTD_H
 873 #include <unistd.h>
 874 #endif
 875       int main() {
 876 #if defined(_POSIX_MONOTONIC_CLOCK) && _POSIX_MONOTONIC_CLOCK >= 0 && defined(CLOCK_MONOTONIC)
 877         return 0;
 878 #else
 879         return 1;
 880 #endif
 881       }],glib_cv_monotonic_clock=yes,glib_cv_monotonic_clock=no))
 882
 883 GLIB_ASSERT_SET(glib_cv_monotonic_clock)
 884 if test "$glib_cv_monotonic_clock" = "yes"; then
 885   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
 886 fi
 887
 888 AC_CHECK_HEADERS(crt_externs.h)
 889 AC_CHECK_FUNCS(_NSGetEnviron)
 890
 891 AC_FUNC_VSNPRINTF_C99
 892 AC_FUNC_PRINTF_UNIX98
 893
 894 #
 895 # Check whether to use an included printf
 896 #
 897
 898 AC_ARG_ENABLE(included-printf,
 899               [AC_HELP_STRING([--enable-included-printf],
 900                               [use included printf [default=auto]])],
 901               enable_included_printf="$enableval")
 902
 903 need_included_printf=no
 904 if test "x$enable_included_printf" = "xyes" ; then
 905   need_included_printf=yes
 906 fi
 907 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
 908   need_included_printf=yes
 909 fi
 910 if test "$ac_cv_func_printf_unix98" != "yes" ; then
 911   need_included_printf=yes
 912 fi
 913 if test "x$ac_cv_sizeof_long_long" = "x8" &&
 914    test -z "$glib_cv_long_long_format" ; then
 915   need_included_printf=yes
 916 fi
 917
 918 if test "x$enable_included_printf" = "xno" &&
 919    test "x$need_included_printf" = "xyes" ; then
 920   AC_MSG_ERROR([
 921 *** Your C library's printf doesn't appear to have the features that
 922 *** GLib needs, but you specified --enable-included-printf=no.])
 923 fi
 924
 925 enable_included_printf=$need_included_printf
 926
 927 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
 928 if test "$enable_included_printf" != "yes" ; then
 929   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
 930 else
 931   if test -z "$glib_cv_long_long_format" ; then
 932     glib_cv_long_long_format="ll"
 933   fi
 934   AC_DEFINE(HAVE_VASPRINTF,1)
 935 fi
 936
 937 # Checks needed for gnulib vasnprintf
 938 bh_C_SIGNED
 939 jm_AC_TYPE_LONG_LONG
 940 gt_TYPE_LONGDOUBLE
 941 gt_TYPE_WCHAR_T
 942 gt_TYPE_WINT_T
 943 AC_TYPE_SIZE_T
 944 AC_CHECK_TYPES(ptrdiff_t)
 945 jm_AC_TYPE_INTMAX_T
 946 AC_CHECK_FUNCS(snprintf)
 947 AC_FUNC_SNPRINTF_C99
 948
 949 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 950 # The check is borrowed from the PERL Configure script.
 951 if test "$ac_cv_func_memmove" != "yes"; then
 952   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 953     glib_cv_working_bcopy,[AC_TRY_RUN([
 954       int main() {
 955         char buf[128], abc[128], *b;
 956         int len, off, align;
 957         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 958         for (align = 7; align >= 0; align--) {
 959           for (len = 36; len; len--) {
 960             b = buf+align; bcopy(abc, b, len);
 961             for (off = 1; off <= len; off++) {
 962               bcopy(b, b+off, len); bcopy(b+off, b, len);
 963                 if (bcmp(b, abc, len)) return(1);
 964             }
 965           }
 966         }
 967         return(0);
 968       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 969
 970   GLIB_ASSERT_SET(glib_cv_working_bcopy)
 971   if test "$glib_cv_working_bcopy" = "yes"; then
 972     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 973   fi
 974 fi
 975
 976 # Check for sys_errlist
 977 AC_MSG_CHECKING(for sys_errlist)
 978 AC_TRY_LINK(, [
 979 extern char *sys_errlist[];
 980 extern int sys_nerr;
 981 sys_errlist[sys_nerr-1][0] = 0;
 982 ], glib_ok=yes, glib_ok=no)
 983 AC_MSG_RESULT($glib_ok)
 984 if test "$glib_ok" = "no"; then
 985     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 986 fi
 987
 988 # Check for sys_siglist
 989 AC_MSG_CHECKING(for sys_siglist)
 990 AC_TRY_LINK(, [
 991 extern char *sys_siglist[];
 992 exit (sys_siglist[0]);
 993 ], glib_ok=yes, glib_ok=no)
 994 AC_MSG_RESULT($glib_ok)
 995 if test "$glib_ok" = "no"; then
 996     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 997 fi
 998
 999 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
1000 AC_MSG_CHECKING(for sys_siglist declaration)
1001 AC_TRY_COMPILE([#include <signal.h>], [
1002 strlen (sys_siglist[0]);
1003 ], glib_ok=yes, glib_ok=no)
1004 AC_MSG_RESULT($glib_ok)
1005 if test "$glib_ok" = "no"; then
1006     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
1007 fi
1008
1009 # Check if <sys/select.h> needs to be included for fd_set
1010 AC_MSG_CHECKING([for fd_set])
1011 AC_TRY_COMPILE([#include <sys/types.h>],
1012         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1013 if test "$gtk_ok" = "yes"; then
1014     AC_MSG_RESULT([yes, found in sys/types.h])
1015 else
1016     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1017     if test "$gtk_ok" = "yes"; then
1018         # *** FIXME: give it a different name
1019         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1020         AC_MSG_RESULT([yes, found in sys/select.h])
1021     else
1022         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1023         AC_MSG_RESULT(no)
1024     fi
1025 fi
1026
1027 dnl *** check for sane realloc() ***
1028 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1029         AC_TRY_RUN([#include <stdlib.h>
1030         int main() {
1031           return realloc (0, sizeof (int)) == 0;
1032         }],
1033         [glib_cv_sane_realloc=yes],
1034         [glib_cv_sane_realloc=no],
1035         [glib_cv_sane_realloc=yes])
1036 ])
1037 if test x$glib_cv_sane_realloc = xyes; then
1038   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1039 fi
1040
1041 dnl Check for nl_langinfo and CODESET
1042
1043 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
1044 AC_TRY_COMPILE([#include <langinfo.h>],
1045         [char *codeset = nl_langinfo (CODESET);],
1046    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1047    have_codeset=yes,
1048    have_codeset=no)
1049 AC_MSG_RESULT($have_codeset)
1050
1051
1052 dnl ****************************************
1053 dnl *** posix_memalign                   ***
1054 dnl ****************************************
1055 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1056 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1057     glib_cv_compliant_posix_memalign=0
1058     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1059         AC_TRY_RUN([
1060                 #define _XOPEN_SOURCE 600
1061                 #include <stdlib.h> /* posix_memalign() should be defined here */
1062                 /* some systems break if #include <malloc.h> used */
1063                 static void test_memalign (size_t boundary, size_t size) {
1064                     void *mem = 0;
1065                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1066                         exit (1);
1067                     else
1068                       free (mem);
1069                 }
1070                 int main() {
1071                     test_memalign (  128,   128 - 2 * sizeof (void*));
1072                     test_memalign (  256,   256 - 2 * sizeof (void*));
1073                     test_memalign (  512,   512 - 2 * sizeof (void*));
1074                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1075                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1076                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1077                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1078                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1079                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1080                     exit (0); /* success */
1081                 }
1082                 ],
1083             [glib_cv_compliant_posix_memalign=1], [], [:])
1084       :
1085     fi
1086     ])
1087 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1088     AC_MSG_RESULT(yes)
1089     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1090 else
1091     AC_MSG_RESULT(no)
1092 fi
1093
1094
1095 dnl ****************************************
1096 dnl *** strlcpy/strlcat                  ***
1097 dnl ****************************************
1098 # Check for strlcpy
1099 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1100 AC_TRY_RUN([#include <stdlib.h>
1101 #include <string.h>
1102 int main() {
1103   char p[10];
1104   (void) strlcpy (p, "hi", 10);
1105   if (strlcat (p, "bye", 0) != 3)
1106     return 1;
1107   return 0;
1108 }], glib_cv_have_strlcpy=yes,
1109     glib_cv_have_strlcpy=no,
1110     glib_cv_have_strlcpy=no)])
1111 if test "$glib_cv_have_strlcpy" = "yes"; then
1112     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1113 fi
1114
1115
1116 dnl **********************
1117 dnl *** va_copy checks ***
1118 dnl **********************
1119 dnl we currently check for all three va_copy possibilities, so we get
1120 dnl all results in config.log for bug reports.
1121 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1122         AC_LINK_IFELSE([#include <stdarg.h>
1123 #include <stdlib.h>
1124         void f (int i, ...) {
1125         va_list args1, args2;
1126         va_start (args1, i);
1127         va_copy (args2, args1);
1128         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1129           exit (1);
1130         va_end (args1); va_end (args2);
1131         }
1132         int main() {
1133           f (0, 42);
1134           return 0;
1135         }],
1136         [glib_cv_va_copy=yes],
1137         [glib_cv_va_copy=no])
1138 ])
1139 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1140         AC_LINK_IFELSE([#include <stdarg.h>
1141 #include <stdlib.h>
1142         void f (int i, ...) {
1143         va_list args1, args2;
1144         va_start (args1, i);
1145         __va_copy (args2, args1);
1146         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1147           exit (1);
1148         va_end (args1); va_end (args2);
1149         }
1150         int main() {
1151           f (0, 42);
1152           return 0;
1153         }],
1154         [glib_cv___va_copy=yes],
1155         [glib_cv___va_copy=no])
1156 ])
1157
1158 if test "x$glib_cv_va_copy" = "xyes"; then
1159   g_va_copy_func=va_copy
1160 else if test "x$glib_cv___va_copy" = "xyes"; then
1161   g_va_copy_func=__va_copy
1162 fi
1163 fi
1164
1165 if test -n "$g_va_copy_func"; then
1166   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1167 fi
1168
1169 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1170         AC_TRY_RUN([#include <stdarg.h>
1171 #include <stdlib.h>
1172         void f (int i, ...) {
1173         va_list args1, args2;
1174         va_start (args1, i);
1175         args2 = args1;
1176         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1177           exit (1);
1178         va_end (args1); va_end (args2);
1179         }
1180         int main() {
1181           f (0, 42);
1182           return 0;
1183         }],
1184         [glib_cv_va_val_copy=yes],
1185         [glib_cv_va_val_copy=no],
1186         [glib_cv_va_val_copy=yes])
1187 ])
1188
1189 if test "x$glib_cv_va_val_copy" = "xno"; then
1190   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1191 fi
1192
1193 dnl ***********************
1194 dnl *** g_module checks ***
1195 dnl ***********************
1196 G_MODULE_LIBS=
1197 G_MODULE_LIBS_EXTRA=
1198 G_MODULE_PLUGIN_LIBS=
1199 if test x"$glib_native_win32" = xyes; then
1200   dnl No use for this on Win32
1201   G_MODULE_LDFLAGS=
1202 else
1203   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1204 fi
1205 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1206 G_MODULE_NEED_USCORE=0
1207 G_MODULE_BROKEN_RTLD_GLOBAL=0
1208 G_MODULE_HAVE_DLERROR=0
1209 dnl *** force native WIN32 shared lib loader
1210 if test -z "$G_MODULE_IMPL"; then
1211   case "$host" in
1212   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1213   esac
1214 fi
1215 dnl *** force native AIX library loader
1216 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1217 if test -z "$G_MODULE_IMPL"; then
1218   case "$host" in
1219   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1220   esac
1221 fi
1222 dnl *** dlopen() and dlsym() in system libraries
1223 if test -z "$G_MODULE_IMPL"; then
1224         AC_CHECK_FUNC(dlopen,
1225                       [AC_CHECK_FUNC(dlsym,
1226                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1227                       [])
1228 fi
1229 dnl *** load_image (BeOS)
1230 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1231   AC_CHECK_LIB(root, load_image,
1232       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1233       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1234       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1235       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1236       [])
1237 fi
1238 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1239 if test -z "$G_MODULE_IMPL"; then
1240         AC_CHECK_FUNC(NSLinkModule,
1241                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1242                        G_MODULE_NEED_USCORE=1],
1243                       [])
1244 fi
1245 dnl *** dlopen() and dlsym() in libdl
1246 if test -z "$G_MODULE_IMPL"; then
1247         AC_CHECK_LIB(dl, dlopen,
1248                      [AC_CHECK_LIB(dl, dlsym,
1249                                    [G_MODULE_LIBS=-ldl
1250                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1251                      [])
1252 fi
1253 dnl *** shl_load() in libdld (HP-UX)
1254 if test -z "$G_MODULE_IMPL"; then
1255         AC_CHECK_LIB(dld, shl_load,
1256                 [G_MODULE_LIBS=-ldld
1257                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1258                 [])
1259 fi
1260 dnl *** additional checks for G_MODULE_IMPL_DL
1261 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1262         LIBS_orig="$LIBS"
1263         LDFLAGS_orig="$LDFLAGS"
1264         LIBS="$G_MODULE_LIBS $LIBS"
1265         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1266 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1267         echo "void glib_plugin_test(void) { }" > plugin.c
1268         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1269                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1270         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1271                 glib_cv_rtldglobal_broken,[
1272                 AC_TRY_RUN([
1273 #include <dlfcn.h>
1274 #ifndef RTLD_GLOBAL
1275 #  define RTLD_GLOBAL 0
1276 #endif
1277 #ifndef RTLD_LAZY
1278 #  define RTLD_LAZY 0
1279 #endif
1280 int glib_plugin_test;
1281 int main () {
1282     void *handle, *global, *local;
1283     global = &glib_plugin_test;
1284     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1285     if (!handle) return 0;
1286     local = dlsym (handle, "glib_plugin_test");
1287     return global == local;
1288 }                       ],
1289                         [glib_cv_rtldglobal_broken=no],
1290                         [glib_cv_rtldglobal_broken=yes],
1291                         [glib_cv_rtldglobal_broken=no])
1292                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1293                 rmdir .libs 2>/dev/null
1294         ])
1295         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1296                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1297         else
1298                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1299         fi
1300 dnl *** check whether we need preceeding underscores
1301         AC_CACHE_CHECK([for preceeding underscore in symbols],
1302                 glib_cv_uscore,[
1303                 AC_TRY_RUN([#include <dlfcn.h>
1304                 int glib_underscore_test (void) { return 42; }
1305                 int main() {
1306                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1307                   handle = dlopen ((void*)0, 0);
1308                   if (handle) {
1309                     f1 = dlsym (handle, "glib_underscore_test");
1310                     f2 = dlsym (handle, "_glib_underscore_test");
1311                   } return (!f2 || f1);
1312                 }],
1313                         [glib_cv_uscore=yes],
1314                         [glib_cv_uscore=no],
1315                         [])
1316                 rm -f plugin.c plugin.$ac_objext plugin.lo
1317         ])
1318         GLIB_ASSERT_SET(glib_cv_uscore)
1319         if test "x$glib_cv_uscore" = "xyes"; then
1320                 G_MODULE_NEED_USCORE=1
1321         else
1322                 G_MODULE_NEED_USCORE=0
1323         fi
1324
1325         LDFLAGS="$LDFLAGS_orig"
1326 dnl *** check for having dlerror()
1327         AC_CHECK_FUNC(dlerror,
1328                 [G_MODULE_HAVE_DLERROR=1],
1329                 [G_MODULE_HAVE_DLERROR=0])
1330         LIBS="$LIBS_orig"
1331 fi
1332 dnl *** done, have we got an implementation?
1333 if test -z "$G_MODULE_IMPL"; then
1334         G_MODULE_IMPL=0
1335         G_MODULE_SUPPORTED=false
1336 else
1337         G_MODULE_SUPPORTED=true
1338 fi
1339
1340 AC_MSG_CHECKING(for the suffix of shared libraries)
1341 case "$host_os" in
1342   hpux9* | hpux10* | hpux11*)  # taken from ltconfig
1343     case "$host_cpu" in
1344       hppa*)
1345         glib_gmodule_suffix='sl'
1346         ;;
1347       ia64*)
1348         glib_gmodule_suffix='so'
1349         ;;
1350     esac
1351     ;;
1352   cygwin* | mingw*)
1353     glib_gmodule_suffix='dll'
1354     ;;
1355   aix*)
1356     glib_gmodule_suffix='a'
1357     ;;
1358   *)
1359     glib_gmodule_suffix='so'
1360     ;;
1361 esac
1362 AC_MSG_RESULT(.$glib_gmodule_suffix)
1363
1364 AC_SUBST(G_MODULE_SUPPORTED)
1365 AC_SUBST(G_MODULE_IMPL)
1366 AC_SUBST(G_MODULE_LIBS)
1367 AC_SUBST(G_MODULE_LIBS_EXTRA)
1368 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1369 AC_SUBST(G_MODULE_LDFLAGS)
1370 AC_SUBST(G_MODULE_HAVE_DLERROR)
1371 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1372 AC_SUBST(G_MODULE_NEED_USCORE)
1373 AC_SUBST(GLIB_DEBUG_FLAGS)
1374
1375 dnl **********************
1376 dnl *** g_spawn checks ***
1377 dnl **********************
1378
1379 AC_MSG_CHECKING(for gspawn implementation)
1380 case "$host" in
1381   *-*-mingw*)
1382     GSPAWN=gspawn-win32.lo
1383     ;;
1384   *)
1385     GSPAWN=gspawn.lo
1386     ;;
1387 esac
1388 AC_MSG_RESULT($GSPAWN)
1389 AC_SUBST(GSPAWN)
1390
1391 dnl *************************
1392 dnl *** GIOChannel checks ***
1393 dnl *************************
1394
1395 AC_MSG_CHECKING(for GIOChannel implementation)
1396 case "$host" in
1397   *-*-mingw*)
1398     GIO=giowin32.lo
1399     ;;
1400   *)
1401     GIO=giounix.lo
1402     ;;
1403 esac
1404 AC_MSG_RESULT($GIO)
1405 AC_SUBST(GIO)
1406
1407 dnl ****************************************
1408 dnl *** platform dependent source checks ***
1409 dnl ****************************************
1410
1411 AC_MSG_CHECKING(for platform-dependent source)
1412 case "$host" in
1413   *-*-cygwin*|*-*-mingw*)
1414     PLATFORMDEP=gwin32.lo
1415     ;;
1416   *)
1417     PLATFORMDEP=
1418     ;;
1419 esac
1420 AC_MSG_RESULT($PLATFORMDEP)
1421 AC_SUBST(PLATFORMDEP)
1422
1423 AC_MSG_CHECKING([whether to compile timeloop])
1424 case "$host" in
1425   *-*-cygwin*|*-*-mingw*|*-*-minix)
1426     enable_timeloop=no
1427     ;;
1428   *)
1429     enable_timeloop=yes
1430     ;;
1431 esac
1432 AC_MSG_RESULT($enable_timeloop)
1433 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1434
1435 AC_MSG_CHECKING([if building for some Win32 platform])
1436 case "$host" in
1437   *-*-mingw*|*-*-cygwin*)
1438     platform_win32=yes
1439     ;;
1440   *)
1441     platform_win32=no
1442     ;;
1443 esac
1444 AC_MSG_RESULT($platform_win32)
1445 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1446
1447 dnl ***********************
1448 dnl *** g_thread checks ***
1449 dnl ***********************
1450
1451 AC_ARG_WITH(threads,
1452            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/win32@:>@],
1453                            [specify a thread implementation to use])],
1454            [if test "x$with_threads" = x; then
1455                 want_threads=yes
1456             else
1457                 want_threads=$with_threads
1458             fi],
1459            [want_threads=yes])
1460 if test "x$enable_threads" = "xno"; then
1461         want_threads=no
1462 fi
1463
1464 dnl error and warning message
1465 dnl *************************
1466
1467 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1468                 computer. GLib will not have a default thread implementation."
1469
1470 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1471                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1472                 compilation now, but then your programs might not work.
1473                 Please provide information on how it is done on your system."
1474
1475 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1476                 "
1477
1478 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1479                 provide information on your thread implementation.
1480                 You can also run 'configure --disable-threads'
1481                 to compile without thread support."
1482
1483 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1484                 functions will not be MT-safe during their first call because
1485                 there is no working 'getpwuid_r' on your system."
1486
1487 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1488                 because there is no 'localtime_r' on your system."
1489
1490 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1491                 crude surrogate will be used. If you happen to know a
1492                 yield function for your system, please inform the GLib
1493                 developers."
1494
1495 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1496                 threads on your system. Thus threads can only have the default
1497                 priority. If you happen to know these main/max
1498                 priorities, please inform the GLib developers."
1499
1500 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1501                 linking threaded applications. As GLib cannot do that
1502                 automatically, you will get an linkg error everytime you are
1503                 not using the right compiler. In that case you have to relink
1504                 with the right compiler. Ususally just '_r' is appended
1505                 to the compiler name."
1506
1507 dnl determination of thread implementation
1508 dnl ***************************************
1509
1510 # have_threads=no   means no thread support
1511 # have_threads=none means no default thread implementation
1512
1513 have_threads=no
1514 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1515                                 || test "x$want_threads" = xdce; then
1516         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1517         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1518         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1519         glib_save_CPPFLAGS="$CPPFLAGS"
1520         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1521         if test "x$have_threads" = xno; then
1522                 AC_TRY_COMPILE([#include <pthread.h>],
1523                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1524                         have_threads=posix)
1525         fi
1526         if test "x$have_threads" = xno; then
1527                 AC_TRY_COMPILE([#include <pthread.h>],
1528                         [pthread_mutex_t m;
1529                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1530                         have_threads=dce)
1531         fi
1532         # Tru64Unix requires -pthread to find pthread.h. See #103020
1533         CPPFLAGS="$CPPFLAGS -pthread"
1534         if test "x$have_threads" = xno; then
1535         AC_TRY_COMPILE([#include <pthread.h>],
1536                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1537                        have_threads=posix)
1538         fi
1539         CPPFLAGS="$glib_save_CPPFLAGS"
1540 fi
1541 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1542         case $host in
1543                 *-*-mingw*)
1544                 have_threads=win32
1545                 ;;
1546         esac
1547 fi
1548 if test "x$want_threads" = xnone; then
1549         have_threads=none
1550 fi
1551
1552 AC_MSG_CHECKING(for thread implementation)
1553
1554 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1555         AC_MSG_RESULT(none available)
1556         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1557 else
1558         AC_MSG_RESULT($have_threads)
1559 fi
1560
1561
1562 dnl determination of G_THREAD_CFLAGS
1563 dnl ********************************
1564
1565 G_THREAD_LIBS=
1566 G_THREAD_LIBS_EXTRA=
1567 G_THREAD_CFLAGS=
1568
1569 dnl
1570 dnl Test program for basic POSIX threads functionality
1571 dnl
1572 m4_define([glib_thread_test],[
1573 #include <pthread.h>
1574 int check_me = 0;
1575 void* func(void* data) {check_me = 42; return &check_me;}
1576 int main()
1577  { pthread_t t;
1578    void *ret;
1579    pthread_create (&t, $1, func, 0);
1580    pthread_join (t, &ret);
1581    return (check_me != 42 || ret != &check_me);
1582 }])
1583
1584 dnl
1585 dnl Test program for sched_get_priority_min()
1586 dnl
1587 m4_define([glib_sched_priority_test],[
1588 #include <sched.h>
1589 #include <errno.h>
1590 int main() {
1591     errno = 0;
1592     return sched_get_priority_min(SCHED_OTHER)==-1
1593            && errno != 0;
1594 }])
1595
1596 if test x"$have_threads" != xno; then
1597
1598   if test x"$have_threads" = xposix; then
1599     # First we test for posix, whether -pthread or -pthreads do the trick as
1600     # both CPPFLAG and LIBS.
1601     # One of them does for most gcc versions and some other platforms/compilers
1602     # too and could be considered as the canonical way to go.
1603     case $host in
1604       *-*-cygwin*|*-*-darwin*)
1605          # skip cygwin and darwin -pthread or -pthreads test
1606          ;;
1607       *-solaris*)
1608         # These compiler/linker flags work with both Sun Studio and gcc
1609         # Sun Studio expands -mt to -D_REENTRANT and -lthread
1610         # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1611         G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1612         G_THREAD_LIBS="-lpthread -lthread"
1613         ;;
1614       *)
1615         for flag in pthread pthreads mt; do
1616           glib_save_CFLAGS="$CFLAGS"
1617           CFLAGS="$CFLAGS -$flag"
1618           AC_TRY_RUN(glib_thread_test(0),
1619                      glib_flag_works=yes,
1620                      glib_flag_works=no,
1621                      [AC_LINK_IFELSE(glib_thread_test(0),
1622                                      glib_flag_works=yes,
1623                                      glib_flag_works=no)])
1624           CFLAGS="$glib_save_CFLAGS"
1625           if test $glib_flag_works = yes ; then
1626              G_THREAD_CFLAGS=-$flag
1627              G_THREAD_LIBS=-$flag
1628              break;
1629           fi
1630         done
1631          ;;
1632     esac
1633   fi
1634
1635   if test x"$G_THREAD_CFLAGS" = x; then
1636
1637     # The canonical -pthread[s] does not work. Try something different.
1638
1639     case $host in
1640         *-aix*)
1641                 if test x"$GCC" = xyes; then
1642                         # GCC 3.0 and above needs -pthread.
1643                         # Should be coverd by the case above.
1644                         # GCC 2.x and below needs -mthreads
1645                         G_THREAD_CFLAGS="-mthreads"
1646                         G_THREAD_LIBS=$G_THREAD_CFLAGS
1647                 else
1648                         # We are probably using the aix compiler. Normaly a
1649                         # program would have to be compiled with the _r variant
1650                         # of the corresponding compiler, but we as GLib cannot
1651                         # do that: but the good news is that for compiling the
1652                         # only difference is the added -D_THREAD_SAFE compile
1653                         # option. This is according to the "C for AIX User's
1654                         # Guide".
1655                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
1656                 fi
1657                 ;;
1658         *-dg-dgux*)  # DG/UX
1659                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
1660                 ;;
1661         *-osf*)
1662                 # So we are using dce threads. posix threads are already
1663                 # catched above.
1664                 G_THREAD_CFLAGS="-threads"
1665                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1666                 ;;
1667         *-sysv5uw7*) # UnixWare 7
1668                 # We are not using gcc with -pthread. Catched above.
1669                 G_THREAD_CFLAGS="-Kthread"
1670                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1671                 ;;
1672         *-mingw*)
1673                 # No flag needed when using MSVCRT.DLL
1674                 G_THREAD_CFLAGS=""
1675                 ;;
1676         *)
1677                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1678                 ;;
1679     esac
1680
1681   fi
1682
1683     # if we are not finding the localtime_r function, then we probably are
1684     # not using the proper multithread flag
1685
1686     glib_save_CPPFLAGS="$CPPFLAGS"
1687     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1688
1689     # First we test, whether localtime_r is declared in time.h
1690     # directly. Then we test whether a macro localtime_r exists, in
1691     # which case localtime_r in the test program is replaced and thus
1692     # if we still find localtime_r in the output, it is not defined as
1693     # a macro.
1694
1695     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1696       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1697                                                            localtime_r(a,b)],
1698                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1699
1700     CPPFLAGS="$glib_save_CPPFLAGS"
1701
1702     AC_MSG_CHECKING(thread related cflags)
1703     AC_MSG_RESULT($G_THREAD_CFLAGS)
1704     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1705 fi
1706
1707 dnl determination of G_THREAD_LIBS
1708 dnl ******************************
1709
1710 mutex_has_default=no
1711 case $have_threads in
1712         posix|dce)
1713           glib_save_CPPFLAGS="$CPPFLAGS"
1714           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1715           if test x"$G_THREAD_LIBS" = x; then
1716             case $host in
1717               *-aix*)
1718                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
1719                 # probably using the aix compiler.
1720                 AC_MSG_WARN($AIX_COMPILE_INFO)
1721                 ;;
1722               *)
1723                 G_THREAD_LIBS=error
1724                 glib_save_LIBS="$LIBS"
1725                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
1726                         if test x"$thread_lib" = x; then
1727                                 add_thread_lib=""
1728                                 IN=""
1729                         else
1730                                 add_thread_lib="-l$thread_lib"
1731                                 IN=" in -l$thread_lib"
1732                         fi
1733                         if test x"$have_threads" = xposix; then
1734                                 defattr=0
1735                         else
1736                                 defattr=pthread_attr_default
1737                         fi
1738
1739                         LIBS="$add_thread_lib $glib_save_LIBS"
1740
1741                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
1742                         AC_TRY_RUN(glib_thread_test($defattr),
1743                                    glib_result=yes,
1744                                    glib_result=no,
1745                                    [AC_LINK_IFELSE(glib_thread_test($defattr),
1746                                                    glib_result=yes,
1747                                                    glib_result=no)])
1748                         AC_MSG_RESULT($glib_result)
1749
1750                         if test "$glib_result" = "yes" ; then
1751                           G_THREAD_LIBS="$add_thread_lib"
1752                           break
1753                         fi
1754                 done
1755                 if test "x$G_THREAD_LIBS" = xerror; then
1756                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1757                 fi
1758                 LIBS="$glib_save_LIBS"
1759                 ;;
1760             esac
1761           fi
1762
1763           glib_save_LIBS="$LIBS"
1764           for thread_lib in "" rt rte; do
1765             if test x"$thread_lib" = x; then
1766               add_thread_lib=""
1767               IN=""
1768             else
1769               add_thread_lib="-l$thread_lib"
1770               IN=" in -l$thread_lib"
1771             fi
1772             LIBS="$add_thread_lib $glib_save_LIBS"
1773
1774             AC_MSG_CHECKING(for sched_get_priority_min$IN)
1775             AC_TRY_RUN(glib_sched_priority_test,
1776                        glib_result=yes,
1777                        glib_result=no,
1778                        [AC_LINK_IFELSE(glib_sched_priority_test,
1779                                        glib_result=yes,
1780                                        glib_result=no)])
1781             AC_MSG_RESULT($glib_result)
1782
1783             if test "$glib_result" = "yes" ; then
1784                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
1785                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
1786                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
1787                break
1788             fi
1789           done
1790           LIBS="$glib_save_LIBS"
1791           mutex_has_default=yes
1792           mutex_default_type='pthread_mutex_t'
1793           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
1794           mutex_header_file='pthread.h'
1795           if test "x$have_threads" = "xposix"; then
1796             g_threads_impl="POSIX"
1797           else
1798             g_threads_impl="DCE"
1799             have_threads="posix"
1800           fi
1801           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
1802           CPPFLAGS="$glib_save_CPPFLAGS"
1803           ;;
1804         win32)
1805            g_threads_impl="WIN32"
1806            ;;
1807         none|no)
1808            g_threads_impl="NONE"
1809            ;;
1810         *)
1811            g_threads_impl="NONE"
1812            G_THREAD_LIBS=error
1813            ;;
1814 esac
1815
1816 if test "x$G_THREAD_LIBS" = xerror; then
1817         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1818 fi
1819
1820 case $host in
1821   *-*-beos*)
1822     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
1823     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1824     ;;
1825   *)
1826     ;;
1827 esac
1828
1829 AC_MSG_CHECKING(thread related libraries)
1830 AC_MSG_RESULT($G_THREAD_LIBS)
1831
1832 dnl check for mt safe function variants and some posix functions
1833 dnl ************************************************************
1834
1835 if test x"$have_threads" != xno; then
1836         glib_save_LIBS="$LIBS"
1837         # we are not doing the following for now, as this might require glib
1838         # to always be linked with the thread libs on some platforms.
1839         # LIBS="$LIBS $G_THREAD_LIBS"
1840         AC_CHECK_FUNCS(localtime_r)
1841         if test "$ac_cv_header_pwd_h" = "yes"; then
1842                 AC_CACHE_CHECK([for posix getpwuid_r],
1843                         ac_cv_func_posix_getpwuid_r,
1844                         [AC_TRY_RUN([
1845 #include <errno.h>
1846 #include <pwd.h>
1847 int main () {
1848     char buffer[10000];
1849     struct passwd pwd, *pwptr = &pwd;
1850     int error;
1851     errno = 0;
1852     error = getpwuid_r (0, &pwd, buffer,
1853                         sizeof (buffer), &pwptr);
1854    return (error < 0 && errno == ENOSYS)
1855            || error == ENOSYS;
1856 }                               ],
1857                                 [ac_cv_func_posix_getpwuid_r=yes],
1858                                 [ac_cv_func_posix_getpwuid_r=no])])
1859                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
1860                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
1861                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
1862                                 [Have POSIX function getpwuid_r])
1863                 else
1864                         AC_CACHE_CHECK([for nonposix getpwuid_r],
1865                                 ac_cv_func_nonposix_getpwuid_r,
1866                                 [AC_TRY_LINK([#include <pwd.h>],
1867                                         [char buffer[10000];
1868                                         struct passwd pwd;
1869                                         getpwuid_r (0, &pwd, buffer,
1870                                                         sizeof (buffer));],
1871                                         [ac_cv_func_nonposix_getpwuid_r=yes],
1872                                         [ac_cv_func_nonposix_getpwuid_r=no])])
1873                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
1874                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
1875                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
1876                                         [Have non-POSIX function getpwuid_r])
1877                         fi
1878                 fi
1879         fi
1880         LIBS="$G_THREAD_LIBS $LIBS"
1881         if test x"$have_threads" = xposix; then
1882                 glib_save_CPPFLAGS="$CPPFLAGS"
1883                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1884                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
1885                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
1886                 # This is not AC_CHECK_FUNC to also work with function
1887                 # name mangling in header files.
1888                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1889                 AC_TRY_LINK([#include <pthread.h>],
1890                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1891                         [AC_MSG_RESULT(yes)
1892                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1893                                   [Have function pthread_attr_setstacksize])],
1894                         [AC_MSG_RESULT(no)])
1895                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1896                 if test x"$posix_priority_min" = x; then
1897                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1898                                 PX_PRIO_MIN],,[
1899                                 posix_priority_min=PX_PRIO_MIN
1900                                 posix_priority_max=PX_PRIO_MAX])
1901                 fi
1902                 if test x"$posix_priority_min" = x; then
1903                         # AIX
1904                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
1905                                 PTHREAD_PRIO_MIN],,[
1906                                 posix_priority_min=PTHREAD_PRIO_MIN
1907                                 posix_priority_max=PTHREAD_PRIO_MAX])
1908                 fi
1909                 if test x"$posix_priority_min" = x; then
1910                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1911                                 PRI_OTHER_MIN],,[
1912                                 posix_priority_min=PRI_OTHER_MIN
1913                                 posix_priority_max=PRI_OTHER_MAX])
1914                 fi
1915                 if test x"$posix_priority_min" = x; then
1916                         AC_MSG_RESULT(none found)
1917                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1918                         posix_priority_min=-1
1919                         posix_priority_max=-1
1920                 else
1921                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1922                         AC_MSG_CHECKING(for pthread_setschedparam)
1923                         AC_TRY_LINK([#include <pthread.h>],
1924                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
1925                           [AC_MSG_RESULT(yes)
1926                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1927                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
1928                           [AC_MSG_RESULT(no)
1929                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
1930                 fi
1931                 posix_yield_func=none
1932                 AC_MSG_CHECKING(for posix yield function)
1933                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1934                                                         thr_yield; do
1935                         AC_TRY_LINK([#include <pthread.h>],
1936                                 [$yield_func()],
1937                                 [posix_yield_func="$yield_func"
1938                                 break])
1939                 done
1940                 if test x"$posix_yield_func" = xnone; then
1941                         AC_MSG_RESULT(none found)
1942                         AC_MSG_WARN($POSIX_NO_YIELD)
1943                         posix_yield_func="g_usleep(1000)"
1944                 else
1945                         AC_MSG_RESULT($posix_yield_func)
1946                         posix_yield_func="$posix_yield_func()"
1947                 fi
1948                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1949                 CPPFLAGS="$glib_save_CPPFLAGS"
1950
1951         elif test x"$have_threads" = xwin32; then
1952                 # It's a pointer to a private struct
1953                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
1954         fi
1955
1956         LIBS="$glib_save_LIBS"
1957
1958         # now spit out all the warnings.
1959         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1960            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1961                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1962         fi
1963         if test "$ac_cv_func_localtime_r" != "yes"; then
1964                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1965         fi
1966 fi
1967
1968 if test x"$glib_cv_sizeof_system_thread" = x; then
1969    # use a pointer as a fallback.
1970    GLIB_SIZEOF(,void *, system_thread)
1971 fi
1972
1973 #
1974 # Hack to deal with:
1975 #
1976 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
1977 #     building shared libraries with linux.
1978 #
1979 case $host in
1980   *-*-linux*)
1981     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
1982     ;;
1983   *)
1984     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
1985     ;;
1986 esac
1987
1988 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1989                    [Source file containing theread implementation])
1990 AC_SUBST(G_THREAD_CFLAGS)
1991 AC_SUBST(G_THREAD_LIBS)
1992 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
1993 AC_SUBST(G_THREAD_LIBS_EXTRA)
1994
1995 dnl **********************************************
1996 dnl *** GDefaultMutex setup and initialization ***
1997 dnl **********************************************
1998 dnl
1999 dnl if mutex_has_default = yes, we also got
2000 dnl mutex_default_type, mutex_default_init and mutex_header_file
2001 if test $mutex_has_default = yes ; then
2002         glib_save_CPPFLAGS="$CPPFLAGS"
2003         glib_save_LIBS="$LIBS"
2004         LIBS="$G_THREAD_LIBS $LIBS"
2005         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2006         GLIB_SIZEOF([#include <$mutex_header_file>],
2007                     $mutex_default_type,
2008                     gmutex)
2009         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
2010                            $mutex_default_type,
2011                            gmutex,
2012                            $glib_cv_sizeof_gmutex,
2013                            $mutex_default_init)
2014         if test x"$glib_cv_byte_contents_gmutex" = xno; then
2015                 mutex_has_default=no
2016         fi
2017         CPPFLAGS="$glib_save_CPPFLAGS"
2018         LIBS="$glib_save_LIBS"
2019 fi
2020
2021 dnl ********************************
2022 dnl *** g_atomic_* tests for gcc ***
2023 dnl ********************************
2024
2025 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
2026
2027 if test x"$GCC" = xyes; then
2028   case $host_cpu in
2029     i386)
2030       AC_MSG_RESULT([none])
2031       glib_memory_barrier_needed=no
2032       ;;
2033     i?86)
2034       AC_MSG_RESULT([i486])
2035       AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
2036                          [i486 atomic implementation])
2037       glib_memory_barrier_needed=no
2038       ;;
2039     sparc*)
2040       SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
2041                 when you are using a sparc with v9 instruction set (most
2042                 sparcs nowadays). This will make the code for atomic
2043                 operations much faster. The resulting code will not run
2044                 on very old sparcs though."
2045
2046       AC_LINK_IFELSE([[
2047         main ()
2048         {
2049           int tmp1, tmp2, tmp3;
2050           __asm__ __volatile__("casx [%2], %0, %1"
2051                                : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
2052         }]],
2053         AC_MSG_RESULT([sparcv9])
2054         AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
2055                            [sparcv9 atomic implementation]),
2056         AC_MSG_RESULT([no])
2057         AC_MSG_WARN([[$SPARCV9_WARNING]]))
2058       glib_memory_barrier_needed=yes
2059       ;;
2060     alpha*)
2061       AC_MSG_RESULT([alpha])
2062       AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
2063                          [alpha atomic implementation])
2064       glib_memory_barrier_needed=yes
2065       ;;
2066     x86_64)
2067       AC_MSG_RESULT([x86_64])
2068       AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
2069                          [x86_64 atomic implementation])
2070       glib_memory_barrier_needed=no
2071      ;;
2072     powerpc*)
2073       AC_MSG_RESULT([powerpc])
2074       AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
2075                          [powerpc atomic implementation])
2076       glib_memory_barrier_needed=yes
2077       ;;
2078     ia64)
2079       AC_MSG_RESULT([ia64])
2080       AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
2081                          [ia64 atomic implementation])
2082       glib_memory_barrier_needed=yes
2083       ;;
2084     s390|s390x)
2085       AC_MSG_RESULT([s390])
2086       AC_DEFINE_UNQUOTED(G_ATOMIC_S390, 1,
2087                          [s390 atomic implementation])
2088       glib_memory_barrier_needed=no
2089       ;;
2090     *)
2091       AC_MSG_RESULT([none])
2092       glib_memory_barrier_needed=yes
2093       ;;
2094   esac
2095 fi
2096
2097 dnl ****************************************
2098 dnl *** GLib POLL* compatibility defines ***
2099 dnl ****************************************
2100
2101 glib_poll_includes=["
2102 #include <sys/types.h>
2103 #include <sys/poll.h>
2104 "]
2105
2106 if test $ac_cv_header_sys_types_h = yes &&
2107    test $ac_cv_header_sys_poll_h = yes ; then
2108   glib_failed=false
2109   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2110   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2111   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2112   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2113   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2114   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2115   if $glib_failed ; then
2116     AC_MSG_ERROR([Could not determine values for POLL* constants])
2117   fi
2118 else
2119   glib_cv_value_POLLIN=1
2120   glib_cv_value_POLLOUT=4
2121   glib_cv_value_POLLPRI=2
2122   glib_cv_value_POLLERR=8
2123   glib_cv_value_POLLHUP=16
2124   glib_cv_value_POLLNVAL=32
2125 fi
2126
2127 # Check for Mac OS X's broken poll
2128 if test $cross_compiling != yes ; then
2129   AC_MSG_CHECKING(for broken poll)
2130   AC_TRY_RUN([[
2131         #include <stdlib.h>
2132         #include <fcntl.h>
2133         #include <poll.h>
2134         int main(void) {
2135           struct pollfd fds[1];
2136           int fd;
2137           fd = open("/dev/null", 1);
2138           fds[0].fd = fd;
2139           fds[0].events = POLLIN;
2140           fds[0].revents = 0;
2141           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2142                 exit(1);  /* Does not work for devices -- fail */
2143           }
2144           exit(0);
2145         }]],
2146     broken_poll=no,
2147     broken_poll=yes
2148     AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])
2149   )
2150   AC_MSG_RESULT($broken_poll)
2151 fi
2152
2153 dnl **********************
2154 dnl *** Win32 API libs ***
2155 dnl **********************
2156
2157 case $host in
2158   *-*-cygwin*)
2159         G_LIBS_EXTRA="-luser32 -lkernel32"
2160     ;;
2161   *-*-mingw*)
2162         G_LIBS_EXTRA="-lws2_32 -lole32"
2163     ;;
2164   *)
2165         G_LIBS_EXTRA=""
2166     ;;
2167 esac
2168 AC_SUBST(G_LIBS_EXTRA)
2169
2170 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2171 dnl since we need it for g_iconv()
2172
2173 AC_MSG_CHECKING([for EILSEQ])
2174 AC_TRY_COMPILE([
2175 #include <errno.h>
2176 ],
2177 [
2178 int error = EILSEQ;
2179 ], have_eilseq=yes, have_eilseq=no);
2180 AC_MSG_RESULT($have_eilseq)
2181
2182 dnl ******************************************************************
2183 dnl *** Look for glib-genmarshal in PATH if we are cross-compiling ***
2184 dnl ******************************************************************
2185
2186 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2187
2188 if test $cross_compiling = yes; then
2189   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2190   if test x$GLIB_GENMARSHAL = xno; then
2191     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2192   fi
2193 fi
2194
2195 dnl **************************
2196 dnl *** Checks for gtk-doc ***
2197 dnl **************************
2198
2199 GTK_DOC_CHECK([1.4])
2200
2201 AC_ARG_ENABLE(man,
2202               [AC_HELP_STRING([--enable-man],
2203                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2204               enable_man=no)
2205
2206 if test "${enable_man}" != no; then
2207 dnl
2208 dnl Check for xsltproc
2209 dnl
2210 AC_PATH_PROG([XSLTPROC], [xsltproc])
2211   if test -z "$XSLTPROC"; then
2212     enable_man=no
2213   fi
2214
2215   dnl check for DocBook DTD and stylesheets in the local catalog.
2216   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2217      [DocBook XML DTD V4.1.2],,enable_man=no)
2218   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2219      [DocBook XSL Stylesheets],,enable_man=no)
2220 fi
2221
2222 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2223
2224 dnl ******************************
2225 dnl *** output the whole stuff ***
2226 dnl ******************************
2227
2228 dnl this section will only be run if config.status is invoked with no
2229 dnl arguments, or with "glibconfig.h" as an argument.
2230 AC_CONFIG_COMMANDS([glibconfig.h],
2231 [
2232         outfile=glibconfig.h-tmp
2233         cat > $outfile <<\_______EOF
2234 /* glibconfig.h
2235  *
2236  * This is a generated file.  Please modify 'configure.in'
2237  */
2238
2239 #ifndef __G_LIBCONFIG_H__
2240 #define __G_LIBCONFIG_H__
2241
2242 #include <glib/gmacros.h>
2243
2244 _______EOF
2245
2246         if test x$glib_limits_h = xyes; then
2247           echo '#include <limits.h>' >> $outfile
2248         fi
2249         if test x$glib_float_h = xyes; then
2250           echo '#include <float.h>' >> $outfile
2251         fi
2252         if test x$glib_values_h = xyes; then
2253           echo '#include <values.h>' >> $outfile
2254         fi
2255         if test "$glib_header_alloca_h" = "yes"; then
2256           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2257         fi
2258         if test x$glib_sys_poll_h = xyes; then
2259           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2260         fi
2261
2262         cat >> $outfile <<_______EOF
2263
2264 G_BEGIN_DECLS
2265
2266 #define G_MINFLOAT      $glib_mf
2267 #define G_MAXFLOAT      $glib_Mf
2268 #define G_MINDOUBLE     $glib_md
2269 #define G_MAXDOUBLE     $glib_Md
2270 #define G_MINSHORT      $glib_ms
2271 #define G_MAXSHORT      $glib_Ms
2272 #define G_MAXUSHORT     $glib_Mus
2273 #define G_MININT        $glib_mi
2274 #define G_MAXINT        $glib_Mi
2275 #define G_MAXUINT       $glib_Mui
2276 #define G_MINLONG       $glib_ml
2277 #define G_MAXLONG       $glib_Ml
2278 #define G_MAXULONG      $glib_Mul
2279
2280 _______EOF
2281
2282
2283         ### this should always be true in a modern C/C++ compiler
2284         cat >>$outfile <<_______EOF
2285 typedef signed char gint8;
2286 typedef unsigned char guint8;
2287 _______EOF
2288
2289
2290         if test -n "$gint16"; then
2291           cat >>$outfile <<_______EOF
2292 typedef signed $gint16 gint16;
2293 typedef unsigned $gint16 guint16;
2294 #define G_GINT16_MODIFIER $gint16_modifier
2295 #define G_GINT16_FORMAT $gint16_format
2296 #define G_GUINT16_FORMAT $guint16_format
2297 _______EOF
2298         fi
2299
2300
2301         if test -n "$gint32"; then
2302           cat >>$outfile <<_______EOF
2303 typedef signed $gint32 gint32;
2304 typedef unsigned $gint32 guint32;
2305 #define G_GINT32_MODIFIER $gint32_modifier
2306 #define G_GINT32_FORMAT $gint32_format
2307 #define G_GUINT32_FORMAT $guint32_format
2308 _______EOF
2309         fi
2310
2311         cat >>$outfile <<_______EOF
2312 #define G_HAVE_GINT64 1          /* deprecated, always true */
2313
2314 ${glib_extension}typedef signed $gint64 gint64;
2315 ${glib_extension}typedef unsigned $gint64 guint64;
2316
2317 #define G_GINT64_CONSTANT(val)  $gint64_constant
2318 #define G_GUINT64_CONSTANT(val) $guint64_constant
2319 _______EOF
2320
2321         if test x$gint64_format != x ; then
2322           cat >>$outfile <<_______EOF
2323 #define G_GINT64_MODIFIER $gint64_modifier
2324 #define G_GINT64_FORMAT $gint64_format
2325 #define G_GUINT64_FORMAT $guint64_format
2326 _______EOF
2327         else
2328           cat >>$outfile <<_______EOF
2329 #undef G_GINT64_MODIFIER
2330 #undef G_GINT64_FORMAT
2331 #undef G_GUINT64_FORMAT
2332 _______EOF
2333         fi
2334
2335         cat >>$outfile <<_______EOF
2336
2337 #define GLIB_SIZEOF_VOID_P $glib_void_p
2338 #define GLIB_SIZEOF_LONG   $glib_long
2339 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2340
2341 _______EOF
2342
2343         cat >>$outfile <<_______EOF
2344 typedef signed $glib_size_type_define gssize;
2345 typedef unsigned $glib_size_type_define gsize;
2346 #define G_GSIZE_MODIFIER $gsize_modifier
2347 #define G_GSSIZE_FORMAT $gssize_format
2348 #define G_GSIZE_FORMAT $gsize_format
2349
2350 #define G_MAXSIZE       G_MAXU$glib_msize_type
2351 _______EOF
2352
2353         if test -z "$glib_unknown_void_p"; then
2354           cat >>$outfile <<_______EOF
2355
2356 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2357 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2358
2359 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2360 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2361 _______EOF
2362         else
2363           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2364         fi
2365
2366
2367
2368         cat >>$outfile <<_______EOF
2369 $glib_atexit
2370 $glib_memmove
2371 $glib_defines
2372 $glib_os
2373
2374 $glib_vacopy
2375
2376 #ifdef  __cplusplus
2377 #define G_HAVE_INLINE   1
2378 #else   /* !__cplusplus */
2379 $glib_inline
2380 #endif  /* !__cplusplus */
2381
2382 #ifdef  __cplusplus
2383 #define G_CAN_INLINE    1
2384 _______EOF
2385
2386         if test x$g_can_inline = xyes ; then
2387                 cat >>$outfile <<_______EOF
2388 #else   /* !__cplusplus */
2389 #define G_CAN_INLINE    1
2390 _______EOF
2391         fi
2392
2393         cat >>$outfile <<_______EOF
2394 #endif
2395
2396 _______EOF
2397
2398         if test x$g_have_iso_c_varargs = xyes ; then
2399                 cat >>$outfile <<_______EOF
2400 #ifndef __cplusplus
2401 # define G_HAVE_ISO_VARARGS 1
2402 #endif
2403 _______EOF
2404         fi
2405         if test x$g_have_iso_cxx_varargs = xyes ; then
2406                 cat >>$outfile <<_______EOF
2407 #ifdef __cplusplus
2408 # define G_HAVE_ISO_VARARGS 1
2409 #endif
2410 _______EOF
2411         fi
2412         if test x$g_have_gnuc_varargs = xyes ; then
2413                 cat >>$outfile <<_______EOF
2414
2415 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2416  * is passed ISO vararg support is turned off, and there is no work
2417  * around to turn it on, so we unconditionally turn it off.
2418  */
2419 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2420 #  undef G_HAVE_ISO_VARARGS
2421 #endif
2422
2423 #define G_HAVE_GNUC_VARARGS 1
2424 _______EOF
2425         fi
2426
2427         case x$g_stack_grows in
2428         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2429         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2430         esac
2431
2432
2433         echo >>$outfile
2434         if test x$g_have_eilseq = xno; then
2435                 cat >>$outfile <<_______EOF
2436 #ifndef EILSEQ
2437 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2438  * The correspondence between this and the corresponding definition
2439  * in libiconv is essential.
2440  */
2441 #  define EILSEQ ENOENT
2442 #endif
2443 _______EOF
2444
2445         fi
2446
2447         if test x$g_have_gnuc_visibility = xyes ; then
2448                 cat >>$outfile <<_______EOF
2449 #define G_HAVE_GNUC_VISIBILITY 1
2450 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2451 _______EOF
2452         else
2453                 cat >>$outfile <<_______EOF
2454 #define G_GNUC_INTERNAL
2455 _______EOF
2456         fi
2457
2458
2459         echo >>$outfile
2460         if test x$g_mutex_has_default = xyes; then
2461                 cat >>$outfile <<_______EOF
2462 $g_enable_threads_def G_THREADS_ENABLED
2463 #define G_THREADS_IMPL_$g_threads_impl_def
2464 typedef struct _GStaticMutex GStaticMutex;
2465 struct _GStaticMutex
2466 {
2467   struct _GMutex *runtime_mutex;
2468   union {
2469     char   pad[[$g_mutex_sizeof]];
2470     double dummy_double;
2471     void  *dummy_pointer;
2472     long   dummy_long;
2473   } static_mutex;
2474 };
2475 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
2476 #define g_static_mutex_get_mutex(mutex) \\
2477   (g_thread_use_default_impl ? ((GMutex*) ((mutex)->static_mutex.pad)) : \\
2478    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
2479 _______EOF
2480         else
2481                 cat >>$outfile <<_______EOF
2482 $g_enable_threads_def G_THREADS_ENABLED
2483 #define G_THREADS_IMPL_$g_threads_impl_def
2484 typedef struct _GMutex* GStaticMutex;
2485 #define G_STATIC_MUTEX_INIT NULL
2486 #define g_static_mutex_get_mutex(mutex) \\
2487   (g_static_mutex_get_mutex_impl_shortcut (mutex))
2488 _______EOF
2489         fi
2490
2491         cat >>$outfile <<_______EOF
2492 /* This represents a system thread as used by the implementation. An
2493  * alien implementaion, as loaded by g_thread_init can only count on
2494  * "sizeof (gpointer)" bytes to store their info. We however need more
2495  * for some of our native implementations. */
2496 typedef union _GSystemThread GSystemThread;
2497 union _GSystemThread
2498 {
2499   char   data[[$g_system_thread_sizeof]];
2500   double dummy_double;
2501   void  *dummy_pointer;
2502   long   dummy_long;
2503 };
2504 _______EOF
2505         if test x"$g_memory_barrier_needed" != xno; then
2506           echo >>$outfile
2507           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2508         fi
2509
2510         echo >>$outfile
2511         g_bit_sizes="16 32 64"
2512         for bits in $g_bit_sizes; do
2513           cat >>$outfile <<_______EOF
2514 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
2515 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
2516 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2517 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
2518 _______EOF
2519         done
2520
2521         cat >>$outfile <<_______EOF
2522 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
2523 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
2524 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
2525 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
2526 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
2527 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
2528 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
2529 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
2530 #define G_BYTE_ORDER $g_byte_order
2531
2532 #define GLIB_SYSDEF_POLLIN =$g_pollin
2533 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2534 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2535 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2536 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2537 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2538
2539 #define G_MODULE_SUFFIX "$g_module_suffix"
2540
2541 typedef $g_pid_type GPid;
2542
2543 G_END_DECLS
2544
2545 #endif /* GLIBCONFIG_H */
2546 _______EOF
2547
2548
2549         if cmp -s $outfile glibconfig.h; then
2550           AC_MSG_NOTICE([glibconfig.h is unchanged])
2551           rm -f $outfile
2552         else
2553           mv $outfile glibconfig.h
2554         fi
2555 ],[
2556
2557 # Note that if two cases are the same, case goes with the first one.
2558 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
2559 # on variable expansion in case labels.  Look at the generated config.status
2560 # for a hint.
2561
2562 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2563   glib_header_alloca_h="$ac_cv_working_alloca_h"
2564 else
2565   glib_header_alloca_h="$ac_cv_header_alloca_h"
2566 fi
2567
2568 case xyes in
2569 x$ac_cv_header_float_h)
2570   glib_float_h=yes
2571   glib_mf=FLT_MIN glib_Mf=FLT_MAX
2572   glib_md=DBL_MIN glib_Md=DBL_MAX
2573   ;;
2574 x$ac_cv_header_values_h)
2575   glib_values_h=yes
2576   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
2577   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
2578   ;;
2579 esac
2580
2581 case xyes in
2582 x$ac_cv_header_limits_h)
2583   glib_limits_h=yes
2584   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
2585   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
2586   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
2587   ;;
2588 x$ac_cv_header_values_h)
2589   glib_values_h=yes
2590   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
2591   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
2592   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
2593   ;;
2594 esac
2595
2596 if test x$ac_cv_header_sys_poll_h = xyes ; then
2597   glib_sys_poll_h=yes
2598 fi
2599
2600 case 2 in
2601 $ac_cv_sizeof_short)
2602   gint16=short
2603   gint16_modifier='"h"'
2604   gint16_format='"hi"'
2605   guint16_format='"hu"'
2606   ;;
2607 $ac_cv_sizeof_int)
2608   gint16=int
2609   gint16_modifier='""'
2610   gint16_format='"i"'
2611   guint16_format='"u"'
2612   ;;
2613 esac
2614 case 4 in
2615 $ac_cv_sizeof_short)
2616   gint32=short
2617   gint32_modifier='"h"'
2618   gint32_format='"hi"'
2619   guint32_format='"hu"'
2620   ;;
2621 $ac_cv_sizeof_int)
2622   gint32=int
2623   gint32_modifier='""'
2624   gint32_format='"i"'
2625   guint32_format='"u"'
2626   ;;
2627 $ac_cv_sizeof_long)
2628   gint32=long
2629   gint32_modifier='"l"'
2630   gint32_format='"li"'
2631   guint32_format='"lu"'
2632   ;;
2633 esac
2634 case 8 in
2635 $ac_cv_sizeof_int)
2636   gint64=int
2637   gint64_modifier='""'
2638   gint64_format='"i"'
2639   guint64_format='"u"'
2640   glib_extension=
2641   gint64_constant='(val)'
2642   guint64_constant='(val)'
2643   ;;
2644 $ac_cv_sizeof_long)
2645   gint64=long
2646   gint64_modifier='"l"'
2647   gint64_format='"li"'
2648   guint64_format='"lu"'
2649   glib_extension=
2650   gint64_constant='(val##L)'
2651   guint64_constant='(val##UL)'
2652   ;;
2653 $ac_cv_sizeof_long_long)
2654   gint64='long long'
2655   if test -n "$glib_cv_long_long_format"; then
2656     gint64_modifier='"'$glib_cv_long_long_format'"'
2657     gint64_format='"'$glib_cv_long_long_format'i"'
2658     guint64_format='"'$glib_cv_long_long_format'u"'
2659   fi
2660   glib_extension='G_GNUC_EXTENSION '
2661   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
2662   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
2663   ;;
2664 $ac_cv_sizeof___int64)
2665   gint64='__int64'
2666   if test -n "$glib_cv_long_long_format"; then
2667     gint64_modifier='"'$glib_cv_long_long_format'"'
2668     gint64_format='"'$glib_cv_long_long_format'i"'
2669     guint64_format='"'$glib_cv_long_long_format'u"'
2670   fi
2671   glib_extension=
2672   gint64_constant='(val##i64)'
2673   guint64_constant='(val##ui64)'
2674   ;;
2675 esac
2676 glib_size_t=$ac_cv_sizeof_size_t
2677 glib_size_type_define=$glib_size_type
2678 glib_void_p=$ac_cv_sizeof_long
2679 glib_long=$ac_cv_sizeof_void_p
2680
2681 case $glib_size_type in
2682 short)
2683   gsize_modifier='"h"'
2684   gsize_format='"hu"'
2685   gssize_format='"hi"'
2686   glib_msize_type='SHRT'
2687   ;;
2688 int)
2689   gsize_modifier='""'
2690   gsize_format='"u"'
2691   gssize_format='"i"'
2692   glib_msize_type='INT'
2693   ;;
2694 long)
2695   gsize_modifier='"l"'
2696   gsize_format='"lu"'
2697   gssize_format='"li"'
2698   glib_msize_type='LONG'
2699   ;;
2700 esac
2701
2702 gintbits=`expr $ac_cv_sizeof_int \* 8`
2703 glongbits=`expr $ac_cv_sizeof_long \* 8`
2704
2705
2706 case $ac_cv_sizeof_void_p in
2707 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
2708 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
2709 *)                      glib_unknown_void_p=yes ;;
2710 esac
2711
2712
2713 case xyes in
2714 x$ac_cv_func_atexit)
2715   glib_atexit="
2716 #ifdef NeXT /* @#%@! NeXTStep */
2717 # define g_ATEXIT(proc) (!atexit (proc))
2718 #else
2719 # define g_ATEXIT(proc) (atexit (proc))
2720 #endif"
2721   ;;
2722 x$ac_cv_func_on_exit)
2723   glib_atexit="
2724 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
2725   ;;
2726 esac
2727
2728 case xyes in
2729 x$ac_cv_func_memmove)
2730   glib_memmove='
2731 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
2732   ;;
2733 x$glib_cv_working_bcopy)
2734   glib_memmove="
2735 /* memmove isn't available, but bcopy can copy overlapping memory regions */
2736 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
2737   ;;
2738 *)
2739   glib_memmove="
2740 /* memmove isn't found and bcopy can't copy overlapping memory regions,
2741  * so we have to roll our own copy routine. */
2742 void g_memmove (void* dest, const void * src, unsigned long len);"
2743   ;;
2744 esac
2745
2746 glib_defines="
2747 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
2748 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
2749 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
2750 "
2751
2752 case xyes in
2753 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
2754 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
2755 *)                      glib_vacopy=''
2756 esac
2757
2758 if test x$glib_cv_va_val_copy = xno; then
2759   glib_vacopy="\$glib_vacopy
2760 #define G_VA_COPY_AS_ARRAY 1"
2761 fi
2762
2763 if test x$glib_cv_hasinline = xyes; then
2764     glib_inline='#define G_HAVE_INLINE 1'
2765 fi
2766 if test x$glib_cv_has__inline = xyes; then
2767     glib_inline="\$glib_inline
2768 #define G_HAVE___INLINE 1"
2769 fi
2770 if test x$glib_cv_has__inline__ = xyes; then
2771     glib_inline="\$glib_inline
2772 #define G_HAVE___INLINE__ 1"
2773 fi
2774
2775 g_have_gnuc_varargs=$g_have_gnuc_varargs
2776 g_have_iso_c_varargs=$g_have_iso_c_varargs
2777 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
2778
2779 g_can_inline=$g_can_inline
2780 g_have_gnuc_visibility=$g_have_gnuc_visibility
2781
2782 case xyes in
2783 x$ac_cv_c_bigendian)
2784   g_byte_order=G_BIG_ENDIAN
2785   g_bs_native=BE
2786   g_bs_alien=LE
2787   ;;
2788 *)
2789   g_byte_order=G_LITTLE_ENDIAN
2790   g_bs_native=LE
2791   g_bs_alien=BE
2792   ;;
2793 esac
2794
2795 g_pollin=$glib_cv_value_POLLIN
2796 g_pollout=$glib_cv_value_POLLOUT
2797 g_pollpri=$glib_cv_value_POLLPRI
2798 g_pollhup=$glib_cv_value_POLLHUP
2799 g_pollerr=$glib_cv_value_POLLERR
2800 g_pollnval=$glib_cv_value_POLLNVAL
2801
2802 g_stack_grows=$glib_cv_stack_grows
2803
2804 g_have_eilseq=$have_eilseq
2805
2806 case x$have_threads in
2807 xno)    g_enable_threads_def="#undef";;
2808 *)      g_enable_threads_def="#define";;
2809 esac
2810
2811 g_threads_impl_def=$g_threads_impl
2812
2813 g_mutex_has_default="$mutex_has_default"
2814 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
2815 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
2816 g_mutex_contents="$glib_cv_byte_contents_gmutex"
2817
2818 g_memory_barrier_needed="$glib_memory_barrier_needed"
2819
2820 g_module_suffix="$glib_gmodule_suffix"
2821
2822 g_pid_type="$glib_pid_type"
2823 case $host in
2824   *-*-beos*)
2825     glib_os="#define G_OS_BEOS"
2826     ;;
2827   *-*-cygwin*)
2828     glib_os="#define G_OS_UNIX
2829 #define G_PLATFORM_WIN32
2830 #define G_WITH_CYGWIN"
2831     ;;
2832   *-*-mingw*)
2833     glib_os="#define G_OS_WIN32
2834 #define G_PLATFORM_WIN32"
2835     ;;
2836   *)
2837     glib_os="#define G_OS_UNIX"
2838     ;;
2839 esac
2840 ])
2841
2842 AC_CONFIG_FILES([
2843 glib-2.0.pc
2844 glib-2.0-uninstalled.pc
2845 gmodule-2.0.pc
2846 gmodule-export-2.0.pc
2847 gmodule-no-export-2.0.pc
2848 gmodule-2.0-uninstalled.pc
2849 gmodule-no-export-2.0-uninstalled.pc
2850 gthread-2.0.pc
2851 gthread-2.0-uninstalled.pc
2852 gobject-2.0.pc
2853 gobject-2.0-uninstalled.pc
2854 glib-zip
2855 glib-gettextize
2856 Makefile
2857 build/Makefile
2858 build/win32/Makefile
2859 build/win32/dirent/Makefile
2860 build/win32/vs8/Makefile
2861 glib/Makefile
2862 glib/libcharset/Makefile
2863 glib/gnulib/Makefile
2864 gmodule/Makefile
2865 gmodule/gmoduleconf.h
2866 gobject/Makefile
2867 gobject/glib-mkenums
2868 gthread/Makefile
2869 po/Makefile.in
2870 docs/Makefile
2871 docs/reference/Makefile
2872 docs/reference/glib/Makefile
2873 docs/reference/glib/version.xml
2874 docs/reference/gobject/Makefile
2875 docs/reference/gobject/version.xml
2876 tests/Makefile
2877 tests/gobject/Makefile
2878 tests/refcount/Makefile
2879 m4macros/Makefile
2880 ])
2881
2882 AC_CONFIG_COMMANDS([chmod-scripts],
2883 [chmod 0755 glib-zip
2884 chmod 0755 glib-gettextize
2885 chmod 0755 gobject/glib-mkenums])
2886
2887 # we want to invoke this macro solely so that the config.status script
2888 # and automake generated makefiles know about these generated files.
2889 # They are only needed to distcheck the package
2890 if false; then
2891   AC_CONFIG_FILES([
2892     INSTALL
2893     README
2894     config.h.win32
2895     glibconfig.h.win32
2896     glib/makefile.msc
2897     glib/glib.rc
2898     gmodule/makefile.msc
2899     gmodule/gmodule.rc
2900     gobject/makefile.msc
2901     gobject/gobject.rc
2902     gthread/makefile.msc
2903     gthread/gthread.rc
2904     tests/makefile.msc
2905   ])
2906 fi
2907
2908 AC_OUTPUT