configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 dnl ***********************************
   6 dnl *** include special GLib macros ***
   7 dnl ***********************************
   8
   9 m4_define(glib_configure_in)
  10 m4_include(acglib.m4)dnl
  11 m4_include(glib/libcharset/codeset.m4)dnl
  12 m4_include(glib/libcharset/glibc21.m4)dnl
  13 m4_include(m4macros/glib-gettext.m4)dnl
  14
  15 #
  16 # The following version number definitions apply to GLib, GModule, GObject
  17 # and GThread as a whole, so if changes occoured in any of them, they are all
  18 # treated with the same interface and binary age.
  19 #
  20 # Making releases:
  21 #   glib_micro_version += 1;
  22 #   glib_interface_age += 1;
  23 #   glib_binary_age += 1;
  24 # if any functions have been added, set glib_interface_age to 0.
  25 # if backwards compatibility has been broken,
  26 # set glib_binary_age _and_ glib_interface_age to 0.
  27 #
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [10])
  30 m4_define([glib_micro_version], [1])
  31 m4_define([glib_interface_age], [1])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_SRCDIR([glib/glib.h])
  56
  57 # Save this value here, since automake will set cflags later
  58 cflags_set=${CFLAGS+set}
  59
  60 AM_INIT_AUTOMAKE([no-define])
  61
  62 # Specify a configuration file
  63 AM_CONFIG_HEADER([config.h])
  64
  65
  66 GLIB_MAJOR_VERSION=glib_major_version
  67 GLIB_MINOR_VERSION=glib_minor_version
  68 GLIB_MICRO_VERSION=glib_micro_version
  69 GLIB_INTERFACE_AGE=glib_interface_age
  70 GLIB_BINARY_AGE=glib_binary_age
  71 GLIB_VERSION=glib_version
  72
  73 AC_SUBST(GLIB_MAJOR_VERSION)
  74 AC_SUBST(GLIB_MINOR_VERSION)
  75 AC_SUBST(GLIB_MICRO_VERSION)
  76 AC_SUBST(GLIB_VERSION)
  77 AC_SUBST(GLIB_INTERFACE_AGE)
  78 AC_SUBST(GLIB_BINARY_AGE)
  79
  80 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  81           [Define to the GLIB major version])
  82 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  83           [Define to the GLIB minor version])
  84 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  85           [Define to the GLIB micro version])
  86 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  87           [Define to the GLIB interface age])
  88 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  89           [Define to the GLIB binary age])
  90
  91 # libtool versioning
  92 LT_RELEASE=glib_lt_release
  93 LT_CURRENT=glib_lt_current
  94 LT_REVISION=glib_lt_revision
  95 LT_AGE=glib_lt_age
  96 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
  97 AC_SUBST(LT_RELEASE)
  98 AC_SUBST(LT_CURRENT)
  99 AC_SUBST(LT_REVISION)
 100 AC_SUBST(LT_AGE)
 101 AC_SUBST(LT_CURRENT_MINUS_AGE)
 102
 103 dnl Initialize maintainer mode
 104 AM_MAINTAINER_MODE
 105
 106 AC_CANONICAL_HOST
 107
 108 AC_MSG_CHECKING([for the BeOS])
 109 case $host in
 110   *-*-beos*)
 111     glib_native_beos="yes"
 112     ;;
 113   *)
 114     glib_native_beos="no"
 115     ;;
 116 esac
 117 AC_MSG_RESULT([$glib_native_beos])
 118
 119 dnl
 120
 121 AC_MSG_CHECKING([for Win32])
 122 case "$host" in
 123   *-*-mingw*)
 124     glib_native_win32=yes
 125     GLIB_DEF=glib.def
 126     GMODULE_DEF=gmodule.def
 127     GOBJECT_DEF=gobject.def
 128     GTHREAD_DEF=gthread.def
 129     TESTGMODULE_EXP=testgmodule.exp
 130     glib_pid_type='void *'
 131     ;;
 132   *)
 133     glib_native_win32=no
 134     GLIB_DEF=
 135     GMODULE_DEF=
 136     GOBJECT_DEF=
 137     GTHREAD_DEF=
 138     TESTGMODULE_EXP=
 139     glib_pid_type=int
 140     ;;
 141 esac
 142 case $host in
 143   *-*-linux*)
 144     glib_os_linux=yes
 145     ;;
 146 esac
 147
 148
 149 AC_MSG_RESULT([$glib_native_win32])
 150 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 151 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 152 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 153 AC_SUBST(GLIB_DEF)
 154 AC_SUBST(GMODULE_DEF)
 155 AC_SUBST(GOBJECT_DEF)
 156 AC_SUBST(GTHREAD_DEF)
 157 AC_SUBST(TESTGMODULE_EXP)
 158
 159 if test "$glib_native_win32" = "yes"; then
 160   AC_CHECK_TOOL(WINDRES, windres, no)
 161   if test "$WINDRES" = no; then
 162     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 163   fi
 164   AC_CHECK_TOOL(NM, nm, no)
 165   if test "$NM" = no; then
 166     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 167   fi
 168   AC_CHECK_TOOL(RANLIB, ranlib, :)
 169   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 170 fi
 171 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 172
 173 if test "$glib_native_win32" != yes; then
 174     # libtool option to control which symbols are exported
 175     # right now, symbols starting with _ are not exported
 176     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 177 else
 178     # We currently use .def files on Windows
 179     LIBTOOL_EXPORT_OPTIONS=
 180 fi
 181 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 182
 183 dnl declare --enable-* args and collect ac_help strings
 184 AC_ARG_ENABLE(debug,
 185               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 186                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 187               enable_debug=glib_debug_default)
 188
 189 AC_ARG_ENABLE(gc_friendly,
 190               [AC_HELP_STRING([--enable-gc-friendly],
 191                               [turn on garbage collector friendliness [default=no]])],,
 192               [enable_gc_friendly=no])
 193 AC_ARG_ENABLE(mem_pools,
 194               [AC_HELP_STRING([--disable-mem-pools],
 195                               [disable all glib memory pools])],,
 196               [disable_mem_pools=no])
 197 AC_ARG_ENABLE(threads,
 198               [AC_HELP_STRING([--enable-threads],
 199                               [turn on basic thread support [default=yes]
 200 ([=no] will override --with-threads)])],,
 201               [enable_threads=yes])
 202 AC_ARG_ENABLE(rebuilds,
 203               [AC_HELP_STRING([--disable-rebuilds],
 204                               [disable all source autogeneration rules])],,
 205               [enable_rebuilds=yes])
 206 AC_ARG_ENABLE(visibility,
 207               [AC_HELP_STRING([--disable-visibility],
 208                               [don't use ELF visibility attributes])],,
 209               [enable_visibility=yes])
 210
 211 if test "x$enable_threads" != "xyes"; then
 212   enable_threads=no
 213 fi
 214
 215 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, ["${enable_debug}"],
 216         [Whether glib was compiled with debugging enabled])
 217
 218 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 219 if test "x$enable_gc_friendly" = "xyes"; then
 220   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 221   AC_MSG_RESULT([yes])
 222 else
 223   AC_MSG_RESULT([no])
 224 fi
 225
 226 AC_MSG_CHECKING([whether to disable memory pools])
 227 if test "x$disable_mem_pools" = "xno"; then
 228   AC_MSG_RESULT([no])
 229 else
 230   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 231   AC_SUBST(DISABLE_MEM_POOLS)
 232   AC_MSG_RESULT([yes])
 233 fi
 234
 235 if test "$glib_native_win32" = "yes"; then
 236   if test x$enable_static = xyes -o x$enable_static = x; then
 237     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 238     enable_static=no
 239   fi
 240   if test x$enable_shared = xno; then
 241     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 242   fi
 243   enable_shared=yes
 244 fi
 245
 246 dnl Checks for programs.
 247 AC_PROG_CC
 248
 249 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 250 AC_CHECK_PROGS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 251 AC_LANG_SAVE
 252 AC_LANG_CPLUSPLUS
 253 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 254 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 255 AC_LANG_RESTORE
 256
 257 AM_PROG_CC_STDC
 258 AC_PROG_INSTALL
 259
 260 AC_SYS_LARGEFILE
 261
 262 #
 263 # Find pkg-config
 264 #
 265 AC_PATH_PROG(PKG_CONFIG, [pkg-config], [no])
 266 if test x$PKG_CONFIG = xno ; then
 267   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
 268 fi
 269
 270 if $PKG_CONFIG --atleast-pkgconfig-version 0.14 ; then
 271   :
 272 else
 273   AC_MSG_ERROR([*** pkg-config too old; version 0.14 or better required.])
 274 fi
 275
 276 if test "x$enable_debug" = "xyes"; then
 277   if test x$cflags_set != xset ; then
 278       case " $CFLAGS " in
 279       *[[\ \    ]]-g[[\ \       ]]*) ;;
 280       *) CFLAGS="$CFLAGS -g" ;;
 281       esac
 282   fi
 283
 284   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 285 else
 286   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 287
 288   if test "x$enable_debug" = "xno"; then
 289     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 290   fi
 291 fi
 292
 293 if test "x$enable_visibility" = "xno"; then
 294   GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DDISABLE_VISIBILITY"
 295 fi
 296
 297 # Ensure MSVC-compatible struct packing convention is used when
 298 # compiling for Win32 with gcc.
 299 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 300 # gcc2 uses "-fnative-struct".
 301 if test x"$glib_native_win32" = xyes; then
 302   if test x"$GCC" = xyes; then
 303     msnative_struct=''
 304     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 305     if test -z "$ac_cv_prog_CC"; then
 306       our_gcc="$CC"
 307     else
 308       our_gcc="$ac_cv_prog_CC"
 309     fi
 310     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 311       2.)
 312         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 313           msnative_struct='-fnative-struct'
 314         fi
 315         ;;
 316       *)
 317         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 318           msnative_struct='-mms-bitfields'
 319         fi
 320         ;;
 321     esac
 322     if test x"$msnative_struct" = x ; then
 323       AC_MSG_RESULT([no way])
 324       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 325     else
 326       CFLAGS="$CFLAGS $msnative_struct"
 327       AC_MSG_RESULT([${msnative_struct}])
 328     fi
 329   fi
 330 fi
 331
 332 AC_EXEEXT
 333
 334 # define a MAINT-like variable REBUILD which is set if Perl
 335 # and awk are found, so autogenerated sources can be rebuilt
 336 AC_PROG_AWK
 337 AC_CHECK_PROGS(PERL, [perl5 perl])
 338 # We would like indent, but don't require it.
 339 AC_CHECK_PROG(INDENT, indent, indent)
 340 REBUILD=\#
 341 if test "x$enable_rebuilds" = "xyes" && \
 342      test -n "$PERL" && \
 343      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 344      test -n "$AWK" ; then
 345   REBUILD=
 346 fi
 347 AC_SUBST(REBUILD)
 348
 349 # Need full path to Perl for glib-mkenums
 350 #
 351 if test "x$PERL" != x ; then
 352   AC_PATH_PROG(PERL_PATH, [$PERL])
 353 else
 354   PERL_PATH="/usr/bin/env perl"
 355 fi
 356 AC_SUBST(PERL_PATH)
 357
 358 dnl ***********************
 359 dnl *** Tests for iconv ***
 360 dnl ***********************
 361 dnl
 362 dnl We do this before the gettext checks, to avoid distortion
 363
 364 AC_ARG_WITH(libiconv,
 365             [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 366                             [use the libiconv library])],,
 367             [with_libiconv=maybe])
 368
 369 found_iconv=no
 370 case $with_libiconv in
 371   maybe)
 372     # Check in the C library first
 373     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 374     # Check if we have GNU libiconv
 375     if test $found_iconv = "no"; then
 376       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 377     fi
 378     # Check if we have a iconv in -liconv, possibly from vendor
 379     if test $found_iconv = "no"; then
 380       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 381     fi
 382     ;;
 383   no)
 384     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 385     ;;
 386   gnu|yes)
 387     AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 388     ;;
 389   native)
 390     AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 391     ;;
 392 esac
 393
 394 if test "x$found_iconv" = "xno" ; then
 395    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 396 fi
 397
 398 jm_GLIBC21
 399 AC_ARG_ENABLE(iconv-cache,
 400               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 401                               [cache iconv descriptors [default=auto]])],,
 402               [enable_iconv_cache=auto])
 403
 404 AC_MSG_CHECKING([Whether to cache iconv descriptors])
 405 case $enable_iconv_cache in
 406   auto)
 407     if test $ac_cv_gnu_library_2_1 = yes; then
 408       enable_iconv_cache=no
 409     else
 410       enable_iconv_cache=yes
 411     fi
 412   ;;
 413   yes|no)
 414   ;;
 415   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 416   ;;
 417 esac
 418
 419 if test $enable_iconv_cache = yes; then
 420    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 421 fi
 422
 423 AC_MSG_RESULT($enable_iconv_cache)
 424
 425
 426 dnl
 427 dnl gettext support
 428 dnl
 429
 430 ALL_LINGUAS="am ar az be bg bn bs ca cs cy da de el en_CA en_GB eo es et eu fa fi fr ga gl gu he hi hr hu id is it ja ko ku lt lv mk ml mn ms nb ne nl nn no or pa pl pt pt_BR ro ru rw sk sl sq sr sr@Latn sr@ije sv ta te th tl tr tt uk vi wa xh yi zh_CN zh_HK zh_TW"
 431 GLIB_GNU_GETTEXT
 432
 433 if test "$gt_cv_have_gettext" != "yes" ; then
 434   AC_MSG_ERROR([
 435 *** You must have either have gettext support in your C library, or use the
 436 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 437 ])
 438 fi
 439
 440 LIBS="$INTLLIBS $LIBS"
 441
 442 GETTEXT_PACKAGE=glib20
 443 AC_SUBST(GETTEXT_PACKAGE)
 444 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 445   [Define the gettext package to be used])
 446
 447 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 448
 449 dnl
 450 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 451 dnl
 452
 453 if test x$with_libiconv != xno ; then
 454   case " $INTLLIBS " in
 455   *[[\ \        ]]-liconv[[\ \  ]]*) ;;
 456   *) ICONV_LIBS="-liconv" ;;
 457   esac
 458 fi
 459 AC_SUBST(ICONV_LIBS)
 460
 461 case $with_libiconv in
 462   gnu)
 463     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 464     ;;
 465   native)
 466     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 467     ;;
 468 esac
 469
 470 dnl Initialize libtool
 471 AM_DISABLE_STATIC
 472 AC_LIBTOOL_WIN32_DLL
 473 AM_PROG_LIBTOOL
 474
 475 if test "x$GCC" = "xyes"; then
 476   case " $CFLAGS " in
 477   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 478   *) CFLAGS="$CFLAGS -Wall" ;;
 479   esac
 480 fi
 481
 482 dnl
 483 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 484 dnl
 485 if test $cross_compiling != yes ; then
 486     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 487     glib_save_LIBS=$LIBS
 488     LIBS="$LIBS -lm"
 489     AC_TRY_RUN([#include <math.h>
 490                  int main (void) { return (log(1) != log(1.)); }],
 491          AC_MSG_RESULT(none needed),
 492          glib_save_CFLAGS=$CFLAGS
 493          CFLAGS="$CFLAGS -std1"
 494          AC_TRY_RUN([#include <math.h>
 495                      int main (void) { return (log(1) != log(1.)); }],
 496              AC_MSG_RESULT(-std1),
 497              AC_MSG_RESULT()
 498              CFLAGS=$glib_save_CFLAGS
 499              AC_MSG_WARN(
 500                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 501          )
 502     )
 503     LIBS=$glib_save_LIBS
 504 fi
 505
 506 dnl NeXTStep cc seems to need this
 507 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 508 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 509   AC_MSG_RESULT(none needed),
 510   glib_save_CFLAGS=$CFLAGS
 511   CFLAGS="$CFLAGS -posix"
 512   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 513     AC_MSG_RESULT(-posix),
 514     AC_MSG_RESULT()
 515     CFLAGS=$glib_save_CFLAGS
 516     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 517
 518 # Checks for header files.
 519 AC_HEADER_STDC
 520
 521 # Checks for library functions.
 522 AC_FUNC_VPRINTF
 523 AC_FUNC_MMAP
 524 AC_FUNC_ALLOCA
 525 AC_CHECK_FUNCS(posix_memalign)
 526 AC_CHECK_FUNCS(memalign)
 527 AC_CHECK_FUNCS(valloc)
 528
 529 AC_CHECK_FUNCS(atexit on_exit)
 530
 531 AC_CHECK_SIZEOF(char)
 532 AC_CHECK_SIZEOF(short)
 533 AC_CHECK_SIZEOF(long)
 534 AC_CHECK_SIZEOF(int)
 535 AC_CHECK_SIZEOF(void *)
 536 AC_CHECK_SIZEOF(long long)
 537 AC_CHECK_SIZEOF(__int64)
 538
 539 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 540   :
 541 else
 542   AC_MSG_ERROR([
 543 *** GLib requires a 64 bit type. You might want to consider
 544 *** using the GNU C compiler.
 545 ])
 546 fi
 547
 548 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 549         # long long is a 64 bit integer.
 550         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 551         AC_CACHE_VAL(glib_cv_long_long_format,[
 552                 for format in ll q I64; do
 553                   AC_TRY_RUN([#include <stdio.h>
 554                         int main()
 555                         {
 556                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 557                           char buffer[1000];
 558                           sprintf (buffer, "%${format}u", a);
 559                           sscanf (buffer, "%${format}u", &b);
 560                           exit (b!=a);
 561                         }
 562                         ],
 563                         [glib_cv_long_long_format=${format}
 564                         break],
 565                         [],[:])
 566                 done])
 567         if test -n "$glib_cv_long_long_format"; then
 568           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 569           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 570           if test x"$glib_cv_long_long_format" = xI64; then
 571             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 572           fi
 573         else
 574           AC_MSG_RESULT(none)
 575         fi
 576 elif test x$ac_cv_sizeof___int64 = x8; then
 577         # __int64 is a 64 bit integer.
 578         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 579         # We know this is MSVCRT.DLL, and what the formats are
 580         glib_cv_long_long_format=I64
 581         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 582         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 583         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 584 fi
 585
 586 dnl long doubles were not used, and a portability problem
 587 dnl AC_C_LONG_DOUBLE
 588 AC_C_CONST
 589
 590 dnl ok, here we try to check whether the systems prototypes for
 591 dnl malloc and friends actually match the prototypes provided
 592 dnl by gmem.h (keep in sync). i currently only know how to check
 593 dnl this reliably with gcc (-Werror), improvements for other
 594 dnl compilers are apprechiated.
 595 SANE_MALLOC_PROTOS=no
 596 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 597 glib_save_CFLAGS=$CFLAGS
 598 if test "x$GCC" = "xyes"; then
 599   CFLAGS="$CFLAGS -Werror"
 600   AC_TRY_COMPILE([#include <stdlib.h>], [
 601     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 602     void* (*my_malloc_p)  (size_t)         = malloc;
 603     void  (*my_free_p)    (void*)          = free;
 604     void* (*my_realloc_p) (void*, size_t)  = realloc;
 605     my_calloc_p = 0;
 606     my_malloc_p = 0;
 607     my_free_p = 0;
 608     my_realloc_p = 0;
 609   ],
 610     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 611       [Define if you have correct malloc prototypes])
 612     SANE_MALLOC_PROTOS=yes)
 613 fi
 614 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 615 CFLAGS=$glib_save_CFLAGS
 616
 617 dnl
 618 dnl check in which direction the stack grows
 619 dnl
 620 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 621         AC_TRY_RUN([
 622         volatile int *a = 0, *b = 0;
 623         void foo (void);
 624         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 625         void foo (void) { volatile int x = 5; b = &x; }
 626         ],
 627         glib_cv_stack_grows=no
 628         ,
 629         glib_cv_stack_grows=yes
 630         ,)
 631 ])
 632
 633 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 634 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 635 dnl actually supported.
 636 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 637         AC_COMPILE_IFELSE([
 638         __inline int foo () { return 0; }
 639         int main () { return foo (); }
 640         ],
 641         glib_cv_has__inline=yes
 642         ,
 643         glib_cv_has__inline=no
 644         ,)
 645 ])
 646 case x$glib_cv_has__inline in
 647 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 648 esac
 649 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 650         AC_COMPILE_IFELSE([
 651         __inline__ int foo () { return 0; }
 652         int main () { return foo (); }
 653         ],
 654         glib_cv_has__inline__=yes
 655         ,
 656         glib_cv_has__inline__=no
 657         ,)
 658 ])
 659 case x$glib_cv_has__inline__ in
 660 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 661 esac
 662 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 663         AC_COMPILE_IFELSE([
 664         #undef inline
 665         inline int foo () { return 0; }
 666         int main () { return foo (); }
 667         ],
 668         glib_cv_hasinline=yes
 669         ,
 670         glib_cv_hasinline=no
 671         ,)
 672 ])
 673 case x$glib_cv_hasinline in
 674 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 675 esac
 676
 677 # if we can use inline functions in headers
 678 AC_MSG_CHECKING(if inline functions in headers work)
 679 AC_LINK_IFELSE([
 680 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 681 #  undef inline
 682 #  define inline __inline__
 683 #elif !defined (G_HAVE_INLINE)
 684 #  undef inline
 685 #  if defined (G_HAVE___INLINE__)
 686 #    define inline __inline__
 687 #  elif defined (G_HAVE___INLINE)
 688 #    define inline __inline
 689 #  endif
 690 #endif
 691
 692 int glib_test_func2 (int);
 693
 694 static inline int
 695 glib_test_func1 (void) {
 696   return glib_test_func2 (1);
 697 }
 698
 699 int
 700 main (void) {
 701   int i = 1;
 702 }],[g_can_inline=yes],[g_can_inline=no])
 703 AC_MSG_RESULT($g_can_inline)
 704
 705 dnl *** check for working do while(0) macros ***
 706 AC_CACHE_CHECK([for working do while(0) macros], g_support_dowhile_macros, [
 707         AC_TRY_COMPILE([],[
 708         #define STMT_START do
 709         #define STMT_END while(0)
 710         #define STMT_TEST STMT_START { i = 0; } STMT_END
 711         int main(void) { int i = 1; STMT_TEST; return i; }],
 712         [g_support_dowhile_macros=yes],
 713         [g_support_dowhile_macros=no],
 714         [g_support_dowhile_macros=yes])
 715 ])
 716 if test x$g_support_dowhile_macros = xyes; then
 717   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 718 fi
 719
 720 # check for flavours of varargs macros
 721 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 722 AC_TRY_COMPILE([],[
 723 int a(int p1, int p2, int p3);
 724 #define call_a(...) a(1,__VA_ARGS__)
 725 call_a(2,3);
 726 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 727 AC_MSG_RESULT($g_have_iso_c_varargs)
 728
 729 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 730 if test "$CXX" = ""; then
 731 dnl No C++ compiler
 732   g_have_iso_cxx_varargs=no
 733 else
 734   AC_LANG_CPLUSPLUS
 735   AC_TRY_COMPILE([],[
 736 int a(int p1, int p2, int p3);
 737 #define call_a(...) a(1,__VA_ARGS__)
 738 call_a(2,3);
 739 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 740   AC_LANG_C
 741 fi
 742 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 743
 744 AC_MSG_CHECKING(for GNUC varargs macros)
 745 AC_TRY_COMPILE([],[
 746 int a(int p1, int p2, int p3);
 747 #define call_a(params...) a(1,params)
 748 call_a(2,3);
 749 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 750 AC_MSG_RESULT($g_have_gnuc_varargs)
 751
 752 # check for GNUC visibility support
 753 AC_MSG_CHECKING(for GNUC visibility attribute)
 754 GLIB_CHECK_COMPILE_WARNINGS([
 755 void
 756 __attribute__ ((visibility ("hidden")))
 757      f_hidden (void)
 758 {
 759 }
 760 void
 761 __attribute__ ((visibility ("internal")))
 762      f_internal (void)
 763 {
 764 }
 765 void
 766 __attribute__ ((visibility ("protected")))
 767      f_protected (void)
 768 {
 769 }
 770 void
 771 __attribute__ ((visibility ("default")))
 772      f_default (void)
 773 {
 774 }
 775 int main (int argc, char **argv)
 776 {
 777         f_hidden();
 778         f_internal();
 779         f_protected();
 780         f_default();
 781         return 0;
 782 }
 783 ],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 784 AC_MSG_RESULT($g_have_gnuc_visibility)
 785 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 786
 787 # check for bytesex stuff
 788 AC_C_BIGENDIAN
 789
 790 # check for header files
 791 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h sys/param.h sys/poll.h])
 792 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 793 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h sched.h malloc.h])
 794
 795 # Checks for libcharset
 796 jm_LANGINFO_CODESET
 797 jm_GLIBC21
 798 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 799 AC_CHECK_FUNCS(setlocale)
 800
 801 # check additional type sizes
 802 AC_CHECK_SIZEOF(size_t)
 803
 804 dnl Try to figure out whether gsize, gssize should be long or int
 805 AC_MSG_CHECKING([for the appropriate definition for size_t])
 806
 807 case $ac_cv_sizeof_size_t in
 808   $ac_cv_sizeof_short)
 809       glib_size_type=short
 810       ;;
 811   $ac_cv_sizeof_int)
 812       glib_size_type=int
 813       ;;
 814   $ac_cv_sizeof_long)
 815       glib_size_type=long
 816       ;;
 817   *)  AC_MSG_ERROR([No type matching size_t in size])
 818       ;;
 819 esac
 820
 821 dnl If int/long are the same size, we see which one produces
 822 dnl warnings when used in the location as size_t. (This matters
 823 dnl on AIX with xlc)
 824 dnl
 825 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 826    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 827   GLIB_CHECK_COMPILE_WARNINGS([
 828 #if defined(_AIX) && !defined(__GNUC__)
 829 #pragma options langlvl=stdc89
 830 #endif
 831 #include <stddef.h>
 832 int main ()
 833 {
 834   size_t s = 1;
 835   unsigned int *size_int = &s;
 836   return (int)*size_int;
 837 }
 838     ],glib_size_type=int,
 839       [GLIB_CHECK_COMPILE_WARNINGS([
 840 #if defined(_AIX) && !defined(__GNUC__)
 841 #pragma options langlvl=stdc89
 842 #endif
 843 #include <stddef.h>
 844 int main ()
 845 {
 846    size_t s = 1;
 847    unsigned long *size_long = &s;
 848    return (int)*size_long;
 849 }
 850         ],glib_size_type=long)])
 851 fi
 852
 853 AC_MSG_RESULT(unsigned $glib_size_type)
 854
 855 # Check for some functions
 856 AC_CHECK_FUNCS(lstat strerror strsignal memmove mkstemp vsnprintf stpcpy strcasecmp strncasecmp poll getcwd nanosleep vasprintf setenv unsetenv getc_unlocked readlink symlink)
 857
 858 AC_CHECK_HEADERS(crt_externs.h)
 859 AC_CHECK_FUNCS(_NSGetEnviron)
 860
 861 AC_FUNC_VSNPRINTF_C99
 862 AC_FUNC_PRINTF_UNIX98
 863
 864 #
 865 # Check whether to use an included printf
 866 #
 867
 868 AC_ARG_ENABLE(included-printf,
 869               [AC_HELP_STRING([--enable-included-printf],
 870                               [use included printf [default=auto]])],
 871               enable_included_printf="$enableval")
 872
 873 need_included_printf=no
 874 if test "x$enable_included_printf" = "xyes" ; then
 875   need_included_printf=yes
 876 fi
 877 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
 878   need_included_printf=yes
 879 fi
 880 if test "$ac_cv_func_printf_unix98" != "yes" ; then
 881   need_included_printf=yes
 882 fi
 883 if test "x$ac_cv_sizeof_long_long" = "x8" &&
 884    test -z "$glib_cv_long_long_format" ; then
 885   need_included_printf=yes
 886 fi
 887
 888 if test "x$enable_included_printf" = "xno" &&
 889    test "x$need_included_printf" = "xyes" ; then
 890   AC_MSG_ERROR([
 891 *** Your C library's printf doesn't appear to have the features that
 892 *** GLib needs, but you specified --enable-included-printf=no.])
 893 fi
 894
 895 enable_included_printf=$need_included_printf
 896
 897 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
 898 if test "$enable_included_printf" != "yes" ; then
 899   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
 900 else
 901   if test -z "$glib_cv_long_long_format" ; then
 902     glib_cv_long_long_format="ll"
 903   fi
 904   AC_DEFINE(HAVE_VASPRINTF,1)
 905 fi
 906
 907 # Checks needed for gnulib vasnprintf
 908 bh_C_SIGNED
 909 jm_AC_TYPE_LONG_LONG
 910 gt_TYPE_LONGDOUBLE
 911 gt_TYPE_WCHAR_T
 912 gt_TYPE_WINT_T
 913 AC_TYPE_SIZE_T
 914 AC_CHECK_TYPES(ptrdiff_t)
 915 jm_AC_TYPE_INTMAX_T
 916 AC_CHECK_FUNCS(snprintf)
 917 AC_FUNC_SNPRINTF_C99
 918
 919 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 920 # The check is borrowed from the PERL Configure script.
 921 if test "$ac_cv_func_memmove" != "yes"; then
 922   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 923     glib_cv_working_bcopy,[AC_TRY_RUN([
 924       int main() {
 925         char buf[128], abc[128], *b;
 926         int len, off, align;
 927         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 928         for (align = 7; align >= 0; align--) {
 929           for (len = 36; len; len--) {
 930             b = buf+align; bcopy(abc, b, len);
 931             for (off = 1; off <= len; off++) {
 932               bcopy(b, b+off, len); bcopy(b+off, b, len);
 933                 if (bcmp(b, abc, len)) return(1);
 934             }
 935           }
 936         }
 937         return(0);
 938       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 939
 940   GLIB_ASSERT_SET(glib_cv_working_bcopy)
 941   if test "$glib_cv_working_bcopy" = "yes"; then
 942     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 943   fi
 944 fi
 945
 946 # Check for sys_errlist
 947 AC_MSG_CHECKING(for sys_errlist)
 948 AC_TRY_LINK(, [
 949 extern char *sys_errlist[];
 950 extern int sys_nerr;
 951 sys_errlist[sys_nerr-1][0] = 0;
 952 ], glib_ok=yes, glib_ok=no)
 953 AC_MSG_RESULT($glib_ok)
 954 if test "$glib_ok" = "no"; then
 955     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 956 fi
 957
 958 # Check for sys_siglist
 959 AC_MSG_CHECKING(for sys_siglist)
 960 AC_TRY_LINK(, [
 961 extern char *sys_siglist[];
 962 exit (sys_siglist[0]);
 963 ], glib_ok=yes, glib_ok=no)
 964 AC_MSG_RESULT($glib_ok)
 965 if test "$glib_ok" = "no"; then
 966     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 967 fi
 968
 969 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 970 AC_MSG_CHECKING(for sys_siglist declaration)
 971 AC_TRY_COMPILE([#include <signal.h>], [
 972 strlen (sys_siglist[0]);
 973 ], glib_ok=yes, glib_ok=no)
 974 AC_MSG_RESULT($glib_ok)
 975 if test "$glib_ok" = "no"; then
 976     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 977 fi
 978
 979 # Check if <sys/select.h> needs to be included for fd_set
 980 AC_MSG_CHECKING([for fd_set])
 981 AC_TRY_COMPILE([#include <sys/types.h>],
 982         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 983 if test "$gtk_ok" = "yes"; then
 984     AC_MSG_RESULT([yes, found in sys/types.h])
 985 else
 986     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
 987     if test "$gtk_ok" = "yes"; then
 988         # *** FIXME: give it a different name
 989         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
 990         AC_MSG_RESULT([yes, found in sys/select.h])
 991     else
 992         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
 993         AC_MSG_RESULT(no)
 994     fi
 995 fi
 996
 997 dnl *** check for sane realloc() ***
 998 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
 999         AC_TRY_RUN([#include <stdlib.h>
1000         int main() {
1001           return realloc (0, sizeof (int)) == 0;
1002         }],
1003         [glib_cv_sane_realloc=yes],
1004         [glib_cv_sane_realloc=no],
1005         [glib_cv_sane_realloc=yes])
1006 ])
1007 if test x$glib_cv_sane_realloc = xyes; then
1008   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1009 fi
1010
1011 dnl Check for nl_langinfo and CODESET
1012
1013 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
1014 AC_TRY_COMPILE([#include <langinfo.h>],
1015         [char *codeset = nl_langinfo (CODESET);],
1016    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1017    have_codeset=yes,
1018    have_codeset=no)
1019 AC_MSG_RESULT($have_codeset)
1020
1021
1022 dnl ****************************************
1023 dnl *** posix_memalign                   ***
1024 dnl ****************************************
1025 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1026 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1027     glib_cv_compliant_posix_memalign=0
1028     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1029         AC_TRY_RUN([
1030                 #define _XOPEN_SOURCE 600
1031                 #include <stdlib.h> /* posix_memalign() should be defined here */
1032                 /* some systems break if #include <malloc.h> used */
1033                 static void test_memalign (size_t boundary, size_t size) {
1034                     void *mem = 0;
1035                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1036                         exit (1);
1037                     else
1038                       free (mem);
1039                 }
1040                 int main() {
1041                     test_memalign (  128,   128 - 2 * sizeof (void*));
1042                     test_memalign (  256,   256 - 2 * sizeof (void*));
1043                     test_memalign (  512,   512 - 2 * sizeof (void*));
1044                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1045                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1046                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1047                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1048                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1049                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1050                     exit (0); /* success */
1051                 }
1052                 ],
1053             [glib_cv_compliant_posix_memalign=1], [], [:])
1054       :
1055     fi
1056     ])
1057 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1058     AC_MSG_RESULT(yes)
1059     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1060 else
1061     AC_MSG_RESULT(no)
1062 fi
1063
1064
1065 dnl ****************************************
1066 dnl *** strlcpy/strlcat                  ***
1067 dnl ****************************************
1068 # Check for strlcpy
1069 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1070 AC_TRY_RUN([#include <stdlib.h>
1071 #include <string.h>
1072 int main() {
1073   char p[10];
1074   (void) strlcpy (p, "hi", 10);
1075   if (strlcat (p, "bye", 0) != 3)
1076     return 1;
1077   return 0;
1078 }], glib_cv_have_strlcpy=yes,
1079     glib_cv_have_strlcpy=no,
1080     glib_cv_have_strlcpy=no)])
1081 if test "$glib_cv_have_strlcpy" = "yes"; then
1082     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1083 fi
1084
1085
1086 dnl **********************
1087 dnl *** va_copy checks ***
1088 dnl **********************
1089 dnl we currently check for all three va_copy possibilities, so we get
1090 dnl all results in config.log for bug reports.
1091 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1092         AC_LINK_IFELSE([#include <stdarg.h>
1093         void f (int i, ...) {
1094         va_list args1, args2;
1095         va_start (args1, i);
1096         va_copy (args2, args1);
1097         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1098           exit (1);
1099         va_end (args1); va_end (args2);
1100         }
1101         int main() {
1102           f (0, 42);
1103           return 0;
1104         }],
1105         [glib_cv_va_copy=yes],
1106         [glib_cv_va_copy=no])
1107 ])
1108 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1109         AC_LINK_IFELSE([#include <stdarg.h>
1110         void f (int i, ...) {
1111         va_list args1, args2;
1112         va_start (args1, i);
1113         __va_copy (args2, args1);
1114         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1115           exit (1);
1116         va_end (args1); va_end (args2);
1117         }
1118         int main() {
1119           f (0, 42);
1120           return 0;
1121         }],
1122         [glib_cv___va_copy=yes],
1123         [glib_cv___va_copy=no])
1124 ])
1125
1126 if test "x$glib_cv_va_copy" = "xyes"; then
1127   g_va_copy_func=va_copy
1128 else if test "x$glib_cv___va_copy" = "xyes"; then
1129   g_va_copy_func=__va_copy
1130 fi
1131 fi
1132
1133 if test -n "$g_va_copy_func"; then
1134   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1135 fi
1136
1137 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1138         AC_TRY_RUN([#include <stdarg.h>
1139         void f (int i, ...) {
1140         va_list args1, args2;
1141         va_start (args1, i);
1142         args2 = args1;
1143         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1144           exit (1);
1145         va_end (args1); va_end (args2);
1146         }
1147         int main() {
1148           f (0, 42);
1149           return 0;
1150         }],
1151         [glib_cv_va_val_copy=yes],
1152         [glib_cv_va_val_copy=no],
1153         [glib_cv_va_val_copy=yes])
1154 ])
1155
1156 if test "x$glib_cv_va_val_copy" = "xno"; then
1157   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1158 fi
1159
1160 dnl ***********************
1161 dnl *** g_module checks ***
1162 dnl ***********************
1163 G_MODULE_LIBS=
1164 G_MODULE_LIBS_EXTRA=
1165 G_MODULE_PLUGIN_LIBS=
1166 if test x"$glib_native_win32" = xyes; then
1167   dnl No use for this on Win32
1168   G_MODULE_LDFLAGS=
1169 else
1170   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1171 fi
1172 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1173 G_MODULE_NEED_USCORE=0
1174 G_MODULE_BROKEN_RTLD_GLOBAL=0
1175 G_MODULE_HAVE_DLERROR=0
1176 dnl *** force native WIN32 shared lib loader
1177 if test -z "$G_MODULE_IMPL"; then
1178   case "$host" in
1179   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1180   esac
1181 fi
1182 dnl *** force native AIX library loader
1183 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1184 if test -z "$G_MODULE_IMPL"; then
1185   case "$host" in
1186   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1187   esac
1188 fi
1189 dnl *** dlopen() and dlsym() in system libraries
1190 if test -z "$G_MODULE_IMPL"; then
1191         AC_CHECK_FUNC(dlopen,
1192                       [AC_CHECK_FUNC(dlsym,
1193                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1194                       [])
1195 fi
1196 dnl *** load_image (BeOS)
1197 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1198   AC_CHECK_LIB(root, load_image,
1199       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1200       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1201       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1202       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1203       [])
1204 fi
1205 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1206 if test -z "$G_MODULE_IMPL"; then
1207         AC_CHECK_FUNC(NSLinkModule,
1208                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1209                        G_MODULE_NEED_USCORE=1],
1210                       [])
1211 fi
1212 dnl *** dlopen() and dlsym() in libdl
1213 if test -z "$G_MODULE_IMPL"; then
1214         AC_CHECK_LIB(dl, dlopen,
1215                      [AC_CHECK_LIB(dl, dlsym,
1216                                    [G_MODULE_LIBS=-ldl
1217                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1218                      [])
1219 fi
1220 dnl *** shl_load() in libdld (HP-UX)
1221 if test -z "$G_MODULE_IMPL"; then
1222         AC_CHECK_LIB(dld, shl_load,
1223                 [G_MODULE_LIBS=-ldld
1224                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1225                 [])
1226 fi
1227 dnl *** additional checks for G_MODULE_IMPL_DL
1228 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1229         LIBS_orig="$LIBS"
1230         LDFLAGS_orig="$LDFLAGS"
1231         LIBS="$G_MODULE_LIBS $LIBS"
1232         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1233 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1234         echo "void glib_plugin_test(void) { }" > plugin.c
1235         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1236                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1237         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1238                 glib_cv_rtldglobal_broken,[
1239                 AC_TRY_RUN([
1240 #include <dlfcn.h>
1241 #ifndef RTLD_GLOBAL
1242 #  define RTLD_GLOBAL 0
1243 #endif
1244 #ifndef RTLD_LAZY
1245 #  define RTLD_LAZY 0
1246 #endif
1247 int glib_plugin_test;
1248 int main () {
1249     void *handle, *global, *local;
1250     global = &glib_plugin_test;
1251     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1252     if (!handle) return 0;
1253     local = dlsym (handle, "glib_plugin_test");
1254     return global == local;
1255 }                       ],
1256                         [glib_cv_rtldglobal_broken=no],
1257                         [glib_cv_rtldglobal_broken=yes],
1258                         [glib_cv_rtldglobal_broken=no])
1259                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1260                 rmdir .libs 2>/dev/null
1261         ])
1262         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1263                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1264         else
1265                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1266         fi
1267 dnl *** check whether we need preceeding underscores
1268         AC_CACHE_CHECK([for preceeding underscore in symbols],
1269                 glib_cv_uscore,[
1270                 AC_TRY_RUN([#include <dlfcn.h>
1271                 int glib_underscore_test (void) { return 42; }
1272                 int main() {
1273                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1274                   handle = dlopen ((void*)0, 0);
1275                   if (handle) {
1276                     f1 = dlsym (handle, "glib_underscore_test");
1277                     f2 = dlsym (handle, "_glib_underscore_test");
1278                   } return (!f2 || f1);
1279                 }],
1280                         [glib_cv_uscore=yes],
1281                         [glib_cv_uscore=no],
1282                         [])
1283                 rm -f plugin.c plugin.$ac_objext plugin.lo
1284         ])
1285         GLIB_ASSERT_SET(glib_cv_uscore)
1286         if test "x$glib_cv_uscore" = "xyes"; then
1287                 G_MODULE_NEED_USCORE=1
1288         else
1289                 G_MODULE_NEED_USCORE=0
1290         fi
1291
1292         LDFLAGS="$LDFLAGS_orig"
1293 dnl *** check for having dlerror()
1294         AC_CHECK_FUNC(dlerror,
1295                 [G_MODULE_HAVE_DLERROR=1],
1296                 [G_MODULE_HAVE_DLERROR=0])
1297         LIBS="$LIBS_orig"
1298 fi
1299 dnl *** done, have we got an implementation?
1300 if test -z "$G_MODULE_IMPL"; then
1301         G_MODULE_IMPL=0
1302         G_MODULE_SUPPORTED=false
1303 else
1304         G_MODULE_SUPPORTED=true
1305 fi
1306
1307 AC_MSG_CHECKING(for the suffix of shared libraries)
1308 case "$host_os" in
1309   hpux9* | hpux10* | hpux11*)  # taken from ltconfig
1310     case "$host_cpu" in
1311       hppa*)
1312         glib_gmodule_suffix='sl'
1313         ;;
1314       ia64*)
1315         glib_gmodule_suffix='so'
1316         ;;
1317     esac
1318     ;;
1319   cygwin* | mingw*)
1320     glib_gmodule_suffix='dll'
1321     ;;
1322   aix*)
1323     glib_gmodule_suffix='a'
1324     ;;
1325   *)
1326     glib_gmodule_suffix='so'
1327     ;;
1328 esac
1329 AC_MSG_RESULT(.$glib_gmodule_suffix)
1330
1331 AC_SUBST(G_MODULE_SUPPORTED)
1332 AC_SUBST(G_MODULE_IMPL)
1333 AC_SUBST(G_MODULE_LIBS)
1334 AC_SUBST(G_MODULE_LIBS_EXTRA)
1335 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1336 AC_SUBST(G_MODULE_LDFLAGS)
1337 AC_SUBST(G_MODULE_HAVE_DLERROR)
1338 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1339 AC_SUBST(G_MODULE_NEED_USCORE)
1340 AC_SUBST(GLIB_DEBUG_FLAGS)
1341
1342 dnl **********************
1343 dnl *** g_spawn checks ***
1344 dnl **********************
1345
1346 AC_MSG_CHECKING(for gspawn implementation)
1347 case "$host" in
1348   *-*-mingw*)
1349     GSPAWN=gspawn-win32.lo
1350     ;;
1351   *)
1352     GSPAWN=gspawn.lo
1353     ;;
1354 esac
1355 AC_MSG_RESULT($GSPAWN)
1356 AC_SUBST(GSPAWN)
1357
1358 dnl *************************
1359 dnl *** GIOChannel checks ***
1360 dnl *************************
1361
1362 AC_MSG_CHECKING(for GIOChannel implementation)
1363 case "$host" in
1364   *-*-mingw*)
1365     GIO=giowin32.lo
1366     ;;
1367   *)
1368     GIO=giounix.lo
1369     ;;
1370 esac
1371 AC_MSG_RESULT($GIO)
1372 AC_SUBST(GIO)
1373
1374 dnl ****************************************
1375 dnl *** platform dependent source checks ***
1376 dnl ****************************************
1377
1378 AC_MSG_CHECKING(for platform-dependent source)
1379 case "$host" in
1380   *-*-cygwin*|*-*-mingw*)
1381     PLATFORMDEP=gwin32.lo
1382     ;;
1383   *)
1384     PLATFORMDEP=
1385     ;;
1386 esac
1387 AC_MSG_RESULT($PLATFORMDEP)
1388 AC_SUBST(PLATFORMDEP)
1389
1390 AC_MSG_CHECKING([whether to compile timeloop])
1391 case "$host" in
1392   *-*-cygwin*|*-*-mingw*)
1393     enable_timeloop=no
1394     ;;
1395   *)
1396     enable_timeloop=yes
1397     ;;
1398 esac
1399 AC_MSG_RESULT($enable_timeloop)
1400 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1401
1402 AC_MSG_CHECKING([if building for some Win32 platform])
1403 case "$host" in
1404   *-*-mingw*|*-*-cygwin*)
1405     platform_win32=yes
1406     ;;
1407   *)
1408     platform_win32=no
1409     ;;
1410 esac
1411 AC_MSG_RESULT($platform_win32)
1412 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1413
1414 dnl ***********************
1415 dnl *** g_thread checks ***
1416 dnl ***********************
1417
1418 AC_ARG_WITH(threads,
1419            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/win32@:>@],
1420                            [specify a thread implementation to use])],
1421            [if test "x$with_threads" = x; then
1422                 want_threads=yes
1423             else
1424                 want_threads=$with_threads
1425             fi],
1426            [want_threads=yes])
1427 if test "x$enable_threads" = "xno"; then
1428         want_threads=no
1429 fi
1430
1431 dnl error and warning message
1432 dnl *************************
1433
1434 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1435                 computer. GLib will not have a default thread implementation."
1436
1437 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1438                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1439                 compilation now, but then your programs might not work.
1440                 Please provide information on how it is done on your system."
1441
1442 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1443                 "
1444
1445 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1446                 provide information on your thread implementation.
1447                 You can also run 'configure --disable-threads'
1448                 to compile without thread support."
1449
1450 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1451                 functions will not be MT-safe during their first call because
1452                 there is no working 'getpwuid_r' on your system."
1453
1454 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1455                 because there is no 'localtime_r' on your system."
1456
1457 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1458                 crude surrogate will be used. If you happen to know a
1459                 yield function for your system, please inform the GLib
1460                 developers."
1461
1462 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1463                 threads on your system. Thus threads can only have the default
1464                 priority. If you happen to know these main/max
1465                 priorities, please inform the GLib developers."
1466
1467 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1468                 linking threaded applications. As GLib cannot do that
1469                 automatically, you will get an linkg error everytime you are
1470                 not using the right compiler. In that case you have to relink
1471                 with the right compiler. Ususally just '_r' is appended
1472                 to the compiler name."
1473
1474 dnl determination of thread implementation
1475 dnl ***************************************
1476
1477 # have_threads=no   means no thread support
1478 # have_threads=none means no default thread implementation
1479
1480 have_threads=no
1481 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1482                                 || test "x$want_threads" = xdce; then
1483         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1484         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1485         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1486         glib_save_CPPFLAGS="$CPPFLAGS"
1487         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1488         if test "x$have_threads" = xno; then
1489                 AC_TRY_COMPILE([#include <pthread.h>],
1490                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1491                         have_threads=posix)
1492         fi
1493         if test "x$have_threads" = xno; then
1494                 AC_TRY_COMPILE([#include <pthread.h>],
1495                         [pthread_mutex_t m;
1496                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1497                         have_threads=dce)
1498         fi
1499         # Tru64Unix requires -pthread to find pthread.h. See #103020
1500         CPPFLAGS="$CPPFLAGS -pthread"
1501         if test "x$have_threads" = xno; then
1502         AC_TRY_COMPILE([#include <pthread.h>],
1503                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1504                        have_threads=posix)
1505         fi
1506         CPPFLAGS="$glib_save_CPPFLAGS"
1507 fi
1508 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1509         case $host in
1510                 *-*-mingw*)
1511                 have_threads=win32
1512                 ;;
1513         esac
1514 fi
1515 if test "x$want_threads" = xnone; then
1516         have_threads=none
1517 fi
1518
1519 AC_MSG_CHECKING(for thread implementation)
1520
1521 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1522         AC_MSG_RESULT(none available)
1523         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1524 else
1525         AC_MSG_RESULT($have_threads)
1526 fi
1527
1528
1529 dnl determination of G_THREAD_CFLAGS
1530 dnl ********************************
1531
1532 G_THREAD_LIBS=
1533 G_THREAD_LIBS_EXTRA=
1534 G_THREAD_CFLAGS=
1535
1536 dnl
1537 dnl Test program for basic POSIX threads functionality
1538 dnl
1539 m4_define([glib_thread_test],[
1540 #include <pthread.h>
1541 int check_me = 0;
1542 void* func(void* data) {check_me = 42; return &check_me;}
1543 int main()
1544  { pthread_t t;
1545    void *ret;
1546    pthread_create (&t, $1, func, 0);
1547    pthread_join (t, &ret);
1548    exit (check_me != 42 || ret != &check_me);
1549 }])
1550
1551 dnl
1552 dnl Test program for sched_get_priority_min()
1553 dnl
1554 m4_define([glib_sched_priority_test],[
1555 #include <sched.h>
1556 #include <errno.h>
1557 int main() {
1558     errno = 0;
1559     return sched_get_priority_min(SCHED_OTHER)==-1
1560            && errno != 0;
1561 }])
1562
1563 if test x"$have_threads" != xno; then
1564
1565   if test x"$have_threads" = xposix; then
1566     # First we test for posix, whether -pthread or -pthreads do the trick as
1567     # both CPPFLAG and LIBS.
1568     # One of them does for most gcc versions and some other platforms/compilers
1569     # too and could be considered as the canonical way to go.
1570     case $host in
1571       *-*-cygwin*)
1572          # skip cygwin -pthread or -pthreads test
1573          ;;
1574       *)
1575         for flag in pthread pthreads mt; do
1576           glib_save_CFLAGS="$CFLAGS"
1577           CFLAGS="$CFLAGS -$flag"
1578           AC_TRY_RUN(glib_thread_test(0),
1579                      glib_flag_works=yes,
1580                      glib_flag_works=no,
1581                      [AC_LINK_IFELSE(glib_thread_test(0),
1582                                      glib_flag_works=yes,
1583                                      glib_flag_works=no)])
1584           CFLAGS="$glib_save_CFLAGS"
1585           if test $glib_flag_works = yes ; then
1586              G_THREAD_CFLAGS=-$flag
1587              G_THREAD_LIBS=-$flag
1588           fi
1589         done
1590          ;;
1591     esac
1592   fi
1593
1594   if test x"$G_THREAD_CFLAGS" = x; then
1595
1596     # The canonical -pthread[s] does not work. Try something different.
1597
1598     case $host in
1599         *-aix*)
1600                 if test x"$GCC" = xyes; then
1601                         # GCC 3.0 and above needs -pthread.
1602                         # Should be coverd by the case above.
1603                         # GCC 2.x and below needs -mthreads
1604                         G_THREAD_CFLAGS="-mthreads"
1605                         G_THREAD_LIBS=$G_THREAD_CFLAGS
1606                 else
1607                         # We are probably using the aix compiler. Normaly a
1608                         # program would have to be compiled with the _r variant
1609                         # of the corresponding compiler, but we as GLib cannot
1610                         # do that: but the good news is that for compiling the
1611                         # only difference is the added -D_THREAD_SAFE compile
1612                         # option. This is according to the "C for AIX User's
1613                         # Guide".
1614                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
1615                 fi
1616                 ;;
1617         *-dg-dgux*)  # DG/UX
1618                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
1619                 ;;
1620         *-osf*)
1621                 # So we are using dce threads. posix threads are already
1622                 # catched above.
1623                 G_THREAD_CFLAGS="-threads"
1624                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1625                 ;;
1626         *-sysv5uw7*) # UnixWare 7
1627                 # We are not using gcc with -pthread. Catched above.
1628                 G_THREAD_CFLAGS="-Kthread"
1629                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1630                 ;;
1631         *-mingw*)
1632                 # No flag needed when using MSVCRT.DLL
1633                 G_THREAD_CFLAGS=""
1634                 ;;
1635         *)
1636                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1637                 ;;
1638     esac
1639
1640   fi
1641
1642     # if we are not finding the localtime_r function, then we probably are
1643     # not using the proper multithread flag
1644
1645     glib_save_CPPFLAGS="$CPPFLAGS"
1646     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1647
1648     # First we test, whether localtime_r is declared in time.h
1649     # directly. Then we test whether a macro localtime_r exists, in
1650     # which case localtime_r in the test program is replaced and thus
1651     # if we still find localtime_r in the output, it is not defined as
1652     # a macro.
1653
1654     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1655       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1656                                                            localtime_r(a,b)],
1657                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1658
1659     CPPFLAGS="$glib_save_CPPFLAGS"
1660
1661     AC_MSG_CHECKING(thread related cflags)
1662     AC_MSG_RESULT($G_THREAD_CFLAGS)
1663     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1664 fi
1665
1666 dnl determination of G_THREAD_LIBS
1667 dnl ******************************
1668
1669 mutex_has_default=no
1670 case $have_threads in
1671         posix|dce)
1672           glib_save_CPPFLAGS="$CPPFLAGS"
1673           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1674           if test x"$G_THREAD_LIBS" = x; then
1675             case $host in
1676               *-aix*)
1677                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
1678                 # probably using the aix compiler.
1679                 AC_MSG_WARN($AIX_COMPILE_INFO)
1680                 ;;
1681               *)
1682                 G_THREAD_LIBS=error
1683                 glib_save_LIBS="$LIBS"
1684                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
1685                         if test x"$thread_lib" = x; then
1686                                 add_thread_lib=""
1687                                 IN=""
1688                         else
1689                                 add_thread_lib="-l$thread_lib"
1690                                 IN=" in -l$thread_lib"
1691                         fi
1692                         if test x"$have_threads" = xposix; then
1693                                 defattr=0
1694                         else
1695                                 defattr=pthread_attr_default
1696                         fi
1697
1698                         LIBS="$add_thread_lib $glib_save_LIBS"
1699
1700                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
1701                         AC_TRY_RUN(glib_thread_test($defattr),
1702                                    glib_result=yes,
1703                                    glib_result=no,
1704                                    [AC_LINK_IFELSE(glib_thread_test($defattr),
1705                                                    glib_result=yes,
1706                                                    glib_result=no)])
1707                         AC_MSG_RESULT($glib_result)
1708
1709                         if test "$glib_result" = "yes" ; then
1710                           G_THREAD_LIBS="$add_thread_lib"
1711                           break
1712                         fi
1713                 done
1714                 if test "x$G_THREAD_LIBS" = xerror; then
1715                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1716                 fi
1717                 LIBS="$glib_save_LIBS"
1718                 ;;
1719             esac
1720           fi
1721
1722           glib_save_LIBS="$LIBS"
1723           for thread_lib in "" rt rte; do
1724             if test x"$thread_lib" = x; then
1725               add_thread_lib=""
1726               IN=""
1727             else
1728               add_thread_lib="-l$thread_lib"
1729               IN=" in -l$thread_lib"
1730             fi
1731             LIBS="$add_thread_lib $glib_save_LIBS"
1732
1733             AC_MSG_CHECKING(for sched_get_priority_min$IN)
1734             AC_TRY_RUN(glib_sched_priority_test,
1735                        glib_result=yes,
1736                        glib_result=no,
1737                        [AC_LINK_IFELSE(glib_sched_priority_test,
1738                                        glib_result=yes,
1739                                        glib_result=no)])
1740             AC_MSG_RESULT($glib_result)
1741
1742             if test "$glib_result" = "yes" ; then
1743                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
1744                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
1745                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
1746                break
1747             fi
1748           done
1749           LIBS="$glib_save_LIBS"
1750           mutex_has_default=yes
1751           mutex_default_type='pthread_mutex_t'
1752           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
1753           mutex_header_file='pthread.h'
1754           if test "x$have_threads" = "xposix"; then
1755             g_threads_impl="POSIX"
1756           else
1757             g_threads_impl="DCE"
1758             have_threads="posix"
1759           fi
1760           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
1761           CPPFLAGS="$glib_save_CPPFLAGS"
1762           ;;
1763         win32)
1764            g_threads_impl="WIN32"
1765            ;;
1766         none|no)
1767            g_threads_impl="NONE"
1768            ;;
1769         *)
1770            g_threads_impl="NONE"
1771            G_THREAD_LIBS=error
1772            ;;
1773 esac
1774
1775 if test "x$G_THREAD_LIBS" = xerror; then
1776         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1777 fi
1778
1779 case $host in
1780   *-*-beos*)
1781     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
1782     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1783     ;;
1784   *)
1785     ;;
1786 esac
1787
1788 AC_MSG_CHECKING(thread related libraries)
1789 AC_MSG_RESULT($G_THREAD_LIBS)
1790
1791 dnl check for mt safe function variants and some posix functions
1792 dnl ************************************************************
1793
1794 if test x"$have_threads" != xno; then
1795         glib_save_LIBS="$LIBS"
1796         # we are not doing the following for now, as this might require glib
1797         # to always be linked with the thread libs on some platforms.
1798         # LIBS="$LIBS $G_THREAD_LIBS"
1799         AC_CHECK_FUNCS(localtime_r)
1800         if test "$ac_cv_header_pwd_h" = "yes"; then
1801                 AC_CACHE_CHECK([for posix getpwuid_r],
1802                         ac_cv_func_posix_getpwuid_r,
1803                         [AC_TRY_RUN([
1804 #include <errno.h>
1805 #include <pwd.h>
1806 int main () {
1807     char buffer[10000];
1808     struct passwd pwd, *pwptr = &pwd;
1809     int error;
1810     errno = 0;
1811     error = getpwuid_r (0, &pwd, buffer,
1812                         sizeof (buffer), &pwptr);
1813    return (error < 0 && errno == ENOSYS)
1814            || error == ENOSYS;
1815 }                               ],
1816                                 [ac_cv_func_posix_getpwuid_r=yes],
1817                                 [ac_cv_func_posix_getpwuid_r=no])])
1818                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
1819                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
1820                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
1821                                 [Have POSIX function getpwuid_r])
1822                 else
1823                         AC_CACHE_CHECK([for nonposix getpwuid_r],
1824                                 ac_cv_func_nonposix_getpwuid_r,
1825                                 [AC_TRY_LINK([#include <pwd.h>],
1826                                         [char buffer[10000];
1827                                         struct passwd pwd;
1828                                         getpwuid_r (0, &pwd, buffer,
1829                                                         sizeof (buffer));],
1830                                         [ac_cv_func_nonposix_getpwuid_r=yes],
1831                                         [ac_cv_func_nonposix_getpwuid_r=no])])
1832                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
1833                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
1834                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
1835                                         [Have non-POSIX function getpwuid_r])
1836                         fi
1837                 fi
1838         fi
1839         LIBS="$G_THREAD_LIBS $LIBS"
1840         if test x"$have_threads" = xposix; then
1841                 glib_save_CPPFLAGS="$CPPFLAGS"
1842                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1843                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
1844                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
1845                 # This is not AC_CHECK_FUNC to also work with function
1846                 # name mangling in header files.
1847                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1848                 AC_TRY_LINK([#include <pthread.h>],
1849                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1850                         [AC_MSG_RESULT(yes)
1851                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1852                                   [Have function pthread_attr_setstacksize])],
1853                         [AC_MSG_RESULT(no)])
1854                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1855                 if test x"$posix_priority_min" = x; then
1856                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1857                                 PX_PRIO_MIN],,[
1858                                 posix_priority_min=PX_PRIO_MIN
1859                                 posix_priority_max=PX_PRIO_MAX])
1860                 fi
1861                 if test x"$posix_priority_min" = x; then
1862                         # AIX
1863                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
1864                                 PTHREAD_PRIO_MIN],,[
1865                                 posix_priority_min=PTHREAD_PRIO_MIN
1866                                 posix_priority_max=PTHREAD_PRIO_MAX])
1867                 fi
1868                 if test x"$posix_priority_min" = x; then
1869                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1870                                 PRI_OTHER_MIN],,[
1871                                 posix_priority_min=PRI_OTHER_MIN
1872                                 posix_priority_max=PRI_OTHER_MAX])
1873                 fi
1874                 if test x"$posix_priority_min" = x; then
1875                         AC_MSG_RESULT(none found)
1876                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1877                         posix_priority_min=-1
1878                         posix_priority_max=-1
1879                 else
1880                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1881                         AC_MSG_CHECKING(for pthread_setschedparam)
1882                         AC_TRY_LINK([#include <pthread.h>],
1883                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
1884                           [AC_MSG_RESULT(yes)
1885                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1886                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
1887                           [AC_MSG_RESULT(no)
1888                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
1889                 fi
1890                 posix_yield_func=none
1891                 AC_MSG_CHECKING(for posix yield function)
1892                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1893                                                         thr_yield; do
1894                         AC_TRY_LINK([#include <pthread.h>],
1895                                 [$yield_func()],
1896                                 [posix_yield_func="$yield_func"
1897                                 break])
1898                 done
1899                 if test x"$posix_yield_func" = xnone; then
1900                         AC_MSG_RESULT(none found)
1901                         AC_MSG_WARN($POSIX_NO_YIELD)
1902                         posix_yield_func="g_usleep(1000)"
1903                 else
1904                         AC_MSG_RESULT($posix_yield_func)
1905                         posix_yield_func="$posix_yield_func()"
1906                 fi
1907                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1908                 CPPFLAGS="$glib_save_CPPFLAGS"
1909
1910         elif test x"$have_threads" = xwin32; then
1911                 # It's a pointer to a private struct
1912                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
1913         fi
1914
1915         LIBS="$glib_save_LIBS"
1916
1917         # now spit out all the warnings.
1918         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1919            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1920                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1921         fi
1922         if test "$ac_cv_func_localtime_r" != "yes"; then
1923                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1924         fi
1925 fi
1926
1927 if test x"$glib_cv_sizeof_system_thread" = x; then
1928    # use a pointer as a fallback.
1929    GLIB_SIZEOF(,void *, system_thread)
1930 fi
1931
1932 #
1933 # Hack to deal with:
1934 #
1935 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
1936 #     building shared libraries with linux.
1937 #
1938 case $host in
1939   *-*-linux*)
1940     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
1941     ;;
1942   *)
1943     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
1944     ;;
1945 esac
1946
1947 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1948                    [Source file containing theread implementation])
1949 AC_SUBST(G_THREAD_CFLAGS)
1950 AC_SUBST(G_THREAD_LIBS)
1951 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
1952 AC_SUBST(G_THREAD_LIBS_EXTRA)
1953
1954 dnl **********************************************
1955 dnl *** GDefaultMutex setup and initialization ***
1956 dnl **********************************************
1957 dnl
1958 dnl if mutex_has_default = yes, we also got
1959 dnl mutex_default_type, mutex_default_init and mutex_header_file
1960 if test $mutex_has_default = yes ; then
1961         glib_save_CPPFLAGS="$CPPFLAGS"
1962         glib_save_LIBS="$LIBS"
1963         LIBS="$G_THREAD_LIBS $LIBS"
1964         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1965         GLIB_SIZEOF([#include <$mutex_header_file>],
1966                     $mutex_default_type,
1967                     gmutex)
1968         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1969                            $mutex_default_type,
1970                            gmutex,
1971                            $glib_cv_sizeof_gmutex,
1972                            $mutex_default_init)
1973         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1974                 mutex_has_default=no
1975         fi
1976         CPPFLAGS="$glib_save_CPPFLAGS"
1977         LIBS="$glib_save_LIBS"
1978 fi
1979
1980 dnl ********************************
1981 dnl *** g_atomic_* tests for gcc ***
1982 dnl ********************************
1983
1984 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
1985
1986 if test x"$GCC" = xyes; then
1987   case $host_cpu in
1988     i386)
1989       AC_MSG_RESULT([none])
1990       glib_memory_barrier_needed=no
1991       ;;
1992     i?86)
1993       AC_MSG_RESULT([i486])
1994       AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
1995                          [i486 atomic implementation])
1996       glib_memory_barrier_needed=no
1997       ;;
1998     sparc*)
1999       SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
2000                 when you are using a sparc with v9 instruction set (most
2001                 sparcs nowadays). This will make the code for atomic
2002                 operations much faster. The resulting code will not run
2003                 on very old sparcs though."
2004
2005       AC_LINK_IFELSE([[
2006         main ()
2007         {
2008           int tmp1, tmp2, tmp3;
2009           __asm__ __volatile__("casx [%2], %0, %1"
2010                                : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
2011         }]],
2012         AC_MSG_RESULT([sparcv9])
2013         AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
2014                            [sparcv9 atomic implementation]),
2015         AC_MSG_RESULT([no])
2016         AC_MSG_WARN([[$SPARCV9_WARNING]]))
2017       glib_memory_barrier_needed=yes
2018       ;;
2019     alpha*)
2020       AC_MSG_RESULT([alpha])
2021       AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
2022                          [alpha atomic implementation])
2023       glib_memory_barrier_needed=yes
2024       ;;
2025     x86_64)
2026       AC_MSG_RESULT([x86_64])
2027       AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
2028                          [x86_64 atomic implementation])
2029       glib_memory_barrier_needed=no
2030      ;;
2031     powerpc*)
2032       AC_MSG_RESULT([powerpc])
2033       AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
2034                          [powerpc atomic implementation])
2035       glib_memory_barrier_needed=yes
2036       ;;
2037     ia64)
2038       AC_MSG_RESULT([ia64])
2039       AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
2040                          [ia64 atomic implementation])
2041       glib_memory_barrier_needed=yes
2042       ;;
2043     s390|s390x)
2044       AC_MSG_RESULT([s390])
2045       AC_DEFINE_UNQUOTED(G_ATOMIC_S390, 1,
2046                          [s390 atomic implementation])
2047       glib_memory_barrier_needed=no
2048       ;;
2049     *)
2050       AC_MSG_RESULT([none])
2051       glib_memory_barrier_needed=yes
2052       ;;
2053   esac
2054 fi
2055
2056 dnl ****************************************
2057 dnl *** GLib POLL* compatibility defines ***
2058 dnl ****************************************
2059
2060 glib_poll_includes=["
2061 #include <sys/types.h>
2062 #include <sys/poll.h>
2063 "]
2064
2065 if test $ac_cv_header_sys_types_h = yes &&
2066    test $ac_cv_header_sys_poll_h = yes ; then
2067   glib_failed=false
2068   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2069   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2070   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2071   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2072   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2073   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2074   if $glib_failed ; then
2075     AC_MSG_ERROR([Could not determine values for POLL* constants])
2076   fi
2077 else
2078   glib_cv_value_POLLIN=1
2079   glib_cv_value_POLLOUT=4
2080   glib_cv_value_POLLPRI=2
2081   glib_cv_value_POLLERR=8
2082   glib_cv_value_POLLHUP=16
2083   glib_cv_value_POLLNVAL=32
2084 fi
2085
2086 dnl **********************
2087 dnl *** Win32 API libs ***
2088 dnl **********************
2089
2090 case $host in
2091   *-*-cygwin*)
2092         G_LIBS_EXTRA="-luser32 -lkernel32"
2093     ;;
2094   *-*-mingw*)
2095         G_LIBS_EXTRA="-lws2_32 -lole32"
2096     ;;
2097   *)
2098         G_LIBS_EXTRA=""
2099     ;;
2100 esac
2101 AC_SUBST(G_LIBS_EXTRA)
2102
2103 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2104 dnl since we need it for g_iconv()
2105
2106 AC_MSG_CHECKING([for EILSEQ])
2107 AC_TRY_COMPILE([
2108 #include <errno.h>
2109 ],
2110 [
2111 int error = EILSEQ;
2112 ], have_eilseq=yes, have_eilseq=no);
2113 AC_MSG_RESULT($have_eilseq)
2114
2115 dnl ******************************************************************
2116 dnl *** Look for glib-genmarshal in PATH if we are cross-compiling ***
2117 dnl ******************************************************************
2118
2119 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2120
2121 if test $cross_compiling = yes; then
2122   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2123   if test x$GLIB_GENMARSHAL = xno; then
2124     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2125   fi
2126 fi
2127
2128 dnl **************************
2129 dnl *** Checks for gtk-doc ***
2130 dnl **************************
2131
2132 GTK_DOC_CHECK([1.4])
2133
2134 AC_ARG_ENABLE(man,
2135               [AC_HELP_STRING([--enable-man],
2136                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2137               enable_man=no)
2138
2139 if test "${enable_man}" != no; then
2140 dnl
2141 dnl Check for xsltproc
2142 dnl
2143 AC_PATH_PROG([XSLTPROC], [xsltproc])
2144   if test -z "$XSLTPROC"; then
2145     enable_man=no
2146   fi
2147
2148   dnl check for DocBook DTD and stylesheets in the local catalog.
2149   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2150      [DocBook XML DTD V4.1.2],,enable_man=no)
2151   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2152      [DocBook XSL Stylesheets],,enable_man=no)
2153 fi
2154
2155 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2156
2157 dnl ******************************
2158 dnl *** output the whole stuff ***
2159 dnl ******************************
2160
2161 dnl this section will only be run if config.status is invoked with no
2162 dnl arguments, or with "glibconfig.h" as an argument.
2163 AC_CONFIG_COMMANDS([glibconfig.h],
2164 [
2165         outfile=glibconfig.h-tmp
2166         cat > $outfile <<\_______EOF
2167 /* glibconfig.h
2168  *
2169  * This is a generated file.  Please modify 'configure.in'
2170  */
2171
2172 #ifndef __G_LIBCONFIG_H__
2173 #define __G_LIBCONFIG_H__
2174
2175 #include <glib/gmacros.h>
2176
2177 _______EOF
2178
2179         if test x$glib_limits_h = xyes; then
2180           echo '#include <limits.h>' >> $outfile
2181         fi
2182         if test x$glib_float_h = xyes; then
2183           echo '#include <float.h>' >> $outfile
2184         fi
2185         if test x$glib_values_h = xyes; then
2186           echo '#include <values.h>' >> $outfile
2187         fi
2188         if test "$glib_header_alloca_h" = "yes"; then
2189           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2190         fi
2191         if test x$glib_sys_poll_h = xyes; then
2192           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2193         fi
2194
2195         cat >> $outfile <<_______EOF
2196
2197 G_BEGIN_DECLS
2198
2199 #define G_MINFLOAT      $glib_mf
2200 #define G_MAXFLOAT      $glib_Mf
2201 #define G_MINDOUBLE     $glib_md
2202 #define G_MAXDOUBLE     $glib_Md
2203 #define G_MINSHORT      $glib_ms
2204 #define G_MAXSHORT      $glib_Ms
2205 #define G_MAXUSHORT     $glib_Mus
2206 #define G_MININT        $glib_mi
2207 #define G_MAXINT        $glib_Mi
2208 #define G_MAXUINT       $glib_Mui
2209 #define G_MINLONG       $glib_ml
2210 #define G_MAXLONG       $glib_Ml
2211 #define G_MAXULONG      $glib_Mul
2212
2213 _______EOF
2214
2215
2216         ### this should always be true in a modern C/C++ compiler
2217         cat >>$outfile <<_______EOF
2218 typedef signed char gint8;
2219 typedef unsigned char guint8;
2220 _______EOF
2221
2222
2223         if test -n "$gint16"; then
2224           cat >>$outfile <<_______EOF
2225 typedef signed $gint16 gint16;
2226 typedef unsigned $gint16 guint16;
2227 #define G_GINT16_MODIFIER $gint16_modifier
2228 #define G_GINT16_FORMAT $gint16_format
2229 #define G_GUINT16_FORMAT $guint16_format
2230 _______EOF
2231         fi
2232
2233
2234         if test -n "$gint32"; then
2235           cat >>$outfile <<_______EOF
2236 typedef signed $gint32 gint32;
2237 typedef unsigned $gint32 guint32;
2238 #define G_GINT32_MODIFIER $gint32_modifier
2239 #define G_GINT32_FORMAT $gint32_format
2240 #define G_GUINT32_FORMAT $guint32_format
2241 _______EOF
2242         fi
2243
2244         cat >>$outfile <<_______EOF
2245 #define G_HAVE_GINT64 1          /* deprecated, always true */
2246
2247 ${glib_extension}typedef signed $gint64 gint64;
2248 ${glib_extension}typedef unsigned $gint64 guint64;
2249
2250 #define G_GINT64_CONSTANT(val)  $gint64_constant
2251 #define G_GUINT64_CONSTANT(val) $guint64_constant
2252 _______EOF
2253
2254         if test x$gint64_format != x ; then
2255           cat >>$outfile <<_______EOF
2256 #define G_GINT64_MODIFIER $gint64_modifier
2257 #define G_GINT64_FORMAT $gint64_format
2258 #define G_GUINT64_FORMAT $guint64_format
2259 _______EOF
2260         else
2261           cat >>$outfile <<_______EOF
2262 #undef G_GINT64_MODIFIER
2263 #undef G_GINT64_FORMAT
2264 #undef G_GUINT64_FORMAT
2265 _______EOF
2266         fi
2267
2268         cat >>$outfile <<_______EOF
2269
2270 #define GLIB_SIZEOF_VOID_P $glib_void_p
2271 #define GLIB_SIZEOF_LONG   $glib_long
2272 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2273
2274 _______EOF
2275
2276         cat >>$outfile <<_______EOF
2277 typedef signed $glib_size_type_define gssize;
2278 typedef unsigned $glib_size_type_define gsize;
2279 #define G_GSIZE_MODIFIER $gsize_modifier
2280 #define G_GSSIZE_FORMAT $gssize_format
2281 #define G_GSIZE_FORMAT $gsize_format
2282
2283 #define G_MAXSIZE       G_MAXU$glib_msize_type
2284 _______EOF
2285
2286         if test -z "$glib_unknown_void_p"; then
2287           cat >>$outfile <<_______EOF
2288
2289 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2290 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2291
2292 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2293 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2294 _______EOF
2295         else
2296           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2297         fi
2298
2299
2300
2301         cat >>$outfile <<_______EOF
2302 $glib_atexit
2303 $glib_memmove
2304 $glib_defines
2305 $glib_os
2306
2307 $glib_vacopy
2308
2309 #ifdef  __cplusplus
2310 #define G_HAVE_INLINE   1
2311 #else   /* !__cplusplus */
2312 $glib_inline
2313 #endif  /* !__cplusplus */
2314
2315 #ifdef  __cplusplus
2316 #define G_CAN_INLINE    1
2317 _______EOF
2318
2319         if test x$g_can_inline = xyes ; then
2320                 cat >>$outfile <<_______EOF
2321 #else   /* !__cplusplus */
2322 #define G_CAN_INLINE    1
2323 _______EOF
2324         fi
2325
2326         cat >>$outfile <<_______EOF
2327 #endif
2328
2329 _______EOF
2330
2331         if test x$g_have_iso_c_varargs = xyes ; then
2332                 cat >>$outfile <<_______EOF
2333 #ifndef __cplusplus
2334 # define G_HAVE_ISO_VARARGS 1
2335 #endif
2336 _______EOF
2337         fi
2338         if test x$g_have_iso_cxx_varargs = xyes ; then
2339                 cat >>$outfile <<_______EOF
2340 #ifdef __cplusplus
2341 # define G_HAVE_ISO_VARARGS 1
2342 #endif
2343 _______EOF
2344         fi
2345         if test x$g_have_gnuc_varargs = xyes ; then
2346                 cat >>$outfile <<_______EOF
2347
2348 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2349  * is passed ISO vararg support is turned off, and there is no work
2350  * around to turn it on, so we unconditionally turn it off.
2351  */
2352 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2353 #  undef G_HAVE_ISO_VARARGS
2354 #endif
2355
2356 #define G_HAVE_GNUC_VARARGS 1
2357 _______EOF
2358         fi
2359
2360         case x$g_stack_grows in
2361         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2362         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2363         esac
2364
2365
2366         echo >>$outfile
2367         if test x$g_have_eilseq = xno; then
2368                 cat >>$outfile <<_______EOF
2369 #ifndef EILSEQ
2370 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2371  * The correspondence between this and the corresponding definition
2372  * in libiconv is essential.
2373  */
2374 #  define EILSEQ ENOENT
2375 #endif
2376 _______EOF
2377
2378         fi
2379
2380         if test x$g_have_gnuc_visibility = xyes ; then
2381                 cat >>$outfile <<_______EOF
2382 #define G_HAVE_GNUC_VISIBILITY 1
2383 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2384 _______EOF
2385         else
2386                 cat >>$outfile <<_______EOF
2387 #define G_GNUC_INTERNAL
2388 _______EOF
2389         fi
2390
2391
2392         echo >>$outfile
2393         if test x$g_mutex_has_default = xyes; then
2394                 cat >>$outfile <<_______EOF
2395 $g_enable_threads_def G_THREADS_ENABLED
2396 #define G_THREADS_IMPL_$g_threads_impl_def
2397 typedef struct _GStaticMutex GStaticMutex;
2398 struct _GStaticMutex
2399 {
2400   struct _GMutex *runtime_mutex;
2401   union {
2402     char   pad[[$g_mutex_sizeof]];
2403     double dummy_double;
2404     void  *dummy_pointer;
2405     long   dummy_long;
2406   } static_mutex;
2407 };
2408 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
2409 #define g_static_mutex_get_mutex(mutex) \\
2410   (g_thread_use_default_impl ? ((GMutex*) ((mutex)->static_mutex.pad)) : \\
2411    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
2412 _______EOF
2413         else
2414                 cat >>$outfile <<_______EOF
2415 $g_enable_threads_def G_THREADS_ENABLED
2416 #define G_THREADS_IMPL_$g_threads_impl_def
2417 typedef struct _GMutex* GStaticMutex;
2418 #define G_STATIC_MUTEX_INIT NULL
2419 #define g_static_mutex_get_mutex(mutex) \\
2420   (g_static_mutex_get_mutex_impl_shortcut (mutex))
2421 _______EOF
2422         fi
2423
2424         cat >>$outfile <<_______EOF
2425 /* This represents a system thread as used by the implementation. An
2426  * alien implementaion, as loaded by g_thread_init can only count on
2427  * "sizeof (gpointer)" bytes to store their info. We however need more
2428  * for some of our native implementations. */
2429 typedef union _GSystemThread GSystemThread;
2430 union _GSystemThread
2431 {
2432   char   data[[$g_system_thread_sizeof]];
2433   double dummy_double;
2434   void  *dummy_pointer;
2435   long   dummy_long;
2436 };
2437 _______EOF
2438         if test x"$g_memory_barrier_needed" != xno; then
2439           echo >>$outfile
2440           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2441         fi
2442
2443         echo >>$outfile
2444         g_bit_sizes="16 32 64"
2445         for bits in $g_bit_sizes; do
2446           cat >>$outfile <<_______EOF
2447 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
2448 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
2449 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2450 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
2451 _______EOF
2452         done
2453
2454         cat >>$outfile <<_______EOF
2455 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
2456 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
2457 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
2458 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
2459 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
2460 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
2461 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
2462 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
2463 #define G_BYTE_ORDER $g_byte_order
2464
2465 #define GLIB_SYSDEF_POLLIN =$g_pollin
2466 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2467 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2468 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2469 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2470 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2471
2472 #define G_MODULE_SUFFIX "$g_module_suffix"
2473
2474 typedef $g_pid_type GPid;
2475
2476 G_END_DECLS
2477
2478 #endif /* GLIBCONFIG_H */
2479 _______EOF
2480
2481
2482         if cmp -s $outfile glibconfig.h; then
2483           AC_MSG_NOTICE([glibconfig.h is unchanged])
2484           rm -f $outfile
2485         else
2486           mv $outfile glibconfig.h
2487         fi
2488 ],[
2489
2490 # Note that if two cases are the same, case goes with the first one.
2491 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
2492 # on variable expansion in case labels.  Look at the generated config.status
2493 # for a hint.
2494
2495 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2496   glib_header_alloca_h="$ac_cv_working_alloca_h"
2497 else
2498   glib_header_alloca_h="$ac_cv_header_alloca_h"
2499 fi
2500
2501 case xyes in
2502 x$ac_cv_header_float_h)
2503   glib_float_h=yes
2504   glib_mf=FLT_MIN glib_Mf=FLT_MAX
2505   glib_md=DBL_MIN glib_Md=DBL_MAX
2506   ;;
2507 x$ac_cv_header_values_h)
2508   glib_values_h=yes
2509   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
2510   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
2511   ;;
2512 esac
2513
2514 case xyes in
2515 x$ac_cv_header_limits_h)
2516   glib_limits_h=yes
2517   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
2518   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
2519   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
2520   ;;
2521 x$ac_cv_header_values_h)
2522   glib_values_h=yes
2523   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
2524   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
2525   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
2526   ;;
2527 esac
2528
2529 if test x$ac_cv_header_sys_poll_h = xyes ; then
2530   glib_sys_poll_h=yes
2531 fi
2532
2533 case 2 in
2534 $ac_cv_sizeof_short)
2535   gint16=short
2536   gint16_modifier='"h"'
2537   gint16_format='"hi"'
2538   guint16_format='"hu"'
2539   ;;
2540 $ac_cv_sizeof_int)
2541   gint16=int
2542   gint16_modifier='""'
2543   gint16_format='"i"'
2544   guint16_format='"u"'
2545   ;;
2546 esac
2547 case 4 in
2548 $ac_cv_sizeof_short)
2549   gint32=short
2550   gint32_modifier='"h"'
2551   gint32_format='"hi"'
2552   guint32_format='"hu"'
2553   ;;
2554 $ac_cv_sizeof_int)
2555   gint32=int
2556   gint32_modifier='""'
2557   gint32_format='"i"'
2558   guint32_format='"u"'
2559   ;;
2560 $ac_cv_sizeof_long)
2561   gint32=long
2562   gint32_modifier='"l"'
2563   gint32_format='"li"'
2564   guint32_format='"lu"'
2565   ;;
2566 esac
2567 case 8 in
2568 $ac_cv_sizeof_int)
2569   gint64=int
2570   gint64_modifier='""'
2571   gint64_format='"i"'
2572   guint64_format='"u"'
2573   glib_extension=
2574   gint64_constant='(val)'
2575   guint64_constant='(val)'
2576   ;;
2577 $ac_cv_sizeof_long)
2578   gint64=long
2579   gint64_modifier='"l"'
2580   gint64_format='"li"'
2581   guint64_format='"lu"'
2582   glib_extension=
2583   gint64_constant='(val##L)'
2584   guint64_constant='(val##UL)'
2585   ;;
2586 $ac_cv_sizeof_long_long)
2587   gint64='long long'
2588   if test -n "$glib_cv_long_long_format"; then
2589     gint64_modifier='"'$glib_cv_long_long_format'"'
2590     gint64_format='"'$glib_cv_long_long_format'i"'
2591     guint64_format='"'$glib_cv_long_long_format'u"'
2592   fi
2593   glib_extension='G_GNUC_EXTENSION '
2594   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
2595   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
2596   ;;
2597 $ac_cv_sizeof___int64)
2598   gint64='__int64'
2599   if test -n "$glib_cv_long_long_format"; then
2600     gint64_modifier='"'$glib_cv_long_long_format'"'
2601     gint64_format='"'$glib_cv_long_long_format'i"'
2602     guint64_format='"'$glib_cv_long_long_format'u"'
2603   fi
2604   glib_extension=
2605   gint64_constant='(val##i64)'
2606   guint64_constant='(val##ui64)'
2607   ;;
2608 esac
2609 glib_size_t=$ac_cv_sizeof_size_t
2610 glib_size_type_define=$glib_size_type
2611 glib_void_p=$ac_cv_sizeof_long
2612 glib_long=$ac_cv_sizeof_void_p
2613
2614 case $glib_size_type in
2615 short)
2616   gsize_modifier='"h"'
2617   gsize_format='"hu"'
2618   gssize_format='"hi"'
2619   glib_msize_type='SHRT'
2620   ;;
2621 int)
2622   gsize_modifier='""'
2623   gsize_format='"u"'
2624   gssize_format='"i"'
2625   glib_msize_type='INT'
2626   ;;
2627 long)
2628   gsize_modifier='"l"'
2629   gsize_format='"lu"'
2630   gssize_format='"li"'
2631   glib_msize_type='LONG'
2632   ;;
2633 esac
2634
2635 gintbits=`expr $ac_cv_sizeof_int \* 8`
2636 glongbits=`expr $ac_cv_sizeof_long \* 8`
2637
2638
2639 case $ac_cv_sizeof_void_p in
2640 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
2641 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
2642 *)                      glib_unknown_void_p=yes ;;
2643 esac
2644
2645
2646 case xyes in
2647 x$ac_cv_func_atexit)
2648   glib_atexit="
2649 #ifdef NeXT /* @#%@! NeXTStep */
2650 # define g_ATEXIT(proc) (!atexit (proc))
2651 #else
2652 # define g_ATEXIT(proc) (atexit (proc))
2653 #endif"
2654   ;;
2655 x$ac_cv_func_on_exit)
2656   glib_atexit="
2657 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
2658   ;;
2659 esac
2660
2661 case xyes in
2662 x$ac_cv_func_memmove)
2663   glib_memmove='
2664 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
2665   ;;
2666 x$glib_cv_working_bcopy)
2667   glib_memmove="
2668 /* memmove isn't available, but bcopy can copy overlapping memory regions */
2669 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
2670   ;;
2671 *)
2672   glib_memmove="
2673 /* memmove isn't found and bcopy can't copy overlapping memory regions,
2674  * so we have to roll our own copy routine. */
2675 void g_memmove (void* dest, const void * src, unsigned long len);"
2676   ;;
2677 esac
2678
2679 glib_defines="
2680 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
2681 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
2682 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
2683 "
2684
2685 case xyes in
2686 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
2687 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
2688 *)                      glib_vacopy=''
2689 esac
2690
2691 if test x$glib_cv_va_val_copy = xno; then
2692   glib_vacopy="\$glib_vacopy
2693 #define G_VA_COPY_AS_ARRAY 1"
2694 fi
2695
2696 if test x$glib_cv_hasinline = xyes; then
2697     glib_inline='#define G_HAVE_INLINE 1'
2698 fi
2699 if test x$glib_cv_has__inline = xyes; then
2700     glib_inline="\$glib_inline
2701 #define G_HAVE___INLINE 1"
2702 fi
2703 if test x$glib_cv_has__inline__ = xyes; then
2704     glib_inline="\$glib_inline
2705 #define G_HAVE___INLINE__ 1"
2706 fi
2707
2708 g_have_gnuc_varargs=$g_have_gnuc_varargs
2709 g_have_iso_c_varargs=$g_have_iso_c_varargs
2710 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
2711
2712 g_can_inline=$g_can_inline
2713 g_have_gnuc_visibility=$g_have_gnuc_visibility
2714
2715 case xyes in
2716 x$ac_cv_c_bigendian)
2717   g_byte_order=G_BIG_ENDIAN
2718   g_bs_native=BE
2719   g_bs_alien=LE
2720   ;;
2721 *)
2722   g_byte_order=G_LITTLE_ENDIAN
2723   g_bs_native=LE
2724   g_bs_alien=BE
2725   ;;
2726 esac
2727
2728 g_pollin=$glib_cv_value_POLLIN
2729 g_pollout=$glib_cv_value_POLLOUT
2730 g_pollpri=$glib_cv_value_POLLPRI
2731 g_pollhup=$glib_cv_value_POLLHUP
2732 g_pollerr=$glib_cv_value_POLLERR
2733 g_pollnval=$glib_cv_value_POLLNVAL
2734
2735 g_stack_grows=$glib_cv_stack_grows
2736
2737 g_have_eilseq=$have_eilseq
2738
2739 case x$have_threads in
2740 xno)    g_enable_threads_def="#undef";;
2741 *)      g_enable_threads_def="#define";;
2742 esac
2743
2744 g_threads_impl_def=$g_threads_impl
2745
2746 g_mutex_has_default="$mutex_has_default"
2747 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
2748 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
2749 g_mutex_contents="$glib_cv_byte_contents_gmutex"
2750
2751 g_memory_barrier_needed="$glib_memory_barrier_needed"
2752
2753 g_module_suffix="$glib_gmodule_suffix"
2754
2755 g_pid_type="$glib_pid_type"
2756 case $host in
2757   *-*-beos*)
2758     glib_os="#define G_OS_BEOS"
2759     ;;
2760   *-*-cygwin*)
2761     glib_os="#define G_OS_UNIX
2762 #define G_PLATFORM_WIN32
2763 #define G_WITH_CYGWIN"
2764     ;;
2765   *-*-mingw*)
2766     glib_os="#define G_OS_WIN32
2767 #define G_PLATFORM_WIN32"
2768     ;;
2769   *)
2770     glib_os="#define G_OS_UNIX"
2771     ;;
2772 esac
2773 ])
2774
2775 AC_CONFIG_FILES([
2776 glib-2.0.pc
2777 glib-2.0-uninstalled.pc
2778 gmodule-2.0.pc
2779 gmodule-export-2.0.pc
2780 gmodule-no-export-2.0.pc
2781 gmodule-2.0-uninstalled.pc
2782 gmodule-no-export-2.0-uninstalled.pc
2783 gthread-2.0.pc
2784 gthread-2.0-uninstalled.pc
2785 gobject-2.0.pc
2786 gobject-2.0-uninstalled.pc
2787 glib-zip
2788 glib-gettextize
2789 Makefile
2790 build/Makefile
2791 build/win32/Makefile
2792 build/win32/dirent/Makefile
2793 build/win32/vs8/Makefile
2794 glib/Makefile
2795 glib/libcharset/Makefile
2796 glib/gnulib/Makefile
2797 gmodule/Makefile
2798 gmodule/gmoduleconf.h
2799 gobject/Makefile
2800 gobject/glib-mkenums
2801 gthread/Makefile
2802 po/Makefile.in
2803 docs/Makefile
2804 docs/reference/Makefile
2805 docs/reference/glib/Makefile
2806 docs/reference/glib/version.xml
2807 docs/reference/gobject/Makefile
2808 docs/reference/gobject/version.xml
2809 tests/Makefile
2810 tests/gobject/Makefile
2811 tests/refcount/Makefile
2812 m4macros/Makefile
2813 ])
2814
2815 AC_CONFIG_COMMANDS([chmod-scripts],
2816 [chmod 0755 glib-zip
2817 chmod 0755 glib-gettextize
2818 chmod 0755 gobject/glib-mkenums])
2819
2820 # we want to invoke this macro solely so that the config.status script
2821 # and automake generated makefiles know about these generated files.
2822 # They are only needed to distcheck the package
2823 if false; then
2824   AC_CONFIG_FILES([
2825     INSTALL
2826     README
2827     config.h.win32
2828     glibconfig.h.win32
2829     glib/makefile.msc
2830     glib/glib.rc
2831     gmodule/makefile.msc
2832     gmodule/gmodule.rc
2833     gobject/makefile.msc
2834     gobject/gobject.rc
2835     gthread/makefile.msc
2836     gthread/gthread.rc
2837     tests/makefile.msc
2838   ])
2839 fi
2840
2841 AC_OUTPUT