configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5 builtin(include, glib/libcharset/codeset.m4)dnl
   6 builtin(include, glib/libcharset/glibc21.m4)dnl
   7
   8 # require autoconf 2.13
   9 AC_PREREQ(2.13)
  10
  11 # Process this file with autoconf to produce a configure script.
  12 AC_INIT(glib/glib.h)
  13
  14 # Save this value here, since automake will set cflags later
  15 cflags_set=${CFLAGS+set}
  16
  17 # we rewrite this file
  18 rm -f glibconfig-sysdefs.h
  19
  20 GLIB_AC_DIVERT_BEFORE_HELP([
  21 #
  22 # The following version number definitions apply to GLib, GModule, GObject
  23 # and GThread as a whole, so if changes occoured in any of them, they are all
  24 # treated with the same interface and binary age.
  25 #
  26 # Making releases:
  27 #   GLIB_MICRO_VERSION += 1;
  28 #   GLIB_INTERFACE_AGE += 1;
  29 #   GLIB_BINARY_AGE += 1;
  30 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  31 # if backwards compatibility has been broken,
  32 # set GLIB_BINARY_AGE _and_ GLIB_INTERFACE_AGE to 0.
  33 #
  34 GLIB_MAJOR_VERSION=1
  35 GLIB_MINOR_VERSION=3
  36 GLIB_MICRO_VERSION=12
  37 GLIB_INTERFACE_AGE=0
  38 GLIB_BINARY_AGE=0
  39 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  40 ])dnl
  41
  42 AC_SUBST(GLIB_MAJOR_VERSION)
  43 AC_SUBST(GLIB_MINOR_VERSION)
  44 AC_SUBST(GLIB_MICRO_VERSION)
  45 AC_SUBST(GLIB_VERSION)
  46 AC_SUBST(GLIB_INTERFACE_AGE)
  47 AC_SUBST(GLIB_BINARY_AGE)
  48
  49 # libtool versioning
  50 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  51 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  52 LT_REVISION=$GLIB_INTERFACE_AGE
  53 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  54 LT_CURRENT_MINUS_AGE=`expr $LT_CURRENT - $LT_AGE`
  55 AC_SUBST(LT_RELEASE)
  56 AC_SUBST(LT_CURRENT)
  57 AC_SUBST(LT_REVISION)
  58 AC_SUBST(LT_AGE)
  59 AC_SUBST(LT_CURRENT_MINUS_AGE)
  60
  61 VERSION=$GLIB_VERSION
  62 PACKAGE=glib
  63
  64 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  65
  66 # Specify a configuration file
  67 AM_CONFIG_HEADER(config.h)
  68
  69 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION,
  70                    [Define to the GLIB major version])
  71 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION,
  72                    [Define to the GLIB minor version])
  73 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION,
  74                    [Define to the GLIB micro version])
  75 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE,
  76                    [Define to the GLIB interface age])
  77 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE,
  78                    [Define to the GLIB binary age])
  79
  80 dnl Initialize maintainer mode
  81 AM_MAINTAINER_MODE
  82
  83 AC_CANONICAL_HOST
  84
  85 AC_MSG_CHECKING(for the BeOS)
  86 case $host in
  87   *-*-beos*)
  88     glib_native_beos="yes"
  89     ;;
  90   *)
  91     glib_native_beos="no"
  92     ;;
  93 esac
  94 AC_MSG_RESULT([$glib_native_beos])
  95
  96 dnl
  97
  98 AC_MSG_CHECKING([for Win32])
  99 case "$host" in
 100   *-*-mingw*)
 101     glib_native_win32=yes
 102     G_LIB_WIN32_RESOURCE=glib-win32res.lo
 103     G_MODULE_WIN32_RESOURCE=gmodule-win32res.lo
 104     G_OBJECT_WIN32_RESOURCE=gobject-win32res.lo
 105     G_THREAD_WIN32_RESOURCE=gthread-win32res.lo
 106     GLIB_DEF=glib.def
 107     GMODULE_DEF=gmodule.def
 108     GOBJECT_DEF=gobject.def
 109     GTHREAD_DEF=gthread.def
 110     TESTGMODULE_EXP=testgmodule.exp
 111     ;;
 112   *)
 113     glib_native_win32=no
 114     G_LIB_WIN32_RESOURCE=
 115     G_MODULE_WIN32_RESOURCE=
 116     G_OBJECT_WIN32_RESOURCE=
 117     G_THREAD_WIN32_RESOURCE=
 118     GLIB_DEF=
 119     GMODULE_DEF=
 120     GOBJECT_DEF=
 121     GTHREAD_DEF=
 122     TESTGMODULE_EXP=
 123     ;;
 124 esac
 125 AC_MSG_RESULT([$glib_native_win32])
 126 AM_CONDITIONAL(OS_WIN32, test "$glib_native_win32" = "yes")
 127 AC_SUBST(G_LIB_WIN32_RESOURCE)
 128 AC_SUBST(G_MODULE_WIN32_RESOURCE)
 129 AC_SUBST(G_OBJECT_WIN32_RESOURCE)
 130 AC_SUBST(G_THREAD_WIN32_RESOURCE)
 131 AC_SUBST(GLIB_DEF)
 132 AC_SUBST(GMODULE_DEF)
 133 AC_SUBST(GOBJECT_DEF)
 134 AC_SUBST(GTHREAD_DEF)
 135 AC_SUBST(TESTGMODULE_EXP)
 136
 137 if test "$glib_native_win32" = "yes"; then
 138   AC_CHECK_PROG(ms_librarian, lib.exe, yes, no)
 139 fi
 140 AM_CONDITIONAL(MS_LIB_AVAILABLE, test x$ms_librarian = xyes)
 141
 142 GLIB_AC_DIVERT_BEFORE_HELP([
 143 # figure debugging default, prior to $ac_help setup
 144 case $GLIB_MINOR_VERSION in
 145 *[[13579]]) debug_default=yes ;;
 146 *)          debug_default=minimum ;;
 147 esac[]dnl
 148 ])
 149
 150 dnl declare --enable-* args and collect ac_help strings
 151 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
 152 AC_ARG_ENABLE(gc_friendly, [  --enable-gc-friendly    turn on garbage collector friendliness [default=no]],,enable_gc_friendly=no)
 153 AC_ARG_ENABLE(mem_pools, [  --disable-mem-pools     disable all glib memory pools],,disable_mem_pools=no)
 154 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
 155                     , enable_ansi=no)
 156 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
 157                           ([=no] will override --with-threads)],,enable_threads=yes)
 158 AC_ARG_ENABLE(rebuilds, [  --disable-rebuilds      disable all source autogeneration rules],,enable_rebuilds=yes)
 159
 160 if test "x$enable_threads" != "xyes"; then
 161   enable_threads=no
 162 fi
 163
 164 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}",
 165         [Whether glib was compiled with debugging enabled])
 166
 167 AC_MSG_CHECKING(whether to enable garbage collector friendliness)
 168 if test "x$enable_gc_friendly" = "xyes"; then
 169   AC_DEFINE(ENABLE_GC_FRIENDLY, 1, [Whether to enable GC friendliness])
 170   AC_SUBST(ENABLE_GC_FRIENDLY)
 171   AC_MSG_RESULT(yes)
 172 else
 173   AC_MSG_RESULT(no)
 174 fi
 175
 176 AC_MSG_CHECKING(whether to disable memory pools)
 177 if test "x$disable_mem_pools" = "xno"; then
 178   AC_MSG_RESULT(no)
 179 else
 180   AC_DEFINE(DISABLE_MEM_POOLS, 1, [Whether to disable memory pools])
 181   AC_SUBST(DISABLE_MEM_POOLS)
 182   AC_MSG_RESULT(yes)
 183 fi
 184
 185 dnl Checks for programs.
 186 AC_PROG_CC
 187
 188 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 189 AC_CHECK_PROGS(CXX, $CCC c++ g++ gcc CC cxx cc++ cl, gcc)
 190 AC_LANG_SAVE
 191 AC_LANG_CPLUSPLUS
 192 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 193 AM_CONDITIONAL(HAVE_CXX, test "$CXX" != "")
 194 AC_LANG_RESTORE
 195
 196 AM_PROG_CC_STDC
 197 AC_PROG_INSTALL
 198
 199 #
 200 # Find pkg-config
 201 #
 202 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 203 if test x$PKG_CONFIG = xno ; then
 204   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
 205 fi
 206
 207 if pkg-config --atleast-pkgconfig-version 0.5 ; then
 208   :
 209 else
 210   AC_MSG_ERROR([*** pkg-config too old; version 0.5 or better required.])
 211 fi
 212
 213 if test "x$enable_debug" = "xyes"; then
 214   if test x$cflags_set != xset ; then
 215       case " $CFLAGS " in
 216       *[[\ \    ]]-g[[\ \       ]]*) ;;
 217       *) CFLAGS="$CFLAGS -g" ;;
 218       esac
 219   fi
 220
 221   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 222 else
 223   if test "x$enable_debug" = "xno"; then
 224     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 225   fi
 226 fi
 227
 228 # Ensure -fnative-struct is used when compiling for Win32
 229 if test "x$glib_native_win32" = "xyes"; then
 230   if test "x$GCC" = "xyes"; then
 231     case " $CFLAGS " in
 232     *[[\ \      ]]-fnative-struct[[\ \  ]]*) ;;
 233     *) CFLAGS="$CFLAGS -fnative-struct" ;;
 234     esac
 235   fi
 236 fi
 237
 238 AC_CYGWIN
 239 AC_EXEEXT
 240
 241 # define a MAINT-like variable REBUILD which is set if Perl
 242 # and awk are found, so autogenerated sources can be rebuilt
 243 AC_PROG_AWK
 244 AC_CHECK_PROGS(PERL, perl5 perl)
 245 # We would like indent, but don't require it.
 246 AC_CHECK_PROG(INDENT, indent, indent)
 247 REBUILD=\#
 248 if test "x$enable_rebuilds" = "xyes" && \
 249      test -n "$PERL" && \
 250      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 251      test -n "$AWK" ; then
 252   REBUILD=
 253 fi
 254 AC_SUBST(REBUILD)
 255
 256 # Need full path to Perl for glib-mkenums
 257 #
 258 if test "x$PERL" != x ; then
 259   AC_PATH_PROG(PERL_PATH, $PERL)
 260 else
 261   PERL_PATH="/usr/bin/env perl"
 262 fi
 263 AC_SUBST(PERL_PATH)
 264
 265 dnl
 266 dnl gettext support
 267 dnl
 268
 269 ALL_LINGUAS="az ca de es eu fr gl ja nl nn no pt ro ru sk sl sv ta tr uk zh_CN zh_TW"
 270 AM_GLIB_GNU_GETTEXT
 271
 272 if test "$gt_cv_func_dgettext_libc" = "yes" || test "$gt_cv_func_dgettext_libintl" = "yes"; then
 273   :
 274 else
 275   AC_MSG_ERROR([
 276 *** You must have either have gettext support in your C library, or use the
 277 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 278 ])
 279 fi
 280
 281 LIBS="$LIBS $INTLLIBS"
 282
 283 GETTEXT_PACKAGE=glib20
 284 AC_SUBST(GETTEXT_PACKAGE)
 285 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE")
 286
 287 # AM_GLIB_GNU_GETTEXT above substs $DATADIRNAME
 288 # this is the directory where the *.{mo,gmo} files are installed
 289 GLIB_LOCALE_DIR="${prefix}/${DATADIRNAME}/locale"
 290 AC_DEFINE_UNQUOTED(GLIB_LOCALE_DIR,"$GLIB_LOCALE_DIR")
 291
 292 dnl Initialize libtool
 293 AC_LIBTOOL_WIN32_DLL
 294 AM_PROG_LIBTOOL
 295
 296 if test "x$GCC" = "xyes"; then
 297   case " $CFLAGS " in
 298   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 299   *) CFLAGS="$CFLAGS -Wall" ;;
 300   esac
 301
 302   if test "x$enable_ansi" = "xyes"; then
 303     case " $CFLAGS " in
 304     *[[\ \      ]]-ansi[[\ \    ]]*) ;;
 305     *) CFLAGS="$CFLAGS -ansi" ;;
 306     esac
 307
 308     case " $CFLAGS " in
 309     *[[\ \      ]]-pedantic[[\ \        ]]*) ;;
 310     *) CFLAGS="$CFLAGS -pedantic" ;;
 311     esac
 312   fi
 313 fi
 314
 315 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 316 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 317 glib_save_LIBS=$LIBS
 318 LIBS="$LIBS -lm"
 319 AC_TRY_RUN([#include <math.h>
 320              int main (void) { return (log(1) != log(1.)); }],
 321      AC_MSG_RESULT(none needed),
 322      glib_save_CFLAGS=$CFLAGS
 323      CFLAGS="$CFLAGS -std1"
 324      AC_TRY_RUN([#include <math.h>
 325                  int main (void) { return (log(1) != log(1.)); }],
 326          AC_MSG_RESULT(-std1),
 327          AC_MSG_RESULT()
 328          CFLAGS=$glib_save_CFLAGS
 329          AC_MSG_WARN(
 330                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 331      )
 332 )
 333 LIBS=$glib_save_LIBS
 334
 335 dnl NeXTStep cc seems to need this
 336 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 337 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 338   AC_MSG_RESULT(none needed),
 339   glib_save_CFLAGS=$CFLAGS
 340   CFLAGS="$CFLAGS -posix"
 341   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 342     AC_MSG_RESULT(-posix),
 343     AC_MSG_RESULT()
 344     CFLAGS=$glib_save_CFLAGS
 345     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 346
 347 # Checks for header files.
 348 AC_HEADER_STDC
 349
 350 # Checks for library functions.
 351 AC_FUNC_VPRINTF
 352
 353 AC_FUNC_ALLOCA
 354
 355 AC_CHECK_FUNCS(atexit on_exit)
 356
 357 AC_CHECK_SIZEOF(char)
 358 AC_CHECK_SIZEOF(short)
 359 AC_CHECK_SIZEOF(long)
 360 AC_CHECK_SIZEOF(int)
 361 AC_CHECK_SIZEOF(void *)
 362 AC_CHECK_SIZEOF(long long)
 363 AC_CHECK_SIZEOF(__int64)
 364
 365 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 366   :
 367 else
 368   AC_MSG_ERROR([
 369 *** GLib requires a 64 bit type. You might want to consider
 370 *** using the GNU C compiler.
 371 ])
 372 fi
 373
 374 if test x$ac_cv_sizeof_long_long = x8; then
 375         # long long is a 64 bit integer.
 376         AC_MSG_CHECKING(for format to printf and scanf a gint64)
 377         AC_CACHE_VAL(glib_cv_long_long_format,[
 378                 for format in ll q I64; do
 379                   AC_TRY_RUN([#include <stdio.h>
 380                         int main()
 381                         {
 382                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 383                           char buffer[1000];
 384                           sprintf (buffer, "%${format}u", a);
 385                           sscanf (buffer, "%${format}u", &b);
 386                           exit (b!=a);
 387                         }
 388                         ],
 389                         glib_cv_long_long_format=${format}
 390                         break)
 391                 done])
 392         if test -n "$glib_cv_long_long_format"; then
 393           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 394         else
 395           AC_MSG_RESULT(none)
 396         fi
 397 elif test x$ac_cv_sizeof___int64 = x8; then
 398         # __int64 is a 64 bit integer.
 399         AC_MSG_CHECKING(for format to printf and scanf a gint64)
 400         # We know this is MSVC, and what the formats are
 401         glib_cv_long_long_format=I64
 402         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 403 fi
 404
 405 dnl long doubles were not used, and a portability problem
 406 dnl AC_C_LONG_DOUBLE
 407 AC_C_CONST
 408
 409 dnl ok, here we try to check whether the systems prototypes for
 410 dnl malloc and friends actually match the prototypes provided
 411 dnl by gmem.h (keep in sync). i currently only know how to check
 412 dnl this reliably with gcc (-Werror), improvements for other
 413 dnl compilers are apprechiated.
 414 SANE_MALLOC_PROTOS=no
 415 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 416 glib_save_CFLAGS=$CFLAGS
 417 if test "x$GCC" = "xyes"; then
 418   CFLAGS="$CFLAGS -Werror"
 419   AC_TRY_COMPILE([#include <stdlib.h>], [
 420     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 421     void* (*my_malloc_p)  (size_t)         = malloc;
 422     void  (*my_free_p)    (void*)          = free;
 423     void* (*my_realloc_p) (void*, size_t)  = realloc;
 424     my_calloc_p = 0;
 425     my_malloc_p = 0;
 426     my_free_p = 0;
 427     my_realloc_p = 0;
 428   ],
 429     AC_DEFINE(SANE_MALLOC_PROTOS)
 430     SANE_MALLOC_PROTOS=yes)
 431 fi
 432 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 433 CFLAGS=$glib_save_CFLAGS
 434
 435 dnl
 436 dnl check in which direction the stack grows
 437 dnl
 438 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 439         AC_TRY_RUN([
 440         volatile int *a = 0, *b = 0;
 441         void foo (void);
 442         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 443         void foo (void) { volatile int x = 5; b = &x; }
 444         ],
 445         glib_cv_stack_grows=no
 446         ,
 447         glib_cv_stack_grows=yes
 448         ,)
 449 ])
 450
 451 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 452 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 453 dnl actually supported.
 454 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 455         AC_TRY_RUN([
 456         __inline int foo () { return 0; }
 457         int main () { return foo (); }
 458         ],
 459         glib_cv_has__inline=yes
 460         ,
 461         glib_cv_has__inline=no
 462         ,)
 463 ])
 464 case x$glib_cv_has__inline in
 465 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 466 esac
 467 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 468         AC_TRY_RUN([
 469         __inline__ int foo () { return 0; }
 470         int main () { return foo (); }
 471         ],
 472         glib_cv_has__inline__=yes
 473         ,
 474         glib_cv_has__inline__=no
 475         ,)
 476 ])
 477 case x$glib_cv_has__inline__ in
 478 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 479 esac
 480 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 481         AC_TRY_RUN([
 482         #undef inline
 483         inline int foo () { return 0; }
 484         int main () { return foo (); }
 485         ],
 486         glib_cv_hasinline=yes
 487         ,
 488         glib_cv_hasinline=no
 489         ,)
 490 ])
 491 case x$glib_cv_hasinline in
 492 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 493 esac
 494
 495 # check for flavours of varargs macros
 496 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 497 AC_TRY_COMPILE([],[
 498 int a(int p1, int p2, int p3);
 499 #define call_a(...) a(1,__VA_ARGS__)
 500 call_a(2,3);
 501 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 502 AC_MSG_RESULT($g_have_iso_c_varargs)
 503
 504 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 505 if test "$CXX" = ""; then
 506 dnl No C++ compiler
 507   g_have_iso_cxx_varargs=no
 508 else
 509   AC_LANG_CPLUSPLUS
 510   AC_TRY_COMPILE([],[
 511 int a(int p1, int p2, int p3);
 512 #define call_a(...) a(1,__VA_ARGS__)
 513 call_a(2,3);
 514 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 515   AC_LANG_C
 516 fi
 517 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 518
 519 AC_MSG_CHECKING(for GNUC varargs macros)
 520 AC_TRY_COMPILE([],[
 521 int a(int p1, int p2, int p3);
 522 #define call_a(params...) a(1,params)
 523 call_a(2,3);
 524 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 525 AC_MSG_RESULT($g_have_gnuc_varargs)
 526
 527 # check for bytesex stuff
 528 AC_C_BIGENDIAN
 529
 530 # check for header files
 531 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h sys/param.h sys/poll.h sys/select.h])
 532 AC_CHECK_HEADERS([sys/time.h sys/times.h unistd.h values.h stdint.h sched.h])
 533
 534 # Checks for libcharset
 535 jm_LANGINFO_CODESET
 536 jm_GLIBC21
 537 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 538 AC_CHECK_FUNCS(setlocale)
 539
 540 AC_MSG_CHECKING(whether make is GNU Make)
 541 STRIP_BEGIN=
 542 STRIP_END=
 543 if $ac_make --version 2>/dev/null | grep '^GNU Make ' >/dev/null ; then
 544         STRIP_BEGIN='$(strip $(STRIP_DUMMY)'
 545         STRIP_END=')'
 546         AC_MSG_RESULT(yes)
 547 else
 548         AC_MSG_RESULT(no)
 549 fi
 550 STRIP_DUMMY=
 551 AC_SUBST(STRIP_DUMMY)
 552 AC_SUBST(STRIP_BEGIN)
 553 AC_SUBST(STRIP_END)
 554
 555 # check additional type sizes
 556 size_includes=["
 557 #include <stdarg.h>
 558 #include <stdio.h>
 559 #include <ctype.h>
 560 #include <string.h>
 561 "]
 562 if test "x$ac_cv_header_stdint_h" = "xyes"; then
 563   size_includes=["$size_includes
 564 #include <stdint.h>
 565 "]
 566 fi
 567 if test "x$ac_cv_header_unistd_h" = "xyes"; then
 568   size_includes=["$size_includes
 569 #include <unistd.h>
 570 "]
 571 fi
 572 GLIB_SIZEOF([$size_includes], size_t, size_t)
 573 GLIB_SIZEOF([$size_includes], ptrdiff_t, ptrdiff_t)
 574 GLIB_SIZEOF([$size_includes], intmax_t, intmax_t)
 575
 576 # Check for some functions
 577 AC_CHECK_FUNCS(lstat strerror strsignal memmove mkstemp vsnprintf stpcpy strcasecmp strncasecmp poll getcwd nanosleep vasprintf)
 578
 579 AC_FUNC_VSNPRINTF_C99
 580
 581 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 582 # The check is borrowed from the PERL Configure script.
 583 if test "$ac_cv_func_memmove" != "yes"; then
 584   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 585     glib_cv_working_bcopy,[AC_TRY_RUN([
 586       int main() {
 587         char buf[128], abc[128], *b;
 588         int len, off, align;
 589         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 590         for (align = 7; align >= 0; align--) {
 591           for (len = 36; len; len--) {
 592             b = buf+align; bcopy(abc, b, len);
 593             for (off = 1; off <= len; off++) {
 594               bcopy(b, b+off, len); bcopy(b+off, b, len);
 595                 if (bcmp(b, abc, len)) return(1);
 596             }
 597           }
 598         }
 599         return(0);
 600       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 601   if test "$glib_cv_working_bcopy" = "yes"; then
 602     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 603   fi
 604 fi
 605
 606 # Check for sys_errlist
 607 AC_MSG_CHECKING(for sys_errlist)
 608 AC_TRY_LINK(, [
 609 extern char *sys_errlist[];
 610 extern int sys_nerr;
 611 sys_errlist[sys_nerr-1][0] = 0;
 612 ], glib_ok=yes, glib_ok=no)
 613 AC_MSG_RESULT($glib_ok)
 614 if test "$glib_ok" = "no"; then
 615     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 616 fi
 617
 618 # Check for sys_siglist
 619 AC_MSG_CHECKING(for sys_siglist)
 620 AC_TRY_LINK(, [
 621 extern char *sys_siglist[];
 622 exit (sys_siglist[0]);
 623 ], glib_ok=yes, glib_ok=no)
 624 AC_MSG_RESULT($glib_ok)
 625 if test "$glib_ok" = "no"; then
 626     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 627 fi
 628
 629 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 630 AC_MSG_CHECKING(for sys_siglist declaration)
 631 AC_TRY_COMPILE([#include <signal.h>], [
 632 strlen (sys_siglist[0]);
 633 ], glib_ok=yes, glib_ok=no)
 634 AC_MSG_RESULT($glib_ok)
 635 if test "$glib_ok" = "no"; then
 636     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 637 fi
 638
 639 # Check if <sys/select.h> needs to be included for fd_set
 640 AC_MSG_CHECKING([for fd_set])
 641 AC_TRY_COMPILE([#include <sys/types.h>],
 642         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 643 if test "$gtk_ok" = "yes"; then
 644     AC_MSG_RESULT([yes, found in sys/types.h])
 645 else
 646     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
 647     if test "$gtk_ok" = "yes"; then
 648         # *** FIXME: give it a different name
 649         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
 650         AC_MSG_RESULT([yes, found in sys/select.h])
 651     else
 652         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
 653         AC_MSG_RESULT(no)
 654     fi
 655 fi
 656
 657 dnl *** check for sane realloc() ***
 658 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
 659         AC_TRY_RUN([
 660         #include <stdlib.h>
 661         int main() {
 662           return realloc (0, sizeof (int)) == 0;
 663         }],
 664         [glib_cv_sane_realloc=yes],
 665         [glib_cv_sane_realloc=no],
 666         [])
 667 ])
 668 if test x$glib_cv_sane_realloc = xyes; then
 669   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
 670 fi
 671
 672 dnl Check for nl_langinfo and CODESET
 673
 674 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
 675 AC_TRY_COMPILE([#include <langinfo.h>],
 676         [char *codeset = nl_langinfo (CODESET);],
 677    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
 678    have_codeset=yes,
 679    have_codeset=no)
 680 AC_MSG_RESULT($have_codeset)
 681
 682
 683 dnl ****************************************
 684 dnl *** strlcpy/strlcat                  ***
 685 dnl ****************************************
 686 # Check for strlcpy
 687 AC_MSG_CHECKING(for strlcpy/strlcat)
 688 AC_TRY_LINK([#include <stdlib.h>
 689 #include <string.h>], [
 690 char *p = malloc(10);
 691 (void) strlcpy(p, "hi", 10);
 692 (void) strlcat(p, "bye", 10);
 693 ], glib_ok=yes, glib_ok=no)
 694 AC_MSG_RESULT($glib_ok)
 695 if test "$glib_ok" = "yes"; then
 696     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
 697 fi
 698
 699
 700 dnl **********************
 701 dnl *** va_copy checks ***
 702 dnl **********************
 703 dnl we currently check for all three va_copy possibilities, so we get
 704 dnl all results in config.log for bug reports.
 705 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
 706         AC_TRY_RUN([
 707         #include <stdarg.h>
 708         void f (int i, ...) {
 709         va_list args1, args2;
 710         va_start (args1, i);
 711         va_copy (args2, args1);
 712         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 713           exit (1);
 714         va_end (args1); va_end (args2);
 715         }
 716         int main() {
 717           f (0, 42);
 718           return 0;
 719         }],
 720         [glib_cv_va_copy=yes],
 721         [glib_cv_va_copy=no],
 722         [])
 723 ])
 724 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
 725         AC_TRY_RUN([
 726         #include <stdarg.h>
 727         void f (int i, ...) {
 728         va_list args1, args2;
 729         va_start (args1, i);
 730         __va_copy (args2, args1);
 731         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 732           exit (1);
 733         va_end (args1); va_end (args2);
 734         }
 735         int main() {
 736           f (0, 42);
 737           return 0;
 738         }],
 739         [glib_cv___va_copy=yes],
 740         [glib_cv___va_copy=no],
 741         [])
 742 ])
 743
 744 if test "x$glib_cv_va_copy" = "xyes"; then
 745   g_va_copy_func=va_copy
 746 else if test "x$glib_cv___va_copy" = "xyes"; then
 747   g_va_copy_func=__va_copy
 748 fi
 749 fi
 750
 751 if test -n "$g_va_copy_func"; then
 752   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
 753 fi
 754
 755 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
 756         AC_TRY_RUN([
 757         #include <stdarg.h>
 758         void f (int i, ...) {
 759         va_list args1, args2;
 760         va_start (args1, i);
 761         args2 = args1;
 762         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 763           exit (1);
 764         va_end (args1); va_end (args2);
 765         }
 766         int main() {
 767           f (0, 42);
 768           return 0;
 769         }],
 770         [glib_cv_va_val_copy=yes],
 771         [glib_cv_va_val_copy=no],
 772         [])
 773 ])
 774
 775 if test "x$glib_cv_va_val_copy" = "xno"; then
 776   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 777 fi
 778
 779 dnl ***********************
 780 dnl *** g_module checks ***
 781 dnl ***********************
 782 G_MODULE_LIBS=
 783 G_MODULE_LIBS_EXTRA=
 784 G_MODULE_PLUGIN_LIBS=
 785 G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
 786 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
 787 G_MODULE_NEED_USCORE=0
 788 G_MODULE_BROKEN_RTLD_GLOBAL=0
 789 G_MODULE_HAVE_DLERROR=0
 790 dnl *** force native WIN32 shared lib loader
 791 if test -z "$G_MODULE_IMPL"; then
 792   case "$host" in
 793   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
 794   esac
 795 fi
 796 dnl *** dlopen() and dlsym() in system libraries
 797 if test -z "$G_MODULE_IMPL"; then
 798         AC_CHECK_FUNC(dlopen,
 799                       [AC_CHECK_FUNC(dlsym,
 800                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 801                       [])
 802 fi
 803 dnl *** load_image (BeOS)
 804 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
 805   AC_CHECK_LIB(root, load_image,
 806       [G_MODULE_LIBS="-lbe -lroot -lglib"
 807       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
 808       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
 809       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
 810       [])
 811 fi
 812 dnl *** dlopen() and dlsym() in libdl
 813 if test -z "$G_MODULE_IMPL"; then
 814         AC_CHECK_LIB(dl, dlopen,
 815                      [AC_CHECK_LIB(dl, dlsym,
 816                                    [G_MODULE_LIBS=-ldl
 817                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
 818                      [])
 819 fi
 820 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
 821 if test -z "$G_MODULE_IMPL"; then
 822         AC_CHECK_FUNC(NSLinkModule,
 823                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
 824                        G_MODULE_NEED_USCORE=1],
 825                       [])
 826 fi
 827 dnl *** shl_load() in libdld (HP-UX)
 828 if test -z "$G_MODULE_IMPL"; then
 829         AC_CHECK_LIB(dld, shl_load,
 830                 [G_MODULE_LIBS=-ldld
 831                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
 832                 [])
 833 fi
 834 dnl *** additional checks for G_MODULE_IMPL_DL
 835 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 836         LIBS_orig="$LIBS"
 837         LDFLAGS_orig="$LDFLAGS"
 838         LIBS="$LIBS $G_MODULE_LIBS"
 839         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 840 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
 841         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
 842                 glib_cv_rtldglobal_broken,[
 843                 AC_TRY_RUN([
 844                 #include <dlfcn.h>
 845                 #ifndef RTLD_GLOBAL
 846                 #define RTLD_GLOBAL 0
 847                 #endif
 848                 #ifndef RTLD_LAZY
 849                 #define RTLD_LAZY 0
 850                 #endif
 851                 int pthread_create;
 852                 int main () {
 853                 void *handle, *global, *local;
 854                 global = &pthread_create;
 855                 handle = dlopen ("libpthread.so", RTLD_GLOBAL | RTLD_LAZY);
 856                 if (!handle) return 0;
 857                 local = dlsym (handle, "pthread_create");
 858                 return global == local;
 859                 }],
 860                         [glib_cv_rtldglobal_broken=no],
 861                         [glib_cv_rtldglobal_broken=yes],
 862                         [])
 863                 rm -f plugin.c plugin.o plugin.lo
 864         ])
 865         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
 866                 G_MODULE_BROKEN_RTLD_GLOBAL=1
 867         else
 868                 G_MODULE_BROKEN_RTLD_GLOBAL=0
 869         fi
 870 dnl *** check whether we need preceeding underscores
 871         AC_CACHE_CHECK([for preceeding underscore in symbols],
 872                 glib_cv_uscore,[
 873                 AC_TRY_RUN([
 874                 #include <dlfcn.h>
 875                 int glib_underscore_test (void) { return 42; }
 876                 int main() {
 877                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 878                   handle = dlopen ((void*)0, 0);
 879                   if (handle) {
 880                     f1 = dlsym (handle, "glib_underscore_test");
 881                     f2 = dlsym (handle, "_glib_underscore_test");
 882                   } return (!f2 || f1);
 883                 }],
 884                         [glib_cv_uscore=yes],
 885                         [glib_cv_uscore=no],
 886                         [])
 887                 rm -f plugin.c plugin.$ac_objext plugin.lo
 888         ])
 889         if test "x$glib_cv_uscore" = "xyes"; then
 890                 G_MODULE_NEED_USCORE=1
 891         else
 892                 G_MODULE_NEED_USCORE=0
 893         fi
 894
 895         LDFLAGS="$LDFLAGS_orig"
 896 dnl *** check for having dlerror()
 897         AC_CHECK_FUNC(dlerror,
 898                 [G_MODULE_HAVE_DLERROR=1],
 899                 [G_MODULE_HAVE_DLERROR=0])
 900         LIBS="$LIBS_orig"
 901 fi
 902 dnl *** done, have we got an implementation?
 903 if test -z "$G_MODULE_IMPL"; then
 904         G_MODULE_IMPL=0
 905         G_MODULE_SUPPORTED=false
 906 else
 907         G_MODULE_SUPPORTED=true
 908 fi
 909
 910 AC_MSG_CHECKING(for the suffix of shared libraries)
 911 case "$host_os" in
 912   hpux9* | hpux10* | hpux11*)  # taken from ltconfig
 913     glib_gmodule_suffix='sl'
 914     ;;
 915   cygwin* | mingw*)
 916     glib_gmodule_suffix='dll'
 917     ;;
 918   *)
 919     glib_gmodule_suffix='so'
 920     ;;
 921 esac
 922 AC_MSG_RESULT(.$glib_gmodule_suffix)
 923
 924 AC_SUBST(G_MODULE_SUPPORTED)
 925 AC_SUBST(G_MODULE_IMPL)
 926 AC_SUBST(G_MODULE_LIBS)
 927 AC_SUBST(G_MODULE_LIBS_EXTRA)
 928 AC_SUBST(G_MODULE_PLUGIN_LIBS)
 929 AC_SUBST(G_MODULE_LDFLAGS)
 930 AC_SUBST(G_MODULE_HAVE_DLERROR)
 931 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
 932 AC_SUBST(G_MODULE_NEED_USCORE)
 933 AC_SUBST(GLIB_DEBUG_FLAGS)
 934
 935 dnl **********************
 936 dnl *** g_spawn checks ***
 937 dnl **********************
 938
 939 AC_MSG_CHECKING(for gspawn implementation)
 940 case "$host" in
 941   *-*-mingw*)
 942     GSPAWN=gspawn-win32.lo
 943     ;;
 944   *)
 945     GSPAWN=gspawn.lo
 946     ;;
 947 esac
 948 AC_MSG_RESULT($GSPAWN)
 949 AC_SUBST(GSPAWN)
 950
 951 dnl *************************
 952 dnl *** GIOChannel checks ***
 953 dnl *************************
 954
 955 AC_MSG_CHECKING(for GIOChannel implementation)
 956 case "$host" in
 957   *-*-mingw*)
 958     GIO=giowin32.lo
 959     ;;
 960   *)
 961     GIO=giounix.lo
 962     ;;
 963 esac
 964 AC_MSG_RESULT($GIO)
 965 AC_SUBST(GIO)
 966
 967 dnl ****************************************
 968 dnl *** platform dependent source checks ***
 969 dnl ****************************************
 970
 971 AC_MSG_CHECKING(for platform-dependent source)
 972 case "$host" in
 973   *-*-cygwin*|*-*-mingw*)
 974     PLATFORMDEP=gwin32.lo
 975     ;;
 976   *)
 977     PLATFORMDEP=
 978     ;;
 979 esac
 980 AC_MSG_RESULT($PLATFORMDEP)
 981 AC_SUBST(PLATFORMDEP)
 982
 983 AC_MSG_CHECKING([whether to compile timeloop])
 984 case "$host" in
 985   *-*-cygwin*|*-*-mingw*)
 986     enable_timeloop=no
 987     ;;
 988   *)
 989     enable_timeloop=yes
 990     ;;
 991 esac
 992 AC_MSG_RESULT($enable_timeloop)
 993 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
 994
 995 AC_MSG_CHECKING([if building for some Win32 platform])
 996 case "$host" in
 997   *-*-mingw*|*-*-cygwin*)
 998     platform_win32=yes
 999     ;;
