configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(automake.in)
   3
   4 AM_INIT_AUTOMAKE(automake, 1.4-p6)
   5
   6 # Find an appropriate tar for use in "dist" targets.  A "best guess"
   7 # is good enough -- if we can't find GNU tar, we don't really care.
   8 AC_CHECK_PROGS(TAR, gnutar gtar tar)
   9 AC_PATH_PROG(PERL, perl)
  10 if test -z "$PERL"; then
  11    AC_MSG_ERROR([perl not found])
  12 fi
  13 if test -n "`$PERL -v | fgrep 'version 5.001' 2> /dev/null`"; then
  14    AC_MSG_ERROR([perl 5.001 has bug which causes automake to fail])
  15 fi
  16
  17 # The API version is the base version.  We must guarantee
  18 # compatibility for all releases with the same API version.
  19 # Our current rule is that:
  20 # * All releases, including the prereleases, in an X.Y series
  21 #   are compatible.  So 1.5.1c is compatible with 1.5.
  22 # * Prereleases on the trunk are all incompatible -- 1.5b and 1.5c
  23 #   aren't the same.
  24 APIVERSION=`echo "$VERSION" | sed -e 's/^\([[0-9]]*\.[[0-9]]*[[a-z]]*\).*$/\1/'`
  25 AC_SUBST(APIVERSION)
  26
  27 # A versioned directory, defined here for convenience.
  28 pkgvdatadir="\${datadir}/automake-${APIVERSION}"
  29 AC_SUBST(pkgvdatadir)
  30
  31 # Test for ln.  We need use it to install the versioned binaries.
  32 AC_MSG_CHECKING([whether ln works])
  33 AC_CACHE_VAL([am_cv_prog_ln], [
  34 rm -f conftest conftest.file
  35 : >conftest.file
  36 if ln conftest.file conftest 2>/dev/null; then
  37   am_cv_prog_ln=ln
  38 else
  39   am_cv_prog_ln='cp -p'
  40 fi
  41 rm -f conftest conftest.file])
  42 LN="$am_cv_prog_ln"
  43 AC_SUBST([LN])
  44 result=no
  45 test "x$am_cv_prog_ln" = xln && result=yes
  46 AC_MSG_RESULT([$result])
  47
  48 AC_OUTPUT([Makefile automake aclocal m4/amversion.m4:m4/amversion.in m4/Makefile tests/Makefile],
  49 [chmod +x automake aclocal])