configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 # require autoconf 2.54
   3 AC_PREREQ(2.54)
   4
   5 dnl ***********************************
   6 dnl *** include special GLib macros ***
   7 dnl ***********************************
   8
   9 m4_define(glib_configure_in)
  10 m4_include(acglib.m4)dnl
  11 m4_include(glib/libcharset/codeset.m4)dnl
  12 m4_include(glib/libcharset/glibc21.m4)dnl
  13 m4_include(m4macros/glib-gettext.m4)dnl
  14
  15 #
  16 # The following version number definitions apply to GLib, GModule, GObject
  17 # and GThread as a whole, so if changes occoured in any of them, they are all
  18 # treated with the same interface and binary age.
  19 #
  20 # Making releases:
  21 #   glib_micro_version += 1;
  22 #   glib_interface_age += 1;
  23 #   glib_binary_age += 1;
  24 # if any functions have been added, set glib_interface_age to 0.
  25 # if backwards compatibility has been broken,
  26 # set glib_binary_age _and_ glib_interface_age to 0.
  27 #
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [6])
  30 m4_define([glib_micro_version], [1])
  31 m4_define([glib_interface_age], [1])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_SRCDIR([glib/glib.h])
  56
  57 # Save this value here, since automake will set cflags later
  58 cflags_set=${CFLAGS+set}
  59
  60 AM_INIT_AUTOMAKE([no-define])
  61
  62 # Specify a configuration file
  63 AM_CONFIG_HEADER([config.h])
  64
  65
  66 GLIB_MAJOR_VERSION=glib_major_version
  67 GLIB_MINOR_VERSION=glib_minor_version
  68 GLIB_MICRO_VERSION=glib_micro_version
  69 GLIB_INTERFACE_AGE=glib_interface_age
  70 GLIB_BINARY_AGE=glib_binary_age
  71 GLIB_VERSION=glib_version
  72
  73 AC_SUBST(GLIB_MAJOR_VERSION)
  74 AC_SUBST(GLIB_MINOR_VERSION)
  75 AC_SUBST(GLIB_MICRO_VERSION)
  76 AC_SUBST(GLIB_VERSION)
  77 AC_SUBST(GLIB_INTERFACE_AGE)
  78 AC_SUBST(GLIB_BINARY_AGE)
  79
  80 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  81           [Define to the GLIB major version])
  82 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  83           [Define to the GLIB minor version])
  84 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  85           [Define to the GLIB micro version])
  86 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  87           [Define to the GLIB interface age])
  88 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  89           [Define to the GLIB binary age])
  90
  91 # libtool versioning
  92 LT_RELEASE=glib_lt_release
  93 LT_CURRENT=glib_lt_current
  94 LT_REVISION=glib_lt_revision
  95 LT_AGE=glib_lt_age
  96 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
  97 AC_SUBST(LT_RELEASE)
  98 AC_SUBST(LT_CURRENT)
  99 AC_SUBST(LT_REVISION)
 100 AC_SUBST(LT_AGE)
 101 AC_SUBST(LT_CURRENT_MINUS_AGE)
 102
 103 dnl Initialize maintainer mode
 104 AM_MAINTAINER_MODE
 105
 106 AC_CANONICAL_HOST
 107
 108 AC_MSG_CHECKING([for the BeOS])
 109 case $host in
 110   *-*-beos*)
 111     glib_native_beos="yes"
 112     ;;
 113   *)
 114     glib_native_beos="no"
 115     ;;
 116 esac
 117 AC_MSG_RESULT([$glib_native_beos])
 118
 119 dnl
 120
 121 AC_MSG_CHECKING([for Win32])
 122 case "$host" in
 123   *-*-mingw*)
 124     glib_native_win32=yes
 125     G_LIB_WIN32_RESOURCE=glib-win32res.lo
 126     G_MODULE_WIN32_RESOURCE=gmodule-win32res.lo
 127     G_OBJECT_WIN32_RESOURCE=gobject-win32res.lo
 128     G_THREAD_WIN32_RESOURCE=gthread-win32res.lo
 129     GLIB_DEF=glib.def
 130     GMODULE_DEF=gmodule.def
 131     GOBJECT_DEF=gobject.def
 132     GTHREAD_DEF=gthread.def
 133     TESTGMODULE_EXP=testgmodule.exp
 134     glib_pid_type='void *'
 135     ;;
 136   *)
 137     glib_native_win32=no
 138     G_LIB_WIN32_RESOURCE=
 139     G_MODULE_WIN32_RESOURCE=
 140     G_OBJECT_WIN32_RESOURCE=
 141     G_THREAD_WIN32_RESOURCE=
 142     GLIB_DEF=
 143     GMODULE_DEF=
 144     GOBJECT_DEF=
 145     GTHREAD_DEF=
 146     TESTGMODULE_EXP=
 147     glib_pid_type=int
 148     ;;
 149 esac
 150 case $host in
 151   *-*-linux*)
 152     glib_os_linux=yes
 153     ;;
 154 esac
 155
 156
 157 AC_MSG_RESULT([$glib_native_win32])
 158 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 159 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 160 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 161 AC_SUBST(G_LIB_WIN32_RESOURCE)
 162 AC_SUBST(G_MODULE_WIN32_RESOURCE)
 163 AC_SUBST(G_OBJECT_WIN32_RESOURCE)
 164 AC_SUBST(G_THREAD_WIN32_RESOURCE)
 165 AC_SUBST(GLIB_DEF)
 166 AC_SUBST(GMODULE_DEF)
 167 AC_SUBST(GOBJECT_DEF)
 168 AC_SUBST(GTHREAD_DEF)
 169 AC_SUBST(TESTGMODULE_EXP)
 170
 171 if test "$glib_native_win32" = "yes"; then
 172   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 173 fi
 174 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 175
 176 if test "$glib_native_win32" != yes; then
 177     # libtool option to control which symbols are exported
 178     # right now, symbols starting with _ are not exported
 179     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^[[^_]].*"'
 180 else
 181     # We currently use .def files on Windows
 182     LIBTOOL_EXPORT_OPTIONS=
 183 fi
 184 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 185
 186 dnl declare --enable-* args and collect ac_help strings
 187 AC_ARG_ENABLE(debug,
 188               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 189                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 190               enable_debug=glib_debug_default)
 191
 192 AC_ARG_ENABLE(gc_friendly,
 193               [AC_HELP_STRING([--enable-gc-friendly],
 194                               [turn on garbage collector friendliness [default=no]])],,
 195               [enable_gc_friendly=no])
 196 AC_ARG_ENABLE(mem_pools,
 197               [AC_HELP_STRING([--disable-mem-pools],
 198                               [disable all glib memory pools])],,
 199               [disable_mem_pools=no])
 200 AC_ARG_ENABLE(ansi,
 201               [AC_HELP_STRING([--enable-ansi],
 202                               [turn on strict ansi [default=no]])],,
 203               [enable_ansi=no])
 204 AC_ARG_ENABLE(threads,
 205               [AC_HELP_STRING([--enable-threads],
 206                               [turn on basic thread support [default=yes]
 207 ([=no] will override --with-threads)])],,
 208               [enable_threads=yes])
 209 AC_ARG_ENABLE(rebuilds,
 210               [AC_HELP_STRING([--disable-rebuilds],
 211                               [disable all source autogeneration rules])],,
 212               [enable_rebuilds=yes])
 213 AC_ARG_ENABLE(visibility,
 214               [AC_HELP_STRING([--disable-visibility],
 215                               [don't use ELF visibility attributes])],,
 216               [enable_visibility=yes])
 217
 218 if test "x$enable_threads" != "xyes"; then
 219   enable_threads=no
 220 fi
 221
 222 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, ["${enable_debug}"],
 223         [Whether glib was compiled with debugging enabled])
 224
 225 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 226 if test "x$enable_gc_friendly" = "xyes"; then
 227   AC_DEFINE(ENABLE_GC_FRIENDLY, 1, [Whether to enable GC friendliness])
 228   AC_SUBST(ENABLE_GC_FRIENDLY)
 229   AC_MSG_RESULT([yes])
 230 else
 231   AC_MSG_RESULT([no])
 232 fi
 233
 234 AC_MSG_CHECKING([whether to disable memory pools])
 235 if test "x$disable_mem_pools" = "xno"; then
 236   AC_MSG_RESULT([no])
 237 else
 238   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 239   AC_SUBST(DISABLE_MEM_POOLS)
 240   AC_MSG_RESULT([yes])
 241 fi
 242
 243 if test "$glib_native_win32" = "yes"; then
 244   if test x$enable_static = xyes -o x$enable_static = x; then
 245     AC_MSG_WARN([Disabling static library build, must build as DLL on Windows.])
 246     enable_static=no
 247   fi
 248   if test x$enable_shared = xno; then
 249     AC_MSG_WARN([Enabling shared library build, must build as DLL on Windows.])
 250   fi
 251   enable_shared=yes
 252 fi
 253
 254 dnl Checks for programs.
 255 AC_PROG_CC
 256
 257 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 258 AC_CHECK_PROGS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 259 AC_LANG_SAVE
 260 AC_LANG_CPLUSPLUS
 261 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 262 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 263 AC_LANG_RESTORE
 264
 265 AM_PROG_CC_STDC
 266 AC_PROG_INSTALL
 267
 268 AC_SYS_LARGEFILE
 269
 270 #
 271 # Find pkg-config
 272 #
 273 AC_PATH_PROG(PKG_CONFIG, [pkg-config], [no])
 274 if test x$PKG_CONFIG = xno ; then
 275   AC_MSG_ERROR([*** pkg-config not found. See http://www.freedesktop.org/software/pkgconfig/])
 276 fi
 277
 278 if $PKG_CONFIG --atleast-pkgconfig-version 0.14 ; then
 279   :
 280 else
 281   AC_MSG_ERROR([*** pkg-config too old; version 0.14 or better required.])
 282 fi
 283
 284 if test "x$enable_debug" = "xyes"; then
 285   if test x$cflags_set != xset ; then
 286       case " $CFLAGS " in
 287       *[[\ \    ]]-g[[\ \       ]]*) ;;
 288       *) CFLAGS="$CFLAGS -g" ;;
 289       esac
 290   fi
 291
 292   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 293 else
 294   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 295
 296   if test "x$enable_debug" = "xno"; then
 297     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 298   fi
 299 fi
 300
 301 if test "x$enable_visibility" = "xno"; then
 302   GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DDISABLE_VISIBILITY"
 303 fi
 304
 305 # Ensure MSVC-compatible struct packing convention is used when
 306 # compiling for Win32 with gcc.
 307 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 308 # gcc2 uses "-fnative-struct".
 309 if test x"$glib_native_win32" = xyes; then
 310   if test x"$GCC" = xyes; then
 311     msnative_struct=''
 312     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 313     if test -z "$ac_cv_prog_CC"; then
 314       our_gcc="$CC"
 315     else
 316       our_gcc="$ac_cv_prog_CC"
 317     fi
 318     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 319       2.)
 320         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 321           msnative_struct='-fnative-struct'
 322         fi
 323         ;;
 324       *)
 325         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 326           msnative_struct='-mms-bitfields'
 327         fi
 328         ;;
 329     esac
 330     if test x"$msnative_struct" = x ; then
 331       AC_MSG_RESULT([no way])
 332       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 333     else
 334       CFLAGS="$CFLAGS $msnative_struct"
 335       AC_MSG_RESULT([${msnative_struct}])
 336     fi
 337   fi
 338 fi
 339
 340 AC_EXEEXT
 341
 342 # define a MAINT-like variable REBUILD which is set if Perl
 343 # and awk are found, so autogenerated sources can be rebuilt
 344 AC_PROG_AWK
 345 AC_CHECK_PROGS(PERL, [perl5 perl])
 346 # We would like indent, but don't require it.
 347 AC_CHECK_PROG(INDENT, indent, indent)
 348 REBUILD=\#
 349 if test "x$enable_rebuilds" = "xyes" && \
 350      test -n "$PERL" && \
 351      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 352      test -n "$AWK" ; then
 353   REBUILD=
 354 fi
 355 AC_SUBST(REBUILD)
 356
 357 # Need full path to Perl for glib-mkenums
 358 #
 359 if test "x$PERL" != x ; then
 360   AC_PATH_PROG(PERL_PATH, [$PERL])
 361 else
 362   PERL_PATH="/usr/bin/env perl"
 363 fi
 364 AC_SUBST(PERL_PATH)
 365
 366 dnl ***********************
 367 dnl *** Tests for iconv ***
 368 dnl ***********************
 369 dnl
 370 dnl We do this before the gettext checks, to avoid distortion
 371
 372 AC_ARG_WITH(libiconv,
 373             [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 374                             [use the libiconv library])],,
 375             [with_libiconv=maybe])
 376
 377 found_iconv=no
 378 case $with_libiconv in
 379   maybe)
 380     # Check in the C library first
 381     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 382     # Check if we have GNU libiconv
 383     if test $found_iconv = "no"; then
 384       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 385     fi
 386     # Check if we have a iconv in -liconv, possibly from vendor
 387     if test $found_iconv = "no"; then
 388       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 389     fi
 390     ;;
 391   no)
 392     AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 393     ;;
 394   gnu|yes)
 395     AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 396     ;;
 397   native)
 398     AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 399     ;;
 400 esac
 401
 402 if test "x$found_iconv" = "xno" ; then
 403    AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 404 fi
 405
 406 dnl
 407 dnl gettext support
 408 dnl
 409
 410 ALL_LINGUAS="am ar az be bg bn bs ca cs cy da de el en_CA en_GB eo es et eu fa fi fr ga gl gu he hi hr id is it ja ko lt lv mk mn ms nb ne nl nn no or pa pl pt pt_BR ro ru sk sl sq sr sr@ije sr@Latn sv ta tr uk vi wa yi zh_CN zh_TW"
 411 GLIB_GNU_GETTEXT
 412
 413 if test "$gt_cv_have_gettext" != "yes" ; then
 414   AC_MSG_ERROR([
 415 *** You must have either have gettext support in your C library, or use the
 416 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 417 ])
 418 fi
 419
 420 LIBS="$INTLLIBS $LIBS"
 421
 422 GETTEXT_PACKAGE=glib20
 423 AC_SUBST(GETTEXT_PACKAGE)
 424 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 425   [Define the gettext package to be used])
 426
 427 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 428
 429 dnl
 430 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 431 dnl
 432
 433 if test x$with_libiconv != xno ; then
 434   case " $INTLLIBS " in
 435   *[[\ \        ]]-liconv[[\ \  ]]*) ;;
 436   *) ICONV_LIBS="-liconv" ;;
 437   esac
 438 fi
 439 AC_SUBST(ICONV_LIBS)
 440
 441 case $with_libiconv in
 442   gnu)
 443     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 444     ;;
 445   native)
 446     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 447     ;;
 448 esac
 449
 450 dnl Initialize libtool
 451 AM_DISABLE_STATIC
 452 AM_PROG_LIBTOOL
 453
 454 if test "x$GCC" = "xyes"; then
 455   case " $CFLAGS " in
 456   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 457   *) CFLAGS="$CFLAGS -Wall" ;;
 458   esac
 459
 460   if test "x$enable_ansi" = "xyes"; then
 461     case " $CFLAGS " in
 462     *[[\ \      ]]-ansi[[\ \    ]]*) ;;
 463     *) CFLAGS="$CFLAGS -ansi" ;;
 464     esac
 465
 466     case " $CFLAGS " in
 467     *[[\ \      ]]-pedantic[[\ \        ]]*) ;;
 468     *) CFLAGS="$CFLAGS -pedantic" ;;
 469     esac
 470   fi
 471 fi
 472
 473 dnl
 474 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 475 dnl
 476 if test $cross_compiling != yes ; then
 477     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 478     glib_save_LIBS=$LIBS
 479     LIBS="$LIBS -lm"
 480     AC_TRY_RUN([#include <math.h>
 481                  int main (void) { return (log(1) != log(1.)); }],
 482          AC_MSG_RESULT(none needed),
 483          glib_save_CFLAGS=$CFLAGS
 484          CFLAGS="$CFLAGS -std1"
 485          AC_TRY_RUN([#include <math.h>
 486                      int main (void) { return (log(1) != log(1.)); }],
 487              AC_MSG_RESULT(-std1),
 488              AC_MSG_RESULT()
 489              CFLAGS=$glib_save_CFLAGS
 490              AC_MSG_WARN(
 491                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 492          )
 493     )
 494     LIBS=$glib_save_LIBS
 495 fi
 496
 497 dnl NeXTStep cc seems to need this
 498 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 499 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 500   AC_MSG_RESULT(none needed),
 501   glib_save_CFLAGS=$CFLAGS
 502   CFLAGS="$CFLAGS -posix"
 503   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 504     AC_MSG_RESULT(-posix),
 505     AC_MSG_RESULT()
 506     CFLAGS=$glib_save_CFLAGS
 507     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 508
 509 # Checks for header files.
 510 AC_HEADER_STDC
 511
 512 # Checks for library functions.
 513 AC_FUNC_VPRINTF
 514
 515 AC_FUNC_ALLOCA
 516
 517 AC_CHECK_FUNCS(atexit on_exit)
 518
 519 AC_CHECK_SIZEOF(char)
 520 AC_CHECK_SIZEOF(short)
 521 AC_CHECK_SIZEOF(long)
 522 AC_CHECK_SIZEOF(int)
 523 AC_CHECK_SIZEOF(void *)
 524 AC_CHECK_SIZEOF(long long)
 525 AC_CHECK_SIZEOF(__int64)
 526
 527 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 528   :
 529 else
 530   AC_MSG_ERROR([
 531 *** GLib requires a 64 bit type. You might want to consider
 532 *** using the GNU C compiler.
 533 ])
 534 fi
 535
 536 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 537         # long long is a 64 bit integer.
 538         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 539         AC_CACHE_VAL(glib_cv_long_long_format,[
 540                 for format in ll q I64; do
 541                   AC_TRY_RUN([#include <stdio.h>
 542                         int main()
 543                         {
 544                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 545                           char buffer[1000];
 546                           sprintf (buffer, "%${format}u", a);
 547                           sscanf (buffer, "%${format}u", &b);
 548                           exit (b!=a);
 549                         }
 550                         ],
 551                         [glib_cv_long_long_format=${format}
 552                         break],
 553                         [],[:])
 554                 done])
 555         if test -n "$glib_cv_long_long_format"; then
 556           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 557           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 558           if test x"$glib_cv_long_long_format" = xI64; then
 559             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 560           fi
 561         else
 562           AC_MSG_RESULT(none)
 563         fi
 564 elif test x$ac_cv_sizeof___int64 = x8; then
 565         # __int64 is a 64 bit integer.
 566         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 567         # We know this is MSVCRT.DLL, and what the formats are
 568         glib_cv_long_long_format=I64
 569         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 570         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 571         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 572 fi
 573
 574 dnl long doubles were not used, and a portability problem
 575 dnl AC_C_LONG_DOUBLE
 576 AC_C_CONST
 577
 578 dnl ok, here we try to check whether the systems prototypes for
 579 dnl malloc and friends actually match the prototypes provided
 580 dnl by gmem.h (keep in sync). i currently only know how to check
 581 dnl this reliably with gcc (-Werror), improvements for other
 582 dnl compilers are apprechiated.
 583 SANE_MALLOC_PROTOS=no
 584 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 585 glib_save_CFLAGS=$CFLAGS
 586 if test "x$GCC" = "xyes"; then
 587   CFLAGS="$CFLAGS -Werror"
 588   AC_TRY_COMPILE([#include <stdlib.h>], [
 589     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 590     void* (*my_malloc_p)  (size_t)         = malloc;
 591     void  (*my_free_p)    (void*)          = free;
 592     void* (*my_realloc_p) (void*, size_t)  = realloc;
 593     my_calloc_p = 0;
 594     my_malloc_p = 0;
 595     my_free_p = 0;
 596     my_realloc_p = 0;
 597   ],
 598     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 599       [Define if you have correct malloc prototypes])
 600     SANE_MALLOC_PROTOS=yes)
 601 fi
 602 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 603 CFLAGS=$glib_save_CFLAGS
 604
 605 dnl
 606 dnl check in which direction the stack grows
 607 dnl
 608 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 609         AC_TRY_RUN([
 610         volatile int *a = 0, *b = 0;
 611         void foo (void);
 612         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 613         void foo (void) { volatile int x = 5; b = &x; }
 614         ],
 615         glib_cv_stack_grows=no
 616         ,
 617         glib_cv_stack_grows=yes
 618         ,)
 619 ])
 620
 621 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 622 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 623 dnl actually supported.
 624 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 625         AC_COMPILE_IFELSE([
 626         __inline int foo () { return 0; }
 627         int main () { return foo (); }
 628         ],
 629         glib_cv_has__inline=yes
 630         ,
 631         glib_cv_has__inline=no
 632         ,)
 633 ])
 634 case x$glib_cv_has__inline in
 635 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 636 esac
 637 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 638         AC_COMPILE_IFELSE([
 639         __inline__ int foo () { return 0; }
 640         int main () { return foo (); }
 641         ],
 642         glib_cv_has__inline__=yes
 643         ,
 644         glib_cv_has__inline__=no
 645         ,)
 646 ])
 647 case x$glib_cv_has__inline__ in
 648 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 649 esac
 650 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 651         AC_COMPILE_IFELSE([
 652         #undef inline
 653         inline int foo () { return 0; }
 654         int main () { return foo (); }
 655         ],
 656         glib_cv_hasinline=yes
 657         ,
 658         glib_cv_hasinline=no
 659         ,)
 660 ])
 661 case x$glib_cv_hasinline in
 662 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 663 esac
 664
 665 # if we can use inline functions in headers
 666 AC_MSG_CHECKING(if inline functions in headers work)
 667 AC_LINK_IFELSE([
 668 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 669 #  undef inline
 670 #  define inline __inline__
 671 #elif !defined (G_HAVE_INLINE)
 672 #  undef inline
 673 #  if defined (G_HAVE___INLINE__)
 674 #    define inline __inline__
 675 #  elif defined (G_HAVE___INLINE)
 676 #    define inline __inline
 677 #  endif
 678 #endif
 679
 680 int glib_test_func2 (int);
 681
 682 static inline int
 683 glib_test_func1 (void) {
 684   return glib_test_func2 (1);
 685 }
 686
 687 int
 688 main (void) {
 689   int i = 1;
 690 }],[g_can_inline=yes],[g_can_inline=no])
 691 AC_MSG_RESULT($g_can_inline)
 692
 693 # check for flavours of varargs macros
 694 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 695 AC_TRY_COMPILE([],[
 696 int a(int p1, int p2, int p3);
 697 #define call_a(...) a(1,__VA_ARGS__)
 698 call_a(2,3);
 699 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 700 AC_MSG_RESULT($g_have_iso_c_varargs)
 701
 702 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 703 if test "$CXX" = ""; then
 704 dnl No C++ compiler
 705   g_have_iso_cxx_varargs=no
 706 else
 707   AC_LANG_CPLUSPLUS
 708   AC_TRY_COMPILE([],[
 709 int a(int p1, int p2, int p3);
 710 #define call_a(...) a(1,__VA_ARGS__)
 711 call_a(2,3);
 712 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 713   AC_LANG_C
 714 fi
 715 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 716
 717 AC_MSG_CHECKING(for GNUC varargs macros)
 718 AC_TRY_COMPILE([],[
 719 int a(int p1, int p2, int p3);
 720 #define call_a(params...) a(1,params)
 721 call_a(2,3);
 722 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 723 AC_MSG_RESULT($g_have_gnuc_varargs)
 724
 725 # check for GNUC visibility support
 726 AC_MSG_CHECKING(for GNUC visibility attribute)
 727 GLIB_CHECK_COMPILE_WARNINGS([
 728 void
 729 __attribute__ ((visibility ("hidden")))
 730      f_hidden (void)
 731 {
 732 }
 733 void
 734 __attribute__ ((visibility ("internal")))
 735      f_internal (void)
 736 {
 737 }
 738 void
 739 __attribute__ ((visibility ("protected")))
 740      f_protected (void)
 741 {
 742 }
 743 void
 744 __attribute__ ((visibility ("default")))
 745      f_default (void)
 746 {
 747 }
 748 int main (int argc, char **argv)
 749 {
 750         f_hidden();
 751         f_internal();
 752         f_protected();
 753         f_default();
 754         return 0;
 755 }
 756 ],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 757 AC_MSG_RESULT($g_have_gnuc_visibility)
 758
 759 # check for bytesex stuff
 760 AC_C_BIGENDIAN
 761
 762 # check for header files
 763 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h sys/param.h sys/poll.h sys/select.h sys/types.h])
 764 AC_CHECK_HEADERS([sys/time.h sys/times.h unistd.h values.h stdint.h sched.h])
 765
 766 # Checks for libcharset
 767 jm_LANGINFO_CODESET
 768 jm_GLIBC21
 769 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 770 AC_CHECK_FUNCS(setlocale)
 771
 772 # check additional type sizes
 773 AC_CHECK_SIZEOF(size_t)
 774
 775 dnl Try to figure out whether gsize, gssize should be long or int
 776 AC_MSG_CHECKING([for the appropriate definition for size_t])
 777
 778 case $ac_cv_sizeof_size_t in
 779   $ac_cv_sizeof_short)
 780       glib_size_type=short
 781       ;;
 782   $ac_cv_sizeof_int)
 783       glib_size_type=int
 784       ;;
 785   $ac_cv_sizeof_long)
 786       glib_size_type=long
 787       ;;
 788   *)  AC_MSG_ERROR([No type matching size_t in size])
 789       ;;
 790 esac
 791
 792 dnl If int/long are the same size, we see which one produces
 793 dnl warnings when used in the location as size_t. (This matters
 794 dnl on AIX with xlc)
 795 dnl
 796 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 797    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 798   GLIB_CHECK_COMPILE_WARNINGS([
 799 #include <stddef.h>
 800 int main ()
 801 {
 802   size_t s = 1;
 803   unsigned int *size_int = &s;
 804   return (int)*size_int;
 805 }
 806     ],glib_size_type=int,
 807       [GLIB_CHECK_COMPILE_WARNINGS([
 808 #include <stddef.h>
 809 int main ()
 810 {
 811    size_t s = 1;
 812    unsigned long *size_long = &s;
 813    return (int)*size_long;
 814 }
 815         ],glib_size_type=long)])
 816 fi
 817
 818 AC_MSG_RESULT(unsigned $glib_size_type)
 819
 820 # Check for some functions
 821 AC_CHECK_FUNCS(lstat strerror strsignal memmove mkstemp vsnprintf stpcpy strcasecmp strncasecmp poll getcwd nanosleep vasprintf setenv unsetenv getc_unlocked readlink symlink)
 822
 823 AC_FUNC_VSNPRINTF_C99
 824 AC_FUNC_PRINTF_UNIX98
 825
 826 #
 827 # Check whether to use an included printf
 828 #
 829
 830 AC_ARG_ENABLE(included-printf,
 831               [AC_HELP_STRING([--enable-included-printf],
 832                               [use included printf [default=auto]])],
 833               enable_included_printf="$enableval")
 834
 835 need_included_printf=no
 836 if test "x$enable_included_printf" = "xyes" ; then
 837   need_included_printf=yes
 838 fi
 839 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
 840   need_included_printf=yes
 841 fi
 842 if test "$ac_cv_func_printf_unix98" != "yes" ; then
 843   need_included_printf=yes
 844 fi
 845 if test "x$ac_cv_sizeof_long_long" = "x8" &&
 846    test -z "$glib_cv_long_long_format" ; then
 847   need_included_printf=yes
 848 fi
 849
 850 if test "x$enable_included_printf" = "xno" &&
 851    test "x$need_included_printf" = "xyes" ; then
 852   AC_MSG_ERROR([
 853 *** Your C library's printf doesn't appear to have the features that
 854 *** GLib needs, but you specified --enable-included-printf=no.])
 855 fi
 856
 857 enable_included_printf=$need_included_printf
 858
 859 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
 860 if test "$enable_included_printf" != "yes" ; then
 861   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
 862 else
 863   if test -z "$glib_cv_long_long_format" ; then
 864     glib_cv_long_long_format="ll"
 865   fi
 866   AC_DEFINE(HAVE_VASPRINTF,1)
 867 fi
 868
 869 # Checks needed for gnulib vasnprintf
 870 bh_C_SIGNED
 871 jm_AC_TYPE_LONG_LONG
 872 gt_TYPE_LONGDOUBLE
 873 gt_TYPE_WCHAR_T
 874 gt_TYPE_WINT_T
 875 AC_TYPE_SIZE_T
 876 AC_CHECK_TYPES(ptrdiff_t)
 877 jm_AC_TYPE_INTMAX_T
 878 AC_CHECK_FUNCS(snprintf)
 879 AC_FUNC_SNPRINTF_C99
 880
 881 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
 882 # The check is borrowed from the PERL Configure script.
 883 if test "$ac_cv_func_memmove" != "yes"; then
 884   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
 885     glib_cv_working_bcopy,[AC_TRY_RUN([
 886       int main() {
 887         char buf[128], abc[128], *b;
 888         int len, off, align;
 889         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
 890         for (align = 7; align >= 0; align--) {
 891           for (len = 36; len; len--) {
 892             b = buf+align; bcopy(abc, b, len);
 893             for (off = 1; off <= len; off++) {
 894               bcopy(b, b+off, len); bcopy(b+off, b, len);
 895                 if (bcmp(b, abc, len)) return(1);
 896             }
 897           }
 898         }
 899         return(0);
 900       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
 901
 902   GLIB_ASSERT_SET(glib_cv_working_bcopy)
 903   if test "$glib_cv_working_bcopy" = "yes"; then
 904     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
 905   fi
 906 fi
 907
 908 # Check for sys_errlist
 909 AC_MSG_CHECKING(for sys_errlist)
 910 AC_TRY_LINK(, [
 911 extern char *sys_errlist[];
 912 extern int sys_nerr;
 913 sys_errlist[sys_nerr-1][0] = 0;
 914 ], glib_ok=yes, glib_ok=no)
 915 AC_MSG_RESULT($glib_ok)
 916 if test "$glib_ok" = "no"; then
 917     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
 918 fi
 919
 920 # Check for sys_siglist
 921 AC_MSG_CHECKING(for sys_siglist)
 922 AC_TRY_LINK(, [
 923 extern char *sys_siglist[];
 924 exit (sys_siglist[0]);
 925 ], glib_ok=yes, glib_ok=no)
 926 AC_MSG_RESULT($glib_ok)
 927 if test "$glib_ok" = "no"; then
 928     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
 929 fi
 930
 931 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 932 AC_MSG_CHECKING(for sys_siglist declaration)
 933 AC_TRY_COMPILE([#include <signal.h>], [
 934 strlen (sys_siglist[0]);
 935 ], glib_ok=yes, glib_ok=no)
 936 AC_MSG_RESULT($glib_ok)
 937 if test "$glib_ok" = "no"; then
 938     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
 939 fi
 940
 941 # Check if <sys/select.h> needs to be included for fd_set
 942 AC_MSG_CHECKING([for fd_set])
 943 AC_TRY_COMPILE([#include <sys/types.h>],
 944         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 945 if test "$gtk_ok" = "yes"; then
 946     AC_MSG_RESULT([yes, found in sys/types.h])
 947 else
 948     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
 949     if test "$gtk_ok" = "yes"; then
 950         # *** FIXME: give it a different name
 951         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
 952         AC_MSG_RESULT([yes, found in sys/select.h])
 953     else
 954         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
 955         AC_MSG_RESULT(no)
 956     fi
 957 fi
 958
 959 dnl *** check for sane realloc() ***
 960 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
 961         AC_TRY_RUN([#include <stdlib.h>
 962         int main() {
 963           return realloc (0, sizeof (int)) == 0;
 964         }],
 965         [glib_cv_sane_realloc=yes],
 966         [glib_cv_sane_realloc=no],
 967         [glib_cv_sane_realloc=yes])
 968 ])
 969 if test x$glib_cv_sane_realloc = xyes; then
 970   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
 971 fi
 972
 973 dnl Check for nl_langinfo and CODESET
 974
 975 AC_MSG_CHECKING([for nl_langinfo (CODESET)])
 976 AC_TRY_COMPILE([#include <langinfo.h>],
 977         [char *codeset = nl_langinfo (CODESET);],
 978    AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
 979    have_codeset=yes,
 980    have_codeset=no)
 981 AC_MSG_RESULT($have_codeset)
 982
 983
 984 dnl ****************************************
 985 dnl *** strlcpy/strlcat                  ***
 986 dnl ****************************************
 987 # Check for strlcpy
 988 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
 989 AC_TRY_RUN([#include <stdlib.h>
 990 #include <string.h>
 991 int main() {
 992   char p[10];
 993   (void) strlcpy (p, "hi", 10);
 994   if (strlcat (p, "bye", 0) != 3)
 995     return 1;
 996   return 0;
 997 }], glib_cv_have_strlcpy=yes,
 998     glib_cv_have_strlcpy=no,
 999     glib_cv_have_strlcpy=no)])
1000 if test "$glib_cv_have_strlcpy" = "yes"; then
1001     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1002 fi
1003
1004
1005 dnl **********************
1006 dnl *** va_copy checks ***
1007 dnl **********************
1008 dnl we currently check for all three va_copy possibilities, so we get
1009 dnl all results in config.log for bug reports.
1010 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1011         AC_LINK_IFELSE([#include <stdarg.h>
1012         void f (int i, ...) {
1013         va_list args1, args2;
1014         va_start (args1, i);
1015         va_copy (args2, args1);
1016         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1017           exit (1);
1018         va_end (args1); va_end (args2);
1019         }
1020         int main() {
1021           f (0, 42);
1022           return 0;
1023         }],
1024         [glib_cv_va_copy=yes],
1025         [glib_cv_va_copy=no])
1026 ])
1027 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1028         AC_LINK_IFELSE([#include <stdarg.h>
1029         void f (int i, ...) {
1030         va_list args1, args2;
1031         va_start (args1, i);
1032         __va_copy (args2, args1);
1033         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1034           exit (1);
1035         va_end (args1); va_end (args2);
1036         }
1037         int main() {
1038           f (0, 42);
1039           return 0;
1040         }],
1041         [glib_cv___va_copy=yes],
1042         [glib_cv___va_copy=no])
1043 ])
1044
1045 if test "x$glib_cv_va_copy" = "xyes"; then
1046   g_va_copy_func=va_copy
1047 else if test "x$glib_cv___va_copy" = "xyes"; then
1048   g_va_copy_func=__va_copy
1049 fi
1050 fi
1051
1052 if test -n "$g_va_copy_func"; then
1053   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1054 fi
1055
1056 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1057         AC_TRY_RUN([#include <stdarg.h>
1058         void f (int i, ...) {
1059         va_list args1, args2;
1060         va_start (args1, i);
1061         args2 = args1;
1062         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1063           exit (1);
1064         va_end (args1); va_end (args2);
1065         }
1066         int main() {
1067           f (0, 42);
1068           return 0;
1069         }],
1070         [glib_cv_va_val_copy=yes],
1071         [glib_cv_va_val_copy=no],
1072         [glib_cv_va_val_copy=yes])
1073 ])
1074
1075 if test "x$glib_cv_va_val_copy" = "xno"; then
1076   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1077 fi
1078
1079 dnl ***********************
1080 dnl *** g_module checks ***
1081 dnl ***********************
1082 G_MODULE_LIBS=
1083 G_MODULE_LIBS_EXTRA=
1084 G_MODULE_PLUGIN_LIBS=
1085 if test x"$glib_native_win32" = xyes; then
1086   dnl No use for this on Win32
1087   G_MODULE_LDFLAGS=
1088 else
1089   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1090 fi
1091 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1092 G_MODULE_NEED_USCORE=0
1093 G_MODULE_BROKEN_RTLD_GLOBAL=0
1094 G_MODULE_HAVE_DLERROR=0
1095 dnl *** force native WIN32 shared lib loader
1096 if test -z "$G_MODULE_IMPL"; then
1097   case "$host" in
1098   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1099   esac
1100 fi
1101 dnl *** force native AIX library loader
1102 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1103 if test -z "$G_MODULE_IMPL"; then
1104   case "$host" in
1105   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1106   esac
1107 fi
1108 dnl *** dlopen() and dlsym() in system libraries
1109 if test -z "$G_MODULE_IMPL"; then
1110         AC_CHECK_FUNC(dlopen,
1111                       [AC_CHECK_FUNC(dlsym,
1112                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1113                       [])
1114 fi
1115 dnl *** load_image (BeOS)
1116 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1117   AC_CHECK_LIB(root, load_image,
1118       [G_MODULE_LIBS="-lbe -lroot -lglib"
1119       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1120       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1121       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1122       [])
1123 fi
1124 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1125 if test -z "$G_MODULE_IMPL"; then
1126         AC_CHECK_FUNC(NSLinkModule,
1127                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1128                        G_MODULE_NEED_USCORE=1],
1129                       [])
1130 fi
1131 dnl *** dlopen() and dlsym() in libdl
1132 if test -z "$G_MODULE_IMPL"; then
1133         AC_CHECK_LIB(dl, dlopen,
1134                      [AC_CHECK_LIB(dl, dlsym,
1135                                    [G_MODULE_LIBS=-ldl
1136                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1137                      [])
1138 fi
1139 dnl *** shl_load() in libdld (HP-UX)
1140 if test -z "$G_MODULE_IMPL"; then
1141         AC_CHECK_LIB(dld, shl_load,
1142                 [G_MODULE_LIBS=-ldld
1143                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1144                 [])
1145 fi
1146 dnl *** additional checks for G_MODULE_IMPL_DL
1147 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1148         LIBS_orig="$LIBS"
1149         LDFLAGS_orig="$LDFLAGS"
1150         LIBS="$G_MODULE_LIBS $LIBS"
1151         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1152 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1153         echo "void glib_plugin_test(void) { }" > plugin.c
1154         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1155                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1156         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1157                 glib_cv_rtldglobal_broken,[
1158                 AC_TRY_RUN([
1159 #include <dlfcn.h>
1160 #ifndef RTLD_GLOBAL
1161 #  define RTLD_GLOBAL 0
1162 #endif
1163 #ifndef RTLD_LAZY
1164 #  define RTLD_LAZY 0
1165 #endif
1166 int glib_plugin_test;
1167 int main () {
1168     void *handle, *global, *local;
1169     global = &glib_plugin_test;
1170     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1171     if (!handle) return 0;
1172     local = dlsym (handle, "glib_plugin_test");
1173     return global == local;
1174 }                       ],
1175                         [glib_cv_rtldglobal_broken=no],
1176                         [glib_cv_rtldglobal_broken=yes],
1177                         [glib_cv_rtldglobal_broken=no])
1178                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1179                 rmdir .libs 2>/dev/null
1180         ])
1181         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1182                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1183         else
1184                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1185         fi
1186 dnl *** check whether we need preceeding underscores
1187         AC_CACHE_CHECK([for preceeding underscore in symbols],
1188                 glib_cv_uscore,[
1189                 AC_TRY_RUN([#include <dlfcn.h>
1190                 int glib_underscore_test (void) { return 42; }
1191                 int main() {
1192                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1193                   handle = dlopen ((void*)0, 0);
1194                   if (handle) {
1195                     f1 = dlsym (handle, "glib_underscore_test");
1196                     f2 = dlsym (handle, "_glib_underscore_test");
1197                   } return (!f2 || f1);
1198                 }],
1199                         [glib_cv_uscore=yes],
1200                         [glib_cv_uscore=no],
1201                         [])
1202                 rm -f plugin.c plugin.$ac_objext plugin.lo
1203         ])
1204         GLIB_ASSERT_SET(glib_cv_uscore)
1205         if test "x$glib_cv_uscore" = "xyes"; then
1206                 G_MODULE_NEED_USCORE=1
1207         else
1208                 G_MODULE_NEED_USCORE=0
1209         fi
1210
1211         LDFLAGS="$LDFLAGS_orig"
1212 dnl *** check for having dlerror()
1213         AC_CHECK_FUNC(dlerror,
1214                 [G_MODULE_HAVE_DLERROR=1],
1215                 [G_MODULE_HAVE_DLERROR=0])
1216         LIBS="$LIBS_orig"
1217 fi
1218 dnl *** done, have we got an implementation?
1219 if test -z "$G_MODULE_IMPL"; then
1220         G_MODULE_IMPL=0
1221         G_MODULE_SUPPORTED=false
1222 else
1223         G_MODULE_SUPPORTED=true
1224 fi
1225
1226 AC_MSG_CHECKING(for the suffix of shared libraries)
1227 case "$host_os" in
1228   hpux9* | hpux10* | hpux11*)  # taken from ltconfig
1229     glib_gmodule_suffix='sl'
1230     ;;
1231   cygwin* | mingw*)
1232     glib_gmodule_suffix='dll'
1233     ;;
1234   aix*)
1235     glib_gmodule_suffix='a'
1236     ;;
1237   *)
1238     glib_gmodule_suffix='so'
1239     ;;
1240 esac
1241 AC_MSG_RESULT(.$glib_gmodule_suffix)
1242
1243 AC_SUBST(G_MODULE_SUPPORTED)
1244 AC_SUBST(G_MODULE_IMPL)
1245 AC_SUBST(G_MODULE_LIBS)
1246 AC_SUBST(G_MODULE_LIBS_EXTRA)
1247 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1248 AC_SUBST(G_MODULE_LDFLAGS)
1249 AC_SUBST(G_MODULE_HAVE_DLERROR)
1250 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1251 AC_SUBST(G_MODULE_NEED_USCORE)
1252 AC_SUBST(GLIB_DEBUG_FLAGS)
1253
1254 dnl **********************
1255 dnl *** g_spawn checks ***
1256 dnl **********************
1257
1258 AC_MSG_CHECKING(for gspawn implementation)
1259 case "$host" in
1260   *-*-mingw*)
1261     GSPAWN=gspawn-win32.lo
1262     ;;
1263   *)
1264     GSPAWN=gspawn.lo
1265     ;;
1266 esac
1267 AC_MSG_RESULT($GSPAWN)
1268 AC_SUBST(GSPAWN)
1269
1270 dnl *************************
1271 dnl *** GIOChannel checks ***
1272 dnl *************************
1273
1274 AC_MSG_CHECKING(for GIOChannel implementation)
1275 case "$host" in
1276   *-*-mingw*)
1277     GIO=giowin32.lo
1278     ;;
1279   *)
1280     GIO=giounix.lo
1281     ;;
1282 esac
1283 AC_MSG_RESULT($GIO)
1284 AC_SUBST(GIO)
1285
1286 dnl ****************************************
1287 dnl *** platform dependent source checks ***
1288 dnl ****************************************
1289
1290 AC_MSG_CHECKING(for platform-dependent source)
1291 case "$host" in
1292   *-*-cygwin*|*-*-mingw*)
1293     PLATFORMDEP=gwin32.lo
1294     ;;
1295   *)
1296     PLATFORMDEP=
1297     ;;
1298 esac
1299 AC_MSG_RESULT($PLATFORMDEP)
1300 AC_SUBST(PLATFORMDEP)
1301
1302 AC_MSG_CHECKING([whether to compile timeloop])
1303 case "$host" in
1304   *-*-cygwin*|*-*-mingw*)
1305     enable_timeloop=no
1306     ;;
1307   *)
1308     enable_timeloop=yes
1309     ;;
1310 esac
1311 AC_MSG_RESULT($enable_timeloop)
1312 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1313
1314 AC_MSG_CHECKING([if building for some Win32 platform])
1315 case "$host" in
1316   *-*-mingw*|*-*-cygwin*)
1317     platform_win32=yes
1318     ;;
1319   *)
1320     platform_win32=no
1321     ;;
1322 esac
1323 AC_MSG_RESULT($platform_win32)
1324 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1325
1326 dnl ***********************
1327 dnl *** g_thread checks ***
1328 dnl ***********************
1329
1330 AC_ARG_WITH(threads,
1331            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/solaris/win32@:>@],
1332                            [specify a thread implementation to use])],
1333            [if test "x$with_threads" = x; then
1334                 want_threads=yes
1335             else
1336                 want_threads=$with_threads
1337             fi],
1338            [want_threads=yes])
1339 if test "x$enable_threads" = "xno"; then
1340         want_threads=no
1341 fi
1342
1343 dnl error and warning message
1344 dnl *************************
1345
1346 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1347                 computer. GLib will not have a default thread implementation."
1348
1349 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1350                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1351                 compilation now, but then your programs might not work.
1352                 Please provide information on how it is done on your system."
1353
1354 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1355                 "
1356
1357 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1358                 provide information on your thread implementation.
1359                 You can also run 'configure --disable-threads'
1360                 to compile without thread support."
1361
1362 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1363                 functions will not be MT-safe during their first call because
1364                 there is no working 'getpwuid_r' on your system."
1365
1366 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1367                 because there is no 'localtime_r' on your system."
1368
1369 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1370                 crude surrogate will be used. If you happen to know a
1371                 yield function for your system, please inform the GLib
1372                 developers."
1373
1374 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1375                 threads on your system. Thus threads can only have the default
1376                 priority. If you happen to know these main/max
1377                 priorities, please inform the GLib developers."
1378
1379 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1380                 linking threaded applications. As GLib cannot do that
1381                 automatically, you will get an linkg error everytime you are
1382                 not using the right compiler. In that case you have to relink
1383                 with the right compiler. Ususally just '_r' is appended
1384                 to the compiler name."
1385
1386 dnl determination of thread implementation
1387 dnl ***************************************
1388
1389 # have_threads=no   means no thread support
1390 # have_threads=none means no default thread implementation
1391
1392 have_threads=no
1393 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
1394         case $host in
1395                 *-*-solaris*)
1396                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
1397                 ;;
1398         esac
1399 fi
1400 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1401                                 || test "x$want_threads" = xdce; then
1402         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1403         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1404         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1405         glib_save_CPPFLAGS="$CPPFLAGS"
1406         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1407         if test "x$have_threads" = xno; then
1408                 AC_TRY_COMPILE([#include <pthread.h>],
1409                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1410                         have_threads=posix)
1411         fi
1412         if test "x$have_threads" = xno; then
1413                 AC_TRY_COMPILE([#include <pthread.h>],
1414                         [pthread_mutex_t m;
1415                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1416                         have_threads=dce)
1417         fi
1418         # Tru64Unix requires -pthread to find pthread.h. See #103020
1419         CPPFLAGS="$CPPFLAGS -pthread"
1420         if test "x$have_threads" = xno; then
1421         AC_TRY_COMPILE([#include <pthread.h>],
1422                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1423                        have_threads=posix)
1424         fi
1425         CPPFLAGS="$glib_save_CPPFLAGS"
1426 fi
1427 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1428         case $host in
1429                 *-*-mingw*)
1430                 have_threads=win32
1431                 ;;
1432         esac
1433 fi
1434 if test "x$want_threads" = xnone; then
1435         have_threads=none
1436 fi
1437
1438 AC_MSG_CHECKING(for thread implementation)
1439
1440 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1441         AC_MSG_RESULT(none available)
1442         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1443 else
1444         AC_MSG_RESULT($have_threads)
1445 fi
1446
1447
1448 dnl determination of G_THREAD_CFLAGS
1449 dnl ********************************
1450
1451 G_THREAD_LIBS=
1452 G_THREAD_LIBS_EXTRA=
1453 G_THREAD_CFLAGS=
1454
1455 dnl
1456 dnl Test program for basic POSIX threads functionality
1457 dnl
1458 m4_define([glib_thread_test],[
1459 #include <pthread.h>
1460 int check_me = 0;
1461 void* func(void* data) {check_me = 42; return &check_me;}
1462 int main()
1463  { pthread_t t;
1464    void *ret;
1465    pthread_create (&t, $1, func, 0);
1466    pthread_join (t, &ret);
1467    exit (check_me != 42 || ret != &check_me);
1468 }])
1469
1470 dnl
1471 dnl Test program for sched_get_priority_min()
1472 dnl
1473 m4_define([glib_sched_priority_test],[
1474 #include <sched.h>
1475 #include <errno.h>
1476 int main() {
1477     errno = 0;
1478     return sched_get_priority_min(SCHED_OTHER)==-1
1479            && errno != 0;
1480 }])
1481
1482 if test x"$have_threads" != xno; then
1483
1484   if test x"$have_threads" = xposix; then
1485     # First we test for posix, whether -pthread or -pthreads do the trick as
1486     # both CPPFLAG and LIBS.
1487     # One of them does for most gcc versions and some other platforms/compilers
1488     # too and could be considered as the canonical way to go.
1489     case $host in
1490       *-*-cygwin*)
1491          # skip cygwin -pthread or -pthreads test
1492          ;;
1493       *)
1494         for flag in pthread pthreads; do
1495           glib_save_CFLAGS="$CFLAGS"
1496           CFLAGS="$CFLAGS -$flag"
1497           AC_TRY_RUN(glib_thread_test(0),
1498                      glib_flag_works=yes,
1499                      glib_flag_works=no,
1500                      [AC_LINK_IFELSE(glib_thread_test(0),
1501                                      glib_flag_works=yes,
1502                                      glib_flag_works=no)])
1503           CFLAGS="$glib_save_CFLAGS"
1504           if test $glib_flag_works = yes ; then
1505              G_THREAD_CFLAGS=-$flag
1506              G_THREAD_LIBS=-$flag
1507           fi
1508         done
1509          ;;
1510     esac
1511   fi
1512
1513   if test x"$G_THREAD_CFLAGS" = x; then
1514
1515     # The canonical -pthread[s] does not work. Try something different.
1516
1517     case $host in
1518         *-aix*)
1519                 if test x"$GCC" = xyes; then
1520                         # GCC 3.0 and above needs -pthread.
1521                         # Should be coverd by the case above.
1522                         # GCC 2.x and below needs -mthreads
1523                         G_THREAD_CFLAGS="-mthreads"
1524                         G_THREAD_LIBS=$G_THREAD_CFLAGS
1525                 else
1526                         # We are probably using the aix compiler. Normaly a
1527                         # program would have to be compiled with the _r variant
1528                         # of the corresponding compiler, but we as GLib cannot
1529                         # do that: but the good news is that for compiling the
1530                         # only difference is the added -D_THREAD_SAFE compile
1531                         # option. This is according to the "C for AIX User's
1532                         # Guide".
1533                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
1534                 fi
1535                 ;;
1536         *-dg-dgux*)  # DG/UX
1537                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
1538                 ;;
1539         *-osf*)
1540                 # So we are using dce threads. posix threads are already
1541                 # catched above.
1542                 G_THREAD_CFLAGS="-threads"
1543                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1544                 ;;
1545         *-solaris*)
1546                 if test x"$GCC" = xyes; then
1547                    # We are using solaris threads. posix threads are
1548                    # already catched above.
1549                         G_THREAD_CFLAGS="-threads"
1550                 else
1551                         G_THREAD_CFLAGS="-mt"
1552                 fi
1553                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1554                 ;;
1555         *-sysv5uw7*) # UnixWare 7
1556                 # We are not using gcc with -pthread. Catched above.
1557                 G_THREAD_CFLAGS="-Kthread"
1558                 G_THREAD_LIBS=$G_THREAD_CFLAGS
1559                 ;;
1560         *-mingw*)
1561                 # No flag needed when using MSVCRT.DLL
1562                 G_THREAD_CFLAGS=""
1563                 ;;
1564         *)
1565                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
1566                 ;;
1567     esac
1568
1569   fi
1570
1571     # if we are not finding the localtime_r function, then we probably are
1572     # not using the proper multithread flag
1573
1574     glib_save_CPPFLAGS="$CPPFLAGS"
1575     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1576
1577     # First we test, whether localtime_r is declared in time.h
1578     # directly. Then we test whether a macro localtime_r exists, in
1579     # which case localtime_r in the test program is replaced and thus
1580     # if we still find localtime_r in the output, it is not defined as
1581     # a macro.
1582
1583     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
1584       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
1585                                                            localtime_r(a,b)],
1586                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
1587
1588     CPPFLAGS="$glib_save_CPPFLAGS"
1589
1590     AC_MSG_CHECKING(thread related cflags)
1591     AC_MSG_RESULT($G_THREAD_CFLAGS)
1592     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
1593 fi
1594
1595 dnl determination of G_THREAD_LIBS
1596 dnl ******************************
1597
1598 mutex_has_default=no
1599 case $have_threads in
1600         posix|dce)
1601           glib_save_CPPFLAGS="$CPPFLAGS"
1602           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1603           if test x"$G_THREAD_LIBS" = x; then
1604             case $host in
1605               *-aix*)
1606                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
1607                 # probably using the aix compiler.
1608                 AC_MSG_WARN($AIX_COMPILE_INFO)
1609                 ;;
1610               *)
1611                 G_THREAD_LIBS=error
1612                 glib_save_LIBS="$LIBS"
1613                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
1614                         if test x"$thread_lib" = x; then
1615                                 add_thread_lib=""
1616                                 IN=""
1617                         else
1618                                 add_thread_lib="-l$thread_lib"
1619                                 IN=" in -l$thread_lib"
1620                         fi
1621                         if test x"$have_threads" = xposix; then
1622                                 defattr=0
1623                         else
1624                                 defattr=pthread_attr_default
1625                         fi
1626
1627                         LIBS="$add_thread_lib $glib_save_LIBS"
1628
1629                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
1630                         AC_TRY_RUN(glib_thread_test($defattr),
1631                                    glib_result=yes,
1632                                    glib_result=no,
1633                                    [AC_LINK_IFELSE(glib_thread_test($defattr),
1634                                                    glib_result=yes,
1635                                                    glib_result=no)])
1636                         AC_MSG_RESULT($glib_result)
1637
1638                         if test "$glib_result" = "yes" ; then
1639                           G_THREAD_LIBS="$add_thread_lib"
1640                           break
1641                         fi
1642                 done
1643                 if test "x$G_THREAD_LIBS" = xerror; then
1644                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1645                 fi
1646                 LIBS="$glib_save_LIBS"
1647                 ;;
1648             esac
1649           fi
1650
1651           glib_save_LIBS="$LIBS"
1652           for thread_lib in "" rt rte; do
1653             if test x"$thread_lib" = x; then
1654               add_thread_lib=""
1655               IN=""
1656             else
1657               add_thread_lib="-l$thread_lib"
1658               IN=" in -l$thread_lib"
1659             fi
1660             LIBS="$add_thread_lib $glib_save_LIBS"
1661
1662             AC_MSG_CHECKING(for sched_get_priority_min$IN)
1663             AC_TRY_RUN(glib_sched_priority_test,
1664                        glib_result=yes,
1665                        glib_result=no,
1666                        [AC_LINK_IFELSE(glib_sched_priority_test,
1667                                        glib_result=yes,
1668                                        glib_result=no)])
1669             AC_MSG_RESULT($glib_result)
1670
1671             if test "$glib_result" = "yes" ; then
1672                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
1673                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
1674                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
1675                break
1676             fi
1677           done
1678           LIBS="$glib_save_LIBS"
1679           mutex_has_default=yes
1680           mutex_default_type='pthread_mutex_t'
1681           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
1682           mutex_header_file='pthread.h'
1683           if test "x$have_threads" = "xposix"; then
1684             g_threads_impl="POSIX"
1685           else
1686             g_threads_impl="DCE"
1687             have_threads="posix"
1688           fi
1689           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
1690           CPPFLAGS="$glib_save_CPPFLAGS"
1691           ;;
1692         solaris)
1693            mutex_has_default=yes
1694            mutex_default_type='mutex_t'
1695            mutex_default_init="DEFAULTMUTEX"
1696            mutex_header_file='thread.h'
1697            g_threads_impl="SOLARIS"
1698            ;;
1699         win32)
1700            g_threads_impl="WIN32"
1701            ;;
1702         none|no)
1703            g_threads_impl="NONE"
1704            ;;
1705         *)
1706            g_threads_impl="NONE"
1707            G_THREAD_LIBS=error
1708            ;;
1709 esac
1710
1711 if test "x$G_THREAD_LIBS" = xerror; then
1712         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
1713 fi
1714
1715 case $host in
1716   *-*-beos*)
1717     G_THREAD_LIBS="-lbe -lroot -lglib "
1718     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1719     ;;
1720   *)
1721     ;;
1722 esac
1723
1724 AC_MSG_CHECKING(thread related libraries)
1725 AC_MSG_RESULT($G_THREAD_LIBS)
1726
1727 dnl check for mt safe function variants and some posix functions
1728 dnl ************************************************************
1729
1730 if test x"$have_threads" != xno; then
1731         glib_save_LIBS="$LIBS"
1732         # we are not doing the following for now, as this might require glib
1733         # to always be linked with the thread libs on some platforms.
1734         # LIBS="$LIBS $G_THREAD_LIBS"
1735         AC_CHECK_FUNCS(localtime_r)
1736         if test "$ac_cv_header_pwd_h" = "yes"; then
1737                 AC_CACHE_CHECK([for posix getpwuid_r],
1738                         ac_cv_func_posix_getpwuid_r,
1739                         [AC_TRY_RUN([
1740 #include <errno.h>
1741 #include <pwd.h>
1742 int main () {
1743     char buffer[10000];
1744     struct passwd pwd, *pwptr = &pwd;
1745     int error;
1746     errno = 0;
1747     error = getpwuid_r (0, &pwd, buffer,
1748                         sizeof (buffer), &pwptr);
1749    return (error < 0 && errno == ENOSYS)
1750            || error == ENOSYS;
1751 }                               ],
1752                                 [ac_cv_func_posix_getpwuid_r=yes],
1753                                 [ac_cv_func_posix_getpwuid_r=no])])
1754                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
1755                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
1756                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
1757                                 [Have POSIX function getpwuid_r])
1758                 else
1759                         AC_CACHE_CHECK([for nonposix getpwuid_r],
1760                                 ac_cv_func_nonposix_getpwuid_r,
1761                                 [AC_TRY_LINK([#include <pwd.h>],
1762                                         [char buffer[10000];
1763                                         struct passwd pwd;
1764                                         getpwuid_r (0, &pwd, buffer,
1765                                                         sizeof (buffer));],
1766                                         [ac_cv_func_nonposix_getpwuid_r=yes],
1767                                         [ac_cv_func_nonposix_getpwuid_r=no])])
1768                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
1769                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
1770                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
1771                                         [Have non-POSIX function getpwuid_r])
1772                         fi
1773                 fi
1774         fi
1775         LIBS="$G_THREAD_LIBS $LIBS"
1776         if test x"$have_threads" = xposix; then
1777                 glib_save_CPPFLAGS="$CPPFLAGS"
1778                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1779                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
1780                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
1781                 # This is not AC_CHECK_FUNC to also work with function
1782                 # name mangling in header files.
1783                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
1784                 AC_TRY_LINK([#include <pthread.h>],
1785                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
1786                         [AC_MSG_RESULT(yes)
1787                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
1788                                   [Have function pthread_attr_setstacksize])],
1789                         [AC_MSG_RESULT(no)])
1790                 AC_MSG_CHECKING(for minimal/maximal thread priority)
1791                 if test x"$posix_priority_min" = x; then
1792                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
1793                                 PX_PRIO_MIN],,[
1794                                 posix_priority_min=PX_PRIO_MIN
1795                                 posix_priority_max=PX_PRIO_MAX])
1796                 fi
1797                 if test x"$posix_priority_min" = x; then
1798                         # AIX
1799                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
1800                                 PTHREAD_PRIO_MIN],,[
1801                                 posix_priority_min=PTHREAD_PRIO_MIN
1802                                 posix_priority_max=PTHREAD_PRIO_MAX])
1803                 fi
1804                 if test x"$posix_priority_min" = x; then
1805                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
1806                                 PRI_OTHER_MIN],,[
1807                                 posix_priority_min=PRI_OTHER_MIN
1808                                 posix_priority_max=PRI_OTHER_MAX])
1809                 fi
1810                 if test x"$posix_priority_min" = x; then
1811                         AC_MSG_RESULT(none found)
1812                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
1813                         posix_priority_min=-1
1814                         posix_priority_max=-1
1815                 else
1816                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
1817                         AC_MSG_CHECKING(for pthread_setschedparam)
1818                         AC_TRY_LINK([#include <pthread.h>],
1819                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
1820                           [AC_MSG_RESULT(yes)
1821                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
1822                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
1823                           [AC_MSG_RESULT(no)
1824                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
1825                 fi
1826                 posix_yield_func=none
1827                 AC_MSG_CHECKING(for posix yield function)
1828                 for yield_func in sched_yield pthread_yield_np pthread_yield \
1829                                                         thr_yield; do
1830                         AC_TRY_LINK([#include <pthread.h>],
1831                                 [$yield_func()],
1832                                 [posix_yield_func="$yield_func"
1833                                 break])
1834                 done
1835                 if test x"$posix_yield_func" = xnone; then
1836                         AC_MSG_RESULT(none found)
1837                         AC_MSG_WARN($POSIX_NO_YIELD)
1838                         posix_yield_func="g_usleep(1000)"
1839                 else
1840                         AC_MSG_RESULT($posix_yield_func)
1841                         posix_yield_func="$posix_yield_func()"
1842                 fi
1843                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
1844                 CPPFLAGS="$glib_save_CPPFLAGS"
1845
1846         elif test x"$have_threads" = xwin32; then
1847                 # It's a pointer to a private struct
1848                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
1849         elif test x"$have_threads" = xsolaris; then
1850                 GLIB_SIZEOF([#include <thread.h>], thread_t, system_thread)
1851         fi
1852
1853         LIBS="$glib_save_LIBS"
1854
1855         # now spit out all the warnings.
1856         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
1857            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
1858                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
1859         fi
1860         if test "$ac_cv_func_localtime_r" != "yes"; then
1861                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
1862         fi
1863 fi
1864
1865 if test x"$glib_cv_sizeof_system_thread" = x; then
1866    # use a pointer as a fallback.
1867    GLIB_SIZEOF(,void *, system_thread)
1868 fi
1869
1870 #
1871 # Hack to deal with:
1872 #
1873 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
1874 #     building shared libraries with linux.
1875 #
1876 case $host in
1877   *-*-linux*)
1878     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
1879     ;;
1880 esac
1881
1882 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
1883                    [Source file containing theread implementation])
1884 AC_SUBST(G_THREAD_CFLAGS)
1885 AC_SUBST(G_THREAD_LIBS)
1886 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
1887 AC_SUBST(G_THREAD_LIBS_EXTRA)
1888
1889 dnl **********************************************
1890 dnl *** GDefaultMutex setup and initialization ***
1891 dnl **********************************************
1892 dnl
1893 dnl if mutex_has_default = yes, we also got
1894 dnl mutex_default_type, mutex_default_init and mutex_header_file
1895 if test $mutex_has_default = yes ; then
1896         glib_save_CPPFLAGS="$CPPFLAGS"
1897         glib_save_LIBS="$LIBS"
1898         LIBS="$G_THREAD_LIBS $LIBS"
1899         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1900         GLIB_SIZEOF([#include <$mutex_header_file>],
1901                     $mutex_default_type,
1902                     gmutex)
1903         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
1904                            $mutex_default_type,
1905                            gmutex,
1906                            $glib_cv_sizeof_gmutex,
1907                            $mutex_default_init)
1908         if test x"$glib_cv_byte_contents_gmutex" = xno; then
1909                 mutex_has_default=no
1910         fi
1911         CPPFLAGS="$glib_save_CPPFLAGS"
1912         LIBS="$glib_save_LIBS"
1913 fi
1914
1915 dnl ********************************
1916 dnl *** g_atomic_* tests for gcc ***
1917 dnl ********************************
1918
1919 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
1920
1921 if test x"$GCC" = xyes; then
1922   case $host_cpu in
1923     i386)
1924       AC_MSG_RESULT([none])
1925       glib_memory_barrier_needed=no
1926       ;;
1927     i?86)
1928       AC_MSG_RESULT([i486])
1929       AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
1930                          [i486 atomic implementation])
1931       glib_memory_barrier_needed=no
1932       ;;
1933     sparc*)
1934       SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
1935                 when you are using a sparc with v9 instruction set (most
1936                 sparcs nowadays). This will make the code for atomic
1937                 operations much faster. The resulting code will not run
1938                 on very old sparcs though."
1939
1940       AC_LINK_IFELSE([[
1941         main ()
1942         {
1943           int tmp1, tmp2, tmp3;
1944           __asm__ __volatile__("casx [%2], %0, %1"
1945                                : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
1946         }]],
1947         AC_MSG_RESULT([sparcv9])
1948         AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
1949                            [sparcv9 atomic implementation]),
1950         AC_MSG_RESULT([no])
1951         AC_MSG_WARN([[$SPARCV9_WARNING]]))
1952       glib_memory_barrier_needed=yes
1953       ;;
1954     alpha*)
1955       AC_MSG_RESULT([alpha])
1956       AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
1957                          [alpha atomic implementation])
1958       glib_memory_barrier_needed=yes
1959       ;;
1960     x86_64)
1961       AC_MSG_RESULT([x86_64])
1962       AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
1963                          [x86_64 atomic implementation])
1964       glib_memory_barrier_needed=no
1965      ;;
1966     powerpc*)
1967       AC_MSG_RESULT([powerpc])
1968       AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
1969                          [powerpc atomic implementation])
1970       glib_memory_barrier_needed=yes
1971       ;;
1972     ia64)
1973       AC_MSG_RESULT([ia64])
1974       AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
1975                          [ia64 atomic implementation])
1976       glib_memory_barrier_needed=yes
1977       ;;
1978     *)
1979       AC_MSG_RESULT([none])
1980       glib_memory_barrier_needed=yes
1981       ;;
1982   esac
1983 fi
1984
1985 dnl ****************************************
1986 dnl *** GLib POLL* compatibility defines ***
1987 dnl ****************************************
1988
1989 glib_poll_includes=["
1990 #include <sys/types.h>
1991 #include <sys/poll.h>
1992 "]
1993
1994 if test $ac_cv_header_sys_types_h = yes &&
1995    test $ac_cv_header_sys_poll_h = yes ; then
1996   glib_failed=false
1997   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
1998   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
1999   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2000   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2001   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2002   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2003   if $glib_failed ; then
2004     AC_MSG_ERROR([Could not determine values for POLL* constants])
2005   fi
2006 else
2007   glib_cv_value_POLLIN=1
2008   glib_cv_value_POLLOUT=4
2009   glib_cv_value_POLLPRI=2
2010   glib_cv_value_POLLERR=8
2011   glib_cv_value_POLLHUP=16
2012   glib_cv_value_POLLNVAL=32
2013 fi
2014
2015 dnl **********************
2016 dnl *** Win32 API libs ***
2017 dnl **********************
2018
2019 case $host in
2020   *-*-cygwin*)
2021         G_LIBS_EXTRA="-luser32 -lkernel32"
2022     ;;
2023   *-*-mingw*)
2024         G_LIBS_EXTRA="-lwsock32 -lole32"
2025     ;;
2026   *)
2027         G_LIBS_EXTRA=""
2028     ;;
2029 esac
2030 AC_SUBST(G_LIBS_EXTRA)
2031
2032 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2033 dnl since we need it for g_iconv()
2034
2035 AC_MSG_CHECKING([for EILSEQ])
2036 AC_TRY_COMPILE([
2037 #include <errno.h>
2038 ],
2039 [
2040 int error = EILSEQ;
2041 ], have_eilseq=yes, have_eilseq=no);
2042 AC_MSG_RESULT($have_eilseq)
2043
2044 dnl ******************************************************************
2045 dnl *** Look for glib-genmarshal in PATH if we are cross-compiling ***
2046 dnl ******************************************************************
2047
2048 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2049
2050 if test $cross_compiling = yes; then
2051   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2052   if test x$GLIB_GENMARSHAL = xno; then
2053     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2054   fi
2055 fi
2056
2057 dnl **************************
2058 dnl *** Checks for gtk-doc ***
2059 dnl **************************
2060
2061 GTK_DOC_CHECK([1.0])
2062
2063 AC_ARG_ENABLE(man,
2064               [AC_HELP_STRING([--enable-man],
2065                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2066               enable_man=no)
2067
2068 if test "${enable_man}" != no; then
2069 dnl
2070 dnl Check for xsltproc
2071 dnl
2072 AC_PATH_PROG([XSLTPROC], [xsltproc])
2073   if test -z "$XSLTPROC"; then
2074     enable_man=no
2075   fi
2076
2077   dnl check for DocBook DTD and stylesheets in the local catalog.
2078   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2079      [DocBook XML DTD V4.1.2],,enable_man=no)
2080   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2081      [DocBook XSL Stylesheets],,enable_man=no)
2082 fi
2083
2084 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2085
2086 dnl ******************************
2087 dnl *** output the whole stuff ***
2088 dnl ******************************
2089
2090 dnl this section will only be run if config.status is invoked with no
2091 dnl arguments, or with "glibconfig.h" as an argument.
2092 AC_CONFIG_COMMANDS([glibconfig.h],
2093 [
2094         outfile=glibconfig.h-tmp
2095         cat > $outfile <<\_______EOF
2096 /* glibconfig.h
2097  *
2098  * This is a generated file.  Please modify 'configure.in'
2099  */
2100
2101 #ifndef __G_LIBCONFIG_H__
2102 #define __G_LIBCONFIG_H__
2103
2104 #include <glib/gmacros.h>
2105
2106 _______EOF
2107
2108         if test x$glib_limits_h = xyes; then
2109           echo '#include <limits.h>' >> $outfile
2110         fi
2111         if test x$glib_float_h = xyes; then
2112           echo '#include <float.h>' >> $outfile
2113         fi
2114         if test x$glib_values_h = xyes; then
2115           echo '#include <values.h>' >> $outfile
2116         fi
2117         if test "$glib_header_alloca_h" = "yes"; then
2118           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2119         fi
2120         if test x$glib_sys_poll_h = xyes; then
2121           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2122         fi
2123
2124         cat >> $outfile <<_______EOF
2125
2126 G_BEGIN_DECLS
2127
2128 #define G_MINFLOAT      $glib_mf
2129 #define G_MAXFLOAT      $glib_Mf
2130 #define G_MINDOUBLE     $glib_md
2131 #define G_MAXDOUBLE     $glib_Md
2132 #define G_MINSHORT      $glib_ms
2133 #define G_MAXSHORT      $glib_Ms
2134 #define G_MAXUSHORT     $glib_Mus
2135 #define G_MININT        $glib_mi
2136 #define G_MAXINT        $glib_Mi
2137 #define G_MAXUINT       $glib_Mui
2138 #define G_MINLONG       $glib_ml
2139 #define G_MAXLONG       $glib_Ml
2140 #define G_MAXULONG      $glib_Mul
2141
2142 _______EOF
2143
2144
2145         ### this should always be true in a modern C/C++ compiler
2146         cat >>$outfile <<_______EOF
2147 typedef signed char gint8;
2148 typedef unsigned char guint8;
2149 _______EOF
2150
2151
2152         if test -n "$gint16"; then
2153           cat >>$outfile <<_______EOF
2154 typedef signed $gint16 gint16;
2155 typedef unsigned $gint16 guint16;
2156 #define G_GINT16_MODIFIER $gint16_modifier
2157 #define G_GINT16_FORMAT $gint16_format
2158 #define G_GUINT16_FORMAT $guint16_format
2159 _______EOF
2160         fi
2161
2162
2163         if test -n "$gint32"; then
2164           cat >>$outfile <<_______EOF
2165 typedef signed $gint32 gint32;
2166 typedef unsigned $gint32 guint32;
2167 #define G_GINT32_MODIFIER $gint32_modifier
2168 #define G_GINT32_FORMAT $gint32_format
2169 #define G_GUINT32_FORMAT $guint32_format
2170 _______EOF
2171         fi
2172
2173         cat >>$outfile <<_______EOF
2174 #define G_HAVE_GINT64 1          /* deprecated, always true */
2175
2176 ${glib_extension}typedef signed $gint64 gint64;
2177 ${glib_extension}typedef unsigned $gint64 guint64;
2178
2179 #define G_GINT64_CONSTANT(val)  $gint64_constant
2180 _______EOF
2181
2182         if test x$gint64_format != x ; then
2183           cat >>$outfile <<_______EOF
2184 #define G_GINT64_MODIFIER $gint64_modifier
2185 #define G_GINT64_FORMAT $gint64_format
2186 #define G_GUINT64_FORMAT $guint64_format
2187 _______EOF
2188         else
2189           cat >>$outfile <<_______EOF
2190 #undef G_GINT64_MODIFIER
2191 #undef G_GINT64_FORMAT
2192 #undef G_GUINT64_FORMAT
2193 _______EOF
2194         fi
2195
2196         cat >>$outfile <<_______EOF
2197
2198 #define GLIB_SIZEOF_VOID_P $glib_void_p
2199 #define GLIB_SIZEOF_LONG   $glib_long
2200 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2201
2202 _______EOF
2203
2204         cat >>$outfile <<_______EOF
2205 typedef signed $glib_size_type_define gssize;
2206 typedef unsigned $glib_size_type_define gsize;
2207 #define G_GSIZE_MODIFIER $gsize_modifier
2208 #define G_GSSIZE_FORMAT $gssize_format
2209 #define G_GSIZE_FORMAT $gsize_format
2210
2211 #define G_MAXSIZE       G_MAXU$glib_msize_type
2212 _______EOF
2213
2214         if test -z "$glib_unknown_void_p"; then
2215           cat >>$outfile <<_______EOF
2216
2217 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2218 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2219
2220 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2221 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2222 _______EOF
2223         else
2224           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2225         fi
2226
2227
2228
2229         cat >>$outfile <<_______EOF
2230 $glib_atexit
2231 $glib_memmove
2232 $glib_defines
2233 $glib_os
2234
2235 $glib_vacopy
2236
2237 #ifdef  __cplusplus
2238 #define G_HAVE_INLINE   1
2239 #else   /* !__cplusplus */
2240 $glib_inline
2241 #endif  /* !__cplusplus */
2242
2243 #ifdef  __cplusplus
2244 #define G_CAN_INLINE    1
2245 _______EOF
2246
2247         if test x$g_can_inline = xyes ; then
2248                 cat >>$outfile <<_______EOF
2249 #else   /* !__cplusplus */
2250 #define G_CAN_INLINE    1
2251 _______EOF
2252         fi
2253
2254         cat >>$outfile <<_______EOF
2255 #endif
2256
2257 _______EOF
2258
2259         if test x$g_have_iso_c_varargs = xyes ; then
2260                 cat >>$outfile <<_______EOF
2261 #ifndef __cplusplus
2262 # define G_HAVE_ISO_VARARGS 1
2263 #endif
2264 _______EOF
2265         fi
2266         if test x$g_have_iso_cxx_varargs = xyes ; then
2267                 cat >>$outfile <<_______EOF
2268 #ifdef __cplusplus
2269 # define G_HAVE_ISO_VARARGS 1
2270 #endif
2271 _______EOF
2272         fi
2273         if test x$g_have_gnuc_varargs = xyes ; then
2274                 cat >>$outfile <<_______EOF
2275
2276 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2277  * is passed ISO vararg support is turned off, and there is no work
2278  * around to turn it on, so we unconditionally turn it off.
2279  */
2280 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2281 #  undef G_HAVE_ISO_VARARGS
2282 #endif
2283
2284 #define G_HAVE_GNUC_VARARGS 1
2285 _______EOF
2286         fi
2287
2288         case x$g_stack_grows in
2289         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2290         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2291         esac
2292
2293
2294         echo >>$outfile
2295         if test x$g_have_eilseq = xno; then
2296                 cat >>$outfile <<_______EOF
2297 #ifndef EILSEQ
2298 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2299  * The correspondence between this and the corresponding definition
2300  * in libiconv is essential.
2301  */
2302 #  define EILSEQ ENOENT
2303 #endif
2304 _______EOF
2305
2306         fi
2307
2308         if test x$g_have_gnuc_visibility = xyes ; then
2309                 cat >>$outfile <<_______EOF
2310 #define G_HAVE_GNUC_VISIBILITY 1
2311 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2312 _______EOF
2313         else
2314                 cat >>$outfile <<_______EOF
2315 #define G_GNUC_INTERNAL
2316 _______EOF
2317         fi
2318
2319
2320         echo >>$outfile
2321         if test x$g_mutex_has_default = xyes; then
2322                 cat >>$outfile <<_______EOF
2323 $g_enable_threads_def G_THREADS_ENABLED
2324 #define G_THREADS_IMPL_$g_threads_impl_def
2325 typedef struct _GStaticMutex GStaticMutex;
2326 struct _GStaticMutex
2327 {
2328   struct _GMutex *runtime_mutex;
2329   union {
2330     char   pad[[$g_mutex_sizeof]];
2331     double dummy_double;
2332     void  *dummy_pointer;
2333     long   dummy_long;
2334   } static_mutex;
2335 };
2336 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
2337 #define g_static_mutex_get_mutex(mutex) \\
2338   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->static_mutex)) : \\
2339    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
2340 _______EOF
2341         else
2342                 cat >>$outfile <<_______EOF
2343 $g_enable_threads_def G_THREADS_ENABLED
2344 #define G_THREADS_IMPL_$g_threads_impl_def
2345 typedef struct _GMutex* GStaticMutex;
2346 #define G_STATIC_MUTEX_INIT NULL
2347 #define g_static_mutex_get_mutex(mutex) \\
2348   (g_static_mutex_get_mutex_impl_shortcut (mutex))
2349 _______EOF
2350         fi
2351
2352         cat >>$outfile <<_______EOF
2353 /* This represents a system thread as used by the implementation. An
2354  * alien implementaion, as loaded by g_thread_init can only count on
2355  * "sizeof (gpointer)" bytes to store their info. We however need more
2356  * for some of our native implementations. */
2357 typedef union _GSystemThread GSystemThread;
2358 union _GSystemThread
2359 {
2360   char   data[[$g_system_thread_sizeof]];
2361   double dummy_double;
2362   void  *dummy_pointer;
2363   long   dummy_long;
2364 };
2365 _______EOF
2366         if test x"$g_memory_barrier_needed" != xno; then
2367           echo >>$outfile
2368           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2369         fi
2370
2371         echo >>$outfile
2372         g_bit_sizes="16 32 64"
2373         for bits in $g_bit_sizes; do
2374           cat >>$outfile <<_______EOF
2375 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
2376 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
2377 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
2378 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
2379 _______EOF
2380         done
2381
2382         cat >>$outfile <<_______EOF
2383 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
2384 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
2385 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
2386 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
2387 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
2388 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
2389 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
2390 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
2391 #define G_BYTE_ORDER $g_byte_order
2392
2393 #define GLIB_SYSDEF_POLLIN =$g_pollin
2394 #define GLIB_SYSDEF_POLLOUT =$g_pollout
2395 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
2396 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
2397 #define GLIB_SYSDEF_POLLERR =$g_pollerr
2398 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
2399
2400 #define G_MODULE_SUFFIX "$g_module_suffix"
2401
2402 typedef $g_pid_type GPid;
2403
2404 G_END_DECLS
2405
2406 #endif /* GLIBCONFIG_H */
2407 _______EOF
2408
2409
2410         if cmp -s $outfile glibconfig.h; then
2411           AC_MSG_NOTICE([glibconfig.h is unchanged])
2412           rm -f $outfile
2413         else
2414           mv $outfile glibconfig.h
2415         fi
2416 ],[
2417
2418 # Note that if two cases are the same, case goes with the first one.
2419 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
2420 # on variable expansion in case labels.  Look at the generated config.status
2421 # for a hint.
2422
2423 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
2424   glib_header_alloca_h="$ac_cv_working_alloca_h"
2425 else
2426   glib_header_alloca_h="$ac_cv_header_alloca_h"
2427 fi
2428
2429 case xyes in
2430 x$ac_cv_header_float_h)
2431   glib_float_h=yes
2432   glib_mf=FLT_MIN glib_Mf=FLT_MAX
2433   glib_md=DBL_MIN glib_Md=DBL_MAX
2434   ;;
2435 x$ac_cv_header_values_h)
2436   glib_values_h=yes
2437   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
2438   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
2439   ;;
2440 esac
2441
2442 case xyes in
2443 x$ac_cv_header_limits_h)
2444   glib_limits_h=yes
2445   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
2446   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
2447   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
2448   ;;
2449 x$ac_cv_header_values_h)
2450   glib_values_h=yes
2451   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
2452   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
2453   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
2454   ;;
2455 esac
2456
2457 if test x$ac_cv_header_sys_poll_h = xyes ; then
2458   glib_sys_poll_h=yes
2459 fi
2460
2461 case 2 in
2462 $ac_cv_sizeof_short)
2463   gint16=short
2464   gint16_modifier='"h"'
2465   gint16_format='"hi"'
2466   guint16_format='"hu"'
2467   ;;
2468 $ac_cv_sizeof_int)
2469   gint16=int
2470   gint16_modifier='""'
2471   gint16_format='"i"'
2472   guint16_format='"u"'
2473   ;;
2474 esac
2475 case 4 in
2476 $ac_cv_sizeof_short)
2477   gint32=short
2478   gint32_modifier='"h"'
2479   gint32_format='"hi"'
2480   guint32_format='"hu"'
2481   ;;
2482 $ac_cv_sizeof_int)
2483   gint32=int
2484   gint32_modifier='""'
2485   gint32_format='"i"'
2486   guint32_format='"u"'
2487   ;;
2488 $ac_cv_sizeof_long)
2489   gint32=long
2490   gint32_modifier='"l"'
2491   gint32_format='"li"'
2492   guint32_format='"lu"'
2493   ;;
2494 esac
2495 case 8 in
2496 $ac_cv_sizeof_int)
2497   gint64=int
2498   gint64_modifier='""'
2499   gint64_format='"i"'
2500   guint64_format='"u"'
2501   glib_extension=
2502   gint64_constant='(val)'
2503   ;;
2504 $ac_cv_sizeof_long)
2505   gint64=long
2506   gint64_modifier='"l"'
2507   gint64_format='"li"'
2508   guint64_format='"lu"'
2509   glib_extension=
2510   gint64_constant='(val##L)'
2511   ;;
2512 $ac_cv_sizeof_long_long)
2513   gint64='long long'
2514   if test -n "$glib_cv_long_long_format"; then
2515     gint64_modifier='"'$glib_cv_long_long_format'"'
2516     gint64_format='"'$glib_cv_long_long_format'i"'
2517     guint64_format='"'$glib_cv_long_long_format'u"'
2518   fi
2519   glib_extension='G_GNUC_EXTENSION '
2520   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
2521   ;;
2522 $ac_cv_sizeof___int64)
2523   gint64='__int64'
2524   if test -n "$glib_cv_long_long_format"; then
2525     gint64_modifier='"'$glib_cv_long_long_format'"'
2526     gint64_format='"'$glib_cv_long_long_format'i"'
2527     guint64_format='"'$glib_cv_long_long_format'u"'
2528   fi
2529   glib_extension=
2530   gint64_constant='(val##i64)'
2531   ;;
2532 esac
2533 glib_size_t=$ac_cv_sizeof_size_t
2534 glib_size_type_define=$glib_size_type
2535 glib_void_p=$ac_cv_sizeof_long
2536 glib_long=$ac_cv_sizeof_void_p
2537
2538 case $glib_size_type in
2539 short)
2540   gsize_modifier='"h"'
2541   gsize_format='"hu"'
2542   gssize_format='"hi"'
2543   glib_msize_type='SHRT'
2544   ;;
2545 int)
2546   gsize_modifier='""'
2547   gsize_format='"u"'
2548   gssize_format='"i"'
2549   glib_msize_type='INT'
2550   ;;
2551 long)
2552   gsize_modifier='"l"'
2553   gsize_format='"lu"'
2554   gssize_format='"li"'
2555   glib_msize_type='LONG'
2556   ;;
2557 esac
2558
2559 gintbits=`expr $ac_cv_sizeof_int \* 8`
2560 glongbits=`expr $ac_cv_sizeof_long \* 8`
2561
2562
2563 case $ac_cv_sizeof_void_p in
2564 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
2565 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
2566 *)                      glib_unknown_void_p=yes ;;
2567 esac
2568
2569
2570 case xyes in
2571 x$ac_cv_func_atexit)
2572   glib_atexit="
2573 #ifdef NeXT /* @#%@! NeXTStep */
2574 # define g_ATEXIT(proc) (!atexit (proc))
2575 #else
2576 # define g_ATEXIT(proc) (atexit (proc))
2577 #endif"
2578   ;;
2579 x$ac_cv_func_on_exit)
2580   glib_atexit="
2581 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
2582   ;;
2583 esac
2584
2585 case xyes in
2586 x$ac_cv_func_memmove)
2587   glib_memmove='
2588 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
2589   ;;
2590 x$glib_cv_working_bcopy)
2591   glib_memmove="
2592 /* memmove isn't available, but bcopy can copy overlapping memory regions */
2593 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
2594   ;;
2595 *)
2596   glib_memmove="
2597 /* memmove isn't found and bcopy can't copy overlapping memory regions,
2598  * so we have to roll our own copy routine. */
2599 void g_memmove (void* dest, const void * src, unsigned long len);"
2600   ;;
2601 esac
2602
2603 glib_defines="
2604 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
2605 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
2606 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
2607 "
2608
2609 case xyes in
2610 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
2611 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
2612 *)                      glib_vacopy=''
2613 esac
2614
2615 if test x$glib_cv_va_val_copy = xno; then
2616   glib_vacopy="\$glib_vacopy
2617 #define G_VA_COPY_AS_ARRAY 1"
2618 fi
2619
2620 if test x$glib_cv_hasinline = xyes; then
2621     glib_inline='#define G_HAVE_INLINE 1'
2622 fi
2623 if test x$glib_cv_has__inline = xyes; then
2624     glib_inline="\$glib_inline
2625 #define G_HAVE___INLINE 1"
2626 fi
2627 if test x$glib_cv_has__inline__ = xyes; then
2628     glib_inline="\$glib_inline
2629 #define G_HAVE___INLINE__ 1"
2630 fi
2631
2632 g_have_gnuc_varargs=$g_have_gnuc_varargs
2633 g_have_iso_c_varargs=$g_have_iso_c_varargs
2634 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
2635
2636 g_can_inline=$g_can_inline
2637 g_have_gnuc_visibility=$g_have_gnuc_visibility
2638
2639 case xyes in
2640 x$ac_cv_c_bigendian)
2641   g_byte_order=G_BIG_ENDIAN
2642   g_bs_native=BE
2643   g_bs_alien=LE
2644   ;;
2645 *)
2646   g_byte_order=G_LITTLE_ENDIAN
2647   g_bs_native=LE
2648   g_bs_alien=BE
2649   ;;
2650 esac
2651
2652 g_pollin=$glib_cv_value_POLLIN
2653 g_pollout=$glib_cv_value_POLLOUT
2654 g_pollpri=$glib_cv_value_POLLPRI
2655 g_pollhup=$glib_cv_value_POLLHUP
2656 g_pollerr=$glib_cv_value_POLLERR
2657 g_pollnval=$glib_cv_value_POLLNVAL
2658
2659 g_stack_grows=$glib_cv_stack_grows
2660
2661 g_have_eilseq=$have_eilseq
2662
2663 case x$have_threads in
2664 xno)    g_enable_threads_def="#undef";;
2665 *)      g_enable_threads_def="#define";;
2666 esac
2667
2668 g_threads_impl_def=$g_threads_impl
2669
2670 g_mutex_has_default="$mutex_has_default"
2671 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
2672 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
2673 g_mutex_contents="$glib_cv_byte_contents_gmutex"
2674
2675 g_memory_barrier_needed="$glib_memory_barrier_needed"
2676
2677 g_module_suffix="$glib_gmodule_suffix"
2678
2679 g_pid_type="$glib_pid_type"
2680 case $host in
2681   *-*-beos*)
2682     glib_os="#define G_OS_BEOS"
2683     ;;
2684   *-*-cygwin*)
2685     glib_os="#define G_OS_UNIX
2686 #define G_PLATFORM_WIN32
2687 #define G_WITH_CYGWIN"
2688     ;;
2689   *-*-mingw*)
2690     glib_os="#define G_OS_WIN32
2691 #define G_PLATFORM_WIN32"
2692     ;;
2693   *)
2694     glib_os="#define G_OS_UNIX"
2695     ;;
2696 esac
2697 ])
2698
2699 AC_CONFIG_FILES([
2700 glib-2.0.pc
2701 glib-2.0-uninstalled.pc
2702 gmodule-2.0.pc
2703 gmodule-no-export-2.0.pc
2704 gmodule-2.0-uninstalled.pc
2705 gthread-2.0.pc
2706 gthread-2.0-uninstalled.pc
2707 gobject-2.0.pc
2708 gobject-2.0-uninstalled.pc
2709 glib-zip
2710 glib-gettextize
2711 Makefile
2712 build/Makefile
2713 build/win32/Makefile
2714 build/win32/dirent/Makefile
2715 glib/Makefile
2716 glib/libcharset/Makefile
2717 glib/gnulib/Makefile
2718 gmodule/Makefile
2719 gmodule/gmoduleconf.h
2720 gobject/Makefile
2721 gobject/glib-mkenums
2722 gthread/Makefile
2723 po/Makefile.in
2724 docs/Makefile
2725 docs/reference/Makefile
2726 docs/reference/glib/Makefile
2727 docs/reference/glib/version.xml
2728 docs/reference/gobject/Makefile
2729 docs/reference/gobject/version.xml
2730 tests/Makefile
2731 tests/gobject/Makefile
2732 m4macros/Makefile
2733 ])
2734
2735 AC_CONFIG_COMMANDS([chmod-scripts],
2736 [chmod 0755 glib-zip
2737 chmod 0755 glib-gettextize
2738 chmod 0755 gobject/glib-mkenums])
2739
2740 # we want to invoke this macro solely so that the config.status script
2741 # and automake generated makefiles know about these generated files.
2742 # They are only needed to distcheck the package
2743 if false; then
2744   AC_CONFIG_FILES([
2745     INSTALL
2746     README
2747     config.h.win32
2748     glibconfig.h.win32
2749     glib/makefile.msc
2750     glib/glib.rc
2751     gmodule/makefile.msc
2752     gmodule/gmodule.rc
2753     gobject/makefile.msc
2754     gobject/gobject.rc
2755     gthread/makefile.msc
2756     gthread/gthread.rc
2757     tests/makefile.msc
2758   ])
2759 fi
2760
2761 AC_OUTPUT