configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 dnl ***********************************
   6 dnl *** include special GLib macros ***
   7 dnl ***********************************
   8
   9 m4_define(glib_configure_in)
  10 m4_include(acglib.m4)dnl
  11 m4_include(glib/libcharset/codeset.m4)dnl
  12 m4_include(glib/libcharset/glibc21.m4)dnl
  13 m4_include(m4macros/glib-gettext.m4)dnl
  14
  15 #
  16 # The following version number definitions apply to GLib, GModule, GObject
  17 # and GThread as a whole, so if changes occoured in any of them, they are all
  18 # treated with the same interface and binary age.
  19 #
  20 # Making releases:
  21 #   glib_micro_version += 1;
  22 #   glib_interface_age += 1;
  23 #   glib_binary_age += 1;
  24 # if any functions have been added, set glib_interface_age to 0.
  25 # if backwards compatibility has been broken,
  26 # set glib_binary_age _and_ glib_interface_age to 0.
  27 #
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [3])
  30 m4_define([glib_micro_version], [2])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_SRCDIR([glib/glib.h])
  56
  57 # Save this value here, since automake will set cflags later
  58 cflags_set=${CFLAGS+set}
  59
  60 AM_INIT_AUTOMAKE([no-define])
  61
  62 # Specify a configuration file
  63 AM_CONFIG_HEADER([config.h])
  64
  65
  66 GLIB_MAJOR_VERSION=glib_major_version
  67 GLIB_MINOR_VERSION=glib_minor_version
  68 GLIB_MICRO_VERSION=glib_micro_version
  69 GLIB_INTERFACE_AGE=glib_interface_age
  70 GLIB_BINARY_AGE=glib_binary_age
  71 GLIB_VERSION=glib_version
  72
  73 AC_SUBST(GLIB_MAJOR_VERSION)
  74 AC_SUBST(GLIB_MINOR_VERSION)
  75 AC_SUBST(GLIB_MICRO_VERSION)
  76 AC_SUBST(GLIB_VERSION)
  77 AC_SUBST(GLIB_INTERFACE_AGE)
  78 AC_SUBST(GLIB_BINARY_AGE)
  79
  80 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  81           [Define to the GLIB major version])
  82 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  83           [Define to the GLIB minor version])
  84 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  85           [Define to the GLIB micro version])
  86 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  87           [Define to the GLIB interface age])
  88 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  89           [Define to the GLIB binary age])
  90
  91 # libtool versioning
  92 LT_RELEASE=glib_lt_release
  93 LT_CURRENT=glib_lt_current
  94 LT_REVISION=glib_lt_revision
  95 LT_AGE=glib_lt_age
  96 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
  97 AC_SUBST(LT_RELEASE)
  98 AC_SUBST(LT_CURRENT)
  99 AC_SUBST(LT_REVISION)
 100 AC_SUBST(LT_AGE)
 101 AC_SUBST(LT_CURRENT_MINUS_AGE)
 102
 103 dnl Initialize maintainer mode
 104 AM_MAINTAINER_MODE
 105
 106 AC_CANONICAL_HOST
 107
 108 AC_MSG_CHECKING([for the BeOS])
 109 case $host in
 110   *-*-beos*)
 111     glib_native_beos="yes"
 112     ;;
 113   *)
 114     glib_native_beos="no"
 115     ;;
 116 esac
 117 AC_MSG_RESULT([$glib_native_beos])
 118
 119 dnl
 120
 121 AC_MSG_CHECKING([for Win32])
 122 case "$host" in
 123   *-*-mingw*)
 124     glib_native_win32=yes
 125     G_LIB_WIN32_RESOURCE=glib-win32res.lo
 126     G_MODULE_WIN32_RESOURCE=gmodule-win32res.lo
 127     G_OBJECT_WIN32_RESOURCE=gobject-win32res.lo
 128     G_THREAD_WIN32_RESOURCE=gthread-win32res.lo
 129     GLIB_DEF=glib.def
 130     GMODULE_DEF=gmodule.def
 131     GOBJECT_DEF=gobject.def
 132     GTHREAD_DEF=gthread.def
 133     TESTGMODULE_EXP=testgmodule.exp
 134     glib_pid_type=HANDLE
 135     ;;
 136   *)
 137     glib_native_win32=no
 138     G_LIB_WIN32_RESOURCE=
 139     G_MODULE_WIN32_RESOURCE=
 140     G_OBJECT_WIN32_RESOURCE=
 141     G_THREAD_WIN32_RESOURCE=
 142     GLIB_DEF=
 143     GMODULE_DEF=
 144     GOBJECT_DEF=
 145     GTHREAD_DEF=
 146     TESTGMODULE_EXP=
 147     glib_pid_type=int
 148     ;;
 149 esac
 150 AC_MSG_RESULT([$glib_native_win32])
 151 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 152 AC_SUBST(G_LIB_WIN32_RESOURCE)
 153 AC_SUBST(G_MODULE_WIN32_RESOURCE)
 154 AC_SUBST(G_OBJECT_WIN32_RESOURCE)
 155 AC_SUBST(G_THREAD_WIN32_RESOURCE)
 156 AC_SUBST(GLIB_DEF)
 157 AC_SUBST(GMODULE_DEF)
 158 AC_SUBST(GOBJECT_DEF)
 159 AC_SUBST(GTHREAD_DEF)
 160 AC_SUBST(TESTGMODULE_EXP)
 161
 162 if test "$glib_native_win32" = "yes"; then
 163   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 164 fi
 165 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 166
 167 dnl declare --enable-* args and collect ac_help strings
 168 AC_ARG_ENABLE(debug,
 169               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 170                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 171               enable_debug=glib_debug_default)
 172
 173 AC_ARG_ENABLE(gc_friendly,
 174               [AC_HELP_STRING([--enable-gc-friendly],
 175                               [turn on garbage collector friendliness [default=no]])],,
 176               [enable_gc_friendly=no])
 177 AC_ARG_ENABLE(mem_pools,
 178               [AC_HELP_STRING([--disable-mem-pools],
 179                               [disable all glib memory pools])],,
 180               [disable_mem_pools=no])
 181 AC_ARG_ENABLE(ansi,
 182               [AC_HELP_STRING([--enable-ansi],
 183                               [turn on strict ansi [default=no]])],,
 184               [enable_ansi=no])
 185 AC_ARG_ENABLE(threads,
 186               [AC_HELP_STRING([--enable-threads],
 187                               [turn on basic thread support [default=yes]
 188 ([=no] will override --with-threads)])],,
 189               [enable_threads=yes])
 190 AC_ARG_ENABLE(rebuilds,
 191               [AC_HELP_STRING([--disable-rebuilds],
 192                               [disable all source autogeneration rules])],,
 193               [enable_rebuilds=yes])
 194
 195 if test "x$enable_threads" != "xyes"; then
 196   enable_threads=no
 197 fi
 198
 199 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, ["${enable_debug}"],
 200         [Whether glib was compiled with debugging enabled])
 201
 202 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 203 if test "x$enable_gc_friendly" = "xyes"; then
 204   AC_DEFINE(ENABLE_GC_FRIENDLY, 1, [Whether to enable GC friendliness])
 205   AC_SUBST(ENABLE_GC_FRIENDLY)
 206   AC_MSG_RESULT([yes])
 207 else
 208   AC_MSG_RESULT([no])
 209 fi
 210
 211 AC_MSG_CHECKING([whether to disable memory pools])
 212 if test "x$disable_mem_pools" = "xno"; then
 213   AC_MSG_RESULT([no])
 214 else
 215   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 216   AC_SUBST(DISABLE_MEM_POOLS)
 217   AC_MSG_RESULT([yes])
 218 fi
 219
 220 if test "$glib_native_win32" = "yes"; then
 221   if test x$enable_static = xyes -o x$enable_static = x; then
 222     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 223     enable_static=no
 224   fi
 225   if test x$enable_shared = xno; then
 226     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 227   fi
 228   enable_shared=yes
 229 fi
 230
 231 dnl Checks for programs.
 232 AC_PROG_CC
 233
 234 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 235 AC_CHECK_PROGS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 236 AC_LANG_SAVE
 237 AC_LANG_CPLUSPLUS
 238 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 239 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 240 AC_LANG_RESTORE
 241
 242 AM_PROG_CC_STDC
 243 AC_PROG_INSTALL
 244
 245 AC_SYS_LARGEFILE
 246
 247 #
 248 # Find pkg-config
 249 #
 250 AC_PATH_PROG(PKG_CONFIG, [pkg-config], [no])
 251 if test x$PKG_CONFIG = xno ; then
 252   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
 253 fi
 254
 255 if $PKG_CONFIG --atleast-pkgconfig-version 0.14 ; then
 256   :
 257 else
 258   AC_MSG_ERROR([*** pkg-config too old; version 0.14 or better required.])
 259 fi
 260
 261 if test "x$enable_debug" = "xyes"; then
 262   if test x$cflags_set != xset ; then
 263       case " $CFLAGS " in
 264       *[[\ \    ]]-g[[\ \       ]]*) ;;
 265       *) CFLAGS="$CFLAGS -g" ;;
 266       esac
 267   fi
 268
 269   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 270 else
 271   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 272
 273   if test "x$enable_debug" = "xno"; then
 274     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 275   fi
 276 fi
 277
 278 # Ensure MSVC-compatible struct packing convention is used when
 279 # compiling for Win32 with gcc.
 280 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 281 # gcc2 uses "-fnative-struct".
 282 if test x"$glib_native_win32" = xyes; then
 283   if test x"$GCC" = xyes; then
 284     msnative_struct=''
 285     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 286     if test -z "$ac_cv_prog_CC"; then
 287       our_gcc="$CC"
 288     else
 289       our_gcc="$ac_cv_prog_CC"
 290     fi
 291     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 292       2.)
 293         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 294           msnative_struct='-fnative-struct'
 295         fi
 296         ;;
 297       *)
 298         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 299           msnative_struct='-mms-bitfields'
 300         fi
 301         ;;
 302     esac
 303     if test x"$msnative_struct" = x ; then
 304       AC_MSG_RESULT([no way])
 305       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 306     else
 307       CFLAGS="$CFLAGS $msnative_struct"
 308       AC_MSG_RESULT([${msnative_struct}])
 309     fi
 310   fi
 311 fi
 312
 313 AC_CYGWIN
 314 AC_EXEEXT
 315
 316 # define a MAINT-like variable REBUILD which is set if Perl
 317 # and awk are found, so autogenerated sources can be rebuilt
 318 AC_PROG_AWK
 319 AC_CHECK_PROGS(PERL, [perl5 perl])
 320 # We would like indent, but don't require it.
 321 AC_CHECK_PROG(INDENT, indent, indent)
 322 REBUILD=\#
 323 if test "x$enable_rebuilds" = "xyes" && \
 324      test -n "$PERL" && \
 325      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 326      test -n "$AWK" ; then
 327   REBUILD=
 328 fi
 329 AC_SUBST(REBUILD)
 330
 331 # Need full path to Perl for glib-mkenums
 332 #
 333 if test "x$PERL" != x ; then
 334   AC_PATH_PROG(PERL_PATH, [$PERL])
 335 else
 336   PERL_PATH="/usr/bin/env perl"
 337 fi
 338 AC_SUBST(PERL_PATH)
 339
 340 dnl ***********************
 341 dnl *** Tests for iconv ***
 342 dnl ***********************
 343 dnl
 344 dnl We do this before the gettext checks, to avoid distortion
 345
 346 AC_ARG_WITH(libiconv,
 347             [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 348                             [use the libiconv library])],,
 349             [with_libiconv=maybe])
 350
 351 found_iconv=no
 352 case $with_libiconv in
 353   maybe)
 354     # Check in the C library first
 355     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 356     # Check if we have GNU libiconv
 357     if test $found_iconv = "no"; then
 358       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 359     fi
 360     # Check if we have a iconv in -liconv, possibly from vendor
 361     if test $found_iconv = "no"; then
 362       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 363     fi
 364     ;;
 365   no)
 366     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 367     ;;
 368   gnu|yes)
 369     AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 370     ;;
 371   native)
 372     AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 373     ;;
 374 esac
 375
 376 if test "x$found_iconv" = "xno" ; then
 377    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 378 fi
 379
 380 dnl
 381 dnl gettext support
 382 dnl
 383
 384 ALL_LINGUAS="am ar az be bg bn ca cs cy da de el eo es et eu fa fi fr gl he hi hr id is it ja ko lt lv mk mn ms nl nn no pl pt pt_BR ro ru sk sl sq sr sr@Latn sv ta tr uk vi yi zh_CN zh_TW"
 385 GLIB_GNU_GETTEXT
 386
 387 if test "$gt_cv_have_gettext" != "yes" ; then
 388   AC_MSG_ERROR([
 389 *** You must have either have gettext support in your C library, or use the
 390 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 391 ])
 392 fi
 393
 394 LIBS="$INTLLIBS $LIBS"
 395
 396 GETTEXT_PACKAGE=glib20
 397 AC_SUBST(GETTEXT_PACKAGE)
 398 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 399   [Define the gettext package to be used])
 400
 401 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 402
 403 dnl
 404 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 405 dnl
 406
 407 if test x$with_libiconv != xno ; then
 408   case " $INTLLIBS " in
 409   *[[\ \        ]]-liconv[[\ \  ]]*) ;;
 410   *) ICONV_LIBS="-liconv" ;;
 411   esac
 412 fi
 413 AC_SUBST(ICONV_LIBS)
 414
 415 case $with_libiconv in
 416   gnu)
 417     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 418     ;;
 419   native)
 420     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 421     ;;
 422 esac
 423
 424 dnl Initialize libtool
 425 AM_DISABLE_STATIC
 426 AM_PROG_LIBTOOL
 427
 428 if test "x$GCC" = "xyes"; then
 429   case " $CFLAGS " in
 430   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 431   *) CFLAGS="$CFLAGS -Wall" ;;
 432   esac
 433
 434   if test "x$enable_ansi" = "xyes"; then
 435     case " $CFLAGS " in
 436     *[[\ \      ]]-ansi[[\ \    ]]*) ;;
 437     *) CFLAGS="$CFLAGS -ansi" ;;
 438     esac
 439
 440     case " $CFLAGS " in
 441     *[[\ \      ]]-pedantic[[\ \        ]]*) ;;
 442     *) CFLAGS="$CFLAGS -pedantic" ;;
 443     esac
 444   fi
 445 fi
 446
 447 dnl
 448 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 449 dnl
 450 if test $cross_compiling != yes ; then
 451     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 452     glib_save_LIBS=$LIBS
 453     LIBS="$LIBS -lm"
 454     AC_TRY_RUN([#include <math.h>
 455                  int main (void) { return (log(1) != log(1.)); }],
 456          AC_MSG_RESULT(none needed),
 457          glib_save_CFLAGS=$CFLAGS
 458          CFLAGS="$CFLAGS -std1"
 459          AC_TRY_RUN([#include <math.h>
 460                      int main (void) { return (log(1) != log(1.)); }],
 461              AC_MSG_RESULT(-std1),
 462              AC_MSG_RESULT()
 463              CFLAGS=$glib_save_CFLAGS
 464              AC_MSG_WARN(
 465                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 466          )
 467     )
 468     LIBS=$glib_save_LIBS
 469 fi
 470
 471 dnl NeXTStep cc seems to need this
 472 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 473 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 474   AC_MSG_RESULT(none needed),
 475   glib_save_CFLAGS=$CFLAGS
 476   CFLAGS="$CFLAGS -posix"
 477   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 478     AC_MSG_RESULT(-posix),
 479     AC_MSG_RESULT()
 480     CFLAGS=$glib_save_CFLAGS
 481     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 482
 483 # Checks for header files.
 484 AC_HEADER_STDC
 485
 486 # Checks for library functions.
 487 AC_FUNC_VPRINTF
 488
 489 AC_FUNC_ALLOCA
 490
 491 AC_CHECK_FUNCS(atexit on_exit)
 492
 493 AC_CHECK_SIZEOF(char)
 494 AC_CHECK_SIZEOF(short)
 495 AC_CHECK_SIZEOF(long)
 496 AC_CHECK_SIZEOF(int)
 497 AC_CHECK_SIZEOF(void *)
 498 AC_CHECK_SIZEOF(long long)
 499 AC_CHECK_SIZEOF(__int64)
 500
 501 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 502   :
 503 else
 504   AC_MSG_ERROR([
 505 *** GLib requires a 64 bit type. You might want to consider
 506 *** using the GNU C compiler.
 507 ])
 508 fi
 509
 510 if test x$ac_cv_sizeof_long_long = x8; then
 511         # long long is a 64 bit integer.
 512         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 513         AC_CACHE_VAL(glib_cv_long_long_format,[
 514                 for format in ll q I64; do
 515                   AC_TRY_RUN([#include <stdio.h>
 516                         int main()
 517                         {
 518                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 519                           char buffer[1000];
 520                           sprintf (buffer, "%${format}u", a);
 521                           sscanf (buffer, "%${format}u", &b);
 522                           exit (b!=a);
 523                         }
 524                         ],
 525                         [glib_cv_long_long_format=${format}
 526                         break],
 527                         [],[:])
 528                 done])
 529         if test -n "$glib_cv_long_long_format"; then
 530           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 531           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 532         else
 533           AC_MSG_RESULT(none)
 534         fi
 535 elif test x$ac_cv_sizeof___int64 = x8; then
 536         # __int64 is a 64 bit integer.
 537         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 538         # We know this is MSVC, and what the formats are
 539         glib_cv_long_long_format=I64
 540         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 541         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 542         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing __int64 with format I64])
 543 fi
 544
 545 dnl long doubles were not used, and a portability problem
 546 dnl AC_C_LONG_DOUBLE
 547 AC_C_CONST
 548
 549 dnl ok, here we try to check whether the systems prototypes for
 550 dnl malloc and friends actually match the prototypes provided
 551 dnl by gmem.h (keep in sync). i currently only know how to check
 552 dnl this reliably with gcc (-Werror), improvements for other
 553 dnl compilers are apprechiated.
 554 SANE_MALLOC_PROTOS=no
 555 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 556 glib_save_CFLAGS=$CFLAGS
 557 if test "x$GCC" = "xyes"; then
 558   CFLAGS="$CFLAGS -Werror"
 559   AC_TRY_COMPILE([#include <stdlib.h>], [
 560     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 561     void* (*my_malloc_p)  (size_t)         = malloc;
 562     void  (*my_free_p)    (void*)          = free;
 563     void* (*my_realloc_p) (void*, size_t)  = realloc;
 564     my_calloc_p = 0;
 565     my_malloc_p = 0;
 566     my_free_p = 0;
 567     my_realloc_p = 0;
 568   ],
 569     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 570       [Define if you have correct malloc prototypes])
 571     SANE_MALLOC_PROTOS=yes)
 572 fi
 573 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 574 CFLAGS=$glib_save_CFLAGS
 575
 576 dnl
 577 dnl check in which direction the stack grows
 578 dnl
 579 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 580         AC_TRY_RUN([
 581         volatile int *a = 0, *b = 0;
 582         void foo (void);
 583         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 584         void foo (void) { volatile int x = 5; b = &x; }
 585         ],
 586         glib_cv_stack_grows=no
 587         ,
 588         glib_cv_stack_grows=yes
 589         ,)
 590 ])
 591
 592 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 593 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 594 dnl actually supported.
 595 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 596         AC_COMPILE_IFELSE([
 597         __inline int foo () { return 0; }
 598         int main () { return foo (); }
 599         ],
 600         glib_cv_has__inline=yes
 601         ,
 602         glib_cv_has__inline=no
 603         ,)
 604 ])
 605 case x$glib_cv_has__inline in
 606 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 607 esac
 608 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 609         AC_COMPILE_IFELSE([
 610         __inline__ int foo () { return 0; }
 611         int main () { return foo (); }
 612         ],
 613         glib_cv_has__inline__=yes
 614         ,
 615         glib_cv_has__inline__=no
 616         ,)
 617 ])
 618 case x$glib_cv_has__inline__ in
 619 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 620 esac
 621 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 622         AC_COMPILE_IFELSE([
 623         #undef inline
 624         inline int foo () { return 0; }
 625         int main () { return foo (); }
 626         ],
 627         glib_cv_hasinline=yes
 628         ,
 629         glib_cv_hasinline=no
 630         ,)
 631 ])
 632 case x$glib_cv_hasinline in
 633 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 634 esac
 635
 636 # check for flavours of varargs macros
 637 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 638 AC_TRY_COMPILE([],[
 639 int a(int p1, int p2, int p3);
 640 #define call_a(...) a(1,__VA_ARGS__)
 641 call_a(2,3);
 642 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 643 AC_MSG_RESULT($g_have_iso_c_varargs)
 644
 645 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 646 if test "$CXX" = ""; then
 647 dnl No C++ compiler
 648   g_have_iso_cxx_varargs=no
 649 else
 650   AC_LANG_CPLUSPLUS
 651   AC_TRY_COMPILE([],[
 652 int a(int p1, int p2, int p3);
 653 #define call_a(...) a(1,__VA_ARGS__)
 654 call_a(2,3);
 655 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 656   AC_LANG_C
 657 fi
 658 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 659
 660 AC_MSG_CHECKING(for GNUC varargs macros)
 661 AC_TRY_COMPILE([],[
 662 int a(int p1, int p2, int p3);
 663 #define call_a(params...) a(1,params)
 664 call_a(2,3);
 665 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 666 AC_MSG_RESULT($g_have_gnuc_varargs)
 667
 668 # check for bytesex stuff
 669 AC_C_BIGENDIAN
 670
 671 # check for header files
 672 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h sys/param.h sys/poll.h sys/select.h sys/types.h])
 673 AC_CHECK_HEADERS([sys/time.h sys/times.h unistd.h values.h stdint.h sched.h])
 674
 675 # Checks for libcharset
 676 jm_LANGINFO_CODESET
 677 jm_GLIBC21
 678 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 679 AC_CHECK_FUNCS(setlocale)
 680
 681 AC_MSG_CHECKING(whether make is GNU Make)
 682 STRIP_BEGIN=
 683 STRIP_END=
 684 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 685         STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
 686         STRIP_END=')'
 687         AC_MSG_RESULT(yes)
 688 else
 689         AC_MSG_RESULT(no)
 690 fi
 691 STRIP_DUMMY=
 692 AC_SUBST(STRIP_DUMMY)
 693 AC_SUBST(STRIP_BEGIN)
 694 AC_SUBST(STRIP_END)
 695
 696 # check additional type sizes
 697 AC_CHECK_SIZEOF(size_t)
 698
 699 dnl Try to figure out whether gsize, gssize should be long or int
 700 AC_MSG_CHECKING([for the appropriate definition for size_t])
 701
 702 case $ac_cv_sizeof_size_t in
 703   $ac_cv_sizeof_short)
 704       glib_size_type=short
 705       ;;
 706   $ac_cv_sizeof_int)
 707       glib_size_type=int
 708       ;;
 709   $ac_cv_sizeof_long)
 710       glib_size_type=long
 711       ;;
 712   *)  AC_MSG_ERROR([No type matching size_t in size])
 713       ;;
 714 esac
 715
 716 dnl If int/long are the same size, we see which one produces
 717 dnl warnings when used in the location as size_t. (This matters
 718 dnl on AIX with xlc)
 719 dnl
 720 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 721    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 722   GLIB_CHECK_COMPILE_WARNINGS([
 723 #include <stddef.h>
 724 int main ()
 725 {
 726   size_t s = 1;
 727   unsigned int *size_int = &s;
 728   return (int)*size_int;
 729 }
 730     ],glib_size_type=int,
 731       [GLIB_CHECK_COMPILE_WARNINGS([
 732 #include <stddef.h>
 733 int main ()
 734 {
 735    size_t s = 1;
 736    unsigned long *size_long = &s;
 737    return (int)*size_long;
 738 }
 739         ],glib_size_type=long)])
 740 fi
 741
 742 AC_MSG_RESULT(unsigned $glib_size_type)
 743
 744 # Check for some functions
 745 AC_CHECK_FUNCS(lstat strerror strsignal memmove mkstemp vsnprintf stpcpy strcasecmp strncasecmp poll getcwd nanosleep vasprintf setenv unsetenv getc_unlocked readlink symlink)
 746
 747 AC_FUNC_VSNPRINTF_C99
 748 AC_FUNC_PRINTF_UNIX98
 749
 750 #
 751 # Check whether to use an included printf
 752 #
 753
 754 AC_ARG_ENABLE(included-printf,
 755               [AC_HELP_STRING([--enable-included-printf],
 756                               [use included printf [default=auto]])],
 757               enable_included_printf="$enableval")
 758
 759 need_included_printf=no
 760 if test "x$enable_included_printf" = "xyes" ; then
 761   need_included_printf=yes
 762 fi
 763 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
 764   need_included_printf=yes
 765 fi
 766 if test "$ac_cv_func_printf_unix98" != "yes" ; then
 767   need_included_printf=yes
 768 fi
 769 if test "x$ac_cv_sizeof_long_long" = "x8" &&
 770    test -z "$glib_cv_long_long_format" ; then
 771   need_included_printf=yes
 772 fi
 773
 774 if test "x$enable_included_printf" = "xno" &&
 775    test "x$need_included_printf" = "xyes" ; then
 776   AC_MSG_ERROR([
 777 *** Your C library's printf doesn't appear to have the features that
 778 *** GLib needs, but you specified --enable-included-printf=no.])
 779 fi
 780
 781 enable_included_printf=$need_included_printf
 782
 783 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
 784 if test "$enable_included_printf" != "yes" ; then
 785   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
 786 else
 787   if test -z "$glib_cv_long_long_format" ; then
 788     glib_cv_long_long_format="ll"
 789   fi
 790   AC_DEFINE(HAVE_VASPRINTF,1)
 791 fi
 792
 793 # Checks needed for gnulib vasnprintf
 794 bh_C_SIGNED
 795 jm_AC_TYPE_LONG_LONG
 796 gt_TYPE_LONGDOUBLE
 797 gt_TYPE_WCHAR_T
 798 gt_TYPE_WINT_T
 799 AC_TYPE_SIZE_T
 800 AC_CHECK_TYPES(ptrdiff_t)
 801 jm_AC_TYPE_INTMAX_T
 802 AC_CHECK_FUNCS(snprintf)
 803 AC_FUNC_SNPRINTF_C99
 804
 805 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 806 # The check is borrowed from the PERL Configure script.
 807 if test "$ac_cv_func_memmove" != "yes"; then
 808   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 809     glib_cv_working_bcopy,[AC_TRY_RUN([
 810       int main() {
 811         char buf[128], abc[128], *b;
 812         int len, off, align;
 813         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 814         for (align = 7; align >= 0; align--) {
 815           for (len = 36; len; len--) {
 816             b = buf+align; bcopy(abc, b, len);
 817             for (off = 1; off <= len; off++) {
 818               bcopy(b, b+off, len); bcopy(b+off, b, len);
 819                 if (bcmp(b, abc, len)) return(1);
 820             }
 821           }
 822         }
 823         return(0);
 824       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 825
 826   GLIB_ASSERT_SET(glib_cv_working_bcopy)
 827   if test "$glib_cv_working_bcopy" = "yes"; then
 828     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 829   fi
 830 fi
 831
 832 # Check for sys_errlist
 833 AC_MSG_CHECKING(for sys_errlist)
 834 AC_TRY_LINK(, [
 835 extern char *sys_errlist[];
 836 extern int sys_nerr;
 837 sys_errlist[sys_nerr-1][0] = 0;
 838 ], glib_ok=yes, glib_ok=no)
 839 AC_MSG_RESULT($glib_ok)
 840 if test "$glib_ok" = "no"; then
 841     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 842 fi
 843
 844 # Check for sys_siglist
 845 AC_MSG_CHECKING(for sys_siglist)
 846 AC_TRY_LINK(, [
 847 extern char *sys_siglist[];
 848 exit (sys_siglist[0]);
 849 ], glib_ok=yes, glib_ok=no)
 850 AC_MSG_RESULT($glib_ok)
 851 if test "$glib_ok" = "no"; then
 852     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 853 fi
 854
 855 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 856 AC_MSG_CHECKING(for sys_siglist declaration)
 857 AC_TRY_COMPILE([#include <signal.h>], [
 858 strlen (sys_siglist[0]);
 859 ], glib_ok=yes, glib_ok=no)
 860 AC_MSG_RESULT($glib_ok)
 861 if test "$glib_ok" = "no"; then
 862     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 863 fi
 864
 865 # Check if <sys/select.h> needs to be included for fd_set
 866 AC_MSG_CHECKING([for fd_set])
 867 AC_TRY_COMPILE([#include <sys/types.h>],
 868         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 869 if test "$gtk_ok" = "yes"; then
 870     AC_MSG_RESULT([yes, found in sys/types.h])
 871 else
 872     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
 873     if test "$gtk_ok" = "yes"; then
 874         # *** FIXME: give it a different name
 875         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
 876         AC_MSG_RESULT([yes, found in sys/select.h])
 877     else
 878         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
 879         AC_MSG_RESULT(no)
 880     fi
 881 fi
 882
 883 dnl *** check for sane realloc() ***
 884 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
 885         AC_TRY_RUN([#include <stdlib.h>
 886         int main() {
 887           return realloc (0, sizeof (int)) == 0;
 888         }],
 889         [glib_cv_sane_realloc=yes],
 890         [glib_cv_sane_realloc=no],
 891         [glib_cv_sane_realloc=yes])
 892 ])
 893 if test x$glib_cv_sane_realloc = xyes; then
 894   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
 895 fi
 896
 897 dnl Check for nl_langinfo and CODESET
 898
 899 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
 900 AC_TRY_COMPILE([#include <langinfo.h>],
 901         [char *codeset = nl_langinfo (CODESET);],
 902    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
 903    have_codeset=yes,
 904    have_codeset=no)
 905 AC_MSG_RESULT($have_codeset)
 906
 907
 908 dnl ****************************************
 909 dnl *** strlcpy/strlcat                  ***
 910 dnl ****************************************
 911 # Check for strlcpy
 912 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
 913 AC_TRY_RUN([#include <stdlib.h>
 914 #include <string.h>
 915 int main() {
 916   char p[10];
 917   (void) strlcpy (p, "hi", 10);
 918   if (strlcat (p, "bye", 0) != 3)
 919     return 1;
 920   return 0;
 921 }], glib_cv_have_strlcpy=yes,
 922     glib_cv_have_strlcpy=no,
 923     glib_cv_have_strlcpy=no)])
 924 if test "$glib_cv_have_strlcpy" = "yes"; then
 925     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
 926 fi
 927
 928
 929 dnl **********************
 930 dnl *** va_copy checks ***
 931 dnl **********************
 932 dnl we currently check for all three va_copy possibilities, so we get
 933 dnl all results in config.log for bug reports.
 934 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
 935         AC_LINK_IFELSE([#include <stdarg.h>
 936         void f (int i, ...) {
 937         va_list args1, args2;
 938         va_start (args1, i);
 939         va_copy (args2, args1);
 940         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 941           exit (1);
 942         va_end (args1); va_end (args2);
 943         }
 944         int main() {
 945           f (0, 42);
 946           return 0;
 947         }],
 948         [glib_cv_va_copy=yes],
 949         [glib_cv_va_copy=no])
 950 ])
 951 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
 952         AC_LINK_IFELSE([#include <stdarg.h>
 953         void f (int i, ...) {
 954         va_list args1, args2;
 955         va_start (args1, i);
 956         __va_copy (args2, args1);
 957         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 958           exit (1);
 959         va_end (args1); va_end (args2);
 960         }
 961         int main() {
 962           f (0, 42);
 963           return 0;
 964         }],
 965         [glib_cv___va_copy=yes],
 966         [glib_cv___va_copy=no])
 967 ])
 968
 969 if test "x$glib_cv_va_copy" = "xyes"; then
 970   g_va_copy_func=va_copy
 971 else if test "x$glib_cv___va_copy" = "xyes"; then
 972   g_va_copy_func=__va_copy
 973 fi
 974 fi
 975
 976 if test -n "$g_va_copy_func"; then
 977   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
 978 fi
 979
 980 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
 981         AC_TRY_RUN([#include <stdarg.h>
 982         void f (int i, ...) {
 983         va_list args1, args2;
 984         va_start (args1, i);
 985         args2 = args1;
 986         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 987           exit (1);
 988         va_end (args1); va_end (args2);
 989         }
 990         int main() {
 991           f (0, 42);
 992           return 0;
 993         }],
 994         [glib_cv_va_val_copy=yes],
 995         [glib_cv_va_val_copy=no],
 996         [glib_cv_va_val_copy=yes])
 997 ])
 998
 999 if test "x$glib_cv_va_val_copy" = "xno"; then
