configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 dnl ***********************************
   6 dnl *** include special GLib macros ***
   7 dnl ***********************************
   8
   9 m4_define(glib_configure_in)
  10 m4_include(acglib.m4)dnl
  11 m4_include(glib/libcharset/codeset.m4)dnl
  12 m4_include(glib/libcharset/glibc21.m4)dnl
  13 m4_include(m4macros/glib-gettext.m4)dnl
  14
  15 #
  16 # The following version number definitions apply to GLib, GModule, GObject
  17 # and GThread as a whole, so if changes occoured in any of them, they are all
  18 # treated with the same interface and binary age.
  19 #
  20 # Making releases:
  21 #   glib_micro_version += 1;
  22 #   glib_interface_age += 1;
  23 #   glib_binary_age += 1;
  24 # if any functions have been added, set glib_interface_age to 0.
  25 # if backwards compatibility has been broken,
  26 # set glib_binary_age _and_ glib_interface_age to 0.
  27 #
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [13])
  30 m4_define([glib_micro_version], [0])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_SRCDIR([glib/glib.h])
  56
  57 # Save this value here, since automake will set cflags later
  58 cflags_set=${CFLAGS+set}
  59
  60 AM_INIT_AUTOMAKE([no-define])
  61
  62 # Specify a configuration file
  63 AM_CONFIG_HEADER([config.h])
  64
  65
  66 GLIB_MAJOR_VERSION=glib_major_version
  67 GLIB_MINOR_VERSION=glib_minor_version
  68 GLIB_MICRO_VERSION=glib_micro_version
  69 GLIB_INTERFACE_AGE=glib_interface_age
  70 GLIB_BINARY_AGE=glib_binary_age
  71 GLIB_VERSION=glib_version
  72
  73 AC_SUBST(GLIB_MAJOR_VERSION)
  74 AC_SUBST(GLIB_MINOR_VERSION)
  75 AC_SUBST(GLIB_MICRO_VERSION)
  76 AC_SUBST(GLIB_VERSION)
  77 AC_SUBST(GLIB_INTERFACE_AGE)
  78 AC_SUBST(GLIB_BINARY_AGE)
  79
  80 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  81           [Define to the GLIB major version])
  82 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  83           [Define to the GLIB minor version])
  84 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  85           [Define to the GLIB micro version])
  86 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  87           [Define to the GLIB interface age])
  88 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  89           [Define to the GLIB binary age])
  90
  91 # libtool versioning
  92 LT_RELEASE=glib_lt_release
  93 LT_CURRENT=glib_lt_current
  94 LT_REVISION=glib_lt_revision
  95 LT_AGE=glib_lt_age
  96 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
  97 AC_SUBST(LT_RELEASE)
  98 AC_SUBST(LT_CURRENT)
  99 AC_SUBST(LT_REVISION)
 100 AC_SUBST(LT_AGE)
 101 AC_SUBST(LT_CURRENT_MINUS_AGE)
 102
 103 dnl Initialize maintainer mode
 104 AM_MAINTAINER_MODE
 105
 106 AC_CANONICAL_HOST
 107
 108 AC_MSG_CHECKING([for the BeOS])
 109 case $host in
 110   *-*-beos*)
 111     glib_native_beos="yes"
 112     ;;
 113   *)
 114     glib_native_beos="no"
 115     ;;
 116 esac
 117 AC_MSG_RESULT([$glib_native_beos])
 118
 119 dnl
 120
 121 AC_MSG_CHECKING([for Win32])
 122 case "$host" in
 123   *-*-mingw*)
 124     glib_native_win32=yes
 125     GLIB_DEF=glib.def
 126     GMODULE_DEF=gmodule.def
 127     GOBJECT_DEF=gobject.def
 128     GTHREAD_DEF=gthread.def
 129     TESTGMODULE_EXP=testgmodule.exp
 130     glib_pid_type='void *'
 131     ;;
 132   *)
 133     glib_native_win32=no
 134     GLIB_DEF=
 135     GMODULE_DEF=
 136     GOBJECT_DEF=
 137     GTHREAD_DEF=
 138     TESTGMODULE_EXP=
 139     glib_pid_type=int
 140     ;;
 141 esac
 142 case $host in
 143   *-*-linux*)
 144     glib_os_linux=yes
 145     ;;
 146 esac
 147
 148
 149 AC_MSG_RESULT([$glib_native_win32])
 150 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 151 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 152 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 153 AC_SUBST(GLIB_DEF)
 154 AC_SUBST(GMODULE_DEF)
 155 AC_SUBST(GOBJECT_DEF)
 156 AC_SUBST(GTHREAD_DEF)
 157 AC_SUBST(TESTGMODULE_EXP)
 158
 159 if test "$glib_native_win32" = "yes"; then
 160   AC_CHECK_TOOL(WINDRES, windres, no)
 161   if test "$WINDRES" = no; then
 162     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 163   fi
 164   AC_CHECK_TOOL(NM, nm, no)
 165   if test "$NM" = no; then
 166     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 167   fi
 168   AC_CHECK_TOOL(RANLIB, ranlib, :)
 169   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 170 fi
 171 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 172
 173 if test "$glib_native_win32" != yes; then
 174     # libtool option to control which symbols are exported
 175     # right now, symbols starting with _ are not exported
 176     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 177 else
 178     # We currently use .def files on Windows
 179     LIBTOOL_EXPORT_OPTIONS=
 180 fi
 181 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 182
 183 dnl declare --enable-* args and collect ac_help strings
 184 AC_ARG_ENABLE(debug,
 185               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 186                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 187               enable_debug=glib_debug_default)
 188
 189 AC_ARG_ENABLE(gc_friendly,
 190               [AC_HELP_STRING([--enable-gc-friendly],
 191                               [turn on garbage collector friendliness [default=no]])],,
 192               [enable_gc_friendly=no])
 193 AC_ARG_ENABLE(mem_pools,
 194               [AC_HELP_STRING([--disable-mem-pools],
 195                               [disable all glib memory pools])],,
 196               [disable_mem_pools=no])
 197 AC_ARG_ENABLE(threads,
 198               [AC_HELP_STRING([--enable-threads],
 199                               [turn on basic thread support [default=yes]
 200 ([=no] will override --with-threads)])],,
 201               [enable_threads=yes])
 202 AC_ARG_ENABLE(rebuilds,
 203               [AC_HELP_STRING([--disable-rebuilds],
 204                               [disable all source autogeneration rules])],,
 205               [enable_rebuilds=yes])
 206 AC_ARG_ENABLE(visibility,
 207               [AC_HELP_STRING([--disable-visibility],
 208                               [don't use ELF visibility attributes])],,
 209               [enable_visibility=yes])
 210
 211 if test "x$enable_threads" != "xyes"; then
 212   enable_threads=no
 213 fi
 214
 215 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, ["${enable_debug}"],
 216         [Whether glib was compiled with debugging enabled])
 217
 218 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 219 if test "x$enable_gc_friendly" = "xyes"; then
 220   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 221   AC_MSG_RESULT([yes])
 222 else
 223   AC_MSG_RESULT([no])
 224 fi
 225
 226 AC_MSG_CHECKING([whether to disable memory pools])
 227 if test "x$disable_mem_pools" = "xno"; then
 228   AC_MSG_RESULT([no])
 229 else
 230   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 231   AC_SUBST(DISABLE_MEM_POOLS)
 232   AC_MSG_RESULT([yes])
 233 fi
 234
 235 if test "$glib_native_win32" = "yes"; then
 236   if test x$enable_static = xyes -o x$enable_static = x; then
 237     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 238     enable_static=no
 239   fi
 240   if test x$enable_shared = xno; then
 241     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 242   fi
 243   enable_shared=yes
 244 fi
 245
 246 dnl Checks for programs.
 247 AC_PROG_CC
 248
 249 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 250 AC_CHECK_PROGS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 251 AC_LANG_SAVE
 252 AC_LANG_CPLUSPLUS
 253 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 254 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 255 AC_LANG_RESTORE
 256
 257 AM_PROG_CC_STDC
 258 AC_PROG_INSTALL
 259
 260 AC_SYS_LARGEFILE
 261
 262 #
 263 # Find pkg-config
 264 #
 265 AC_PATH_PROG(PKG_CONFIG, [pkg-config], [no])
 266 if test x$PKG_CONFIG = xno ; then
 267   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
 268 fi
 269
 270 if $PKG_CONFIG --atleast-pkgconfig-version 0.14 ; then
 271   :
 272 else
 273   AC_MSG_ERROR([*** pkg-config too old; version 0.14 or better required.])
 274 fi
 275
 276 if test "x$enable_debug" = "xyes"; then
 277   if test x$cflags_set != xset ; then
 278       case " $CFLAGS " in
 279       *[[\ \    ]]-g[[\ \       ]]*) ;;
 280       *) CFLAGS="$CFLAGS -g" ;;
 281       esac
 282   fi
 283
 284   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 285 else
 286   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 287
 288   if test "x$enable_debug" = "xno"; then
 289     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 290   fi
 291 fi
 292
 293 if test "x$enable_visibility" = "xno"; then
 294   GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DDISABLE_VISIBILITY"
 295 fi
 296
 297 # Ensure MSVC-compatible struct packing convention is used when
 298 # compiling for Win32 with gcc.
 299 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 300 # gcc2 uses "-fnative-struct".
 301 if test x"$glib_native_win32" = xyes; then
 302   if test x"$GCC" = xyes; then
 303     msnative_struct=''
 304     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 305     if test -z "$ac_cv_prog_CC"; then
 306       our_gcc="$CC"
 307     else
 308       our_gcc="$ac_cv_prog_CC"
 309     fi
 310     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 311       2.)
 312         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 313           msnative_struct='-fnative-struct'
 314         fi
 315         ;;
 316       *)
 317         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 318           msnative_struct='-mms-bitfields'
 319         fi
 320         ;;
 321     esac
 322     if test x"$msnative_struct" = x ; then
 323       AC_MSG_RESULT([no way])
 324       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 325     else
 326       CFLAGS="$CFLAGS $msnative_struct"
 327       AC_MSG_RESULT([${msnative_struct}])
 328     fi
 329   fi
 330 fi
 331
 332 AC_EXEEXT
 333
 334 # define a MAINT-like variable REBUILD which is set if Perl
 335 # and awk are found, so autogenerated sources can be rebuilt
 336 AC_PROG_AWK
 337 AC_CHECK_PROGS(PERL, [perl5 perl])
 338 # We would like indent, but don't require it.
 339 AC_CHECK_PROG(INDENT, indent, indent)
 340 REBUILD=\#
 341 if test "x$enable_rebuilds" = "xyes" && \
 342      test -n "$PERL" && \
 343      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 344      test -n "$AWK" ; then
 345   REBUILD=
 346 fi
 347 AC_SUBST(REBUILD)
 348
 349 # Need full path to Perl for glib-mkenums
 350 #
 351 if test "x$PERL" != x ; then
 352   AC_PATH_PROG(PERL_PATH, [$PERL])
 353 else
 354   PERL_PATH="/usr/bin/env perl"
 355 fi
 356 AC_SUBST(PERL_PATH)
 357
 358 dnl ***********************
 359 dnl *** Tests for iconv ***
 360 dnl ***********************
 361 dnl
 362 dnl We do this before the gettext checks, to avoid distortion
 363
 364 AC_ARG_WITH(libiconv,
 365             [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 366                             [use the libiconv library])],,
 367             [with_libiconv=maybe])
 368
 369 found_iconv=no
 370 case $with_libiconv in
 371   maybe)
 372     # Check in the C library first
 373     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 374     # Check if we have GNU libiconv
 375     if test $found_iconv = "no"; then
 376       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 377     fi
 378     # Check if we have a iconv in -liconv, possibly from vendor
 379     if test $found_iconv = "no"; then
 380       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 381     fi
 382     ;;
 383   no)
 384     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 385     ;;
 386   gnu|yes)
 387     AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 388     ;;
 389   native)
 390     AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 391     ;;
 392 esac
 393
 394 if test "x$found_iconv" = "xno" ; then
 395    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 396 fi
 397
 398 jm_GLIBC21
 399 AC_ARG_ENABLE(iconv-cache,
 400               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 401                               [cache iconv descriptors [default=auto]])],,
 402               [enable_iconv_cache=auto])
 403
 404 AC_MSG_CHECKING([Whether to cache iconv descriptors])
 405 case $enable_iconv_cache in
 406   auto)
 407     if test $ac_cv_gnu_library_2_1 = yes; then
 408       enable_iconv_cache=no
 409     else
 410       enable_iconv_cache=yes
 411     fi
 412   ;;
 413   yes|no)
 414   ;;
 415   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 416   ;;
 417 esac
 418
 419 if test $enable_iconv_cache = yes; then
 420    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 421 fi
 422
 423 AC_MSG_RESULT($enable_iconv_cache)
 424
 425
 426 dnl
 427 dnl gettext support
 428 dnl
 429
 430 ALL_LINGUAS="am ar az be bg bn bn_IN bs ca cs cy da de dz el en_CA en_GB eo es et eu fa fi fr ga gl gu he hi hr hu hy id is it ja ka ko ku lt lv mk ml mn ms nb ne nl nn or pa pl pt pt_BR ro ru rw sk sl sq sr sr@Latn sr@ije sv ta te th tl tr tt uk vi wa xh yi zh_CN zh_HK zh_TW"
 431 GLIB_GNU_GETTEXT
 432
 433 if test "$gt_cv_have_gettext" != "yes" ; then
 434   AC_MSG_ERROR([
 435 *** You must have either have gettext support in your C library, or use the
 436 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 437 ])
 438 fi
 439
 440 LIBS="$INTLLIBS $LIBS"
 441
 442 GETTEXT_PACKAGE=glib20
 443 AC_SUBST(GETTEXT_PACKAGE)
 444 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 445   [Define the gettext package to be used])
 446
 447 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 448
 449 dnl
 450 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 451 dnl
 452
 453 if test x$with_libiconv != xno ; then
 454   case " $INTLLIBS " in
 455   *[[\ \        ]]-liconv[[\ \  ]]*) ;;
 456   *) ICONV_LIBS="-liconv" ;;
 457   esac
 458 fi
 459 AC_SUBST(ICONV_LIBS)
 460
 461 case $with_libiconv in
 462   gnu)
 463     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 464     ;;
 465   native)
 466     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 467     ;;
 468 esac
 469
 470 dnl Initialize libtool
 471 AM_DISABLE_STATIC
 472 AC_LIBTOOL_WIN32_DLL
 473 AM_PROG_LIBTOOL
 474
 475 if test "x$GCC" = "xyes"; then
 476   case " $CFLAGS " in
 477   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 478   *) CFLAGS="$CFLAGS -Wall" ;;
 479   esac
 480 fi
 481
 482 dnl
 483 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 484 dnl
 485 if test $cross_compiling != yes ; then
 486     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 487     glib_save_LIBS=$LIBS
 488     LIBS="$LIBS -lm"
 489     AC_TRY_RUN([#include <math.h>
 490                  int main (void) { return (log(1) != log(1.)); }],
 491          AC_MSG_RESULT(none needed),
 492          glib_save_CFLAGS=$CFLAGS
 493          CFLAGS="$CFLAGS -std1"
 494          AC_TRY_RUN([#include <math.h>
 495                      int main (void) { return (log(1) != log(1.)); }],
 496              AC_MSG_RESULT(-std1),
 497              AC_MSG_RESULT()
 498              CFLAGS=$glib_save_CFLAGS
 499              AC_MSG_WARN(
 500                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 501          )
 502     )
 503     LIBS=$glib_save_LIBS
 504 fi
 505
 506 dnl NeXTStep cc seems to need this
 507 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 508 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 509   AC_MSG_RESULT(none needed),
 510   glib_save_CFLAGS=$CFLAGS
 511   CFLAGS="$CFLAGS -posix"
 512   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 513     AC_MSG_RESULT(-posix),
 514     AC_MSG_RESULT()
 515     CFLAGS=$glib_save_CFLAGS
 516     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 517
 518 # Checks for header files.
 519 AC_HEADER_STDC
 520
 521 # Checks for library functions.
 522 AC_FUNC_VPRINTF
 523 AC_FUNC_MMAP
 524 AC_FUNC_ALLOCA
 525 AC_CHECK_FUNCS(posix_memalign)
 526 AC_CHECK_FUNCS(memalign)
 527 AC_CHECK_FUNCS(valloc)
 528
 529 AC_CHECK_FUNCS(atexit on_exit)
 530
 531 AC_CHECK_FUNCS(timegm)
 532
 533 AC_CHECK_SIZEOF(char)
 534 AC_CHECK_SIZEOF(short)
 535 AC_CHECK_SIZEOF(long)
 536 AC_CHECK_SIZEOF(int)
 537 AC_CHECK_SIZEOF(void *)
 538 AC_CHECK_SIZEOF(long long)
 539 AC_CHECK_SIZEOF(__int64)
 540
 541 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 542   :
 543 else
 544   AC_MSG_ERROR([
 545 *** GLib requires a 64 bit type. You might want to consider
 546 *** using the GNU C compiler.
 547 ])
 548 fi
 549
 550 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 551         # long long is a 64 bit integer.
 552         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 553         AC_CACHE_VAL(glib_cv_long_long_format,[
 554                 for format in ll q I64; do
 555                   AC_TRY_RUN([#include <stdio.h>
 556                         int main()
 557                         {
 558                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 559                           char buffer[1000];
 560                           sprintf (buffer, "%${format}u", a);
 561                           sscanf (buffer, "%${format}u", &b);
 562                           exit (b!=a);
 563                         }
 564                         ],
 565                         [glib_cv_long_long_format=${format}
 566                         break],
 567                         [],[:])
 568                 done])
 569         if test -n "$glib_cv_long_long_format"; then
 570           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 571           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 572           if test x"$glib_cv_long_long_format" = xI64; then
 573             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 574           fi
 575         else
 576           AC_MSG_RESULT(none)
 577         fi
 578 elif test x$ac_cv_sizeof___int64 = x8; then
 579         # __int64 is a 64 bit integer.
 580         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 581         # We know this is MSVCRT.DLL, and what the formats are
 582         glib_cv_long_long_format=I64
 583         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 584         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 585         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 586 fi
 587
 588 dnl long doubles were not used, and a portability problem
 589 dnl AC_C_LONG_DOUBLE
 590 AC_C_CONST
 591
 592 dnl ok, here we try to check whether the systems prototypes for
 593 dnl malloc and friends actually match the prototypes provided
 594 dnl by gmem.h (keep in sync). i currently only know how to check
 595 dnl this reliably with gcc (-Werror), improvements for other
 596 dnl compilers are apprechiated.
 597 SANE_MALLOC_PROTOS=no
 598 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 599 glib_save_CFLAGS=$CFLAGS
 600 if test "x$GCC" = "xyes"; then
 601   CFLAGS="$CFLAGS -Werror"
 602   AC_TRY_COMPILE([#include <stdlib.h>], [
 603     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 604     void* (*my_malloc_p)  (size_t)         = malloc;
 605     void  (*my_free_p)    (void*)          = free;
 606     void* (*my_realloc_p) (void*, size_t)  = realloc;
 607     my_calloc_p = 0;
 608     my_malloc_p = 0;
 609     my_free_p = 0;
 610     my_realloc_p = 0;
 611   ],
 612     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 613       [Define if you have correct malloc prototypes])
 614     SANE_MALLOC_PROTOS=yes)
 615 fi
 616 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 617 CFLAGS=$glib_save_CFLAGS
 618
 619 dnl
 620 dnl check in which direction the stack grows
 621 dnl
 622 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 623         AC_TRY_RUN([
 624         volatile int *a = 0, *b = 0;
 625         void foo (void);
 626         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 627         void foo (void) { volatile int x = 5; b = &x; }
 628         ],
 629         glib_cv_stack_grows=no
 630         ,
 631         glib_cv_stack_grows=yes
 632         ,)
 633 ])
 634
 635 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 636 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 637 dnl actually supported.
 638 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 639         AC_COMPILE_IFELSE([
 640         __inline int foo () { return 0; }
 641         int main () { return foo (); }
 642         ],
 643         glib_cv_has__inline=yes
 644         ,
 645         glib_cv_has__inline=no
 646         ,)
 647 ])
 648 case x$glib_cv_has__inline in
 649 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 650 esac
 651 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 652         AC_COMPILE_IFELSE([
 653         __inline__ int foo () { return 0; }
 654         int main () { return foo (); }
 655         ],
 656         glib_cv_has__inline__=yes
 657         ,
 658         glib_cv_has__inline__=no
 659         ,)
 660 ])
 661 case x$glib_cv_has__inline__ in
 662 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 663 esac
 664 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 665         AC_COMPILE_IFELSE([
 666         #undef inline
 667         inline int foo () { return 0; }
 668         int main () { return foo (); }
 669         ],
 670         glib_cv_hasinline=yes
 671         ,
 672         glib_cv_hasinline=no
 673         ,)
 674 ])
 675 case x$glib_cv_hasinline in
 676 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 677 esac
 678
 679 # if we can use inline functions in headers
 680 AC_MSG_CHECKING(if inline functions in headers work)
 681 AC_LINK_IFELSE([
 682 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 683 #  undef inline
 684 #  define inline __inline__
 685 #elif !defined (G_HAVE_INLINE)
 686 #  undef inline
 687 #  if defined (G_HAVE___INLINE__)
 688 #    define inline __inline__
 689 #  elif defined (G_HAVE___INLINE)
 690 #    define inline __inline
 691 #  endif
 692 #endif
 693
 694 int glib_test_func2 (int);
 695
 696 static inline int
 697 glib_test_func1 (void) {
 698   return glib_test_func2 (1);
 699 }
 700
 701 int
 702 main (void) {
 703   int i = 1;
 704 }],[g_can_inline=yes],[g_can_inline=no])
 705 AC_MSG_RESULT($g_can_inline)
 706
 707 dnl *** check for working do while(0) macros ***
 708 AC_CACHE_CHECK([for working do while(0) macros], g_support_dowhile_macros, [
 709         AC_TRY_COMPILE([],[
 710         #define STMT_START do
 711         #define STMT_END while(0)
 712         #define STMT_TEST STMT_START { i = 0; } STMT_END
 713         int main(void) { int i = 1; STMT_TEST; return i; }],
 714         [g_support_dowhile_macros=yes],
 715         [g_support_dowhile_macros=no],
 716         [g_support_dowhile_macros=yes])
 717 ])
 718 if test x$g_support_dowhile_macros = xyes; then
 719   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 720 fi
 721
 722 # check for flavours of varargs macros
 723 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 724 AC_TRY_COMPILE([],[
 725 int a(int p1, int p2, int p3);
 726 #define call_a(...) a(1,__VA_ARGS__)
 727 call_a(2,3);
 728 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 729 AC_MSG_RESULT($g_have_iso_c_varargs)
 730
 731 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 732 if test "$CXX" = ""; then
 733 dnl No C++ compiler
 734   g_have_iso_cxx_varargs=no
 735 else
 736   AC_LANG_CPLUSPLUS
 737   AC_TRY_COMPILE([],[
 738 int a(int p1, int p2, int p3);
 739 #define call_a(...) a(1,__VA_ARGS__)
 740 call_a(2,3);
 741 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 742   AC_LANG_C
 743 fi
 744 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 745
 746 AC_MSG_CHECKING(for GNUC varargs macros)
 747 AC_TRY_COMPILE([],[
 748 int a(int p1, int p2, int p3);
 749 #define call_a(params...) a(1,params)
 750 call_a(2,3);
 751 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 752 AC_MSG_RESULT($g_have_gnuc_varargs)
 753
 754 # check for GNUC visibility support
 755 AC_MSG_CHECKING(for GNUC visibility attribute)
 756 GLIB_CHECK_COMPILE_WARNINGS([
 757 void
 758 __attribute__ ((visibility ("hidden")))
 759      f_hidden (void)
 760 {
 761 }
 762 void
 763 __attribute__ ((visibility ("internal")))
 764      f_internal (void)
 765 {
 766 }
 767 void
 768 __attribute__ ((visibility ("protected")))
 769      f_protected (void)
 770 {
 771 }
 772 void
 773 __attribute__ ((visibility ("default")))
 774      f_default (void)
 775 {
 776 }
 777 int main (int argc, char **argv)
 778 {
 779         f_hidden();
 780         f_internal();
 781         f_protected();
 782         f_default();
 783         return 0;
 784 }
 785 ],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 786 AC_MSG_RESULT($g_have_gnuc_visibility)
 787 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 788
 789 # check for bytesex stuff
 790 AC_C_BIGENDIAN
 791
 792 # check for header files
 793 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h sys/param.h sys/poll.h])
 794 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 795 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h sched.h malloc.h])
 796
 797 # Checks for libcharset
 798 jm_LANGINFO_CODESET
 799 jm_GLIBC21
 800 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 801 AC_CHECK_FUNCS(setlocale)
 802
 803 # check additional type sizes
 804 AC_CHECK_SIZEOF(size_t)
 805
 806 dnl Try to figure out whether gsize, gssize should be long or int
 807 AC_MSG_CHECKING([for the appropriate definition for size_t])
 808
 809 case $ac_cv_sizeof_size_t in
 810   $ac_cv_sizeof_short)
 811       glib_size_type=short
 812       ;;
 813   $ac_cv_sizeof_int)
 814       glib_size_type=int
 815       ;;
 816   $ac_cv_sizeof_long)
 817       glib_size_type=long
 818       ;;
 819   *)  AC_MSG_ERROR([No type matching size_t in size])
 820       ;;
 821 esac
 822
 823 dnl If int/long are the same size, we see which one produces
 824 dnl warnings when used in the location as size_t. (This matters
 825 dnl on AIX with xlc)
 826 dnl
 827 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 828    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 829   GLIB_CHECK_COMPILE_WARNINGS([
 830 #if defined(_AIX) && !defined(__GNUC__)
 831 #pragma options langlvl=stdc89
 832 #endif
 833 #include <stddef.h>
 834 int main ()
 835 {
 836   size_t s = 1;
 837   unsigned int *size_int = &s;
 838   return (int)*size_int;
 839 }
 840     ],glib_size_type=int,
 841       [GLIB_CHECK_COMPILE_WARNINGS([
 842 #if defined(_AIX) && !defined(__GNUC__)
 843 #pragma options langlvl=stdc89
 844 #endif
 845 #include <stddef.h>
 846 int main ()
 847 {
 848    size_t s = 1;
 849    unsigned long *size_long = &s;
 850    return (int)*size_long;
 851 }
 852         ],glib_size_type=long)])
 853 fi
 854
 855 AC_MSG_RESULT(unsigned $glib_size_type)
 856
 857 # Check for some functions
 858 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk)
 859 # Check for high-resolution sleep functions
 860 AC_CHECK_FUNCS(nanosleep nsleep)
 861
 862 AC_CHECK_HEADERS(crt_externs.h)
 863 AC_CHECK_FUNCS(_NSGetEnviron)
 864
 865 AC_FUNC_VSNPRINTF_C99
 866 AC_FUNC_PRINTF_UNIX98
 867
 868 #
 869 # Check whether to use an included printf
 870 #
 871
 872 AC_ARG_ENABLE(included-printf,
 873               [AC_HELP_STRING([--enable-included-printf],
 874                               [use included printf [default=auto]])],
 875               enable_included_printf="$enableval")
 876
 877 need_included_printf=no
 878 if test "x$enable_included_printf" = "xyes" ; then
 879   need_included_printf=yes
 880 fi
 881 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
 882   need_included_printf=yes
 883 fi
 884 if test "$ac_cv_func_printf_unix98" != "yes" ; then
 885   need_included_printf=yes
 886 fi
 887 if test "x$ac_cv_sizeof_long_long" = "x8" &&
 888    test -z "$glib_cv_long_long_format" ; then
 889   need_included_printf=yes
 890 fi
 891
 892 if test "x$enable_included_printf" = "xno" &&
 893    test "x$need_included_printf" = "xyes" ; then
 894   AC_MSG_ERROR([
 895 *** Your C library's printf doesn't appear to have the features that
 896 *** GLib needs, but you specified --enable-included-printf=no.])
 897 fi
 898
 899 enable_included_printf=$need_included_printf
 900
 901 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
 902 if test "$enable_included_printf" != "yes" ; then
 903   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
 904 else
 905   if test -z "$glib_cv_long_long_format" ; then
 906     glib_cv_long_long_format="ll"
 907   fi
 908   AC_DEFINE(HAVE_VASPRINTF,1)
 909 fi
 910
 911 # Checks needed for gnulib vasnprintf
 912 bh_C_SIGNED
 913 jm_AC_TYPE_LONG_LONG
 914 gt_TYPE_LONGDOUBLE
 915 gt_TYPE_WCHAR_T
 916 gt_TYPE_WINT_T
 917 AC_TYPE_SIZE_T
 918 AC_CHECK_TYPES(ptrdiff_t)
 919 jm_AC_TYPE_INTMAX_T
 920 AC_CHECK_FUNCS(snprintf)
 921 AC_FUNC_SNPRINTF_C99
 922
 923 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 924 # The check is borrowed from the PERL Configure script.
 925 if test "$ac_cv_func_memmove" != "yes"; then
 926   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 927     glib_cv_working_bcopy,[AC_TRY_RUN([
 928       int main() {
 929         char buf[128], abc[128], *b;
 930         int len, off, align;
 931         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 932         for (align = 7; align >= 0; align--) {
 933           for (len = 36; len; len--) {
 934             b = buf+align; bcopy(abc, b, len);
 935             for (off = 1; off <= len; off++) {
 936               bcopy(b, b+off, len); bcopy(b+off, b, len);
 937                 if (bcmp(b, abc, len)) return(1);
 938             }
 939           }
 940         }
 941         return(0);
 942       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 943
 944   GLIB_ASSERT_SET(glib_cv_working_bcopy)
 945   if test "$glib_cv_working_bcopy" = "yes"; then
 946     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 947   fi
 948 fi
 949
 950 # Check for sys_errlist
 951 AC_MSG_CHECKING(for sys_errlist)
 952 AC_TRY_LINK(, [
 953 extern char *sys_errlist[];
 954 extern int sys_nerr;
 955 sys_errlist[sys_nerr-1][0] = 0;
 956 ], glib_ok=yes, glib_ok=no)
 957 AC_MSG_RESULT($glib_ok)
 958 if test "$glib_ok" = "no"; then
 959     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 960 fi
 961
 962 # Check for sys_siglist
 963 AC_MSG_CHECKING(for sys_siglist)
 964 AC_TRY_LINK(, [
 965 extern char *sys_siglist[];
 966 exit (sys_siglist[0]);
 967 ], glib_ok=yes, glib_ok=no)
 968 AC_MSG_RESULT($glib_ok)
 969 if test "$glib_ok" = "no"; then
 970     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 971 fi
 972
 973 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 974 AC_MSG_CHECKING(for sys_siglist declaration)
 975 AC_TRY_COMPILE([#include <signal.h>], [
 976 strlen (sys_siglist[0]);
 977 ], glib_ok=yes, glib_ok=no)
 978 AC_MSG_RESULT($glib_ok)
 979 if test "$glib_ok" = "no"; then
 980     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 981 fi
 982
 983 # Check if <sys/select.h> needs to be included for fd_set
 984 AC_MSG_CHECKING([for fd_set])
 985 AC_TRY_COMPILE([#include <sys/types.h>],
 986         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 987 if test "$gtk_ok" = "yes"; then
 988     AC_MSG_RESULT([yes, found in sys/types.h])
 989 else
 990     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
 991     if test "$gtk_ok" = "yes"; then
 992         # *** FIXME: give it a different name
 993         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
 994         AC_MSG_RESULT([yes, found in sys/select.h])
 995     else
 996         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
 997         AC_MSG_RESULT(no)
 998     fi
 999 fi
1000
1001 dnl *** check for sane realloc() ***
1002 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1003         AC_TRY_RUN([#include <stdlib.h>
1004         int main() {
1005           return realloc (0, sizeof (int)) == 0;
1006         }],
1007         [glib_cv_sane_realloc=yes],
1008         [glib_cv_sane_realloc=no],
1009         [glib_cv_sane_realloc=yes])
1010 ])
1011 if test x$glib_cv_sane_realloc = xyes; then
1012   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1013 fi
1014
1015 dnl Check for nl_langinfo and CODESET
1016
1017 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
1018 AC_TRY_COMPILE([#include <langinfo.h>],
1019         [char *codeset = nl_langinfo (CODESET);],
1020    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1021    have_codeset=yes,
1022    have_codeset=no)
1023 AC_MSG_RESULT($have_codeset)
1024
1025
1026 dnl ****************************************
1027 dnl *** posix_memalign                   ***
1028 dnl ****************************************
1029 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1030 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1031     glib_cv_compliant_posix_memalign=0
1032     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1033         AC_TRY_RUN([
1034                 #define _XOPEN_SOURCE 600
1035                 #include <stdlib.h> /* posix_memalign() should be defined here */
1036                 /* some systems break if #include <malloc.h> used */
1037                 static void test_memalign (size_t boundary, size_t size) {
1038                     void *mem = 0;
1039                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1040                         exit (1);
1041                     else
1042                       free (mem);
1043                 }
1044                 int main() {
1045                     test_memalign (  128,   128 - 2 * sizeof (void*));
1046                     test_memalign (  256,   256 - 2 * sizeof (void*));
1047                     test_memalign (  512,   512 - 2 * sizeof (void*));
1048                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1049                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1050                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1051                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1052                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1053                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1054                     exit (0); /* success */
1055                 }
1056                 ],
1057             [glib_cv_compliant_posix_memalign=1], [], [:])
1058       :
1059     fi
1060     ])
1061 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1062     AC_MSG_RESULT(yes)
1063     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1064 else
1065     AC_MSG_RESULT(no)
1066 fi
1067
1068
1069 dnl ****************************************
1070 dnl *** strlcpy/strlcat                  ***
1071 dnl ****************************************
1072 # Check for strlcpy
1073 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1074 AC_TRY_RUN([#include <stdlib.h>
1075 #include <string.h>
1076 int main() {
1077   char p[10];
1078   (void) strlcpy (p, "hi", 10);
1079   if (strlcat (p, "bye", 0) != 3)
1080     return 1;
1081   return 0;
1082 }], glib_cv_have_strlcpy=yes,
1083     glib_cv_have_strlcpy=no,
1084     glib_cv_have_strlcpy=no)])
1085 if test "$glib_cv_have_strlcpy" = "yes"; then
1086     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1087 fi
1088
1089
1090 dnl **********************
1091 dnl *** va_copy checks ***
1092 dnl **********************
1093 dnl we currently check for all three va_copy possibilities, so we get
1094 dnl all results in config.log for bug reports.
1095 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1096         AC_LINK_IFELSE([#include <stdarg.h>
1097 #include <stdlib.h>
1098         void f (int i, ...) {
1099         va_list args1, args2;
1100         va_start (args1, i);
1101         va_copy (args2, args1);
1102         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1103           exit (1);
1104         va_end (args1); va_end (args2);
1105         }
1106         int main() {
1107           f (0, 42);
1108           return 0;
1109         }],
1110         [glib_cv_va_copy=yes],
1111         [glib_cv_va_copy=no])
1112 ])
1113 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1114         AC_LINK_IFELSE([#include <stdarg.h>
1115 #include <stdlib.h>
1116         void f (int i, ...) {
1117         va_list args1, args2;
1118         va_start (args1, i);
1119         __va_copy (args2, args1);
1120         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1121           exit (1);
1122         va_end (args1); va_end (args2);
1123         }
1124         int main() {
1125           f (0, 42);
1126           return 0;
1127         }],
1128         [glib_cv___va_copy=yes],
1129         [glib_cv___va_copy=no])
1130 ])
1131
1132 if test "x$glib_cv_va_copy" = "xyes"; then
1133   g_va_copy_func=va_copy
1134 else if test "x$glib_cv___va_copy" = "xyes"; then
1135   g_va_copy_func=__va_copy
1136 fi
1137 fi
1138
1139 if test -n "$g_va_copy_func"; then
1140   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1141 fi
1142
1143 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1144         AC_TRY_RUN([#include <stdarg.h>
1145 #include <stdlib.h>
1146         void f (int i, ...) {
1147         va_list args1, args2;
1148         va_start (args1, i);
1149         args2 = args1;
1150         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1151           exit (1);
1152         va_end (args1); va_end (args2);
1153         }
1154         int main() {
1155           f (0, 42);
1156           return 0;
1157         }],
1158         [glib_cv_va_val_copy=yes],
1159         [glib_cv_va_val_copy=no],
1160         [glib_cv_va_val_copy=yes])
1161 ])
1162
1163 if test "x$glib_cv_va_val_copy" = "xno"; then
1164   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1165 fi
1166
1167 dnl ***********************
1168 dnl *** g_module checks ***
1169 dnl ***********************
1170 G_MODULE_LIBS=
1171 G_MODULE_LIBS_EXTRA=
1172 G_MODULE_PLUGIN_LIBS=
1173 if test x"$glib_native_win32" = xyes; then
1174   dnl No use for this on Win32
1175   G_MODULE_LDFLAGS=
1176 else
1177   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1178 fi
1179 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1180 G_MODULE_NEED_USCORE=0
1181 G_MODULE_BROKEN_RTLD_GLOBAL=0
1182 G_MODULE_HAVE_DLERROR=0
1183 dnl *** force native WIN32 shared lib loader
1184 if test -z "$G_MODULE_IMPL"; then
1185   case "$host" in
1186   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1187   esac
1188 fi
1189 dnl *** force native AIX library loader
1190 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1191 if test -z "$G_MODULE_IMPL"; then
1192   case "$host" in
1193   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1194   esac
1195 fi
1196 dnl *** dlopen() and dlsym() in system libraries
1197 if test -z "$G_MODULE_IMPL"; then
1198         AC_CHECK_FUNC(dlopen,
1199                       [AC_CHECK_FUNC(dlsym,
1200                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1201                       [])
1202 fi
1203 dnl *** load_image (BeOS)
1204 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1205   AC_CHECK_LIB(root, load_image,
1206       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1207       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1208       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1209       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1210       [])
1211 fi
1212 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1213 if test -z "$G_MODULE_IMPL"; then
1214         AC_CHECK_FUNC(NSLinkModule,
1215                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1216                        G_MODULE_NEED_USCORE=1],
1217                       [])
1218 fi
1219 dnl *** dlopen() and dlsym() in libdl
1220 if test -z "$G_MODULE_IMPL"; then
1221         AC_CHECK_LIB(dl, dlopen,
1222                      [AC_CHECK_LIB(dl, dlsym,
1223                                    [G_MODULE_LIBS=-ldl
1224                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1225                      [])
1226 fi
1227 dnl *** shl_load() in libdld (HP-UX)
1228 if test -z "$G_MODULE_IMPL"; then
1229         AC_CHECK_LIB(dld, shl_load,
1230                 [G_MODULE_LIBS=-ldld
1231                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1232                 [])
1233 fi
1234 dnl *** additional checks for G_MODULE_IMPL_DL
1235 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1236         LIBS_orig="$LIBS"
1237         LDFLAGS_orig="$LDFLAGS"
1238         LIBS="$G_MODULE_LIBS $LIBS"
1239         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1240 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1241         echo "void glib_plugin_test(void) { }" > plugin.c
1242         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1243                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1244         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1245                 glib_cv_rtldglobal_broken,[
1246                 AC_TRY_RUN([
1247 #include <dlfcn.h>
1248 #ifndef RTLD_GLOBAL
1249 #  define RTLD_GLOBAL 0
1250 #endif
1251 #ifndef RTLD_LAZY
1252 #  define RTLD_LAZY 0
1253 #endif
1254 int glib_plugin_test;
1255 int main () {
1256     void *handle, *global, *local;
1257     global = &glib_plugin_test;
1258     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1259     if (!handle) return 0;
1260     local = dlsym (handle, "glib_plugin_test");
1261     return global == local;
1262 }                       ],
1263                         [glib_cv_rtldglobal_broken=no],
1264                         [glib_cv_rtldglobal_broken=yes],
1265                         [glib_cv_rtldglobal_broken=no])
1266                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1267                 rmdir .libs 2>/dev/null
1268         ])
1269         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1270                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1271         else
1272                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1273         fi
1274 dnl *** check whether we need preceeding underscores
1275         AC_CACHE_CHECK([for preceeding underscore in symbols],
1276                 glib_cv_uscore,[
1277                 AC_TRY_RUN([#include <dlfcn.h>
1278                 int glib_underscore_test (void) { return 42; }
1279                 int main() {
1280                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1281                   handle = dlopen ((void*)0, 0);
1282                   if (handle) {
1283                     f1 = dlsym (handle, "glib_underscore_test");
1284                     f2 = dlsym (handle, "_glib_underscore_test");
1285                   } return (!f2 || f1);
1286                 }],
1287                         [glib_cv_uscore=yes],
1288                         [glib_cv_uscore=no],
1289                         [])
1290                 rm -f plugin.c plugin.$ac_objext plugin.lo
1291         ])
1292         GLIB_ASSERT_SET(glib_cv_uscore)
1293         if test "x$glib_cv_uscore" = "xyes"; then
1294                 G_MODULE_NEED_USCORE=1
1295         else
1296                 G_MODULE_NEED_USCORE=0
1297         fi
1298
1299         LDFLAGS="$LDFLAGS_orig"
1300 dnl *** check for having dlerror()
1301         AC_CHECK_FUNC(dlerror,
1302                 [G_MODULE_HAVE_DLERROR=1],
1303                 [G_MODULE_HAVE_DLERROR=0])
1304         LIBS="$LIBS_orig"
1305 fi
1306 dnl *** done, have we got an implementation?
1307 if test -z "$G_MODULE_IMPL"; then
1308         G_MODULE_IMPL=0
1309         G_MODULE_SUPPORTED=false
1310 else
1311         G_MODULE_SUPPORTED=true
1312 fi
1313
1314 AC_MSG_CHECKING(for the suffix of shared libraries)
1315 case "$host_os" in
1316   hpux9* | hpux10* | hpux11*)  # taken from ltconfig
1317     case "$host_cpu" in
1318       hppa*)
1319         glib_gmodule_suffix='sl'
1320         ;;
1321       ia64*)
1322         glib_gmodule_suffix='so'
1323         ;;
1324     esac
1325     ;;
1326   cygwin* | mingw*)
1327     glib_gmodule_suffix='dll'
1328     ;;
1329   aix*)
1330     glib_gmodule_suffix='a'
1331     ;;
1332   *)
1333     glib_gmodule_suffix='so'
1334     ;;
1335 esac
1336 AC_MSG_RESULT(.$glib_gmodule_suffix)
1337
1338 AC_SUBST(G_MODULE_SUPPORTED)
1339 AC_SUBST(G_MODULE_IMPL)
1340 AC_SUBST(G_MODULE_LIBS)
1341 AC_SUBST(G_MODULE_LIBS_EXTRA)
1342 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1343 AC_SUBST(G_MODULE_LDFLAGS)
1344 AC_SUBST(G_MODULE_HAVE_DLERROR)
1345 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1346 AC_SUBST(G_MODULE_NEED_USCORE)
1347 AC_SUBST(GLIB_DEBUG_FLAGS)
1348
1349 dnl **********************
1350 dnl *** g_spawn checks ***
1351 dnl **********************
1352
1353 AC_MSG_CHECKING(for gspawn implementation)
1354 case "$host" in
1355   *-*-mingw*)
1356     GSPAWN=gspawn-win32.lo
1357     ;;
1358   *)
1359     GSPAWN=gspawn.lo
1360     ;;
1361 esac
1362 AC_MSG_RESULT($GSPAWN)
1363 AC_SUBST(GSPAWN)
1364
1365 dnl *************************
1366 dnl *** GIOChannel checks ***
1367 dnl *************************
1368
1369 AC_MSG_CHECKING(for GIOChannel implementation)
1370 case "$host" in
1371   *-*-mingw*)
1372     GIO=giowin32.lo
1373     ;;
1374   *)
1375     GIO=giounix.lo
1376     ;;
1377 esac
1378 AC_MSG_RESULT($GIO)
1379 AC_SUBST(GIO)
1380
1381 dnl ****************************************
1382 dnl *** platform dependent source checks ***
1383 dnl ****************************************
1384
1385 AC_MSG_CHECKING(for platform-dependent source)
1386 case "$host" in
1387   *-*-cygwin*|*-*-mingw*)
1388     PLATFORMDEP=gwin32.lo
1389     ;;
1390   *)
1391     PLATFORMDEP=
1392     ;;
1393 esac
1394 AC_MSG_RESULT($PLATFORMDEP)
1395 AC_SUBST(PLATFORMDEP)
1396
1397 AC_MSG_CHECKING([whether to compile timeloop])
1398 case "$host" in
1399   *-*-cygwin*|*-*-mingw*|*-*-minix)
1400     enable_timeloop=no
1401     ;;
1402   *)
1403     enable_timeloop=yes
1404     ;;
1405 esac
1406 AC_MSG_RESULT($enable_timeloop)
1407 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1408
1409 AC_MSG_CHECKING([if building for some Win32 platform])
1410 case "$host" in
1411   *-*-mingw*|*-*-cygwin*)
1412     platform_win32=yes
1413     ;;
1414   *)
1415     platform_win32=no
1416     ;;
1417 esac
1418 AC_MSG_RESULT($platform_win32)
1419 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1420
1421 dnl ***********************
1422 dnl *** g_thread checks ***
1423 dnl ***********************
1424
1425 AC_ARG_WITH(threads,
1426            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/win32@:>@],
1427                            [specify a thread implementation to use])],
1428            [if test "x$with_threads" = x; then
1429                 want_threads=yes
1430             else
1431                 want_threads=$with_threads
1432             fi],
1433            [want_threads=yes])
1434 if test "x$enable_threads" = "xno"; then
1435         want_threads=no
1436 fi
1437
1438 dnl error and warning message
1439 dnl *************************
1440
1441 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1442                 computer. GLib will not have a default thread implementation."
1443
1444 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1445                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1446                 compilation now, but then your programs might not work.
1447                 Please provide information on how it is done on your system."
1448
1449 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1450                 "
1451
1452 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1453                 provide information on your thread implementation.
1454                 You can also run 'configure --disable-threads'
1455                 to compile without thread support."
1456
1457 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1458                 functions will not be MT-safe during their first call because
1459                 there is no working 'getpwuid_r' on your system."
1460
1461 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1462                 because there is no 'localtime_r' on your system."
1463
1464 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1465                 crude surrogate will be used. If you happen to know a
1466                 yield function for your system, please inform the GLib
1467                 developers."
1468
1469 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1470                 threads on your system. Thus threads can only have the default
1471                 priority. If you happen to know these main/max
1472                 priorities, please inform the GLib developers."
1473
1474 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1475                 linking threaded applications. As GLib cannot do that
1476                 automatically, you will get an linkg error everytime you are
1477                 not using the right compiler. In that case you have to relink
1478                 with the right compiler. Ususally just '_r' is appended
1479                 to the compiler name."
1480
1481 dnl determination of thread implementation
1482 dnl ***************************************
1483
1484 # have_threads=no   means no thread support
1485 # have_threads=none means no default thread implementation
1486
1487 have_threads=no
1488 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1489                                 || test "x$want_threads" = xdce; then
1490         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1491         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1492         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1493         glib_save_CPPFLAGS="$CPPFLAGS"
1494         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1495         if test "x$have_threads" = xno; then
1496                 AC_TRY_COMPILE([#include <pthread.h>],
1497                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1498                         have_threads=posix)
1499         fi
1500         if test "x$have_threads" = xno; then
1501                 AC_TRY_COMPILE([#include <pthread.h>],
1502                         [pthread_mutex_t m;
1503                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1504                         have_threads=dce)
1505         fi
1506         # Tru64Unix requires -pthread to find pthread.h. See #103020
1507         CPPFLAGS="$CPPFLAGS -pthread"
1508         if test "x$have_threads" = xno; then
1509         AC_TRY_COMPILE([#include <pthread.h>],
1510                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1511                        have_threads=posix)
1512         fi
1513         CPPFLAGS="$glib_save_CPPFLAGS"
1514 fi
1515 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1516         case $host in
1517                 *-*-mingw*)
1518                 have_threads=win32
1519                 ;;
1520         esac
1521 fi
1522 if test "x$want_threads" = xnone; then
1523         have_threads=none
1524 fi
1525
1526 AC_MSG_CHECKING(for thread implementation)
1527
1528 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1529         AC_MSG_RESULT(none available)
1530         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1531 else
1532         AC_MSG_RESULT($have_threads)
1533 fi
1534
1535
1536 dnl determination of G_THREAD_CFLAGS
1537 dnl ********************************
1538
1539 G_THREAD_LIBS=
1540 G_THREAD_LIBS_EXTRA=
1541 G_THREAD_CFLAGS=
1542
1543 dnl
1544 dnl Test program for basic POSIX threads functionality
1545 dnl
1546 m4_define([glib_thread_test],[
1547 #include <pthread.h>
1548 int check_me = 0;
1549 void* func(void* data) {check_me = 42; return &check_me;}
1550 int main()
1551  { pthread_t t;
1552    void *ret;
1553    pthread_create (&t, $1, func, 0);
1554    pthread_join (t, &ret);
1555    return (check_me != 42 || ret != &check_me);
1556 }])
1557
1558 dnl
1559 dnl Test program for sched_get_priority_min()
1560 dnl
1561 m4_define([glib_sched_priority_test],[
1562 #include <sched.h>
1563 #include <errno.h>
1564 int main() {
1565     errno = 0;
1566     return sched_get_priority_min(SCHED_OTHER)==-1
1567            && errno != 0;
1568 }])
1569
1570 if test x"$have_threads" != xno; then
1571
1572   if test x"$have_threads" = xposix; then
1573     # First we test for posix, whether -pthread or -pthreads do the trick as
1574     # both CPPFLAG and LIBS.
1575     # One of them does for most gcc versions and some other platforms/compilers
1576     # too and could be considered as the canonical way to go.
1577     case $host in
1578       *-*-cygwin*|*-*-darwin*)
1579          # skip cygwin and darwin -pthread or -pthreads test
1580          ;;
1581       *-solaris*)
1582         # These compiler/linker flags work with both Sun Studio and gcc
1583         # Sun Studio expands -mt to -D_REENTRANT and -lthread
1584         # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1585         G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1586         G_THREAD_LIBS="-lpthread -lthread"
1587         ;;
1588       *)
1589         for flag in pthread pthreads mt; do
1590           glib_save_CFLAGS="$CFLAGS"
1591           CFLAGS="$CFLAGS -$flag"
1592           AC_TRY_RUN(glib_thread_test(0),
1593                      glib_flag_works=yes,
1594                      glib_flag_works=no,
1595                      [AC_LINK_IFELSE(glib_thread_test(0),
1596                                      glib_flag_works=yes,
1597                                      glib_flag_works=no)])
1598           CFLAGS="$glib_save_CFLAGS"
1599           if test $glib_flag_works = yes ; then
1600              G_THREAD_CFLAGS=-$flag
1601              G_THREAD_LIBS=-$flag
1602              break;
1603           fi
1604         done
1605          ;;
1606     esac
1607   fi
1608
1609   if test x"$G_THREAD_CFLAGS" = x; then
1610
1611     # The canonical -pthread[s] does not work. Try something different.
1612
1613     case $host in
1614         *-aix*)
1615                 if test x"$GCC" = xyes; then
1616                         # GCC 3.0 and above needs -pthread.
1617                         # Should be coverd by the case above.
1618                         # GCC 2.x and below needs -mthreads
1619                         G_THREAD_CFLAGS="-mthreads"
1620                         G_THREAD_LIBS=$G_THREAD_CFLAGS
1621                 else
1622                         # We are probably using the aix compiler. Normaly a
1623                         # program would have to be compiled with the _r variant
1624                         # of the corresponding compiler, but we as GLib cannot
1625                         # do that: but the good news is that for compiling the
1626                         # only difference is the added -D_THREAD_SAFE compile
1627                         # option. This is according to the "C for AIX User's
1628                         # Guide".
1629                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
1630                 fi
1631                 ;;
1632         *-dg-dgux*)  # DG/UX
1633                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
1634                 ;;
1635         *-osf*)
1636                 # So we are using dce threads. posix threads are already
1637                 # catched above.
1638                 G_THREAD_CFLAGS="-threads"
1639                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1640                 ;;
1641         *-sysv5uw7*) # UnixWare 7
1642                 # We are not using gcc with -pthread. Catched above.
1643                 G_THREAD_CFLAGS="-Kthread"
1644                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1645                 ;;
1646         *-mingw*)
1647                 # No flag needed when using MSVCRT.DLL
1648                 G_THREAD_CFLAGS=""
1649                 ;;
1650         *)
1651                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1652                 ;;
1653     esac
1654
1655   fi
1656
1657     # if we are not finding the localtime_r function, then we probably are
1658     # not using the proper multithread flag
1659
1660     glib_save_CPPFLAGS="$CPPFLAGS"
1661     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1662
1663     # First we test, whether localtime_r is declared in time.h
1664     # directly. Then we test whether a macro localtime_r exists, in
1665     # which case localtime_r in the test program is replaced and thus
1666     # if we still find localtime_r in the output, it is not defined as
1667     # a macro.
1668
1669     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1670       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1671                                                            localtime_r(a,b)],
1672                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1673
1674     CPPFLAGS="$glib_save_CPPFLAGS"
1675
1676     AC_MSG_CHECKING(thread related cflags)
1677     AC_MSG_RESULT($G_THREAD_CFLAGS)
1678     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1679 fi
1680
1681 dnl determination of G_THREAD_LIBS
1682 dnl ******************************
1683
1684 mutex_has_default=no
1685 case $have_threads in
1686         posix|dce)
1687           glib_save_CPPFLAGS="$CPPFLAGS"
1688           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1689           if test x"$G_THREAD_LIBS" = x; then
1690             case $host in
1691               *-aix*)
1692                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
1693                 # probably using the aix compiler.
1694                 AC_MSG_WARN($AIX_COMPILE_INFO)
1695                 ;;
1696               *)
1697                 G_THREAD_LIBS=error
1698                 glib_save_LIBS="$LIBS"
1699                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
1700                         if test x"$thread_lib" = x; then
1701                                 add_thread_lib=""
1702                                 IN=""
1703                         else
1704                                 add_thread_lib="-l$thread_lib"
1705                                 IN=" in -l$thread_lib"
1706                         fi
1707                         if test x"$have_threads" = xposix; then
1708                                 defattr=0
1709                         else
1710                                 defattr=pthread_attr_default
1711                         fi
1712
1713                         LIBS="$add_thread_lib $glib_save_LIBS"
1714
1715                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
1716                         AC_TRY_RUN(glib_thread_test($defattr),
1717                                    glib_result=yes,
1718                                    glib_result=no,
1719                                    [AC_LINK_IFELSE(glib_thread_test($defattr),
1720                                                    glib_result=yes,
1721                                                    glib_result=no)])
1722                         AC_MSG_RESULT($glib_result)
1723
1724                         if test "$glib_result" = "yes" ; then
1725                           G_THREAD_LIBS="$add_thread_lib"
1726                           break
1727                         fi
1728                 done
1729                 if test "x$G_THREAD_LIBS" = xerror; then
1730                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1731                 fi
1732                 LIBS="$glib_save_LIBS"
1733                 ;;
1734             esac
1735           fi
1736
1737           glib_save_LIBS="$LIBS"
1738           for thread_lib in "" rt rte; do
1739             if test x"$thread_lib" = x; then
1740               add_thread_lib=""
1741               IN=""
1742             else
1743               add_thread_lib="-l$thread_lib"
1744               IN=" in -l$thread_lib"
1745             fi
1746             LIBS="$add_thread_lib $glib_save_LIBS"
1747
1748             AC_MSG_CHECKING(for sched_get_priority_min$IN)
1749             AC_TRY_RUN(glib_sched_priority_test,
1750                        glib_result=yes,
1751                        glib_result=no,
1752                        [AC_LINK_IFELSE(glib_sched_priority_test,
1753                                        glib_result=yes,
1754                                        glib_result=no)])
1755             AC_MSG_RESULT($glib_result)
1756
1757             if test "$glib_result" = "yes" ; then
1758                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
1759                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
1760                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
1761                break
1762             fi
1763           done
1764           LIBS="$glib_save_LIBS"
1765           mutex_has_default=yes
1766           mutex_default_type='pthread_mutex_t'
1767           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
1768           mutex_header_file='pthread.h'
1769           if test "x$have_threads" = "xposix"; then
1770             g_threads_impl="POSIX"
1771           else
1772             g_threads_impl="DCE"
1773             have_threads="posix"
1774           fi
1775           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
1776           CPPFLAGS="$glib_save_CPPFLAGS"
1777           ;;
1778         win32)
1779            g_threads_impl="WIN32"
1780            ;;
1781         none|no)
1782            g_threads_impl="NONE"
1783            ;;
1784         *)
1785            g_threads_impl="NONE"
1786            G_THREAD_LIBS=error
1787            ;;
1788 esac
1789
1790 if test "x$G_THREAD_LIBS" = xerror; then
1791         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1792 fi
1793
1794 case $host in
1795   *-*-beos*)
1796     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
1797     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1798     ;;
1799   *)
1800     ;;
1801 esac
1802
1803 AC_MSG_CHECKING(thread related libraries)
1804 AC_MSG_RESULT($G_THREAD_LIBS)
1805
1806 dnl check for mt safe function variants and some posix functions
1807 dnl ************************************************************
1808
1809 if test x"$have_threads" != xno; then
1810         glib_save_LIBS="$LIBS"
1811         # we are not doing the following for now, as this might require glib
1812         # to always be linked with the thread libs on some platforms.
1813         # LIBS="$LIBS $G_THREAD_LIBS"
1814         AC_CHECK_FUNCS(localtime_r)
1815         if test "$ac_cv_header_pwd_h" = "yes"; then
1816                 AC_CACHE_CHECK([for posix getpwuid_r],
1817                         ac_cv_func_posix_getpwuid_r,
1818                         [AC_TRY_RUN([
1819 #include <errno.h>
1820 #include <pwd.h>
1821 int main () {
1822     char buffer[10000];
1823     struct passwd pwd, *pwptr = &pwd;
1824     int error;
1825     errno = 0;
1826     error = getpwuid_r (0, &pwd, buffer,
1827                         sizeof (buffer), &pwptr);
1828    return (error < 0 && errno == ENOSYS)
1829            || error == ENOSYS;
1830 }                               ],
1831                                 [ac_cv_func_posix_getpwuid_r=yes],
1832                                 [ac_cv_func_posix_getpwuid_r=no])])
1833                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
1834                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
1835                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
1836                                 [Have POSIX function getpwuid_r])
1837                 else
1838                         AC_CACHE_CHECK([for nonposix getpwuid_r],
1839                                 ac_cv_func_nonposix_getpwuid_r,
1840                                 [AC_TRY_LINK([#include <pwd.h>],
1841                                         [char buffer[10000];
1842                                         struct passwd pwd;
1843                                         getpwuid_r (0, &pwd, buffer,
1844                                                         sizeof (buffer));],
1845                                         [ac_cv_func_nonposix_getpwuid_r=yes],
1846                                         [ac_cv_func_nonposix_getpwuid_r=no])])
1847                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
1848                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
1849                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
1850                                         [Have non-POSIX function getpwuid_r])
1851                         fi
1852                 fi
1853         fi
1854         LIBS="$G_THREAD_LIBS $LIBS"
1855         if test x"$have_threads" = xposix; then
1856                 glib_save_CPPFLAGS="$CPPFLAGS"
1857                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1858                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
1859                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
1860                 # This is not AC_CHECK_FUNC to also work with function
1861                 # name mangling in header files.
1862                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1863                 AC_TRY_LINK([#include <pthread.h>],
1864                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1865                         [AC_MSG_RESULT(yes)
1866                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1867                                   [Have function pthread_attr_setstacksize])],
1868                         [AC_MSG_RESULT(no)])
1869                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1870                 if test x"$posix_priority_min" = x; then
1871                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1872                                 PX_PRIO_MIN],,[
1873                                 posix_priority_min=PX_PRIO_MIN
1874                                 posix_priority_max=PX_PRIO_MAX])
1875                 fi
1876                 if test x"$posix_priority_min" = x; then
1877                         # AIX
1878                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
1879                                 PTHREAD_PRIO_MIN],,[
1880                                 posix_priority_min=PTHREAD_PRIO_MIN
1881                                 posix_priority_max=PTHREAD_PRIO_MAX])
1882                 fi
1883                 if test x"$posix_priority_min" = x; then
1884                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1885                                 PRI_OTHER_MIN],,[
1886                                 posix_priority_min=PRI_OTHER_MIN
1887                                 posix_priority_max=PRI_OTHER_MAX])
1888                 fi
1889                 if test x"$posix_priority_min" = x; then
1890                         AC_MSG_RESULT(none found)
1891                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1892                         posix_priority_min=-1
1893                         posix_priority_max=-1
1894                 else
1895                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1896                         AC_MSG_CHECKING(for pthread_setschedparam)
1897                         AC_TRY_LINK([#include <pthread.h>],
1898                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
1899                           [AC_MSG_RESULT(yes)
1900                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1901                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
1902                           [AC_MSG_RESULT(no)
1903                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
1904                 fi
1905                 posix_yield_func=none
1906                 AC_MSG_CHECKING(for posix yield function)
1907                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1908                                                         thr_yield; do
1909                         AC_TRY_LINK([#include <pthread.h>],
1910                                 [$yield_func()],
1911                                 [posix_yield_func="$yield_func"
1912                                 break])
1913                 done
1914                 if test x"$posix_yield_func" = xnone; then
1915                         AC_MSG_RESULT(none found)
1916                         AC_MSG_WARN($POSIX_NO_YIELD)
1917                         posix_yield_func="g_usleep(1000)"
1918                 else
1919                         AC_MSG_RESULT($posix_yield_func)
1920                         posix_yield_func="$posix_yield_func()"
1921                 fi
1922                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1923                 CPPFLAGS="$glib_save_CPPFLAGS"
1924
1925         elif test x"$have_threads" = xwin32; then
1926                 # It's a pointer to a private struct
1927                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
1928         fi
1929
1930         LIBS="$glib_save_LIBS"
1931
1932         # now spit out all the warnings.
1933         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1934            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1935                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1936         fi
1937         if test "$ac_cv_func_localtime_r" != "yes"; then
1938                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1939         fi
1940 fi
1941
1942 if test x"$glib_cv_sizeof_system_thread" = x; then
1943    # use a pointer as a fallback.
1944    GLIB_SIZEOF(,void *, system_thread)
1945 fi
1946
1947 #
1948 # Hack to deal with:
1949 #
1950 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
1951 #     building shared libraries with linux.
1952 #
1953 case $host in
1954   *-*-linux*)
1955     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
1956     ;;
1957   *)
1958     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
1959     ;;
1960 esac
1961
1962 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1963                    [Source file containing theread implementation])
1964 AC_SUBST(G_THREAD_CFLAGS)
1965 AC_SUBST(G_THREAD_LIBS)
1966 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
1967 AC_SUBST(G_THREAD_LIBS_EXTRA)
1968
1969 dnl **********************************************
1970 dnl *** GDefaultMutex setup and initialization ***
1971 dnl **********************************************
1972 dnl
1973 dnl if mutex_has_default = yes, we also got
1974 dnl mutex_default_type, mutex_default_init and mutex_header_file
1975 if test $mutex_has_default = yes ; then
1976         glib_save_CPPFLAGS="$CPPFLAGS"
1977         glib_save_LIBS="$LIBS"
1978         LIBS="$G_THREAD_LIBS $LIBS"
1979         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1980         GLIB_SIZEOF([#include <$mutex_header_file>],
1981                     $mutex_default_type,
1982                     gmutex)
1983         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1984                            $mutex_default_type,
1985                            gmutex,
1986                            $glib_cv_sizeof_gmutex,
1987                            $mutex_default_init)
1988         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1989                 mutex_has_default=no
1990         fi
1991         CPPFLAGS="$glib_save_CPPFLAGS"
1992         LIBS="$glib_save_LIBS"
1993 fi
1994
1995 AC_CHECK_FUNCS(clock_gettime, [], [
1996   AC_CHECK_LIB(rt, clock_gettime, [
1997     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
1998     LIBS="$LIBS -lrt"
1999   ])
2000 ])
2001
2002 AC_CACHE_CHECK(for monotonic clocks,
2003     glib_cv_monotonic_clock,AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
2004 #include <time.h>
2005 #include <unistd.h>
2006 int main() {
2007 #if !(defined(_POSIX_MONOTONIC_CLOCK) && _POSIX_MONOTONIC_CLOCK >= 0 && defined(CLOCK_MONOTONIC))
2008         #error No monotonic clock
2009 #endif
2010         return 0;
2011 }
2012 ]])],glib_cv_monotonic_clock=yes,glib_cv_monotonic_clock=no))
2013 if test "$glib_cv_monotonic_clock" = "yes"; then
2014   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
2015 fi
2016
2017
2018 dnl ********************************
2019 dnl *** g_atomic_* tests for gcc ***
2020 dnl ********************************
2021
2022 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
2023
2024 if test x"$GCC" = xyes; then
2025   case $host_cpu in
2026     i386)
2027       AC_MSG_RESULT([none])
2028       glib_memory_barrier_needed=no
2029       ;;
2030     i?86)
2031       AC_MSG_RESULT([i486])
2032       AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
2033                          [i486 atomic implementation])
2034       glib_memory_barrier_needed=no
2035       ;;
2036     sparc*)
2037       SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
2038                 when you are using a sparc with v9 instruction set (most
2039                 sparcs nowadays). This will make the code for atomic
2040                 operations much faster. The resulting code will not run
2041                 on very old sparcs though."
2042
2043       AC_LINK_IFELSE([[
2044         main ()
2045         {
2046           int tmp1, tmp2, tmp3;
2047           __asm__ __volatile__("casx [%2], %0, %1"
2048                                : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
2049         }]],
2050         AC_MSG_RESULT([sparcv9])
2051         AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
2052                            [sparcv9 atomic implementation]),
2053         AC_MSG_RESULT([no])
2054         AC_MSG_WARN([[$SPARCV9_WARNING]]))
2055       glib_memory_barrier_needed=yes
2056       ;;
2057     alpha*)
2058       AC_MSG_RESULT([alpha])
2059       AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
2060                          [alpha atomic implementation])
2061       glib_memory_barrier_needed=yes
2062       ;;
2063     x86_64)
2064       AC_MSG_RESULT([x86_64])
2065       AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
2066                          [x86_64 atomic implementation])
2067       glib_memory_barrier_needed=no
2068      ;;
2069     powerpc*)
2070       AC_MSG_RESULT([powerpc])
2071       AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
2072                          [powerpc atomic implementation])
2073       glib_memory_barrier_needed=yes
2074       ;;
2075     ia64)
2076       AC_MSG_RESULT([ia64])
2077       AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
2078                          [ia64 atomic implementation])
2079       glib_memory_barrier_needed=yes
2080       ;;
2081     s390|s390x)
2082       AC_MSG_RESULT([s390])
2083       AC_DEFINE_UNQUOTED(G_ATOMIC_S390, 1,
2084                          [s390 atomic implementation])
2085       glib_memory_barrier_needed=no
2086       ;;
2087     *)
2088       AC_MSG_RESULT([none])
2089       glib_memory_barrier_needed=yes
2090       ;;
2091   esac
2092 fi
2093
2094 dnl ****************************************
2095 dnl *** GLib POLL* compatibility defines ***
2096 dnl ****************************************
2097
2098 glib_poll_includes=["
2099 #include <sys/types.h>
2100 #include <sys/poll.h>
2101 "]
2102
2103 if test $ac_cv_header_sys_types_h = yes &&
2104    test $ac_cv_header_sys_poll_h = yes ; then
2105   glib_failed=false
2106   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2107   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2108   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2109   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2110   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2111   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2112   if $glib_failed ; then
2113     AC_MSG_ERROR([Could not determine values for POLL* constants])
2114   fi
2115 else
2116   glib_cv_value_POLLIN=1
2117   glib_cv_value_POLLOUT=4
2118   glib_cv_value_POLLPRI=2
2119   glib_cv_value_POLLERR=8
2120   glib_cv_value_POLLHUP=16
2121   glib_cv_value_POLLNVAL=32
2122 fi
2123
2124 # Check for Mac OS X's broken poll
2125 if test $cross_compiling != yes ; then
2126   AC_MSG_CHECKING(for broken poll)
2127   AC_TRY_RUN([[
2128         #include <stdlib.h>
2129         #include <fcntl.h>
2130         #include <poll.h>
2131         int main(void) {
2132           struct pollfd fds[1];
2133           int fd;
2134           fd = open("/dev/null", 1);
2135           fds[0].fd = fd;
2136           fds[0].events = POLLIN;
2137           fds[0].revents = 0;
2138           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2139                 exit(1);  /* Does not work for devices -- fail */
2140           }
2141           exit(0);
2142         }]],
2143     broken_poll=no,
2144     broken_poll=yes
2145     AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])
2146   )
2147   AC_MSG_RESULT($broken_poll)
2148 fi
2149
2150 dnl **********************
2151 dnl *** Win32 API libs ***
2152 dnl **********************
2153
2154 case $host in
2155   *-*-cygwin*)
2156         G_LIBS_EXTRA="-luser32 -lkernel32"
2157     ;;
2158   *-*-mingw*)
2159         G_LIBS_EXTRA="-lws2_32 -lole32"
2160     ;;
2161   *)
2162         G_LIBS_EXTRA=""
2163     ;;
2164 esac
2165 AC_SUBST(G_LIBS_EXTRA)
2166
2167 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2168 dnl since we need it for g_iconv()
2169
2170 AC_MSG_CHECKING([for EILSEQ])
2171 AC_TRY_COMPILE([
2172 #include <errno.h>
2173 ],
2174 [
2175 int error = EILSEQ;
2176 ], have_eilseq=yes, have_eilseq=no);
2177 AC_MSG_RESULT($have_eilseq)
2178
2179 dnl ******************************************************************
2180 dnl *** Look for glib-genmarshal in PATH if we are cross-compiling ***
2181 dnl ******************************************************************
2182
2183 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2184
2185 if test $cross_compiling = yes; then
2186   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2187   if test x$GLIB_GENMARSHAL = xno; then
2188     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2189   fi
2190 fi
2191
2192 dnl **************************
2193 dnl *** Checks for gtk-doc ***
2194 dnl **************************
2195
2196 GTK_DOC_CHECK([1.4])
2197
2198 AC_ARG_ENABLE(man,
2199               [AC_HELP_STRING([--enable-man],
2200                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2201               enable_man=no)
2202
2203 if test "${enable_man}" != no; then
2204 dnl
2205 dnl Check for xsltproc
2206 dnl
2207 AC_PATH_PROG([XSLTPROC], [xsltproc])
2208   if test -z "$XSLTPROC"; then
2209     enable_man=no
2210   fi
2211
2212   dnl check for DocBook DTD and stylesheets in the local catalog.
2213   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2214      [DocBook XML DTD V4.1.2],,enable_man=no)
2215   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2216      [DocBook XSL Stylesheets],,enable_man=no)
2217 fi
2218
2219 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2220
2221 dnl ******************************
2222 dnl *** output the whole stuff ***
2223 dnl ******************************
2224
2225 dnl this section will only be run if config.status is invoked with no
2226 dnl arguments, or with "glibconfig.h" as an argument.
2227 AC_CONFIG_COMMANDS([glibconfig.h],
2228 [
2229         outfile=glibconfig.h-tmp
2230         cat > $outfile <<\_______EOF
2231 /* glibconfig.h
2232  *
2233  * This is a generated file.  Please modify 'configure.in'
2234  */
2235
2236 #ifndef __G_LIBCONFIG_H__
2237 #define __G_LIBCONFIG_H__
2238
2239 #include <glib/gmacros.h>
2240
2241 _______EOF
2242
2243         if test x$glib_limits_h = xyes; then
2244           echo '#include <limits.h>' >> $outfile
2245         fi
2246         if test x$glib_float_h = xyes; then
2247           echo '#include <float.h>' >> $outfile
2248         fi
2249         if test x$glib_values_h = xyes; then
2250           echo '#include <values.h>' >> $outfile
2251         fi
2252         if test "$glib_header_alloca_h" = "yes"; then
2253           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2254         fi
2255         if test x$glib_sys_poll_h = xyes; then
2256           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2257         fi
2258
2259         cat >> $outfile <<_______EOF
2260
2261 G_BEGIN_DECLS
2262
2263 #define G_MINFLOAT      $glib_mf
2264 #define G_MAXFLOAT      $glib_Mf
2265 #define G_MINDOUBLE     $glib_md
2266 #define G_MAXDOUBLE     $glib_Md
2267 #define G_MINSHORT      $glib_ms
2268 #define G_MAXSHORT      $glib_Ms
2269 #define G_MAXUSHORT     $glib_Mus
2270 #define G_MININT        $glib_mi
2271 #define G_MAXINT        $glib_Mi
2272 #define G_MAXUINT       $glib_Mui
2273 #define G_MINLONG       $glib_ml
2274 #define G_MAXLONG       $glib_Ml
2275 #define G_MAXULONG      $glib_Mul
2276
2277 _______EOF
2278
2279
2280         ### this should always be true in a modern C/C++ compiler
2281         cat >>$outfile <<_______EOF
2282 typedef signed char gint8;
2283 typedef unsigned char guint8;
2284 _______EOF
2285
2286
2287         if test -n "$gint16"; then
2288           cat >>$outfile <<_______EOF
2289 typedef signed $gint16 gint16;
2290 typedef unsigned $gint16 guint16;
2291 #define G_GINT16_MODIFIER $gint16_modifier
2292 #define G_GINT16_FORMAT $gint16_format
2293 #define G_GUINT16_FORMAT $guint16_format
2294 _______EOF
2295         fi
2296
2297
2298         if test -n "$gint32"; then
2299           cat >>$outfile <<_______EOF
2300 typedef signed $gint32 gint32;
2301 typedef unsigned $gint32 guint32;
2302 #define G_GINT32_MODIFIER $gint32_modifier
2303 #define G_GINT32_FORMAT $gint32_format
2304 #define G_GUINT32_FORMAT $guint32_format
2305 _______EOF
2306         fi
2307
2308         cat >>$outfile <<_______EOF
2309 #define G_HAVE_GINT64 1          /* deprecated, always true */
2310
2311 ${glib_extension}typedef signed $gint64 gint64;
2312 ${glib_extension}typedef unsigned $gint64 guint64;
2313
2314 #define G_GINT64_CONSTANT(val)  $gint64_constant
2315 #define G_GUINT64_CONSTANT(val) $guint64_constant
2316 _______EOF
2317
2318         if test x$gint64_format != x ; then
2319           cat >>$outfile <<_______EOF
2320 #define G_GINT64_MODIFIER $gint64_modifier
2321 #define G_GINT64_FORMAT $gint64_format
2322 #define G_GUINT64_FORMAT $guint64_format
2323 _______EOF
2324         else
2325           cat >>$outfile <<_______EOF
2326 #undef G_GINT64_MODIFIER
2327 #undef G_GINT64_FORMAT
2328 #undef G_GUINT64_FORMAT
2329 _______EOF
2330         fi
2331
2332         cat >>$outfile <<_______EOF
2333
2334 #define GLIB_SIZEOF_VOID_P $glib_void_p
2335 #define GLIB_SIZEOF_LONG   $glib_long
2336 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2337
2338 _______EOF
2339
2340         cat >>$outfile <<_______EOF
2341 typedef signed $glib_size_type_define gssize;
2342 typedef unsigned $glib_size_type_define gsize;
2343 #define G_GSIZE_MODIFIER $gsize_modifier
2344 #define G_GSSIZE_FORMAT $gssize_format
2345 #define G_GSIZE_FORMAT $gsize_format
2346
2347 #define G_MAXSIZE       G_MAXU$glib_msize_type
2348 _______EOF
2349
2350         if test -z "$glib_unknown_void_p"; then
2351           cat >>$outfile <<_______EOF
2352
2353 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2354 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2355
2356 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2357 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2358 _______EOF
2359         else
2360           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2361         fi
2362
2363
2364
2365         cat >>$outfile <<_______EOF
2366 $glib_atexit
2367 $glib_memmove
2368 $glib_defines
2369 $glib_os
2370
2371 $glib_vacopy
2372
2373 #ifdef  __cplusplus
2374 #define G_HAVE_INLINE   1
2375 #else   /* !__cplusplus */
2376 $glib_inline
2377 #endif  /* !__cplusplus */
2378
2379 #ifdef  __cplusplus
2380 #define G_CAN_INLINE    1
2381 _______EOF
2382
2383         if test x$g_can_inline = xyes ; then
2384                 cat >>$outfile <<_______EOF
2385 #else   /* !__cplusplus */
2386 #define G_CAN_INLINE    1
2387 _______EOF
2388         fi
2389
2390         cat >>$outfile <<_______EOF
2391 #endif
2392
2393 _______EOF
2394
2395         if test x$g_have_iso_c_varargs = xyes ; then
2396                 cat >>$outfile <<_______EOF
2397 #ifndef __cplusplus
2398 # define G_HAVE_ISO_VARARGS 1
2399 #endif
2400 _______EOF
2401         fi
2402         if test x$g_have_iso_cxx_varargs = xyes ; then
2403                 cat >>$outfile <<_______EOF
2404 #ifdef __cplusplus
2405 # define G_HAVE_ISO_VARARGS 1
2406 #endif
2407 _______EOF
2408         fi
2409         if test x$g_have_gnuc_varargs = xyes ; then
2410                 cat >>$outfile <<_______EOF
2411
2412 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2413  * is passed ISO vararg support is turned off, and there is no work
2414  * around to turn it on, so we unconditionally turn it off.
2415  */
2416 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2417 #  undef G_HAVE_ISO_VARARGS
2418 #endif
2419
2420 #define G_HAVE_GNUC_VARARGS 1
2421 _______EOF
2422         fi
2423
2424         case x$g_stack_grows in
2425         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2426         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2427         esac
2428
2429
2430         echo >>$outfile
2431         if test x$g_have_eilseq = xno; then
2432                 cat >>$outfile <<_______EOF
2433 #ifndef EILSEQ
2434 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2435  * The correspondence between this and the corresponding definition
2436  * in libiconv is essential.
2437  */
2438 #  define EILSEQ ENOENT
2439 #endif
2440 _______EOF
2441
2442         fi
2443
2444         if test x$g_have_gnuc_visibility = xyes ; then
2445                 cat >>$outfile <<_______EOF
2446 #define G_HAVE_GNUC_VISIBILITY 1
2447 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2448 _______EOF
2449         else
2450                 cat >>$outfile <<_______EOF
2451 #define G_GNUC_INTERNAL
2452 _______EOF
2453         fi
2454
2455
2456         echo >>$outfile
2457         if test x$g_mutex_has_default = xyes; then
2458                 cat >>$outfile <<_______EOF
2459 $g_enable_threads_def G_THREADS_ENABLED
2460 #define G_THREADS_IMPL_$g_threads_impl_def
2461 typedef struct _GStaticMutex GStaticMutex;
2462 struct _GStaticMutex
2463 {
2464   struct _GMutex *runtime_mutex;
2465   union {
2466     char   pad[[$g_mutex_sizeof]];
2467     double dummy_double;
2468     void  *dummy_pointer;
2469     long   dummy_long;
2470   } static_mutex;
2471 };
2472 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
2473 #define g_static_mutex_get_mutex(mutex) \\
2474   (g_thread_use_default_impl ? ((GMutex*) ((mutex)->static_mutex.pad)) : \\
2475    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
2476 _______EOF
2477         else
2478                 cat >>$outfile <<_______EOF
2479 $g_enable_threads_def G_THREADS_ENABLED
2480 #define G_THREADS_IMPL_$g_threads_impl_def
2481 typedef struct _GMutex* GStaticMutex;
2482 #define G_STATIC_MUTEX_INIT NULL
2483 #define g_static_mutex_get_mutex(mutex) \\
2484   (g_static_mutex_get_mutex_impl_shortcut (mutex))
2485 _______EOF
2486         fi
2487
2488         cat >>$outfile <<_______EOF
2489 /* This represents a system thread as used by the implementation. An
2490  * alien implementaion, as loaded by g_thread_init can only count on
2491  * "sizeof (gpointer)" bytes to store their info. We however need more
2492  * for some of our native implementations. */
2493 typedef union _GSystemThread GSystemThread;
2494 union _GSystemThread
2495 {
2496   char   data[[$g_system_thread_sizeof]];
2497   double dummy_double;
2498   void  *dummy_pointer;
2499   long   dummy_long;
2500 };
2501 _______EOF
2502         if test x"$g_memory_barrier_needed" != xno; then
2503           echo >>$outfile
2504           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2505         fi
2506
2507         echo >>$outfile
2508         g_bit_sizes="16 32 64"
2509         for bits in $g_bit_sizes; do
2510           cat >>$outfile <<_______EOF
2511 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
2512 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
2513 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2514 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
2515 _______EOF
2516         done
2517
2518         cat >>$outfile <<_______EOF
2519 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
2520 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
2521 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
2522 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
2523 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
2524 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
2525 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
2526 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
2527 #define G_BYTE_ORDER $g_byte_order
2528
2529 #define GLIB_SYSDEF_POLLIN =$g_pollin
2530 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2531 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2532 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2533 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2534 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2535
2536 #define G_MODULE_SUFFIX "$g_module_suffix"
2537
2538 typedef $g_pid_type GPid;
2539
2540 G_END_DECLS
2541
2542 #endif /* GLIBCONFIG_H */
2543 _______EOF
2544
2545
2546         if cmp -s $outfile glibconfig.h; then
2547           AC_MSG_NOTICE([glibconfig.h is unchanged])
2548           rm -f $outfile
2549         else
2550           mv $outfile glibconfig.h
2551         fi
2552 ],[
2553
2554 # Note that if two cases are the same, case goes with the first one.
2555 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
2556 # on variable expansion in case labels.  Look at the generated config.status
2557 # for a hint.
2558
2559 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2560   glib_header_alloca_h="$ac_cv_working_alloca_h"
2561 else
2562   glib_header_alloca_h="$ac_cv_header_alloca_h"
2563 fi
2564
2565 case xyes in
2566 x$ac_cv_header_float_h)
2567   glib_float_h=yes
2568   glib_mf=FLT_MIN glib_Mf=FLT_MAX
2569   glib_md=DBL_MIN glib_Md=DBL_MAX
2570   ;;
2571 x$ac_cv_header_values_h)
2572   glib_values_h=yes
2573   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
2574   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
2575   ;;
2576 esac
2577
2578 case xyes in
2579 x$ac_cv_header_limits_h)
2580   glib_limits_h=yes
2581   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
2582   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
2583   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
2584   ;;
2585 x$ac_cv_header_values_h)
2586   glib_values_h=yes
2587   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
2588   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
2589   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
2590   ;;
2591 esac
2592
2593 if test x$ac_cv_header_sys_poll_h = xyes ; then
2594   glib_sys_poll_h=yes
2595 fi
2596
2597 case 2 in
2598 $ac_cv_sizeof_short)
2599   gint16=short
2600   gint16_modifier='"h"'
2601   gint16_format='"hi"'
2602   guint16_format='"hu"'
2603   ;;
2604 $ac_cv_sizeof_int)
2605   gint16=int
2606   gint16_modifier='""'
2607   gint16_format='"i"'
2608   guint16_format='"u"'
2609   ;;
2610 esac
2611 case 4 in
2612 $ac_cv_sizeof_short)
2613   gint32=short
2614   gint32_modifier='"h"'
2615   gint32_format='"hi"'
2616   guint32_format='"hu"'
2617   ;;
2618 $ac_cv_sizeof_int)
2619   gint32=int
2620   gint32_modifier='""'
2621   gint32_format='"i"'
2622   guint32_format='"u"'
2623   ;;
2624 $ac_cv_sizeof_long)
2625   gint32=long
2626   gint32_modifier='"l"'
2627   gint32_format='"li"'
2628   guint32_format='"lu"'
2629   ;;
2630 esac
2631 case 8 in
2632 $ac_cv_sizeof_int)
2633   gint64=int
2634   gint64_modifier='""'
2635   gint64_format='"i"'
2636   guint64_format='"u"'
2637   glib_extension=
2638   gint64_constant='(val)'
2639   guint64_constant='(val)'
2640   ;;
2641 $ac_cv_sizeof_long)
2642   gint64=long
2643   gint64_modifier='"l"'
2644   gint64_format='"li"'
2645   guint64_format='"lu"'
2646   glib_extension=
2647   gint64_constant='(val##L)'
2648   guint64_constant='(val##UL)'
2649   ;;
2650 $ac_cv_sizeof_long_long)
2651   gint64='long long'
2652   if test -n "$glib_cv_long_long_format"; then
2653     gint64_modifier='"'$glib_cv_long_long_format'"'
2654     gint64_format='"'$glib_cv_long_long_format'i"'
2655     guint64_format='"'$glib_cv_long_long_format'u"'
2656   fi
2657   glib_extension='G_GNUC_EXTENSION '
2658   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
2659   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
2660   ;;
2661 $ac_cv_sizeof___int64)
2662   gint64='__int64'
2663   if test -n "$glib_cv_long_long_format"; then
2664     gint64_modifier='"'$glib_cv_long_long_format'"'
2665     gint64_format='"'$glib_cv_long_long_format'i"'
2666     guint64_format='"'$glib_cv_long_long_format'u"'
2667   fi
2668   glib_extension=
2669   gint64_constant='(val##i64)'
2670   guint64_constant='(val##ui64)'
2671   ;;
2672 esac
2673 glib_size_t=$ac_cv_sizeof_size_t
2674 glib_size_type_define=$glib_size_type
2675 glib_void_p=$ac_cv_sizeof_long
2676 glib_long=$ac_cv_sizeof_void_p
2677
2678 case $glib_size_type in
2679 short)
2680   gsize_modifier='"h"'
2681   gsize_format='"hu"'
2682   gssize_format='"hi"'
2683   glib_msize_type='SHRT'
2684   ;;
2685 int)
2686   gsize_modifier='""'
2687   gsize_format='"u"'
2688   gssize_format='"i"'
2689   glib_msize_type='INT'
2690   ;;
2691 long)
2692   gsize_modifier='"l"'
2693   gsize_format='"lu"'
2694   gssize_format='"li"'
2695   glib_msize_type='LONG'
2696   ;;
2697 esac
2698
2699 gintbits=`expr $ac_cv_sizeof_int \* 8`
2700 glongbits=`expr $ac_cv_sizeof_long \* 8`
2701
2702
2703 case $ac_cv_sizeof_void_p in
2704 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
2705 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
2706 *)                      glib_unknown_void_p=yes ;;
2707 esac
2708
2709
2710 case xyes in
2711 x$ac_cv_func_atexit)
2712   glib_atexit="
2713 #ifdef NeXT /* @#%@! NeXTStep */
2714 # define g_ATEXIT(proc) (!atexit (proc))
2715 #else
2716 # define g_ATEXIT(proc) (atexit (proc))
2717 #endif"
2718   ;;
2719 x$ac_cv_func_on_exit)
2720   glib_atexit="
2721 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
2722   ;;
2723 esac
2724
2725 case xyes in
2726 x$ac_cv_func_memmove)
2727   glib_memmove='
2728 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
2729   ;;
2730 x$glib_cv_working_bcopy)
2731   glib_memmove="
2732 /* memmove isn't available, but bcopy can copy overlapping memory regions */
2733 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
2734   ;;
2735 *)
2736   glib_memmove="
2737 /* memmove isn't found and bcopy can't copy overlapping memory regions,
2738  * so we have to roll our own copy routine. */
2739 void g_memmove (void* dest, const void * src, unsigned long len);"
2740   ;;
2741 esac
2742
2743 glib_defines="
2744 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
2745 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
2746 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
2747 "
2748
2749 case xyes in
2750 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
2751 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
2752 *)                      glib_vacopy=''
2753 esac
2754
2755 if test x$glib_cv_va_val_copy = xno; then
2756   glib_vacopy="\$glib_vacopy
2757 #define G_VA_COPY_AS_ARRAY 1"
2758 fi
2759
2760 if test x$glib_cv_hasinline = xyes; then
2761     glib_inline='#define G_HAVE_INLINE 1'
2762 fi
2763 if test x$glib_cv_has__inline = xyes; then
2764     glib_inline="\$glib_inline
2765 #define G_HAVE___INLINE 1"
2766 fi
2767 if test x$glib_cv_has__inline__ = xyes; then
2768     glib_inline="\$glib_inline
2769 #define G_HAVE___INLINE__ 1"
2770 fi
2771
2772 g_have_gnuc_varargs=$g_have_gnuc_varargs
2773 g_have_iso_c_varargs=$g_have_iso_c_varargs
2774 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
2775
2776 g_can_inline=$g_can_inline
2777 g_have_gnuc_visibility=$g_have_gnuc_visibility
2778
2779 case xyes in
2780 x$ac_cv_c_bigendian)
2781   g_byte_order=G_BIG_ENDIAN
2782   g_bs_native=BE
2783   g_bs_alien=LE
2784   ;;
2785 *)
2786   g_byte_order=G_LITTLE_ENDIAN
2787   g_bs_native=LE
2788   g_bs_alien=BE
2789   ;;
2790 esac
2791
2792 g_pollin=$glib_cv_value_POLLIN
2793 g_pollout=$glib_cv_value_POLLOUT
2794 g_pollpri=$glib_cv_value_POLLPRI
2795 g_pollhup=$glib_cv_value_POLLHUP
2796 g_pollerr=$glib_cv_value_POLLERR
2797 g_pollnval=$glib_cv_value_POLLNVAL
2798
2799 g_stack_grows=$glib_cv_stack_grows
2800
2801 g_have_eilseq=$have_eilseq
2802
2803 case x$have_threads in
2804 xno)    g_enable_threads_def="#undef";;
2805 *)      g_enable_threads_def="#define";;
2806 esac
2807
2808 g_threads_impl_def=$g_threads_impl
2809
2810 g_mutex_has_default="$mutex_has_default"
2811 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
2812 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
2813 g_mutex_contents="$glib_cv_byte_contents_gmutex"
2814
2815 g_memory_barrier_needed="$glib_memory_barrier_needed"
2816
2817 g_module_suffix="$glib_gmodule_suffix"
2818
2819 g_pid_type="$glib_pid_type"
2820 case $host in
2821   *-*-beos*)
2822     glib_os="#define G_OS_BEOS"
2823     ;;
2824   *-*-cygwin*)
2825     glib_os="#define G_OS_UNIX
2826 #define G_PLATFORM_WIN32
2827 #define G_WITH_CYGWIN"
2828     ;;
2829   *-*-mingw*)
2830     glib_os="#define G_OS_WIN32
2831 #define G_PLATFORM_WIN32"
2832     ;;
2833   *)
2834     glib_os="#define G_OS_UNIX"
2835     ;;
2836 esac
2837 ])
2838
2839 AC_CONFIG_FILES([
2840 glib-2.0.pc
2841 glib-2.0-uninstalled.pc
2842 gmodule-2.0.pc
2843 gmodule-export-2.0.pc
2844 gmodule-no-export-2.0.pc
2845 gmodule-2.0-uninstalled.pc
2846 gmodule-no-export-2.0-uninstalled.pc
2847 gthread-2.0.pc
2848 gthread-2.0-uninstalled.pc
2849 gobject-2.0.pc
2850 gobject-2.0-uninstalled.pc
2851 glib-zip
2852 glib-gettextize
2853 Makefile
2854 build/Makefile
2855 build/win32/Makefile
2856 build/win32/dirent/Makefile
2857 build/win32/vs8/Makefile
2858 glib/Makefile
2859 glib/libcharset/Makefile
2860 glib/gnulib/Makefile
2861 gmodule/Makefile
2862 gmodule/gmoduleconf.h
2863 gobject/Makefile
2864 gobject/glib-mkenums
2865 gthread/Makefile
2866 po/Makefile.in
2867 docs/Makefile
2868 docs/reference/Makefile
2869 docs/reference/glib/Makefile
2870 docs/reference/glib/version.xml
2871 docs/reference/gobject/Makefile
2872 docs/reference/gobject/version.xml
2873 tests/Makefile
2874 tests/gobject/Makefile
2875 tests/refcount/Makefile
2876 m4macros/Makefile
2877 ])
2878
2879 AC_CONFIG_COMMANDS([chmod-scripts],
2880 [chmod 0755 glib-zip
2881 chmod 0755 glib-gettextize
2882 chmod 0755 gobject/glib-mkenums])
2883
2884 # we want to invoke this macro solely so that the config.status script
2885 # and automake generated makefiles know about these generated files.
2886 # They are only needed to distcheck the package
2887 if false; then
2888   AC_CONFIG_FILES([
2889     INSTALL
2890     README
2891     config.h.win32
2892     glibconfig.h.win32
2893     glib/makefile.msc
2894     glib/glib.rc
2895     gmodule/makefile.msc
2896     gmodule/gmodule.rc
2897     gobject/makefile.msc
2898     gobject/gobject.rc
2899     gthread/makefile.msc
2900     gthread/gthread.rc
2901     tests/makefile.msc
2902   ])
2903 fi
2904
2905 AC_OUTPUT