configure.in

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ(2.52)
   3
   4 AC_INIT(dbus/dbus.h)
   5
   6 AM_INIT_AUTOMAKE(dbus, 0.9)
   7
   8 AM_CONFIG_HEADER(config.h)
   9
  10 # Honor aclocal flags
  11 ACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"
  12
  13 GETTEXT_PACKAGE=dbus-1
  14 AC_SUBST(GETTEXT_PACKAGE)
  15 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  16
  17  ## must come before we use the $USE_MAINTAINER_MODE variable later
  18 AM_MAINTAINER_MODE
  19
  20 AC_PROG_CC
  21 AC_PROG_CXX
  22 AC_ISC_POSIX
  23 AC_HEADER_STDC
  24 AM_PROG_LIBTOOL
  25
  26 AC_ARG_ENABLE(qt,      [  --enable-qt      enable Qt-friendly client library],enable_qt=$enableval,enable_qt=auto)
  27 AC_ARG_ENABLE(glib,    [  --enable-glib    enable GLib-friendly client library],enable_glib=$enableval,enable_glib=auto)
  28 AC_ARG_ENABLE(tests,   [  --enable-tests   enable unit test code],enable_tests=$enableval,enable_tests=$USE_MAINTAINER_MODE)
  29 AC_ARG_ENABLE(ansi,    [  --enable-ansi    enable -ansi -pedantic gcc flags],enable_ansi=$enableval,enable_ansi=no)
  30 AC_ARG_ENABLE(verbose-mode, [  --enable-verbose-mode support verbose debug mode],enable_verbose_mode=$enableval,enable_verbose_mode=yes)
  31 AC_ARG_ENABLE(asserts, [  --enable-asserts include assertion checks],enable_asserts=$enableval,enable_asserts=yes)
  32 AC_ARG_ENABLE(gcov,    [  --enable-gcov compile with coverage profiling instrumentation (gcc only)],enable_gcov=$enableval,enable_gcov=no)
  33
  34 AC_ARG_WITH(xml,                [  --with-xml=[libxml/expat] XML library to use])
  35 AC_ARG_WITH(init-scripts,       [  --with-init-scripts=[redhat] Style of init scripts to install])
  36 AC_ARG_WITH(session-socket-dir, [  --with-session-socket-dir=[dirname] Where to put sockets for the per-login-session message bus])
  37 AC_ARG_WITH(test-socket-dir,    [  --with-test-socket-dir=[dirname] Where to put sockets for make check])
  38 AC_ARG_WITH(system-pid-file,    [  --with-system-pid-file=[pidfile] PID file for systemwide daemon])
  39 AC_ARG_WITH(system-socket,      [  --with-system-socket=[filename] UNIX domain socket for systemwide daemon])
  40
  41 dnl DBUS_BUILD_TESTS controls unit tests built in to .c files
  42 dnl and also some stuff in the test/ subdir
  43 AM_CONDITIONAL(DBUS_BUILD_TESTS, test x$enable_tests = xyes)
  44 if test x$enable_tests = xyes; then
  45     AC_DEFINE(DBUS_BUILD_TESTS,1,[Build test code])
  46 fi
  47
  48 if test x$enable_verbose_mode = xyes; then
  49     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
  50 fi
  51 if test x$enable_asserts = xno; then
  52     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
  53 fi
  54
  55 #### gcc warning flags
  56
  57 if test "x$GCC" = "xyes"; then
  58   changequote(,)dnl
  59   case " $CFLAGS " in
  60   *[\ \ ]-Wall[\ \      ]*) ;;
  61   *) CFLAGS="$CFLAGS -Wall" ;;
  62   esac
  63
  64   case " $CFLAGS " in
  65   *[\ \ ]-Wchar-subscripts[\ \  ]*) ;;
  66   *) CFLAGS="$CFLAGS -Wchar-subscripts" ;;
  67   esac
  68
  69   case " $CFLAGS " in
  70   *[\ \ ]-Wmissing-declarations[\ \     ]*) ;;
  71   *) CFLAGS="$CFLAGS -Wmissing-declarations" ;;
  72   esac
  73
  74   case " $CFLAGS " in
  75   *[\ \ ]-Wmissing-prototypes[\ \       ]*) ;;
  76   *) CFLAGS="$CFLAGS -Wmissing-prototypes" ;;
  77   esac
  78
  79   case " $CFLAGS " in
  80   *[\ \ ]-Wnested-externs[\ \   ]*) ;;
  81   *) CFLAGS="$CFLAGS -Wnested-externs" ;;
  82   esac
  83
  84   case " $CFLAGS " in
  85   *[\ \ ]-Wpointer-arith[\ \    ]*) ;;
  86   *) CFLAGS="$CFLAGS -Wpointer-arith" ;;
  87   esac
  88
  89   case " $CFLAGS " in
  90   *[\ \ ]-Wcast-align[\ \       ]*) ;;
  91   *) CFLAGS="$CFLAGS -Wcast-align" ;;
  92   esac
  93
  94   case " $CFLAGS " in
  95   *[\ \ ]-Wsign-compare[\ \     ]*) ;;
  96   *) CFLAGS="$CFLAGS -Wsign-compare" ;;
  97   esac
  98
  99   if test "x$enable_ansi" = "xyes"; then
 100     case " $CFLAGS " in
 101     *[\ \       ]-ansi[\ \      ]*) ;;
 102     *) CFLAGS="$CFLAGS -ansi" ;;
 103     esac
 104
 105     case " $CFLAGS " in
 106     *[\ \       ]-pedantic[\ \  ]*) ;;
 107     *) CFLAGS="$CFLAGS -pedantic" ;;
 108     esac
 109   fi
 110   if test x$enable_gcov = xyes; then
 111     case " $CFLAGS " in
 112     *[\ \       ]-fprofile-arcs[\ \     ]*) ;;
 113     *) CFLAGS="$CFLAGS -fprofile-arcs" ;;
 114     esac
 115     case " $CFLAGS " in
 116     *[\ \       ]-ftest-coverage[\ \    ]*) ;;
 117     *) CFLAGS="$CFLAGS -ftest-coverage" ;;
 118     esac
 119
 120     ## remove optimization
 121     CFLAGS=`echo "$CFLAGS" | sed -e 's/-O[0-9]*//g'`
 122   fi
 123   changequote([,])dnl
 124 else
 125   if test x$enable_gcov = xyes; then
 126     AC_MSG_ERROR([--enable-gcov can only be used with gcc])
 127   fi
 128 fi
 129
 130 # compress spaces in cflags
 131 CFLAGS=`echo "$CFLAGS" | sed -e 's/ +/ /g'`
 132
 133 if test x$enable_gcov = xyes; then
 134      ## so that config.h changes when you toggle gcov support
 135      AC_DEFINE_UNQUOTED(DBUS_GCOV_ENABLED, 1, [Defined if gcov is enabled to force a rebuild due to config.h changing])
 136 fi
 137 AM_CONDITIONAL(DBUS_GCOV_ENABLED, test x$enable_gcov = xyes)
 138
 139 #### Integer sizes
 140
 141 AC_CHECK_SIZEOF(char)
 142 AC_CHECK_SIZEOF(short)
 143 AC_CHECK_SIZEOF(long)
 144 AC_CHECK_SIZEOF(int)
 145 AC_CHECK_SIZEOF(void *)
 146 AC_CHECK_SIZEOF(long long)
 147 AC_CHECK_SIZEOF(__int64)
 148
 149 ### this is only used in decode-gcov.c right now
 150 case 8 in
 151 $ac_cv_sizeof_int)
 152   dbusint64=int
 153   ;;
 154 $ac_cv_sizeof_long)
 155   dbusint64=long
 156   ;;
 157 $ac_cv_sizeof_long_long)
 158   dbusint64='long long'
 159   ;;
 160 $ac_cv_sizeof___int64)
 161   dbusint64=__int64
 162   ;;
 163 esac
 164
 165 AC_DEFINE_UNQUOTED(DBUS_INT64_TYPE, $dbusint64, [64-bit integer type])
 166
 167 ## byte order
 168 AC_C_BIGENDIAN
 169
 170 #### Various functions
 171 AC_CHECK_LIB(socket,socket)
 172 AC_CHECK_LIB(nsl,gethostbyname)
 173
 174 AC_CHECK_FUNCS(vsnprintf vasprintf nanosleep usleep poll setenv unsetenv socketpair getgrouplist)
 175
 176 AC_CHECK_HEADERS(execinfo.h, [AC_CHECK_FUNCS(backtrace)])
 177
 178 AC_CACHE_CHECK([for posix getpwnam_r],
 179                 ac_cv_func_posix_getpwnam_r,
 180                 [AC_TRY_RUN([
 181 #include <errno.h>
 182 #include <pwd.h>
 183 int main () {
 184     char buffer[10000];
 185     struct passwd pwd, *pwptr = &pwd;
 186     int error;
 187     errno = 0;
 188     error = getpwnam_r ("", &pwd, buffer,
 189                         sizeof (buffer), &pwptr);
 190    return (error < 0 && errno == ENOSYS)
 191            || error == ENOSYS;
 192 }               ],
 193         [ac_cv_func_posix_getpwnam_r=yes],
 194         [ac_cv_func_posix_getpwnam_r=no])])
 195 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 196         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 197                 [Have POSIX function getpwnam_r])
 198 else
 199         AC_CACHE_CHECK([for nonposix getpwnam_r],
 200                 ac_cv_func_nonposix_getpwnam_r,
 201                 [AC_TRY_LINK([#include <pwd.h>],
 202                         [char buffer[10000];
 203                         struct passwd pwd;
 204                         getpwnam_r ("", &pwd, buffer,
 205                                         sizeof (buffer));],
 206                         [ac_cv_func_nonposix_getpwnam_r=yes],
 207                         [ac_cv_func_nonposix_getpwnam_r=no])])
 208                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 209                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 210                         [Have non-POSIX function getpwnam_r])
 211         fi
 212 fi
 213
 214 dnl check for writev header and writev function so we're
 215 dnl good to go if HAVE_WRITEV gets defined.
 216 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 217
 218 dnl check for flavours of varargs macros (test from GLib)
 219 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 220 AC_TRY_COMPILE([],[
 221 int a(int p1, int p2, int p3);
 222 #define call_a(...) a(1,__VA_ARGS__)
 223 call_a(2,3);
 224 ],dbus_have_iso_c_varargs=yes,dbus_have_iso_c_varargs=no)
 225 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 226
 227 AC_MSG_CHECKING(for GNUC varargs macros)
 228 AC_TRY_COMPILE([],[
 229 int a(int p1, int p2, int p3);
 230 #define call_a(params...) a(1,params)
 231 call_a(2,3);
 232 ],dbus_have_gnuc_varargs=yes,dbus_have_gnuc_varargs=no)
 233 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 234
 235 dnl Output varargs tests
 236 if test x$dbus_have_iso_c_varargs = xyes; then
 237     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 238 fi
 239 if test x$dbus_have_gnuc_varargs = xyes; then
 240     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 241 fi
 242
 243 dnl Check for various credentials.
 244 AC_MSG_CHECKING(for struct cmsgcred)
 245 AC_TRY_COMPILE([
 246 #include <sys/types.h>
 247 #include <sys/socket.h>
 248 ],[
 249 struct cmsgcred cred;
 250
 251 cred.cmcred_pid = 0;
 252 ],dbus_have_struct_cmsgcred=yes,dbus_have_struct_cmsgcred=no)
 253 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 254
 255 if test x$dbus_have_struct_cmsgcred = xyes; then
 256     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 257 fi
 258
 259
 260 #### Sort out XML library
 261
 262 # see what we have
 263 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 264              [ AC_CHECK_HEADERS(expat.h, have_expat=true, have_expat=false) ],
 265              have_expat=false)
 266
 267 PKG_CHECK_MODULES(LIBXML, libxml-2.0, have_libxml=true, have_libxml=false)
 268
 269 # see what we want to use
 270 dbus_use_libxml=false
 271 dbus_use_expat=false
 272 if test x$with_xml = xexpat; then
 273         dbus_use_expat=true
 274         if ! $have_expat ; then
 275            AC_MSG_ERROR([Explicitly requested expat but expat not found])
 276         fi
 277 elif test x$with_xml = xlibxml; then
 278         dbus_use_libxml=true
 279         if ! $have_libxml ; then
 280            AC_MSG_ERROR([Explicitly requested libxml but libxml not found])
 281         fi
 282 else
 283         ### expat is the default because libxml can't currently survive
 284         ### our brutal OOM-handling unit test setup.
 285         ### http://bugzilla.gnome.org/show_bug.cgi?id=109368
 286         if $have_expat ; then
 287                 with_xml=expat
 288                 dbus_use_expat=true
 289         elif $have_libxml ; then
 290                 with_xml=libxml
 291                 dbus_use_libxml=true
 292         else
 293                 AC_MSG_ERROR([No XML library found, check config.log for failed attempts])
 294         fi
 295 fi
 296
 297 AM_CONDITIONAL(DBUS_USE_EXPAT, $dbus_use_expat)
 298 AM_CONDITIONAL(DBUS_USE_LIBXML, $dbus_use_libxml)
 299
 300 if $dbus_use_expat; then
 301    XML_LIBS=-lexpat
 302    XML_CFLAGS=
 303 fi
 304 if $dbus_use_libxml; then
 305    XML_LIBS=$LIBXML_LIBS
 306    XML_CFLAGS=$LIBXML_CFLAGS
 307 fi
 308
 309 #### Set up final flags
 310 DBUS_CLIENT_CFLAGS=
 311 DBUS_CLIENT_LIBS=
 312 AC_SUBST(DBUS_CLIENT_CFLAGS)
 313 AC_SUBST(DBUS_CLIENT_LIBS)
 314
 315 DBUS_BUS_CFLAGS=$XML_CFLAGS
 316 DBUS_BUS_LIBS=$XML_LIBS
 317 AC_SUBST(DBUS_BUS_CFLAGS)
 318 AC_SUBST(DBUS_BUS_LIBS)
 319
 320 DBUS_TEST_CFLAGS=
 321 DBUS_TEST_LIBS=
 322 AC_SUBST(DBUS_TEST_CFLAGS)
 323 AC_SUBST(DBUS_TEST_LIBS)
 324
 325 # Glib detection
 326 PKG_CHECK_MODULES(DBUS_GLIB, glib-2.0, have_glib=yes, have_glib=no)
 327 PKG_CHECK_MODULES(DBUS_GLIB_THREADS, glib-2.0 gthread-2.0, have_glib_threads=yes, have_glib_threads=no)
 328
 329 if test x$have_glib = xno ; then
 330     AC_MSG_WARN([GLib development libraries not found])
 331 fi
 332
 333 if test x$enable_glib = xyes; then
 334     if test x$have_glib = xno; then
 335         AC_MSG_ERROR([GLib explicitly required, and GLib development libraries not found])
 336     fi
 337 fi
 338
 339 if test x$enable_glib = xno; then
 340    have_glib=no;
 341 fi
 342
 343 AM_CONDITIONAL(HAVE_GLIB, test x$have_glib = xyes)
 344 AM_CONDITIONAL(HAVE_GLIB_THREADS, test x$have_glib_threads = xyes)
 345
 346 dnl GLib flags
 347 AC_SUBST(DBUS_GLIB_CFLAGS)
 348 AC_SUBST(DBUS_GLIB_LIBS)
 349 AC_SUBST(DBUS_GLIB_THREADS_LIBS)
 350
 351 # Qt detection
 352 have_qt=no
 353 AC_MSG_CHECKING([for qglobal.h])
 354 if test -n "$QTDIR" -a -f "$QTDIR/include/qglobal.h"; then
 355     have_qt=yes
 356     DBUS_QT_CXXFLAGS="-I$QTDIR/include"
 357 else
 358     for dir in "${prefix}/include/qt" "/usr/include/qt-3.1" "/usr/include/qt3" "/usr/include/qt" "/usr/lib/qt/include"; do
 359         if test -f "$dir/qglobal.h"; then
 360             have_qt=yes
 361             DBUS_QT_CXXFLAGS="-I$dir"
 362        fi
 363     done
 364 fi
 365 if test x"$have_qt" = x"yes"; then
 366    AC_MSG_RESULT([found])
 367 else
 368    AC_MSG_RESULT([not found])
 369 fi
 370
 371 dnl linking to kdecore will give us a bit of help from libtool
 372 if (! kde-config >& /dev/null); then
 373     have_qt=no
 374 else
 375     kdelibs=`kde-config --install lib --expandvars 2>/dev/null`
 376     if test -z $kdelibs -o ! -f $kdelibs/libkdecore.la; then
 377         have_qt=no
 378     else
 379         DBUS_QT_LIBS="$kdelibs/libkdecore.la"
 380     fi
 381 fi
 382
 383 if test x$have_qt = xno ; then
 384     AC_MSG_WARN([Qt development libraries not found])
 385 fi
 386
 387 if test x$enable_qt = xyes; then
 388     if test x$have_qt = xno; then
 389         AC_MSG_ERROR([Qt integration explicitly required, and Qt libraries not found])
 390     fi
 391 fi
 392
 393 if test x$enable_qt = xno; then
 394    have_qt=no;
 395 fi
 396
 397 AM_CONDITIONAL(HAVE_QT, test x$have_qt = xyes)
 398
 399 dnl Qt flags
 400 AC_SUBST(DBUS_QT_CXXFLAGS)
 401 AC_SUBST(DBUS_QT_LIBS)
 402
 403 #### find the actual value for $prefix that we'll end up with
 404 ##   (I know this is broken and should be done in the Makefile, but
 405 ##    that's a major pain and almost nobody actually seems to care)
 406 REAL_PREFIX=
 407 if test "x$prefix" = "xNONE"; then
 408   REAL_PREFIX=$ac_default_prefix
 409 else
 410   REAL_PREFIX=$prefix
 411 fi
 412
 413 #### Have to go $localstatedir->$prefix/var->/usr/local/var
 414 #### someone please fix this a better way...
 415 LOCALSTATEDIR_TMP="$localstatedir"
 416 old_prefix=$prefix
 417 prefix=$REAL_PREFIX
 418 EXPANDED_LOCALSTATEDIR=`eval echo $LOCALSTATEDIR_TMP`
 419 prefix=$old_prefix
 420 AC_SUBST(EXPANDED_LOCALSTATEDIR)
 421
 422 SYSCONFDIR_TMP="$sysconfdir"
 423 old_prefix=$prefix
 424 prefix=$REAL_PREFIX
 425 EXPANDED_SYSCONFDIR=`eval echo $SYSCONFDIR_TMP`
 426 prefix=$old_prefix
 427 AC_SUBST(EXPANDED_SYSCONFDIR)
 428
 429 BINDIR_TMP="$bindir"
 430 old_prefix=$prefix
 431 prefix=$REAL_PREFIX
 432 EXPANDED_BINDIR=`eval echo $BINDIR_TMP`
 433 prefix=$old_prefix
 434 AC_SUBST(EXPANDED_BINDIR)
 435
 436 #### Check our operating system
 437 operating_system=unknown
 438 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
 439    operating_system=redhat
 440 fi
 441
 442 #### Sort out init scripts
 443
 444 if test x$with_init_scripts = x; then
 445     if test xredhat = x$operating_system ; then
 446         with_init_scripts=redhat
 447     else
 448         with_init_scripts=none
 449     fi
 450 fi
 451
 452 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
 453
 454
 455 ##### Set up location for system bus socket
 456 if ! test -z "$with_system_socket"; then
 457    DBUS_SYSTEM_SOCKET=$with_system_socket
 458 else
 459    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
 460 fi
 461
 462 AC_SUBST(DBUS_SYSTEM_SOCKET)
 463
 464 #### Set up the pid file
 465 if ! test -z "$with_system_pid_file"; then
 466    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
 467 elif test x$operating_system = xredhat ; then
 468    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/messagebus.pid
 469 else
 470    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/dbus/pid
 471 fi
 472
 473 AC_SUBST(DBUS_SYSTEM_PID_FILE)
 474
 475 #### Tell tests where to find certain stuff in builddir
 476 ABSOLUTE_TOP_BUILDDIR=`cd ${ac_top_builddir}. && pwd`
 477
 478 AC_DEFUN(TEST_PATH, [
 479 TEST_$1=${ABSOLUTE_TOP_BUILDDIR}/test/$2
 480 AC_DEFINE_UNQUOTED(TEST_$1, "$TEST_$1",
 481                    [Full path to test file test/$2 in builddir])
 482 AC_SUBST(TEST_$1)
 483 ])
 484
 485 TEST_PATH(SERVICE_DIR, data/valid-service-files)
 486 TEST_PATH(SERVICE_BINARY, test-service)
 487 TEST_PATH(EXIT_BINARY, test-exit)
 488 TEST_PATH(SEGFAULT_BINARY, test-segfault)
 489 TEST_PATH(SLEEP_FOREVER_BINARY, test-sleep-forever)
 490
 491 #### Find socket directories
 492 if ! test -z "$TMPDIR" ; then
 493    DEFAULT_SOCKET_DIR=$TMPDIR
 494 elif ! test -z "$TEMP" ; then
 495    DEFAULT_SOCKET_DIR=$TEMP
 496 elif ! test -z "$TMP" ; then
 497    DEFAULT_SOCKET_DIR=$TMP
 498 else
 499    DEFAULT_SOCKET_DIR=/tmp
 500 fi
 501
 502 if ! test -z "$with_test_socket_dir" ; then
 503    TEST_SOCKET_DIR="$with_test_socket_dir"
 504 else
 505    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
 506 fi
 507 AC_SUBST(TEST_SOCKET_DIR)
 508
 509 if ! test -z "$with_session_socket_dir" ; then
 510    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
 511 else
 512    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
 513 fi
 514 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
 515
 516
 517 AC_OUTPUT([
 518 Doxyfile
 519 bus/system.conf
 520 bus/session.conf
 521 bus/messagebus
 522 Makefile
 523 dbus/Makefile
 524 glib/Makefile
 525 qt/Makefile
 526 bus/Makefile
 527 test/Makefile
 528 doc/Makefile
 529 dbus-1.0.pc
 530 dbus-glib-1.0.pc
 531 test/data/valid-config-files/debug-allow-all.conf
 532 test/data/valid-service-files/debug-echo.service
 533 test/data/valid-service-files/debug-segfault.service
 534 ])
 535
 536 dnl ==========================================================================
 537 echo "
 538                     D-BUS $VERSION
 539                   ==============
 540
 541         prefix:                   ${prefix}
 542         source code location:     ${srcdir}
 543         compiler:                 ${CC}
 544         cflags:                   ${CFLAGS}
 545
 546         Maintainer mode:          ${USE_MAINTAINER_MODE}
 547         gcc coverage profiling:   ${enable_gcov}
 548         Building unit tests:      ${enable_tests}
 549         Building verbose mode:    ${enable_verbose_mode}
 550         Building assertions:      ${enable_asserts}
 551         Building Qt bindings:     ${have_qt}
 552         Building GLib bindings:   ${have_glib}
 553         Using XML parser:         ${with_xml}
 554         Init scripts style:       ${with_init_scripts}
 555         System bus socket:        ${DBUS_SYSTEM_SOCKET}
 556         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
 557         Session bus socket dir:   ${DBUS_SESSION_SOCKET_DIR}
 558         'make check' socket dir:  ${TEST_SOCKET_DIR}
 559 "
 560
 561 if test x$enable_tests = xyes; then
 562         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
 563 fi
 564 if test x$enable_gcov = xyes; then
 565         echo "NOTE: building with coverage profiling is definitely for developers only."
 566 fi
 567 if test x$enable_verbose_mode = xyes; then
 568         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and may cause a slight performance decrease, but aids debugging."
 569 fi
 570 if test x$enable_asserts = xyes; then
 571         echo "NOTE: building with assertions increases library size, but will help a lot when tracking down bugs in software using D-BUS."
 572 fi