1000   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1001 fi
1002
1003 dnl ***********************
1004 dnl *** g_module checks ***
1005 dnl ***********************
1006 G_MODULE_LIBS=
1007 G_MODULE_LIBS_EXTRA=
1008 G_MODULE_PLUGIN_LIBS=
1009 if test x"$glib_native_win32" = xyes; then
1010   dnl No use for this on Win32
1011   G_MODULE_LDFLAGS=
1012 else
1013   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1014 fi
1015 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1016 G_MODULE_NEED_USCORE=0
1017 G_MODULE_BROKEN_RTLD_GLOBAL=0
1018 G_MODULE_HAVE_DLERROR=0
1019 dnl *** force native WIN32 shared lib loader
1020 if test -z "$G_MODULE_IMPL"; then
1021   case "$host" in
1022   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1023   esac
1024 fi
1025 dnl *** dlopen() and dlsym() in system libraries
1026 if test -z "$G_MODULE_IMPL"; then
1027         AC_CHECK_FUNC(dlopen,
1028                       [AC_CHECK_FUNC(dlsym,
1029                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1030                       [])
1031 fi
1032 dnl *** load_image (BeOS)
1033 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1034   AC_CHECK_LIB(root, load_image,
1035       [G_MODULE_LIBS="-lbe -lroot -lglib"
1036       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1037       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1038       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1039       [])
1040 fi
1041 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1042 if test -z "$G_MODULE_IMPL"; then
1043         AC_CHECK_FUNC(NSLinkModule,
1044                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1045                        G_MODULE_NEED_USCORE=1],
1046                       [])
1047 fi
1048 dnl *** dlopen() and dlsym() in libdl
1049 if test -z "$G_MODULE_IMPL"; then
1050         AC_CHECK_LIB(dl, dlopen,
1051                      [AC_CHECK_LIB(dl, dlsym,
1052                                    [G_MODULE_LIBS=-ldl
1053                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1054                      [])
1055 fi
1056 dnl *** shl_load() in libdld (HP-UX)
1057 if test -z "$G_MODULE_IMPL"; then
1058         AC_CHECK_LIB(dld, shl_load,
1059                 [G_MODULE_LIBS=-ldld
1060                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1061                 [])
1062 fi
1063 dnl *** additional checks for G_MODULE_IMPL_DL
1064 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1065         LIBS_orig="$LIBS"
1066         LDFLAGS_orig="$LDFLAGS"
1067         LIBS="$G_MODULE_LIBS $LIBS"
1068         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1069 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1070         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1071                 glib_cv_rtldglobal_broken,[
1072                 AC_TRY_RUN([
1073 #include <dlfcn.h>
1074 #ifndef RTLD_GLOBAL
1075 #  define RTLD_GLOBAL 0
1076 #endif
1077 #ifndef RTLD_LAZY
1078 #  define RTLD_LAZY 0
1079 #endif
1080 int pthread_create;
1081 int main () {
1082     void *handle, *global, *local;
1083     global = &pthread_create;
1084     handle = dlopen ("libpthread.so", RTLD_GLOBAL | RTLD_LAZY);
1085     if (!handle) return 0;
1086     local = dlsym (handle, "pthread_create");
1087     return global == local;
1088 }                       ],
1089                         [glib_cv_rtldglobal_broken=no],
1090                         [glib_cv_rtldglobal_broken=yes],
1091                         [glib_cv_rtldglobal_broken=no])
1092                 rm -f plugin.c plugin.o plugin.lo
1093         ])
1094         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1095                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1096         else
1097                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1098         fi
1099 dnl *** check whether we need preceeding underscores
1100         AC_CACHE_CHECK([for preceeding underscore in symbols],
1101                 glib_cv_uscore,[
1102                 AC_TRY_RUN([#include <dlfcn.h>
1103                 int glib_underscore_test (void) { return 42; }
1104                 int main() {
1105                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1106                   handle = dlopen ((void*)0, 0);
1107                   if (handle) {
1108                     f1 = dlsym (handle, "glib_underscore_test");
1109                     f2 = dlsym (handle, "_glib_underscore_test");
1110                   } return (!f2 || f1);
1111                 }],
1112                         [glib_cv_uscore=yes],
1113                         [glib_cv_uscore=no],
1114                         [])
1115                 rm -f plugin.c plugin.$ac_objext plugin.lo
1116         ])
1117         GLIB_ASSERT_SET(glib_cv_uscore)
1118         if test "x$glib_cv_uscore" = "xyes"; then
1119                 G_MODULE_NEED_USCORE=1
1120         else
1121                 G_MODULE_NEED_USCORE=0
1122         fi
1123
1124         LDFLAGS="$LDFLAGS_orig"
1125 dnl *** check for having dlerror()
1126         AC_CHECK_FUNC(dlerror,
1127                 [G_MODULE_HAVE_DLERROR=1],
1128                 [G_MODULE_HAVE_DLERROR=0])
1129         LIBS="$LIBS_orig"
1130 fi
1131 dnl *** done, have we got an implementation?
1132 if test -z "$G_MODULE_IMPL"; then
1133         G_MODULE_IMPL=0
1134         G_MODULE_SUPPORTED=false
1135 else
1136         G_MODULE_SUPPORTED=true
1137 fi
1138
1139 AC_MSG_CHECKING(for the suffix of shared libraries)
1140 case "$host_os" in
1141   hpux9* | hpux10* | hpux11*)  # taken from ltconfig
1142     glib_gmodule_suffix='sl'
1143     ;;
1144   cygwin* | mingw*)
1145     glib_gmodule_suffix='dll'
1146     ;;
1147   *)
1148     glib_gmodule_suffix='so'
1149     ;;
1150 esac
1151 AC_MSG_RESULT(.$glib_gmodule_suffix)
1152
1153 AC_SUBST(G_MODULE_SUPPORTED)
1154 AC_SUBST(G_MODULE_IMPL)
1155 AC_SUBST(G_MODULE_LIBS)
1156 AC_SUBST(G_MODULE_LIBS_EXTRA)
1157 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1158 AC_SUBST(G_MODULE_LDFLAGS)
1159 AC_SUBST(G_MODULE_HAVE_DLERROR)
1160 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1161 AC_SUBST(G_MODULE_NEED_USCORE)
1162 AC_SUBST(GLIB_DEBUG_FLAGS)
1163
1164 dnl **********************
1165 dnl *** g_spawn checks ***
1166 dnl **********************
1167
1168 AC_MSG_CHECKING(for gspawn implementation)
1169 case "$host" in
1170   *-*-mingw*)
1171     GSPAWN=gspawn-win32.lo
1172     ;;
1173   *)
1174     GSPAWN=gspawn.lo
1175     ;;
1176 esac
1177 AC_MSG_RESULT($GSPAWN)
1178 AC_SUBST(GSPAWN)
1179
1180 dnl *************************
1181 dnl *** GIOChannel checks ***
1182 dnl *************************
1183
1184 AC_MSG_CHECKING(for GIOChannel implementation)
1185 case "$host" in
1186   *-*-mingw*)
1187     GIO=giowin32.lo
1188     ;;
1189   *)
1190     GIO=giounix.lo
1191     ;;
1192 esac
1193 AC_MSG_RESULT($GIO)
1194 AC_SUBST(GIO)
1195
1196 dnl check for cpu to enable double checked locking when possible
1197 dnl ************************************************************
1198
1199 if test x"$have_threads" != xno; then
1200         AC_MSG_CHECKING(whether double checked locking is safe)
1201         # According to glibc/linuxthreads the following platforms do
1202         # not have the notion of a read or write memory barrier and
1203         # therefore the double checked locking should be safe. Have a
1204         # look at pthread_once in glibc/linuxthreads/mutex.c to see,
1205         # what this means.
1206         case $host_cpu in
1207                 arm|hppa|i386|i686|ia64|m68k|sh|cris|x86_64)
1208                         g_use_double_checked_locking=yes
1209                 ;;
1210                 *)
1211                         g_use_double_checked_locking=no
1212                 ;;
1213         esac
1214         AC_MSG_RESULT($g_use_double_checked_locking)
1215 fi
1216
1217 dnl ****************************************
1218 dnl *** platform dependent source checks ***
1219 dnl ****************************************
1220
1221 AC_MSG_CHECKING(for platform-dependent source)
1222 case "$host" in
1223   *-*-cygwin*|*-*-mingw*)
1224     PLATFORMDEP=gwin32.lo
1225     ;;
1226   *)
1227     PLATFORMDEP=
1228     ;;
1229 esac
1230 AC_MSG_RESULT($PLATFORMDEP)
1231 AC_SUBST(PLATFORMDEP)
1232
1233 AC_MSG_CHECKING([whether to compile timeloop])
1234 case "$host" in
1235   *-*-cygwin*|*-*-mingw*)
1236     enable_timeloop=no
1237     ;;
1238   *)
1239     enable_timeloop=yes
1240     ;;
1241 esac
1242 AC_MSG_RESULT($enable_timeloop)
1243 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1244
1245 AC_MSG_CHECKING([if building for some Win32 platform])
1246 case "$host" in
1247   *-*-mingw*|*-*-cygwin*)
1248     platform_win32=yes
1249     ;;
1250   *)
1251     platform_win32=no
1252     ;;
1253 esac
1254 AC_MSG_RESULT($platform_win32)
1255 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1256
1257 dnl ***********************
1258 dnl *** g_thread checks ***
1259 dnl ***********************
1260
1261 AC_ARG_WITH(threads,
1262            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/solaris/win32@:>@],
1263                            [specify a thread implementation to use])],
1264            [if test "x$with_threads" = x; then
1265                 want_threads=yes
1266             else
1267                 want_threads=$with_threads
1268             fi],
1269            [want_threads=yes])
1270 if test "x$enable_threads" = "xno"; then
1271         want_threads=no
1272 fi
1273
1274 dnl error and warning message
1275 dnl *************************
1276
1277 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1278                 computer. GLib will not have a default thread implementation."
1279
1280 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1281                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1282                 compilation now, but then your programs might not work.
1283                 Please provide information on how it is done on your system."
1284
1285 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1286                 "
1287
1288 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1289                 provide information on your thread implementation.
1290                 You can also run 'configure --disable-threads'
1291                 to compile without thread support."
1292
1293 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1294                 functions will not be MT-safe during their first call because
1295                 there is no working 'getpwuid_r' on your system."
1296
1297 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1298                 because there is no 'localtime_r' on your system."
1299
1300 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1301                 crude surrogate will be used. If you happen to know a
1302                 yield function for your system, please inform the GLib
1303                 developers."
1304
1305 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1306                 threads on your system. Thus threads can only have the default
1307                 priority. If you happen to know these main/max
1308                 priorities, please inform the GLib developers."
1309
1310 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1311                 linking threaded applications. As GLib cannot do that
1312                 automatically, you will get an linkg error everytime you are
1313                 not using the right compiler. In that case you have to relink
1314                 with the right compiler. Ususally just '_r' is appended
1315                 to the compiler name."
1316
1317 dnl determination of thread implementation
1318 dnl ***************************************
1319
1320 # have_threads=no   means no thread support
1321 # have_threads=none means no default thread implementation
1322
1323 have_threads=no
1324 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
1325         case $host in
1326                 *-*-solaris*)
1327                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
1328                 ;;
1329         esac
1330 fi
1331 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1332                                 || test "x$want_threads" = xdce; then
1333         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1334         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1335         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1336         glib_save_CPPFLAGS="$CPPFLAGS"
1337         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1338         if test "x$have_threads" = xno; then
1339                 AC_TRY_COMPILE([#include <pthread.h>],
1340                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1341                         have_threads=posix)
1342         fi
1343         if test "x$have_threads" = xno; then
1344                 AC_TRY_COMPILE([#include <pthread.h>],
1345                         [pthread_mutex_t m;
1346                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1347                         have_threads=dce)
1348         fi
1349         # Tru64Unix requires -pthread to find pthread.h. See #103020
1350         CPPFLAGS="$CPPFLAGS -pthread"
1351         if test "x$have_threads" = xno; then
1352         AC_TRY_COMPILE([#include <pthread.h>],
1353                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1354                        have_threads=posix)
1355         fi
1356         CPPFLAGS="$glib_save_CPPFLAGS"
1357 fi
1358 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1359         case $host in
1360                 *-*-mingw*)
1361                 have_threads=win32
1362                 ;;
1363         esac
1364 fi
1365 if test "x$want_threads" = xnone; then
1366         have_threads=none
1367 fi
1368
1369 AC_MSG_CHECKING(for thread implementation)
1370
1371 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1372         AC_MSG_RESULT(none available)
1373         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1374 else
1375         AC_MSG_RESULT($have_threads)
1376 fi
1377
1378
1379 dnl determination of G_THREAD_CFLAGS
1380 dnl ********************************
1381
1382 G_THREAD_LIBS=
1383 G_THREAD_LIBS_EXTRA=
1384 G_THREAD_CFLAGS=
1385
1386 dnl
1387 dnl Test program for basic POSIX threads functionality
1388 dnl
1389 m4_define([glib_thread_test],[
1390 #include <pthread.h>
1391 int check_me = 0;
1392 void* func(void* data) {check_me = 42; return &check_me;}
1393 int main()
1394  { pthread_t t;
1395    void *ret;
1396    pthread_create (&t, $1, func, 0);
1397    pthread_join (t, &ret);
1398    exit (check_me != 42 || ret != &check_me);
1399 }])
1400
1401 dnl
1402 dnl Test program for sched_get_priority_min()
1403 dnl
1404 m4_define([glib_sched_priority_test],[
1405 #include <sched.h>
1406 #include <errno.h>
1407 int main() {
1408     errno = 0;
1409     return sched_get_priority_min(SCHED_OTHER)==-1
1410            && errno != 0;
1411 }])
1412
1413 if test x"$have_threads" != xno; then
1414
1415   if test x"$have_threads" = xposix; then
1416     # First we test for posix, whether -pthread or -pthreads do the trick as
1417     # both CPPFLAG and LIBS.
1418     # One of them does for most gcc versions and some other platforms/compilers
1419     # too and could be considered as the canonical way to go.
1420     for flag in pthread pthreads; do
1421       glib_save_CFLAGS="$CFLAGS"
1422       CFLAGS="$CFLAGS -$flag"
1423       AC_TRY_RUN(glib_thread_test(0),
1424                  glib_flag_works=yes,
1425                  glib_flag_works=no,
1426                  [AC_LINK_IFELSE(glib_thread_test(0),
1427                                  glib_flag_works=yes,
1428                                  glib_flag_works=no)])
1429       CFLAGS="$glib_save_CFLAGS"
1430       if test $glib_flag_works = yes ; then
1431          G_THREAD_CFLAGS=-$flag
1432          G_THREAD_LIBS=-$flag
1433       fi
1434     done
1435   fi
1436
1437   if test x"$G_THREAD_CFLAGS" = x; then
1438
1439     # The canonical -pthread[s] does not work. Try something different.
1440
1441     case $host in
1442         *-aix*)
1443                 if test x"$GCC" = xyes; then
1444                         # GCC 3.0 and above needs -pthread.
1445                         # Should be coverd by the case above.
1446                         # GCC 2.x and below needs -mthreads
1447                         G_THREAD_CFLAGS="-mthreads"
1448                         G_THREAD_LIBS=$G_THREAD_CFLAGS
1449                 else
1450                         # We are probably using the aix compiler. Normaly a
1451                         # program would have to be compiled with the _r variant
1452                         # of the corresponding compiler, but we as GLib cannot
1453                         # do that: but the good news is that for compiling the
1454                         # only difference is the added -D_THREAD_SAFE compile
1455                         # option. This is according to the "C for AIX User's
1456                         # Guide".
1457                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
1458                 fi
1459                 ;;
1460         *-dg-dgux*)  # DG/UX
1461                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
1462                 ;;
1463         *-osf*)
1464                 # So we are using dce threads. posix threads are already
1465                 # catched above.
1466                 G_THREAD_CFLAGS="-threads"
1467                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1468                 ;;
1469         *-solaris*)
1470                 if test x"$GCC" = xyes; then
1471                    # We are using solaris threads. posix threads are
1472                    # already catched above.
1473                         G_THREAD_CFLAGS="-threads"
1474                 else
1475                         G_THREAD_CFLAGS="-mt"
1476                 fi
1477                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1478                 ;;
1479         *-sysv5uw7*) # UnixWare 7
1480                 # We are not using gcc with -pthread. Catched above.
1481                 G_THREAD_CFLAGS="-Kthread"
1482                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1483                 ;;
1484         *-mingw*)
1485                 # No flag needed when using MSVCRT.DLL
1486                 G_THREAD_CFLAGS=""
1487                 ;;
1488         *)
1489                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1490                 ;;
1491     esac
1492
1493   fi
1494
1495     # if we are not finding the localtime_r function, then we probably are
1496     # not using the proper multithread flag
1497
1498     glib_save_CPPFLAGS="$CPPFLAGS"
1499     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1500
1501     # First we test, whether localtime_r is declared in time.h
1502     # directly. Then we test whether a macro localtime_r exists, in
1503     # which case localtime_r in the test program is replaced and thus
1504     # if we still find localtime_r in the output, it is not defined as
1505     # a macro.
1506
1507     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1508       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1509                                                            localtime_r(a,b)],
1510                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1511
1512     CPPFLAGS="$glib_save_CPPFLAGS"
1513
1514     AC_MSG_CHECKING(thread related cflags)
1515     AC_MSG_RESULT($G_THREAD_CFLAGS)
1516     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1517 fi
1518
1519 dnl determination of G_THREAD_LIBS
1520 dnl ******************************
1521
1522 mutex_has_default=no
1523 case $have_threads in
1524         posix|dce)
1525           glib_save_CPPFLAGS="$CPPFLAGS"
1526           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1527           if test x"$G_THREAD_LIBS" = x; then
1528             case $host in
1529               *-aix*)
1530                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
1531                 # probably using the aix compiler.
1532                 AC_MSG_WARN($AIX_COMPILE_INFO)
1533                 ;;
1534               *)
1535                 G_THREAD_LIBS=error
1536                 glib_save_LIBS="$LIBS"
1537                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
1538                         if test x"$thread_lib" = x; then
1539                                 add_thread_lib=""
1540                                 IN=""
1541                         else
1542                                 add_thread_lib="-l$thread_lib"
1543                                 IN=" in -l$thread_lib"
1544                         fi
1545                         if test x"$have_threads" = xposix; then
1546                                 defattr=0
1547                         else
1548                                 defattr=pthread_attr_default
1549                         fi
1550
1551                         LIBS="$add_thread_lib $glib_save_LIBS"
1552
1553                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
1554                         AC_TRY_RUN(glib_thread_test($defattr),
1555                                    glib_result=yes,
1556                                    glib_result=no,
1557                                    [AC_LINK_IFELSE(glib_thread_test($defattr),
1558                                                    glib_result=yes,
1559                                                    glib_result=no)])
1560                         AC_MSG_RESULT($glib_result)
1561
1562                         if test "$glib_result" = "yes" ; then
1563                           G_THREAD_LIBS="$add_thread_lib"
1564                           break
1565                         fi
1566                 done
1567                 if test "x$G_THREAD_LIBS" = xerror; then
1568                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1569                 fi
1570                 LIBS="$glib_save_LIBS"
1571                 ;;
1572             esac
1573           fi
1574
1575           glib_save_LIBS="$LIBS"
1576           for thread_lib in "" rt rte; do
1577             if test x"$thread_lib" = x; then
1578               add_thread_lib=""
1579               IN=""
1580             else
1581               add_thread_lib="-l$thread_lib"
1582               IN=" in -l$thread_lib"
1583             fi
1584             LIBS="$add_thread_lib $glib_save_LIBS"
1585
1586             AC_MSG_CHECKING(for sched_get_priority_min$IN)
1587             AC_TRY_RUN(glib_sched_priority_test,
1588                        glib_result=yes,
1589                        glib_result=no,
1590                        [AC_LINK_IFELSE(glib_sched_priority_test,
1591                                        glib_result=yes,
1592                                        glib_result=no)])
1593             AC_MSG_RESULT($glib_result)
1594
1595             if test "$glib_result" = "yes" ; then
1596                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
1597                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
1598                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
1599                break
1600             fi
1601           done
1602           LIBS="$glib_save_LIBS"
1603           mutex_has_default=yes
1604           mutex_default_type='pthread_mutex_t'
1605           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
1606           mutex_header_file='pthread.h'
1607           if test "x$have_threads" = "xposix"; then
1608             g_threads_impl="POSIX"
1609           else
1610             g_threads_impl="DCE"
1611             have_threads="posix"
1612           fi
1613           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
1614           CPPFLAGS="$glib_save_CPPFLAGS"
1615           ;;
1616         solaris)
1617            mutex_has_default=yes
1618            mutex_default_type='mutex_t'
1619            mutex_default_init="DEFAULTMUTEX"
1620            mutex_header_file='thread.h'
1621            g_threads_impl="SOLARIS"
1622            ;;
1623         win32)
1624            g_threads_impl="WIN32"
1625            ;;
1626         none|no)
1627            g_threads_impl="NONE"
1628            ;;
1629         *)
1630            g_threads_impl="NONE"
1631            G_THREAD_LIBS=error
1632            ;;
1633 esac
1634
1635 if test "x$G_THREAD_LIBS" = xerror; then
1636         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1637 fi
1638
1639 case $host in
1640   *-*-beos*)
1641     G_THREAD_LIBS="-lbe -lroot -lglib "
1642     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1643     ;;
1644   *)
1645     ;;
1646 esac
1647
1648 AC_MSG_CHECKING(thread related libraries)
1649 AC_MSG_RESULT($G_THREAD_LIBS)
1650
1651 dnl check for mt safe function variants and some posix functions
1652 dnl ************************************************************
1653
1654 if test x"$have_threads" != xno; then
1655         glib_save_LIBS="$LIBS"
1656         # we are not doing the following for now, as this might require glib
1657         # to always be linked with the thread libs on some platforms.
1658         # LIBS="$LIBS $G_THREAD_LIBS"
1659         AC_CHECK_FUNCS(localtime_r)
1660         if test "$ac_cv_header_pwd_h" = "yes"; then
1661                 AC_CACHE_CHECK([for posix getpwuid_r],
1662                         ac_cv_func_posix_getpwuid_r,
1663                         [AC_TRY_RUN([
1664 #include <errno.h>
1665 #include <pwd.h>
1666 int main () {
1667     char buffer[10000];
1668     struct passwd pwd, *pwptr = &pwd;
1669     int error;
1670     errno = 0;
1671     error = getpwuid_r (0, &pwd, buffer,
1672                         sizeof (buffer), &pwptr);
1673    return (error < 0 && errno == ENOSYS)
1674            || error == ENOSYS;
1675 }                               ],
1676                                 [ac_cv_func_posix_getpwuid_r=yes],
1677                                 [ac_cv_func_posix_getpwuid_r=no])])
1678                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
1679                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
1680                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
1681                                 [Have POSIX function getpwuid_r])
1682                 else
1683                         AC_CACHE_CHECK([for nonposix getpwuid_r],
1684                                 ac_cv_func_nonposix_getpwuid_r,
1685                                 [AC_TRY_LINK([#include <pwd.h>],
1686                                         [char buffer[10000];
1687                                         struct passwd pwd;
1688                                         getpwuid_r (0, &pwd, buffer,
1689                                                         sizeof (buffer));],
1690                                         [ac_cv_func_nonposix_getpwuid_r=yes],
1691                                         [ac_cv_func_nonposix_getpwuid_r=no])])
1692                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
1693                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
1694                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
1695                                         [Have non-POSIX function getpwuid_r])
1696                         fi
1697                 fi
1698         fi
1699         LIBS="$G_THREAD_LIBS $LIBS"
1700         if test x"$have_threads" = xposix; then
1701                 glib_save_CPPFLAGS="$CPPFLAGS"
1702                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1703                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
1704                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
1705                 # This is not AC_CHECK_FUNC to also work with function
1706                 # name mangling in header files.
1707                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1708                 AC_TRY_LINK([#include <pthread.h>],
1709                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1710                         [AC_MSG_RESULT(yes)
1711                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1712                                   [Have function pthread_attr_setstacksize])],
1713                         [AC_MSG_RESULT(no)])
1714                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1715                 if test x"$posix_priority_min" = x; then
1716                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1717                                 PX_PRIO_MIN],,[
1718                                 posix_priority_min=PX_PRIO_MIN
1719                                 posix_priority_max=PX_PRIO_MAX])
1720                 fi
1721                 if test x"$posix_priority_min" = x; then
1722                         # AIX
1723                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
1724                                 PTHREAD_PRIO_MIN],,[
1725                                 posix_priority_min=PTHREAD_PRIO_MIN
1726                                 posix_priority_max=PTHREAD_PRIO_MAX])
1727                 fi
1728                 if test x"$posix_priority_min" = x; then
1729                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1730                                 PRI_OTHER_MIN],,[
1731                                 posix_priority_min=PRI_OTHER_MIN
1732                                 posix_priority_max=PRI_OTHER_MAX])
1733                 fi
1734                 if test x"$posix_priority_min" = x; then
1735                         AC_MSG_RESULT(none found)
1736                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1737                         posix_priority_min=-1
1738                         posix_priority_max=-1
1739                 else
1740                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1741                         AC_MSG_CHECKING(for pthread_setschedparam)
1742                         AC_TRY_LINK([#include <pthread.h>],
1743                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
1744                           [AC_MSG_RESULT(yes)
1745                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1746                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
1747                           [AC_MSG_RESULT(no)
1748                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
1749                 fi
1750                 posix_yield_func=none
1751                 AC_MSG_CHECKING(for posix yield function)
1752                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1753                                                         thr_yield; do
1754                         AC_TRY_LINK([#include <pthread.h>],
1755                                 [$yield_func()],
1756                                 [posix_yield_func="$yield_func"
1757                                 break])
1758                 done
1759                 if test x"$posix_yield_func" = xnone; then
1760                         AC_MSG_RESULT(none found)
1761                         AC_MSG_WARN($POSIX_NO_YIELD)
1762                         posix_yield_func="g_usleep(1000)"
1763                 else
1764                         AC_MSG_RESULT($posix_yield_func)
1765                         posix_yield_func="$posix_yield_func()"
1766                 fi
1767                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1768                 CPPFLAGS="$glib_save_CPPFLAGS"
1769
1770                 AC_CACHE_CHECK([whether to use the PID niceness surrogate for thread priorities],
1771                                glib_cv_use_pid_surrogate,
1772                  [AC_TRY_RUN([
1773 #include <pthread.h>
1774 #include <sys/types.h>
1775 #include <unistd.h>
1776 pid_t other_pid = 0;
1777
1778 void* func(void* data) {other_pid = getpid();}
1779 main()
1780 { pthread_t t;
1781   void *ret;
1782   pthread_create (&t, 0, func, NULL);
1783   pthread_join (t, &ret);
1784   exit (getpid()==other_pid ||
1785         $posix_priority_min != $posix_priority_max);
1786 }               ],
1787                 [glib_cv_use_pid_surrogate=yes],
1788                 [glib_cv_use_pid_surrogate=no],
1789                 [])])
1790           GLIB_ASSERT_SET(glib_cv_use_pid_surrogate)
1791           if test "$glib_cv_use_pid_surrogate" = "yes" ; then
1792             AC_DEFINE(G_THREAD_USE_PID_SURROGATE, 1,
1793                       [whether to use the PID niceness surrogate for thread priorities])
1794           fi
1795
1796         elif test x"$have_threads" = xwin32; then
1797                 # It's a pointer to a private struct
1798                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
1799         elif test x"$have_threads" = xsolaris; then
1800                 GLIB_SIZEOF([#include <thread.h>], thread_t, system_thread)
1801         fi
1802
1803         LIBS="$glib_save_LIBS"
1804
1805         # now spit out all the warnings.
1806         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1807            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1808                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1809         fi
1810         if test "$ac_cv_func_localtime_r" != "yes"; then
1811                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1812         fi
1813 fi
1814
1815 if test x"$glib_cv_sizeof_system_thread" = x; then
1816    # use a pointer as a fallback.
1817    GLIB_SIZEOF(,void *, system_thread)
1818 fi
1819
1820 #
1821 # Hack to deal with:
1822 #
1823 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
1824 #     building shared libraries with linux.
1825 #  b) libtool doesn't recognize -pthread as a library dependency.
1826 #
1827 case $host in
1828   *-*-linux*)
1829     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
1830     ;;
1831   *)
1832     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-Wc,-pthread/`"
1833     ;;
1834 esac
1835
1836 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1837                    [Source file containing theread implementation])
1838 AC_SUBST(G_THREAD_CFLAGS)
1839 AC_SUBST(G_THREAD_LIBS)
1840 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
1841 AC_SUBST(G_THREAD_LIBS_EXTRA)
1842
1843 dnl **********************************************
1844 dnl *** GDefaultMutex setup and initialization ***
1845 dnl **********************************************
1846 dnl
1847 dnl if mutex_has_default = yes, we also got
1848 dnl mutex_default_type, mutex_default_init and mutex_header_file
1849 if test $mutex_has_default = yes ; then
1850         glib_save_CPPFLAGS="$CPPFLAGS"
1851         glib_save_LIBS="$LIBS"
1852         LIBS="$G_THREAD_LIBS $LIBS"
1853         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1854         GLIB_SIZEOF([#include <$mutex_header_file>],
1855                     $mutex_default_type,
1856                     gmutex)
1857         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1858                            $mutex_default_type,
1859                            gmutex,
1860                            $glib_cv_sizeof_gmutex,
1861                            $mutex_default_init)
1862         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1863                 mutex_has_default=no
1864         fi
1865         CPPFLAGS="$glib_save_CPPFLAGS"
1866         LIBS="$glib_save_LIBS"
1867 fi
1868
1869 dnl ****************************************
1870 dnl *** GLib POLL* compatibility defines ***
1871 dnl ****************************************
1872
1873 glib_poll_includes=["
1874 #include <sys/types.h>
1875 #include <sys/poll.h>
1876 "]
1877
1878 if test $ac_cv_header_sys_types_h = yes &&
1879    test $ac_cv_header_sys_poll_h = yes ; then
1880   glib_failed=false
1881   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
1882   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
1883   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
1884   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
1885   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
1886   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
1887   if $glib_failed ; then
1888     AC_MSG_ERROR([Could not determine values for POLL* constants])
1889   fi
1890 else
1891   glib_cv_value_POLLIN=1
1892   glib_cv_value_POLLOUT=4
1893   glib_cv_value_POLLPRI=2
1894   glib_cv_value_POLLERR=8
1895   glib_cv_value_POLLHUP=16
1896   glib_cv_value_POLLNVAL=32
1897 fi
1898
1899 dnl **********************
1900 dnl *** Win32 API libs ***
1901 dnl **********************
1902
1903 case $host in
1904   *-*-cygwin*)
1905         G_LIBS_EXTRA="-luser32 -lkernel32"
1906     ;;
1907   *-*-mingw*)
1908         G_LIBS_EXTRA="-lwsock32"
1909     ;;
1910   *)
1911         G_LIBS_EXTRA=""
1912     ;;
1913 esac
1914 AC_SUBST(G_LIBS_EXTRA)
1915
1916 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
1917 dnl since we need it for g_iconv()
1918
1919 AC_MSG_CHECKING([for EILSEQ])
1920 AC_TRY_COMPILE([
1921 #include <errno.h>
1922 ],
1923 [
1924 int error = EILSEQ;
1925 ], have_eilseq=yes, have_eilseq=no);
1926 AC_MSG_RESULT($have_eilseq)
1927
1928 dnl ******************************************************************
1929 dnl *** Look for glib-genmarshal in PATH if we are cross-compiling ***
1930 dnl ******************************************************************
1931
1932 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
1933
1934 if test $cross_compiling = yes; then
1935   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
1936   if test x$GLIB_GENMARSHAL = xno; then
1937     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
1938   fi
1939 fi
1940
1941 dnl **************************
1942 dnl *** Checks for gtk-doc ***
1943 dnl **************************
1944
1945 GTK_DOC_CHECK([1.0])
1946
1947 AC_ARG_ENABLE(man,
1948               [AC_HELP_STRING([--enable-man],
1949                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
1950               enable_man=no)
1951
1952 if test "${enable_man}" != no; then
1953 dnl
1954 dnl Check for xsltproc
1955 dnl
1956 AC_PATH_PROG([XSLTPROC], [xsltproc])
1957   if test -z "$XSLTPROC"; then
1958     enable_man=no
1959   fi
1960
1961   dnl check for DocBook DTD and stylesheets in the local catalog.
1962   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
1963      [DocBook XML DTD V4.1.2],,enable_man=no)
1964   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
1965      [DocBook XSL Stylesheets],,enable_man=no)
1966 fi
1967
1968 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
1969
1970 dnl ******************************
1971 dnl *** output the whole stuff ***
1972 dnl ******************************
1973
1974 dnl this section will only be run if config.status is invoked with no
1975 dnl arguments, or with "glibconfig.h" as an argument.
1976 AC_CONFIG_COMMANDS([glibconfig.h],
1977 [
1978         outfile=glibconfig.h-tmp
1979         cat > $outfile <<\_______EOF
1980 /* glibconfig.h
1981  *
1982  * This is a generated file.  Please modify 'configure.in'
1983  */
1984
1985 #ifndef __G_LIBCONFIG_H__
1986 #define __G_LIBCONFIG_H__
1987
1988 #include <glib/gmacros.h>
1989
1990 _______EOF
1991
1992         if test x$glib_limits_h = xyes; then
1993           echo '#include <limits.h>' >> $outfile
1994         fi
1995         if test x$glib_float_h = xyes; then
1996           echo '#include <float.h>' >> $outfile
1997         fi
1998         if test x$glib_values_h = xyes; then
1999           echo '#include <values.h>' >> $outfile
2000         fi
2001         if test "$glib_header_alloca_h" = "yes"; then
2002           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2003         fi
2004         if test x$glib_sys_poll_h = xyes; then
2005           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2006         fi
2007
2008         cat >> $outfile <<_______EOF
2009
2010 G_BEGIN_DECLS
2011
2012 #define G_MINFLOAT      $glib_mf
2013 #define G_MAXFLOAT      $glib_Mf
2014 #define G_MINDOUBLE     $glib_md
2015 #define G_MAXDOUBLE     $glib_Md
2016 #define G_MINSHORT      $glib_ms
2017 #define G_MAXSHORT      $glib_Ms
2018 #define G_MAXUSHORT     $glib_Mus
2019 #define G_MININT        $glib_mi
2020 #define G_MAXINT        $glib_Mi
2021 #define G_MAXUINT       $glib_Mui
2022 #define G_MINLONG       $glib_ml
2023 #define G_MAXLONG       $glib_Ml
2024 #define G_MAXULONG      $glib_Mul
2025
2026 _______EOF
2027
2028
2029         ### this should always be true in a modern C/C++ compiler
2030         cat >>$outfile <<_______EOF
2031 typedef signed char gint8;
2032 typedef unsigned char guint8;
2033 _______EOF
2034
2035
2036         if test -n "$gint16"; then
2037           cat >>$outfile <<_______EOF
2038 typedef signed $gint16 gint16;
2039 typedef unsigned $gint16 guint16;
2040 #define G_GINT16_MODIFIER $gint16_modifier
2041 #define G_GINT16_FORMAT $gint16_format
2042 #define G_GUINT16_FORMAT $guint16_format
2043 _______EOF
2044         fi
2045
2046
2047         if test -n "$gint32"; then
2048           cat >>$outfile <<_______EOF
2049 typedef signed $gint32 gint32;
2050 typedef unsigned $gint32 guint32;
2051 #define G_GINT32_MODIFIER $gint32_modifier
2052 #define G_GINT32_FORMAT $gint32_format
2053 #define G_GUINT32_FORMAT $guint32_format
2054 _______EOF
2055         fi
2056
2057         cat >>$outfile <<_______EOF
2058 #define G_HAVE_GINT64 1          /* deprecated, always true */
2059
2060 ${glib_extension}typedef signed $gint64 gint64;
2061 ${glib_extension}typedef unsigned $gint64 guint64;
2062
2063 #define G_GINT64_CONSTANT(val)  $gint64_constant
2064 _______EOF
2065
2066         if test x$gint64_format != x ; then
2067           cat >>$outfile <<_______EOF
2068 #define G_GINT64_MODIFIER $gint64_modifier
2069 #define G_GINT64_FORMAT $gint64_format
2070 #define G_GUINT64_FORMAT $guint64_format
2071 _______EOF
2072         else
2073           cat >>$outfile <<_______EOF
2074 #undef G_GINT64_MODIFIER
2075 #undef G_GINT64_FORMAT
2076 #undef G_GUINT64_FORMAT
2077 _______EOF
2078         fi
2079
2080         cat >>$outfile <<_______EOF
2081
2082 #define GLIB_SIZEOF_VOID_P $glib_void_p
2083 #define GLIB_SIZEOF_LONG   $glib_long
2084 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2085
2086 _______EOF
2087
2088         cat >>$outfile <<_______EOF
2089 typedef signed $glib_size_type_define gssize;
2090 typedef unsigned $glib_size_type_define gsize;
2091 #define G_GSIZE_MODIFIER $gsize_modifier
2092 #define G_GSSIZE_FORMAT $gssize_format
2093 #define G_GSIZE_FORMAT $gsize_format
2094
2095 #define G_MAXSIZE       G_MAXU$glib_msize_type
2096 _______EOF
2097
2098         if test -z "$glib_unknown_void_p"; then
2099           cat >>$outfile <<_______EOF
2100
2101 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2102 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2103
2104 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2105 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2106 _______EOF
2107         else
2108           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2109         fi
2110
2111
2112
2113         cat >>$outfile <<_______EOF
2114 $glib_atexit
2115 $glib_memmove
2116 $glib_defines
2117 $glib_os
2118
2119 $glib_vacopy
2120
2121 #ifdef  __cplusplus
2122 #define G_HAVE_INLINE   1
2123 #else   /* !__cplusplus */
2124 $glib_inline
2125 #endif  /* !__cplusplus */
2126
2127 _______EOF
2128
2129         if test x$g_have_iso_c_varargs = xyes ; then
2130                 cat >>$outfile <<_______EOF
2131 #ifndef __cplusplus
2132 # define G_HAVE_ISO_VARARGS 1
2133 #endif
2134 _______EOF
2135         fi
2136         if test x$g_have_iso_cxx_varargs = xyes ; then
2137                 cat >>$outfile <<_______EOF
2138 #ifdef __cplusplus
2139 # define G_HAVE_ISO_VARARGS 1
2140 #endif
2141 _______EOF
2142         fi
2143         if test x$g_have_gnuc_varargs = xyes ; then
2144                 cat >>$outfile <<_______EOF
2145
2146 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2147  * is passed ISO vararg support is turned off, and there is no work
2148  * around to turn it on, so we unconditionally turn it off.
2149  */
2150 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2151 #  undef G_HAVE_ISO_VARARGS
2152 #endif
2153
2154 #define G_HAVE_GNUC_VARARGS 1
2155 _______EOF
2156         fi
2157
2158         case x$g_stack_grows in
2159         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2160         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2161         esac
2162
2163
2164         echo >>$outfile
2165         if test x$g_have_eilseq = xno; then
2166                 cat >>$outfile <<_______EOF
2167 #ifndef EILSEQ
2168 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2169  * The correspondence between this and the corresponding definition
2170  * in libiconv is essential.
2171  */
2172 #  define EILSEQ ENOENT
2173 #endif
2174 _______EOF
2175
2176         fi
2177
2178         echo >>$outfile
2179         if test x$g_mutex_has_default = xyes; then
2180                 cat >>$outfile <<_______EOF
2181 $g_enable_threads_def G_THREADS_ENABLED
2182 #define G_THREADS_IMPL_$g_threads_impl_def
2183 typedef struct _GStaticMutex GStaticMutex;
2184 struct _GStaticMutex
2185 {
2186   struct _GMutex *runtime_mutex;
2187   union {
2188     char   pad[[$g_mutex_sizeof]];
2189     double dummy_double;
2190     void  *dummy_pointer;
2191     long   dummy_long;
2192   } static_mutex;
2193 };
2194 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
2195 #define g_static_mutex_get_mutex(mutex) \\
2196   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->static_mutex)) : \\
2197    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
2198 _______EOF
2199         else
2200                 cat >>$outfile <<_______EOF
2201 $g_enable_threads_def G_THREADS_ENABLED
2202 #define G_THREADS_IMPL_$g_threads_impl_def
2203 typedef struct _GMutex* GStaticMutex;
2204 #define G_STATIC_MUTEX_INIT NULL
2205 #define g_static_mutex_get_mutex(mutex) \\
2206   (g_static_mutex_get_mutex_impl_shortcut (mutex))
2207 _______EOF
2208         fi
2209
2210         if test x$g_use_double_checked_locking = xyes; then
2211                 cat >>$outfile <<_______EOF
2212 /* double checked locking can be used on this platform */
2213 #define g_once(once, func, arg) \\
2214   ((once)->status == G_ONCE_STATUS_READY ? (once)->retval : \\
2215    g_once_impl (once, func, arg))
2216 #define g_static_mutex_get_mutex_impl_shortcut(mutex) \\
2217   (*(mutex) ? *(mutex) : g_static_mutex_get_mutex_impl (mutex))
2218 _______EOF
2219         else
2220                 cat >>$outfile <<_______EOF
2221 /* double checked locking is unsafe to use on this platform, do full locking */
2222 #define g_once(once, func, arg) (g_once_impl(once, func, arg))
2223 #define g_static_mutex_get_mutex_impl_shortcut(mutex) \\
2224   (g_static_mutex_get_mutex_impl (mutex))
2225 _______EOF
2226 fi
2227
2228         cat >>$outfile <<_______EOF
2229 /* This represents a system thread as used by the implementation. An
2230  * alien implementaion, as loaded by g_thread_init can only count on
2231  * "sizeof (gpointer)" bytes to store their info. We however need more
2232  * for some of our native implementations. */
2233 typedef union _GSystemThread GSystemThread;
2234 union _GSystemThread
2235 {
2236   char   data[[$g_system_thread_sizeof]];
2237   double dummy_double;
2238   void  *dummy_pointer;
2239   long   dummy_long;
2240 };
2241 _______EOF
2242
2243         echo >>$outfile
2244         g_bit_sizes="16 32 64"
2245         for bits in $g_bit_sizes; do
2246           cat >>$outfile <<_______EOF
2247 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
2248 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
2249 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2250 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
2251 _______EOF
2252         done
2253
2254         cat >>$outfile <<_______EOF
2255 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
2256 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
2257 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
2258 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
2259 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
2260 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
2261 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
2262 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
2263 #define G_BYTE_ORDER $g_byte_order
2264
2265 #define GLIB_SYSDEF_POLLIN =$g_pollin
2266 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2267 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2268 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2269 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2270 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2271
2272 #define G_MODULE_SUFFIX "$g_module_suffix"
2273
2274 typedef $g_pid_type GPid;
2275
2276 G_END_DECLS
2277
2278 #endif /* GLIBCONFIG_H */
2279 _______EOF
2280
2281
2282         if cmp -s $outfile glibconfig.h; then
2283           AC_MSG_NOTICE([glibconfig.h is unchanged])
2284           rm -f $outfile
2285         else
2286           mv $outfile glibconfig.h
2287         fi
2288 ],[
2289
2290 # Note that if two cases are the same, case goes with the first one.
2291 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
2292 # on variable expansion in case labels.  Look at the generated config.status
2293 # for a hint.
2294
2295 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2296   glib_header_alloca_h="$ac_cv_working_alloca_h"
2297 else
2298   glib_header_alloca_h="$ac_cv_header_alloca_h"
2299 fi
2300
2301 case xyes in
2302 x$ac_cv_header_float_h)
2303   glib_float_h=yes
2304   glib_mf=FLT_MIN glib_Mf=FLT_MAX
2305   glib_md=DBL_MIN glib_Md=DBL_MAX
2306   ;;
2307 x$ac_cv_header_values_h)
2308   glib_values_h=yes
2309   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
2310   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
2311   ;;
2312 esac
2313
2314 case xyes in
2315 x$ac_cv_header_limits_h)
2316   glib_limits_h=yes
2317   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
2318   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
2319   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
2320   ;;
2321 x$ac_cv_header_values_h)
2322   glib_values_h=yes
2323   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
2324   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
2325   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
2326   ;;
2327 esac
2328
2329 if test x$ac_cv_header_sys_poll_h = xyes ; then
2330   glib_sys_poll_h=yes
2331 fi
2332
2333 case 2 in
2334 $ac_cv_sizeof_short)
2335   gint16=short
2336   gint16_modifier='"h"'
2337   gint16_format='"hi"'
2338   guint16_format='"hu"'
2339   ;;
2340 $ac_cv_sizeof_int)
2341   gint16=int
2342   gint16_modifier='""'
2343   gint16_format='"i"'
2344   guint16_format='"u"'
2345   ;;
2346 esac
2347 case 4 in
2348 $ac_cv_sizeof_short)
2349   gint32=short
2350   gint32_modifier='"h"'
2351   gint32_format='"hi"'
2352   guint32_format='"hu"'
2353   ;;
2354 $ac_cv_sizeof_int)
2355   gint32=int
2356   gint32_modifier='""'
2357   gint32_format='"i"'
2358   guint32_format='"u"'
2359   ;;
2360 $ac_cv_sizeof_long)
2361   gint32=long
2362   gint32_modifier='"l"'
2363   gint32_format='"li"'
2364   guint32_format='"lu"'
2365   ;;
2366 esac
2367 case 8 in
2368 $ac_cv_sizeof_int)
2369   gint64=int
2370   gint64_modifier='""'
2371   gint64_format='"i"'
2372   guint64_format='"u"'
2373   glib_extension=
2374   gint64_constant='(val)'
2375   ;;
2376 $ac_cv_sizeof_long)
2377   gint64=long
2378   gint64_modifier='"l"'
2379   gint64_format='"li"'
2380   guint64_format='"lu"'
2381   glib_extension=
2382   gint64_constant='(val##L)'
2383   ;;
2384 $ac_cv_sizeof_long_long)
2385   gint64='long long'
2386   if test -n "$glib_cv_long_long_format"; then
2387     gint64_modifier='"'$glib_cv_long_long_format'"'
2388     gint64_format='"'$glib_cv_long_long_format'i"'
2389     guint64_format='"'$glib_cv_long_long_format'u"'
2390   fi
2391   glib_extension='G_GNUC_EXTENSION '
2392   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
2393   ;;
2394 $ac_cv_sizeof___int64)
2395   gint64='__int64'
2396   if test -n "$glib_cv_long_long_format"; then
2397     gint64_modifier='"'$glib_cv_long_long_format'"'
2398     gint64_format='"'$glib_cv_long_long_format'i"'
2399     guint64_format='"'$glib_cv_long_long_format'u"'
2400   fi
2401   glib_extension=
2402   gint64_constant='(val##i64)'
2403   ;;
2404 esac
2405 glib_size_t=$ac_cv_sizeof_size_t
2406 glib_size_type_define=$glib_size_type
2407 glib_void_p=$ac_cv_sizeof_long
2408 glib_long=$ac_cv_sizeof_void_p
2409
2410 case $glib_size_type in
2411 short)
2412   gsize_modifier='"h"'
2413   gsize_format='"hu"'
2414   gssize_format='"hi"'
2415   glib_msize_type='SHRT'
2416   ;;
2417 int)
2418   gsize_modifier='""'
2419   gsize_format='"u"'
2420   gssize_format='"i"'
2421   glib_msize_type='INT'
2422   ;;
2423 long)
2424   gsize_modifier='"l"'
2425   gsize_format='"lu"'
2426   gssize_format='"li"'
2427   glib_msize_type='LONG'
2428   ;;
2429 esac
2430
2431 gintbits=`expr $ac_cv_sizeof_int \* 8`
2432 glongbits=`expr $ac_cv_sizeof_long \* 8`
2433
2434
2435 case $ac_cv_sizeof_void_p in
2436 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
2437 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
2438 *)                      glib_unknown_void_p=yes ;;
2439 esac
2440
2441
2442 case xyes in
2443 x$ac_cv_func_atexit)
2444   glib_atexit="
2445 #ifdef NeXT /* @#%@! NeXTStep */
2446 # define g_ATEXIT(proc) (!atexit (proc))
2447 #else
2448 # define g_ATEXIT(proc) (atexit (proc))
2449 #endif"
2450   ;;
2451 x$ac_cv_func_on_exit)
2452   glib_atexit="
2453 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
2454   ;;
2455 esac
2456
2457 case xyes in
2458 x$ac_cv_func_memmove)
2459   glib_memmove='
2460 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
2461   ;;
2462 x$glib_cv_working_bcopy)
2463   glib_memmove="
2464 /* memmove isn't available, but bcopy can copy overlapping memory regions */
2465 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
2466   ;;
2467 *)
2468   glib_memmove="
2469 /* memmove isn't found and bcopy can't copy overlapping memory regions,
2470  * so we have to roll our own copy routine. */
2471 void g_memmove (void* dest, const void * src, unsigned long len);"
2472   ;;
2473 esac
2474
2475 glib_defines="
2476 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
2477 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
2478 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
2479 "
2480
2481 case xyes in
2482 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
2483 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
2484 *)                      glib_vacopy=''
2485 esac
2486
2487 if test x$glib_cv_va_val_copy = xno; then
2488   glib_vacopy="\$glib_vacopy
2489 #define G_VA_COPY_AS_ARRAY 1"
2490 fi
2491
2492 if test x$glib_cv_hasinline = xyes; then
2493     glib_inline='#define G_HAVE_INLINE 1'
2494 fi
2495 if test x$glib_cv_has__inline = xyes; then
2496     glib_inline="\$glib_inline
2497 #define G_HAVE___INLINE 1"
2498 fi
2499 if test x$glib_cv_has__inline__ = xyes; then
2500     glib_inline="\$glib_inline
2501 #define G_HAVE___INLINE__ 1"
2502 fi
2503
2504 g_have_gnuc_varargs=$g_have_gnuc_varargs
2505 g_have_iso_c_varargs=$g_have_iso_c_varargs
2506 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
2507
2508 case xyes in
2509 x$ac_cv_c_bigendian)
2510   g_byte_order=G_BIG_ENDIAN
2511   g_bs_native=BE
2512   g_bs_alien=LE
2513   ;;
2514 *)
2515   g_byte_order=G_LITTLE_ENDIAN
2516   g_bs_native=LE
2517   g_bs_alien=BE
2518   ;;
2519 esac
2520
2521 g_pollin=$glib_cv_value_POLLIN
2522 g_pollout=$glib_cv_value_POLLOUT
2523 g_pollpri=$glib_cv_value_POLLPRI
2524 g_pollhup=$glib_cv_value_POLLHUP
2525 g_pollerr=$glib_cv_value_POLLERR
2526 g_pollnval=$glib_cv_value_POLLNVAL
2527
2528 g_stack_grows=$glib_cv_stack_grows
2529
2530 g_have_eilseq=$have_eilseq
2531
2532 case x$have_threads in
2533 xno)    g_enable_threads_def="#undef";;
2534 *)      g_enable_threads_def="#define";;
2535 esac
2536
2537 g_threads_impl_def=$g_threads_impl
2538 g_use_double_checked_locking=$g_use_double_checked_locking
2539
2540 g_mutex_has_default="$mutex_has_default"
2541 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
2542 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
2543 g_mutex_contents="$glib_cv_byte_contents_gmutex"
2544
2545 g_module_suffix="$glib_gmodule_suffix"
2546
2547 g_pid_type="$glib_pid_type"
2548 case $host in
2549   *-*-beos*)
2550     glib_os="#define G_OS_BEOS"
2551     ;;
2552   *-*-cygwin*)
2553     glib_os="#define G_OS_UNIX
2554 #define G_PLATFORM_WIN32
2555 #define G_WITH_CYGWIN"
2556     ;;
2557   *-*-mingw*)
2558     glib_os="#define G_OS_WIN32
2559 #define G_PLATFORM_WIN32"
2560     ;;
2561   *)
2562     glib_os="#define G_OS_UNIX"
2563     ;;
2564 esac
2565 ])
2566
2567 AC_CONFIG_FILES([
2568 glib-2.0.pc
2569 glib-2.0-uninstalled.pc
2570 gmodule-2.0.pc
2571 gmodule-2.0-uninstalled.pc
2572 gthread-2.0.pc
2573 gthread-2.0-uninstalled.pc
2574 gobject-2.0.pc
2575 gobject-2.0-uninstalled.pc
2576 glib-zip
2577 glib-gettextize
2578 Makefile
2579 build/Makefile
2580 build/win32/Makefile
2581 build/win32/dirent/Makefile
2582 glib/Makefile
2583 glib/libcharset/Makefile
2584 glib/gnulib/Makefile
2585 gmodule/Makefile
2586 gmodule/gmoduleconf.h
2587 gobject/Makefile
2588 gobject/glib-mkenums
2589 gthread/Makefile
2590 po/Makefile.in
2591 docs/Makefile
2592 docs/reference/Makefile
2593 docs/reference/glib/Makefile
2594 docs/reference/glib/version.xml
2595 docs/reference/gobject/Makefile
2596 docs/reference/gobject/version.xml
2597 tests/Makefile
2598 tests/gobject/Makefile
2599 m4macros/Makefile
2600 ])
2601
2602 AC_CONFIG_COMMANDS([chmod-scripts],
2603 [chmod 0755 glib-zip
2604 chmod 0755 glib-gettextize
2605 chmod 0755 gobject/glib-mkenums])
2606
2607 # we want to invoke this macro solely so that the config.status script
2608 # and automake generated makefiles know about these generated files.
2609 # They are only needed to distcheck the package
2610 if false; then
2611   AC_CONFIG_FILES([
2612     INSTALL
2613     README
2614     config.h.win32
2615     glibconfig.h.win32
2616     glib/makefile.mingw
2617     glib/makefile.msc
2618     glib/glib.rc
2619     gmodule/makefile.mingw
2620     gmodule/makefile.msc
2621     gmodule/gmodule.rc
2622     gobject/makefile.mingw
2623     gobject/makefile.msc
2624     gobject/gobject.rc
2625     gthread/makefile.mingw
2626     gthread/makefile.msc
2627     gthread/gthread.rc
2628     tests/makefile.mingw
2629     tests/makefile.msc
2630   ])
2631 fi
2632
2633 AC_OUTPUT