configure.in

   1 #  FLAC - Free Lossless Audio Codec
   2 #  Copyright (C) 2001,2002  Josh Coalson
   3 #
   4 #  This program is part of FLAC; you can redistribute it and/or
   5 #  modify it under the terms of the GNU General Public License
   6 #  as published by the Free Software Foundation; either version 2
   7 #  of the License, or (at your option) any later version.
   8 #
   9 #  This program is distributed in the hope that it will be useful,
  10 #  but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 #  GNU General Public License for more details.
  13 #
  14 #  You should have received a copy of the GNU General Public License
  15 #  along with this program; if not, write to the Free Software
  16 #  Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
  17
  18 # NOTE that for many of the AM_CONDITIONALs we use the prefix FLaC__
  19 # instead of FLAC__ since autoconf triggers off 'AC_' in strings
  20
  21 AC_INIT(src/flac/main.c)
  22 AM_INIT_AUTOMAKE(flac, 1.0.3)
  23
  24 # We need two libtools, one that builds both shared and static, and
  25 # one that builds only static.  This is because the resulting libtool
  26 # does not allow us to choose which to build at runtime.
  27 AM_PROG_LIBTOOL
  28 sed -e 's/^build_old_libs=yes/build_old_libs=no/' libtool > libtool-disable-static
  29 chmod +x libtool-disable-static
  30
  31 AC_PROG_CXX
  32 AC_PROG_MAKE_SET
  33
  34 dnl check for getopt in standard library
  35 dnl AC_CHECK_FUNCS(getopt_long , , [LIBOBJS="$LIBOBJS getopt.o getopt1.o"] )
  36 AC_CHECK_FUNCS(getopt_long, [], [])
  37
  38 AC_CANONICAL_HOST
  39 case "$host_cpu" in
  40         i*86)   cpu_ia32=true ; AC_DEFINE(FLAC__CPU_IA32) ;;
  41         powerpc)        cpu_ppc=true ; AC_DEFINE(FLAC__CPU_PPC) ;;
  42         sparc)  cpu_sparc=true ; AC_DEFINE(FLAC__CPU_SPARC) ;;
  43 esac
  44 AM_CONDITIONAL(FLaC__CPU_IA32, test x$cpu_ia32 = xtrue)
  45 AM_CONDITIONAL(FLaC__CPU_PPC, test x$cpu_ppc = xtrue)
  46 AM_CONDITIONAL(FLaC__CPU_SPARC, test x$cpu_sparc = xtrue)
  47 case "$host" in
  48         i[[3-6]]86-*-openbsd*) OBJ_FORMAT=aoutb ;;
  49         *) OBJ_FORMAT=elf ;;
  50 esac
  51 AC_SUBST(OBJ_FORMAT)
  52
  53 if test x$cpu_ia32 = xtrue ; then
  54 AC_DEFINE(FLAC__ALIGN_MALLOC_DATA)
  55 fi
  56
  57 AC_ARG_ENABLE(asm-optimizations, [  --disable-asm-optimizations    Don't use any assembly optimization routines], asm_opt=no, asm_opt=yes)
  58 AM_CONDITIONAL(FLaC__NO_ASM, test x$asm_opt = xno)
  59 if test x$asm_opt = xno ; then
  60 AC_DEFINE(FLAC__NO_ASM)
  61 fi
  62
  63 AC_ARG_ENABLE(debug,
  64 [  --enable-debug                 Turn on debugging],
  65 [case "${enableval}" in
  66         yes) debug=true ;;
  67         no)  debug=false ;;
  68         *) AC_MSG_ERROR(bad value ${enableval} for --enable-debug) ;;
  69 esac],[debug=false])
  70 AM_CONDITIONAL(DEBUG, test x$debug = xtrue)
  71
  72 AC_ARG_ENABLE(sse,
  73 [  --enable-sse                   Enable SSE support by asserting that the OS supports SSE instructions],
  74 [case "${enableval}" in
  75         yes) sse_os=true ;;
  76         no)  sse_os=false ;;
  77         *) AC_MSG_ERROR(bad value ${enableval} for --enable-sse) ;;
  78 esac],[sse_os=false])
  79 AM_CONDITIONAL(FLaC__SSE_OS, test x$sse_os = xtrue)
  80 if test x$sse_os = xtrue ; then
  81 AC_DEFINE(FLAC__SSE_OS)
  82 fi
  83
  84 AC_ARG_ENABLE(3dnow,
  85 [  --enable-3dnow                 Enable 3DNOW! support],
  86 [case "${enableval}" in
  87         yes) use_3dnow=true ;;
  88         no)  use_3dnow=false ;;
  89         *) AC_MSG_ERROR(bad value ${enableval} for --enable-3dnow) ;;
  90 esac],[use_3dnow=false])
  91 AM_CONDITIONAL(FLaC__USE_3DNOW, test x$use_3dnow = xtrue)
  92 if test x$use_3dnow = xtrue ; then
  93 AC_DEFINE(FLAC__USE_3DNOW)
  94 fi
  95
  96 AM_PATH_OGG(have_ogg=yes, AC_MSG_WARN([*** Ogg development enviroment not installed - Ogg support will not be built]))
  97 AM_CONDITIONAL(FLaC__HAS_OGG, [test x$have_ogg = xyes])
  98 if test x$have_ogg = xyes ; then
  99 AC_DEFINE(FLAC__HAS_OGG)
 100 fi
 101
 102 AM_PATH_XMMS(0.9.5.1, , AC_MSG_WARN([*** XMMS >= 0.9.5.1 not installed - xmms support will not be built]))
 103 AM_CONDITIONAL(FLaC__HAS_XMMS, test x$XMMS_INPUT_PLUGIN_DIR != x)
 104
 105 SHARE_LIBS='$(top_builddir)/src/share/libutf8.a $(top_builddir)/src/share/libgetopt.a'
 106
 107 dnl check for i18n(internationalization)
 108 AM_WITH_NLS
 109 AM_ICONV
 110 AM_LANGINFO_CODESET
 111
 112 dnl check id3lib librairies
 113 LIBS_save_blah_blah_blah=$LIBS
 114 LIBS=""
 115 AC_SEARCH_LIBS(ID3Tag_Link,"id3" "id3 -lstdc++" "id3 -lz" "id3 -lz -lstdc++",
 116                [have_id3lib=yes],
 117                [AC_MSG_WARN([id3lib not found - ID3v2 will not be supported, internal function support only id3v1])])
 118 AM_CONDITIONAL(FLaC__HAS_ID3LIB, [test x$have_id3lib = xyes])
 119 if test x$have_id3lib = xyes ; then
 120 AC_DEFINE(FLAC__HAS_ID3LIB)
 121 ID3LIBS=$LIBS
 122 fi
 123 AC_SUBST(ID3LIBS)
 124
 125 dnl expected version for cross compiling
 126 ID3LIB_MAJOR=3
 127 ID3LIB_MINOR=8
 128 ID3LIB_PATCH=0
 129
 130 AC_MSG_CHECKING(for id3lib version)
 131       AC_TRY_RUN([
 132 #include <id3.h>
 133 #include <stdio.h>
 134 int
 135 main ()
 136 {
 137     FILE *output;
 138     output=fopen("conftest.id3","w");
 139     fprintf(output,"ID3LIB_MAJOR=%d\nID3LIB_MINOR=%d\nID3LIB_PATCH=%d\n",ID3LIB_MAJOR_VERSION,ID3LIB_MINOR_VERSION,ID3LIB_PATCH_VERSION);
 140     fclose(output);
 141     exit(0);
 142 }
 143 ], . conftest.id3; echo "${ID3LIB_MAJOR}.${ID3LIB_MINOR}.${ID3LIB_PATCH}", AC_MSG_WARN(could not determine id3lib version),[echo $ac_n "cross compiling; assuming ${ID3LIB_MAJOR}.${ID3LIB_MINOR}.${ID3LIB_PATCH} $ac_c"])
 144 AC_DEFINE_UNQUOTED(ID3LIB_MAJOR, $ID3LIB_MAJOR)
 145 AC_DEFINE_UNQUOTED(ID3LIB_MINOR, $ID3LIB_MINOR)
 146 AC_DEFINE_UNQUOTED(ID3LIB_PATCH, $ID3LIB_PATCH)
 147
 148 LIBS=$LIBS_save_blah_blah_blah
 149
 150 AC_CHECK_PROGS(NASM, nasm)
 151 AM_CONDITIONAL(FLaC__HAS_NASM, test -n "$NASM")
 152 if test -n "$NASM" ; then
 153 AC_DEFINE(FLAC__HAS_NASM)
 154 fi
 155
 156 dnl Check for type sizes
 157
 158 AC_CHECK_SIZEOF(short)
 159 AC_CHECK_SIZEOF(int)
 160 AC_CHECK_SIZEOF(long)
 161 AC_CHECK_SIZEOF(long long)
 162
 163 case 2 in
 164         $ac_cv_sizeof_short) FLaC__SIZE16="short" ; FLaC__USIZE16="unsigned short";;
 165         $ac_cv_sizeof_int) FLaC__SIZE16="int" ; FLaC__USIZE16="unsigned int";;
 166 esac
 167
 168 case 4 in
 169         $ac_cv_sizeof_short) FLaC__SIZE32="short" ; FLaC__USIZE32="unsigned short";;
 170         $ac_cv_sizeof_int) FLaC__SIZE32="int" ; FLaC__USIZE32="unsigned int";;
 171         $ac_cv_sizeof_long) FLaC__SIZE32="long" ; FLaC__USIZE32="unsigned long";;
 172 esac
 173
 174 case 8 in
 175         $ac_cv_sizeof_int) FLaC__SIZE64="int" ; FLaC__USIZE64="unsigned int";;
 176         $ac_cv_sizeof_long) FLaC__SIZE64="long" ; FLaC__USIZE64="unsigned long";;
 177         $ac_cv_sizeof_long_long) FLaC__SIZE64="long long" ; FLaC__USIZE64="unsigned long long";;
 178 esac
 179
 180 if test -z "$FLaC__SIZE16"; then
 181         AC_MSG_ERROR(No 16 bit type found on this platform!)
 182 fi
 183 if test -z "$FLaC__USIZE16"; then
 184         AC_MSG_ERROR(No unsigned 16 bit type found on this platform!)
 185 fi
 186 if test -z "$FLaC__SIZE32"; then
 187         AC_MSG_ERROR(No 32 bit type found on this platform!)
 188 fi
 189 if test -z "$FLaC__USIZE32"; then
 190         AC_MSG_ERROR(No unsigned 32 bit type found on this platform!)
 191 fi
 192 if test -z "$FLaC__SIZE64"; then
 193         AC_MSG_WARN(No 64 bit type found on this platform!)
 194 fi
 195 if test -z "$FLaC__USIZE64"; then
 196         AC_MSG_ERROR(No unsigned 64 bit type found on this platform!)
 197 fi
 198
 199 AC_SUBST(FLaC__SIZE16)
 200 AC_SUBST(FLaC__USIZE16)
 201 AC_SUBST(FLaC__SIZE32)
 202 AC_SUBST(FLaC__USIZE32)
 203 AC_SUBST(FLaC__SIZE64)
 204 AC_SUBST(FLaC__USIZE64)
 205
 206 AC_SUBST(SHARE_LIBS)
 207
 208 OUR_CFLAGS_HEAD='-I$(top_builddir) -I$(srcdir)/include -I$(top_srcdir)/include'
 209 if test x$debug = xtrue; then
 210         OUR_CFLAGS_TAIL="-g -O0 -DDEBUG"
 211 else
 212         OUR_CFLAGS_TAIL="-O3 -DNDEBUG"
 213         if test x$GCC = xyes; then
 214                 OUR_CFLAGS_TAIL="$OUR_CFLAGS_TAIL -fomit-frame-pointer -funroll-loops -finline-functions -Wall -W -Winline -DFLaC__INLINE=__inline__"
 215         fi
 216 fi
 217 CFLAGS="$OUR_CFLAGS_HEAD $CFLAGS $OUR_CFLAGS_TAIL"
 218 CXXFLAGS="$OUR_CFLAGS_HEAD $CXXFLAGS $OUR_CFLAGS_TAIL"
 219
 220 AC_OUTPUT(      Makefile        \
 221         src/Makefile    \
 222         src/libFLAC/Makefile    \
 223         src/libFLAC/ia32/Makefile       \
 224         src/libFLAC/include/Makefile    \
 225         src/libFLAC/include/private/Makefile    \
 226         src/libFLAC/include/protected/Makefile  \
 227         src/libFLAC++/Makefile  \
 228         src/flac/Makefile       \
 229         src/metaflac/Makefile   \
 230         src/plugin_xmms/Makefile        \
 231         src/share/Makefile      \
 232         src/test_libFLAC/Makefile       \
 233         src/test_libFLAC++/Makefile     \
 234         src/test_streams/Makefile       \
 235         include/Makefile \
 236         include/FLAC/Makefile \
 237         include/FLAC/ordinals.h \
 238         include/FLAC++/Makefile \
 239         include/share/Makefile \
 240         doc/Makefile \
 241         doc/images/Makefile \
 242         doc/ru/Makefile \
 243         man/Makefile \
 244         test/Makefile   \
 245 )