configure.in

   1 dnl ***********************************
   2 dnl *** include special GLib macros ***
   3 dnl ***********************************
   4 builtin(include, acglib.m4)dnl
   5
   6 # require autoconf 2.13
   7 AC_PREREQ(2.13)
   8
   9 # Process this file with autoconf to produce a configure script.
  10 AC_INIT(glist.c)
  11
  12 # Save this value here, since automake will set cflags later
  13 cflags_set=${CFLAGS+set}
  14
  15 # we rewrite this file
  16 rm -f glibconfig-sysdefs.h
  17
  18 dnl we to AC_DIVERT_PUSH/AC_DIVERT_POP these variable definitions so they
  19 dnl are available for $ac_help expansion (don't we all *love* autoconf?)
  20 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  21 #
  22 # The following version number definitions apply to GLib and GModule
  23 # as a whole, so if changes occoured in either of them, they are both
  24 # treated with the same interface and binary age.
  25 #
  26 # Making releases:
  27 #   GLIB_MICRO_VERSION += 1;
  28 #   GLIB_INTERFACE_AGE += 1;
  29 #   GLIB_BINARY_AGE += 1;
  30 # if any functions have been added, set GLIB_INTERFACE_AGE to 0.
  31 # if backwards compatibility has been broken,
  32 # set GLIB_BINARY_AGE and GLIB_INTERFACE_AGE to 0.
  33 #
  34 GLIB_MAJOR_VERSION=1
  35 GLIB_MINOR_VERSION=3
  36 GLIB_MICRO_VERSION=0
  37 GLIB_INTERFACE_AGE=0
  38 GLIB_BINARY_AGE=0
  39 GLIB_VERSION=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION.$GLIB_MICRO_VERSION
  40 dnl
  41 AC_DIVERT_POP()dnl
  42
  43 AC_SUBST(GLIB_VERSION)
  44
  45 # libtool versioning
  46 LT_RELEASE=$GLIB_MAJOR_VERSION.$GLIB_MINOR_VERSION
  47 LT_CURRENT=`expr $GLIB_MICRO_VERSION - $GLIB_INTERFACE_AGE`
  48 LT_REVISION=$GLIB_INTERFACE_AGE
  49 LT_AGE=`expr $GLIB_BINARY_AGE - $GLIB_INTERFACE_AGE`
  50 AC_SUBST(LT_RELEASE)
  51 AC_SUBST(LT_CURRENT)
  52 AC_SUBST(LT_REVISION)
  53 AC_SUBST(LT_AGE)
  54
  55 VERSION=$GLIB_VERSION
  56 PACKAGE=glib
  57
  58 AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
  59
  60 # Specify a configuration file
  61 AM_CONFIG_HEADER(config.h)
  62
  63 AC_DEFINE_UNQUOTED(GLIB_MAJOR_VERSION, $GLIB_MAJOR_VERSION)
  64 AC_DEFINE_UNQUOTED(GLIB_MINOR_VERSION, $GLIB_MINOR_VERSION)
  65 AC_DEFINE_UNQUOTED(GLIB_MICRO_VERSION, $GLIB_MICRO_VERSION)
  66 AC_DEFINE_UNQUOTED(GLIB_INTERFACE_AGE, $GLIB_INTERFACE_AGE)
  67 AC_DEFINE_UNQUOTED(GLIB_BINARY_AGE, $GLIB_BINARY_AGE)
  68
  69 dnl Initialize libtool
  70 AM_PROG_LIBTOOL
  71
  72 dnl Initialize maintainer mode
  73 AM_MAINTAINER_MODE
  74
  75 AC_CANONICAL_HOST
  76
  77 dnl figure debugging default, prior to $ac_help setup
  78 dnl
  79 AC_DIVERT_PUSH(AC_DIVERSION_NOTICE)dnl
  80 if test `expr $GLIB_MINOR_VERSION \% 2` = 1 ; then
  81         debug_default=yes
  82 else
  83         debug_default=minimum
  84 fi
  85 AC_DIVERT_POP()dnl
  86
  87 dnl declare --enable-* args and collect ac_help strings
  88 AC_ARG_ENABLE(debug, [  --enable-debug=[no/minimum/yes] turn on debugging [default=$debug_default]],,enable_debug=$debug_default)
  89 AC_ARG_ENABLE(mem_check, [  --enable-mem-check      turn on malloc/free sanity checking [default=no]],,enable_mem_check=no)
  90 AC_ARG_ENABLE(mem_profile, [  --enable-mem-profile    turn on malloc profiling atexit [default=no]],,enable_mem_profile=no)
  91 AC_ARG_ENABLE(ansi, [  --enable-ansi           turn on strict ansi [default=no]],
  92                     , enable_ansi=no)
  93 AC_ARG_ENABLE(threads, [  --enable-threads        turn on basic thread support [default=yes]
  94                           ([=no] will override --with-threads)],,enable_threads=yes)
  95
  96 if test "x$enable_threads" != "xyes"; then
  97   enable_threads=no
  98 fi
  99
 100 AC_MSG_CHECKING(whether to enable memory checking)
 101 if test "x$enable_mem_check" = "xyes"; then
 102   AC_DEFINE(ENABLE_MEM_CHECK, 1)
 103   AC_SUBST(ENABLE_MEM_CHECK)
 104   AC_MSG_RESULT(yes)
 105 else
 106   AC_MSG_RESULT(no)
 107 fi
 108
 109 AC_MSG_CHECKING(whether to enable memory profiling)
 110 if test "x$enable_mem_profile" = "xyes"; then
 111   AC_DEFINE(ENABLE_MEM_PROFILE, 1)
 112   AC_SUBST(ENABLE_MEM_PROFILE)
 113   AC_MSG_RESULT(yes)
 114 else
 115   AC_MSG_RESULT(no)
 116 fi
 117
 118 if test "x$enable_debug" = "xyes"; then
 119   test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 120   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 121 else
 122   if test "x$enable_debug" = "xno"; then
 123     GLIB_DEBUG_FLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 124   fi
 125 fi
 126
 127 AC_DEFINE_UNQUOTED(G_COMPILED_WITH_DEBUGGING, "${enable_debug}")
 128
 129 # Checks for programs.
 130 AC_PROG_CC
 131 AM_PROG_CC_STDC
 132 AC_PROG_INSTALL
 133
 134 changequote(,)dnl
 135 if test "x$GCC" = "xyes"; then
 136   case " $CFLAGS " in
 137   *[\ \ ]-Wall[\ \      ]*) ;;
 138   *) CFLAGS="$CFLAGS -Wall" ;;
 139   esac
 140
 141   if test "x$enable_ansi" = "xyes"; then
 142     case " $CFLAGS " in
 143     *[\ \       ]-ansi[\ \      ]*) ;;
 144     *) CFLAGS="$CFLAGS -ansi" ;;
 145     esac
 146
 147     case " $CFLAGS " in
 148     *[\ \       ]-pedantic[\ \  ]*) ;;
 149     *) CFLAGS="$CFLAGS -pedantic" ;;
 150     esac
 151   fi
 152 fi
 153 changequote([,])dnl
 154
 155 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 156 AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 157 glib_save_LIBS=$LIBS
 158 LIBS="$LIBS -lm"
 159 AC_TRY_RUN([#include <math.h>
 160              int main (void) { return (log(1) != log(1.)); }],
 161      AC_MSG_RESULT(none needed),
 162      glib_save_CFLAGS=$CFLAGS
 163      CFLAGS="$CFLAGS -std1"
 164      AC_TRY_RUN([#include <math.h>
 165                  int main (void) { return (log(1) != log(1.)); }],
 166          AC_MSG_RESULT(-std1),
 167          AC_MSG_RESULT()
 168          CFLAGS=$glib_save_CFLAGS
 169          AC_MSG_WARN(
 170                 [No ANSI prototypes found in library. (-std1 didn't work.)])
 171      )
 172 )
 173 LIBS=$glib_save_LIBS
 174
 175 dnl NeXTStep cc seems to need this
 176 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 177 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 178   AC_MSG_RESULT(none needed),
 179   glib_save_CFLAGS=$CFLAGS
 180   CFLAGS="$CFLAGS -posix"
 181   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 182     AC_MSG_RESULT(-posix),
 183     AC_MSG_RESULT()
 184     CFLAGS=$glib_save_CFLAGS
 185     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 186
 187 # Checks for header files.
 188 AC_HEADER_STDC
 189
 190 # Checks for library functions.
 191 AC_FUNC_VPRINTF
 192
 193 AC_CHECK_FUNCS(atexit on_exit)
 194
 195 AC_CHECK_SIZEOF(char)
 196 AC_CHECK_SIZEOF(short)
 197 AC_CHECK_SIZEOF(long)
 198 AC_CHECK_SIZEOF(int)
 199 AC_CHECK_SIZEOF(void *)
 200 AC_CHECK_SIZEOF(long long)
 201
 202 dnl long doubles were not used, and a portability problem
 203 dnl AC_C_LONG_DOUBLE
 204 AC_C_CONST
 205
 206 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 207 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 208 dnl actually supported.
 209 AC_MSG_CHECKING(for __inline)
 210 AC_CACHE_VAL(glib_cv_has__inline,[
 211         AC_TRY_RUN([
 212         __inline int foo () { return 0; }
 213         int main () { return foo (); }
 214         ],
 215         glib_cv_has__inline=yes
 216         ,
 217         glib_cv_has__inline=no
 218         ,)
 219 ])
 220 AC_MSG_RESULT($glib_cv_has__inline)
 221 case x$glib_cv_has__inline in
 222 xyes) AC_DEFINE(G_HAVE___INLINE)
 223 esac
 224 AC_MSG_CHECKING(for __inline__)
 225 AC_CACHE_VAL(glib_cv_has__inline__,[
 226         AC_TRY_RUN([
 227         __inline__ int foo () { return 0; }
 228         int main () { return foo (); }
 229         ],
 230         glib_cv_has__inline__=yes
 231         ,
 232         glib_cv_has__inline__=no
 233         ,)
 234 ])
 235 AC_MSG_RESULT($glib_cv_has__inline__)
 236 case x$glib_cv_has__inline__ in
 237 xyes) AC_DEFINE(G_HAVE___INLINE__)
 238 esac
 239 AC_MSG_CHECKING(for inline)
 240 AC_CACHE_VAL(glib_cv_hasinline,[
 241         AC_TRY_RUN([
 242         inline int foo () { return 0; }
 243         int main () { return foo (); }
 244         ],
 245         glib_cv_hasinline=yes
 246         ,
 247         glib_cv_hasinline=no
 248         ,)
 249 ])
 250 AC_MSG_RESULT($glib_cv_hasinline)
 251 case x$glib_cv_hasinline in
 252 xyes) AC_DEFINE(G_HAVE_INLINE)
 253 esac
 254
 255 dnl for bytesex stuff
 256 AC_C_BIGENDIAN
 257
 258 dnl header file checks
 259 AC_CHECK_HEADERS(float.h, AC_DEFINE(HAVE_FLOAT_H))
 260 AC_CHECK_HEADERS(limits.h, AC_DEFINE(HAVE_LIMITS_H))
 261 AC_CHECK_HEADERS(pwd.h, AC_DEFINE(HAVE_PWD_H))
 262 AC_CHECK_HEADERS(sys/param.h, AC_DEFINE(HAVE_SYS_PARAM_H))
 263 AC_CHECK_HEADERS(sys/poll.h, AC_DEFINE(HAVE_SYS_POLL_H))
 264 AC_CHECK_HEADERS(sys/select.h, AC_DEFINE(HAVE_SYS_SELECT_H))
 265 AC_CHECK_HEADERS(sys/time.h, AC_DEFINE(HAVE_SYS_TIME_H))
 266 AC_CHECK_HEADERS(sys/times.h, AC_DEFINE(HAVE_SYS_TIMES_H))
 267 AC_CHECK_HEADERS(unistd.h, AC_DEFINE(HAVE_UNISTD_H))
 268 AC_CHECK_HEADERS(values.h, AC_DEFINE(HAVE_VALUES_H))
 269
 270 # Check for some functions
 271 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf strcasecmp strncasecmp poll)
 272
 273 # Check for sys_errlist
 274 AC_MSG_CHECKING(for sys_errlist)
 275 AC_TRY_LINK(, [
 276 extern char *sys_errlist[];
 277 extern int sys_nerr;
 278 sys_errlist[sys_nerr-1][0] = 0;
 279 ], glib_ok=yes, glib_ok=no)
 280 AC_MSG_RESULT($glib_ok)
 281 if test $glib_ok = no; then
 282     AC_DEFINE(NO_SYS_ERRLIST)
 283 fi
 284
 285 # Check for sys_siglist
 286 AC_MSG_CHECKING(for sys_siglist)
 287 AC_TRY_LINK(, [
 288 extern char *sys_siglist[];
 289 strlen (sys_siglist[0]);
 290 ], glib_ok=yes, glib_ok=no)
 291 AC_MSG_RESULT($glib_ok)
 292 if test $glib_ok = no; then
 293     AC_DEFINE(NO_SYS_SIGLIST)
 294 fi
 295
 296 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
 297 AC_MSG_CHECKING(for sys_siglist declaration)
 298 AC_TRY_COMPILE([#include <signal.h>], [
 299 strlen (sys_siglist[0]);
 300 ], glib_ok=yes, glib_ok=no)
 301 AC_MSG_RESULT($glib_ok)
 302 if test $glib_ok = no; then
 303     AC_DEFINE(NO_SYS_SIGLIST_DECL)
 304 fi
 305
 306 # Check if <sys/select.h> needs to be included for fd_set
 307 AC_MSG_CHECKING([for fd_set])
 308 AC_TRY_COMPILE([#include <sys/types.h>],
 309         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
 310 if test $gtk_ok = yes; then
 311     AC_MSG_RESULT([yes, found in sys/types.h])
 312 else
 313     AC_HEADER_EGREP(fd_mask, sys/select.h, gtk_ok=yes)
 314     if test $gtk_ok = yes; then
 315         AC_DEFINE(HAVE_SYS_SELECT_H)
 316         AC_MSG_RESULT([yes, found in sys/select.h])
 317     else
 318         AC_DEFINE(NO_FD_SET)
 319         AC_MSG_RESULT(no)
 320     fi
 321 fi
 322
 323 # These are used only in GDK (gdki18n.h)
 324 # This stuff is here only so that we can define these
 325 # things in glibconfig.h. If gtk+ started using an installed
 326 # gdkconfig.h file, then the definitions would belong there.
 327
 328 # Check for wchar.h
 329
 330 AC_MSG_CHECKING(for wchar.h)
 331 AC_TRY_CPP([#include <wchar.h>], glib_wchar_h=yes, glib_wchar_h=no)
 332 if test $glib_wchar_h = yes; then
 333    AC_DEFINE(HAVE_WCHAR_H)
 334 fi
 335 AC_MSG_RESULT($glib_wchar_h)
 336
 337 # Check for wctype.h (for iswalnum)
 338
 339 AC_MSG_CHECKING(for wctype.h)
 340 AC_TRY_CPP([#include <wctype.h>], glib_wctype_h=yes, glib_wctype_h=no)
 341 if test $glib_wctype_h = yes; then
 342    AC_DEFINE(HAVE_WCTYPE_H)
 343 fi
 344 AC_MSG_RESULT($glib_wctype_h)
 345
 346 oLIBS="$LIBS"
 347 # in Solaris 2.5, `iswalnum' is in -lw
 348 AC_CHECK_FUNC(iswalnum,,[AC_CHECK_LIB(w,iswalnum)])
 349
 350 # The following is necessary for Linux libc-5.4.38
 351 AC_MSG_CHECKING(if iswalnum() and friends are properly defined)
 352 AC_TRY_LINK([#include <stdlib.h>],[
 353 #if (defined(HAVE_WCTYPE_H) || defined(HAVE_WCHAR_H))
 354 #  ifdef HAVE_WCTYPE_H
 355 #    include <wctype.h>
 356 #  else
 357 #    ifdef HAVE_WCHAR_H
 358 #      include <wchar.h>
 359 #    endif
 360 #  endif
 361 #else
 362 #  define iswalnum(c) ((wchar_t)(c) <= 0xFF && isalnum(c))
 363 #endif
 364 iswalnum((wchar_t) 0);
 365 ], glib_working_wctype=yes, glib_working_wctype=no)
 366 LIBS="$oLIBS"
 367
 368 if test $glib_working_wctype = no; then
 369    AC_DEFINE(HAVE_BROKEN_WCTYPE)
 370 fi
 371 AC_MSG_RESULT($glib_working_wctype)
 372
 373
 374 dnl **********************
 375 dnl *** va_copy checks ***
 376 dnl **********************
 377 dnl we currently check for all three va_copy possibilities, so we get
 378 dnl all results in config.log for bug reports.
 379 AC_MSG_CHECKING(for an implementation of va_copy())
 380 AC_CACHE_VAL(glib_cv_va_copy,[
 381         AC_TRY_RUN([
 382         #include <stdarg.h>
 383         void f (int i, ...) {
 384         va_list args1, args2;
 385         va_start (args1, i);
 386         va_copy (args2, args1);
 387         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 388           exit (1);
 389         va_end (args1); va_end (args2);
 390         }
 391         int main() {
 392           f (0, 42);
 393           return 0;
 394         }],
 395         glib_cv_va_copy=yes
 396         ,
 397         glib_cv_va_copy=no
 398         ,)
 399 ])
 400 AC_MSG_RESULT($glib_cv_va_copy)
 401 AC_MSG_CHECKING(for an implementation of __va_copy())
 402 AC_CACHE_VAL(glib_cv___va_copy,[
 403         AC_TRY_RUN([
 404         #include <stdarg.h>
 405         void f (int i, ...) {
 406         va_list args1, args2;
 407         va_start (args1, i);
 408         __va_copy (args2, args1);
 409         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 410           exit (1);
 411         va_end (args1); va_end (args2);
 412         }
 413         int main() {
 414           f (0, 42);
 415           return 0;
 416         }],
 417         glib_cv___va_copy=yes
 418         ,
 419         glib_cv___va_copy=no
 420         ,)
 421 ])
 422 AC_MSG_RESULT($glib_cv___va_copy)
 423 AC_MSG_CHECKING(whether va_lists can be copied by value)
 424 AC_CACHE_VAL(glib_cv_va_val_copy,[
 425         AC_TRY_RUN([
 426         #include <stdarg.h>
 427         void f (int i, ...) {
 428         va_list args1, args2;
 429         va_start (args1, i);
 430         args2 = args1;
 431         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 432           exit (1);
 433         va_end (args1); va_end (args2);
 434         }
 435         int main() {
 436           f (0, 42);
 437           return 0;
 438         }],
 439         glib_cv_va_val_copy=yes
 440         ,
 441         glib_cv_va_val_copy=no
 442         ,)
 443 ])
 444 if test "x$glib_cv_va_copy" = "xyes"; then
 445   AC_DEFINE(G_VA_COPY, va_copy)
 446 else if test "x$glib_cv___va_copy" = "xyes"; then
 447   AC_DEFINE(G_VA_COPY, __va_copy)
 448 fi
 449 fi
 450 if test "x$glib_cv_va_val_copy" = "xno"; then
 451   AC_DEFINE(G_VA_COPY_AS_ARRAY)
 452 fi
 453 AC_MSG_RESULT($glib_cv_va_val_copy)
 454
 455
 456 dnl ***********************
 457 dnl *** g_module checks ***
 458 dnl ***********************
 459 G_MODULE_LIBS=
 460 G_MODULE_LDFLAGS=
 461 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
 462 G_MODULE_NEED_USCORE=0
 463 G_MODULE_HAVE_DLERROR=0
 464 dnl *** dlopen() and dlsym() in system libraries
 465 if test -z "$G_MODULE_IMPL"; then
 466         AC_CHECK_FUNC(dlopen,
 467                 AC_CHECK_FUNC(dlsym,
 468                         G_MODULE_IMPL=G_MODULE_IMPL_DL
 469                 ,)
 470         ,)
 471 fi
 472 dnl *** dlopen() and dlsym() in libdl
 473 if test -z "$G_MODULE_IMPL"; then
 474         AC_CHECK_LIB(dl, dlopen,
 475                 AC_CHECK_LIB(dl, dlsym,
 476                         G_MODULE_LIBS=-ldl
 477                         G_MODULE_IMPL=G_MODULE_IMPL_DL
 478                 ,)
 479         ,)
 480 fi
 481 dnl *** shl_load() in libdld (HP-UX)
 482 if test -z "$G_MODULE_IMPL"; then
 483         AC_MSG_CHECKING(how to export all symbols)
 484         SAVED_LDFLAGS=$LDFLAGS
 485         LDFLAGS="$LDFLAGS -Wl,-E"
 486         AC_TRY_LINK(,[ return 0; ],
 487                 [ G_MODULE_LDFLAGS="-Wl,-E" ],[
 488                 LDFLAGS="$SAVED_LDFLAGS -bexpall"
 489                 AC_TRY_LINK(,[ return 0; ],
 490                         G_MODULE_LDFLAGS="-bexpall",
 491                         G_MODULE_LDFLAGS="none"
 492                 )
 493         ])
 494         LDFLAGS=$SAVED_LDFLAGS
 495         AC_MSG_RESULT($G_MODULE_LDFLAGS)
 496         if test "x$G_MODULE_LDFLAGS" = "xnone"; then
 497                 G_MODULE_LDFLAGS=
 498         fi
 499         AC_CHECK_LIB(dld, shl_load,
 500                 G_MODULE_LIBS=-ldld
 501                 G_MODULE_IMPL=G_MODULE_IMPL_DLD
 502         ,)
 503 fi
 504 dnl *** additional checks for G_MODULE_IMPL_DL
 505 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
 506         case "$host_os" in
 507           linux*)
 508             G_MODULE_LDFLAGS='-rdynamic'
 509             ;;
 510         esac
 511         LIBS_orig="$LIBS"
 512         LDFLAGS_orig="$LDFLAGS"
 513         LIBS="$LIBS $G_MODULE_LIBS"
 514         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
 515 dnl *** check whether we need preceeding underscores
 516         AC_MSG_CHECKING(for preceeding underscore in symbols)
 517         AC_CACHE_VAL(glib_cv_uscore,[
 518                 AC_TRY_RUN([
 519                 #include <dlfcn.h>
 520                 int glib_underscore_test (void) { return 42; }
 521                 int main() {
 522                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
 523                   handle = dlopen ((void*)0, 0);
 524                   if (handle) {
 525                     f1 = dlsym (handle, "glib_underscore_test");
 526                     f2 = dlsym (handle, "_glib_underscore_test");
 527                   } return (!f2 || f1);
 528                 }],
 529                         glib_cv_uscore=yes,
 530                         glib_cv_uscore=no,
 531                 )
 532                 rm -f plugin.c plugin.o plugin.lo
 533         ])
 534         AC_MSG_RESULT($glib_cv_uscore)
 535         if test "x$glib_cv_uscore" = "xyes"; then
 536                 G_MODULE_NEED_USCORE=1
 537         else
 538                 G_MODULE_NEED_USCORE=0
 539         fi
 540
 541         LDFLAGS="$LDFLAGS_orig"
 542 dnl *** check for having dlerror()
 543         AC_CHECK_FUNC(dlerror,
 544                 G_MODULE_HAVE_DLERROR=1,
 545                 G_MODULE_HAVE_DLERROR=0)
 546         LIBS="$LIBS_orig"
 547 fi
 548 dnl *** done, have e got an implementation?
 549 if test -z "$G_MODULE_IMPL"; then
 550         G_MODULE_IMPL=0
 551 fi
 552 AC_SUBST(G_MODULE_IMPL)
 553 AC_SUBST(G_MODULE_LIBS)
 554 AC_SUBST(G_MODULE_LDFLAGS)
 555 AC_SUBST(G_MODULE_HAVE_DLERROR)
 556 AC_SUBST(G_MODULE_NEED_USCORE)
 557 AC_SUBST(GLIB_DEBUG_FLAGS)
 558
 559
 560 dnl ***********************
 561 dnl *** g_thread checks ***
 562 dnl ***********************
 563
 564 AC_ARG_WITH(threads, [  --with-threads=[none/posix/solaris/nspr] specify a thread implementation to use],
 565         if test "x$with_threads" = x; then
 566                 want_threads=yes
 567         else
 568                 want_threads=$with_threads
 569         fi,
 570         want_threads=yes)
 571 if test "x$enable_threads" = "xno"; then
 572         want_threads=no
 573 fi
 574 if test "x$want_threads" = "xnone"; then
 575         want_threads=no
 576 fi
 577
 578 dnl error and warning message
 579 dnl *************************
 580
 581 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
 582                 computer. glib will not be thread safe on your computer."
 583
 584 FLAG_DOES_NOT_WORK="I can't find the MACRO, that enables thread safety on your
 585                 platform (normaly it's "_REENTRANT"). I'll not use any flag on
 586                 compilation now, but then your programs might not work.
 587                 Please provide information on how it is done on your system."
 588
 589 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
 590                 "
 591
 592 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
 593                 provide information on your thread implementation.
 594                 You can also run 'configure --disable-threads'
 595                 to compile without thread support."
 596
 597 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
 598                 functions will not be MT-safe during their first call because
 599                 there is no working 'getpwuid_r' on your system."
 600
 601 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
 602                 because there is no 'localtime_r' on your system."
 603
 604 dnl determination of thread implementation
 605 dnl ***************************************
 606
 607 have_threads=none
 608 if test "x$want_threads" = xyes || test "x$want_threads" = xsolaris; then
 609         case $host in
 610                 *-*-solaris*)
 611                 AC_CHECK_LIB(thread, cond_init, have_threads=solaris)
 612                 ;;
 613         esac
 614 fi
 615 if test "x$want_threads" = xyes || test "x$want_threads" = xposix; then
 616         if test "x$have_threads" = xnone; then
 617                 AC_CHECK_HEADER(pthread.h, have_threads=posix)
 618         fi
 619 fi
 620 if test "x$want_threads" = xyes || test "x$want_threads" = xnspr; then
 621         if test "x$have_threads" = xnone; then
 622                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar, have_threads=nspr)
 623         fi
 624 fi
 625
 626 AC_MSG_CHECKING(for thread implementation)
 627
 628 if test "x$have_threads" = xnone && test "x$want_threads" != xno; then
 629         AC_MSG_RESULT(none available)
 630         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
 631 else
 632         AC_MSG_RESULT($have_threads)
 633 fi
 634
 635
 636 dnl determination of G_THREAD_LIBS
 637 dnl ******************************
 638
 639 G_THREAD_LIBS=
 640 G_THREAD_CFLAGS=
 641
 642 mutex_has_default=no
 643 case $have_threads in
 644         posix)
 645                 G_THREAD_LIBS=error
 646                 AC_CHECK_LIB(pthread, pthread_attr_init,
 647                              G_THREAD_LIBS="-lpthread")
 648                 if test "x$G_THREAD_LIBS" = xerror; then
 649                         AC_CHECK_LIB(pthreads, pthread_attr_init,
 650                                 G_THREAD_LIBS="-lpthreads")
 651                 fi
 652                 if test "x$G_THREAD_LIBS" = xerror; then
 653                         AC_CHECK_LIB(c_r, pthread_attr_init,
 654                                 G_THREAD_LIBS="-lc_r")
 655                 fi
 656                 if test "x$G_THREAD_LIBS" = xerror; then
 657                         AC_CHECK_FUNC(pthread_attr_init, G_THREAD_LIBS="")
 658                 fi
 659                 dnl ********** DG/UX ************
 660                 if test "x$G_THREAD_LIBS" = xerror; then
 661                         AC_CHECK_LIB(thread, __d10_pthread_attr_init,
 662                                 G_THREAD_LIBS="-lthread"
 663                                 G_THREAD_CFLAGS="-D_POSIX4A_DRAFT10_SOURCE")
 664                 fi
 665                 dnl ********* HPUX 11 ***********
 666                 if test "x$G_THREAD_LIBS" = xerror; then
 667                         AC_CHECK_LIB(pthread, __pthread_attr_init_system,
 668                                 G_THREAD_LIBS="-lpthread")
 669                 fi
 670                 mutex_has_default=yes
 671                 mutex_default_type='pthread_mutex_t'
 672                 mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
 673                 mutex_header_file='pthread.h'
 674                 g_threads_impl="POSIX"
 675                 ;;
 676         solaris)
 677                 G_THREAD_LIBS=error
 678                 AC_CHECK_LIB(thread, cond_init, G_THREAD_LIBS="-lthread")
 679                 mutex_has_default=yes
 680                 mutex_default_type='mutex_t'
 681                 mutex_default_init="DEFAULTMUTEX"
 682                 mutex_header_file='thread.h'
 683                 g_threads_impl="SOLARIS"
 684                 ;;
 685         nspr)
 686                 AC_CHECK_LIB(nspr21, PRP_NewNakedCondVar,
 687                              G_THREAD_LIBS="-lnspr21")
 688                 g_threads_impl="NSPR"
 689                 ;;
 690         none)
 691                 g_threads_impl="NONE"
 692                 ;;
 693         *)
 694                 g_threads_impl="NONE"
 695                 G_THREAD_LIBS=error
 696                 ;;
 697 esac
 698
 699 if test "x$G_THREAD_LIBS" = xerror; then
 700         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
 701 fi
 702
 703 AC_MSG_CHECKING(necessary linker options)
 704 AC_MSG_RESULT($G_THREAD_LIBS)
 705
 706 dnl determination of G_THREAD_CFLAGS
 707 dnl ********************************
 708
 709 if test x"$have_threads" != xnone; then
 710 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_REENTRANT" # good default guess
 711
 712     case $host in
 713         *-aix*)
 714                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 715                 if test x"$GCC" = xyes; then
 716                         G_THREAD_CFLAGS="$G_THREAD_CFLAGS -mthreads"
 717                 fi
 718                 ;;
 719         *-freebsd2.2*)
 720                 G_THREAD_CFLAGS="$G_THREAD_CFLAGS -D_THREAD_SAFE"
 721
 722                 # FreeBSD 2.2.x shiped with gcc 2.7.2.x, which doesn't support
 723                 # -mthreads flag.
 724                 ;;
 725     esac
 726
 727     # if we are not finding the ctime_r function, then we probably are
 728     # not using the proper multithread flag
 729     old_CPPFLAGS=$CPPFLAGS
 730     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
 731     AC_EGREP_HEADER([[^a-zA-Z_]ctime_r[^a-zA-Z_]], time.h, ,
 732     G_THREAD_CFLAGS=
 733     AC_MSG_WARN($FLAG_DOES_NOT_WORK))
 734     CPPFLAGS=$old_CPPFLAGS
 735
 736     AC_MSG_CHECKING(necessary compiler options)
 737
 738     AC_MSG_RESULT($G_THREAD_CFLAGS)
 739 else
 740     G_THREAD_CFLAGS=
 741 fi
 742
 743 dnl check for mt safe function variants
 744 dnl ***********************************
 745
 746 if test x"$have_threads" != xnone; then
 747         glib_save_LIBS="$LIBS"
 748         glib_save_CFLAGS="$CFLAGS"
 749         # we are not doing the following for now, as this might require glib
 750         # to always be linked with the thread libs on some platforms.
 751         # LIBS="$LIBS $G_THREAD_LIBS"
 752         CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 753         AC_CHECK_FUNCS(localtime_r rand_r)
 754         if test "$ac_cv_header_pwd_h" = "yes"; then
 755                 AC_MSG_CHECKING([for getpwuid_r])
 756                 AC_CACHE_VAL(ac_cv_func_getpwuid_r,
 757                         [AC_TRY_RUN([#include <errno.h>
 758                                 int main () { char buffer[10000], *pointer;
 759                                 char getpwuid_r (long, void*, void*,
 760                                         int, void*);
 761                                 errno = 0;
 762                                 getpwuid_r (0, &buffer, &buffer,
 763                                         sizeof (buffer), &pointer);
 764                                 return errno == ENOSYS;}],
 765                                 [ac_cv_func_getpwuid_r=yes],
 766                                 [ac_cv_func_getpwuid_r=no])])
 767                 if test "$ac_cv_func_getpwuid_r" = yes; then
 768                         AC_MSG_RESULT(yes)
 769                         AC_DEFINE(HAVE_GETPWUID_R)
 770                 else
 771                         AC_MSG_RESULT(no)
 772                 fi
 773                 if test "$ac_cv_func_getpwuid_r" = "yes"; then
 774                         AC_MSG_CHECKING(whether getpwuid_r is posix like)
 775                         # getpwuid_r(0, NULL, NULL, 0) is the signature on
 776                         # solaris, if that is not found, the prog below won't
 777                         # compile, then the posix signature is assumed as
 778                         # the default.
 779                         AC_TRY_COMPILE([#include <pwd.h>],
 780                                 [getpwuid_r(0, NULL, NULL, 0);],
 781                                 [AC_MSG_RESULT(no)],
 782                                 [AC_MSG_RESULT(yes)
 783                                 AC_DEFINE(HAVE_GETPWUID_R_POSIX)])
 784                 fi
 785         fi
 786         if test x"$have_threads" = xposix; then
 787                 AC_MSG_CHECKING(whether pthread_getspecific is posix like)
 788                 # PCThreads has pthread_getspecific(pthread_key_t, void **);
 789                 AC_TRY_COMPILE([#include <pthread.h>],
 790                         [pthread_getspecific(0,NULL);],
 791                         [AC_MSG_RESULT(no)],
 792                         [AC_MSG_RESULT(yes)
 793                         AC_DEFINE(HAVE_PTHREAD_GETSPECIFIC_POSIX)])
 794         fi
 795         LIBS="$glib_save_LIBS"
 796         CFLAGS="$glib_save_CFLAGS"
 797 fi
 798
 799 if test "x$enable_threads" = "xyes"; then
 800         if test "$ac_cv_func_getpwuid_r" != "yes"; then
 801                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
 802         fi
 803         if test "$ac_cv_func_localtime_r" != "yes"; then
 804                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
 805         fi
 806 fi
 807
 808 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c")
 809 AC_SUBST(G_THREAD_CFLAGS)
 810 AC_SUBST(G_THREAD_LIBS)
 811
 812 CFLAGS="$CFLAGS $G_THREAD_CFLAGS"
 813
 814 dnl **********************************************
 815 dnl *** GDefaultMutex setup and initialization ***
 816 dnl **********************************************
 817 dnl
 818 dnl if mutex_has_default = yes, we also got
 819 dnl mutex_default_type, mutex_default_init and mutex_header_file
 820 GLIB_IF_VAR_EQ(mutex_has_default, yes,
 821         GLIB_SIZEOF([#include <$mutex_header_file>],
 822                     $mutex_default_type,
 823                     gmutex,
 824                     )
 825         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
 826                            $mutex_default_type,
 827                            gmutex,
 828                            $glib_cv_sizeof_gmutex,
 829                            $mutex_default_init)
 830         ,
 831 )
 832
 833
 834 dnl ****************************************
 835 dnl *** GLib POLL* compatibility defines ***
 836 dnl ****************************************
 837 GLIB_SYSDEFS(
 838 [#include <sys/types.h>
 839 #include <sys/poll.h>],
 840         POLLIN:1 POLLOUT:4 POLLPRI:2 POLLERR:8 POLLHUP:16 POLLNVAL:32,
 841         glibconfig-sysdefs.h,
 842         =)
 843
 844
 845 dnl ******************************
 846 dnl *** output the whole stuff ***
 847 dnl ******************************
 848
 849 AC_OUTPUT_COMMANDS([
 850
 851 ## Generate `glibconfig.h' in two cases
 852 ## 1. `config.status' is run either explicitly, or via configure.
 853 ##     Esp. not when it is run in `Makefile' to generate makefiles and
 854 ##     config.h
 855 ## 2. CONFIG_OTHER is set explicitly
 856 ##
 857 ## Case 1 is difficult.  We know that `automake' sets one of
 858 ## CONFIG_FILES or CONFIG_HEADERS to empty.  This heuristic works
 859 ## only when AM_CONFIG_HEADER is set, however.
 860
 861 if test -n "${CONFIG_FILES}" && test -n "${CONFIG_HEADERS}"; then
 862   # Both CONFIG_FILES and CONFIG_HEADERS are non-empty ==> Case 1
 863   CONFIG_OTHER=${CONFIG_OTHER:-glibconfig.h}
 864 fi
 865 case "$CONFIG_OTHER" in
 866 *glibconfig.h*)
 867         echo creating glibconfig.h
 868         outfile=glibconfig.h-tmp
 869         cat > $outfile <<\_______EOF
 870 /* glibconfig.h
 871  *
 872  * This is a generated file.  Please modify `configure.in'
 873  */
 874
 875 #ifndef GLIBCONFIG_H
 876 #define GLIBCONFIG_H
 877
 878 #ifdef __cplusplus
 879 extern "C" {
 880 #endif /* __cplusplus */
 881
 882 _______EOF
 883
 884         if test x$glib_limits_h = xyes; then
 885           echo '#include <limits.h>' >> $outfile
 886         fi
 887         if test x$glib_float_h = xyes; then
 888           echo '#include <float.h>' >> $outfile
 889         fi
 890         if test x$glib_values_h = xyes; then
 891           echo '#include <values.h>' >> $outfile
 892         fi
 893         if test x$g_mutex_header_file != x; then
 894           echo '#include <'"$g_mutex_header_file"'>' >> $outfile
 895         fi
 896         if test x$glib_sys_poll_h = xyes; then
 897           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
 898         fi
 899
 900         cat >> $outfile <<_______EOF
 901
 902 #define G_MINFLOAT      $glib_mf
 903 #define G_MAXFLOAT      $glib_Mf
 904 #define G_MINDOUBLE     $glib_md
 905 #define G_MAXDOUBLE     $glib_Md
 906 #define G_MINSHORT      $glib_ms
 907 #define G_MAXSHORT      $glib_Ms
 908 #define G_MININT        $glib_mi
 909 #define G_MAXINT        $glib_Mi
 910 #define G_MINLONG       $glib_ml
 911 #define G_MAXLONG       $glib_Ml
 912
 913 _______EOF
 914
 915
 916         ### this should always be true in a modern C/C++ compiler
 917         cat >>$outfile <<_______EOF
 918 typedef signed char gint8;
 919 typedef unsigned char guint8;
 920 _______EOF
 921
 922
 923         if test -n "$gint16"; then
 924           cat >>$outfile <<_______EOF
 925 typedef signed $gint16 gint16;
 926 typedef unsigned $gint16 guint16;
 927 _______EOF
 928         fi
 929
 930
 931         if test -n "$gint32"; then
 932           cat >>$outfile <<_______EOF
 933 typedef signed $gint32 gint32;
 934 typedef unsigned $gint32 guint32;
 935 _______EOF
 936         fi
 937
 938
 939         if test -n "$gint64"; then
 940           cat >>$outfile <<_______EOF
 941 ${glib_warning_guard}#define G_HAVE_GINT64 1
 942
 943 ${glib_extension}typedef signed $gint64 gint64;
 944 ${glib_extension}typedef unsigned $gint64 guint64;
 945
 946 #define G_GINT64_CONSTANT(val)  $gint64_constant
 947 _______EOF
 948         fi
 949
 950
 951         if test -z "$glib_unknown_void_p"; then
 952           cat >>$outfile <<_______EOF
 953
 954 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
 955 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
 956
 957 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
 958 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
 959 _______EOF
 960         else
 961           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
 962         fi
 963
 964
 965
 966         cat >>$outfile <<_______EOF
 967 $glib_atexit
 968 $glib_memmove
 969 $glib_defines
 970
 971 $glib_vacopy
 972
 973 #ifdef  __cplusplus
 974 #define G_HAVE_INLINE   1
 975 #else   /* !__cplusplus */
 976 $glib_inline
 977 #endif  /* !__cplusplus */
 978 _______EOF
 979
 980         echo >>$outfile
 981         if test x$g_mutex_has_default = xyes; then
 982                 cat >>$outfile <<_______EOF
 983 $g_enable_threads_def G_THREADS_ENABLED
 984 #define G_THREADS_IMPL_$g_threads_impl_def
 985 typedef struct _GStaticMutex GStaticMutex;
 986 struct _GStaticMutex
 987 {
 988   struct _GMutex *runtime_mutex;
 989   union {
 990     char   pad[$g_mutex_sizeof];
 991     double dummy_double;
 992     void  *dummy_pointer;
 993     long   dummy_long;
 994   } aligned_pad_u;
 995 };
 996 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
 997 #define g_static_mutex_get_mutex(mutex) \
 998   (g_thread_use_default_impl ? ((GMutex*) &((mutex)->aligned_pad_u)) : \
 999    g_static_mutex_get_mutex_impl (&((mutex)->runtime_mutex)))
1000 _______EOF
1001         else
1002                 cat >>$outfile <<_______EOF
1003 $g_enable_threads_def G_THREADS_ENABLED
1004 #define G_THREADS_IMPL_$g_threads_impl_def
1005 typedef struct _GMutex* GStaticMutex;
1006 #define G_STATIC_MUTEX_INIT NULL
1007 #define g_static_mutex_get_mutex(mutex) (g_static_mutex_get_mutex_impl (mutex))
1008 _______EOF
1009         fi
1010
1011         echo >>$outfile
1012         g_bit_sizes="16 32"
1013         if test -n "$gint64"; then
1014           g_bit_sizes="$g_bit_sizes 64"
1015         fi
1016         for bits in $g_bit_sizes; do
1017           cat >>$outfile <<_______EOF
1018 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
1019 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
1020 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
1021 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
1022 _______EOF
1023         done
1024
1025         cat >>$outfile <<_______EOF
1026 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
1027 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
1028 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
1029 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
1030 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
1031 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
1032 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
1033 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
1034 #define G_BYTE_ORDER $g_byte_order
1035
1036 _______EOF
1037
1038         if test -r glibconfig-sysdefs.h; then
1039           cat glibconfig-sysdefs.h >>$outfile
1040         fi
1041
1042
1043         cat >>$outfile <<_______EOF
1044
1045 $glib_wc
1046
1047
1048 #ifdef __cplusplus
1049 }
1050 #endif /* __cplusplus */
1051
1052 #endif /* GLIBCONFIG_H */
1053 _______EOF
1054
1055
1056         if cmp -s $outfile glibconfig.h; then
1057           echo glibconfig.h is unchanged
1058           rm -f $outfile
1059         else
1060           mv $outfile glibconfig.h
1061         fi ;;
1062 esac
1063 ],[
1064
1065 # Note that if two cases are the same, case goes with the first one.
1066 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
1067 # on variable expansion in case labels.  Look at the generated config.status
1068 # for a hint.
1069
1070 case xyes in
1071 x$ac_cv_header_float_h)
1072   glib_float_h=yes
1073   glib_mf=FLT_MIN glib_Mf=FLT_MAX
1074   glib_md=DBL_MIN glib_Md=DBL_MAX
1075   ;;
1076 x$ac_cv_header_values_h)
1077   glib_values_h=yes
1078   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
1079   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
1080   ;;
1081 esac
1082
1083 case xyes in
1084 x$ac_cv_header_limits_h)
1085   glib_limits_h=yes
1086   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX
1087   glib_mi=INT_MIN  glib_Mi=INT_MAX
1088   glib_ml=LONG_MIN glib_Ml=LONG_MAX
1089   ;;
1090 x$ac_cv_header_values_h)
1091   glib_values_h=yes
1092   glib_ms=MINSHORT glib_Ms=MAXSHORT
1093   glib_mi=MININT   glib_Mi=MAXINT
1094   glib_ml=MINLONG  glib_Ml=MAXLONG
1095   ;;
1096 esac
1097
1098 if test x$ac_cv_header_sys_poll_h = xyes ; then
1099   glib_sys_poll_h=yes
1100 fi
1101
1102 case 2 in
1103 $ac_cv_sizeof_short)            gint16=short;;
1104 $ac_cv_sizeof_int)              gint16=int;;
1105 esac
1106 case 4 in
1107 $ac_cv_sizeof_short)            gint32=short;;
1108 $ac_cv_sizeof_int)              gint32=int;;
1109 $ac_cv_sizeof_long)             gint32=long;;
1110 esac
1111 case 8 in
1112 $ac_cv_sizeof_int)
1113   gint64=int
1114   glib_extension=
1115   glib_warning_guard=
1116   gint64_constant='(val)'
1117   ;;
1118 $ac_cv_sizeof_long)
1119   gint64=long
1120   glib_extension=
1121   glib_warning_guard=
1122   gint64_constant='(val##L)'
1123   ;;
1124 $ac_cv_sizeof_long_long)
1125   gint64='long long'
1126   glib_extension='G_GNUC_EXTENSION '
1127   glib_warning_guard="
1128 #if defined (__GNUC__) && __GNUC__ >= 2 && __GNUC_MINOR__ >= 8
1129 #  define G_GNUC_EXTENSION __extension__
1130 #else
1131 #  define G_GNUC_EXTENSION
1132 #endif
1133
1134 "
1135   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
1136   ;;
1137 esac
1138
1139 gintbits=`expr $ac_cv_sizeof_int \* 8`
1140 glongbits=`expr $ac_cv_sizeof_long \* 8`
1141
1142
1143 case $ac_cv_sizeof_void_p in
1144 $ac_cv_sizeof_int)      glib_gpi_cast=''        glib_gpui_cast=''         ;;
1145 $ac_cv_sizeof_long)     glib_gpi_cast='(glong)' glib_gpui_cast='(gulong)' ;;
1146 *)                      glib_unknown_void_p=yes ;;
1147 esac
1148
1149
1150 case xyes in
1151 x$ac_cv_func_atexit)
1152   glib_atexit="
1153 #ifdef NeXT /* @#%@! NeXTStep */
1154 # define g_ATEXIT(proc) (!atexit (proc))
1155 #else
1156 # define g_ATEXIT(proc) (atexit (proc))
1157 #endif"
1158   ;;
1159 x$ac_cv_func_on_exit)
1160   glib_atexit="
1161 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
1162   ;;
1163 esac
1164
1165 case xyes in
1166 x$ac_cv_func_memmove)
1167   glib_memmove='
1168 #define g_memmove(d,s,n) G_STMT_START { memmove ((d), (s), (n)); } G_STMT_END'
1169   ;;
1170 *)
1171   glib_memmove="
1172 /* We make the assumption that if memmove isn't available, then
1173  * bcopy will do the job. This isn't safe everywhere. (bcopy can't
1174  * necessarily handle overlapping copies) */
1175 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
1176   ;;
1177 esac
1178
1179 glib_defines="
1180 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
1181 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
1182 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
1183 "
1184
1185 case xyes in
1186 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
1187 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
1188 *)                      glib_vacopy=''
1189 esac
1190
1191 if test x$glib_cv_va_val_copy = xno; then
1192   glib_vacopy="\$glib_vacopy
1193 #define G_VA_COPY_AS_ARRAY 1"
1194 fi
1195
1196 if test x$glib_cv_hasinline = xyes; then
1197     glib_inline='#define G_HAVE_INLINE 1'
1198 fi
1199 if test x$glib_cv_has__inline = xyes; then
1200     glib_inline="\$glib_inline
1201 #define G_HAVE___INLINE 1"
1202 fi
1203 if test x$glib_cv_has__inline__ = xyes; then
1204     glib_inline="\$glib_inline
1205 #define G_HAVE___INLINE__ 1"
1206 fi
1207
1208 case xyes in
1209 x$ac_cv_c_bigendian)
1210   g_byte_order=G_BIG_ENDIAN
1211   g_bs_native=BE
1212   g_bs_alien=LE
1213   ;;
1214 *)
1215   g_byte_order=G_LITTLE_ENDIAN
1216   g_bs_native=LE
1217   g_bs_alien=BE
1218   ;;
1219 esac
1220
1221 if test x$glib_wchar_h = xyes; then
1222   glib_wc='
1223 #define G_HAVE_WCHAR_H 1'
1224 fi
1225 if test x$glib_wctype_h = xyes; then
1226   glib_wc="\$glib_wc
1227 #define G_HAVE_WCTYPE_H 1"
1228 fi
1229 if test x$glib_working_wctype = xno; then
1230   glib_wc="\$glib_wc
1231 #define G_HAVE_BROKEN_WCTYPE 1"
1232 fi
1233
1234 case x$enable_threads in
1235 xyes)   g_enable_threads_def="#define";;
1236 *)      g_enable_threads_def="#undef ";;
1237 esac
1238
1239 g_threads_impl_def=$g_threads_impl
1240
1241 g_mutex_has_default="$mutex_has_default"
1242 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
1243 g_mutex_contents="$glib_cv_byte_contents_gmutex"
1244 ])
1245
1246 AC_OUTPUT([
1247 glib.spec
1248 Makefile
1249 glib-config
1250 gmodule/gmoduleconf.h
1251 gmodule/Makefile
1252 gthread/Makefile
1253 docs/Makefile
1254 tests/Makefile
1255 ],[case "$CONFIG_FILES" in
1256 *glib-config*)chmod +x glib-config;;
1257 esac])