1000   *)
1001     platform_win32=no
1002     ;;
1003 esac
1004 AC_MSG_RESULT($platform_win32)
1005 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1006
1007 dnl ***********************
1008 dnl *** g_thread checks ***
1009 dnl ***********************
1010
1011 AC_ARG_WITH(threads, [  --with-threads=[none/posix/dce/solaris/win32] specify a thread implementation to use],
1012         if test "x$with_threads" = x; then
1013                 want_threads=yes
1014         else
1015                 want_threads=$with_threads
1016         fi,
1017         want_threads=yes)
1018 if test "x$enable_threads" = "xno"; then
1019         want_threads=no
1020 fi
1021
1022 dnl error and warning message
1023 dnl *************************
1024
1025 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1026                 computer. GLib will not have a default thread implementation."
1027
1028 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1029                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1030                 compilation now, but then your programs might not work.
1031                 Please provide information on how it is done on your system."
1032
1033 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1034                 "
1035
1036 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1037                 provide information on your thread implementation.
1038                 You can also run 'configure --disable-threads'
1039                 to compile without thread support."
1040
1041 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1042                 functions will not be MT-safe during their first call because
1043                 there is no working 'getpwuid_r' on your system."
1044
1045 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1046                 because there is no 'localtime_r' on your system."
1047
1048 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1049                 crude surrogate will be used. If you happen to know a
1050                 yield function for your system, please inform the GLib
1051                 developers."
1052
1053 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1054                 threads on your system. Thus threads can only have the default
1055                 priority. If you happen to know these main/max
1056                 priorities, please inform the GLib developers."
1057
1058
1059 dnl determination of thread implementation
1060 dnl ***************************************
1061
1062 # have_threads=no   means no thread support
1063 # have_threads=none means no default thread implementation
1064
1065 have_threads=no
1066 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
1067         case $host in
1068                 *-*-solaris*)
1069                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
1070                 ;;
1071         esac
1072 fi
1073 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1074                                 || test "x$want_threads" = xdce; then
1075         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1076         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1077         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1078         glib_save_CPPFLAGS="$CPPFLAGS"
1079         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1080         if test "x$have_threads" = xno; then
1081                 AC_TRY_COMPILE([#include <pthread.h>],
1082                         [pthread_attr_t attr; pthread_attr_init(&attr);],
1083                         have_threads=posix)
1084         fi
1085         if test "x$have_threads" = xno; then
1086                 AC_TRY_COMPILE([#include <pthread.h>],
1087                         [pthread_attr_t attr; pthread_attr_create(&attr);],
1088                         have_threads=posix)
1089         fi
1090         CPPFLAGS="$glib_save_CPPFLAGS"
1091 fi
1092 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1093         case $host in
1094                 *-*-mingw*)
1095                 have_threads=win32
1096                 ;;
1097         esac
1098 fi
1099 if test "x$want_threads" = xnone; then
1100         have_threads=none
1101 fi
1102
1103 AC_MSG_CHECKING(for thread implementation)
1104
1105 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1106         AC_MSG_RESULT(none available)
1107         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1108 else
1109         AC_MSG_RESULT($have_threads)
1110 fi
1111
1112
1113 dnl determination of G_THREAD_CFLAGS
1114 dnl ********************************
1115
1116 G_THREAD_LIBS=
1117 G_THREAD_LIBS_EXTRA=
1118 G_THREAD_CFLAGS=
1119
1120 if test x"$have_threads" != xno; then
1121
1122     G_THREAD_CFLAGS="-D_REENTRANT" # good default guess
1123
1124     case $host in
1125         *-aix*)
1126                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
1127                 if test x"$GCC" = xyes; then
1128                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
1129                 fi
1130                 ;;
1131         *-freebsd2.2*)
1132                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
1133
1134                 # FreeBSD 2.2.x shiped with gcc 2.7.2.x, which doesn't support
1135                 # -mthreads flag.
1136                 ;;
1137         *-sysv5uw7*)  # UnixWare 7
1138                 if test "$GCC" != "yes"; then
1139                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -Kthread"
1140                 else
1141                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -pthread"
1142                 fi
1143                 ;;
1144         *-dg-dgux*)  # DG/UX
1145                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_POSIX4A_DRAFT10_SOURCE"
1146     esac
1147
1148     # if we are not finding the localtime_r function, then we probably are
1149     # not using the proper multithread flag
1150
1151     glib_save_CPPFLAGS="$CPPFLAGS"
1152     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1153
1154     # First we test, whether localtime_r is declared in time.h
1155     # directly. Then we test whether a macro localtime_r exists, in
1156     # which case localtime_r in the test program is replaced and thus
1157     # if we still find localtime_r in the output, it is not defined as
1158     # a macro.
1159
1160     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1161       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1162                                                            localtime_r(a,b)],
1163                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1164
1165     CPPFLAGS="$glib_save_CPPFLAGS"
1166
1167     AC_MSG_CHECKING(thread related cflags)
1168     AC_MSG_RESULT($G_THREAD_CFLAGS)
1169     CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
1170 fi
1171
1172 dnl determination of G_THREAD_LIBS
1173 dnl ******************************
1174
1175 mutex_has_default=no
1176 case $have_threads in
1177         posix|dce)
1178            glib_save_CPPFLAGS="$CPPFLAGS"
1179            CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1180            G_THREAD_LIBS=error
1181            glib_save_LIBS="$LIBS"
1182            case $host in
1183              *-sysv5uw7*) # UnixWare 7
1184                 if test "$GCC" != "yes"; then
1185                         G_THREAD_LIBS="-Kthread"
1186                 else
1187                         G_THREAD_LIBS="-pthread"
1188                 fi
1189                 ;;
1190              *)
1191                 for thread_lib in "" pthread pthread32 pthreads c_r thread dce; do
1192                         if test x"$thread_lib" = x; then
1193                                 add_thread_lib=""
1194                                 IN=""
1195                         else
1196                                 add_thread_lib="-l$thread_lib"
1197                                 IN=" in -l$thread_lib"
1198                         fi
1199                         if test x"$have_threads" = xposix; then
1200                                 defattr=0
1201                         else
1202                                 defattr=pthread_attr_default
1203                         fi
1204
1205                         LIBS="$glib_save_LIBS $add_thread_lib"
1206
1207                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
1208                         AC_TRY_RUN([#include <pthread.h>
1209                                 int check_me = 0;
1210                                 void* func(void* data) {check_me = 42;}
1211                                 main()
1212                                 { pthread_t t;
1213                                   void *ret;
1214                                   pthread_create (&t, $defattr, func, 0);
1215                                   pthread_join (t, &ret);
1216                                   exit (check_me != 42);
1217                                 }],
1218                                 [AC_MSG_RESULT(yes)
1219                                 G_THREAD_LIBS="$add_thread_lib"
1220                                 break],
1221                                 [AC_MSG_RESULT(no)])
1222                 done
1223                 if test "x$G_THREAD_LIBS" = xerror; then
1224                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1225                 fi
1226                 for thread_lib in "" rt rte; do
1227                         if test x"$thread_lib" = x; then
1228                                 add_thread_lib=""
1229                                 IN=""
1230                         else
1231                                 add_thread_lib="-l$thread_lib"
1232                                 IN=" in -l$thread_lib"
1233                         fi
1234                         LIBS="$glib_save_LIBS $add_thread_lib"
1235
1236                         AC_MSG_CHECKING(for sched_get_priority_min$IN)
1237                         AC_TRY_RUN([#include <sched.h>
1238                                 #include <errno.h>
1239                                 int main() {
1240                                 errno = 0;
1241                                 return sched_get_priority_min(SCHED_OTHER)==-1
1242                                         && errno != 0;
1243                                 }],
1244                                 [AC_MSG_RESULT(yes)
1245                                 G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
1246                                 posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
1247                                 posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
1248                                 break],
1249                                 [AC_MSG_RESULT(no)])
1250                 done
1251                 LIBS="$glib_save_LIBS"
1252                 ;;
1253            esac
1254            mutex_has_default=yes
1255            mutex_default_type='pthread_mutex_t'
1256            mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
1257            mutex_header_file='pthread.h'
1258            if test "x$have_threads" = "xposix"; then
1259              g_threads_impl="POSIX"
1260            else
1261              g_threads_impl="DCE"
1262              have_threads="posix"
1263            fi
1264            AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
1265            CPPFLAGS="$glib_save_CPPFLAGS"
1266            ;;
1267         solaris)
1268            G_THREAD_LIBS=error
1269            AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
1270            mutex_has_default=yes
1271            mutex_default_type='mutex_t'
1272            mutex_default_init="DEFAULTMUTEX"
1273            mutex_header_file='thread.h'
1274            g_threads_impl="SOLARIS"
1275            ;;
1276         win32)
1277            g_threads_impl="WIN32"
1278            G_THREAD_LIBS=""
1279            ;;
1280         none)
1281            g_threads_impl="NONE"
1282            ;;
1283         *)
1284            g_threads_impl="NONE"
1285            G_THREAD_LIBS=error
1286            ;;
1287 esac
1288
1289 if test "x$G_THREAD_LIBS" = xerror; then
1290         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1291 fi
1292
1293 case $host in
1294   *-*-beos*)
1295     G_THREAD_LIBS="-lbe -lroot -lglib "
1296     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1297     ;;
1298   *)
1299     ;;
1300 esac
1301
1302 AC_MSG_CHECKING(thread related libraries)
1303 AC_MSG_RESULT($G_THREAD_LIBS)
1304
1305 dnl check for mt safe function variants and some posix functions
1306 dnl ************************************************************
1307
1308 if test x"$have_threads" != xno; then
1309         glib_save_LIBS="$LIBS"
1310         # we are not doing the following for now, as this might require glib
1311         # to always be linked with the thread libs on some platforms.
1312         # LIBS="$LIBS $G_THREAD_LIBS"
1313         AC_CHECK_FUNCS(localtime_r)
1314         if test "$ac_cv_header_pwd_h" = "yes"; then
1315                 AC_CACHE_CHECK([for posix getpwuid_r],
1316                         ac_cv_func_posix_getpwuid_r,
1317                         [AC_TRY_RUN([#include <errno.h>
1318                                 #include <pwd.h>
1319                                 int main () { char buffer[10000];
1320                                 struct passwd pwd, *pwptr = &pwd;
1321                                 int error;
1322                                 errno = 0;
1323                                 error = getpwuid_r (0, &pwd, buffer,
1324                                         sizeof (buffer), &pwptr);
1325                                 return (error < 0 && errno == ENOSYS)
1326                                         || error == ENOSYS; }],
1327                                 [ac_cv_func_posix_getpwuid_r=yes],
1328                                 [ac_cv_func_posix_getpwuid_r=no])])
1329                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
1330                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
1331                                 [Have POSIX function getpwuid_r])
1332                 else
1333                         AC_CACHE_CHECK([for nonposix getpwuid_r],
1334                                 ac_cv_func_nonposix_getpwuid_r,
1335                                 [AC_TRY_LINK([#include <pwd.h>],
1336                                         [char buffer[10000];
1337                                         struct passwd pwd;
1338                                         getpwuid_r (0, &pwd, buffer,
1339                                                         sizeof (buffer));],
1340                                         [ac_cv_func_nonposix_getpwuid_r=yes],
1341                                         [ac_cv_func_nonposix_getpwuid_r=no])])
1342                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
1343                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
1344                                         [Have non-POSIX function getpwuid_r])
1345                         fi
1346                 fi
1347         fi
1348         LIBS="$LIBS $G_THREAD_LIBS"
1349         if test x"$have_threads" = xposix; then
1350                 glib_save_CPPFLAGS="$CPPFLAGS"
1351                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1352                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
1353                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
1354                 # This is not AC_CHECK_FUNC to also work with function
1355                 # name mangling in header files.
1356                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1357                 AC_TRY_LINK([#include <pthread.h>],
1358                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1359                         [AC_MSG_RESULT(yes)
1360                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1361                                   [Have function pthread_attr_setstacksize])],
1362                         [AC_MSG_RESULT(no)])
1363                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1364                 if test x"$posix_priority_min" = xnone; then
1365                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1366                                 PX_PRIO_MIN],,[
1367                                 posix_priority_min=PX_PRIO_MIN
1368                                 posix_priority_max=PX_PRIO_MAX])
1369                 fi
1370                 if test x"$posix_priority_min" = xnone; then
1371                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1372                                 PRI_OTHER_MIN],,[
1373                                 posix_priority_min=PRI_OTHER_MIN
1374                                 posix_priority_max=PRI_OTHER_MAX])
1375                 fi
1376                 if test x"$posix_priority_min" = x; then
1377                         AC_MSG_RESULT(none found)
1378                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1379                         posix_priority_min=-1
1380                         posix_priority_max=-1
1381                 else
1382                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1383                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1384                         AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])
1385                 fi
1386                 posix_yield_func=none
1387                 AC_MSG_CHECKING(for posix yield function)
1388                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1389                                                         thr_yield; do
1390                         AC_TRY_LINK([#include <pthread.h>],
1391                                 [$yield_func()],
1392                                 [posix_yield_func="$yield_func"
1393                                 break])
1394                 done
1395                 if test x"$posix_yield_func" = xnone; then
1396                         AC_MSG_RESULT(none found)
1397                         AC_MSG_WARN($POSIX_NO_YIELD)
1398                         posix_yield_func="g_usleep(1000)"
1399                 else
1400                         AC_MSG_RESULT($posix_yield_func)
1401                         posix_yield_func="$posix_yield_func()"
1402                 fi
1403                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1404                 CPPFLAGS="$glib_save_CPPFLAGS"
1405
1406                 AC_MSG_CHECKING(whether to use the PID niceness surrogate for thread priorities)
1407                 AC_TRY_RUN([#include <pthread.h>
1408                         #include <sys/types.h>
1409                         #include <unistd.h>
1410                         pid_t other_pid = 0;
1411
1412                         void* func(void* data) {other_pid = getpid();}
1413                         main()
1414                         { pthread_t t;
1415                           void *ret;
1416                           pthread_create (&t, $defattr, func, NULL);
1417                           pthread_join (t, &ret);
1418                           exit (getpid()==other_pid ||
1419                                 $posix_priority_min != $posix_priority_max);
1420                         }],
1421                         [AC_MSG_RESULT(yes)
1422                           AC_DEFINE(G_THREAD_USE_PID_SURROGATE, 1, [whether to use the PID niceness surrogate for thread priorities])
1423                         ],
1424                         [AC_MSG_RESULT(no)])
1425         elif test x"$have_threads" = xwin32; then
1426                 # It's a pointer to a private struct
1427                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
1428         elif test x"$have_threads" = xsolaris; then
1429                 GLIB_SIZEOF([#include <thread.h>], thread_t, system_thread)
1430         fi
1431
1432         LIBS="$glib_save_LIBS"
1433
1434         # now spit out all the warnings.
1435         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1436            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1437                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1438         fi
1439         if test "$ac_cv_func_localtime_r" != "yes"; then
1440                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1441         fi
1442 fi
1443
1444 if test x"$glib_cv_sizeof_system_thread" = x; then
1445    # use a pointer as a fallback.
1446    GLIB_SIZEOF(,void *, system_thread)
1447 fi
1448
1449 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1450                    [Source file containing theread implementation])
1451 AC_SUBST(G_THREAD_CFLAGS)
1452 AC_SUBST(G_THREAD_LIBS)
1453 AC_SUBST(G_THREAD_LIBS_EXTRA)
1454
1455 dnl **********************************************
1456 dnl *** GDefaultMutex setup and initialization ***
1457 dnl **********************************************
1458 dnl
1459 dnl if mutex_has_default = yes, we also got
1460 dnl mutex_default_type, mutex_default_init and mutex_header_file
1461 GLIB_IF_VAR_EQ(mutex_has_default, yes,
1462         glib_save_CPPFLAGS="$CPPFLAGS"
1463         glib_save_LIBS="$LIBS"
1464         LIBS="$LIBS $G_THREAD_LIBS"
1465         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1466         GLIB_SIZEOF([#include <$mutex_header_file>],
1467                     $mutex_default_type,
1468                     gmutex,
1469                     )
1470         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1471                            $mutex_default_type,
1472                            gmutex,
1473                            $glib_cv_sizeof_gmutex,
1474                            $mutex_default_init)
1475         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1476                 mutex_has_default=no
1477         fi
1478         CPPFLAGS="$glib_save_CPPFLAGS"
1479         LIBS="$glib_save_LIBS"
1480         ,
1481 )
1482
1483
1484 dnl ****************************************
1485 dnl *** GLib POLL* compatibility defines ***
1486 dnl ****************************************
1487 GLIB_SYSDEFS(
1488 [#include <sys/types.h>
1489 #include <sys/poll.h>],
1490         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
1491         glibconfig-sysdefs.h,
1492         =)
1493
1494 dnl **********************
1495 dnl *** Win32 API libs ***
1496 dnl **********************
1497
1498 case $host in
1499   *-*-cygwin*)
1500         G_LIBS_EXTRA="-luser32 -lwsock32 -lkernel32"
1501     ;;
1502   *-*-mingw*)
1503         G_LIBS_EXTRA="-lwsock32"
1504     ;;
1505   *)
1506         G_LIBS_EXTRA=""
1507     ;;
1508 esac
1509 AC_SUBST(G_LIBS_EXTRA)
1510
1511 dnl ***********************
1512 dnl *** Tests for iconv ***
1513 dnl ***********************
1514
1515 AC_ARG_WITH(libiconv, [ --with-libiconv     Use the libiconv library ],,with_libiconv=maybe)
1516
1517 found_iconv=no
1518
1519 if test "x$with_libiconv" != "xyes" ; then
1520    #
1521    # Check in the C library
1522    #
1523    AC_CHECK_FUNC(iconv_open, with_libiconv=no; found_iconv=yes)
1524 fi
1525
1526 if test "x$with_libiconv" != "xno" ; then
1527    #
1528    # Check for libiconv
1529    #
1530    AC_CHECK_LIB(iconv, libiconv_open, with_libiconv=yes; found_iconv=yes)
1531 fi
1532
1533 if test "x$found_iconv" = "xno" ; then
1534    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
1535 fi
1536
1537 if test "x$with_libiconv" = "xyes" ; then
1538   ICONV_LIBS="-liconv"
1539   AC_DEFINE(USE_LIBICONV)
1540 fi
1541 AC_SUBST(ICONV_LIBS)
1542
1543 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
1544 dnl since we need it for g_iconv()
1545
1546 AC_MSG_CHECKING([for EILSEQ])
1547 AC_TRY_COMPILE([
1548 #include <errno.h>
1549 ],
1550 [
1551 int error = EILSEQ;
1552 ], have_eilseq=yes, have_eilseq=no);
1553 AC_MSG_RESULT($have_eilseq)
1554
1555 dnl **************************
1556 dnl *** Checks for gtk-doc ***
1557 dnl **************************
1558
1559 AC_ARG_WITH(html-dir, [  --with-html-dir=PATH    path to installed docs])
1560
1561 if test "x$with_html_dir" = "x" ; then
1562   HTML_DIR='${datadir}/gtk-doc/html'
1563 else
1564   HTML_DIR=$with_html_dir
1565 fi
1566
1567 AC_SUBST(HTML_DIR)
1568
1569 AC_CHECK_PROG(GTKDOC, gtkdoc-mkdb, true, false)
1570
1571 gtk_doc_min_version=0.6
1572 if $GTKDOC ; then
1573     gtk_doc_version=`gtkdoc-mkdb --version`
1574     AC_MSG_CHECKING([gtk-doc version ($gtk_doc_version) >= $gtk_doc_min_version])
1575     if perl <<EOF ; then
1576       exit (("$gtk_doc_version" =~ /^[[0-9]]+\.[[0-9]]+$/) &&
1577             ("$gtk_doc_version" >= "$gtk_doc_min_version") ? 0 : 1);
1578 EOF
1579       AC_MSG_RESULT(yes)
1580    else
1581       AC_MSG_RESULT(no)
1582       GTKDOC=false
1583    fi
1584 fi
1585
1586 AM_CONDITIONAL(HAVE_GTK_DOC, $GTKDOC)
1587 AC_SUBST(HAVE_GTK_DOC)
1588
1589 AC_CHECK_PROG(DB2HTML, db2html, true, false)
1590 AM_CONDITIONAL(HAVE_DOCBOOK, $DB2HTML)
1591
1592 dnl Let people disable the gtk-doc stuff.
1593 AC_ARG_ENABLE(gtk-doc, [  --enable-gtk-doc        use gtk-doc to build documentation [default=auto]], enable_gtk_doc="$enableval", enable_gtk_doc=auto)
1594
1595 if test x$enable_gtk_doc = xauto ; then
1596   if test x$GTKDOC = xtrue ; then
1597     enable_gtk_doc=yes
1598   else
1599     enable_gtk_doc=no
1600   fi
1601 fi
1602
1603 dnl NOTE: We need to use a separate automake conditional for this
1604 dnl       to make this work with the tarballs.
1605 AM_CONDITIONAL(ENABLE_GTK_DOC, test x$enable_gtk_doc = xyes)
1606
1607 dnl ******************************
1608 dnl *** output the whole stuff ***
1609 dnl ******************************
1610
1611 AC_OUTPUT_COMMANDS([
1612
1613 ## Generate `glibconfig.h' in two cases
1614 ## 1. `config.status' is run either explicitly, or via configure.
1615 ##     Esp. not when it is run in `Makefile' to generate makefiles and
1616 ##     config.h
1617 ## 2. CONFIG_OTHER is set explicitly
1618 ##
1619 ## Case 1 is difficult.  We know that `automake' sets one of
1620 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
1621 ## only when AM_CONFIG_HEADER is set, however.
1622
1623 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
1624   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
1625   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
1626 fi
1627 case "$CONFIG_OTHER" in
1628 *glibconfig.h*)
1629         echo creating glibconfig.h
1630         outfile=glibconfig.h-tmp
1631         cat > $outfile <<\_______EOF
1632 /* glibconfig.h
1633  *
1634  * This is a generated file.  Please modify 'configure.in'
1635  */
1636
1637 #ifndef __G_LIBCONFIG_H__
1638 #define __G_LIBCONFIG_H__
1639
1640 #include <glib/gmacros.h>
1641
1642 _______EOF
1643
1644         if test x$glib_limits_h = xyes; then
1645           echo '#include <limits.h>' >> $outfile
1646         fi
1647         if test x$glib_float_h = xyes; then
1648           echo '#include <float.h>' >> $outfile
1649         fi
1650         if test x$glib_values_h = xyes; then
1651           echo '#include <values.h>' >> $outfile
1652         fi
1653         if test "$glib_header_alloca_h" = "yes"; then
1654           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
1655         fi
1656         if test x$glib_sys_poll_h = xyes; then
1657           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
1658         fi
1659
1660         cat >> $outfile <<_______EOF
1661
1662 G_BEGIN_DECLS
1663
1664 #define G_MINFLOAT      $glib_mf
1665 #define G_MAXFLOAT      $glib_Mf
1666 #define G_MINDOUBLE     $glib_md
1667 #define G_MAXDOUBLE     $glib_Md
1668 #define G_MINSHORT      $glib_ms
1669 #define G_MAXSHORT      $glib_Ms
1670 #define G_MAXUSHORT     $glib_Mus
1671 #define G_MININT        $glib_mi
1672 #define G_MAXINT        $glib_Mi
1673 #define G_MAXUINT       $glib_Mui
1674 #define G_MINLONG       $glib_ml
1675 #define G_MAXLONG       $glib_Ml
1676 #define G_MAXULONG      $glib_Mul
1677
1678 #define G_MININT64      ((gint64)  0x8000000000000000)
1679 #define G_MAXINT64      ((gint64)  0x7fffffffffffffff)
1680 #define G_MAXUINT64     ((guint64) 0xffffffffffffffff)
1681
1682 _______EOF
1683
1684
1685         ### this should always be true in a modern C/C++ compiler
1686         cat >>$outfile <<_______EOF
1687 typedef signed char gint8;
1688 typedef unsigned char guint8;
1689 _______EOF
1690
1691
1692         if test -n "$gint16"; then
1693           cat >>$outfile <<_______EOF
1694 typedef signed $gint16 gint16;
1695 typedef unsigned $gint16 guint16;
1696 #define G_GINT16_FORMAT $gint16_format
1697 #define G_GUINT16_FORMAT $guint16_format
1698 _______EOF
1699         fi
1700
1701
1702         if test -n "$gint32"; then
1703           cat >>$outfile <<_______EOF
1704 typedef signed $gint32 gint32;
1705 typedef unsigned $gint32 guint32;
1706 #define G_GINT32_FORMAT $gint32_format
1707 #define G_GUINT32_FORMAT $guint32_format
1708 _______EOF
1709         fi
1710
1711         cat >>$outfile <<_______EOF
1712 #define G_HAVE_GINT64 1          /* deprecated, always true */
1713
1714 ${glib_extension}typedef signed $gint64 gint64;
1715 ${glib_extension}typedef unsigned $gint64 guint64;
1716
1717 #define G_GINT64_CONSTANT(val)  $gint64_constant
1718
1719 #define G_GINT64_FORMAT $gint64_format
1720 #define G_GUINT64_FORMAT $guint64_format
1721 _______EOF
1722
1723         cat >>$outfile <<_______EOF
1724
1725 #define GLIB_SIZEOF_VOID_P $glib_void_p
1726 #define GLIB_SIZEOF_LONG   $glib_long
1727 #define GLIB_SIZEOF_SIZE_T $glib_size_t
1728
1729 _______EOF
1730
1731         case x$glib_size_t in
1732         x2) echo "typedef gint16  gssize;" >> $outfile
1733             echo "typedef guint16 gsize;"  >> $outfile
1734             ;;
1735         x4) echo "typedef gint32  gssize;" >> $outfile
1736             echo "typedef guint32 gsize;"  >> $outfile
1737             ;;
1738         x8) echo "typedef gint64  gssize;" >> $outfile
1739             echo "typedef guint64 gsize;"  >> $outfile
1740             ;;
1741         *)  echo "#error size of size_t is unknown" >> $outfile
1742             ;;
1743         esac
1744
1745         if test -z "$glib_unknown_void_p"; then
1746           cat >>$outfile <<_______EOF
1747
1748 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
1749 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
1750
1751 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
1752 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
1753 _______EOF
1754         else
1755           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
1756         fi
1757
1758
1759
1760         cat >>$outfile <<_______EOF
1761 $glib_atexit
1762 $glib_memmove
1763 $glib_defines
1764 $glib_os
1765
1766 $glib_vacopy
1767
1768 #ifdef  __cplusplus
1769 #define G_HAVE_INLINE   1
1770 #else   /* !__cplusplus */
1771 $glib_inline
1772 #endif  /* !__cplusplus */
1773
1774 _______EOF
1775
1776         if test x$g_have_iso_c_varargs = xyes ; then
1777                 cat >>$outfile <<_______EOF
1778 #ifndef __cplusplus
1779 # define G_HAVE_ISO_VARARGS 1
1780 #endif
1781 _______EOF
1782         fi
1783         if test x$g_have_iso_cxx_varargs = xyes ; then
1784                 cat >>$outfile <<_______EOF
1785 #ifdef __cplusplus
1786 # define G_HAVE_ISO_VARARGS 1
1787 #endif
1788 _______EOF
1789         fi
1790         if test x$g_have_gnuc_varargs = xyes ; then
1791                 cat >>$outfile <<_______EOF
1792
1793 #define G_HAVE_GNUC_VARARGS 1
1794 _______EOF
1795         fi
1796
1797         case x$g_stack_grows in
1798         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
1799         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
1800         esac
1801
1802
1803         echo >>$outfile
1804         if test x$g_have_eilseq = xno; then
1805                 cat >>$outfile <<_______EOF
1806 #ifndef EILSEQ
1807 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
1808  * The correspondence between this and the corresponding definition
1809  * in libiconv is essential.
1810  */
1811 #  define EILSEQ ENOENT
1812 #endif
1813 _______EOF
1814
1815         fi
1816
1817         echo >>$outfile
1818         if test x$g_mutex_has_default = xyes; then
1819                 cat >>$outfile <<_______EOF
1820 $g_enable_threads_def G_THREADS_ENABLED
1821 #define G_THREADS_IMPL_$g_threads_impl_def
1822 typedef struct _GStaticMutex GStaticMutex;
1823 struct _GStaticMutex
1824 {
1825   struct _GMutex *runtime_mutex;
1826   union {
1827     char   pad[$g_mutex_sizeof];
1828     double dummy_double;
1829     void  *dummy_pointer;
1830     long   dummy_long;
1831   } static_mutex;
1832 };
1833 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
1834 #define g_static_mutex_get_mutex(mutex) \
1835   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->static_mutex)) : \
1836    g_static_mutex_get_mutex_impl (&((mutex)->runtime_mutex)))
1837 _______EOF
1838         else
1839                 cat >>$outfile <<_______EOF
1840 $g_enable_threads_def G_THREADS_ENABLED
1841 #define G_THREADS_IMPL_$g_threads_impl_def
1842 typedef struct _GMutex* GStaticMutex;
1843 #define G_STATIC_MUTEX_INIT NULL
1844 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (mutex))
1845 _______EOF
1846         fi
1847
1848         cat >>$outfile <<_______EOF
1849 /* This represents a system thread as used by the implementation. An
1850  * alien implementaion, as loaded by g_thread_init can only count on
1851  * "sizeof (gpointer)" bytes to store their info. We however need more
1852  * for some of our native implementations. */
1853 typedef union _GSystemThread GSystemThread;
1854 union _GSystemThread
1855 {
1856   char   data[$g_system_thread_sizeof];
1857   double dummy_double;
1858   void  *dummy_pointer;
1859   long   dummy_long;
1860 };
1861 _______EOF
1862
1863         echo >>$outfile
1864         g_bit_sizes="16 32 64"
1865         for bits in $g_bit_sizes; do
1866           cat >>$outfile <<_______EOF
1867 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
1868 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
1869 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
1870 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
1871 _______EOF
1872         done
1873
1874         cat >>$outfile <<_______EOF
1875 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
1876 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
1877 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
1878 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
1879 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
1880 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
1881 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
1882 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
1883 #define G_BYTE_ORDER $g_byte_order
1884
1885 _______EOF
1886
1887         if test -r glibconfig-sysdefs.h; then
1888           cat glibconfig-sysdefs.h >>$outfile
1889         fi
1890
1891         cat >>$outfile <<_______EOF
1892
1893 #define G_MODULE_SUFFIX "$g_module_suffix"
1894
1895 G_END_DECLS
1896
1897 #endif /* GLIBCONFIG_H */
1898 _______EOF
1899
1900
1901         if cmp -s $outfile glibconfig.h; then
1902           echo glibconfig.h is unchanged
1903           rm -f $outfile
1904         else
1905           mv $outfile glibconfig.h
1906         fi ;;
1907 esac
1908 ],[
1909
1910 # Note that if two cases are the same, case goes with the first one.
1911 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
1912 # on variable expansion in case labels.  Look at the generated config.status
1913 # for a hint.
1914
1915 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
1916   glib_header_alloca_h="$ac_cv_working_alloca_h"
1917 else
1918   glib_header_alloca_h="$ac_cv_header_alloca_h"
1919 fi
1920
1921 case xyes in
1922 x$ac_cv_header_float_h)
1923   glib_float_h=yes
1924   glib_mf=FLT_MIN glib_Mf=FLT_MAX
1925   glib_md=DBL_MIN glib_Md=DBL_MAX
1926   ;;
1927 x$ac_cv_header_values_h)
1928   glib_values_h=yes
1929   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
1930   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
1931   ;;
1932 esac
1933
1934 case xyes in
1935 x$ac_cv_header_limits_h)
1936   glib_limits_h=yes
1937   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
1938   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
1939   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
1940   ;;
1941 x$ac_cv_header_values_h)
1942   glib_values_h=yes
1943   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
1944   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
1945   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
1946   ;;
1947 esac
1948
1949 if test x$ac_cv_header_sys_poll_h = xyes ; then
1950   glib_sys_poll_h=yes
1951 fi
1952
1953 case 2 in
1954 $ac_cv_sizeof_short)
1955   gint16=short
1956   gint16_format='"hi"'
1957   guint16_format='"hu"'
1958   ;;
1959 $ac_cv_sizeof_int)
1960   gint16=int
1961   gint16_format='"i"'
1962   guint16_format='"u"'
1963   ;;
1964 esac
1965 case 4 in
1966 $ac_cv_sizeof_short)
1967   gint32=short
1968   gint32_format='"hi"'
1969   guint32_format='"hu"'
1970   ;;
1971 $ac_cv_sizeof_int)
1972   gint32=int
1973   gint32_format='"i"'
1974   guint32_format='"u"'
1975   ;;
1976 $ac_cv_sizeof_long)
1977   gint32=long
1978   gint32_format='"li"'
1979   guint32_format='"lu"'
1980   ;;
1981 esac
1982 case 8 in
1983 $ac_cv_sizeof_int)
1984   gint64=int
1985   gint64_format='"i"'
1986   guint64_format='"u"'
1987   glib_extension=
1988   gint64_constant='(val)'
1989   ;;
1990 $ac_cv_sizeof_long)
1991   gint64=long
1992   gint64_format='"li"'
1993   guint64_format='"lu"'
1994   glib_extension=
1995   gint64_constant='(val##L)'
1996   ;;
1997 $ac_cv_sizeof_long_long)
1998   gint64='long long'
1999   if test -n "$glib_cv_long_long_format"; then
2000     gint64_format='"'$glib_cv_long_long_format'i"'
2001     guint64_format='"'$glib_cv_long_long_format'u"'
2002   fi
2003   glib_extension='G_GNUC_EXTENSION '
2004   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
2005   ;;
2006 $ac_cv_sizeof___int64)
2007   gint64='__int64'
2008   if test -n "$glib_cv_long_long_format"; then
2009     gint64_format='"'$glib_cv_long_long_format'i"'
2010     guint64_format='"'$glib_cv_long_long_format'u"'
2011   fi
2012   glib_extension=
2013   gint64_constant='(val##i64)'
2014   ;;
2015 esac
2016 glib_size_t=$glib_cv_sizeof_size_t
2017 glib_void_p=$ac_cv_sizeof_long
2018 glib_long=$ac_cv_sizeof_void_p
2019
2020 gintbits=`expr $ac_cv_sizeof_int \* 8`
2021 glongbits=`expr $ac_cv_sizeof_long \* 8`
2022
2023
2024 case $ac_cv_sizeof_void_p in
2025 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
2026 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
2027 *)                      glib_unknown_void_p=yes ;;
2028 esac
2029
2030
2031 case xyes in
2032 x$ac_cv_func_atexit)
2033   glib_atexit="
2034 #ifdef NeXT /* @#%@! NeXTStep */
2035 # define g_ATEXIT(proc) (!atexit (proc))
2036 #else
2037 # define g_ATEXIT(proc) (atexit (proc))
2038 #endif"
2039   ;;
2040 x$ac_cv_func_on_exit)
2041   glib_atexit="
2042 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
2043   ;;
2044 esac
2045
2046 case xyes in
2047 x$ac_cv_func_memmove)
2048   glib_memmove='
2049 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
2050   ;;
2051 x$glib_cv_working_bcopy)
2052   glib_memmove="
2053 /* memmove isn't available, but bcopy can copy overlapping memory regions */
2054 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
2055   ;;
2056 *)
2057   glib_memmove="
2058 /* memmove isn't found and bcopy can't copy overlapping memory regions,
2059  * so we have to roll our own copy routine. */
2060 void g_memmove (void* dest, const void * src, unsigned long len);"
2061   ;;
2062 esac
2063
2064 glib_defines="
2065 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
2066 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
2067 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
2068 "
2069
2070 case xyes in
2071 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
2072 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
2073 *)                      glib_vacopy=''
2074 esac
2075
2076 if test x$glib_cv_va_val_copy = xno; then
2077   glib_vacopy="\$glib_vacopy
2078 #define G_VA_COPY_AS_ARRAY 1"
2079 fi
2080
2081 if test x$glib_cv_hasinline = xyes; then
2082     glib_inline='#define G_HAVE_INLINE 1'
2083 fi
2084 if test x$glib_cv_has__inline = xyes; then
2085     glib_inline="\$glib_inline
2086 #define G_HAVE___INLINE 1"
2087 fi
2088 if test x$glib_cv_has__inline__ = xyes; then
2089     glib_inline="\$glib_inline
2090 #define G_HAVE___INLINE__ 1"
2091 fi
2092
2093 g_have_gnuc_varargs=$g_have_gnuc_varargs
2094 g_have_iso_c_varargs=$g_have_iso_c_varargs
2095 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
2096
2097 case xyes in
2098 x$ac_cv_c_bigendian)
2099   g_byte_order=G_BIG_ENDIAN
2100   g_bs_native=BE
2101   g_bs_alien=LE
2102   ;;
2103 *)
2104   g_byte_order=G_LITTLE_ENDIAN
2105   g_bs_native=LE
2106   g_bs_alien=BE
2107   ;;
2108 esac
2109
2110 g_stack_grows=$glib_cv_stack_grows
2111
2112 g_have_eilseq=$have_eilseq
2113
2114 case x$have_threads in
2115 xno)    g_enable_threads_def="#undef";;
2116 *)      g_enable_threads_def="#define";;
2117 esac
2118
2119 g_threads_impl_def=$g_threads_impl
2120
2121 g_mutex_has_default="$mutex_has_default"
2122 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
2123 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
2124 g_mutex_contents="$glib_cv_byte_contents_gmutex"
2125
2126 g_module_suffix="$glib_gmodule_suffix"
2127
2128 case $host in
2129   *-*-beos*)
2130     glib_os="#define G_OS_BEOS"
2131     ;;
2132   *-*-cygwin*)
2133     glib_os="#define G_OS_UNIX
2134 #define G_PLATFORM_WIN32
2135 #define G_WITH_CYGWIN"
2136     ;;
2137   *-*-mingw*)
2138     glib_os="#define G_OS_WIN32
2139 #define G_PLATFORM_WIN32"
2140     ;;
2141   *)
2142     glib_os="#define G_OS_UNIX"
2143     ;;
2144 esac
2145 ])
2146
2147 AC_OUTPUT([
2148 glib-2.0.pc
2149 glib-2.0-uninstalled.pc
2150 gmodule-2.0.pc
2151 gmodule-2.0-uninstalled.pc
2152 gthread-2.0.pc
2153 gthread-2.0-uninstalled.pc
2154 gobject-2.0.pc
2155 gobject-2.0-uninstalled.pc
2156 glib.spec
2157 glib-zip
2158 glib-gettextize
2159 Makefile
2160 build/Makefile
2161 build/win32/Makefile
2162 build/win32/dirent/Makefile
2163 glib/Makefile
2164 glib/libcharset/Makefile
2165 gmodule/gmoduleconf.h
2166 gmodule/Makefile
2167 gobject/Makefile
2168 gobject/glib-mkenums
2169 gthread/Makefile
2170 po/Makefile.in
2171 docs/Makefile
2172 docs/reference/Makefile
2173 docs/reference/glib/Makefile
2174 docs/reference/gobject/Makefile
2175 tests/Makefile
2176 m4macros/Makefile
2177 ],[echo ""
2178 echo " *** IMPORTANT *** "
2179 echo ""
2180 echo "This is a development version of GLib.  You should be using a stable"
2181 echo "version, which is available at ftp://ftp.gtk.org/pub/gtk/v1.2/.  The"
2182 echo "version you just configured is meant for developers of GLib only:"
2183 echo ""
2184 echo "  * You should not base stable software on this version of GLib."
2185 echo "  * GNOME developers should use a stable version of GLib."
2186 echo ""
2187 echo " *** You should be using GLib 1.2 instead. ***"
2188 ])