configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 dnl ***********************************
   6 dnl *** include special GLib macros ***
   7 dnl ***********************************
   8
   9 m4_define(glib_configure_in)
  10 m4_include(acglib.m4)dnl
  11 m4_include(glib/libcharset/codeset.m4)dnl
  12 m4_include(glib/libcharset/glibc21.m4)dnl
  13 m4_include(m4macros/glib-gettext.m4)dnl
  14
  15 #
  16 # The following version number definitions apply to GLib, GModule, GObject
  17 # and GThread as a whole, so if changes occoured in any of them, they are all
  18 # treated with the same interface and binary age.
  19 #
  20 # Making releases:
  21 #   glib_micro_version += 1;
  22 #   glib_interface_age += 1;
  23 #   glib_binary_age += 1;
  24 # if any functions have been added, set glib_interface_age to 0.
  25 # if backwards compatibility has been broken,
  26 # set glib_binary_age _and_ glib_interface_age to 0.
  27 #
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [13])
  30 m4_define([glib_micro_version], [0])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_SRCDIR([glib/glib.h])
  56
  57 # Save this value here, since automake will set cflags later
  58 cflags_set=${CFLAGS+set}
  59
  60 AM_INIT_AUTOMAKE([no-define])
  61
  62 # Specify a configuration file
  63 AM_CONFIG_HEADER([config.h])
  64
  65
  66 GLIB_MAJOR_VERSION=glib_major_version
  67 GLIB_MINOR_VERSION=glib_minor_version
  68 GLIB_MICRO_VERSION=glib_micro_version
  69 GLIB_INTERFACE_AGE=glib_interface_age
  70 GLIB_BINARY_AGE=glib_binary_age
  71 GLIB_VERSION=glib_version
  72
  73 AC_SUBST(GLIB_MAJOR_VERSION)
  74 AC_SUBST(GLIB_MINOR_VERSION)
  75 AC_SUBST(GLIB_MICRO_VERSION)
  76 AC_SUBST(GLIB_VERSION)
  77 AC_SUBST(GLIB_INTERFACE_AGE)
  78 AC_SUBST(GLIB_BINARY_AGE)
  79
  80 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  81           [Define to the GLIB major version])
  82 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  83           [Define to the GLIB minor version])
  84 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  85           [Define to the GLIB micro version])
  86 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  87           [Define to the GLIB interface age])
  88 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  89           [Define to the GLIB binary age])
  90
  91 # libtool versioning
  92 LT_RELEASE=glib_lt_release
  93 LT_CURRENT=glib_lt_current
  94 LT_REVISION=glib_lt_revision
  95 LT_AGE=glib_lt_age
  96 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
  97 AC_SUBST(LT_RELEASE)
  98 AC_SUBST(LT_CURRENT)
  99 AC_SUBST(LT_REVISION)
 100 AC_SUBST(LT_AGE)
 101 AC_SUBST(LT_CURRENT_MINUS_AGE)
 102
 103 dnl Initialize maintainer mode
 104 AM_MAINTAINER_MODE
 105
 106 AC_CANONICAL_HOST
 107
 108 AC_MSG_CHECKING([for the BeOS])
 109 case $host in
 110   *-*-beos*)
 111     glib_native_beos="yes"
 112     ;;
 113   *)
 114     glib_native_beos="no"
 115     ;;
 116 esac
 117 AC_MSG_RESULT([$glib_native_beos])
 118
 119 dnl
 120
 121 AC_MSG_CHECKING([for Win32])
 122 case "$host" in
 123   *-*-mingw*)
 124     glib_native_win32=yes
 125     GLIB_DEF=glib.def
 126     GMODULE_DEF=gmodule.def
 127     GOBJECT_DEF=gobject.def
 128     GTHREAD_DEF=gthread.def
 129     TESTGMODULE_EXP=testgmodule.exp
 130     glib_pid_type='void *'
 131     ;;
 132   *)
 133     glib_native_win32=no
 134     GLIB_DEF=
 135     GMODULE_DEF=
 136     GOBJECT_DEF=
 137     GTHREAD_DEF=
 138     TESTGMODULE_EXP=
 139     glib_pid_type=int
 140     ;;
 141 esac
 142 case $host in
 143   *-*-linux*)
 144     glib_os_linux=yes
 145     ;;
 146 esac
 147
 148
 149 AC_MSG_RESULT([$glib_native_win32])
 150 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 151 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 152 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 153 AC_SUBST(GLIB_DEF)
 154 AC_SUBST(GMODULE_DEF)
 155 AC_SUBST(GOBJECT_DEF)
 156 AC_SUBST(GTHREAD_DEF)
 157 AC_SUBST(TESTGMODULE_EXP)
 158
 159 if test "$glib_native_win32" = "yes"; then
 160   AC_CHECK_TOOL(WINDRES, windres, no)
 161   if test "$WINDRES" = no; then
 162     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 163   fi
 164   AC_CHECK_TOOL(NM, nm, no)
 165   if test "$NM" = no; then
 166     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 167   fi
 168   AC_CHECK_TOOL(RANLIB, ranlib, :)
 169   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 170 fi
 171 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 172
 173 if test "$glib_native_win32" != yes; then
 174     # libtool option to control which symbols are exported
 175     # right now, symbols starting with _ are not exported
 176     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 177 else
 178     # We currently use .def files on Windows
 179     LIBTOOL_EXPORT_OPTIONS=
 180 fi
 181 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 182
 183 dnl declare --enable-* args and collect ac_help strings
 184 AC_ARG_ENABLE(debug,
 185               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 186                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 187               enable_debug=glib_debug_default)
 188
 189 AC_ARG_ENABLE(gc_friendly,
 190               [AC_HELP_STRING([--enable-gc-friendly],
 191                               [turn on garbage collector friendliness [default=no]])],,
 192               [enable_gc_friendly=no])
 193 AC_ARG_ENABLE(mem_pools,
 194               [AC_HELP_STRING([--disable-mem-pools],
 195                               [disable all glib memory pools])],,
 196               [disable_mem_pools=no])
 197 AC_ARG_ENABLE(threads,
 198               [AC_HELP_STRING([--enable-threads],
 199                               [turn on basic thread support [default=yes]
 200 ([=no] will override --with-threads)])],,
 201               [enable_threads=yes])
 202 AC_ARG_ENABLE(rebuilds,
 203               [AC_HELP_STRING([--disable-rebuilds],
 204                               [disable all source autogeneration rules])],,
 205               [enable_rebuilds=yes])
 206 AC_ARG_ENABLE(visibility,
 207               [AC_HELP_STRING([--disable-visibility],
 208                               [don't use ELF visibility attributes])],,
 209               [enable_visibility=yes])
 210
 211 if test "x$enable_threads" != "xyes"; then
 212   enable_threads=no
 213 fi
 214
 215 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, ["${enable_debug}"],
 216         [Whether glib was compiled with debugging enabled])
 217
 218 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 219 if test "x$enable_gc_friendly" = "xyes"; then
 220   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 221   AC_MSG_RESULT([yes])
 222 else
 223   AC_MSG_RESULT([no])
 224 fi
 225
 226 AC_MSG_CHECKING([whether to disable memory pools])
 227 if test "x$disable_mem_pools" = "xno"; then
 228   AC_MSG_RESULT([no])
 229 else
 230   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 231   AC_SUBST(DISABLE_MEM_POOLS)
 232   AC_MSG_RESULT([yes])
 233 fi
 234
 235 if test "$glib_native_win32" = "yes"; then
 236   if test x$enable_static = xyes -o x$enable_static = x; then
 237     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 238     enable_static=no
 239   fi
 240   if test x$enable_shared = xno; then
 241     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 242   fi
 243   enable_shared=yes
 244 fi
 245
 246 dnl Checks for programs.
 247 AC_PROG_CC
 248
 249 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 250 AC_CHECK_PROGS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 251 AC_LANG_SAVE
 252 AC_LANG_CPLUSPLUS
 253 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 254 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 255 AC_LANG_RESTORE
 256
 257 AM_PROG_CC_STDC
 258 AC_PROG_INSTALL
 259
 260 AC_SYS_LARGEFILE
 261
 262 #
 263 # Find pkg-config
 264 #
 265 AC_PATH_PROG(PKG_CONFIG, [pkg-config], [no])
 266 if test x$PKG_CONFIG = xno ; then
 267   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
 268 fi
 269
 270 if $PKG_CONFIG --atleast-pkgconfig-version 0.14 ; then
 271   :
 272 else
 273   AC_MSG_ERROR([*** pkg-config too old; version 0.14 or better required.])
 274 fi
 275
 276 if test "x$enable_debug" = "xyes"; then
 277   if test x$cflags_set != xset ; then
 278       case " $CFLAGS " in
 279       *[[\ \    ]]-g[[\ \       ]]*) ;;
 280       *) CFLAGS="$CFLAGS -g" ;;
 281       esac
 282   fi
 283
 284   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 285 else
 286   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 287
 288   if test "x$enable_debug" = "xno"; then
 289     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 290   fi
 291 fi
 292
 293 if test "x$enable_visibility" = "xno"; then
 294   GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DDISABLE_VISIBILITY"
 295 fi
 296
 297 # Ensure MSVC-compatible struct packing convention is used when
 298 # compiling for Win32 with gcc.
 299 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 300 # gcc2 uses "-fnative-struct".
 301 if test x"$glib_native_win32" = xyes; then
 302   if test x"$GCC" = xyes; then
 303     msnative_struct=''
 304     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 305     if test -z "$ac_cv_prog_CC"; then
 306       our_gcc="$CC"
 307     else
 308       our_gcc="$ac_cv_prog_CC"
 309     fi
 310     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 311       2.)
 312         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 313           msnative_struct='-fnative-struct'
 314         fi
 315         ;;
 316       *)
 317         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 318           msnative_struct='-mms-bitfields'
 319         fi
 320         ;;
 321     esac
 322     if test x"$msnative_struct" = x ; then
 323       AC_MSG_RESULT([no way])
 324       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 325     else
 326       CFLAGS="$CFLAGS $msnative_struct"
 327       AC_MSG_RESULT([${msnative_struct}])
 328     fi
 329   fi
 330 fi
 331
 332 AC_EXEEXT
 333
 334 # define a MAINT-like variable REBUILD which is set if Perl
 335 # and awk are found, so autogenerated sources can be rebuilt
 336 AC_PROG_AWK
 337 AC_CHECK_PROGS(PERL, [perl5 perl])
 338 # We would like indent, but don't require it.
 339 AC_CHECK_PROG(INDENT, indent, indent)
 340 REBUILD=\#
 341 if test "x$enable_rebuilds" = "xyes" && \
 342      test -n "$PERL" && \
 343      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 344      test -n "$AWK" ; then
 345   REBUILD=
 346 fi
 347 AC_SUBST(REBUILD)
 348
 349 # Need full path to Perl for glib-mkenums
 350 #
 351 if test "x$PERL" != x ; then
 352   AC_PATH_PROG(PERL_PATH, [$PERL])
 353 else
 354   PERL_PATH="/usr/bin/env perl"
 355 fi
 356 AC_SUBST(PERL_PATH)
 357
 358 dnl ***********************
 359 dnl *** Tests for iconv ***
 360 dnl ***********************
 361 dnl
 362 dnl We do this before the gettext checks, to avoid distortion
 363
 364 AC_ARG_WITH(libiconv,
 365             [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 366                             [use the libiconv library])],,
 367             [with_libiconv=maybe])
 368
 369 found_iconv=no
 370 case $with_libiconv in
 371   maybe)
 372     # Check in the C library first
 373     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 374     # Check if we have GNU libiconv
 375     if test $found_iconv = "no"; then
 376       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 377     fi
 378     # Check if we have a iconv in -liconv, possibly from vendor
 379     if test $found_iconv = "no"; then
 380       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 381     fi
 382     ;;
 383   no)
 384     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 385     ;;
 386   gnu|yes)
 387     AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 388     ;;
 389   native)
 390     AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 391     ;;
 392 esac
 393
 394 if test "x$found_iconv" = "xno" ; then
 395    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 396 fi
 397
 398 jm_GLIBC21
 399 AC_ARG_ENABLE(iconv-cache,
 400               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 401                               [cache iconv descriptors [default=auto]])],,
 402               [enable_iconv_cache=auto])
 403
 404 AC_MSG_CHECKING([Whether to cache iconv descriptors])
 405 case $enable_iconv_cache in
 406   auto)
 407     if test $ac_cv_gnu_library_2_1 = yes; then
 408       enable_iconv_cache=no
 409     else
 410       enable_iconv_cache=yes
 411     fi
 412   ;;
 413   yes|no)
 414   ;;
 415   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 416   ;;
 417 esac
 418
 419 if test $enable_iconv_cache = yes; then
 420    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 421 fi
 422
 423 AC_MSG_RESULT($enable_iconv_cache)
 424
 425
 426 dnl
 427 dnl gettext support
 428 dnl
 429
 430 ALL_LINGUAS="am ar az be be@latin bg bn bn_IN bs ca cs cy da de dz el en_CA en_GB eo es et eu fa fi fr ga gl gu he hi hr hu hy id is it ja ka ko ku lt lv mg mk ml mn ms nb ne nl nn or pa pl pt pt_BR ro ru rw sk sl sq sr sr@Latn sr@ije sv ta te th tl tr tt uk vi wa xh yi zh_CN zh_HK zh_TW"
 431 GLIB_GNU_GETTEXT
 432
 433 if test "$gt_cv_have_gettext" != "yes" ; then
 434   AC_MSG_ERROR([
 435 *** You must have either have gettext support in your C library, or use the
 436 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 437 ])
 438 fi
 439
 440 LIBS="$INTLLIBS $LIBS"
 441
 442 GETTEXT_PACKAGE=glib20
 443 AC_SUBST(GETTEXT_PACKAGE)
 444 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 445   [Define the gettext package to be used])
 446
 447 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 448
 449 dnl
 450 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 451 dnl
 452
 453 if test x$with_libiconv != xno ; then
 454   case " $INTLLIBS " in
 455   *[[\ \        ]]-liconv[[\ \  ]]*) ;;
 456   *) ICONV_LIBS="-liconv" ;;
 457   esac
 458 fi
 459 AC_SUBST(ICONV_LIBS)
 460
 461 case $with_libiconv in
 462   gnu)
 463     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 464     ;;
 465   native)
 466     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 467     ;;
 468 esac
 469
 470 dnl Initialize libtool
 471 AM_DISABLE_STATIC
 472 AC_LIBTOOL_WIN32_DLL
 473 AM_PROG_LIBTOOL
 474
 475 if test "x$GCC" = "xyes"; then
 476   case " $CFLAGS " in
 477   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 478   *) CFLAGS="$CFLAGS -Wall" ;;
 479   esac
 480 fi
 481
 482 dnl
 483 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 484 dnl
 485 if test $cross_compiling != yes ; then
 486     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 487     glib_save_LIBS=$LIBS
 488     LIBS="$LIBS -lm"
 489     AC_TRY_RUN([#include <math.h>
 490                  int main (void) { return (log(1) != log(1.)); }],
 491          AC_MSG_RESULT(none needed),
 492          glib_save_CFLAGS=$CFLAGS
 493          CFLAGS="$CFLAGS -std1"
 494          AC_TRY_RUN([#include <math.h>
 495                      int main (void) { return (log(1) != log(1.)); }],
 496              AC_MSG_RESULT(-std1),
 497              AC_MSG_RESULT()
 498              CFLAGS=$glib_save_CFLAGS
 499              AC_MSG_WARN(
 500                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 501          )
 502     )
 503     LIBS=$glib_save_LIBS
 504 fi
 505
 506 dnl NeXTStep cc seems to need this
 507 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 508 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 509   AC_MSG_RESULT(none needed),
 510   glib_save_CFLAGS=$CFLAGS
 511   CFLAGS="$CFLAGS -posix"
 512   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 513     AC_MSG_RESULT(-posix),
 514     AC_MSG_RESULT()
 515     CFLAGS=$glib_save_CFLAGS
 516     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 517
 518 # Checks for header files.
 519 AC_HEADER_STDC
 520
 521 # Checks for library functions.
 522 AC_FUNC_VPRINTF
 523 AC_FUNC_MMAP
 524 AC_FUNC_ALLOCA
 525 AC_CHECK_FUNCS(posix_memalign)
 526 AC_CHECK_FUNCS(memalign)
 527 AC_CHECK_FUNCS(valloc)
 528
 529 AC_CHECK_FUNCS(atexit on_exit)
 530
 531 AC_CHECK_FUNCS(timegm)
 532
 533 AC_CHECK_SIZEOF(char)
 534 AC_CHECK_SIZEOF(short)
 535 AC_CHECK_SIZEOF(long)
 536 AC_CHECK_SIZEOF(int)
 537 AC_CHECK_SIZEOF(void *)
 538 AC_CHECK_SIZEOF(long long)
 539 AC_CHECK_SIZEOF(__int64)
 540
 541 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 542   :
 543 else
 544   AC_MSG_ERROR([
 545 *** GLib requires a 64 bit type. You might want to consider
 546 *** using the GNU C compiler.
 547 ])
 548 fi
 549
 550 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 551         # long long is a 64 bit integer.
 552         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 553         AC_CACHE_VAL(glib_cv_long_long_format,[
 554                 for format in ll q I64; do
 555                   AC_TRY_RUN([#include <stdio.h>
 556                         int main()
 557                         {
 558                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 559                           char buffer[1000];
 560                           sprintf (buffer, "%${format}u", a);
 561                           sscanf (buffer, "%${format}u", &b);
 562                           exit (b!=a);
 563                         }
 564                         ],
 565                         [glib_cv_long_long_format=${format}
 566                         break],
 567                         [],[:])
 568                 done])
 569         if test -n "$glib_cv_long_long_format"; then
 570           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 571           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 572           if test x"$glib_cv_long_long_format" = xI64; then
 573             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 574           fi
 575         else
 576           AC_MSG_RESULT(none)
 577         fi
 578 elif test x$ac_cv_sizeof___int64 = x8; then
 579         # __int64 is a 64 bit integer.
 580         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 581         # We know this is MSVCRT.DLL, and what the formats are
 582         glib_cv_long_long_format=I64
 583         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 584         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 585         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 586 fi
 587
 588 dnl long doubles were not used, and a portability problem
 589 dnl AC_C_LONG_DOUBLE
 590 AC_C_CONST
 591
 592 dnl ok, here we try to check whether the systems prototypes for
 593 dnl malloc and friends actually match the prototypes provided
 594 dnl by gmem.h (keep in sync). i currently only know how to check
 595 dnl this reliably with gcc (-Werror), improvements for other
 596 dnl compilers are apprechiated.
 597 SANE_MALLOC_PROTOS=no
 598 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 599 glib_save_CFLAGS=$CFLAGS
 600 if test "x$GCC" = "xyes"; then
 601   CFLAGS="$CFLAGS -Werror"
 602   AC_TRY_COMPILE([#include <stdlib.h>], [
 603     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 604     void* (*my_malloc_p)  (size_t)         = malloc;
 605     void  (*my_free_p)    (void*)          = free;
 606     void* (*my_realloc_p) (void*, size_t)  = realloc;
 607     my_calloc_p = 0;
 608     my_malloc_p = 0;
 609     my_free_p = 0;
 610     my_realloc_p = 0;
 611   ],
 612     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 613       [Define if you have correct malloc prototypes])
 614     SANE_MALLOC_PROTOS=yes)
 615 fi
 616 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 617 CFLAGS=$glib_save_CFLAGS
 618
 619 dnl
 620 dnl check in which direction the stack grows
 621 dnl
 622 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 623         AC_TRY_RUN([
 624         volatile int *a = 0, *b = 0;
 625         void foo (void);
 626         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 627         void foo (void) { volatile int x = 5; b = &x; }
 628         ],
 629         glib_cv_stack_grows=no
 630         ,
 631         glib_cv_stack_grows=yes
 632         ,)
 633 ])
 634
 635 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 636 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 637 dnl actually supported.
 638 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 639         AC_COMPILE_IFELSE([
 640         __inline int foo () { return 0; }
 641         int main () { return foo (); }
 642         ],
 643         glib_cv_has__inline=yes
 644         ,
 645         glib_cv_has__inline=no
 646         ,)
 647 ])
 648 case x$glib_cv_has__inline in
 649 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 650 esac
 651 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 652         AC_COMPILE_IFELSE([
 653         __inline__ int foo () { return 0; }
 654         int main () { return foo (); }
 655         ],
 656         glib_cv_has__inline__=yes
 657         ,
 658         glib_cv_has__inline__=no
 659         ,)
 660 ])
 661 case x$glib_cv_has__inline__ in
 662 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 663 esac
 664 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 665         AC_COMPILE_IFELSE([
 666         #undef inline
 667         inline int foo () { return 0; }
 668         int main () { return foo (); }
 669         ],
 670         glib_cv_hasinline=yes
 671         ,
 672         glib_cv_hasinline=no
 673         ,)
 674 ])
 675 case x$glib_cv_hasinline in
 676 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 677 esac
 678
 679 # if we can use inline functions in headers
 680 AC_MSG_CHECKING(if inline functions in headers work)
 681 AC_LINK_IFELSE([
 682 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 683 #  undef inline
 684 #  define inline __inline__
 685 #elif !defined (G_HAVE_INLINE)
 686 #  undef inline
 687 #  if defined (G_HAVE___INLINE__)
 688 #    define inline __inline__
 689 #  elif defined (G_HAVE___INLINE)
 690 #    define inline __inline
 691 #  endif
 692 #endif
 693
 694 int glib_test_func2 (int);
 695
 696 static inline int
 697 glib_test_func1 (void) {
 698   return glib_test_func2 (1);
 699 }
 700
 701 int
 702 main (void) {
 703   int i = 1;
 704 }],[g_can_inline=yes],[g_can_inline=no])
 705 AC_MSG_RESULT($g_can_inline)
 706
 707 dnl *** check for working do while(0) macros ***
 708 AC_CACHE_CHECK([for working do while(0) macros], g_support_dowhile_macros, [
 709         AC_TRY_COMPILE([],[
 710         #define STMT_START do
 711         #define STMT_END while(0)
 712         #define STMT_TEST STMT_START { i = 0; } STMT_END
 713         int main(void) { int i = 1; STMT_TEST; return i; }],
 714         [g_support_dowhile_macros=yes],
 715         [g_support_dowhile_macros=no],
 716         [g_support_dowhile_macros=yes])
 717 ])
 718 if test x$g_support_dowhile_macros = xyes; then
 719   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 720 fi
 721
 722 # check for flavours of varargs macros
 723 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 724 AC_TRY_COMPILE([],[
 725 int a(int p1, int p2, int p3);
 726 #define call_a(...) a(1,__VA_ARGS__)
 727 call_a(2,3);
 728 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 729 AC_MSG_RESULT($g_have_iso_c_varargs)
 730
 731 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 732 if test "$CXX" = ""; then
 733 dnl No C++ compiler
 734   g_have_iso_cxx_varargs=no
 735 else
 736   AC_LANG_CPLUSPLUS
 737   AC_TRY_COMPILE([],[
 738 int a(int p1, int p2, int p3);
 739 #define call_a(...) a(1,__VA_ARGS__)
 740 call_a(2,3);
 741 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 742   AC_LANG_C
 743 fi
 744 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 745
 746 AC_MSG_CHECKING(for GNUC varargs macros)
 747 AC_TRY_COMPILE([],[
 748 int a(int p1, int p2, int p3);
 749 #define call_a(params...) a(1,params)
 750 call_a(2,3);
 751 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 752 AC_MSG_RESULT($g_have_gnuc_varargs)
 753
 754 # check for GNUC visibility support
 755 AC_MSG_CHECKING(for GNUC visibility attribute)
 756 GLIB_CHECK_COMPILE_WARNINGS([
 757 void
 758 __attribute__ ((visibility ("hidden")))
 759      f_hidden (void)
 760 {
 761 }
 762 void
 763 __attribute__ ((visibility ("internal")))
 764      f_internal (void)
 765 {
 766 }
 767 void
 768 __attribute__ ((visibility ("protected")))
 769      f_protected (void)
 770 {
 771 }
 772 void
 773 __attribute__ ((visibility ("default")))
 774      f_default (void)
 775 {
 776 }
 777 int main (int argc, char **argv)
 778 {
 779         f_hidden();
 780         f_internal();
 781         f_protected();
 782         f_default();
 783         return 0;
 784 }
 785 ],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 786 AC_MSG_RESULT($g_have_gnuc_visibility)
 787 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 788
 789 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 790 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 791 #else
 792 # include "error: this is not Sun Studio."
 793 #endif
 794 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 795 AC_MSG_RESULT($g_have_sunstudio_visibility)
 796 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 797
 798 # check for bytesex stuff
 799 AC_C_BIGENDIAN
 800
 801 # check for header files
 802 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h sys/param.h sys/poll.h])
 803 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 804 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h sched.h malloc.h])
 805
 806 # Checks for libcharset
 807 jm_LANGINFO_CODESET
 808 jm_GLIBC21
 809 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 810 AC_CHECK_FUNCS(setlocale)
 811
 812 # check additional type sizes
 813 AC_CHECK_SIZEOF(size_t)
 814
 815 dnl Try to figure out whether gsize, gssize should be long or int
 816 AC_MSG_CHECKING([for the appropriate definition for size_t])
 817
 818 case $ac_cv_sizeof_size_t in
 819   $ac_cv_sizeof_short)
 820       glib_size_type=short
 821       ;;
 822   $ac_cv_sizeof_int)
 823       glib_size_type=int
 824       ;;
 825   $ac_cv_sizeof_long)
 826       glib_size_type=long
 827       ;;
 828   *)  AC_MSG_ERROR([No type matching size_t in size])
 829       ;;
 830 esac
 831
 832 dnl If int/long are the same size, we see which one produces
 833 dnl warnings when used in the location as size_t. (This matters
 834 dnl on AIX with xlc)
 835 dnl
 836 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 837    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 838   GLIB_CHECK_COMPILE_WARNINGS([
 839 #if defined(_AIX) && !defined(__GNUC__)
 840 #pragma options langlvl=stdc89
 841 #endif
 842 #include <stddef.h>
 843 int main ()
 844 {
 845   size_t s = 1;
 846   unsigned int *size_int = &s;
 847   return (int)*size_int;
 848 }
 849     ],glib_size_type=int,
 850       [GLIB_CHECK_COMPILE_WARNINGS([
 851 #if defined(_AIX) && !defined(__GNUC__)
 852 #pragma options langlvl=stdc89
 853 #endif
 854 #include <stddef.h>
 855 int main ()
 856 {
 857    size_t s = 1;
 858    unsigned long *size_long = &s;
 859    return (int)*size_long;
 860 }
 861         ],glib_size_type=long)])
 862 fi
 863
 864 AC_MSG_RESULT(unsigned $glib_size_type)
 865
 866 # Check for some functions
 867 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk)
 868 # Check for high-resolution sleep functions
 869 AC_CHECK_FUNCS(nanosleep nsleep)
 870
 871 AC_CHECK_HEADERS(crt_externs.h)
 872 AC_CHECK_FUNCS(_NSGetEnviron)
 873
 874 AC_FUNC_VSNPRINTF_C99
 875 AC_FUNC_PRINTF_UNIX98
 876
 877 #
 878 # Check whether to use an included printf
 879 #
 880
 881 AC_ARG_ENABLE(included-printf,
 882               [AC_HELP_STRING([--enable-included-printf],
 883                               [use included printf [default=auto]])],
 884               enable_included_printf="$enableval")
 885
 886 need_included_printf=no
 887 if test "x$enable_included_printf" = "xyes" ; then
 888   need_included_printf=yes
 889 fi
 890 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
 891   need_included_printf=yes
 892 fi
 893 if test "$ac_cv_func_printf_unix98" != "yes" ; then
 894   need_included_printf=yes
 895 fi
 896 if test "x$ac_cv_sizeof_long_long" = "x8" &&
 897    test -z "$glib_cv_long_long_format" ; then
 898   need_included_printf=yes
 899 fi
 900
 901 if test "x$enable_included_printf" = "xno" &&
 902    test "x$need_included_printf" = "xyes" ; then
 903   AC_MSG_ERROR([
 904 *** Your C library's printf doesn't appear to have the features that
 905 *** GLib needs, but you specified --enable-included-printf=no.])
 906 fi
 907
 908 enable_included_printf=$need_included_printf
 909
 910 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
 911 if test "$enable_included_printf" != "yes" ; then
 912   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
 913 else
 914   if test -z "$glib_cv_long_long_format" ; then
 915     glib_cv_long_long_format="ll"
 916   fi
 917   AC_DEFINE(HAVE_VASPRINTF,1)
 918 fi
 919
 920 # Checks needed for gnulib vasnprintf
 921 bh_C_SIGNED
 922 jm_AC_TYPE_LONG_LONG
 923 gt_TYPE_LONGDOUBLE
 924 gt_TYPE_WCHAR_T
 925 gt_TYPE_WINT_T
 926 AC_TYPE_SIZE_T
 927 AC_CHECK_TYPES(ptrdiff_t)
 928 jm_AC_TYPE_INTMAX_T
 929 AC_CHECK_FUNCS([snprintf wcslen])
 930 AC_FUNC_SNPRINTF_C99
 931
 932 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 933 # The check is borrowed from the PERL Configure script.
 934 if test "$ac_cv_func_memmove" != "yes"; then
 935   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 936     glib_cv_working_bcopy,[AC_TRY_RUN([
 937       int main() {
 938         char buf[128], abc[128], *b;
 939         int len, off, align;
 940         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 941         for (align = 7; align >= 0; align--) {
 942           for (len = 36; len; len--) {
 943             b = buf+align; bcopy(abc, b, len);
 944             for (off = 1; off <= len; off++) {
 945               bcopy(b, b+off, len); bcopy(b+off, b, len);
 946                 if (bcmp(b, abc, len)) return(1);
 947             }
 948           }
 949         }
 950         return(0);
 951       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 952
 953   GLIB_ASSERT_SET(glib_cv_working_bcopy)
 954   if test "$glib_cv_working_bcopy" = "yes"; then
 955     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 956   fi
 957 fi
 958
 959 # Check for sys_errlist
 960 AC_MSG_CHECKING(for sys_errlist)
 961 AC_TRY_LINK(, [
 962 extern char *sys_errlist[];
 963 extern int sys_nerr;
 964 sys_errlist[sys_nerr-1][0] = 0;
 965 ], glib_ok=yes, glib_ok=no)
 966 AC_MSG_RESULT($glib_ok)
 967 if test "$glib_ok" = "no"; then
 968     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 969 fi
 970
 971 # Check for sys_siglist
 972 AC_MSG_CHECKING(for sys_siglist)
 973 AC_TRY_LINK(, [
 974 extern char *sys_siglist[];
 975 exit (sys_siglist[0]);
 976 ], glib_ok=yes, glib_ok=no)
 977 AC_MSG_RESULT($glib_ok)
 978 if test "$glib_ok" = "no"; then
 979     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 980 fi
 981
 982 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 983 AC_MSG_CHECKING(for sys_siglist declaration)
 984 AC_TRY_COMPILE([#include <signal.h>], [
 985 strlen (sys_siglist[0]);
 986 ], glib_ok=yes, glib_ok=no)
 987 AC_MSG_RESULT($glib_ok)
 988 if test "$glib_ok" = "no"; then
 989     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 990 fi
 991
 992 # Check if <sys/select.h> needs to be included for fd_set
 993 AC_MSG_CHECKING([for fd_set])
 994 AC_TRY_COMPILE([#include <sys/types.h>],
 995         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 996 if test "$gtk_ok" = "yes"; then
 997     AC_MSG_RESULT([yes, found in sys/types.h])
 998 else
 999     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1000     if test "$gtk_ok" = "yes"; then
1001         # *** FIXME: give it a different name
1002         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1003         AC_MSG_RESULT([yes, found in sys/select.h])
1004     else
1005         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1006         AC_MSG_RESULT(no)
1007     fi
1008 fi
1009
1010 dnl *** check for sane realloc() ***
1011 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1012         AC_TRY_RUN([#include <stdlib.h>
1013         int main() {
1014           return realloc (0, sizeof (int)) == 0;
1015         }],
1016         [glib_cv_sane_realloc=yes],
1017         [glib_cv_sane_realloc=no],
1018         [glib_cv_sane_realloc=yes])
1019 ])
1020 if test x$glib_cv_sane_realloc = xyes; then
1021   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1022 fi
1023
1024 dnl Check for nl_langinfo and CODESET
1025 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1026         AC_TRY_COMPILE([#include <langinfo.h>],
1027                 [char *codeset = nl_langinfo (CODESET);],
1028                 [glib_cv_langinfo_codeset=yes],
1029                 [glib_cv_langinfo_codeset=no])])
1030 if test x$glib_cv_langinfo_codeset = xyes; then
1031   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1032 fi
1033
1034 dnl ****************************************
1035 dnl *** posix_memalign                   ***
1036 dnl ****************************************
1037 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1038 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1039     glib_cv_compliant_posix_memalign=0
1040     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1041         AC_TRY_RUN([
1042                 #define _XOPEN_SOURCE 600
1043                 #include <stdlib.h> /* posix_memalign() should be defined here */
1044                 /* some systems break if #include <malloc.h> used */
1045                 static void test_memalign (size_t boundary, size_t size) {
1046                     void *mem = 0;
1047                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1048                         exit (1);
1049                     else
1050                       free (mem);
1051                 }
1052                 int main() {
1053                     test_memalign (  128,   128 - 2 * sizeof (void*));
1054                     test_memalign (  256,   256 - 2 * sizeof (void*));
1055                     test_memalign (  512,   512 - 2 * sizeof (void*));
1056                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1057                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1058                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1059                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1060                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1061                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1062                     exit (0); /* success */
1063                 }
1064                 ],
1065             [glib_cv_compliant_posix_memalign=1], [], [:])
1066       :
1067     fi
1068     ])
1069 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1070     AC_MSG_RESULT(yes)
1071     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1072 else
1073     AC_MSG_RESULT(no)
1074 fi
1075
1076
1077 dnl ****************************************
1078 dnl *** strlcpy/strlcat                  ***
1079 dnl ****************************************
1080 # Check for strlcpy
1081 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1082 AC_TRY_RUN([#include <stdlib.h>
1083 #include <string.h>
1084 int main() {
1085   char p[10];
1086   (void) strlcpy (p, "hi", 10);
1087   if (strlcat (p, "bye", 0) != 3)
1088     return 1;
1089   return 0;
1090 }], glib_cv_have_strlcpy=yes,
1091     glib_cv_have_strlcpy=no,
1092     glib_cv_have_strlcpy=no)])
1093 if test "$glib_cv_have_strlcpy" = "yes"; then
1094     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1095 fi
1096
1097
1098 dnl **********************
1099 dnl *** va_copy checks ***
1100 dnl **********************
1101 dnl we currently check for all three va_copy possibilities, so we get
1102 dnl all results in config.log for bug reports.
1103 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1104         AC_LINK_IFELSE([#include <stdarg.h>
1105 #include <stdlib.h>
1106         void f (int i, ...) {
1107         va_list args1, args2;
1108         va_start (args1, i);
1109         va_copy (args2, args1);
1110         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1111           exit (1);
1112         va_end (args1); va_end (args2);
1113         }
1114         int main() {
1115           f (0, 42);
1116           return 0;
1117         }],
1118         [glib_cv_va_copy=yes],
1119         [glib_cv_va_copy=no])
1120 ])
1121 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1122         AC_LINK_IFELSE([#include <stdarg.h>
1123 #include <stdlib.h>
1124         void f (int i, ...) {
1125         va_list args1, args2;
1126         va_start (args1, i);
1127         __va_copy (args2, args1);
1128         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1129           exit (1);
1130         va_end (args1); va_end (args2);
1131         }
1132         int main() {
1133           f (0, 42);
1134           return 0;
1135         }],
1136         [glib_cv___va_copy=yes],
1137         [glib_cv___va_copy=no])
1138 ])
1139
1140 if test "x$glib_cv_va_copy" = "xyes"; then
1141   g_va_copy_func=va_copy
1142 else if test "x$glib_cv___va_copy" = "xyes"; then
1143   g_va_copy_func=__va_copy
1144 fi
1145 fi
1146
1147 if test -n "$g_va_copy_func"; then
1148   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1149 fi
1150
1151 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1152         AC_TRY_RUN([#include <stdarg.h>
1153 #include <stdlib.h>
1154         void f (int i, ...) {
1155         va_list args1, args2;
1156         va_start (args1, i);
1157         args2 = args1;
1158         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1159           exit (1);
1160         va_end (args1); va_end (args2);
1161         }
1162         int main() {
1163           f (0, 42);
1164           return 0;
1165         }],
1166         [glib_cv_va_val_copy=yes],
1167         [glib_cv_va_val_copy=no],
1168         [glib_cv_va_val_copy=yes])
1169 ])
1170
1171 if test "x$glib_cv_va_val_copy" = "xno"; then
1172   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1173 fi
1174
1175 dnl ***********************
1176 dnl *** g_module checks ***
1177 dnl ***********************
1178 G_MODULE_LIBS=
1179 G_MODULE_LIBS_EXTRA=
1180 G_MODULE_PLUGIN_LIBS=
1181 if test x"$glib_native_win32" = xyes; then
1182   dnl No use for this on Win32
1183   G_MODULE_LDFLAGS=
1184 else
1185   export SED
1186   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1187 fi
1188 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1189 G_MODULE_NEED_USCORE=0
1190 G_MODULE_BROKEN_RTLD_GLOBAL=0
1191 G_MODULE_HAVE_DLERROR=0
1192 dnl *** force native WIN32 shared lib loader
1193 if test -z "$G_MODULE_IMPL"; then
1194   case "$host" in
1195   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1196   esac
1197 fi
1198 dnl *** force native AIX library loader
1199 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1200 if test -z "$G_MODULE_IMPL"; then
1201   case "$host" in
1202   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1203   esac
1204 fi
1205 dnl *** dlopen() and dlsym() in system libraries
1206 if test -z "$G_MODULE_IMPL"; then
1207         AC_CHECK_FUNC(dlopen,
1208                       [AC_CHECK_FUNC(dlsym,
1209                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1210                       [])
1211 fi
1212 dnl *** load_image (BeOS)
1213 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1214   AC_CHECK_LIB(root, load_image,
1215       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1216       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1217       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1218       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1219       [])
1220 fi
1221 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1222 if test -z "$G_MODULE_IMPL"; then
1223         AC_CHECK_FUNC(NSLinkModule,
1224                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1225                        G_MODULE_NEED_USCORE=1],
1226                       [])
1227 fi
1228 dnl *** dlopen() and dlsym() in libdl
1229 if test -z "$G_MODULE_IMPL"; then
1230         AC_CHECK_LIB(dl, dlopen,
1231                      [AC_CHECK_LIB(dl, dlsym,
1232                                    [G_MODULE_LIBS=-ldl
1233                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1234                      [])
1235 fi
1236 dnl *** shl_load() in libdld (HP-UX)
1237 if test -z "$G_MODULE_IMPL"; then
1238         AC_CHECK_LIB(dld, shl_load,
1239                 [G_MODULE_LIBS=-ldld
1240                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1241                 [])
1242 fi
1243 dnl *** additional checks for G_MODULE_IMPL_DL
1244 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1245         LIBS_orig="$LIBS"
1246         LDFLAGS_orig="$LDFLAGS"
1247         LIBS="$G_MODULE_LIBS $LIBS"
1248         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1249 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1250         echo "void glib_plugin_test(void) { }" > plugin.c
1251         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1252                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1253         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1254                 glib_cv_rtldglobal_broken,[
1255                 AC_TRY_RUN([
1256 #include <dlfcn.h>
1257 #ifndef RTLD_GLOBAL
1258 #  define RTLD_GLOBAL 0
1259 #endif
1260 #ifndef RTLD_LAZY
1261 #  define RTLD_LAZY 0
1262 #endif
1263 int glib_plugin_test;
1264 int main () {
1265     void *handle, *global, *local;
1266     global = &glib_plugin_test;
1267     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1268     if (!handle) return 0;
1269     local = dlsym (handle, "glib_plugin_test");
1270     return global == local;
1271 }                       ],
1272                         [glib_cv_rtldglobal_broken=no],
1273                         [glib_cv_rtldglobal_broken=yes],
1274                         [glib_cv_rtldglobal_broken=no])
1275                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1276                 rmdir .libs 2>/dev/null
1277         ])
1278         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1279                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1280         else
1281                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1282         fi
1283 dnl *** check whether we need preceeding underscores
1284         AC_CACHE_CHECK([for preceeding underscore in symbols],
1285                 glib_cv_uscore,[
1286                 AC_TRY_RUN([#include <dlfcn.h>
1287                 int glib_underscore_test (void) { return 42; }
1288                 int main() {
1289                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1290                   handle = dlopen ((void*)0, 0);
1291                   if (handle) {
1292                     f1 = dlsym (handle, "glib_underscore_test");
1293                     f2 = dlsym (handle, "_glib_underscore_test");
1294                   } return (!f2 || f1);
1295                 }],
1296                         [glib_cv_uscore=yes],
1297                         [glib_cv_uscore=no],
1298                         [])
1299                 rm -f plugin.c plugin.$ac_objext plugin.lo
1300         ])
1301         GLIB_ASSERT_SET(glib_cv_uscore)
1302         if test "x$glib_cv_uscore" = "xyes"; then
1303                 G_MODULE_NEED_USCORE=1
1304         else
1305                 G_MODULE_NEED_USCORE=0
1306         fi
1307
1308         LDFLAGS="$LDFLAGS_orig"
1309 dnl *** check for having dlerror()
1310         AC_CHECK_FUNC(dlerror,
1311                 [G_MODULE_HAVE_DLERROR=1],
1312                 [G_MODULE_HAVE_DLERROR=0])
1313         LIBS="$LIBS_orig"
1314 fi
1315 dnl *** done, have we got an implementation?
1316 if test -z "$G_MODULE_IMPL"; then
1317         G_MODULE_IMPL=0
1318         G_MODULE_SUPPORTED=false
1319 else
1320         G_MODULE_SUPPORTED=true
1321 fi
1322
1323 AC_MSG_CHECKING(for the suffix of shared libraries)
1324 export SED
1325 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1326 eval $shrext_cmds
1327 module=yes eval std_shrext=$shrext_cmds
1328 # chop the initial dot
1329 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1330 AC_MSG_RESULT(.$glib_gmodule_suffix)
1331 # any reason it may fail?
1332 if test "x$glib_gmodule_suffix" = x; then
1333         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1334 fi
1335
1336 AC_SUBST(G_MODULE_SUPPORTED)
1337 AC_SUBST(G_MODULE_IMPL)
1338 AC_SUBST(G_MODULE_LIBS)
1339 AC_SUBST(G_MODULE_LIBS_EXTRA)
1340 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1341 AC_SUBST(G_MODULE_LDFLAGS)
1342 AC_SUBST(G_MODULE_HAVE_DLERROR)
1343 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1344 AC_SUBST(G_MODULE_NEED_USCORE)
1345 AC_SUBST(GLIB_DEBUG_FLAGS)
1346
1347 dnl **********************
1348 dnl *** g_spawn checks ***
1349 dnl **********************
1350
1351 AC_MSG_CHECKING(for gspawn implementation)
1352 case "$host" in
1353   *-*-mingw*)
1354     GSPAWN=gspawn-win32.lo
1355     ;;
1356   *)
1357     GSPAWN=gspawn.lo
1358     ;;
1359 esac
1360 AC_MSG_RESULT($GSPAWN)
1361 AC_SUBST(GSPAWN)
1362
1363 dnl *************************
1364 dnl *** GIOChannel checks ***
1365 dnl *************************
1366
1367 AC_MSG_CHECKING(for GIOChannel implementation)
1368 case "$host" in
1369   *-*-mingw*)
1370     GIO=giowin32.lo
1371     ;;
1372   *)
1373     GIO=giounix.lo
1374     ;;
1375 esac
1376 AC_MSG_RESULT($GIO)
1377 AC_SUBST(GIO)
1378
1379 dnl ****************************************
1380 dnl *** platform dependent source checks ***
1381 dnl ****************************************
1382
1383 AC_MSG_CHECKING(for platform-dependent source)
1384 case "$host" in
1385   *-*-cygwin*|*-*-mingw*)
1386     PLATFORMDEP=gwin32.lo
1387     ;;
1388   *)
1389     PLATFORMDEP=
1390     ;;
1391 esac
1392 AC_MSG_RESULT($PLATFORMDEP)
1393 AC_SUBST(PLATFORMDEP)
1394
1395 AC_MSG_CHECKING([whether to compile timeloop])
1396 case "$host" in
1397   *-*-cygwin*|*-*-mingw*|*-*-minix)
1398     enable_timeloop=no
1399     ;;
1400   *)
1401     enable_timeloop=yes
1402     ;;
1403 esac
1404 AC_MSG_RESULT($enable_timeloop)
1405 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1406
1407 AC_MSG_CHECKING([if building for some Win32 platform])
1408 case "$host" in
1409   *-*-mingw*|*-*-cygwin*)
1410     platform_win32=yes
1411     ;;
1412   *)
1413     platform_win32=no
1414     ;;
1415 esac
1416 AC_MSG_RESULT($platform_win32)
1417 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1418
1419 dnl ***********************
1420 dnl *** g_thread checks ***
1421 dnl ***********************
1422
1423 AC_ARG_WITH(threads,
1424            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/win32@:>@],
1425                            [specify a thread implementation to use])],
1426            [if test "x$with_threads" = x; then
1427                 want_threads=yes
1428             else
1429                 want_threads=$with_threads
1430             fi],
1431            [want_threads=yes])
1432 if test "x$enable_threads" = "xno"; then
1433         want_threads=no
1434 fi
1435
1436 dnl error and warning message
1437 dnl *************************
1438
1439 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1440                 computer. GLib will not have a default thread implementation."
1441
1442 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1443                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1444                 compilation now, but then your programs might not work.
1445                 Please provide information on how it is done on your system."
1446
1447 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1448                 "
1449
1450 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1451                 provide information on your thread implementation.
1452                 You can also run 'configure --disable-threads'
1453                 to compile without thread support."
1454
1455 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1456                 functions will not be MT-safe during their first call because
1457                 there is no working 'getpwuid_r' on your system."
1458
1459 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1460                 because there is no 'localtime_r' on your system."
1461
1462 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1463                 crude surrogate will be used. If you happen to know a
1464                 yield function for your system, please inform the GLib
1465                 developers."
1466
1467 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1468                 threads on your system. Thus threads can only have the default
1469                 priority. If you happen to know these main/max
1470                 priorities, please inform the GLib developers."
1471
1472 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1473                 linking threaded applications. As GLib cannot do that
1474                 automatically, you will get an linkg error everytime you are
1475                 not using the right compiler. In that case you have to relink
1476                 with the right compiler. Ususally just '_r' is appended
1477                 to the compiler name."
1478
1479 dnl determination of thread implementation
1480 dnl ***************************************
1481
1482 # have_threads=no   means no thread support
1483 # have_threads=none means no default thread implementation
1484
1485 have_threads=no
1486 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1487                                 || test "x$want_threads" = xdce; then
1488         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1489         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1490         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1491         glib_save_CPPFLAGS="$CPPFLAGS"
1492         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1493         if test "x$have_threads" = xno; then
1494                 AC_TRY_COMPILE([#include <pthread.h>],
1495                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1496                         have_threads=posix)
1497         fi
1498         if test "x$have_threads" = xno; then
1499                 AC_TRY_COMPILE([#include <pthread.h>],
1500                         [pthread_mutex_t m;
1501                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1502                         have_threads=dce)
1503         fi
1504         # Tru64Unix requires -pthread to find pthread.h. See #103020
1505         CPPFLAGS="$CPPFLAGS -pthread"
1506         if test "x$have_threads" = xno; then
1507         AC_TRY_COMPILE([#include <pthread.h>],
1508                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1509                        have_threads=posix)
1510         fi
1511         CPPFLAGS="$glib_save_CPPFLAGS"
1512 fi
1513 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1514         case $host in
1515                 *-*-mingw*)
1516                 have_threads=win32
1517                 ;;
1518         esac
1519 fi
1520 if test "x$want_threads" = xnone; then
1521         have_threads=none
1522 fi
1523
1524 AC_MSG_CHECKING(for thread implementation)
1525
1526 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1527         AC_MSG_RESULT(none available)
1528         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1529 else
1530         AC_MSG_RESULT($have_threads)
1531 fi
1532
1533
1534 dnl determination of G_THREAD_CFLAGS
1535 dnl ********************************
1536
1537 G_THREAD_LIBS=
1538 G_THREAD_LIBS_EXTRA=
1539 G_THREAD_CFLAGS=
1540
1541 dnl
1542 dnl Test program for basic POSIX threads functionality
1543 dnl
1544 m4_define([glib_thread_test],[
1545 #include <pthread.h>
1546 int check_me = 0;
1547 void* func(void* data) {check_me = 42; return &check_me;}
1548 int main()
1549  { pthread_t t;
1550    void *ret;
1551    pthread_create (&t, $1, func, 0);
1552    pthread_join (t, &ret);
1553    return (check_me != 42 || ret != &check_me);
1554 }])
1555
1556 dnl
1557 dnl Test program for sched_get_priority_min()
1558 dnl
1559 m4_define([glib_sched_priority_test],[
1560 #include <sched.h>
1561 #include <errno.h>
1562 int main() {
1563     errno = 0;
1564     return sched_get_priority_min(SCHED_OTHER)==-1
1565            && errno != 0;
1566 }])
1567
1568 if test x"$have_threads" != xno; then
1569
1570   if test x"$have_threads" = xposix; then
1571     # First we test for posix, whether -pthread or -pthreads do the trick as
1572     # both CPPFLAG and LIBS.
1573     # One of them does for most gcc versions and some other platforms/compilers
1574     # too and could be considered as the canonical way to go.
1575     case $host in
1576       *-*-cygwin*|*-*-darwin*)
1577          # skip cygwin and darwin -pthread or -pthreads test
1578          ;;
1579       *-solaris*)
1580         # These compiler/linker flags work with both Sun Studio and gcc
1581         # Sun Studio expands -mt to -D_REENTRANT and -lthread
1582         # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1583         G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1584         G_THREAD_LIBS="-lpthread -lthread"
1585         ;;
1586       *)
1587         for flag in pthread pthreads mt; do
1588           glib_save_CFLAGS="$CFLAGS"
1589           CFLAGS="$CFLAGS -$flag"
1590           AC_TRY_RUN(glib_thread_test(0),
1591                      glib_flag_works=yes,
1592                      glib_flag_works=no,
1593                      [AC_LINK_IFELSE(glib_thread_test(0),
1594                                      glib_flag_works=yes,
1595                                      glib_flag_works=no)])
1596           CFLAGS="$glib_save_CFLAGS"
1597           if test $glib_flag_works = yes ; then
1598              G_THREAD_CFLAGS=-$flag
1599              G_THREAD_LIBS=-$flag
1600              break;
1601           fi
1602         done
1603          ;;
1604     esac
1605   fi
1606
1607   if test x"$G_THREAD_CFLAGS" = x; then
1608
1609     # The canonical -pthread[s] does not work. Try something different.
1610
1611     case $host in
1612         *-aix*)
1613                 if test x"$GCC" = xyes; then
1614                         # GCC 3.0 and above needs -pthread.
1615                         # Should be coverd by the case above.
1616                         # GCC 2.x and below needs -mthreads
1617                         G_THREAD_CFLAGS="-mthreads"
1618                         G_THREAD_LIBS=$G_THREAD_CFLAGS
1619                 else
1620                         # We are probably using the aix compiler. Normaly a
1621                         # program would have to be compiled with the _r variant
1622                         # of the corresponding compiler, but we as GLib cannot
1623                         # do that: but the good news is that for compiling the
1624                         # only difference is the added -D_THREAD_SAFE compile
1625                         # option. This is according to the "C for AIX User's
1626                         # Guide".
1627                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
1628                 fi
1629                 ;;
1630         *-dg-dgux*)  # DG/UX
1631                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
1632                 ;;
1633         *-osf*)
1634                 # So we are using dce threads. posix threads are already
1635                 # catched above.
1636                 G_THREAD_CFLAGS="-threads"
1637                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1638                 ;;
1639         *-sysv5uw7*) # UnixWare 7
1640                 # We are not using gcc with -pthread. Catched above.
1641                 G_THREAD_CFLAGS="-Kthread"
1642                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1643                 ;;
1644         *-mingw*)
1645                 # No flag needed when using MSVCRT.DLL
1646                 G_THREAD_CFLAGS=""
1647                 ;;
1648         *)
1649                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1650                 ;;
1651     esac
1652
1653   fi
1654
1655     # if we are not finding the localtime_r function, then we probably are
1656     # not using the proper multithread flag
1657
1658     glib_save_CPPFLAGS="$CPPFLAGS"
1659     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1660
1661     # First we test, whether localtime_r is declared in time.h
1662     # directly. Then we test whether a macro localtime_r exists, in
1663     # which case localtime_r in the test program is replaced and thus
1664     # if we still find localtime_r in the output, it is not defined as
1665     # a macro.
1666
1667     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1668       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1669                                                            localtime_r(a,b)],
1670                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1671
1672     CPPFLAGS="$glib_save_CPPFLAGS"
1673
1674     AC_MSG_CHECKING(thread related cflags)
1675     AC_MSG_RESULT($G_THREAD_CFLAGS)
1676     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1677 fi
1678
1679 dnl determination of G_THREAD_LIBS
1680 dnl ******************************
1681
1682 mutex_has_default=no
1683 case $have_threads in
1684         posix|dce)
1685           glib_save_CPPFLAGS="$CPPFLAGS"
1686           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1687           if test x"$G_THREAD_LIBS" = x; then
1688             case $host in
1689               *-aix*)
1690                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
1691                 # probably using the aix compiler.
1692                 AC_MSG_WARN($AIX_COMPILE_INFO)
1693                 ;;
1694               *)
1695                 G_THREAD_LIBS=error
1696                 glib_save_LIBS="$LIBS"
1697                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
1698                         if test x"$thread_lib" = x; then
1699                                 add_thread_lib=""
1700                                 IN=""
1701                         else
1702                                 add_thread_lib="-l$thread_lib"
1703                                 IN=" in -l$thread_lib"
1704                         fi
1705                         if test x"$have_threads" = xposix; then
1706                                 defattr=0
1707                         else
1708                                 defattr=pthread_attr_default
1709                         fi
1710
1711                         LIBS="$add_thread_lib $glib_save_LIBS"
1712
1713                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
1714                         AC_TRY_RUN(glib_thread_test($defattr),
1715                                    glib_result=yes,
1716                                    glib_result=no,
1717                                    [AC_LINK_IFELSE(glib_thread_test($defattr),
1718                                                    glib_result=yes,
1719                                                    glib_result=no)])
1720                         AC_MSG_RESULT($glib_result)
1721
1722                         if test "$glib_result" = "yes" ; then
1723                           G_THREAD_LIBS="$add_thread_lib"
1724                           break
1725                         fi
1726                 done
1727                 if test "x$G_THREAD_LIBS" = xerror; then
1728                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1729                 fi
1730                 LIBS="$glib_save_LIBS"
1731                 ;;
1732             esac
1733           fi
1734
1735           glib_save_LIBS="$LIBS"
1736           for thread_lib in "" rt rte; do
1737             if test x"$thread_lib" = x; then
1738               add_thread_lib=""
1739               IN=""
1740             else
1741               add_thread_lib="-l$thread_lib"
1742               IN=" in -l$thread_lib"
1743             fi
1744             LIBS="$add_thread_lib $glib_save_LIBS"
1745
1746             AC_MSG_CHECKING(for sched_get_priority_min$IN)
1747             AC_TRY_RUN(glib_sched_priority_test,
1748                        glib_result=yes,
1749                        glib_result=no,
1750                        [AC_LINK_IFELSE(glib_sched_priority_test,
1751                                        glib_result=yes,
1752                                        glib_result=no)])
1753             AC_MSG_RESULT($glib_result)
1754
1755             if test "$glib_result" = "yes" ; then
1756                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
1757                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
1758                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
1759                break
1760             fi
1761           done
1762           LIBS="$glib_save_LIBS"
1763           mutex_has_default=yes
1764           mutex_default_type='pthread_mutex_t'
1765           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
1766           mutex_header_file='pthread.h'
1767           if test "x$have_threads" = "xposix"; then
1768             g_threads_impl="POSIX"
1769           else
1770             g_threads_impl="DCE"
1771             have_threads="posix"
1772           fi
1773           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
1774           CPPFLAGS="$glib_save_CPPFLAGS"
1775           ;;
1776         win32)
1777            g_threads_impl="WIN32"
1778            ;;
1779         none|no)
1780            g_threads_impl="NONE"
1781            ;;
1782         *)
1783            g_threads_impl="NONE"
1784            G_THREAD_LIBS=error
1785            ;;
1786 esac
1787
1788 if test "x$G_THREAD_LIBS" = xerror; then
1789         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1790 fi
1791
1792 case $host in
1793   *-*-beos*)
1794     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
1795     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1796     ;;
1797   *)
1798     ;;
1799 esac
1800
1801 AC_MSG_CHECKING(thread related libraries)
1802 AC_MSG_RESULT($G_THREAD_LIBS)
1803
1804 dnl check for mt safe function variants and some posix functions
1805 dnl ************************************************************
1806
1807 if test x"$have_threads" != xno; then
1808         glib_save_LIBS="$LIBS"
1809         # we are not doing the following for now, as this might require glib
1810         # to always be linked with the thread libs on some platforms.
1811         # LIBS="$LIBS $G_THREAD_LIBS"
1812         AC_CHECK_FUNCS(localtime_r)
1813         if test "$ac_cv_header_pwd_h" = "yes"; then
1814                 AC_CACHE_CHECK([for posix getpwuid_r],
1815                         ac_cv_func_posix_getpwuid_r,
1816                         [AC_TRY_RUN([
1817 #include <errno.h>
1818 #include <pwd.h>
1819 int main () {
1820     char buffer[10000];
1821     struct passwd pwd, *pwptr = &pwd;
1822     int error;
1823     errno = 0;
1824     error = getpwuid_r (0, &pwd, buffer,
1825                         sizeof (buffer), &pwptr);
1826    return (error < 0 && errno == ENOSYS)
1827            || error == ENOSYS;
1828 }                               ],
1829                                 [ac_cv_func_posix_getpwuid_r=yes],
1830                                 [ac_cv_func_posix_getpwuid_r=no])])
1831                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
1832                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
1833                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
1834                                 [Have POSIX function getpwuid_r])
1835                 else
1836                         AC_CACHE_CHECK([for nonposix getpwuid_r],
1837                                 ac_cv_func_nonposix_getpwuid_r,
1838                                 [AC_TRY_LINK([#include <pwd.h>],
1839                                         [char buffer[10000];
1840                                         struct passwd pwd;
1841                                         getpwuid_r (0, &pwd, buffer,
1842                                                         sizeof (buffer));],
1843                                         [ac_cv_func_nonposix_getpwuid_r=yes],
1844                                         [ac_cv_func_nonposix_getpwuid_r=no])])
1845                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
1846                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
1847                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
1848                                         [Have non-POSIX function getpwuid_r])
1849                         fi
1850                 fi
1851         fi
1852         LIBS="$G_THREAD_LIBS $LIBS"
1853         if test x"$have_threads" = xposix; then
1854                 glib_save_CPPFLAGS="$CPPFLAGS"
1855                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1856                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
1857                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
1858                 # This is not AC_CHECK_FUNC to also work with function
1859                 # name mangling in header files.
1860                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1861                 AC_TRY_LINK([#include <pthread.h>],
1862                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1863                         [AC_MSG_RESULT(yes)
1864                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1865                                   [Have function pthread_attr_setstacksize])],
1866                         [AC_MSG_RESULT(no)])
1867                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1868                 if test x"$posix_priority_min" = x; then
1869                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1870                                 PX_PRIO_MIN],,[
1871                                 posix_priority_min=PX_PRIO_MIN
1872                                 posix_priority_max=PX_PRIO_MAX])
1873                 fi
1874                 if test x"$posix_priority_min" = x; then
1875                         # AIX
1876                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
1877                                 PTHREAD_PRIO_MIN],,[
1878                                 posix_priority_min=PTHREAD_PRIO_MIN
1879                                 posix_priority_max=PTHREAD_PRIO_MAX])
1880                 fi
1881                 if test x"$posix_priority_min" = x; then
1882                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1883                                 PRI_OTHER_MIN],,[
1884                                 posix_priority_min=PRI_OTHER_MIN
1885                                 posix_priority_max=PRI_OTHER_MAX])
1886                 fi
1887                 if test x"$posix_priority_min" = x; then
1888                         AC_MSG_RESULT(none found)
1889                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1890                         posix_priority_min=-1
1891                         posix_priority_max=-1
1892                 else
1893                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1894                         AC_MSG_CHECKING(for pthread_setschedparam)
1895                         AC_TRY_LINK([#include <pthread.h>],
1896                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
1897                           [AC_MSG_RESULT(yes)
1898                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1899                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
1900                           [AC_MSG_RESULT(no)
1901                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
1902                 fi
1903                 posix_yield_func=none
1904                 AC_MSG_CHECKING(for posix yield function)
1905                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1906                                                         thr_yield; do
1907                         AC_TRY_LINK([#include <pthread.h>],
1908                                 [$yield_func()],
1909                                 [posix_yield_func="$yield_func"
1910                                 break])
1911                 done
1912                 if test x"$posix_yield_func" = xnone; then
1913                         AC_MSG_RESULT(none found)
1914                         AC_MSG_WARN($POSIX_NO_YIELD)
1915                         posix_yield_func="g_usleep(1000)"
1916                 else
1917                         AC_MSG_RESULT($posix_yield_func)
1918                         posix_yield_func="$posix_yield_func()"
1919                 fi
1920                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1921                 CPPFLAGS="$glib_save_CPPFLAGS"
1922
1923         elif test x"$have_threads" = xwin32; then
1924                 # It's a pointer to a private struct
1925                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
1926         fi
1927
1928         LIBS="$glib_save_LIBS"
1929
1930         # now spit out all the warnings.
1931         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1932            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1933                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1934         fi
1935         if test "$ac_cv_func_localtime_r" != "yes"; then
1936                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1937         fi
1938 fi
1939
1940 if test x"$glib_cv_sizeof_system_thread" = x; then
1941    # use a pointer as a fallback.
1942    GLIB_SIZEOF(,void *, system_thread)
1943 fi
1944
1945 #
1946 # Hack to deal with:
1947 #
1948 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
1949 #     building shared libraries with linux.
1950 #
1951 case $host in
1952   *-*-linux*)
1953     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
1954     ;;
1955   *)
1956     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
1957     ;;
1958 esac
1959
1960 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1961                    [Source file containing theread implementation])
1962 AC_SUBST(G_THREAD_CFLAGS)
1963 AC_SUBST(G_THREAD_LIBS)
1964 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
1965 AC_SUBST(G_THREAD_LIBS_EXTRA)
1966
1967 dnl **********************************************
1968 dnl *** GDefaultMutex setup and initialization ***
1969 dnl **********************************************
1970 dnl
1971 dnl if mutex_has_default = yes, we also got
1972 dnl mutex_default_type, mutex_default_init and mutex_header_file
1973 if test $mutex_has_default = yes ; then
1974         glib_save_CPPFLAGS="$CPPFLAGS"
1975         glib_save_LIBS="$LIBS"
1976         LIBS="$G_THREAD_LIBS $LIBS"
1977         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1978         GLIB_SIZEOF([#include <$mutex_header_file>],
1979                     $mutex_default_type,
1980                     gmutex)
1981         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1982                            $mutex_default_type,
1983                            gmutex,
1984                            $glib_cv_sizeof_gmutex,
1985                            $mutex_default_init)
1986         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1987                 mutex_has_default=no
1988         fi
1989         CPPFLAGS="$glib_save_CPPFLAGS"
1990         LIBS="$glib_save_LIBS"
1991 fi
1992
1993 AC_CHECK_FUNCS(clock_gettime, [], [
1994   AC_CHECK_LIB(rt, clock_gettime, [
1995     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
1996     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
1997     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
1998   ])
1999 ])
2000
2001 AC_CACHE_CHECK(for monotonic clocks,
2002     glib_cv_monotonic_clock,AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
2003 #include <time.h>
2004 #include <unistd.h>
2005 int main() {
2006 #if !(defined(_POSIX_MONOTONIC_CLOCK) && _POSIX_MONOTONIC_CLOCK >= 0 && defined(CLOCK_MONOTONIC))
2007         #error No monotonic clock
2008 #endif
2009         return 0;
2010 }
2011 ]])],glib_cv_monotonic_clock=yes,glib_cv_monotonic_clock=no))
2012 if test "$glib_cv_monotonic_clock" = "yes"; then
2013   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
2014 fi
2015
2016
2017 dnl ********************************
2018 dnl *** g_atomic_* tests for gcc ***
2019 dnl ********************************
2020
2021 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
2022
2023 if test x"$GCC" = xyes; then
2024   case $host_cpu in
2025     i386)
2026       AC_MSG_RESULT([none])
2027       glib_memory_barrier_needed=no
2028       ;;
2029     i?86)
2030       AC_MSG_RESULT([i486])
2031       AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
2032                          [i486 atomic implementation])
2033       glib_memory_barrier_needed=no
2034       ;;
2035     sparc*)
2036       SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
2037                 when you are using a sparc with v9 instruction set (most
2038                 sparcs nowadays). This will make the code for atomic
2039                 operations much faster. The resulting code will not run
2040                 on very old sparcs though."
2041
2042       AC_LINK_IFELSE([[
2043         main ()
2044         {
2045           int tmp1, tmp2, tmp3;
2046           __asm__ __volatile__("casx [%2], %0, %1"
2047                                : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
2048         }]],
2049         AC_MSG_RESULT([sparcv9])
2050         AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
2051                            [sparcv9 atomic implementation]),
2052         AC_MSG_RESULT([no])
2053         AC_MSG_WARN([[$SPARCV9_WARNING]]))
2054       glib_memory_barrier_needed=yes
2055       ;;
2056     alpha*)
2057       AC_MSG_RESULT([alpha])
2058       AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
2059                          [alpha atomic implementation])
2060       glib_memory_barrier_needed=yes
2061       ;;
2062     x86_64)
2063       AC_MSG_RESULT([x86_64])
2064       AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
2065                          [x86_64 atomic implementation])
2066       glib_memory_barrier_needed=no
2067      ;;
2068     powerpc*)
2069       AC_MSG_RESULT([powerpc])
2070       AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
2071                          [powerpc atomic implementation])
2072       glib_memory_barrier_needed=yes
2073       ;;
2074     ia64)
2075       AC_MSG_RESULT([ia64])
2076       AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
2077                          [ia64 atomic implementation])
2078       glib_memory_barrier_needed=yes
2079       ;;
2080     s390|s390x)
2081       AC_MSG_RESULT([s390])
2082       AC_DEFINE_UNQUOTED(G_ATOMIC_S390, 1,
2083                          [s390 atomic implementation])
2084       glib_memory_barrier_needed=no
2085       ;;
2086     *)
2087       AC_MSG_RESULT([none])
2088       glib_memory_barrier_needed=yes
2089       ;;
2090   esac
2091 fi
2092
2093 dnl ****************************************
2094 dnl *** GLib POLL* compatibility defines ***
2095 dnl ****************************************
2096
2097 glib_poll_includes=["
2098 #include <sys/types.h>
2099 #include <sys/poll.h>
2100 "]
2101
2102 if test $ac_cv_header_sys_types_h = yes &&
2103    test $ac_cv_header_sys_poll_h = yes ; then
2104   glib_failed=false
2105   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2106   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2107   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2108   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2109   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2110   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2111   if $glib_failed ; then
2112     AC_MSG_ERROR([Could not determine values for POLL* constants])
2113   fi
2114 else
2115   glib_cv_value_POLLIN=1
2116   glib_cv_value_POLLOUT=4
2117   glib_cv_value_POLLPRI=2
2118   glib_cv_value_POLLERR=8
2119   glib_cv_value_POLLHUP=16
2120   glib_cv_value_POLLNVAL=32
2121 fi
2122
2123 AC_MSG_CHECKING([for broken poll])
2124 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2125         #include <stdlib.h>
2126         #include <fcntl.h>
2127         #include <poll.h>
2128         #ifdef HAVE_SYS_POLL_H
2129         #include <sys/poll.h>
2130         #endif
2131         int main(void) {
2132           struct pollfd fds[1];
2133           int fd;
2134           fd = open("/dev/null", 1);
2135           fds[0].fd = fd;
2136           fds[0].events = POLLIN;
2137           fds[0].revents = 0;
2138           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2139                 exit(1);  /* Does not work for devices -- fail */
2140           }
2141           exit(0);
2142         }]])],
2143   [broken_poll=no],
2144   [broken_poll=yes
2145    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2146   [broken_poll="no (cross compiling)"])
2147 AC_MSG_RESULT($broken_poll)
2148
2149 dnl *********************
2150 dnl *** GRegex checks ***
2151 dnl *********************
2152 PCRE_REQUIRED_VERSION=7.0
2153
2154 # Check if we should compile GRegex
2155 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2156               [disable the compilation of GRegex]),
2157 [case "${enableval}" in
2158   yes) enable_regex=true ;;
2159   no)  enable_regex=false ;;
2160   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2161 esac],
2162 [enable_regex=true])
2163
2164 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2165
2166 if test x$enable_regex = xtrue; then
2167   # Check if we should use the internal or the system-supplied pcre
2168   AC_ARG_WITH(pcre,
2169              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2170                              [specify whether to use the internal or the
2171                               system-supplied PCRE library])])
2172
2173   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2174
2175   if test "x$with_pcre" = xsystem; then
2176     PKG_CHECK_MODULES(PCRE,
2177                       libpcre >= $PCRE_REQUIRED_VERSION)
2178     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2179                    CFLAGS="$PCRE_CFLAGS" LDFLAGS="$PCRE_LIBS"
2180                    AC_TRY_RUN([#include <pcre.h>
2181                                int main () {
2182                                  int support;
2183                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2184                                  if (!support)
2185                                    return 1;
2186                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2187                                  if (!support)
2188                                    return 1;
2189                                  return 0;
2190                                }],
2191                    glib_cv_pcre_has_unicode=yes,
2192                    glib_cv_pcre_has_unicode=no,
2193                    glib_cv_pcre_has_unicode=yes)])
2194     if test "$glib_cv_pcre_has_unicode" = "no"; then
2195       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2196     fi
2197     AC_SUBST(PCRE_CFLAGS)
2198     AC_SUBST(PCRE_LIBS)
2199     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2200   else
2201     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2202     if test x"$GCC" = xyes; then
2203       AC_MSG_CHECKING([whether gcc understands -Wno-pointer-sign])
2204       if test [`$CC --version | sed -e 's/[^0-9]*\([0-9]\).*/\1/' -e q`] -ge 4; then
2205         PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2206         AC_MSG_RESULT([yes])
2207       else
2208         AC_MSG_RESULT([no])
2209       fi
2210     fi
2211   fi
2212   AC_SUBST(PCRE_WARN_CFLAGS)
2213 else
2214   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2215 fi
2216
2217 dnl **********************
2218 dnl *** Win32 API libs ***
2219 dnl **********************
2220
2221 case $host in
2222   *-*-cygwin*)
2223         G_LIBS_EXTRA="-luser32 -lkernel32"
2224     ;;
2225   *-*-mingw*)
2226         G_LIBS_EXTRA="-lws2_32 -lole32"
2227     ;;
2228   *)
2229         G_LIBS_EXTRA=""
2230     ;;
2231 esac
2232 AC_SUBST(G_LIBS_EXTRA)
2233
2234 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2235 dnl since we need it for g_iconv()
2236
2237 AC_MSG_CHECKING([for EILSEQ])
2238 AC_TRY_COMPILE([
2239 #include <errno.h>
2240 ],
2241 [
2242 int error = EILSEQ;
2243 ], have_eilseq=yes, have_eilseq=no);
2244 AC_MSG_RESULT($have_eilseq)
2245
2246 dnl ******************************************************************
2247 dnl *** Look for glib-genmarshal in PATH if we are cross-compiling ***
2248 dnl ******************************************************************
2249
2250 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2251
2252 if test $cross_compiling = yes; then
2253   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2254   if test x$GLIB_GENMARSHAL = xno; then
2255     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2256   fi
2257 fi
2258
2259 dnl **************************
2260 dnl *** Checks for gtk-doc ***
2261 dnl **************************
2262
2263 GTK_DOC_CHECK([1.4])
2264
2265 AC_ARG_ENABLE(man,
2266               [AC_HELP_STRING([--enable-man],
2267                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2268               enable_man=no)
2269
2270 if test "${enable_man}" != no; then
2271 dnl
2272 dnl Check for xsltproc
2273 dnl
2274 AC_PATH_PROG([XSLTPROC], [xsltproc])
2275   if test -z "$XSLTPROC"; then
2276     enable_man=no
2277   fi
2278
2279   dnl check for DocBook DTD and stylesheets in the local catalog.
2280   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2281      [DocBook XML DTD V4.1.2],,enable_man=no)
2282   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2283      [DocBook XSL Stylesheets],,enable_man=no)
2284 fi
2285
2286 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2287
2288 dnl ******************************
2289 dnl *** output the whole stuff ***
2290 dnl ******************************
2291
2292 dnl this section will only be run if config.status is invoked with no
2293 dnl arguments, or with "glibconfig.h" as an argument.
2294 AC_CONFIG_COMMANDS([glibconfig.h],
2295 [
2296         outfile=glibconfig.h-tmp
2297         cat > $outfile <<\_______EOF
2298 /* glibconfig.h
2299  *
2300  * This is a generated file.  Please modify 'configure.in'
2301  */
2302
2303 #ifndef __G_LIBCONFIG_H__
2304 #define __G_LIBCONFIG_H__
2305
2306 #include <glib/gmacros.h>
2307
2308 _______EOF
2309
2310         if test x$glib_limits_h = xyes; then
2311           echo '#include <limits.h>' >> $outfile
2312         fi
2313         if test x$glib_float_h = xyes; then
2314           echo '#include <float.h>' >> $outfile
2315         fi
2316         if test x$glib_values_h = xyes; then
2317           echo '#include <values.h>' >> $outfile
2318         fi
2319         if test "$glib_header_alloca_h" = "yes"; then
2320           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2321         fi
2322         if test x$glib_sys_poll_h = xyes; then
2323           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2324         fi
2325
2326         cat >> $outfile <<_______EOF
2327
2328 G_BEGIN_DECLS
2329
2330 #define G_MINFLOAT      $glib_mf
2331 #define G_MAXFLOAT      $glib_Mf
2332 #define G_MINDOUBLE     $glib_md
2333 #define G_MAXDOUBLE     $glib_Md
2334 #define G_MINSHORT      $glib_ms
2335 #define G_MAXSHORT      $glib_Ms
2336 #define G_MAXUSHORT     $glib_Mus
2337 #define G_MININT        $glib_mi
2338 #define G_MAXINT        $glib_Mi
2339 #define G_MAXUINT       $glib_Mui
2340 #define G_MINLONG       $glib_ml
2341 #define G_MAXLONG       $glib_Ml
2342 #define G_MAXULONG      $glib_Mul
2343
2344 _______EOF
2345
2346
2347         ### this should always be true in a modern C/C++ compiler
2348         cat >>$outfile <<_______EOF
2349 typedef signed char gint8;
2350 typedef unsigned char guint8;
2351 _______EOF
2352
2353
2354         if test -n "$gint16"; then
2355           cat >>$outfile <<_______EOF
2356 typedef signed $gint16 gint16;
2357 typedef unsigned $gint16 guint16;
2358 #define G_GINT16_MODIFIER $gint16_modifier
2359 #define G_GINT16_FORMAT $gint16_format
2360 #define G_GUINT16_FORMAT $guint16_format
2361 _______EOF
2362         fi
2363
2364
2365         if test -n "$gint32"; then
2366           cat >>$outfile <<_______EOF
2367 typedef signed $gint32 gint32;
2368 typedef unsigned $gint32 guint32;
2369 #define G_GINT32_MODIFIER $gint32_modifier
2370 #define G_GINT32_FORMAT $gint32_format
2371 #define G_GUINT32_FORMAT $guint32_format
2372 _______EOF
2373         fi
2374
2375         cat >>$outfile <<_______EOF
2376 #define G_HAVE_GINT64 1          /* deprecated, always true */
2377
2378 ${glib_extension}typedef signed $gint64 gint64;
2379 ${glib_extension}typedef unsigned $gint64 guint64;
2380
2381 #define G_GINT64_CONSTANT(val)  $gint64_constant
2382 #define G_GUINT64_CONSTANT(val) $guint64_constant
2383 _______EOF
2384
2385         if test x$gint64_format != x ; then
2386           cat >>$outfile <<_______EOF
2387 #define G_GINT64_MODIFIER $gint64_modifier
2388 #define G_GINT64_FORMAT $gint64_format
2389 #define G_GUINT64_FORMAT $guint64_format
2390 _______EOF
2391         else
2392           cat >>$outfile <<_______EOF
2393 #undef G_GINT64_MODIFIER
2394 #undef G_GINT64_FORMAT
2395 #undef G_GUINT64_FORMAT
2396 _______EOF
2397         fi
2398
2399         cat >>$outfile <<_______EOF
2400
2401 #define GLIB_SIZEOF_VOID_P $glib_void_p
2402 #define GLIB_SIZEOF_LONG   $glib_long
2403 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2404
2405 _______EOF
2406
2407         cat >>$outfile <<_______EOF
2408 typedef signed $glib_size_type_define gssize;
2409 typedef unsigned $glib_size_type_define gsize;
2410 #define G_GSIZE_MODIFIER $gsize_modifier
2411 #define G_GSSIZE_FORMAT $gssize_format
2412 #define G_GSIZE_FORMAT $gsize_format
2413
2414 #define G_MAXSIZE       G_MAXU$glib_msize_type
2415 _______EOF
2416
2417         if test -z "$glib_unknown_void_p"; then
2418           cat >>$outfile <<_______EOF
2419
2420 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2421 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2422
2423 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2424 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2425 _______EOF
2426         else
2427           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2428         fi
2429
2430
2431
2432         cat >>$outfile <<_______EOF
2433 $glib_atexit
2434 $glib_memmove
2435 $glib_defines
2436 $glib_os
2437
2438 $glib_vacopy
2439
2440 #ifdef  __cplusplus
2441 #define G_HAVE_INLINE   1
2442 #else   /* !__cplusplus */
2443 $glib_inline
2444 #endif  /* !__cplusplus */
2445
2446 #ifdef  __cplusplus
2447 #define G_CAN_INLINE    1
2448 _______EOF
2449
2450         if test x$g_can_inline = xyes ; then
2451                 cat >>$outfile <<_______EOF
2452 #else   /* !__cplusplus */
2453 #define G_CAN_INLINE    1
2454 _______EOF
2455         fi
2456
2457         cat >>$outfile <<_______EOF
2458 #endif
2459
2460 _______EOF
2461
2462         if test x$g_have_iso_c_varargs = xyes ; then
2463                 cat >>$outfile <<_______EOF
2464 #ifndef __cplusplus
2465 # define G_HAVE_ISO_VARARGS 1
2466 #endif
2467 _______EOF
2468         fi
2469         if test x$g_have_iso_cxx_varargs = xyes ; then
2470                 cat >>$outfile <<_______EOF
2471 #ifdef __cplusplus
2472 # define G_HAVE_ISO_VARARGS 1
2473 #endif
2474 _______EOF
2475         fi
2476         if test x$g_have_gnuc_varargs = xyes ; then
2477                 cat >>$outfile <<_______EOF
2478
2479 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2480  * is passed ISO vararg support is turned off, and there is no work
2481  * around to turn it on, so we unconditionally turn it off.
2482  */
2483 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2484 #  undef G_HAVE_ISO_VARARGS
2485 #endif
2486
2487 #define G_HAVE_GNUC_VARARGS 1
2488 _______EOF
2489         fi
2490
2491         case x$g_stack_grows in
2492         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2493         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2494         esac
2495
2496
2497         echo >>$outfile
2498         if test x$g_have_eilseq = xno; then
2499                 cat >>$outfile <<_______EOF
2500 #ifndef EILSEQ
2501 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2502  * The correspondence between this and the corresponding definition
2503  * in libiconv is essential.
2504  */
2505 #  define EILSEQ ENOENT
2506 #endif
2507 _______EOF
2508
2509         fi
2510
2511         if test x$g_have_gnuc_visibility = xyes ; then
2512                 cat >>$outfile <<_______EOF
2513 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2514 #define G_GNUC_INTERNAL
2515 #else
2516 #define G_HAVE_GNUC_VISIBILITY 1
2517 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2518 #endif
2519 _______EOF
2520         else
2521           if test x$g_have_sunstudio_visibility = xyes ; then
2522                 cat >>$outfile <<_______EOF
2523 #define G_GNUC_INTERNAL __hidden
2524 _______EOF
2525           else
2526                 cat >>$outfile <<_______EOF
2527 #define G_GNUC_INTERNAL
2528 _______EOF
2529           fi
2530         fi
2531
2532
2533         echo >>$outfile
2534         if test x$g_mutex_has_default = xyes; then
2535                 cat >>$outfile <<_______EOF
2536 $g_enable_threads_def G_THREADS_ENABLED
2537 #define G_THREADS_IMPL_$g_threads_impl_def
2538 typedef struct _GStaticMutex GStaticMutex;
2539 struct _GStaticMutex
2540 {
2541   struct _GMutex *runtime_mutex;
2542   union {
2543     char   pad[[$g_mutex_sizeof]];
2544     double dummy_double;
2545     void  *dummy_pointer;
2546     long   dummy_long;
2547   } static_mutex;
2548 };
2549 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
2550 #define g_static_mutex_get_mutex(mutex) \\
2551   (g_thread_use_default_impl ? ((GMutex*) ((mutex)->static_mutex.pad)) : \\
2552    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
2553 _______EOF
2554         else
2555                 cat >>$outfile <<_______EOF
2556 $g_enable_threads_def G_THREADS_ENABLED
2557 #define G_THREADS_IMPL_$g_threads_impl_def
2558 typedef struct _GMutex* GStaticMutex;
2559 #define G_STATIC_MUTEX_INIT NULL
2560 #define g_static_mutex_get_mutex(mutex) \\
2561   (g_static_mutex_get_mutex_impl_shortcut (mutex))
2562 _______EOF
2563         fi
2564
2565         cat >>$outfile <<_______EOF
2566 /* This represents a system thread as used by the implementation. An
2567  * alien implementaion, as loaded by g_thread_init can only count on
2568  * "sizeof (gpointer)" bytes to store their info. We however need more
2569  * for some of our native implementations. */
2570 typedef union _GSystemThread GSystemThread;
2571 union _GSystemThread
2572 {
2573   char   data[[$g_system_thread_sizeof]];
2574   double dummy_double;
2575   void  *dummy_pointer;
2576   long   dummy_long;
2577 };
2578 _______EOF
2579         if test x"$g_memory_barrier_needed" != xno; then
2580           echo >>$outfile
2581           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2582         fi
2583
2584         echo >>$outfile
2585         g_bit_sizes="16 32 64"
2586         for bits in $g_bit_sizes; do
2587           cat >>$outfile <<_______EOF
2588 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
2589 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
2590 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2591 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
2592 _______EOF
2593         done
2594
2595         cat >>$outfile <<_______EOF
2596 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
2597 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
2598 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
2599 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
2600 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
2601 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
2602 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
2603 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
2604 #define G_BYTE_ORDER $g_byte_order
2605
2606 #define GLIB_SYSDEF_POLLIN =$g_pollin
2607 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2608 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2609 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2610 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2611 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2612
2613 #define G_MODULE_SUFFIX "$g_module_suffix"
2614
2615 typedef $g_pid_type GPid;
2616
2617 G_END_DECLS
2618
2619 #endif /* GLIBCONFIG_H */
2620 _______EOF
2621
2622
2623         if cmp -s $outfile glibconfig.h; then
2624           AC_MSG_NOTICE([glibconfig.h is unchanged])
2625           rm -f $outfile
2626         else
2627           mv $outfile glibconfig.h
2628         fi
2629 ],[
2630
2631 # Note that if two cases are the same, case goes with the first one.
2632 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
2633 # on variable expansion in case labels.  Look at the generated config.status
2634 # for a hint.
2635
2636 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2637   glib_header_alloca_h="$ac_cv_working_alloca_h"
2638 else
2639   glib_header_alloca_h="$ac_cv_header_alloca_h"
2640 fi
2641
2642 case xyes in
2643 x$ac_cv_header_float_h)
2644   glib_float_h=yes
2645   glib_mf=FLT_MIN glib_Mf=FLT_MAX
2646   glib_md=DBL_MIN glib_Md=DBL_MAX
2647   ;;
2648 x$ac_cv_header_values_h)
2649   glib_values_h=yes
2650   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
2651   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
2652   ;;
2653 esac
2654
2655 case xyes in
2656 x$ac_cv_header_limits_h)
2657   glib_limits_h=yes
2658   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
2659   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
2660   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
2661   ;;
2662 x$ac_cv_header_values_h)
2663   glib_values_h=yes
2664   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
2665   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
2666   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
2667   ;;
2668 esac
2669
2670 if test x$ac_cv_header_sys_poll_h = xyes ; then
2671   glib_sys_poll_h=yes
2672 fi
2673
2674 case 2 in
2675 $ac_cv_sizeof_short)
2676   gint16=short
2677   gint16_modifier='"h"'
2678   gint16_format='"hi"'
2679   guint16_format='"hu"'
2680   ;;
2681 $ac_cv_sizeof_int)
2682   gint16=int
2683   gint16_modifier='""'
2684   gint16_format='"i"'
2685   guint16_format='"u"'
2686   ;;
2687 esac
2688 case 4 in
2689 $ac_cv_sizeof_short)
2690   gint32=short
2691   gint32_modifier='"h"'
2692   gint32_format='"hi"'
2693   guint32_format='"hu"'
2694   ;;
2695 $ac_cv_sizeof_int)
2696   gint32=int
2697   gint32_modifier='""'
2698   gint32_format='"i"'
2699   guint32_format='"u"'
2700   ;;
2701 $ac_cv_sizeof_long)
2702   gint32=long
2703   gint32_modifier='"l"'
2704   gint32_format='"li"'
2705   guint32_format='"lu"'
2706   ;;
2707 esac
2708 case 8 in
2709 $ac_cv_sizeof_int)
2710   gint64=int
2711   gint64_modifier='""'
2712   gint64_format='"i"'
2713   guint64_format='"u"'
2714   glib_extension=
2715   gint64_constant='(val)'
2716   guint64_constant='(val)'
2717   ;;
2718 $ac_cv_sizeof_long)
2719   gint64=long
2720   gint64_modifier='"l"'
2721   gint64_format='"li"'
2722   guint64_format='"lu"'
2723   glib_extension=
2724   gint64_constant='(val##L)'
2725   guint64_constant='(val##UL)'
2726   ;;
2727 $ac_cv_sizeof_long_long)
2728   gint64='long long'
2729   if test -n "$glib_cv_long_long_format"; then
2730     gint64_modifier='"'$glib_cv_long_long_format'"'
2731     gint64_format='"'$glib_cv_long_long_format'i"'
2732     guint64_format='"'$glib_cv_long_long_format'u"'
2733   fi
2734   glib_extension='G_GNUC_EXTENSION '
2735   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
2736   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
2737   ;;
2738 $ac_cv_sizeof___int64)
2739   gint64='__int64'
2740   if test -n "$glib_cv_long_long_format"; then
2741     gint64_modifier='"'$glib_cv_long_long_format'"'
2742     gint64_format='"'$glib_cv_long_long_format'i"'
2743     guint64_format='"'$glib_cv_long_long_format'u"'
2744   fi
2745   glib_extension=
2746   gint64_constant='(val##i64)'
2747   guint64_constant='(val##ui64)'
2748   ;;
2749 esac
2750 glib_size_t=$ac_cv_sizeof_size_t
2751 glib_size_type_define=$glib_size_type
2752 glib_void_p=$ac_cv_sizeof_long
2753 glib_long=$ac_cv_sizeof_void_p
2754
2755 case $glib_size_type in
2756 short)
2757   gsize_modifier='"h"'
2758   gsize_format='"hu"'
2759   gssize_format='"hi"'
2760   glib_msize_type='SHRT'
2761   ;;
2762 int)
2763   gsize_modifier='""'
2764   gsize_format='"u"'
2765   gssize_format='"i"'
2766   glib_msize_type='INT'
2767   ;;
2768 long)
2769   gsize_modifier='"l"'
2770   gsize_format='"lu"'
2771   gssize_format='"li"'
2772   glib_msize_type='LONG'
2773   ;;
2774 esac
2775
2776 gintbits=`expr $ac_cv_sizeof_int \* 8`
2777 glongbits=`expr $ac_cv_sizeof_long \* 8`
2778
2779
2780 case $ac_cv_sizeof_void_p in
2781 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
2782 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
2783 *)                      glib_unknown_void_p=yes ;;
2784 esac
2785
2786
2787 case xyes in
2788 x$ac_cv_func_atexit)
2789   glib_atexit="
2790 #ifdef NeXT /* @#%@! NeXTStep */
2791 # define g_ATEXIT(proc) (!atexit (proc))
2792 #else
2793 # define g_ATEXIT(proc) (atexit (proc))
2794 #endif"
2795   ;;
2796 x$ac_cv_func_on_exit)
2797   glib_atexit="
2798 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
2799   ;;
2800 esac
2801
2802 case xyes in
2803 x$ac_cv_func_memmove)
2804   glib_memmove='
2805 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
2806   ;;
2807 x$glib_cv_working_bcopy)
2808   glib_memmove="
2809 /* memmove isn't available, but bcopy can copy overlapping memory regions */
2810 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
2811   ;;
2812 *)
2813   glib_memmove="
2814 /* memmove isn't found and bcopy can't copy overlapping memory regions,
2815  * so we have to roll our own copy routine. */
2816 void g_memmove (void* dest, const void * src, unsigned long len);"
2817   ;;
2818 esac
2819
2820 glib_defines="
2821 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
2822 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
2823 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
2824 "
2825
2826 case xyes in
2827 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
2828 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
2829 *)                      glib_vacopy=''
2830 esac
2831
2832 if test x$glib_cv_va_val_copy = xno; then
2833   glib_vacopy="\$glib_vacopy
2834 #define G_VA_COPY_AS_ARRAY 1"
2835 fi
2836
2837 if test x$glib_cv_hasinline = xyes; then
2838     glib_inline='#define G_HAVE_INLINE 1'
2839 fi
2840 if test x$glib_cv_has__inline = xyes; then
2841     glib_inline="\$glib_inline
2842 #define G_HAVE___INLINE 1"
2843 fi
2844 if test x$glib_cv_has__inline__ = xyes; then
2845     glib_inline="\$glib_inline
2846 #define G_HAVE___INLINE__ 1"
2847 fi
2848
2849 g_have_gnuc_varargs=$g_have_gnuc_varargs
2850 g_have_iso_c_varargs=$g_have_iso_c_varargs
2851 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
2852
2853 g_can_inline=$g_can_inline
2854 g_have_gnuc_visibility=$g_have_gnuc_visibility
2855 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
2856
2857 case xyes in
2858 x$ac_cv_c_bigendian)
2859   g_byte_order=G_BIG_ENDIAN
2860   g_bs_native=BE
2861   g_bs_alien=LE
2862   ;;
2863 *)
2864   g_byte_order=G_LITTLE_ENDIAN
2865   g_bs_native=LE
2866   g_bs_alien=BE
2867   ;;
2868 esac
2869
2870 g_pollin=$glib_cv_value_POLLIN
2871 g_pollout=$glib_cv_value_POLLOUT
2872 g_pollpri=$glib_cv_value_POLLPRI
2873 g_pollhup=$glib_cv_value_POLLHUP
2874 g_pollerr=$glib_cv_value_POLLERR
2875 g_pollnval=$glib_cv_value_POLLNVAL
2876
2877 g_stack_grows=$glib_cv_stack_grows
2878
2879 g_have_eilseq=$have_eilseq
2880
2881 case x$have_threads in
2882 xno)    g_enable_threads_def="#undef";;
2883 *)      g_enable_threads_def="#define";;
2884 esac
2885
2886 g_threads_impl_def=$g_threads_impl
2887
2888 g_mutex_has_default="$mutex_has_default"
2889 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
2890 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
2891 g_mutex_contents="$glib_cv_byte_contents_gmutex"
2892
2893 g_memory_barrier_needed="$glib_memory_barrier_needed"
2894
2895 g_module_suffix="$glib_gmodule_suffix"
2896
2897 g_pid_type="$glib_pid_type"
2898 case $host in
2899   *-*-beos*)
2900     glib_os="#define G_OS_BEOS"
2901     ;;
2902   *-*-cygwin*)
2903     glib_os="#define G_OS_UNIX
2904 #define G_PLATFORM_WIN32
2905 #define G_WITH_CYGWIN"
2906     ;;
2907   *-*-mingw*)
2908     glib_os="#define G_OS_WIN32
2909 #define G_PLATFORM_WIN32"
2910     ;;
2911   *)
2912     glib_os="#define G_OS_UNIX"
2913     ;;
2914 esac
2915 ])
2916
2917 AC_CONFIG_FILES([
2918 glib-2.0.pc
2919 glib-2.0-uninstalled.pc
2920 gmodule-2.0.pc
2921 gmodule-export-2.0.pc
2922 gmodule-no-export-2.0.pc
2923 gmodule-2.0-uninstalled.pc
2924 gmodule-no-export-2.0-uninstalled.pc
2925 gthread-2.0.pc
2926 gthread-2.0-uninstalled.pc
2927 gobject-2.0.pc
2928 gobject-2.0-uninstalled.pc
2929 glib-zip
2930 glib-gettextize
2931 Makefile
2932 glib/Makefile
2933 glib/libcharset/Makefile
2934 glib/gnulib/Makefile
2935 glib/pcre/Makefile
2936 glib/update-pcre/Makefile
2937 gmodule/Makefile
2938 gmodule/gmoduleconf.h
2939 gobject/Makefile
2940 gobject/glib-mkenums
2941 gthread/Makefile
2942 po/Makefile.in
2943 docs/Makefile
2944 docs/reference/Makefile
2945 docs/reference/glib/Makefile
2946 docs/reference/glib/version.xml
2947 docs/reference/gobject/Makefile
2948 docs/reference/gobject/version.xml
2949 tests/Makefile
2950 tests/gobject/Makefile
2951 tests/refcount/Makefile
2952 m4macros/Makefile
2953 ])
2954
2955 AC_CONFIG_COMMANDS([chmod-scripts],
2956 [chmod 0755 glib-zip
2957 chmod 0755 glib-gettextize
2958 chmod 0755 gobject/glib-mkenums])
2959
2960 # we want to invoke this macro solely so that the config.status script
2961 # and automake generated makefiles know about these generated files.
2962 # They are only needed to distcheck the package
2963 if false; then
2964   AC_CONFIG_FILES([
2965     INSTALL
2966     README
2967     config.h.win32
2968     glibconfig.h.win32
2969     glib/makefile.msc
2970     glib/glib.rc
2971     gmodule/makefile.msc
2972     gmodule/gmodule.rc
2973     gobject/makefile.msc
2974     gobject/gobject.rc
2975     gthread/makefile.msc
2976     gthread/gthread.rc
2977     tests/makefile.msc
2978   ])
2979 fi
2980
2981 AC_OUTPUT