Released GLib 1.1.8
[platform/upstream/glib.git] / configure.in
1 # Process this file with autoconf to produce a configure script.
2 AC_INIT(glist.c)
3
4 # Save this value here, since automake will set cflags later
5 cflags_set=${CFLAGS+set}
6
7 # The following version number definitions apply to GLib and GModule
8 # as a whole, so if changes occoured in either of them, they are both
9 # treated with the same interface and binary age.
10 #
11 # Making releases:
12 #   GLIB_MICRO_VERSION += 1;
13 #   GLIB_INTERFACE_AGE += 1;
14 #   GLIB_BINARY_AGE += 1;
15 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
16 # if backwards compatibility has been broken,
17 # set GLIB_BINARY_AGE and GLIB_INTERFACE_AGE to 0.
18 #
19 GLIB_MAJOR_VERSION=1
20 GLIB_MINOR_VERSION=1
21 GLIB_MICRO_VERSION=8
22 GLIB_INTERFACE_AGE=0
23 GLIB_BINARY_AGE=0
24 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
25 AC_SUBST(GLIB_VERSION)
26
27 # libtool versioning
28 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
29 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
30 LT_REVISION=$GLIB_INTERFACE_AGE
31 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
32 AC_SUBST(LT_RELEASE)
33 AC_SUBST(LT_CURRENT)
34 AC_SUBST(LT_REVISION)
35 AC_SUBST(LT_AGE)
36
37 VERSION=$GLIB_VERSION
38 PACKAGE=glib
39
40 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
41
42 # Specify a configuration file
43 AM_CONFIG_HEADER(config.h)
44
45 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION)
46 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION)
47 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION)
48 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE)
49 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE)
50
51 dnl Initialize libtool
52 AM_PROG_LIBTOOL
53
54 dnl Initialize maintainer mode
55 AM_MAINTAINER_MODE
56
57 AC_CANONICAL_HOST
58
59 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=minimum]],,enable_debug=minimum)
60 AC_ARG_ENABLE(mem_check, [  --enable-mem-check=[no/yes] turn on malloc/free sanity checking [default=no]],,enable_mem_check=no)
61 AC_ARG_ENABLE(mem_profile, [  --enable-mem-profile=[no/yes] turn on malloc profiling atexit [default=no]],,enable_mem_profile=no)
62
63 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
64                     , enable_ansi=no)
65
66 AC_MSG_CHECKING(whether to enable memory checking)
67 if test "x$enable_mem_check" = "xyes"; then
68   AC_DEFINE(ENABLE_MEM_CHECK, 1)
69   AC_SUBST(ENABLE_MEM_CHECK)
70   AC_MSG_RESULT(yes)
71 else
72   AC_MSG_RESULT(no)
73 fi
74
75 AC_MSG_CHECKING(whether to enable memory profiling)
76 if test "x$enable_mem_profile" = "xyes"; then
77   AC_DEFINE(ENABLE_MEM_PROFILE, 1)
78   AC_SUBST(ENABLE_MEM_PROFILE)
79   AC_MSG_RESULT(yes)
80 else
81   AC_MSG_RESULT(no)
82 fi
83
84 if test "x$enable_debug" = "xyes"; then
85   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
86   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
87 else
88   if test "x$enable_debug" = "xno"; then
89     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
90   fi
91 fi
92
93 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}")
94
95 # Checks for programs.
96 AC_PROG_CC
97 AM_PROG_CC_STDC
98 AC_PROG_INSTALL
99
100 changequote(,)dnl
101 if test "x$GCC" = "xyes"; then
102   case " $CFLAGS " in
103   *[\ \ ]-Wall[\ \      ]*) ;;
104   *) CFLAGS="$CFLAGS -Wall" ;;
105   esac
106
107   if test "x$enable_ansi" = "xyes"; then
108     case " $CFLAGS " in
109     *[\ \       ]-ansi[\ \      ]*) ;;
110     *) CFLAGS="$CFLAGS -ansi" ;;
111     esac
112
113     case " $CFLAGS " in
114     *[\ \       ]-pedantic[\ \  ]*) ;;
115     *) CFLAGS="$CFLAGS -pedantic" ;;
116     esac
117   fi
118 fi
119 changequote([,])dnl
120
121 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
122 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
123 glib_save_LIBS=$LIBS
124 LIBS="$LIBS -lm"
125 AC_TRY_RUN([#include <math.h>
126              int main (void) { return (log(1) != log(1.)); }],
127      AC_MSG_RESULT(none needed),
128      glib_save_CFLAGS=$CFLAGS
129      CFLAGS="$CFLAGS -std1"
130      AC_TRY_RUN([#include <math.h>
131                  int main (void) { return (log(1) != log(1.)); }],
132          AC_MSG_RESULT(-std1),
133          AC_MSG_RESULT()
134          CFLAGS=$glib_save_CFLAGS
135          AC_MSG_WARN(
136                 [No ANSI prototypes found in library. (-std1 didn't work.)])
137      )
138 )
139 LIBS=$glib_save_LIBS
140
141 dnl NeXTStep cc seems to need this
142 AC_MSG_CHECKING([for extra flags for POSIX compliance])
143 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
144   AC_MSG_RESULT(none needed),
145   glib_save_CFLAGS=$CFLAGS
146   CFLAGS="$CFLAGS -posix"
147   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
148     AC_MSG_RESULT(-posix),
149     AC_MSG_RESULT()
150     CFLAGS=$glib_save_CFLAGS
151     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
152
153 # Checks for header files.
154 AC_HEADER_STDC
155
156 # Checks for library functions.
157 AC_FUNC_VPRINTF
158
159 AC_CHECK_FUNCS(atexit on_exit)
160
161 AC_CHECK_SIZEOF(char)
162 AC_CHECK_SIZEOF(short)
163 AC_CHECK_SIZEOF(long)
164 AC_CHECK_SIZEOF(int)
165 AC_CHECK_SIZEOF(void *)
166 AC_CHECK_SIZEOF(long long)
167
168 dnl long doubles were not used, and a portability problem 
169 dnl AC_C_LONG_DOUBLE
170 AC_C_CONST
171
172 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
173 dnl truely know which ones of `inline', `__inline' and `__inline__' are
174 dnl actually supported.
175 AC_MSG_CHECKING(for __inline)
176 AC_CACHE_VAL(glib_cv_has__inline,[
177         AC_TRY_RUN([
178         __inline int foo () { return 0; }
179         int main () { return foo (); }
180         ],
181         glib_cv_has__inline=yes
182         ,
183         glib_cv_has__inline=no
184         ,)
185 ])
186 AC_MSG_RESULT($glib_cv_has__inline)
187 case x$glib_cv_has__inline in
188 xyes) AC_DEFINE(G_HAVE___INLINE)
189 esac
190 AC_MSG_CHECKING(for __inline__)
191 AC_CACHE_VAL(glib_cv_has__inline__,[
192         AC_TRY_RUN([
193         __inline__ int foo () { return 0; }
194         int main () { return foo (); }
195         ],
196         glib_cv_has__inline__=yes
197         ,
198         glib_cv_has__inline__=no
199         ,)
200 ])
201 AC_MSG_RESULT($glib_cv_has__inline__)
202 case x$glib_cv_has__inline__ in
203 xyes) AC_DEFINE(G_HAVE___INLINE__)
204 esac
205 AC_MSG_CHECKING(for inline)
206 AC_CACHE_VAL(glib_cv_hasinline,[
207         AC_TRY_RUN([
208         inline int foo () { return 0; }
209         int main () { return foo (); }
210         ],
211         glib_cv_hasinline=yes
212         ,
213         glib_cv_hasinline=no
214         ,)
215 ])
216 AC_MSG_RESULT($glib_cv_hasinline)
217 case x$glib_cv_hasinline in
218 xyes) AC_DEFINE(G_HAVE_INLINE)
219 esac
220
221 dnl for bytesex stuff
222 AC_C_BIGENDIAN
223
224 dnl header file checks
225 AC_CHECK_HEADERS(float.h, AC_DEFINE(HAVE_FLOAT_H))
226 AC_CHECK_HEADERS(limits.h, AC_DEFINE(HAVE_LIMITS_H))
227 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
228 AC_CHECK_HEADERS(sys/param.h, AC_DEFINE(HAVE_SYS_PARAM_H))
229 AC_CHECK_HEADERS(sys/poll.h, AC_DEFINE(HAVE_SYS_POLL_H))
230 AC_CHECK_HEADERS(sys/select.h, AC_DEFINE(HAVE_SYS_SELECT_H))
231 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
232 AC_CHECK_HEADERS(sys/times.h, AC_DEFINE(HAVE_SYS_TIMES_H))
233 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
234 AC_CHECK_HEADERS(values.h, AC_DEFINE(HAVE_VALUES_H))
235
236 # Check for some functions
237 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf strcasecmp strncasecmp poll)
238
239 # Check for sys_errlist
240 AC_MSG_CHECKING(for sys_errlist)
241 AC_TRY_LINK(, [
242 extern char *sys_errlist[];
243 extern int sys_nerr;
244 sys_errlist[sys_nerr-1][0] = 0;
245 ], glib_ok=yes, glib_ok=no)
246 AC_MSG_RESULT($glib_ok)
247 if test $glib_ok = no; then
248     AC_DEFINE(NO_SYS_ERRLIST)
249 fi
250
251 # Check for sys_siglist
252 AC_MSG_CHECKING(for sys_siglist)
253 AC_TRY_LINK(, [
254 extern char *sys_siglist[];
255 sys_siglist[1][0] = 0;
256 ], glib_ok=yes, glib_ok=no)
257 AC_MSG_RESULT($glib_ok)
258 if test $glib_ok = no; then
259     AC_DEFINE(NO_SYS_SIGLIST)
260 fi
261
262 # Check if <sys/select.h> needs to be included for fd_set
263 AC_MSG_CHECKING([for fd_set])
264 AC_TRY_COMPILE([#include <sys/types.h>],
265         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
266 if test $gtk_ok = yes; then
267     AC_MSG_RESULT([yes, found in sys/types.h])
268 else
269     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
270     if test $gtk_ok = yes; then
271         AC_DEFINE(HAVE_SYS_SELECT_H)
272         AC_MSG_RESULT([yes, found in sys/select.h])
273     else
274         AC_DEFINE(NO_FD_SET)
275         AC_MSG_RESULT(no)
276     fi
277 fi
278
279 # These are used only in GDK (gdki18n.h)
280 # This stuff is here only so that we can define these
281 # things in glibconfig.h. If gtk+ started using an installed
282 # gdkconfig.h file, then the definitions would belong there. 
283
284 # Check for wchar.h
285
286 AC_MSG_CHECKING(for wchar.h)
287 AC_TRY_CPP([#include <wchar.h>], glib_wchar_h=yes, glib_wchar_h=no)
288 if test $glib_wchar_h = yes; then
289    AC_DEFINE(HAVE_WCHAR_H)
290 fi
291 AC_MSG_RESULT($glib_wchar_h)
292
293 # Check for wctype.h (for iswalnum)
294
295 AC_MSG_CHECKING(for wctype.h)
296 AC_TRY_CPP([#include <wctype.h>], glib_wctype_h=yes, glib_wctype_h=no)
297 if test $glib_wctype_h = yes; then
298    AC_DEFINE(HAVE_WCTYPE_H)
299 fi
300 AC_MSG_RESULT($glib_wctype_h)
301
302 oLIBS="$LIBS"
303 # in Solaris 2.5, `iswalnum' is in -lw
304 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum)])
305
306 # The following is necessary for Linux libc-5.4.38
307 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
308 AC_TRY_LINK([#include <stdlib.h>],[
309 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
310 #  ifdef HAVE_WCTYPE_H
311 #    include <wctype.h>
312 #  else
313 #    ifdef HAVE_WCHAR_H
314 #      include <wchar.h>
315 #    endif
316 #  endif
317 #else
318 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
319 #endif
320 iswalnum((wchar_t) 0);
321 ], glib_working_wctype=yes, glib_working_wctype=no)
322 LIBS="$oLIBS"
323
324 if test $glib_working_wctype = no; then
325    AC_DEFINE(HAVE_BROKEN_WCTYPE)
326 fi
327 AC_MSG_RESULT($glib_working_wctype)
328
329
330 dnl **********************
331 dnl *** va_copy checks ***
332 dnl **********************
333 dnl we currently check for all three va_copy possibilities, so we get
334 dnl all results in config.log for bug reports.
335 AC_MSG_CHECKING(for an implementation of va_copy())
336 AC_CACHE_VAL(glib_cv_va_copy,[
337         AC_TRY_RUN([
338         #include <stdarg.h>
339         void f (int i, ...) {
340         va_list args1, args2;
341         va_start (args1, i);
342         va_copy (args2, args1);
343         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
344           exit (1);
345         va_end (args1); va_end (args2);
346         }
347         int main() {
348           f (0, 42);
349           return 0;
350         }],
351         glib_cv_va_copy=yes
352         ,
353         glib_cv_va_copy=no
354         ,)
355 ])
356 AC_MSG_RESULT($glib_cv_va_copy)
357 AC_MSG_CHECKING(for an implementation of __va_copy())
358 AC_CACHE_VAL(glib_cv___va_copy,[
359         AC_TRY_RUN([
360         #include <stdarg.h>
361         void f (int i, ...) {
362         va_list args1, args2;
363         va_start (args1, i);
364         __va_copy (args2, args1);
365         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
366           exit (1);
367         va_end (args1); va_end (args2);
368         }
369         int main() {
370           f (0, 42);
371           return 0;
372         }],
373         glib_cv___va_copy=yes
374         ,
375         glib_cv___va_copy=no
376         ,)
377 ])
378 AC_MSG_RESULT($glib_cv___va_copy)
379 AC_MSG_CHECKING(whether va_lists can be copied by value)
380 AC_CACHE_VAL(glib_cv_va_val_copy,[
381         AC_TRY_RUN([
382         #include <stdarg.h>
383         void f (int i, ...) {
384         va_list args1, args2;
385         va_start (args1, i);
386         args2 = args1;
387         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
388           exit (1);
389         va_end (args1); va_end (args2);
390         }
391         int main() {
392           f (0, 42);
393           return 0;
394         }],
395         glib_cv_va_val_copy=yes
396         ,
397         glib_cv_va_val_copy=no
398         ,)
399 ])
400 if test "x$glib_cv_va_copy" = "xyes"; then
401   AC_DEFINE(G_VA_COPY, va_copy)
402 else if test "x$glib_cv___va_copy" = "xyes"; then
403   AC_DEFINE(G_VA_COPY, __va_copy)
404 fi
405 fi
406 if test "x$glib_cv_va_val_copy" = "xno"; then
407   AC_DEFINE(G_VA_COPY_AS_ARRAY)
408 fi
409 AC_MSG_RESULT($glib_cv_va_val_copy)
410
411
412 dnl ***********************
413 dnl *** g_module checks ***
414 dnl ***********************
415 G_MODULE_LIBS=
416 G_MODULE_LDFLAGS=
417 G_MODULE_IMPL=
418 G_MODULE_NEED_USCORE=0
419 G_MODULE_HAVE_DLERROR=0
420 dnl *** dlopen() in system libraries
421 if test -z "$G_MODULE_IMPL"; then
422         AC_CHECK_FUNC(dlopen,
423                 G_MODULE_IMPL=G_MODULE_IMPL_DL
424         ,)
425 fi
426 dnl *** dlopen() in libdl
427 if test -z "$G_MODULE_IMPL"; then
428         AC_CHECK_LIB(dl, dlopen,
429                 G_MODULE_LIBS=-ldl
430                 G_MODULE_IMPL=G_MODULE_IMPL_DL
431         ,)
432 fi
433 dnl *** shl_load() in libdld (HP-UX)
434 if test -z "$G_MODULE_IMPL"; then
435         AC_MSG_CHECKING(how to export all symbols)
436         SAVED_LDFLAGS=$LDFLAGS
437         LDFLAGS="$LDFLAGS -Wl,-E"
438         AC_TRY_LINK(,[ return 0; ],
439                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
440                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
441                 AC_TRY_LINK(,[ return 0; ],
442                         G_MODULE_LDFLAGS="-bexpall",
443                         G_MODULE_LDFLAGS="none"
444                 )
445         ])
446         LDFLAGS=$SAVED_LDFLAGS
447         AC_MSG_RESULT($G_MODULE_LDFLAGS)
448         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
449                 G_MODULE_LDFLAGS=
450         fi
451         AC_CHECK_LIB(dld, shl_load,
452                 G_MODULE_LIBS=-ldld
453                 G_MODULE_IMPL=G_MODULE_IMPL_DLD
454         ,)
455 fi
456 dnl *** additional checks for G_MODULE_IMPL_DL
457 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
458         case "$host_os" in
459           linux*)
460             G_MODULE_LDFLAGS='-rdynamic'
461             ;;
462         esac
463         LIBS_orig="$LIBS"
464         LDFLAGS_orig="$LDFLAGS"
465         LIBS="$LIBS $G_MODULE_LIBS"
466         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
467 dnl *** check whether we need preceeding underscores
468         AC_MSG_CHECKING(for preceeding underscore in symbols)
469         AC_CACHE_VAL(glib_cv_uscore,[
470                 AC_TRY_RUN([
471                 #include <dlfcn.h>
472                 int glib_underscore_test (void) { return 42; }
473                 int main() {
474                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
475                   handle = dlopen ((void*)0, 0);
476                   if (handle) {
477                     f1 = dlsym (handle, "glib_underscore_test");
478                     f2 = dlsym (handle, "_glib_underscore_test");
479                   } return (!f2 || f1);
480                 }],     
481                         glib_cv_uscore=yes,     
482                         glib_cv_uscore=no,
483                 )
484                 rm -f plugin.c plugin.o plugin.lo
485         ])
486         AC_MSG_RESULT($glib_cv_uscore)  
487         if test "x$glib_cv_uscore" = "xyes"; then
488                 G_MODULE_NEED_USCORE=1
489         else
490                 G_MODULE_NEED_USCORE=0
491         fi      
492         
493         LDFLAGS="$LDFLAGS_orig"
494 dnl *** check for having dlerror()
495         AC_CHECK_FUNC(dlerror,
496                 G_MODULE_HAVE_DLERROR=1,
497                 G_MODULE_HAVE_DLERROR=0)
498         LIBS="$LIBS_orig"
499 fi
500 dnl *** done, have e got an implementation?
501 if test -z "$G_MODULE_IMPL"; then
502         G_MODULE_IMPL=0
503 fi
504 AC_SUBST(G_MODULE_IMPL)
505 AC_SUBST(G_MODULE_LIBS)
506 AC_SUBST(G_MODULE_LDFLAGS)
507 AC_SUBST(G_MODULE_HAVE_DLERROR)
508 AC_SUBST(G_MODULE_NEED_USCORE)
509 AC_SUBST(GLIB_DEBUG_FLAGS)
510
511
512 dnl ***********************
513 dnl *** g_thread checks ***
514 dnl ***********************
515
516 AC_ARG_WITH(threads, [  --with-threads=[none/posix/solaris/nspr] specify a thread implementation to use.],
517         if test "x$with_threads" = x; then
518                 want_threads=yes
519         else
520                 want_threads=$with_threads
521         fi,
522         want_threads=yes)
523 if test "x$want_threads" = "xnone"; then
524         want_threads=no
525 fi
526
527 dnl error and warning message
528 dnl *************************
529
530 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
531                 computer. glib will not be thread safe on your computer."
532
533 THREAD_UNKNOWN_COMPILER="Your compiler is not known, so I cannot
534                 determine the necessary compiler options to compile programs 
535                 which are using threads. Please provide such information."
536
537 FLAG_DOES_NOT_WORK="I can't find the MACRO, that enables thread safety on your
538                 platform (normaly it's "_REENTRANT"). I'll not use any flag on
539                 compilation now, but then your programs might not work. 
540                 Please provide information on how it is done on your system."
541
542 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
543                 "
544
545 LIBS_NOT_FOUND_2=". Please choose another thread implementation or 
546                 provide informationon your thread implementation."
547
548 dnl determination of thread implementation
549 dnl ***************************************
550
551 have_threads=none
552 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
553         case $host in
554                 *-*-solaris*)
555                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
556                 ;;
557         esac
558 fi
559 if test "x$want_threads" = xyes || test "x$want_threads" = xposix; then
560         if test "x$have_threads" = xnone; then
561                 AC_CHECK_LIB(pthread, pthread_cond_init, have_threads=posix)
562         fi
563         if test "x$have_threads" = xnone; then
564                 AC_CHECK_LIB(pthreads, pthread_cond_init, have_threads=posix)
565         fi
566         if test "x$have_threads" = xnone; then
567                 # dont let us be fooled by a defined pthread_cond_init
568                 # function in the standard c-lib, that doesn't have too mean, 
569                 # there is full thread support, it might be a weak symbol.
570                 AC_CHECK_FUNC(pthread_attr_init, have_threads=posix)
571         fi
572 fi
573 if test "x$want_threads" = xyes || test "x$want_threads" = xnspr; then
574         if test "x$have_threads" = xnone; then
575                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar, have_threads=nspr)
576         fi
577 fi
578
579 AC_MSG_CHECKING(for thread implementation)
580
581 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
582         AC_MSG_RESULT(none available)
583         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
584 else
585         AC_MSG_RESULT($have_threads)
586 fi
587
588
589 dnl determination of G_THREAD_LIBS
590 dnl ******************************
591
592 G_THREAD_LIBS=
593
594 case $have_threads in
595         posix)
596                 G_THREAD_LIBS=error
597                 AC_CHECK_LIB(pthread, pthread_cond_init,
598                              G_THREAD_LIBS="-lpthread") 
599                 if test "x$G_THREAD_LIBS" = xerror; then
600                         AC_CHECK_LIB(pthreads, pthread_cond_init,
601                                 G_THREAD_LIBS="-lpthreads")
602                 fi
603                 if test "x$G_THREAD_LIBS" = xerror; then
604                         AC_CHECK_FUNC(pthread_cond_init, G_THREAD_LIBS="")
605                 fi
606                 ;;
607         solaris)
608                 G_THREAD_LIBS=error
609                 AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
610                 # solaris has a broken initializer for mutexes, if we find it,
611                 # we will replace it.
612                 AC_MSG_CHECKING(for broken solaris mutex initialization)
613                 AC_EGREP_CPP([ *begin *{ *0 *, *0 *, *0 *, *0 *, *0 *, *0 *, *0 *, *0 *, *0 *, *0 *, *0 *, *0 *, *0 *, *0 *} *end *],
614                              [#include <thread.h>
615                              begin DEFAULTMUTEX end],
616                              [solaris_mutex_init_broken=yes],
617                              [solaris_mutex_init_broken=no])
618                 AC_MSG_RESULT($solaris_mutex_init_broken)
619                 ;;
620         nspr)
621                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar,
622                              G_THREAD_LIBS="-lnspr21")
623                 ;;
624         none)
625                 ;;
626         *)
627                 G_THREAD_LIBS=error
628                 ;;
629 esac
630
631 if test "x$G_THREAD_LIBS" = xerror; then
632         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
633 fi
634
635 AC_MSG_CHECKING(necessary linker options)
636 AC_MSG_RESULT($G_THREAD_LIBS)
637
638 dnl determination of G_THREAD_CFLAGS
639 dnl ********************************
640
641 if test x"$have_threads" != xnone; then
642         G_THREAD_CFLAGS="-D_REENTRANT" # good default
643
644         case $host in
645                *-aix*)
646                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
647                         if test x"$GCC" = xyes; then 
648                                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
649                         fi
650                         ;;
651         esac
652
653         # if we are not finding the ctime_r function, then we probably are 
654         # not using the proper multithread flag
655         old_CPPFLAGS=$CPPFLAGS
656         CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
657         AC_EGREP_HEADER([[^a-zA-Z_]ctime_r[^a-zA-Z_]], time.h, , 
658                 G_THREAD_CFLAGS=
659                 AC_MSG_WARN($FLAG_DOES_NOT_WORK))
660         CPPFLAGS=$old_CPPFLAGS
661                 
662 #       if test x"$GCC" = xyes; then    
663 #               # older gcc's do not know the -fstack-check option and will
664 #               # stop compiling, so just check this here 
665 #               old_CPPFLAGS="$CPPFLAGS"
666 #               CPPFLAGS="$CPPFLAGS -fstack-check"
667 #               AC_TRY_COMPILE(,,
668 #                       G_THREAD_CFLAGS="$G_THREAD_CFLAGS -fstack-check")
669 #               CPPFLAGS=$old_CPPFLAGS
670 #       else
671 #               AC_MSG_WARN($THREAD_UNKNOWN_COMPILER)
672 #       fi
673
674         AC_MSG_CHECKING(necessary compiler options)
675
676         AC_MSG_RESULT($G_THREAD_CFLAGS)
677 else
678         G_THREAD_CFLAGS=
679 fi
680
681 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c")
682 AC_SUBST(G_THREAD_CFLAGS)
683 AC_SUBST(G_THREAD_LIBS)
684
685 CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
686
687 dnl ******************************
688 dnl *** output the whole stuff ***
689 dnl ******************************
690
691 AC_OUTPUT_COMMANDS([
692
693 ## Generate `glibconfig.h' in two cases
694 ## 1. `config.status' is run either explicitly, or via configure.
695 ##     Esp. not when it is run in `Makefile' to generate makefiles and
696 ##     config.h
697 ## 2. CONFIG_OTHER is set explicitly
698 ##
699 ## Case 1 is difficult.  We know that `automake' sets one of
700 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
701 ## only when AM_CONFIG_HEADER is set, however.  
702
703 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
704   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
705   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
706 fi
707 case "$CONFIG_OTHER" in
708 *glibconfig.h*)
709   echo creating glibconfig.h
710   outfile=glibconfig.h-tmp
711   cat > $outfile <<\outfile_EOF
712 /* glibconfig.h */
713 /* This is a generated file.  Please modify `configure.in' */
714
715 #ifndef GLIBCONFIG_H
716 #define GLIBCONFIG_H
717
718 #ifdef __cplusplus
719 extern "C" {
720 #endif /* __cplusplus */
721
722 outfile_EOF
723
724   if test x$glib_limits_h = xyes; then
725     echo '#include <limits.h>' >> $outfile
726   fi 
727   if test x$glib_float_h = xyes; then
728     echo '#include <float.h>' >> $outfile
729   fi 
730   if test x$glib_values_h = xyes; then
731     echo '#include <values.h>' >> $outfile
732   fi
733   if test x$g_mutex_header_file != x; then
734     echo '#include <'"$g_mutex_header_file"'>' >> $outfile
735   fi
736   if test x$glib_sys_poll_h = xyes; then
737     echo '#include <sys/types.h>' >> $outfile
738     echo '#include <sys/poll.h>' >> $outfile
739   fi
740
741   cat >> $outfile <<outfile_EOF
742
743 #define G_MINFLOAT $glib_mf
744 #define G_MAXFLOAT $glib_Mf
745 #define G_MINDOUBLE $glib_md
746 #define G_MAXDOUBLE $glib_Md
747 #define G_MINSHORT $glib_ms
748 #define G_MAXSHORT $glib_Ms
749 #define G_MININT $glib_mi
750 #define G_MAXINT $glib_Mi
751 #define G_MINLONG $glib_ml
752 #define G_MAXLONG $glib_Ml
753
754 outfile_EOF
755
756   ## this should always be true in a modern C/C++ compiler
757   cat >>$outfile <<outfile_EOF
758 typedef signed char gint8;
759 typedef unsigned char guint8;
760 outfile_EOF
761
762   if test -n "$gint16"; then
763     cat >>$outfile <<outfile_EOF
764 typedef signed $gint16 gint16;
765 typedef unsigned $gint16 guint16;
766 outfile_EOF
767   fi
768   if test -n "$gint32"; then
769     cat >>$outfile <<outfile_EOF
770 typedef signed $gint32 gint32;
771 typedef unsigned $gint32 guint32;
772 outfile_EOF
773   fi 
774   if test -n "$gint64"; then
775     cat >>$outfile <<outfile_EOF
776 ${glib_warning_guard}#define G_HAVE_GINT64 1
777
778 ${glib_extension}typedef signed $gint64 gint64;
779 ${glib_extension}typedef unsigned $gint64 guint64;
780
781 #define G_GINT64_CONSTANT(val)  $gint64_constant
782 outfile_EOF
783   fi 
784
785   if test -z "$glib_unknown_void_p"; then
786     cat >>$outfile <<outfile_EOF
787
788 #define GPOINTER_TO_INT(p)      ((gint)${glib_gpi_cast}(p))
789 #define GPOINTER_TO_UINT(p)     ((guint)${glib_gpui_cast}(p))
790
791 #define GINT_TO_POINTER(i)      ((gpointer)${glib_gpi_cast}(i))
792 #define GUINT_TO_POINTER(u)     ((gpointer)${glib_gpui_cast}(u))
793 outfile_EOF
794   else
795     echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
796   fi
797
798   cat >>$outfile <<outfile_EOF
799 $glib_atexit
800 $glib_memmove
801 $glib_defines
802
803 $glib_vacopy
804
805 #ifdef  __cplusplus
806 #define G_HAVE_INLINE   1
807 #else   /* !__cplusplus */
808 $glib_inline
809 #endif  /* !__cplusplus */
810
811 #define G_BYTE_ORDER $g_byte_order
812 outfile_EOF
813
814 cat >>$outfile <<outfile_EOF                                               
815
816 /* definitions for the default mutex implementation */
817 outfile_EOF
818
819   if test x$g_mutex_has_default = xyes; then
820 cat >>$outfile <<outfile_EOF                                               
821
822 typedef struct _GStaticMutex GStaticMutex;
823 struct _GStaticMutex 
824 {
825   $g_mutex_default_type default_mutex;
826   struct _GMutex* runtime_mutex;
827 };
828 #define G_STATIC_MUTEX_INIT { $g_mutex_default_init, NULL }
829 #define g_static_mutex_get_mutex(mutex) \
830   ( g_thread_use_default_impl ? (GMutex*)&mutex.default_mutex : \
831     g_static_mutex_get_mutex_impl(&mutex.runtime_mutex) )
832 outfile_EOF
833   else
834 cat >>$outfile <<outfile_EOF                                               
835
836 typedef struct _GMutex* GStaticMutex;
837 #define G_STATIC_MUTEX_INIT NULL
838 #define g_static_mutex_get_mutex(mutex) g_static_mutex_get_mutex_impl(&mutex)
839 outfile_EOF
840   fi
841
842   g_bit_sizes="16 32"
843   if test -n "$gint64"; then
844     g_bit_sizes="$g_bit_sizes 64"
845   fi
846
847   for bits in $g_bit_sizes; do                                                  
848     cat >>$outfile <<outfile_EOF                                               
849
850 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
851 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
852 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
853 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
854 outfile_EOF
855 done
856
857   cat >>$outfile <<outfile_EOF
858
859 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
860 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
861 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
862 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
863
864 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
865 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
866 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
867 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
868 $glib_wc
869
870 #ifdef __cplusplus
871 }
872 #endif /* __cplusplus */
873
874 #endif /* GLIBCONFIG_H */
875
876 outfile_EOF
877
878   if cmp -s $outfile glibconfig.h; then
879     echo glibconfig.h is unchanged
880     rm -f $outfile
881   else
882     mv $outfile glibconfig.h
883   fi ;;
884 esac
885 ],[
886
887 # Note that if two cases are the same, case goes with the first one.
888 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
889 # on variable expansion in case labels.  Look at the generated config.status
890 # for a hint.
891
892 case xyes in
893 x$ac_cv_header_float_h)
894   glib_float_h=yes
895   glib_mf=FLT_MIN glib_Mf=FLT_MAX
896   glib_md=DBL_MIN glib_Md=DBL_MAX
897   ;;
898 x$ac_cv_header_values_h)
899   glib_values_h=yes
900   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
901   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
902   ;;
903 esac
904
905 case xyes in
906 x$ac_cv_header_limits_h)
907   glib_limits_h=yes
908   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX
909   glib_mi=INT_MIN  glib_Mi=INT_MAX
910   glib_ml=LONG_MIN glib_Ml=LONG_MAX
911   ;;
912 x$ac_cv_header_values_h)
913   glib_values_h=yes
914   glib_ms=MINSHORT glib_Ms=MAXSHORT
915   glib_mi=MININT   glib_Mi=MAXINT
916   glib_ml=MINLONG  glib_Ml=MAXLONG
917   ;;
918 esac
919
920 if test x$ac_cv_header_sys_poll_h = xyes ; then
921   glib_sys_poll_h=yes
922 fi
923
924 case 2 in
925 $ac_cv_sizeof_short)            gint16=short;;
926 $ac_cv_sizeof_int)              gint16=int;;
927 esac
928 case 4 in
929 $ac_cv_sizeof_short)            gint32=short;;
930 $ac_cv_sizeof_int)              gint32=int;;
931 $ac_cv_sizeof_long)             gint32=long;;
932 esac
933 case 8 in
934 $ac_cv_sizeof_int)
935   gint64=int
936   glib_extension=
937   glib_warning_guard=
938   gint64_constant='(val)'
939   ;;
940 $ac_cv_sizeof_long)
941   gint64=long
942   glib_extension=
943   glib_warning_guard=
944   gint64_constant='(val##L)'
945   ;;
946 $ac_cv_sizeof_long_long)
947   gint64='long long'
948   glib_extension='GLIB_WARNINGS_MAKE_PEOPLE_CRY '
949   glib_warning_guard="
950 #if defined (__GNUC__) && __GNUC__ >= 2 && __GNUC_MINOR__ >= 8
951 #  define GLIB_WARNINGS_MAKE_PEOPLE_CRY __extension__
952 #else
953 #  define GLIB_WARNINGS_MAKE_PEOPLE_CRY
954 #endif
955
956 "
957   gint64_constant='(GLIB_WARNINGS_MAKE_PEOPLE_CRY (val##LL))'
958   ;;
959 esac
960
961 gintbits=`expr $ac_cv_sizeof_int \* 8`
962 glongbits=`expr $ac_cv_sizeof_long \* 8`
963
964
965 case $ac_cv_sizeof_void_p in
966 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
967 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
968 *)                      glib_unknown_void_p=yes ;;
969 esac
970
971
972 case xyes in
973 x$ac_cv_func_atexit)
974   glib_atexit="
975 #ifdef NeXT /* @#%@! NeXTStep */
976 # define g_ATEXIT(proc) (!atexit (proc))
977 #else
978 # define g_ATEXIT(proc) (atexit (proc))
979 #endif"
980   ;;
981 x$ac_cv_func_on_exit)
982   glib_atexit="
983 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
984   ;;
985 esac
986
987 case xyes in
988 x$ac_cv_func_memmove)
989   glib_memmove='
990 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
991   ;;
992 *)
993   glib_memmove="
994 /* We make the assumption that if memmove isn't available, then
995  * bcopy will do the job. This isn't safe everywhere. (bcopy can't
996  * necessarily handle overlapping copies) */
997 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
998   ;;
999 esac
1000
1001 glib_defines="
1002 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
1003 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
1004 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
1005 "
1006
1007 case xyes in
1008 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
1009 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
1010 *)                      glib_vacopy=''
1011 esac
1012
1013 if test x$glib_cv_va_val_copy = xno; then
1014   glib_vacopy="\$glib_vacopy
1015 #define G_VA_COPY_AS_ARRAY 1"
1016 fi
1017
1018 if test x$glib_cv_hasinline = xyes; then
1019     glib_inline='#define G_HAVE_INLINE 1'
1020 fi
1021 if test x$glib_cv_has__inline = xyes; then
1022     glib_inline="\$glib_inline
1023 #define G_HAVE___INLINE 1"
1024 fi
1025 if test x$glib_cv_has__inline__ = xyes; then
1026     glib_inline="\$glib_inline
1027 #define G_HAVE___INLINE__ 1"
1028 fi
1029
1030 case xyes in
1031 x$ac_cv_c_bigendian)
1032   g_byte_order=G_BIG_ENDIAN
1033   g_bs_native=BE
1034   g_bs_alien=LE
1035   ;;
1036 *)
1037   g_byte_order=G_LITTLE_ENDIAN
1038   g_bs_native=LE
1039   g_bs_alien=BE
1040   ;;
1041 esac
1042
1043 if test x$glib_wchar_h = xyes; then
1044   glib_wc='
1045 #define G_HAVE_WCHAR_H 1'
1046 fi
1047 if test x$glib_wctype_h = xyes; then
1048   glib_wc="\$glib_wc
1049 #define G_HAVE_WCTYPE_H 1"
1050 fi
1051 if test x$glib_working_wctype = xno; then
1052   glib_wc="\$glib_wc
1053 #define G_HAVE_BROKEN_WCTYPE 1"
1054 fi
1055
1056 case $have_threads in
1057         posix)
1058                 g_mutex_has_default=yes
1059                 g_mutex_default_type='pthread_mutex_t'
1060                 g_mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
1061                 g_mutex_header_file='pthread.h'
1062                 ;;
1063         solaris)
1064                 g_mutex_has_default=yes
1065                 g_mutex_default_type='mutex_t'
1066                 if test x$solaris_mutex_init_broken = xyes; then
1067                   g_mutex_default_init="{ { { 0, 0, 0, 0 }, USYNC_THREAD }, { { { 0, 0, 0, 0, 0, 0, 0, 0 } } }, 0}"
1068                 else
1069                   g_mutex_default_init="DEFAULTMUTEX"
1070                 fi
1071                 g_mutex_header_file='thread.h'
1072                 ;;
1073         nspr)
1074                 g_mutex_has_default=no
1075                 ;;
1076         *)              
1077                 g_mutex_has_default=no
1078                 ;;
1079 esac
1080 ])
1081
1082 AC_OUTPUT([
1083 Makefile
1084 glib-config
1085 gmodule/gmoduleconf.h
1086 gmodule/Makefile
1087 gthread/Makefile
1088 docs/Makefile
1089 ],[case "$CONFIG_FILES" in
1090 *glib-config*)chmod +x glib-config;;
1091 esac])