configure.in

   1 dnl configure.in for RPM
   2 dnl
   3 dnl Don't add checks for things we can't work around, unless those checks
   4 dnl failing causes the script to bomb out with a message. If we can't fix
   5 dnl it, why check it?
   6
   7 AC_INIT(rpm.c)
   8 AM_CONFIG_HEADER(config.h)
   9 AC_PREREQ(2.12)         dnl Minimum Autoconf version required.
  10
  11 AM_INIT_AUTOMAKE(rpm, 2.90)
  12
  13 AC_CANONICAL_HOST
  14 dnl XXX AM_MAINTAINER_MODE
  15
  16 dnl Set of available languages.
  17 ALL_LINGUAS="cz de fi fr pt_BR ru sk sr sv tr"
  18
  19 LIBOBJS=
  20
  21 dnl YYY AC_CANONICAL_SYSTEM
  22
  23 dnl Checks for programs.
  24 AC_PROG_CC
  25 if test "$ac_cv_prog_gcc" = yes; then
  26     CFLAGS="$CFLAGS -Wall -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wno-char-subscripts"
  27 fi
  28
  29 AC_PROG_CPP
  30 AC_PROG_GCC_TRADITIONAL
  31 AC_PROG_INSTALL
  32
  33 dnl
  34 dnl if CC is gcc, we can rebuild the dependencies (since the depend rule
  35 dnl requires gcc).  If it's not, don't rebuild dependencies -- use what was
  36 dnl shipped with RPM.
  37 dnl
  38 if test X"$GCC" = Xyes ; then
  39         TARGET="depend everything"
  40 else
  41         TARGET="everything"
  42         #
  43         # let the top level Makefile know that we're done with `depend'
  44         #
  45         echo > .depend-done
  46 fi
  47 AC_SUBST(TARGET)
  48
  49
  50 dnl
  51 dnl This is a quick hack, to make it so that we can statically link the
  52 dnl rpm binary on as many platforms as possible.
  53 dnl
  54 dnl a *much* better solution would be to use libtool to determine the proper
  55 dnl way to statically link on your platform.
  56 dnl
  57 AC_MSG_CHECKING(what additional CFLAGS are needed to link statically)
  58 if test X"$GCC" = Xyes ; then
  59         case "$target" in
  60                 *-*-hpux*)              LDFLAGS_STATIC="-Wl,-a,archive_shared";; #works better
  61                 *-*-*)                  LDFLAGS_STATIC="-static";;
  62         esac
  63 elif test X"$CC" = Xcc ; then
  64         case "$target" in
  65                 *-*-linux*)             LDFLAGS_STATIC="-static";;
  66                 *-*-freebsd*)   LDFLAGS_STATIC="-static";;
  67                 *-*-osf*)               LDFLAGS_STATIC="-non_shared";;
  68                 *-*-aix*)               LDFLAGS_STATIC="";;  # -Wl,-bnso doesn't seem to work...
  69                 *-*-hpux*)              LDFLAGS_STATIC="-Wl,-a,archive_shared";;
  70                 *-*-solaris*)   LDFLAGS_STATIC="-B static";;
  71                 *-*-irix*)              LDFLAGS_STATIC="";;  #should be -non_shared, but can't
  72                                                                                         # link because of crt1.o then.
  73                 *-*-ultrix*)    LDFLAGS_STATIC="";;  #ultrix doesn't have shared libs.
  74                 *-*-*)                  LDFLAGS_STATIC=""
  75 AC_MSG_WARN([
  76
  77 Unable to guess what option to pass to $CC to generate a static
  78 executable.  You will need to set the LDFLAGS_STATIC macro in Makefile.inc to
  79 the appropriate argument(s) if you want to build a static rpm executable.
  80
  81 ])
  82                 ;;
  83         esac
  84 else
  85         # just link it dynamically
  86         LDFLAGS_STATIC=""
  87 fi
  88 AC_MSG_RESULT($LDFLAGS_STATIC)
  89
  90 if test -n "$LDFLAGS_STATIC"
  91 then
  92   AC_CHECKING(if we can link dynamically and still access the services switch)
  93   AC_CHECK_LIB(c,gethostbyname,
  94     AC_MSG_RESULT(will build static executable)
  95      RPM=rpm,
  96     AC_MSG_RESULT(will have to link dynamically)
  97      RPM=rpm.shared,
  98     $LDFLAGS_STATIC)
  99 fi
 100
 101 AC_MSG_CHECKING(POSIX chmod)
 102 touch foo.chmodtest
 103 chmod 744 foo.chmodtest
 104 chmod +X foo.chmodtest 2>/dev/null
 105 a=`ls -l foo.chmodtest | awk '{print $1}'`
 106 rm -f foo.chmodtest
 107 if test "$a" = "-rwxr-xr-x"; then
 108     AC_MSG_RESULT(yes)
 109     FIXPERMS=a+rX,g-w,o-w
 110 else
 111     AC_MSG_RESULT(no (tell your OS vendor about GNU fileutils))
 112     FIXPERMS=a+r,g-w,o-w
 113 fi
 114
 115 dnl
 116 dnl see if we have a mkdir that supports `-p'.
 117 dnl
 118 AC_PATH_PROGS(MKDIR, mkdir, mkdir)
 119 AC_MSG_CHECKING(if $MKDIR supports -p)
 120 rm -rf conftest
 121 $MKDIR -p conftest/a 2>/dev/null
 122 if test $? = 0 ; then
 123         rmdir conftest/a 2>/dev/null
 124         if test $? = 0  ; then
 125                 :
 126         else
 127                 MKDIR_P=0
 128         fi
 129
 130         rmdir conftest 2>/dev/null
 131         if test $? = 0 ; then
 132                 MKDIR_P="$MKDIR -p"
 133         else
 134                 MKDIR_P=0
 135         fi
 136 else
 137         MKDIR_P=0
 138 fi
 139
 140 if test X"$MKDIR_P" = X0 ; then
 141         AC_MSG_RESULT(no)
 142         MKDIR_P="`echo ${prefix}/lib/rpm/mkinstalldirs`"
 143 else
 144         AC_MSG_RESULT(yes)
 145 fi
 146 dnl
 147 dnl substitute this into config.h, so the C source picks it up.
 148 dnl
 149 AC_DEFINE_UNQUOTED(MKDIR_P, "${MKDIR_P}")
 150
 151
 152
 153 AC_AIX
 154 AC_MINIX
 155 AC_ISC_POSIX
 156
 157 dnl This test must precede tests of compiler characteristics like
 158 dnl that for the inline keyword, since it may change the degree to
 159 dnl which the compiler supports such features.
 160 AM_C_PROTOTYPES
 161
 162 AC_PROG_AWK
 163 AC_PROG_LN_S
 164 AC_PROG_MAKE_SET
 165 AC_PROG_RANLIB
 166
 167 AC_CHECK_TOOL(AR, ar, :)
 168
 169 if test "$cross_compiling" != "yes"; then
 170     MYPATH="/bin:/usr/bin:/usr/local/bin:$PATH:/opt/gnu/bin"
 171     AC_MSG_CHECKING(for gzip location)
 172     if test -z "$GZIPBIN"; then
 173             oldifs="$IFS"
 174             IFS=:
 175             for n in $MYPATH; do
 176                     if test -f $n/gzip; then
 177                             GZIPBIN="$n/gzip";
 178                             break
 179                     fi
 180             done
 181             IFS="$oldifs"
 182     fi
 183
 184     if test -z "$GZIPBIN"; then
 185             GZIPBIN="/bin/gzip"
 186             AC_MSG_RESULT(no)
 187             AC_MSG_WARN(Can't find gzip, assuming $GZIPBIN)
 188     else
 189             AC_MSG_RESULT($GZIPBIN)
 190     fi
 191
 192     AC_MSG_CHECKING(for bzip2 location)
 193     if test -z "$BZIP2BIN"; then
 194             oldifs="$IFS"
 195             IFS=:
 196             for n in $MYPATH; do
 197                     if test -f $n/bzip2; then
 198                             BZIP2BIN="$n/bzip2";
 199                             break
 200                     fi
 201             done
 202             IFS="$oldifs"
 203     fi
 204
 205     if test -z "$BZIP2BIN"; then
 206             BZIP2BIN="/usr/bin/bzip2"
 207             AC_MSG_RESULT(no)
 208             AC_MSG_WARN(Can't find bzip2, assuming $BZIP2BIN)
 209     else
 210             AC_MSG_RESULT($BZIP2BIN)
 211     fi
 212
 213     AC_MSG_CHECKING(old version of patch)
 214     PATCHVERSION=`patch --version 2>&1`
 215
 216     if test "$PATCHVERSION" = "Patch version 2.1"; then
 217         AC_DEFINE(HAVE_OLDPATCH_21)
 218         AC_MSG_RESULT(patch older then 2.2 found)
 219     else
 220         AC_MSG_RESULT(patch later then 2.2 found)
 221     fi
 222 fi
 223
 224 addlib() {
 225   l=$1
 226   shift
 227   case "$target" in
 228     *-*-solaris*)       LIBS="$LIBS -L$l -R$l $*";;
 229     *)          LIBS="$LIBS -L$l $*";;
 230   esac
 231 }
 232
 233 localdone=
 234 for dir in $prefix /usr/local
 235 do
 236         case $dir in
 237         NONE|/usr)      continue;;
 238         /usr/local)
 239                 if test X$localdone != X ; then continue; fi
 240                 localdone="$dir"
 241                 ;;
 242         esac
 243
 244         AC_MSG_CHECKING(for $dir/lib in LIBS)
 245         if test -d $dir/lib ; then
 246                 addlib $dir/lib
 247                 AC_MSG_RESULT(yes)
 248         else
 249                 AC_MSG_RESULT(no)
 250         fi
 251
 252         AC_MSG_CHECKING(for $dir/include in INCPATH)
 253         if test -d $dir/include ; then
 254                 INCPATH="$INCPATH -I$dir/include"
 255                 AC_MSG_RESULT(yes)
 256         else
 257                 AC_MSG_RESULT(no)
 258         fi
 259 done
 260
 261 AC_MSG_CHECKING(for /usr/ucblib in LIBS)
 262 if test -d /usr/ucblib ; then
 263         if test "$build" = "mips-sni-sysv4" ; then
 264                 addlib /usr/ccs/lib -lc
 265         fi
 266
 267         addlib /usr/ucblib
 268
 269         AC_MSG_RESULT(yes)
 270 else
 271         AC_MSG_RESULT(no)
 272 fi
 273
 274 dnl Checks for libraries.
 275
 276 AC_CHECK_FUNC(strcasecmp, [], [
 277     AC_CHECK_LIB(ucb, strcasecmp, [LIBS="$LIBS -lc -lucb" USEUCB=y])
 278 ])
 279 AC_CHECK_FUNC(setreuid, [], [
 280     AC_CHECK_LIB(ucb, setreuid, [if echo $LIBS | grep -- -lucb >/dev/null ;then :; else LIBS="$LIBS -lc -lucb" USEUCB=y;fi])
 281 ])
 282
 283 AC_CHECK_FUNC(rand, [], [
 284     AC_CHECK_LIB(rand, rand, [LIBS="$LIBS -lm"])
 285 ])
 286
 287 AC_CHECK_FUNC(getdomainname, [], [
 288     AC_CHECK_LIB(nsl, getdomainname, [LIBS="$LIBS -lnsl"])
 289 ])
 290 AC_CHECK_FUNC(socket, [], [
 291     AC_CHECK_LIB(socket, socket, [LIBS="$LIBS -lsocket"])
 292 ])
 293
 294 AC_CHECK_FUNC(dbopen, [],
 295   AC_CHECK_LIB(db, dbopen, [], AC_MSG_WARN([sorry this package needs libdb.a
 296 (from the db package)]))
 297            )
 298
 299 AC_CHECK_FUNC(fork, [], [echo "using vfork() instead of fork()";
 300         LIBOBJS=fakefork.o])
 301
 302 dnl AmigaOS and IXEmul have a fork() dummy
 303     case "$target" in
 304         m68k-*-amigaos )
 305                 echo "Building for AmigaOS: using vfork() instead of fork()";
 306                 CFLAGS="$CFLAGS -Dfork=vfork"
 307                 ;;
 308 esac
 309
 310
 311 ZLIB=
 312 for zlib in z gz ; do
 313    AC_CHECK_LIB(${zlib}, gzread,
 314         [LIBS="$LIBS -l${zlib}"; break],
 315         [if test ${zlib} = gz; then
 316             AC_MSG_WARN([sorry this package needs libz.a or libgz.a (from the zlib package)])
 317          fi]
 318                )
 319 done
 320
 321 dnl XXX these are needed only by rpmgettext right now
 322 AM_FUNC_ERROR_AT_LINE
 323
 324 dnl ==> AM_GNU_GETTEXT does this (and more)
 325 dnl AC_CHECK_HEADERS(unistd.h limits.h locale.h malloc.h string.h sys/param.h)
 326
 327 AM_GNU_GETTEXT
 328
 329 dnl Checks for header files we can live without.
 330 AC_HEADER_STDC
 331 AC_HEADER_MAJOR
 332 AC_HEADER_DIRENT
 333 AC_HEADER_TIME
 334
 335 AC_CHECK_HEADERS(db_185.h fcntl.h getopt.h grp.h memory.h netdb.h pwd.h utime.h)
 336
 337 AC_CHECK_HEADERS(sys/socket.h sys/select.h)
 338 AC_CHECK_HEADERS(sys/types.h sys/stdtypes.h)
 339 AC_CHECK_HEADERS(sys/mman.h sys/resource.h sys/utsname.h sys/wait.h)
 340
 341 AC_CHECK_HEADERS(netinet/in_systm.h)
 342 AC_CHECK_HEADERS(machine/types.h)
 343 AC_CHECK_HEADERS(mntent.h sys/mnttab.h sys/systemcfg.h)
 344 AC_CHECK_HEADERS(sys/mount.h sys/mntctl.h sys/vmount.h)
 345
 346 AC_C_BIGENDIAN
 347 AC_C_INLINE
 348
 349 dnl look for libc features
 350 PROVIDES_ERRNO=no
 351 AC_MSG_CHECKING(if <netdb.h> defines h_errno)
 352 AC_TRY_LINK([#include <netdb.h>],printf("%d",h_errno),PROVIDES_ERRNO=yes)
 353 AC_MSG_RESULT($PROVIDES_ERRNO)
 354 if test $PROVIDES_ERRNO = yes; then
 355         AC_DEFINE(HAVE_HERRNO)
 356 fi
 357
 358 dnl If a system doesn't have S_IFSOCK, define it as 0 which will
 359 dnl make S_ISSOCK always return false (nice, eh?)
 360 AC_MSG_CHECKING(if <sys/stat.h> defines S_IFSOCK)
 361 AC_TRY_LINK([#include <sys/stat.h>],printf("%d", S_IFSOCK),
 362         HAS_S_IFSOCK=yes,HAS_S_IFSOCK=no)
 363 AC_MSG_RESULT($HAS_S_IFSOCK)
 364 if test $HAS_S_IFSOCK = yes; then
 365         AC_DEFINE(HAVE_S_IFSOCK)
 366 fi
 367
 368 dnl Some Unix's are missing S_ISLNK, S_ISSOCK
 369 AC_MSG_CHECKING(if <sys/stat.h> defines S_ISLNK)
 370 AC_TRY_LINK([#include <sys/stat.h>],printf("%d", S_ISLNK(0755)),
 371         HAS_S_ISLNK=yes,HAS_S_ISLNK=no)
 372 AC_MSG_RESULT($HAS_S_ISLNK)
 373 if test $HAS_S_ISLNK = yes; then
 374         AC_DEFINE(HAVE_S_ISLNK)
 375 fi
 376
 377 AC_MSG_CHECKING(if <sys/stat.h> defines S_ISSOCK)
 378 AC_TRY_LINK([#include <sys/stat.h>],printf("%d", S_ISSOCK(0755)),
 379         HAS_S_ISSOCK=yes,HAS_S_ISSOCK=no)
 380 AC_MSG_RESULT($HAS_S_ISSOCK)
 381 if test $HAS_S_ISSOCK = yes; then
 382         AC_DEFINE(HAVE_S_ISSOCK)
 383 fi
 384
 385 AC_MSG_CHECKING(if timezone is defined)
 386 AC_TRY_LINK([#include <time.h>],printf("%ld", timezone),
 387       HAS_TIMEZONE=yes,HAS_TIMEZONE=no)
 388 AC_MSG_RESULT($HAS_TIMEZONE)
 389
 390 dnl Check for missing typedefs
 391 AC_TYPE_MODE_T
 392 AC_TYPE_PID_T
 393
 394 dnl Checks for library functions.
 395 AC_FUNC_ALLOCA
 396 AC_FUNC_VPRINTF
 397
 398 AC_FUNC_FNMATCH
 399 if test $ac_cv_func_fnmatch_works = no; then
 400    LIBOBJS="$LIBOBJS fnmatch.o"
 401    AC_DEFINE_UNQUOTED(fnmatch, rpl_fnmatch)
 402 fi
 403
 404 dnl XXX AC_FUNC_MEMCMP
 405 dnl XXX AC_FUNC_MMAP
 406 dnl XXX AC_TYPE_SIGNAL
 407 dnl XXX AC_FUNC_STRCOLL
 408 dnl XXX AC_FUNC_STRFTIME
 409 dnl XXX AC_FUNC_UTIME_NULL
 410 dnl XXX AC_FUNC_VFORK
 411 dnl XXX AC_CHECK_FUNCS(gethostname lchown mkdir mkfifo rmdir select uname)
 412
 413 AC_REPLACE_FUNCS(getcwd getwd glob inet_aton putenv realpath)
 414 AC_REPLACE_FUNCS(strdup strerror strtol strtoul strspn strstr)
 415
 416 dnl XXX stpcpy/stpncpy needed by rpmgettext
 417 AC_REPLACE_FUNCS(stpcpy stpncpy strcasecmp strncasecmp strcspn)
 418
 419 AC_CHECK_FUNCS(setlocale)
 420
 421 AC_CHECK_FUNC(getmntent, AC_DEFINE(HAVE_GETMNTENT), [
 422   AC_CHECK_FUNC(mntctl, AC_DEFINE(HAVE_MNTCTL),[
 423     AC_CHECK_FUNC(getmntinfo_r, AC_DEFINE(HAVE_GETMNTINFO_R), [
 424       AC_CHECK_LIB(c_r, getmntinfo_r, [LIBS="$LIBS -lc_r";
 425                                         AC_DEFINE(HAVE_GETMNTINFO_R)],
 426                  LIBOBJS="$LIBOBJS getmntent.o")])])])
 427 LCHOWN=no
 428 AC_CHECK_FUNC(lchown, [LCHOWN=yes; AC_DEFINE(HAVE_LCHOWN)])
 429
 430 if test "$LCHOWN" = no; then
 431     dnl Does chown() follow symlinks? This should be a good enough test.
 432     AC_MSG_CHECKING(whether chown() follows symlinks)
 433     AC_ARG_ENABLE([broken-chown],
 434     [  --enable-broken-chown  this system's chown follows symbolic links],
 435             result=$enableval, result=unknown)
 436     if echo "$build" | egrep "(aix)|(hpux)|(linux)" > /dev/null ; then
 437         result=yes
 438     elif echo "$build" | egrep "(nextstep)" > /dev/null ; then
 439         result=no
 440     fi
 441     if test $result = unknown; then
 442         if test `id | cut -f2 -d\= | cut -f1 -d\(` = 0; then
 443             rm -f foo bar
 444             touch foo
 445             ln -s foo bar
 446             chown 10 bar
 447             if test `ls -l foo | awk '{print $3}'` != "root"; then
 448                 result=yes
 449             else
 450                 result=no
 451             fi
 452             rm -f foo bar
 453         else
 454             AC_MSG_CHECKING((cannot check by non-root user))
 455             result=no
 456         fi
 457     fi
 458
 459     AC_MSG_RESULT($result)
 460     if test $result = yes; then
 461             AC_DEFINE(CHOWN_FOLLOWS_SYMLINK)
 462     fi
 463 fi
 464
 465
 466 dnl
 467 dnl figure out what root's primary group is
 468 dnl
 469 AC_MSG_CHECKING(root's primary group)
 470 AC_TRY_RUN([#include <stdio.h>
 471 #include <sys/types.h>
 472 #include <pwd.h>
 473 #include <grp.h>
 474
 475 int main()
 476 {
 477         struct passwd *root = NULL;
 478         struct group *roots_group = NULL;
 479         FILE * tempfile = NULL;
 480
 481         root = getpwuid( (uid_t) 0 );
 482         if (root != NULL) {
 483                 roots_group = getgrgid(root->pw_gid);
 484                 if (roots_group != NULL) {
 485                         tempfile = fopen("conftest_rootg", "w");
 486                         if (tempfile != NULL) {
 487                                 fprintf(tempfile, "%s\n", roots_group->gr_name);
 488                                 fclose(tempfile);
 489                                 exit(0);
 490                         }
 491                 }
 492         }
 493
 494         exit(1);
 495 }], ROOT_GROUP=`cat conftest_rootg`,
 496         ROOT_GROUP="root",ROOT_GROUP="root"
 497 )
 498 AC_DEFINE_UNQUOTED(ROOT_GROUP, "$ROOT_GROUP")
 499 AC_MSG_RESULT($ROOT_GROUP)
 500 AC_SUBST(ROOT_GROUP)
 501
 502 if test "x$varprefix" = "x"; then
 503     varprefix=`echo $prefix | sed 's/usr/var/'`
 504     test "x$prefix" = xNONE && varprefix=`echo $ac_default_prefix | sed 's/usr/var/'`
 505 fi
 506
 507 if test "x$tmpdir" = "x"; then
 508     if test -d $varprefix/tmp; then
 509         tmpdir=$varprefix/tmp
 510     else
 511         if test -d /var/tmp; then
 512             tmpdir=/var/tmp
 513         else
 514             tmpdir=/tmp
 515         fi
 516     fi
 517 fi
 518
 519 if echo "$build_os" | grep sco > /dev/null; then
 520         echo "hacking things up for sco"
 521         AC_DEFINE(NEED_STRINGS_H)
 522         AC_DEFINE(HAVE_STRUCT_MNTTAB)
 523 elif echo "$build_os" | grep sunos > /dev/null; then
 524         echo "hacking things up for sunos"
 525         CFLAGS="$CFLAGS -D__USE_FIXED_PROTOTYPES__"
 526         AC_DEFINE(NEED_STRINGS_H)
 527         AC_DEFINE(NEED_MYREALLOC)
 528         LIBOBJS="$LIBOBJS myrealloc.o"
 529 elif echo "$build_os" | grep hpux > /dev/null; then
 530         LIBDL=-ldld
 531         echo "hacking things up for hpux"
 532 fi
 533
 534 #
 535 # get rid of the 4-th tuple, if config.guess returned "linux-gnu" for build_os
 536 #
 537 if echo "$build_os" | grep '.*-gnu' > /dev/null ; then
 538         build_os=`echo "${build_os}" | sed 's/-gnu$//'`
 539 fi
 540
 541 changequote(<, >)
 542 build_os_exact="${build_os}"
 543 build_os_major=`echo "${build_os}" | sed 's/\..*$//'`
 544 build_os_noversion=`echo "${build_os}" | sed 's/[0-9]*\..*$//'`
 545 changequote([, ])
 546
 547 rm -f ./find-provides.sh
 548 if test -f ${srcdir}/autodeps/${build_os_exact}.prov ; then
 549         echo "using ${srcdir}/autodeps/${build_os_exact}.prov for automatic provides generation"
 550     ln -s ${srcdir}/autodeps/${build_os_exact}.prov ./find-provides.sh
 551 elif test -f ${srcdir}/autodeps/${build_os_major}.prov ; then
 552         echo "using ${srcdir}/autodeps/${build_os_major}.prov for automatic provides generation"
 553     ln -s ${srcdir}/autodeps/${build_os_major}.prov ./find-provides.sh
 554 elif test -f ${srcdir}/autodeps/${build_os_noversion}.prov ; then
 555         echo "using ${srcdir}/autodeps/${build_os_noversion}.prov for automatic provides generation"
 556     ln -s ${srcdir}/autodeps/${build_os_noversion}.prov ./find-provides.sh
 557 else
 558     echo "*** no default provides information is available for ${build_os_noversion}"
 559     ln -s ${srcdir}/autodeps/none ./find-provides.sh
 560 fi
 561
 562 rm -f ./find-requires.sh
 563 if test -f ${srcdir}/autodeps/${build_os_exact}.req ; then
 564         echo "using ${srcdir}/autodeps/${build_os_exact}.req for automatic requires generation"
 565     ln -s ${srcdir}/autodeps/${build_os_exact}.req ./find-requires.sh
 566 elif test -f ${srcdir}/autodeps/${build_os_major}.req ; then
 567         echo "using ${srcdir}/autodeps/${build_os_major}.req for automatic requires generation"
 568     ln -s ${srcdir}/autodeps/${build_os_major}.req ./find-requires.sh
 569 elif test -f ${srcdir}/autodeps/${build_os_noversion}.req ; then
 570         echo "using ${srcdir}/autodeps/${build_os_noversion}.req for automatic requires generation"
 571     ln -s ${srcdir}/autodeps/${build_os_noversion}.req ./find-requires.sh
 572 else
 573     echo "*** no default requires information is available for ${build_os_noversion}"
 574     ln -s ${srcdir}/autodeps/none ./find-requires.sh
 575 fi
 576
 577
 578 if test -n "$LIBOBJS" ; then
 579         MISCDIR=misc
 580         LIBMISC=-lmisc
 581         MISCPATH=misc/libmisc.a
 582 fi
 583
 584 RPMCONFIGDIR="`echo ${prefix}/lib/rpm`"
 585 AC_DEFINE_UNQUOTED(RPMCONFIGDIR, "$RPMCONFIGDIR")
 586 AC_SUBST(RPMCONFIGDIR)
 587 LIBRPMRC_FILENAME="${RPMCONFIGDIR}/rpmrc"
 588 AC_DEFINE_UNQUOTED(LIBRPMRC_FILENAME, "$LIBRPMRC_FILENAME")
 589 AC_SUBST(LIBRPMRC_FILENAME)
 590 LIBRPMALIAS_FILENAME="${RPMCONFIGDIR}/rpmpopt"
 591 AC_DEFINE_UNQUOTED(LIBRPMALIAS_FILENAME, "$LIBRPMALIAS_FILENAME")
 592 AC_SUBST(LIBRPMALIAS_FILENAME)
 593 FINDREQUIRES="${RPMCONFIGDIR}/find-requires"
 594 AC_DEFINE_UNQUOTED(FINDREQUIRES, "$FINDREQUIRES")
 595 AC_SUBST(FINDREQUIRES)
 596 FINDPROVIDES="${RPMCONFIGDIR}/find-provides"
 597 AC_DEFINE_UNQUOTED(FINDPROVIDES, "$FINDPROVIDES")
 598 AC_SUBST(FINDPROVIDES)
 599 MACROFILES="${RPMCONFIGDIR}/macros"
 600 AC_DEFINE_UNQUOTED(MACROFILES, "$MACROFILES")
 601 AC_SUBST(MACROFILES)
 602
 603 AC_SUBST(LIBOBJS)
 604 AC_SUBST(INCPATH)
 605
 606 AC_SUBST(varprefix)
 607 AC_SUBST(tmpdir)
 608
 609 AC_SUBST(LIBS)
 610 AC_SUBST(LIBDL)
 611
 612 AC_SUBST(RPM)
 613 AC_SUBST(GZIPBIN)
 614 AC_SUBST(BZIP2BIN)
 615 AC_SUBST(FIXPERMS)
 616 AC_SUBST(MISCDIR)
 617 AC_SUBST(LIBMISC)
 618 AC_SUBST(MISCPATH)
 619 AC_SUBST(MKDIR_P)
 620 AC_SUBST(LDFLAGS_STATIC)
 621
 622 # XXX Propagate -lucb to popt ...
 623 export LIBS INCPATH
 624
 625 AC_CONFIG_SUBDIRS(popt)
 626 AC_OUTPUT([Makefile Makefile.inc lib-rpmrc macros lib/Makefile
 627         build/Makefile tools/Makefile scripts/Makefile
 628         misc/Makefile po/Makefile.in intl/Makefile],
 629         [sed -e "/POTFILES =/r po/POTFILES" po/Makefile.in > po/Makefile])