configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 dnl ***********************************
   6 dnl *** include special GLib macros ***
   7 dnl ***********************************
   8
   9 m4_define(glib_configure_in)
  10 m4_include(acglib.m4)dnl
  11 m4_include(glib/libcharset/codeset.m4)dnl
  12 m4_include(glib/libcharset/glibc21.m4)dnl
  13 m4_include(m4macros/glib-gettext.m4)dnl
  14
  15 #
  16 # The following version number definitions apply to GLib, GModule, GObject
  17 # and GThread as a whole, so if changes occoured in any of them, they are all
  18 # treated with the same interface and binary age.
  19 #
  20 # Making releases:
  21 #   glib_micro_version += 1;
  22 #   glib_interface_age += 1;
  23 #   glib_binary_age += 1;
  24 # if any functions have been added, set glib_interface_age to 0.
  25 # if backwards compatibility has been broken,
  26 # set glib_binary_age _and_ glib_interface_age to 0.
  27 #
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [7])
  30 m4_define([glib_micro_version], [2])
  31 m4_define([glib_interface_age], [1])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_SRCDIR([glib/glib.h])
  56
  57 # Save this value here, since automake will set cflags later
  58 cflags_set=${CFLAGS+set}
  59
  60 AM_INIT_AUTOMAKE([no-define])
  61
  62 # Specify a configuration file
  63 AM_CONFIG_HEADER([config.h])
  64
  65
  66 GLIB_MAJOR_VERSION=glib_major_version
  67 GLIB_MINOR_VERSION=glib_minor_version
  68 GLIB_MICRO_VERSION=glib_micro_version
  69 GLIB_INTERFACE_AGE=glib_interface_age
  70 GLIB_BINARY_AGE=glib_binary_age
  71 GLIB_VERSION=glib_version
  72
  73 AC_SUBST(GLIB_MAJOR_VERSION)
  74 AC_SUBST(GLIB_MINOR_VERSION)
  75 AC_SUBST(GLIB_MICRO_VERSION)
  76 AC_SUBST(GLIB_VERSION)
  77 AC_SUBST(GLIB_INTERFACE_AGE)
  78 AC_SUBST(GLIB_BINARY_AGE)
  79
  80 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  81           [Define to the GLIB major version])
  82 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  83           [Define to the GLIB minor version])
  84 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  85           [Define to the GLIB micro version])
  86 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  87           [Define to the GLIB interface age])
  88 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  89           [Define to the GLIB binary age])
  90
  91 # libtool versioning
  92 LT_RELEASE=glib_lt_release
  93 LT_CURRENT=glib_lt_current
  94 LT_REVISION=glib_lt_revision
  95 LT_AGE=glib_lt_age
  96 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
  97 AC_SUBST(LT_RELEASE)
  98 AC_SUBST(LT_CURRENT)
  99 AC_SUBST(LT_REVISION)
 100 AC_SUBST(LT_AGE)
 101 AC_SUBST(LT_CURRENT_MINUS_AGE)
 102
 103 dnl Initialize maintainer mode
 104 AM_MAINTAINER_MODE
 105
 106 AC_CANONICAL_HOST
 107
 108 AC_MSG_CHECKING([for the BeOS])
 109 case $host in
 110   *-*-beos*)
 111     glib_native_beos="yes"
 112     ;;
 113   *)
 114     glib_native_beos="no"
 115     ;;
 116 esac
 117 AC_MSG_RESULT([$glib_native_beos])
 118
 119 dnl
 120
 121 AC_MSG_CHECKING([for Win32])
 122 case "$host" in
 123   *-*-mingw*)
 124     glib_native_win32=yes
 125     G_LIB_WIN32_RESOURCE=glib-win32res.lo
 126     G_MODULE_WIN32_RESOURCE=gmodule-win32res.lo
 127     G_OBJECT_WIN32_RESOURCE=gobject-win32res.lo
 128     G_THREAD_WIN32_RESOURCE=gthread-win32res.lo
 129     GLIB_DEF=glib.def
 130     GMODULE_DEF=gmodule.def
 131     GOBJECT_DEF=gobject.def
 132     GTHREAD_DEF=gthread.def
 133     TESTGMODULE_EXP=testgmodule.exp
 134     glib_pid_type='void *'
 135     ;;
 136   *)
 137     glib_native_win32=no
 138     G_LIB_WIN32_RESOURCE=
 139     G_MODULE_WIN32_RESOURCE=
 140     G_OBJECT_WIN32_RESOURCE=
 141     G_THREAD_WIN32_RESOURCE=
 142     GLIB_DEF=
 143     GMODULE_DEF=
 144     GOBJECT_DEF=
 145     GTHREAD_DEF=
 146     TESTGMODULE_EXP=
 147     glib_pid_type=int
 148     ;;
 149 esac
 150 case $host in
 151   *-*-linux*)
 152     glib_os_linux=yes
 153     ;;
 154 esac
 155
 156
 157 AC_MSG_RESULT([$glib_native_win32])
 158 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 159 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 160 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 161 AC_SUBST(G_LIB_WIN32_RESOURCE)
 162 AC_SUBST(G_MODULE_WIN32_RESOURCE)
 163 AC_SUBST(G_OBJECT_WIN32_RESOURCE)
 164 AC_SUBST(G_THREAD_WIN32_RESOURCE)
 165 AC_SUBST(GLIB_DEF)
 166 AC_SUBST(GMODULE_DEF)
 167 AC_SUBST(GOBJECT_DEF)
 168 AC_SUBST(GTHREAD_DEF)
 169 AC_SUBST(TESTGMODULE_EXP)
 170
 171 if test "$glib_native_win32" = "yes"; then
 172   AC_CHECK_TOOL(NM, nm, no)
 173   if test "$NM" = no; then
 174     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 175   fi
 176   AC_CHECK_TOOL(RANLIB, ranlib, :)
 177   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 178 fi
 179 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 180
 181 if test "$glib_native_win32" != yes; then
 182     # libtool option to control which symbols are exported
 183     # right now, symbols starting with _ are not exported
 184     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 185 else
 186     # We currently use .def files on Windows
 187     LIBTOOL_EXPORT_OPTIONS=
 188 fi
 189 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 190
 191 dnl declare --enable-* args and collect ac_help strings
 192 AC_ARG_ENABLE(debug,
 193               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 194                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 195               enable_debug=glib_debug_default)
 196
 197 AC_ARG_ENABLE(gc_friendly,
 198               [AC_HELP_STRING([--enable-gc-friendly],
 199                               [turn on garbage collector friendliness [default=no]])],,
 200               [enable_gc_friendly=no])
 201 AC_ARG_ENABLE(mem_pools,
 202               [AC_HELP_STRING([--disable-mem-pools],
 203                               [disable all glib memory pools])],,
 204               [disable_mem_pools=no])
 205 AC_ARG_ENABLE(threads,
 206               [AC_HELP_STRING([--enable-threads],
 207                               [turn on basic thread support [default=yes]
 208 ([=no] will override --with-threads)])],,
 209               [enable_threads=yes])
 210 AC_ARG_ENABLE(rebuilds,
 211               [AC_HELP_STRING([--disable-rebuilds],
 212                               [disable all source autogeneration rules])],,
 213               [enable_rebuilds=yes])
 214 AC_ARG_ENABLE(visibility,
 215               [AC_HELP_STRING([--disable-visibility],
 216                               [don't use ELF visibility attributes])],,
 217               [enable_visibility=yes])
 218
 219 if test "x$enable_threads" != "xyes"; then
 220   enable_threads=no
 221 fi
 222
 223 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, ["${enable_debug}"],
 224         [Whether glib was compiled with debugging enabled])
 225
 226 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 227 if test "x$enable_gc_friendly" = "xyes"; then
 228   AC_DEFINE(ENABLE_GC_FRIENDLY, 1, [Whether to enable GC friendliness])
 229   AC_SUBST(ENABLE_GC_FRIENDLY)
 230   AC_MSG_RESULT([yes])
 231 else
 232   AC_MSG_RESULT([no])
 233 fi
 234
 235 AC_MSG_CHECKING([whether to disable memory pools])
 236 if test "x$disable_mem_pools" = "xno"; then
 237   AC_MSG_RESULT([no])
 238 else
 239   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 240   AC_SUBST(DISABLE_MEM_POOLS)
 241   AC_MSG_RESULT([yes])
 242 fi
 243
 244 if test "$glib_native_win32" = "yes"; then
 245   if test x$enable_static = xyes -o x$enable_static = x; then
 246     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 247     enable_static=no
 248   fi
 249   if test x$enable_shared = xno; then
 250     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 251   fi
 252   enable_shared=yes
 253 fi
 254
 255 dnl Checks for programs.
 256 AC_PROG_CC
 257
 258 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 259 AC_CHECK_PROGS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 260 AC_LANG_SAVE
 261 AC_LANG_CPLUSPLUS
 262 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 263 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 264 AC_LANG_RESTORE
 265
 266 AM_PROG_CC_STDC
 267 AC_PROG_INSTALL
 268
 269 AC_SYS_LARGEFILE
 270
 271 #
 272 # Find pkg-config
 273 #
 274 AC_PATH_PROG(PKG_CONFIG, [pkg-config], [no])
 275 if test x$PKG_CONFIG = xno ; then
 276   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
 277 fi
 278
 279 if $PKG_CONFIG --atleast-pkgconfig-version 0.14 ; then
 280   :
 281 else
 282   AC_MSG_ERROR([*** pkg-config too old; version 0.14 or better required.])
 283 fi
 284
 285 if test "x$enable_debug" = "xyes"; then
 286   if test x$cflags_set != xset ; then
 287       case " $CFLAGS " in
 288       *[[\ \    ]]-g[[\ \       ]]*) ;;
 289       *) CFLAGS="$CFLAGS -g" ;;
 290       esac
 291   fi
 292
 293   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 294 else
 295   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 296
 297   if test "x$enable_debug" = "xno"; then
 298     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 299   fi
 300 fi
 301
 302 if test "x$enable_visibility" = "xno"; then
 303   GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DDISABLE_VISIBILITY"
 304 fi
 305
 306 # Ensure MSVC-compatible struct packing convention is used when
 307 # compiling for Win32 with gcc.
 308 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 309 # gcc2 uses "-fnative-struct".
 310 if test x"$glib_native_win32" = xyes; then
 311   if test x"$GCC" = xyes; then
 312     msnative_struct=''
 313     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 314     if test -z "$ac_cv_prog_CC"; then
 315       our_gcc="$CC"
 316     else
 317       our_gcc="$ac_cv_prog_CC"
 318     fi
 319     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 320       2.)
 321         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 322           msnative_struct='-fnative-struct'
 323         fi
 324         ;;
 325       *)
 326         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 327           msnative_struct='-mms-bitfields'
 328         fi
 329         ;;
 330     esac
 331     if test x"$msnative_struct" = x ; then
 332       AC_MSG_RESULT([no way])
 333       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 334     else
 335       CFLAGS="$CFLAGS $msnative_struct"
 336       AC_MSG_RESULT([${msnative_struct}])
 337     fi
 338   fi
 339 fi
 340
 341 AC_EXEEXT
 342
 343 # define a MAINT-like variable REBUILD which is set if Perl
 344 # and awk are found, so autogenerated sources can be rebuilt
 345 AC_PROG_AWK
 346 AC_CHECK_PROGS(PERL, [perl5 perl])
 347 # We would like indent, but don't require it.
 348 AC_CHECK_PROG(INDENT, indent, indent)
 349 REBUILD=\#
 350 if test "x$enable_rebuilds" = "xyes" && \
 351      test -n "$PERL" && \
 352      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 353      test -n "$AWK" ; then
 354   REBUILD=
 355 fi
 356 AC_SUBST(REBUILD)
 357
 358 # Need full path to Perl for glib-mkenums
 359 #
 360 if test "x$PERL" != x ; then
 361   AC_PATH_PROG(PERL_PATH, [$PERL])
 362 else
 363   PERL_PATH="/usr/bin/env perl"
 364 fi
 365 AC_SUBST(PERL_PATH)
 366
 367 dnl ***********************
 368 dnl *** Tests for iconv ***
 369 dnl ***********************
 370 dnl
 371 dnl We do this before the gettext checks, to avoid distortion
 372
 373 AC_ARG_WITH(libiconv,
 374             [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 375                             [use the libiconv library])],,
 376             [with_libiconv=maybe])
 377
 378 found_iconv=no
 379 case $with_libiconv in
 380   maybe)
 381     # Check in the C library first
 382     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 383     # Check if we have GNU libiconv
 384     if test $found_iconv = "no"; then
 385       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 386     fi
 387     # Check if we have a iconv in -liconv, possibly from vendor
 388     if test $found_iconv = "no"; then
 389       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 390     fi
 391     ;;
 392   no)
 393     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 394     ;;
 395   gnu|yes)
 396     AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 397     ;;
 398   native)
 399     AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 400     ;;
 401 esac
 402
 403 if test "x$found_iconv" = "xno" ; then
 404    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 405 fi
 406
 407 dnl
 408 dnl gettext support
 409 dnl
 410
 411 ALL_LINGUAS="am ar az be bg bn bs ca cs cy da de el en_CA en_GB eo es et eu fa fi fr ga gl gu he hi hr hu id is it ja ko lt lv mk mn ms nb ne nl nn no or pa pl pt pt_BR ro ru rw sk sl sq sr sr@ije sr@Latn sv ta th tl tr uk vi wa xh yi zh_CN zh_TW"
 412 GLIB_GNU_GETTEXT
 413
 414 if test "$gt_cv_have_gettext" != "yes" ; then
 415   AC_MSG_ERROR([
 416 *** You must have either have gettext support in your C library, or use the
 417 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 418 ])
 419 fi
 420
 421 LIBS="$INTLLIBS $LIBS"
 422
 423 GETTEXT_PACKAGE=glib20
 424 AC_SUBST(GETTEXT_PACKAGE)
 425 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 426   [Define the gettext package to be used])
 427
 428 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 429
 430 dnl
 431 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 432 dnl
 433
 434 if test x$with_libiconv != xno ; then
 435   case " $INTLLIBS " in
 436   *[[\ \        ]]-liconv[[\ \  ]]*) ;;
 437   *) ICONV_LIBS="-liconv" ;;
 438   esac
 439 fi
 440 AC_SUBST(ICONV_LIBS)
 441
 442 case $with_libiconv in
 443   gnu)
 444     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 445     ;;
 446   native)
 447     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 448     ;;
 449 esac
 450
 451 dnl Initialize libtool
 452 AM_DISABLE_STATIC
 453 AC_LIBTOOL_WIN32_DLL
 454 AM_PROG_LIBTOOL
 455
 456 if test "x$GCC" = "xyes"; then
 457   case " $CFLAGS " in
 458   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 459   *) CFLAGS="$CFLAGS -Wall" ;;
 460   esac
 461 fi
 462
 463 dnl
 464 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 465 dnl
 466 if test $cross_compiling != yes ; then
 467     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 468     glib_save_LIBS=$LIBS
 469     LIBS="$LIBS -lm"
 470     AC_TRY_RUN([#include <math.h>
 471                  int main (void) { return (log(1) != log(1.)); }],
 472          AC_MSG_RESULT(none needed),
 473          glib_save_CFLAGS=$CFLAGS
 474          CFLAGS="$CFLAGS -std1"
 475          AC_TRY_RUN([#include <math.h>
 476                      int main (void) { return (log(1) != log(1.)); }],
 477              AC_MSG_RESULT(-std1),
 478              AC_MSG_RESULT()
 479              CFLAGS=$glib_save_CFLAGS
 480              AC_MSG_WARN(
 481                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 482          )
 483     )
 484     LIBS=$glib_save_LIBS
 485 fi
 486
 487 dnl NeXTStep cc seems to need this
 488 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 489 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 490   AC_MSG_RESULT(none needed),
 491   glib_save_CFLAGS=$CFLAGS
 492   CFLAGS="$CFLAGS -posix"
 493   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 494     AC_MSG_RESULT(-posix),
 495     AC_MSG_RESULT()
 496     CFLAGS=$glib_save_CFLAGS
 497     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 498
 499 # Checks for header files.
 500 AC_HEADER_STDC
 501
 502 # Checks for library functions.
 503 AC_FUNC_VPRINTF
 504 AC_FUNC_MMAP
 505 AC_FUNC_ALLOCA
 506
 507 AC_CHECK_FUNCS(atexit on_exit)
 508
 509 AC_CHECK_SIZEOF(char)
 510 AC_CHECK_SIZEOF(short)
 511 AC_CHECK_SIZEOF(long)
 512 AC_CHECK_SIZEOF(int)
 513 AC_CHECK_SIZEOF(void *)
 514 AC_CHECK_SIZEOF(long long)
 515 AC_CHECK_SIZEOF(__int64)
 516
 517 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 518   :
 519 else
 520   AC_MSG_ERROR([
 521 *** GLib requires a 64 bit type. You might want to consider
 522 *** using the GNU C compiler.
 523 ])
 524 fi
 525
 526 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 527         # long long is a 64 bit integer.
 528         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 529         AC_CACHE_VAL(glib_cv_long_long_format,[
 530                 for format in ll q I64; do
 531                   AC_TRY_RUN([#include <stdio.h>
 532                         int main()
 533                         {
 534                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 535                           char buffer[1000];
 536                           sprintf (buffer, "%${format}u", a);
 537                           sscanf (buffer, "%${format}u", &b);
 538                           exit (b!=a);
 539                         }
 540                         ],
 541                         [glib_cv_long_long_format=${format}
 542                         break],
 543                         [],[:])
 544                 done])
 545         if test -n "$glib_cv_long_long_format"; then
 546           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 547           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 548           if test x"$glib_cv_long_long_format" = xI64; then
 549             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 550           fi
 551         else
 552           AC_MSG_RESULT(none)
 553         fi
 554 elif test x$ac_cv_sizeof___int64 = x8; then
 555         # __int64 is a 64 bit integer.
 556         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 557         # We know this is MSVCRT.DLL, and what the formats are
 558         glib_cv_long_long_format=I64
 559         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 560         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 561         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 562 fi
 563
 564 dnl long doubles were not used, and a portability problem
 565 dnl AC_C_LONG_DOUBLE
 566 AC_C_CONST
 567
 568 dnl ok, here we try to check whether the systems prototypes for
 569 dnl malloc and friends actually match the prototypes provided
 570 dnl by gmem.h (keep in sync). i currently only know how to check
 571 dnl this reliably with gcc (-Werror), improvements for other
 572 dnl compilers are apprechiated.
 573 SANE_MALLOC_PROTOS=no
 574 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 575 glib_save_CFLAGS=$CFLAGS
 576 if test "x$GCC" = "xyes"; then
 577   CFLAGS="$CFLAGS -Werror"
 578   AC_TRY_COMPILE([#include <stdlib.h>], [
 579     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 580     void* (*my_malloc_p)  (size_t)         = malloc;
 581     void  (*my_free_p)    (void*)          = free;
 582     void* (*my_realloc_p) (void*, size_t)  = realloc;
 583     my_calloc_p = 0;
 584     my_malloc_p = 0;
 585     my_free_p = 0;
 586     my_realloc_p = 0;
 587   ],
 588     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 589       [Define if you have correct malloc prototypes])
 590     SANE_MALLOC_PROTOS=yes)
 591 fi
 592 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 593 CFLAGS=$glib_save_CFLAGS
 594
 595 dnl
 596 dnl check in which direction the stack grows
 597 dnl
 598 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 599         AC_TRY_RUN([
 600         volatile int *a = 0, *b = 0;
 601         void foo (void);
 602         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 603         void foo (void) { volatile int x = 5; b = &x; }
 604         ],
 605         glib_cv_stack_grows=no
 606         ,
 607         glib_cv_stack_grows=yes
 608         ,)
 609 ])
 610
 611 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 612 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 613 dnl actually supported.
 614 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 615         AC_COMPILE_IFELSE([
 616         __inline int foo () { return 0; }
 617         int main () { return foo (); }
 618         ],
 619         glib_cv_has__inline=yes
 620         ,
 621         glib_cv_has__inline=no
 622         ,)
 623 ])
 624 case x$glib_cv_has__inline in
 625 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 626 esac
 627 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 628         AC_COMPILE_IFELSE([
 629         __inline__ int foo () { return 0; }
 630         int main () { return foo (); }
 631         ],
 632         glib_cv_has__inline__=yes
 633         ,
 634         glib_cv_has__inline__=no
 635         ,)
 636 ])
 637 case x$glib_cv_has__inline__ in
 638 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 639 esac
 640 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 641         AC_COMPILE_IFELSE([
 642         #undef inline
 643         inline int foo () { return 0; }
 644         int main () { return foo (); }
 645         ],
 646         glib_cv_hasinline=yes
 647         ,
 648         glib_cv_hasinline=no
 649         ,)
 650 ])
 651 case x$glib_cv_hasinline in
 652 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 653 esac
 654
 655 # if we can use inline functions in headers
 656 AC_MSG_CHECKING(if inline functions in headers work)
 657 AC_LINK_IFELSE([
 658 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 659 #  undef inline
 660 #  define inline __inline__
 661 #elif !defined (G_HAVE_INLINE)
 662 #  undef inline
 663 #  if defined (G_HAVE___INLINE__)
 664 #    define inline __inline__
 665 #  elif defined (G_HAVE___INLINE)
 666 #    define inline __inline
 667 #  endif
 668 #endif
 669
 670 int glib_test_func2 (int);
 671
 672 static inline int
 673 glib_test_func1 (void) {
 674   return glib_test_func2 (1);
 675 }
 676
 677 int
 678 main (void) {
 679   int i = 1;
 680 }],[g_can_inline=yes],[g_can_inline=no])
 681 AC_MSG_RESULT($g_can_inline)
 682
 683 # check for flavours of varargs macros
 684 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 685 AC_TRY_COMPILE([],[
 686 int a(int p1, int p2, int p3);
 687 #define call_a(...) a(1,__VA_ARGS__)
 688 call_a(2,3);
 689 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 690 AC_MSG_RESULT($g_have_iso_c_varargs)
 691
 692 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 693 if test "$CXX" = ""; then
 694 dnl No C++ compiler
 695   g_have_iso_cxx_varargs=no
 696 else
 697   AC_LANG_CPLUSPLUS
 698   AC_TRY_COMPILE([],[
 699 int a(int p1, int p2, int p3);
 700 #define call_a(...) a(1,__VA_ARGS__)
 701 call_a(2,3);
 702 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 703   AC_LANG_C
 704 fi
 705 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 706
 707 AC_MSG_CHECKING(for GNUC varargs macros)
 708 AC_TRY_COMPILE([],[
 709 int a(int p1, int p2, int p3);
 710 #define call_a(params...) a(1,params)
 711 call_a(2,3);
 712 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 713 AC_MSG_RESULT($g_have_gnuc_varargs)
 714
 715 # check for GNUC visibility support
 716 AC_MSG_CHECKING(for GNUC visibility attribute)
 717 GLIB_CHECK_COMPILE_WARNINGS([
 718 void
 719 __attribute__ ((visibility ("hidden")))
 720      f_hidden (void)
 721 {
 722 }
 723 void
 724 __attribute__ ((visibility ("internal")))
 725      f_internal (void)
 726 {
 727 }
 728 void
 729 __attribute__ ((visibility ("protected")))
 730      f_protected (void)
 731 {
 732 }
 733 void
 734 __attribute__ ((visibility ("default")))
 735      f_default (void)
 736 {
 737 }
 738 int main (int argc, char **argv)
 739 {
 740         f_hidden();
 741         f_internal();
 742         f_protected();
 743         f_default();
 744         return 0;
 745 }
 746 ],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 747 AC_MSG_RESULT($g_have_gnuc_visibility)
 748 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 749
 750 # check for bytesex stuff
 751 AC_C_BIGENDIAN
 752
 753 # check for header files
 754 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h sys/param.h sys/poll.h sys/select.h sys/types.h])
 755 AC_CHECK_HEADERS([sys/time.h sys/times.h unistd.h values.h stdint.h sched.h])
 756
 757 # Checks for libcharset
 758 jm_LANGINFO_CODESET
 759 jm_GLIBC21
 760 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 761 AC_CHECK_FUNCS(setlocale)
 762
 763 # check additional type sizes
 764 AC_CHECK_SIZEOF(size_t)
 765
 766 dnl Try to figure out whether gsize, gssize should be long or int
 767 AC_MSG_CHECKING([for the appropriate definition for size_t])
 768
 769 case $ac_cv_sizeof_size_t in
 770   $ac_cv_sizeof_short)
 771       glib_size_type=short
 772       ;;
 773   $ac_cv_sizeof_int)
 774       glib_size_type=int
 775       ;;
 776   $ac_cv_sizeof_long)
 777       glib_size_type=long
 778       ;;
 779   *)  AC_MSG_ERROR([No type matching size_t in size])
 780       ;;
 781 esac
 782
 783 dnl If int/long are the same size, we see which one produces
 784 dnl warnings when used in the location as size_t. (This matters
 785 dnl on AIX with xlc)
 786 dnl
 787 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 788    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 789   GLIB_CHECK_COMPILE_WARNINGS([
 790 #if defined(_AIX) && !defined(__GNUC__)
 791 #pragma options langlvl=stdc89
 792 #endif
 793 #include <stddef.h>
 794 int main ()
 795 {
 796   size_t s = 1;
 797   unsigned int *size_int = &s;
 798   return (int)*size_int;
 799 }
 800     ],glib_size_type=int,
 801       [GLIB_CHECK_COMPILE_WARNINGS([
 802 #ifdef _AIX
 803 #pragma options langlvl=stdc89
 804 #endif
 805 #include <stddef.h>
 806 int main ()
 807 {
 808    size_t s = 1;
 809    unsigned long *size_long = &s;
 810    return (int)*size_long;
 811 }
 812         ],glib_size_type=long)])
 813 fi
 814
 815 AC_MSG_RESULT(unsigned $glib_size_type)
 816
 817 # Check for some functions
 818 AC_CHECK_FUNCS(lstat strerror strsignal memmove mkstemp vsnprintf stpcpy strcasecmp strncasecmp poll getcwd nanosleep vasprintf setenv unsetenv getc_unlocked readlink symlink)
 819
 820 AC_FUNC_VSNPRINTF_C99
 821 AC_FUNC_PRINTF_UNIX98
 822
 823 #
 824 # Check whether to use an included printf
 825 #
 826
 827 AC_ARG_ENABLE(included-printf,
 828               [AC_HELP_STRING([--enable-included-printf],
 829                               [use included printf [default=auto]])],
 830               enable_included_printf="$enableval")
 831
 832 need_included_printf=no
 833 if test "x$enable_included_printf" = "xyes" ; then
 834   need_included_printf=yes
 835 fi
 836 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
 837   need_included_printf=yes
 838 fi
 839 if test "$ac_cv_func_printf_unix98" != "yes" ; then
 840   need_included_printf=yes
 841 fi
 842 if test "x$ac_cv_sizeof_long_long" = "x8" &&
 843    test -z "$glib_cv_long_long_format" ; then
 844   need_included_printf=yes
 845 fi
 846
 847 if test "x$enable_included_printf" = "xno" &&
 848    test "x$need_included_printf" = "xyes" ; then
 849   AC_MSG_ERROR([
 850 *** Your C library's printf doesn't appear to have the features that
 851 *** GLib needs, but you specified --enable-included-printf=no.])
 852 fi
 853
 854 enable_included_printf=$need_included_printf
 855
 856 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
 857 if test "$enable_included_printf" != "yes" ; then
 858   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
 859 else
 860   if test -z "$glib_cv_long_long_format" ; then
 861     glib_cv_long_long_format="ll"
 862   fi
 863   AC_DEFINE(HAVE_VASPRINTF,1)
 864 fi
 865
 866 # Checks needed for gnulib vasnprintf
 867 bh_C_SIGNED
 868 jm_AC_TYPE_LONG_LONG
 869 gt_TYPE_LONGDOUBLE
 870 gt_TYPE_WCHAR_T
 871 gt_TYPE_WINT_T
 872 AC_TYPE_SIZE_T
 873 AC_CHECK_TYPES(ptrdiff_t)
 874 jm_AC_TYPE_INTMAX_T
 875 AC_CHECK_FUNCS(snprintf)
 876 AC_FUNC_SNPRINTF_C99
 877
 878 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 879 # The check is borrowed from the PERL Configure script.
 880 if test "$ac_cv_func_memmove" != "yes"; then
 881   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 882     glib_cv_working_bcopy,[AC_TRY_RUN([
 883       int main() {
 884         char buf[128], abc[128], *b;
 885         int len, off, align;
 886         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 887         for (align = 7; align >= 0; align--) {
 888           for (len = 36; len; len--) {
 889             b = buf+align; bcopy(abc, b, len);
 890             for (off = 1; off <= len; off++) {
 891               bcopy(b, b+off, len); bcopy(b+off, b, len);
 892                 if (bcmp(b, abc, len)) return(1);
 893             }
 894           }
 895         }
 896         return(0);
 897       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 898
 899   GLIB_ASSERT_SET(glib_cv_working_bcopy)
 900   if test "$glib_cv_working_bcopy" = "yes"; then
 901     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 902   fi
 903 fi
 904
 905 # Check for sys_errlist
 906 AC_MSG_CHECKING(for sys_errlist)
 907 AC_TRY_LINK(, [
 908 extern char *sys_errlist[];
 909 extern int sys_nerr;
 910 sys_errlist[sys_nerr-1][0] = 0;
 911 ], glib_ok=yes, glib_ok=no)
 912 AC_MSG_RESULT($glib_ok)
 913 if test "$glib_ok" = "no"; then
 914     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 915 fi
 916
 917 # Check for sys_siglist
 918 AC_MSG_CHECKING(for sys_siglist)
 919 AC_TRY_LINK(, [
 920 extern char *sys_siglist[];
 921 exit (sys_siglist[0]);
 922 ], glib_ok=yes, glib_ok=no)
 923 AC_MSG_RESULT($glib_ok)
 924 if test "$glib_ok" = "no"; then
 925     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 926 fi
 927
 928 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 929 AC_MSG_CHECKING(for sys_siglist declaration)
 930 AC_TRY_COMPILE([#include <signal.h>], [
 931 strlen (sys_siglist[0]);
 932 ], glib_ok=yes, glib_ok=no)
 933 AC_MSG_RESULT($glib_ok)
 934 if test "$glib_ok" = "no"; then
 935     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 936 fi
 937
 938 # Check if <sys/select.h> needs to be included for fd_set
 939 AC_MSG_CHECKING([for fd_set])
 940 AC_TRY_COMPILE([#include <sys/types.h>],
 941         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 942 if test "$gtk_ok" = "yes"; then
 943     AC_MSG_RESULT([yes, found in sys/types.h])
 944 else
 945     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
 946     if test "$gtk_ok" = "yes"; then
 947         # *** FIXME: give it a different name
 948         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
 949         AC_MSG_RESULT([yes, found in sys/select.h])
 950     else
 951         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
 952         AC_MSG_RESULT(no)
 953     fi
 954 fi
 955
 956 dnl *** check for sane realloc() ***
 957 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
 958         AC_TRY_RUN([#include <stdlib.h>
 959         int main() {
 960           return realloc (0, sizeof (int)) == 0;
 961         }],
 962         [glib_cv_sane_realloc=yes],
 963         [glib_cv_sane_realloc=no],
 964         [glib_cv_sane_realloc=yes])
 965 ])
 966 if test x$glib_cv_sane_realloc = xyes; then
 967   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
 968 fi
 969
 970 dnl Check for nl_langinfo and CODESET
 971
 972 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
 973 AC_TRY_COMPILE([#include <langinfo.h>],
 974         [char *codeset = nl_langinfo (CODESET);],
 975    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
 976    have_codeset=yes,
 977    have_codeset=no)
 978 AC_MSG_RESULT($have_codeset)
 979
 980
 981 dnl ****************************************
 982 dnl *** strlcpy/strlcat                  ***
 983 dnl ****************************************
 984 # Check for strlcpy
 985 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
 986 AC_TRY_RUN([#include <stdlib.h>
 987 #include <string.h>
 988 int main() {
 989   char p[10];
 990   (void) strlcpy (p, "hi", 10);
 991   if (strlcat (p, "bye", 0) != 3)
 992     return 1;
 993   return 0;
 994 }], glib_cv_have_strlcpy=yes,
 995     glib_cv_have_strlcpy=no,
 996     glib_cv_have_strlcpy=no)])
 997 if test "$glib_cv_have_strlcpy" = "yes"; then
 998     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
 999 fi
1000
1001
1002 dnl **********************
1003 dnl *** va_copy checks ***
1004 dnl **********************
1005 dnl we currently check for all three va_copy possibilities, so we get
1006 dnl all results in config.log for bug reports.
1007 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1008         AC_LINK_IFELSE([#include <stdarg.h>
1009         void f (int i, ...) {
1010         va_list args1, args2;
1011         va_start (args1, i);
1012         va_copy (args2, args1);
1013         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1014           exit (1);
1015         va_end (args1); va_end (args2);
1016         }
1017         int main() {
1018           f (0, 42);
1019           return 0;
1020         }],
1021         [glib_cv_va_copy=yes],
1022         [glib_cv_va_copy=no])
1023 ])
1024 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1025         AC_LINK_IFELSE([#include <stdarg.h>
1026         void f (int i, ...) {
1027         va_list args1, args2;
1028         va_start (args1, i);
1029         __va_copy (args2, args1);
1030         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1031           exit (1);
1032         va_end (args1); va_end (args2);
1033         }
1034         int main() {
1035           f (0, 42);
1036           return 0;
1037         }],
1038         [glib_cv___va_copy=yes],
1039         [glib_cv___va_copy=no])
1040 ])
1041
1042 if test "x$glib_cv_va_copy" = "xyes"; then
1043   g_va_copy_func=va_copy
1044 else if test "x$glib_cv___va_copy" = "xyes"; then
1045   g_va_copy_func=__va_copy
1046 fi
1047 fi
1048
1049 if test -n "$g_va_copy_func"; then
1050   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1051 fi
1052
1053 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1054         AC_TRY_RUN([#include <stdarg.h>
1055         void f (int i, ...) {
1056         va_list args1, args2;
1057         va_start (args1, i);
1058         args2 = args1;
1059         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1060           exit (1);
1061         va_end (args1); va_end (args2);
1062         }
1063         int main() {
1064           f (0, 42);
1065           return 0;
1066         }],
1067         [glib_cv_va_val_copy=yes],
1068         [glib_cv_va_val_copy=no],
1069         [glib_cv_va_val_copy=yes])
1070 ])
1071
1072 if test "x$glib_cv_va_val_copy" = "xno"; then
1073   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1074 fi
1075
1076 dnl ***********************
1077 dnl *** g_module checks ***
1078 dnl ***********************
1079 G_MODULE_LIBS=
1080 G_MODULE_LIBS_EXTRA=
1081 G_MODULE_PLUGIN_LIBS=
1082 if test x"$glib_native_win32" = xyes; then
1083   dnl No use for this on Win32
1084   G_MODULE_LDFLAGS=
1085 else
1086   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1087 fi
1088 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1089 G_MODULE_NEED_USCORE=0
1090 G_MODULE_BROKEN_RTLD_GLOBAL=0
1091 G_MODULE_HAVE_DLERROR=0
1092 dnl *** force native WIN32 shared lib loader
1093 if test -z "$G_MODULE_IMPL"; then
1094   case "$host" in
1095   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1096   esac
1097 fi
1098 dnl *** force native AIX library loader
1099 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1100 if test -z "$G_MODULE_IMPL"; then
1101   case "$host" in
1102   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1103   esac
1104 fi
1105 dnl *** dlopen() and dlsym() in system libraries
1106 if test -z "$G_MODULE_IMPL"; then
1107         AC_CHECK_FUNC(dlopen,
1108                       [AC_CHECK_FUNC(dlsym,
1109                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1110                       [])
1111 fi
1112 dnl *** load_image (BeOS)
1113 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1114   AC_CHECK_LIB(root, load_image,
1115       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1116       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1117       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1118       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1119       [])
1120 fi
1121 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1122 if test -z "$G_MODULE_IMPL"; then
1123         AC_CHECK_FUNC(NSLinkModule,
1124                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1125                        G_MODULE_NEED_USCORE=1],
1126                       [])
1127 fi
1128 dnl *** dlopen() and dlsym() in libdl
1129 if test -z "$G_MODULE_IMPL"; then
1130         AC_CHECK_LIB(dl, dlopen,
1131                      [AC_CHECK_LIB(dl, dlsym,
1132                                    [G_MODULE_LIBS=-ldl
1133                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1134                      [])
1135 fi
1136 dnl *** shl_load() in libdld (HP-UX)
1137 if test -z "$G_MODULE_IMPL"; then
1138         AC_CHECK_LIB(dld, shl_load,
1139                 [G_MODULE_LIBS=-ldld
1140                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1141                 [])
1142 fi
1143 dnl *** additional checks for G_MODULE_IMPL_DL
1144 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1145         LIBS_orig="$LIBS"
1146         LDFLAGS_orig="$LDFLAGS"
1147         LIBS="$G_MODULE_LIBS $LIBS"
1148         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1149 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1150         echo "void glib_plugin_test(void) { }" > plugin.c
1151         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1152                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1153         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1154                 glib_cv_rtldglobal_broken,[
1155                 AC_TRY_RUN([
1156 #include <dlfcn.h>
1157 #ifndef RTLD_GLOBAL
1158 #  define RTLD_GLOBAL 0
1159 #endif
1160 #ifndef RTLD_LAZY
1161 #  define RTLD_LAZY 0
1162 #endif
1163 int glib_plugin_test;
1164 int main () {
1165     void *handle, *global, *local;
1166     global = &glib_plugin_test;
1167     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1168     if (!handle) return 0;
1169     local = dlsym (handle, "glib_plugin_test");
1170     return global == local;
1171 }                       ],
1172                         [glib_cv_rtldglobal_broken=no],
1173                         [glib_cv_rtldglobal_broken=yes],
1174                         [glib_cv_rtldglobal_broken=no])
1175                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1176                 rmdir .libs 2>/dev/null
1177         ])
1178         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1179                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1180         else
1181                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1182         fi
1183 dnl *** check whether we need preceeding underscores
1184         AC_CACHE_CHECK([for preceeding underscore in symbols],
1185                 glib_cv_uscore,[
1186                 AC_TRY_RUN([#include <dlfcn.h>
1187                 int glib_underscore_test (void) { return 42; }
1188                 int main() {
1189                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1190                   handle = dlopen ((void*)0, 0);
1191                   if (handle) {
1192                     f1 = dlsym (handle, "glib_underscore_test");
1193                     f2 = dlsym (handle, "_glib_underscore_test");
1194                   } return (!f2 || f1);
1195                 }],
1196                         [glib_cv_uscore=yes],
1197                         [glib_cv_uscore=no],
1198                         [])
1199                 rm -f plugin.c plugin.$ac_objext plugin.lo
1200         ])
1201         GLIB_ASSERT_SET(glib_cv_uscore)
1202         if test "x$glib_cv_uscore" = "xyes"; then
1203                 G_MODULE_NEED_USCORE=1
1204         else
1205                 G_MODULE_NEED_USCORE=0
1206         fi
1207
1208         LDFLAGS="$LDFLAGS_orig"
1209 dnl *** check for having dlerror()
1210         AC_CHECK_FUNC(dlerror,
1211                 [G_MODULE_HAVE_DLERROR=1],
1212                 [G_MODULE_HAVE_DLERROR=0])
1213         LIBS="$LIBS_orig"
1214 fi
1215 dnl *** done, have we got an implementation?
1216 if test -z "$G_MODULE_IMPL"; then
1217         G_MODULE_IMPL=0
1218         G_MODULE_SUPPORTED=false
1219 else
1220         G_MODULE_SUPPORTED=true
1221 fi
1222
1223 AC_MSG_CHECKING(for the suffix of shared libraries)
1224 case "$host_os" in
1225   hpux9* | hpux10* | hpux11*)  # taken from ltconfig
1226     glib_gmodule_suffix='sl'
1227     ;;
1228   cygwin* | mingw*)
1229     glib_gmodule_suffix='dll'
1230     ;;
1231   aix*)
1232     glib_gmodule_suffix='a'
1233     ;;
1234   *)
1235     glib_gmodule_suffix='so'
1236     ;;
1237 esac
1238 AC_MSG_RESULT(.$glib_gmodule_suffix)
1239
1240 AC_SUBST(G_MODULE_SUPPORTED)
1241 AC_SUBST(G_MODULE_IMPL)
1242 AC_SUBST(G_MODULE_LIBS)
1243 AC_SUBST(G_MODULE_LIBS_EXTRA)
1244 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1245 AC_SUBST(G_MODULE_LDFLAGS)
1246 AC_SUBST(G_MODULE_HAVE_DLERROR)
1247 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1248 AC_SUBST(G_MODULE_NEED_USCORE)
1249 AC_SUBST(GLIB_DEBUG_FLAGS)
1250
1251 dnl **********************
1252 dnl *** g_spawn checks ***
1253 dnl **********************
1254
1255 AC_MSG_CHECKING(for gspawn implementation)
1256 case "$host" in
1257   *-*-mingw*)
1258     GSPAWN=gspawn-win32.lo
1259     ;;
1260   *)
1261     GSPAWN=gspawn.lo
1262     ;;
1263 esac
1264 AC_MSG_RESULT($GSPAWN)
1265 AC_SUBST(GSPAWN)
1266
1267 dnl *************************
1268 dnl *** GIOChannel checks ***
1269 dnl *************************
1270
1271 AC_MSG_CHECKING(for GIOChannel implementation)
1272 case "$host" in
1273   *-*-mingw*)
1274     GIO=giowin32.lo
1275     ;;
1276   *)
1277     GIO=giounix.lo
1278     ;;
1279 esac
1280 AC_MSG_RESULT($GIO)
1281 AC_SUBST(GIO)
1282
1283 dnl ****************************************
1284 dnl *** platform dependent source checks ***
1285 dnl ****************************************
1286
1287 AC_MSG_CHECKING(for platform-dependent source)
1288 case "$host" in
1289   *-*-cygwin*|*-*-mingw*)
1290     PLATFORMDEP=gwin32.lo
1291     ;;
1292   *)
1293     PLATFORMDEP=
1294     ;;
1295 esac
1296 AC_MSG_RESULT($PLATFORMDEP)
1297 AC_SUBST(PLATFORMDEP)
1298
1299 AC_MSG_CHECKING([whether to compile timeloop])
1300 case "$host" in
1301   *-*-cygwin*|*-*-mingw*)
1302     enable_timeloop=no
1303     ;;
1304   *)
1305     enable_timeloop=yes
1306     ;;
1307 esac
1308 AC_MSG_RESULT($enable_timeloop)
1309 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1310
1311 AC_MSG_CHECKING([if building for some Win32 platform])
1312 case "$host" in
1313   *-*-mingw*|*-*-cygwin*)
1314     platform_win32=yes
1315     ;;
1316   *)
1317     platform_win32=no
1318     ;;
1319 esac
1320 AC_MSG_RESULT($platform_win32)
1321 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1322
1323 dnl ***********************
1324 dnl *** g_thread checks ***
1325 dnl ***********************
1326
1327 AC_ARG_WITH(threads,
1328            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/solaris/win32@:>@],
1329                            [specify a thread implementation to use])],
1330            [if test "x$with_threads" = x; then
1331                 want_threads=yes
1332             else
1333                 want_threads=$with_threads
1334             fi],
1335            [want_threads=yes])
1336 if test "x$enable_threads" = "xno"; then
1337         want_threads=no
1338 fi
1339
1340 dnl error and warning message
1341 dnl *************************
1342
1343 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1344                 computer. GLib will not have a default thread implementation."
1345
1346 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1347                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1348                 compilation now, but then your programs might not work.
1349                 Please provide information on how it is done on your system."
1350
1351 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1352                 "
1353
1354 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1355                 provide information on your thread implementation.
1356                 You can also run 'configure --disable-threads'
1357                 to compile without thread support."
1358
1359 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1360                 functions will not be MT-safe during their first call because
1361                 there is no working 'getpwuid_r' on your system."
1362
1363 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1364                 because there is no 'localtime_r' on your system."
1365
1366 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1367                 crude surrogate will be used. If you happen to know a
1368                 yield function for your system, please inform the GLib
1369                 developers."
1370
1371 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1372                 threads on your system. Thus threads can only have the default
1373                 priority. If you happen to know these main/max
1374                 priorities, please inform the GLib developers."
1375
1376 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1377                 linking threaded applications. As GLib cannot do that
1378                 automatically, you will get an linkg error everytime you are
1379                 not using the right compiler. In that case you have to relink
1380                 with the right compiler. Ususally just '_r' is appended
1381                 to the compiler name."
1382
1383 dnl determination of thread implementation
1384 dnl ***************************************
1385
1386 # have_threads=no   means no thread support
1387 # have_threads=none means no default thread implementation
1388
1389 have_threads=no
1390 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
1391         case $host in
1392                 *-*-solaris*)
1393                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
1394                 ;;
1395         esac
1396 fi
1397 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1398                                 || test "x$want_threads" = xdce; then
1399         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1400         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1401         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1402         glib_save_CPPFLAGS="$CPPFLAGS"
1403         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1404         if test "x$have_threads" = xno; then
1405                 AC_TRY_COMPILE([#include <pthread.h>],
1406                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1407                         have_threads=posix)
1408         fi
1409         if test "x$have_threads" = xno; then
1410                 AC_TRY_COMPILE([#include <pthread.h>],
1411                         [pthread_mutex_t m;
1412                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1413                         have_threads=dce)
1414         fi
1415         # Tru64Unix requires -pthread to find pthread.h. See #103020
1416         CPPFLAGS="$CPPFLAGS -pthread"
1417         if test "x$have_threads" = xno; then
1418         AC_TRY_COMPILE([#include <pthread.h>],
1419                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1420                        have_threads=posix)
1421         fi
1422         CPPFLAGS="$glib_save_CPPFLAGS"
1423 fi
1424 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1425         case $host in
1426                 *-*-mingw*)
1427                 have_threads=win32
1428                 ;;
1429         esac
1430 fi
1431 if test "x$want_threads" = xnone; then
1432         have_threads=none
1433 fi
1434
1435 AC_MSG_CHECKING(for thread implementation)
1436
1437 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1438         AC_MSG_RESULT(none available)
1439         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1440 else
1441         AC_MSG_RESULT($have_threads)
1442 fi
1443
1444
1445 dnl determination of G_THREAD_CFLAGS
1446 dnl ********************************
1447
1448 G_THREAD_LIBS=
1449 G_THREAD_LIBS_EXTRA=
1450 G_THREAD_CFLAGS=
1451
1452 dnl
1453 dnl Test program for basic POSIX threads functionality
1454 dnl
1455 m4_define([glib_thread_test],[
1456 #include <pthread.h>
1457 int check_me = 0;
1458 void* func(void* data) {check_me = 42; return &check_me;}
1459 int main()
1460  { pthread_t t;
1461    void *ret;
1462    pthread_create (&t, $1, func, 0);
1463    pthread_join (t, &ret);
1464    exit (check_me != 42 || ret != &check_me);
1465 }])
1466
1467 dnl
1468 dnl Test program for sched_get_priority_min()
1469 dnl
1470 m4_define([glib_sched_priority_test],[
1471 #include <sched.h>
1472 #include <errno.h>
1473 int main() {
1474     errno = 0;
1475     return sched_get_priority_min(SCHED_OTHER)==-1
1476            && errno != 0;
1477 }])
1478
1479 if test x"$have_threads" != xno; then
1480
1481   if test x"$have_threads" = xposix; then
1482     # First we test for posix, whether -pthread or -pthreads do the trick as
1483     # both CPPFLAG and LIBS.
1484     # One of them does for most gcc versions and some other platforms/compilers
1485     # too and could be considered as the canonical way to go.
1486     case $host in
1487       *-*-cygwin*)
1488          # skip cygwin -pthread or -pthreads test
1489          ;;
1490       *)
1491         for flag in pthread pthreads; do
1492           glib_save_CFLAGS="$CFLAGS"
1493           CFLAGS="$CFLAGS -$flag"
1494           AC_TRY_RUN(glib_thread_test(0),
1495                      glib_flag_works=yes,
1496                      glib_flag_works=no,
1497                      [AC_LINK_IFELSE(glib_thread_test(0),
1498                                      glib_flag_works=yes,
1499                                      glib_flag_works=no)])
1500           CFLAGS="$glib_save_CFLAGS"
1501           if test $glib_flag_works = yes ; then
1502              G_THREAD_CFLAGS=-$flag
1503              G_THREAD_LIBS=-$flag
1504           fi
1505         done
1506          ;;
1507     esac
1508   fi
1509
1510   if test x"$G_THREAD_CFLAGS" = x; then
1511
1512     # The canonical -pthread[s] does not work. Try something different.
1513
1514     case $host in
1515         *-aix*)
1516                 if test x"$GCC" = xyes; then
1517                         # GCC 3.0 and above needs -pthread.
1518                         # Should be coverd by the case above.
1519                         # GCC 2.x and below needs -mthreads
1520                         G_THREAD_CFLAGS="-mthreads"
1521                         G_THREAD_LIBS=$G_THREAD_CFLAGS
1522                 else
1523                         # We are probably using the aix compiler. Normaly a
1524                         # program would have to be compiled with the _r variant
1525                         # of the corresponding compiler, but we as GLib cannot
1526                         # do that: but the good news is that for compiling the
1527                         # only difference is the added -D_THREAD_SAFE compile
1528                         # option. This is according to the "C for AIX User's
1529                         # Guide".
1530                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
1531                 fi
1532                 ;;
1533         *-dg-dgux*)  # DG/UX
1534                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
1535                 ;;
1536         *-osf*)
1537                 # So we are using dce threads. posix threads are already
1538                 # catched above.
1539                 G_THREAD_CFLAGS="-threads"
1540                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1541                 ;;
1542         *-solaris*)
1543                 if test x"$GCC" = xyes; then
1544                    # We are using solaris threads. posix threads are
1545                    # already catched above.
1546                         G_THREAD_CFLAGS="-threads"
1547                 else
1548                         G_THREAD_CFLAGS="-mt"
1549                 fi
1550                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1551                 ;;
1552         *-sysv5uw7*) # UnixWare 7
1553                 # We are not using gcc with -pthread. Catched above.
1554                 G_THREAD_CFLAGS="-Kthread"
1555                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1556                 ;;
1557         *-mingw*)
1558                 # No flag needed when using MSVCRT.DLL
1559                 G_THREAD_CFLAGS=""
1560                 ;;
1561         *)
1562                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1563                 ;;
1564     esac
1565
1566   fi
1567
1568     # if we are not finding the localtime_r function, then we probably are
1569     # not using the proper multithread flag
1570
1571     glib_save_CPPFLAGS="$CPPFLAGS"
1572     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1573
1574     # First we test, whether localtime_r is declared in time.h
1575     # directly. Then we test whether a macro localtime_r exists, in
1576     # which case localtime_r in the test program is replaced and thus
1577     # if we still find localtime_r in the output, it is not defined as
1578     # a macro.
1579
1580     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1581       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1582                                                            localtime_r(a,b)],
1583                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1584
1585     CPPFLAGS="$glib_save_CPPFLAGS"
1586
1587     AC_MSG_CHECKING(thread related cflags)
1588     AC_MSG_RESULT($G_THREAD_CFLAGS)
1589     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1590 fi
1591
1592 dnl determination of G_THREAD_LIBS
1593 dnl ******************************
1594
1595 mutex_has_default=no
1596 case $have_threads in
1597         posix|dce)
1598           glib_save_CPPFLAGS="$CPPFLAGS"
1599           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1600           if test x"$G_THREAD_LIBS" = x; then
1601             case $host in
1602               *-aix*)
1603                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
1604                 # probably using the aix compiler.
1605                 AC_MSG_WARN($AIX_COMPILE_INFO)
1606                 ;;
1607               *)
1608                 G_THREAD_LIBS=error
1609                 glib_save_LIBS="$LIBS"
1610                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
1611                         if test x"$thread_lib" = x; then
1612                                 add_thread_lib=""
1613                                 IN=""
1614                         else
1615                                 add_thread_lib="-l$thread_lib"
1616                                 IN=" in -l$thread_lib"
1617                         fi
1618                         if test x"$have_threads" = xposix; then
1619                                 defattr=0
1620                         else
1621                                 defattr=pthread_attr_default
1622                         fi
1623
1624                         LIBS="$add_thread_lib $glib_save_LIBS"
1625
1626                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
1627                         AC_TRY_RUN(glib_thread_test($defattr),
1628                                    glib_result=yes,
1629                                    glib_result=no,
1630                                    [AC_LINK_IFELSE(glib_thread_test($defattr),
1631                                                    glib_result=yes,
1632                                                    glib_result=no)])
1633                         AC_MSG_RESULT($glib_result)
1634
1635                         if test "$glib_result" = "yes" ; then
1636                           G_THREAD_LIBS="$add_thread_lib"
1637                           break
1638                         fi
1639                 done
1640                 if test "x$G_THREAD_LIBS" = xerror; then
1641                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1642                 fi
1643                 LIBS="$glib_save_LIBS"
1644                 ;;
1645             esac
1646           fi
1647
1648           glib_save_LIBS="$LIBS"
1649           for thread_lib in "" rt rte; do
1650             if test x"$thread_lib" = x; then
1651               add_thread_lib=""
1652               IN=""
1653             else
1654               add_thread_lib="-l$thread_lib"
1655               IN=" in -l$thread_lib"
1656             fi
1657             LIBS="$add_thread_lib $glib_save_LIBS"
1658
1659             AC_MSG_CHECKING(for sched_get_priority_min$IN)
1660             AC_TRY_RUN(glib_sched_priority_test,
1661                        glib_result=yes,
1662                        glib_result=no,
1663                        [AC_LINK_IFELSE(glib_sched_priority_test,
1664                                        glib_result=yes,
1665                                        glib_result=no)])
1666             AC_MSG_RESULT($glib_result)
1667
1668             if test "$glib_result" = "yes" ; then
1669                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
1670                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
1671                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
1672                break
1673             fi
1674           done
1675           LIBS="$glib_save_LIBS"
1676           mutex_has_default=yes
1677           mutex_default_type='pthread_mutex_t'
1678           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
1679           mutex_header_file='pthread.h'
1680           if test "x$have_threads" = "xposix"; then
1681             g_threads_impl="POSIX"
1682           else
1683             g_threads_impl="DCE"
1684             have_threads="posix"
1685           fi
1686           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
1687           CPPFLAGS="$glib_save_CPPFLAGS"
1688           ;;
1689         solaris)
1690            mutex_has_default=yes
1691            mutex_default_type='mutex_t'
1692            mutex_default_init="DEFAULTMUTEX"
1693            mutex_header_file='thread.h'
1694            g_threads_impl="SOLARIS"
1695            ;;
1696         win32)
1697            g_threads_impl="WIN32"
1698            ;;
1699         none|no)
1700            g_threads_impl="NONE"
1701            ;;
1702         *)
1703            g_threads_impl="NONE"
1704            G_THREAD_LIBS=error
1705            ;;
1706 esac
1707
1708 if test "x$G_THREAD_LIBS" = xerror; then
1709         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1710 fi
1711
1712 case $host in
1713   *-*-beos*)
1714     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
1715     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1716     ;;
1717   *)
1718     ;;
1719 esac
1720
1721 AC_MSG_CHECKING(thread related libraries)
1722 AC_MSG_RESULT($G_THREAD_LIBS)
1723
1724 dnl check for mt safe function variants and some posix functions
1725 dnl ************************************************************
1726
1727 if test x"$have_threads" != xno; then
1728         glib_save_LIBS="$LIBS"
1729         # we are not doing the following for now, as this might require glib
1730         # to always be linked with the thread libs on some platforms.
1731         # LIBS="$LIBS $G_THREAD_LIBS"
1732         AC_CHECK_FUNCS(localtime_r)
1733         if test "$ac_cv_header_pwd_h" = "yes"; then
1734                 AC_CACHE_CHECK([for posix getpwuid_r],
1735                         ac_cv_func_posix_getpwuid_r,
1736                         [AC_TRY_RUN([
1737 #include <errno.h>
1738 #include <pwd.h>
1739 int main () {
1740     char buffer[10000];
1741     struct passwd pwd, *pwptr = &pwd;
1742     int error;
1743     errno = 0;
1744     error = getpwuid_r (0, &pwd, buffer,
1745                         sizeof (buffer), &pwptr);
1746    return (error < 0 && errno == ENOSYS)
1747            || error == ENOSYS;
1748 }                               ],
1749                                 [ac_cv_func_posix_getpwuid_r=yes],
1750                                 [ac_cv_func_posix_getpwuid_r=no])])
1751                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
1752                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
1753                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
1754                                 [Have POSIX function getpwuid_r])
1755                 else
1756                         AC_CACHE_CHECK([for nonposix getpwuid_r],
1757                                 ac_cv_func_nonposix_getpwuid_r,
1758                                 [AC_TRY_LINK([#include <pwd.h>],
1759                                         [char buffer[10000];
1760                                         struct passwd pwd;
1761                                         getpwuid_r (0, &pwd, buffer,
1762                                                         sizeof (buffer));],
1763                                         [ac_cv_func_nonposix_getpwuid_r=yes],
1764                                         [ac_cv_func_nonposix_getpwuid_r=no])])
1765                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
1766                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
1767                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
1768                                         [Have non-POSIX function getpwuid_r])
1769                         fi
1770                 fi
1771         fi
1772         LIBS="$G_THREAD_LIBS $LIBS"
1773         if test x"$have_threads" = xposix; then
1774                 glib_save_CPPFLAGS="$CPPFLAGS"
1775                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1776                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
1777                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
1778                 # This is not AC_CHECK_FUNC to also work with function
1779                 # name mangling in header files.
1780                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1781                 AC_TRY_LINK([#include <pthread.h>],
1782                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1783                         [AC_MSG_RESULT(yes)
1784                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1785                                   [Have function pthread_attr_setstacksize])],
1786                         [AC_MSG_RESULT(no)])
1787                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1788                 if test x"$posix_priority_min" = x; then
1789                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1790                                 PX_PRIO_MIN],,[
1791                                 posix_priority_min=PX_PRIO_MIN
1792                                 posix_priority_max=PX_PRIO_MAX])
1793                 fi
1794                 if test x"$posix_priority_min" = x; then
1795                         # AIX
1796                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
1797                                 PTHREAD_PRIO_MIN],,[
1798                                 posix_priority_min=PTHREAD_PRIO_MIN
1799                                 posix_priority_max=PTHREAD_PRIO_MAX])
1800                 fi
1801                 if test x"$posix_priority_min" = x; then
1802                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1803                                 PRI_OTHER_MIN],,[
1804                                 posix_priority_min=PRI_OTHER_MIN
1805                                 posix_priority_max=PRI_OTHER_MAX])
1806                 fi
1807                 if test x"$posix_priority_min" = x; then
1808                         AC_MSG_RESULT(none found)
1809                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1810                         posix_priority_min=-1
1811                         posix_priority_max=-1
1812                 else
1813                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1814                         AC_MSG_CHECKING(for pthread_setschedparam)
1815                         AC_TRY_LINK([#include <pthread.h>],
1816                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
1817                           [AC_MSG_RESULT(yes)
1818                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1819                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
1820                           [AC_MSG_RESULT(no)
1821                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
1822                 fi
1823                 posix_yield_func=none
1824                 AC_MSG_CHECKING(for posix yield function)
1825                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1826                                                         thr_yield; do
1827                         AC_TRY_LINK([#include <pthread.h>],
1828                                 [$yield_func()],
1829                                 [posix_yield_func="$yield_func"
1830                                 break])
1831                 done
1832                 if test x"$posix_yield_func" = xnone; then
1833                         AC_MSG_RESULT(none found)
1834                         AC_MSG_WARN($POSIX_NO_YIELD)
1835                         posix_yield_func="g_usleep(1000)"
1836                 else
1837                         AC_MSG_RESULT($posix_yield_func)
1838                         posix_yield_func="$posix_yield_func()"
1839                 fi
1840                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1841                 CPPFLAGS="$glib_save_CPPFLAGS"
1842
1843         elif test x"$have_threads" = xwin32; then
1844                 # It's a pointer to a private struct
1845                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
1846         elif test x"$have_threads" = xsolaris; then
1847                 GLIB_SIZEOF([#include <thread.h>], thread_t, system_thread)
1848         fi
1849
1850         LIBS="$glib_save_LIBS"
1851
1852         # now spit out all the warnings.
1853         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1854            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1855                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1856         fi
1857         if test "$ac_cv_func_localtime_r" != "yes"; then
1858                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1859         fi
1860 fi
1861
1862 if test x"$glib_cv_sizeof_system_thread" = x; then
1863    # use a pointer as a fallback.
1864    GLIB_SIZEOF(,void *, system_thread)
1865 fi
1866
1867 #
1868 # Hack to deal with:
1869 #
1870 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
1871 #     building shared libraries with linux.
1872 #
1873 case $host in
1874   *-*-linux*)
1875     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
1876     ;;
1877   *)
1878     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
1879     ;;
1880 esac
1881
1882 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1883                    [Source file containing theread implementation])
1884 AC_SUBST(G_THREAD_CFLAGS)
1885 AC_SUBST(G_THREAD_LIBS)
1886 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
1887 AC_SUBST(G_THREAD_LIBS_EXTRA)
1888
1889 dnl **********************************************
1890 dnl *** GDefaultMutex setup and initialization ***
1891 dnl **********************************************
1892 dnl
1893 dnl if mutex_has_default = yes, we also got
1894 dnl mutex_default_type, mutex_default_init and mutex_header_file
1895 if test $mutex_has_default = yes ; then
1896         glib_save_CPPFLAGS="$CPPFLAGS"
1897         glib_save_LIBS="$LIBS"
1898         LIBS="$G_THREAD_LIBS $LIBS"
1899         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1900         GLIB_SIZEOF([#include <$mutex_header_file>],
1901                     $mutex_default_type,
1902                     gmutex)
1903         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1904                            $mutex_default_type,
1905                            gmutex,
1906                            $glib_cv_sizeof_gmutex,
1907                            $mutex_default_init)
1908         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1909                 mutex_has_default=no
1910         fi
1911         CPPFLAGS="$glib_save_CPPFLAGS"
1912         LIBS="$glib_save_LIBS"
1913 fi
1914
1915 dnl ********************************
1916 dnl *** g_atomic_* tests for gcc ***
1917 dnl ********************************
1918
1919 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
1920
1921 if test x"$GCC" = xyes; then
1922   case $host_cpu in
1923     i386)
1924       AC_MSG_RESULT([none])
1925       glib_memory_barrier_needed=no
1926       ;;
1927     i?86)
1928       AC_MSG_RESULT([i486])
1929       AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
1930                          [i486 atomic implementation])
1931       glib_memory_barrier_needed=no
1932       ;;
1933     sparc*)
1934       SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
1935                 when you are using a sparc with v9 instruction set (most
1936                 sparcs nowadays). This will make the code for atomic
1937                 operations much faster. The resulting code will not run
1938                 on very old sparcs though."
1939
1940       AC_LINK_IFELSE([[
1941         main ()
1942         {
1943           int tmp1, tmp2, tmp3;
1944           __asm__ __volatile__("casx [%2], %0, %1"
1945                                : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
1946         }]],
1947         AC_MSG_RESULT([sparcv9])
1948         AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
1949                            [sparcv9 atomic implementation]),
1950         AC_MSG_RESULT([no])
1951         AC_MSG_WARN([[$SPARCV9_WARNING]]))
1952       glib_memory_barrier_needed=yes
1953       ;;
1954     alpha*)
1955       AC_MSG_RESULT([alpha])
1956       AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
1957                          [alpha atomic implementation])
1958       glib_memory_barrier_needed=yes
1959       ;;
1960     x86_64)
1961       AC_MSG_RESULT([x86_64])
1962       AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
1963                          [x86_64 atomic implementation])
1964       glib_memory_barrier_needed=no
1965      ;;
1966     powerpc*)
1967       AC_MSG_RESULT([powerpc])
1968       AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
1969                          [powerpc atomic implementation])
1970       glib_memory_barrier_needed=yes
1971       ;;
1972     ia64)
1973       AC_MSG_RESULT([ia64])
1974       AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
1975                          [ia64 atomic implementation])
1976       glib_memory_barrier_needed=yes
1977       ;;
1978     *)
1979       AC_MSG_RESULT([none])
1980       glib_memory_barrier_needed=yes
1981       ;;
1982   esac
1983 fi
1984
1985 dnl ****************************************
1986 dnl *** GLib POLL* compatibility defines ***
1987 dnl ****************************************
1988
1989 glib_poll_includes=["
1990 #include <sys/types.h>
1991 #include <sys/poll.h>
1992 "]
1993
1994 if test $ac_cv_header_sys_types_h = yes &&
1995    test $ac_cv_header_sys_poll_h = yes ; then
1996   glib_failed=false
1997   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
1998   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
1999   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2000   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2001   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2002   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2003   if $glib_failed ; then
2004     AC_MSG_ERROR([Could not determine values for POLL* constants])
2005   fi
2006 else
2007   glib_cv_value_POLLIN=1
2008   glib_cv_value_POLLOUT=4
2009   glib_cv_value_POLLPRI=2
2010   glib_cv_value_POLLERR=8
2011   glib_cv_value_POLLHUP=16
2012   glib_cv_value_POLLNVAL=32
2013 fi
2014
2015 dnl **********************
2016 dnl *** Win32 API libs ***
2017 dnl **********************
2018
2019 case $host in
2020   *-*-cygwin*)
2021         G_LIBS_EXTRA="-luser32 -lkernel32"
2022     ;;
2023   *-*-mingw*)
2024         G_LIBS_EXTRA="-lws2_32 -lole32"
2025     ;;
2026   *)
2027         G_LIBS_EXTRA=""
2028     ;;
2029 esac
2030 AC_SUBST(G_LIBS_EXTRA)
2031
2032 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2033 dnl since we need it for g_iconv()
2034
2035 AC_MSG_CHECKING([for EILSEQ])
2036 AC_TRY_COMPILE([
2037 #include <errno.h>
2038 ],
2039 [
2040 int error = EILSEQ;
2041 ], have_eilseq=yes, have_eilseq=no);
2042 AC_MSG_RESULT($have_eilseq)
2043
2044 dnl ******************************************************************
2045 dnl *** Look for glib-genmarshal in PATH if we are cross-compiling ***
2046 dnl ******************************************************************
2047
2048 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2049
2050 if test $cross_compiling = yes; then
2051   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2052   if test x$GLIB_GENMARSHAL = xno; then
2053     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2054   fi
2055 fi
2056
2057 dnl **************************
2058 dnl *** Checks for gtk-doc ***
2059 dnl **************************
2060
2061 GTK_DOC_CHECK([1.4])
2062
2063 AC_ARG_ENABLE(man,
2064               [AC_HELP_STRING([--enable-man],
2065                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2066               enable_man=no)
2067
2068 if test "${enable_man}" != no; then
2069 dnl
2070 dnl Check for xsltproc
2071 dnl
2072 AC_PATH_PROG([XSLTPROC], [xsltproc])
2073   if test -z "$XSLTPROC"; then
2074     enable_man=no
2075   fi
2076
2077   dnl check for DocBook DTD and stylesheets in the local catalog.
2078   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2079      [DocBook XML DTD V4.1.2],,enable_man=no)
2080   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2081      [DocBook XSL Stylesheets],,enable_man=no)
2082 fi
2083
2084 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2085
2086 dnl ******************************
2087 dnl *** output the whole stuff ***
2088 dnl ******************************
2089
2090 dnl this section will only be run if config.status is invoked with no
2091 dnl arguments, or with "glibconfig.h" as an argument.
2092 AC_CONFIG_COMMANDS([glibconfig.h],
2093 [
2094         outfile=glibconfig.h-tmp
2095         cat > $outfile <<\_______EOF
2096 /* glibconfig.h
2097  *
2098  * This is a generated file.  Please modify 'configure.in'
2099  */
2100
2101 #ifndef __G_LIBCONFIG_H__
2102 #define __G_LIBCONFIG_H__
2103
2104 #include <glib/gmacros.h>
2105
2106 _______EOF
2107
2108         if test x$glib_limits_h = xyes; then
2109           echo '#include <limits.h>' >> $outfile
2110         fi
2111         if test x$glib_float_h = xyes; then
2112           echo '#include <float.h>' >> $outfile
2113         fi
2114         if test x$glib_values_h = xyes; then
2115           echo '#include <values.h>' >> $outfile
2116         fi
2117         if test "$glib_header_alloca_h" = "yes"; then
2118           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2119         fi
2120         if test x$glib_sys_poll_h = xyes; then
2121           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2122         fi
2123
2124         cat >> $outfile <<_______EOF
2125
2126 G_BEGIN_DECLS
2127
2128 #define G_MINFLOAT      $glib_mf
2129 #define G_MAXFLOAT      $glib_Mf
2130 #define G_MINDOUBLE     $glib_md
2131 #define G_MAXDOUBLE     $glib_Md
2132 #define G_MINSHORT      $glib_ms
2133 #define G_MAXSHORT      $glib_Ms
2134 #define G_MAXUSHORT     $glib_Mus
2135 #define G_MININT        $glib_mi
2136 #define G_MAXINT        $glib_Mi
2137 #define G_MAXUINT       $glib_Mui
2138 #define G_MINLONG       $glib_ml
2139 #define G_MAXLONG       $glib_Ml
2140 #define G_MAXULONG      $glib_Mul
2141
2142 _______EOF
2143
2144
2145         ### this should always be true in a modern C/C++ compiler
2146         cat >>$outfile <<_______EOF
2147 typedef signed char gint8;
2148 typedef unsigned char guint8;
2149 _______EOF
2150
2151
2152         if test -n "$gint16"; then
2153           cat >>$outfile <<_______EOF
2154 typedef signed $gint16 gint16;
2155 typedef unsigned $gint16 guint16;
2156 #define G_GINT16_MODIFIER $gint16_modifier
2157 #define G_GINT16_FORMAT $gint16_format
2158 #define G_GUINT16_FORMAT $guint16_format
2159 _______EOF
2160         fi
2161
2162
2163         if test -n "$gint32"; then
2164           cat >>$outfile <<_______EOF
2165 typedef signed $gint32 gint32;
2166 typedef unsigned $gint32 guint32;
2167 #define G_GINT32_MODIFIER $gint32_modifier
2168 #define G_GINT32_FORMAT $gint32_format
2169 #define G_GUINT32_FORMAT $guint32_format
2170 _______EOF
2171         fi
2172
2173         cat >>$outfile <<_______EOF
2174 #define G_HAVE_GINT64 1          /* deprecated, always true */
2175
2176 ${glib_extension}typedef signed $gint64 gint64;
2177 ${glib_extension}typedef unsigned $gint64 guint64;
2178
2179 #define G_GINT64_CONSTANT(val)  $gint64_constant
2180 _______EOF
2181
2182         if test x$gint64_format != x ; then
2183           cat >>$outfile <<_______EOF
2184 #define G_GINT64_MODIFIER $gint64_modifier
2185 #define G_GINT64_FORMAT $gint64_format
2186 #define G_GUINT64_FORMAT $guint64_format
2187 _______EOF
2188         else
2189           cat >>$outfile <<_______EOF
2190 #undef G_GINT64_MODIFIER
2191 #undef G_GINT64_FORMAT
2192 #undef G_GUINT64_FORMAT
2193 _______EOF
2194         fi
2195
2196         cat >>$outfile <<_______EOF
2197
2198 #define GLIB_SIZEOF_VOID_P $glib_void_p
2199 #define GLIB_SIZEOF_LONG   $glib_long
2200 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2201
2202 _______EOF
2203
2204         cat >>$outfile <<_______EOF
2205 typedef signed $glib_size_type_define gssize;
2206 typedef unsigned $glib_size_type_define gsize;
2207 #define G_GSIZE_MODIFIER $gsize_modifier
2208 #define G_GSSIZE_FORMAT $gssize_format
2209 #define G_GSIZE_FORMAT $gsize_format
2210
2211 #define G_MAXSIZE       G_MAXU$glib_msize_type
2212 _______EOF
2213
2214         if test -z "$glib_unknown_void_p"; then
2215           cat >>$outfile <<_______EOF
2216
2217 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2218 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2219
2220 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2221 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2222 _______EOF
2223         else
2224           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2225         fi
2226
2227
2228
2229         cat >>$outfile <<_______EOF
2230 $glib_atexit
2231 $glib_memmove
2232 $glib_defines
2233 $glib_os
2234
2235 $glib_vacopy
2236
2237 #ifdef  __cplusplus
2238 #define G_HAVE_INLINE   1
2239 #else   /* !__cplusplus */
2240 $glib_inline
2241 #endif  /* !__cplusplus */
2242
2243 #ifdef  __cplusplus
2244 #define G_CAN_INLINE    1
2245 _______EOF
2246
2247         if test x$g_can_inline = xyes ; then
2248                 cat >>$outfile <<_______EOF
2249 #else   /* !__cplusplus */
2250 #define G_CAN_INLINE    1
2251 _______EOF
2252         fi
2253
2254         cat >>$outfile <<_______EOF
2255 #endif
2256
2257 _______EOF
2258
2259         if test x$g_have_iso_c_varargs = xyes ; then
2260                 cat >>$outfile <<_______EOF
2261 #ifndef __cplusplus
2262 # define G_HAVE_ISO_VARARGS 1
2263 #endif
2264 _______EOF
2265         fi
2266         if test x$g_have_iso_cxx_varargs = xyes ; then
2267                 cat >>$outfile <<_______EOF
2268 #ifdef __cplusplus
2269 # define G_HAVE_ISO_VARARGS 1
2270 #endif
2271 _______EOF
2272         fi
2273         if test x$g_have_gnuc_varargs = xyes ; then
2274                 cat >>$outfile <<_______EOF
2275
2276 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2277  * is passed ISO vararg support is turned off, and there is no work
2278  * around to turn it on, so we unconditionally turn it off.
2279  */
2280 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2281 #  undef G_HAVE_ISO_VARARGS
2282 #endif
2283
2284 #define G_HAVE_GNUC_VARARGS 1
2285 _______EOF
2286         fi
2287
2288         case x$g_stack_grows in
2289         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2290         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2291         esac
2292
2293
2294         echo >>$outfile
2295         if test x$g_have_eilseq = xno; then
2296                 cat >>$outfile <<_______EOF
2297 #ifndef EILSEQ
2298 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2299  * The correspondence between this and the corresponding definition
2300  * in libiconv is essential.
2301  */
2302 #  define EILSEQ ENOENT
2303 #endif
2304 _______EOF
2305
2306         fi
2307
2308         if test x$g_have_gnuc_visibility = xyes ; then
2309                 cat >>$outfile <<_______EOF
2310 #define G_HAVE_GNUC_VISIBILITY 1
2311 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2312 _______EOF
2313         else
2314                 cat >>$outfile <<_______EOF
2315 #define G_GNUC_INTERNAL
2316 _______EOF
2317         fi
2318
2319
2320         echo >>$outfile
2321         if test x$g_mutex_has_default = xyes; then
2322                 cat >>$outfile <<_______EOF
2323 $g_enable_threads_def G_THREADS_ENABLED
2324 #define G_THREADS_IMPL_$g_threads_impl_def
2325 typedef struct _GStaticMutex GStaticMutex;
2326 struct _GStaticMutex
2327 {
2328   struct _GMutex *runtime_mutex;
2329   union {
2330     char   pad[[$g_mutex_sizeof]];
2331     double dummy_double;
2332     void  *dummy_pointer;
2333     long   dummy_long;
2334   } static_mutex;
2335 };
2336 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
2337 #define g_static_mutex_get_mutex(mutex) \\
2338   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->static_mutex)) : \\
2339    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
2340 _______EOF
2341         else
2342                 cat >>$outfile <<_______EOF
2343 $g_enable_threads_def G_THREADS_ENABLED
2344 #define G_THREADS_IMPL_$g_threads_impl_def
2345 typedef struct _GMutex* GStaticMutex;
2346 #define G_STATIC_MUTEX_INIT NULL
2347 #define g_static_mutex_get_mutex(mutex) \\
2348   (g_static_mutex_get_mutex_impl_shortcut (mutex))
2349 _______EOF
2350         fi
2351
2352         cat >>$outfile <<_______EOF
2353 /* This represents a system thread as used by the implementation. An
2354  * alien implementaion, as loaded by g_thread_init can only count on
2355  * "sizeof (gpointer)" bytes to store their info. We however need more
2356  * for some of our native implementations. */
2357 typedef union _GSystemThread GSystemThread;
2358 union _GSystemThread
2359 {
2360   char   data[[$g_system_thread_sizeof]];
2361   double dummy_double;
2362   void  *dummy_pointer;
2363   long   dummy_long;
2364 };
2365 _______EOF
2366         if test x"$g_memory_barrier_needed" != xno; then
2367           echo >>$outfile
2368           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2369         fi
2370
2371         echo >>$outfile
2372         g_bit_sizes="16 32 64"
2373         for bits in $g_bit_sizes; do
2374           cat >>$outfile <<_______EOF
2375 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
2376 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
2377 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2378 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
2379 _______EOF
2380         done
2381
2382         cat >>$outfile <<_______EOF
2383 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
2384 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
2385 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
2386 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
2387 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
2388 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
2389 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
2390 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
2391 #define G_BYTE_ORDER $g_byte_order
2392
2393 #define GLIB_SYSDEF_POLLIN =$g_pollin
2394 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2395 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2396 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2397 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2398 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2399
2400 #define G_MODULE_SUFFIX "$g_module_suffix"
2401
2402 typedef $g_pid_type GPid;
2403
2404 G_END_DECLS
2405
2406 #endif /* GLIBCONFIG_H */
2407 _______EOF
2408
2409
2410         if cmp -s $outfile glibconfig.h; then
2411           AC_MSG_NOTICE([glibconfig.h is unchanged])
2412           rm -f $outfile
2413         else
2414           mv $outfile glibconfig.h
2415         fi
2416 ],[
2417
2418 # Note that if two cases are the same, case goes with the first one.
2419 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
2420 # on variable expansion in case labels.  Look at the generated config.status
2421 # for a hint.
2422
2423 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2424   glib_header_alloca_h="$ac_cv_working_alloca_h"
2425 else
2426   glib_header_alloca_h="$ac_cv_header_alloca_h"
2427 fi
2428
2429 case xyes in
2430 x$ac_cv_header_float_h)
2431   glib_float_h=yes
2432   glib_mf=FLT_MIN glib_Mf=FLT_MAX
2433   glib_md=DBL_MIN glib_Md=DBL_MAX
2434   ;;
2435 x$ac_cv_header_values_h)
2436   glib_values_h=yes
2437   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
2438   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
2439   ;;
2440 esac
2441
2442 case xyes in
2443 x$ac_cv_header_limits_h)
2444   glib_limits_h=yes
2445   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
2446   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
2447   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
2448   ;;
2449 x$ac_cv_header_values_h)
2450   glib_values_h=yes
2451   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
2452   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
2453   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
2454   ;;
2455 esac
2456
2457 if test x$ac_cv_header_sys_poll_h = xyes ; then
2458   glib_sys_poll_h=yes
2459 fi
2460
2461 case 2 in
2462 $ac_cv_sizeof_short)
2463   gint16=short
2464   gint16_modifier='"h"'
2465   gint16_format='"hi"'
2466   guint16_format='"hu"'
2467   ;;
2468 $ac_cv_sizeof_int)
2469   gint16=int
2470   gint16_modifier='""'
2471   gint16_format='"i"'
2472   guint16_format='"u"'
2473   ;;
2474 esac
2475 case 4 in
2476 $ac_cv_sizeof_short)
2477   gint32=short
2478   gint32_modifier='"h"'
2479   gint32_format='"hi"'
2480   guint32_format='"hu"'
2481   ;;
2482 $ac_cv_sizeof_int)
2483   gint32=int
2484   gint32_modifier='""'
2485   gint32_format='"i"'
2486   guint32_format='"u"'
2487   ;;
2488 $ac_cv_sizeof_long)
2489   gint32=long
2490   gint32_modifier='"l"'
2491   gint32_format='"li"'
2492   guint32_format='"lu"'
2493   ;;
2494 esac
2495 case 8 in
2496 $ac_cv_sizeof_int)
2497   gint64=int
2498   gint64_modifier='""'
2499   gint64_format='"i"'
2500   guint64_format='"u"'
2501   glib_extension=
2502   gint64_constant='(val)'
2503   ;;
2504 $ac_cv_sizeof_long)
2505   gint64=long
2506   gint64_modifier='"l"'
2507   gint64_format='"li"'
2508   guint64_format='"lu"'
2509   glib_extension=
2510   gint64_constant='(val##L)'
2511   ;;
2512 $ac_cv_sizeof_long_long)
2513   gint64='long long'
2514   if test -n "$glib_cv_long_long_format"; then
2515     gint64_modifier='"'$glib_cv_long_long_format'"'
2516     gint64_format='"'$glib_cv_long_long_format'i"'
2517     guint64_format='"'$glib_cv_long_long_format'u"'
2518   fi
2519   glib_extension='G_GNUC_EXTENSION '
2520   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
2521   ;;
2522 $ac_cv_sizeof___int64)
2523   gint64='__int64'
2524   if test -n "$glib_cv_long_long_format"; then
2525     gint64_modifier='"'$glib_cv_long_long_format'"'
2526     gint64_format='"'$glib_cv_long_long_format'i"'
2527     guint64_format='"'$glib_cv_long_long_format'u"'
2528   fi
2529   glib_extension=
2530   gint64_constant='(val##i64)'
2531   ;;
2532 esac
2533 glib_size_t=$ac_cv_sizeof_size_t
2534 glib_size_type_define=$glib_size_type
2535 glib_void_p=$ac_cv_sizeof_long
2536 glib_long=$ac_cv_sizeof_void_p
2537
2538 case $glib_size_type in
2539 short)
2540   gsize_modifier='"h"'
2541   gsize_format='"hu"'
2542   gssize_format='"hi"'
2543   glib_msize_type='SHRT'
2544   ;;
2545 int)
2546   gsize_modifier='""'
2547   gsize_format='"u"'
2548   gssize_format='"i"'
2549   glib_msize_type='INT'
2550   ;;
2551 long)
2552   gsize_modifier='"l"'
2553   gsize_format='"lu"'
2554   gssize_format='"li"'
2555   glib_msize_type='LONG'
2556   ;;
2557 esac
2558
2559 gintbits=`expr $ac_cv_sizeof_int \* 8`
2560 glongbits=`expr $ac_cv_sizeof_long \* 8`
2561
2562
2563 case $ac_cv_sizeof_void_p in
2564 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
2565 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
2566 *)                      glib_unknown_void_p=yes ;;
2567 esac
2568
2569
2570 case xyes in
2571 x$ac_cv_func_atexit)
2572   glib_atexit="
2573 #ifdef NeXT /* @#%@! NeXTStep */
2574 # define g_ATEXIT(proc) (!atexit (proc))
2575 #else
2576 # define g_ATEXIT(proc) (atexit (proc))
2577 #endif"
2578   ;;
2579 x$ac_cv_func_on_exit)
2580   glib_atexit="
2581 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
2582   ;;
2583 esac
2584
2585 case xyes in
2586 x$ac_cv_func_memmove)
2587   glib_memmove='
2588 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
2589   ;;
2590 x$glib_cv_working_bcopy)
2591   glib_memmove="
2592 /* memmove isn't available, but bcopy can copy overlapping memory regions */
2593 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
2594   ;;
2595 *)
2596   glib_memmove="
2597 /* memmove isn't found and bcopy can't copy overlapping memory regions,
2598  * so we have to roll our own copy routine. */
2599 void g_memmove (void* dest, const void * src, unsigned long len);"
2600   ;;
2601 esac
2602
2603 glib_defines="
2604 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
2605 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
2606 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
2607 "
2608
2609 case xyes in
2610 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
2611 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
2612 *)                      glib_vacopy=''
2613 esac
2614
2615 if test x$glib_cv_va_val_copy = xno; then
2616   glib_vacopy="\$glib_vacopy
2617 #define G_VA_COPY_AS_ARRAY 1"
2618 fi
2619
2620 if test x$glib_cv_hasinline = xyes; then
2621     glib_inline='#define G_HAVE_INLINE 1'
2622 fi
2623 if test x$glib_cv_has__inline = xyes; then
2624     glib_inline="\$glib_inline
2625 #define G_HAVE___INLINE 1"
2626 fi
2627 if test x$glib_cv_has__inline__ = xyes; then
2628     glib_inline="\$glib_inline
2629 #define G_HAVE___INLINE__ 1"
2630 fi
2631
2632 g_have_gnuc_varargs=$g_have_gnuc_varargs
2633 g_have_iso_c_varargs=$g_have_iso_c_varargs
2634 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
2635
2636 g_can_inline=$g_can_inline
2637 g_have_gnuc_visibility=$g_have_gnuc_visibility
2638
2639 case xyes in
2640 x$ac_cv_c_bigendian)
2641   g_byte_order=G_BIG_ENDIAN
2642   g_bs_native=BE
2643   g_bs_alien=LE
2644   ;;
2645 *)
2646   g_byte_order=G_LITTLE_ENDIAN
2647   g_bs_native=LE
2648   g_bs_alien=BE
2649   ;;
2650 esac
2651
2652 g_pollin=$glib_cv_value_POLLIN
2653 g_pollout=$glib_cv_value_POLLOUT
2654 g_pollpri=$glib_cv_value_POLLPRI
2655 g_pollhup=$glib_cv_value_POLLHUP
2656 g_pollerr=$glib_cv_value_POLLERR
2657 g_pollnval=$glib_cv_value_POLLNVAL
2658
2659 g_stack_grows=$glib_cv_stack_grows
2660
2661 g_have_eilseq=$have_eilseq
2662
2663 case x$have_threads in
2664 xno)    g_enable_threads_def="#undef";;
2665 *)      g_enable_threads_def="#define";;
2666 esac
2667
2668 g_threads_impl_def=$g_threads_impl
2669
2670 g_mutex_has_default="$mutex_has_default"
2671 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
2672 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
2673 g_mutex_contents="$glib_cv_byte_contents_gmutex"
2674
2675 g_memory_barrier_needed="$glib_memory_barrier_needed"
2676
2677 g_module_suffix="$glib_gmodule_suffix"
2678
2679 g_pid_type="$glib_pid_type"
2680 case $host in
2681   *-*-beos*)
2682     glib_os="#define G_OS_BEOS"
2683     ;;
2684   *-*-cygwin*)
2685     glib_os="#define G_OS_UNIX
2686 #define G_PLATFORM_WIN32
2687 #define G_WITH_CYGWIN"
2688     ;;
2689   *-*-mingw*)
2690     glib_os="#define G_OS_WIN32
2691 #define G_PLATFORM_WIN32"
2692     ;;
2693   *)
2694     glib_os="#define G_OS_UNIX"
2695     ;;
2696 esac
2697 ])
2698
2699 AC_CONFIG_FILES([
2700 glib-2.0.pc
2701 glib-2.0-uninstalled.pc
2702 gmodule-2.0.pc
2703 gmodule-export-2.0.pc
2704 gmodule-no-export-2.0.pc
2705 gmodule-2.0-uninstalled.pc
2706 gmodule-no-export-2.0-uninstalled.pc
2707 gthread-2.0.pc
2708 gthread-2.0-uninstalled.pc
2709 gobject-2.0.pc
2710 gobject-2.0-uninstalled.pc
2711 glib-zip
2712 glib-gettextize
2713 Makefile
2714 build/Makefile
2715 build/win32/Makefile
2716 build/win32/dirent/Makefile
2717 glib/Makefile
2718 glib/libcharset/Makefile
2719 glib/gnulib/Makefile
2720 gmodule/Makefile
2721 gmodule/gmoduleconf.h
2722 gobject/Makefile
2723 gobject/glib-mkenums
2724 gthread/Makefile
2725 po/Makefile.in
2726 docs/Makefile
2727 docs/reference/Makefile
2728 docs/reference/glib/Makefile
2729 docs/reference/glib/version.xml
2730 docs/reference/gobject/Makefile
2731 docs/reference/gobject/version.xml
2732 tests/Makefile
2733 tests/gobject/Makefile
2734 m4macros/Makefile
2735 ])
2736
2737 AC_CONFIG_COMMANDS([chmod-scripts],
2738 [chmod 0755 glib-zip
2739 chmod 0755 glib-gettextize
2740 chmod 0755 gobject/glib-mkenums])
2741
2742 # we want to invoke this macro solely so that the config.status script
2743 # and automake generated makefiles know about these generated files.
2744 # They are only needed to distcheck the package
2745 if false; then
2746   AC_CONFIG_FILES([
2747     INSTALL
2748     README
2749     config.h.win32
2750     glibconfig.h.win32
2751     glib/makefile.msc
2752     glib/glib.rc
2753     gmodule/makefile.msc
2754     gmodule/gmodule.rc
2755     gobject/makefile.msc
2756     gobject/gobject.rc
2757     gthread/makefile.msc
2758     gthread/gthread.rc
2759     tests/makefile.msc
2760   ])
2761 fi
2762
2763 AC_OUTPUT