configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5
   6 # require autoconf 2.13
   7 AC_PREREQ(2.13)
   8
   9 # Process this file with autoconf to produce a configure script.
  10 AC_INIT(glist.c)
  11
  12 # Save this value here, since automake will set cflags later
  13 cflags_set=${CFLAGS+set}
  14
  15 # we rewrite this file
  16 rm -f glibconfig-sysdefs.h
  17
  18 dnl we need to AC_DIVERT_PUSH/AC_DIVERT_POP these variable definitions so they
  19 dnl are available for $ac_help expansion (don't we all *love* autoconf?)
  20 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  21 #
  22 # The following version number definitions apply to GLib, GModule and GThread
  23 # as a whole, so if changes occoured in any of them, they are all
  24 # treated with the same interface and binary age.
  25 #
  26 # Making releases:
  27 #   GLIB_MICRO_VERSION += 1;
  28 #   GLIB_INTERFACE_AGE += 1;
  29 #   GLIB_BINARY_AGE += 1;
  30 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  31 # if backwards compatibility has been broken,
  32 # set GLIB_BINARY_AGE _and_ GLIB_INTERFACE_AGE to 0.
  33 #
  34 GLIB_MAJOR_VERSION=1
  35 GLIB_MINOR_VERSION=3
  36 GLIB_MICRO_VERSION=1
  37 GLIB_INTERFACE_AGE=0
  38 GLIB_BINARY_AGE=0
  39 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  40 dnl
  41 AC_DIVERT_POP()dnl
  42
  43 AC_SUBST(GLIB_MAJOR_VERSION)
  44 AC_SUBST(GLIB_MINOR_VERSION)
  45 AC_SUBST(GLIB_MICRO_VERSION)
  46 AC_SUBST(GLIB_VERSION)
  47 AC_SUBST(GLIB_INTERFACE_AGE)
  48 AC_SUBST(GLIB_BINARY_AGE)
  49
  50 # libtool versioning
  51 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  52 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  53 LT_REVISION=$GLIB_INTERFACE_AGE
  54 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  55 AC_SUBST(LT_RELEASE)
  56 AC_SUBST(LT_CURRENT)
  57 AC_SUBST(LT_REVISION)
  58 AC_SUBST(LT_AGE)
  59
  60 VERSION=$GLIB_VERSION
  61 PACKAGE=glib
  62
  63 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  64
  65 # Specify a configuration file
  66 AM_CONFIG_HEADER(config.h)
  67
  68 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION)
  69 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION)
  70 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION)
  71 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE)
  72 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE)
  73
  74 dnl Initialize libtool
  75 AM_PROG_LIBTOOL
  76
  77 dnl Initialize maintainer mode
  78 AM_MAINTAINER_MODE
  79
  80 AC_CANONICAL_HOST
  81
  82 AC_MSG_CHECKING(for the BeOS)
  83 case $host in
  84   *-*-beos*)
  85     glib_native_beos="yes"
  86     ;;
  87   *)
  88     glib_native_beos="no"
  89     ;;
  90 esac
  91 AC_MSG_RESULT([$glib_native_beos])
  92
  93 dnl figure debugging default, prior to $ac_help setup
  94 dnl
  95 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  96 if test `expr $GLIB_MINOR_VERSION \% 2` = 1 ; then
  97         debug_default=yes
  98 else
  99         debug_default=minimum
 100 fi
 101 AC_DIVERT_POP()dnl
 102
 103 dnl declare --enable-* args and collect ac_help strings
 104 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
 105 AC_ARG_ENABLE(msg-prefix, [  --enable-msg-prefix     turn on program name and PID prefixing of messages and warnings],,enable_msg_prefix=no)
 106 AC_ARG_ENABLE(mem_check, [  --enable-mem-check      turn on malloc/free sanity checking [default=no]],,enable_mem_check=no)
 107 AC_ARG_ENABLE(mem_profile, [  --enable-mem-profile    turn on malloc profiling atexit [default=no]],,enable_mem_profile=no)
 108 AC_ARG_ENABLE(gc_friendly, [  --enable-gc-friendly    turn on garbage collector friendliness [default=no]],,enable_gc_friendly=no)
 109 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
 110                     , enable_ansi=no)
 111 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
 112                           ([=no] will override --with-threads)],,enable_threads=yes)
 113
 114 if test "x$enable_threads" != "xyes"; then
 115   enable_threads=no
 116 fi
 117
 118 AC_MSG_CHECKING(whether to enable memory checking)
 119 if test "x$enable_mem_check" = "xyes"; then
 120   AC_DEFINE(ENABLE_MEM_CHECK, 1)
 121   AC_SUBST(ENABLE_MEM_CHECK)
 122   AC_MSG_RESULT(yes)
 123 else
 124   AC_MSG_RESULT(no)
 125 fi
 126
 127 AC_MSG_CHECKING(whether to enable memory profiling)
 128 if test "x$enable_mem_profile" = "xyes"; then
 129   AC_DEFINE(ENABLE_MEM_PROFILE, 1)
 130   AC_SUBST(ENABLE_MEM_PROFILE)
 131   AC_MSG_RESULT(yes)
 132 else
 133   AC_MSG_RESULT(no)
 134 fi
 135
 136 AC_MSG_CHECKING(whether to enable garbage collector friendliness)
 137 if test "x$enable_gc_friendly" = "xyes"; then
 138   AC_DEFINE(ENABLE_GC_FRIENDLY, 1)
 139   AC_SUBST(ENABLE_GC_FRIENDLY)
 140   AC_MSG_RESULT(yes)
 141 else
 142   AC_MSG_RESULT(no)
 143 fi
 144
 145 if test "x$enable_debug" = "xyes"; then
 146   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 147   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 148 else
 149   if test "x$enable_debug" = "xno"; then
 150     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 151   fi
 152 fi
 153
 154 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 155
 156 if test "x$enable_msg_prefix" = "xyes"; then
 157   AC_DEFINE_UNQUOTED(G_ENABLE_MSG_PREFIX, 1)
 158 fi
 159
 160 # Checks for programs.
 161 AC_PROG_CC
 162 AM_PROG_CC_STDC
 163 AC_PROG_INSTALL
 164
 165 changequote(,)dnl
 166 if test "x$GCC" = "xyes"; then
 167   case " $CFLAGS " in
 168   *[\ \ ]-Wall[\ \      ]*) ;;
 169   *) CFLAGS="$CFLAGS -Wall" ;;
 170   esac
 171
 172   if test "x$enable_ansi" = "xyes"; then
 173     case " $CFLAGS " in
 174     *[\ \       ]-ansi[\ \      ]*) ;;
 175     *) CFLAGS="$CFLAGS -ansi" ;;
 176     esac
 177
 178     case " $CFLAGS " in
 179     *[\ \       ]-pedantic[\ \  ]*) ;;
 180     *) CFLAGS="$CFLAGS -pedantic" ;;
 181     esac
 182   fi
 183 fi
 184 changequote([,])dnl
 185
 186 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 187 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 188 glib_save_LIBS=$LIBS
 189 LIBS="$LIBS -lm"
 190 AC_TRY_RUN([#include <math.h>
 191              int main (void) { return (log(1) != log(1.)); }],
 192      AC_MSG_RESULT(none needed),
 193      glib_save_CFLAGS=$CFLAGS
 194      CFLAGS="$CFLAGS -std1"
 195      AC_TRY_RUN([#include <math.h>
 196                  int main (void) { return (log(1) != log(1.)); }],
 197          AC_MSG_RESULT(-std1),
 198          AC_MSG_RESULT()
 199          CFLAGS=$glib_save_CFLAGS
 200          AC_MSG_WARN(
 201                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 202      )
 203 )
 204 LIBS=$glib_save_LIBS
 205
 206 dnl NeXTStep cc seems to need this
 207 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 208 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 209   AC_MSG_RESULT(none needed),
 210   glib_save_CFLAGS=$CFLAGS
 211   CFLAGS="$CFLAGS -posix"
 212   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 213     AC_MSG_RESULT(-posix),
 214     AC_MSG_RESULT()
 215     CFLAGS=$glib_save_CFLAGS
 216     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 217
 218 # Checks for header files.
 219 AC_HEADER_STDC
 220
 221 # Checks for library functions.
 222 AC_FUNC_VPRINTF
 223
 224 AC_CHECK_FUNCS(atexit on_exit)
 225
 226 AC_CHECK_SIZEOF(char)
 227 AC_CHECK_SIZEOF(short)
 228 AC_CHECK_SIZEOF(long)
 229 AC_CHECK_SIZEOF(int)
 230 AC_CHECK_SIZEOF(void *)
 231 AC_CHECK_SIZEOF(long long)
 232
 233 if test x$ac_cv_sizeof_long_long = x8; then
 234         # long long is a 64 bit integer.
 235         AC_MSG_CHECKING(for format to printf and scanf a gint64)
 236         AC_CACHE_VAL(glib_cv_long_long_format,[
 237                 AC_TRY_RUN([#include <stdio.h>
 238                         int main()
 239                         {
 240                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 241                           char buffer[1000];
 242                           sprintf (buffer, "%llu", a);
 243                           sscanf (buffer, "%llu", &b);
 244                           exit (b!=a);
 245                         }
 246                         ],
 247                         glib_cv_long_long_format=ll,
 248                         glib_cv_long_long_format=q)])
 249         AC_MSG_RESULT(%${glib_cv_long_long_format}i)
 250 fi
 251
 252 dnl long doubles were not used, and a portability problem
 253 dnl AC_C_LONG_DOUBLE
 254 AC_C_CONST
 255
 256 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 257 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 258 dnl actually supported.
 259 AC_MSG_CHECKING(for __inline)
 260 AC_CACHE_VAL(glib_cv_has__inline,[
 261         AC_TRY_RUN([
 262         __inline int foo () { return 0; }
 263         int main () { return foo (); }
 264         ],
 265         glib_cv_has__inline=yes
 266         ,
 267         glib_cv_has__inline=no
 268         ,)
 269 ])
 270 AC_MSG_RESULT($glib_cv_has__inline)
 271 case x$glib_cv_has__inline in
 272 xyes) AC_DEFINE(G_HAVE___INLINE)
 273 esac
 274 AC_MSG_CHECKING(for __inline__)
 275 AC_CACHE_VAL(glib_cv_has__inline__,[
 276         AC_TRY_RUN([
 277         __inline__ int foo () { return 0; }
 278         int main () { return foo (); }
 279         ],
 280         glib_cv_has__inline__=yes
 281         ,
 282         glib_cv_has__inline__=no
 283         ,)
 284 ])
 285 AC_MSG_RESULT($glib_cv_has__inline__)
 286 case x$glib_cv_has__inline__ in
 287 xyes) AC_DEFINE(G_HAVE___INLINE__)
 288 esac
 289 AC_MSG_CHECKING(for inline)
 290 AC_CACHE_VAL(glib_cv_hasinline,[
 291         AC_TRY_RUN([
 292         inline int foo () { return 0; }
 293         int main () { return foo (); }
 294         ],
 295         glib_cv_hasinline=yes
 296         ,
 297         glib_cv_hasinline=no
 298         ,)
 299 ])
 300 AC_MSG_RESULT($glib_cv_hasinline)
 301 case x$glib_cv_hasinline in
 302 xyes) AC_DEFINE(G_HAVE_INLINE)
 303 esac
 304
 305 # check for bytesex stuff
 306 AC_C_BIGENDIAN
 307
 308 # xhexk for header files
 309 AC_CHECK_HEADERS(float.h, AC_DEFINE(HAVE_FLOAT_H))
 310 AC_CHECK_HEADERS(limits.h, AC_DEFINE(HAVE_LIMITS_H))
 311 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 312 AC_CHECK_HEADERS(sys/param.h, AC_DEFINE(HAVE_SYS_PARAM_H))
 313 AC_CHECK_HEADERS(sys/poll.h, AC_DEFINE(HAVE_SYS_POLL_H))
 314 AC_CHECK_HEADERS(sys/select.h, AC_DEFINE(HAVE_SYS_SELECT_H))
 315 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 316 AC_CHECK_HEADERS(sys/times.h, AC_DEFINE(HAVE_SYS_TIMES_H))
 317 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 318 AC_CHECK_HEADERS(values.h, AC_DEFINE(HAVE_VALUES_H))
 319 AC_CHECK_HEADERS(stdint.h, AC_DEFINE(HAVE_VALUES_H))
 320
 321 # check additional type sizes
 322 size_includes=["
 323 #include <stdarg.h>
 324 #include <stdio.h>
 325 #include <stdlib.h>
 326 #include <ctype.h>
 327 #include <string.h>
 328 "]
 329 if test "x$ac_cv_header_stdint_h" = "xyes"; then
 330   size_includes=["$size_includes
 331 #include <stdint.h>
 332 "]
 333 fi
 334 if test "x$ac_cv_header_unistd_h" = "xyes"; then
 335   size_includes=["$size_includes
 336 #include <unistd.h>
 337 "]
 338 fi
 339 GLIB_SIZEOF([$size_includes], size_t, size_t)
 340 GLIB_SIZEOF([$size_includes], ptrdiff_t, ptrdiff_t)
 341 GLIB_SIZEOF([$size_includes], intmax_t, intmax_t)
 342
 343 # Check for some functions
 344 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf strcasecmp strncasecmp poll)
 345
 346 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 347 # The check is borrowed from the PERL Configure script.
 348 if test "$ac_cv_func_memmove" != "yes"; then
 349   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 350     glib_cv_working_bcopy,[AC_TRY_RUN([
 351       int main() {
 352         char buf[128], abc[128], *b;
 353         int len, off, align;
 354         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 355         for (align = 7; align >= 0; align--) {
 356           for (len = 36; len; len--) {
 357             b = buf+align; bcopy(abc, b, len);
 358             for (off = 1; off <= len; off++) {
 359               bcopy(b, b+off, len); bcopy(b+off, b, len);
 360                 if (bcmp(b, abc, len)) return(1);
 361             }
 362           }
 363         }
 364         return(0);
 365       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 366   if test "$glib_cv_working_bcopy" == "yes"; then
 367     AC_DEFINE(HAVE_WORKING_BCOPY)
 368   fi
 369 fi
 370
 371 # Check for sys_errlist
 372 AC_MSG_CHECKING(for sys_errlist)
 373 AC_TRY_LINK(, [
 374 extern char *sys_errlist[];
 375 extern int sys_nerr;
 376 sys_errlist[sys_nerr-1][0] = 0;
 377 ], glib_ok=yes, glib_ok=no)
 378 AC_MSG_RESULT($glib_ok)
 379 if test $glib_ok = no; then
 380     AC_DEFINE(NO_SYS_ERRLIST)
 381 fi
 382
 383 # Check for sys_siglist
 384 AC_MSG_CHECKING(for sys_siglist)
 385 AC_TRY_LINK(, [
 386 extern char *sys_siglist[];
 387 strlen (sys_siglist[0]);
 388 ], glib_ok=yes, glib_ok=no)
 389 AC_MSG_RESULT($glib_ok)
 390 if test $glib_ok = no; then
 391     AC_DEFINE(NO_SYS_SIGLIST)
 392 fi
 393
 394 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 395 AC_MSG_CHECKING(for sys_siglist declaration)
 396 AC_TRY_COMPILE([#include <signal.h>], [
 397 strlen (sys_siglist[0]);
 398 ], glib_ok=yes, glib_ok=no)
 399 AC_MSG_RESULT($glib_ok)
 400 if test $glib_ok = no; then
 401     AC_DEFINE(NO_SYS_SIGLIST_DECL)
 402 fi
 403
 404 # Check if <sys/select.h> needs to be included for fd_set
 405 AC_MSG_CHECKING([for fd_set])
 406 AC_TRY_COMPILE([#include <sys/types.h>],
 407         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 408 if test $gtk_ok = yes; then
 409     AC_MSG_RESULT([yes, found in sys/types.h])
 410 else
 411     AC_HEADER_EGREP(fd_set, sys/select.h, gtk_ok=yes)
 412     if test $gtk_ok = yes; then
 413         AC_DEFINE(HAVE_SYS_SELECT_H)
 414         AC_MSG_RESULT([yes, found in sys/select.h])
 415     else
 416         AC_DEFINE(NO_FD_SET)
 417         AC_MSG_RESULT(no)
 418     fi
 419 fi
 420
 421 dnl *** check for sane realloc() ***
 422 AC_MSG_CHECKING(whether realloc (NULL,) will work)
 423 AC_CACHE_VAL(glib_cv_sane_realloc,[
 424         AC_TRY_RUN([
 425         #include <stdlib.h>
 426         int main() {
 427           return realloc (0, sizeof (int)) == 0;
 428         }],
 429         glib_cv_sane_realloc=yes
 430         AC_DEFINE(REALLOC_0_WORKS)
 431         ,
 432         glib_cv_sane_realloc=no
 433         ,)
 434 ])
 435 AC_MSG_RESULT($glib_cv_sane_realloc)
 436
 437
 438 dnl **********************
 439 dnl *** va_copy checks ***
 440 dnl **********************
 441 dnl we currently check for all three va_copy possibilities, so we get
 442 dnl all results in config.log for bug reports.
 443 AC_MSG_CHECKING(for an implementation of va_copy())
 444 AC_CACHE_VAL(glib_cv_va_copy,[
 445         AC_TRY_RUN([
 446         #include <stdarg.h>
 447         void f (int i, ...) {
 448         va_list args1, args2;
 449         va_start (args1, i);
 450         va_copy (args2, args1);
 451         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 452           exit (1);
 453         va_end (args1); va_end (args2);
 454         }
 455         int main() {
 456           f (0, 42);
 457           return 0;
 458         }],
 459         glib_cv_va_copy=yes
 460         ,
 461         glib_cv_va_copy=no
 462         ,)
 463 ])
 464 AC_MSG_RESULT($glib_cv_va_copy)
 465 AC_MSG_CHECKING(for an implementation of __va_copy())
 466 AC_CACHE_VAL(glib_cv___va_copy,[
 467         AC_TRY_RUN([
 468         #include <stdarg.h>
 469         void f (int i, ...) {
 470         va_list args1, args2;
 471         va_start (args1, i);
 472         __va_copy (args2, args1);
 473         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 474           exit (1);
 475         va_end (args1); va_end (args2);
 476         }
 477         int main() {
 478           f (0, 42);
 479           return 0;
 480         }],
 481         glib_cv___va_copy=yes
 482         ,
 483         glib_cv___va_copy=no
 484         ,)
 485 ])
 486 AC_MSG_RESULT($glib_cv___va_copy)
 487 AC_MSG_CHECKING(whether va_lists can be copied by value)
 488 AC_CACHE_VAL(glib_cv_va_val_copy,[
 489         AC_TRY_RUN([
 490         #include <stdarg.h>
 491         void f (int i, ...) {
 492         va_list args1, args2;
 493         va_start (args1, i);
 494         args2 = args1;
 495         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 496           exit (1);
 497         va_end (args1); va_end (args2);
 498         }
 499         int main() {
 500           f (0, 42);
 501           return 0;
 502         }],
 503         glib_cv_va_val_copy=yes
 504         ,
 505         glib_cv_va_val_copy=no
 506         ,)
 507 ])
 508 if test "x$glib_cv_va_copy" = "xyes"; then
 509   AC_DEFINE(G_VA_COPY, va_copy)
 510 else if test "x$glib_cv___va_copy" = "xyes"; then
 511   AC_DEFINE(G_VA_COPY, __va_copy)
 512 fi
 513 fi
 514 if test "x$glib_cv_va_val_copy" = "xno"; then
 515   AC_DEFINE(G_VA_COPY_AS_ARRAY)
 516 fi
 517 AC_MSG_RESULT($glib_cv_va_val_copy)
 518
 519
 520 dnl ***********************
 521 dnl *** g_module checks ***
 522 dnl ***********************
 523 G_MODULE_LIBS=
 524 G_MODULE_LIBS_EXTRA=
 525 G_MODULE_PLUGIN_LIBS=
 526 G_MODULE_LDFLAGS=
 527 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
 528 G_MODULE_NEED_USCORE=0
 529 G_MODULE_HAVE_DLERROR=0
 530 dnl *** dlopen() and dlsym() in system libraries
 531 if test -z "$G_MODULE_IMPL"; then
 532         AC_CHECK_FUNC(dlopen,
 533                 AC_CHECK_FUNC(dlsym,
 534                         G_MODULE_IMPL=G_MODULE_IMPL_DL
 535                 ,)
 536         ,)
 537 fi
 538 dnl *** load_image (BeOS)
 539 if test -z "$G_MODULE_IMPL" -a "x$glib_native_beos" = "xyes"; then
 540   AC_CHECK_LIB(root, load_image,
 541       G_MODULE_LIBS="-lbe -lroot -lglib"
 542       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
 543       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
 544       G_MODULE_IMPL=G_MODULE_IMPL_BEOS
 545 ,)
 546 fi
 547 dnl *** dlopen() and dlsym() in libdl
 548 if test -z "$G_MODULE_IMPL"; then
 549         AC_CHECK_LIB(dl, dlopen,
 550                 AC_CHECK_LIB(dl, dlsym,
 551                         G_MODULE_LIBS=-ldl
 552                         G_MODULE_IMPL=G_MODULE_IMPL_DL
 553                 ,)
 554         ,)
 555 fi
 556 dnl *** shl_load() in libdld (HP-UX)
 557 if test -z "$G_MODULE_IMPL"; then
 558         AC_MSG_CHECKING(how to export all symbols)
 559         SAVED_LDFLAGS=$LDFLAGS
 560         LDFLAGS="$LDFLAGS -Wl,-E"
 561         AC_TRY_LINK(,[ return 0; ],
 562                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 563                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 564                 AC_TRY_LINK(,[ return 0; ],
 565                         G_MODULE_LDFLAGS="-bexpall",
 566                         G_MODULE_LDFLAGS="none"
 567                 )
 568         ])
 569         LDFLAGS=$SAVED_LDFLAGS
 570         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 571         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 572                 G_MODULE_LDFLAGS=
 573         fi
 574         AC_CHECK_LIB(dld, shl_load,
 575                 G_MODULE_LIBS=-ldld
 576                 G_MODULE_IMPL=G_MODULE_IMPL_DLD
 577         ,)
 578 fi
 579 dnl *** additional checks for G_MODULE_IMPL_DL
 580 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 581         case "$host_os" in
 582           linux*)
 583             G_MODULE_LDFLAGS='-rdynamic'
 584             ;;
 585         esac
 586         LIBS_orig="$LIBS"
 587         LDFLAGS_orig="$LDFLAGS"
 588         LIBS="$LIBS $G_MODULE_LIBS"
 589         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 590 dnl *** check whether we need preceeding underscores
 591         AC_MSG_CHECKING(for preceeding underscore in symbols)
 592         AC_CACHE_VAL(glib_cv_uscore,[
 593                 AC_TRY_RUN([
 594                 #include <dlfcn.h>
 595                 int glib_underscore_test (void) { return 42; }
 596                 int main() {
 597                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 598                   handle = dlopen ((void*)0, 0);
 599                   if (handle) {
 600                     f1 = dlsym (handle, "glib_underscore_test");
 601                     f2 = dlsym (handle, "_glib_underscore_test");
 602                   } return (!f2 || f1);
 603                 }],
 604                         glib_cv_uscore=yes,
 605                         glib_cv_uscore=no,
 606                 )
 607                 rm -f plugin.c plugin.o plugin.lo
 608         ])
 609         AC_MSG_RESULT($glib_cv_uscore)
 610         if test "x$glib_cv_uscore" = "xyes"; then
 611                 G_MODULE_NEED_USCORE=1
 612         else
 613                 G_MODULE_NEED_USCORE=0
 614         fi
 615
 616         LDFLAGS="$LDFLAGS_orig"
 617 dnl *** check for having dlerror()
 618         AC_CHECK_FUNC(dlerror,
 619                 G_MODULE_HAVE_DLERROR=1,
 620                 G_MODULE_HAVE_DLERROR=0)
 621         LIBS="$LIBS_orig"
 622 fi
 623 dnl *** done, have e got an implementation?
 624 if test -z "$G_MODULE_IMPL"; then
 625         G_MODULE_IMPL=0
 626 fi
 627 AC_SUBST(G_MODULE_IMPL)
 628 AC_SUBST(G_MODULE_LIBS)
 629 AC_SUBST(G_MODULE_LIBS_EXTRA)
 630 AC_SUBST(G_MODULE_PLUGIN_LIBS)
 631 AC_SUBST(G_MODULE_LDFLAGS)
 632 AC_SUBST(G_MODULE_HAVE_DLERROR)
 633 AC_SUBST(G_MODULE_NEED_USCORE)
 634 AC_SUBST(GLIB_DEBUG_FLAGS)
 635
 636
 637 dnl ***********************
 638 dnl *** g_thread checks ***
 639 dnl ***********************
 640
 641 AC_ARG_WITH(threads, [  --with-threads=[none/posix/dce/solaris] specify a thread implementation to use],
 642         if test "x$with_threads" = x; then
 643                 want_threads=yes
 644         else
 645                 want_threads=$with_threads
 646         fi,
 647         want_threads=yes)
 648 if test "x$enable_threads" = "xno"; then
 649         want_threads=no
 650 fi
 651 if test "x$want_threads" = "xnone"; then
 652         want_threads=no
 653 fi
 654
 655 dnl error and warning message
 656 dnl *************************
 657
 658 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
 659                 computer. GLib will not have a default thread implementation."
 660
 661 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
 662                 platform (normaly it's "_REENTRANT"). I'll not use any flag on
 663                 compilation now, but then your programs might not work.
 664                 Please provide information on how it is done on your system."
 665
 666 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
 667                 "
 668
 669 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
 670                 provide information on your thread implementation.
 671                 You can also run 'configure --disable-threads'
 672                 to compile without thread support."
 673
 674 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
 675                 functions will not be MT-safe during their first call because
 676                 there is no working 'getpwuid_r' on your system."
 677
 678 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
 679                 because there is no 'localtime_r' on your system."
 680
 681 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
 682                 crude surrogate will be used. If you happen to know a
 683                 yield function for your system, please inform the GLib
 684                 developers."
 685
 686 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
 687                 threads on your system. Thus threads can only have the default
 688                 priority. If you happen to know these main/max
 689                 priorities, please inform the GLib developers."
 690
 691
 692 dnl determination of thread implementation
 693 dnl ***************************************
 694
 695 have_threads=none
 696 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
 697         case $host in
 698                 *-*-solaris*)
 699                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
 700                 ;;
 701         esac
 702 fi
 703 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
 704                                 || test "x$want_threads" = xdce; then
 705         # -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
 706         # -U_OSF_SOURCE is for Digital UNIX 4.0d
 707         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
 708         glib_save_CPPFLAGS="$CPPFLAGS"
 709         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
 710         if test "x$have_threads" = xnone; then
 711                 AC_EGREP_HEADER([(^|[^a-zA-Z_])pthread_attr_init[^a-zA-Z_]],
 712                         pthread.h,
 713                         have_threads=posix)
 714         fi
 715         if test "x$have_threads" = xnone; then
 716                 AC_EGREP_HEADER([(^|[^a-zA-Z_])pthread_attr_create[^a-zA-Z_]],
 717                         pthread.h,
 718                         have_threads=dce)
 719         fi
 720         CPPFLAGS="$glib_save_CPPFLAGS"
 721 fi
 722
 723 AC_MSG_CHECKING(for thread implementation)
 724
 725 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
 726         AC_MSG_RESULT(none available)
 727         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
 728 else
 729         AC_MSG_RESULT($have_threads)
 730 fi
 731
 732
 733 dnl determination of G_THREAD_LIBS
 734 dnl ******************************
 735
 736 G_THREAD_LIBS=
 737 G_THREAD_LIBS_EXTRA=
 738 G_THREAD_CFLAGS=
 739
 740 mutex_has_default=no
 741 case $have_threads in
 742         posix|dce)
 743                 G_THREAD_LIBS=error
 744                 glib_save_LIBS="$LIBS"
 745                 for thread_lib in "" pthread pthreads c_r thread dce; do
 746                         if test x"$thread_lib" = x; then
 747                                 add_thread_lib=""
 748                                 IN=""
 749                         else
 750                                 add_thread_lib="-l$thread_lib"
 751                                 IN=" in -l$thread_lib"
 752                         fi
 753                         if test x"$have_threads" = xposix; then
 754                                 defattr=NULL
 755                         else
 756                                 defattr=pthread_attr_default
 757                         fi
 758
 759                         LIBS="$glib_save_LIBS $add_thread_lib"
 760
 761                         AC_MSG_CHECKING(for pthread_create$IN)
 762                         AC_TRY_RUN([#include <pthread.h>
 763                                 void* func(void* data) {}
 764                                 main()
 765                                 { pthread_t t;
 766                                   exit(pthread_create (&t, $defattr, func,
 767                                                 NULL));
 768                                 }],
 769                                 [AC_MSG_RESULT(yes)
 770                                 G_THREAD_LIBS="$add_thread_lib"
 771                                 break],
 772                                 [AC_MSG_RESULT(no)])
 773                 done
 774                 for thread_lib in "" rt; do
 775                         if test x"$thread_lib" = x; then
 776                                 add_thread_lib=""
 777                                 IN=""
 778                         else
 779                                 add_thread_lib="-l$thread_lib"
 780                                 IN=" in -l$thread_lib"
 781                         fi
 782                         LIBS="$glib_save_LIBS $add_thread_lib"
 783
 784                         AC_MSG_CHECKING(for sched_get_priority_min$IN)
 785                         AC_TRY_RUN([#include <sched.h>
 786                                 #include <errno.h>
 787                                 int main() {
 788                                 errno = 0;
 789                                 return sched_get_priority_min(SCHED_OTHER)==-1
 790                                         && errno != 0;
 791                                 }],
 792                                 [AC_MSG_RESULT(yes)
 793                                 G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
 794                                 posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
 795                                 posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
 796                                 break],
 797                                 [AC_MSG_RESULT(no)])
 798                 done
 799                 LIBS="$glib_save_LIBS"
 800                 mutex_has_default=yes
 801                 mutex_default_type='pthread_mutex_t'
 802                 mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
 803                 mutex_header_file='pthread.h'
 804                 if test "x$have_threads" = "xposix"; then
 805                         g_threads_impl="POSIX"
 806                 else
 807                         g_threads_impl="DCE"
 808                         have_threads="posix"
 809                 fi
 810                 AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
 811                 ;;
 812         solaris)
 813                 G_THREAD_LIBS=error
 814                 AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
 815                 mutex_has_default=yes
 816                 mutex_default_type='mutex_t'
 817                 mutex_default_init="DEFAULTMUTEX"
 818                 mutex_header_file='thread.h'
 819                 g_threads_impl="SOLARIS"
 820                 ;;
 821         none)
 822                 g_threads_impl="NONE"
 823                 ;;
 824         *)
 825                 g_threads_impl="NONE"
 826                 G_THREAD_LIBS=error
 827                 ;;
 828 esac
 829
 830 if test "x$G_THREAD_LIBS" = xerror; then
 831         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 832 fi
 833
 834 case $host in
 835   *-*-beos*)
 836     G_THREAD_LIBS="-lbe -lroot -lglib "
 837     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
 838     ;;
 839   *)
 840     ;;
 841 esac
 842
 843 AC_MSG_CHECKING(thread related libraries)
 844 AC_MSG_RESULT($G_THREAD_LIBS)
 845
 846 dnl determination of G_THREAD_CFLAGS
 847 dnl ********************************
 848
 849 if test x"$enable_threads" = xyes; then
 850
 851     G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_REENTRANT" # good default guess
 852
 853     case $host in
 854         *-aix*)
 855                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 856                 if test x"$GCC" = xyes; then
 857                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
 858                 fi
 859                 ;;
 860         *-freebsd2.2*)
 861                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 862
 863                 # FreeBSD 2.2.x shiped with gcc 2.7.2.x, which doesn't support
 864                 # -mthreads flag.
 865                 ;;
 866     esac
 867
 868     # if we are not finding the ctime_r function, then we probably are
 869     # not using the proper multithread flag
 870     old_CPPFLAGS=$CPPFLAGS
 871     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
 872     # Note: Digital UNIX 4.0d #defines ctime_r to _Pctime_r for gcc.
 873     AC_EGREP_HEADER([[^a-zA-Z_](_P)?ctime_r[^a-zA-Z_]], time.h, ,
 874     G_THREAD_CFLAGS=
 875     AC_MSG_WARN($FLAG_DOES_NOT_WORK))
 876     CPPFLAGS=$old_CPPFLAGS
 877
 878     AC_MSG_CHECKING(thread related cflags)
 879
 880     AC_MSG_RESULT($G_THREAD_CFLAGS)
 881 else
 882     G_THREAD_CFLAGS=
 883 fi
 884
 885 dnl check for mt safe function variants and some posix functions
 886 dnl ************************************************************
 887
 888 if test x"$enable_threads" = xyes; then
 889         glib_save_LIBS="$LIBS"
 890         glib_save_CFLAGS="$CFLAGS"
 891         # we are not doing the following for now, as this might require glib
 892         # to always be linked with the thread libs on some platforms.
 893         # LIBS="$LIBS $G_THREAD_LIBS"
 894         CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 895         AC_CHECK_FUNCS(localtime_r)
 896         if test "$ac_cv_header_pwd_h" = "yes"; then
 897                 AC_MSG_CHECKING([for getpwuid_r])
 898                 AC_CACHE_VAL(ac_cv_func_getpwuid_r,
 899                         [AC_TRY_RUN([#include <errno.h>
 900                                 int main () { char buffer[10000], *pointer;
 901                                 char getpwuid_r (long, void*, void*,
 902                                         int, void*);
 903                                 errno = 0;
 904                                 getpwuid_r (0, &buffer, &buffer,
 905                                         sizeof (buffer), &pointer);
 906                                 return errno == ENOSYS;}],
 907                                 [ac_cv_func_getpwuid_r=yes],
 908                                 [ac_cv_func_getpwuid_r=no])])
 909                 if test "$ac_cv_func_getpwuid_r" = yes; then
 910                         AC_MSG_RESULT(yes)
 911                         AC_DEFINE(HAVE_GETPWUID_R)
 912                 else
 913                         AC_MSG_RESULT(no)
 914                 fi
 915                 if test "$ac_cv_func_getpwuid_r" = "yes"; then
 916                         AC_MSG_CHECKING(whether getpwuid_r is posix like)
 917                         # The signature for the POSIX version is:
 918                         # int getpwuid_r(uid_t, struct passwd *, char *, size_t, struct passwd **)
 919                         AC_TRY_COMPILE([#include <pwd.h>
 920                                 #include <sys/types.h>
 921                                 #include <stdlib.h>],
 922                                 [getpwuid_r((uid_t)0, NULL, NULL, (size_t)0, NULL);],
 923                                 [AC_DEFINE(HAVE_GETPWUID_R_POSIX)
 924                                 AC_MSG_RESULT(yes)],
 925                                 [AC_MSG_RESULT(no)])
 926                 fi
 927         fi
 928         LIBS="$LIBS $G_THREAD_LIBS"
 929         if test x"$have_threads" = xposix; then
 930                 glib_save_CPPFLAGS="$CPPFLAGS"
 931                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
 932                 GLIB_SIZEOF([#include <pthread.h>],
 933                         pthread_t,
 934                         system_thread)
 935                 # This is not AC_CHECK_FUNC to also work with function
 936                 # name mangling in header files.
 937                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
 938                 AC_TRY_LINK([#include <pthread.h>],
 939                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
 940                         [AC_MSG_RESULT(yes)
 941                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE)],
 942                         [AC_MSG_RESULT(no)])
 943                 AC_MSG_CHECKING(for minimal/maximal thread priority)
 944                 if test x"$posix_priority_min" = xnone; then
 945                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
 946                                 PX_PRIO_MIN],,[
 947                                 posix_priority_min=PX_PRIO_MIN
 948                                 posix_priority_max=PX_PRIO_MAX])
 949                 fi
 950                 if test x"$posix_priority_min" = xnone; then
 951                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
 952                                 PRI_OTHER_MIN],,[
 953                                 posix_priority_min=PRI_OTHER_MIN
 954                                 posix_priority_max=PRI_OTHER_MAX])
 955                 fi
 956                 if test x"$posix_priority_min" = x; then
 957                         AC_MSG_RESULT(none found)
 958                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
 959                         posix_priority_min=-1
 960                         posix_priority_max=-1
 961                 else
 962                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
 963                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min)
 964                         AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max)
 965                 fi
 966                 posix_yield_func=none
 967                 AC_MSG_CHECKING(for posix yield function)
 968                 for yield_func in sched_yield pthread_yield_np pthread_yield \
 969                                                         thr_yield; do
 970                         AC_TRY_LINK([#include <pthread.h>],
 971                                 [$yield_func()],
 972                                 [posix_yield_func="$yield_func"
 973                                 break])
 974                 done
 975                 if test x"$posix_yield_func" = xnone; then
 976                         AC_MSG_RESULT(none found)
 977                         AC_MSG_WARN($POSIX_NO_YIELD)
 978                         posix_yield_func="g_usleep(1000)"
 979                 else
 980                         AC_MSG_RESULT($posix_yield_func)
 981                         posix_yield_func="$posix_yield_func()"
 982                 fi
 983                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func)
 984                 CPPFLAGS="$glib_save_CPPFLAGS"
 985         else # solaris threads
 986                 GLIB_SIZEOF([#include <thread.h>],
 987                         thread_t,
 988                         system_thread)
 989         fi
 990
 991         LIBS="$glib_save_LIBS"
 992         CFLAGS="$glib_save_CFLAGS"
 993
 994         # now spit out all the warnings.
 995         if test "$ac_cv_func_getpwuid_r" != "yes"; then
 996                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
 997         fi
 998         if test "$ac_cv_func_localtime_r" != "yes"; then
 999                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1000         fi
1001 else
1002         # If no thread implementation exists, we will provide enough
1003         # space for a pointer
1004         GLIB_SIZEOF(, void*, system_thread)
1005 fi
1006
1007 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c")
1008 AC_SUBST(G_THREAD_CFLAGS)
1009 AC_SUBST(G_THREAD_LIBS)
1010 AC_SUBST(G_THREAD_LIBS_EXTRA)
1011
1012 CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
1013
1014 dnl **********************************************
1015 dnl *** GDefaultMutex setup and initialization ***
1016 dnl **********************************************
1017 dnl
1018 dnl if mutex_has_default = yes, we also got
1019 dnl mutex_default_type, mutex_default_init and mutex_header_file
1020 GLIB_IF_VAR_EQ(mutex_has_default, yes,
1021         glib_save_CPPFLAGS="$CPPFLAGS"
1022         glib_save_LIBS="$LIBS"
1023         LIBS="$LIBS $G_THREAD_LIBS"
1024         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1025         GLIB_SIZEOF([#include <$mutex_header_file>],
1026                     $mutex_default_type,
1027                     gmutex,
1028                     )
1029         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1030                            $mutex_default_type,
1031                            gmutex,
1032                            $glib_cv_sizeof_gmutex,
1033                            $mutex_default_init)
1034         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1035                 mutex_has_default=no
1036         fi
1037         CPPFLAGS="$glib_save_CPPFLAGS"
1038         LIBS="$glib_save_LIBS"
1039         ,
1040 )
1041
1042
1043 dnl ****************************************
1044 dnl *** GLib POLL* compatibility defines ***
1045 dnl ****************************************
1046 GLIB_SYSDEFS(
1047 [#include <sys/types.h>
1048 #include <sys/poll.h>],
1049         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
1050         glibconfig-sysdefs.h,
1051         =)
1052
1053
1054 dnl ******************************
1055 dnl *** output the whole stuff ***
1056 dnl ******************************
1057
1058 AC_OUTPUT_COMMANDS([
1059
1060 ## Generate `glibconfig.h' in two cases
1061 ## 1. `config.status' is run either explicitly, or via configure.
1062 ##     Esp. not when it is run in `Makefile' to generate makefiles and
1063 ##     config.h
1064 ## 2. CONFIG_OTHER is set explicitly
1065 ##
1066 ## Case 1 is difficult.  We know that `automake' sets one of
1067 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
1068 ## only when AM_CONFIG_HEADER is set, however.
1069
1070 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
1071   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
1072   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
1073 fi
1074 case "$CONFIG_OTHER" in
1075 *glibconfig.h*)
1076         echo creating glibconfig.h
1077         outfile=glibconfig.h-tmp
1078         cat > $outfile <<\_______EOF
1079 /* glibconfig.h
1080  *
1081  * This is a generated file.  Please modify `configure.in'
1082  */
1083
1084 #ifndef GLIBCONFIG_H
1085 #define GLIBCONFIG_H
1086
1087 #ifdef __cplusplus
1088 extern "C" {
1089 #endif /* __cplusplus */
1090
1091 _______EOF
1092
1093         if test x$glib_limits_h = xyes; then
1094           echo '#include <limits.h>' >> $outfile
1095         fi
1096         if test x$glib_float_h = xyes; then
1097           echo '#include <float.h>' >> $outfile
1098         fi
1099         if test x$glib_values_h = xyes; then
1100           echo '#include <values.h>' >> $outfile
1101         fi
1102         if test x$g_mutex_header_file != x; then
1103           echo '#include <'"$g_mutex_header_file"'>' >> $outfile
1104         fi
1105         if test x$glib_sys_poll_h = xyes; then
1106           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
1107         fi
1108
1109         cat >> $outfile <<_______EOF
1110
1111 #define G_MINFLOAT      $glib_mf
1112 #define G_MAXFLOAT      $glib_Mf
1113 #define G_MINDOUBLE     $glib_md
1114 #define G_MAXDOUBLE     $glib_Md
1115 #define G_MINSHORT      $glib_ms
1116 #define G_MAXSHORT      $glib_Ms
1117 #define G_MAXUSHORT     $glib_Mus
1118 #define G_MININT        $glib_mi
1119 #define G_MAXINT        $glib_Mi
1120 #define G_MAXUINT       $glib_Mui
1121 #define G_MINLONG       $glib_ml
1122 #define G_MAXLONG       $glib_Ml
1123 #define G_MAXULONG      $glib_Mul
1124
1125 _______EOF
1126
1127
1128         ### this should always be true in a modern C/C++ compiler
1129         cat >>$outfile <<_______EOF
1130 typedef signed char gint8;
1131 typedef unsigned char guint8;
1132 _______EOF
1133
1134
1135         if test -n "$gint16"; then
1136           cat >>$outfile <<_______EOF
1137 typedef signed $gint16 gint16;
1138 typedef unsigned $gint16 guint16;
1139 #define G_GINT16_FORMAT $gint16_format
1140 #define G_GUINT16_FORMAT $guint16_format
1141 _______EOF
1142         fi
1143
1144
1145         if test -n "$gint32"; then
1146           cat >>$outfile <<_______EOF
1147 typedef signed $gint32 gint32;
1148 typedef unsigned $gint32 guint32;
1149 #define G_GINT32_FORMAT $gint32_format
1150 #define G_GUINT32_FORMAT $guint32_format
1151 _______EOF
1152         fi
1153
1154
1155         if test -n "$gint64"; then
1156           cat >>$outfile <<_______EOF
1157 #define G_HAVE_GINT64 1
1158
1159 ${glib_extension}typedef signed $gint64 gint64;
1160 ${glib_extension}typedef unsigned $gint64 guint64;
1161
1162 #define G_GINT64_FORMAT $gint64_format
1163 #define G_GUINT64_FORMAT $guint64_format
1164 #define G_GINT64_CONSTANT(val)  $gint64_constant
1165 _______EOF
1166         fi
1167
1168
1169         if test -z "$glib_unknown_void_p"; then
1170           cat >>$outfile <<_______EOF
1171
1172 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
1173 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
1174
1175 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
1176 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
1177 _______EOF
1178         else
1179           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
1180         fi
1181
1182
1183
1184         cat >>$outfile <<_______EOF
1185 $glib_atexit
1186 $glib_memmove
1187 $glib_defines
1188 $glib_os
1189
1190 $glib_vacopy
1191
1192 #ifdef  __cplusplus
1193 #define G_HAVE_INLINE   1
1194 #else   /* !__cplusplus */
1195 $glib_inline
1196 #endif  /* !__cplusplus */
1197 _______EOF
1198
1199         echo >>$outfile
1200         if test x$g_mutex_has_default = xyes; then
1201                 cat >>$outfile <<_______EOF
1202 $g_enable_threads_def G_THREADS_ENABLED
1203 #define G_THREADS_IMPL_$g_threads_impl_def
1204 typedef struct _GStaticMutex GStaticMutex;
1205 struct _GStaticMutex
1206 {
1207   struct _GMutex *runtime_mutex;
1208   union {
1209     char   pad[$g_mutex_sizeof];
1210     double dummy_double;
1211     void  *dummy_pointer;
1212     long   dummy_long;
1213   } aligned_pad_u;
1214 };
1215 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
1216 #define g_static_mutex_get_mutex(mutex) \
1217   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->aligned_pad_u)) : \
1218    g_static_mutex_get_mutex_impl (&((mutex)->runtime_mutex)))
1219 _______EOF
1220         else
1221                 cat >>$outfile <<_______EOF
1222 $g_enable_threads_def G_THREADS_ENABLED
1223 #define G_THREADS_IMPL_$g_threads_impl_def
1224 typedef struct _GMutex* GStaticMutex;
1225 #define G_STATIC_MUTEX_INIT NULL
1226 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (mutex))
1227 _______EOF
1228         fi
1229
1230         cat >>$outfile <<_______EOF
1231 /* This represents a system thread as used by the implementation. An
1232  * alien implementaion, as loaded by g_thread_init can only count on
1233  * "sizeof (gpointer)" bytes to store their info. We however need more
1234  * for some of our native implementations. */
1235 typedef union _GSystemThread GSystemThread;
1236 union _GSystemThread
1237 {
1238   char   data[$g_system_thread_sizeof];
1239   double dummy_double;
1240   void  *dummy_pointer;
1241   long   dummy_long;
1242 };
1243 _______EOF
1244
1245         echo >>$outfile
1246         g_bit_sizes="16 32"
1247         if test -n "$gint64"; then
1248           g_bit_sizes="$g_bit_sizes 64"
1249         fi
1250         for bits in $g_bit_sizes; do
1251           cat >>$outfile <<_______EOF
1252 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
1253 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
1254 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
1255 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
1256 _______EOF
1257         done
1258
1259         cat >>$outfile <<_______EOF
1260 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
1261 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
1262 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
1263 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
1264 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
1265 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
1266 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
1267 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
1268 #define G_BYTE_ORDER $g_byte_order
1269
1270 _______EOF
1271
1272         if test -r glibconfig-sysdefs.h; then
1273           cat glibconfig-sysdefs.h >>$outfile
1274         fi
1275
1276         cat >>$outfile <<_______EOF
1277
1278 #ifdef __cplusplus
1279 }
1280 #endif /* __cplusplus */
1281
1282 #endif /* GLIBCONFIG_H */
1283 _______EOF
1284
1285
1286         if cmp -s $outfile glibconfig.h; then
1287           echo glibconfig.h is unchanged
1288           rm -f $outfile
1289         else
1290           mv $outfile glibconfig.h
1291         fi ;;
1292 esac
1293 ],[
1294
1295 # Note that if two cases are the same, case goes with the first one.
1296 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
1297 # on variable expansion in case labels.  Look at the generated config.status
1298 # for a hint.
1299
1300 case xyes in
1301 x$ac_cv_header_float_h)
1302   glib_float_h=yes
1303   glib_mf=FLT_MIN glib_Mf=FLT_MAX
1304   glib_md=DBL_MIN glib_Md=DBL_MAX
1305   ;;
1306 x$ac_cv_header_values_h)
1307   glib_values_h=yes
1308   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
1309   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
1310   ;;
1311 esac
1312
1313 case xyes in
1314 x$ac_cv_header_limits_h)
1315   glib_limits_h=yes
1316   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
1317   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
1318   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
1319   ;;
1320 x$ac_cv_header_values_h)
1321   glib_values_h=yes
1322   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
1323   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
1324   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
1325   ;;
1326 esac
1327
1328 if test x$ac_cv_header_sys_poll_h = xyes ; then
1329   glib_sys_poll_h=yes
1330 fi
1331
1332 case 2 in
1333 $ac_cv_sizeof_short)
1334   gint16=short
1335   gint16_format='"hi"'
1336   guint16_format='"hu"'
1337   ;;
1338 $ac_cv_sizeof_int)
1339   gint16=int
1340   gint16_format='"i"'
1341   guint16_format='"u"'
1342   ;;
1343 esac
1344 case 4 in
1345 $ac_cv_sizeof_short)
1346   gint32=short
1347   gint32_format='"hi"'
1348   guint32_format='"hu"'
1349   ;;
1350 $ac_cv_sizeof_int)
1351   gint32=int
1352   gint32_format='"i"'
1353   guint32_format='"u"'
1354   ;;
1355 $ac_cv_sizeof_long)
1356   gint32=long
1357   gint32_format='"li"'
1358   guint32_format='"lu"'
1359   ;;
1360 esac
1361 case 8 in
1362 $ac_cv_sizeof_int)
1363   gint64=int
1364   gint64_format='"i"'
1365   guint64_format='"u"'
1366   glib_extension=
1367   gint64_constant='(val)'
1368   ;;
1369 $ac_cv_sizeof_long)
1370   gint64=long
1371   gint64_format='"li"'
1372   guint64_format='"lu"'
1373   glib_extension=
1374   gint64_constant='(val##L)'
1375   ;;
1376 $ac_cv_sizeof_long_long)
1377   gint64='long long'
1378   gint64_format='"'$glib_cv_long_long_format'i"'
1379   guint64_format='"'$glib_cv_long_long_format'u"'
1380   glib_extension='G_GNUC_EXTENSION '
1381   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1382   ;;
1383 esac
1384
1385 gintbits=`expr $ac_cv_sizeof_int \* 8`
1386 glongbits=`expr $ac_cv_sizeof_long \* 8`
1387
1388
1389 case $ac_cv_sizeof_void_p in
1390 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
1391 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
1392 *)                      glib_unknown_void_p=yes ;;
1393 esac
1394
1395
1396 case xyes in
1397 x$ac_cv_func_atexit)
1398   glib_atexit="
1399 #ifdef NeXT /* @#%@! NeXTStep */
1400 # define g_ATEXIT(proc) (!atexit (proc))
1401 #else
1402 # define g_ATEXIT(proc) (atexit (proc))
1403 #endif"
1404   ;;
1405 x$ac_cv_func_on_exit)
1406   glib_atexit="
1407 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
1408   ;;
1409 esac
1410
1411 case xyes in
1412 x$ac_cv_func_memmove)
1413   glib_memmove='
1414 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
1415   ;;
1416 x$glib_cv_working_bcopy)
1417   glib_memmove="
1418 /* memmove isn't available, but bcopy can copy overlapping memory regions */
1419 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
1420   ;;
1421 *)
1422   glib_memmove="
1423 /* memmove isn't found and bcopy can't copy overlapping memory regions,
1424  * so we have to roll our own copy routine. */
1425 void g_memmove (void* dest, const void * src, unsigned long len);"
1426   ;;
1427 esac
1428
1429 glib_defines="
1430 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
1431 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
1432 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
1433 "
1434
1435 case xyes in
1436 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
1437 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
1438 *)                      glib_vacopy=''
1439 esac
1440
1441 if test x$glib_cv_va_val_copy = xno; then
1442   glib_vacopy="\$glib_vacopy
1443 #define G_VA_COPY_AS_ARRAY 1"
1444 fi
1445
1446 if test x$glib_cv_hasinline = xyes; then
1447     glib_inline='#define G_HAVE_INLINE 1'
1448 fi
1449 if test x$glib_cv_has__inline = xyes; then
1450     glib_inline="\$glib_inline
1451 #define G_HAVE___INLINE 1"
1452 fi
1453 if test x$glib_cv_has__inline__ = xyes; then
1454     glib_inline="\$glib_inline
1455 #define G_HAVE___INLINE__ 1"
1456 fi
1457
1458 case xyes in
1459 x$ac_cv_c_bigendian)
1460   g_byte_order=G_BIG_ENDIAN
1461   g_bs_native=BE
1462   g_bs_alien=LE
1463   ;;
1464 *)
1465   g_byte_order=G_LITTLE_ENDIAN
1466   g_bs_native=LE
1467   g_bs_alien=BE
1468   ;;
1469 esac
1470
1471 case x$enable_threads in
1472 xyes)   g_enable_threads_def="#define";;
1473 *)      g_enable_threads_def="#undef ";;
1474 esac
1475
1476 g_threads_impl_def=$g_threads_impl
1477
1478 g_mutex_has_default="$mutex_has_default"
1479 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
1480 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
1481 g_mutex_contents="$glib_cv_byte_contents_gmutex"
1482
1483 case $host in
1484   *-*-beos*)
1485     glib_os="#define G_OS_BEOS"
1486     ;;
1487   *-*-cygwin*)
1488     glib_os="#define G_OS_UNIX
1489 #define G_WITH_CYGWIN"
1490     ;;
1491   *)
1492     glib_os="#define G_OS_UNIX"
1493     ;;
1494 esac
1495 ])
1496
1497 AC_OUTPUT([
1498 glib.spec
1499 Makefile
1500 glib-config
1501 gmodule/gmoduleconf.h
1502 gmodule/Makefile
1503 gthread/Makefile
1504 docs/Makefile
1505 docs/glib-config.1
1506 tests/Makefile
1507 ],[case "$CONFIG_FILES" in
1508 *glib-config*)chmod +x glib-config;;
1509 esac
1510 echo ""
1511 echo " *** IMPORTANT *** "
1512 echo ""
1513 echo "This is a development version of GLib.  You should be using a stable"
1514 echo "version, which is available at ftp://ftp.gtk.org/pub/gtk/v1.2/.  The"
1515 echo "version you just configured is meant for developers of GLib only:"
1516 echo ""
1517 echo "  * You should not base stable software on this version of GLib."
1518 echo "  * GNOME developers should use a stable version of GLib."
1519 echo ""
1520 echo "Distributions should *NOT* ship a development package of this GLib."
1521 echo "Do not ship the headers and do not ship the glib-config script.  These"
1522 echo "things will conflict with the stable 1.2 series.  Package only enough"
1523 echo "to satisfy the requirements of some other package.  Package only the"
1524 echo "library itself.  Doing otherwise will do no favors to the community."
1525 echo ""
1526 echo "If you install this version of GLib, we strongly recommend that you"
1527 echo "install it in a different prefix than GLib 1.2.  Use --prefix as an"
1528 echo "argument to configure to do this.  Otherwise, you will not be able to"
1529 echo "do development with GLib 1.2 any longer."
1530 echo ""
1531 echo " *** You should be using GLib 1.2 instead. ***"
1532 ])
1533